         TITLE 'GJP SYSOUT DISPLAY DESCRIPTION'                         00200018
* MODULE NAME       -IKAPDIS0                                           00560018
* CSECT  NAME       -IKAPDIS0                                           00600018
*                                                                       00640018
* FUNCTION          -DISPLAY SYSOUT DATA SETS WHICH RESULT FROM GJP     00680018
*                   -EITHER ENQUE SYSOUT DATA SETS ON PRINT OR PUNCH    00720018
*                    QUEUE (OR BOTH) OR DELETE                          00760018
* ATTRIBUTES        -NON-RESIDENT                                       00800018
*                   -REENTRANT                                          00840018
* INPUT             REG ONE -ADDR CCT                                   00880018
*                   JCL DATA SET  DSB'S,JFCB'S                          00920018
* OUTPUT            SYSOUT DATA SET DISPLAY                             00960018
*                                                                       01000018
* OPERATION                                                             01080018
*              IKAPDIS0 MODULE CONSISTS OF THREE CSECTS.                01120018
         SPACE 3                                                        01160018
*                 * IKAPDIS0. TO GET AND DISPLAY DESIRED RECORDS FROM   01200018
*                             SYSOUT DATA SETS, ENQUEUE SYSOUT DATA SET 01240018
*                             ON PRINT/PUNCH QUEUE.                     01280018
*                                                                       01320018
         SPACE 3                                                        01360018
*                 * IKAADIS0 .TO HANDLE ATTENTIONS BY PUTTING INPUT     01400018
*                             INTO WORKAREA,(OR IF ATTENTION IS INVALID 01440018
*                             PUTTING MESSAGE IN MESSAGE AREA) & PUT    01480018
*                             ADDRESS OF APPROPRIATE PHASE OF IKAPDIS0  01520018
*                             INTO WORKAREA AND POSTING ECB.            01560018
*                                                                       01600018
         SPACE 3                                                        01640018
*                 * IKAMDIS0. NON-EXECUTABLE CODE. CONSISTS OF MESSAGES 01680018
*                             TO BE DISPLAYED.                          01720018
*                                                                       01760018
         EJECT                                                          02080018
* IKAPDIS0 CSECT PHASE ONE    * INITIALIZATION *                        02120018
*                                                                       02160018
*              THE FUNCTION OF PHASE ONE IS TO PERFORM ALL INITIZATION  02200018
*              FOR THE IKAPDIS0 MODULE.                                 02240018
*                                                                       02280018
*              ESTABLISH ADDRESSABILITY FOR ITSELF AND FOR CCT          02320018
*                                                                       02360018
*              GETMAIN FOR WORKAREA (13K), CLEAR WORKAREA AND ESTABLISH 02400018
*              ADDRESSABILITY FOR WORKAREA.                             02440018
*                                                                       02480018
*              ESTABLISH COMMUNICATION WITH ATTENTION ROUTINE BY        02520018
*              PUTTING ADDRESS OF ATTENTION ROUTINE IN GJP'S GACB AND   02560018
*              ADDRESS  OF WORKAREA IN THE GRAPHIC COMMUNICATION AREA   02600018
*              FOR GACB.                                                02640018
*                                                                       02680018
*              OPEN WORK DATA SET (GJPDIS1) TO HOLD BLOCKS OF 25-132    02720018
*              BYTE SYSOUT RECORDS                                      02760018
*                                                                       02800018
*              PUT ADDR OF END OF DATA AND SYNAD ROUTINES INTO JCL DCB  02840018
*              TRANSLATE ONE BYTE QUE NAMES FOR PRINT, PUNCH AND GSP    02880018
*              FOREGROUND JOBS                                          02920018
*              BRANCH TO POINT JCL DATA SET IN PHASE 2                  02960018
* PHASE TWO    CYCLE                                                    03000018
*              IF THIS IS NOT FIRST SYSOUT DS, CLOSE IT AND BRANCH TO   03040018
*              POINT JCL DCB AT FIRST RECORD                            03080018
*              SEARCH TIOT FOR DUMMY ENTRY                              03120018
*              SAVE DUMMY TIOT ENTRY                                    03160018
*   CLEARTTR   CLEAR TTRTABLE (TABLE OFADDR OF BLOCKS IN WORK DS)       03200018
*              READ JCL DATA SET TILL DSB IS FOUND                      03240018
*              SAVE DDNAME IN DSB                                       03280018
*              PUT TIOT INFORMATION ABOUT SYSOUT DS IN DSB INTO DUMMY   03320018
*              ENTRY IN TIOT                                            03360018
*              OPEN SYSOUT DS                                           03400018
*              REPLACE DUMMY ENTRY IN TIOT                              03440018
*              INCREMENT COUNT OF DATA SETS OPENED                      03480018
*              CALCULATE AND SAVE BUFFER ADDR FOR CURSOR INSERTION      03520018
*              RESET POINTER TO TTRTABLE                                03560018
*              USING COUNT OF DATA SETS OPEN ADD PRINT/PUNCH TABLE PUT  03600018
*              XS INTO DISPLAY IF REQUIRED                              03640018
*              CLEARTTR                                                 03680018
         EJECT                                                          03720018
* PHASE THREE  NEWDISP   THIS PHASE WILL GET THE REQUIRED SYSOUT DATA   03760018
*              SET RECORDS. IT DOES THIS BY USING QSAM TO GET RECORDS   03800018
*              FROM SYSOUT DATA SET.  TO ALLOW NEXT/BACK CAPABILITY     03840018
*              (ALLOW USER TO SKIP AROUND IN DATA SET) WITH A RESONABL  03880018
*              E RESPONSE TIME,  SYSOUT RECORDS ARE PADDED OR TRUNCATED 03920018
*              TO A LENGTH OF 132 BYTES, BLOCKED 25 TO A BLOCK AND      03960018
*              WRITTEN TO A GJP DATA SET (GJPDIS1).  A TABLE OF TTR     04000018
*              ADDRESSES IS BUILT AS BLOCKS ARE WRITTEN SO THAT ANY     04040018
*              BLOCK CAN BE READ WHEN NEEDED.  THE ENTIRE SYSOUT DATA   04080018
*              SET IS NOT WRITTEN ALL AT ONCE BUT ONLY AS NEEDED.  THIS 04120018
*              MEANS THAT A USER WHO ONLY WANTS TO VIEW A FEW RECORDS   04160018
*              AT THE BEGINING OF A DATA SET DOES NOT HAVE TO WAIT FOR  04200018
*              THE ENTIRE DATA SET TO BE WRITTEN.                       04240018
*                                                                       04280018
*              THE USER IS ALLOWED TO SPECIFY EXACTLY HOW MANY RECORDS  04320018
*              HE WANTS TO SKIP (FORWARD OR BACK).  FOR THIS REASON     04360018
*              TWO BLOCKS (50 RECORDS) ARE KEPT IN CORE, AND A POINTER  04400018
*              IS KEPT INDICATING WHICH OF THE RECORDS IS THE FIRST TO  04440018
*              BE DISPLAYED. (POINTER IS CALLED 'DC')                   04480018
*                                                                       04520018
*              THIS FUNCTION IS PERFORMED BY THE FOLLOWING LOGIC        04560018
*              COMPARE P (POINTER TO TTR OF BLOCK TO BE DISPLAYED)      04600018
*              ADD PP (POINTER TO TTR OF LAST BLOCK WRITTEN ON WORK DS) 04640018
*              IF DESIRED RECORDS HAVE NOT YET BEEN WRITTEN, OTHERWISE  04680018
* GET25REC     GET 25 RECORDS FROM SYSOUT DS                            04720018
*              PAD OR TRUNCATE TO 132 BYTES                             04760018
*              WRITE AS A BLOCK TO WORK DS                              04800018
*              NOTE TTR                                                 04840018
*              SAVE TTR IN TTRTABLE                                     04880018
*              INCREMENT PP                                             04920018
*              IF MORE RECORDS ARE NEEDE BRANCH TO GET25REC             04960018
*              BRANCH TO POINT                                          05000018
* POINT        USEING P (POINTER TO BLOCK NEEDED) POINT SYSOUT DCB      05040018
* READBLK      READ A BLOCK                                             05080018
*              IF ANOTHER BLOCK IS NEEDED AND HAS BEEN WRITTEN ON WORK  05120018
*              DS BRANCH TO READBLK                                     05160018
*              IF ANOTHER BLOCK IS NEEDED BUT HAS NOT BEEN WRITTEN,     05200018
*              BRANCH TO GET25REC                                       05240018
*              IF NO MORE BLOCKS ARE NEEDED, FALL THROUGH               05280018
         EJECT                                                          05320018
* PHASE FOUR   BLDDISP   THIS PHASE WILL GENERATE THE DISPLAY           05360018
*                                                                       05400018
*                                                                       05440018
*              INITIALIZE POINTERS                                      05480018
*              MOVE GRAPHIC ORDERS FOR DISPLAY HEADER TO WORKAREA       05520018
*              TRANSLATE 'TAB' AND INSERT INTO HEADER                   05560018
*              USE P AND DC TO CALCUTALATE NUMBER OF RECORD BEING       05600018
*              DISPLAYED, TRANSLATE AND INSERT IN HEADER                05640018
*              INSERT DDNAME IN HEADER                                  05680018
*                                                                       05720018
*              MOVE GRAPHIC ORDER TO DISPLAY ONE LINE OF TEXT INTO      05760018
*              DISPLAY AREA, UPDATE POINTER TO DISPLAY AREA             05800018
*              MOVE 72 BYTES FROM SYSOUT RECORD TO DISPLAY AREA (USING  05840018
*              CURRENT TAB VALUE AS DISPLACEMENT OF 72 BYTES WITHIN     05880018
*              RECORD), UPDATE POINTER TO DISPLAY AREA.                 05920018
*                                                                       05960018
*              LOOP TO SET UP 25 LINES                                  06000018
*                                                                       06040018
*                                                                       06080018
*              MOVE GRAPHIC ORDERS TO DISPLAY MESSAGE                   06120018
*                                                                       06160018
*                                                                       06200018
*              GWRITE FROM DISPLAY AREA TO 2250 BUFFER                  06240018
*              INSERT CURSOR                                            06280018
*              RESTART DISPLAY                                          06320018
*                                                                       06360018
*              WAIT FOR ECB TO BE POSTED BY 2250                        06400018
*                                                                       06440018
*              WHEN CONTROL IS RETURNED AFTER ECB HAS BEEN POSTED,      06480018
*                                                                       06520018
*                                                                       06560018
*                                                                       06600018
*                                                                       06640018
*                                                                       06680018
*                                                                       06720018
*                                                                       06760018
*              WHEN POST BRANCH TO ADDRESS POINTED TO BY ATTN RTN       06800018
*                                                                       06840018
*                                                                       06880018
         EJECT                                                          06920018
*                                                                       06960018
*TABLES                                                                 07000018
*              PRINT/PUNCH TABLE                                        07040018
*              FUNCTION  TO KEEP TRACK OF WHICH SYSOUT DATA SETS HAVE   07080018
*              BEEN ENQUEUED ON PRINT/PUNCH QUEUE                       07120018
*              FORMAT ONE BYTE PER SYSOUT DATA SET HIGH ORDER BIT=1     07160018
*              MEANS DATA SET ON PRINT QUEUE, NEXT BIT=1 MEAN DATA SET  07200018
*              ON PUNCH QUEUE.                                          07240018
*              LENGTH=20 BYTES. A ONE BYTE INDEX IS USED                07280018
*                                                                       07320018
*              TTR TABLE                                                07360018
*              FUNCTION  TO KEEP TRACK OF BLOCKS OF LINES WRITTEN TO    07400018
*              GJPDIS1 DATA SET                                         07440018
*              FORMAT ONE 3 BYTE TTR FOR EACH BLOCK                     07480018
*              LENGTH IS 630 BYTES.  TWO HALF WORD POINTER ARE USED     07520018
*              WITH TTR TABLE. P POINTS TO TTR OF BLOCK(S) NEEDED FOR   07560018
*              NEXT DISPLAY, PP POINTS TO TTR OF LAST BLOCK WRITTEN ON  07600018
*              GJPDIS1                                                  07640018
*                                                                       07680018
*              SWITCH TABLE                                             07720018
*              TAB  CURRENT DISPLACEMENT OF LINE WITHIN RECORD   (1BYTE 07760018
*              NEXTAB  DISPLACEMENT OF LINE WITHIN RECORD TO BE USED    07800018
*              AFTER TAB ATTN.   1BYTE.                                 07840018
*              SET BY PHASE 7 (TERM) REFERRED TO BY PHASE 2 (CYCLE) IN  07880018
*              DELETING SYSOUT DATA SETS.                               07920018
*                                                                       07960018
*WORK AREAS                                                             08000018
*              RECAREA   FUNCTION RECEIVE 50 SYSOUT RECORD              08040018
*              LENGTH  132*50=6600 BYTES. ONE ONE BYTE INDEX IS USED    08080018
*              WITH RECORD AREA TO INDICATE WHICH OF RECORD  IN RECAREA 08120018
*              IS THE FIRST TO BE DISPLAYED                             08160018
         EJECT                                                          08200018
*                                                                       08240018
*              DISPLAREA DISPLAY AREA   USED TO HOLD DISPLAY BEING      08280018
*              BUILT.  LENGTH = 2400 BYTES.  CONSISTS OF                08320018
*                                            DDNAME                     08360018
*                                            TEXT                       08400018
*                                            KEY                        08440018
*                                            MSG                        08480018
*                   SYSTEM CONTROL BLOCKS USED                          08520018
*                        CVT                                            08560018
*                        DCB                                            08600018
*                        SMB                                            08640018
*                        DSB                                            08680018
*                        TCB                                            08720018
*                        TIOT                                           08760018
*                        ECB                                            08800018
*                        QMPA                                           08840018
*                        QMPA EXTENSION                                 08880018
*                   GJP TABLES                                          08920018
*                        CCT                                            08960018
*                        OCT                                            09000018
*                   WORK AREA                                           09040018
*                                  READ JCL DS                          09080018
*                                                                       09120018
*                                                                       09160018
*              IKAPDIS0 ATTENTION ROUTINE                               09200018
*              SAVE O/S REGS.                                           09240018
*              SET BASE AND ESTABLISH ADDRESSABILITY FOR WORK AREA VIA  09280018
*              ADDRESS IN COMAREA.                                      09320018
*              READ BUFFER , IF ATTN LIGHTPEN BRANCH TO 'XTAB'          09360018
*              IF ATTN IS END KEY, SCAN FOR NON-BLANKS IN KEY AREA      09400018
*              IF TAB NON-BLANK BAL TO CONVERT ROUTINE, AND RESET 'TAB' 09440018
*              AND SET'PHASE' TO BLDDISP                                09480018
*              IF 'NEXT' NON-BLANK, BAL TO CONVERT RTN, AND RESET 'P'   09520018
*              AND 'DC', SET'PHASE' TO 'NEWDISP'                        09560018
*              IF 'BACK' NON-BLANK, BAL TO CONVERT, AND RESET 'P' AND   09600018
*              'DC' AND SET 'PHASE' TO 'NEWDISP'                        09640018
*              IF 'TOP' NON-BLANK, SET 'P' AND 'DC' TO 0 AND SET 'PHASE 09680018
*              TO 'POINT'                                               09720018
*              IF 'CYCLE' NON-BLANK, SET 'PHASE' TO 'CYCLE'             09760018
*        IF 'PRINT' NON BLANK, TURN ON PRINT BIT IN PP TABLE            09800018
*              IF 'PRINT' BLANK TURN PRINT BIT OFF                      09840018
*              IF 'PUNCH' NON-BLANK TURN PUNCH BIT ON                   09880018
*              IF 'PUNCH' BLANK TURN BIT OFF                            09920018
*        IF 'TERM' NON-BLANK AND TERM BIT ON SET 'PHASE' TO TERM        09960018
*        IF 'TERM' NON-BLANK AND TERM BIT OFF, SET UP TERMINATION MSG   10000018
*        IF 'TERM' BLANK, TURN OFF TERM BIT                             10040018
* OUT    POST  ECB                                                      10080018
*        RESTORE REGS                                                   10120018
*        RETURN TO O/S                                                  10160018
* XTAB   COMPARE BUFFER ADDR OF LP-ATTN WITH BUFFER ADDRESSES OF ORDERS 10200018
*        FOR KEYS AND PUT X INTO PROPER KEY,  SAVE APPROPRIATE BUFFER   10240018
*        ADDR TO INSERT CURSOR UNDER X.                                 10280018
*        BRANCH TO 'OUT'                                                10320018
*                                                                       10360018
*                                                                       10400018
*                                                                       10440018
*                                                                       10480018
*                                                                       10520018
*                                                                       10560018
*                                                                       10600018
*                                                                       10640018
*                                                                       10680018
*                                                                       10720018
*                                                                       10760018
*                                                                       10800018
*                                                                       10840018
*                                                                       10880018
  TITLE 'IKAPDIS0    PHASE ONE   INITIALIZATION'                        10920018
*                                                                       10924021
* 115224-115228,363100-363200,363400,363600                   LD A46547 10928021
*                                                                       10932021
**       EQUATES                                                        10936021
*                                                                       10940018
RPAR0    EQU   0                                                        10960018
RPAR1    EQU   1                                                        11000018
RDSECT   EQU   2                                                        11040018
RWORK    EQU   3                                                        11080018
RWORK2   EQU   4                                                        11120018
RBASE    EQU   5                                                        11160018
RAREA    EQU   6                                                        11200018
RCCT     EQU   7                                                        11240018
RWORK4   EQU   8                                                        11280018
RWORK3   EQU   9                                                        11320018
RCOM     EQU   10                                                       11360018
R11      EQU   11                                                       11400018
RSAVE    EQU   13                                                       11440018
RET      EQU   14                                                       11480018
RBR      EQU   15                                                       11520018
T8       EQU   8                   EQUATE                               11520818
T0C      EQU   X'0C'               EQUATE                               11521218
T14      EQU   X'14'               EQUATE                               11521618
T2C      EQU   X'34'                                          LD A46547 11522121
T3D      EQU   X'45'                                          LD A46547 11522621
T27      EQU   X'27'                                                    11523218
UCBTYPE  EQU   16                       DEVICE TYPE                     11523318
*                                                                       11523418
**   'SWITCH' SETTINGS                                                  11523618
*                                                                       11523818
TERMC    EQU   X'80'               TERMINATE                            11524018
SEC      EQU   X'40'               USE SECOND HALF OF BUFFER            11528018
SYSEOD   EQU   X'20'               END OF DATA ON SYSOUT DS             11532018
DELETALL EQU   X'10'                    MEDIUM STOP ISSUED              11536018
EOV      EQU   X'08'               END OF VOLUME ON WORK DS             11540018
BLANKOUT EQU   X'04'               BIT IS ONE IFSECBUF TO BE BLANKED    11544018
NODATA   EQU   X'02'                    NO DATA WRITTEN                 11546018
NORECS   EQU   EOV+X'01'                NO RECORDS                      11548018
SGJP     EQU   32                       BIT SET FOR SGJP                11554018
COMPD    EQU   X'1DA'              DISPLACEMENT OF JOB COMPLETED MSG    11560018
*                                  IN IKAPSMB0 WORKAREA                 11600018
ZERO     EQU   0                   EQUATE                               11610018
TWENTY   EQU   20                  EQUATE                               11620018
MSG01    EQU   1                        EQUATE                          11621018
MSG02    EQU   2                        EQUATE                          11622018
MSG03    EQU   3                        EQUATE                          11623018
MSG04    EQU   4                        EQUATE                          11624018
MSG05    EQU   5                        EQUATE                          11625018
MSG06    EQU   6                        EQUATE                          11626018
MSG07    EQU   7                        EQUATE                          11627018
MSG08    EQU   8                        EQUATE                          11628018
MSG09    EQU   9                        EQUATE                          11629018
MSG10    EQU   10                       EQUATE                          11630018
MSG11    EQU   11                       EQUATE                          11631018
MSG12    EQU   12                       EQUATE                          11632018
MSG13    EQU   13                       EQUATE                          11633018
MSG14    EQU   14                       EQUATE                          11634018
MSG15    EQU   15                       EQUATE                          11635018
MSG16    EQU   16                       EQUATE                          11636018
MSG17    EQU   17                       EQUATE                          11637018
MSG18    EQU   18                       EQUATE                          11638018
         ENTRY      CYCLE,NEWDISP,BLDDISP,POINT,TERM,RERR               11650018
IKAPDIS0 CSECT                                                          11680018
         SAVE  (14,12)             SAVE IKAPSMB0 REGS                   11720018
         BALR  RBASE,0             SET BASE                             11760018
         USING *,RBASE                                                  11800018
         USING CCT,RCCT                                                 11840018
         L     RCCT,0(RPAR1)                                            11880018
         L     R11,4(RPAR1)                                             11920018
         LR    RWORK4,RPAR1        SAVE ADDR OF IKAPSMB0 WORKAREA       11960018
*                                                                       12000018
*                                  THE ADDR OF THE CCT IS PASSED IN REG 12040018
*                                  ONE BY IKASMBP.  IT IS USED WITH     12080018
*                                  RCCT TO ESTABLISH ADDRESSABILITY FOR 12120018
*                                  CCT                                  12160018
         L     RPAR0,LWORKS             GET SIZE OF WORKAREA            12180018
         GETMAIN R,LV=(0)                                               12200018
         LR    RAREA,RPAR1                                              12240018
*                                  RAREA IS USED FOR ADDRESSING THE     12280018
*                                  FIRST DSECT OF THE WORKAREA, WHEN    12320018
*                                  OTHER DSECTS ARE USED WORK REGISTERS 12360018
*                                  ARE SET UP TO ADDRESS THEM           12400018
         USING WORKAREA,RAREA      SET UP ADDRESSABILITY FOR WORK AREA  12440018
         SPACE 3                                                        12480018
         LA    RWORK2,CLEAR1      LOOP CONTROL FOR 256 BYTE CLEARING    12520018
         LR    RWORK,RPAR1         INITIALIZE RWORK FOR CLEARING AREA   12560018
CLEAR256 EQU   *                                                        12600018
         XC    0(255,RWORK),0(RWORK)                                    12640018
*                                  CLEAR OUT A 255 BYTE SEGMENT         12680018
         LA    RWORK,255(RWORK)   POINT TO NEXT SECTION TO BE CLEARED   12720018
         BCT   RWORK2,CLEAR256    END OF CLEAR 256 LOOP                 12760018
         XC    0(CLEAR2,RWORK),0(RWORK) CLEAR THE LEFTOVER BYTES        12800018
         L     RBR,LWORKS          LENGTH OF GETMAIN                    12810018
         ST    RBR,FREELENG        INTO LIST FOR FREEMAIN               12820018
         MVI   DDNAME,C' '              INITIALIZE                      12840018
         MVC   DDNAME+1(7),DDNAME       WITH BLANKS                     12860018
         ST    RPAR1,FREELIST      SAVE ADDR OF GETMAIN                 12880018
         ST    RSAVE,SAVE+4                                             12920018
         LA    RWORK,SAVE                                               12960018
         ST    RWORK,8(0,RSAVE)                                         13000018
         LR    RSAVE,RWORK                                              13040018
         ST    RCCT,ACCT           SAVE ADDR CCT IN WORKAREA FOR ATTN   13080018
         TM    CCTSSTAT,SGJP            Q. SGJP IN CONTROL              13090018
         BO    SGJP2                    YES, AVOID ATTENTION ROUTINE    13100018
* SAVE ADDR OF GJP ATTENTION ROUTINE                                    13120018
         L     RWORK,CCTGACBP      PICK UP ADDR GACB                    13160018
         MVC   GJPATTN(4),16(RWORK)                                     13200018
*                                  SAVE ADDR GJP'S GACB. IT MUST BE     13240018
*                                  RESTORED BEFORE RETURNING TO IKASMBP 13280018
         L     RWORK2,ATTNRTN      PICK UP ADDR IKAPDIS0 ATTN RTN       13320018
         ST    RWORK2,16(RWORK)    PUT ADDR IKAPDIS0 ATTN RTN IN GACB   13360018
* PUT ADDR WORKAREA IN GRAPHICS COMMUNICATIONS AREA                     13400018
         L     RWORK2,0(RWORK)     ADDR COMMUNICATIONS AREA             13440018
*                                  WHICH IS FIRST WORD OF GACB          13480018
*                                  NOTE THAT ADDR CCT MUST BE RESTORED  13520018
*                                  TO GACB BEFORE RETURNING TO IKASMBP  13560018
         ST    RAREA,16(RWORK2)    PUT ADDR WORKAREA INTO COMMUNICATION 13600018
*                                  AREA+16                              13640018
         L     RWORK,CCTDDCBP      ADDR GRAPHIC DCB                     13680018
         MVC   BLP(2),16(RWORK)    SAVE BUFFER LOAD POINT               13720018
         MVC   DCB(LDCB),DIS1DCBF                                       14040018
*                                  MOVE IN L-FORM OF DCB                14080018
*                                  MOVE DCB FOR WORK DATA SET INTO      14120018
*                                  WORKAREA                             14160018
         MVC   DOPEN(LOPEN),OPEN   MOVE L-FROM OPEN TO WORKAREA         14200018
         LA    RPAR1,DOPEN         ADDR L-FORM OPEN IN REG 1            14240018
         OPEN      (DCB,(INOUT)),MF=(E,(1))                             14280018
*                                  OPEN WORK DATA SET DIS1 FOR BSAM     14320018
*                                  READ AND WRITE                       14360018
* VERIFY THAT DATA SET GJPDIS1 IS OPEN                                  14400018
         MVC   INPUTA(LORDER4H),ORDER4  MOVE 1ST HALF OF KEY AREA INTO  14410018
         MVC   INPUTA+LORDER4H(LORDER4H),ORDER4+LORDER4H SECOND HALF    14420018
         B     SGJP2                    SET UP QUEUES                   14426018
CHKOPEN  EQU   *                                                        14432018
         USING IHADCB,R11                                               14440018
         MVC   DCBSYNAD+1(3),JCLSYN+1   ADDR OF SYNAD RTNE              14520018
         MVC   DCBEODAD+1(3),JCLEOD+1   ADDR OF EOD RTNE                14600018
         DROP  R11                                                      14680018
         USING IHADCB,RDSECT                                            14720018
         LA    RDSECT,DCB          ADDR WORK DS DCB                     14760018
         TM    DCBOFLGS,GOODOPEN   TEST IF OPEN OK                      14800018
         BO    OK                  BRANCH IF OK                         14840018
GOODOPEN EQU   X'10'                                                    14880018
         MVI   MSGNO,MSG01              DATA SET NOT OPENED             14920018
         B     NTOPN                    SET SWITCHES                    15020018
OK       EQU   *                                                        15160018
         LA    RWORK,DCBSYS        ADDR SYSOUT DATA SET DCB             15320018
         ST    RWORK,ADSYSDS       SAVE ADDR SYSOUT DATA SET DCB        15360018
         LA    RWORK,DCB           ADD WORK DATA SET DCB                15400018
         ST    RWORK,ADWORKDS      SAVE ADDR WORK DATA SET DCB          15440018
         CLC   COMPD(5,RWORK4),COMP     Q. NORMAL COMPLETION            15450018
         BNE   ENQTERM                  NO - PRINT ALL                  15460018
         B     NOCLOSE                  CONTINUE                        15470018
 EJECT                                                                  15480018
**********************************************************************  15520018
* TRANSLATE QUEUE NAME TO INTERNAL FORMAT                               15560018
SGJP2    EQU   *                                                        15580018
         SR    RPAR1,RPAR1        CLEAR REG                             15600018
         L     RWORK2,CVTPTR       ADDR CVT                             15640018
         USING CVT,RWORK2                                               15680018
         L     RWORK2,CVTQOCR      ADDR ADDR OCT HEADER                 15720018
         DROP  RWORK2                                                   15760018
         USING GFXOCTHD,RWORK2                                          15800018
         L     RWORK2,0(RWORK2)    ADDR OCT HEADER                      15840018
         IC    RPAR1,OCTGSMB      EBCDIC CHAR TO CONVERT                15880018
         BAL   RET,CONVCOD                                              15920018
         STC   RPAR1,GJPQUE       SAVE INTERNAL FORMAT                  15960018
         IC    RPAR1,OCTPRINT     EBCDIC CHAR TO CONVERT                16000018
         BAL   RET,CONVCOD                                              16040018
         STC   RPAR1,QUE          SAVE INTERNAL FORMAT                  16080018
         IC    RPAR1,OCTPUNCH     EBCDIC CHAR TO CONVERT                16120018
         BAL   RET,CONVCOD                                              16200018
         STC   RPAR1,QUE1         SAVE INTERNAL FORMAT                  16240018
   SPACE                                                                16245018
*    TEST IF MEDIUM STOP                                                16248018
         LH    RPAR1,OCTUNBR            NO. OF OCT ENTRIES              16251018
         LA    RWORK2,GFXHDSZE+GFXHDSTR                                 16254018
         USING GFXOCTEN,RWORK2                                          16257018
LOOKUP   CLC   CCTUNIT(3),OCTUNIT+1     Q. OCT ENTRY FOUND              16260018
         BE    TESTMED                  YES                             16263018
         LA    RWORK2,GFXENSTR+GFXENSZE  GET NEXT ENTRY                 16266018
         BCT   RPAR1,LOOKUP             CONTINUE                        16269018
         B     NOTMED                   NOT FOUND                       16272018
TESTMED  TM    OCTATTR2,OCTBMED         Q. MEDIUM STOP                  16275018
         BO    DELTERM                  GO DELETE                       16278018
         DROP  RWORK2                                                   16281018
NOTMED   EQU   *                                                        16284018
         SPACE 2                                                        16287018
         TM    CCTSSTAT,SGJP            Q. SGJP IN CONTROL              16290018
         BO    ENQTERM                  YES, PRINT ALL                  16293018
         B     CHKOPEN                  CONTINUE                        16296018
         EJECT                                                          16300018
*                                                                       16320018
*        TRANSLATION EBCDIC TO Q MANAGER CODE                           16360018
*        A THROUGH I     BECOME    3 THROUGH 11                         16400018
*        J THROUGH R     BECOME   12 THROUGH 20                         16440018
*        S THROUGH Z     BECOME   21 THROUGH 28                         16480018
*        0 THROUGH 9     BECOME   29 THROUGH 38                         16520018
*                                                                       16560018
*                                                                       16600018
*                                                                       16640018
CONVCOD  EQU   *                                                        16680018
         STC   RPAR1,INSAD         SAVE BYTE                            16720018
         LA    RWORK3,29           NUMERIC CODE                         16760018
         TM    INSAD,48            TEST IF NUMERIC                      16800018
         BO    XX                  BRANCH IF NUMERIC                    16840018
         LA    RWORK3,2            A-J CODE                             16880018
         BZ    XX                  BRANCH IF A-J                        16920018
         LA    RWORK3,11                                                16960018
         TM    INSAD,32        TEST  CHAR                               17000018
         BZ    XX                                                       17040018
         LA    RWORK3,19                                                17080018
XX       EQU   *                                                        17120018
         N     RPAR1,LOWEST4       CLEAR ALL BUT 4 LOWEST BITS          17160018
         AR    RPAR1,RWORK3                                             17200018
         BR    RET                 RETURN                               17240018
  TITLE  'IKAPDIS0    PHASE  TWO   CYCLE'                               17280018
*********************************************************************** 17320018
* PHASE TWO CYCLE                                                       17360018
*                                                                       17400018
CYCLE    EQU   *                                                        17440018
         CLC   ADTIOTEN(4),HEXZERO CHECK IF FIRST PASS                  17480018
         BE    NOCLOSE             DO NOT CLOSE                         17520018
         MVI   ADSYSDS,X'80'       SET HI BIT OF ADDR OF DCB            17560018
         LA    RPAR1,ADSYSDS       ADDR DCB                             17600018
         CLOSE MF=(E,(1))          CLOSE SYSOUT DATA SET                17640018
         B     CLEARTTR                                                 17760018
NOCLOSE  EQU   *                                                        17800018
         MVI   PPTABPTR,0               ZERO FOR BEGINNING              17820018
         BAL   RWORK4,BEGING            TO THE BEGINNING                17850018
         TM    ERRORSW,ERREODJ          Q. END OF FILE                  17886018
         BZ    INIT1                    NO                              17892018
         NI    ERRORSW,255-ERREODJ      TURN OFF SWITCH                 17898018
         B     CLEARTTR                 PRESENT FIRST DATA SET          17904018
INIT1    EQU   *                                                        17910018
         MVI   PPTABLE,0           SET COUNT OF SYSOUT DS TO ZERO       17920018
* SEARCH FOR DUMMY ENTRY IN TIOT                                        17960018
         L     RWORK,16            ADDR CVT                             18000018
         L     RWORK,0(RWORK)      ADDR ADDR TCB                        18040018
         L     RWORK,4(RWORK)      ADDR CURRENT TCB                     18080018
         L     RWORK,12(RWORK)     ADDR TIOT                            18120018
         SR    RWORK2,RWORK2       CLEAR REG                            18200018
         LA    RWORK,24(RWORK)     FIRST  DDENTRY IN TIOT               18240018
SCANTIOT CLC  4(8,RWORK),GJPDIS0  SCAN FOR DUMMY ENTRY                  18280018
         BE    FOUND                                                    18320018
         IC    RWORK2,0(RWORK)     LENGTH DDENTRY                       18360018
         AR    RWORK,RWORK2        ADDR  NEXT DDENTRY                   18400018
         CLI   0(RWORK),X'00'      IS THIS END OF TIOT                  18440018
         BNE   SCANTIOT                                                 18480018
         MVI   MSGNO,MSG18              DD CARD NOT FOUND               18486018
NTOPN    MVI   SWITCH,TERMC+NORECS      INDICATE NO RECORDS             18492018
         OI    ERRORSW,PRINTALL         TO PRINT ALL                    18500018
         B     BLDDISP                                                  18512018
FOUND    EQU   *                                                        18520018
         ST    RWORK,ADTIOTEN      SAVE ADDR OF DUMMY ENTRY IN TIOT     18560018
         MVC   HOLDTIOT(TWENTY),ZERO(RWORK)  SAVE DUMMY TIOT ENTRY      18620018
CLEARTTR EQU   *                                                        18680018
         XC    TTRTABLE(250),TTRTABLE             CLEAR FIRST 250 BYTES 18720018
         XC    TTRTABLE+250(250),TTRTABLE+250     CLEAR SECOND 250 BYTE 18760018
         XC    TTRTABLE+500(ENDCLEAR-TTRTABLE-500),TTRTABLE+500         18800018
*                                                 CLEAR REMAINDER AND   18840018
*                                                 POINTERS              18880018
*                                  CLEAR END OF TABLE AND POINTERS      18920018
TAB2     EQU   132-72                                                   18960018
         MVI   NEXTAB,TAB2                                              19000018
         XC    P(2),P                                                   19040018
         MVC     ADECB(LREAD),READB                                     19120018
         LR    RWORK2,R11               GET ADDR OF JCL DCB             19160018
R        LA    RWORK,DSB           READ A RECORD INTO DSB AREA          19200018
         BAL   RWORK4,READJCL      GO READ A RECORD                     19240018
         CLI   DSBFF,X'FF'         FF=DSB                               19280018
         BE    RE                  YES GO PROCESS DSB                   19320018
         CLC   SMBNEXT(4),HEXZERO  A NO, IS THIS THE LAST SMB           19360018
         BE    JCLEODRT            YES, GO TO EOD RTN                   19400018
         B     R                   NO, GO READ ANOTHER RECORD           19440018
         EJECT                                                          19445018
*                                                                       19450018
**       READ THE SMB DATA SET FOR DSB'S                                19460018
*                                                                       19470018
READJCL  READ    ADECB,SF,(RWORK2),(RWORK),,,MF=E                       19480018
         CHECK ADECB                                                    19520018
         CLI   DSBFF,X'FF'              Q. DATA SET BLOCK               19530018
         BCR   7,RWORK4                 NO, RETURN                      19540018
         READ  ADECB,SF,(RWORK2),QMPA,,,MF=E     READ QMPA,ECBIOB       19560018
         CHECK ADECB                                                    19600018
         BR    RWORK4                                                   19640018
*                                                                       19650018
**   INCREMENT DISPOSITION POINTER                                      19660018
*                                                                       19670018
RE       EQU   *                                                        19680018
         CLI   PPTABPTR,LPPTABLE        Q. END OF TABLE                 19686018
         BE    TERM                     YES, TERMINATE                  19692018
         IC    RPAR1,PPTABPTR           GET DATA SET POINTER            19698018
         LA    RPAR1,1(,RPAR1)          INCREMENT FOR THIS DSB          19704018
         STC   RPAR1,PPTABPTR           STORE BACK                      19710018
 EJECT                                                                  19720018
* DDNAME PROCESSING                                                     19760018
         MVC  DDNAME(8),DSBDDNAM       SAVE DDNAME                      19800018
         TM    SWITCH,TERMC                                             19840018
         BO    BLDDISP             GO PUT UP MSG                        19880018
         MVC   OPEN2(LOPEN2),OPEN2C                                     19920018
         MVC   DCBSYS(LDCBSYS),DCBSYSLF                                 19960018
         L     RWORK,ADTIOTEN     PICK UP ADDR TIOT ENTRY               20000018
          MVC   0(LDSBTIOT,RWORK),DSBTIOT  PUT INFO ROM DSB INTO TIOT   20040018
         MVC   DCBSYS+40(8),4(RWORK)   PUT DDNAME FROM TIOT INTO  DCB   20080018
         LA    1,OPEN2                                                  20120018
         OPEN  (DCBSYS,(INPUT)),MF=(E,(1))                              20160018
         LA    RDSECT,DCBSYS                                            20200018
         USING IHADCB,RDSECT                                            20240018
         TM   DCBOFLGS,GOODOPEN                                         20280018
         BO   OK2                                                       20320018
         MVI   MSGNO,MSG04              DATA SET NOT OPENED             20360018
         MVC   ERRNO(3),ERR74           SET UP ERROR MSG.               20410018
         BAL   RWORK4,ERRNM             TO ISSUE MSG.                   20420018
         B     NOREC                    TO TURN ON SWITCH               20440018
OK2      TM    SWITCH,NODATA            Q. NO DATA WRITTEN              20460018
         BZ    OK3                      NO, OPEN IS OK                  20480018
         MVI   MSGNO,MSG02              INDICATE NO RECORDS             20500018
NOREC    OI    SWITCH,NORECS            INDICATE NO RECORDS             20520018
         B     BLDDISP                  TO BUILD DISPLAY                20540018
OK3      EQU   *                                                        20560018
         LH    RPAR1,BLP           BUFFER LOAD POINT                    20840018
         LA    RPAR1,KEYAREA(RPAR1)    KEYAREA                          20880018
         LA    RPAR1,KTAB(RPAR1)   PLACE TO INSERT CURSOR               20920018
         STH   RPAR1,INSCURLP      SAVE DISPLACEMENT OF CURSOR          20960018
         NI    ERRORSW,255-ERRSYN2-ERREOD2   RESET FOR THIS DATA SET    21000018
         MVC   PP(2),XM3           INITIALIZE POINTER TO BLOCK AT       21040018
*                                  MINUS THREE                          21080018
         MVI   SWITCH,X'00'        RESET SWITCH                         21120018
         XC    P(2),P                                                   21160018
         TITLE 'IKAPDIS0      PHASE THREE    NEW DISPLAY'               21680018
NEWDISP  LH    RWORK,P             COMPARE BLK WANTED WITH LAST BLK     21720018
         LA    RWORK2,RECAREA                                           21760018
         LA    R12,RECAREA         REG USED TO WRITE OUT BLOCKS         21800018
         CH    RWORK,PP                                                 21840018
*                                  READ FROM SYSOUT DS                  21880018
         BNH   POINT                                                    21920018
R12      EQU   12                                                       21960018
NEEDMORE EQU   *                                                        22000018
         LA  RWORK2,RECAREA                                             22040018
         LA    R12,RECAREA         REG USED TO POINT TO FIRST HALF      22080018
*                                  OF BUFFER   USED FOR WRITE           22120018
GET25REC EQU   *                                                        22160018
         TM    SWITCH,SYSEOD       Q. HAS END OF DATA BEEN REACHED      22200018
         BO    BLDDISP             A. YES, GO BUILD DISPLAY             22240018
* RECORDS NEEDED HAVE NOT YET BEEN WRITTEN                              22280018
         LH    RWORK3,X25               NUMBER OF LOOPS                 22320018
GET      GET   DCBSYS                                                   22360018
         MVI   0(RWORK2),X'40'                                          22400018
         MVC   1(132,RWORK2),0(RWORK2)                                  22440018
         LH    RWORK4,DCBLRECL                                          22480018
         BCTR  RWORK4,0                                                 22520018
         EX    RWORK4,MOVE                                              22560018
         LA    RWORK2,132(RWORK2)  INCREMENT POINTER TO RECAREA         22600018
         BCT   RWORK3,GET                                               22640018
WRITE25  MVC   BDECB(LBDECB),BDECBL    MOVE IN L FORM READ FOR WORK DS  22680018
         TM    SWITCH,EOV          TEST EOV SWITCH                      22690018
         BO    BLDDISPV            GO TO DISPLAY MSG IF ON              22700018
         MVI   LASTWRT+3,1         SET BIT TO MEAN 'POINT TO NEXT BLK'  22720018
         POINT DCB,LASTWRT         POINT TO NEXT UNUSED BLOCK           22760018
         WRITE BDECB,SF,DCB,(R12),MF=E                                  22800018
         CHECK BDECB                                                    22840018
         NOTE  DCB                                                      22880018
         ST    RPAR1,HOLDNOTE      SAVE TTRZ                            22920018
         ST    RPAR1,LASTWRT       SAVE TTR OF L AST BLK WRITTEN        22960018
         LH    RPAR1,PP            INCREMENT PP                         23000018
         LA    RPAR1,3(RPAR1)                  BY THREE                 23040018
         STH   RPAR1,PP            PP NOW HAS DISPLACEMENT FOR NOTE     23080018
         LA    RPAR1,TTRTABLE      ADDR NOTE TABLE                      23120018
         AH    RPAR1,PP            LOC IN NOTE TABLE FOR LAST NOTE      23160018
         MVC   0(3,RPAR1),HOLDNOTE SAVE NOTE IN NOTE TABLE              23200018
         AH    R12,SECBUF          POINT TO SECOND HALF OF BUFFER FOR   23240018
*                                  WRITE                                23280018
         CH    RWORK,PP                                                 23320018
         BE    GET25REC            A. YES GO GET 25 RECS. PUT IN SECOND 23360018
         BNH   BLDDISP             A. YES GO BUILD DISPLAY              23400018
         B     NEEDMORE            A. NO,GET MORE                       23440018
*                                  READ                                 23480018
* POINT TO BLOCK REQUIRED                                               23560018
POINT    LA    RWORK,TTRTABLE      ADDR TABLE OF NOTE POSITION          23600018
         AH    RWORK,P             ADDR OF DESIRED NOTE POSITION        23640018
         MVC   HOLDNOTE(3),0(RWORK) MOVE TO HOLD LOCATION               23680018
         MVI   HOLDNOTE+3,X'00'    MOVE 0 INTO TTRZ                     23720018
         POINT DCB,HOLDNOTE        POINT TO BLOCK REQUIRED              23760018
READTOTP LA    RWORK2,RECAREA                                           23800018
*                                  RWORK2 POINTS TO RECAREA             23840018
         LA    R12,RECAREA         REG USED TO WRITE OUT BLOCKS         23880018
READBLK  READ  BDECB,SF,DCB,(RWORK2),MF=E                               23920018
         CHECK BDECB                                                    23960018
         TM    SWITCH,BLANKOUT     EOD AND FINAL BLOCK?                 23970018
         BO    CLEARSEC            YES GO CLEAR BLOCK                   23980018
         TM    SWITCH,SEC          Q. MORE NEEDED                       24000018
         BO    BLDDISP             A. NO                                24040018
         OI    SWITCH,SEC          A. YES, SET SWITCH FOR ONE MORE      24080018
         AH    R12,SECBUF          POINT TO SECOND HALF OF BUFFER FOR   24120018
*                                  WRITE                                24160018
         AH    RWORK2,SECBUF       PREPARE TO READ INTO SECOND HALF BUF 24200018
         LH    RWORK,P             LOCATION IN TTR TABLE OF BLOCK       24240018
*                                  NEEDED                               24280018
         CH     RWORK,PP                                                24320018
         BE    GET25REC                                                 24360018
         B     READBLK             ONE READ.                            24400018
CLEARSEC LA    RBR,25              NUM OF RECORDS IN BLOCK              24404018
         LA    RET,RECAREA         ADDR FIRST HALF OF BUF               24408018
         AH    RET,SECBUF          ADDR SECOND HALF OF BUF              24412018
         MVI   0(RET),64           PUT IN FIRST BLANK                   24416018
BLANKET  MVC   1(132,RET),0(RET)   PROPAGATE BLANKS                     24420018
         LA    RET,132(RET)        POINT TO NEXT REC                    24424018
         BCT   RBR,BLANKET         LOOP TO BLANK BLOCK                  24428018
         B     BLDDISP             CONTINUE                             24432018
BLDDISPV MVI   MSGNO,MSG09              END OF VOLUME                   24436018
         TITLE ' IKAPDIS0     PHASE FOUR     BUILD NEW DISPLAY'         24440018
BLDDISP  EQU   *                                                        24480018
* REGISTER USAGE FOR BUILDING DISPLAY                                   24520018
* RWORK  POINTS TO DISPLAY                                              24560018
* RWORK2 HOLDS COUNT FOR LOOP CONTROL                                   24600018
* RWORK4 HAS Y POSITION FOR LINE ON SCREEN                              24640018
* RWORK3 POINTS TO BYTES BEING MOVED                                    24680018
         NI    SWITCH,255-(SEC+BLANKOUT)  TURN OFF BUFFER BITS          24720018
         LH    RWORK3,DC           NUMBER OF RECORDS FROM TOP OF BLOCK  24840018
*                                  TO BE DISPLAYED (DISPLAY             24880018
         MH    RWORK3,X132         NUMBER OF BYTES FROM TOP OF BLOCK    24920018
         SR    RPAR1,RPAR1         CLEAR REG FOR INSERT CHAR            24960018
         IC    RPAR1,TAB           PICK UP 1BYTE TAB VALUE              25000018
         AR    RWORK3,RPAR1        ADD TAB VALUE                        25040018
*                                  WITHIN INDIVIDUAL RECORD             25080018
         AR    RWORK3,RAREA        PLUS ADDR WORKAREA                   25120018
         AH    RWORK3,KRECAREA                                          25160018
*                                  PLUS DISPLACEMENT OF BEGINING OF     25200018
*                                  RECORD AREA WITHIN WORKAREA          25240018
* RWORK3 NOW HAS THE ADDR OF THE FIRST BYTE TO BE DISPLAYED             25280018
         LR    RWORK,RAREA                                              25320018
*                                  ADDR WORK AREA                       25360018
         AH    RWORK,ADISPLAY      ADDR DISPLAY AREA                    25400018
         MVC   0(LORDER1,RWORK),ORDER1                                  25440018
         TM    SWITCH,TERMC+NORECS   Q. SYNAD ERROR                     25480018
         BO    NORECSON            YES LEAVE NO RECS ON                 25520018
         TM    SWITCH,NORECS                                            25560018
         BZ    RECSOK                                                   25600018
         NI    SWITCH,255-NORECS  TURN OF BIT                           25640018
NORECSON EQU   *                                                        25680018
         MVC   DD8(LGTRU),GTRU                                          25720018
         LH    RWORK4,BLP                                               25760018
         LA    RWORK4,KEYAREA(RWORK4)                                   25800018
*                                 BUFFER LOCATION OF KEY AREA           25840018
         LA    RWORK4,DTERM(RWORK4)   ADDR OF TERM                      25880018
         STH   RWORK4,DD8+LGTRU                                         25920018
         LA    RWORK4,DDTERM(RWORK4)   ADDR IN BUBBER FOR CURSOR        25960018
         STH   RWORK4,INSCURLP     SAVE ADDR                            26000018
RECSOK   EQU   *                                                        26040018
         SR    RPAR1,RPAR1         CLEAR REG                            26080018
         IC    RPAR1,TAB           PICK UP TAB VALUE                    26120018
         CVD   RPAR1,DOUBLE        CONVERT TO DECIMAL                   26160018
         UNPK  DISPLC(3,RWORK),DOUBLE+5(3)   UNPACK=IN ORDER1           26200018
         OI    DISPLC+2(RWORK),X'F0'  RESET SIGN BIT                    26240018
         LH    RBR,P               PICK UP PTR TO TTR TABLE             26280018
         SR    RET,RET             CLEAR EVEN REG                       26320018
         LA    RPAR1,3             DIVISOR                              26360018
         DR    RET,RPAR1           DIVIDE  P/3                          26400018
         LA    RPAR1,25            MULTIPLIER                           26440018
         MR    RET,RPAR1           MULTIPLY     RECORD=P/3*25           26480018
         AH    RBR,DC              RECORD=(P/3)*25+DC)                  26520018
         CVD   RBR,DOUBLE          CONVERT TO DECIMAL                   26560018
         UNPK  RECORD(5,RWORK),DOUBLE+3(5)                              26600018
          OI   RECORD+4(RWORK),X'F0'  RESET SIGN BIT                    26640018
*                                  MOVE IN ORDERS TO INITIALIZE DISPLAY 26680018
*                                  AND DISPLAY DDNAME                   26720018
         MVC   DDNAMEP(8,RWORK),DDNAME                                  26760018
*                                  MOVE IN DDNAME                       26800018
         MVC   LORDER1+0(LORDER2,RWORK),ORDER2                          26840018
*                                  MOVE IN ORDERS FOR FIRST LINE OF     26880018
*                                  TEXT                                 26920018
         LA    RWORK,LORDER1+0+LORDER2(RWORK)                           26960018
*                                  INCREMENT POINTER TO DISPLAY AREA    27000018
*                                  FOR FIRST LINE OF TEXT               27040018
         LA    RWORK2,25          LOOP CONTROL                          27080018
         LH    RWORK4,ORDER2+4     INITIAL Y POSITION FOR TEXT          27120018
         LA    RPAR1,71            INITIALIZE TO DEFAULT LENGTH         27160018
MOVORDER CLI   TAB,61              WILL TAB OVERLAP NEXT RECORD         27200018
         BL    TABLO               NO                                   27240018
         SR    RBR,RBR             CLEAR REG                            27280018
         IC    RBR,TAB             PICK UP TAB                          27320018
         LA    RPAR1,131           RECORD LENGTH LESS ONE               27360018
         SR    RPAR1,RBR           132-TAB                              27400018
         MVI   0(RWORK),64         MOVE IN ONE BLANK                    27440018
         MVC   1(72,RWORK),0(RWORK) MOVE IN 72 BLANKS                   27480018
TABLO    EX    RPAR1,MOVETAB       MOVE IN PART OF REC                  27520018
         MVC   72(LORDER3,RWORK),ORDER3                                 27560018
*                                  MOVE IN ORDERS FOR THE NEXT LINE     27600018
         SH    RWORK4,LINESPAC     DECRIMENT LINE LOCATION              27640018
         STH   RWORK4,72+4(RWORK)  MOVE Y POSITION INTO ORDER           27680018
         LA    RWORK3,132(RWORK3)  INCREMENT TO NEXT RECORD             27720018
         LA    RWORK,LORDER3+72(RWORK)                                  27760018
*                                  INCREMENT POINTER TO DISPLAY FOR     27800018
*                                  NEXT LINE                            27840018
         BCT   RWORK2,MOVORDER                                          27880018
         EJECT                                                          27920018
* MSG HANDLING                                                          27960018
MSG      EQU   *                                                        28000018
         MVC   0(LORDER4H,RWORK),INPUTA  MOVE FIRST HALF OF KEY AREA    28040018
         MVC   LORDER4H(LORDER4H,RWORK),INPUTA+LORDER4H  SECOND HALF    28080018
*                                  MOVE IN ORDERS TO DISPLAY KEYS+ MSG  28120018
         MVI   LORDER4(RWORK),X'40'                                     28160018
         MVC   LORDER4+1(71,RWORK),LORDER4(RWORK)                       28200018
*                                  MOVE 72 BLANKS INTO MSGAREA          28240018
         MVC   LORDER4+72(LORDER5,RWORK),ORDER5                         28280018
*                                  MOVE IN FINAL ORDERS                 28320018
         SR    RWORK4,RWORK4       CLEAR REG FOR LOOP CONTROL           28360018
         CLI   MSGNO,X'00'         TEST IF ANY MSG                      28400018
         BE    NOMSG               IF NO MSG SKIP MSG PROCESSING        28440018
         IC    RWORK4,MSGNO        PICK UP MSG NUMBER FOR LOOP CONTROL  28480018
         L     RWORK2,IKAMDIS      PICK UP ADDR MSG MODULE              28520018
LOOPMSG  SR    RWORK3,RWORK3       CLEAR REG FOR INDEXING               28560018
         IC    RWORK3,0(RWORK2)    PICK UP LENGTH OF MSG                28600018
         AR    RWORK2,(RWORK3)     ADDR OF NEXT MSG                     28640018
         BCT   RWORK4,LOOPMSG      MSG NUMBER USED FOR LOOP CONTROL     28680018
         SR    RWORK2,RWORK3                                            28720018
         BCTR  RWORK3,0            SUBTRACT ONE FROM LENGTH OF ENTRY    28760018
*                                  FOR THE EXECUTE INSTRUCTION          28800018
         BCTR  RWORK3,0            SUBTRACT ONE FROM LENGTH OF ENTRY    28840018
*                                  FOR THE ONE BYTE LENGTH-FIELD        28880018
         EX    RWORK3,MVCMSG                                            28920018
*                                  MOVE MESSAGE INTO DISPLAY AREA       28960018
         MVC   LORDER4+72(LORDER5,RWORK),ORDER5                         29000018
NOMSG    MVI   MSGNO,X'00'         RESET MSG NUMBER TO ZER0             29040018
*    SAVE ADDRESS OF 'GTRU'                                             29060018
         LA    RWORK4,LORDER4+72(,RWORK)  SAVE ADDR OF GTRU             29080018
* GWRITE DISPLAY FROM WORKAREA TO 2250 BUFFER                           29120018
         LR    RWORK2,RAREA        ADDR WORKAREA                        29160018
         AH    RWORK2,ADISPLAY     ADDR DISPLAY                         29200018
         STH   RWORK2,STARTADR     PUT START ADDRESS OF DISPLAY INTO    29240018
*                                  HALF WORD                            29280018
         MVC   WDECB(LGWRITE),GWDECB                                    29320018
*                                 MOVE IN L FORM OF GWRITE              29360018
         L     RWORK,CCTDDCBP      ADDR GRAPHIC DCB                     29400018
         MVC   WDECB+8(4),CCTDDCBP ADDR DCB                             29440018
         ST    RWORK2,WDECB+12     ADDR DISPLAY                         29480018
         LA    RWORK,LENGTH        LENGTH OF DISPLAY                    29520018
         ST    RWORK,WDECB+20      AMOUNT TO WRITE                      29560018
         L     RWORK,CCTDDCBP      ADDR GRAPHIC DCB                     29600018
         MVC   BLP(2),16(RWORK)    SAVE BUFFER LOAD POINT               29640018
         MVC   2(2,RWORK4),16(RWORK)    PUT BLP IN GTRU                 29660018
         LA    RWORK,BLP           ADDR BLP                             29680018
         ST    RWORK,WDECB+24      SET UP START ADDR                    29720018
         ST    RWORK,WDECB+28      ADDR BLP                             29760018
         LA    1,WDECB                                                  29800018
         GWRITE (1),MF=E                                                29840018
         MVC   ERRNO(3),ERR70           SET UP ERROR MSG                29880018
         LTR   RBR,RBR             TEST RETURN CODE                     29920018
         BNZ   ERR                 BRANCH TO ERROR RTN WITH CODE IN 15  29960018
         WAIT  ECB=WDECB                                                30000018
         CLI   WDECB,X'7F'                                              30040018
         BE    GWRITEOK                                                 30080018
         SR    RBR,RBR                  ZERO REGISTER                   30200018
         IC    RBR,WDECB                POST CODE                       30260018
         LA    RWORK4,TERM              RETURN ADDRESS                  30320018
         B     ERR                      ISSUE ERROR MSG                 30380018
GWRITEOK EQU   *                                                        30480018
         MVC   CDECB(LGCNTRLC),CCDECB                                   30520018
         MVC   CDECB+8(4),CCTDDCBP PUT ADDR DCB IN DECB                 30560018
         LA    RWORK2,INSCURLP     ADDR OF HALF WORD ADDR TO INSERT     30600018
         ST    RWORK2,CDECB+28     PUT INTO DECB                        30640018
         LA    RPAR1,CDECB         PUT ADDR DECB IN REG 1               30680018
         GCNTRL (RPAR1),MF=E       INSERT CURSOR                        30720018
         MVC   ERRNO(3),ERR73           SET UP ERROR MSG                30760018
         LTR   RBR,RBR             TEST RETURN CODE                     30800018
         BNZ   ERR                 BRANCH TO ERROR RTN WITH CODE IN 15  30840018
         WAIT  ECB=CDECB                                                30880018
         CLI   CDECB,X'7F'                                              30920018
         BE    COK                                                      30960018
         MVC   ERRNO(3),ERR73           BAD INSERT MSG                  30970018
         SR    RBR,RBR                  ZERO REGISTER                   30980018
         IC    RBR,CDECB                POST CODE                       30990018
         LA    RWORK4,TERM              RETURN ADDRESS                  31000018
         B     ERR                      ISSUE ERROR MSG                 31010018
COK      EQU   *                                                        31040018
         MVC   RDECB(LGCNTRLR),RRDECB                                   31080018
         MVC   RDECB+8(4),CCTDDCBP PUT ADDR DCB IN DECB                 31120018
         LA    RWORK2,BLP          ADDR BLP                             31160018
         ST    RWORK2,RDECB+24     IN DECB                              31200018
         LA    RPAR1,RDECB         ADDR DECB IN REG 1                   31240018
         GCNTRL (RPAR1),MF=E       RESTART DISPLAY                      31280018
         MVC   ERRNO(3),ERR72           SET UP ERROR MSG.               31300018
         LTR   RBR,RBR             TEST RETURN CODE                     31320018
         BNZ   ERR                 BRANCH TO ERROR RTN WITH CODE IN 15  31360018
         WAIT  ECB=RDECB                                                31480018
         CLI   RDECB,X'7F'                                              31520018
         BE    ROK                                                      31560018
         SR    RBR,RBR             CLEAR REG                            31570018
         IC    RBR,RDECB           POST CODE                            31580018
         LA    RWORK4,TERM         RET ADDR                             31590018
         B     ERR                 ISSUE MSG + RET TO GJP               31610018
ROK      EQU   *                                                        31640018
         XC    ECB(4),ECB          CLEAR ECB FOR WAIT                   31680018
         WAIT  ECB=ECB                                                  31720018
*                                                                       31725018
**   TEST IF GJP MUST BE STOPPED                                        31730018
*                                                                       31735018
         L     RWORK,CCTTIME            PTR TO COMM. PARM. LIST    EXTR 31740019
         L     RWORK,0(RWORK)           POINTER TO ECB             EXTR 31745019
         TM    ZERO(RWORK),X'10'        Q. FAST STOP ISSUED             31750018
         L     RWORK,PHASE              GET ADDR OF ROUTINE SELECTED    31770018
         BCR   8,RWORK                  NO, CONTINUE                    31790018
         OI    ERRORSW,FSTOP            INDICATE FAST STOP ISSUED       31810018
         B     DELTERM                  GO DELETE                       31840018
         TITLE '   IKAPDIS0        PHASE FIVE     PRINT'                31880018
*                                                                       31890018
**   MISCELLANEOUS ROUTINES                                             31900018
*                                                                       31910018
SYNAD1   OI    ERRORSW,ERRSYN1          DISPLAY SYNCHRONOUS ERROR       31920018
         MVI   MSGNO,MSG10              SYNAD ERROR                     31960018
         B     CYCLE                                                    32000018
EODAD1   OI    ERRORSW,ERREOD1          DISPLAY END OF FILE             32040018
         MVI   MSGNO,MSG11              END OF DATA                     32080018
         B     CYCLE                                                    32120018
SYNAD2   OI    ERRORSW,ERRSYN2          SYSOUT SYNCHRONOUS ERROR        32160018
         MVI   MSGNO,MSG08              SYNAD ERROR                     32200018
         B     NOREC                    TO TURN ON SWITCH               32260018
EODAD2   OI    ERRORSW,ERREOD2          SYSOUT END OF FILE              32320018
* END OF DATA ON SYSOUT DATA SET RTN.                                   32360018
* THIS RTN TAKES OVER FROM 'GET' AND HAS RWORK3=COUNT, RWORK2=LOCATION  32400018
         OI    SWITCH,SYSEOD                                            32440018
         LH    RPAR1,PP             TTR OF LAST BLOCK                   32446018
         LA    RBR,RECAREA         ADDR OF BUFFER                       32452018
         CR    RBR,R12             ARE RECORDS GOING INTO SECOND HALF   32458018
*                                  OF BUFFER                            32464018
         BNE   SHORT               YES, SKIP EOD MSG                    32470018
         MVI   MSGNO,MSG13              END OF DATA                     32510018
*                                  PREVENT OVERRUNING END OF DATA       32560018
         LA    RWORK3,25(RWORK3)   INCREMENT SO AS TO BLANK SECOND      32580018
*                                  HALF OF BUFFER                       32600018
         LA    RPAR1,3(RPAR1)      SET P TO WHAT WILL BE DISPLAYED      32680018
         STH   RPAR1,P                                                  32720018
SHORT    EQU   *                   DATA SET IS LESS THAN 50 RECS        32740018
         LTR   RWORK3,RWORK3       ANY BLANKS REQUIRED                  32760018
         BC    8,WRITE25           NO, RETURN                           32800018
BLANKEOD MVI   0(RWORK2),C' '      YES, BLANK FIRST BYTE IN RECORD      32840018
         MVC   1(131,RWORK2),0(RWORK2)                                  32880018
*                                  BLANK ENTIRE RECORD                  32920018
         LA    RWORK2,132(RWORK2)  INCREMENT FOR NEXT RECORD            32960018
         BCT   RWORK3,BLANKEOD     LOOP CONTROL                         33000018
         B     WRITE25             RETURN                               33040018
JCLEODRT OI    ERRORSW,ERREODJ          JCL END OF FILE                 33080018
         MVI   MSGNO,MSG16              FIRST DATA SET                  33130018
         B     NOCLOSE                  GO TO THE BEGINNING             33230018
JCLSYNAD MVI   MSGNO,MSG12              SYNAD ERROR                     33260018
         MVI   DDNAME,C' '              BLANK OUT                       33290018
         MVC   DDNAME+1(7),DDNAME       THE NAME                        33320018
         OI    ERRORSW,ERRSYNJ          JCL SYNCHRONOUS ERROR           33360018
         B     NOREC                    TO TURN ON SWITCH               33390018
*                                                                       33420018
**   DCB EXIT ROUTINE                                                   33440018
*                                                                       33460018
DCBEXIT  LA    RDSECT,DCBSYS       DCBEXIT ROUTINE PUTS BLOCKSIZE 24    33480018
         USING IHADCB,RDSECT                                            33520018
         CLC   DCBBLKSI(2),HEXZERO      Q. BLKSIZE = ZER0               33560018
         BCR   7,RET                    NO                              33600018
         CLC   DCBBUFL(2),HEXZERO       Q. BUFL = ZERO                  33640018
         BCR   7,RET                    NO                              33680018
         OI    SWITCH,NODATA            INDICATE NO DATA                33720018
         MVC   DCBBLKSI(2),X18     SET BLOCK SIZE AT 24                 33760018
         BR    RET                 RETURN                               33800018
*                                                                       33900018
**   END OF VOLUME EXIT ROUTINE                                         34000018
*                                                                       34100018
WORKEOV  MVI   MSGNO,MSG09              END OF VOLUME                   34200018
         OI    SWITCH,EOV          SET E O V SWITCH                     34400018
         BR    RET                 RETURN                               34700018
*                                                                       34770018
**   PRINT ALL SYSOUT (SGJP OR JOB ERRORS)                              34840018
*                                                                       34910018
ENQTERM  OI    ERRORSW,PRINTALL         PRINT ALL SYSOUT                35000018
         B     TERM                     GO ENQUEUE                      35300018
*                                                                       35370018
**   DELETE ALL SYSOUT (MEDIUM STOP)                                    35440018
*                                                                       35510018
DELTERM  OI    SWITCH,DELETALL          DELETE ALL SYSOUT               35580018
         B     TERM                     GO DELETE                       35650018
*                                                                       35660018
**   POINT TO THE BEGINNING OF THE SMB/DSB DATA SET                     35670018
*                                                                       35680018
BEGING   POINT (R11),ONE                TO THE FIRST RECORD             35690018
         BR    RWORK4                   RETURN                          35700018
*                                                                       35706018
**   COMMON LINK TO QUEUE MANAGER ROUTINE                               35712018
*                                                                       35718018
TOQMGR   LA    RPAR1,QMPA               ADDR OF QMPA                    35724018
         L     RBR,IEFQMGR              ADDR OF Q-MANAGER ROUTINE       35730018
         BALR  RET,RBR                  TO QUEUE MANAGER                35736018
         LTR   RBR,RBR                  TEST RETURN CODE                35742018
         BR    RWORK4                   RETURN                          35748018
         TITLE '   IKAPDIS0        PHASE SEVEN    TERM'                 35760018
*                                                                       35770018
**   FREE UNNEEDED WORK SPACE                                           35771018
*                                                                       35772018
TERM     L     RPAR0,LNOWRK             GET LENGTH TO FREE              35773018
         L     RPAR1,FREELIST           AREA TO FREE LESS               35774018
         LA    RPAR1,WORKING(,RPAR1)    AMOUNT TO KEEP                  35775018
         FREEMAIN R,LV=(0),A=(1)        GOODBYE WASTE SPACE             35776018
         LA    RBR,WORKING              UPDATE FIELD WITH               35777018
         ST    RBR,FREELENG             SIZE OF WORK AREA               35778018
*                                                                       35779018
**   ENQUEUE DATA SET(S) TO PRINT, PUNCH, OR DELETE                     35780018
*                                                                       35790018
         LOAD  EP=IEFQDELE              GET Q-MGR DELETE ROUTINE        35800018
         ST    RPAR0,IEFQDEL            SAVE ENTRY POINT                35810018
         LOAD  EP=IEFQMSSS              GET Q-MGR CONTROL ROUTINE       35820018
         ST    RPAR0,IEFQMGR            SAVE ENTRY POINT                35830018
         MVI   QMGRSW,X'F0'             INDICATE Q-MGR LOADED           35840018
         MVI   PPTABPTR,0               RE-INITIALIZE                   35880018
         BAL   RWORK4,BEGING            TO THE BEGINNING                35930018
         USING IHADCB,R11                                               35980018
         MVC   DCBSYNAD+1(3),TERMSYN+1  ADDR OF SYNAD ROUTINE           36000018
         MVC   DCBEODAD+1(3),TERMEOD+1  ADDR OF EOD RTNE                36020018
         DROP  R11                                                      36040018
         MVC   ADECB(LREAD),READB       INITIALIZE LIST                 36060018
         LR    RWORK2,R11               GET ADDR OF JCL DCB             36080018
TERM1    LA    RWORK,DSB                READ INTO DSB AREA              36100018
         BAL   RWORK4,READJCL           READ A DSB                      36120018
         CLI   DSBFF,X'FF'              Q. DSB READ                     36140018
         BE    TERMP                    YES, GO PROCESS                 36160018
         CLC   SMBNEXT(4),HEXZERO       Q. LAST SMB                     36180018
         BE    TERMOUT                  YES,END                         36200018
         B     TERM1                    CONTINUE                        36220018
*                                                                       36230018
*    SET UP AN IOB FOR THE QMPA                                         36240018
*                                                                       36250018
SETUP    EQU   *                                                        36260018
         LA    RDSECT,QMPA         ADDRESSABILITY FOR QMPA              36290018
         USING  IOPARAMS,RDSECT                                         36300018
X44      EQU   X'54'                                          LD A46547 36310021
T35      EQU   X'3D'                                          LD A46547 36320021
T15      EQU   X'15'                                                    36330018
         LA    RPAR0,X'58'         LENGTH OF ECB/IOB          LD A46547 36340021
         GETMAIN  R,LV=(0)         GET SPACE FOR ECB/IOB                36350018
         LA    RPAR0,X'58'         LENGTH OF GETMAIN          LD A46547 36360021
         ST    RPAR0,0(RPAR1)      STORE SUBPOOL '0' AND LENGTH         36370018
         MVC   4(X44,RPAR1),QMECBIOB   COPY GFX'S ECB/IOB               36380018
         LA    RPAR1,4(RPAR1)      ADDR OF START OF ECB/IOB             36390018
         ST    RPAR1,QMEIA         QMPA NOW HAS AN ECB/IOB OF ITS OWN   36400018
         L     RWORK3,QMEIA        SAVE ADDR ECB IOB                    36410018
R0       EQU   0                                                        36420018
R1       EQU   1                                                        36430018
R15      EQU   15                                                       36440018
         ST    R1,T8(R1)           ADDR ECB                             36450018
         MVC   T8(1,R1),0(R1)                                           36460018
         IC    R15,T2C(R1)         CODE IN CCW                          36470018
         LA    R0,T27(R1)                                               36480018
         ST    R0,T2C(R1)                                               36490018
         STC   R15,T2C(R1)                                              36500018
         LA    R0,T2C(R1)                                               36510018
         ST    R0,T14(R1)          PUT ADDR IN CCW                      36520018
         MVC   T35(3,R1),T15(R1)   PUT ADDR IN CCW                      36530018
         LA    R0,X44(,R1)              GET ENDING ADDR                 36620018
         ST    R0,T0C(,R1)              STORE IN IOB                    36710018
         LA    RBR,QMPCA           ADDR EXTENDED SAVE AREA              36800018
          ST   RBR,QMPCL           SET UP IN QMPA                       36840018
         MVI   QMPNC,X'01'         NUMB OF RECORDS TO WRITE             36880018
         LA    RBR,DSB             DSB ADDR                             36920018
         ST    RBR,QMPCA           STORE IT                             36960018
         MVC   T3D(3,R1),QMPCA+1        CHANGE ADDRESS                  36980018
         MVC   QMPEX(3),DSB        MOVE IN TTR OF THIS DSB              37000018
         MVI   QMPEX+3,0           PUT 0 IN Z                           37040018
         BR    RWORK4                   RETURN                          37043018
*    FIND OUT THE DISPOSITION                                           37047018
TERMP    MVC   DDNAME(8),DSBDDNAM       GET DATA SET'S DDNAME           37048018
         MVI   TERMSW,X'FF'             DSB FOUND                       37049018
         BAL   RWORK4,SETUP             SET UP QMPA-IOB                 37050018
         TM    ERRORSW,PRINTALL         Q. PRINT ALL                    37054018
         BO    QPR                      YES                             37061018
         TM    SWITCH,DELETALL          Q. DELETE ALL                   37063018
         BO    DELETE                   YES                             37065018
         CLI   PPTABPTR,LPPTABLE        Q. END OF TABLE                 37068018
         BE    QPR                      YES, PRINT REMAINDED            37075018
         IC    RPAR1,PPTABPTR           GET POINTER TO DISPOSITION      37082018
         LA    RPAR1,1(,RPAR1)          INCREMENT BY ONE                37089018
         STC   RPAR1,PPTABPTR           STORE BACK FOR THIS DSB         37096018
         XR    RPAR0,RPAR0              CLEAR REGISTER                  37103018
         IC    RPAR0,PPTABPTR           GET INDEX TO THE DISPOSITION    37110018
         LA    RPAR1,PPTABLE            BEGINNING OF THE TABLE          37117018
         AR    RPAR1,RPAR0              SYSOUT DISPOSITION              37124018
         TM    0(RPAR1),128             Q. PRINT SELECTED               37131018
         BO    QPR                      YES                             37138018
         TM    0(RPAR1),64              Q. PUNCH SELECTED               37145018
         BO    QPU                      YES                             37152018
         B     DELETE                   ELSE DELETE                     37159018
QPR      MVC   QMTPY,QUE                PRINT QUEUE                     37159618
         B     COPYJFCB                 CONTINUE                        37160218
QPU      MVC   QMTPY,QUE1               PUNCH QUEUE                     37160818
COPYJFCB BAL   RWORK4,READJFCB          READ IN THE JFCB                37161418
         LTR   RBR,RBR                  Q. READ OK                      37162018
         BZ    AGST                     YES                             37162618
FREEIT   EQU   *                                                        37162918
         BAL   RWORK4,FREEIOB           DELETE IOB FOR QMPA             37163218
         MVC   ERRNO(3),ERR75           CAN'T ENQUEUE                   37163818
         BAL   RWORK4,ERRNM             TO ISSUE MSG                    37164418
         B     TERM1                    CONTINUE                        37165018
AGST     BAL   RWORK4,FREEIOB           DELETE IOB FOR QMPA             37165618
         CLI   SWQMPA,X'FF'             Q. QMPA SAVED                   37166218
         BE    NOQMPA                   YES                             37166818
         MVI   SWQMPA,X'FF'             INDICATE QMPA SAVED             37167418
         MVC   RECAREA+16(LQMPA),QMPA   SAVE QMPA FOR DELETION          37168018
NOQMPA   EQU   *                                                        37168618
         MVI   QMPOP,QMASGS             ASSIGN/START                    37169818
         LA    RBR,RECAREA              ADDR FOR TTR'S                  37170418
         ST    RBR,QMPCM                PUT IN QMPA                     37171018
         MVI   QMPCM,X'20'              GET TWO TRACKS                  37171618
         XC    QMFLT(QMTPY-QMFLT),QMFLT      ZERO QMPA                  37172618
         XC    QMLNK(L'QMLNK),QMLNK     FOR NEW LTH'S                   37173618
         BAL   RWORK4,TOQMGR            INITIALIZE IOB, ASSIGN TRACKS   37174618
         BNZ   FREEIT                   NOT DONE                        37175618
         LA    RBR,QMPCA                ADDR OF EXTERNAL PARM           37176618
         ST    RBR,QMPCL                PUT INTO QMPA                   37180618
         MVI   QMPNC,1                  ONE RECORD                      37181218
         MVC   QMPEX(3),RECAREA+4       SECOND TTR FOR JFCB             37181818
         MVI   QMPEX+3,0                ZERO LAST BYTE                  37182418
         LA    RBR,LOCJFCB              ADDR OF RECORD                  37183018
         ST    RBR,QMPCA                PUT INTO JFCB                   37183618
         MVI   QMPOP,QMWRTE             WRITE OPERATION                 37184218
         BAL   RWORK4,TOQMGR            WRITE JFCB                      37185218
         BNZ   NENQ                     NO                              37187218
         LA    RBR,DSB                  ADDR OF RECORD                  37187818
         ST    RBR,QMPCA                PUT INTO QMPA                   37188418
         MVC   QMPEX(3),RECAREA         FIRST TTR FOR DSB               37189018
         MVC   JFCBTTRZ(3),RECAREA+4    SECOND TTR FOR JFCB             37189618
         MVC   DSB(3),RECAREA           TRACK ID FOR DSB                37190218
         XC    SMBNEXT(4),SMBNEXT       ZERO FOR LAST                   37190818
         BAL   RWORK4,TOQMGR            WRITE DSB                       37191818
         BNZ   NENQ                     NO                              37193818
ENQ      MVI   QMPOP,QMWREN             ENQUEUE                         37203818
         BAL   RWORK4,TOQMGR            ENQUEUE THE DSB                 37213818
         BZ    TERM1                    CONTINUE IF OK                  37248018
NENQ     MVC   ERRNO(3),ERR75           CAN'T ENQUEUE                   37256018
         BAL   RWORK4,ERRNM             TO ISSUE MSG.                   37264018
         MVI   QMPOP,QMDELE             DELETE CODE                     37270018
         LA    RPAR1,QMPA               GET ADDR OF QMPA                37276018
         L     RBR,IEFQDEL              ADDR OF DELETE RTNE             37282018
         BALR  RET,RBR                  TO DELETE FROM JOBQ             37288018
         B     TERM1                    CONTINUE                        37294018
*                                                                       37304018
**   READ THE JFCB FOR THE DSB                                          37314018
*                                                                       37324018
READJFCB LA    RPAR1,QMPA               GET ADDR OF QMPA                37334018
         MVC   QMPEX(3),JFCBTTRZ        TTR FOR JFCB                    37384018
         MVI   QMPEX+3,0                ZERO LAST BYTE                  37414018
         MVI   QMPOP,QMREAD             READ                            37444018
         LA    RBR,LOCJFCB              USE AVAILABLE SPACE             37474018
         ST    RBR,QMPCA                STORE IN QMPA                   37504018
         L     RBR,IEFQMGR              ADDR OF Q-MANAGER ROUTINE       37534018
         BALR  RET,RBR                  TO READ JFCB                    37564018
         BR    RWORK4                   RETURN                          37569018
*                                                                       37574018
**   DELETE THE DATA SET                                                37579018
*                                                                       37584018
DELETE   BAL   RWORK4,READJFCB          READ IN THE JFCB                37589018
         LTR   RBR,RBR                  Q. READ OK                      37594018
         BZ    RJFCBOK                  YES                             37624018
         BAL   RWORK4,FREEIOB           DELETE IOB FOR QMPA             37634018
         MVC   ERRNO(3),ERR76           CAN'T DELETE                    37654018
         BAL   RWORK4,ERRNM             GO ISSUE MSG                    37684018
         B     TERM1                    CONTINUE                        37714018
RJFCBOK  MVC   CAMLIST(LCAM),CAM        SET UP TO SCRATCH               37744018
         BAL   RWORK4,FREEIOB           DELETE IOB FOR QMPA             37754018
         LA    RBR,VOLIST               LOCATION OF VOL LIST            37774018
         ST    RBR,CAMLIST+12           PLACED INTO FIELD               37804018
         LA    RBR,LOCJFCB              LOCATION OF DSNAME              37834018
         USING JFCB,RBR                                                 37864018
         ST    RBR,CAMLIST+4            PLACED INTO FIELD               37894018
         SR    RPAR1,RPAR1              ZERO REGISTER                   37924018
         IC    RPAR1,JFCBNVOL           GET NO. OF VOLUMES              37954018
         STH   RPAR1,VOLIST             PLACE INTO FIELD                37984018
         MVC   VOLSER(6),JFCBVOLS       GET VOLUME SERIAL NO.           38014018
         DROP  RBR                                                      38044018
         LH    RBR,UCB                  GET UCB ADDR                    38074018
         MVC   VOLTYP(4),UCBTYPE(RBR)   DEVICE TYPE                     38104018
         XC    VOLCODE(2),VOLCODE       ZERO FOR DISK                   38134018
         SR    RPAR0,RPAR0              NO UCB                          38164018
         SCRATCH CAMLIST                ADDR OF PARMLIST                38194018
         LTR   RBR,RBR                  Q. SCRATCH OK                   38224018
         BZ    TERM1                    YES                             38254018
         MVC   ERRNO(3),ERR76           ERROR MSG NO.                   38284018
         BAL   RWORK4,ERRNM             TO ISSUE MSG                    38314018
         B     TERM1                    CONTINUE                        38344018
*                                                                       38374018
**   DELETE THE SMB'S                                                   38404018
*                                                                       38434018
TERMOUT  EQU   *                                                        38464018
         CLI   TERMSW,X'FF'             Q. ANY DSB'S FOUND              38494018
         BNE   TERM2                    NO - TERMINATE                  38524018
         BAL   RWORK4,BEGING            TO THE BEGINNING                38534018
         CLI   SWQMPA,X'FF'             Q. QMPA SAVED                   38544018
         BNE   NOQMPA1                                                  38554018
         MVC   QMPA(LQMPA),RECAREA+16   RESTORE QMPA FOR DELETION       38564018
NOQMPA1  EQU   *                                                        38574018
         LA    RWORK,DSB                ADDR OF DSB AREA                38584018
         BAL   RWORK4,READJCL           READ FIRST SMB                  38614018
         BAL   RWORK4,SETUP             SET UP QMPA-IOB                 38644018
         MVI   QMPOP,QMDELE        DELETE CODE                          38960018
         MVC   QMTPY,GJPQUE        Q THAT GJP USES                      39000018
         L     RBR,IEFQDEL         ADDR DELETE RTN                      39080018
         LA    RPAR1,QMPA               ADDR OF QMPA-IOB                39100018
         BALR  RET,RBR                                                  39120018
         B     TERM2                    TO TERMINATE                    39124018
*                                                                       39125018
**   FREE THE IOB FOR THE QMPA                                          39126018
*                                                                       39127018
FREEIOB  L     RPAR1,QMEIA              GET ADDR OF ECB/IOB             39128018
         SH    RPAR1,K4                 DECREMENT TO BEGINNING          39129018
         L     RPAR0,0(,RPAR1)          GET SUBPOOL AND LENGTH          39130018
         FREEMAIN R,LV=(0),A=(1)        GOODBYE ECB-IOB                 39131018
         BR    RWORK4                   RETURN                          39132018
         DROP  RDSECT                   GOODBYE QMPA                    39133018
         EJECT                                                          39134018
*                                                                       39137018
**   CLEAN UP AND GO BACK                                               39140018
*                                                                       39143018
TERM2    CLC   ADTIOTEN,HEXZERO         Q. DATA SET OPENED              39150018
         BE    TERM3                    NO, DON'T CLOSE                 39160018
         MVI   ADSYSDS,X'80'            TURN ON HIGH ORDER BIT          39170018
         LA    RPAR1,ADSYSDS       ADDR SYSOUT DS                       39180018
         CLOSE MF=(E,(1))          CLOSE SYSOUT SET                     39200018
         FREEPOOL DCBSYS                                         A36206 39202000
         L     RWORK,ADTIOTEN           GET POINTER TO TIOT ENTRY       39210018
         MVC   ZERO(TWENTY,RWORK),HOLDTIOT   RESTORE DUMMY TIOT ENTRY   39220018
TERM3    TM    CCTSSTAT,SGJP            Q. SGJP IN CONTROL              39240018
         BO    TERM4                    NO, DON'T CLOSE DCB             39260018
         LA    RPAR1,ADWORKDS      ADDR ADDR WORK DATA SET DCB          39280018
         MVI   ADWORKDS,X'80'      SET LAST DCB BIT                     39320018
         CLOSE MF=(E,(1))          CLOSE WORK DATA SET                  39360018
TERM4    SR    R12,R12                  ZERO FOR RETURN CODE            39370018
         TM    ERRORSW,FSTOP            Q. FAST STOP ISSUED             39372018
         BZ    TERMNATE                 NO                              39374018
         LH    R12,TERMCODE             MUST TERMINATE                  39376018
TERMNATE TM    CCTSSTAT,SGJP            Q. SGJP IN CONTROL              39384018
         BO    SGJP4                    YES, AVOID ATTENTION RTNE       39392018
         L     RWORK,CCTGACBP      ADDR GACB                            39400018
         MVC   16(4,RWORK),GJPATTN   STORE GJP ATTN RTN ADDR TO GACB    39440018
         L     RWORK,0(RWORK)      ADDR COMMUNICATIONS AREA             39480018
         ST    RCCT,16(RWORK)      RESTORE CCT AS COMMUNICATIONS AREA   39520018
SGJP4    CLI   QMGRSW,X'F0'             Q. Q-MGR ROUTINES LOADED        39540018
         BNE   FREEWA                   NO, DON'T DELETE                39560018
         DELETE EP=IEFQMSSS             Q-MGR CONTROL ROUTINE           39580018
         DELETE EP=IEFQDELE             Q-MGR DELETE ROUTINE            39600018
FREEWA   EQU   *                                                        39620018
         L     RPAR0,FREELENG      LENGTH TO FREE                       39670018
         L     RPAR1,FREELIST      AREA TO FREE                         39700018
         FREEMAIN R,LV=(0),A=(1)   FREE                                 39730018
         L     RSAVE,SAVE+4                                             39760018
         LR    RBR,R12                  GET RETURN CODE                 39780018
         RETURN (14,12),RC=(15)         GO BACK                         39800018
         EJECT                                                          39810018
**       ERROR MESSAGE ROUTINE                                          39820018
*                                                                       39830018
ERRNM    EQU   *                                                        39840018
         LA    RPAR1,ERRCNT             ADDR OF INSERT                  39850018
         ST    RPAR1,ERRINS             PLACED IN LIST                  39860018
         LA    RPAR1,10                 TOTAL LENGTH                    39870018
         STH   RPAR1,ERRCNT             PLACED IN LIST                  39880018
         MVC   ERRDDNM(8),DDNAME        DDNAME FOR MSG                  39890018
         B     ERRCOMM                  CONTINUE                        39900018
RERR     EQU   *                                                        39910018
         MVC   ERRNO(3),ERR71           SET UP ERROR MSG.               39920018
         MVI   INSERT,C'R'              INDICATE RETURN CODE            39930018
         LA    RWORK4,TERM              SET UP EXIT ADDR                39940018
         B     ERRCOMM                  CONTINUE                        39950018
ERR      EQU   *                                                        39960018
         MVI   INSERT,C'R'              INDICATE RETURN CODE            39970018
         STH   RBR,INSERTCD             PLACE RC INTO LIST              39980018
ERRCOMM  MVC   ERRCONST(5),ERRCONS      PLACE MODULE NAME INTO LIST     39990018
         MVI   ERRATTR,X'40'       ERROR ATTRIBUTES                     40120018
         L     RBR,CCTIERRP        ADDR IKAIERR                         40160018
         LR    RPAR1,RCCT          ADDR CCT IN REG 1                    40200018
         LA    RPAR0,ERRLIST       ADDR OF ERROR PARM LIST              40240018
         BALR  RET,RBR                                                  40280018
         LTR   RBR,RBR                  Q. RETURN CODE ZERO             40288018
         BZ    TESTIO                   YES, CONTINUE                   40296018
         LR    R12,RBR                  SAVE RETURN CODE                40304018
         B     TERMNATE                 TO EXIT                         40312018
TESTIO   CLI   ERRNO+2,C'4'             Q. I/O ERROR                    40314018
         BL    ENQTERM                  YES, PRINT ALL                  40316018
         BR    RWORK4                   CONTINUE                        40318018
 TITLE ' IKAPDIS0     CONSTANTS'                                        40320018
**********************************************************************  40360018
*********************************************************************** 40400018
* EXECUTABLE INSTRUCTIONS                                               40440018
MVCMSG   MVC   LORDER4(0,RWORK),1(RWORK2)                               40560018
MOVE     MVC   0(0,RWORK2),0(RPAR1)                                     40600018
*                                  MOVE MSG (NUMB. IN 'MSGNO' ADDR IN   40640018
*                                  RWORK2) INTO DISPLAY                 40680018
MOVETAB  MVC   0(0,RWORK),0(RWORK3)    MOVE PART OF REC TO DISP         40720018
HEXZERO  DC    F'0'                     BINARY ZERO                     40820018
ONE      DC      F'0001'           USED TO POINT AT FIRST RECORD OF JCL 41040018
ERR70    DC    C'070'                   ERROR MESSAGE NO.               41090018
ERR71    DC    C'071'                   ERROR MESSAGE NO.               41140018
ERR72    DC    C'072'                                                   41208018
ERR73    DC    C'073'                   ERROR MESSAGE NO.               41210018
ERR74    DC    C'074'                   ERROR MESSAGE NO.               41212018
ERR75    DC    C'075'                                                   41216018
ERR76    DC    C'076'                   ERROR MESSAGE NO.               41220018
ERRCONS  DC    C'PDIS0'                                                 41320018
XM3      DC    H'-3'                                                    41360018
X132     DC    H'132'                                                   41400018
X18      DC    H'24'                                                    41440018
TERMCODE DC    H'28'                    'MUST TERMINATE' CODE           41500018
K4       DC    H'4'                     CONSTANT                        41530018
X25      DC    H'25'                    RECORDS PER PAGE                41560018
KRECAREA DC    AL2(RECAREA-WORKAREA)                                    41600018
SECBUF   DC    AL2(LRECAREA)                                            41640018
ADISPLAY DC    AL2(LDISP)                                               41680018
LWORKS   DC    A(GETMAIN)          GETMAIN LENGTH                       41700018
         DS    0F                                                       41720018
GJPDIS0  DC    C'GJPDIS0 '                                              41840018
IKAMDIS  DC    V(IKAMDIS0)                                              41880018
JCLSYN   DC    A(JCLSYNAD)                                              41900018
JCLEOD   DC    A(JCLEODRT)                                              41920018
TERMEOD  DC    A(TERMOUT)               END OF DATA                     41930018
TERMSYN  DC    A(TERM2)                 SYNCHRONOUS ERROR               41940018
ATTNRTN  DC    V(IKAADIS0)                                              41960018
LNOWRK   DC    A(GETMAIN1)              AREA FREED AT TERMINATION       41970018
LINESPAC DC    H'110'              RASTER UNITS BETWEEN LINES           41990018
COMP     DC    C'COMPL'                                                 42000018
         DS    0F                                                       42040018
LOWEST4  DC    X'0000000F'                                              42080018
CAM      CAMLST SCRATCH,0,,0,,OVRD      CATALOG MANAGEMENT CONSTANT     42180018
LCAM     EQU   *-CAM                    SIZE OF CAMLST                  42280018
DIS1DCBF DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=GJPDIS1,DEVD=DA,          X42400018
               RECFM=FBS,LRECL=132,BLKSIZE=3300,SYNAD=SYNAD1,          X42440018
               EODAD=EODAD1,EXLST=WORKEXIT                              42480018
DIS1DCBE EQU   *                                                        42520018
DCBSYSLF DCB DSORG=PS,MACRF=(GL),EODAD=EODAD2,BUFNO=2,EXLST=EXITLIST,  *42560018
               SYNAD=SYNAD2                                             42600018
DCBSYSLE EQU   *                                                        42640018
LDCBSYS  EQU   DCBSYSLE-DCBSYSLF                                        42680018
EXITLIST DS    0F                  PARAMETERS OF EXIT LIST FOR SYS DCB  42720018
         DC    XL1'85'                                                  42760018
         DC    AL3(DCBEXIT)        ADDR EXIT RTN                        42800018
         DS    0F                                                       42840018
LDIS1DCB EQU   DIS1DCBE-DIS1DCBF   LENGTH OF DCB FOR WORK DATA SET      42880018
OPEN     OPEN         (,(INOUT)),MF=L                                   42920018
OPENEND  EQU   *                                                        42960018
LOPEN    EQU   OPENEND-OPEN                                             43000018
OPEN2C   OPEN  (,(INPUT)),MF=L                                          43040018
         GCNTRL CCDECB,INS,DUMMY,DUMMY,MF=L                             43080018
CDECBE   EQU   *                                                        43120018
LGCNTRLC EQU   CDECBE-CCDECB                                            43160018
         GCNTRL RRDECB,STR,DUMMY,DUMMY,MF=L                             43200018
RDECBE   EQU   *                                                        43240018
LGCNTRLR EQU   RDECBE-RRDECB                                            43280018
OPEN2E   EQU   *                                                        43320018
LOPEN2   EQU   OPEN2E-OPEN2C                                            43360018
READB    EQU   *                                                        43400018
         READ  JCLDECB,SF,,,176,MF=L                                    43440018
READE    EQU   *                                                        43480018
LREAD    EQU   READE-READB                                              43520018
         READ  BDECBL,SF,,,132,MF=L                                     43560018
BDECBLE  EQU   *                                                        43600018
LBDECB   EQU   BDECBLE-BDECBL                                           43640018
DUMMY    EQU   *                                                        43680018
LFORMGW  GWRITE GWDECB,STR,DUMMY,2232,DUMMY,DUMMY,MF=L                  43720018
GWRITEND EQU   *                                                        43760018
LGWRITE  EQU   GWRITEND-LFORMGW                                         43800018
ORDER1   EQU   *                                                        43840018
         DS    0F                                                       43850018
WORKEXIT DC    X'86'                                                    43860018
         DC    AL3(WORKEOV)        ADDR  WORK DS END OF VOL RTN         43870018
         EJECT                                                          43872018
*                                                                       43874018
**   THIS DESCRIBES THE DISPLAY FOR THE 2250                            43876018
*                                                                       43878018
         GINIT                                                          43880018
*                                  INITIALIZE BUFFER                    43920018
GSRT     EQU   *                                                        43960018
         GSRT                                                           44000018
*                                  START REGENERATION                   44040018
GEVM     GEVM                                                           44080018
*                                  ENTER VECTOR MODE                    44120018
         GDV   0,4016,B                                                 44160018
*                                  POSITION BEAM TO UPPER-LEFT          44200018
         GECP  L                                                        44240018
          GTXT 'SYSOUT DISPLAY:'                                        44280018
DDNAMEPE EQU   *                                                        44320018
DDNAMEP  EQU   DDNAMEPE-ORDER1                                          44360018
          GTXT                '                                  '      44400018
          GTXT '    TAB='                                               44440018
DISPLCE  EQU   *                                                        44480018
DISPLC   EQU   DISPLCE-ORDER1                                           44520018
         GTXT          '           RECORD='                             44560018
RECORDPE EQU   *                                                        44600018
RECORD   EQU   RECORDPE-ORDER1                                          44640018
          GTXT                           '     '                        44680018
*                                  ENTER CHARACTER MODE FOR DDNAME      44720018
ORDER1E  EQU   *                                                        44760018
LORDER1  EQU   ORDER1E-ORDER1                                           44800018
         DS    0H                                                       44840018
ORDER2   EQU   *                                                        44880018
         GEVM                                                           44920018
         GDV   0,3600,B                                                 44960018
         GECP  B                                                        45000018
ORDER2E  EQU   *                                                        45040018
LORDER2  EQU   ORDER2E-ORDER2                                           45080018
ORDER3   EQU   *                                                        45120018
         GEVM                                                           45160018
         GDV   0,0,B                                                    45200018
         GECP  B                                                        45240018
ORDER3E  EQU   *                                                        45280018
LORDER3  EQU   ORDER3E-ORDER3                                           45320018
ORDER4   EQU   *                                                        45360018
         GEVM                                                           45400018
         GDV   500,700,B                                                45440018
         GECP  L                                                        45480018
         GTXT  '       TAB'                                             45520018
         GEVM                                                           45560018
         GDV   *+0,*-60,B                                               45600018
         GDV   *+150,*+0,U                                              45640018
         GDV   *-150,*+60,B                                             45680018
         GECF  L                                                        45720018
BTAB     GTXT  '    '                                                   45760018
BTABE    EQU   *                                                        45800018
ATAB     EQU   *                        LAST CHAR OF KEY IN ORDER4      45840018
         GECP  L                                                        45880018
         GTXT  '  NEXT'                                                 45920018
         GEVM                                                           45960018
         GDV   *+0,*-60,B                                               46000018
         GDV   *+150,*+0,U                                              46040018
         GDV   *-150,*+60,B                                             46080018
         GECF  L                                                        46120018
BNEXT    GTXT  '    '                                                   46160018
BNEXTE   EQU   *                                                        46200018
ANEXT    EQU   *                        LAST CHAR OF KEY IN ORDER4      46240018
         GECP  L                                                        46280018
         GTXT  '  BACK'                                                 46320018
         GEVM                                                           46360018
         GDV   *+0,*-60,B                                               46400018
         GDV   *+150,*+0,U                                              46440018
         GDV   *-150,*+60,B                                             46480018
         GECF  L                                                        46520018
BBACK    GTXT  '    '                                                   46560018
BBACKE   EQU   *                                                        46600018
ABACK    EQU   *                        LAST CHAR OF KEY IN ORDER4      46640018
         GEVM                                                           46680018
         GDV   500,500,B                                                46720018
         GDV   *+0,*-60,B                                               46760018
         GDV   *+075,*+0,U                                              46800018
         GDV   *-075,*+60,B                                             46840018
         GECF  L                                                        46880018
BTOP      GTXT '  '                                                     46920018
BTOPE    EQU   *                                                        46960018
         GECP  L                                                        47000018
         GTXT  'TOP   '                                                 47040018
ATOP     EQU   *                        LAST CHAR OF KEY IN ORDER4      47080018
         GEVM                                                           47120018
         GDV   *+0,*-60,B                                               47160018
         GDV   *+075,*+0,U                                              47200018
         GDV   *-075,*+60,B                                             47240018
         GECF  L                                                        47280018
BCYCLE   GTXT  '  '                                                     47320018
BCYCLEE  EQU   *                                                        47360018
         GECP  L                                                        47400018
         GTXT  'CYCLE '                                                 47440018
ACYCLE   EQU   *                        LAST CHAR OF KEY IN ORDER4      47480018
         GEVM                                                           47520018
         GDV   *+0,*-60,B                                               47560018
         GDV   *+075,*+0,U                                              47600018
         GDV   *-075,*+60,B                                             47640018
         GECF  L                                                        47680018
BPRINT   GTXT  '  '                                                     47720018
BPRINTE  EQU   *                                                        47760018
         GECP  L                                                        47800018
         GTXT  'PRINT '                                                 47840018
APRINT   EQU   *                        LAST CHAR OF KEY IN ORDER4      47880018
         GEVM                                                           47920018
         GDV   *+0,*-60,B                                               47960018
         GDV   *+075,*+0,U                                              48000018
         GDV   *-075,*+60,B                                             48040018
         GECF  L                                                        48080018
BPUNCH   GTXT  '  '                                                     48120018
BPUNCHE  EQU   *                                                        48160018
         GECP  L                                                        48200018
         GTXT  'PUNCH '                                                 48240018
APUNCH   EQU   *                        LAST CHAR OF KEY IN ORDER4      48280018
         GEVM                                                           48320018
         GDV   *+0,*-60,B                                               48360018
         GDV   *+075,*+0,U                                              48400018
         GDV   *-075,*+60,B                                             48440018
         GECF  L                                                        48480018
BTERM    GTXT  '  '                                                     48520018
BTERME   EQU   *                                                        48560018
         GECP  L                                                        48600018
         GTXT  'TERM'                                                   48640018
ATERM    EQU   *                        LAST CHAR OF KEY IN ORDER4      48680018
         GEVM                                                           48720018
         GDV   RUXENDX1,RUXENDY1,B                                      48760018
AEND     EQU   *                                                        48800018
         GDV   RUXENDX1,RUXENDY2,U                                      48840018
         GDV   RUXENDX2,RUXENDY2,U                                      48880018
         GDV   RUXENDX2,RUXENDY1,U                                      48920018
         GDV   RUXENDX1,RUXENDY1,U                                      48960018
         GDV   200,200,B                                                49000018
         GECP  L                                                        49040018
         GTXT  'END '                                                   49080018
         GEVM                                                           49120018
AENDE    EQU   *                                                        49160018
         GDV   300,300,B                                                49200018
         GECP  B                                                        49240018
ORDER4E  EQU   *                                                        49280018
LORDER4  EQU   ORDER4E-ORDER4                                           49320018
ORDER5   EQU   *                                                        49360018
         GTRU  GSRT                                                     49400018
ORDER5E  EQU   *                                                        49440018
LORDER5  EQU   ORDER5E-ORDER5                                           49480018
GTRU     DC    C'**'                                                    49520018
         GTRU  GSRT                                                     49560018
BTABL    EQU   BTABE-BTAB                                               49600018
BNEXTL   EQU   BNEXTE-BNEXT                                             49640018
BBACKL   EQU   BBACKE-BBACK                                             49680018
BTOPL    EQU   BTOPE-BTOP                                               49720018
BCYCLEL  EQU   BCYCLEE-BCYCLE                                           49760018
BPRINTL  EQU   BPRINTE-BPRINT                                           49800018
BPUNCHL  EQU   BPUNCHE-BPUNCH                                           49840018
BTERML   EQU   BTERME-BTERM                                             49880018
LGTRU    EQU   4                                                        49920018
KEYAREA  EQU           LORDER1+0+LORDER2+LORDER3*25+72*25               49960018
LENGTH   EQU   LORDER1+0+LORDER2+LORDER3*25+LORDER4+72+LORDER5+72*25    50000018
LORDER4H EQU   LORDER4/2                                                50040018
KTAB     EQU   BTAB-ORDER4         DISPLACEMENT TO NEXT INPUT AREA      50080018
KNEXT    EQU   BNEXT-BTAB          DISPLACEMENT TO NEXT INPUT AREA      50120018
KBACK    EQU   BBACK-BNEXT         DISPLACEMENT TO NEXT INPUT AREA      50160018
KTOP     EQU   BTOP-BBACK          DISPLACEMENT TO NEXT INPUT AREA      50200018
KCYCLE   EQU   BCYCLE-BTOP         DISPLACEMENT TO NEXT INPUT AREA      50240018
KPRINT   EQU   BPRINT-BCYCLE       DISPLACEMENT TO NEXT INPUT AREA      50280018
KPUNCH   EQU   BPUNCH-BPRINT       DISPLACEMENT TO NEXT INPUT AREA      50320018
KTERM    EQU   BTERM-BPUNCH        DISPLACEMENT TO NEXT INPUT AREA      50360018
LDISPLAY EQU    LORDER5-LORDER1+24*72+24*LORDER3                        50400018
KKPRINT  EQU   BPRINT-ORDER4                                            50440018
KKPUNCH  EQU   BPUNCH-ORDER4                                            50480018
ITAB     EQU   BTAB-ORDER4              FIRST UNPROTECTED CHAR OF KEY   50520018
INEXT    EQU   BNEXT-ORDER4             FIRST UNPROTECTED CHAR OF KEY   50560018
IBACK    EQU   BBACK-ORDER4             FIRST UNPROTECTED CHAR OF KEY   50600018
ITOP     EQU   BTOP-ORDER4              FIRST UNPROTECTED CHAR OF KEY   50640018
ICYCLE   EQU   BCYCLE-ORDER4            FIRST UNPROTECTED CHAR OF KEY   50680018
IPRINT   EQU   BPRINT-ORDER4            FIRST UNPROTECTED CHAR OF KEY   50720018
IPUNCH   EQU   BPUNCH-ORDER4            FIRST UNPROTECTED CHAR OF KEY   50760018
ITERM    EQU   BTERM-ORDER4             FIRST UNPROTECTED CHAR OF KEY   50800018
LPTAB    EQU   ATAB-ORDER4              LAST CHAR OF KEY IN DISPLAY     50840018
LPNEXT   EQU   ANEXT-ATAB               LAST CHAR OF KEY IN DISPLAY     50880018
LPBACK   EQU   ABACK-ANEXT              LAST CHAR OF KEY IN DISPLAY     50920018
LPTOP    EQU   ATOP-ABACK               LAST CHAR OF KEY IN DISPLAY     50960018
LPCYCLE  EQU   ACYCLE-ATOP              LAST CHAR OF KEY IN DISPLAY     51000018
LPPRINT  EQU   APRINT-ACYCLE            LAST CHAR OF KEY IN DISPLAY     51040018
LPPUNCH  EQU   APUNCH-APRINT            LAST CHAR OF KEY IN DISPLAY     51080018
LPTERM   EQU   ATERM-APUNCH             LAST CHAR OF KEY IN DISPLAY     51120018
LPEND    EQU           AEND-ORDER4                                      51160018
LPENDE   EQU   AENDE-AEND                                               51200018
DTERM    EQU   APUNCH-ORDER4       ADDR IN BUFFER OF TERM KEY           51240018
DDTERM   EQU   BTERM-APUNCH        DISPLACEMENT FROM BEGINNING OF TERM  51280018
*                                  KEY TO LOCATION OF CURSOR            51320018
RUXENDX1 EQU   200-42                                                   51360018
RUXENDX2 EQU   200+3*84+42                                              51400018
RUXENDY1 EQU   200+60                                                   51440018
RUXENDY2 EQU   200-60                                                   51480018
         SPACE 2                                                        51482020
*********************************************************************** 51484020
*                                                                       51486020
*        MAINTENANCE AREA                                        A33564 51488020
*                                                                       51490020
*********************************************************************** 51492020
PATCH    DC    50F'0'                                            A33564 51494020
         SPACE 2                                                        51496020
         TITLE 'IKAMDIS0    MESSAGES'                                   51500018
*                                                                       51504018
**   MESSAGE MODULE FOR IKAPDIS0                                        51508018
*                                                                       51512018
*                                  MESSAGE MUST NOT EXCEED 72 CHARS     51516018
IKAMDIS0 CSECT                                                          51520018
INSCUR   EQU   KEYAREA+KTAB        DISPLACEMENT  FOR INSERTING CURSOR   51560018
M1       DC    AL1(LM1)                                                 51600018
         DC    C'GJPDIS1, THE WORK DATA SET CAN NOT BE OPENED'          51640018
M1E      EQU   *                                                        51680018
LM1      EQU   M1E-M1                                                   51720018
M2       DC    AL1(L2)                                                  51760018
         DC    C'THERE ARE NO RECORDS IN THIS DATA SET'                 51800018
M2E      EQU   *                                                        51840018
L2       EQU       (M2E-M2)                                             51880018
M3       DC    AL1(L3)                                                  51920018
         DC   C'DATA SET CAN NOT BE FOUND'                              51960018
M3E      EQU   *                                                        52000018
L3       EQU       (M3E-M3)                                             52040018
M4       DC    AL1(L4)                                                  52080018
         DC   C'SYSOUT DATA SET CAN NOT BE OPENED'                      52120018
M4E      EQU   *                                                        52160018
L4       EQU       (M4E-M4)                                             52200018
M5       DC    AL1(L5)                                                  52240018
         DC    C'REQUEST EXCEEDS RECORD COUNT'                          52280018
M5E      EQU   *                                                        52320018
L5       EQU       (M5E-M5)                                             52360018
M6       DC    AL1(L6)                                                  52400018
         DC   C'INVALID ATTENTION'                                      52440018
M6E      EQU   *                                                        52480018
L6       EQU       (M6E-M6)                                             52520018
M7       DC    AL1(L7)                                                  52560018
         DC    C'TAB VALUE EXCEEDS RECORD LENGTH'                       52600018
M7E      EQU   *                                                        52640018
L7       EQU       (M7E-M7)                                             52680018
M8       DC    AL1(L8)                                                  52720018
         DC    C'SYNCHRONOUS ERROR FOR THIS DATA SET'                   52760018
M8E      EQU   *                                                        52800018
L8       EQU       (M8E-M8)                                             52840018
M9       DC    AL1(L9)                                                  52880018
         DC    C'END OF VOLUME ON GJPDIS1'                              52920018
M9E      EQU   *                                                        52960018
L9   EQU           (M9E-M9)                                             53000018
M10      DC    AL1(L10)                                                 53040018
         DC    C'SYNCHRONOUS ERROR FOR GJPDIS1'                         53080018
M10E     EQU   *                                                        53120018
L10      EQU       (M10E-M10)                                           53160018
M11      DC    AL1(L11)                                                 53200018
         DC    C'END OF DATA ON GJPDIS1'                                53240018
M11E     EQU   *                                                        53280018
L11      EQU       (M11E-M11)                                           53320018
M12      DC    AL1(L12)                                                 53360018
         DC    C'SYNCHRONOUS ERROR FOR GJPJCL'                          53400018
M12E     EQU   *                                                        53440018
L12      EQU       (M12E-M12)                                           53480018
M13      DC    AL1(L13)                                                 53520018
         DC    C'END OF DATA ON THIS DATA SET'                          53560018
M13E     EQU   *                                                        53600018
L13      EQU   M13E-M13                                                 53640018
M14      DC    AL1(L14)                                                 53680018
         DC    C'NO INPUT'                                              53720018
M14E     EQU   *                                                        53760018
L14      EQU   M14E-M14                                                 53800018
M15      DC    AL1(L15)                                                 53840018
         DC    C'BEGINING OF DATA SET'                                  53880018
M15E     EQU   *                                                        53920018
L15      EQU   M15E-M15                                                 53960018
M16      DC    AL1(L16)                                                 54000018
         DC    C'THIS IS THE FIRST DATA SET'                            54040018
M16E     EQU   *                                                        54080018
L16      EQU   M16E-M16                                                 54120018
M17      DC    AL1(L17)                                                 54160018
         DC    C'SELECT TERM TO END DISPLAY'                            54200018
M17E     EQU   *                                                        54240018
L17      EQU   M17E-M17                                                 54280018
M18      DC    AL1(L18)                                                 54290018
         DC    C'GJPDIS0, DD CARD NOT FOUND'                            54300018
L18      EQU   *-M18                                                    54310018
 TITLE ' IKAPDIS0     DSECTS'                                           54320018
**********************************************************************  54360018
         DCBD  DSORG=PS,DEVD=DA                                         54400018
DCBE     EQU   *                                                        54440018
LDCB     EQU   DCBE-IHADCB                                              54480018
         EJECT                                                          54500018
         IEFQMNGR                                                       54520018
QMPAE    EQU   *                                                        54560018
LQMPA    EQU   QMPAE-IOPARAMS                                           54600018
         EJECT                                                          54610018
JFCB     DSECT                                                          54620018
         IEFJFCBN                                                       54630018
         EJECT                                                     PDUM 54640018
CVT      DSECT                                                          54680018
         CVT                                                            54720018
         EJECT                                                          54740018
GFXOCTHD DSECT                                                     PDUM 54760018
GFXHDSTR EQU   *                       START OF HEADER RECORD      PDUM 54800018
OCTSYS   DS    CL1                     BASE SYSTEM                 PDUM 54840018
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS           PDUM 54880018
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS     PDUM 54920018
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD  PDUM 54960018
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD  PDUM 55000018
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS         PDUM 55040018
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS         PDUM 55080018
         DS    0H                                                  PDUM 55120018
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250        PDUM 55160018
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD  PDUM 55200018
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD  PDUM 55240018
         DS    0F                                                  PDUM 55280018
OCTFGREG DS    CL4                      REGION SIZE GJP            PDUM 55320018
OCTFUREG DS    CL4                      REGION SIZE USER FGD       PDUM 55360018
OCTBUREG DS    CL4                      REGION SIZE USER BGD       PDUM 55400018
OCTGTCB  DS    CL4                     TCB ADDRESS OF GFX          PDUM 55440018
OCTHRES  DS    CL4                     RESERVED                    PDUM 55480018
OCTNAME  DS    CL20                     PROGRAMMER NAME            PDUM 55520018
OCTACCT  DS    CL20                     ACCOUNT NUMBER             PDUM 55560018
GFXHDEND EQU   *                       END OF HEADER RECORD        PDUM 55600018
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD   PDUM 55640018
         EJECT                                                     PDUM 55680018
GFXOCTEN DSECT                                                     PDUM 55720018
         DS    0F                                                  PDUM 55760018
GFXENSTR EQU   *                       START OF ENTRY RECORD       PDUM 55800018
OCTECB   DS    CL4                      ECB                        PDUM 55840018
OCTUCB   DS    CL4                      UCB ADDRESS                PDUM 55880018
OCTUNIT  DS    CL4                      UNIT ADDRESS               PDUM 55920018
OCTCOUNT DS    CL4                      JOB COUNT                  PDUM 55960018
OCTNOTE  DS    CL4                      NOTE                       PDUM 56000018
OCTABEND DS    A                       ABEND CODE                  PDUM 56040018
OCTFPART DS    CL2                      PARTITION NUMBER (MFT ONLY)PDUM 56080018
OCTDNOTE DS    CL3                      NOTE FIELD FOR DIARY DATA SPDUM 56120018
OCTIERNO DS    CL3                      INTERNAL ERROR NUMBER      PDUM 56160018
OCTATTR1 DS    CL2                      ATTRIBUTES                 PDUM 56200018
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE    PDUM 56240018
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USE- PPDUM 56280018
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING    PDUM 56320018
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ  PDUM 56360018
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SPDUM 56400018
OCTBIOGD EQU   X'04'          0-                  1-&/O E--O--USE- PDUM 56440018
OCTBIOUS EQU   X'02'          0-                  1-&/O E--O--USE- PDUM 56480018
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250      PDUM 56520018
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB     PDUM 56560018
OCTBCANC EQU   X'40'          0-WA&T FO- &N&T CAN 1-&N&T CANCEL -ECPDUM 56600018
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT      PDUM 56640018
OCTBERR1 EQU   X'10'          0-                  1-GJP &NTE-NAL E-PDUM 56680018
OCTBERR2 EQU   X'08'          0-                  1-GJP &NTE-NAL E-PDUM 56720018
*******************************************************************PDUM 56760018
****                          ATT-&BUTE 2                          PDUM 56800018
*******************************************************************PDUM 56840018
OCTATTR2 DS    CL2                      ATTRIBUTES                 PDUM 56880018
OCTBIRRE EQU   X'80'          0-                  1-GJP &NTE-NAL E-PDUM 56920018
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB PDUM 56960018
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF         PDUM 57000018
OCTBFAST EQU   X'10'          0-                  1-FAST STOP      PDUM 57040018
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP    PDUM 57080018
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP      PDUM 57120018
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND  PDUM 57160018
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250       PDUM 57200018
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INPDUM 57240018
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USPDUM 57280018
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST   PDUM 57320018
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST    PDUM 57360018
*******************************************************************PDUM 57400018
****                          ATTRIBUTE 3                          PDUM 57440018
OCTATTR3 DS    CL2                      ATTRIBUTES                 PDUM 57480018
OCTBIERR EQU   X'80'          0-                  1-GJP &NTE-NAL E-PDUM 57520018
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB PDUM 57560018
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF         PDUM 57600018
OCTBFASM EQU   X'10'          0-                  1-FAST STOP      PDUM 57640018
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP    PDUM 57680018
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP      PDUM 57720018
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND  PDUM 57760018
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250       PDUM 57800018
OCTBCANI EQU   X'80'          0-                  1-&KACKXT POST(&NPDUM 57840018
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USPDUM 57880018
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST   PDUM 57920018
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST    PDUM 57960018
****                          ATTRIBUTE 4                          PDUM 58000018
OCTATTR4 DS    CL1                      ATTRIBUTES                      58010018
OCTBSGJP EQU   X'80'          0-USER/GJP JOB      1-INITIAL PROCESSOR   58020018
****                                                                    58030018
*                             CONSOLE IDENTIFICATION                    58040018
****                                                                    58050018
OCTCONSL DS    CL1                      CONSOLE ID                      58060018
GFXENEND EQU   *                       END OF ENTRY RECORD         PDUM 58080018
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD        PDUM 58120018
         EJECT                                                     PDUM 58160018
CCT      DSECT                                                          58200018
         SPACE 2                                                        58240018
*                             SECTION ONE                               58280018
         SPACE                                                          58320018
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     58360018
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    58400018
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  58440018
         SPACE                                                          58480018
         DS    0F                                                       58520018
CCTUNAME DS    5F                  USER'S NAME                          58560018
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         58600018
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     58640018
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       58680018
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    58720018
*                                       AT LAST BEGIN JOB               58760018
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   58800018
*                                       LAST BEGIN JOB                  58840018
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 58880018
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    58920018
*                                       JOB                             58960018
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    59000018
*                                       JOB                             59040018
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     59080018
*                                       CESSOR                          59120018
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         59160018
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         59200018
CCTJCTR  DS    H                   JOB COUNTER                          59240018
CCTHIST  DS    109F                HISTORY OF OPERATIONS                59280018
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   59320018
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  59360018
CCTSSTAT DS    C                   SESSION STATUS                       59400018
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              59440018
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              59480018
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    59520018
         EJECT                                                          59560018
         SPACE 2                                                        59600018
*                             SECTION TWO                               59640018
         SPACE                                                          59680018
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   59720018
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  59760018
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 59800018
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              59840018
         SPACE                                                          59880018
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     59920018
*                                       FRAME                           59960018
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  60000018
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     60040018
*                                       MULTIPLE DISPLAY FRAME (ENT)    60080018
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   60120018
CCTDISM  DS    C                   DISPLAY MASK                         60160018
CCTCSM   DS    C                   COMMAND SELECT MASK                  60200018
CCTPSTAT DS    CL2                 GJP STATUS                           60240018
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              60280018
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  60320018
         SPACE 2                                                        60360018
*                             SECTION THREE                             60400018
         SPACE                                                          60440018
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    60480018
*                   INTO SECTION ONE OR TWO                             60520018
         SPACE                                                          60560018
CCTDGMP  DS    F                  POINTER TO DGM                        60600018
CCTDATAP DS    F                  POINTER TO DATA NUMBER                60640018
CCTCSTP  DS    F                  POINTER TO CST                        60680018
CCTCPSTP DS    F                  POINTER TO CURRENT PST                60720018
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            60760018
CCTDORP  DS    F                  POINTER TO DOR MODULE                 60800018
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              60840018
CCTDIARP DS    F                  POINTER TO DIA                        60880018
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      60920018
CCTACTP  DS    F                  POINTER TO ACT                        60960018
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     61000018
CCTIERRP DS    F                  POINTER TO IERR                       61040018
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              61080018
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               61120018
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                61160018
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 61200018
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 61240018
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   61280018
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                61320018
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                61360018
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               61400018
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              61440018
CCTPECB  DS    F                  PROCESSOR'S ECB                       61480018
CCTWECB  DS    F                  WTOR ECB                              61520018
CCTDIAWA DS    CL136               DIARY WORK AREA                      61560018
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    61600018
CCTCSAVE DS    CL72                CTL SAVE AREA                        61640018
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                61680018
CCTASAVE DS    CL72                DAT SAVE AREA                        61720018
 TITLE ' IKAPDIS0     WORKAREA'                                         61760018
**********************************************************************  61800018
*                                                                       61860018
         USING WORKAREA,RAREA                                           61920018
*                                                                       61960018
WORKAREA DSECT                                                          62000018
FREELIST DS    1F                                                       62050018
FREELENG DS    1F                                                       62060018
AREA1    EQU   *                                                        62080018
DOPEN    DS    1F                                                       62120018
OPEN2    DS    1F                                                       62160018
ATTNSAVE DS    18F                 SAVE AREA FOR ATTN ROUTINE           62200018
SAVE     DS    18F                 SAVE AREA                            62240018
QECB     DS    2F                                                       62280018
ECB      DS    F                                                        62320018
ADECB    EQU   *                                                        62360018
DSCB     DS    4F                                                       62440018
BDECB    DS    XL(LBDECB)                                               62480018
SWITCH   DS    XL1                      BIT SWITCHES                    62490018
*                                                                       62500018
ERRORSW  DS    XL1                      ERROR CONDITION SWITCH          62510018
ERRSYN1  EQU   128                      SYNAD - DISPLAY DATA SET        62520018
ERREOD1  EQU   64                       EODAD - DISPLAY DATA SET        62530018
ERRSYN2  EQU   32                       SYNAD - SYSOUT DATA SET(S)      62540018
ERREOD2  EQU   16                       EODAD - SYSOUT DATA SET(S)      62550018
ERRSYNJ  EQU   8                        SYNAD - JCL DATA SET (SMB,DSB)  62560018
ERREODJ  EQU   4                        EODAD - JCL DATA SET (SMB,DSB)  62570018
PRINTALL EQU   2                        PRINT ALL SYSOUT                62580018
FSTOP    EQU   1                        FAST STOP ISSUED                62590018
*    DISPOSITION QUEUES                                                 62600018
QUE      DS    C                        PRINT QUEUE                     62610018
QUE1     DS    C                        PUNCH QUEUE                     62620018
ADTIOTEN DS    F                   ADDR  DUMMY ENTRY IN TIOT            62640018
ADSYSDS  DS    A(DCBSYS)                                                62680018
HOLDNOTE DS    F                                                        62720018
ACCT     DS    F                                                        62760018
GJPATTN  DS    1F                                                       62840018
IEFQMGR  DS    F                                                        62940018
IEFQDEL  DS    F                                                        63120018
T        EQU   4                                                        63160018
PHASE    DS    1F                                                       63200018
BLP      DS    H                                                        63240018
STARTADR DS    H                                                        63400018
INA      DS    H                                                        63440018
INSAD    DS    H                                                        63480018
*                                                                       63510018
**   TIOT ENTRY                                                         63540018
*                                                                       63570018
HOLDTIOT DS    CL20                     DUMMY TIOT ENTRY                63600018
QMGRSW   DS    C                        SWITCH ON IF Q-MGR LOADED       63610018
SWQMPA   DS    C                   SWITCH ON IF QMPA SAVED              63630018
DOUBLE   DS    D                   DOUBLE WORD USED TO CONVERT TO BINAR 63640018
ADWORKDS DS    A(DCB)              ADDR SYSOUT DATA SET DCB             63720018
INPUTA   DS    XL(LORDER4)                                              63760018
MSGNO    DS    CL1'1'         MSG NUMBER                                63800018
*    SYSOUT=DISPLAY QUEUE                                               63810018
GJPQUE   DS    C                        GFX QUEUE                       63820018
* DISPLACEMENT OF LINE WITHIN RECORD. THIS FIELD IS IN EBCDIC WHEN      63840018
* RECEIVED FROM USER BY IKAADIS0, BUT IKAADIS0 TRANSLATES IT TO BINARY  63880018
* FOR IKAPDIS0                                                          63920018
*                                                                       63960018
TAB      DS    1C                 DISPLACEMENT WITHIN RECORD OF DISPLAY 64000018
NEXTAB   DS    1C                                                       64040018
* DISPLACEMENT OF LINE WITHIN RECORD. THIS FIELD IS ALWAYS HEX. IT IS   64080018
* USED BY IKAADIS0 TO HOLD TAB AMOUNT NOT CURRENTLY WANTED BY USER.     64120018
*                                                                       64160018
         DS    0H                                                       64200018
         SPACE 3                                                        64240018
DDNAME   DS    CL8                                                      64280018
* DDNAME OF SYSOUT DATA SET BEGING DISPLAYED                            64320018
DD8      DS    CL8                                                      64380018
* PPTABLE IS THE 'PRINT/PUNCH TABLE' AND IS USED TO INDICATE WHICH      64440018
* DATA SETS HAVE BEEN QUEUED. THE HIGH BIT IS ONE FOR PRINT, NEXT BIT   64480018
* IS ONE FOR PUNCH                                                      64520018
PPTABLE  DS    27B                      TABLE OF DISPOSITIONS           64540018
LPPTABLE EQU   *-1-PPTABLE              LENGTH OF TABLE                 64570018
PPTABPTR DS    1C                                                       64600018
* INDEX TO PRINT/PUNCH TABLE                                            64640018
TERMSW   EQU   PPTABLE                  FIRST BYTE                      64680018
TTRTABLE EQU   *                                                        64720018
* TTRTABLE IS A TABLE OF TTR'S OF BLOCKS WRITTEN TO SYS1.XXXDIS1        64760018
         DS    210CL3                                                   64800018
               SPACE 1                                                  64840018
INSCURLP DS    1H                  DISPLACEMENT IN KEY AREA FOR CURSOR  64880018
*                                                                       64920018
* POINTERS                                                              64960018
P        DS    1H                                                       65000018
* POINTER TO BLOCK NEED FOR DISPLAY                                     65040018
*                                                                       65080018
PP       DS    1H                                                       65120018
* POINTER TO LAST BLOCK WRITTEN ON SYS1.XXXDIS1                         65160018
*                                                                       65200018
*                                                                       65240018
         SPACE 3                                                        65280018
         SPACE 3                                                        65320018
DC       DS    1H                                                       65360018
* ACTUAL DISPLACEMENT IN HEX OF FIRST RECORD TO BE DISPLAYED FROM THE   65400018
*                                  WORKAREA                             65440018
ENDCLEAR EQU   *                                                        65480018
ERRLIST  DS    2F                       MSG NO., MOD NAME               65520018
ERRNO    EQU   ERRLIST+0                                                65560018
ERRCONST EQU   ERRLIST+3                                                65600018
ERRATTR  EQU   ERRLIST+8                                                65640018
ERRINS   EQU   ERRLIST+8                                                65680018
         DS    XL1                                                      65760018
INSERT   DS    XL3                                                      65800018
INSERTCD EQU   INSERT+1                                                 65840018
ERRCNT   DS    H                        TOTAL LENGTH                    65850018
ERRDDNM  DS    4H                       DDNAME FOR MSG                  65860018
         DS    0F                                                       65880018
RDECB    DS    XL(LGCNTRLR)                                             65920018
CDECB    DS    XL(LGCNTRLC)                                             65960018
*                                                                       65970018
**   DESCRIPTION OF THE DSB                                             65980018
*                                                                       65990018
DSB      EQU   *                                                        66000018
SMBNEXT   EQU  DSB+4                                                    66040018
         DS    CL14                                                     66200018
DSBFF    DS    CL1                                                      66240018
         DS    CL1                                                      66280018
DSBTIOT  DS    CL4                                                      66320018
DSBDDNAM DS    CL8                                                      66360018
JFCBTTRZ DS    F                                                        66380018
         DS    H                                                        66400018
UCB      DS    H                                                        66420018
LDSBTIOT EQU   20                                                       66440018
         DS    XL(140)                                                  66480018
*                                                                       66510018
**   DESCRIPTION OF A QMPA-IOB                                          66540018
*                                                                       66570018
QMPA     DS    176CL1                                                   66600018
QMECBIOB EQU   QMPA+44                                                  66640018
QMPCA    EQU   QMPA+36                                                  66680018
QMPEX    EQU   QMPA+40                                                  66720018
LASTWRT  DS    F                                                        66760018
         DS    0F                                                       66800018
GDECB    DS    XL(32)              SPACE FOR GRAPHIC READ ECB           66840018
         DS    0F                                                       66880018
WDECB   DS    XL(LGWRITE)                                               66920018
DCB      DS    XL(LDCB)                                                 66960018
DCBSYS   DS    XL(LDCBSYS)                                              67000018
*                                                                       67004018
**   DELETE WORK AREA                                                   67008018
*                                                                       67012018
CAMLIST  DS    XL(LCAM)                                                 67016018
LOCJFCB  DS    XL(JFCBLGTH)                                             67020018
VOLIST   DS    XL2                                                      67024018
VOLTYP   DS    XL4                                                      67028018
VOLSER   DS    XL6                                                      67032018
VOLCODE  DS    XL2                                                      67036018
         DS    0F                       ALIGNMENT                       67038018
* BEGINNING OF THE RECORD AREA                                          67040018
* RECORD AREA HOLD 50 RECORDS TRUNCATED OR PADDED TO 132 BYTES          67080018
RECAREA  DS    25CL132                                                  67120018
RECAREAE EQU   *                                                        67160018
LRECAREA EQU   RECAREAE-RECAREA                                         67200018
SECBUB   DS    25CL132                                                  67240018
SECBUBE  EQU   *                                                        67280018
LSECBUB  EQU   SECBUBE-SECBUB                                           67320018
DISPLAY  EQU   *                                                        67360018
* DISPLAY AREA                                                          67400018
         DS    2700CL1                                                  67440018
LDISP    EQU   DISPLAY-WORKAREA                                         67480018
         DS    0D                       ALIGNMENT                       67500018
AREA1E   EQU   *                                                        67520018
LAREA1   EQU   AREA1E-AREA1                                             67560018
GETMAIN  EQU   LAREA1+8                 TOTAL AREA                      67600018
*                                  TOTAL LENGTH OF WORKAREA             67640018
CLEAR1   EQU   GETMAIN/255         NUMBER OF 255 BYTE SEGMENTS IN AREA  67680018
CLEAR2   EQU   GETMAIN-(CLEAR1*255)                                     67720018
*                                  MODULUS //255 OF WORKAREA            67760018
*                                                                       67766018
**   DEFINE AREA TO BE RELEASED AT TERMINATION                          67772018
*                                                                       67778018
WORKING  EQU   X'900'                   AMOUNT TO KEEP                  67784018
GETMAIN1 EQU   GETMAIN-WORKING          AMOUNT TO FREE                  67790018
         TITLE 'IKAADIS0    ATTENTION ROUTINE'                          67800018
IKAADIS0 CSECT                                                          67840018
         SAVE  (14,12)                                                  67880018
         BALR  RBASE,0                                                  67920018
         USING *,RBASE                                                  67960018
         L      RCOM,0(RPAR1)      ADDR COMMUNICATIONS AREA             68000018
         L     RAREA,16(RCOM)      ADDR WORKAREA                        68040018
         L     RCCT,ACCT           ADDR CCT FROM WORKAREA               68080018
         LA    RWORK,ATTNSAVE      ADDR SAVE AREA FOR ATTN RTN          68120018
         ST    RWORK,X8(RPAR0,RSAVE) PUT INTO O/S SAVE AREA             68160018
X8       EQU   8                                                        68200018
         ST    RSAVE,ATTNSAVE+4     ADDR O/S REGS INTO THIS SAVE AREA   68240018
         LA    RSAVE,ATTNSAVE      ATTN RTN SAVE AREA SET UP            68280018
         MVC   PHASE(T),ZBLDISP    DEFAULT ADDR IN MAON RTN IS BLDDISP  68320018
         TM    SWITCH,TERMC+NORECS TEST FOR BAD DS                      68330018
         BC    5,FAILTERM               TERMINATE IF ON                 68340018
         CLI   3(RCOM),X'01'       ATTN EQU 'END'                       68360018
         BE    GREAD               GO READ BUFFER                       68400018
         CLI   3(RCOM),X'03'       Q. ATTN EQU LP                       68440018
         BE    GREAD               GO READ BUFFER                       68480018
         MVI   MSGNO,MSG06              INVALID ATTENTION               68520018
         B     OUT                                                      68560018
GREAD    EQU   *                                                        68600018
         MVC   GDECB(LGDECB),XDECB                                      68640018
         LA      RWORK3,INPUTA                                          68680018
         MVC   GDECB+8(4),CCTDDCBP ADDR GRAPHIC DCB                     68720018
         ST    RWORK3,GDECB+12     INPUT AREA                           68760018
         LA    RWORK,LORDER4                                            68800018
         ST    RWORK,GDECB+20      LENGTH TO READ                       68840018
         LA    RWORK,BLP           PICK UP ADDR BUFFER LOAD POINT       68880018
         ST    RWORK,GDECB+24      RESTART ADDR WIL BE BLP              68920018
         LH    RWORK,BLP                                                68960018
         LA    RWORK,KEYAREA(RWORK)                                     69000018
         STH   RWORK,INA           PUT DISPLACEMENT INTO 2 BYTE FIELD   69040018
         LA    RWORK,INA           PICK UP ADDR OF 2 BYTE FIELD         69080018
         ST    RWORK,GDECB+28      BUFFER ADDR FOR READ                 69120018
         LA    1,GDECB             ADDR GREAD DECB                      69160018
         GREAD (1),MF=E            READ KEY AREA                        69200018
         LTR   RBR,RBR             TEST RETURN CODE                     69240018
         BZ    RWAIT               ISSUE WAIT IF GREAD OK               69280018
RDERR    STH   RBR,INSERTCD             SAVE RETURN CODE                69300018
         MVC   PHASE(T),ZERR       ADDR OF ERROR RTN                    69320018
         B     OUT                 RETURN                               69360018
RWAIT    EQU   *                                                        69400018
         WAIT  ECB=GDECB           CHECK I/O                            69440018
         CLI   GDECB,X'7F'         IF I/O OK CONTINUE                   69480018
         BE    GREADOK                                                  69520018
         XR    RBR,RBR                  ZERO REGISTER                   69530018
         IC    RBR,GDECB                GET VALUE                       69540018
         B     RDERR                    TO TERMINATE                    69550018
GREADOK  EQU   *                                                        69560018
         CLI   MSGNO,MSG12              Q. SYNCHRONOUS ERROR            69600018
         BE    FAILTERM                                                 69640018
         CLI   3(RCOM),X'01'       Q ATTN=KEYBOARD END                  69680018
         BE    QTAB                A.YES, PROCESS INPUT                 69720018
         CLI   3(RCOM),X'03'       Q.ATTN = LP                          69760018
         BNE   INVALID             A.NO, PUT INVALID ATTN MSG           69800018
         LH    RPAR1,BLP           BUFFER LOAD POINT                    69840018
         LA    RPAR1,KEYAREA(RPAR1)                                     69880018
         LA    RPAR1,LPEND(RPAR1)  LOCATION OF 'END' LP KEY             69920018
         CH    RPAR1,6(0,RCOM)     Q. IS IT LP 'END'                    69960018
         BH    XTAB                A. NO, TEST FOR KEY                  70000018
         LA    RPAR1,LPENDE(RPAR1) LOC OF LAST CHAR. OF 'END'           70040018
         CH    RPAR1,6(0,RCOM)     Q. IS IT LP 'END'                    70080018
         BL    INVALID             A. NO, INVALID                       70120018
QTAB     LA    RWORK,INPUTA+KTAB                                        70160018
         CLC   0(BTABL,RWORK),BLANKS    ANY INPUT FOR TAB               70200018
         BE    QNEXT               NO CHECK NEXT INPUT LOCATION         70240018
         BAL   RPAR1,CONVERT       A. YES, GO CONVERT                   70280018
         MVC   0(BTABL,RWORK),BLANKS    MOVE IN BLANKS FOR NEXT DISPLAY 70320018
         LTR   RBR,RBR                                                  70360018
         BC    4,QTABALPH          BRANCH IF HI BIT ON                  70400018
         LA    RWORK2,DCBSYS                                            70440018
         USING IHADCB,RWORK2                                            70480018
         CH    RBR,DCBLRECL        COMPARE TAB VALUE WITH RECORD LENGTH 70520018
         BL    QTABLOK             A. IF DESIRED TAB TOO HI ISSUE MSG   70560018
         MVI   MSGNO,MSG07              TAB VALUE HIGH                  70600018
         B     PUTMSG              RETURN TO MAIN RTN                   70640018
QTABLOK  STC   RBR,TAB             SAVE NEW TAB VALUE                   70680018
QTABPHAS MVC   PHASE(T),ZBLDISP    MOVE IN ADDR OF BLD DISP PHASE       70720018
         B     QNEXT               CHECK FOR MORE INPUT                 70760018
QTABALPH XC    TAB(1),NEXTAB       INPUT WAS ALPHABETIC,                70800018
         XC    NEXTAB(1),TAB       SWAP                                 70840018
         XC    TAB(1),NEXTAB       TAB VALUES                           70880018
         B     QTABPHAS            SET PHASE AND OUT                    70920018
QNEXT    LA    RWORK,KNEXT(RWORK)  POINT TO NEXT INPUT AREA             70960018
         CLC   0(BNEXTL,RWORK),BLANKS   ANY INPUT FOR NEXT              71000018
         BE    QBACK               A. NO                                71040018
QNEXTEOD BAL   RPAR1,CONVERT       CONVERT RTN                          71080018
         MVC   0(BNEXTL,RWORK),BLANKS   MOVE IN BLANKS FOR NEXT DISPLAY 71120018
         N     RBR,NBIT            TURN OFF HI BIT                      71160018
         SR    RET,RET             CLEAR EVEN REG                       71200018
         LA    RPAR1,25            DIVISOR                              71240018
         AH    RBR,DC                                                   71280018
         DR    RET,RPAR1           NUMB. OF BLOCKS WANTED IN RBR        71320018
         STH   RET,DC              SAVE NEW DC                          71360018
         LH    RPAR1,P             PICK UP PTR TO CURRENT BLK           71400018
         AR    RPAR1,RBR           ADD NUMB OF BLKS NEEDED 3 TIMES      71520018
         AR    RPAR1,RBR           ADD NUMB OF BLKS NEEDED 3 TIMES      71560018
         AR    RPAR1,RBR           ADD NUMB OF BLKS NEEDED 3 TIMES      71600018
         STH   RPAR1,P             SAVE PTR TO TTR TABLE FOR DESIRE BLK 71640018
         TM    SWITCH,SYSEOD       Q. ANY MORE SYSOUT RECORDS           71680018
         BZ    QNEXTOK             A. YES                               71720018
         CH    RPAR1,PP            Q. WILL THIS GO BEYOND EOD           71760018
         BL    QNEXTOK             A. NO                                71800018
         MVC   P(2),PP             SET INDEX TO FINAL BLOCK             71840018
         MVI   MSGNO,MSG13              END OF DATA                     71900018
         OI    SWITCH,BLANKOUT     SET SWITCH TO BLANKOUT SECOND HALF   71960018
         MVC   PHASE(T),ZPOINT     SET UP TO POINT AT FINAL BLOCK       72000018
         B     QBACK               GO TEST 'BACK' KEY                   72040018
QNEXTOK  EQU   *                                                        72080018
         LTR   RBR,RBR             ANY BLOCKS NEEDED                    72090018
         BC    8,QBACK             BRANCH IF NONE NEEDED                72100018
         MVC   PHASE(T),ZNEWDISP                                        72120018
QBACK    LA    RWORK,KBACK(RWORK)  POINT TO BACK INPUT AREA             72160018
         CLC   0(BBACKL,RWORK),BLANKS   ANY INPUT FOR BACK              72200018
         BE    QTOP                A. NO. CHECK TOP INPUT AREA          72240018
QBACKCNV BAL   RPAR1,CONVERT       CONVERT                              72280018
         MVC   0(BBACKL,RWORK),BLANKS   MOVE IN BLANKS FOR NEXT DISPLA  72320018
         N     RBR,NBIT            TURN OFF HI BIT                      72360018
         SR    RET,RET             CLEAR REG                            72400018
         LA    RPAR1,25            25                                   72440018
         DR    RET,RPAR1           GET DELTA/25                         72480018
         LH    RPAR0,P             PICK UP P                            72520018
         SR    RPAR0,RBR           SUBTRACT                             72560018
         SR    RPAR0,RBR                   3 TIMES                      72600018
         SR    RPAR0,RBR                          NUMBER OF BLOCKS      72640018
         BC    4,QBACKTOF          IF RESULT IS NEGATIVE BRANCH         72680018
         LH    RPAR1,DC                                                 72720018
         CH    RET,DC                                                   72760018
         BNH   QBACKOK                                                  72800018
         AH    RPAR1,H25                                                72840018
         SH    RPAR0,H3                                                 72880018
         BC    4,QBACKTOF          IF RESULT IS NEGATIVE BRANCH         72920018
QBACKOK  STH   RPAR0,P             SAVE NEW P                           72960018
         SR    RPAR1,RET                                                73000018
         STH   RPAR1,DC            SAVE NEW DC                          73040018
QBACKP   MVC   PHASE(T),ZPOINT     SET TO POINT                         73080018
         B     QTOP                CONTINUE TO COLLECT INPUT            73120018
QBACKTOF MVI   MSGNO,MSG15              BEGINNING                       73160018
         XC    P(2),P              CLEAR P                              73200018
         XC    DC(2),DC                                                 73240018
         B     QBACKP              GO SET UP PHASE                      73280018
QTOP     LA    RWORK,KTOP(RWORK)   POINT TO TOP INPUT AREA              73320018
         CLC   0(BTOPL,RWORK),BLANKS    ANY INPUT FOR TOP               73360018
         BE   QCYCLE                                                    73400018
         MVC    0(BTOPL,RWORK),BLANKS   MOVE IN BLANKS FOR NEXT DISPLAY 73440018
         MVI   P,X'00'             SET POINTER TO FIRST BLOCK           73480018
         MVI   P+1,X'00'                                                73520018
         MVC   DC(2),HEXZEROS      RESET POINTER WITHIN BLOCK           73540018
         MVC   PHASE(T),ZPOINT     SET UP ADDR TO RETURN TO MAIN RTN    73560018
QCYCLE   LA    RWORK,KCYCLE(RWORK) POINT TO CYCLE INPUT AREA            73600018
         CLC   0(BCYCLEL,RWORK),BLANKS  ANY INPUT FOR CYCLE             73640018
         MVC  0(BCYCLEL,RWORK),BLANKS   MOVE IN BLANKS FOR NEXT DISPLAY 73680018
         BNE   QCYCLEON            YES, RESET PRINT/PUNCH TABLE         73720018
         CLC   KPRINT+KPUNCH+KTERM(BTERML,RWORK),BLANKS  Q. TERM HIT    73760018
         BE    NOTERM                                    A. NO, OUT     73800018
         B     CYC                 THIS IS A TERM DO NOT SET UP CYCLE   73840018
QCYCLEON EQU   *                                                        73880018
         MVC   PHASE(T),ZCYCLEP    A. YES SET PHASE TO START WITH FIRST 73920018
CYC      EQU   *                                                        73960018
         LA    RPAR1,PPTABLE       PRINT/PUNCH TABLE                    74000018
         SR    RPAR0,RPAR0         CLEAR REG                            74040018
         IC    RPAR0,PPTABPTR      INDEX TO PRINT/PUNCH TABLE           74080018
         AR    RPAR1,RPAR0         BYTE IN TABLE FOR THIS DS            74120018
         CLC   KPRINT(BPRINTL,RWORK),BLANKS  Q. PRINT DESIRED           74160018
         BE    QPRINTOF                 A. NO, TURN PRINT BIT OFF       74200018
         OI    0(RPAR1),X'80'                                           74240018
         B     QPUNCHOF                 TURN OFF PUNCH BIT              74260018
QQPUNCH  EQU   *                                                        74280018
         CLC   KPRINT+KPUNCH(BPUNCHL,RWORK),BLANKS  Q. PUNCH DESIRED    74320018
         BE    QPUNCHOF                 A. NO TURN BIT OFF              74360018
         OI    0(RPAR1),X'40'                                           74400018
         B    QTERM                CHECK NEXT KEY                       74440018
QPRINTOF NI    0(RPAR1),X'7F'      TURN OFF PRINT BIT                   74480018
         B     QQPUNCH             GO CHECK PUNCH BIT                   74520018
QPUNCHOF NI    0(RPAR1),X'BF'      TURN OFF PUNCH BIT                   74560018
QTERM    EQU   *                                                        74600018
         CLC   KPRINT+KPUNCH+KTERM(BTERML,RWORK),BLANKS  Q. TERM HIT    74640018
         BE    NOTERM              GO TURN OFF TERM BIT                 74680018
FAILTERM EQU   *                                                        74920018
         MVC   PHASE(T),ZTERM      A. YES, SET UP ADDR NEXT PHASE       74960018
         B     OUT            OUT                                       75000018
INVALID  EQU   *                                                        75040018
         MVI   MSGNO,MSG06              INVALID ATTENTION               75080018
         B     PUTMSG              RETURN TO MAIN RTN                   75120018
XTAB     LH    RPAR1,BLP                                                75160018
         LA    RPAR1,KEYAREA(RPAR1)                                     75200018
         CH    RPAR1,6(0,RCOM)          Q. ATTN ON THIS KEY             75240018
         BH    INVALID             A. NO                                75280018
         LA    RPAR1,LPTAB(RPAR1)                                       75320018
         CH    RPAR1,6(0,RCOM)          Q. ATTN ON THIS KEY             75360018
         BL    XNEXT               CHECK FOR LP ON SUBSEQUENT KEY       75400018
         LA    RPAR1,ITAB          PICK DISPLACEMENT OF ATTN            75440018
         MVC   INPUTA+ITAB(BTABL),XBLANKS         PUT X AND BLANKS IN D 75480018
         B     LPOUT                    GO SAVE ADDR TO INSERT CURSOR   75520018
XNEXT    EQU   *                        Q. IF ATTN ON KEY               75560018
         LA    RPAR1,LPNEXT(RPAR1) INCREMENT TO DISPL. OF END OF NEXT K 75600018
         CH    RPAR1,6(0,RCOM)          Q. ATTN ON THIS KEY             75640018
         BL    XBACK               CHECK FOR LP ON SUBSEQUENT KEY       75680018
         LA    RPAR1,INEXT                                              75720018
         MVC   INPUTA+INEXT(BNEXTL),XBLANKS       PUT X AND BLANKS IN D 75760018
         B     LPOUT                    GO SAVE ADDR TO INSERT CURSOR   75800018
XBACK    EQU   *                        Q. IF ATTN ON KEY               75840018
         LA    RPAR1,LPBACK(RPAR1) INCREMENT TO DISPL. OF END OF NEXT K 75880018
         CH    RPAR1,6(0,RCOM)          Q. ATTN ON THIS KEY             75920018
         BL    XTOP                CHECK FOR LP ON SUBSEQUENT KEY       75960018
         MVC   INPUTA+IBACK(BBACKL),XBLANKS       PUT X AND BLANKS IN D 76000018
         LA    RPAR1,IBACK                                              76040018
         B     LPOUT                    GO SAVE ADDR TO INSERT CURSOR   76080018
XTOP     EQU   *                        Q. IF ATTN ON KEY               76120018
         LA    RPAR1,LPTOP(RPAR1)  INCREMENT TO DISPL. OF END OF NEXT K 76160018
         CH    RPAR1,6(0,RCOM)          Q. ATTN ON THIS KEY             76200018
         BL    XCYCLE              CHECK FOR LP ON SUBSEQUENT KEY       76240018
         MVC   INPUTA+ITOP(BTOPL),XBLANKS         PUT X AND BLANKS IN D 76280018
         LA    RPAR1,ITOP                                               76320018
         B     LPOUT                    GO SAVE ADDR TO INSERT CURSOR   76360018
XCYCLE   EQU   *                        Q. IF ATTN ON KEY               76400018
         LA    RPAR1,LPCYCLE(RPAR1)                                     76440018
         CH    RPAR1,6(0,RCOM)          Q. ATTN ON THIS KEY             76480018
         BL    XPRINT              CHECK FOR LP ON SUBSEQUENT KEY       76520018
         MVC   INPUTA+ICYCLE(BCYCLEL),XBLANKS     PUT X AND BLANKS IN D 76560018
         LA    RPAR1,ICYCLE                                             76600018
         B     LPOUT                    GO SAVE ADDR TO INSERT CURSOR   76640018
XPRINT   EQU   *                        Q. IF ATTN ON KEY               76680018
         LA    RPAR1,LPPRINT(RPAR1) NCREMENT TO DISPL. OF END OF NEXT K 76720018
         CH    RPAR1,6(0,RCOM)          Q. ATTN ON THIS KEY             76760018
         BL    XPUNCH              CHECK FOR LP ON SUBSEQUENT KEY       76800018
         MVC   INPUTA+IPRINT(BPRINTL),XBLANKS     PUT X AND BLANKS IN D 76840018
         LA    RPAR1,IPRINT                                             76880018
         B     LPOUT                    GO SAVE ADDR TO INSERT CURSOR   76920018
XPUNCH   EQU   *                        Q. IF ATTN ON KEY               76960018
         LA    RPAR1,LPPUNCH(RPAR1) NCREMENT TO DISPL. OF END OF NEXT K 77000018
         CH    RPAR1,6(0,RCOM)          Q. ATTN ON THIS KEY             77040018
         BL    XTERM               CHECK FOR LP ON SUBSEQUENT KEY       77080018
         MVC   INPUTA+IPUNCH(BPUNCHL),XBLANKS     PUT X AND BLANKS IN D 77120018
         LA    RPAR1,IPUNCH                                             77160018
         B     LPOUT                    GO SAVE ADDR TO INSERT CURSOR   77200018
XTERM    EQU   *                        Q. IF ATTN ON KEY               77240018
         LA    RPAR1,LPTERM(RPAR1) INCREMENT TO DISPL. OF END OF NEXT K 77280018
         CH    RPAR1,6(0,RCOM)     Q. ATTN ON KEY AREA                  77320018
         BL    INVALID                                                  77360018
         MVC   INPUTA+ITERM(BTERML),XBLANKS       PUT X AND BLANKS IN D 77400018
         LA    RPAR1,ITERM                                              77440018
LPOUT    EQU   *                                                        77480018
         AH    RPAR1,BLP                                                77520018
         LA    RPAR1,KEYAREA(RPAR1)                                     77560018
         STH   RPAR1,INSCURLP           SAVE ADDR TO INSERT CURSOR      77600018
          B    OUT                                                      77640018
PUTMSG   MVC   PHASE(T),ZBLDISP    ADDR OF PROPREREPRP                  77680018
NOTERM   NI    SWITCH,255-TERMC                                         77720018
OUT      EQU   *                                                        77760018
         STM    14,12,ATTNSAVE+12                                       77800018
*        POST  ECB                                                      77840018
         POST  ECB                                                      77880018
         L     RSAVE,ATTNSAVE+4    PICK UP ADDR OF O/S REGS             77920018
         RETURN (14,12)                                                 77960018
CONVERT  EQU   *                                                        78000018
*                                  RIGHT ADJUST                         78040018
*                                  REPLACE LEADING BLANKS WITH ZEROS    78080018
C2       CLC   0(3,RWORK),BLANKS   Q. 3 LEADING BLANKS                  78120018
         BNE   C3                  A. NO, TEST FOR 2                    78160018
         MVC   0(3,RWORK),ZEROS    A  YES, REPLACE WITH ZEROS           78200018
C3       CLC   0(2,RWORK),BLANKS   Q. 2 LEADING BLANKS                  78240018
         BNE   C4                  A. NO, TEST FOR 1                    78280018
         MVC   0(2,RWORK),ZEROS    A. YES, REPLACE WITH ZEROS           78320018
C4       CLI   0(RWORK),C' '       Q. 1 LEADING BLANK                   78360018
         BNE   C5                  A. NO, TEST FOR ALPHABETIC CHARS     78400018
         MVI   0(RWORK),C'0'       A. YES, REPLACE WITH ZERO            78440018
C5       EQU   *                   REMOVE TRAILING BLANKS BY SHIFTING   78480018
*                                  RIGHT AND PADDING LEFT WITH ZEROS    78520018
         CLI   3(RWORK),C' '       IS THERE A TRAILING BLANK            78560018
         BNE   C6                  NO, GO CONVERT                       78600018
         MVC   3(1,RWORK),2(RWORK) YES,SHIFT RIGHT ONE CHAR             78640018
         MVC   2(1,RWORK),1(RWORK) SHIFT RIGHT ONE PLACE                78680018
         MVC   1(1,RWORK),0(RWORK) SHIFT RIGHT ONE PLACE                78720018
         MVI   0(RWORK),C'0'       PUT ZERO IN FIRST PLACE              78760018
         B     C5                  LOOP                                 78800018
C6       EQU   *                                                        78840018
         TM    0(RWORK),X'F0'      TEST FIRST CHAR                      78880018
         BC    12,ALPHA            BRANCH IF NON-NUMERIC                78920018
         TM    1(RWORK),X'F0'      TEST SECOND CHAR                     78960018
         BC    12,ALPHA            BRANCH IF NON-NUMERIC                79000018
         TM    2(RWORK),X'F0'      TEST THIRD CHAR                      79040018
         BC    12,ALPHA            BRANCH IF NON-NUMERIC                79080018
         TM    3(RWORK),X'F0'      TEST FOURTH CHAR                     79120018
         BC    12,ALPHA            BRANCH IF NON-NUMERIC                79160018
         PACK  DOUBLE+4(4),0(4,RWORK)                                   79200018
*                                  MOVE INTO DOUBLE WORD AREA & PACK    79240018
         CVB     RBR,DOUBLE        CONVERT TO BINARY                    79280018
         ST    RBR,DOUBLE+4                                             79320018
         BR    RPAR1               RETURN CALLER                        79360018
ALPHA    EQU   *                   NON NUMERIC CHAR HAS BEEN FOUND      79400018
         LA    RBR,25              SET DEFAULT FOR NEXT AND BACK        79440018
         O     RBR,HIBIT1          TURN ON HI BIT FOR TAB               79480018
         BR    RPAR1               RETURN                               79520018
         DS    0F                                                       79560018
HIBIT1   DC    XL4'80000000'                                            79600018
NBIT     DC    XL4'7FFFFFFF'                                            79640018
ZEROS    DC    CL4'0000'                                                79840018
ZTERM    DC    V(TERM)                                                  80240018
ZBLDISP  DC    V(BLDDISP)                                               80280018
ZCYCLEP  DC    V(CYCLE)                                                 80320018
ZNEWDISP DC    V(NEWDISP)                                               80360018
ZPOINT   DC    V(POINT)                                                 80400018
ZERR     DC    V(RERR)                  READ ERROR                      80460018
XBLANKS  DC    C'X'                                                     80560018
BLANKS   DC    C'    '                                                  80600018
H3       DC    H'3'                                                     80640018
H25      DC    H'25'                                                    80680018
HEXZEROS DC    XL4'0'                                                   80700018
LGREAD   GREAD XDECB,STR,,LORDER4,,,MF=L                                80720018
LGREADE  EQU   *                                                        80760018
LGDECB   EQU   LGREADE-LGREAD                                           80800018
         SPACE 2                                                        80804020
*********************************************************************** 80808020
*                                                                       80812020
*        MAINTENANCE AREA                                        A33564 80816020
*                                                                       80820020
*********************************************************************** 80824020
PATCH1   DC    15F'0'                                            A33564 80828020
         SPACE 2                                                        80832020
         END                                                            80840018
