PENT     TITLE 'ENTER DATA PROCESSING ROUTINE'                          00100016
         START 0                                                        00200016
*                                                                       00300016
*  MODULE NAME           -PENT                                          00400016
*                                                                       00500016
* CHART ID              -FE                                             00600016
*                                                                       00700016
*  FUNCTION              -CHECK INPUT TO ENTER DATA FRAME FOR CORRECT-  00800016
*                        NESS                                           00900016
*                                                                       01000016
*  ATTRIBUTES            -TRANSIENT,REENTERABLE                         01100016
*                                                                       01200016
*  ENTRY POINTS          -GJP00ECI                                      01300016
*                        -LOADED BY CONTROL ROUTINE                     01400016
*                                                                       01500016
*  OPERATION             -SCAN THE INPUT FOR ERROR CONDITIONS(SEE ERROR 01600016
*                         CONDITIONS FOR DESCRIPTION)                   01700016
*                        -GO TO HISTORY AND DIARY ROUTINE FOR THE FIRST 01800016
*                         RECORD.GO TO DIARY RTN ONLY FOR ADDITIONAL    01900016
*                         RECORDS                                       02000016
*                        -SET SWITCHES IN THE CCT TO INDICATE A JOBLIB  02100016
*                         CARD OR EXEC CARD HAS BEEN ENTERED            02200016
*                        -SET DISPLAY MASK IN CCT TO STOP DISPLAY OF    02300016
*                         LIBRARY AND BACKGROUND PARAMETERS OF SPE      02400016
*                         FRAME IF AN EXEC CARD WAS ENTERED             02500016
*                        -POSITION DELIMITERS IN CCT PROCESSOR WORK     02600016
*                         AREA FOR USE BY JCL GENERATOR                 02700016
*                        -SET RETURN CODES FOR USE BY CONTROL(SEE EXITS 02800016
*                         FOR RETURN CODE LIST                          02900016
*                                                                       03000016
*  EXITS                 -RETURN TO CONTROL                             03100016
*                        -CODES IN REGISTER 15                          03200016
*                        0-NORMAL                                       03300016
*                        4-REDISPLAY ENTER DATA FRAME(4 CARDS ENTERED)  03400016
*                        12-REDISPLAY PREVIOUS SELECT FRAME(EXEC CARD   03500016
*                           IS REQUIRED                                 03600016
*                                                                       03700016
*  INPUT                 -REG 1 CONTAINS ADDRESS OF CCT                 03800016
*                        -CCTPWKA FIELD CONTAINS INPUT FROM  ENTER DATA 03900016
*                         FRAME                                         04000016
*                                                                       04100016
*  OUTPUT                -DELIMITERS ADDED TO DATA IN CCTPWKA FIELD     04200016
*                                                                       04300016
*  EXTERNAL REFERENCES   -JCL GENERATOR                                 04400016
*                        -DIARY RTN                                     04500016
*                        -MSG RTN                                       04600016
*                                                                       04700016
*  ERROR CONDITIONS      -MESSAGES CAUSED BY                            04800016
*                         JOB CARD IN INPUT                             04900016
*                         BLANK INPUT                                   05000016
*                         COMMENT CONTINUATION CARD INDICATED BUT NOT   05100016
*                         SUPPLIED                                      05200016
*                         NO EXEC CARD FOR JOB STEP                     05300016
*                         /* CARD IN INPUT                              05400016
*                         JOBLIB CARD AFTER EXEC CARD                   05500016
*                         MORE THEN ONE JOBLIB CARD PER JOB             05600016
*                         BLANK CARD IN INPUT                           05700016
*                                                                       05800016
*  TABLES AND WORKAREAS  -CONSOLE CONTROL TABLE                         05900016
*                                                                       06000016
*  RESTRICTIONS          -NONE                                          06100016
         EJECT                                                          06200016
* ENT DEFINITION CODES                                                  06300016
*E                                                                      06400016
* BIT 0 ON- CONCATINATION CARD OK FOLLOWING A JOBLIB CARD               06500016
*     1 ON- EXEC CARD REQUIRED-X'40'                                    06600016
*     2 ON- JOBLIB CARD SPECIFIED-X'20'                                 06700016
*     3 ON- JOBLIB CONTINUATION CARD SPECIFIED                          06800016
*     4 ON-                                                             06900016
*     5 ON-                                                             07000016
*     6 ON-                                                             07100016
*     7 ON- JOBLIB DDNAME FOUND-X'01'                                   07200016
* N                                                                     07300016
* NOT USED                                                              07400016
* T                                                                     07500016
* SET TO F WHEN BLANK CARD(S) ENTERED                                   07600016
         EJECT                                                          07700016
         SPACE                                                          07740016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         07780016
         SPACE                                                          07820016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    07860016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     07900016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       07940016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             07980016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  08020016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  08060016
*                   SET.                                                08100016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      08140016
*                   SECOND.                                             08180016
         SPACE 2                                                        08220016
CCT      DSECT                                                          08260016
         SPACE 2                                                        08300016
*                             SECTION ONE                               08340016
         SPACE                                                          08380016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     08420016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    08460016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  08500016
         SPACE                                                          08540016
         DS    0F                                                       08580016
CCTUNAME DS    5F                  USER'S NAME                          08620016
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         08660016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     08700016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       08740016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    08780016
*                                       AT LAST BEGIN JOB               08820016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   08860016
*                                       LAST BEGIN JOB                  08900016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 08940016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    08980016
*                                       JOB                             09020016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    09060016
*                                       JOB                             09100016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     09140016
*                                       CESSOR                          09180016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         09220016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         09260016
CCTJCTR  DS    H                   JOB COUNTER                          09300016
CCTUBPRI DS    H                   PRIORITY SPECIFIED FOR THE JOB  0169 09320018
CCTHIST  DS    109F                HISTORY OF OPERATIONS                09340016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   09380016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  09420016
CCTSSTAT DS    C                   SESSION STATUS                       09460016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              09500016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              09540016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    09580016
         EJECT                                                          09620016
         SPACE 2                                                        09660016
*                             SECTION TWO                               09700016
         SPACE                                                          09740016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   09780016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  09820016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 09860016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              09900016
         SPACE                                                          09940016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     09980016
*                                       FRAME                           10020016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  10060016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     10100016
*                                       MULTIPLE DISPLAY FRAME (ENT)    10140016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   10180016
CCTDISM  DS    C                   DISPLAY MASK                         10220016
CCTCSM   DS    C                   COMMAND SELECT MASK                  10260016
CCTPSTAT DS    CL2                 GJP STATUS                           10300016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              10340016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  10380016
         SPACE 2                                                        10420016
*                             SECTION THREE                             10460016
         SPACE                                                          10500016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    10540016
*                   INTO SECTION ONE OR TWO                             10580016
         SPACE                                                          10620016
CCTDGMP  DS    F                  POINTER TO DGM                        10660016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                10700016
CCTCSTP  DS    F                  POINTER TO CST                        10740016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                10780016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            10820016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 10860016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              10900016
CCTDIARP DS    F                  POINTER TO DIA                        10940016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      10980016
CCTACTP  DS    F                  POINTER TO ACT                        11020016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     11060016
CCTIERRP DS    F                  POINTER TO IERR                       11100016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              11140016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               11180016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                11220016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 11260016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 11300016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   11340016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                11380016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                11420016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               11460016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              11500016
CCTPECB  DS    F                  PROCESSOR'S ECB                       11540016
CCTWECB  DS    F                  WTOR ECB                              11580016
CCTDIAWA DS    CL136               DIARY WORK AREA                      11620016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    11660016
CCTCSAVE DS    CL72                CTL SAVE AREA                        11700016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                11740016
CCTASAVE DS    CL72                DAT SAVE AREA                        11780016
*                                                                       11820016
IKACCT   EQU   CCT                                                      11860016
         EJECT                                                          12300016
IKAPENT0 CSECT                                                          12400016
*0298,197100,204000,243100,457000                                  PJKK 12450018
*0298,406000,410000,432000,438500                                  0169 12470018
*3283,418200                                                       4218 12480018
* 210300,418100,421600                                           A33618 12485000
*                                                                       12490000
*********************************************************************** 12495000
RPAR0    EQU   0                        PARAMETER REG                   12500016
RPAR1    EQU   1                        PARAMETER REG                   12600016
RSUM     EQU   1                                                        12700016
RINCR    EQU   2                                                        12800016
RCODES   EQU   2                        MSG CODE REGISTER               12900016
RCOMP    EQU   3                                                        13000016
RLENGTH  EQU   4                                                        13100016
RCOUNT   EQU   5                                                        13200016
RCHECK   EQU   6                                                        13300016
RSCAN    EQU   7                                                        13400016
RHOLD    EQU   8                                                        13500016
RMSG     EQU   9                                                        13600016
RCARDCNT EQU   10                       NO OF CARDS IN INPUT            13700016
RBASE    EQU   11                       BASE REG FOR PGM                13800016
RCCT     EQU   12                       CCT DSECT BASE                  13900016
RSAVE    EQU   13                       SAVE REG                        14000016
RRET     EQU   14                       RETURN REG                      14100016
RBR      EQU   15                       BRANCH AND RETURN CODE REG      14200016
         EJECT                                                          14300016
ATTNSW   EQU   X'DF'                                                    14400016
BACKGRND EQU   X'80'                                                    14500016
BLANK    EQU   X'40'                                                    14600016
BLANKOFF EQU   X'F7'                                                    14700016
BLANKSW  EQU   X'08'                                                    14800016
CANCEL   EQU   X'08'                    CANCEL POST CODE                14900016
CONCOFF  EQU   X'7F'                    CONCATINATION SW OFF            15000016
CONCSW   EQU   X'80'                    CONCATINATION SW ON             15100016
CONTOFF  EQU   X'EF'                   CONTINUATION SW OFF              15200016
CONTSW   EQU   X'10'                    CONTINUATION SW ON              15300016
DELIM    EQU   X'26'                    RECORD DELIMITER                15400016
EIGHTY   EQU   X'50'                    80                              15500016
END      EQU   X'04'                    END POST CODE                   15600016
ENDSTREM EQU   X'37'                    END OF INPUT STREAM             15700016
EXEC     EQU   X'40'                    EXEC CARD REQUIRED              15800016
EXECOFF  EQU   X'BF'                    TURN OFF EXEC SW IN CCTPWKA     15900016
EXECSW   EQU   EXEC                     EXEC CARD REQUIRED              16000016
F        EQU   X'C6'                    F                               16100016
FOUREQ   EQU   X'04'                                                    16200016
JOBLIB   EQU   X'20'                                                    16300016
JOBLIBSW EQU   JOBLIB                   JOBLIB CARD ENTERED             16400016
LIBDD    EQU   X'01'                    JOBLIB DDNAME FOUND             16500016
LIBDDSW  EQU   X'FE'                    TURN OFF JOBLIB DDNAME FOUND    16600016
LIBRARY  EQU   X'20'                                                    16700016
LNG      EQU   X'0F'                    LENGTH OF 15                    16800016
MDATAON  EQU   X'01'                    MORE DATA SWT ON         A33618 16830000
MDATAOFF EQU   X'FE'                    MORE DATA SWT OFF        A33618 16860000
N        EQU   X'D5'                    N                               16900016
ONE      EQU   X'01'                    ONE                             17000016
QUIT     EQU   X'1C'                    QUIT POST CODE             PJKK 17050018
TWO      EQU   X'02'                                                    17100016
WORKLNTH EQU   326                     326&1 IS LAST POSITION(CCTPWKA)  17200016
ZERO     EQU   X'00'                                                    17300016
         EJECT                                                          17400016
*                   START PROGRAM                                       17500016
*                                                                       17600016
*                   SAVE REGS AND ESTABLISH BASE                        17700016
         SAVE  (14,12)                  SAVE REGISTERS                  17800016
         BALR  RBASE,0                  ESTABLISH PROGRAM BASE          17900016
         USING *,RBASE                                                  18000016
         USING IKACCT,RCCT             CCT ADDRESSABILITY               18100016
         LR    RCCT,RPAR1               ADDRESS OF CCT                  18200016
         LA    RPAR1,CCTPSAVE           ADDRESS OF SAVE AREA            18300016
         ST    RPAR1,8(RSAVE)           PNTR IN OLD TO NEW SAVE AREA    18400016
         ST    RSAVE,CCTPSAVE+4         PNTR IN NEW TO OLD SAVE AREA    18500016
         LR    RSAVE,RPAR1              POINT 13 TO NEW SAVE AREA       18600016
*                                                                       18700016
*   WAIT UNTIL POSTED BY DAT (USER PERFORMS END OR CANCEL FUNCTION)     18800016
*                                                                       18900016
WAITPONT WAIT  ECB=CCTPECB              WAIT FOR ATTENTION              19000016
         MVI   CCTPECB,ZERO             CLEAR FIRST BYTE IN ECB         19100016
         CLI   CCTPECB+3,END         Q.USER PERFORMED END FUNCTION      19200016
         BE    SCAN                     YES,CHECK WORK AREA IN CCT      19300016
         CLI   CCTPECB+3,QUIT         Q. IS POST CODE QUIT         PJKK 19330018
         BE    CUTOUT                 A. YES                       PJKK 19360018
         CLI   CCTPECB+3,CANCEL      Q.USER PERFORMED CANCEL FUNCTION   19400016
         BNE   ERRMSG                   NO,PUT OUT ERROR MSG(POST NG)   19500016
         LH    RBR,TWELVE              CODE FOR PREVIOUS CST            19600016
         B     OUTHERE                                                  19700016
*                                                                  PJKK 19702018
CUTOUT   L     RBR,QUITCODE             CODE TO QUIT               PJKK 19704018
         B     OUTHERE                                             PJKK 19706018
ERRMSG   EQU   *                                                   PJKK 19713018
         MVC   CCTPWKA+332(3),IMSG29    MOVE MSG.NUMBER INTO LIST       19720016
         MVC   CCTPWKA+335(5),MODIDEN        MODULE IDENTIFIER          19730016
         MVC   CCTPWKA+340(4),ZEROS          ZEROES TO ADDR.OF INSERT   19740016
         OI    CCTPWKA+340,X'80'        SET CONTROL BIT TO RETURN       19750016
         LR    RPAR1,RCCT               CCT POINTER                     19760016
         LA    RPAR0,CCTPWKA+332        PARAMETER LIST POINTER          19770016
         L     RBR,CCTIERRP             LOAD POINTER TO IERR.ROUTINE    19780016
         BALR  RRET,RBR                 BRANCH TO IT                    19790016
*                                                                       19800016
* MESSAGE READS: IKA029I IKAPENT0 - IKADAT - BAD POST CODE              19810016
*                                                                       19820016
         B     OUTHERE                                                  19900016
*   SET RETURN CODE  FOR CTL 0-NORMAL(NEXT CST)                         20000016
*                            4-REPEAT(SAME PST)                         20100016
*                           12-CANCEL(SAME CST)                         20200016
*                           20-EXEC.CARD REQ.(SAME CST)                 20250016
*                          IC-QUIT                                 PJKK 20270018
*                                                                       20300016
BACK     EQU   *                                                   PJKK 20340018
         CL    RBR,QUITCODE           Q. IS CODE QUIT              PJKK 20380018
         BE    OUTHERE                A. YES                       PJKK 20420018
         SR    RBR,RBR                  ZERO RETURN REGISTER       PJKK 20460018
EXECHECK TM    CCTPSTAT,EXEC         Q.EXEC CARD REQUIRED               20500016
         BZ    CARDCHK                 NO                               20600016
CANCELA  LA    RBR,20                  A. YES,RETURN CODE IS 20         20700016
CARDCHK  CLC   CCTPWKA+350(2),TWOBLNKS Q.MORE DATA TO FOLLOW            20800016
         BE    OUTHERE                  NO                              20900016
         LH    RBR,FOUR                 YES,RETURN CODE IS 4            21000016
         OI    CCTPSTAT,MDATAON         TURN ON MORE DATA BIT    A33618 21030000
*                                       IN CCT                     4218 21060018
OUTHERE  NI    CCTPSTAT+1,ATTNSW        ALLOW ATTANTIONS TO BE RECEIVED 21100016
         NI    CCTPSTAT,BLANKOFF        TURN OFF BLANK CARD OK SW       21200016
         MVC   CCTDIAWA(1),TWOBLNKS     BLANK OUT AREA USED FOR MSG.    21230016
         MVC   CCTDIAWA+1(130),CCTDIAWA                                 21260016
         L     RSAVE,CCTPSAVE+4         RESTORE PNTR TO OLD SAVE AREA   21300016
         RETURN (14,12),RC=(15)         RETURN TO CONTROL(CTL)          21400016
         EJECT                                                          21500016
*                                                                       21600016
* DETERMINE NUMBER OR CARDS ENTERED USING A BACKWARD SCAN               21700016
*                                                                       21800016
* REGISTER USE                                                          21900016
* RSUM    1    SUM REGISTER        INITIALIZED TO 1                     22000016
* RINCR   2    INCREMENT REGISTER  INITIALIZED TO 1                     22100016
* RCOMP   3    COMPARAND REGISTER  MAX SCAN LENGTH                      22200016
* RLNGTH  4    LENGTH OF CARD IMAGE(81)                                 22300016
* RCOUNT  5    NUMBER OF CARDS ENTERED (MAX IS FOUR)                    22400016
* RCHECK  6    ADDRESS OF WORKAREA TO BE COMPARED                       22500016
*                                                                       22600016
*                                                                       22700016
*                                                                       22800016
*                                                                       22900016
*                                                                       23000016
SCAN     EQU   *                                                        23100016
         CLC   CCTPWKA+350(2),TWOBLNKS Q.MORE DATA TO FOLLOW            23200016
         BE    SCANA                  NO                                23300016
         B     HAVECRD                                                  23400016
SCANA    LM    RSUM,RCOUNT,LIST    SET REGISTERS                        23500016
         LA    RCHECK,CCTPWKA+WORKLNTH       FIRST POSITION TO SCAN     23600016
SCANB    CLI   0(RCHECK),BLANK             Q.POSITION BLANK             23700016
         BNE   CHECKCDS                      NO,GO TO MAIN ROUTINE      23800016
         BCT   RLENGTH,CHECKSUM         BRANCH IF NOT ZERO              23900016
         SH    RCOUNT,ONEH              DECREMENT CARD COUNT            24000016
         L     RLENGTH,CARDLNGH         INIT CARD LENGTH                24100016
CHECKSUM BXH   RSUM,RINCR,CHECKCDS           BRANCH IF NO CARDS         24200016
         BCT   RCHECK,SCANB                  NEXT POSITION TO CHECK     24300016
         MVC   CCTPWKA+332(3),IMSG07    MOVE MSG.NUMBER INTO LIST       24320016
         MVC   CCTPWKA+335(5),MODIDEN        MODULE IDENTIFIER          24330016
         MVC   CCTPWKA+340(4),ZEROS          ZEROES TO ADDR.OF INSERT   24340016
         OI    CCTPWKA+340,X'80'        SET CONTROL BIT TO RETURN       24350016
         LR    RPAR1,RCCT               CCT POINTER                     24360016
         LA    RPAR0,CCTPWKA+332        PARAMETER LIST POINTER          24370016
         L     RBR,CCTIERRP             LOAD POINTER TO IERR.ROUTINE    24380016
         BALR  RRET,RBR                 BRANCH TO IT                    24390016
*                                                                       24400016
* MESSAGE READS: IKA007I IKAPENT0 - OF UNKNOWN ORIGIN                   24410016
*                                                                       24420016
         B     OUTHERE                                                  24500016
         EJECT                                                          24600016
*                                                                       24700016
* DETERMINE IF ANY CARDS IN INPUT ARE INCORRECT                         24800016
*                                                                       24900016
CHECKCDS LTR   RCARDCNT,RCOUNT          NUMBER OF INPUT CARDS           25000016
         BP    HAVECARD                 INPUT NOT BLANK                 25100016
HAVECRD  EQU   *                                                        25200016
         LH    RCARDCNT,FOUR            DUMMY FOUR BLANK CARDS          25300016
         LR    RCOUNT,RCARDCNT          INITIALIZE COUNT                25400016
HAVECARD EQU   *                                                        25500016
*                                                                       25600016
* PREPARE FOR SCAN ON PROCESSOR WORK AREA                               25700016
*                                                                       25800016
*                                                                       25900016
         LA    RCHECK,CCTPWKA+3         FIRST SCAN POSITION             26000016
         MVI   CCTPWKA,ZERO             ZERO OUT E POSITION IN WORK ARE 26100016
         TM    CCTPSTAT,EXEC          Q.IS AN EXEC CARD REQUIRED        26200016
         BZ    CHECKLIB                NO                               26300016
         OI    CCTPWKA,EXECSW          YES,TURN ON EXEC CARD REQ        26400016
CHECKLIB TM    CCTPSTAT,JOBLIB        Q.JOBLIB CARD SPECIFIED           26500016
         BZ    CHKJCL                   NO                              26600016
         OI    CCTPWKA,JOBLIBSW         YES,INDICATE JOBLIB ENTERRED    26700016
CHKJCL   CLI   CCTPWKA+2,F            Q.BLANK CARD ENTERED              26800016
         BE    BLANKCHK                 YES,CHECK FOR OTHER BLANKS      26900016
         CLC   0(2,RCHECK),SLASHES    Q.IS THIS A // CARD               27000016
         BE    JCLCARD                  YES                             27100016
         TM    CCTPWKA,EXECSW         Q.IS AN EXEC CARD REQUIRED        27200016
         BZ    JCLSLAS                 NO                               27300016
EXECMSG  LH    RCODES,CODE3             LOAD MESSAGE CODE               27400016
         B     OTHERIN                                                  27500016
         EJECT                                                          27600016
JCLSLAS  CLC   0(2,RCHECK),SLASHAST   Q.IS THIS A /* CARD               27700016
         BNE   BLANKCHK                 NO,CHECK FOR BLANKS             27800016
         LH    RCODES,CODE4             YES,PUT OUT MESSAGE             27900016
         B     OTHERIN                                                  28000016
JCLCARD  LA    RSCAN,TWO(RCHECK)        POSITION TO SCAN                28100016
         LH    RLENGTH,CARDSIZE         LENGTH OF UNSCANNED CARD        28200016
BLNKLOOK CLI   0(RSCAN),BLANK         Q.POSITION AFTER // BLANK         28300016
         BNE   NOTBLANK                 NO,CHECK DDNAME                 28340016
         MVI   CCTPWKA+1,F              YES,MOVE IN CODE FOR NULL CHECK 28380016
         B     CHKOPRND                 NOW IS IF REST OF CARD BLANK    28420016
NOTBLANK EQU   *                                                        28460016
         CLC   0(7,RSCAN),JOBLIBCN    Q.IS THIS A JOBLIB CARD           28500016
         BNE   FINDEND                  NO                              28600016
         OI    CCTPWKA,LIBDD            TURN ON JOBLIB DDNAME FOUND     28700016
FINDEND  CLI   0(RSCAN),BLANK         Q.IS POSITION BLANK               28800016
         BE    CHKOPRND                 YES                             28900016
         LA    RSCAN,ONE(RSCAN)         NO,BUMP CHARACTER               29000016
         BCT   RLENGTH,FINDEND          BRANCH IF MORE TO SCAN          29100016
FINDEXEC TM    CCTPWKA,EXECSW         Q.IS EXEC CARD REQUIRED           29200016
         BO    EXECMSG                 YES                              29300016
         CLI   CCTPWKA+1,N           Q.IS THIS A NULL DELIMETER CARD    29310016
         BE    NOTNULL                  NO,CARD IS OKAY                 29320016
         LH    RCODES,CODE9             PUT OUT MSG FOR NULL CARD       29330016
         B     OTHERIN                  GO TO MSG ROUTINE               29340016
NOTNULL  EQU   *                                                        29350016
         NI    CCTPWKA,LIBDDSW         NO,TURN OFF JOBLIB DDNAME SW     29400016
         B     NEXTCARD                                                 29500016
         EJECT                                                          29600016
BLANKCHK LA    RSCAN,0(RCHECK)          POSITION TO SCAN                29700016
         LH    RLENGTH,EIGHTYH          CARD LENGTH                     29800016
BLNKLOOP CLI   0(RSCAN),BLANK         Q.IS POSITION BLANK               29900016
         BNE   NEXTCARD                 NO,CARD OK                      30000016
         LA    RSCAN,1(RSCAN)           BUMP ADDRESS                    30100016
         BCT   RLENGTH,BLNKLOOP         BRANCH IF MORE TO SCAN          30200016
         TM    CCTPSTAT,BLANKSW       Q.IS A BLANK CARD OK              30300016
         BO    NEXTCARD                 YES                             30400016
         CLI   CCTPWKA+2,F            Q.BLANK CARD PREVIOUSLY ENTERED   30500016
         BE    MOREBLNK                 YES,SKIP WORK AREA INIT         30600016
         MVI   CCTPWKA+2,F              NO,SET BLANK CARD SWITCH        30700016
         LA    RCOMP,CCTDIAWA           USE RECORD WORK AREA FOR MSG    30800016
MOREBLNK LR    RCODES,RCHECK            START POSITION OF THIS RECORD   30900016
         LA    RLENGTH,CCTPWKA          START OF WORK AREA              31000016
         SR    RCODES,RLENGTH           RELATIVE DISP OF RECORD MINUS 1 31100016
         ST    RCODES,0(RCOMP)          PUT INTO PARAMETER LIST         31200016
         LA    RCOMP,FOUREQ(RCOMP)      NEXT POSITION IN LIST           31300016
         B     NEXTCARD                 PROCESS NEXT CARD               31400016
         EJECT                                                          31500016
CHKOPRND CLI   0(RSCAN),BLANK         Q.IS POSITION BLANK               31600016
         BNE   OPRNDISO                 NO                              31700016
         LA    RSCAN,ONE(RSCAN)         YES,BUMP TO NEXT POSITION       31800016
         BCT   RLENGTH,CHKOPRND         BRANCH IF MORE TO SCAN          31900016
         CLI   CCTPWKA+1,N            Q.IS THIS A NULL DELIMITER CARD   31930016
         BNE   FINDEXEC                YES, SEE IF EXEC CARD ENTERED    31960016
         NI    CCTPWKA,CONTOFF          TURN OFF CONTINUATION SW        31990016
         NI    CCTPWKA,CONCOFF         TURN OFF CONCATINATION SW        32020016
         B     FINDEXEC                 SEE IF EXEC REQUIRED            32050016
OPRNDISO MVI   CCTPWKA+1,N              TURN OFF NULL CARD SW           32100016
         TM    CCTPWKA,CONTSW         Q.CONTINUATION CARD SW ON         32150016
         BZ    OPRNDIS                  NO,CHECK OPERAND                32200016
         CLI   71(RCHECK),BLANK       Q.THIS CARD INDICATE CONTINUATION 32300016
         BNE   NEXTCARD                 YES,LEAVE CONTINUATION SW ON    32400016
SWOFF    NI    CCTPWKA,CONTOFF          NO,TURN CONTINUATION SW OFF     32500016
         B     CONCON                   TURN CONCATINATION OK SW ON     32600016
OPRNDIS  CH    RLENGTH,FOURTEEN       Q.ROOM FOR JOB,EXEC OR DD         33100016
         BL    LESS14                   NO                              33200016
         CLC   0(4,RSCAN),JOBCON      Q. IS OPERAND JOB                 33230016
         BE    JOBERR                 A. YES                            33260016
         CLC   0(5,RSCAN),EXECON      Q.    IS OPERAND EXEC             33300016
         BNE   ISDD                     NO                              33400016
         NI    CCTPWKA,EXECOFF          YES,TURN OFF EXEC CARD REQ      33500016
         B     NEXTCARD                                                 33600016
ISDD     CLC   0(3,RSCAN),DDCON       Q.IS OPERAND DD                   33700016
         BNE   OLDEXEC                  NO                              33800016
         TM    CCTPWKA,CONCSW         Q.IS THIS A DD CONCATINATION      33900016
         BZ    CHKDDNME                 NO                              34000016
         CLI   71(RCHECK),BLANK       Q.IS THIS CONC CARD INDICATE CONT 34100016
         BE    NEXTCARD                 NO,LEAVE CONCATINATION SW ON    34200016
         OI    CCTPWKA,CONTSW           YES,TURN ON CONTINUATION SW     34300016
NEXTCHK  B     NEXTCARD                                                 34400016
CHKDDNME EQU   *                                                        34500016
         TM    CCTPWKA,LIBDD          Q.DDNAME WAS JOBLIB               34600016
         BZ    OLDEXEC                  NO                              34700016
         TM    CCTPWKA,JOBLIBSW       Q.JOBLIB CARD ENTERED             34800016
         BZ    TESTEXEC                 NO                              34900016
         LH    RCODES,CODE5             YES,PUT OUT MESSAGE             35000016
         B     OTHERIN                                                  35100016
TESTEXEC EQU   *                                                        35200016
         TM    CCTPWKA,EXECSW         Q.WAS AN EXEC CARD ENTERED        35300016
         BZ    LIBMSG                   YES                             35400016
EXECENT  EQU   *                                                        35500016
         OI    CCTPWKA,JOBLIBSW         NO,TURN ON JOBLIB SW            35600016
         CLI   71(RCHECK),BLANK       Q.THIS CARD INDICATE CONTINUATION 35700016
         BE    CONCON                   NO,INDICATE CONCATINATION OK    35800016
         OI    CCTPWKA,CONTSW           YES,TURN ON SWITCH              35900016
         B     NEXTCARD                                                 36000016
CONCON   OI    CCTPWKA,CONCSW           TURN ON CONCATINATION OK SWITCH 36100016
         B     NEXTCARD                                                 36200016
         EJECT                                                          36300016
LIBMSG   LH    RCODES,CODE6                                             36400016
         B     OTHERIN                                                  36500016
OLDEXEC  EQU   *                                                        36600016
         NI    CCTPWKA,CONCOFF          TURN OFF CONCATINATION OK SW    36700016
         TM    CCTPWKA,EXECSW         Q.EXEC CARD REQUIRED              36800016
         BO    EXECMSG                 YES                              36900016
JOBCHK   CH    RLENGTH,TWELVE         Q.ROOM FOR JOB OPERAND            37000016
         BL    NEXTCARD                 NO,CHECK NEXT CARD              37100016
         CLC   0(4,RSCAN),JOBCON      Q.IS OPERAND JOB                  37200016
         BNE   NEXTCARD                 NO,CHECK NEXT CARD              37300016
JOBERR   LH    RCODES,CODE7             YES,PUT OUT MESSAGE             37400016
         B     OTHERIN                                                  37500016
LESS14   CH    RLENGTH,THIRTEEN       Q.ROOM FOR JOB AND DD OPERATION   37600016
         BL    LESS13                   NO                              37700016
         B     ISDD                     YES                             37800016
LESS13   CH    RLENGTH,TWELVE         Q.ROOM FOR DD OPERATION           37900016
         BL    ISDD                     YES                             38000016
         B     OLDEXEC                                                  38100016
NEXTCARD NI    CCTPWKA,LIBDDSW          TURN OFF JOBLIB DDNAME FOUND SW 38200016
         A     RCHECK,CARDLNGH          UPDATE ADDRESS                  38300016
         BCT   RCOUNT,CHKJCLO           BRANCH IF MORE INPUT TO CHECK   38400016
         CLI   CCTPWKA+2,F            Q.BLANK CARD ENTERED              38500016
         BNE   CONTIN                   NO,SEE IF LAST CARD WAS A CONT. 38600016
         LH    RCODES,CODE8             YES,SET UP MESSAGE              38700016
         OI    CCTPSTAT,BLANKSW         TURN ON BLANKS ENTERED SW       38800016
         B     OTHERIN                  GO TO MESSAGE                   38900016
CHKJCLO  TM    CCTPWKA,CONTSW         Q.WAS A CONTINUATION CARD INDIC.  39000016
         BZ    CONCAT                   NO                              39100016
         CLC   0(15,RCHECK),BLANK16    YES, IS NEXT CARD PROPER         39200016
         BNE   MSGILL                  NO,PUT OUT MESSAGE               39300016
         CLI   15(RCHECK),BLANK         SOMETHING IN COL 16             39400016
         BNE   CHKJCL                  YES,CARD OKAY                    39500016
MSGILL   EQU   *                                                        39600016
         LH    RCODES,CODE2             NO,LOAD MESSAGE CODE            39700016
         B     OTHERIN                  GO TO MESSAGE ROUTINE           39800016
CONCAT   TM    CCTPWKA,CONCSW         Q.CAN CARD BE CONCATINATION TYPE  39900016
         BZ    CHKJCL                   NO                              40000016
         CLC   0(3,RCHECK),BLANK16    Q.CARD LOOKS OK FOR CONCATINATION 40100016
         BE    CHKJCL                   YES,DO FURTHER CHECK            40200016
         NI    CCTPWKA,CONCOFF          NO,TURN OFF SWITCH              40300016
         B     CHKJCL                                                   40400016
CONTIN   TM    CCTPWKA,CONTSW         Q.LAST CARD A CONTINUATION CARD   40500016
         BZ    CHECKPIB                 NO, TEST IF BACKGROUND     0169 40600018
         S     RCHECK,CARDLNGH         REPOSITION SCAN POINTER          40700016
         LH    RCODES,CODE1             YES,PUT OUT MESSAGE             40800016
         B     OTHERIN                                                  40900016
CHECKPIB TM    CCTSSTAT,32              Q. REMOTE GRAPHIC DEVICE   0169 40910018
         BZ    HISTORY                  NO, LOCAL GRAPHIC DEVICE   0169 40920018
         CLI   CCTPWKA+340,BLANK        Q. PROCESS IN BACKGROUND   0169 40930018
         BE    HISTORY                  NO                         0169 40940018
         TM    CCTPSTAT,X'80'           Q. JOB CARD GENERATED      0169 40950018
         BO    PIBOK                    NO, OPTION IS VALID        0169 40960018
         TM    CCTPSTAT,X'10'           Q. BACKGROUND JOB          0169 40970018
         BO    PIBOK                    YES, OPTION IS VALID       0169 40980018
***  PUT OUT ERROR MESSAGE                                         0169 40990018
PIBOK    EQU   *                                                   0169 41000018
         MVC   CCTUBPRI(2),CCTBRPRI     GET BACKGROUND PRIORITY    0169 41010018
         OI    CCTPSTAT,X'10'           INDICATE BACKGROUND JOB    0169 41020018
         B     HISTORY                  TO WRITE HISTORY RECORD    0169 41030018
         EJECT                                                          41040018
* PREPARE FOR  HISTORY AND RECORD ROUTINE                               41100016
*                                                                       41200016
HISTORY  EQU   *                                                        41300016
         GETMAIN R,LV=352               GET CORE TO MOVE IN CCTWORKAREA 41308016
         LR    RMSG,RPAR1                                               41316016
         USING DUMMYWK,RMSG                                             41324016
         MVC   DUMWK(200),CCTPWKA       MOVE IN WORKAREA                41332016
         MVC   DUMWK+200(152),CCTPWKA+200                               41340016
         MVI   CCTPWKA+84,BLANK                                         41348016
         MVC   CCTPWKA+85(200),CCTPWKA+84  CLEAR ALL BUT FIRST CARD     41356016
         MVC   CCTPWKA+285(45),CCTPWKA+84  OF CCT WORKAREA              41364016
         MVI   CCTPWKA+84,ENDSTREM      MOVE IN DELIMETER               41372016
         LA     RHOLD,DUMWK             SET UP COUNTER                  41380016
         LA    RHOLD,84(RHOLD)                                          41388016
         LR    RCOUNT,RCARDCNT          RESTORE CARD COUNT              41400016
         LA    RCHECK,CCTPWKA+3         FIRST RECORD TO BE MOVED        41500016
CHECKNXT LR    RPAR1,RCCT               CCT ADDRESS                     41600016
         O     RPAR1,RECORDBF          NO SEQ NO BIT ON(BIT 1)          41700016
         CLI   DUMWK+1,N              Q. IS THIS FIRST TIME TO RECORD   41760016
         BNE   UPDTEHSN                 A. NO, INCREMENT HSN       4218 41770018
         TM    CCTSSTAT,X'20'         Q. IS SGJP IN CONTROL        4218 41780018
         BO    TURNBIT                  A. YES, DO NOT INCREMENT   4218 41790018
*                                               HSN                4218 41800018
         TM    CCTPSTAT,MDATAON      Q. IS MORE DATA BIT ON      A33618 41810000
         BZ    TURNBIT                  A. NO, DO NOT INCREMENT    4218 41820018
*                                              HSN                 4218 41830018
         TM    CCTPSTAT+1,X'02'       Q. IS RECALL IN CONTROL      4218 41840018
         BO    TURNBIT                  A. YES, DO NOT INCREMENT   4218 41850018
*                                               HSN                4218 41860018
UPDTEHSN EQU   *                                                   4218 41870018
         L     RPAR1,CCTHSN             LOAD HISTORY SEQUENCE NUMBER    41880016
         LA    RPAR1,1(RPAR1)           INCREMENT                       41940016
         STH   RPAR1,CCTHSN+2           STORE BACK NEW HSN              42000016
TURNBIT  LR    RPAR1,RCCT               TURN BIT 1 OFF                  42060016
         MVI   DUMWK+1,F                TURN ON FIRST RECORD SWITCH     42120016
         NI    CCTPSTAT,MDATAOFF        TURN OFF MORE DATA BIT   A33618 42160000
         MVC   CCTDIAWA(LNG),HISTCON    MOVE HISTORY FORMAT TO RECORD   42200016
SKIPHIST MVC   CCTDIAWA+LNG(EIGHTY),0(RCHECK) MOVE RECORD               42300016
         MVI   EIGHTY(RCHECK),DELIM     MOVE IN RECORD DELIMITER        42400016
         L     RBR,CCTDIARP             ADDRESS OF RECORD ROUTINE       42500016
         BALR  RRET,RBR                 GO TO RECORD                    42600016
*                                       BACK FROM RECORD ROUTINE   PJKK 42650018
         CL    RBR,QUITCODE           Q. IS RETURN CODE QUIT       PJKK 42700018
         BE    FREE                   A. YES                       PJKK 42750018
         TM    DUMWK,EXECSW            Q. WAS AN EXECUTE CARD DEFINED   42800016
         BO    JOBLIBTS                 NO,CHECK FOR JOBLIB             43100016
         NI    CCTPSTAT,EXECOFF         TURN OFF EXEC REQ SWITCH        43300016
JOBLIBTS TM    DUMWK,JOBLIBSW          Q. WAS A JOBLIB CARD ENTERED     43400016
         BZ    TOJCL                    NO,GET READY TO RETURN          43500016
         OI    CCTPSTAT,JOBLIBSW        TURN ON JOBLIB CARD ENTERED     43700016
TOJCL    MVC   CCTPWKA(3),ENT           RESTORE CODE                    43800016
         OI    CCTDISM,LIBRARY+BACKGRND TURN ON NO DISPLAY BITS    0169 43830018
GOTOJCL  L     RBR,CCTJCLGP             ADDRESS OF JCL GENERATOR        43870016
         LR    RPAR1,RCCT               POINTER TO CCT                  43890016
         BALR  RRET,RBR                                                 43910016
*                                       BACK FROM JCL GENERATOR         43930016
         CL    RBR,QUITCODE           Q. IS RETURN CODE QUIT       PJKK 43932018
         BE    FREE                   A. YES                       PJKK 43934018
         TM    DUMWK,EXECSW           Q. WAS AN EXEC. CARD ENTERED      43938016
         BO    TESTEND                A. NO                             43946016
         MVI   CCTCSM,X'26'           A. YES - SET CCTCSM               43954016
TESTEND  CLI   0(RHOLD),ENDSTREM      Q. IS IT END OF INPUT             43962016
         BE    FREE                    A. YES                           43970016
         MVC   CCTPWKA+3(81),0(RHOLD)   MOVE NEXT CARD                  43990016
         LA    RHOLD,81(RHOLD)          BUMP TO NEXT CARD               44010016
         MVI   CCTPWKA+84,ENDSTREM      MOVE IN DELIMETER               44030016
         BCT   RCOUNT,CHECKNXT          CHECK NEXT REC.                 44050016
*                                                                       44070016
FREE     LR    RPAR1,RMSG               LOAD ADDRESS OF DUMMYWK         44090016
         FREEMAIN R,LV=352,A=(1)                                        44110016
         B     BACK                     GO TO ROUTINE HANDLING RETURN   44130016
         EJECT                                                          44200016
*                                                                       44300016
* MESSAGE ROUTINE                                                       44400016
*                                                                       44500016
* REGISTER USE                                                          44600016
*                                                                       44700016
* RCODES   2   DISPLECEMENT FOR CODETBL                                 44800016
*              ADDRESS OF PROC WORK AREA END                            44900016
* RCOMP    3   POINTER TO MSG ADDRESS                                   45000016
*                                                                       45100016
* RLENGTH  4   ADDRESS IN PROC WORK AREA OF NEXT MESSAGE                45200016
* RCOUNT   5   NUMBER OF MESSAGE LINES                                  45300016
* RMSG     9   POSITION IN PROC WORK AREA                               45400016
* RSCAN    7   MSG ADDRESS                                              45500016
OTHERIN  EQU   *                                                        45600016
         TM    CCTPSTAT,X'04'         Q. ARE WE IN RECALL ACCEPT   PJKK 45620018
         BZ    CONTMES                A. NO                        PJKK 45640018
         L     RBR,HEX18                GIVE ERROR CODE TO RECALL  PJKK 45660018
         B     OUTHERE                  RETURN                     PJKK 45680018
CONTMES  CLI   CCTPWKA+2,F            Q. BLANK CARDS ENTERED       PJKK 45740018
         BNE   NOBLANK                  NO,FIND DISPLACEMENT            45800016
         LR    RMSG,RCOMP               POSITION IN RECORD WORK AREA    45900016
         B     ENTRYBLK                                                 46000016
NOBLANK  EQU   *                                                        46100016
         LA    RMSG,CCTDIAWA            START OF WORK AREA              46200016
         LA    RCOMP,CCTPWKA                                            46300016
         SR    RCHECK,RCOMP             START OF CURRENT EXTRACT RCD    46400016
         ST    RCHECK,0(RMSG)           INTENSIFICATION ENTRY           46500016
         LA    RMSG,FOUREQ(RMSG)        NEXT POSITION IN WORK AREA      46600016
ENTRYBLK EQU *                                                          46700016
         L     RSCAN,PENTMV             MESSAGE MODULE ADDRESS          46800016
         L     RCOMP,0(RCODES,RSCAN)    ADDRESS OF MESSAGE LIST         46900016
         L     RCOUNT,0(RCOMP)          MESSAGESIZE                     47000016
         EX    RCOUNT,MOVEMSG           MOVE PARAMETER LIST             47100016
         LR    RPAR1,RCCT               ADDRESS OF THE CCT              47200016
         LA    RPAR0,CCTDIAWA           ADDRESS OF PARAMETER LIST       47300016
         L     RBR,CCTDMRP              ADDRESS OF DISPLAY MESSAGE RTN  47400016
         BALR  RRET,RBR                 GO TO DISPLAY MESSAGE RTN       47500016
         NI    CCTPSTAT+1,ATTNSW        ALLOW ATTANTIONS TO BE RECEIVED 47600016
         B     WAITPONT                 WAIT FOR ATTENTION              47700016
MOVEMSG  MVC   0(1,RMSG),FOUREQ(RCOMP)  MOVE PARAMETER LIST             47800016
         EJECT                                                          47900016
BLANK16  DC    CL15'//             '    CONTINUATION OR CONCATINATION   48000016
DDCON    DC    C'DD '                                                   48100016
ENT      DC    C'ENT'                                                   48200016
EXECON   DC    C'EXEC '                                                 48300016
HISTCON  DC    C'     DATA      '      HISTORY FORMAT                   48400016
JOBLIBCN DC    C'JOBLIB '                                               48500016
JOBCON   DC    C'JOB '                                                  48600016
SLASHES  DC    C'//'                                                    48700016
SLASHAST DC    C'/*'                                                    48800016
ZEROS    DC    F'0'                                                     48820016
MODIDEN  DC    C'PENT0'                                                 48840016
IMSG07   DC    C'007'                                                   48860016
IMSG29   DC    C'029'                                                   48880016
         DS    0F                                                  PJKK 48885018
HEX18    DC    X'00000018'              ERROR INDICATOR FOR RECALL PJKK 48890018
QUITCODE DC    X'0000001C'              RETURN CODE - QUIT         PJKK 48895018
         EJECT                                                          48900016
         DS    0H                                                       49000016
ONEH     DC    X'0001'                                                  49100016
CARDSIZE DC    X'004E'                  78                              49200016
CODE1    DC    X'0000'                  CONTINUATION BETWEEN FRAME NG   49300016
CODE2    DC    X'0004'                  CONTINUATION FORMAL INCORRECT   49400016
CODE3    DC    X'0008'                  EXEC CARD REQUIRED              49500016
CODE4    DC    X'000C'                  /* CARD                         49600016
CODE5    DC    X'0010'                  JOBLIB PREVIOUSLY ENTERED       49700016
CODE6    DC    X'0014'                  JOBLIB MUST BE BEFORE EXEC      49800016
CODE7    DC    X'0018'                  JOB CARD NG                     49900016
CODE8    DC    X'001C'                  BLANK CARD                      50000016
CODE9    DC    X'0020'                  NULL CARD ILLEGAL               50050016
EIGHTYH  DC    X'0050'                                                  50100016
FOUR     DC    X'0004'                  RETURN CODE-REPEAT              50200016
FOURTEEN DC    X'000E'                                                  50300016
THIRTEEN DC    X'000D'                                                  50400016
TWELVE   DC    X'000C'                  RETURN CODE CANCEL              50500016
TWOBLNKS DC    X'4040'                 CHECK FOR MORE DATA FOLLOWS      50600016
         EJECT                                                          50700016
LIST     DS    0F                                                       50800016
         DC    X'00000001'         *                   * DO             50900016
         DC    X'00000001'         *                   *   NOT          51000016
         DC    X'00000144'         *    DECIMAL 324    *      BREAK     51100016
CARDLNGH DC    X'00000051'         *    DECIMAL 81     *           UP   51200016
FOURF    DC    X'00000004'              *                 * THIS        51300016
RECORDBF DC    X'40000000'             NO SEQ NUMBER BIT ON FOR DIA     51400016
PENTMV   DC    V(IKAMENT0)             MESSAGE MODULE                   51500016
* *                                                                     51510016
         SPACE 2                                                        51511000
*********************************************************************** 51512000
*                                                                       51513000
*        MAINTENANCE AREA                                        A33564 51514000
*                                                                       51515000
*********************************************************************** 51516000
PATCH    DC    18F'0'                                            A33564 51517000
         SPACE 2                                                        51518000
DUMMYWK  DSECT                                                          51520016
         DS    0F                                                       51530016
DUMWK    DS    XL352                    AREA TO SAVE CCTPWKA (FROM HERE 51540016
*                                       THE CARDS ARE MOVED-ONE AT A    51550016
*                                       TIME-BACK TO THE FIRST CARDPOSI 51560016
*                                       TION OF THE CCTPWKA,A X26 + X37 51570016
*                                       FOLLOWING IT)                   51580016
* *                                                                     51590016
         END                                                            51600016
