         TITLE 'RECALL PROCESSOR FOR GJP'                               00080016
*                                                                       00080416
*  IKAPREC   RECALL PROCESSOR                                           00080816
*                                                                       00081216
*    CHART ID  - FK,FL,FM                                               00081316
*                                                                       00081416
*    FUNCTION  - PROCESS THE RECALL COMMAND TO ALLOW THE CONSOLE        00081616
*                OPERATOR TO CHANGE HIS JOB STREAM.                     00082016
*                                                                       00082416
*    ATTRIBUTES - TRANSIENT, REENTRENT                                  00082816
*                                                                       00083216
*    OPERATION - TWO DATA SETS ARE USED TO PREFORM THE RECALL FUNCTION, 00083616
*                (GJPEXT,GJPEXT1). IKAINIT OPENS THESE DATA SETS AND    00084016
*                INITIALLY POINTS AT GJPEXT AS THE EXTRACT DATA SET.    00084416
*                WHEN RECALL IS ENTERED IT SWITCHES THE POINTERS IN THE 00084816
*                CCT SO THAT GJPEXT1 NOW BECOMES THE EXTRACT DATA SET   00085216
*                AND GJPEXT NOW BECOMES THE INPUT DATA SET FOR RECALL.  00085616
*                A BIT IS ALSO SET IN THE CCT (CCTSSTAT BIT 1) TO       00086016
*                INFORM IKAINIT WHICH DATA SET TO INITIALIZE WHEN GJP   00086416
*                IS REINITIALIZED AT USER JOB TERMINATION. IF THE       00086816
*                RECALL OPTION IS CHOSEN MORE THAN ONCE DURING THE      00087216
*                SPECIFICATION OF A JOB THE DATA SETS ARE AGAIN         00087616
*                REVERSED IN THE ABOVE MANNER.                          00088016
*                                                                       00088416
*                A RECORD IS THEN READ FROM THE EXTRACT DATA SET AND    00088816
*                CHECKED TO INSURE THAT IT IS NOT OUT OF CONTEXT WITH   00089216
*                THE CURRENT JOB SPECIFICATION. IF THE OPERATION IS     00089616
*                EITHER OUT OF CONTEX OR MUST HAVE A PREVIOUS OPERATION 00090016
*                SPECIFIED THE USER IS GIVEN THE FOLLOWING OPTIONS;     00090416
*                                                                       00090816
*                   1.OUT OF CONTEXT                                    00091216
*                                                                       00091616
*                      - REVIEW                                         00092016
*                      - INSERT                                         00092416
*                      - OMIT                                           00092816
*                                                                       00093216
*                   2.PREVIOUS OPERATION REQUIRED                       00093616
*                                                                       00094016
*                     - INSERT                                          00094416
*                     - OMIT                                            00094816
*                                                                       00095216
*                 IF ALL CONDITIONS OF JOB SPECIFICATION ARE MEET THE   00095616
*                 USER IS GIVEN ALL FOUR OPTIONS;                       00096016
*                                                                       00096416
*                     - ACCEPT                                          00096816
*                     - REVIEW                                          00097216
*                     - INSERT                                          00097616
*                     - OMIT                                            00098016
*                                                                       00098416
*                 WHEN IT HAS BEEN DETERMINED WHICH OPTIONS THE USER    00098816
*                 WILL BE GIVEN A HISTORY ENTRY IS FORMED FROM THE      00099216
*                 RECALLED RECORD. THIS ENTRY IS DISPLAYED IN THE       00099616
*                 FOLLOWING FORMAT;                                     00100016
*                                                                       00100416
*                        CURRENT ITEM: OO2 JOB STEP (NAME)              00100816
*                                                                       00101216
*                 ALSO INCLUDED ON THE DISPLAY IS THE OPTIONS ALLOWED   00101616
*                 AND THE HISTORY OF OPERATIONS TO THIS POINT IN THE    00102016
*                 JOB.                                                  00102416
*                                                                       00102816
*                 IF THE USER CHOOSES ACCEPT, THE INFORMATION IN THE    00103216
*                 RECALLED RECORD IS PLACED IN THE PROCESSOR WORK AREA  00103616
*                 IN THE FORMAT REQUIRED OF THAT PROCESSOR AND THE      00104016
*                 PROCESSOR IS THEN BRANCHED TO TO PROCESS THE INPUT.   00104416
*                                                                       00104816
*                 IF THE USER CHOOSES REVIEW, THE PARAMETER FRAME IS    00105216
*                 DISPLAYED AS HE LAST SAW IT. AT THIS TIME HE MAY MAKE 00105616
*                 ANY MODIFICATION HE WISHES PROVIDED HE DOES NOT       00106016
*                 INSERT ERRONEOUS INFORMATION. THE APPROPIATE          00106416
*                 PROCESSOR IS THEN BRANCHED TO TO HANDLE THE INPUT.    00106816
*                                                                       00107216
*                 IF THE USER CHOOSES OMIT THE NEXT EXTRACT RECORD IS   00107616
*                 READ AND A RECALL FRAME IS GENERATED FOR IT           00108016
*                                                                       00108416
*                 IF THE USER CHOOSES INSERT, IKAPCSR0 IS LINKED TO     00108816
*                 AND THE USER WILL SEE A SELECT FRAME. HIS SELECTION   00109216
*                 WILL BE HANDLED IN THE NORMAL MANNER. WHEN RECALL IS  00109616
*                 REENTERED IT WILL AGAIN GENERATE THE FRAME FROM WHICH 00110016
*                 THE USER CHOOSE THE INSERT OPTION.                    00110416
*                                                                       00110816
*                 DURING THE PROCESSING DESCRIBE ABOVE A NEW JCL DATA   00111216
*                 SET IS BEING BUILT AND THE NEW EXTRACTED RECORDS ARE  00111616
*                 BEING WRITTEN ON A NEW EXTRACT DATA SET.              00112016
*                                                                       00112416
*    INPUT     - ADDRESS OF CCT IN REGISTER 1                           00112816
*                ADDRESS OF TWO DATA CONTROL BLOCKS IN CCT              00113216
*                       CCTEDCBP FOR  GJPEXT                            00113616
*                       CCTEDCB1 FOR  GJPEXT1                           00114016
*                                                                       00114416
*    TABLES AND WORK AREA USED -                                        00114816
*                                                                       00115216
*                CONSOLE CONTROL TABLE (CCT)                            00115616
*                   PROCESSOR WORK AREA (CCTPWKA)                       00116016
*                   DIARY WORK AREA (CCTDIAWA)                          00116416
*                   PROCESSOR ECB (CCTPECB)(POSTCODE)                   00116816
*                   GJP STATUS BYTE (IGNORBIT)                          00117216
*                                   (SELMODE)                           00117616
*                                   (RECMODE)                           00118016
*                                                                       00118416
*                GETAREA: STORAGE AQUIRED BY GETMAIN                    00118816
*                   REGISTER SAVE AREA (GETSTART)                       00119216
*                   DOR CALLING SEQUENCE (DORATIR)                      00119616
*                   POINTER SAVE AREA (PNTSTRT)                         00120016
*                   LIST FOR READ MACRO (READMAC)                       00120416
*                   EXTRACTED RECORD READ IN AREA (EXTREC)              00120816
*                                                                       00121216
*                PARAMETER SELECT TABLES (PST)                          00121616
*                                                                       00122016
*                COMMAND SELECT TABLE (CST)                             00122416
*                                                                       00122816
*                ATTENTION CORRELATION TABLE (ACT)                      00123216
*                                                                       00123616
*                                                                       00124016
*    EXTERNAL REFERENCES -                                              00124416
*                                                                       00124816
*                BRANCH TO IKADIA FOR HISTORY AND RECORD FUNCTION       00125216
*                BRANCH TO IKADMSG TO DISPLAY MESSAGES                  00125616
*                BRANCH OR LINK TO ALL PROCESSORS                       00126016
*                BRANCH TO IKADGM TO GENERATE FRAMES                    00126416
*                BRANCH TO KYMANIP TO GENERATE OVERLAYS                 00126816
*                BRANCH TO IKADOR TO DISPLAY FRAMES                     00127216
*                BRANCH TO IKADIR TO READ INPUT BUFFER                  00127616
*                LINK TO IKAPCSR0 TO ACCEPT COMMANDS                    00128016
*                                                                       00128416
*    RESTRICTIONS - WHEN THE RECALL FUNCTION HAS BEEN SELECTED THERE    00128816
*                ARE ONLY FOUR WAYS TO TERMINATE IT.                    00129216
*                                                                       00129616
*                  1. RECALL READS LAST EXTRACTED RECORD FROM DATA SET. 00130016
*                                                                       00130416
*                  2. BY ACCEPTING A BEGIN JOB.                         00130816
*                                                                       00131216
*                  3. BY INSERTING A BEGIN JOB.                         00131616
*                                                                       00132016
*                  4. BY INSERTING A CANCEL JOB.                        00132416
*                                                                       00132816
*    ERROR CONDITIONS -                                                 00133216
*                                                                       00133616
*                KEY IN THE RECALLED RECORD CANNOT BE FOUND IN THE      00134016
*                COMMAND SELECT TABLE (CST).                            00134416
*                                                                       00134816
*                KEY IN THE RECALLED RECORD CANNOT BE FOUND IN THE      00135216
*                DISPLACEMENT TABLE (PNTDISTB) WHICH POINTS TO CURRENT  00135616
*                ITEM DISPLACEMENTS.                                    00136016
*                                                                       00136416
*                A RETURN OF HEX '80' FROM KYMANIP WHICH INDICATES THAN 00136816
*                AN OVERLAY CANNOT BE GENERATED FROM THE INPUT MAP IT   00137216
*                WAS PASSED.                                            00137616
*                                                                       00138016
*                AN INVALID RETURN CODE FROM A PROCESSOR. VALID RETURN  00138416
*                CODES ARE '00 04 08 0C 10 14 18'.                      00138816
*                                                                       00139216
*                IF NO ATTENTION CORRELATION TABLE (ACT) ENTRY CAN BE   00139616
*                FOUND FOR A DATA FIELD.                                00140016
*                                                                       00140416
*                                                                       00140816
*    RETURN CODES ISSUED -                                              00141216
*                                                                       00141616
*               '00' FOR NORMAL COMPLETION                              00142016
*               '0C' IF OMIT WAS ONLY OPTION TAKEN                      00142416
*                                                                       00142816
*                ANY CODE PASSED FROM THE PROCESSORS IF THE PROCESSOR   00143216
*                DOES NOT RETURN A CODE OF '00' OR '0C'. '0C' IS A      00143616
*                CANCEL CODE FROM THE PROCESSOR.                        00144016
*                                                                       00144416
*    EXIT      - RETURN TO IKACTL                                       00144816
*              - XCTL TO IKAPBEG0 IF BEGIN JOB OR BEGIN PROCEDURE       00145016
*                                                                       00145216
         EJECT                                                          00145616
*                                                                       00160016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         00240016
         SPACE                                                          00320016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    00400016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     00480016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       00560016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             00640016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  00720016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  00800016
*                   SET.                                                00880016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      00960016
*                   SECOND.                                             01040016
         SPACE 2                                                        01120016
CCT      DSECT                                                          01280016
         USING *,CCTR                                                   01360016
         SPACE                                                          01440016
*                             SECTION ONE                               01520016
         SPACE                                                          01600016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     01680016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    01760016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  01840016
         SPACE                                                          01920016
         DS    0F                                                       02000016
CCTUNAME DS    5F                  USER'S NAME                          02080016
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         02160016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     02240016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       02320016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    02400016
*                                       AT LAST BEGIN JOB               02480016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   02560016
*                                       LAST BEGIN JOB                  02640016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 02720016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    02800016
*                                       JOB                             02880016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    02960016
*                                       JOB                             03040016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     03120016
*                                       CESSOR                          03200016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         03280016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         03360016
CCTJCTR  DS    H                   JOB COUNTER                          03440016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                03520016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   03600016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  03680016
CCTSSTAT DS    C                   SESSION STATUS                       03760016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              03840016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              03920016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    04000016
         EJECT                                                          04080016
         SPACE 2                                                        04160016
*                             SECTION TWO                               04240016
         SPACE                                                          04320016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   04400016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  04480016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 04560016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              04640016
         SPACE                                                          04720016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     04800016
*                                       FRAME                           04880016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  04960016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     05040016
*                                       MULTIPLE DISPLAY FRAME (ENT)    05120016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   05200016
CCTDISM  DS    C                   DISPLAY MASK                         05280016
CCTCSM   DS    C                   COMMAND SELECT MASK                  05360016
CCTPSTAT DS    CL2                 GJP STATUS                           05440016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              05520016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  05600016
         SPACE 2                                                        05680016
*                             SECTION THREE                             05760016
         SPACE                                                          05840016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    05920016
*                   INTO SECTION ONE OR TWO                             06000016
         SPACE                                                          06080016
CCTDGMP  DS    F                  POINTER TO DGM                        06160016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                06240016
CCTCSTP  DS    F                  POINTER TO CST                        06320016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                06400016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            06480016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 06560016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              06640016
CCTDIARP DS    F                  POINTER TO DIA                        06720016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      06800016
CCTACTP  DS    F                  POINTER TO ACT                        06880016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     06960016
CCTIERRP DS    F                  POINTER TO IERR                       07040016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              07120016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               07200016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                07280016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 07360016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 07440016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   07520016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                07600016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                07680016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               07760016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              07840016
CCTPECB  DS    F                  PROCESSOR'S ECB                       07920016
CCTWECB  DS    F                  WTOR ECB                              08000016
CCTDIAWA DS    CL136               DIARY WORK AREA                      08080016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    08160016
CCTCSAVE DS    CL72                CTL SAVE AREA                        08240016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                08320016
CCTASAVE DS    CL72                DAT SAVE AREA                        08400016
         EJECT                                                          08480016
*                                                                       08560016
*  REGISTER EQUATES USED                                                08640016
*                                                                       08720016
         SPACE                                                          08800016
RPAR0    EQU   0                       PARAMETER REGISTER 0             08880016
RPAR1    EQU   1                       PARAMETER REGISTER 1             08960016
BASER    EQU   2                       BASE REGISTER                    09040016
CCTR     EQU   3                       CCT BASE REGISTER                09120016
GETR     EQU   4                       POINTER TO GETMAIN               09200016
EXTR     EQU   5                       POINTER TO EXTRACT RECORD        09280016
CSTR     EQU   6                       POINTER TO CST                   09360016
PNTAR    EQU   7                       A POINTER TO EXT DATA SET        09440016
WORKR1   EQU   9                       WORK REG 1                       09520016
WORKR2   EQU   10                      WORK REG 2                       09600016
WORKR3   EQU   11                      WORK REG 3                       09680016
WORKR4   EQU   12                      WORK REG 4                       09760016
RSAVE    EQU   13                      POINTER TO SAVE AREA             09840016
RRET     EQU   14                      RETURN REGISTER                  09920016
RBR      EQU   15                      BRANCH REGISTER                  10000016
         EJECT                                                          10080016
*                                                                       10160016
*  DSECT LAYOUT OF GETMAIN WORK AREA                                    10240016
*                                                                       10320016
         SPACE                                                          10400016
GETAREA  DSECT                                                          10480016
         USING *,GETR                                                   10560016
GETSTART DS    F                       INDICATOR BYTE AND STORAGE LGT   10640016
SAVE13   DS    F                       SAVE AREA FOR REG.13             10720016
         DS    16F                     ADDRESS OF MY SAVE AREA          10800016
         SPACE                                                          10880016
*   CALLING SEQUENCE FOR IKADOR                                         10960016
         SPACE                                                          11040016
DORATIR  DS    C                       CONTROL BITS                     11120016
DORORDAD DS    CL3                     ADDR OF ORDERS                   11200016
DORLEN   DS    F                       LENGTH OF ORDERS                 11280016
DORCUR   DS    H                       CURSOR ADDR                      11360016
DORINS   DS    H                       RELATIVE INPUT ADDR              11440016
DORCCT   DS    F                       ADDR OF CCT                      11520016
DORWKA   DS    14D                     WORK AREA FOR IKADOR             11600016
         SPACE                                                          11680016
*  POINTERS FOR CURRENT PROCESSORS AND SYSTEM MASKS AND POINTERS        11760016
         SPACE                                                          11840016
PNTSTRT  EQU   *                                                        11920016
CURRPROC DS    F                       ADDR OF CURRENT PROCESSOR        12000016
CPROCNM  DS    F                       CURRENT PROCESSOR NAME           12160016
PCON     DS    F                       CURRENT PROCESSOR KEY            12240016
CURRTAB  DS    F                       ADDR OF CURRENT PST              12320016
CTABNM   DS    F                       CURRENT TABLE NAME               12400016
TCON     DS    F                       CURRENT TABLE KEY                12480016
CTABNM2  DS    F                       INSERT TABLE NAME                12560016
TCON2    DS    F                       INSERT TABLE KEY                 12640016
LINKLIST DS    2F                      LIST FOR EXECUTE FORM OF LINK    12650016
IPROCNM  DS    F                       INSERT PROCESSOR NAME            12660016
ICON     DS    F                       INSERT PROCESSOR KEY             12680016
RECPST   DS    F                       ADDR OF RECALL PST               12720016
CSTSAV   DS    F                       ADDR OF COMMAND SELECT TABLE     12800016
CSMSAVP  DS    C                       COMMAND SELECT MASK PERMAMENT    12880016
CSMSAVD  DS    C                       COMMAND SELECT MASY DYNAMIC      12960016
DISMSAV  DS    C                       DISPLAY MASK                     13040016
NMSKSAV  DS    C                       NEXT MASK SAVE                   13120016
MODPSAV  DS    F                       POINTER TO MODEL IN WORK AREA    13200016
HISTPSAV DS    F                       POINTER TO HISTORY BEING BUILT   13280016
STATBIT  DS    C                       STATUS BITS                      13360016
RECCSM   DS    C                       RECALL COMMAND SELECT MASK       13440016
CODESAV  DS    H                       RETURN CODE SAVE AREA            13520016
RETSAV   DS    F                       RETURN ADDR SAVE                 13600016
DECHSN   DS    D                       PACKED DECIMAL HSN               13680016
EBDICHSN DS    D                       UNPACKED HSN                     13760016
POINTRA  DS    F                       PNTR TO END OF EXT DATA SET      13840016
HSNSAV   DS    H                       SAVE AREA FOR CURRENT HSN        13880016
KEYSAVE  DS    H                       SAVE AREA FOR EXTRACT KEY        13900016
PNTEND   EQU   *                                                        13920016
         SPACE                                                          14000016
*  SPACE FOR LIST FORM OF READ MACRO                                    14080016
         SPACE                                                          14160016
READMAC  DS    F                       ECB FOR READ                     14240016
RTYPE    DS    CL2                     TYPE RECORD                      14320016
RLENGTH  DS    CL2                     LENGTH                           14400016
RDCB     DS    F                       DCB ADDR                         14480016
RAREA    DS    F                       AREA ADDR                        14560016
RSTAT    DS    3F                      STATUS                           14640016
         SPACE                                                          14720016
*  SPACE TO READ EXTRACT RECORD INTO                                    14800016
         SPACE                                                          14880016
EXTREC   EQU   *                                                        14960016
OVERLAY  DS    F                       OVERLAY MASK FOR THIS FRAME      15040016
CMDKEY   DS    CL3                     CURRENT COMMAND KEY              15120016
SPOS     DS    C                       SCREEN POSITION                  15200016
DBEF     DS    C                       BEFORE DISPLAY MASK              15280016
DAFT     DS    C                       AFTER DISPLAY MASK               15360016
COMDMSK  DS    C                       COMMAND SELECT MASK              15440016
GJPSTAT  DS    CL2                     GJP STATUS                       15520016
         DS    CL5                     UNUSED                           15600016
HSN      DS    H                       HISTORY SEQUENCE NUM.            15680016
EXTDATA  DS    88F                     EXTRACTED DATA                   15760016
         SPACE                                                          15840016
GETEND   EQU   *                                                        15920016
         EJECT                                                          16000016
*                                                                       16080016
*  DSECT FOR GRAPHIC WORK AREA                                          16160016
*                                                                       16240016
         SPACE                                                          16320016
GRPWKA   DSECT                                                          16400016
         USING *,WORKR1                                                 16480016
OANXT    DS    F                       ORDER AREA NEXT AVAILABLE PNTR   16560016
OAPTRSV  DS    F                       ORDER AREA POINTER SAVE          16640016
ACTNXT   DS    F                       ACT NEXT AVAILABLE POINTER       16720016
ACTPTRSV DS    F                       ACT POINTER SAVE                 16800016
XPOS     DS    F                       X POSITION POINTER               16880016
YPOS     DS    F                       Y POSITION POINTER               16960016
         SPACE                                                          17040016
*                                                                       17120016
*  DSECT LAYOUT FOR HISTORY TABLES                                      17200016
*                                                                       17280016
         SPACE                                                          17360016
HISTAB   DSECT                                                          17440016
         USING *,WORKR3                                                 17520016
ENTLGTH  DS    H                       ENTRY LENGTH                     17600016
EXTDISP  DS    H                       EXTRACT DISP                     17680016
NUMCHAR  DS    H                       NUMBER OF CHAR'S                 17760016
HISTDISP DS    H                       HISTORY DISP                     17840016
CON      DS    CL8                     CONSTANT                         17920016
         SPACE                                                          18000016
*                                                                       18080016
*  DSECT LAYOUT FOR COMMAND SELECT TABLE ENTRIES                        18160016
*                                                                       18240016
         SPACE                                                          18320016
COMSTB   DSECT                                                          18400016
         USING *,CSTR                                                   18480016
TENTLGT  DS    C                       ENTRY LENGTH                     18560016
TCSMSK   DS    C                       COMMAND SELECT MASK              18640016
TTXTLGT  DS    C                       TEXT LENGTH                      18720016
         DS    C                       UNUSED                           18800016
TCMDSTAT DS    C                       COMMAND STATUS                   18880016
TNXTMULT DS    C                       POINTER TO NEXT MULTIPLE CHOICE  18960016
TNXTCMD  DS    C                       NEXT AVAILABLE COMMAND           19040016
TINLGT   DS    C                       INPUT DATA LENGTH                19120016
         DS    C                       GRID COLUMNS FOR X               19200016
         DS    C                       GRID LINES FOR Y                 19280016
TINMAP   DS    H                       INPUT MAPPING                    19360016
TKEY     DS    C                       COMMAND KEY                      19440016
         SPACE                                                          19520016
*                                                                       19600016
*  EQUATES USED                                                         19680016
*                                                                       19760016
         SPACE                                                          19840016
SELMODE  EQU   CCTPSTAT+1                                               19920016
IGNORBIT EQU   CCTPSTAT+1                                               20000016
RECMODE  EQU   CCTPSTAT+1                                               20080016
POSTCODE EQU   CCTPECB+3                                                20160016
GETLEN   EQU   PNTEND-PNTSTRT                                           20240016
ZERO     EQU   0                                                        20320016
ONE      EQU   1                                                        20400016
TWO      EQU   2                                                        20480016
THREE    EQU   3                                                        20560016
FOUR     EQU   4                                                        20640016
ENDCODE  EQU   4                                                        20720016
FIVE     EQU   5                                                        20800016
SIX      EQU   6                                                        20880016
ACTDATA1 EQU   6                                                        20960016
ACTDATA2 EQU   7                                                        21040016
ACTLNGTH EQU   8                                                        21120016
EIGHT    EQU   8                                                        21200016
KEY      EQU   12                                                       21280016
CANCEL   EQU   12                                                       21360016
BFRST    EQU   16                                                       21440016
BGNORD   EQU   48                                                       21520016
COMSELT  EQU   318                                                      21600016
ACCEPT   EQU   320                                                      21680016
REVIEW   EQU   322                                                      21760016
INSERT   EQU   324                                                      21840016
OMIT     EQU   326                                                      21920016
ENTX     EQU   350                 DISPLACEMENT OF 'MORE DATA' IN  GJPF 21940017
*                                  CCTPWKA FOR 'ENTER DATA' FRAME  GJPF 21960017
HEX00    EQU   X'00'                                                    22000016
OVRLY    EQU   X'01'                                                    22040016
PSTBIT   EQU   X'01'                                                    22080016
HEX01    EQU   X'01'                                                    22160016
ENDON    EQU   X'02'                                                    22240016
RECBIT   EQU   X'02'                                                    22320016
HEX02    EQU   X'02'                                                    22400016
HEX04    EQU   X'04'                                                    22480016
XCEPT    EQU   X'04'                                                    22560016
NOXCEPT  EQU   X'04'                                                    22580016
RVIEW    EQU   X'08'                                                    22600016
NOREV    EQU   X'08'                                                    22610016
MSGBIT   EQU   X'10'                                                    22620016
INDATA   EQU   X'20'                                                    22640016
RECON    EQU   X'21'                                                    22680016
NODISPBT EQU   X'24'                                                    22700016
CONTBITS EQU   X'2C'                                                    22720016
INSRT    EQU   X'30'                                                    22800016
MULTC    EQU   X'40'                                                    22880016
DCBBIT   EQU   X'40'                                                    22960016
HEX40    EQU   X'40'                                                    23040016
SELTOFF  EQU   X'7F'                                                    23120016
SELTBIT  EQU   X'80'                                                    23200016
JBCRDREQ EQU   X'C0'                                                    23280016
CONBIT   EQU   X'C8'                                                    23360016
JBLIBCRD EQU   X'CF'                                                    23440016
IGNOROFF EQU   X'DF'                                                    23520016
NOREC    EQU   X'DF'                                                    23600016
MSGOFF   EQU   X'EF'                                                    23640016
XCEPTOFF EQU   X'FB'                                                    23680016
RECOFF   EQU   X'FD'                                                    23760016
PSTOFF   EQU   X'FE'                                                    23840016
HEXFF    EQU   X'FF'                                                    23920016
MFTBIT   EQU   X'10'               BIT IN CCTDISM SET FOR MFT      IIXX 23940018
STATBYT  EQU   STATBIT                                                  23960016
MSG1     EQU   0                       DISP OF MSG1                     24000016
MSG2     EQU   MSG1+4                  DISP OF MSG2                     24080016
MSG3     EQU   MSG2+4                                                   24120016
         EJECT                                                          24160016
IKAPREC0 CSECT                                                          24240016
*0520,568000,684400,687200,822800                                  GJPF 24280017
*0520,356400,532100,577200,591200,675000,675985,684400-684800      0169 24290017
*     842800                                                       0169 24300017
*0460,293200-293400                                                IIXX 24310018
         SPACE                                                          24320016
*                                                                       24400016
*  SAVE REGISTERS AND SET UP BASE REGISTER                              24480016
*                                                                       24560016
         SPACE                                                          24640016
         SAVE  (14,12),,*              SAVE ALL REGISTERS               24720016
         SPACE                                                          24800016
         BALR  BASER,0                 ESTABLISH REG,2 AS BASE          24880016
         USING *,BASER                 USING REG 2                      24960016
         LR    CCTR,RPAR1              LOAD ADDR OF CCT INTO REG.3      25040016
         SPACE                                                          25120016
*                                                                       25200016
*  GET SPACE FOR SAVE AREA AND WORK AREA                                25280016
*                                                                       25360016
         SPACE                                                          25440016
         GETMAIN R,LV=GETEND-GETSTART  GET STORAGE                      25520016
         SPACE                                                          25600016
         LR    GETR,RPAR1              LOAD ADDR OF GETMAIN AREA        25680016
         XC    PNTSTRT(GETLEN),PNTSTRT  ZERO POINTER AREA               25760016
         ST    RPAR1,EIGHT(ZERO,RSAVE) STORE MY SAVE AREA ADDR          25840016
         ST    RSAVE,SAVE13            STORE HIGHER LEVEL SAVE AREA     25920016
         LR    RSAVE,RPAR1             LOAD ADDR OF SAVE AREA           26000016
         MVC   READMAC(RMACLEN),READB  MOVE READ MODEL                  26080016
         SPACE                                                          26160016
*                                                                       26240016
*  SET UP POINTERS TO EXTRACT DCB'S                                     26320016
*                                                                       26400016
         SPACE                                                          26480016
         MVC   RDCB(FOUR),CCTEDCBP     MOVE DCB ADDR                    26560016
         MVC   CCTEDCBP(FOUR),CCTEDCB1 MOVE POINTER TO WRITE DCB        26640016
         MVC   CCTEDCB1(FOUR),RDCB     MOVE POINTER TO READ DCB         26720016
         XI    CCTSSTAT,DCBBIT         TURN DCB INDICATOR OVER          26800016
         LA    EXTR,EXTREC             LOAD ADDR OF EXTRACT RECORD      26880016
         ST    EXTR,RAREA              STORE AREA ADDR IN READ MACRO    26960016
         LA    EXTR,EXTDATA            LOAD ADDR OF EXTRATED DATA       27040016
         OI    RECMODE,RECBIT          TURN ON RECALL MODE              27120016
         SPACE                                                          27200016
*                                                                       27280016
*  GO TO DIARY ROUTINE WITH RECALL KEYWORK                              27360016
*                                                                       27440016
         SPACE                                                          27520016
         MVC   CCTDIAWA+FIVE(SIX),RECALL     MOVE RECALL KEYWORD        27600016
         LR    RPAR1,CCTR              LOAD ADDR OF CCT                 27680016
         L     RBR,CCTDIARP            LOAD ADDR OF DIARY ROUTINE       27760016
         BALR  RRET,RBR                BRANCH TO DIARY ROUTINE          27840016
         SPACE                                                          27920016
*                                                                       28000016
*  LOAD RECALL PST                                                      28080016
*                                                                       28160016
         SPACE                                                          28240016
         LOAD  EP=IKATREC0             LOAD RECALL PST                  28320016
         ST    RPAR0,RECPST            SAVE ADDR OF PST                 28400016
         SPACE                                                          28480016
*                                                                       28560016
*  SAVE OLD STATUS BYTES AND INITIATE TO NEW STATUS                     28640016
*                                                                       28720016
         SPACE                                                          28800016
         MVC   CSTSAV(FOUR),CCTCSTP    SAVE CURRENT CST                 28880016
         MVC   CSMSAVP(ONE),CCTCSM     SAVE CURRENT CSM                 28960016
         ST    RPAR0,CCTCSTP           STORE RECALL PST POINTER         29040016
         OI    CCTPSTAT,JBCRDREQ       TURN ON JOB CARD REQ.            29120016
         NI    CCTPSTAT,JBLIBCRD       TURN OFF JOB CARD ENTERED        29200016
         MVI   CCTCSM,HEX01             INITIATE CSM TO AFTER LOGON     29280016
         NI    CCTDISM,MFTBIT      TURN OF ALL DISPLAY MASK BITS   IIXX 29290018
         NI    CCTADISM,MFTBIT     TURN OF ALL DISPLAY MASK BITS   IIXX 29300018
*                                  EXCEPT MFT BIT (CURRENT DISPLAY)IIXX 29310018
*                                  EXCEPT MFT BIT (LAST DISPLAY)   IIXX 29320018
         SPACE                                                          29360016
*                                                                       29440016
*  SET UP POINTERS TO EXTRACT DATA SET                                  29520016
*                                                                       29600016
         SPACE                                                          29680016
         L     RPAR0,CCTEDCB1          LOAD ADDR OF EXTRACT DCB FOR RD  29760016
         NOTE  (RPAR0)                 NOTE LOCATION OF LAST WRITE      29840016
         SPACE                                                          29920016
         LR    PNTAR,RPAR1             LOAD RETURNED ADDR               30000016
         C     PNTAR,ZEROS             IS A EQUAL TO ZERO               30080016
         BE    MVENOTE                 YES GO TO MOVE CCTENOTE          30160016
         A     PNTAR,ZERONE            ADD ONE TO POINTER A             30240016
         B     LDEDCB                  GO TO LOAD POINTER TO EXT DCB    30320016
         SPACE                                                          30400016
MVENOTE  L     PNTAR,CCTENOTE          LOAD ADDR OF LAST WRITE          30480016
LDEDCB   L     RPAR1,CCTEDCB1          LOAD ADDR OF EXTRACT DCB FOR RD  30560016
         POINT (RPAR1),ZERONE          POINT EXT DATA SET               30640016
         SPACE                                                          30720016
         L     RPAR1,CCTEDCBP          LOAD ADDR OF EXT DCB FOR WRITE   30800016
         POINT (RPAR1),ZERONE                                           30880016
         SPACE                                                          30960016
*                                                                       31040016
*  INITIALIZE JCL DATA SET TO WRITE AT ZERO ONE                         31120016
*                                                                       31200016
         SPACE                                                          31280016
         L     RPAR1,CCTJDCBP          LOAD ADDR OF JCL DCB             31360016
         POINT (RPAR1),ZERONE                                           31440016
         SPACE                                                          31520016
         ST    PNTAR,POINTRA           STORE POINTERS TO EXT DATA SET   31600016
         SPACE                                                          31680016
*                                                                       31760016
*  INITIALIZE PROCESSOR AND TABLE NAME CONSTANTS                        31840016
*                                                                       31920016
         SPACE                                                          32000016
         MVC   CPROCNM(EIGHT),PROCCON  MOVE PROC CONSTANT               32080016
         MVC   CTABNM(EIGHT),TABCON    MOVE TABLE CONSTANT              32160016
         MVC   CTABNM2(EIGHT),TABCON   MOVE TABLE CONSTANT              32240016
         MVC   IPROCNM(EIGHT),PROCCON  MOVE PROC CONSTANT               32280016
         SPACE                                                          32320016
*                                                                       32400016
*  GO TO READ FIRST EXTRACT RECORD                                      32480016
*                                                                       32560016
         SPACE                                                          32640016
TORDEXT  TM    STATBYT,ENDON           HAVE ALL RECORDS BEEN READ       32720016
         BO    EXIT                    YES GO TO EXIT                   32800016
         BAL   RRET,READEXT            BRANCH TO READ ROUTINE           32880016
         SPACE                                                          32960016
*                                                                       33040016
*  SCAN CST FOR ENTRY                                                   33120016
*                                                                       33200016
         SPACE                                                          33280016
SAVECSM  MVC   CSMSAVD(ONE),CCTCSM     SAVE DYNAMIC CSM                 33360016
         L     CSTR,CSTSAV             LOAD ADDR OF CST                 33440016
         SR    RPAR1,RPAR1                   ZERO PARAMETER REG         33520016
TSTLAST  CLC   TENTLGT(TWO),ZEROS      IS THIS LAST ENTRY               33600016
         BE    KEYERR                  YES GO TO KEY ERROR              33680016
         CLC   ZERO(THREE,EXTR),TKEY   ARE KEYS EQUAL                   33760016
         BE    TSTCSMD                       YES GO TO TEST CSM         33840016
         IC    RPAR1,TENTLGT           INSERT LENGTH OF ENTRY           33920016
         AR    CSTR,RPAR1                    ADD LENGTH FOR NEXT ENTRY  34000016
         B     TSTLAST                       GO TO TEST NEXT ENTRY      34080016
         SPACE                                                          34240016
*                                                                       34320016
*  TEST FOR ENTRY ALLOWED NOW                                           34400016
*                                                                       34480016
         SPACE                                                          34560016
TSTCSMD  IC    RPAR1,TCSMSK            INSERT COMMAND SELECT MASK       34640016
         EX    RPAR1,MSKTST             EXECUTE TEST INSTRUCTION        34720016
         BZ    NOTALWD                  ZEROS ENTRY NOT ALLOWED         34800016
         SPACE                                                          34880016
         SR    WORKR1,WORKR1           ZERO WORK REG                    34960016
         IC    WORKR1,COMDMSK          INSERT COMMAND MASK FROF EXT REC 35040016
         EX    WORKR1,MSKTST           EXECUTE TEST INSTRUCTION         35120016
         BO    ALOWALL                 ONES ALL OPTIONS ALLOWED         35200016
         CLI   COMDMSK,RECON           WAS RECALL DISPLAYED             35220016
         BE    ALOWALL                 YES ALLOW ALL APTIONS            35240016
         SPACE                                                          35280016
NOACCEPT MVI   RECCSM,NOXCEPT          MAKE RECALL SELECT MASK A HEX 4  35340016
         CLC   ZERO(THREE,EXTR),CONBEG IS IT A BEGIN JOB                35360016
         BE    NOTALWD                 YES GO TO NOT ALLOWED            35380016
         OI    STATBYT,RVIEW           TURN ON REVIEW BIT               35400016
         B     SAVMSK                  GO TO SAVE CMD MSK               35440016
         SPACE                                                          35520016
ALOWALL  CLC   ZERO(THREE,EXTR),CONBEG  IS IT A BEGIN JOB OR PROC       35560016
         BE    NOREVIEW                YES DO NOT ALLOW REVIEW          35600016
         OI    STATBYT,XCEPT           TURN ON ACCEPT BIT IN RECAL STAT 35620016
         MVI   RECCSM,HEX01            SET ON ALL OPTIONS               35680016
SAVMSK   MVC   NMSKSAV(ONE),TNXTCMD    SAVE NEXT AVAILABLE COMMAND MASK 35760016
         B     MVPSTPNT                GO TO MOVE PST POINTER           35840016
         SPACE                                                          35850016
NOREVIEW MVI   RECCSM,NOREV            MAKE RECALL SELECT MASK A HEX 8  35860016
         OI    STATBYT,XCEPT                                            35870016
         B     MVPSTPNT                GO TO MOVE PST POINTER           35880016
         SPACE                                                          35920016
MSKTST   TM    CCTCSM,HEX00            TEST FOR ENTRY ALLOWED           36000016
         SPACE                                                          36080016
NOTALWD  MVI   RECCSM,HEX02            SET ON OMIT OR INSERT ONLY       36160016
MVPSTPNT MVC   CCTCSTP(FOUR),RECPST    MOVE POINTER TO REC PST          36240016
         MVC   CCTCSM(ONE),RECCSM      MOVE RECALL SELECT MASK          36320016
         OI    SELMODE,SELTBIT         TURN ON COMMAND MODE             36400016
         TM    TCMDSTAT,PSTBIT         DOES CURRENT PROC HAVE A PST     36480016
         BO    TODGM                   NO GO TO DGM                     36560016
         OI    STATBYT,PSTBIT          TURN ON PST BIT                  36640016
         SPACE                                                          36720016
*                                                                       36800016
*  GO TO DGM ROUTINE TO GENERATE RECALL FRAME NO DISPLAY                36880016
*                                                                       36960016
         SPACE                                                          37040016
TODGM    LR    RPAR1,CCTR              LOAD ADDR OF CCT                 37120016
         L     RBR,CCTDGMP             LOAD ADDR OF DGM                 37200016
         BALR  RRET,RBR                BRANCH TO DGM                    37280016
         B     CONT                    BRANCH AROUND CONSTANT           37360016
         DC    X'4000'                 CODE FOR GENERATE BUT NO DISPLA 37440016
         SPACE                                                          37520016
CONT     MVC   CCTCSM(ONE),CSMSAVD     RESTORE COMMAND SELECT MASK      37600016
         SPACE                                                          37680016
*                                                                       37760016
*  MOVE CURRENT ITEM MODEL AND BUILD HISTORY ENTRY IN GRAPHIC WORK AREA 37840016
*                                                                       37920016
         SPACE                                                          38000016
         L     WORKR1,CCTGWRKP         LOAD ADDR OF GRAPHIC WORK AREA   38080016
         L     RPAR1,OAPTRSV           LOAD ADDR OF NEXT AVAILABLE AREA 38160016
         SH    RPAR1,CON4              SUBTRACT FOUR FROM NEXT AREA     38240016
         MVC   ZERO(MODLGT,RPAR1),CURRITEM          MOVE MODEL          38320016
         LA    WORKR3,PNTDISTB         LOAD ADDR OF POINTER DISP TAB    38400016
         MVC   KEYSAVE(THREE),ZERO(EXTR)    SAVE EXTRACT KEY            38420016
         CLC   KEYSAVE(THREE),CONBEG   IS KEY A BEG                     38440016
         BE    TSTYPE                  YES GO TEST TYPE                 38460016
COMPENTY CLI   ZERO(WORKR3),HEXFF      IS THIS END OF LIST              38480016
         BE    KEYERR                  YES GO TO KEY ERROR              38560016
         CLC   KEYSAVE(THREE),ZERO(WORKR3)   IS THIS THE ENTRY          38640016
         BE    LDTABLE                 YES GO TO LOAD TABLE ADDR        38720016
         LA    WORKR3,EIGHT(WORKR3)    ADD EIGHT TO MOVE TO NEXT        38800016
         B     COMPENTY                GO TO COMPARE NEXT ENTRY         38880016
         SPACE                                                          38890016
TSTYPE   CLI   FOUR(EXTR),C'/'         IS FIFTH CHAR A /                38900016
         BE    MOVEP                   YES GO MOVE IN A P               38910016
         B     COMPENTY                GO TO COMPARE FIRST ENTRY        38920016
MOVEP    MVI   KEYSAVE+TWO,C'P'        MOVE A P INTO KEYSAVE            38930016
         B     COMPENTY                GO TO COMPARE FIRST ENTRY        38940016
         SPACE                                                          38960016
LDTABLE  L     WORKR3,FOUR(WORKR3)     LOAD ADDR OF TABLE               39040016
         ST    RPAR1,MODPSAV           STORE ADDR OF BEGINNING OF MODEL 39120016
         LA    RPAR1,CURRBLNK-CURRST(RPAR1)  LOAD ADDR OF HISTORY       39200016
         ST    RPAR1,HISTPSAV          STORE ADDR OF HISTORY ENTRY      39280016
         MVC   ZERO(THREE,RPAR1),EBDICHSN+5   MOVE HISTORY SEQ. NUM.    39360016
         SPACE                                                          39440016
TSTEND   CLC   ENTLGTH(TWO),ONES       END OF TABLE                     39520016
         BE    INSTRU                  YES GO TO INSERT GTRU            39600016
         L     RPAR1,HISTPSAV          LOAD ADDR OF HISTORY             39680016
         CLC   EXTDISP(TWO),ZEROS      ENTRY IN EXTRACT RECORD          39760016
         BE    ADDNXT                  NO GO TO ADD NEXT BYTE           39840016
         LH    WORKR1,EXTDISP          LOAD EXTRACT DISPLACEMENT        39940016
         AR    WORKR1,EXTR             ADD BEGINNING OF EXTRACT RECORD  40080016
         AH    RPAR1,HISTDISP          ADD HISTORY DISPLACEMENT         40180016
         LH    WORKR2,NUMCHAR          LOAD NUMBER OF CHAR'S TO MOVE    40280016
         EX    WORKR2,MOVE1            EXECUTE MOVE INSTRUCTION         40480016
         AH    WORKR3,ENTLGTH          MOVE TO NEXT ENTRY               40580016
         B     TSTEND                  GO TO TEST FOR END               40720016
LSTEND   DC    F'0'                                                     40800016
         SPACE                                                          40880016
MOVE1    MVC   ZERO(ZERO,RPAR1),ZERO(WORKR1)     MOVE INSTRUCTION ONE   40960016
MOVE2    MVC   ZERO(ZERO,RPAR1),CON              MOVE INSTRUCTION TWO   41040016
         SPACE                                                          41120016
ADDNXT   AH    RPAR1,HISTDISP          ADD DISP TO BEGIN OF HISTORY     41220016
         LH    WORKR2,NUMCHAR          LOAD NUMBER OF CHAR'S TO MOVE    41320016
         EX    WORKR2,MOVE2            EXECUTE MOVE INSTRUCTION         41420016
         AH    WORKR3,ENTLGTH          MOVE TO NEXT ENTRY               41520016
         B     TSTEND                  GO TO TEST END                   41760016
         SPACE                                                          41840016
*                                                                       41920016
*  INSERT GTRU AT END OF ORDERS                                         42000016
*                                                                       42080016
         SPACE                                                          42160016
INSTRU   L     WORKR1,CCTDDCBP         LOAD 2250 DCB ADDR               42240016
         LH    WORKR3,BFRST(WORKR1)    LOAD BUFFER START ADDR           42320016
         L     WORKR1,HISTPSAV         LOAD ADDR OF HISTORY             42400016
         STH   WORKR3,GTRUE(ZERO,WORKR1)     STORE BUFFER START ADDR    42480016
         SPACE                                                          42560016
*                                                                       42640016
*  BUILD NEW ACT ENTRY AND ADJUST POINTER TO ORDER AREAS                42720016
*                                                                       42800016
         SPACE                                                          42880016
BLDACT   L     WORKR1,CCTGWRKP         LOAD ADDR OF GRAPHIC WORK AREA   42960016
         L     WORKR3,MODPSAV          LOAD ADDR OF MODEL               43040016
         ST    WORKR3,DORATIR          STORE ORDER ADDR                 43120016
         LA    WORKR3,MODLGT(ZERO,WORKR3)    ADD LENGTH OF ORDERS       43200016
         ST    WORKR3,OANXT            STORE AS NEXT AVAILABLE ORDER AR 43280016
         ST    WORKR3,OAPTRSV          SAVE NEXT AVAILABLE ORERER AREA  43360016
         L     WORKR3,MODPSAV          LOAD BEGINNING OF MODEL          43440016
         L     WORKR2,ACTPTRSV         LOAD NEXT ACT ENTRY ADDR         43520016
         LA    RPAR1,BGNORD(WORKR1)    LOAD ADDR OF ORDER AREA          43600016
         SR    WORKR3,RPAR1            GET DISPLACEMENT OF ORDERS       43680016
         MVC   ZERO(TWO,WORKR2),ONES   MOVE HALF WORD OF ONES           43760016
         STH   WORKR3,TWO(WORKR2)      STORE DISPLACEMENT IN ACT        43840016
         LA    WORKR3,ORDLGT(WORKR3)   ADD LENGTH OF ORDERS             43920016
         STH   WORKR3,FOUR(WORKR2)     STORE END DISP OF ORDERS         44000016
         XC    SIX(TWO,WORKR2),SIX(WORKR2)   ZERO 4TH HALF WORD OF ACT  44080016
         MVC   EIGHT(FOUR,WORKR2),ONES MOVE ONES TO END OF ACT          44160016
         LA    WORKR2,ACTLNGTH(WORKR2) ADD LENGTH OF ACT ENTRY          44240016
         ST    WORKR2,ACTNXT           STORE ADDR OF NEXT ACT ENTRY     44320016
         ST    WORKR2,ACTPTRSV         SAVE ADDR OF NEXT ACT ENTRY      44400016
         SPACE                                                          44480016
*                                                                       44560016
*  BUILD CALLING SEQUENCE FOR IKADOR                                    44640016
*                                                                       44720016
         SPACE                                                          44800016
         TM    STATBYT,MSGBIT          Q. ERROR MSG TO DISPLAY          44830016
         BZ    BLDSEQ                  NO BUILD NORMAL SEQ              44860016
         MVI   DORATIR,NODISPBT        MOVE NO DISPLAY CONTROL BITS     44890016
         B     MVORDLGT                GO TO MOVE ORDER LENGTH          44920016
         SPACE                                                          44950016
BLDSEQ   MVI   DORATIR,CONTBITS        MOVE CONTROL BITS                44980016
MVORDLGT MVC   DORLEN(FOUR),ORDLENGT   MOVE LENGTH OF ORDERS            45010016
         ST    CCTR,DORCCT             STORE CCT ADDR                   45040016
         LA    RPAR1,DORATIR           LOAD ADDR OF CALLING SEQUENCE    45120016
         LA    RPAR0,DORWKA            LOAD ADDR OF DOR WORK AREA       45200016
         L     RBR,CCTDORP             LOAD ADDR OF IKADOR              45280016
         BALR  RRET,RBR                BRANCH TO IKADOR                 45360016
         SPACE                                                          45370016
         TM    STATBYT,MSGBIT          Q. ERROR MSG TO DISPLAY          45380016
         BZ    LDPROC                  NO GO LOAD PROCESSOR             45390016
         NI    STATBYT,MSGOFF          TURN OFF MESSAGE BIT             45400016
         LA    RRET,LDPROC             LOAD ADDR OF RETURN              45410016
         BAL   RPAR1,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    45420016
         DC    AL2(MSG3)               DISP OF ERROR MSG 2              45430016
         SPACE                                                          45440016
*                                                                       45520016
*  DELETE CURRENT PROCESSOR IF ANY AND LOAD DEFAULT PROCESSOR*          45600016
*                                                                       45680016
         SPACE                                                          45720016
LDPROC   CLC   CURRPROC(FOUR),ZEROS    IS THERE A PROCESSOR PRESENT     45760016
         BE    LOADDFLT                NO GO TO LOAD DEFAULT            45840016
         LA    RPAR1,CPROCNM           LOAD ADDR OF CURRENT PROCESSOR   45920016
         DELETE EPLOC=(RPAR1)          DELETE CURRENT PROCESSOR         46000016
         SPACE                                                          46080016
         XC    CURRPROC(FOUR),CURRPROC ZERO POINTER TO CURRENT PROC     46160016
LOADDFLT TM    STATBYT,XCEPT+RVIEW     IS REVIEW AND ACCEPT DISPLAYED   46240016
         BZ    DELPST                  NO GO TO DELETE CURRENT PST      46320016
         CLC   ZERO(THREE,EXTR),CONBEG  IS PROCESSOR BEGIN JOB          46340016
         BE    DELPST                  YES GO TO DELETE CURRENT PST     46360016
         MVC   PCON(THREE),ZERO(EXTR)  MOVE KEY TO CONSTANT             46400016
         SPACE                                                          46480016
         LOAD  EPLOC=CPROCNM                                            46560016
         ST    RPAR0,CURRPROC          STORE ADDR OF CURRENT PROCESSOR  46640016
*                                                                       46720016
*  DELETE CURRENT PARAMETER SELECT TABLE IF ANY AND LOAD DEFAULT        46800016
*                                                                       46880016
         SPACE                                                          46960016
DELPST   CLC   CURRTAB(FOUR),ZEROS                                      47040016
         BE    TSTFRPST                                                 47120016
         SPACE                                                          47200016
         DELETE  EPLOC=CTABNM          DELETE CURRENT PST               47280016
         SPACE                                                          47360016
         XC    CURRTAB(FOUR),CURRTAB   ZERO POINTER TO CURRENT PST      47440016
TSTFRPST TM    STATBYT,PSTBIT          DOES CURR PROC HAVE A PST        47520016
         BZ    TRNIGNOF                NO GO TO TURN IGNORE ATTN OFF    47600016
         MVC   TCON(THREE),ZERO(EXTR)  MOVE KEY TO TABLE CONSTANT       47680016
         SPACE                                                          47760016
         LOAD  EPLOC=CTABNM            LOAD DEFAULT TABLE               47840016
         SPACE                                                          47920016
         ST    RPAR0,CURRTAB           STORE ADDR OF CURRENT PST        48000016
TRNIGNOF NI    IGNORBIT,IGNOROFF       TURN OFF IGNORE ATTN BIT         48080016
         SPACE                                                          48160016
         WAIT  ECB=CCTPECB             WAIT FOR ECB TO BE POSTED        48240016
         SPACE                                                          48320016
         TM    POSTCODE,EIGHT          IS POST CODE CANCEL              48400016
         BO    CLEARIT                 YES GO REDISPLAY RECALL FRAME    48480016
         TM    POSTCODE,X'1C'          IS POST CODE 1C             GJPF 48500017
         BO    ERRORTN                 YES GO TO ERROR RETURN      GJPF 48520017
         XC    CCTPECB(FOUR),CCTPECB   CLEAR PROCESSOR ECB              48560016
         SPACE                                                          48640016
*                                                                       48720016
*  MAKE SURE ONLY ONE OPTION WAS SELECTED                               48800016
*                                                                       48880016
         SPACE                                                          48960016
         SR    WORKR1,WORKR1           ZERO REG TO BE USED FOR COUNT    49040016
         LA    WORKR2,FOUR             LOAD NUMBER OF OPTIONS           49120016
         LA    WORKR3,CCTPWKA          LOAD ADDR OF PROCESSOR WORK AREA 49200016
         SPACE                                                          49280016
COMP     CLC   ACCEPT(TWO,WORKR3),BLANK   WAS AN OPTION SELECTED        49360016
         BNE   ADDONE                  YES GO TO ADD TO COUNT           49440016
NXTCMD   LA    WORKR3,TWO(WORKR3)      MOVE TO NEXT OPTION              49520016
         BCT   WORKR2,COMP             IF MORE BRANCH TO COMPARE        49600016
         B     TSTTOT                  GO TO TEST FOR TOTAL             49680016
         SPACE                                                          49760016
ADDONE   LA    WORKR1,ONE(WORKR1)      ADD ONE TO COUNT                 49840016
         B     NXTCMD                  GO TO MOVE TO NEXT               49920016
         SPACE                                                          50000016
TSTTOT   C     WORKR1,ZERONE           COMPARE TOTAL TO ONE             50080016
         BNH   TSTOPTNS                TOTAL NOT MORE THAN ONE          50160016
         SPACE                                                          50240016
*                                                                       50320016
*  ERROR MORE THAN ONE CHOICE                                           50400016
*                                                                       50480016
         SPACE                                                          50560016
         LA    RRET,TCOMDBIT           LOAD ADDR OF RETURN              50640016
         BAL   RPAR1,MSGSUB            LOAD REG AND BRANCH TO MSG SUB   50720016
         DC    AL2(MSG2)               DISP OF ERROR MSG 2              50800016
         SPACE                                                          50880016
*                                                                       50960016
*  DETERMINE TYPE OF OPTION SELECTED IF NONE DEFAULT TO ACCEPT          51040016
*                                                                       51120016
         SPACE                                                          51200016
TSTOPTNS LA    RPAR1,CCTPWKA           LOAD ADDR OF PROCESSOR WORK AREA 51280016
         CLC   INSERT(TWO,RPAR1),BLANK IS OPTION INSERT                 51360016
         BNE   RSTCST                  YES GO TO RESTORE CST            51440016
         NI    SELMODE,SELTOFF         TURN OF COMMAND SELECT MODE BIT  51520016
         CLC   REVIEW(TWO,RPAR1),BLANK   IS OPTION REVIEW               51600016
         BNE   LOADPST                 YES GO TO LOAD PST               51680016
         CLC   OMIT(TWO,RPAR1),BLANK   IS OPTION OMIT                   51760016
         BNE   SETOFF                  YES GO TO SET ACCEPT OFF         51840016
         CLC   ACCEPT(TWO,RPAR1),BLANK IS OPTION ACCEPT                 51920016
         BNE   TSTPST                  YES GO TO TEST FOR A PST         52000016
         TM    STATBYT,XCEPT           WAS ACCEPT DISPLAYED             52080016
         BO    TSTPST                  YES GO TO TEST FOR A PST         52160016
         SPACE                                                          52240016
*                                                                       52320016
*  ERROR NO CHOICE WAS MADE                                             52400016
*                                                                       52480016
         LA    RRET,TCOMDBIT           LOAD ADDR OF RETURN              52560016
         BAL   RPAR1,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    52640016
         DC    AL2(MSG1)               DISPLACEMENT OF ERROR MSG        52720016
         SPACE                                                          52800016
TCOMDBIT OI    SELMODE,SELTBIT         TURN ON COMMAND SELECT MODE BIT  52880016
         B     TRNIGNOF                GO TURN OF INGNORE ATTN BIT      52960016
         SPACE                                                          53040016
SETOFF   NI    STATBYT,HEXFF-RVIEW-XCEPT-PSTBIT  TURN OFF STATUS BITS   53140016
         B     TORDEXT                 GO TO READ NEXT EXTRACT RECORD   53280016
CLEARIT  XC    CCTPECB(FOUR),CCTPECB   CLEAR PROCESSOR ECB              53300016
         B     SAVECSM                 GO SAVE COMMAND SELECT MASK      53320016
         SPACE                                                          53360016
         EJECT                                                          53440016
**********************************************************************  53520016
*                                                                       53600016
*  OPTION WAS INSERT RESTORE POINTERS AND GENERATE A SELECT FRAME       53680016
*                                                                       53760016
**********************************************************************  53840016
         SPACE                                                          53920016
RSTCST   MVC   CCTCSTP,CSTSAV          RESTORE POINTER TO CST           54000016
         NI    CCTCSM,NOREC            ZERO RECALL BIT IN CCTCSM        54080016
         MVC   HSNSAV(2),CCTHSN+2      SAVE CURRENT HIST SEQ NO.        54120016
         LR    RPAR1,CCTR              LOAD ADDR OF CCT                 54160016
         L     RBR,CCTDGMP             LOAD ADDR OF DGM                 54240016
         BALR  RRET,RBR                BRANCH TO DGM                    54320016
         B     LINKCSR                 BRANCH AROUND CONSTANT           54400016
         DC    X'C000'                 ORDER SELECT FRAME DISPLAYED     54480016
         SPACE                                                          54560016
*                                                                       54640016
*  LINK TO IKAPCSR0 TO ACCEPT COMMAND SELECTION                         54720016
*                                                                       54800016
LINKCSR  LR    RPAR1,CCTR              LOAD CCT ADDR                    54880016
         XC    CCTPECB(FOUR),CCTPECB   CLEAD PROCESSOR ECB              54960016
         NI    IGNORBIT,IGNOROFF       TURN OFF IGNORE ATTN BIT         55040016
         LINK  EP=IKAPCSR0             LINK TO COMMAND SELECT ROUTINE   55120016
         SPACE                                                          55200016
*                                                                       55280016
*  CHECK FOR CANCEL OF COMMAND SELECT FRAME  IF A CHOICE WAS MADE       55360016
*  REDISPLAY FRAME IF NONE WAS MADE DISPLAY RECALL FRAME                55440016
*                                                                       55520016
         SPACE                                                          55600016
         CH    RBR,CON8                WAS FRAME CANCELED               55680016
         BE    TODIR                   YES GO TO DIR TO READ BUFFER     55760016
         CH    RBR,ERRCODE             IS RETURN CODE 1C           GJPF 55780017
         BE    ERRORTN                 YES GO TO ERROR RETURN      GJPF 55800017
         SPACE                                                          55840016
         NI    SELMODE,SELTOFF         TURN OF COMMAND SELECT MODE BIT  55920016
         CLC   CCTCPSTP(FOUR),ZEROS    IS THERE A PST PRESENT           56000016
         BE    TOPROC                  NO GO DIRECT TO PROCESSOR        56080016
         SPACE                                                          56160016
*                                                                       56240016
*  GO TO DGM TO DISPLAY PRAMATER SELECT FRAME                           56320016
*                                                                       56400016
         SPACE                                                          56480016
RPTFRM   LR    RPAR1,CCTR              LOAD ADDR OF CCT                 56560016
         L     RBR,CCTDGMP             LOAD ADDR OF DGM                 56640016
         BALR  RRET,RBR                BRANCH TO IKADGM                 56720016
         B     TOCHKERR                GO CHECK RETURN CODE        GJPF 56800017
         DC    X'C000'                 GENERATE AND DISPLAY PST         56880016
         SPACE                                                          56900017
TOCHKERR CH    RBR,ERRCODE             IS RETURN CODE 1C           GJPF 56920017
         BE    ERRORTN                 YES GO TO ERROR RETURN      GJPF 56940017
         SPACE                                                          56960016
*                                                                       57040016
*  LINK TO PROCESSOR TO PROCESS INPUT                                   57120016
*                                                                       57200016
         SPACE                                                          57280016
TOPROC   MVC   ICON(THREE),CCTCCR      MOVE KEY TO INSERT PROC CONSTANT 57330016
         CLC   CCTCCR(THREE),CONBEG    IS KEY BEG                       57380016
         BE    BEGINJOB                YES BRANCH TO BEGIN JOB          57400016
         XC    LINKLIST(8),LINKLIST    CLEAR LIST AREA FOR LINK MACRO   57480016
         LA    WORKR1,IPROCNM          LOAD ADDR OF INSERT PROC NAME    57560016
         LA    RBR,LINKLIST            LOAD ADDR OF LINK LIST           57600016
         XC    CCTPECB(FOUR),CCTPECB   CLEAR PROCESSOR ECB              57680016
         NI    IGNORBIT,IGNOROFF       TURN OFF IGNORE ATTN BIT         57760016
         LR    RPAR1,CCTR              LOAD CCT ADDR                    57840016
         SPACE                                                          57920016
         LINK  EPLOC=(WORKR1),MF=(E,(1)),SF=(E,(15))    LINK TO PROC    58000016
         SPACE                                                          58080016
*                                                                       58160016
*  ANALIZE RETURN CODE TO DETERMINE NEXT STEP                           58240016
*                                                                       58320016
         SPACE                                                          58400016
         MVC   CCTADISM(ONE),CCTDISM   MOVE AFTER DISPLAY MASK          58440016
         CH    RBR,CONC                WAS RETURN CODE CANCEL           58480016
         BE    HSNRST                  YES GO RESTORE OLD HSN           58560016
         CH    RBR,ZEROS               WAS RETURN CODE ZERO             58640016
         BE    UPDCSM                  YES GO TO UPDATE CCTCSM          58720016
         CH    RBR,CON4                WAS RETURN CODE FOUR             58800016
         BE    RPTFRM                  YES GO TO REPEAT FRAME           58880016
         CH    RBR,CON8                WAS RETURN CODE EIGHT            58960016
         BE    RETURN                  YES RETURN TO IKACTL             58980016
         CH    RBR,CON10               WAS RETURN CODE HEX TEN          59000016
         BE    RETURN                  YES RETURN TO IKACTL             59040016
         CH    RBR,CON14               WAS RETURN CODE HEX 14           59080016
         BE    DELTAB                  YES GO TO DELETE PST        0169 59100017
         CH    RBR,ERRCODE             IS RETURN CODE 1C           GJPF 59130017
         BE    ERRORTN                 YES                         GJPF 59140017
         B     ERROR                   NO INVALID RETURN CODE ERROR     59160016
         SPACE                                                          59170016
HSNRST   MVC   CCTHSN+2(2),HSNSAV      RESTORE OLD HSN                  59180016
DELTAB   MVC   TCON2(THREE),CCTCCR     MOVE CMD KEY TO TABLE CON   0169 59182017
         DELETE  EPLOC=CTABNM2         DELETE CURRENT PST          0169 59184017
         SPACE                                                          59186017
         XC    CCTCPSTP(FOUR),CCTCPSTP  ZERO PST POINTER           0169 59188017
         B     MVPSTPNT                GO GENERATE NEW RECALL FRAME     59190016
         SPACE                                                          59200016
*                                                                       59280016
*  SELECT FRAME WAS CANCELED DETERMINE IF ANY COMMANDS WERE SELECTED    59360016
*                                                                       59440016
         SPACE                                                          59520016
TODIR    MVC   CCTHSN+2(2),HSNSAV      RESTORE OLD HSN                  59570016
         LR    RPAR1,CCTR              LOAD ADDR OF CCT                 59620016
         L     RBR,CCTDIRP             LOAD ADDR OF IKADIR              59680016
         BALR  RRET,RBR                BRANCH TO IKADIR                 59760016
         SPACE                                                          59840016
         CLC   CCTPWKA+COMSELT(14),BLANK    WAS ANY COMMAND SELECTED    59920016
         BE    MVPSTPNT                NO GO REGEN RECALL FRAME         60000016
         B     RSTCST                  GO TO GENERATE NEW SELECT FRAME  60080016
         SPACE                                                          60160016
*                                                                       60240016
*  UPDATE NEXT AVAILABLE COMMAND MASK                                   60320016
*                                                                       60400016
         SPACE                                                          60480016
UPDCSM   L     CSTR,CSTSAV             LOAD ADDR OF COMMAND SELECT TAB  60560016
         SR    WORKR1,WORKR1           ZERO WORK REG                    60640016
COMPEND  CLC   TENTLGT(TWO),ZEROS      IS THIS END OF TABLE             60720016
         BE    KEYERR                  YES GO TO ERROR ROUTINE          60800016
         CLC   CCTCCR(THREE),TKEY      IS THIS ENTRY JUST SELECTED      60880016
         BE    MVMSK                   YES GO TO MOVE CSM               60960016
         IC    WORKR1,TENTLGT          INSERT ENTRY LENGTH              61040016
         AR    CSTR,WORKR1             MOVE CST POINTER TO NEXT ENTRY   61120016
         B     COMPEND                 GO TO COMPARE FOR END            61200016
         SPACE                                                          61280016
MVMSK    MVC   CCTCSM(ONE),TNXTCMD     MOVE NEW COMMAND SELECT MASK     61360016
         CLC   CCTCCR(THREE),CONCAN    WAS PROCESSOR CANCEL JOB         61380016
         BE    RETURN                  YES RETURN TO CALLER             61400016
         NI    STATBYT,XCEPTOFF        TURN OFF ACCEPT BIT              61460016
         CLC   CCTCPSTP(FOUR),ZEROS    WAS A PST LOADED                 61520016
         BE    SAVECSM                 NO GO TO REDISPLAY RECALL FRAME  61600016
         MVC   TCON2(THREE),CCTCCR     MOVE COMMAND KEY TO TABLE CON    61680016
         SPACE                                                          61760016
         DELETE EPLOC=CTABNM2          DELTET PST                       61840016
         SPACE                                                          61920016
         XC    CCTCPSTP(FOUR),CCTCPSTP CLEAR PST POINTER                62000016
         B     SAVECSM                 GO TO REDISPLAY RECALL FRAME     62080016
         SPACE                                                          62160016
         EJECT                                                          62240016
**********************************************************************  62320016
*                                                                       62400016
*  OPTION WAS ACCEPT IF THERE IS NO PST FOR THIS PROCESSOR BRANCH TO IT 62480016
*                                                                       62560016
**********************************************************************  62640016
         SPACE                                                          62720016
TSTPST   TM    STATBYT,PSTBIT          DOES CURR PROC HAVE A PST        62800016
         BZ    TSTBEGIN                NO GO TO TEST FOR BEGIN PROC     62880016
         L     CSTR,CURRTAB            LOAD CURRENT PST ADDR            62960016
CLRWKA   MVI   CCTPWKA,C' '            MOVE A BLANK TO PROC WORK AREA   63040016
         MVC   CCTPWKA+1(251),CCTPWKA  MOVE BLANKS TO ALL OF            63120016
         MVC   CCTPWKA+251(100),CCTPWKA WORK AREA                       63200016
         MVC   CCTPWKA(THREE),ZERO(EXTR)     MOVE KEY TO WORK AREA      63280016
         SPACE                                                          63360016
*                                                                       63440016
*  MOVE FIELDS WHICH CONTAIN DATA TO PROCESSOR WORK AREA                63520016
*                                                                       63600016
         SPACE                                                          63680016
         LA    WORKR4,CCTPWKA                                           63760016
         SR    WORKR3,WORKR3           ZERO WORK REG                    63840016
TABEND   CLC   TENTLGT(TWO),ZEROS      IS THIS END IF TABLE             63920016
         BE    POSTPROC                YES GO TO POST PROCESSOR         64000016
         TM    TINLGT,HEXFF            DOES THIS ENTRY HAVE INPUT DATA  64080016
         BZ    NEXTENT                 NO GO TO NEXT ENTRY              64160016
         LH    WORKR2,TINMAP           LOAD INPUT MAPPING               64240016
         LR    RPAR1,WORKR2            LOAD INPUT MAPPING TO PARM REG   64320016
         AR    WORKR2,EXTR             ADD BEGINNING OF EXT RECORD      64400016
         TM    ZERO(WORKR2),X'37'      IS THIS AN END DELIMETER         64480016
         BO    NEXTENT                 YES GO TO NEXT ENTRY             64560016
         AR    RPAR1,WORKR4            ADD BEGINNING OF WORK AREA       64640016
         IC    WORKR3,TINLGT           INSERT INPUT DATA LENGTH         64720016
         BCT   WORKR3,NEXT             SUBTRACT ONE FROM INPUT LENGTH   64800016
NEXT     EX    WORKR3,MVDATA           EXECUTE MOVE DATA FIELDS         64880016
         SPACE                                                          64960016
NEXTENT  IC    WORKR3,TENTLGT          INSERT EXTRY LENGTH              65040016
         AR    CSTR,WORKR3             ADD ENTRY LENGTH TO MOVE TO NEXT 65120016
         B     TABEND                  GO TO TEST FOR END OF TABLE      65200016
         SPACE                                                          65280016
MVDATA   MVC   ZERO(ZERO,RPAR1),ZERO(WORKR2) MOVE FIELDS TO EXT RECORD  65360016
         SPACE                                                          65370016
TSTBEGIN CLC   ZERO(FIVE,EXTR),BEGP    IS IT A BEGIN PROCEDURE          65380016
         BNE   INCHSN                                                   65390016
         L     CSTR,CSTSAV             LOAD ADDR OF COMMAND SELEC TABLE 65400016
         B     CLRWKA                  GO TO CLEAR WORK AREA            65410016
         SPACE                                                          65440016
*                                                                       65520016
*  POST PROCESSOR INCREMENT HSN AND BRANCH TO PROCESSOR                 65600016
*                                                                       65680016
         SPACE                                                          65760016
POSTPROC POST  CCTPECB,ENDCODE         POST END CODE                    65840016
         OI    CCTPSTAT,XCEPT          TURN ON ACCEPT MODE BIT     0169 65880017
         SPACE                                                          65920016
INCHSN   LH    WORKR1,CCTHSN+TWO       LOAD HISTORY SEQ. NUM.           66000016
         STH   WORKR1,HSNSAV           SAVE CURRENT HSN                 66040016
         LA    WORKR1,ONE(WORKR1)      ADD ONE                          66080016
         STH   WORKR1,CCTHSN+TWO       STORE HISTORY SEQ. NUM.          66160016
         SPACE                                                          66240016
         CLC   ZERO(THREE,EXTR),CONBEG  IS PROCESSOR BEGIN JOB          66260016
         BE    BEGINJOB                YES BRANCH TO BEGIN JOB          66280016
         L     RBR,CURRPROC            LOAD ADDR OF CURRENT PROCESSOR   66320016
         LR    RPAR1,CCTR              LOAD ADDR OF CCT                 66400016
         BALR  RRET,RBR                BRANCH TO PROCESSOR              66480016
         SPACE                                                          66560016
*                                                                       66640016
*  TEST RETURN CODE IF EIGHT RETURN TO CALLER  IF TWELVE REDISPLAY      66720016
*   RECALL FRAME                                                        66800016
*                                                                       66880016
         SPACE                                                          66960016
         MVC   CCTADISM(ONE),CCTDISM   MOVE AFTER DISPLAY MASK          67000016
         NI    CCTPSTAT,XCEPTOFF       TURN OFF ACCEPT MODE BIT    0169 67020017
         CH    RBR,CON8                IS RETURN CODE EIGHT             67040016
         BE    RETURN                  YES GO TO RETURN                 67120016
         CH    RBR,CONC                IS RETURN CODE TWELVE            67200016
         BE    RSTHSN                  YES GO TO RESTORE CURRENT HSN    67280016
         CH    RBR,CON14               WAS RETURN CODE HEX 14           67300016
         BE    MOVCCTCR                YES GO MOVE CURRENT CMD KEY      67320016
         CH    RBR,CON18               WAS RETURN CODE HEX 18           67330016
         BE    DISPMSG                 YES GO DISPLAY ERROR MSG         67340016
         CH    RBR,ERRCODE             IS RETURN CODE 1C           GJPF 67346017
         BE    ERRORTN                 YES GO TO ERROR RETURN      GJPF 67352017
         MVC   CCTCSM(ONE),NMSKSAV     UPDATE COMMAND SELECT MASK       67360016
MOVCCTCR MVC   CCTCCR(THREE),ZERO(EXTR)   MOVE CURRENT COMMAND KEY      67410016
         MVC   CCTCPSTP(FOUR),CURRTAB  MOVE CURRENT TABLE ADDR TO CCT   67460016
         NI    STATBYT,HEXFF-RVIEW-XCEPT-PSTBIT  TURN OFF STATUS BITS   67480016
         B     TORDEXT                 GO TO READ NEXT EXTRACT RECORD   67520016
         SPACE                                                          67540016
RSTHSN   MVC   CCTHSN+TWO(TWO),HSNSAV  RESTORE OLD HSN                  67560016
         MVC   CCTDISM,DISMSAV         RESTORE CURRENT DISPLAY MASKGJPF 67570017
         B     SAVECSM                 GO TO REDISPLAY RECALL FRAME     67580016
         SPACE                                                          67585016
BEGINJOB LA    RBR,FIVE                LOAD RETURN OF FIVE              67590016
         B     RETURN                  BRANCH TO RETURN                 67595016
         SPACE                                                          67595716
DISPMSG  OI    STATBYT,MSGBIT+RVIEW    TURN ON MESSAGE AND REVIEW BITS  67596416
         MVI   RECCSM,NOXCEPT          MOVE IN NO ACCEPT SELECT MASK    67597116
         NI    STATBYT,XCEPTOFF        TURN OFF ACCEPT BIT              67597816
         B     MVPSTPNT                GO REGENERATE RECALL FRAME       67599216
         EJECT                                                          67600016
**********************************************************************  67680016
*                                                                       67760016
*  OPTION WAS REVIEW LOAD PRAMATER SELECT TABLE AND GENERATE FRAME      67840016
*                                                                       67920016
**********************************************************************  68000016
         SPACE                                                          68080016
LOADPST  MVC   CCTCPSTP(FOUR),CURRTAB  MOVE CURRENT PST POINTER         68160016
         MVC   CCTCCR(THREE),ZERO(EXTR)     MOVE CURRENT COMMAND KEY    68240016
         MVC   DISMSAV(1),CCTDISM      SAVE DISPLAY MASK                68320016
         TM    CCTPSTAT,X'80'          IS THIS INITIAL FRAME       GJPF 68340017
         BO    LDONE                   YES DO NOT RESTORE OLD MASK GJPF 68360017
         MVC   CCTDISM(1),DBEF         MOVE BEFORE DISPLAY MASK         68400016
         CLC   CCTCCR(THREE),CONDES     Q. DESCRIBE DATA           IIXX 68410018
         BNE   LDONE                    NO                         IIXX 68420018
         TM    CCTPSTAT,X'10'           Q. BACKGROUND JOB          IIXX 68430018
         BZ    DISPLAY                  NO                         IIXX 68440018
         OI    CCTDISM,X'40'            DON'T DISPLAY 'DISPLAY'    IIXX 68450018
         B     LDONE                    CONTINUE                   IIXX 68460018
DISPLAY  NI    CCTDISM,X'BF'            DO DISPLAY 'DISPLAY'       IIXX 68470018
LDONE    LR    RPAR1,CCTR              LOAD ADDR OF CCT            0169 68480017
         L     RBR,CCTDGMP             LOAD ADDR OF DGM                 68560016
         BALR  RRET,RBR                BRANCH TO DGM                    68640016
         B     CHKERR                  GO TO CHECK RETURN CODE     GJPF 68720017
         DC    X'4000'                 CODE FOR GENERATE FRAME NO DISP. 68800016
         SPACE                                                          68820017
CHKERR   CH    RBR,ERRCODE             IS RETURN CODE 1C           GJPF 68840017
         BE    ERRORTN                 YES GO TO ERROR RETURN      GJPF 68860017
         SPACE                                                          68880016
*                                                                       68888016
*  SEARCH EXTRACTED RECORD AND PST FOR OVERLAYS                         68896016
*                                                                       68904016
         SPACE                                                          68912016
LDPSTADD MVC   CCTDISM(ONE),DISMSAV    RESTORE SAVED DISPLAY MASK       68920016
         SR    WORKR1,WORKR1           ZERO WORK REG ONE                68928016
         L     CSTR,CURRTAB            LOAD ADDR OF CURRENT TABLE       68936016
EOFTAB   CLC   TENTLGT(TWO),ZEROS      END OF TABLE                     68944016
         BE    TSTINPUT                YES GO TO TEST FOR INPUT         68952016
         TM    TNXTCMD,OVRLY           DOES THIS ENTRY CREATE AN OVRLY  68960016
         BO    TSTSELT                 YES GO TO TEST IF IT WAS ENTERED 68968016
INSRTLGT IC    WORKR1,TENTLGT          INSERT ENTRY LENGTH              68976016
         AR    CSTR,WORKR1             ADD TO CST POINTER               68984016
         B     EOFTAB                  GO TO TEST FOR END OF TABLE      68992016
         SPACE                                                          69000016
TSTSELT  LH    WORKR3,TINMAP           LOAD INPUT MAPPING               69008016
         AR    WORKR3,EXTR             ADD BEGINNING OF EXTRACT RECORD  69016016
         CLC   ZERO(TWO,WORKR3),BLANK  DOES THIS FIELD CONTAIN DATA     69024016
         BNE   GENOVLY                 YES GO TO GENERATE AN OVERLAY    69032016
         B     INSRTLGT                NO GO TO INSERT LENGTH           69040016
         SPACE                                                          69048016
*                                                                       69056016
*  TEST PST ENTRIES AND EXTRACTED RECORD FOR INPUT                      69064016
*                                                                       69072016
         SPACE                                                          69080016
TSTINPUT L     CSTR,CURRTAB            LOAD ADDR OF CURRENT TABLE       69088016
         SR    WORKR1,WORKR1           ZERO WORK REG                    69120016
TBEND    CLC   TENTLGT(TWO),ZEROS      END OF TABLES                    69200016
         BE    DISPFRM                 YES GO TO DISPLAY FRAME          69280016
         SPACE                                                          69360016
         TM    TCMDSTAT,INDATA         DOES THIS ENTRY ALLOW INPUT      69440016
         BO    TSTDATA                 YES GO TO TEST DATA              69520016
         TM    TCMDSTAT,MULTC          IS THIS ENTRY MULTIPLE CHOICE    69600016
         BO    TSTDATA                 YES GO TO TEST DATA              69680016
NXTENT   IC    WORKR1,TENTLGT          INSERT LENGTH OF ENTRY           69760016
         AR    CSTR,WORKR1             MOVE POINTER TO NEXT ENTRY       69840016
         B     TBEND                   GO TO TEST FOR END OF TABLE      69920016
         SPACE                                                          70000016
*                                                                       70080016
*  DETERMINE IF ENTRY HAS INPUT DATA                                    70160016
*                                                                       70240016
         SPACE                                                          70320016
TSTDATA  LH    WORKR2,TINMAP           LOAD INPUT MAPPING               70400016
         AR    WORKR2,EXTR             ADD BEGINNING OF EXTRACT RECORD  70480016
         IC    WORKR1,TINLGT           INSERT DATA LENGTH               70560016
         BCT   WORKR1,EXTST            SUBTRACT ONE FROM LENGTH         70640016
EXTST    EX    WORKR1,TST01            EXECUTE COMPARE INSTRUCTION      70720016
         BE    NXTENT                  IF EQUAL TO BLANKS GO TO NXT ENT 70800016
         CLI   ZERO(WORKR2),X'37'      IS DATA AN END DELIMETER         70880016
         BE    NXTENT                  YES GO TO NEXT ENTRY             70960016
         SPACE                                                          71040016
*                                                                       71120016
*  ENTRY HAS INPUT DATA SEARCH ACT FOR ENTRY IF NONE GENERATE OVERLAY   71200016
*                                                                       71280016
         SPACE                                                          71360016
SRACT    LR    WORKR4,CSTR             LOAD ADDR OF ENTRY               71440016
         S     WORKR4,CCTCPSTP         SUBTRACT BEGINNING OF TABLE      71520016
         L     WORKR3,CCTACTP          LOAD BEGINNING OF ACT ENTRIES    71600016
ACTEND   CLC   ZERO(FOUR,WORKR3),ONES  IS THIS END OF ACT               71680016
         BE    DISPFRM                 YES GO DISPLAY FRAME             71760016
         CH    WORKR4,ZERO(WORKR3)     ARE RELATIVE DISPLAMENTS EQUAL   71840016
         BE    INSRDATA                YES GO TO INSERT DATA IN DISPLAY 71920016
         LA    WORKR3,ACTLNGTH(WORKR3) MOVE POINTER TO NEXT ACT ENTRY   72000016
         B     ACTEND                  GO TO TEST FOR END OF ACT        72080016
         SPACE                                                          72160016
*                                                                       72240016
*  NO ACT ENTRY GO GENERATE AN OVERLAY                                  72320016
*                                                                       72400016
         SPACE                                                          72480016
GENOVLY  LH    RPAR0,TINMAP            LOAD INPUT MAPPING               72560016
         LR    RPAR1,CCTR              LOAD ADDR OF CCT                 72640016
         L     RBR,CCTPKYM             LOAD ADDR OF KEY MANIP           72720016
         OI    CCTPKYM,X'80'           TURN ON RECALL FOR KEY MANIP     72800016
         BALR  RRET,RBR                BRANCH TO KEY MANIP              72880016
         SPACE                                                          72960016
         CH    RBR,CON80               IS RETURN CODE 80                73000016
         BE    OVLYERR                 YES GO TO OVERLAY ERROR          73040016
         B     TSTINPUT                GO TO TEST INPUT                 73080016
*                                                                       73120016
*  INSERT USER'S DATA INTO ORDER AREA                                   73200016
*                                                                       73280016
         SPACE                                                          73360016
INSRDATA ST    WORKR2,DORATIR          STORE ADDR OF DATA               73440016
         MVC   DORINS(TWO),SIX(WORKR3) MOVE RELATIVE BUFFER ADDR        73520016
         LA    WORKR1,ONE(WORKR1)      ADD ONE TO LENGTH OF DATA        73600016
         ST    WORKR1,DORLEN           STORE LENGTH OF DATA             73680016
         ST    CCTR,DORCCT             STORE ADDR OF CCT                73760016
         MVI   DORATIR,INSRT           MOVE INSERT CONTROL BIT          73840016
         LA    RPAR0,DORWKA            LOAD ADDR OF DOR WORK AREA       73920016
         LA    RPAR1,DORATIR           LOAD ADDR OF DOR CALLING SEQ.    74000016
         L     RBR,CCTDORP             LOAD ADDR OF DOR                 74080016
         BALR  RRET,RBR                BRANCH TO IKADOR                 74160016
         CH    RBR,ERRCODE             IS RETURN CODE 1C           GJPF 74180017
         BE    ERRORTN                 YES GO TO ERROR RETURN      GJPF 74200017
         B     NXTENT                  GO TO MOVE POINTER TO NEXT ENTRY 74240016
         SPACE                                                          74320016
*                                                                       74400016
*  COMPARE AND MOVE INSTRUCTIONS TO BE USED BY EXECUTE INSTRUCTIONS     74480016
*                                                                       74560016
         SPACE                                                          74640016
TST01    CLC   ZERO(ZERO,WORKR2),BLANK  COMPARE FOR INPUT DATA          74720016
         SPACE                                                          74800016
*                                                                       74880016
*  ALL DATA HAS BEEN MOVE DISPLAY FRAME                                 74960016
*                                                                       75040016
         SPACE                                                          75120016
DISPFRM  L     RPAR1,CCTACTP           LOAD ADDR OF ACT                 75200016
ENDOFACT CLC   ZERO(FOUR,RPAR1),ONES   END OF ACT                       75280016
         BE    MVCONBIT                YES GO TO MOVE CONTROL BIT       75360016
         TM    ACTDATA1(RPAR1),X'3F'   TEST FIRST BYTE                  75440016
         BZ    TSTSECND                IF ZERO GO TO TEST SECOND BYTE   75520016
         B     MVCURADD                IF NOT GO TO MOVE CURSOR ADDR    75600016
         SPACE                                                          75680016
TSTSECND TM    ACTDATA2(RPAR1),HEXFF   TEST SECOND BYTE                 75760016
         BM    MVCURADD                IF NOT ZERO GO TO MOVE CURSOR    75840016
         LA    RPAR1,ACTLNGTH(RPAR1)   MOVE POINTER TO NEXT ACT ENTRY   75920016
         B     ENDOFACT                GO TO TEST NEXT ACT ENTRY        76000016
         SPACE                                                          76080016
MVCURADD MVC   DORCUR(TWO),ACTDATA1(RPAR1) MOVE RELATIVE ADDR OF CURSOR 76160016
MVCONBIT MVI   DORATIR,CONBIT          MOVE CONTROL BITS                76240016
         NI    IGNORBIT,IGNOROFF       TURN OFF IGNORE ATTN BIT         76320016
         ST    CCTR,DORCCT             STORE ADDR OF CCT                76400016
         LA    RPAR1,DORATIR           LOAD ADDR OF CALLING SEQ         76480016
         LA    RPAR0,DORWKA            LOAD ADDR OF DOR WORK AREA       76560016
         L     RBR,CCTDORP             LOAD ADDR OF DOR                 76640016
         BALR  RRET,RBR                BRANCH TO IKADOR                 76720016
         SPACE                                                          76740017
         CH    RBR,ERRCODE             IS RETURN CODE 1C           GJPF 76760017
         BE    ERRORTN                 YES GO TO ERROR RETURN      GJPF 76780017
         SPACE                                                          76800016
         XC    CCTPECB(FOUR),CCTPECB   CLEAR PROCESSOR ECB              76880016
         B     INCHSN                  GO TO INCREMENT HSN              76960016
         EJECT                                                          77040016
*                                                                       77120016
*  THIS SUBROUTINE READS THE EXTRACT DATA SET AND MAINTAINES POINTERS   77200016
*  FOR THE NEXT READ AND NEXT WRITE                                     77280016
*                                                                       77360016
         SPACE                                                          77440016
READEXT  ST    RRET,RETSAV             SAVE RETURN ADDR                 77520016
         L     PNTAR,POINTRA           LOAD A POINTER                   77600016
         L     WORKR1,CCTEDCB1         LOAD DCB ADDR                    77680016
         SPACE                                                          77760016
*                                                                       77840016
*  READ RECORD FROM EXTRACT DATA SET                                    77920016
*                                                                       78000016
         SPACE                                                          78080016
         LA    WORKR2,READMAC          LOAD ADDR OF DECB                78160016
         READ  (WORKR2),SF,,,,,,MF=E   EXECUTE READ                     78240016
         SPACE                                                          78320016
         CHECK (WORKR2)                CHECK FOR COMPLETION             78400016
         SPACE                                                          78480016
         NOTE  (WORKR1)                NOTE POSITION OF LAST READ       78560016
         CLC   EXTDATA(3),ENT      IS RECORD ENTER DATA            GJPF 78570017
         BNE   NOTENTA             NO                              GJPF 78580017
         MVI   EXTDATA+ENTX,X'40'  BLANK OUT 'MORE DATA FOLLOWS'   GJPF 78590017
NOTENTA  EQU   *                                                   GJPF 78600017
         SPACE                                                          78640016
         A     RPAR1,ZERONE            ADD ONE TO NOTE POSITION         78720016
         CR    RPAR1,PNTAR             COMPARE FOR END OF DATA          78800016
         BL    CONVERT                 BRANCH IF NOT END                78880016
         OI    STATBYT,ENDON           TURN ON END OF DATA              78960016
         SPACE                                                          79040016
*                                                                       79120016
*  CONVERT HSN TO EBDIC FORM                                            79200016
*                                                                       79280016
         SPACE                                                          79360016
CONVERT  LH    WORKR3,HSN              LOAD HISTORY SEQ. NUM.           79440016
         CVD   WORKR3,DECHSN           CONVERT NUMBER TO PACKED DECIMAL 79520016
         UNPK  EBDICHSN,DECHSN         UNPACK TO EBDIC FORM             79600016
         OI    EBDICHSN+7,X'F0'        TURN ON SIGN                     79680016
         ST    PNTAR,POINTRA           SAVE END OF DATA ADDR            79760016
         L     RRET,RETSAV             LOAD RETURN ADDR                 79840016
         BR    RRET                                                     79920016
         EJECT                                                          80000016
*                                                                       80080016
*  THIS SUBROUTINE IS USED TO PASS CALLING SEQUENCES FOR MESSAGES TO BE 80160016
*  DISPLAYED FROM IKAMREC0 TO IKADMSG. IT USES AN AVAIABLE AREA         80240016
*  (DORWKA) IN THE GETMAIN AREA TO PLACE THE PARAMETERS INTO.           80320016
*                                                                       80400016
         SPACE                                                          80480016
MSGSUB   ST    RRET,RETSAV             SAVE RETURN ADDR                 80560016
         LH    WORKR1,ZERO(RPAR1)      LOAD DISPLACEMENT OF MSG         80640016
         A     WORKR1,MSGMOD           ADD BEGINNING OF MSG MODULE      80720016
         L     WORKR1,ZERO(WORKR1)     LOAD ADDR OF A CALLING SEQ.      80800016
         LA    WORKR2,DORWKA           LOAD ADDR OF WORK AREA           80880016
         SPACE                                                          80960016
LOADPARM L     WORKR3,ZERO(WORKR1)     LOAD A PARM                      81040016
         ST    WORKR3,ZERO(WORKR2)     STORE IN WORK AREA               81120016
         LTR   WORKR3,WORKR3           IS THIS LAST PARM                81200016
         BC    10,MOVEPT               NO GO TO MOVE POINTERS           81280016
         SPACE                                                          81360016
         LR    RPAR1,CCTR              LOAD ADDR OF CCT                 81440016
         LA    RPAR0,DORWKA            LOAD ADDR OF CALLING SEQUENCE    81520016
         L     RBR,CCTDMRP             LOAD ADDR OF DMSG                81600016
         BALR  RRET,RBR                BRANCH TO DMSG                   81680016
         SPACE                                                          81700017
         CH    RBR,ERRCODE             IS RETURN CODE 1C           GJPF 81720017
         BE    ERRORTN                 YES GO TO ERROR RETURN      GJPF 81740017
         SPACE                                                          81760016
         L     RRET,RETSAV             LOAD RETURN ADDR                 81840016
         BR    RRET                    RETURN TO MAIN ROUTINE           81920016
         SPACE                                                          82000016
MOVEPT   LA    WORKR1,FOUR(WORKR1)     ADD FOUR TO MSG MOD DISP         82080016
         LA    WORKR2,FOUR(WORKR2)     ADD FOUR TO PARM DISP            82160016
         B     LOADPARM                GO TO LOAD NEXT PARM             82240016
         SPACE                                                          82244016
*                                                                       82248016
*  INTERNAL ERROR EXIT FOR INVALID DATA FROM EXTRACT RECORDS OR AN      82252016
*  INVALID RETURN CODE FROM A PROCESSOR                                 82256016
*                                                                       82260016
         SPACE                                                          82264016
KEYERR   LA    RPAR0,IRMSG24           LOAD ADDR OF ERROR MSG 24        82268016
LDERRCCT LR    RPAR1,CCTR              LOAD ADDR OF CCT                 82272016
         L     RBR,CCTIERRP            LOAD ADDR OF IERR                82276016
         BALR  RRET,RBR                BRANCH TO IERR ROUTINE      GJPF 82277017
         SPACE                                                          82278017
         LH    RBR,ERRCODE             LOAD INTERNAL ERROR CODE    GJPF 82279017
         B     RETURN                  GO TO EXIT ROUTINE          GJPF 82280017
         SPACE                                                          82284016
ERROR    LA    RPAR0,IRMSG52           LOAD ADDR OF ERROR MSG 52        82288016
         B     LDERRCCT                GO TO LOAD CCT ADDR              82292016
         SPACE                                                          82296016
OVLYERR  LA    RPAR0,IRMSG36           LOAD ADDR OF ERROR MSG 36        82300016
         B     LDERRCCT                GO TO LOAD CCT ADDR              82304016
         EJECT                                                          82320016
*                                                                       82350016
*  EXIT ROUTINE  INSURE THAT USER DID NOT ONLY DO OMITS ALSO DELETE ALL 82380016
*  PROCESSORS AND TABLES LOADED BY RECALL AND RETURN STATUS TO CTL AS   82410016
*  IT WAS UPON ENTERING RECALL.                                         82440016
*                                                                       82470016
         SPACE                                                          82500016
EXIT     L     WORKR1,CCTEDCBP         LOAD ADDRESS OF EXTRACT DCB      82530016
         NOTE  (WORKR1)                NOTE POSIITON OF EXT DATA SET    82560016
         SPACE                                                          82590016
         C     RPAR1,ZERONE            IS POSITION MORE THAN ZERO ONE   82620016
         BNH   LOAD0C                  NO GO TO LOAD A 0C RETURN CODE   82650016
         LA    RBR,ZERO                LOAD '00' RETURN CODE            82700016
         B     RETURN                  BRANCH TO RETURN                 82720016
         SPACE                                                          82725017
ERRORTN  LH    RBR,ERRCODE             LOAD INTERNAL ERROR RETURN  GJPF 82730017
         B     RETURN                  BRANCH TO RETURN            GJPF 82735017
         SPACE                                                          82740016
LOAD0C   LA    RBR,CANCEL              LOAD '0C' RETURN CODE            82760016
RETURN   LR    WORKR1,RBR              SAVE RETURN CODE                 82800016
         MVC   CCTCSTP(FOUR),CSTSAV    RESTORE ADDR OF PST              82880016
         NI    IGNORBIT,IGNOROFF       TURN OFF IGNORE ATTN BIT         82960016
         SPACE                                                          83040016
         DELETE  EP=IKATREC0           DELETE RECALL PST                83120016
         SPACE                                                          83200016
         CLC   CURRPROC(FOUR),ZEROS    IS THERE A PROCESSOR PRESENT     83280016
         BE    PSTDEL                  NO GO TO TEST FOR A PST          83360016
         DELETE  EPLOC=CPROCNM         DELETE PROCESSOR                 83440016
         SPACE                                                          83520016
PSTDEL   CLC   CURRTAB(FOUR),ZEROS     IS THERE A PST PRESENT           83600016
         BE    CLRCPST                 NO GO TO CLEAR PST POINTER       83680016
         DELETE  EPLOC=CTABNM          DELETE CURRENT PST               83760016
         SPACE                                                          83840016
CLRCPST  XC    CCTCPSTP(FOUR),CCTCPSTP ZERO CURRENT PST POINTER         83920016
         L     RSAVE,SAVE13            LOAD SAVE AREA ADDR              84000016
         FREEMAIN R,LV=GETEND-GETSTART,A=(4)     FREE WORK AREA         84080016
         SPACE                                                          84160016
         NI    RECMODE,RECOFF          TURN OFF RECALL MODE             84240016
         LR    RBR,WORKR1              LOAD RETURN CODE                 84320016
         CH    RBR,CON5                                                 84340016
         BE    LDCCTADD                IS RETURN CODE FIVE              84360016
         RETURN (14,12),RC=(15)        RESTORE REGS AND RETURN          84400016
         SPACE                                                          84420016
LDCCTADD LR    RPAR1,CCTR              LOAD CCT ADDR                    84440016
         L     RRET,12(0,RSAVE)        RESTORE RETURN REG               84450016
         XCTL  (2,12),EP=IKAPBEG0                                       84460016
         EJECT                                                          84480016
MSGMOD   DC    V(IKAMREC0)             ADDR OF MESSAGE MODULE           84560016
ZERONE   DC    X'00000001'             STARTING ADDR FOR DATA SETS      84640016
ONES     DC    X'FFFFFFFF'             CONSTANT OF ONES                 84720016
ZEROS    DC    X'00000000'             CONSTANT OF ZEROS                84800016
ORDLENGT DC    A(MODLGT)               LENGTH OF ORDERS IN BUFFER       84880016
PROCCON  DC    C'IKAPXXX0'             PROCESSOR CONSTANT               84960016
TABCON   DC    C'IKATXXX0'             CONSTANT FOR TABLES              85040016
BLANK    DC    CL80' '                 CONSTANT OF EIGHTY BLANKS        85120016
CON4     DC    X'0004'                                                  85200016
CON5     DC    X'0005'                 CONSTANT OF FIVE                 85240016
CON8     DC    X'0008'                                                  85280016
CONC     DC    X'000C'                                                  85360016
CON10    DC    X'0010'                 HEX 10 CONSTANT                  85380016
CON80    DC    X'0080'                 CONSTANT OF 80                   85400016
CON14    DC    X'0014'                 CONSTAN HEX 14                   85420016
CON18    DC    X'0018'                 CONSTANT OF HEX 18               85430016
ERRCODE  DC    X'001C'                 INTERNAL ERROR CODE         GJPF 85435017
RECALL   DC    C'RECALL'               RECALL CONSTANT                  85440016
CONCAN   DC    C'CAN '                 CONSTANT OF CAN                  85480016
CONBEG   DC    C'BEG '                 CONSTANT OF BEG                  85500016
BEGP     DC    C'BEG//'                CONSTANT OF BEG//                85520016
CONDES   DC    C'DES'                   CONSTANT                   IIXX 85521018
         DS    0F                                                       85522016
IRMSG24  DC    C'024PREC0'             CALLING SEQ TO IERR FOR          85524016
         DC    F'0'                    ERROR MSG 24                     85526016
IRMSG52  DC    C'052PREC0'             CALLING SEQ TO IERR FOR          85528016
         DC    F'0'                    ERROR MSG 25                     85530016
IRMSG36  DC    C'036PREC0'             CALLING SEQ TO IERR FOR          85532016
         DC    F'0'                    ERROR MSG 36                     85534016
         DS    0H                                                       85540016
         SPACE 2                                                        85542000
*********************************************************************** 85544000
*                                                                       85546000
*        MAINTENANCE AREA                                        A33564 85548000
*                                                                       85550000
*********************************************************************** 85552000
PATCH    DC    38F'0'                                            A33564 85554000
         EJECT                                                          85560016
*                                                                       85580016
*  MODELS USED TO CREATE A CURRENT ITEM AND TO READ FROM EXTRACT RECORD 85600016
*                                                                       85620016
         SPACE                                                          85640016
CURRITEM EQU   *                                                        85660016
         GBFLM                                                          85680016
CURRST   GDV   440,3720,B              STARTING POINT FOR CURRENT ITEM  85760016
CURRTYP  GECP  LARGE                   TYPE CHARACTERS                  85840016
CURRCON  DC    C'CURRENT ITEM- '       CONSTANT TO BE DISPLAYED         85920016
CURRBLNK DC    CL32' '                 AREA TO BE FILLED IN FOR HIST    86000016
         GEVM                                                           86080016
CURRTRU  GTRU  0                                                        86160016
CURREND  EQU   *                                                        86240016
         SPACE                                                          86320016
         READ  READB,SF,,,,,,MF=L      READ MACRO LIST                  86400016
READEND  EQU   *                                                        86480016
         SPACE                                                          86560016
MODLGT   EQU   CURREND-CURRST                                           86640016
RMACLEN  EQU   READEND-READB                                            86720016
ORDLGT   EQU   CURRTRU-CURRST                                           86800016
GTRUE    EQU   CURRTRU+2-CURRBLNK                                       86880016
         EJECT                                                          86960016
*                                                                       87040016
*  THIS SERIES OF TABLES IS USED TO CREATE A HISTORY ENTRY TO BE        87120016
*  DISPLAYED AS CURRENT ITEM ON A RECALL SELECT FRAME                   87200016
*                                                                       87280016
*        THE PNTDISTB TABLE IS A SERIES OF POINTERS TO THE              87360016
*        INDIVIDUAL PROCESSOR TABLES. THIS TABLE IS SEARCHED USING      87440016
*        THE THREE BYTE KEY IN THE EXTRACT RECORD                       87520016
*                                                                       87600016
*        THE PROCESSOR TABLE ENTRIES HAVE THE FOLLOWING FORMAT          87680016
*                                                                       87760016
*              BYTE ONE    TOTAL LENGTH OF ENTRY                        87840016
*                   TWO    IF ZERO FIELD IS NOT IN EXTRACT RECORD       87920016
*                   THREE  THE NUMBER OF BYTES TO BE MOVED              88000016
*                   FOUR   THE DISPLACEMENT IN HISTORY RECORD           88080016
*                   FIVE   IS THE BEGINNING OF CONSTANT TO BE PLACED    88160016
*                          IN HISTORY RECORD IF FIELD IS NOT IN         88240016
*                          EXTRACT RECORD                               88320016
         SPACE                                                          88400016
         DS    0F                                                       88480016
PNTDISTB DC    C'SPE '                 SPE CONSTANT                     88560016
         DC    A(SPETABLE)             ADDR OF SPE TABLE                88640016
ENT      EQU   *                                                   GJPF 88680017
         DC    C'ENT '                 ENT CONSTANT                     88720016
         DC    A(ENTTABLE)             ADDR OF ENT TABLE                88800016
         DC    C'DES '                 DES CONSTANT                     88880016
         DC    A(DESTABLE)             ADDR OF DES TABLE                88960016
         DC    C'BEG '                 BEG CONSTANT                     88980016
         DC    A(BEGTABLE)             ADDR OF BEG TABLE                89000016
         DC    C'BEP '                 BEP CONSTANT                     89010016
         DC    A(BEPTABLE)             ADDR OF BEP TABLE                89020016
         DC    X'FFFF'                 END OF LIST                      89040016
         SPACE                                                          89120016
SPE1     EQU   *                                                        89200016
SPETABLE DC    AL2(SPE1E-SPE1)         LENGTH OF ENTRY                  89260016
         DC    AL2(0)                  ZERO EQUALS NOT IN EXTRACT       89320016
         DC    AL2(7)                  NUMBER OF CHAR'S TO MOVE LESS 1  89380016
         DC    AL2(4)                  HISTORY DISPLACEMENT             89440016
         DC    C'JOB STEP'             KEYWORD CONSTANT                 89500016
SPE1E    EQU   *                                                        89560016
*                                                                       89620016
SPE2     EQU   *                                                        89680016
         DC    AL2(SPE2E-SPE2)         LENGTH OF ENTRY                  89740016
         DC    AL2(103)                EXTRACT DISPLACEMENT             89800016
         DC    AL2(7)                  NUMBER OF CHAR'S TO MOVE LESS 1  89860016
         DC    AL2(14)                 HISTORY DISPLACEMENT             89920016
SPE2E    EQU   *                                                        89980016
         DC    X'FFFF'                 END OF TABLE                     90040016
SPEEND   EQU   *                                                        90100016
         SPACE                                                          90160016
ENT1     EQU   *                                                        90220016
ENTTABLE DC    AL2(ENT1E-ENT1)         LENGTH OF ENTRY                  90280016
         DC    AL2(0)                  ZERO EQUALS NOT IN EXTRACT       90340016
         DC    AL2(3)                  NUMBER OF CHAR'S TO MOVE LESS 1  90400016
         DC    AL2(4)                  HISTORY DISPLACEMENT             90460016
         DC    C'DATA'                 KEYWORD CONSTANT                 90520016
ENT1E    EQU   *                                                        90580016
*                                                                       90640016
ENT2     EQU   *                                                        90700016
         DC    AL2(ENT2E-ENT2)         LENGTH OF ENTRY                  90760016
         DC    AL2(3)                  EXTRACT DISPLACEMENT             90820016
         DC    AL2(15)                 NUMBER OF CHAR'S TO MOVE LESS 1  90880016
         DC    AL2(14)                 HISTORY DISPLACEMENT             90940016
ENT2E    EQU   *                                                        91000016
         DC    X'FFFF'                 END OF TABLE                     91060016
ENTEND   EQU   *                                                        91120016
         SPACE                                                          91180016
DES1     EQU   *                                                        91240016
DESTABLE DC    AL2(DES1E-DES1)         LENGTH OF ENTRY                  91300016
         DC    AL2(0)                  ZERO EQUALS NOT IN EXTRACT       91360016
         DC    AL2(7)                  LENGTH OF CHAR'S TO MOVE LESS 1  91420016
         DC    AL2(4)                  HISTORY DISPLACEMENT             91480016
         DC    C'DESCRIBE'                                              91540016
DES1E    EQU   *                                                        91600016
*                                                                       91660016
DES2     EQU   *                                                        91720016
         DC    AL2(DES2E-DES2)         LENGTH OF ENTRY                  91780016
         DC    AL2(5)                  EXTRACT DISPLACEMENT             91840016
         DC    AL2(15)                 NUMBER OF CHAR'S TO MOVE LESS 1  91900016
         DC    AL2(14)                 HISTORY DISPLACEMENT             91960016
DES2E    EQU   *                                                        92020016
         DC    X'FFFF'                 END OF TABLE                     92080016
DESEND   EQU   *                                                        92140016
         SPACE                                                          92200016
BEG1     EQU   *                                                        92260016
BEGTABLE DC    AL2(BEG1E-BEG1)         LENGTH OF ENTRY                  92320016
         DC    AL2(0)                  ZERO EQUALES NOT IN EXTRACT      92380016
         DC    AL2(4)                  NUMBER OF CHAR'S TO MOVE LESS 1  92440016
         DC    AL2(4)                  HISTORY DISPLACEMENT             92500016
         DC    C'BEGIN '               CONSTANT BEGIN                   92560016
BEG1E    EQU   *                                                        92620016
         SPACE                                                          92680016
BEG2     EQU   *                                                        92740016
         DC    AL2(BEG2E-BEG2)         LENGTH OF ENTRY                  92800016
         DC    AL2(70)                 EXTRACT DISPLACEMENT             92900016
         DC    AL2(7)                  NUMBER OF CHAR'S TO MOVE LESS 1  93000016
         DC    AL2(14)                 HISTORY DISPLACEMENT             93100016
BEG2E    EQU   *                                                        93200016
         DC    X'FFFF'                 END OF TABLE                     93300016
         SPACE                                                          93400016
BEP1     EQU   *                                                        93500016
BEPTABLE DC    AL2(BEP1E-BEP1)         LENGTH OF ENTRY                  93600016
         DC    AL2(0)                  ZERO EQUALS NOT IN EXTRACT       93700016
         DC    AL2(6)                  NUMBER OF CHAR'S TO MOVE LESS 1  93800016
         DC    AL2(4)                  HISTORY DISPLACEMENT             93900016
         DC    C'BEGPROC '             KEYWORK CONSTANT                 94300016
BEP1E    EQU   *                                                        94784016
         SPACE                                                          94984016
BEP2     EQU   *                                                        95184016
         DC    AL2(BEP2E-BEP2)         LENGTH OF ENTRY                  95384016
         DC    AL2(268)                EXTRACT DISPLACEMENT             95584016
         DC    AL2(7)                  NUMBER OF CHAR'S TO MOVE LESS 1  95784016
         DC    AL2(13)                 HISTORY DISPLACEMENT             95984016
BEP2E    EQU   *                                                        96184016
         SPACE                                                          97984016
BEP4     EQU   *                                                        98184016
         DC    AL2(BEP4E-BEP4)         LENGTH OF ENTRY                  98384016
         DC    AL2(70)                 EXTRACT DISPLACEMENT             98584016
         DC    AL2(7)                  NUMBER OF CHAR'S TO MOVE LESS 1  98784016
         DC    AL2(22)                 HISTORY DISPLACEMENT             98984016
BEP4E    EQU   *                                                        99184016
         DC    X'FFFF'                 END OF TABLE                     99384016
BEPEND   EQU   *                                                        99584016
         END                                                            99784016
