         START 0                                                        00100016
***               * SPECIFY  JOB  STEP  PROCESSOR *                     00200016
*                                                                       00300016
*  MODULE NAME=    IKAPSPE                                              00400016
*                                                                       00500016
*  CHART ID.  =     FC,FD                                               00600016
*                                                                       00700016
*  FUNCTION   =    PROCESS SPECIFY JOB STEP PARAMETER FRAME INPUT DATA  00800016
*                                                                       00900016
*  ATTRIBUTES =    TRANSIENT,REUSABLE                                   01000016
*                                                                       01100016
*  ENTRY POINT=    ENTERED VIA LINK FROM IKAPCTL                        01200016
*                                                                       01300016
*  OPERATION  =                                                         01400016
*                                                                       01500016
*  EXITS      =    BRANCH TO MSG - IF ERROR IN USER"S INPUT             01600016
*                  BRANCH TO IKADIA                                     01700016
*                  BRANCH TO IKAJCL                                     01800016
*                  RETURN TO IKAPCTL                                    01900016
*                                                                       02000016
*  INPUT      =    USER"S INPUT DATA IN CCT PROCESSOR WORKAREA          02100016
*                  (RECORD IS BUILDT BY IKAEXT)                         02200016
*                                                                       02300016
*  OUTPUT     =    ERROR CHECKED AND UPDATED RECORD IN CCT PROCESSOR    02400016
*                  WORKAREA - INPUT TO JCL GENERATOR                    02500016
*                                                                       02600016
*  EXTERNAL                                                             02700016
*   REFERENCES=                                                         02800016
*                                                                       02900016
*  ERROR                                                                03000016
*   CONDITIONS=                                                         03100016
*                                                                       03200016
*  TABLES AND                                                           03300016
*   WORKAREAS =    PST                                                  03400016
*                  IKACCT                                               03500016
*                                                                       03600016
* RESTRICTIONS=                                                         03700016
* * * * * * * * * * * * * * * *                                         03800016
         EJECT                                                          03900016
***                      REGISTER  EQUATES                              04000016
*                                                                       04100016
RPAR0    EQU   0                                                        04200016
RPAR1    EQU   1                                                        04300016
RTRT     EQU   2                                                        04400016
RBASE    EQU   3                                                        04500016
RCCT     EQU   4                                                        04600016
RMES     EQU   5                                                        04700016
RJCL     EQU   6                                                        04800016
RCOUNT   EQU   7                                                        04900016
RDIGCT   EQU   8                                                        05000016
RWORK    EQU   9                                                        05100016
RMANIP   EQU   10                                                       05200016
RFLD     EQU   11                                                       05300016
RLENG    EQU   12                                                       05400016
RSAVE    EQU   13                                                       05500016
RRET     EQU   14                                                       05600016
RBR      EQU   15                                                       05700016
*                                                                       05800016
         EJECT                                                          06000016
WKAREA   DSECT                                                          06100016
TRTABLE  DS    XL250                                                    06200016
SECLINE  DS    73C                                                      06300016
BLKURSW  DS    XL1                                                      06400016
DOUBLSW  DS    XL1                                                      06500016
URSW     DS    XL1                                                      06600016
ADMESSW  DS    XL1                                                      06700016
PERISW   DS    XL1                                                      06800016
         DS    0F                                                       06900016
MSGPARAM DS    20F                                                      07000016
PRCOD    DS    1F                                                  9904 07030018
APOWORK  DS    XL41                                                     07060016
PROCNAME DS    2F                                                       07130016
PROCNAMP DS    1F                                                       07160016
*                                                                       07200016
         EJECT                                                          07300016
         SPACE                                                          07340016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         07380016
         SPACE                                                          07420016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    07460016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     07500016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       07540016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             07580016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  07620016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  07660016
*                   SET.                                                07700016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      07740016
*                   SECOND.                                             07780016
         SPACE 2                                                        07820016
CCT      DSECT                                                          07860016
         SPACE 2                                                        07900016
*                             SECTION ONE                               07940016
         SPACE                                                          07980016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     08020016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    08060016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  08100016
         SPACE                                                          08140016
         DS    0F                                                       08180016
CCTUNAME DS    5F                  USER'S NAME                          08220016
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         08260016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     08300016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       08340016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    08380016
*                                       AT LAST BEGIN JOB               08420016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   08460016
*                                       LAST BEGIN JOB                  08500016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 08540016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    08580016
*                                       JOB                             08620016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    08660016
*                                       JOB                             08700016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     08740016
*                                       CESSOR                          08780016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         08820016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         08860016
CCTJCTR  DS    H                   JOB COUNTER                          08900016
CCTUBPRI DS    H                        USERS BACKGROUND PRIORITY  PJKA 08920017
CCTHIST  DS    109F                HISTORY OF OPERATIONS                08940016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   08980016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  09020016
CCTSSTAT DS    C                   SESSION STATUS                       09060016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              09100016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              09140016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    09180016
         EJECT                                                          09220016
         SPACE 2                                                        09260016
*                             SECTION TWO                               09300016
         SPACE                                                          09340016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   09380016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  09420016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 09460016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              09500016
         SPACE                                                          09540016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     09580016
*                                       FRAME                           09620016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  09660016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     09700016
*                                       MULTIPLE DISPLAY FRAME (ENT)    09740016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   09780016
CCTDISM  DS    C                   DISPLAY MASK                         09820016
CCTCSM   DS    C                   COMMAND SELECT MASK                  09860016
CCTPSTAT DS    CL2                 GJP STATUS                           09900016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              09940016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  09980016
         SPACE 2                                                        10020016
*                             SECTION THREE                             10060016
         SPACE                                                          10100016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    10140016
*                   INTO SECTION ONE OR TWO                             10180016
         SPACE                                                          10220016
CCTDGMP  DS    F                  POINTER TO DGM                        10260016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                10300016
CCTCSTP  DS    F                  POINTER TO CST                        10340016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                10380016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            10420016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 10460016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              10500016
CCTDIARP DS    F                  POINTER TO DIA                        10540016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      10580016
CCTACTP  DS    F                  POINTER TO ACT                        10620016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     10660016
CCTIERRP DS    F                  POINTER TO IERR                       10700016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              10740016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               10780016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                10820016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 10860016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 10900016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   10940016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                10980016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                11020016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               11060016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              11100016
CCTPECB  DS    F                  PROCESSOR'S ECB                       11140016
CCTWECB  DS    F                  WTOR ECB                              11180016
CCTDIAWA DS    CL136               DIARY WORK AREA                      11220016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    11260016
CCTCSAVE DS    CL72                CTL SAVE AREA                        11300016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                11340016
CCTASAVE DS    CL72                DAT SAVE AREA                        11380016
*                                                                       11420016
IKACCT   EQU   CCT                                                      11460016
         EJECT                                                          11900016
* *  RELATIVE FIELD POSITIONS IN WORKAREA AND MAXIMUM LENGTH OF FIELDS  12000016
*                                                                       12100016
ELIB     EQU   22                                                       12200016
ENAM     EQU   103                                                      12300016
EPAR     EQU   118                                                      12400016
EREG     EQU   167                                                      12500016
EOTH     EQU   174                                                      12600016
EURE     EQU   227                                                      12700016
ESIZ     EQU   307                                                 PJKA 12703017
EPRI     EQU   311                                                 PJKA 12706017
EPGM     EQU   313                                                      12710016
EUIN     EQU   321                                                      12730016
EPRC     EQU   339                                                      12780016
EBGR     EQU   347                                                      12830016
*                                                                       13100016
WKANAME  EQU   CCTPWKA+ENAM             PGM OR PROC NAME (LENGTH  8)    13200016
WKAPRCN  EQU   CCTPWKA+EPRC             PROCEDURE NAME   (LENGTH  8)    13230016
WKAPGM   EQU   CCTPWKA+EPGM             PROGRAM NAME     (LENGTH  8)    13240016
WKAURIN  EQU   CCTPWKA+EUIN             USER'S UNIT REF. (LENGTH 17)    13260016
WKAUREF  EQU   CCTPWKA+EURE             UNIT REFERENCE   (LENGTH 17)    13300016
WKALIBR  EQU   CCTPWKA+ELIB             JOBLIB NAME      (LENGTH 44)    13400016
WKAPARM  EQU   CCTPWKA+EPAR             PARAMETERS       (LENGTH 40)    13500016
WKAREGI  EQU   CCTPWKA+EREG             REGION           (LENGTH 4)PJKA 13550017
WKAIREG  EQU   CCTPWKA+ESIZ             USERS SIZE INPUT (LENGTH 3)PJKA 13600017
WKAPRI   EQU   CCTPWKA+EPRI             USERS BCKGR.PRITY(LENGTH 2)PJKA 13650017
WKAOTHR  EQU   CCTPWKA+EOTH             OTHER            (LENGTH 50)    13700016
WKABACK  EQU   CCTPWKA+EBGR             BACKGROUND       (LENGTH  2)    13800016
* * * * * * * * * * * * * * * * * * *                                   14100016
         EJECT                                                          14200016
IKAPSPE0 CSECT                                                          14300016
*0832,136000,164700,262640,418260-418320,418800,419000-420200,     PJKA 14330017
*     425000,519000-521000,588200,616200,618012-618030,630600      PJKA 14360017
*0832,278300,419520                                                0169 14380017
*3281                                                              9904 14386018
*3281,420600-421000,421800-422200                                  R001 14392018
*2721,440500,442000                                                     14396019
*                                                                       14400016
         EXTRN IKATOP,IKAMSG1,IKAMSG2,IKAMSG3,IKAMSG3A,IKAMSG4,IKAMSG5  14500016
         EXTRN IKAMSG6,IKAMSG6A,IKAMSG7,IKAMSG8,IKAMSG9,IKAMSG10        14600016
         EXTRN IKAMSG11,IKAMSG12,IKAMSG13,IKAMSG14,IKAMSG15,IKAMSG16    14650016
         EXTRN IKAMSG17,IKAMSG18,IKAMSG19,IKAMSG20,IKAMSG21,IKAMSG22    14670017
*                                                                       14700016
START    EQU   *                                                        14800016
         SAVE  (14,12)                                                  14900016
         BALR  RBASE,0                  SET UP BASE                     15000016
         USING *,RBASE                                                  15100016
         LR    RCCT,RPAR1               LOAD REG WITH ADDR.OF CCT       15200016
         USING IKACCT,RCCT                                              15300016
         L     RJCL,CCTJCLGP                                  JCL       15400016
         LA    RPAR1,CCTPSAVE                                           15500016
         ST    RPAR1,8(0,RSAVE)                                         15600016
         ST    RSAVE,4(RPAR1)                                           15700016
         LR    RSAVE,RPAR1                                              15800016
         GETMAIN R,LV=480                                               15900016
         LR    RMANIP,RPAR1                                             16000016
         USING WKAREA,RMANIP                                            16100016
         MVI   SECLINE,X'48'                                            16200016
         NI    DOUBLSW,X'7F'            SET DOUBLSW OFF                 16300016
         NI    URSW,X'7F'                  URSW OFF                     16400016
         NI    ADMESSW,X'1F'               ADMESSW OFF             PJKA 16470017
         NI    BLKURSW,X'7F'               BLKURSW OFF                  16550016
*                                                                       16600016
* * * *                              BUILD TRANSLATE & TEST TABLE       16700016
WAITECB  MVI   TRTABLE,ZERO             SET TO ZERO                     16800016
         MVC   TRTABLE+1(249),TRTABLE                                   16900016
         MVI   TRTABLE+64,CANC          BLANK                           17000016
         MVI   TRTABLE+74,FIVE         CENT                             17100016
         MVI   TRTABLE+75,ONE           PERIOD                          17200016
         MVI   TRTABLE+76,FIVE         <                                17300016
         MVI   TRTABLE+77,FIVE         LEFT PAREN                       17400016
         MVI   TRTABLE+78,FIVE          PLUS                            17500016
         MVI   TRTABLE+79,FIVE                                         17600016
         MVI   TRTABLE+80,FIVE          AMPERSAND                       17700016
         MVI   TRTABLE+90,FIVE         !                                17800016
         MVI   TRTABLE+91,SEVEN         DOLLAR                          17900016
         MVI   TRTABLE+92,FIVE          ASTERISK                        18000016
         MVI   TRTABLE+93,FIVE         RIGHT PAREN                      18100016
         MVI   TRTABLE+94,FIVE         ;                                18200016
         MVI   TRTABLE+95,FIVE                                         18300016
         MVI   TRTABLE+96,FIVE          DASH                            18400016
         MVI   TRTABLE+97,FIVE          SLASH                           18500016
         MVI   TRTABLE+107,FIVE         COMMA                           18600016
         MVI   TRTABLE+108,FIVE        %                                18700016
         MVI   TRTABLE+109,FIVE        _                                18800016
         MVI   TRTABLE+110,FIVE        >                                18900016
         MVI   TRTABLE+111,FIVE        ?                                19000016
         MVI   TRTABLE+122,FIVE        :                                19100016
         MVI   TRTABLE+123,SEVEN        POUND                           19200016
         MVI   TRTABLE+124,SEVEN        COMMERCIAL AD                   19300016
         MVI   TRTABLE+125,FOUR         APOSTROPHE                      19400016
         MVI   TRTABLE+126,FIVE         EQUAL                           19500016
         MVI   TRTABLE+127,FIVE        "                                19600016
         MVI   TRTABLE+193,SIX             A-I                          19700016
         MVC   TRTABLE+194(8),TRTABLE+193                               19800016
         MVC   TRTABLE+209(8),TRTABLE+193  J-Q                          19900016
         MVI   TRTABLE+217,SIX             R                            20000016
         MVC   TRTABLE+226(8),TRTABLE+193  S-Z                          20100016
         MVI   TRTABLE+240,SEVEN                                        20200016
         MVC   TRTABLE+241(9),TRTABLE+240  0-9                          20300016
*                                                                       20400016
         WAIT  ECB=CCTPECB              WAIT ON PROCESSOR ECB (POSTED   20500016
*                                                              BY DAT)  20600016
         TM    CCTPECB+3,CANC          Q. IS POST CODE ''CANCEL''       20700016
         BO    CANCELD                  A. YES                          20800016
         TM    CCTPECB+3,X'1C'        Q. IS POST CODE QUIT         PJKA 20830017
         BO    QUITECB                A. YES                       PJKA 20860017
         B     NOCANC                   A. NO                           20900016
*                                                                       21000016
CANCELD  L     RWORK,CANCRETC          LOAD RETURN CODE                 21100016
         B     FINI                                                     21200016
*                                                                       21300016
QUITECB  L     RWORK,QUITCODE           LOAD QUIT RETURN CODE      PJKA 21330017
         B     FINI                                                PJKA 21360017
*                                                                       21400016
NOCANC   CLC   WKAPGM(8),BLANKS       Q. IS PROGRAM NAME GIVEN          21440016
         BE    ISITPROC               A. NO                             21480016
         MVC   WKANAME(8),WKAPGM        MOVE PROGRAM NAME               21520016
         B     TESTNAM                                                  21560016
*                                                                       21600016
ISITPROC CLC   WKAPRCN(8),BLANKS      Q. IS PROCEDURE NAME GIVEN        21640016
         BE    NONAME                 A. NO - ERROR                     21680016
         MVC   WKANAME(8),WKAPRCN       MOVE PROCEDURE NAME             21720016
TESTNAM  L     RLENG,CZERO              SET UP TO TEST FIRST POSITION   21760016
         LA    RFLD,WKANAME             LOAD ADDRESS OF FIELD TESTED    21800016
         SR    RTRT,RTRT                                                21900016
         EX    RLENG,TRANSL             EXECUTE TRANLATE AND TEST       22000016
         CL    RTRT,CSIX                Q. IS FIRST POSITION ALPHA      22100016
         BNE   NOALNAM                  A. NO                           22200016
*                                                                       22300016
         CLC   WKAURIN(17),BLANKS      Q. WAS U.R. ENTERED BY USER      22360016
         BE    GENUR                    A. NO                           22420016
         TM    CCTDISM,X'40'            Q. UNIT REF. DATA PERMITTED     22480016
         BO    RIDUR                    A. NO                           22540016
         CLC   WKAPRCN(8),BLANKS   *  Q. IS IT PROCEDURE  *             22550016
         BNE   URNPROC             *  A. YES              *             22560016
         MVC   WKAUREF(17),WKAURIN      MOVE USER'S U.R. TO EXTRACT REC 22570016
         L     RLENG,CZERO              LOAD LENGTH OF FIELD TESTED     22600016
         LA    RFLD,WKAUREF             LOAD ADDRESS OF FIELD TESTED    22700016
         SR    RTRT,RTRT               SET TRT REG TO ZERO              22800016
         EX    RLENG,TRANSL             EXECUTE TRANSLATE AND TEST      22900016
         CL    RTRT,CSIX                Q. IS FIRST POSITION ALPHA      23000016
         BNE   NOALUR                   A. NO                           23100016
         CLC   WKABACK(2),BLANKS        Q. BACKGROUND SPECIFIED         23130016
         BNE   BCKGRNUR                 A. YES - ERROR                  23160016
ALPHOUT  MVC   TRTABLE+193(57),TRTABLE+192  ZERO OUT ALPHAS IN TR.TABLE 23200016
         L     RLENG,CSEVEN             LOAD MAX.  LENGTH OF NAME       23300016
         LA    RFLD,WKANAME+7           LOAD LOW POS. OF NAME           23400016
SCAN1    CLI   0(RFLD),X'40'            SCAN NAME TO GET ACTUAL LENGTH  23500016
         BNE   ENDSCAN1                 FIRST NON-BLANK,END OF SCAN     23600016
         S     RFLD,CONE                TEST  NEXT POSITION             23700016
         BCT   RLENG,SCAN1              CONTINUE SCAN                   23800016
ENDSCAN1 LA    RFLD,WKANAME                                             23900016
         SR    RTRT,RTRT                SET TRT REG TO ZERO             24000016
         EX    RLENG,TRANSL             TEST NAME FOR SYNTAX ERROR      24100016
         CL    RTRT,CZERO               Q. ERROR                        24200016
         BNE   NMSYNTER                 A. YES                          24300016
         CLC   WKAPGM(8),BLANKS       Q. IS IT PROGRAM                  24330016
         BE    PROCUR                   A. NO                           24360016
         TM    URSW,X'80'               Q. IS UR SWITCH ON              24400016
         BO    PGMSPEC                  A. YES - NO SCAN + SYNTAX TEST  24500016
         OI    BLKURSW,X'80'            SET BLKURSW ON                  24570016
         L     RLENG,CSEVTEN            LOAD LENGTH OF U.REF.           24640016
         LA    RFLD,WKAUREF+16          LOAD LOW POS. OF U.REF.         24710016
SCAN2    CLI   0(RFLD),X'40'            SCAN UR.TO GET ACTUAL LENGTH    24800016
         BNE   ENDSCAN2                 FIRST NON-BLANK,END OF SCAN     24900016
         S     RFLD,CONE                GO TO NEXT POSITION             25000016
         BCT   RLENG,SCAN2                                              25100016
*                                                                       25200016
ENDSCAN2 CL    RLENG,EIGHT              Q. IS U.REF. OVER 8 CHARACTERS  25240016
         BH    OVER8                    A. YES                          25280016
         LA    RFLD,WKAUREF                                             25320016
         S     RLENG,CONE               DECREMENT FOR TRANSLATE         25360016
         SR    RTRT,RTRT               SET TRT REG TO ZERO              25400016
         EX    RLENG,TRANSL             TEST UNIT REF. FOR SYNTAX ERROR 25500016
         CL    RTRT,CZERO               Q. ERROR                        25600016
         BNE   URSYNTER                 A. YES                          25700016
         B     PGMSPEC                  A. NO                           25800016
*                                                                       25900016
GENUR    OI    URSW,X'80'               SET UR SWITCH ON                26000016
         OI    BLKURSW,X'80'            SET BLKURSW ON                  26050016
         B     ALPHOUT                                                  26100016
*                                                                       26200016
PROCUR   TM    BLKURSW,X'80'            Q. IS BLKURSW ON                26204016
         BZ    CHECKUR                  A. NO                           26208016
GOPROC   MVC   PROCNAME(8),WKANAME      MOVE PROCEDURE NAME TO WORKAREA 26220016
         LA    RPAR0,PROCNAME           POINTER TO PROCNAME             26224016
         CLC   WKABACK(2),BLANKS      Q. IS BACKGROUND SPECIFIED        26225016
         BNE   NODDRET                A. YES - INDICATE NO RETURN OF    26226016
*                                       PROCSTEPNAME.DDNAME REQUIRED    26227016
         LA    RPAR1,WKAUREF            POINTER TO AREA STEPNAME-DDNAME 26228016
         ST    RPAR1,PROCNAMP           IS PLACED BY IKAPROC MODULE     26232016
SETR1    LA    RPAR1,IKACCT             POINTER TO CCT                  26236016
*                                                                       26240016
*                                                                       26244016
         LINK  EP=IKAPROC0              LINK TO IKAPROC                 26248016
         ST    RBR,PRCOD           SAVE RETURN CODE                9904 26250018
*                                                                       26252016
         LTR   RBR,RBR                  TEST RETURN CODE                26256016
         BZ    PROCOK                   OK                              26260016
         CL    RBR,PROCODE         Q. DOES CODE INDICATE PROCEDURE 9904 26260218
*                                  REQUIRING ',UNIT=XXX' ON EXEC G 9904 26260418
         BE    PROCOK              A. YES                          9904 26260618
         CL    RBR,QUITCODE           Q. IS RETURN CODE QUIT       PJKA 26261017
         BE    SETQUIT                A. YES                       PJKA 26262017
         CL    RBR,CANCRETC           Q. IS R.C. 'NO STEPNAME'     PJKA 26263017
         BE    NOSTEP                 A. YES                       PJKA 26264017
         CL    RBR,CFOUR                                           PJKA 26265017
         BE    NOPROC                   RETURN CODE IS 4                26268016
         B     PROCIOER                 RETURN CODE IS 8                26272016
*                                                                       26276016
NODDRET  MVC   PROCNAMP(4),BLANKS       BLANK OUT POINTER TO RETURN FLD 26276816
         OI    PROCNAMP,X'80'           SET HIGH ORDER BIT ON           26277616
         B     SETR1                    CONTINUE                        26278416
*                                                                       26279216
PROCOK   NI    BLKURSW,X'7F'            TURN BLKURSW OFF                26280016
PGMSPEC  CLC   WKAPGM(8),BLANKS       Q. IS PGM SPECIFIED               26360016
         BE    BCKGR                  A. NO                             26440016
         CLC   WKAPRCN(8),BLANKS      Q. IS PROC SPECIFIED              26520016
         BNE   PGMNPROC                 A. YES                          26600016
BCKGR    CLC   WKABACK(2),BLANKS        Q. IS BACKGROUND SPECIFIED      26700016
         BNE   URSWTST                  A. YES                          26800016
         TM    CCTPSTAT,X'10'          Q. IS BACKGROUND JOB BIT ON      26900016
         BO    NOSHBCK                 A. YES                           27000016
         TM    URSW,X'80'               Q. IS UR SWITCH ON              27100016
         BZ    NOSHBCK                  A. NO                           27200016
         CLC   WKAPGM(8),BLANKS       Q. IS PROGRAM SPECIFIED           27230016
         BE    OFFURSW                  A. NO                           27260016
         L     RWORK,CCTGEND            LOAD POINTER TO SYSGEND UR NAME 27300016
         MVC   WKAUREF(8),0(RWORK)      MOVE IN SYSGEND UNIT REFERENCE  27400016
         TM    CCTSSTAT,32              Q. REMOTE GRAPHIC DEVICE   0169 27420017
         BZ    OFFURSW                  NO                         0169 27440017
         MVC   WKAUREF(8),30(RWORK)     USE SUBSYSTEM REFERENCE    0169 27460017
OFFURSW  NI    URSW,X'7F'               SET UR SWITCH OFF               27500016
         B     NOSHBCK                                                  27600016
*                                                                       27700016
CHECKUR  OI    BLKURSW,X'80'            SET BLKURSW ON                  27709016
         L     RLENG,CSXTEN             LOAD LENGTH OF UNIT REF.        27718016
         LA    RFLD,WKAUREF+16          LOAD ADDRESS OF IT              27727016
SCANUR   CLI   0(RFLD),X'40'            SCAN FIELD TO GET ACTUAL ELNGTH 27736016
         BNE   URSCANEN                 FIRST NON-BLANK-END OF SCAN     27745016
         S     RFLD,CONE                TEST NEXT POSITION              27754016
         BCT   RLENG,SCANUR             CONTINUE SCAN                   27763016
URSCANEN LA    RFLD,WKAUREF                                             27772016
         B     RESTORE                                                  27781016
*                                                                       27790016
URSWTST  TM    CCTDISM,X'80'          Q. BACKGROUND PERMITTED           27810016
         BZ    URSWTST1                 YES                        0169 27818017
         TM    CCTPSTAT,X'10'           Q. BACKGROUND JOB          0169 27826017
         BZ    RIDBACK                  NO, ISSUE ERROR MSG        0169 27834017
URSWTST1 EQU   *                                                   0169 27842017
         TM    URSW,X'80'             Q. IS UR SWITCH ON                27850016
         BZ    BCKGRNUR                 A. NO                           27900016
NOSHBCK  EQU   *                                                        27970016
         NI    BLKURSW,X'7F'            SET BLKURSW OFF                 28050016
         LA    RWORK,CCTPWKA                                            28100016
         CLC   WKALIBR(44),BLANKS       Q. IS USER LIBRARY SPECIFIED    28200016
         BE    MVSLASH                  A. NO                           28300016
         TM    CCTDISM,X'20'            Q. LIBRARY DATA PERMITTED       28330016
         BO    RIDLIB                   A. NO                           28360016
         L     RLENG,FOURTY4            LOAD FULL LENGTH OF LIBRARY NM. 28400016
         LA    RFLD,WKALIBR+43          LOAD LOW POS.OF LIBRARY NAME    28500016
SCAN3    CLI   0(RFLD),X'40'            SCAN LIBRARY TO GET REAL LENGTH 28600016
         BNE   ENDSCAN3                 FIRST NON-BLANK,END OF SCAN     28700016
         S     RFLD,CONE                TEST NEXT POSITION              28800016
         BCT   RLENG,SCAN3              CONTINUE                        28900016
ENDSCAN3 LA    RFLD,WKALIBR             LOAD ADDRESS OF LIBRARY         28960016
RESTORE  MVI   TRTABLE+193,SIX          RESTORE ALPHAS + NUMERICS       29020016
         MVC   TRTABLE+194(8),TRTABLE+193  A-I                          29100016
         MVC   TRTABLE+209(8),TRTABLE+193  J-Q                          29200016
         MVI   TRTABLE+217,SIX             R                            29300016
         MVC   TRTABLE+226(8),TRTABLE+193  S-Z                          29400016
         MVI   TRTABLE+240,SEVEN                                        29500016
         MVC   TRTABLE+241(9),TRTABLE+240  0-9                          29600016
         NI    PERISW,X'7F'            SET PERIOD SWITCH OFF            29900016
         LR    RCOUNT,RLENG            ADD RLENG TO COUNT               30000016
         A     RCOUNT,CTWO             INCREMENT TO CORRECT FOR BCT     30100016
SETDGCT1 LA    RDIGCT,1                 SET DIGITCOUNT TO 1             30200016
NEXTPOS  SR    RTRT,RTRT                                                30300016
         EX    RLENG,TRANSL             EXECUTE TRANSLATE AND TEST      30400016
         S     RLENG,CONE              DECREMENT LENGTH                 30500016
         BCT   RCOUNT,TESTLIB           Q. ENTIRE LIBRARY NAME TESTED   30600016
*                                       A. NO - GO TO TESTLIB           30700016
         TM    PERISW,X'80'             Q. IS PERIOD SWITCH ON          30800016
         BO    LASTPOS                  A. YES                          30900016
*                                                                       31000016
         TM    BLKURSW,X'80'            Q. IS BLKURSW ON                31040016
         BZ    LIBRA                    A. NO                           31080016
         B     NOSHBCK                                                  31160016
*                                                                       31200016
LIBRA    OI    CCTPSTAT,X'20'           GET JOBLIB CARD SPECIF.BIT ON   31240016
         LA    RWORK,CCTPWKA                                            31300016
         MVC   3(19,RWORK),CJOBLIB      MOVE JOBLIB CONSTANT TO WKAR.   31400016
         B     MVEXEC                                                   31500016
*                                                                       31600016
TESTLIB  A     RFLD,CONE               INCREASE TO TEST NEXT POSITION   31700016
         CL    RDIGCT,CONE              Q. IS DIGITCOUNT 1              31800016
         BNE   TESTPER                  A. NO                           31900016
         CL    RTRT,CSIX                Q. IS FIRST POSITION ALPHA      32000016
         BE    ADTODIG                  A. YES                          32100016
         TM    PERISW,X'80'            Q. IS PERIOD SWITCH ON           32200016
         BZ    NOALLIB                  A. NO                           32300016
         CL    RTRT,CONE               Q. IS THIS A PERIOD              32400016
         BE    PERER                   A. YES                           32500016
         B     NOALLIB                 A. NO                            32600016
*                                                                       32700016
TESTPER  CL    RTRT,CONE                Q. IS THIS A PERIOD             32800016
         BNE   TSTSPEC                 A. NO                            32900016
*                                                                       33600016
SECPER   TM    PERISW,X'80'            Q. IS PERIOD SWITCH ON           33700016
         BO    SETDGCT1                A. YES                           33800016
         OI    PERISW,X'80'            SET PERIOD SWITCH ON             33900016
         B     SETDGCT1                                                 34000016
*                                                                       34100016
TSTSPEC  CL    RTRT,CFIVE               Q. IS THIS A SPECIAL CHARACTER  35200016
         BE    SPECHAR                  A. YES                          35300016
         CL    RTRT,EIGHT              Q. IS THIS A BLANK               35400016
         BE    BLKINLIB                A. YES                           35500016
         CL    RTRT,CFOUR               Q. IS THIS AN APOSTROPHE        35600016
         BE    SPECHAR                  A. YES                          35700016
         CL    RDIGCT,EIGHT             Q. IS DIGITCOUNT OVER 8         35800016
         BH    OVER8                    A. YES                          35900016
ADTODIG  A     RDIGCT,CONE              ADD ONE TO DIGITCOUNT           36000016
         NI    PERISW,X'7F'            SET PERIOD SWITCH OFF            36050016
         B     NEXTPOS                                                  36100016
*                                                                       36200016
MVEXEC   MVC   66(16,RWORK),CDISP       MOVE DISPOSITION CONSTANT       36300016
         MVC   82(1,RWORK),CARDEL      MOVE HEX 26 CONSTANT             36400016
MVSLASH  MVC   83(2,RWORK),CSLASH      MOVE SLASH-SLASH CONSTANT        36500016
         MVC   93(6,RWORK),CEXEC        MOVE EXEC CONSTANT              36600016
         CLC   PRCOD,PROCODE       Q. CODE FOR MULTISTEP PROC      9904 36610018
         BNE   NOPROCC             A. NO                           9904 36620018
         MVI   226(RWORK),37       PUT IN COMMA CODE               9904 36630018
         MVC   227(6,RWORK),CUNIT+4  PUT IN UNIT=                  9904 36640018
         MVC   233(24,RWORK),BLANKS     PUT IN BLANKS              9904 36650018
         MVC   232(3,RWORK),CCTUNIT  PUT IN UNIT ADDR              9904 36660018
NOPROCC  EQU   *                                                   9904 36670018
         CLC   WKAPGM(8),BLANKS       Q. IS IT PROGRAM                  36700016
         BE    PARATST                  A. NO                           36800016
         MVC   99(4,RWORK),CPROGR       MOVE PROGRAM CONSTANT           36900016
PARATST  CLC   WKAPARM(40),BLANKS       Q. IS PARAMETER FIELD BLANK     37000016
         BE    REGTEST                  A. YES                          37100016
         CLC   WKAPRCN(8),BLANKS   *  Q. IS IT PROCEDURE  *             37106016
         BNE   PARNPROC            *  A. YES - GO TO ERR.MSG  *         37112016
         MVC   112(6,RWORK),CPAR        MOVE PARAMETER CONSTANT         39112016
REGTEST  EQU   *                                                        41820016
         L     RPAR1,CCTGEND            POINTER TO SYSGEND DATA         41840016
         CLC   28(2,RPAR1),CONE+2     Q. IS IT MVT                      41860016
         BNE   PRITST                 A. NO                        PJKA 41880017
         CLC   WKAIREG(4),BLANKS      Q. HAS  SIZE  BEEN ENTERED   PJKA 41884017
         BE    DEFREG                 A. NO-GO TO MOVE IN DEFAULT  PJKA 41888017
         CLC   WKAPRCN(8),BLANKS      Q. IS IT PROCEDURE           PJKA 41892017
         BNE   PROCSIZE               A. YES - ERROR MSG           PJKA 41896017
         L     RLENG,CTWO               LOAD LENGTH OF SIZE        PJKA 41900017
         NI    BLKURSW,X'7F'            SET BLANK SW OFF           PJKA 41904017
         LA    RFLD,WKAIREG+2           LOAD LOW POS. OF SIZE      PJKA 41908017
         LA    RTRT,WKAREGI+1                                      PJKA 41912017
         MVC   WKAREGI(4),FZERO         INITIALIZE WITH ZEROES     0169 41914017
SCAN4    CLI   0(RFLD),X'40'          Q. TRAILING BLANK            PJKA 41916017
         BNE   MVNUM                  A. NO                        PJKA 41920017
         S     RFLD,CONE                POINT TO NEXT POSITION     PJKA 41924017
         LA    RTRT,1(RTRT)             INCREMENT POINTER          PJKA 41928017
         BCT   RLENG,SCAN4              CONTINUE TEST              PJKA 41932017
MVNUM    EQU   *                                                   PJKA 41936017
         CLI   WKAIREG+3,X'40'        Q. DID USER ENTER FOUR DIGITSPJKA 41940017
         BNE   ONLY3                  A. YES                       PJKA 41944017
         EX    RLENG,SHIFT                                         PJKA 41948017
         LA    RTRT,WKAREGI+3                                      PJKA 41956017
         LA    RLENG,1(RLENG)           INCREMENT TO REAL LENGTH   PJKA 41960017
NUMTST   TM    0(RTRT),X'F0'          Q. IS THIS NUMERIC           PJKA 41964017
         BC 12,NOTNUM                 A. NO                        PJKA 41968017
         BCTR  RTRT,RPAR0               DECREMENT POINTER          PJKA 41972017
         BCT   RLENG,NUMTST             DECREMENT TO TEST NEXT POS.PJKA 41976017
         B     MVREGC                   GO TO TEST PRIORITY        PJKA 41980017
*                                                                  PJKA 41984017
SHIFT    MVC   0(0,RTRT),WKAIREG                                   PJKA 41988017
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 41992017
*                                                                       41996017
DEFREG   EQU   *                                                   PJKA 42000017
         CLC   WKAPRCN(8),BLANKS      Q. IS IT PROCEDURE           PJKA 42004017
         BNE   PRITST                 A. YES - BYPASS REGION       PJKA 42008017
         CLC   WKABACK(2),BLANKS       Q. IS IT BACKGROUND              42012017
         BNE   BACKREGI                A. YES                           42016017
         CLC   CCTUFRGN(4),BLANKS     Q. IS FGD REGION IN CCT BLANK     42040016
         BE    PRITST                   YES                        R001 42060018
         CLC   CCTUFRGN(4),FZERO        Q. FGD REGION IN CCT ZERO  R001 42080018
         BE    PRITST                   YES                        R001 42100018
         MVC   167(4,RWORK),CCTUFRGN    MOVE FGD REGION FROM CCT        42120016
         B     MVREGC                                                   42140016
BACKREGI CLC   CCTUBRGN(4),BLANKS     Q. IS BGD REGION IN CCT BLANK     42160016
         BE    PRITST                   YES                        R001 42180018
         CLC   CCTUBRGN(4),FZERO        Q. BGD REGION IN CCT ZERO  R001 42200018
         BE    PRITST                   YES                        R001 42220018
         MVC   167(4,RWORK),CCTUBRGN    MOVE BGD REGION FROM CCT        42240016
MVREGC   MVC   159(8,RWORK),CREGI       MOVE REGION CONSTANT            42260016
         MVC   171(1,RWORK),CK          MOVE TRAILING K                 42280016
PRITST   EQU   *                                                   PJKA 42285017
         CLC   WKAPRI(2),BLANKS       Q. HAS PRIORITY BEEN ENTERED PJKA 42290017
         BE    MOVEPRI                A. NO                        PJKA 42295017
         CLC   WKABACK(2),BLANKS      Q. IS BACKGROUND SPECIFIED   PJKA 42300017
         BE    NOBACKGR               A. NO                        PJKA 42305017
         L     RLENG,CTWO                                          PJKA 42310017
         LA    RFLD,WKAPRI+1                                       PJKA 42315017
         CLI   0(RFLD),X'40'          Q. TRAILING BLANK            PJKA 42320017
         BNE   NUMTST2                A. NO                        PJKA 42325017
         OI    BLKURSW,X'80'            SET BLANK SW ON            PJKA 42330017
REDUCE   BCTR  RFLD,RPAR0               POINT TO NEXT              PJKA 42335017
NUMTST2  TM    0(RFLD),X'F0'          Q. IS IT NUMERIC             PJKA 42340017
         BC 12,BLNKTST2               A. NO                        PJKA 42345017
         BCT   RLENG,REDUCE             TEST NEXT                  PJKA 42350017
         B     COMPSHFT                 GO TO COMPARE              PJKA 42355017
*                                                                  PJKA 42360017
MOVEPRI  EQU   *                                                   PJKA 42365017
         MVC   CCTUBPRI(2),CCTBRPRI     MOVE IN ORIGINAL BGR.PRI.  PJKA 42370017
         B     OTHRTST                                             PJKA 42375017
*                                                                  PJKA 42380017
BLNKTST2 CLI   0(RFLD),X'40'          Q. IS IT BLANK               PJKA 42385017
         BE    COMPSHFT               A. YES                       PJKA 42390017
         B     NOTNUM2                A. NO - ERROR MSG.15         PJKA 42395017
*                                                                  PJKA 42400017
OFFSET   MVC   SECLINE+2(1),WKAPRI      MOVE IT OFFSET TO WORKAREA PJKA 42405017
         MVC   SECLINE+1(1),FZERO       MOVE IN PRECEEDING ZERO    PKKA 42410017
         B     COMPRI                   GO TO COMPARE              PJKA 42415017
*                                                                  PJKA 42420017
COMPSHFT TM    BLKURSW,X'80'          Q. IS BLANKSW ON             PJKA 42425017
         BO    OFFSET                 A. YES                       PJKA 42430017
         MVC   SECLINE+1(2),WKAPRI    A. NO - MOVE DATA TO WORKAREAPJKA 42435017
         CLI   0(RFLD),X'40'          Q. LEADING BLANK             PJKA 42440017
         BNE   COMPRI                                              PJKA 42445017
         MVC   SECLINE+1(1),FZERO       MOVE IN LEADING ZERO       PJKA 42450017
COMPRI   CLC   SECLINE+1(2),CCTBRPRI    COMPARE WITH DATA IN CCT   PJKA 42455017
         BNL   PRIBAD                 DATA ENTERED IS NOT LOWER    PJKA 42460017
         MVC   CCTUBPRI(2),SECLINE+1    DATA OK, MOVE TO CCT       PJKA 42465017
*                                                                  PJKA 42470017
OTHRTST  EQU   *                                                   PJKA 42490017
         OI    CCTDISM,X'A0'            DO NOT SHOW LIBRARY NAME & PJKA 42510017
*                                       BACKGROUND                 PJKA 42530017
         CLC   WKAOTHR(50),BLANKS     Q. IS OTHER DATA GIVEN       PJKA 42550017
         BE    MVUNIT                   A. NO                           42600016
         MVC   173(1,RWORK),CDISP       A. YES-MOVE IN HEX 25           42700016
MVUNIT   CLC   WKABACK(2),BLANKS       Q. DO WE WANT UNIT REFERENCE     42800016
         BNE   TSTSYSCL                A. NO                            42900016
         TM    CCTPSTAT,X'10'          Q. IS BACKGROUND JOB BIT ON      43000016
         BO    TSTSYSCL                A. YES                           43100016
         CLC   CCTUNIT(3),BLANKS        Q. IS UNIT ADDRESS BLANK        43300016
         BE    INTMES2                 A. YES                           43400016
         CLC   CCTUNIT(3),CZERO         Q. IS UNIT ADDRESS ZEROES       43500016
         BE    INTMES2                 A. YES                           43600016
         CLC   PRCOD,PROCODE           IS PROC CARD INDICATED      9904 43610018
         BE    TSTSYSCL                YES  TEST SYS               9904 43620018
         MVC   224(3,RWORK),CARDEL      MOVE CARD DELIMETER AND //      43650016
         MVC   244(12,RWORK),CUNIT      MOVE UNIT CONSTANT              43720016
         MVC   253(3,RWORK),CCTUNIT    MOVE UNIT ADDRESS                43800016
TSTSYSCL CLC   WKAPRCN(8),BLANKS      Q. IS IT PROCEDURE                43850016
         BNE   EXOFF                  A. YES - DON'T GENERATE SYSABEND  43900016
         CLC   CCTSOUT+1(1),BLANKS     Q. IS SYSOUTCLASS BLANK          43950016
         BE    INTMES3                 A. YES                           44000016
MVSYSAB  MVC   256(23,RWORK),SYSAB      MOVE SYSABEND CONSTANT     R019 44050019
         MVC   278(1,RWORK),CCTSOUT+1  MOVE PRINT SYSOUT CLASS          44100016
         TM    CCTSSTAT,X'20'        Q. IS SGJP IN CONTROL         R019 44110019
         BO    EXOFF                 A. YES, BRANCH                R019 44120019
         CLC   WKABACK(2),BLANKS     Q. IS IT A BACKGROUND JOB     R019 44130019
         BNE   EXOFF                 A. YES, BRANCH                R019 44140019
         MVC   279(23,RWORK),SYSBF      MOVE SYSBFDMP CONSTANT     R019 44150019
         MVC   301(1,RWORK),CCTSOUT+1   MOVE PRINT SYSOUT CLASS    R019 44160019
EXOFF    EQU   *                                                   R019 44200019
         MVC   302(2,RWORK),HEXEND      MOVE X26 AND X37 DELIM.    R019 44240019
         NI    CCTPSTAT,X'BF'           SET EXEC.CARD REQUIRED BIT OFF  44300016
         MVC   CCTDIAWA+5(8),CJOBSTP   FORM HISTORY AND DIARY DATA      44500016
         MVC   CCTDIAWA+15(8),WKANAME   NAME                            44600016
         CLC   WKAPGM(8),BLANKS                                         44700016
         BE    MVPROC                                                   44800016
         MVC   CCTDIAWA+25(4),RECPGM   PROGRAMM                         44900016
HIST1    CLC   WKABACK(2),BLANKS                                        45000016
         BNE   MOVEBACK                                                 45100016
         MVC   CCTDIAWA+31(17),WKAUREF  UNIT REFERENCE                  45200016
HIST2    MVC   CCTDIAWA+50(44),WKALIBR  LIBRARY NAME                    45300016
         MVC   CCTDIAWA+96(40),WKAPARM  PARAMETERS                      45400016
         B     HIST3                                                    45500016
*                                                                       45900016
MVPROC   MVC   CCTDIAWA+25(4),RECPROC  PROCEDURE                        46000016
         B     HIST1                                                    46100016
*                                                                       46200016
MOVEBACK MVC   CCTDIAWA+31(10),RECBACK  BACKGROUND                      46300016
         OI    CCTPSTAT,X'10'          SET BACKGROUND JOB BIT ON        46400016
         OI    CCTDISM,X'40'           DO NOT SHOW UNIT REFERENCE       46500016
         B     HIST2                                                    46600016
*                                                                       46700016
HIST3    LR    RPAR1,RCCT               LOAD POINTER TO CCT             46800016
         L     RBR,CCTDIARP             LOAD POINTER TO DIARY ROUTINE   46900016
         BALR  RRET,RBR                 BRANCH TO DIARY  ROUTINE        47000016
*                        AFTER RETURN FROM DIARY  ROUTINE               47100016
*                        SET UP BRANCH INSTRUCTIONS TO GO TO JCL        47200016
         CL    RBR,QUITCODE           Q. IS RETURN CODE QUIT       PJKA 47220017
         BE    SETQUIT                A. YES                       PJKA 47240017
*                                                                  PJKA 47260017
         LR    RPAR1,RCCT               LOAD POINTER TO CCT             47300016
         LR    RBR,RJCL                 LOAD POINTER TO JCL GENERATOR   47400016
         BALR  RRET,RBR                 BRANCH TO JCL GENERATOR         47500016
*                                                                       47600016
*                        AFTER RETURN FROM JCL GENERATOR                47700016
         CL    RBR,QUITCODE           Q. IS RETURN CODE QUIT       PJKA 47730017
         BE    SETQUIT                A. YES                       PJKA 47760017
*                                                                       47800016
         L     RWORK,CZERO              LOAD RETURN CODE                47900016
FINI     LR    RPAR1,RMANIP            LOAD ADDR OF MAIN STORAGE WKAR   48000016
         FREEMAIN  R,LV=480,A=(1)                                       48100016
         MVI   CCTPECB,ZERO             CLEAR PROCESSOR ECB             48200016
         NI    CCTPSTAT+1,X'DF'         SET IGNORE ATTENTION BIT OFF    48300016
         LR    RBR,RWORK                                                48400016
         LR    RPAR1,RCCT               LOAD POINTER TO CCT             48500016
         L     RSAVE,4(RSAVE)                                           48600016
         RETURN (14,12),RC=(15)         RETURN TO CTL                   48700016
*                                                                       48800016
         EJECT                                                          48900016
*                                                                       49000016
**       ** FOLLOWING ARE ROUTINES TO HANDLE ERROR MESSAGES **          49100016
*                                                                       49200016
*                                                                       49300016
NOALNAM  L     RMES,MSG2                ADDRESS OF ERROR MSG.2          49400016
RESTNAM  MVC   SECLINE+1(1),BLANKS                                      49500016
         MVC   SECLINE+2(71),SECLINE+1  CLEAR SECOND LINE AREA          49600016
         MVC   SECLINE+1(4),CNAME       MOVE NAME TO MSG.               49700016
         MVC   SECLINE+5(2),COLON       MOVE COLON                      49800016
         MVC   SECLINE+7(8),WKANAME     MOVE PARAM. CONTENTS TO MSG.    49900016
         LA    RLENG,MSGPARAM          LOAD POINTER TO MSG.PARAMETERS   50000016
WHICHNM  CLC   WKAPGM(8),BLANKS       Q. IS IT PROGRAM                  50060016
         BE    LDPRCDPL               A. NO                             50120016
         L     RWORK,PGMDISPL           INTENSIFY PROGRAM NAME          50180016
CONTNAM  ST    RWORK,0(RLENG)                                           50240016
         B     RESTOMSG                                                 50300016
*                                                                       50400016
LDPRCDPL L     RWORK,PROCDISP           INTENSIFY PROCEDURE NAME        50430016
         B     CONTNAM                                                  50460016
*                                                                       50480016
NONAME   L     RMES,MSG1                ADDRESS OF ERROR MSG.1          50500016
         MVC   SECLINE+1(1),BLANKS                                      50520016
         MVC   SECLINE+2(71),SECLINE+1  CLEAR SECOND LINE AREA          50540016
         MVC   SECLINE+1(27),PGNPROC    PROC OR PGM MSG.                50560016
         LA    RLENG,MSGPARAM           LOAD PTR TO MSG. PARAMETERS     50580016
         L     RWORK,PGMDISPL           INTENSIFY PGM NAME              50600016
         ST    RWORK,0(RLENG)                                           50620016
         LA    RLENG,4(RLENG)                                           50640016
         B     WHICHNM                  CONTINUE                        50660016
*                                                                       50680016
NMSYNTER CL    RTRT,EIGHT              Q. IS IT A BLANK                 50800016
         BE    BLKINAM                 A. YES                           50900016
         L     RMES,MSG3                ADDRESS OF ERROR MESSAGE 3      51000016
         B     RESTNAM                                                  51100016
*                                                                       51200016
BLKINAM  L     RMES,MSG3A              ADDRESS OF ERROR MESSAGE 3A      51300016
         B     RESTNAM                                                  51400016
*                                                                       51500016
NOALUR   L     RMES,MSG2                ADDRESS OF ERROR MESSAGE 2      51600016
RESTUR   MVC   SECLINE+1(1),BLANKS                                      51700016
         MVC   SECLINE+2(71),SECLINE+1  CLEAR SECOND LINE AREA          51800016
         TM    CCTSSTAT,32              Q. REMOTE GRAPHIC DEVICE   PJKA 51840017
         BO    SGJP1                    YES                        PJKA 51880017
         MVC   SECLINE+1(22),CUR        MOVE UNIT REFERENCE TO MSG PJKA 51920017
         LA    RLENG,SECLINE+23         GET ADDR FOR REMAINDER     PJKA 51960017
         B     SGJP2                                               PJKA 52000017
SGJP1    MVC   SECLINE+1(19),CSUB       MOVE SUBSYSTEM REFERENCE   PJKA 52040017
         LA    RLENG,SECLINE+20         GET ADDR FOR REMAINDER     PJKA 52080017
SGJP2    MVC   0(2,RLENG),COLON         MOVE COLON                 PJKA 52120017
         MVC   2(17,RLENG),WKAURIN      MOVE PARM CONTENTS TO MSG. PJKA 52160017
         LA    RLENG,MSGPARAM          LOAD POINTER TO MSG.PARAMETERS   52200016
         L     RWORK,URDISPL            INTENSIFY UNIT REFERENCE        52300016
         ST    RWORK,0(RLENG)                                           52400016
         B     RESTOMSG                                                 52500016
*                                                                       52600016
URNPROC  L     RMES,MSG13          *    ADDRESS OF ERROR MSG13  *       52620016
         B     RESTUR              *               *            *       52640016
*                                                                       52660016
PARNPROC L     RMES,MSG13               ADDRESS OF ERROR MSG13          52663016
         MVC   SECLINE+1(1),BLANKS                                      52666016
         MVC   SECLINE+2(71),SECLINE+1  CLEAR SECOND LINE AREA          52669016
         MVC   SECLINE+1(10),CPARAM     MOVE PARAMETERS TO MSG          52672016
         MVC   SECLINE+11(2),COLON      MOVE COLON                      52675016
         MVC   SECLINE+13(40),WKAPARM   MOVE PARM. CONTENTS TO MSG      52678016
         LA    RLENG,MSGPARAM           LOAD POINTER TO MSG.PARAMETERS  52681016
         L     RWORK,PARMDISP           INTENSIFY PARAMETERS            52684016
         ST    RWORK,0(RLENG)                                           52687016
         B     RESTOMSG                                                 52690016
*                                                                       52693016
URSYNTER CL    RTRT,EIGHT              Q. IS IT A BLANK                 52700016
         BE    BLKINUR                 A. YES                           52800016
         L     RMES,MSG3                ADDRESS OF ERROR MESSAGE 3      52900016
         B     RESTUR                                                   53000016
*                                                                       53100016
BLKINUR  L     RMES,MSG3A              ADDRESS OF ERROR MESSAGE 3A      53200016
         B     RESTUR                                                   53300016
*                                                                       53400016
BLKINLIB L     RMES,MSG3A              ADDRESS OF ERROR MESSAGE 3A      53500016
         TM    BLKURSW,X'80'            IF BLKURSW IS ON-U.REF. DATA    53530016
         BO    RESTUR                   GOES TO MSG.,OFF-LIBRARY DATA   53560016
         B     RESTLIB                                                  53600016
*                                                                       53700016
NOALLIB  L     RMES,MSG2                ADDRESS OF ERROR MESSAGE 2      53800016
         TM    BLKURSW,X'80'            IF BLKURSW IS ON-U.REF. DATA    53830016
         BO    RESTUR                   GOES TO MSG.,OFF-LIBRARY DATA   53860016
RESTLIB  MVC   SECLINE+1(1),BLANKS                                      53900016
         MVC   SECLINE+2(71),SECLINE+1  CLEAR SECOND LINE AREA          54000016
         MVC   SECLINE+1(12),CLIB       MOVE LIBRARY NAME TO MSG.       54100016
         MVC   SECLINE+13(2),COLON      MOVE COLON                      54200016
         MVC   SECLINE+15(44),WKALIBR   MOVE PARAM. CONTENTS TO MSG.    54300016
         LA    RLENG,MSGPARAM          LOAD POINTER TO MSG.PARAMETERS   54400016
         L     RWORK,LIBDISPL           INTENSIFY LIBRARY NAME          54500016
         ST    RWORK,0(RLENG)                                           54600016
         B     RESTOMSG                                                 54700016
*                                                                       54800016
PERER    L     RMES,MSG5               LOAD ADDRESS OF ERROR MESSAGE 5  54900016
         TM    BLKURSW,X'80'            IF BLKURSW IS ON-U.REF. DATA    54930016
         BO    RESTUR                   GOES TO MSG.,OFF-LIBRARY DATA   54960016
         B     RESTLIB                                                  55000016
*                                                                       55400016
LASTPOS  L     RMES,MSG10               ADDRESS OF ERROR MESSAGE 10     55420016
         TM    BLKURSW,X'80'            IF BLKURSW IS ON-U.REF. DATA    55426016
         BO    RESTUR                   GOES TO MSG.,OFF-LIBRARY DATA   55432016
         B     RESTLIB                                                  55440016
*                                                                       55460016
OVER8    L     RMES,MSG7                ADDRESS OF ERROR MESSAGE 7      55500016
         TM    BLKURSW,X'80'            IF BLKURSW IS ON-U.REF. DATA    55530016
         BO    RESTUR                   GOES TO MSG.,OFF-LIBRARY DATA   55560016
         B     RESTLIB                                                  55600016
*                                                                       55700016
PGMNPROC L     RMES,MSG4                ADDRESS OF ERROR MESSAGE 4      55800016
         LA    RLENG,MSGPARAM          LOAD POINTER TO MSG.PARAMETERS   55900016
         L     RWORK,PGMDISPL           INTENSIFY PGM                   56000016
         ST    RWORK,0(RLENG)                                           56100016
         LA    RLENG,4(RLENG)          INCREMENT COUNTER                56200016
         L     RWORK,PROCDISP           INTENSIFY PROC                  56300016
         ST    RWORK,0(RLENG)                                           56400016
         MVC   SECLINE+1(1),BLANKS                                      56500016
         MVC   SECLINE+2(71),SECLINE+1  CLEAR SECOND LINE AREA          56600016
         MVC   SECLINE+1(27),PGNPROC    MOVE MULTIPLE CHOCIE ERR.TO MSG 56700016
         B     RESTOMSG                                                 56800016
*                                                                       56900016
BCKGRNUR L     RMES,MSG4                ADDRESS OF ERROR MESSAGE 4      57000016
         LA    RLENG,MSGPARAM          LOAD POINTER TO MSG.PARAMETERS   57100016
         L     RWORK,URDISPL            INTENSIFY UNIT REFERENCE        57200016
         ST    RWORK,0(RLENG)                                           57300016
         LA    RLENG,4(RLENG)          INCREMENT COUNTER                57400016
         L     RWORK,BACKDISP           INTENSIFY BACKGROUND            57500016
         ST    RWORK,0(RLENG)                                           57600016
         MVC   SECLINE+1(1),BLANKS                                      57700016
         MVC   SECLINE+2(71),SECLINE+1  CLEAR SECOND LINE AREA          57800016
         TM    CCTSSTAT,32                                         PJKA 57810017
         BZ    SGJP3                                               PJKA 57820017
         MVC   SECLINE+1(35),SUBNBCK                               PJKA 57830017
         B     RESTOMSG                                            PJKA 57840017
SGJP3    EQU   *                                                   PJKA 57850017
         MVC   SECLINE+1(38),URNBCK     MOVE MULTIPLE CHOICE ERR.TO MSG 57900016
         B     RESTOMSG                                                 58000016
*                                                                       58100016
SPECHAR  L     RMES,MSG6               ADDRESS OF ERROR MESSAGE 6       58500016
         TM    BLKURSW,X'80'            IF BLKURSW IS ON-U.REF. DATA    58630016
         BO    RESTUR                   GOES TO MSG.,OFF-LIBRARY DATA   58660016
         B     RESTLIB                                                  58700016
*                                                                       58800016
PROCIOER L     RMES,MSG9                ADDRESS OF ERROR MESSAGE 9      58805016
         OI    ADMESSW,X'80'            SET ADDITIONAL MSG SW.          58807016
         B     PROCINT                                                  58810016
*                                                                       58815016
NOTNUM   L     RMES,MSG15               ADDRESS OF ERR.MSG.15      PJKA 58815217
RESTNUM  MVC   SECLINE+1(1),BLANKS                                 PJKA 58815417
         MVC   SECLINE+2(71),SECLINE+1  CLEAR SECOND LINE AREA     PJKA 58815617
         MVC   SECLINE+1(4),CSIZE       MOVE SIZE TO MSG           PJKA 58815817
         MVC   SECLINE+5(2),COLON       MOVE COLON                 PJKA 58816017
         MVC   SECLINE+7(4),WKAIREG     MOVE SIZE CONTENTS TO MSG  PJKA 58816217
         LA    RLENG,MSGPARAM           PTR. TO MSG.PARAM          PJKA 58816417
         L     RWORK,SIZEDISP           INTENSIFY SIZE             PJKA 58816617
         ST    RWORK,0(RLENG)                                      PJKA 58816817
         B     RESTOMSG                                            PJKA 58817017
*                                                                  PJKA 58817217
ONLY3    L     RMES,MSG18               ERROR MESSAGE 18           PJKA 58817417
         B     RESTNUM                                             PJKA 58817617
*                                                                  PJKA 58817817
NOTNUM2  L     RMES,MSG15               ADDRESS OF ERROR MSG.15    PJKA 58818017
         B     RESTPRI                                             PJKA 58818217
*                                                                  PJKA 58818417
PROCSIZE L     RMES,MSG13               ADDRESS OF ERR.MSG.13      PJKA 58818617
         B     RESTNUM                                             PJKA 58818817
*                                                                  PJKA 58819017
NOBACKGR EQU   *                                                   PJKA 58819217
         L     RMES,MSG16               ADDRESS OF ERR.MSG.16      PJKA 58819417
RESTPRI  MVC   SECLINE+1(1),BLANKS                                 PJKA 58819617
         MVC   SECLINE+2(71),SECLINE+1  CLEAR SECOND LINE AREA     PJKA 58819817
         MVC   SECLINE+1(8),CPRI        MOVE PRIORITY TO MSG       PJKA 58820017
         MVC   SECLINE+9(2),COLON       MOVE COLON                 PJKA 58820217
         MVC   SECLINE+11(2),WKAPRI     MOVE PRIORITY TO MSG.      PJKA 58820417
INTENS   LA    RLENG,MSGPARAM           PTR.TO MSG.PARAM           PJKA 58820617
         L     RWORK,PRIDISPL           INTENISFY PRIORITY         PJKA 58820817
         ST    RWORK,0(RLENG)                                      PJKA 58821017
         B     RESTOMSG                                            PJKA 58821217
*                                                                  PJKA 58821417
PRIBAD   EQU   *                                                   PJKA 58821617
         L     RMES,MSG17               ADDRESS OF ERR.MSG.17      PJKA 58821817
         MVC   SECLINE+1(1),BLANKS                                 PJKA 58822017
         MVC   SECLINE+2(71),SECLINE+1  CLEAR SECOND LINE AREA     PJKA 58822217
         MVC   SECLINE+1(25),PRIMESS    MOVE IN MESSAGE            PJKA 58822417
         LH    RTRT,CCTBRPRI            LOAD PRIORITY FROM CCT     PJKA 58822617
         BCTR  RTRT,RPAR0               REDUCE BY ONE              PJKA 58822817
         STH   RTRT,PRISUM              STORE IT                   PJKA 58823017
         MVC   SECLINE+26(2),PRISUM    MOVE TO MESSAGE             PJKA 58823217
         B     INTENS                   GO TO INTENISFY PRIORITY   PJKA 58823417
*                                                                  PJKA 58823617
NOSTEP   EQU   *                                                   PJKA 58823817
         L     RMES,MSG19               ADDRESS OF ERR. MSG. 19    PJKA 58824017
         OI    ADMESSW,X'20'            SET ADDITIONAL MSG. SW.    PJKA 58824217
         B     PROCINT                                             PJKA 58824417
*                                                                  PJKA 58824617
NOPROC   L     RMES,MSG8                ADDRESS OF ERROR MESSAGE 8      58825016
         OI    ADMESSW,X'40'            SET ADDITIONAL MSG SW.          58827016
PROCINT  MVC   SECLINE+1(1),BLANKS      CLEAR SECOND LINE AREA          58830016
         MVC   SECLINE+2(71),SECLINE+1                                  58835016
         MVC   SECLINE+1(4),CNAME       MOVE NAME CONSTANT TO MSG.      58840016
         MVC   SECLINE+5(2),COLON       MOVE COLON                      58845016
         MVC   SECLINE+7(8),WKANAME     MOVE PARAM. CONTENTS TO MSG.    58850016
         LA    RLENG,MSGPARAM           LOAD POINTER TO MSG.PARAMETERS  58855016
         L     RWORK,PROCDISP           INTENSIFY PROC                  58860016
         ST    RWORK,0(RLENG)                                           58865016
*                                                                       58885016
RESTOMSG TM    CCTPSTAT,X'04'         Q. ARE WE IN RECALL ACCEPT MODE   58905016
         BO    GOTORECL               A. YES                            58925016
         LA    RLENG,4(RLENG)           INCREMENT COUNTER               58945016
         L     RWORK,TOPMES             ADDRESS OF FIRST LINE           59000016
         ST    RWORK,0(RLENG)                                           59100016
         MVI   0(RLENG),X'40'          DISPLAY WITH BASIC CHARACTERS    59200016
         LA    RLENG,4(RLENG)          INCREMENT COUNTER                59300016
         LA    RWORK,SECLINE            ADDRESS OF SECOND LINE          59400016
         ST    RWORK,0(RLENG)                                           59500016
         MVI   0(RLENG),X'40'           DISPLAY WITH BASIC CHARACTERS   59600016
         LA    RLENG,4(RLENG)          INCREMENT COUNTER                59700016
CONTMES  LR    RWORK,RMES               ADDRESS OF ERROR MESSAGE        59800016
         ST    RWORK,0(RLENG)                                           59900016
         MVI   0(RLENG),X'40'           DISPLAY WITH BASIC CHARACTERS   60000016
         TM    ADMESSW,X'80'           Q. IS ADDITIONAL MESSAGE SW. ON  60100016
         BZ    MOREMES                  FIRST BYTE OFF - TEST SECOND    60200016
         LA    RLENG,4(RLENG)          INCREMENT COUNTER                60300016
         L    RWORK,MSG6A               ADDR. OF CONTINUING MSG. (6A)   60400016
         ST    RWORK,0(RLENG)                                           60500016
         MVI    0(RLENG),X'40'          DISPLAY WITH BASIC CHARACTERS   60600016
ENDOPAR  OI    0(RLENG),X'80'          END OF PARAMETER TABLE           60700016
*                                                                       60800016
CLEARECB MVI   CCTPECB,ZERO             CLEAR PROCESSOR ECB             60900016
         LR    RPAR1,RCCT               LOAD POINTER TO CCT             61000016
         LA    RPAR0,MSGPARAM           LOAD POINTER TO MSG.PARAMETERS  61100016
         L     RBR,CCTDMRP              LOAD POINTER TO MSG ROUTINE     61200016
         BALR  RRET,RBR                 BRANCH TO MSG ROUTINE           61300016
         NI    CCTPSTAT+1,X'DF'         SET IGNORE ATTENTION BIT OFF    61400016
         NI    URSW,X'7F'               SET UR SWITCH OFF               61500016
         NI    BLKURSW,X'7F'            SET BLANKUR SW OFF              61550016
         NI    ADMESSW,X'1F'            SET ADDITIONAL MSG. SW. OFFPJKA 61620017
         B     WAITECB                                                  61700016
*                                                                       61800016
MOREMES  TM    ADMESSW,X'40'           Q. DOES IT INDICATE MORE MSG.    61800616
         BO    GOTO12                 A. YES                       PJKA 61800817
         TM    ADMESSW,X'20'          Q. IS IT 'NO STEPNAME'       PJKA 61801017
         BZ    ENDOPAR                A. NO                        PJKA 61801217
         LA    RLENG,4(RLENG)           INCREMENT COUNTER          PJKA 61801417
         L     RWORK,MSG20              ADDRESS OF ERR. MSG.20     PJKA 61801617
         B     STORMSG                                             PJKA 61801817
*                                                                  PJKA 61802017
GOTO12   EQU   *                                                   PJKA 61802217
         LA    RLENG,4(RLENG)           INCREMENT COUNTER          PJKA 61802417
         L     RWORK,MSG12              ADDRESS OF ERROR MSG. 12   PJKA 61802617
STORMSG  ST    RWORK,0(RLENG)                                      PJKA 61802817
         MVI   0(RLENG),X'40'           DISPLAY WITH BASIC CHAR.        61803616
         B     ENDOPAR                                                  61804216
RIDUR    L     RMES,MSG11               ADDRESS OF ERROR MESSAGE 11     61805016
         B     RESTUR                   CONTINUE MESSAGE FOR UNIT REF.  61810016
*                                                                       61815016
RIDLIB   L     RMES,MSG11               ADDRESS OF ERROR MESSAGE 11     61820016
         B     RESTLIB                  CONTINUE MESSAGE FOR LIBRARY    61825016
*                                                                       61830016
RIDBACK  L     RMES,MSG11               ADDRESS OF ERROR MESSAGE 11     61835016
         MVC   SECLINE+1(1),BLANKS                                      61840016
         MVC   SECLINE+2(71),SECLINE+1                                  61845016
         MVC   SECLINE+1(21),PROCBACK   MOVE IN PROCESS IN BACKGROUND   61850016
         MVC   SECLINE+22(2),COLON      MOVE COLON                      61855016
         MVC   SECLINE+24(2),WKABACK    MOVE PARAM. CONTENTS TO MSG.    61860016
         LA    RLENG,MSGPARAM           LOAD POINTERS TO MSG.PARAMETERS 61865016
         L     RWORK,BACKDISP           INTENSIFY BACKGROUND            61870016
         ST    RWORK,0(RLENG)                                           61875016
         B     RESTOMSG                                                 61880016
GOTORECL L     RWORK,HEX18              GIVE ERROR CODE TO RECALL       61886016
         B     FINI                     RETURN                          61892016
*                                                                       61900016
* * *                                                                   61940016
*              FOLLOWING ARE INTERNAL ERROR MESSAGES - THEIR NUMBER     61980016
*              IS PASSED TO IKAERR IN A LIST--CONSTRUCTED IN A WORKAREA 62020016
*              TOGETHER WITH MODULE IDENTIFIER AND CONTROL BIT.THE      62060016
*              LATTER TELLS WEATHER TO RETURN TO THE CALLING PGM. OR TO 62100016
*              TERMINATE GJP                                            62140016
* * *                                                                   62180016
*   IKA014I IKAPSPE0 - NO CCT UNIT                                      62220016
INTMES2  EQU   *                                                        62260016
         MVC   APOWORK(3),IMSG14        MOVE MESSAGE NUMBER INTO LIST   62300016
         MVC   APOWORK+3(5),MODIDEN          MODULE IDENTIFIER          62340016
         MVC   APOWORK+8(4),CZERO            ZEROS TO ADDR. OF INSERT   62380016
         LR    RPAR1,RCCT               CCT POINTER                     62460016
         LA    RPAR0,APOWORK            PARAMETER LIST POINTER          62500016
         L     RBR,CCTIERRP             LOAD POINTER TO IERR.ROUTINE    62540016
         BALR  RRET,RBR                 BRANCH TO IT                    62580016
         CL    RBR,QUITCODE          Q. IS RETURN CODE 'QUIT'           62588016
         BNE   TSTSYSCL              A. NO                              62596016
SETQUIT  EQU   *                                                   PJKA 62600017
         LR    RWORK,RBR                LOAD RETURN CODE                62604016
         B     FINI                                                     62612016
*                                                                       62620016
*   IKA015I IKAPSPE0 - NO CCTSOUT                                       62660016
INTMES3  EQU   *                                                        62700016
         MVC   APOWORK(3),IMSG15        MOVE MESSAGE NUMBER INTO LIST   62740016
         MVC   APOWORK+3(5),MODIDEN          MODULE IDENTIFIER          62780016
         MVC   APOWORK+8(4),CZERO            ZEROS TO ADDR. OF INSERT   62820016
         OI    APOWORK+8,X'80'          SET CONTROL BIT (RETURN TO ME)  62860016
         LR    RPAR1,RCCT               CCT POINTER                     62900016
         LA    RPAR0,APOWORK            PARAMETER LIST POINTER          62940016
         L     RBR,CCTIERRP             LOAD POINTER TO IERR.ROUTINE    62980016
         BALR  RRET,RBR                 BRANCH TO IT                    63020016
         CL    RBR,QUITCODE           Q. IS RETURN CODE QUIT       PJKA 63040017
         BE    SETQUIT                A. YES                       PJKA 63060017
         MVC   CCTSOUT+1(1),DEFPRTCL    MOVE DEFAULT SYSOUT CLASS       63090016
*                                       TO CCT                          63120016
         B     MVSYSAB                                                  63150016
         EJECT                                                          63200016
**                   **  CONSTANTS  **                                  63300016
*                                                                       63400016
TRANSL   TRT   0(0,RFLD),TRTABLE        INSTRUCTION TO EXECUTE TRT      63500016
*                                                                       63600016
ZERO     EQU   0                                                        63700016
ONE      EQU   1                                                        63800016
TWO      EQU   2                                                        63900016
THREE    EQU   3                                                        64000016
FOUR     EQU   4                                                        64100016
FIVE     EQU   5                                                        64200016
SIX      EQU   6                                                        64300016
SEVEN    EQU   7                                                        64400016
CANC     EQU   8                                                        64500016
TOPMES   DC    A(IKATOP)                                                64600016
MSG1     DC    A(IKAMSG1)                                               64700016
MSG2     DC    A(IKAMSG2)                                               64800016
MSG3     DC    A(IKAMSG3)                                               64900016
MSG3A    DC    A(IKAMSG3A)                                              65000016
MSG4     DC    A(IKAMSG4)                                               65100016
MSG5     DC    A(IKAMSG5)                                               65200016
MSG6     DC    A(IKAMSG6)                                               65300016
MSG6A    DC    A(IKAMSG6A)                                              65400016
MSG7     DC    A(IKAMSG7)                                               65500016
MSG8     DC    A(IKAMSG8)                                               65600016
MSG9     DC    A(IKAMSG9)                                               65700016
MSG10    DC    A(IKAMSG10)                                              65750016
MSG11    DC    A(IKAMSG11)                                              65770016
MSG12    DC    A(IKAMSG12)                                              65780016
MSG13    DC    A(IKAMSG13)                                              65790016
MSG14    DC    A(IKAMSG14)                                              65792016
MSG15    DC    A(IKAMSG15)                                              65794016
MSG16    DC    A(IKAMSG16)                                              65796016
MSG17    DC    A(IKAMSG17)                                         PJKA 65796217
MSG18    DC    A(IKAMSG18)                                         PJKA 65796417
MSG19    DC    A(IKAMSG19)                                         PJKA 65796617
MSG20    DC    A(IKAMSG20)                                         PJKA 65796817
MSG21    DC    A(IKAMSG21)                                         PJKA 65797017
MSG22    DC    A(IKAMSG22)                                         PJKA 65797217
HEX18    DC    X'00000018'                                              65798016
CZERO    DC    F'0'                                                     65800016
CONE     DC    F'1'                                                     65900016
CTWO     DC    F'2'                                                     66000016
CTRI     DC    F'3'                                                     66100016
CFOUR    DC    F'4'                                                     66200016
CFIVE    DC    F'5'                                                     66300016
CSIX     DC    F'6'                                                     66400016
CSEVEN   DC    F'7'                                                     66500016
EIGHT    DC    F'8'                                                     66600016
CSXTEN   DC    F'16'                                                    66630016
CSEVTEN  DC    F'17'                                                    66660016
FOURTY4  DC    F'43'                                                    66700016
SIZEDISP DC    X'00000133'                                         PJKA 66730017
PRIDISPL DC    X'00000137'                                         PJKA 66760017
URDISPL  DC    X'00000141'                                              66800016
PARMDISP DC    X'00000076'                                              66900016
BACKDISP DC    X'0000015B'                                              67000016
PGMDISPL DC    X'00000139'                                              67100016
PROCDISP DC    X'00000153'                                              67200016
LIBDISPL DC    X'00000016'                                              67300016
CANCRETC DC    X'0000000C'                                              67400016
QUITCODE DC    X'0000001C'                                              67450016
PROCODE  DC    X'00000010'                                         9904 67470018
BLANKS   DC    50XL1'40'                                                67500016
MODIDEN  DC    C'PSPE0'                                                 67520016
         DS    0F                                                  PJKA 67526017
FZERO    DC    C'0000'                                             PJKA 67532017
IMSG14   DC    C'014'                                                   67540016
IMSG15   DC    C'015'                                                   67560016
         SPACE 3                                                        67580016
CNAME    DC    C'NAME'                                                  67600016
CUR      DC   C'DISPLAY UNIT REFERENCE'                                 67700016
CSUB     DC    C'SUBSYSTEM REFERENCE'                              PJKA 67750017
CLIB     DC   C'LIBRARY NAME'                                           67800016
CPARAM   DC    C'PARAMETERS'                                            67850016
CJOBLIB  DC    C'//JOBLIB'                                              67900016
         DC    XL1'24'                                                  68000016
         DC    C'DD'                                                    68100016
         DC    XL1'24'                                                  68200016
         DC    C'DSNAME='                                               68300016
CDISP    DC    XL1'25'                                                  68400016
         DC    C'DISP=(SHR,PASS)'                                       68500016
CARDEL   DC    XL1'26'                                                  68600016
CSLASH   DC    C'//'                                                    68700016
CEXEC    DC    XL1'24'                                                  68800016
         DC    C'EXEC'                                                  68900016
         DC    XL1'24'                                                  69000016
CPAR     DC    XL1'25'                                                  69100016
         DC    C'PARM='                                                 69200016
CREGI    DC    XL1'25'                                                  69400016
         DC    C'REGION='                                               69500016
CK       DC    C'K'                                                     69600016
CUNIT    DC    XL1'24'                                                  69700016
         DC    C'DD'                                                    69800016
         DC    XL1'24'                                                  69900016
         DC    C'UNIT=   '                                              70000016
SYSAB    DC    XL1'26'                                                  70100016
         DC    C'//SYSABEND'                                            70200016
         DC    XL1'24'                                                  70300016
         DC    C'DD'                                                    70400016
         DC    XL1'24'                                                  70500016
         DC    C'SYSOUT= '                                              70600016
SYSBF    DC    XL1'26'                                             R019 70610019
         DC    C'//SYSBFDMP'                                       R019 70620019
         DC    XL1'24'                                             R019 70630019
         DC    C'DD'                                               R019 70640019
         DC    XL1'24'                                             R019 70650019
         DC    C'SYSOUT= '                                         R019 70660019
HEXEND   DC    XL1'26'                                                  70700016
         DC    XL1'37'                                                  70800016
CJOBSTP  DC    C'JOB STEP'                                              70900016
CPROGR   DC   C'PGM='                                                   71000016
RECPGM   DC   C'    '                                                   71100016
RECPROC  DC   C'PROC'                                                   71200016
RECBACK  DC   C'BACKGROUND'                                             71300016
COLON    DC    C': '                                                    71400016
DEFPRTCL DC    C'A'                                                     71450016
PGNPROC  DC    C'* PROCEDURE OR PROGRAM NAME'                           71500016
URNBCK   DC    C'* DISPLAY UNIT REFERENCE OR BACKGROUND'                71600016
SUBNBCK  DC    C'* SUBSYSTEM REFERENCE OR BACKGROUND'              PJKA 71620017
PROCBACK DC    C'PROCESS IN BACKGROUND'                                 71650016
CSIZE    DC    C'SIZE'                                             PJKA 71658017
CPRI     DC    C'PRIORITY'                                         PJKA 71666017
PRIMESS  DC    C'- PRIORITY NOT TO EXCEED '                        PJKA 71674017
         DS    0H                                                  PJKA 71682017
PRISUM   DC    C'XX'                                               PJKA 71690017
*                                                                       71700016
         SPACE 2                                                        71710000
*********************************************************************** 71720000
*                                                                       71730000
*        MAINTENANCE AREA                                        A33564 71740000
*                                                                       71750000
*********************************************************************** 71760000
PATCH    DC    40F'0'                                            A33564 71770000
         SPACE 2                                                        71780000
         END                                                            71800016
