IKAPSMB0 CSECT                                                          00090016
*0829,532800,613800,665350,679900,691860-691880,692060-692080      1042 00130017
*3502,243000-257400,258300,306000,664620,714700                    PDUM 00140018
*3502                                                              4218 00160018
*3502,609000-609600                                                5102 00170018
         TITLE 'IKAPSMB0'                                               00180016
*                                                                       00270016
* MODULE NAME       IKAPSMB0                                            00360016
*                                                                       00450016
* CHART ID          EC,ED                                               00540016
*                                                                       00630016
* FUNCTION          TO CHECK USER SYSTEM MESSAGE BLOCK (SMB) FOR        00720016
*                   OPERATING SYSTEM/360 ERROR MESSAGES OR ABEND        00810016
*                   MESSAGE AND INFORM THE USER OF ANY ERRORS OR        00900016
*                   JOB RUN SUCCESSFULLY VIA A MESSAGE DISPLAY ON       00990016
*                   A FRAME.  IF SGJP THEN THE MESSAGES ARE TRANS-    S 01050016
*                   MITTED TO THE 1130/2250 SUBSYSTEM INSTEAD.        S 01110016
*                                                                       01170016
* ATTRIBUTES        NON-RESIDENT, REENTERABLE                           01260016
*                                                                       01350016
* ENTRY POINTS      IKAPSMB0 VIA AN XCTL FROM IKAINIT                   01440016
*                   IF SGJP, VIA AN XCTL FROM IKDINIT                 S 01480016
*                                                                       01530016
* OPERATION         SCAN THE SMB FOR IEF MESSAGES OR ABEND COMPLETION   01620016
*                   CODES                                               01710016
*                   LOAD APPROPRIATE TABLES TO PROCESS MESSAGES         01800016
*                   OUTPUT SELECTED MESSAGES                            01890016
*                                                                       01980016
* EXITS             XCTL TO CONTROL ROUTINE (IKACTL)                    02070016
*                   IF SGJP, THEN XCTL TO IKDCTL                      S 02110016
*                                                                       02160016
* INPUT             REGISTER 1 POINTING TO CONSOLE CONTROL TABLE        02250016
*                   REGISTER 13 POINTING TO A REGISTER SAVE AREA        02340016
*                                                                       02430016
*                   THE ADDRESS OF GRAPLIST IN CVT                      02520016
*                                                                       02610016
*                   SMB DATA SET CONTAINS SMB RECORD                    02700016
*                                                                       02790016
*              THE SMB LOOK LIKE THIS                                   02880016
*                                                                       02970016
*                  +0  AUXILIARY STORAGE ADDRESS OF THIS SMB            03060016
*                                                                       03150016
*                  +3  TABLE ID=5                                       03240016
*                                                                       03330016
*                  +4  AUXILIARY STORAGE ADDRESS OF NEXT SMB, OR ZERO   03420016
*                      IF LAST SMB IN CHAIN                             03510016
*                                                                       03600016
*                  +7  RESERVED                                         03690016
*                                                                       03780016
*                 +12  POINTER TO NEXT AVAILABLE BYTE                   03870016
*                                                                       03960016
*                 +14  STATUS BYTE   X'00' IF THERE IS NO MORE MESSAGE  04050016
*                                    X'FE' COMPRESSED MESSAGE           04140016
*                                    X'FF' IF DATA SET ENTRY FOLLOWS    04230016
*                                    MESSAGE LENGTH IF NOT ABOVE        04320016
*                                                                       04410016
*                 +15  MESSAGE STARTS                                   04500016
*                                                                       04590016
* OUTPUT            ERROR MESSAGES OR ABEND MESSAGE                     04680016
*                                                                       04770016
* EXTERNAL REFERENCES MESSAGE ROUTINE                                   04860016
*                    CONSOLE CONTROL TABLE                              05040016
*                    SCHEDULER ATTRIBUTE TABLE                          05130016
*                    SCHEDULER TEXT TABLES                              05230016
*                    ABEND ATTRIBUTE TABLE                              05490016
*                                                                       05590016
*                                                                       05760016
* RESTRICTION                                                           05850016
*                                                                       05940016
*                                                                       06030016
                    EJECT                                               06120016
*                                  EQUATES                              06210016
*                                                                       06300016
DSBLOC   EQU   14                       OFFSET TO DSB INDICATOR    PDUM 06330018
DSBIND   EQU   X'FF'                    DSB INDICATOR              PDUM 06360018
MSGSTART EQU        20             A RELATIVE ADDRESS IN CCTPWKA WHERE  06390016
*                                  THE MESSAGE TEXT STARTS              06480016
ANYSMB   EQU   4                   POINTER TO AUXILIARY STORAGE ADDRESS 06570016
*                                  OF NEXT SMB                          06660016
STATUS   EQU   14                  POINTER TO STATUS FIELD OF SMB       06750016
MSGPTR   EQU   15                  POINTER TO FIRST BYTE OF MESSAGE     06840016
*                                  IN SMB                               06930016
DATTR    EQU   3                   DISPLACEMET OF ATTRIBUTE FIELD OF    07020016
*                                  ABEND OR SCHEDULER ATTRIBUTE TABLE   07110016
DCORR    EQU   5                   DISPLACEMENT OF CORRELATION FIELD    07200016
*                                       OF SCHEDULER ATTRIBUTE TABLE    07290016
DTEXT    EQU   6                   DISPLACEMENT OF TEXT FIELD OF ABEND  07380016
*                                  OR SCHEDULER ATTRIBUTE TABLE         07470016
*                                                                       07560016
* THESE EQUATES FOR ARE FOR ATTRIBUTE FIELD OF ABEND OR SCHEDULER       07650016
* ATTRIBUTE TABLE                                                       07740016
*                                                                       07830016
DISPLAY  EQU   X'80'               MESSAGE DISPLAY                      07920016
DPLYJCL  EQU   X'40'               DISPLAY WITH JCL                     08010016
DTRSLATE EQU   X'20'               MESSAGE NEED TO TRANSLATE            08100016
MSGCOND  EQU   X'10'               MESSAGE WITH CONDITIONS              08190016
MSGINDPT EQU   X'08'               THIS MESSAGE IS NOT NOT DEPENT ON    08280016
*                                  OTHER MESSAGES                       08370016
OPENOK   EQU   X'10'               MASK TO TEST FOR SUCCESSFUL OPEN     08410016
ADDTNMSG EQU   X'04'               WITH ADDITIONAL MESSAGES             08460016
*                    *******************                                08550016
DCMSG    EQU   8                                                        08640016
DUNIT    EQU   14                       DISPLACEMENT                    08730016
DJCTR    EQU   17                       DISPLACEMENT                    08820016
*                                                                       08910016
*                                                                       08920016
* EQUATES FOR BUILD SMB MESSAGE TABLE                                   08930016
*                                                                       08940016
XYDISP   EQU   8                        DISPLACEMENT FOR X Y POSITION   08950016
TEXTDISP EQU   12                       DISPLACEMENT FOR TEXT           08960016
SMBDISPL EQU   24                                                       08970016
         EJECT                                                          09000016
* THIS IS INITIALIZATION ROUTINE WHICH WILL SET BASE, GET CORE FOR      09090016
* WORKAREA, AND INITIATES SWITCHES IN WORKAREA                          09180016
*                                                                       09270016
*                                                                       09360016
*  DEFINE REGISTERS                                                     09450016
*                                                                       09540016
RPAR0    EQU   0                   PARAMETER REGISTER                   09630016
RPAR1    EQU   1                   POINTING TO CCT                      09720016
RCCT     EQU   2                   BASE FOR CCT                         09810016
RWORKARA EQU   3                   BASE FOR OUT WORKAREA                09900016
RBASE    EQU   4                   BASE FOR THE ROUTINE                 09990016
RWORK    EQU   8                   GENERAL PURPOSE                      10350016
RLENGTH  EQU 14                                                         10440016
RINCR    EQU   10                       CONTAINS 8                      10530016
REND     EQU   11                       END LOCATION OF GETMAIN         10620016
RABEND   EQU   12                                                       10660016
RBEGIN   EQU   12                       START LOCATION OF GETMAIN       10710016
RSAVE    EQU   13                  POINTING TO REGISTER SAVE AREA       10800016
RRET     EQU   14                  RETURN REGISTER                      10890016
RBR      EQU   15                  BRANCH REGISTER                      10980016
SMBINIT  EQU   *                                                        11070016
         SAVE  (2,12)                                                   11160016
         BALR  RBASE,0                                                  11250016
         USING *,RBASE                                                  11340016
         LR    RCCT,RPAR1               CCT ADDRESS                     11430016
         USING CCT,RCCT                                                 11520016
         ST    RSAVE,CCTPSAVE+4         SAVE CALLING SAVE               11610016
         LA    RWORK,CCTPSAVE           QUR SAVE ADDR                   11700016
         ST    RWORK,8(0,RSAVE)         STORE IN CALLING SAVE AREA      11790016
         LR    RSAVE,RWORK              POINTING TO OUR SAVE ADDR       11880016
         GETMAIN R,LV=WORKEND-WORKBEG                                   12420016
         LR    RWORKARA,RPAR1      GETMAIN ADDRESS                      12510016
         USING WORKBEG,RWORKARA                                         12600016
         L     RLENGTH,LWKA        LENGTH OF WORKAREA                   12690016
         LR    RBEGIN,RPAR1             START ADDRESS                   12780016
         LA    REND,0(RBEGIN,RLENGTH)   END ADDRESS                     12870016
         LA    RINCR,8             SET INCREMENT                        12960016
         SR    REND,RINCR          SUBTRACT 8                           13050016
CLEARCOR XC    0(8,RBEGIN),0(RBEGIN)    CLEAR CORE                      13140016
         BXLE  RBEGIN,RINCR,CLEARCOR    CONTINUE IF NOT FINISH CLEAR    13230016
         OI    CCTPSTAT+1,X'01'        ON SMB MODE                      13320016
         OI    CCTPSTAT+1,X'80'        SELECT MODE                      13380016
         MVC   HOLDMSG(255),CCTPWKA     SAVE MESSAGE                    13390016
         EJECT                                                          13410016
         B     CREATDCB                BRANCH                           14410016
         EJECT                                                          16020016
*                                                                       16110016
* THIS ROUTINE HANDLES ABEND CODE IT WILL DISPLAY ABEND MESSAGE AND     16200016
* XCTL TO IKACTL                                                        16290016
*                                                                       16380016
* INPUT- A ABEND CODE IN REGISTER RABEND                                16470016
*                                                                       16560016
* AVAILABLE REGISTES 0 1 5 6 7 8 9 10 11 14 15                          16650016
*                                                                       16740016
ABENDRTN EQU   *                                                        16830016
         LOAD  EP=IKABENDA             LOAD                             16920016
         ST    RPAR0,ABENDAP            SAVE TABLE ADDRESS              17010016
         OI    SWAREA,ABDATTR           TURN ON ABEND ATTRIBUTE SWITCH  17100016
         OI    SWAREA,X'20'            ABEND SWITCH ON                  17140016
*                                                                       17190016
* PREPARE TO GO TO SEARCH ROUTINE                                       17280016
* RPAR0 CONTAINS ABEND NUMBER                                           17370016
* RPAR1 POINTING TO THE ENTRY OF ABEND ATTRIBUTE TABLE                  17460016
*                                                                       17550016
         LR    RPAR0,RABEND             ABEND CODE                      17640016
         L     RPAR1,ABENDAP            ABEND ATTRIBUTE TABLE ADDRESS   17730016
         BAL   RRET,SEARCH              GO TO SEARCH                    17820016
         EJECT                                                          17910016
* WHEN RETURNED FROM SEARCH ROUTINE RBR      POINTING TO THE OBJECTIVE  18090016
* FIELD WHICH CONTAINS ABEND CODE, ATTRIBUTES, AND TEXT POINTER         18180016
*                                                                       18270016
         LTR   RBR,RBR                 Q. FUND THIS NUMBER              18810016
         BC    6,MOVEMOD2              BRANCH IF YES                    18900016
         LA    RBR,ABENDATR             UNFOUND ABEND CODE ENTRY        18990016
         MVC   ABENDATR(8),DUMYATR      MAKE AN ENTRY FOR UNFOUND       19080016
         MVC   ABENDATR(3),CCTPWKA+1    ABEND CODE                      19170016
MOVEMOD2 EQU   *                                                        19260016
         MVC   IKASMBCX(8),AMODEL       * SET ABEND TEXT TABLE          19350016
         MVC   IKASMBCX+7(1),7(RBR)     * MODEL IN WORKAREA             19440016
         MVC   ATTENTRY(8),0(RBR)      A ATTR ENTRY NEEDED              19480016
         LA    RPAR0,IKASMBCX           TEXT TABLE ADDRESS              19530016
         LOAD  EPLOC=(0)                LOAD IN TABLE                   19620016
         OI    SWAREA,ABDTXT            TURN ON TABLE SWITCH            19710016
         ST    0,TEXTADDR              TEXT ADDRESS                     20210016
         LA    0,PARLIST               PARAMETER ADDRESS                21210016
         LR    1,RSTATUS               POINTER TO STATUS BYTE IN SMB    21710016
         BAL   14,MSGBUILD             DISPLAY MSG                      22210016
         B     TESTERR                 BRANCH                           22710016
         EJECT                                                          23490016
*                                                                       23580016
* THIS ROUTINE RESTORE REGISTERS FREE CORD AND XCTL TO CTL              23670016
*                                                                       23760016
CLEARUP  EQU   *                                                        23850016
         TM    CCTSSTAT,X'80'          Q. RECORD OPTION                 23853016
         BZ    CLEARUP1                BRANCH IF NO                     23856016
         MVC   CCTPWKA(LWRITE1),FWRITE                                  23859016
         L     RDCB,CCTRDCBP           DIARY DCB ADDRESS                23862016
         LA    RAREA,BLANKRD           ADDR OF BLANK RECORDS            23865016
         SR    9,9                     CLEAR COUNTER                    23868016
WRITEBK  EQU   *                                                        23871016
         WRITE CCTPWKA,SF,(RDCB),(RAREA),MF=E                           23874016
         CHECK CCTPWKA                                                  23877016
         LA    9,1(9)                  UPDATE COUNTER BY ONE            23880016
         CH    9,TWO                   Q. NUMBER TWO IN THE COUNTER     23883016
         BE    CLEARUP1                  BRANCH IF EQUAL                23886016
         LA    RAREA,120(RAREA)        JUMP TO NEXT RECORD              23889016
         B     WRITEBK                 BRANCH                           23892016
CLEARUP1 EQU   *                                                        23895016
         TM    SWAREA,ABDATTR          Q. ABEND ATTRIBUTE TABLE IN CORE 23895218
         BZ    TEST1                    BRANCH IF NO                    23895418
         DELETE EP=IKABENDA            DELETE IF YES                    23895618
TEST1    TM    SWAREA,ABDTXT           Q. ABEND TEXT TABLE IN CORE      23895818
         BZ    TEST3                    BRANCH IF NO                    23896018
         LA    RPAR0,IKASMBCX           TABLE ADDRESS                   23896218
         DELETE EPLOC=(0)               DELETE                          23896418
TEST3    TM    SWAREA,SCHATTR          Q. SCH-ATTRIBUTE TABLE IN CORE   23896618
         BZ    TEST5                   BRANCH IF NO                     23896818
         DELETE EP=IKASMBSA             DELETE IF YES                   23897018
TEST5    TM    SWAREA,SCHTXT           Q. SCHEDULER MESSAGE TABLE LOAD  23897218
         BZ    FREEMAIN                 BRANCH IF NO                    23897418
         LA    RPAR0,IKASMBSX           TABLE ADDRESS                   23897618
         DELETE EPLOC=(0)               DELETE                          23897818
FREEMAIN  EQU   *                                                  PDUM 23898018
         CLI   DISPLAD,X'FF'       ANYTHING TO DISPLAY             PDUM 23898218
         BNE   NODISPLY            NO                              PDUM 23898418
MSTOP    EQU   *                                                   PDUM 23898518
         ST    RCCT,ACCT           PUT ADDR CCT IN PARM LIST       PDUM 23898618
         LA    RPAR1,WORKBEG                                       PDUM 23898818
         LINK  EP=IKAPDIS0                                         PDUM 23899018
         LTR   RBR,RBR                  Q. NORMAL COMPLETION       PDUM 23899118
         BNZ   TERMNATE                 NO                         PDUM 23899218
         DELETE EP=IKAPDIS0                                             23899318
NODISPLY EQU   *                                                   PDUM 23899418
         MVI   CCTJDCBP,X'83'          SET UP OPTION BYTE               23900016
         LA    1,CCTJDCBP              PAR-LIST                         23950016
         OPEN  MF=(E,(1))                                               24000016
         LA    10,DSMBDCB               DCB ADDR                        24008016
         USING IHADCB,10                                                24016016
         TM    DCBOFLGS,OPENOK         Q. OPEN OK                       24024016
         BZ    IOERROR                  BRANCH IF NO                    24032016
         DROP  10                       1                               24040016
         MVC   DCLOSE(4),CLOSESMB       MOVE MACRO IN WORKAREA          24050016
         LA    1,DCLOSE                 PAR-ADDR                        24100016
         CLOSE (DSMBDCB),MF=(E,(1))                                     24150016
EXIT     EQU   *                                                   PDUM 24180018
         NI    CCTPSTAT+1,X'FE'        SMB MODE OFF                     24210016
         MVC   CCTPWKA(255),HOLDMSG    RESTORE MESSAGE                  25870016
         LA    RPAR1,WORKBEG                FREEMAIN ADDRESS            25920016
         FREEMAIN R,LV=WORKEND-WORKBEG,A=(1)                            26010016
         LA    RPAR1,CCT                CCT ADDRESS                     26100016
         L     RSAVE,CCTPSAVE+4         RESTORE CALLING SAVE ADDRESS    26190016
         TM    CCTSSTAT,32              Q. REMOTE GRAPHIC DEVICE      S 26220016
         BO    SGJPXT                   YES                           S 26250016
         XCTL  (2,12),EP=IKACTL         TRANSFER CONTROL TO IKACTL      26280016
SGJPXT   XCTL  (2,12),EP=IKDCTL         TRANSFER CONTROL TO IKDCTL    S 26320016
         EJECT                                                          26370016
*                                                                       26470016
* THIS ROUTINE READ SMB FROM JCL DATA SET                               26570016
*                                                                       26670016
* OUT PUT SMB IS READ IN ASMB                                           26770016
*                                                                       26870016
*                                                                       26970016
RDCB     EQU   7                        POINTER TO DCB                  27070016
RAREA    EQU   8                        POINTER TO AREA FOR SMB RECORD  27170016
RDECB    EQU   9                        POINTER TO DECB FOR READ        27270016
CREATDCB EQU   *                                                        27290016
         MVC   DSMBDCB(LSMBDCB),SMBDCB  MOVE DCB IN WORKAREA            27310016
         MVC   DOPENDCB(LOPEN),OPENDCB  MOVE OPEN IN WORKAREA           27330016
         LA    RDCB,DSMBDCB            DCB ADDR                         27350016
         ST    RDCB,ADCB           PUT ADDR DSMBDCB INTO PARM LIST PDUM 27360018
         LA    1,DOPENDCB              DCB ADDR                         27370016
         OPEN  (DSMBDCB,(INOUT)),MF=(E,(1))  OPEN                       27390016
         L     10,CCTJDCBP              DCB ADDR                        27393016
         USING IHADCB,10                                                27396016
         TM    DCBOFLGS,OPENOK         Q. OPEN SUCCESSFUL               27399016
         BZ    IOERROR1                BRANCH IF NO                     27402016
         DROP  10                                                       27405016
         L     RCVT,X'10'               CVT ADDR                   PDUM 27405218
         USING CVT,RCVT                                            PDUM 27405418
         L     RCVT,CVTQOCR             PNTR TO LIST               PDUM 27405618
         USING GRAPLIST,RCVT                                       PDUM 27405818
         L     RCVT,GOCT                OCT ADDR                   PDUM 27406018
         USING GFXOCTHD,RCVT                                       PDUM 27406218
         LH    RENTCTR,OCTUNBR          NO. OF OCT ENTRIES         PDUM 27406418
         LA    RCVT,GFXHDSZE+GFXHDSTR   OCT ENTRIES                PDUM 27406618
         USING GFXOCTEN,RCVT                                       PDUM 27406818
LOOKUP   CLC   CCTUNIT(3),OCTUNIT+1     Q. OCT ENTRY FOUND         PDUM 27407018
         BE    TESTMED                  YES                        PDUM 27407218
         LA    RCVT,GFXENSTR+GFXENSZE   GET NEXT ENTRY             PDUM 27407418
         BCT   RENTCTR,LOOKUP           CONTINUE                   PDUM 27407618
         B     READSMB                  NOT FOUND                  PDUM 27407818
TESTMED  TM    OCTATTR2,OCTBMED         Q. MEDIUM STOP             PDUM 27408018
         BO    MSTOP                    GO DELETE                  PDUM 27408218
READSMB  EQU   *                                                        27410016
         LA    RDCB,DSMBDCB            DCBADDR                          27430016
         MVI   ASMB,X'00'               * CLEAR CORE FOR NEW            27470016
         MVC   ASMB+1(175),ASMB         * SMB RECORD READ IN            27570016
         MVC   DREAD(LREAD),READ        MOVE READ IN WORKAREA           27670016
         LA    RDECB,DREAD              DECB ADDRESS                    27770016
         LA    RAREA,ASMB               READ IN AREA                    27870016
         READ  (RDECB),SF,(RDCB),(RAREA),,,MF=E                         27970016
         CHECK (RDECB)                                                  28070016
         CLI   ASMB+DSBLOC,DSBIND       Q. DATA SET BLOCK          PDUM 28170018
         BNE   NOTDSB                   NO, DON'T READ QMPA-IOB    PDUM 28270018
         READ  (RDECB),SF,(RDCB),QMPA,,,MF=E     READ QMPA         PDUM 28370018
         CHECK (RDECB)                            CHECK IF READ FINISH  28710016
NOTDSB   EQU   *                                                   PDUM 28750018
         EJECT                                                          28800016
*                                                                       28890016
* THIS ROUTINE TEST SMB MESSAGE AND GIVE CONTROL TO APPROPRIATE ROUTINE 28980016
*                                                                       29070016
* AVAILABLE REGISTERS  0 1 5 6 7 8 9 10 11 12 14 15                     29160016
*                                                                       29250016
* OUTPUT- IF RECORD OPTION TAKEN RPAR0 POINTING TO MESSAGE STATUS BYTE  29340016
*       - IF ABEND RABEND CONTAINS ABEND CODE AND BRANCH TO ABENDRTN    29430016
*         ROUTINE                                                       29520016
*       - IF IEF MESSAGE RPAR0 POINTING TO MESSAGE STATUS BYTE          29610016
*                                                                       29700016
*                                                                       29790016
RMSGPTR  EQU   5                   POINTER TO MESSAGE FIELD IN SMB      29880016
RSMBADDR EQU   6                   POINTER TO SMB                       29970016
RRDLTH   EQU   7                   MESSAGE RECORD LENGTH                30060016
SMBCTL   EQU   *                                                        30150016
         LA    RSMBADDR,ASMB            SMB ADDRESS                     30240016
         LA    RMSGPTR,STATUS(RSMBADDR) MESSAGE STATUS BYTE ADDRESS     30330016
         CLI   0(RMSGPTR),X'FF'        Q. SMB CONTAINS DATA SET         30420016
*                                      ENTRY                            30510016
         BNE   RDOPTION            AN SMB                          PDUM 30550018
         MVI   DISPLAD,X'FF'       SET SWITCH TO DISPLAY DATA S    PDUM 30590018
         NI    SWAREA+1,X'BF'      RESET ERROR SWITCH         LD A47858 30610021
         B     TESTMSMB            GO CHECK FOR MORE SMBS          PDUM 30630018
RDOPTION TM    CCTSSTAT,X'80'          Q. RECORD OPTION                 30690016
         BZ    TESTABND                 BRANCH IF NO                    30780016
         LR    RPAR0,RMSGPTR            SET PARAMETER                   30870016
         BAL   RRET,WRITESMB            BRANCH TO WRITESMB ROUTINE      30960016
TESTABND CLC   1(16,RMSGPTR),COMPCODE  Q. IS COMPLTION CODE             31050016
         BNE   TESTIEF                  BRANCH IF NO                    31140016
         XC    CCTPWKA(4),CCTPWKA       *                               31230016
         MVC   CCTPWKA+1(4),26(RMSGPTR) *GET ABEND CODE                 31320016
         L     RABEND,CCTPWKA          GET ABEND CODE                   31410016
         B     ABENDRTN                 BRANCH TO ABEND HANDLE ROUTINE  31500016
TESTIEF  CLC   1(3,RMSGPTR),IEFMSG     Q. IS IEF MESSAGE                31590016
         BNE   TESTMMSG                 BRANCH IF NO                    31680016
         LR    RPAR0,RMSGPTR            SET PARAMETER                   31770016
         B     IEFHANDL                 BRANCH TO IEF MESSAGE HANDLING  31860016
*                                       ROUTINE                         31950016
TESTMMSG EQU   *                                                        32050016
         CLI   0(RMSGPTR),X'FE'        Q. COMPRESS MESSAGE              32220016
         BE    COMPRD                                                   32310016
         SR    RRDLTH,RRDLTH            CLEAR REGISTER                  32400016
         IC    RRDLTH,0(RMSGPTR)        GET RECORD LENGTH               32490016
         AR    RMSGPTR,RRDLTH           POINTING TO NEXT MSG STATUS BYT 32580016
         A     RMSGPTR,ONE              ADD ONE                         32670016
         CLC   0(1,RMSGPTR),ZERO       Q. MORE MESSAGE FOLLOW           32700016
         BE    TESTMSMB                BRANCH IF NO                     32730016
         B     RDOPTION                 BRANCH                          32760016
COMPRD   EQU   *                                                        32800016
         SR    RRDLTH,RRDLTH           CLEAR REGISTER                   32840016
         IC    RRDLTH,1(RMSGPTR)       LENGTH                           32880016
         AR    RMSGPTR,RRDLTH           * POINTING TO NEXT MESSAGE      32940016
         CLC   0(1,RMSGPTR),ZERO       Q. IS  A RECORD NEEDED           33000016
         BNE   RDOPTION                BRANCH IF YES                    33060016
TESTMSMB EQU   *                                                        33120016
         SR    RWORK,RWORK              CLEAR                           33210016
         C     RWORK,ANYSMB(RSMBADDR)  Q. MORE SMB FOLLOW               33300016
         BNE   READSMB                  BRANCH IF YES                   33390016
TESTQUE  EQU   *                                                        33480016
         TM    SWAREA+1,ERRORSW        Q. ERROR SWITCH ON               33570016
         BO    CLEARUP                 BRANCH IF YES                    33660016
         LA    RWORK,CCTPWKA+100        MAKE A DOUBLE BOUNDARY          33759016
         N     RWORK,DOUBLE             AREA                            33768016
         LH    RWORK1,CCTJCTR           JOB COUNTER PACKED              33777016
         CVD   RWORK1,0(RWORK)          CONVERTE TO DECIMAL             33786016
         UNPK  CCTPWKA(5),5(3,RWORK)    PRINTED FORMAT                  33795016
         OI    CCTPWKA+4,X'F0'          CHAGE SIZE                      33804016
         MVC   CCTPWKA(4),CCTPWKA+1                                     33813016
         L     RWORK,CCTPWKA            GET JOB COUNT                   33822016
         ST    RWORK,CCTPWKA+120        SAVE I                          33831016
         MVC   HOLDMSG+DCMSG(24),CMSG   MOVE MSG IN WORKAREA            33851016
         MVC   HOLDMSG+DUNIT(3),CCTUNIT     * SET JOB COMPLETE          33871016
         MVC   HOLDMSG+DJCTR(4),CCTPWKA+120  * MESSAGE IN WORKAREA      33891016
         LA    1,CCTPWKA+8                   *                          33911016
         ST    1,HOLDMSG                     *                          33931016
         MVI   CCTPSTAT+1,X'40'              TURN ON MESSAGE SWITCH     33951016
*                                                                       33971016
*  SET OCT  BASE AND TEST SLOW STOP, IF YES SETUP JOB CLMPLETEP         33991016
*    AND LOGOFF MESSAGE, IF NO SLOW STOP  THEN SETUP JOB COMPLETE       34011016
*   MESSAGE  ONLY                                                       34031016
*                                                                       34051016
RCVT     EQU   6                       CVT BASE                         34071016
ROCT     EQU   7                       OCT BASE                         34091016
RGFXLIST EQU   8                       GFX PARM-LIST BASE               34111016
ROCTENT  EQU   9                       OCT RECORD ENTRY                 34131016
RENTCTR  EQU   10                                                       34151016
CKSTOP   EQU   *                                                        34171016
         L     RCVT,X'10'               CVT ADDRESS                     34191016
         USING CVT,RCVT                                                 34211016
         L     RGFXLIST,CVTQOCR        PARM-LIST ADDR                   34231016
         USING GRAPLIST,RGFXLIST                                        34251016
         L     ROCT,GOCT               OCT ADDRESS                      34271016
         USING GFXOCTHD,ROCT                                            34291016
         LA    ROCTENT,GFXHDSZE+GFXHDSTR OCT RECORD ENTRY               34311016
         USING  GFXOCTEN,ROCTENT                                        34331016
         LH    RENTCTR,OCTUNBR         OCT RECORD NUMBER                34351016
CSEARCH  EQU   *                                                        34371016
         CLC   CCTUNIT(3),OCTUNIT+1    Q. THIS OCT RECORD NEEDED        34391016
         BE    TESTSTOP                BRANCH IF YES                    34411016
         LA    ROCTENT,GFXENSTR+GFXENSZE UPDATE ENTRY                   34431016
         BCT   RENTCTR,CSEARCH         BRANCH                           34451016
TESTSTOP EQU   *                                                        34471016
         TM    OCTATTR2,X'04'          Q. SLOW STOP                     34491016
         BO    STOPMSG                 BRANCH IF YES                    34511016
         DROP  6,7,8,9                                                  34531016
         MVI   HOLDMSG,X'C0'            OPTION BYTE OF MSG PARM         34551016
         B     CLEARUP                                                  34571016
STOPMSG  EQU   *                                                        34591016
         MVC   HOLDMSG+60(42),LOGMSG   * SET LOG OFF                    34611016
         LA    1,HOLDMSG+60            * MESSAGE                        34631016
         ST    1,HOLDMSG+4                                              34651016
         MVI   HOLDMSG,X'40'           *                                34671016
         MVI   HOLDMSG+4,X'C0'                                          34691016
         B     CLEARUP                 BRANCH                           34711016
         EJECT                                                          35010016
*                                                                       35100016
* THIS ROUTINE WRITES SMB MESSAGE ON DIARY DATA SET, IT ALSO HANDLES    35190016
* COMPRESSED MESSAGE IN SYSTEM MESSAGE BLOCK                            35280016
*                                                                       35370016
* INPUT  REGISTER 0 POINTING TO THE STATUS BYTE OF SMB MESSAGE          35460016
*                                                                       35550016
* OUTPUT THE MESSAGE IS WRITTEN ON DIARY DATA SET                       35640016
*                                                                       35730016
* EXIT   RETURN TO CALLING ROUTINE                                      35820016
*                                                                       35910016
* DEFINE REGISTERS                                                      36000016
*RPAR0   EQU   POINTER TO STATUS BYTE OF SMB                            36090016
RLTHPTER EQU   1                   POINTER TO LENGTH OF DATA            36180016
RMOVELTH EQU   5                   LENGTH OF DATA TO BE MOVED           36270016
RDCBADDR EQU   6                   DIARY DATA SET ADDRESS               36360016
RHLDMSG  EQU   7                       POINTER TO DATA MOVE TO          36450016
*RAREA   EQU   8                       POINTER TO DATA WRITE FROM       36540016
RWRITE   EQU   9                   POINTER TO REAL WRITE MACRO          36630016
RCOMPLTH EQU   10                  LENGTH OF COMPRESSED MESSAGE         36720016
REXPDLTH EQU   12                  LENGTH OF EXPANDED MESSAGE           36810016
WRITESMB EQU   *                                                        36900016
         SAVE  (14,12)                  SAVE CALLING REGISTER           36990016
         ST    RSAVE,HOLD13             SAVE CALLING SAVE ADDRESS       37020016
         LA    RSAVE,SMBSAVE           GET OUR SAVE ADDRESS             37050016
         LR    RLTHPTER,RPAR0           INPUT DATA                      37080016
         MVI   CCTPWKA,C' '                                             37170016
         MVC   CCTPWKA+1(176),CCTPWKA   CLEAR WORKAREA                  37260016
         LA    RWRITE,WRITE             AN ADDRESS IN WORKAREA          37350016
         MVC   0(LWRITE,RWRITE),WRITEL  MAKE WRITE REENTERABLE          37440016
         CLI   0(RLTHPTER),X'FE'       Q. COMPRESSED MESSAGE            37530016
         BE    DECOMP                   BRANCH IF YES                   37620016
         SR    REXPDLTH,REXPDLTH        CLEAR REGISTER                  37710016
         IC    REXPDLTH,0(RLTHPTER)     MSG LENGTH                      37800016
         S     REXPDLTH,ONE             SUBTRACT ONE                    37890016
         LA    RHLDMSG,CCTPWKA+4        WORKAREA FOR MESSAGE            37980016
         MVC   0(1,RHLDMSG),1(RLTHPTER) MOVE MESSAGE IN WORKAREA        38070016
         EX    REXPDLTH,*-6                                             38160016
         LA    RAREA,CCTPWKA+4          MESSAGE ADDRESS FOR WRITE-      38250016
EWRITE   EQU   *                                                        38340016
         L     RDCBADDR,CCTRDCBP        DIARY DCB ADDRESS               38430016
         WRITE WECB,SF,(6),(8),MF=E                                     38520016
         CHECK WECB                     CHECK FOR COMPLETION            38610016
         L     RSAVE,HOLD13            RESTORE CALLING SAVE ADDRESS     38650016
WRTN     RETURN (14,12)                 RETURN TO CALLING ROUTINE       38700016
*                                                                       38790016
DECOMP   EQU   *                                                        38880016
         LA    RLTHPTER,1(RLTHPTER)     POINTER TO LENGTH OF COMPRESSED 38970016
*                                       MESSAGE                         39060016
         SR    REXPDLTH,REXPDLTH        FOR EXPANDED MESSAGE LENGTH     39150016
         SR    RCOMPLTH,RCOMPLTH        FOR COMPRESSED MESSAGE LENGTH   39240016
         IC    RCOMPLTH,0(RLTHPTER)     GET TOTAL LENGTH                39330016
         BCT   RCOMPLTH,*+4             DEDUCT ONE BYTE - STATUS BYTE   39420016
         SR    RMOVELTH,RMOVELTH       FOR LENGTH OF A DATA TO BE       39510016
*                                       MOVED                           39600016
         LA    RHLDMSG,CCTPWKA+4        SET ADDRESS WHERE MESSAGE MOVE  39690016
*                                       TO                              39780016
* MOVE IN FIELD FROM COMPRESSED MESSAGE                                 39870016
MFRCM    BCT   RCOMPLTH,*+4            DEDUCT ONE BYTE - FIELD          39960016
         LA    RLTHPTER,1(RLTHPTER)     POINTER TO FIELD LENGTH         40050016
         IC    RMOVELTH,0(RLTHPTER)     GET FIELD LENGTH                40140016
         S     RMOVELTH,ONE             SUBTRACT ONE               4218 40180018
         MVC   0(1,RHLDMSG),1(RLTHPTER) DUMMY                           40230016
         EX    RMOVELTH,*-6             MOVE FIELD IN TO WORK AREA      40320016
         A     RMOVELTH,ONE             RESTORE CONTENT OF REG.    4218 40360018
         AR    REXPDLTH,RMOVELTH       UPDATE COUNTER FOR MOVED DATA    40410016
         AR    RHLDMSG,RMOVELTH         UPDATE POINTER FOR DATA MOVE TO 40500016
         LA    RLTHPTER,1(1,RMOVELTH)   POINTER TO NUMBER OF BLANKS     40590016
* IS THE COMPRESSED MESSAGE COMPLETE                                    40680016
         BCT   RCOMPLTH,*+4            DEDUCT ONE BYTE - BLANKS         40770016
         SR    RCOMPLTH,RMOVELTH        DEDUCT LENGTH HAS MOVED         40860016
         BZ    PWRITE                   BRANCH IF COMPLETE              40950016
* MOVE IN THE BLANKS FOR EXPANDED RECORD                                41040016
         IC    RMOVELTH,0(RLTHPTER)     GET BLANK LENGTH                41130016
         S     RMOVELTH,ONE             SUBTRACT ONE               4218 41170018
         MVI   0(RHLDMSG),C' '          * MOVE BLANKS IN                41220016
         MVC   1(1,RHLDMSG),0(RHLDMSG)  * WORKAREA                      41310016
         EX    RMOVELTH,*-6             *                               41400016
         A     RMOVELTH,ONE             RESTORE CONTENT OF REG.    4218 41440018
         AR    REXPDLTH,RMOVELTH       UPDATE COUNTER FOR MOVED DATA    41490016
         AR    RHLDMSG,RMOVELTH         UPDATING POINTER FOR DATA MOVE  41580016
*                                       TO                              41670016
         B     MFRCM                    BRANCH                          41760016
PWRITE   LA    RAREA,CCTPWKA+4         MSG ADDR                         41850016
         B     EWRITE                   BRANCH                          41940016
*                                                                       42030016
         EJECT                                                          42120016
* THIS IS IEF MESSAGE HANDLING ROUTINE IT IS ENTER FROM SMBCTL ROUTINE  42210016
* VIA A BRANCH                                                          42300016
*                                                                       42390016
* INPUT  RPAR0 POINTING TO MESSAGE STATUS BYTE                          42480016
*                                                                       42570016
* OUTPUT- IF THIS MESSAGE IS DEPOND ON OTHER MESSAGES, THIS MESSAGE NO  42660016
*         AND THE NUMBERS BE DEPONDED ON ARE SAVED - DMESSAGE           42750016
*                                                                       42840016
*       - IF THIS MESSAGE IS DEPONDED BY OTHER MESSAGES, THIS IT IS     42930016
*         SAVED - SAVEMSG                                               43020016
*                                                                       43110016
*       - IF THERE IS ADDITIONAL MESSAGE TO BE DISPLAY - ADMSGHD        43200016
*                                                                       43290016
* EXIT  - BRANCH TO TESTMMSG ROUTINE IF MESSAGE NOT DISPLAY             43380016
*                                                                       43470016
*       - BRANCH TESTTRLT ROUTINE IF MESSAGE DISPLAYS                   43560016
*                                                                       43650016
RSTATUS  EQU   5                   POINTING SMB STATUS BYTG             43740016
RWORK1   EQU   7                                                        43830016
RINPUT   EQU   9                   MESSAGE ENTRY IN ATTRIBUTE TABLE     43920016
RCORR    EQU   10                  ENTRY IN CORRELATION TABLE           44010016
RRET1    EQU   11                  RETURN REGISTER                      44100016
IEFHANDL EQU   *                                                        44190016
         LR    RSTATUS,RPAR0            SAVE CALLING SEQUENCE           44280016
         TM    SWAREA,SCHATTR          Q. SCHEDULER ATTRIBUTE TABLE     44370016
*                                         LOAD IN CORE                  44460016
         BO    PSEARCH                  BRANCH IF YES                   44550016
         LOAD  EP=IKASMBSA              LOAD IN SCHECDULER ATTRIBUTE    44640016
*                                       TABLE                           44730016
         ST    RPAR0,SCHAP              SAVE ITS ADDRESS                44820016
         OI    SWAREA,SCHATTR           TURN ON SCHEDULER ATTRIBUTE     44910016
         EJECT                                                          45000016
*                                       TABLE SWITCH                    45090016
PSEARCH  EQU   *                                                        45180016
*                                                                       45270016
* PREPARE GO TO SEARCH ROUTINE RPAR0- IEF NUMBER                        45360016
*                              RPAR1- ENTRY TO ATTRBUTE TABLE           45450016
         XC    CCTPWKA(4),CCTPWKA       * MOVE IEF NUMBER INTO          45540016
         MVC   CCTPWKA+1(3),4(RSTATUS)  * WORKAREA                      45630016
         L     RPAR0,CCTPWKA            GET ABEND NUMBER                45720016
         L     RPAR1,SCHAP              ATTRIBUTE TABLE ENTRY           45810016
         BAL   RRET,SEARCH              BRANCH TO SEARCH ROUTINE        45900016
*                                                                       45990016
* TEST THE CHARACTERISTICS OF IEF MESSAGE                               46080016
*                                                                       46170016
         LTR   RBR,RBR                 Q. IEF MSG FOUNDED IN ATTR-TABLE 46260016
         BC    6,TESTATTR               BANCH IF YES                    46350016
*                                                                       46440016
*  BUILD A MESSAGE ATTRIBUTE ENTRY FOR THE UNFOUND IEF MESSAGE NUMBER   46530016
*                                                                       46620016
         LA    RINPUT,DUMYATTR          POINTER TO A MSG ATTRIBUTE      46710016
*                                       ENTRY                           46800016
         B     TESTA1                   BRANCH                          46890016
*  TEST ATTRIBUTES OF THE MESSAGE                                       46980016
*                                                                       47070016
TESTATTR EQU   *                                                        47160016
         LR    RINPUT,RBR               SAVE INPUT DATA                 47250016
TESTA1   TM    DATTR(RINPUT),DISPLAY   Q. DISPLAY THIS MESSAGE          47340016
         BZ    TESTMMSG                 BRANCH IF NO                    47430016
         B     TESTTRLT                                                 51030016
         EJECT                                                          51120016
*                                                                       51210016
TESTTRLT EQU   *                                                        51300016
         TM    DATTR(RINPUT),DTRSLATE  Q. THIS MESSAGE NEED TRANSLATION 51390016
         BZ    NTLMSG                   BRANCH IF NO                    51480016
         MVC   IKASMBSX(8),STMODLE     MOVE SCH TEXT TABLE MODLE        51570016
*                                       IN WORKAREA                     51660016
         MVC   IKASMBSX+7(1),7(RINPUT)  MOVE KEY WORD IN                51750016
         LA    RPAR0,IKASMBSX           TABLE NAME ADDRESS              51840016
         LOAD  EPLOC=(0)                LOAD IN THIS TABLE              51930016
         OI    SWAREA,SCHTXT            TURN ON SCHEDULER TEXT SW. 5102 51935018
         B     PMBLD                   BRANCH                           51940016
NTLMSG   EQU   *                                                        51960016
         LR    RPAR1,RMSGPTR                                            51990016
*        BAL   14,MSGBUILD                                              52020016
         SR    RBR,RBR                  ZERO RETURN CODE           1042 52030017
         B     TESTERR                 BRANCH                           52050016
         EJECT                                                          52110016
* PREPARE GO MESSAGE BUILD ROUTINE MSGBUILD                             52200016
* RPAR0 - POINTING TO PARAMETER LIST                                    52290016
*                                                                       52380016
* PARAMETER LIST LOOK LIKE THIS                                         52470016
*        +0  TEXT TABLE ADDRESS                                         52560016
*        +4  ONE ENTRY OF ATTRIBUTE TABLE                               52650016
PMBLD    ST    RPAR0,TEXTADDR          *SET UP PARAMETER LIST           52740016
         MVC   ATTENTRY(8),0(RINPUT)    MOVE OJECT FIELD IN             52830016
         LA    RPAR0,PARLIST            POINTING TO PARAMETER LIST      52920016
         LR    RPAR1,RSTATUS           POINTER TO MSG  ATATUS BYTE      53010016
         BAL   RRET,MSGBUILD            BRANCH                          53100016
TESTERR  CH    RBR,QUITCODE             Q. MUST TERMINATE          1042 53190017
         BE    TERMNATE                 YES                        1042 53280017
         TM    SWAREA+1,ERRORSW        Q. ERROR SWITCH ON               53370016
         BO    TESTMMSG                BRANCH IF YES                    53460016
         OI    SWAREA+1,ERRORSW         TURN ON  ERROR SWITCH           53550016
         B     TESTMMSG                BRANCH                           54150016
         EJECT                                                          54810016
***                                                                     54900016
*** ROUTINE NEED TO BE IMPLEMENT (DISPLAY ADDITIONAL MESSAGES)          54990016
DPLYAMSG EQU   *                                                        55080016
*                                                                       55140016
* MSGBUILD ROUTINE BUILD MESSAGE TABLE IN WORKAREA AND BRANCH TO DMSG   55200016
* DISPLAY SMB MESSAGE AND HISTORY                                       55260016
*                                                                       55320016
* INPUT  ATTENTRY CONTAINS IEF MSG ATTRIBUTE ENTRY                      55380016
*        RPAR1 POINTER TO STATUS BYTE OF SMB MESSAGE                    55440016
*                                                                       55500016
* EXIT   RETURN TO CALLING                                              55560016
*                                                                       55620016
* RPAR1  EQU   1                   PARAMETER REGISTER                   55680016
RPARLIST EQU   5                   POINTER TO MSG PARAMETER LIST        55740016
RMSG     EQU   6                   POINTER TO MSG                       55800016
* RTENTRY EQU  7                                                        55860016
* RWORK  EQU   8                                                        55920016
ROPTBYTE EQU   9                                                        55980016
RMSGLTH  EQU   10                  CONTAINS MSG LENGTH                  56040016
RXYPOS   EQU   11                  POINTER TO CURRENT XY POSITION       56100016
RFROM    EQU   12                  POINTER TO A RELATIVE ADDR WHERE     56160016
*                                  SMB DATA MOVE TO TEXT                56220016
* RSAVE  EQU   13                  POINTER TO SMB SAVE AREA             56280016
RTO      EQU   15                  A RELATIVE ADDR WHERE DATA MOVE TO   56340016
*                                                                       56400016
MSGBUILD EQU   *                                                        56460016
         SAVE  (14,12)                  SAVE CALLING REGISTERS          56520016
         ST    RSAVE,HOLD13             SAVE CALLING SAVE AREA ADDRESS  56580016
         LA    RSAVE,SMBSAVE            OUR SAVE ADDRESS                56640016
         MVC   HOLDCST(4),CCTCSTP       SAVE CST ADDRESS                56700016
         LA    RTENTRY,DMSGTABL         SMB MSG TABLE ADDRESS           56760016
         ST    RTENTRY,CCTCSTP                                          56820016
*                                       GENERATE MESSAGE                56880016
         MVC   0(TLENGTH,RTENTRY),MODENTRY MOVE MSG MODEL IN WORKAREA   56940016
         MVC   TEXTDISP(28,RTENTRY),CONSTANT MOVE COMSTANT IN           57000016
*                                                                       57060016
*  SET POINTERS                                                         57120016
*                                                                       57180016
         LA    RXYPOS,XY1               POINTER TO FIRST MSG X Y        57240016
*                                       POSITION                        57300016
         LA    RTENTRY,TLENGTH(RTENTRY) POINTER TO NEXT MSG TABLE ENTRY 57360016
         SR    RPARLIST,RPARLIST        CLEAR REGISTER                  57420016
         IC    RPARLIST,ATTENTRY+DTEXT  POINTER TO A RELATIVE ADDR OF   57480016
*                                       POINTER                         57540016
         L     RWORK,TEXTADDR          TEXT TABLE ADDR                  57600016
         AR    RPARLIST,RWORK          ADDR WHICH CONTAINS RELATIVE     57660016
*                                       ADDR OF PARAMETER LIST          57720016
         LH    RPARLIST,0(RPARLIST)     *                               57780016
         AR    RPARLIST,RWORK                                           57840016
*                                                                       57900016
*  START TO BUILD A MESSAGE ENTRY                                       57960016
*                                                                       58020016
MOVEMOD  EQU   *                                                        58080016
         MVC   0(TLENGTH,RTENTRY),MODENTRY   MOVE MODEL IN WORKAREA     58140016
         MVC   XYDISP(2,RTENTRY),0(RXYPOS)  MOVE X Y POSITION IN        58200016
         SR    ROPTBYTE,ROPTBYTE             CLEAR REGISTER             58260016
         IC    ROPTBYTE,0(RPARLIST)          OPTION BYTE                58320016
         MVI   0(RPARLIST),X'00'             ZERO OPTION BYTE           58380016
         L     RMSG,0(RPARLIST)          POINT MESSAGE                  58440016
         C     RMSG,FF                       * IN SMB                   58500016
         BE    LSTENTRY                      BRANCH IF YES              58560016
         IC    RMSGLTH,3(RMSG)               MSG LENGTH                 58620016
         S     RMSGLTH,ONE             SUBTRACT ONE                     58650016
         EX    RMSGLTH,MOVEMSG1              MOVE MSG INTO TABLE        58680016
         SR    RWORK,RWORK             CLEAR REGISTER                   58740016
         IC    RWORK,2(RMSG)           * TEST IF ANY DATA IN SMB        58800016
         LTR   RWORK,RWORK             * NEEDED TO DISPLAY              58860016
         BC    8,TESTEND                     BRANCH IF NO               58920016
         SR    RFROM,RFROM                   *                          58980016
         IC    RFROM,0(RMSG)                 *GET DATA ADDRESS          59040016
         AR    RFROM,RPAR1                   *                          59100016
         S     RWORK,ONE               LENGTH OF DATA                   59160016
         EX    RWORK,MOVEDATA          MOVE                             59220016
TESTEND  CH    ROPTBYTE,ENTRYEND            Q. MORE MESSAGE             59280016
         BE    GODGM                         BRANCH IF NO               59340016
*                                                                       59400016
* UPDATE POINTERS                                                       59460016
*                                                                       59520016
         LA    RXYPOS,2(RXYPOS)         POINTER TO NEXT X Y POSITION    59580016
         LA    RTENTRY,TLENGTH(RTENTRY) POINTER TO NEXT ENTRY           59640016
         LA    RPARLIST,4(RPARLIST)     POINTER TO NEXT PARAMETER       59700016
         B     MOVEMOD                  BRANCH                          59760016
LSTENTRY EQU   *                                                        59820016
         SR    RMSGLTH,RMSGLTH          CLEAR REGISTER                  59880016
         IC    RMSGLTH,0(RPAR1)         MESSAGE LENGTH IN SMB           60000016
         TM    SWAREA,ABENDSW          Q. ABEND SWITCH ON               60010016
         BC    8,SEIGHT                BRANCH IF NO                     60020016
         EX    RMSGLTH,MOVESMB1        MOVE ABEND MSG                   60030016
         B     GODGM                   GO TO DGM AND DISPLAY            60040016
SEIGHT   EQU   *                                                        60050016
         S     RMSGLTH,EIGHT            MSG LENGTH - IEFXXXI            60060016
         C     RMSGLTH,FIFTY2          Q. MSG LENGTH LONGER THAN        60070016
*                                         FIFTY TWO                     60080016
         BNH   EX                      BRANCH IF NO                     60090016
         L     RMSGLTH,FIFTY2          GET NEW LENGTH                   60100016
EX       EX    RMSGLTH,MOVESMB         MOVE DATA                        60140016
GODGM    EQU   *                                                        60180016
         MVC   TLENGTH(4,RTENTRY),ZEROS END OF TABLE                    60240016
         TM    CCTSSTAT,32              Q. REMOTE GRAPHIC DEVICE      S 60260016
         BO    SGJPMSG                  YES, TRANSMIT MSGS            S 60280016
         L     RBR,CCTDGMP              DGM ADDRESS                     60300016
SGJPRET  EQU   *                                                      S 60330016
         LR    RPAR1,RCCT               CCT ADDRESS                     60360016
         BALR  RRET,RBR                 BRANCH                          60420016
         B     PRETURN                  BRANCH                          60480016
         DC    X'C000'                  START GENERATE                  60540016
PRETURN  EQU   *                                                        60600016
         MVC   CCTCSTP(4),HOLDCST       RESTORE CST                     60660016
         L     RSAVE,HOLD13             RESTORE CALLING SAVE            60720016
         NI    CCTPSTAT+1,X'DF'            ATTENTION SWITCH ON          60840016
         LA    RPAR0,IKASMBSX          TEXT TABLE ADDRESS               61020016
         DELETE EPLOC=(0)              DELETE                           61080016
         XC    IKASMBSX(8),IKASMBSX     CLEAR AREA                      61140016
         NI    SWAREA,255-SCHTXT        TURN OFF SCHEDULER TEXT SW.5102 61170018
SMBWAIT  EQU   *                                                        61200016
         WAIT  ECB=CCTPECB             WAIT                             61260016
         MVI   CCTPECB,X'00'           CLEAR ECB                        61320016
         SR    RBR,RBR                  ZERO REGISTER,             1042 61350017
         IC    RBR,CCTPECB+3            GET POST CODE              1042 61380017
         RETURN (14,12),RC=(15)         RETURN WITH CODE           1042 61410017
MOVEMSG1 MVC   TEXTDISP(0,RTENTRY),4(RMSG)                              61440016
MOVEDATA MVC   TEXTDISP(0,RTENTRY),1(RFROM)                             61500016
MOVESMB  MVC   SMBDISPL(0,RTENTRY),8(RPAR1)                             61560016
MOVESMB1 MVC   SMBDISPL(0,RTENTRY),1(1)                                 61600016
         EJECT                                                          61601016
*                                                                     S 61602016
*    THIS ROUTINE WILL SCAN THE MESSAGE TABLE IN THE WORKAREA         S 61603016
*    AND BUILD ENTRIES IN THE BTAM BUFFER, AFTER WHICH THE TEXT       S 61604016
*    WILL BE TRANSMITTED TO THE 1130/2250 SUBSYSTEM                   S 61605016
*                                                                     S 61606016
*                   INPUT - REFER TO 'MODENTRY'                       S 61607016
*                   OUTPUT - VARIABLE EVEN NUMBER OF BYTES            S 61608016
*                            0-1 - LENGTH OF TEXT                     S 61609016
*                            2-N - TEXT                               S 61610016
         SPACE 1                                                      S 61611016
SGJPMSG  EQU   *                                                      S 61612016
         SPACE 1                                                      S 61613016
*    INITIALIZE POINTERS                                              S 61614016
         SR    RMSGLTH,RMSGLTH          ZERO TEXT LENGTH REGISTER     S 61615016
         SR    ROPTBYTE,ROPTBYTE        ZERO 'MODENTRY' LENGTH REG    S 61616016
         L     RWORK,CCTBUFFP           ADDR OF OUTPUT BRAM BUFFER    S 61617016
         L     RTENTRY,CCTCSTP          ADDR OF INPUT MESSAGE TABLE   S 61618016
*    BYPASS FIRST ENTRY - 'CONSTANT'                                  S 61619016
         IC    ROPTBYTE,0(,RTENTRY)     GET ENTRY LENGTH              S 61620016
         AR    RTENTRY,ROPTBYTE         BYPASS 1ST ENTRY              S 61621016
*    MOVE TEXT INTO OUTPUT BUFFER                                     S 61622016
NEXTENT  IC    ROPTBYTE,0(,RTENTRY)     GET ENTRY LENGTH              S 61623016
         IC    RMSGLTH,2(,RTENTRY)      GET TEXT LENGTH               S 61624016
         BCTR  RMSGLTH,0                DECREMENT FOR MOVE            S 61625016
         EX    RMSGLTH,MOVEBUF          MOVE IN TEXT OF MSG           S 61626016
         TM    2(RTENTRY),1             Q. ODD TEXT LENGTH            S 61627016
         BO    PAD                      YES - PAD WITH BLANK          S 61628016
         LA    RMSGLTH,1(,RMSGLTH)      INCREMENT AFTER MOVE          S 61629016
STLTH    STH   RMSGLTH,0(,RWORK)        MOVE IN LENGTH OF TEXT        S 61630016
         LR    RXYPOS,RWORK             SAVE STARTING POINT           S 61631016
         LA    RWORK,2(RMSGLTH,RWORK)   GET NEXT OUTPUT POSITION      S 61632016
         LA    RTENTRY,0(ROPTBYTE,RTENTRY)   GET NEXT MESSAGE ENTRY   S 61633016
         CLC   0(4,RTENTRY),ZEROS       Q. LAST ENTRY                 S 61634016
         BNE   NEXTENT                  NO,THERE ARE MORE ENTRIES     S 61635016
         OI    0(RXYPOS),128            INDICATE LAST ENTRY           S 61636016
         S     RWORK,CCTBUFFP           GET SIZE OF OUTPUT,           S 61637016
         ST    RWORK,CCTRECLN           STORE IT FOR IKDIOR           S 61638016
         LA    RPAR0,4                  SETTING CODE FOR I/O ROUTINE  S 61639016
         L     RBR,CCTIORP              LOADING ADDR OF I/O ROUTINES  S 61640016
         B     SGJPRET                  TRANSMIT TO SUBSYSTEM         S 61641016
PAD      LA    RXYPOS,3(RMSGLTH,RWORK)  ADJUST FOR TOTAL SIZE         S 61642016
         MVI   0(RXYPOS),64             PAD TEXT WITH BLANK           S 61643016
         LA    RMSGLTH,2(RMSGLTH)       COMPENSATE FOR EXTRA CHAR     S 61644016
         B     STLTH                                                  S 61645016
MOVEBUF  MVC   2(0,RWORK),12(RTENTRY)   MOVE TEXT TO OUTPUT BUFFER    S 61646016
         EJECT                                                          61650016
         EJECT                                                          64080016
*                                                                       64170016
* THIS IS A SEQUENTIAL SEARCHING ROUTINE                                64260016
*                                                                       64350016
*  INPUT REGISTER   0- ABEND CODE OR IEF MESSAGE NUMBER                 64440016
*                   1- POINTING TO EITHER ABEND OR SCHEDULER            64530016
*                      ATTRIBUTE TABLE                                  64620016
* OUTPUT REGISTER 15 POINTING TO OBJECT FIELD ENTRY AND WILL CONTAIN    64710016
*        ZERO IF THE SEARCH WAS FAILD TO FIND THE ARGUMENT              64800016
RTENTRY  EQU   7                   ENTRY POINT OF TABLE                 64890016
RTESIZE  EQU   8                   ENTRY SIZE                           64980016
RTEND    EQU   9                   END OF TABLE                         65070016
SEARCH   EQU   *                                                        65160016
         SAVE  (14,12)                                                  65250016
         LR    RTENTRY,RPAR1            ENTRY OF TABLE                  65340016
         L     RTEND,0(RTENTRY)        TABLE SIZE                       65430016
         LA    RTESIZE,8                SET INCREAMENT                  65520016
         AR    RTEND,RTENTRY           END OF TABLE ADDRESS             65610016
         LA    RTENTRY,4(RTENTRY)       POINTING TO FIRST ENTRY FIELD   65700016
         ST    RPAR0,CCTPWKA            SAVE ARGUMENT                   65790016
SEARCH1  CLC   CCTPWKA+1(3),0(RTENTRY)  COMPARE IF FOUND                65880016
         BC    8,FOUND                  BRANCH IF YES                   65970016
         BXLE  RTENTRY,RTESIZE,SEARCH1 Q. FURTHER SEARCH NEEDED         66060016
         LA    RBR,0                    NO SET NOT FOUND RETURN CODE    66150016
         B     RETN                     BRANCH                          66240016
FOUND    LR    RBR,RTENTRY              LOAD ENTRY WE FOUND             66330016
RETN     RETURN (14,12),RC=(15)         RETURN                          66420016
IOERROR  EQU   *                                                        66427016
         LA    0,IRRPARM           PARAMETER PAST TO IERR               66434016
         LR    1,RCCT              CCT ADDRESS                          66441016
         L     15,CCTIERRP         IERR ADDR                            66448016
         BALR  14,15                    GO TO IERR ROUTINE              66455016
         B     EXIT                     TO EXIT                    PDUM 66462018
IOERROR1 EQU *                                                          66469016
         LA    RPAR0,IRRPARM1          PARM-LIST ADDRESS                66476016
         LR    RPAR1,RCCT              CCT ADDRESS                      66483016
         L     RBR,CCTIERRP            IKAIERR ADDRESS                  66490016
         BALR  RRET,RBR                 GO TO IERR                      66499016
TERMNATE EQU   *                                                   1042 66503017
         LA    1,WORKBEG                     * FREEMAIN AND RETURN      66508016
         FREEMAIN R,LV=WORKEND-WORKBEG,A=(1) *                          66517016
         L     RSAVE,CCTPSAVE+4              * TO O/S                   66526016
         RETURN (14,12),RC=0            EXIT                       1042 66536017
SMBSYNAD B     IOERROR1                                                 66547016
         EJECT                                                          66600016
*                                                                       66690016
*                             CONSTANT  AREA                            66780016
*                                                                       66870016
LWKA     DC    A(WORKEND-WORKBEG)       WORKAREA LENGTH                 66960016
STMODLE  DC    C'IKASMBS '              SCHEDULER MESSAGE TABLE MODLE   67050016
AMODEL   DC    C'IKASMBC '              ABEND CODE MESSAGE TABLE MODEL  67140016
ABEND820 DC    C'0820'                  A NUMBER                        67230016
ONE      DC    F'1'                     ONE                             67320016
EIGHT    DC    F'8'                        EIGHT                        67410016
FIFTY2   DC    F'52'                   A NUMBER                         67450016
FF       DC    XL4'00FFFFFF'                                            67500016
DOUBLE   DC    X'FFFFFFF8'              A NUMBER                        67540016
ZEROS    DC    F'0'                                                     67560016
ENTRYEND DC    X'00C0'                                                  67590016
ZERO     DC    X'00'                    ZERO                            67680016
IEFMSG   DC    C'IEF'                   TEST IEF MESSAGE                67770016
COMPCODE DC    C'COMPLETION CODE '      TEST FOR SMB COMPLETION CODE    67860016
IEF300   DC    C'300'                   A NUMBER                        67950016
         DS    0H                       ALIGNMENT                       67970017
QUITCODE DC    X'001C'                  'MUST TERMINATE' CODE      1042 67990017
CMSG     DC    X'16'                                                    68030016
         DC    CL24'JOB JXXXYYYY COMPLETED  '                           68070016
LOGMSG   DC    X'2A'                   LENGTH                           68120016
         DC    C'SYSTEM OPERATOR REQUESTS THAT YOU LOG OFF   '          68160016
DUMYATTR DS    0F                                                       68220016
         DC    CL3' '                   MESSAGE NUMBER                  68310016
         DC    XL2'A800'                ATTRIBUTES                      68400016
         DC    AL1(0)                   POINTER TO A COR-TABLE ENTRY    68490016
         DC    AL1(0)                   POINTER TO A TEXT TABLE ENTRY   68580016
         DC    C'1'                     KEY WORD OF A TEXT TABLE        68670016
DUMYATR  DC    CL3'   '                 ABEND CODE                      68760016
         DC    AL2(0)                   ATTRIBUTES                      68850016
         DC    AL1(0)                   RESERVED                        68940016
         DC    AL1(0)                   RELATIVE ADDR FOR A TEXT ENTRY  69030016
         DC    C'1'                     KEY WORD OF TEXT TABLE          69120016
TWO      DC    H'2'                    A NUMBER                         69130016
BLANKRD  DC    CL60' '                                                  69140016
         DC    CL60' '                                                  69150016
         DC    CL60' '                                                  69160016
         DC    CL60' '                                                  69170016
IRRPARM  EQU   *                                                        69172016
         DC    CL3'056'                MESSAGE NUMBER                   69174016
MODULE   DC    CL5'PSMB0'         MODULE ID                             69176016
         DC    X'C0'                   CONTROL BITS                     69178016
         DC    AL3(DCBMSG)             DATA ADDRESS                     69180016
*                                                                       69182016
DCBMSG   EQU   *                                                        69184016
         DC    H'5'                     LENGTH                     1042 69186018
         DC    C'JCL '                  DATA TO BE INSERTED        1042 69188018
*                                                                       69190016
IRRPARM1 EQU   *                                                        69192016
         DC    CL3'056'                MESSAGE NUMBER                   69194016
         DC    CL5'PSMB0'              MODULE'S NAME                    69196016
         DC    X'C0'                    RETURN + INSERT                 69198016
         DC    AL3(DCBMSG1)            DATA TO BE INSERTED ADDRESS      69200016
*                                                                       69202016
DCBMSG1  EQU   *                                                        69204016
         DC    H'5'                     LENGTH                     1042 69206018
         DC    C'JCL '                  DATA TO BE INSERTED        1042 69208018
         SPACE 2                                                        69208220
*********************************************************************** 69208420
*                                                                       69208620
*        MAINTENANCE AREA                                        A33564 69208820
*                                                                       69209020
*********************************************************************** 69209220
PATCH    DC    30F'0'                                            A33564 69209420
         SPACE 2                                                        69209620
         EJECT                                                          69210016
*                                                                       69930016
FWRITE   WRITE DECBR,SF,,,120,MF=L     WRITE                            69940016
FWRITEE  EQU   *                                                        69950016
*                                                                       69960016
LWRITE1  EQU   FWRITEE-FWRITE                                           69970016
READ     EQU   *                                                        70020016
         READ  SMBECB,SF,,,176,MF=L                                     70110016
READEND  EQU   *                                                        70200016
         DS    0F                                                       70290016
WRITEL   WRITE DECBW,SF,,,120,MF=L                                      70380016
WRITELE  EQU   *                                                        70470016
*                                                                       70560016
         DS    0F                                                       70630016
OPENDCB  EQU   *                                                        70700016
         OPEN  (SMBDCB,(INOUT)),MF=L                                    70770016
OPENEND  EQU   *                                                        70840016
*                                                                       70910016
         DS    0F                                                       70980016
CLOSESMB CLOSE (SMBDCB),MF=L                                            71050016
         EJECT                                                          71120016
*                                                                       71190016
* SMB DCB                                                               71260016
*                                                                       71330016
SMBDCB   DCB   BLKSIZE=176,DDNAME=GJPJCL,DSORG=PS,EODAD=TESTQUE,       X71400016
               MACRF=RP,RECFM=FBA,SYNAD=SMBSYNAD,LRECL=176         PDUM 71470018
DCBEND   EQU   *                                                        71540016
*                                                                       71610016
*                                                                       71680016
LSMBDCB EQU   DCBEND-SMBDCB            DCB LENGTH                       71750016
LOPEN    EQU   OPENEND-OPENDCB         OPEN LENGTH                      71820016
LREAD    EQU   READEND-READ        READ MACRO LENGTH                    71910016
LWRITE   EQU   WRITELE-WRITEL           LENGTH OF WRITE MACRO           72000016
*                                                                       72002016
* MODEL FOR SMB MESSAGE TABLE ENTRIES                                   72004016
*                                                                       72006016
         DS    0F                                                       72008016
MODENTRY EQU   *                        ENTRY OF MODEL                  72010016
         DC    AL1(ENDENTRY-MODENTRY)       ENTRY LENGTH                72012016
         DC    X'FF'                                                    72014016
         DC    AL1(67)                  TEST LENGTH                     72016016
         DC    X'0'                     RESERVED                        72018016
         DC    X'0'                     COMMAND STATUS BITS             72020016
         DC    X'0'                     POINTER TO NEXT MULT-CHOICE     72022016
         DC    X'0'                     AVAILABLE COMMAND NEXT TIME     72024016
         DC    X'0'                     INPUT LENGTH                    72026016
         DC    AL1(34)                  GRID COLUMNS FOR X              72028016
         DC    AL1(76)                  GRID LINES FOR Y                72030016
         DC    H'0'                     INPUT MAPPING                   72032016
         DC    CL68' '                  TEXT                            72034016
ENDENTRY EQU   *                                                        72036016
*                                                                       72038016
CONSTANT DC    CL28'ACKNOWLEDGE MESSAGE WITH END'                       72040016
*                                                                       72042016
TLENGTH  EQU   ENDENTRY-MODENTRY                                        72044016
         DS    H                                                        72046016
XY1      DC    X'0B61'                  X AND Y POSITION FOR FIRST      72048016
*                                       MESSAGE LINE                    72050016
XY2      DC    X'0B5D'                  X AND Y POSITION FOR SECOND     72052016
*                                       MESSAGE LINE                    72054016
XY3      DC    X'0B59'                  X AND Y POSITION FOR THIRD      72056016
*                                       MESSAGE LINE                    72058016
XY4      DC    X'0B55'                  X AND Y POSITION FOR FOURTH     72060016
*                                       MESSAGE LINE                    72062016
XY5      DC    X'0B51'                  X AND Y POSITION FOR FIFTH      72064016
*                                       MESSAGE LINE                    72066016
XY6      DC    X'0B4D'                  X AND Y POSITION FOR SIXTH      72068016
*                                       MESSAGE LINE                    72070016
         EJECT                                                          72090016
*                                                                       72180016
* THIS IS A WORKAREA LAYOUT                                             72270016
*                                                                       72360016
WORKBEG  DSECT                                                          72450016
*                                                                       72540016
*                   SWITCHES CONTROL                                    72630016
*                                       ATTRIBUTES                  BIT 72720016
*                                  PARM LIST FOR IKAPDIS0          PDUM 72730018
ACCT     DS    A(CCT)                                              PDUM 72740018
ADCB     DS    A(DSMBDCB)                                          PDUM 72750018
DISPLAD  DS    C                   SWITCH FOR CALLING DATA SET DISPPDUM 72760018
SWAREA   DS    CL2            SPACE FOR SWITCH CONTROL                  72810016
ABDATTR  EQU   X'80'          0-ABEND ATTRIBUTE TABLE IS NOT LOADED  0  72900016
*                             1-ABEND ATTRIBUTE TABLE IS LOADED      0  72990016
ABDTXT   EQU   X'40'               0-ABEND TEXT TABLE IS NOT LOADED     73080016
*                                  1-ABEND TEXT TABLE IS LOADED         73170016
* BIT 3 IS RESERVED                                                     73260016
ABENDSW  EQU   X'20'                   1-ABEND MODE                     73300016
SCHATTR  EQU   X'08'          0-SCHEDULER ATTRIBUTE TABLE UNLOADED   4  73350016
*                             1-SCHEDULER ATTRIBUTE TABLE IS LOADED  4  73440016
SCHCORR  EQU   X'04'          0-SCHEDULER CORRELATION TABLE UNLOADED 5  73530016
*                             1-SCHEDULER CORRELATION T IS LOADED    5  73620016
SCHTXT   EQU   X'02'          0-SCHEDULER TEXT TABLE IS NOT LOADED      73710016
*                             1-SCHEDULER TEXT TABLE 1 IS LOADED     6  73800016
MSGQUESW EQU   X'80'          0-NO MESSAGE IN QUEUE                  8  73890016
ERRORSW  EQU   X'40'          0-NO ERROR MESSAGE OCCURED             9  73980016
*                             1-ERROR MESSAGE OCCURED                9  74070016
ADMSGSW  EQU   X'20'          0-NO ADDITIONAL ERROR MESSAGE         10  74160016
*                             1-ADDITIONAL ERROR MESSAGE FOLLOWS    10  74250016
*                             1-HAVE MESSAGE IN QUEUE                8  74340016
* BIT 11 TO 15 ARE RESERVED                                             74430016
*                        ********************                           74520016
*                                                                       74610016
* EVERY SMB RECORD IS READ IN THIS AREA                                 74700016
*                                                                       74790016
         DS    0F                                                       74880016
ASMB     DS    XL176                                                    74970016
*                                                                       75060016
ABENDAP  DS    F                   ABEND ATTRIBUTE TABLE ADDRESS        75150016
SCHAP    DS    F                   SCHEDULER ATTRIBUTE TABLE ADDRESS    75240016
SCHCORAP DS    F                   SCHEDULER CORRELATION TABLE ADDRESS  75330016
MSGSTATU DS    F                   POINTING TO SMB MESSAGE STATUS BYTE  75420016
PARLIST  EQU   *                                                        75510016
TEXTADDR DS    F                   TEXT TABLE ADDRESS                   75600016
ATTENTRY DS    2F                                                       75690016
ABENDATR DS    D                        SPACE FOR A ATTRIBUTE ENTRY     75780016
IKASMBSX DS    D                        A DOUBLE WORD AREA              75870016
IKASMBCX DS    D                        A DOUBLE WORD FOR TEXT TABLE    75960016
DREAD    DS    XL(READEND-READ)    SPACE FOR READ MACRO                 76680016
         DS    0F                                                       76770016
WRITE    EQU   *                                                        76860016
WECB     DS    XL(WRITELE-WRITEL)      SPACE FOR WRITE                  76950016
*                                                                       77040016
         DS    0F                                                       77050016
DSMBDCB  DS    XL(DCBEND-SMBDCB)       SPACE FOR SMBDCB                 77060016
         DS    0F                                                       77070016
DOPENDCB DS    F                       SPACE FOR OPEN                   77080016
*                                                                       77090016
DCLOSE   DS    F                       SPACE FOR CLOSE                  77100016
HOLD13   DS    F                                                        77110016
SMBSAVE  DS    18F                                                      77120016
HOLDMSG  DS    XL256                   SAVE MESSAGE AREA                77120516
*                                                                       77121016
* SPACE FOR SMB MESSAGE TABLE                                           77122016
*                                                                       77123016
         DS    0F                                                       77124016
DMSGTABL DS    XL500                    SPACE FOR MESSAGE TABLE         77125016
*                                                                       77126016
HOLDCST  DS    F                       ADDRESS SAVE CST                 77127016
QMPA     DS    176C                     AREA FOR QMPA-IOB          PDUM 77128018
WORKEND  EQU   *                   END OF WORK AREA                     77130016
         EJECT                                                          77220016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         77310016
         SPACE                                                          77400016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    77490016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     77580016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       77670016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             77760016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  77850016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  77940016
*                   SET.                                                78030016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      78120016
*                   SECOND.                                             78210016
         SPACE 2                                                        78300016
CCT      DSECT                                                          78390016
         SPACE                                                          78480016
*                             SECTION ONE                               78570016
         SPACE                                                          78660016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     78750016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    78840016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  78930016
         SPACE                                                          79020016
         DS    0F                                                       79110016
CCTUNAME DS    5F                  USER'S NAME                          79200016
CCTUACCT DS    5F                  USER'S ACCOUNT NUMBER                79290016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     79380016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       79470016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    79560016
*                                       AT LAST BEGIN JOB               79650016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   79740016
*                                       LAST BEGIN JOB                  79830016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 79920016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    80010016
*                                       JOB                             80100016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    80190016
*                                       JOB                             80280016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     80370016
*                                       CESSOR                          80460016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         80550016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         80640016
CCTJCTR  DS    H                   JOB COUNTER                          80730016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                80820016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   80910016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  81000016
CCTSSTAT DS    C                   SESSION STATUS                       81090016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              81180016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              81270016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    81360016
         EJECT                                                          81450016
         SPACE 2                                                        81540016
*                             SECTION TWO                               81630016
         SPACE                                                          81720016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   81810016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  81900016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 81990016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              82080016
         SPACE                                                          82170016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     82260016
*                                       FRAME                           82350016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  82440016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     82530016
*                                       MULTIPLE DISPLAY FRAME (ENT)    82620016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   82710016
CCTDISM  DS    C                   DISPLAY MASK                         82800016
CCTCSM   DS    C                   COMMAND SELECT MASK                  82890016
CCTPSTAT DS    CL2                 GJP STATUS                           82980016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              83070016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  83160016
CCTPWKAE EQU   *                                                        83200016
         SPACE 2                                                        83250016
*                             SECTION THREE                             83340016
         SPACE                                                          83430016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    83520016
*                   INTO SECTION ONE OR TWO                             83610016
         SPACE                                                          83700016
CCTDGMP  DS    F                  POINTER TO DGM                        83790016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                83880016
CCTCSTP  DS    F                  POINTER TO CST                        83970016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                84060016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            84150016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 84240016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              84330016
CCTDIARP DS    F                  POINTER TO DIA                        84420016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      84510016
CCTACTP  DS    F                  POINTER TO ACT                        84600016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     84690016
CCTIERRP DS    F                  POINTER TO IERR                       84780016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              84870016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               84960016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                85050016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 85140016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 85230016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   85320016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                85410016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                85500016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               85590016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              85680016
CCTPECB  DS    F                  PROCESSOR'S ECB                       85770016
CCTWECB  DS    F                  WTOR ECB                              85860016
CCTDIAWA DS    CL136               DIARY WORK AREA                      85950016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    86040016
CCTCSAVE DS    CL72                CTL SAVE AREA                        86130016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                86220016
CCTASAVE DS    CL72                DAT SAVE AREA                        86310016
*                                                                       86313016
* THESE ARE THE CHANGES MADE TO THE CONSOLE CONTROL TABLE OF GJP.       86316016
* CONTENTS NOT NEEDED BY SGJP ARE REPLACED AS INDICATED BELOW           86319016
*                                                                       86322016
IKDCCT   EQU   CCT                 THREE CHARACTER PREFIX IS REPLACED   86325016
CCTCWKA  EQU   CCTCSTP             CONTROL ROUTINE WORKAREA             86328016
CCTBUFFP EQU   CCTGWRKP            POINTER TO BTAM BUFFER               86331016
CCTRECLN EQU   CCTDGMP             LENGTH OF DATA TO BE TRANSMITTED     86334016
CCTIORP  EQU   CCTDORP             POINTER TO I/O ROUTINE               86337016
CCTMSGP  EQU   CCTDMRP             POINTER TO MESSAGE ROUTINE           86340016
CCTSTAT  EQU   CCTACTP             SGJP STATUS BYTES                    86343016
CCTIELST EQU   CCTLPWRK            AREA USED FOR GTNIT/GTEND PARAM LIST 86346016
CCTRDLST EQU   CCTLPWRK+24         AREA USED FOR GTRED PARAMETER LIST   86349016
CCTWRLST EQU   CCTLPWRK+40         AREA USED FOR GTWRT PARAMETER LIST   86352016
CCTTSLST EQU   CCTLPWRK+60         AREA USED FOR GTCLT PARAMETER LIST   86355016
CCTDSREF EQU   CCTLPWRK+72         DATA SET REFERENCE NUMBER            86358016
CCTSTCOD EQU   CCTLPWRK+76         WORD TO CONTAIN RESULTS OF INIT,TEST 86361016
CCTDATYP EQU   CCTLPWRK+80         WORD TO CONTAIN DATA TYPE CODE       86364016
CCTCTLOP EQU   CCTLPWRK+84         WORD CONTAINING CODE DENOTING DEST-  86367016
*                                  INATION OF DATA                      86370016
CCTTSTCD EQU   CCTLPWRK+88         WORD TO CONTAIN CODE REPRESENTING    86373016
*                                  THE I/O OPERATION TO BE TESTED BY    86376016
*                                  GTCLT                                86379016
CCTPWKAL EQU   CCTPWKAE-CCTPWKA                                         86382016
         EJECT                                                          86390016
CVT      DSECT                                                          86470016
         CVT   SYS=VMS                                                  86550016
         EJECT                                                          86630016
*                                                                       86710016
*  GFX LIST POINTED TO BY CVT                                           86790016
*                                                                       86870016
GRAPLIST DSECT                                                          86950016
GOCT     DS    1F                      POINTER TO THE OCT               87030016
GGAPR    DS    1F                      POINTER TO GAPR                  87110016
GCANC    DS    1F                      POINTER TO CANCEL RTN            87190016
GFXOCTHD DSECT                                                          87270016
GFXHDSTR EQU   *                       START OF HEADER RECORD           87350016
OCTSYS   DS    CL1                     BASE SYSTEM                      87430016
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                87510016
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          87590016
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       87670016
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       87750016
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              87830016
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              87910016
         DS    0H                                                       87990016
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             88070016
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       88150016
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       88230016
         DS    0F                                                       88310016
OCTFGREG DS    CL4                      REGION SIZE GJP                 88390016
OCTFUREG DS    CL4                      REGION SIZE USER FGD            88470016
OCTBUREG DS    CL4                      REGION SIZE USER BGD            88550016
OCTGTCB  DS    CL4                     TCB ADDRESS OF GFX               88630016
OCTHRES  DS    CL4                     RESERVED                         88710016
OCTNAME  DS    CL20                     PROGRAMMER NAME                 88790016
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  88870016
GFXHDEND EQU   *                       END OF HEADER RECORD             88950016
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        89030016
         EJECT                                                          89110016
GFXOCTEN DSECT                                                          89190016
         DS    0F                                                       89270016
GFXENSTR EQU   *                       START OF ENTRY RECORD            89350016
OCTECB   DS    CL4                      ECB                             89430016
OCTUCB   DS    CL4                      UCB ADDRESS                     89510016
OCTUNIT  DS    CL4                      UNIT ADDRESS                    89590016
OCTCOUNT DS    CL4                      JOB COUNT                       89670016
OCTNOTE  DS    CL4                      NOTE                            89750016
OCTABEND DS    A                       ABEND CODE                       89830016
OCTRESD  DS    CL8                      RESERVED                        89910016
**********************************************************************  89990016
****                          ATTRIBUTE 1                          **** 90070016
**********************************************************************  90150016
OCTATTR1 DS    CL2                      ATTRIBUTES                      90230016
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         90310016
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   90390016
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         90470016
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       90550016
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   90630016
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  90710016
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  90790016
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           90870016
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          90950016
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   91030016
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           91110016
OCTBERR1 EQU   X'10'          0-                  1-GJP INTERNAL ERROR  91190016
OCTBERR2 EQU   X'08'          0-                  1-GJP INTERNAL ERR(2) 91270016
**********************************************************************  91350016
****                          ATTRIBUTE 2                          **** 91430016
**********************************************************************  91510016
OCTATTR2 DS    CL2                      ATTRIBUTES                      91590016
OCTBIRRE EQU   X'80'          0-                  1-GJP INTERNAL ERROR  91670016
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      91750016
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              91830016
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           91910016
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         91990016
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           92070016
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       92150016
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            92230016
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  92310016
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  92390016
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        92470016
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         92550016
**********************************************************************  92630016
****                          ATTRIBUTE 3                          **** 92710016
**********************************************************************  92790016
OCTATTR3 DS    CL2                      ATTRIBUTES                      92870016
OCTBIERR EQU   X'80'          0-                  1-GJP INTERNAL ERROR  92950016
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB      93030016
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              93110016
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           93190016
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         93270016
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           93350016
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       93430016
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            93510016
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  93590016
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  93670016
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        93750016
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         93830016
**********************************************************************  93910016
****                          ATTRIBUTE 4                          **** 93990016
**********************************************************************  94070016
OCTATTR4 DS    CL2                      ATTRIBUTES                      94150016
GFXENEND EQU   *                       END OF ENTRY RECORD              94230016
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             94310016
         EJECT                                                          94410016
*                                                                       94510016
* DSECT DEFINING DCB                                                    94610016
*                                                                       94710016
         DCBD  DSORG=PO,DEVD=DA                                         94810016
         END                                                            95040016
