         TITLE 'IKAPLON0 PROCESSOR FOR IKAGJP'                          00300016
*                             LOG ON ROUTINE                            00600016
*                                                                       00900016
* ROUTINE NAME       IKAPLON0                                           01200016
*                                                                       01500016
* CHART ID          FB                                                  01800016
*                                                                       02100016
*  FUCTION:         PROCESS LOG ON OPERATIONS                           02400016
*                                                                       02700016
*  ATTRIBUTES:      TRANSIENT, REENTERABLE                              03000016
*                                                                       03300016
* ENTRY POINT       IKAPLON0                                            03600016
*                                                                       03900016
* OPERATION        -ENTERED VIA LINK FROM IKACTL AND IN WAIT STATUS     04100016
*                  -PASS PARAMETER TO USER'S ACCOUNTING ROUTINE         04300016
*                  -UPDATE CONSOLE CONTROL TABLE SUCH AS USER'S NAME,   04500016
*                   ACCOUNT NUMBER, PASS WORD, RECORD OPTION SWITCH,    04700016
*                   COMMAND SELECT MASK                                 04900016
*                  -OPEN DIARY DATA SET                                 05100016
*                  -SET MESSAGE FOR USER'S INVALID INPUT DATA, AND      05300016
*                   ACCOUNTING MESSAGE                                  05500016
*                                                                       05700016
* EXIT             -BRANCH TO IKADIA ROUTINE IF RECORD OPTION TAKEN     05900016
*                  -BRANCH TO IKADMSG IN ERRON CONDITION                06100016
*                  -RETURN TO IKACTL WITH RETURN CODE IN REGISTER 15    06300016
*                   CODE---X'0'        NORMAL                           06500016
*                          X'12'       CANCEL                           06700016
*                                                                       06900016
* INPUT             REGISTER 1 POINTING TO CONSOLE CONTROL TABLE        07100016
*                                                                       07300016
*                   SET UP RETURN CODE FOR CTL                          09000016
*                   PASSES PARAMETER TO MSG IN ERROR CONDITION          09300016
*                                                                       09600016
* RETURN CODE FROM USER'S ACCOUNTING ROUTINE:                           09620016
*                   CODE - X'00'   NORMAL WITH MESSAGE                  09640016
*                          X'04'   NORMAL WITHOUT MESSAGE               09660016
*                          X'08'   ERROR WITH MESSAGE                   09680016
*                          X'0C'   INVALID USER'S NAME                  09700016
*                          X'10'   INVLAID USER'S ACCOUNT NUMBER        09720016
*                                                                       09740016
* EXTERNAL REFERENCE IKACTL                                             09800016
*                    IKADIA                                             10000016
*                    IKADMSG                                            10200016
*                    IKAACCTG                                           10400016
*                                                                       10600016
*                                                                       10800016
*  ERROR CONDITIONS: USER'S NAME UNDEFINED OR NOT IN CORRECT FORMAT     11100016
*                    USER'S ACCOUNT NUMBER UNDEFINED OR NOT IN CORRECT  11400016
*                    FORMAT                                             11700016
*                                                                       12000016
*  TABLE AND WORKAREAS: CONSOLE CONTROL TABLE                           12300016
*                       PARAMETER SELECT TABLE                          12600016
*                                                                       12900016
*  RESTRICTIONS                                                         13200016
*                                                                       13500016
*  REMARK           THE FORMATE OF PARAMETER LIST FOR USER'S ACCOUNTING 15500016
*                   ROUTINE, AND THE RETURN CODE FROM USER'S ACCOUNTING 17500016
*                   IS D DESCRIBED IN DETAIL IN IKAACCTG                19500016
*                                                                       21500016
         EJECT                                                     PDUM 21560017
*                                                                  PDUM 21620017
* CVT DSECT                                                        PDUM 21680017
*                                                                  PDUM 21740017
CVT      DSECT                                                     PDUM 21800017
         USING *,RINTRET                                           PDUM 21860017
**********THE NEXT CARD HAS BEEN ADDED PDUM PDUM PDUM              PDUM 21920017
         CVT                                                            21980017
         EJECT                                                     PDUM 22040017
GFXOCTHD DSECT                                                     PDUM 22100017
GFXHDSTR EQU   *                       START OF HEADER RECORD      PDUM 22160017
OCTSYS   DS    CL1                     BASE SYSTEM                 PDUM 22220017
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS           PDUM 22280017
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS     PDUM 22340017
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD  PDUM 22400017
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD  PDUM 22460017
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS         PDUM 22520017
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS         PDUM 22580017
         DS    0H                                                  PDUM 22640017
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250        PDUM 22700017
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD  PDUM 22760017
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD  PDUM 22820017
         DS    0F                                                  PDUM 22880017
OCTFGREG DS    CL4                      REGION SIZE GJP            PDUM 22940017
OCTFUREG DS    CL4                      REGION SIZE USER FGD       PDUM 23000017
OCTBUREG DS    CL4                      REGION SIZE USER BGD       PDUM 23060017
OCTGTCB  DS    CL4                     TCB ADDRESS OF GFX          PDUM 23120017
OCTHRES  DS    CL4                     RESERVED                    PDUM 23180017
OCTNAME  DS    CL20                     PROGRAMMER NAME            PDUM 23240017
OCTACCT  DS    CL20                     ACCOUNT NUMBER             PDUM 23300017
GFXHDEND EQU   *                       END OF HEADER RECORD        PDUM 23360017
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD   PDUM 23420017
         EJECT                                                     PDUM 23480017
GFXOCTEN DSECT                                                     PDUM 23540017
         DS    0F                                                  PDUM 23600017
GFXENSTR EQU   *                       START OF ENTRY RECORD       PDUM 23660017
OCTECB   DS    CL4                      ECB                        PDUM 23720017
OCTUCB   DS    CL4                      UCB ADDRESS                PDUM 23780017
OCTUNIT  DS    CL4                      UNIT ADDRESS               PDUM 23840017
OCTCOUNT DS    CL4                      JOB COUNT                  PDUM 23900017
OCTNOTE  DS    CL4                      NOTE                       PDUM 23960017
OCTABEND DS    A                       ABEND CODE                  PDUM 24020017
OCTFPART DS    CL2                      PARTITION NUMBER (MFT ONLY)PDUM 24080017
OCTDNOTE DS    CL3                      NOTE FIELD FOR DIARY DATA SPDUM 24140017
OCTIERNO DS    CL3                      INTERNAL ERROR NUMBER      PDUM 24200017
*******************************************************************PDUM 24260017
****                          ATTRIBUTE 1                          PDUM 24320017
*******************************************************************PDUM 24380017
OCTATTR1 DS    CL2                      ATTRIBUTES                 PDUM 24440017
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE    PDUM 24500017
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PPDUM 24560017
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING    PDUM 24620017
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ  PDUM 24680017
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SPDUM 24740017
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER PDUM 24800017
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER PDUM 24860017
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250      PDUM 24920017
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB     PDUM 24980017
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECPDUM 25040017
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT      PDUM 25100017
OCTBERR1 EQU   X'10'          0-                  1-GJP INTERNAL ERPDUM 25160017
OCTBERR2 EQU   X'08'          0-                  1-GJP INTERNAL ERPDUM 25220017
*******************************************************************PDUM 25280017
****                          ATTRIBUTE 2                          PDUM 25340017
*******************************************************************PDUM 25400017
OCTATTR2 DS    CL2                      ATTRIBUTES                 PDUM 25460017
OCTBIRRE EQU   X'80'          0-                  1-GJP INTERNAL ERPDUM 25520017
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB PDUM 25580017
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF         PDUM 25640017
OCTBFAST EQU   X'10'          0-                  1-FAST STOP      PDUM 25700017
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP    PDUM 25760017
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP      PDUM 25820017
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND  PDUM 25880017
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250       PDUM 25940017
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INPDUM 26000017
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USPDUM 26060017
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST   PDUM 26120017
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST    PDUM 26180017
*******************************************************************PDUM 26240017
****                          ATTRIBUTE 3                          PDUM 26300017
*******************************************************************PDUM 26360017
OCTATTR3 DS    CL2                      ATTRIBUTES                 PDUM 26420017
OCTBIERR EQU   X'80'          0-                  1-GJP INTERNAL ERPDUM 26480017
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB PDUM 26540017
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF         PDUM 26600017
OCTBFASM EQU   X'10'          0-                  1-FAST STOP      PDUM 26660017
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP    PDUM 26720017
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP      PDUM 26780017
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND  PDUM 26840017
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250       PDUM 26900017
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INPDUM 26960017
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USPDUM 27020017
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST   PDUM 27080017
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST    PDUM 27140017
*******************************************************************PDUM 27200017
****                          ATTRIBUTE 4                          PDUM 27260017
*******************************************************************PDUM 27320017
OCTATTR4 DS    CL2                      ATTRIBUTES                 PDUM 27380017
GFXENEND EQU   *                       END OF ENTRY RECORD         PDUM 27440017
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD        PDUM 27500017
         EJECT                                                     PDUM 27560017
         EJECT                                                          28200016
IKAPLON0 CSECT                                                          28500016
*2255,525000,769500-770000,770480-770520,770644,770860             0170 28600017
RPAR0    EQU   0                   PARAMETER                            28800016
RPAR1    EQU   1                   PARAMETER                            29100016
RCCT     EQU   2                   CONTAINS CCT ADDRESS                 29400016
RPWKA    EQU   3                   CONTAINS PROCESSOR WORK AREA ADDRESS 29700016
RINTRET  EQU   4                  INTERAL RETURN REGISTER               30000016
RMSG     EQU   5                  MESSAGE REGISTER                      30300016
RWORK    EQU   6                                                        30600016
RDIAWKA  EQU   7                                                        30900016
RTEST    EQU   8                                                        31200016
RDCB     EQU   8                        BASE FOR DIA DCB DSECT          31300016
RMSGMODA EQU   9                                                        31500016
RDESECT  EQU   10                                                       31800016
RBASE    EQU   11                  BASE REGISTER                        32100016
RWORK1   EQU   12                  GENERAL FUNCTION REGISTER            32400016
RSAVE    EQU   13                  SAVE REGISTER                        32700016
RRET     EQU   14                  RETURN REGISTER                      33000016
RBR      EQU   15                  BRANCH REGISTER                      33300016
*                                                                       33600016
*                                                                       33900016
*                                                                       34200016
* SAVE REGISTERS, GETMAIN FOR IKAACCTG, SET BASE                        34500016
*                                                                       34800016
*                                                                       35100016
         SAVE  (14,12)                  SAVE GENERAL REGISTER           35400016
         BALR  RBASE,0                                                  35700016
         USING *,RBASE             SET UP BASE                          36000016
         LR    RCCT,RPAR1          LOAD CCT ADDRESS                     36300016
         USING CCT,RCCT                                                 36600016
         LA    RPWKA,CCTPWKA       LOAD PROCESSOR WORK AREA             36900016
         GETMAIN R,LV=ACCTWKE-ACCTWKA                                   37200016
         LR    RDESECT,RPAR1       LOAD GET MAIN ADDRESS                37500016
         USING  ACCTWKAR,RDESECT                                        37800016
         LR    RPAR1,RCCT          LOAD CCT ADDRESS                     38100016
         ST    RSAVE,CCTPSAVE+4    SAVE CALLING SAVE ADDRESS            38400016
         LA    RWORK1,CCTPSAVE     LOAD OUR SAVE ADDRESS AND            38700016
         ST    RWORK1,8(0,RSAVE)   GIVE TO CALLING PROGRAM              39000016
         LR    RSAVE,RWORK1        POINTER TO OUR SAVE ADDRESS          39300016
         L     RMSGMODA,MSGMODA         LOAD IKAMLON0 ADDRESS           39340016
         USING IKAMLON0,RMSGMODA        SET DISPLACEMENT                39380016
         LA    RPAR1,1                 LOAD ONE                         39440016
         ST    RPAR1,CCTENOTE          SAVE IT IN CCT                   39500016
         EJECT                                                          39540016
*                                                                       39600016
* WAIT PROCESSOR'S ECB AND TEST IF CANCEL OR END FUNCTION               39900016
*                                                                       40200016
LWAIT    WAIT  ECB=CCTPECB         WAIT PROCESSOR ECB                   40500016
         MVI   CCTPECB,X'00'           CLEAR ECB                        40600016
         TM    CCTPECB+3,X'1C'         Q. IERR ENTERED             PDUM 40660017
         BO    IERENTR            BRANCH IF YES                    PDUM 40720017
         TM    CCTPECB+3,X'08'     IS IT CANCEL                         40800016
         BC    1,LCANCEL           YES BRANCH TO LCANCEL                41100016
         TM    CCTPECB+3,X'04'     NO, IS IT END                        41400016
         BC    1,LBEGIN            YES BRANCH TO LBEGIN                 41700016
         LA    RPAR0,MSG29              PARAMETER ADDRESS               41900016
         B     LMSG0                    BRANCH                          42100016
IERENTR  LA    15,28                                               PDUM 42200017
         B     LCLEAR                   BRANCH                     PDUM 42300017
         EJECT                                                          42600016
*                                                                       42900016
* TEST IF USER'S NAME AND ACCOUNT DEFINED                               43200016
*                                                                       43500016
LBEGIN   CLI   3(RPWKA),X'40'       IS IT  A BLANK                      43800016
         BNE   LCKACCT             NO SEE IF ACCOUNT NUMBER DEFINED     44100016
         CLC   3(10,RPWKA),13(RPWKA) IS USER NAME DEFINED               44400016
         BNE   LCKACCT             YES SEE IF ACCOUNT NUMBER DEFINED    44700016
         BAL   RINTRET,LMSG       BRANCH TO MESSAHE                     45600016
         DC    H'0'                     MESSAGE INDICATOR               45700016
         DC    H'0'                     NAME NOT DEFINED                45800016
         B     LCLEAR1             BRANCH CLEAR ECB                     45900016
LCKACCT  CLI   23(RPWKA),X'40'     IS IT A BLANK                        46200016
         BNE   LACCTG              NO LINK TO ACCTG ROUTINE             46500016
         CLC   23(10,RPWKA),33(RPWKA) ACCOUNTING NUMBER DEFINED         46800016
         BNE   LACCTG              YES LINK TO ACCTG ROUTINE            47100016
         BAL   RINTRET,LMSG        BRANCH TO MESSAGE                    48000016
         DC    H'0'                     MESSAGE INDICATOR               48100016
         DC    H'4'                     ACCOUNT NOT DEFINED             48200016
         B     LCLEAR1             BRANCH CLEAR ECB                     48300016
*                                                                       48600016
* SET UP PARAMER LIST AND LINK TO IKAACCTG                              48900016
*                                                                       49200016
LACCTG   LA    RWORK1,3(RPWKA)     LOAD USER NAME FIELD                 49500016
         ST    RWORK1,UNAME        STORE IN PARAMETER LIST              49800016
         MVI   LOGCODE,0                ZERO FOR LOG-ON            0170 49900017
         MVC   LOGUTN,CCTUNIT           IDENTIFICATION OF UNIT     0170 50000017
         LA    RWORK1,23(RPWKA)    LOAD USER ACCOUNTING NUMBER FIELD    50100016
         ST    RWORK1,UACCT        STORE IN PARAMETER LIST              50400016
         LA    RWORK1,43(RPWKA)    LOAD OTHER ACCOUNTING INFORMATION    50700016
         ST    RWORK1,UOTHER       STORE IN PARAMETER LIST              51000016
         LA    RWORK1,UARD         LOAD ADDRESS FOR ADDITIONAL INFORMTN 51300016
         ST    RWORK1,UARDAD      STORE IN PARAMETER  LIST              51600016
         LA    RWORK1,LTEXT       LOAD MESSAGE FIELD ADDR               51900016
         ST    RWORK1,UMSGAD       STORE IT IN THE PARAMETER LIST       52200016
         LA    RPAR1,LOGCODE            LOAD PARAMETER ADDR        0170 52400017
         O     RPAR1,HIBIT              INDICATE LOG ON            0170 52600017
         LA    RWORK,LTEXT         LOAD TEXT ADDRESS                    52800016
         MVI   0(RWORK),C' '       CLEAR THE AREA                       53100016
         MVC   1(71,RWORK),0(RWORK)                                     53400016
         L     RBR,VIKAACCT            LOAD ACCOUTING ROUTINE ADDRESS   53700016
         BALR  RRET,RBR                BRANCH TO ACCOUTING ROUTINE      54000016
*                                                                       54300016
* TEST RETURN CODE FROM IKAACCTG AND BRANCH ACCORDINGLY                 54600016
*                                                                       54900016
         LA    RWORK1,16                LOAD 16 TO CHECK RETURN CODE    55200016
         CR    RBR,RWORK1               IS RETURN CODE LARGER THAN 16   55500016
         LA    RPAR0,IERRPAR            MESSAGE PARAMETER ADDRESS       55600016
         BH    LMSG0              YES BRANCH TO MESSAGE                 55800016
         LA    RWORK1,3           LOAD 3 TO CHECK IS RETURN CODEMULT-4  56100016
         NR    RWORK1,RBR          AND REGISTERS                        56400016
         BC    4,LMSG0            NO BRANCH MESSAGE                     56700016
         B     LRETCODE(15)        BRANCH TO RETURN CODE TABLE          57000016
LRETCODE EQU   *                                                        57300016
         B     LNORMSG                  NORMAL WITH MESSAGE             57600016
         B     LNORNMSG            NORMAL WITHOUT MESSAGE               57900016
         B     LERRMSG             ERROR WIT MESSAGE                    58200016
         B     LINVDNM             INVALID USER'S NAME                  58500016
         B     LINVDACT           INVALID ACCOUNT NUMBER                58800016
LNORMSG  BAL   RINTRET,LMSG             BRANCH TO MSG                   58900016
         DC    H'1'                     SET UP MESSAGE INDICATOR        59000016
         DC    H'8'                     NORMAL WITH MESSAGE             59100016
         WAIT  ECB=CCTPECB             WAIT                             59400016
         TM    CCTPECB+3,X'08'          CANCEL?                         59500016
         BC    1,LCANCEL               BRANCH CANCEL                    59600016
         B     LNORNMSG                 CONTINUE PROCESS                59700016
LERRMSG  BAL   RINTRET,LMSG             BRANCH TO LMSG                  59800016
         DC    H'1'                     SET UP MESSAGE INDICATOR        59900016
         DC    H'8'                     ERROR WITH MESSAGE              60000016
         B     LCLEAR1                  GO TO CLEAR PROCESSOR'S ECB     60100016
LINVDNM  BAL   RINTRET,LMSG             BRANCH TO LMSG                  60200016
         DC    H'2'                     SET UP MESSAGE INDICATOR        60300016
         DC    H'12'                    NAME NOT ACCEPT BY ACCTG        60400016
         B     LCLEAR1                  CLEAR ECB AND WAIT              60500016
LINVDACT BAL   RINTRET,LMSG             BRANCH TO LMSG                  60600016
         DC    H'2'                     MESSAGE INDICATOR               60700016
         DC    H'16'                    ACCOUNT NOT ACCEPTED BY ACCTG   60800016
         B     LCLEAR1                  CLEAR ECB AND WAIT              60900016
LMSG     MVI   99(RPWKA),C' '           BLANK MESSAGE AREA              61000016
         MVC   100(200,RPWKA),99(RPWKA)                                 61100016
         LH    RTEST,0(RINTRET)         LOAD MESSAGE INDICATOR          61200016
         CH    RTEST,ZEROS             IS CONSTANT MESSAGE              61300016
         BE    CONSTMSG                 YES                             61400016
         CH    RTEST,ONE                DOES USER HAVE MESSAGE          61500016
         BE    ACTGMSG                  YES                             61600016
LONMSG   LH    RMSG,2(RINTRET)          LOAD MESSAGE POINTER            61700016
         LR    RWORK1,RMSG              SAVE IT                         61800016
         A     RWORK1,MSGMODA           POINT TO MESSAGE                61900016
         L     RWORK1,0(RWORK1)         LOAD MESSAGE AFFRESS            62000016
         MVC   100(16,RPWKA),0(RWORK1)  MOVE PARAMETER LIST IN WORKAREA 62100016
         LA    RWORK1,116(RPWKA)        LOAD MESSAGE ADDRESS            62200016
         ST    RWORK1,104(RPWKA)        STORE IN PARAMETER LIST         62300016
         MVI   104(RPWKA),X'40'         SET STATUS BITS                 62400016
         CH    RMSG,TWELVE              NAME NOT ACCEPTED?              62500016
         BE    LONMSG1                  YES                             62600016
         MVC   116(33,RPWKA),UACCTP1    MOVE IN ACCOUNT PARAMETER       62700016
         MVC   127(20,RPWKA),23(RPWKA)  MOVE IN INPUT DATA              62800016
         LA    RPAR0,100(RPWKA)         LOAD PAR-LIST ADDR              62900016
         B     COMMON                   BRANCH                          63000016
LONMSG1  MVC   116(29,RPWKA),UNAMEP1    MOVE IN NAME PARAMETE           63100016
         MVC   124(20,RPWKA),3(RPWKA)   MOVE IN USER'S INPUT DATA       63200016
         LA    RPAR0,100(RPWKA)         LOAD PARAMETER LIST ADDR        63300016
         B     COMMON                   BRANCH                          63400016
ACTGMSG  MVC    100(4,RPWKA),MSG3      MOVE PAR-LIST                    63500016
         LA    RTEST,MGLENGTH           FILLED IN USER'S MESSAGE ADDR   63600016
         ST    RTEST,104(RPWKA)                                         63700016
         MVI   104(RPWKA),X'C0'        SET STATUS BITS                  63800016
         MVI   MGLENGTH,X'48'                                           63900016
         LA    RPAR0,100(RPWKA)         SET PARAMETER                   64000016
         B     COMMON                   BRANCH                          64100016
CONSTMSG LH    RMSG,2(RINTRET)          LOAD PARAMETER POINTER          64200016
         A     RMSG,MSGMODA             LOAD IKAMLON0 ADDRESS           64300016
         L     RPAR0,0(RMSG)            LOAD PARAMETER LIST ADDRESS     64400016
COMMON   LR    RPAR1,RCCT              LOAD CCT ADDRESS                 64500016
         L     RBR,CCTDMRP              LOAD IKADMSG ADDRESS            64600016
         OI    CCTPSTAT+1,B'00100000'   TURN ATTENTION SWITCH OFF       64700016
         XC    CCTPECB,CCTPECB          CLEAR PROCESSOR ECB           S 64730016
*                                       BEFORE GOING TO DISPLAY MSG   S 64760016
         BALR  RRET,RBR                 BRANCH TO IKADMSG               64800016
         LA    RRET,28                                             0170 64820017
         CR    RRET,RBR                IS RETURN CODE TERMINATE    0170 64840017
         BE    LCLEAR                  YES RETURN TO CALLER        0170 64860017
         NI    CCTPSTAT+1,B'11011111'   TURN ATTENTION SWITCH ON        64900016
         B     4(RINTRET)               BRANCH BACK                     65000016
LCLEAR1  EQU   *                                                      S 65100016
         B     LWAIT                                                    65300016
LNORNMSG MVC   CCTUNAME(20),3(RPWKA) UPDATE USER'S NAME IN CCT          69900016
         MVC   CCTUACCT(20),23(RPWKA) UPDATE USER ACCOUNT NUMBER        70200016
         MVC   CCTUARD(20),UARD    UPDATE USER'S ACCOUTING INFORMATION  70500016
         MVC   CCTUOTHR(20),43(RPWKA) MOVE OTHER ACCTOUNTING INFORMTION 70800016
         LA    RDIAWKA,CCTDIAWA                 LOAD DIA WORKAREA ADDR  71400016
         MVC   5(5,RDIAWKA),LOGON        MOVE LOGON IN DIA WORKAREA     72000016
         MVC  LUNAME(20,RDIAWKA),3(RPWKA) MOVE USER'S NAME IN DIA WORKA 72300016
         MVC  LUACCT(20,RDIAWKA),23(RPWKA) MOVE ACCT NO.IN DIA WORKAREA 72600016
         MVC   UPASS(20,RDIAWKA),43(RPWKA) MOVE PASS WORD IN DIA WKAREA 72900016
         MVC   URECD(6,RDIAWKA),RECORD     MOVE RECORD IN DIA WORKAREA  73200016
         FREEMAIN R,LV=ACCTWKE-ACCTWKA,A=(RDESECT)                      73300016
         B     CHKOCT                  GO TO CHECK IF THIS IS A RESPDUM 73400017
CHKREC   CLC   350(2,RPWKA),BLANK      RECORD OPTION               PDUM 73500017
         BE    LREC                    NO                          PDUM 73600017
SETREC   OI    CCTSSTAT,X'80'          TURN ON RECORD OPTION SWITCHPDUM 73700017
         GETMAIN R,LV=ENDDSECT-DCBDSECT                                 73801016
         LR    RDCB,RPAR1               GATMAIN ADDRESS                 73802016
         USING DCBDSECT,RDCB                                            73803016
         L     RWORK,LDCB1                                              73804016
         SH    RWORK,TWO                * CLEAR GETMAIN AREA            73805016
         LA    RWORK1,DCBDSECT          *                               73806016
         MVI   0(RWORK1),X'00'          *                               73807016
         EX    RWORK,MOVE               *                               73808016
         AH    RWORK,TWO                                                73809016
         ST    RWORK,SAVELTH            SAVE GETMAIN LENGTH             73810016
         LA    RWORK,DIADCB                                             73811016
         ST    RWORK,CCTRDCBP          SAVE DIADCB ADDRESS              73815016
         EJECT                                                          73820016
*                                                                       73840016
* OPEN DIARY DCB                                                        73860016
*                                                                       73880016
         MVC   DIADCB(LDCB),DCBDIA      MAKE DIARY DCB REENTERABLE      73900016
         MVC   REALOPEN(4),MFLOPEN      MOVE OPEN MACRO IN AND          73960016
         MVC   REALOPEN+1(3),CCTRDCBP+1 PUT DIARY DCB ADDRESS IN IT     73980016
         LA    RPAR1,REALOPEN          LOAD PARAMETER ADDRESS           74000016
         OPEN  ,MF=(E,(1))              ISSUE OPEN MACRO IN E FORM      74020016
         L     6,CCTRDCBP              DIARY DCB ADDRESS                74030016
         USING IHADCB,6                                                 74040016
         TM    DCBOFLGS,OPENOK         Q. OPEN OK                       74050016
         BZ    IOERROR                 BRANCH IF NO                     74060016
         DROP  6                       DROP BASE                        74070016
         CLI   350(RPWKA),X'FF'        IS THIS RESTARTED GJP       PDUM 74120017
         BNE   LREC                    NO GO TO LOAD REC           PDUM 74170017
         L     RPAR1,CCTRDCBP          LOAD DCB ADDR               PDUM 74220017
         POINT (1),356(RPWKA)          POINT DIARY DATA SET        PDUM 74270017
         MVC   356(4,RPWKA),BLANK      CLEAR OUT POINT ADDR        PDUM 74320017
LREC     L     RBR,CCTDIARP       LOAD DIA ADDRESS                      74400016
         LR    RPAR1,RCCT          LOAD CCT ADDRESS                     74700016
         BALR  RRET,RBR            BRANCH TO RECORD ROUTINE             75000016
         LA    RRET,28                  GET VALUE OF X'1C'         0170 75020017
         CR    RRET,RBR                 Q. 'MUST TERMINATE' CODE   0170 75040017
         BE    LCLEAR                   YES, END LOG ON            0170 75060017
         MVC   CCTPWKA(14),MSG37        MESSAGE 37                      75100016
         LA    RWORK,CCTPWKA+12         SETUP INSERT DATA               75200016
         ST    RWORK,CCTPWKA+8          ADDRESS                         75300016
         MVI   CCTPWKA+8,X'C0'          CONTROL BITS                    75400016
         MVC   CCTPWKA+14(3),CCTUNIT    UNIT NUMBER                     75500016
         LA    RPAR0,CCTPWKA            POINTER TO MESSAGE PARAMETER    75600016
         B     IERR                     BRANCH                          75700016
LCANCEL  EQU   *                                                   PDUM 75770017
         FREEMAIN R,LV=ACCTWKE-ACCTWKA,A=(RDESECT)                 PDUM 75840017
         LA    RBR,12                  RETURN CODE FOR CANCEL      PDUM 75910017
         MVI       CCTCSM,X'18'         SET MASK DISPLAY LOGON-LOGOFF   76000016
LCLEAR   MVI   CCTPECB,X'00'      CLEAR PROCESSOR'S ECB                 76200016
         L     RSAVE,CCTPSAVE+4    LOAD CALLING PROGRAM SAVE ADDRESS    76500016
         RETURN (14,12),RC=(15)    RETURN WITH RETURN CODE              76800016
ERRTN    EQU   *                                                        76850016
         LA    RPAR0,MSG62              MESSAGE PARAMETER ADDRESS       76900016
LMSG0    EQU   *                                                        77010016
         LR    1,RCCT                  CCT ADDRESS                      77020016
         L     15,CCTIERRP             IERR ADDRESS                     77040016
         BALR  RRET,RBR                 GO TO IERR                      77044016
         LA    RRET,28                  GET VALUE OF X'1C'         0170 77046017
         CR    RRET,RBR                 Q. 'MUST TERMINATE' CODE   0170 77048017
         BE    LCLEAR                   YES, END LOG ON            0170 77050017
         B     LNORNMSG                 DEFAULT                    0170 77052017
IOERROR  EQU   *                                                        77056016
         LA    RPAR0,IRRPARM           IERRPARM-LIST ADDRESS            77062016
         LR    1,RCCT                   CCT ADDRESS                PDUM 77062617
         L     15,CCTIERRP              IKAIERR ADDRESS            PDUM 77063217
         BALR  14,15                    GO TO IERR                 PDUM 77063817
         LA    RRET,28                  GET VALUE OF X'1C'         0170 77064017
         CR    RRET,RBR                 Q. 'MUST TERMINATE' CODE   0170 77064217
         BE    LCLEAR                   YES, END LOG ON            0170 77064417
         B     LREC                     NO, CONTINUE               0170 77064617
IERR     EQU   *                                                        77065016
         LR    RPAR1,RCCT              CCT ADDRESS                      77068016
         L     RBR,CCTIERRP            IKAIERR ADDRESS                  77074016
         BALR  RRET,RBR                BRANCH TO IERR                   77080016
         B     LCLEAR                  BRANCH                      PDUM 77106017
         EJECT                                                     PDUM 77126017
         USING GFXOCTHD,RWORK1                                     PDUM 77146017
         USING GFXOCTEN,RWORK                                      PDUM 77166017
CHKOCT   L     RINTRET,16              LOAD CVT ADDR               PDUM 77186017
         L     RINTRET,CVTQOCR         LOAD PARM LIST ADDR         PDUM 77206017
         LTR   RINTRET,RINTRET         IS ADDR ZERO                PDUM 77226017
         BZ    CHKREC                  YES GO CHECK RECORD OPTION  PDUM 77246017
         L     RWORK1,0(RINTRET)       LOAD OCT ADDR               PDUM 77266017
         LA    RWORK,GFXHDSZE(RWORK1)  SKIP OVER OCT HEADER        PDUM 77286017
         LH    RINTRET,OCTUNBR         LOAD 2250 COUNT             PDUM 77306017
CHKUNIT  CLC   OCTUNIT+1(3),CCTUNIT    IS THIS UNIT                PDUM 77326017
         BE    TSTPOINT                YES GO TO TEST FOR POINT    PDUM 77346017
         LA    RWORK,GFXENSZE(RWORK)   MOVE TO NEXT ENTRY          PDUM 77366017
         BCT   RINTRET,CHKUNIT         ALLL UNITS NOT CHECKED      PDUM 77386017
         B     CHKREC                  GO TO CHECK RECORD OPTION   PDUM 77406017
TSTPOINT CLC   OCTDNOTE(3),ZERO        IS NOTE FIELD ZEROS         PDUM 77426017
         BE    CHKREC                  YES GO TO CHECK RECORD OPT  PDUM 77446017
         MVC   356(3,RPWKA),OCTDNOTE   MOVE NOTE FIELD             PDUM 77466017
         MVI   359(RPWKA),X'01'        INCREASE NOTE POSITION BY ONPDUM 77486017
         MVI   350(RPWKA),X'FF'        SET BIT TO INDICATE POINT   PDUM 77506017
         MVC   OCTDNOTE(3),ZERO        CLEAR NOTE FIELD TO EBDIC ZEPDUM 77526017
         B     SETREC                  GO TO SET RECORD OPTION     PDUM 77546017
         EJECT                                                     PDUM 77566017
*                                                                  PDUM 77586017
*                                                                       77700016
* DEFINE CONSTANT AREA                                                  78000016
*                                                                       78300016
LUNAME   EQU   15                                                       80400016
LUACCT   EQU   37                                                       80700016
UPASS    EQU   59                                                       81000016
URECD    EQU   81                                                       81300016
OPENOK   EQU   X'10'                   MASK TO TEST OPEN DCB            81350016
BLANK    DC    C'    '                                             PDUM 81430017
ZERO     DC    C'0000'                 EBDIC ZEROS                 PDUM 81510017
LOGON    DC    C'LOGON'                                                 81600016
RECORD   DC    C'RECORD'                                                81900016
         DS    0F                                                       81950016
HIBIT    DC    X'80000000'              HIGH ORDER BIT ON          0170 81970017
ZEROS    DC    H'0'                                                     82000016
ONE      DC    H'1'                                                     82050016
TWO      DC    H'2'                                                     82070016
TWELVE   DC    H'12'                                                    82100016
MSGMODA  DC    V(IKAMLON0)                                              82150016
VIKAACCT DC    V(IKAACCTG)             ACCOUTING ROOUTINE ADDR          82200016
MOVE     MVC   1(0,RWORK1),0(RWORK1)                                    82300016
*                                                                       82320016
* THIS IS  A PARAMETER LIST PAST TO INTERNAL ERROR ROUTINE              82340016
*                                                                       82346016
*                                                                       82352016
         DS    0F                                                       82358016
MSG37    EQU   *                                                        82364016
         DC    CL3'037'                 MESSAGE NUMBER                  82370016
         DC    CL5'PLON0'               MODULE KEY WORD                 82376016
         DC    X'C0'                    CONTROL BYTE                    82382016
         DC    XL3'0'                   SPACE                           82388016
         DC    H'5'                    LENGTH FOR INSERT DATA           82394016
         DS    0F                                                       82400016
IERRPAR  EQU   *                                                        82406016
         DC    CL3'023'                 MSG NUMBER                      82420016
         DC    CL5'PLON0'              MODULE NAME                      82440016
         DC    X'80'                    RETURN                          82460016
         DC    XL4'00000000'                                            82480016
         DS    0F                                                       82482016
IRRPARM  EQU   *                                                        82484016
MSGNO    DC    CL3'056'                MESSAGE NUMBER                   82488016
         DC    CL5'PLON0'              MODULE'S NAME                    82492016
         DC    X'C0'                   CONTROL BITS                     82496016
         DC    AL3(DCBMSG)             ADDR OF INSERT DATA              82500016
*                                                                       82500316
         DS    0F                                                       82500416
MSG29    DC    CL3'029'                 MESSAGE NUMBER                  82500616
         DC    CL5'PLON0'               MODULE'S KEY WORD               82500916
         DC    XL4'80000000'            RETURN                          82501216
*                                                                       82501516
         DS    0F                                                       82501616
MSG62    DC    CL3'062'                 MESSAGE NUMBER                  82501816
         DC    CL5'PLON0'               MODOLE'S KEY WORD               82502116
         DC    X'C0'                    INSERT + RETURN                 82502416
         DC    AL3(DCBIO)               ADDRESS FOR INSERT DATA         82502716
DCBIO    DC    H'6'                     LENGTH                          82503016
         DC    CL4'UNIT'                DATA                            82503316
*                                                                       82504016
DCBMSG   EQU   *                                                        82508016
         DC    H'6'                    LENGTH                           82512016
         DC    C' DIA'                 DATA TO INSERTED                 82516016
         SPACE 2                                                        82516500
*********************************************************************** 82517000
*                                                                       82517500
*        MAINTENANCE AREA                                        A33564 82518000
*                                                                       82518500
*********************************************************************** 82519000
PATCH    DC    15F'0'                                            A33564 82519500
         EJECT                                                          82520016
*                                                                       82540016
* DIARY DCB                                                             82560016
*                                                                       82580016
DCBDIA   DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=GJPDIA,DEVD=DA,RECFM=FBS, X82600016
               LRECL=120,BLKSIZE=120,SYNAD=ERRTN                        82620016
DCBDIAE  EQU   *                                                        82640016
*                                                                       82660016
* OPEN DIARY DCB IN MF=L                                                82680016
*                                                                       82700016
MFLOPEN  OPEN  (DCBDIA,(INOUT)),MF=L                                    82720016
LDCB     EQU   DCBDIAE-DCBDIA                                           82740016
LDCB1    DC    A(ENDDSECT-DCBDSECT)                                     82750016
DSECTLTH DC    A(DCBDIAE-DCBDIA)                                        82770016
*                                                                       82800016
* DSECT AREA                                                            83100016
*                                                                       83400016
*                                                                       83700016
*                                                                       84000016
ACCTWKAR DSECT                                                          84300016
ACCTWKA  EQU   *                                                        84600016
LOGCODE  DS    XL1                      PARAMETER CODE             0170 84700017
LOGUTN   DS    XL3                      UNIT NAME                  0170 84800017
UNAME    DS    F                   POINTER TO USER NAME                 84900016
UACCT    DS    F                  POINYER TO USER ACCTG NUMBER          85200016
UOTHER   DS    F                   POINTER TO USER'S OTHER ACCOUNT      85500016
UARDAD   DS    F                   POINTER TO USER ACCOUNTING RTN DATA  85800016
UMSGAD   DS    F                   POINTER TO USER ACCTG MESSAGE FIELD  86100016
UARD     DS    5F                                                       86400016
         DS    CL3                                                      86800016
MGLENGTH DS    X                                                        87200016
LTEXT    DS    XL72                     MESSAGE FIELD                   87600016
         DS    0F                                                       87670016
ACCTWKE  EQU   *                                                        87900016
*                                                                       87901016
* DSECT FOR DIARY DCB                                                   87902016
*                                                                       87903016
DCBDSECT DSECT                                                          87904016
SAVELTH  DS    2F                                                       87905016
DIADCB   DS    XL(DCBDIAE-DCBDIA)                                       87906016
REALOPEN DS    F                                                        87907016
ENDDSECT EQU   *                                                        87908016
         EJECT                                                          87910016
         EJECT                                                          87914016
         SPACE                                                          87918016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         87922016
         SPACE                                                          87926016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    87930016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     87934016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       87938016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             87942016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  87946016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  87950016
*                   SET.                                                87954016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      87958016
*                   SECOND.                                             87962016
         SPACE 2                                                        87966016
CCT      DSECT                                                          87970016
         SPACE 2                                                        87974016
*                             SECTION ONE                               87978016
         SPACE                                                          87982016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     87986016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    87990016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  87994016
         SPACE                                                          87998016
         DS    0F                                                       88002016
CCTUNAME DS    5F                  USER'S NAME                          88006016
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         88010016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     88014016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       88018016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    88022016
*                                       AT LAST BEGIN JOB               88026016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   88030016
*                                       LAST BEGIN JOB                  88034016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 88038016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    88042016
*                                       JOB                             88046016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    88050016
*                                       JOB                             88054016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     88058016
*                                       CESSOR                          88062016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         88066016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         88070016
CCTJCTR  DS    H                   JOB COUNTER                          88074016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                88078016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   88082016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  88086016
CCTSSTAT DS    C                   SESSION STATUS                       88090016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              88094016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              88098016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    88102016
         EJECT                                                          88106016
         SPACE 2                                                        88110016
*                             SECTION TWO                               88114016
         SPACE                                                          88118016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   88122016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  88126016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 88130016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              88134016
         SPACE                                                          88138016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     88142016
*                                       FRAME                           88146016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  88150016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     88154016
*                                       MULTIPLE DISPLAY FRAME (ENT)    88158016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   88162016
CCTDISM  DS    C                   DISPLAY MASK                         88166016
CCTCSM   DS    C                   COMMAND SELECT MASK                  88170016
CCTPSTAT DS    CL2                 GJP STATUS                           88174016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              88178016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  88182016
         SPACE 2                                                        88186016
*                             SECTION THREE                             88190016
         SPACE                                                          88194016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    88198016
*                   INTO SECTION ONE OR TWO                             88202016
         SPACE                                                          88206016
CCTDGMP  DS    F                  POINTER TO DGM                        88210016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                88214016
CCTCSTP  DS    F                  POINTER TO CST                        88218016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                88222016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            88226016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 88230016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              88234016
CCTDIARP DS    F                  POINTER TO DIA                        88238016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      88242016
CCTACTP  DS    F                  POINTER TO ACT                        88246016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     88250016
CCTIERRP DS    F                  POINTER TO IERR                       88254016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              88258016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               88262016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                88266016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 88270016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 88274016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   88278016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                88282016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                88286016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               88290016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              88294016
CCTPECB  DS    F                  PROCESSOR'S ECB                       88298016
CCTWECB  DS    F                  WTOR ECB                              88302016
CCTDIAWA DS    CL136               DIARY WORK AREA                      88306016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    88310016
CCTCSAVE DS    CL72                CTL SAVE AREA                        88314016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                88318016
CCTASAVE DS    CL72                DAT SAVE AREA                        88322016
         EJECT                                                          88331016
*                                                                       88340016
* DSECT DEFINE DCB                                                      88349016
*                                                                       88358016
         DCBD  DSORG=PO,DEVD=DA                                         88367016
         EJECT                                                          88381016
IKAMLON0 CSECT                                                          88382016
NAMEMSG  DC    A(MSG1)                  POINTER TO MSG1                 88383016
ACCTMSG  DC    A(MSG2)                  POINTER TO MSG2                 88384016
ACCTGMSG DC    A(MSG3)                  POINTER TO MSG3                 88385016
ANAMEMSG DC    A(MSG5)                  POINTER TO MSG5                 88386016
AACCTMSG DC    A(MSG6)                  POINTER TO MSG6                 88387016
MSG1     DC    X'40'                    ENTRY IS MESSAGE                88388016
         DC    AL3(TITLE)               POINTER TO TEXT                 88389016
         DC    X'40'                    ENTRY IS MESSAGE                88390016
         DC    AL3(UNAMEP)              POINTER TO TEXT                 88391016
         DC    X'40'                    ENTRY IS MESSAGE                88392016
         DC    AL3(TEXT2)              POINTER TO TEXT             PDUM 88393017
         DC    X'80000003'              INTENCIFY AND LAST ENTRY        88394016
*                                                                       88395016
*                                                                       88396016
MSG2     DC    X'40'                    ENTRY IS MESSAGE                88397016
         DC    AL3(TITLE)               POINTER TO TEXT                 88398016
         DC    X'40'                    ENTRY IS MESSAGE                88399016
         DC    AL3(UACCTP)              POINTER TO TEXT                 88400016
         DC    X'40'                    ENTRY IS MESSAGE                88401016
         DC    AL3(TEXT2)               POINTER TO TEXT                 88402016
         DC    X'80000017'             INTENCIFY AND LAST ENTRY         88403016
*                                                                       88404016
*                                                                       88405016
MSG3     DC    X'40'                    ENTRY IS MESSAGE                88406016
         DC    AL3(TITLE1)              POINTER TO TEXT                 88407016
*                                                                       88408016
*                                                                       88409016
MSG5     DC    X'40'                    ENTRY IS MESSAGE                88410016
         DC    AL3(TITLE)               POINTER TO TEXT                 88411016
         DC    X'40'                    ENTRY IS MESSAGE                88412016
         DC    AL3(UNAMEP1)             POINTER TO TEXT                 88413016
         DC    X'40'                    ENTRY IS MESSAGE                88414016
         DC    AL3(TEXT3)               POINTER TO TEXT                 88415016
         DC    X'80000003'              INTENCIFY AND LAST ENTRY        88416016
*                                                                       88417016
*                                                                       88418016
MSG6     DC    X'40'                    ENTRY IS MESSAGE                88419016
         DC    AL3(TITLE)               POINTER TO TEXT                 88420016
         DC    X'40'                    ENTRY IS MESSAGE                88421016
         DC    AL3(UACCTP1)             POINTER TO TEXT                 88422016
         DC    X'40'                    ENTRY IS MESSAGE                88423016
         DC    AL3(TEXT3)               POINTER TO TEXT                 88424016
         DC    X'80000017'              INTENCIFY AND LAST ENTRY        88425016
*                                                                       88426016
*                                                                       88427016
TITLE    DC    X'14'                    MESSAGE LENGTH                  88428016
         DC    C'JOB CONTROL ERROR:  '   MESSAGE                        88429016
UNAMEP   DC    X'08'                                                    88430016
         DC    C'NAME :  '                                              88431016
UNAMEP1  DC    X'1C'                                                    88432016
         DC    C'NAME :                      '                          88433016
UACCTP   DC    X'0C'                                                    88434016
         DC    C'ACCOUNT :   '                                          88435016
UACCTP1  DC    X'20'                                                    88436016
         DC    C'ACCOUNT :                       '                      88437016
TITLE1   DC    X'14'                    MESSAGE LENGTH                  88438016
         DC    C'JOB CONTROL COMMENT: ' MESSAGE                         88439016
TEXT2    DC    X'20'                    MESSAGE LENGTH                  88442016
         DC    C'- SUPPLY REQUIRED INFORMATION   '                      88443016
TEXT3    DC    X'20'                    MESSAGE LENGTH                  88444016
         DC    C'- UNACCEPTABLE TO ACCOUNTING    '                      88445016
         END                                                            88500016
