         TITLE 'IKAPLOG0 PROCESSOR FOR IKAGJP'                          00300016
*                                                                       00600016
*                                                                       00900016
*                             LOG OFF ROUTINE                           01200016
*                                                                       01500016
* ROUTINE NAME       IKAPLOG                                            01800016
*                                                                       02100016
* CHART ID          FO                                                  02400016
*                                                                       02700016
*  FUNCTION:        PROCESS LOGOFF OPERATIONS                           03000016
*                                                                       03300016
*  ATTRIBUTES:      TRANSIENT,REENTERABLE                               03600016
*                                                                       03900016
*  ENTRY POINTS:    ENTERED VIA LINK FROM CTL                           04200016
*                                                                       04500016
*  OPERATION       -PASS PARAMETER TO USER'S ACCOUNTING ROUTINE.        04800016
*                   THROUGH THE PARAMETER, USER AND THE ACCOUNTING      05100016
*                   ROUTINE MAY COMMUNITE EACH OTHER                    05400016
*                  -DISPLAY LOGOFF FRAME FOR USER'S ACKNOWLEDGE, AND    05700016
*                   HANDLES USER'S INPUT DATA                           06000016
*                  -IF RECORD OPTION NOT TAKEN,LOGOFF RELEASE WORKAREA  06300016
*                   PASSES PARAMETER TO SVC ROUTINE, INFORMING THAT     06600016
*                   IT IS LOGOFF TIME, AND TRANSFER CONTROL TO          06900016
*                   SCHEDULER INTERFACE ROUTINE (IKASCH)                07200016
*                  -IF RECORD OPTION IS TAKEN, INADDITION TO THE ABOVE  07500016
*                   FUNCTION, LOGOFF CREATE SYSOUT DCB, AND THE DIARY   07800016
*                   DATA SET IS COPIED ONTO THE SYSOUT DATA SET.        08100016
*                                                                       08400016
*                                                                       09600016
*  EXISTS:          XCTL TO SCH                                         09900016
*                                                                       10200016
*  INPUT:           DATA IN CONSOLE CONTROL TABLE                       10500016
*                                                                       10560016
*                   REGISTER 1 POINTING TO CONSOLE CONTROL TABLE        10620016
*                                                                       10680016
*                   REGISTER 13 POINTING TO A REGISTER SAVE AREA        10740016
*                                                                       10800016
*  OUTPUT:          SYSOUT DATA SET (IF RECORD OPTION HAS BEEN CHOSEN)  11100016
*                                                                       11400016
*  EXTERNAL REFERENCES: USER'S ACCOUNTING ROUTINE                       11700016
*                                                                       12000016
*  ERROR CONDITIONS                                                     12300016
*                                                                       12600016
*  TABLES AND WORKAREA: CONSOLE CONTROL TABLE                           12900016
*                                                                       13200016
*  RESTRICTION:                                                         13500016
*                                                                       13800016
*                                                                       14100016
*                                                                       14400016
*  SPECIFICATION FOR USER'S ACCOUNTING ROUTINE: THE USER'S ACCOUNTING   14700016
*                   ROUTINE IS LINK EDITED WITH LOG OFF PROCESSOR. THE  15000016
*                   ENTRY POINT OF YOUR ACCOUNTING ROUTINE MUST BE      15300016
*                   NAMED IKAACCTG AND MUST BE REENTERABLE              15600016
*                                                                       15900016
*  INPUT TO THE ACCOUNTING ROUTINE: THE HIGH ORDER BIT OF REGISTER 1    16200016
*                   SHOULD BE ONE WHEN ENTERED FROM LOG OFF. THE        16500016
*                   REGISTER 1 CONTAINS THE STARTING ADDRESS OF A LIST  16800016
*                   OF POINTERS TO ACCOUNTING INFORMATION               17100016
         EJECT                                                          17400016
*  PARAMETER LIST TO ACCOUNTING ROUTINE                                 17700016
*                                                                       18000016
*                                                                       18200016
*  '*****************************************************************'  18400016
*  'DISPLACEMENT'                  CONTENT                           '  18600016
*  '************'****************************************************'  18800016
*  '     0      ' ONE BYTE CODE IN HEXDICIMAL                        '  19000016
*  '************'****************************************************'  19200016
*  '     1      ' THREE BYTES WHICH CONTAIN 2250 UNIT ADDRESS      0170 19260017
*  '************'**************************************************0170 19320017
*  '     4      ' FOUR BYTE POINTER TO A 20-BYTE FIELD WHERE USER'S0170 19420017
*  '            ' NAME IS CONTAINED                                  '  19600016
*  '************'****************************************************'  19800016
*  '     8      ' FOUR BYTE POINTER TO A 20-BYTE FIELD WHERE USER'S0170 20000017
*  '            ' ACCOUNT NUMBER IS CONTAINED                        '  20200016
*  '************'****************************************************'  20400016
*  '     12     ' FOUR BYTE POINTER TO A 20-BYTE FIELD WHERE USER'S0170 20420017
*  '            ' OTHER DATA IS CONTAINED                          0170 20440017
*  '************'**************************************************0170 20460017
*  '     16     ' FOUR BYTE POINTER TO A 20-BYTE FIELD WHERE USER'S0170 20480017
*  '            ' ACCOUNTING DATA IS CONTAINED                     0170 20500017
*  '************'**************************************************0170 20520017
*  '     20     ' FOUR BYTE POINTER TO A 72-BYTE FIELD WHERE USER'S0170 20620017
*  '            ' MESSAGE MAY CONTAINED                              '  20800016
*  '************'****************************************************'  21000016
*  '     24     ' FOUR BYTE POINTER TO A 72-BYTE FIELD WHERE USER'S0170 21200017
*  '            ' ACCOUNTING ROUTINE MAY PLACE MESSAGE               '  21400016
*  '************'****************************************************'  21600016
*                                                                       21800016
*  DEFINE OF CODE :  X'00'  FIRST TIME ENTERING ACCOUNTING ROUTINE      22000016
*                    X'04'  USER CANCEL LOGOFF SELECTION                22200016
*                    X'08'  USER HAS MESSAGE TO ACCOUNTING ROUTINE      22400016
*                                                                       22800016
         EJECT                                                          23100016
IKAPLOG0 CSECT                                                          23400016
*2452,194000,200000,206000,212000,331000,332000,333500,580450      0170 23430017
*     668000                                                       0170 23460017
*1100,326000                                                     PDUM   23500017
RPAR0    EQU   0                   PARAMETER REGISTER                   23700016
RPAR1    EQU   1                   PARAMETER REGISTER                   24000016
RCCT     EQU   2                   CCT ADDRESS REGISTER                 24300016
RWORK    EQU   3                   GENERAL PURPOSE REGISTER             24600016
RRECADDR EQU   4                   RECORD DCB ADDRESS                   24900016
RPTR     EQU   5                                                        25200016
R6       EQU   6                                                        25300016
RINRETN  EQU   7                       INTERNAL RETURN REGISTER         25360016
RPTR1    EQU   6                                                        25390016
RCOUNTER EQU   8                       COUNTER                          25420016
RDSECT   EQU   10                  DESECT DISPLACEMEN                   25500016
RBASE    EQU   11                  BASE REGISTER                        25800016
RSAVE    EQU   13                  SAVE REGISTER                        26100016
RRET     EQU   14                  RETURN REGISTER                      26400016
RBR      EQU   15                  BRANCH REGISTER                      26700016
*                                                                       26770016
OPENOK   EQU   X'10'                   MASK TO TEST OPEN DCB            26780016
EODADDR  EQU   33                  RELATIVE ADDR OF END OF DATA ROUTINE 26840016
*                                  IN DCB                               26910016
LOGINPUT EQU   100                      LOGOFF INPUT MAPPING            26950016
*                                                                       27000016
* HOUSE KEEPING WORK                                                    27300016
*                                                                       27600016
         SAVE  (14,12)             SAVE GENERAL REGISTERS               27900016
         BALR  RBASE,0             SETUP BASE REGISTER                  28200016
         USING *,RBASE                                                  28500016
         LR    RCCT,RPAR1          LOAD CCT ADDRESS                     28800016
         USING CCT,RCCT                                                 29100016
*                                                                       29400016
* GETMAIN FOR IKAACCTG SYSOUT DCB L-FORM FOR READ WRITE AND OPEN        29700016
*                                                                       30000016
         GETMAIN R,LV=ENDDSECT-WORKAREA                                 30300016
         LR    RDSECT,RPAR1        LOAD GETMAIN ADDRESS                 30600016
         USING WORKAREA,RDSECT     SET UP ACCOUNTING WORKAREA BASE      30900016
         ST    RSAVE,CCTPSAVE+4    SAVE CALLING PROGRAM SAVE ADDRESS    31200016
         LA    RWORK,CCTPSAVE      LOAD OUR SAVE ADDRESS AND            31500016
         ST    RWORK,8(0,RSAVE)    GIVE TO CALLING PROGRAM              31800016
         LR    RSAVE,RWORK         POINTER TO OUR SAVE AREA             32100016
         LOAD  EP=IKATLOG0             LOAD LOGOFF TABLE                32150016
         ST    0,CCTCPSTP              STORE IN CCT                     32200016
         SR    RCOUNTER,RCOUNTER       CLEAR COOUNTER                   32250016
         LR    RPAR1,RCCT               CCT ADDRESS                     32300016
         L     RBR,CCTDGMP              DGM ADDRESS                     32350016
         XC    UMSGAREA(72),UMSGAREA   CLEAR USER MSG AREA              32400016
         BALR  RRET,RBR                 BRANCH TO DGM ROUTINE           32450016
         B     APARM                    GO TO APARM                     32500016
         DC    X'4000'                  GENERATE BUT NOT DISPLAY        32550016
APARM    EQU   *                                                   PDUM 32560017
         CH    15,CODE1C               Q. INTERNAL ERROR HAPPENED  PDUM 32570017
         BE    RETURNIR                 BRANCH IF YES              PDUM 32580017
         MVI   LOGCODE,X'00'            CODE FOR FIRST TIME ENTER  PDUM 32590017
*                                       ACCOUNTING ROUTINE         PDUM 32600017
*                                       GO TO USER ACCTING ROUTINE      32650016
         BAL   RINRETN,LKACCTG          BRANCH TO ACCTG                 32700016
         B     TESTCODE                 BRANCH                          32750016
LKACCTG  EQU   *                                                        32800016
         XC    MSGAREA(72),MSGAREA      CLEAR ACCOUNTING MSG AREA       32850016
         MVC   LOGUNIT(3),CCTUNIT      MOVE UNIT ADDR TO PARM LIST 0170 32870017
         LA    RWORK,CCTUNAME           USER NAME ADDRESS               32900016
         ST    RWORK,LOGNAME            PUT IN PAR-LIST                 32950016
         LA    RWORK,CCTUACCT           USER ACCOUNT NUMBER ADDRESS     33000016
         ST    RWORK,LOGACCT            PUT IN PAR-LIST                 33050016
         LA    RWORK,CCTUARD           ADDR OF USER ACCT DATA      0170 33060017
         ST    RWORK,LOGACDAT          STORE IN PARM LIST          0170 33070017
         LA    RWORK,CCTUOTHR          ADDR OF USER OTHER DATA     0170 33080017
         ST    RWORK,LOGOTHR           STORE IN PARM LIST          0170 33090017
         LA    RWORK,MSGAREA           ACCOUNTING RTN MSG AREA     0170 33120017
         ST    RWORK,LOGUMSG            POINTER TO USER MSG AREA        33150016
         LA    RWORK,UMSGAREA          USER MESSAGE AREA           0170 33200017
         ST    RWORK,LOGMSG             POINTER TO ACCOUNTING MSG AREA  33250016
         LA    RPAR1,LOGCODE            ACCOUNTING PARAMETER LIST ADDR  33300016
         L     RBR,VACCTG               ACCOUNTING ROUTINE ADDRESS      33400016
         BALR  RRET,RBR                 BRANCH TO ACCOUNTING ROUTINE    33450016
         BR    RINRETN                  RETURN TO CALL                  33500016
TESTCODE EQU   *                                                        33550016
         SR    RWORK,RWORK              ZERO REGISTER                   33600016
         CR    RBR,RWORK               Q. ACCOUNTING RTN HAVE MESSAGE   33650016
         BE    MOVEAMSG                 BRANCH IF YES                   33700016
         LA    RWORK,4                  CODE 4 WITHOUT MESSGE           33750016
         CR    RBR,RWORK               Q. NO MESSAGE DISPLAY LOGOFF     33800016
         BE    DLOGOFF                  BRANCH IF YES                   33850016
         LA    RPAR0,IERRPAR            PARAMETER                       33870016
IERRRN   LR    RPAR1,RCCT               CCT ADDR                        33890016
         L     15,CCTIERRP              IERR ADDR                       33910016
         BALR  RRET,RBR                  GO TO IERR                     33930016
RETURNIR EQU   *                                                   PDUM 33940017
         DELETE EP=IKATLOG0            DELETE LOGOFF TABLE         PDUM 33950017
         B     FREEMAIN                 PREPARE TO RETURN               33970016
DLOGOFF  EQU   *                                                        34000016
         LR    RPAR1,RCCT               CCT ADDRESS                     34050016
         L     RBR,CCTDGMP              DGM ADDRESS                     34100016
         BALR  RRET,RBR                 DISPLAY LOG OFF                 34150016
         B     WAITECB                  GO TO WAIT                      34200016
         DC    X'C000'                  GENERATE AND DISPLAY            34250016
WAITECB  EQU   *                                                        34300016
         CH    15,CODE1C               Q. INTERNAL ERROR HAPPENED  PDUM 34310017
         BE    RETURNIR                 BRANCH IF YES              PDUM 34320017
         WAIT  ECB=CCTPECB              WAIT                            34400016
         TM    CCTPECB+3,X'1C'         Q. INTERNAL ERROR HAPPENED  PDUM 34408017
         BO    RETURNIR                 BRANCH IF YES              PDUM 34416017
         MVI   CCTPECB,X'00'           CLEAR ECB                   PDUM 34424017
         TM    CCTPECB+3,X'0C'         Q. END + CANCEL             PDUM 34432017
         BC    1,POSTER                ERROR IF YES                PDUM 34440017
         TM    CCTPECB+3,X'08'         Q. IS CANCEL                     34450016
         BC    1,CANCEL                 BRANCH IF YES                   34500016
         TM    CCTPECB+3,X'04'         Q. END                           34550016
         BC    1,END                    BRANCH IF YES                   34600016
POSTER   EQU   *                                                   PDUM 34610017
         LA    RPAR0,MSG29              PARAMETER ADDR                  34630016
         B     IERRRN                   BRANCH                          34660016
CANCEL   EQU   *                                                        34750016
         MVI   LOGCODE,X'04'            SET CANCEL CODE                 34800016
         BAL   RINRETN,LKACCTG          GO TO USER ACCOUNTING ROUTINE   34850016
         DELETE EP=IKATLOG0            DELETE LOGOFF TABLE         PDUM 34860017
         FREEMAIN R,LV=ENDDSECT-WORKAREA,A=(10)                    PDUM 34870017
         LA    RBR,12                   CODE FOR DISPLAY LAST SELECT    34900016
*                                       FRAME                           34950016
         LR    RPAR1,RCCT               CCT ADDRESS                     35000016
         L     RSAVE,CCTPSAVE+4         RSTORE REGISTER                 35050016
         RETURN (14,12),RC=(15)         RETURN TO CTL                   35100016
END      EQU   *                                                        35150016
         LA    RCOUNTER,1(RCOUNTER)    UPDATE COUNTER                   35200016
         MVI   LOGCODE,X'08'            CODE USER HAS MSG TO ACCTG      35250016
         LA    RWORK,CCTPWKA+LOGINPUT   INPUT ADDRESS                   35300016
         CLI   0(RWORK),X'40'          Q. A BLANK IN USER MSG AREA      35350016
         BNE   MOVEUMSG                 BRANCH IF NO                    35400016
         CLC   0(36,RWORK),36(RWORK)   Q. ANY THING THERE               35450016
         BE    NORMAL                   BRANCH IF NO                    35500016
MOVEUMSG EQU   *                                                        35550016
         C     RCOUNTER,ONE            FIRST TIME ENTER DATA            35600016
         BE    MOVE                    BRANCH IF YES                    35650016
         CLC   SAVEMSG(72),0(RWORK)    COMPARE MESSAGE                  35700016
         BE    NORMAL                  BRANCH IF YES                    35750016
MOVE     EQU   *                                                        35800016
         MVC   SAVEMSG(72),0(RWORK)    SAVE INPUT                       35850016
         MVC   UMSGAREA(72),0(RWORK)   MOVE USER'S MSG IN PAR-LIST      35900016
         BAL   RINRETN,LKACCTG          GO TO ACCOUNTING ROUTINE        35950016
         LA    RWORK,0                 LOAD A CODE                      36000016
         CR    RBR,RWORK              Q.ACCOUNTING HAS MSG              36050016
         BE    MOVEAMSG                 BRANCH IF YES                   36100016
         LA    RWORK,4                 LOAD A CODE                      36150016
         CR    RBR,RWORK               Q. NO MSG                        36200016
         BE    NORMAL                   BRANCH IF YES                   36250016
         LA    RPAR0,IERRPAR           PARAMETER ADDRESS                36280016
         B     IERRRN                   BRANCH                          36310016
MOVEAMSG EQU   *                                                        36350016
         MVC   CCTPWKA+8(20),CTITLE     MOVE ACCOUNTING MESSAGE TITLE   36400016
         LA    RWORK,CCTPWKA+8          * POINTER TO THIS MESSAGE       36450016
         ST    RWORK,CCTPWKA            *                               36500016
         MVI   CCTPWKA,X'40'            SET OPTION BYTE                 36550016
         MVC   CCTPWKA+30(72),MSGAREA     MOVE IN ACCOUNTING MSG        36600016
         MVI   CCTPWKA+29,X'48'           SET LENGTH                    36650016
         LA    RWORK,CCTPWKA+29         * POINTER TO THIS MESSAGE       36700016
         ST    RWORK,CCTPWKA+4          *                               36750016
         MVI   CCTPWKA+4,X'C0'          OPTION CODE - LAST ENTRY        36800016
         LA    0,CCTPWKA               PARAMETER LIST                   36850016
         LR    RPAR1,RCCT               CCT ADDRESS                     36900016
         L     RBR,CCTDMRP              DMSG ADDR                       36950016
         OI    CCTPSTAT+1,X'20'         IGNORE ATTENTION                37000016
         BALR  RRET,RBR                 DISPLAY ACCOUNTING MSG          37050016
         NI    CCTPSTAT+1,X'DF'         ATTENTION SWITCH                37100016
         B     WAITECB                  GO TO WAIT                      37150016
NORMAL   EQU   *                                                        37200016
         DELETE EP=IKATLOG0            DELETE LOGOFF TABLE              37250016
         MVC   CCTPWKA(14),MSG50        MESSAGE NUMBER                  37300016
         LA    RWORK,CCTPWKA+12         ADDRESS FOR INSERT DATA         37350016
         ST    RWORK,CCTPWKA+8          *                               37400016
         MVI   CCTPWKA+8,X'C0'          CONTROL BITS                    37450016
         MVC   CCTPWKA+14(3),CCTUNIT    UNIT NUMBER                     37500016
         LA    RPAR0,CCTPWKA            MESSAGE PARAMETER               37550016
         LR    RPAR1,RCCT               CCT ADDRESS                     37600016
         L     RBR,CCTIERRP            IERR ADDRESS                     37650016
         BALR  RRET,RBR                 BRANCH TO IERR                  37700016
         CH    15,CODE1C               Q. INTERNAL ERROR HAPPENED  PDUM 37710017
         BE    FREEMAIN                 BRANCH IF YES              PDUM 37720017
         LA    RWORK,CCTDIAWA           DIARY WORKAREA ADDRESS     PDUM 37730017
         MVC   5(6,RWORK),LOGOFF       PROCESSOR,S NAME            PDUM 37740017
         MVC   15(20,RWORK),CCTUNAME   USER'S NAME                 PDUM 37750017
         L     RBR,CCTDIARP             DIARY ROUTINE ADDRESS      PDUM 37760017
         LR    RPAR1,RCCT               CCT ADDRESS                PDUM 37770017
         BALR  RRET,RBR                 GO TO DIARY PROCESSOR      PDUM 37780017
         EJECT                                                          37800016
*                                                                       38100016
* MOVE SYSOUT DCB AND L-FORM MACROS IN GETMAIN AREA FOR REENTERABLE     38400016
*                                                                       38700016
         TM    CCTSSTAT,X'80'      RECORD OPTION                        39000016
         BC    8,FREEMAIN          NO GO FREEMAIN                       39300016
*                   MOVE DCB AND L FORMS TO GETMAIN AREA                39600016
*                                                                       39900016
         MVC   DCBSOUT(LSYSOUT),SYOUTDCB     MOVE SYSOUT DCB TO GETMAIN 40200016
*                                                                       40500016
         MVC   READ(LREAD),FREAD        MOVE READ TO GETMAIN            40800016
*                                                                       41100016
         MVC   WRITE(LWRITE),FWRITE     MOVE WRITE TO GETMAIN           41400016
*                                                                       41700016
         MVC   OPEN(4),OPENSOUT         MOVE OPEN TO GETMAIN            42000016
*                                                                       42300016
         MVC   CLOSE(4),CLOSEOUT        MOVE CLOSE TO GETMAIN           42600016
*                                                                       42900016
         L     R6,CCTRDCBP                                              43200016
         CLOSE ((R6),),MF=(E,CLOSE)                                     43500016
         L     R6,CCTRDCBP              GET ADDR OF DIARY DCB           43800016
         OPEN  ((R6),(INOUT)),MF=(E,OPEN)                               44100016
         L     R6,CCTRDCBP             DIARY DCB ADDRESS                44140016
         USING IHADCB,6                                                 44180016
         TM    DCBOFLGS,OPENOK         Q. OPEN OK                       44220016
         LA    RPAR0,IRRPARM           IERRPARM-LIST ADDRESS            44260016
         BZ    IOERROR                 BRANCH IF NO                     44300016
         DROP  6                                                        44340016
*                                                                       44400016
*                     OPEN SYSOUT DCB                                   44700016
*                                                                       45000016
         OPEN  (DCBSOUT,(OUTPUT)),MF=(E,OPEN)                           45300016
         LA    6,DCBSOUT               SYSOUT DCB ADDRESS               45340016
         USING IHADCB,6                                                 45380016
         TM    DCBOFLGS,OPENOK         Q. OPEN SUCCESSFUL               45420016
         LA    RPAR0,IRRPARM1          IERR PARM-LIST ADDRESS           45460016
         BZ    IOERROR                 BRANCH IF NO                     45500016
         DROP  6                                                        45540016
*                                                                       45600016
         L     RPTR,CCTRDCBP          LOAD RECORD DCB ADDRESS AND       46800016
         ST    RPTR,DCBADDR        STORE IN READ FIELD                  47100016
         LA    RWORK,FCLOSE              * MOVE END OF DATA SET         47170016
         ST    RWORK,CCTPWKA             * HANDLING ROUTINE ADDRESS     47240016
         MVC   EODADDR(3,RPTR),CCTPWKA+1 * IN DIARY DCB                 47310016
         LA    RPTR,CCTPWKA       LOAD PROCESSOR'S WORK AREA            47400016
         ST    RPTR,AREAADDR       STORE IN READ AREA                   47700016
         LA    RPTR,DCBSOUT        LOAD SYSOUT DCB ADDRESS              48000016
         ST    RPTR,WDCBADDR       STORE IN WRITE FIELD                 48300016
         LA    RPTR,PRECORD             S                               48360016
         LA    RCOUNTER,5               RECORDS NUMBER                  48420016
         LA    RPTR1,RECORD             START ADDRESS OF MOVE FROM      48480016
MOVERD   MVC   0(120,RPTR),0(RPTR1)     MOVE ONE RECORD                 48540016
         LA    RPTR,120(RPTR)           * UPDATE POINTERS               48600016
         LA    RPTR1,120(RPTR1)        *                                48660016
         BCT   RCOUNTER,MOVERD          FINISH MOVE RECORDS             48720016
         LA    RPTR,PRECORD             RECORD ADDRESS                  48780016
         MVC   175(3,RPTR),CCTUNIT      MOVE IN UNIT ADDRESS            48840016
         ST    RPTR,WAREADDR       STORE IN WRITE FIELD                 48900016
         SR    RCOUNTER,RCOUNTER        SETUP COUNTER                   48920016
WRITE1   WRITE WECBLOCK,SF,MF=E         WRITE                           48940016
         CHECK WRITE                    CHECK                           48960016
         LA    RCOUNTER,1(RCOUNTER)     UPDATE COUNTER                  48980016
         C     RCOUNTER,FIVE            FIVE RECORD                     49000016
         BE    WSYSOUT                 BRANCH IF EQUAL                  49020016
         LA    RPTR,120(RPTR)          UPDATE RECORD                    49040016
         ST    RPTR,WAREADDR           WRITE FIELD                      49060016
         B     WRITE1                  BRANCH                           49080016
WSYSOUT  EQU   *                                                        49100016
         LA    RPTR,CCTPWKA             DIARY RECORD ADDRESS            49120016
         ST    RPTR,WAREADDR            STORE IN WRITE FIELD            49140016
*                                                                       49200016
* READ AND WRITE FUNCTION                                               49500016
*                                                                       49800016
FREADEFM READ  ECTBLOCK,SF,MF=E                                         50100016
         CHECK READ                CHECK READ                           50400016
         WRITE WECBLOCK,SF,MF=E                                         50700016
         CHECK WRITE               CHECK WRITE                          51000016
         B     FREADEFM                                                 51300016
*                                                                       52800016
* CLOSE RECORD AND SYSOUT DCB IN MF=E                                   53100016
*                                                                       53400016
FCLOSE   EQU   *                                                        53500016
         LA    1,DCBSOUT               SYSOUT DCB ADDRESS               53600016
         ST    1,CLOSE                 STORE IT IN PARAMETER LIST       53700016
         MVI   CLOSE,X'80'             SET OPTION BITS                  53800016
         LA    1,CLOSE                 GET PARAMETER ADDRESS            53900016
         CLOSE ,MF=(E,(1))         CLOSE SYSOUT DCB                     54000016
FREEMAIN FREEMAIN R,LV=ENDDSECT-WORKAREA,A=(10)                         54300016
*                                                                       54310016
* INFORM GFX IT IS LOGOFF                                               54320016
*                                                                       54330016
         MVC   CCTPWKA(LISTLTH),SVCPARM MOVE PARM LIST IN WORKAREA      54340016
         MVC   CCTPWKA+5(3),CCTUNIT    2250 ADDRESS                     54350016
         LR    RPAR1,RCCT               SET CCT ADDRESS                 54360016
         LA    RPAR0,CCTPWKA            LOAD PARAMETER LIST ADDRESS     54370016
         SVC   80                      ISSUE SVC                        54380016
         L     RSAVE,CCTPSAVE+4        RELOAD CALLING SAVE ADDRESS      54400016
         LR    RPAR1,RCCT          LOAD CCT ADDRESS                     54600016
         O     RPAR1,HBITONE            HIGH ORDER BIT ON INDICATE      54700016
*                                       LOGOFF TIME                     54800016
         XCTL  (2,12),EP=IKASCH                                         54900016
IOERROR  EQU   *                                                        54950016
         LR    RPAR1,RCCT              CCT ADDRESS                      55000016
         L     RBR,CCTIERRP            IKAIERR ADDRESS                  55050016
         BALR  RRET,RBR                BRANCH TO IERR                   55100016
         B     FCLOSE                  BRANCH                           55150016
FWTO     EQU   *                                                        55230016
         LA    RPAR0,MSG62             PARAMETER ADDRESS                55310016
         B     IERRRN                   BRANCH                          55390016
         EJECT                                                          55500016
*                                                                       55800016
*                                                                       56100016
* CONSTANTS, READ, WRITE, OPEN IN MF=L FORM                             56400016
*                                                                       56700016
*                                                                       57000016
         DS    0F                                                       57300016
HBITONE  DC    X'80000000'                                              57600016
*                                                                       57603016
MSG50    EQU   *                                                        57606016
         DC    CL3'050'                MSG NO                           57609016
         DC    CL5'PLOG0'              MODULE NAME                      57612016
         DC    X'C0'                   INSERT AND RETURN                57615016
         DC    CL3'0'                                                   57618016
         DC    H'5'                    DATA LENGTH                      57621016
SVCPARM  EQU   *                        *                               57630016
PARMCODE DC    C'PLOG'                  *SVC PARAMETER LIST             57660016
UNIT2250 DC    F'0'                     *                               57690016
SVCPARME EQU   *                        *                               57720016
*                                                                       57750016
LISTLTH  EQU   SVCPARME-SVCPARM         *SVC PARAMETER LIST LENGTH      57780016
CTITLE   DC    AL1(19)                                                  57785016
         DC    C'ACCOUNTING MESSAGE:'                                   57790016
ONE      DC    F'1'                                                     57795016
TWO      DC    H'2'                    A NUMBER                         57805016
CODE1C   DC    H'28'                    INTERNAL ERROR CODE        PDUM 57810017
FIVE     DC    F'5'                                                     57815016
LOGOFF   DC    C'LOGOFF'               CONSTANT                    PDUM 57820017
*                                                                       57825016
* RECORDS FOR DIARY DATA SET                                            57835016
*                                                                       57845016
RECORD   EQU   *                                                        57855016
RECORD1  DC    CL50'**************************************************' 57865016
         DC    CL20'********************'                               57875016
         DC    CL50' '                                                  57885016
RECORD2  DC    CL50'**    PRINTED RECORD OF SESSION AT CONSOLE       '  57895016
         DC    CL20'UNIT=             **'                               57905016
         DC    CL50' '                                                  57915016
RECORD3  DC    CL50'**************************************************' 57925016
         DC    CL20'********************'                               57935016
         DC    CL50' '                                                  57945016
R4AND5   DC    CL240' '                                                 57955016
RECORDE  EQU   *                                                        57960016
PARLTH   DC    A(ENDPAR-BEGPAR)                                         57965016
*                                                                       57975016
* PARAMETER LIST FOR INTERNAL ERROR ROUTINE                             57985016
*                                                                       57995016
         DS    0F                                                       58005016
IERRPAR  DC    C'023'                   MESSAGE NUMBER                  58015016
         DC    C'PLOG0'                 MODULE NAME                     58025016
         DC    X'80'                    RETURN                          58035016
         DC    X'000000'                                           0170 58115017
*                                                                       58200016
MSG29    DC    CL3'029'                 MESSAGE NUMBER                  58220016
         DC    CL5'PLOG0'               MODULE KEY WORD                 58240016
         DC    XL4'80000000'             RETURN                         58260016
*                                                                       58280016
MSG62    DC    CL3'062'                MESSAGE NUMBER                   58300016
         DC    CL5'PLOG0'               MODULE'S KEY WORD               58320016
         DC    X'C0'                    RETURN + INSERT                 58340016
         DC    AL3(INDATA)             INSERT DATA ADDRESS              58360016
*                                                                       58380016
INDATA   DC    H'6'                     DATA LENGTH                     58400016
         DC    C' OUT'                 INSERT DATA                      58420016
*                                                                       58440016
FREAD    READ  DECBR,SF,,,120,MF=L                                      58500016
FREADE   EQU   *                                                        58800016
FWRITE   WRITE DECBW,SF,,,120,MF=L                                      59100016
FWRITEE  EQU   *                                                        59400016
VACCTG   DC    V(IKAACCTG)                                              59700016
LREAD    EQU   FREADE-FREAD        LENGTH READ EXPANSION                60000016
LWRITE   EQU   FWRITEE-FWRITE      LENGTH OF WRITE EXPANSION            60300016
*                                                                       60600016
* OPEN AND CLOSE SYSOUT DCB IN MF=L                                     60900016
*                                                                       61200016
OPENSOUT OPEN  (SYOUTDCB,(OUTPUT)),MF=L                                 61500016
CLOSEOUT CLOSE (SYOUTDCB),MF=L                                          61800016
IRRPARM  EQU   *                                                        61810016
MSGNO    DC    CL3'056'                MESSAGE NUMBER                   61820016
         DC    CL5'PLOG0'              MODULE NAME                      61830016
         DC    X'C0'                   CONTROL BITS                     61840016
         DC    AL3(DCBMSG)             ADDR OF INSERT DATA              61850016
*                                                                       61860016
DCBMSG   EQU   *                                                        61870016
         DC    H'6'                    LENGTH                           61880016
         DC    C' DIA'                 DATA TO INSERTED                 61890016
IRRPARM1 EQU   *                                                        61900016
         DC    CL3'056'                MESSAGE NUMBER                   61910016
         DC    CL5'PLOG0'              MODULE NAME                      61920016
         DC    X'C0'                   CONTROL BITS                     61930016
         DC    AL3(DCBMSG1)            ADDR OF INSERT DATA              61940016
*                                                                       61950016
DCBMSG1  EQU   *                                                        61960016
         DC    H'6'                    LENGTH                           61970016
         DC    C' OUT'                                                  61980016
         SPACE 2                                                        61990000
*********************************************************************** 62000000
*                                                                       62010000
*        MAINTENANCE AREA                                        A33564 62020000
*                                                                       62030000
*********************************************************************** 62040000
PATCH    DC    24F'0'                                            A33564 62050000
         EJECT                                                          62100016
*                                                                       62400016
* DCB FOR SYSOUT                                                        62700016
*                                                                       63000016
SYOUTDCB DCB   DSORG=PS,MACRF=(WP),DDNAME=GJPOUT,DEVD=DA,              X63300016
               RECFM=FBS,LRECL=120,BLKSIZE=120,EODAD=FCLOSE,SYNAD=FWTO  63600016
SYSDCB1  EQU   *                                                        63900016
*                                                                       64200016
LSYSOUT  EQU   SYSDCB1-SYOUTDCB    LENGTH OF SYSOUT DCB                 64500016
         EJECT                                                          64800016
*                                                                       65100016
*                                                                       65400016
* DSECT FOR ACCOUNTING ROUTINE PARAMETER LIST, READ, WRITE, OPEN        65700016
*                                                                       66000016
*                                                                       66300016
WORKAREA DSECT                                                          66600016
         DS    0F                                                       66700016
LOGCODE  DS    XL1                      PARAMETER CODE                  66900016
LOGUNIT  DS    XL3                     UNIT ADDRESS                0170 66950017
BEGPAR   EQU   *                                                        67000016
LOGNAME  DS    F                        POINTER TO USER NAME            67100016
LOGACCT  DS    F                        POINTER TO ACCOUNT NUMBER       67200016
LOGOTHR  DS    F                       POINTER TO USER OTHER DATA  0170 67230017
LOGACDAT DS    F                       POINTER TO USER ACCT DATA   0170 67260017
LOGUMSG  DS    F                        POINTER TO USER MESSAGE         67300016
LOGMSG   DS    F                        POINTER TO ACCOUNTING MESSAGE   67400016
UMSGAREA DS    18F                      USER MESSAGE AREA               67500016
MSGAREA  DS    18F                      ACCOUNTING MESSAGE AREA         67600016
SAVEMSG  DS    18F                                                      67700016
ENDPAR   EQU   *                                                        67800016
DCBSOUT  DS    25F                     SPACE FOR SYSOUT DCB             68700016
READ     EQU   *                                                        69000016
ECTBLOCK DC    F'0'                EVENT CONTROL BLOCK                  69300016
         DC    X'00'               TYPE FIELD                           69600016
         DC    X'80'               TYPE FIELD                           69900016
RLENGTH  DC    AL2(120)            LENGTH                               70200016
DCBADDR  DC    A(0)                DCB ADDRESS                          70500016
AREAADDR DC    A(0)                AREA ADDRESS                         70800016
         DC    A(0)                RECORD POINTER WORD                  71100016
*                                                                       71400016
WRITE    EQU   *                                                        71700016
WECBLOCK DC    F'0'                EVENT CONTROL BLOCK                  72000016
         DC    X'00'               TYPE FIELD                           72300016
         DC    X'20'               TYPE FIELD                           72600016
WLENGTH  DC    AL2(120)            LENGTH                               72900016
WDCBADDR DC    A(0)                DCB ADDRESS                          73200016
WAREADDR DC    A(0)                AREA ADDRESS                         73500016
         DC    A(0)                RECORD POINTER WORD                  73800016
OPEN     DS    0F                                                       74100016
OPTION   DC    AL1(131)            OPTION BYTE                          74400016
ODCBADDR DC    AL3(DCBSOUT)        DCB ADDRESS                          74700016
CLOSE    DS    0F                                                       75000016
COPTION  DC    AL1(128)            OPTION BYTE                          75300016
CDCBADDR DC    AL3(DCBSOUT)        DCB ADDRESS                          75600016
*                                                                       75670016
         DS    0F                                                       75740016
PRECORD  DS    XL(RECORDE-RECORD)                                       75810016
ENDDSECT EQU   *                                                        75900016
         EJECT                                                          76200016
         EJECT                                                          76300016
         SPACE                                                          76400016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         76500016
         SPACE                                                          76600016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    76700016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     76800016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       76900016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             77000016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  77100016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  77200016
*                   SET.                                                77300016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      77400016
*                   SECOND.                                             77500016
         SPACE 2                                                        77600016
CCT      DSECT                                                          77700016
         SPACE 2                                                        77800016
*                             SECTION ONE                               77900016
         SPACE                                                          78000016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     78100016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    78200016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  78300016
         SPACE                                                          78400016
         DS    0F                                                       78500016
CCTUNAME DS    5F                  USER'S NAME                          78600016
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         78700016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     78800016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       78900016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    79000016
*                                       AT LAST BEGIN JOB               79100016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   79200016
*                                       LAST BEGIN JOB                  79300016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 79400016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    79500016
*                                       JOB                             79600016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    79700016
*                                       JOB                             79800016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     79900016
*                                       CESSOR                          80000016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         80100016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         80200016
CCTJCTR  DS    H                   JOB COUNTER                          80300016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                80400016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   80500016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  80600016
CCTSSTAT DS    C                   SESSION STATUS                       80700016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              80800016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              80900016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    81000016
         EJECT                                                          81100016
         SPACE 2                                                        81200016
*                             SECTION TWO                               81300016
         SPACE                                                          81400016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   81500016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  81600016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 81700016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              81800016
         SPACE                                                          81900016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     82000016
*                                       FRAME                           82100016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  82200016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     82300016
*                                       MULTIPLE DISPLAY FRAME (ENT)    82400016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   82500016
CCTDISM  DS    C                   DISPLAY MASK                         82600016
CCTCSM   DS    C                   COMMAND SELECT MASK                  82700016
CCTPSTAT DS    CL2                 GJP STATUS                           82800016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              82900016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  83000016
         SPACE 2                                                        83100016
*                             SECTION THREE                             83200016
         SPACE                                                          83300016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    83400016
*                   INTO SECTION ONE OR TWO                             83500016
         SPACE                                                          83600016
CCTDGMP  DS    F                  POINTER TO DGM                        83700016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                83800016
CCTCSTP  DS    F                  POINTER TO CST                        83900016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                84000016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            84100016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 84200016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              84300016
CCTDIARP DS    F                  POINTER TO DIA                        84400016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      84500016
CCTACTP  DS    F                  POINTER TO ACT                        84600016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     84700016
CCTIERRP DS    F                  POINTER TO IERR                       84800016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              84900016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               85000016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                85100016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 85200016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 85300016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   85400016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                85500016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                85600016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               85700016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              85800016
CCTPECB  DS    F                  PROCESSOR'S ECB                       85900016
CCTWECB  DS    F                  WTOR ECB                              86000016
CCTDIAWA DS    CL136               DIARY WORK AREA                      86100016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    86200016
CCTCSAVE DS    CL72                CTL SAVE AREA                        86300016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                86400016
CCTASAVE DS    CL72                DAT SAVE AREA                        86500016
         EJECT                                                          87300016
*                                                                       88100016
* DSECT DEFINE DCB                                                      88900016
*                                                                       89700016
         DCBD  DSORG=PO,DEVD=DA                                         90500016
         END                                                            91500016
