         TITLE 'WRITE MESSAGE PROCESSOR FOR GJP'                        00200016
*                                                                       00400016
*     IKAPWRI0 WRITE MESSAGE ROUTINE                                    00600016
*                                                                       00800016
*              CHART ID - FN                                            00860017
*                                                                       00920017
*              FUNCTION - PROCESS WRITE MESSAGE COMMAND FROM            01000016
*               2250 OPERATOR TO CPU OPERATOR.                          01200016
*                                                                       01400016
*              OPERATION - DETERMINE LENGTH OF TEXT TO BE WRITTEN       01600016
*               ON CPU CONSOLE TYPEWRITER. PASS KEYWORDS AND            01800016
*               TEXT OF MESSAGE TO DIA ROUTINE TO FORM HISTORY          02000016
*               AND RECORD DATA SETS. DETERMINE IF REPLY HAS BEEN       02200016
*               REQUESTED AND DISPLAY A REPLY PENDING MESSAGE IF        02400016
*               IT HAS. IF REPLY NOT REQUESTED ISSUE SVC 35 AND         02600016
*               RETURN CONTROL TO CONTROL ROUTINE. IF REPLY HAS         02800016
*               BEEN REQUESTED WAIT FOR CPU OPERATOR REPLY. WHEN        03000016
*               OPERATOR REPLYS FORMAT REPLY FOR DISPLAYING AND         03200016
*               PASS KEYWORD AND TEXT TO DIA ROUTINE. WHEN MESSAGE      03400016
*               HAS BEEN DISPLAYED WAIT FOR CONSOLE OPERATOR            03600016
*               ACKNOWLEDGEMENT. RETURN CONTROL TO CONTROL ROUTINE.     03800016
*                                                                       04000016
*              POST CODES REQUIRED - '04' END                           04200016
*                                    '08' CANCEL                        04400016
*                                    '1C' INTERNAL ERROR           GJPF 04500017
*                                                                       04600016
*              RETURN CODES ISSUED - '00' NORMAL COMPLETION             04800016
*                                    'OC' CANCEL FRAME                  05000016
*                                    '1C' TERNINATE GJP            GJPF 05100017
*                                                                       05200016
*              TABLES AND WORK AREAS USED -                             05400016
*               CONSOLE CONTROL TABLE (CCT)                             05600016
*                EXTRACT RECORD (CCTPWKA)                               05800016
*                RECORD WORK AREA (CCTRECWA)                            06000016
*                PROCESSOR ECB (CCTPECB)                                06200016
*                WRITE TO OPERATOR ECB (CCTWECB)                        06400016
*                GJP STATUS BYTE (IGNORBIT)                             06600016
*                                                                       06800016
*              REGISTER EQUATES AND LABELS                              07000016
*                                                                       07200016
         SPACE                                                          07400016
RPAR0    EQU   0    PARAMETER REG.0                                     07600016
RPAR1    EQU   1    PARAMETER REG.1                                     07800016
BASER    EQU   2    BASE REGISTER                                       08000016
CCTR     EQU   3    POINTER TO CCT                                      08200016
EXTR     EQU   4    POINTER TO PROCESSOR WORK AREA                      08400016
MSGR     EQU   5    POINTER TO MESSAGE TEXT                             08600016
LENR     EQU   6    LENGTH OF DATA FIELD                                08800016
TOTR     EQU   7    POINTER TO CHAR. TO BE TESTED                       09000016
PARMR    EQU   8                       POINTER TO PARAMETER LIST        09200016
RETR     EQU   9                       RETURN FROM MSGSUB               09400016
RSAVE    EQU   13   ADDR OF REG, SAVE AREA                              09600016
RRET     EQU   14   RETURN ADDR                                         09800016
RBR      EQU   15   BRANCH ADDR                                         10000016
         EJECT                                                          10200016
*                                                                       10400016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         10490016
         SPACE                                                          10580016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    10670016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     10760016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       10850016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             10940016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  11030016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  11120016
*                   SET.                                                11210016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      11300016
*                   SECOND.                                             11390016
         SPACE 2                                                        11480016
CCT      DSECT                                                          11570016
         USING *,CCTR                                                   11660016
         SPACE                                                          11750016
*                             SECTION ONE                               11840016
         SPACE                                                          11930016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     12020016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    12110016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  12200016
         SPACE                                                          12290016
         DS    0F                                                       12380016
CCTUNAME DS    5F                  USER'S NAME                          12470016
CCTUACCT DS    5F                  USER'S ACCOUNT NUMBER                12560016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     12650016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       12740016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    12830016
*                                       AT LAST BEGIN JOB               12920016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   13010016
*                                       LAST BEGIN JOB                  13100016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 13190016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    13280016
*                                       JOB                             13370016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    13460016
*                                       JOB                             13550016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     13640016
*                                       CESSOR                          13730016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         13820016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         13910016
CCTJCTR  DS    H                   JOB COUNTER                          14000016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                14090016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   14180016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  14270016
CCTSSTAT DS    C                   SESSION STATUS                       14360016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              14450016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              14540016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    14630016
         EJECT                                                          14720016
         SPACE 2                                                        14810016
*                             SECTION TWO                               14900016
         SPACE                                                          14990016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   15080016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  15170016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 15260016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              15350016
         SPACE                                                          15440016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     15530016
*                                       FRAME                           15620016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  15710016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     15800016
*                                       MULTIPLE DISPLAY FRAME (ENT)    15890016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   15980016
CCTDISM  DS    C                   DISPLAY MASK                         16070016
CCTCSM   DS    C                   COMMAND SELECT MASK                  16160016
CCTPSTAT DS    CL2                 GJP STATUS                           16250016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              16340016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  16430016
         SPACE 2                                                        16520016
*                             SECTION THREE                             16610016
         SPACE                                                          16700016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    16790016
*                   INTO SECTION ONE OR TWO                             16880016
         SPACE                                                          16970016
CCTDGMP  DS    F                  POINTER TO DGM                        17060016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                17150016
CCTCSTP  DS    F                  POINTER TO CST                        17240016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                17330016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            17420016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 17510016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              17600016
CCTDIARP DS    F                  POINTER TO DIA                        17690016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      17780016
CCTACTP  DS    F                  POINTER TO ACT                        17870016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     17960016
CCTIERRP DS    F                  POINTER TO IERR                       18050016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              18140016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               18230016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                18320016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 18410016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 18500016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   18590016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                18680016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                18770016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               18860016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              18950016
CCTPECB  DS    F                  PROCESSOR'S ECB                       19040016
CCTWECB  DS    F                  WTOR ECB                              19130016
CCTDIAWA DS    CL136               DIARY WORK AREA                      19220016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    19310016
CCTCSAVE DS    CL72                CTL SAVE AREA                        19400016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                19490016
CCTASAVE DS    CL72                DAT SAVE AREA                        19580016
         EJECT                                                          20400016
*                                                                       20600016
*  DSECT LAYOUT OF PROCESSOR WORK AREA (CCTRECWA)                       20800016
*                                                                       21000016
         SPACE                                                          21200016
EXTREC   DSECT                                                          21400016
         USING *,EXTR                                                   21600016
EXTSTART DS    0F                                                       21800016
WRICON   DS    CL4                     CONSTANT OF 'WRI'                22000016
         DS    2F                      UNUSED                           22200016
REPLENGT DS    CL1                     REPLY LENGTH                     22400016
REPADDR  DS    CL3                     REPLY ADDRESS                    22600016
REPECB   DS    CL4                     REPLY ECB ADDRESS                22800016
MSGLENGT DS    CL2                     MESSAGE LENGTH                   23000016
ZEROS    DS    CL2                     FIELD SHOULD BE ZEROS            23200016
MSGDATA  DS    CL126                   DATA FIELD FOR MESSAGE           23400016
LENGTH   DS    CL1                     LENGTH OF REPLY                  23600016
DISPLEN  DS    CL1                     LENGTH OF REPLY TO BE DISPLAYED  23800016
REPMSG   DS    CL70                    DATA FIELD FOR FIRST LINE        23900016
SCNDLINE DS    CL56                    SECOND LINE INPUT                24000016
LENGTH2  DS    CL1                     LENGTH OF SECOND LINE            24100016
DISPLEN2 DS    CL57                    DATA FIELD FOR SECOND LINE       24200016
DISPLIST DS    CL1                     DISPLAY PARAMETER LIST           24400016
MSGADDR  DS    CL3                     ADDR OF OPERATER REPLY MSG       24600016
PARMLST  DS    CL10                    DISPLAY MESSAGE PARM LIST        24900016
REPOPT   DS    CL2                     REPLY OPTION                     25200016
EXTEND   EQU   *                       END OF EXTRACT RECORD            25400016
         SPACE                                                          25600016
*                                                                       25800016
*  EQUATES USED                                                         26000016
*                                                                       26200016
MASK4    EQU   X'04'                   END CODE MASK                    26400016
MASK8    EQU   X'08'                   CANCEL CODE MASK                 26600016
HEX7E    EQU   X'7E'                                                    26800016
HEXC0    EQU   X'C0'                                                    27000016
HEXFF    EQU   X'FF'                                                    27200016
POSTCODE EQU   CCTPECB+3               ADDR OF POST CODE                27400016
WORDCON  EQU   CCTDIAWA+5              ADDR OF CON IN DIARY WORK AREA   27600016
RECMSG   EQU   CCTDIAWA+15             ADDR OF TEXT IN DIARY WORK AREA  27800016
SAVE13   EQU   CCTPSAVE+4              ADDR OF PERVIOUS SAVE AREA       28000016
IGNORBIT EQU   CCTPSTAT+1              SECOND BYTE OF GJP STATUS        28200016
MSGTEXT  EQU   MSGDATA-1                                                28400016
ZERO     EQU   0                                                        28600016
ONE      EQU   1                                                        28800016
TWO      EQU   2                                                        29000016
THREE    EQU   3                                                        29200016
FOUR     EQU   4                                                        29400016
EIGHT    EQU   8                                                        29600016
TEN      EQU   10                                                       29800016
ONE17    EQU   117                                                      30000016
PARMLST1 EQU   0                                                        30200016
PARMLST2 EQU   PARMLST1+4                                               30400016
PARMLST3 EQU   PARMLST2+4                                               30600016
RETCODE  EQU   12                                                       30700016
         EJECT                                                          30800016
IKAPWRI0 CSECT                                                          31000016
*0792,410000,484000,550000                                         GJPF 31100017
         SPACE                                                          31200016
*                                                                       31400016
*  SAVE REGISTERS AND SET UP BASE REGISTER                              31600016
*                                                                       31800016
         SPACE 2                                                        32000016
         SAVE  (14,12),,*              SAVE ALL REGISTERS               32200016
         BALR  BASER,0                 ESTABLISH REG.2 AS BASE          32400016
         USING *,BASER                                                  32600016
         LR    CCTR,RPAR1              LOAD ADDR OF CCT INTO REG.3      32800016
         LA    RPAR1,CCTPSAVE          LOAD ADDR OF MY SAVE AREA        33000016
         ST    RPAR1,EIGHT(ZERO,RSAVE) STORE ADDR OF SAVE AREA IN       33200016
*                                      HIGHER LEVEL SAVE AREA           33400016
         ST    RSAVE,SAVE13            STORE ADDR OF PREVIOUS SAVE AREA 33600016
         LA    RSAVE,CCTPSAVE          LOAD ADDR OF REG. SAVE AREA      33800016
         SPACE 2                                                        34000016
WAITECB  NC    IGNORBIT(ONE),IGNOROFF  TURN OFF IGNORE ATTN BIT         34100016
         WAIT  ECB=CCTPECB             WAIT FOR POSTING OF ECB BY DAT   34200016
         SPACE                                                          34400016
         TM    POSTCODE,MASK8          TEST FOR CANCEL CODE             34600016
         BO    EXIT                                                     34800016
         TM    POSTCODE,X'1C'          IS POST CODE INT ERROR      GJPF 34860017
         BO    ERRRTN                  YES GO TO ERROR RETURN      GJPF 34920017
         SPACE                                                          35000016
*                                                                       35200016
*  LOAD POINTERS TO EXTRACTED RECORD AND DETERMINE LENGTH OF MESSAGE    35400016
*  TO BE WRITTEN TO CPU OPERATOR                                        35600016
*                                                                       35800016
         SPACE                                                          36000016
LOADPTR  LA    EXTR,CCTPWKA            LOAD ADDR OF EXTRACT RECORD      36200016
         LA    MSGR,MSGTEXT            LOAD ADDR OF TEXT FIELD          36400016
         LH    LENR,CON126             LOAD LENGTH OF DATA FIELD        36600016
TOTDISP  LA    TOTR,ZERO(MSGR,LENR)    TOTAL DISPLAMENT FOR COMPARE     36800016
         CLC   ZERO(ONE,TOTR),BLANK    IS IT A BLANK                    37000016
         BNE   STORLEN                 NO STORE LENGTH                  37200016
         BCT   LENR,TOTDISP            BRANCH IF LENGTH REG. NOT ZERO   37400016
         SPACE                                                          37600016
*                                                                       37800016
*  IF MESSAGE TEXT FIELD WAS BLANK INFORM CONSOLE OPERATOR              38000016
*                                                                       38200016
         SPACE                                                          38400016
         LA    RETR,WAITECB            LOAD ADDR OF RETURN              38600016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    38800016
         DC    AL2(PARMLST1)           DISPLACEMENT OF PARM LIST NO,1   39000016
         SPACE                                                          39200016
*                                                                       39400016
*  STORE LENGTH OF DATA AND GO TO DIA ROUTINE FOR RECORDING OF MESSAGE  39600016
*                                                                       39800016
         SPACE                                                          40000016
STORLEN  LA    LENR,4(LENR)            ADD FOUR TO LENGTH               40200016
         STH   LENR,MSGLENGT           STORE LENGTH AT BEGINNING OF MSG 40400016
         XC    ZEROS(TWO),ZEROS        ZERO TWO BYTES BEFORE TEXT       40600016
         MVI   CCTDIAWA,C' '           MOVE A BLANK TO WORK AREA   GJPF 40650017
         MVC   CCTDIAWA+1(175),CCTDIAWA  CLEAR WORK AREA TO BLANKS GJPF 40700017
         MVC   RECMSG(126),MSGDATA     MOVE TEXT TO DIARY WORK AREAGJPF 40750017
         MVC   WORDCON(EIGHT),MSGCON   MOVE CONSTANT TO DIA WORK AREA   40800016
         LR    RPAR1,CCTR              LOAD ADDR OF CCT INTO REG.1      41200016
         L     RBR,CCTDIARP            LOAD ADDR OF DIARY ROUTINE       41400016
         O     RPAR1,HIGH4             OR IN SECOND HIGH ORDER BIT GJPF 41500017
         BALR  RRET,RBR                BRANCH TO DIA                    41600016
         SPACE                                                          41800016
*                                                                       42000016
*  CHECK FOR REPLY OPTION AND DISPLAY REPLY PENDING MSG. IF REQUESTED   42200016
*                                                                       42400016
         SPACE                                                          42450017
         CH    RBR,CON1C               IS RETURN CODE 1C           GJPF 42500017
         BE    ERRRTN                  YES GO TO ERROR RETURN      GJPF 42550017
         SPACE                                                          42600016
CKREP    CLC   REPOPT(TWO),BLANK       COMPARE FOR REPLY OPTION         42800016
         BE    NOREPLY                 BRANCH NO REPLY REQUESTED        43000016
         SPACE                                                          43200016
         LA    RETR,LOADECB            LOAD ADDR OF RETURN              43400016
         OI    CCTSSTAT,16              INDICATE NO EXTRACT RECORD GJPF 43500017
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    43600016
         DC    AL2(PARMLST2)           DISPLACEMENT OF PARM LIST NO.2   43800016
         SPACE                                                          44000016
*                                                                       44200016
*  SET UP MESSAGE FOR WTO WHEN SVC 35 IS ISSUED                         44400016
*                                                                       44600016
         SPACE                                                          44800016
LOADECB  LA    RPAR1,CCTWECB           LOAD ADDR OF REPLY ECB           45000016
         ST    RPAR1,REPECB            STORE ADDR OF REPLY ECB          45200016
         LA    RPAR1,REPMSG            LOAD ADDR FOR REPLY TEXT         45400016
         ST    RPAR1,REPLENGT          STORE ADDR FOR REPLY TEXT IN     45600016
*                                      MESSAGE FIELD                    45800016
         MVI   REPLENGT,HEX7E          MOVE REPLY LENGTH                46000016
         XC    CCTWECB(FOUR),CCTWECB   CLEAR REPLY ECB                  46200016
         LA    RPAR1,REPLENGT          LOAD ADDR OF START OF WTO FIELD  46400016
         SVC   35                                                       46600016
         SPACE                                                          46800016
         WAIT  ECB=CCTWECB             WAIT FOR ECB TO BE POSTED        47000016
         SPACE                                                          47200016
*                                                                       47400016
*  MOVE CONSTANT 'REPLY' AND TEXT OF REPLY TO DIA WORK AREA             47600016
*                                                                       47800016
         SPACE                                                          48000016
         MVI   CCTDIAWA,C' '           MOVE A BLANK TO WORK AREA   GJPF 48050017
         MVC   CCTDIAWA+1(175),CCTDIAWA  CLEAR WORK AREA TO BLANKS GJPF 48100017
         MVC   RECMSG(126),REPMSG      MOVE TEXT TO DIARY WORK AREAGJPF 48150017
         MVC   WORDCON(EIGHT),REPCON   MOVE CONSTANT TO DIA WORK AREA   48200016
         LR    RPAR1,CCTR              LOAD ADDR OF CCT INTO REG.1      48600016
         L     RBR,CCTDIARP            LOAD ADDR OF DIARY ROUTINE       48800016
         O     RPAR1,HIGH4             OR IN SECOND HIGH ORDER BIT GJPF 48900017
         BALR  RRET,RBR                BRANCH TO DIA ROUTINE            49000016
         SPACE                                                          49200016
*                                                                       49400016
*  FORMAT REPLY TEXT AND DISPLAY ON CONSOLE                             49600016
*                                                                       49800016
         SPACE                                                          49850017
         CH    RBR,CON1C               IS RETURN CODE 1C           GJPF 49900017
         BE    ERRRTN                  YES GO TO ERROR RETURN      GJPF 49950017
         SPACE                                                          50000016
         LA    MSGR,DISPLEN            LOAD ADDR OF DATA FIELD          50200016
         LH    LENR,CON126             LOAD LENGTH OF DATA FIELD        50400016
ADDLENGT LA    TOTR,ZERO(MSGR,LENR)    ADD LENGTH OF TEXT TO ADDR       50600016
         CLC   ZERO(ONE,TOTR),BLANK    IS CHARACTER A BLANK             50800016
         BNE   STORLGT                 NO STORE LENGTH                  51000016
         BCT   LENR,ADDLENGT           BRANCH IF LENR NOT ZERO          51200016
STORLGT  CH    LENR,CON70              IS LENGTH MORE THAN 70 CHAR'S    51300016
         BH    SHIFT                   YES SHIFT CHARACTERS OVER        51400016
         STH   LENR,LENGTH             STORE LENGTH OF TEXT             51500016
         SPACE                                                          51600016
LDRET    LA    RETR,WAIT               LOAD ADDR OF RETURN              51800016
         OI    CCTSSTAT,16              INDICATE NO EXTRACT RECORD GJPF 51900017
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    52000016
         DC    AL2(PARMLST3)           DISPLACEMENT OF PARM LIST NO.3   52200016
         SPACE                                                          52220016
SHIFT    MVC   LENGTH2+2(56),SCNDLINE  MOVE SECOND LINE OVER 2 SPACES   52240016
         MVC   LENGTH(2),CON70         MOVE LENGTH OF 70 TO FIRST LINE  52260016
         SH    LENR,CON70              SUBTRACT 70 FROM LENGTH          52280016
         STH   LENR,LENGTH2            STORE LENGTH OF SECOND LINE      52300016
         B     LDRET                                                    52320016
         SPACE                                                          52400016
*                                                                       52600016
*  CLEAR ECB'S AND WAIT FOR POSTING BY DAT ROUTINE                      52800016
*                                                                       53000016
         SPACE                                                          53200016
WAIT     NC    IGNORBIT(ONE),IGNOROFF  TURN OFF IGNORE ATTN BIT         53300016
         WAIT  ECB=CCTPECB             WAIT FOR POSTING OF ECB BY DAT   53400016
         SPACE                                                          53600016
*                                                                       53800016
*  CLEAR PROCESSOR ECB TURN OFF IGNORE ATTN BIT AND RETURN TO PCTL      54000016
*                                                                       54200016
         SPACE                                                          54250017
         CH    RBR,CON1C               IS RETURN CODE 1C           GJPF 54300017
         BE    ERRRTN                  YES GO TO ERROR RETURN      GJPF 54350017
         SPACE                                                          54400016
EXIT     LA    RBR,RETCODE             LOAD RETURN CODE                 54700016
ERRRTN   NC    IGNORBIT(ONE),IGNOROFF  TURN OFF IGNORE ATTN BIT    GJPF 55000017
         XC    CCTPECB(FOUR),CCTPECB   CLEAR PROCESSOR ECB              55400016
         L     RSAVE,SAVE13            LOAD SAVE AREA ADDR INTO REG.13  55600016
         RETURN (14,12),RC=(15)        RETURN TO PCTL ROUTINE           55800016
         SPACE                                                          56000016
*                                                                       56200016
*  LOAD REGISTER AND ISSUE SVC 35 WITH NO REPLY REQUESTED               56400016
*                                                                       56600016
         SPACE                                                          56800016
NOREPLY  LA    RPAR1,MSGLENGT          LOAD ADDR OF MSG TO BE WRITTEN   57000016
         SVC   35                                                       57200016
         B     EXIT                    BRANCH TO EXIT ROURINE           57400016
         SPACE                                                          57600016
*                                                                       57800016
*  GO TO DMSG ROUTINE WITH ERROR MESSAGES AND RETURN TO WAIT            58000016
*                                                                       58200016
         SPACE                                                          58400016
MSGSUB   LH    PARMR,ZERO(PARMR)       LOAD DISPLACEMENT                58600016
         A     PARMR,LISTPNTR      ADD BEGINNING OF MSG MODULE          58800016
         L     PARMR,ZERO(PARMR)       LOAD POINTER TO LIST             59000016
         LA    MSGR,DISPLIST           LOAD ADDR OF PARM LIST TO BE BLT 59200016
LDPARM   L     TOTR,ZERO(PARMR)        LOAD PARAMETER                   59400016
         ST    TOTR,ZERO(MSGR)         STORE PARAMETER                  59600016
         LTR   TOTR,TOTR               TEST FOR LAST PARAMETER          59800016
         BC    TEN,MOVEPT              NOT LAST PARAMETER               60000016
         SPACE                                                          60200016
         CLI   ONE(PARMR),HEXFF        DOES ADDR HAVE TO BE INSERTED    60400016
         BE    INSERT                  YES GO TO INSERT ADDR            60600016
LOADCCTA LR    RPAR1,CCTR              LOAD ADDR OF IKACCT              60800016
         LA    RPAR0,DISPLIST          LOAD ADDR OF PARAMETER LIST      61000016
         L     RBR,CCTDMRP             LOAD ADDR OF IKADMSG             61200016
         SPACE                                                          61600016
         XC    CCTPECB(FOUR),CCTPECB   CLEAR PROCESSOR ECB              62000016
         XC    CCTWECB(FOUR),CCTWECB   CLEAR WTO ECB                    62200016
         BALR  RRET,RBR                 BRANCH TO DMSG                S 62300016
         CH    RBR,CON1C               IS RETURN CODE 1C           GJPF 62330017
         BE    ERRRTN                  YES GO TO ERROR RETURN      GJPF 62360017
         BR    RETR                    RETURN TO MAIN ROUTINE           62400016
         SPACE                                                          62600016
MOVEPT   LA    MSGR,FOUR(MSGR)         MOVE POINTER FOUR BYTES          62800016
         LA    PARMR,FOUR(PARMR)       MOVE POINTER FOUR BYTES          62900016
         B     LDPARM                  GO TO LOAD NEXT PARAMETER        63000016
         SPACE                                                          63200016
INSERT   LA    RPAR1,DISPLEN           LOAD ADDR OF DISPLAY LINE        63400016
         ST    RPAR1,PARMLST           STORE IN PARM LIST               63450016
         CLI   LENGTH2,C' '            IS LENGTH OF SECOND LINE BLANK   63500016
         BE    MOVEC0                  YES GO TO MOVE END CODE          63550016
         SPACE                                                          63600016
         LA    RPAR1,DISPLEN2          LOAD ADDR OF SECOND LINE         63650016
         ST    RPAR1,PARMLST+4         STORE IN PARM LIST               63700016
         MVI   PARMLST,X'40'           MOVE TEXT CODE TO FIRST LINE     63750016
         MVI   PARMLST+4,HEXC0         MOVE END CODE TO SECOND LINE     63800016
         B     LOADCCTA                GO TO LOAD CCT ADDR              63850016
         SPACE                                                          63900016
MOVEC0   MVI   PARMLST,HEXC0           MOVE END CODE TO FIRST LINE      63950016
         B     LOADCCTA                GO TO LOAD CCT ADDR              64000016
         SPACE                                                          64200016
*                                                                       64400016
*  CONSTANTS USED                                                       64600016
*                                                                       64800016
         SPACE                                                          65000016
LISTPNTR DC    V(IKAMWRI0)         ADDR OF IKAMWRI0                     65200016
NORMCODE DC    X'0000'                                                  65400016
CANCODE  DC    X'000C'                                                  65600016
HIGH4    DC    X'40000000'             ORING CONSTANT FOR REG      GJPF 65660017
CON1C    DC    X'001C'                 ERROR CODE CONSTANT         GJPF 65720017
CON126   DC    X'007E'                 CONSTANT OF 126                  65800016
CON70    DC    H'70'                   CONSTANT OF 70                   65900016
BLANK    DC    C'  '                   CONSTANT OF BLANKS               66000016
MSGCON   DC    C'MESSAGE '             CONSTANT OF MESSAGE              66200016
REPCON   DC    C'REPLY   '             CONSTANT OF REPLY                66400016
IGNOROFF DC    X'DF'                   ONE BYTE MASK USED TO TURN OFF   66600016
*                                      IGNORE ATTN BIT IN CCT           66800016
         SPACE 2                                                        66820000
*********************************************************************** 66840000
*                                                                       66860000
*        MAINTENANCE AREA                                        A33564 66880000
*                                                                       66900000
*********************************************************************** 66920000
PATCH    DC    7F'0'                                             A33564 66940000
         END                                                            67000016
