IKASD079 CSECT                                                          00700016
*0801,483000-490000,549000,648000                                  IIXX 00800018
         TITLE 'IKASD079-DELETE USER JOB SMB'                           01000016
         TITLE 'IEFSD079 - VMS SYSOUT WTR  LINK-TO-QMNGR-DELETE'        01400016
**********************************************************************  02100016
*                                                                    *  02800016
*   MODULE NAME         -IKASD079                                       03200016
*                                                                       03600016
* CHART ID              -DF                                             04000016
*                                                                       04400016
* FUNCTION              -DELETE SMB'S ASSOCIATED WITH CURRENT SYSOUTJOB 04800016
*                                                                       05200016
* ENTRY POINTS          -IKASD079 FRAM IKASD082 VIA XCTL(IKA079SD)      05600016
*                                      IKASDENQ VIA XCTL                06000016
*                                                                       06400016
* OPERATION             -AFTER READING SMB'S FOR CURRENT SYSOUT JOB TO  06800016
*                        DISK,IKASD082 WILL XCTL TO THIS MODULE IN      07200016
*                        ORDER TO DELETE ALL CONTROL RECORDS,SMB OR     07600016
*                        DSB'S ASSOCIATED WITH THE CURRENT JOB.IKASDEWQ 08000016
*                        WILL DO THE SAME WHEN IT IS UNABLE TO ENQ FOR  08400016
*                        PRINT OUTPUT AN NON-GJP STARTED DSB OR SMB.THE 08800016
*                        DELETE FUNCTION IS PERFORMED BY A LINK TO      09200016
*                        IEFQDELQ(QUEUE MANAGER 'DELETE' FUNCTION. EXIT 09600016
*                        IS TAKEN TO IKASD082 VIA AN XCTL(IKA082SD)     10000016
*                        UPON COMPLETION                                10400016
*                                                                       10800016
* EXITS                 -IKASD082(VIA XCTL-IKA082SD)                    11200016
*                                                                       11600016
* INPUT                 -REGISTER 1 POINTS TO A NINE WORD PARAMETER     12000016
*                        LIST(PARLIST)                                  12400016
*                        WORD 1-PARCSCB-POINTER TO CSCB                 12800016
*                        WORD 2-PAROCT -POINTER TO OVERALL CONTROL TBL  13200016
*                        WORD 3-PARCOCT-POINTER TO CURRENT ENTRY RCD IN 13600016
*                                       OCT                             14000016
*                        WORD 4-PARECBL-POINTER TO ECB LIST             14400016
*                                       (SEE IKASD081 FOR FORMAT)       14800016
*                        WORK 5-PARQMPAR-POINTER TO QMPA                15200016
*                        WORD 6-PARSMB -POINTER TO SMB INPUT AREA       15600016
*                        WORD 7-GPAROCT-POINTER TO OCT(THE ENTRY IN THE 16000016
*                                       CVT POINTS TO THIS LOCATION)    16400016
*                        WORD 8-GPARABND-POINTER TO ABEND ROUTINE       16800016
*                        WORD 9-GPARCANC-POINTER TO CANCEL KEY ROUTINE  17200016
*                                        (IKACKXT)                      17600016
*                                                                       18000016
* OUTPUT                -SAME AS INPUT PLUS 'COMING FROM IKASD079'      18400016
*                        INDICATION IN REGISTER 8.                      18800016
*                                                                       19200016
* EXTERNAL REFERENCES   -IKASD082                                       19600016
*                        IEFQDELE                                       20000016
*                                                                       20400016
* TABLES                -NINE WORD PARLIST                              20800016
*                                                                       21200016
* WORKAREAS             -NONE                                           21600016
*                                                                       22000016
* ERROR CONDITIONS      -Q/MGR ERROR IN ATTEMPTING TO DELETE SMB/DSB    22400016
*                                                                       22800016
*********************************************************************** 23200016
*                                                                    *  28700016
**********************************************************************  29400016
***                                                                ***  30100016
*        ESSENTIAL EQUATES                                           *  30800016
***                                                                ***  31500016
*                                                                    *  32200016
R0       EQU   0                                                        32900016
R1       EQU   1                                                        33600016
R2       EQU   2                                                   IIXX 33800018
R3       EQU   3                                                   IIXX 34000018
R4       EQU   4                                                        34300016
R5       EQU   5                                                   IIXX 34600018
R6       EQU   6                                                        35000016
R7       EQU   7                                                   IIXX 35300018
R8       EQU   8                                                        35700016
R9       EQU   9                                                        36400016
RBASE1   EQU   10                            BASE FOR WORKAREA     IIXX 36500018
RBASE2   EQU   11                            BASE FOR IHADCB       IIXX 36600018
RBASE3   EQU   12                                                  IIXX 36700018
R14      EQU   14                                                       37100016
R15      EQU   15                                                       37800016
*                                                                    *  38500016
IOERROR  EQU   X'0C'                    USED TO INDICATE QMGR I/O ERR   39200016
UCBTYPE  EQU   16                                                  IIXX 39500018
*                                                                    *  39900016
**********************************************************************  40600016
         BALR  R9,0                                                     41300016
         USING *,R9                                                     42000016
***                                                                ***  42700016
*        GO TO QUEUE MANAGER  TO DELETE EXTERNAL SPACE               *  43400016
*        ASSOCIATED WITH THE JOB WHICH HAS JUST BEEN FINISHED        *  44100016
***                                                                ***  44800016
         LR    R6,R1                    LOAD ADDR OF PARLIST            45500016
         USING PARLIST,R6               ADDRESSABILITY FOR PARLIST      46200016
         CLI   PARWORK2,X'00'           IS ERROR INDICATOR ZERO         46900016
         BNE   SD79RETN                 NO,DO NOT DELETE,LEAVE          47600016
         L     R7,PARQMPAR              LD PTR TO QMNGR PARM AREA  IIXX 48100018
         USING IOPARAMS,R7              ADDRESSABILITY             IIXX 48600018
         CLI  PARCOCT,X'FF'        ANY DSBS ON QUEUE               IIXX 49200018
         BE    FREEIOB             GO FREE IOB                     IIXX 49400018
         CLI   PARCOCT,X'0F'                                       IIXX 49403018
         BNE   CONT                                                IIXX 49406018
         GETMAIN R,LV=GETMAIN                                      IIXX 49409018
         LR    RBASE1,R1                                           IIXX 49412018
*                                                                  IIXX 49415018
**       RBASE1 IS USED FOR ADDRESSING THE WORK AREA               IIXX 49418018
*                                                                  IIXX 49421018
         USING WORKAREA,RBASE1                                     IIXX 49424018
         LA    R3,CLEAR1                LOOP CONTROL FOR CLEAR     IIXX 49427018
         LR    R5,R1                                               IIXX 49430018
CLEAR256 EQU   *                                                   IIXX 49433018
         XC    0(255,R5),0(R5)          CLEAR OUT 255 BYTES        IIXX 49436018
         LA    R5,255(R5)               POINT TO NEXT SEGMENT      IIXX 49439018
         BCT   R3,CLEAR256              END OF CLEAR LOOP          IIXX 49442018
         XC    0(CLEAR2,R5),0(R5)       CLEAR LEFTOVER BYTES       IIXX 49445018
         L     R3,LWORKS                LENGTH OF GETMAIN          IIXX 49448018
         ST    R3,FREELENG              INTO LIST FOR FREEMAIN     IIXX 49451018
         ST    R1,FREELIST              SAVE ADDR OF GETMAIN       IIXX 49454018
         LOAD  EP=IEFQMRAW                                         IIXX 49457018
         ST    R0,IEFQMRWA                                         IIXX 49460018
         MVC   DCB(LDCB),SMBDCB         MOVE DCB INTO WORKAREA     IIXX 49463018
         LA    RBASE2,DCB                    ADDRESSABILITY FOR DCBIIXX 49466018
         USING IHADCB,RBASE2                                       IIXX 49469018
         L     R3,PARCOCT                    OCT ADDRESS           IIXX 49472018
         MVC   DCBDDNAM+3(3),OCTUNIT+1(R3)   MOVE IN DDNAME        IIXX 49475018
OCTUNIT  EQU   8                             UNIT ADDRS IN OCT     IIXX 49478018
         MVC   DOPEN(OPENSIZE),SMBOPEN  MOVE L-FORM OPEN TO WAREA  IIXX 49481018
         LA    R1,DOPEN                                            IIXX 49484018
         OPEN  (DCB,(INPUT)),MF=(E,(1))                            IIXX 49487018
OPENOK   EQU   X'10'                                               IIXX 49490018
         TM    DCBOFLGS,OPENOK                                     IIXX 49493018
         BZ    OPENNG                                              IIXX 49496018
         MVC   DREAD(READSIZE),READSTRT      MOVE L-FORM TO WAREA  IIXX 49499018
         LA    R2,DCB                        ADDRS OF JCL DCB      IIXX 49502018
NEXT     EQU   *                             WORKAREA ADDR FOR RCD IIXX 49505018
READJCL  EQU   *                                                   IIXX 49508018
         READ  DREAD,SF,(R2),DSB,,,MF=E      READ A RECORD         IIXX 49511018
         CHECK DREAD                                               IIXX 49514018
         CLI   DSBFF,X'FF'                 Q. DATA SET BLOCK       IIXX 49517018
         BE    READQMPA                                            IIXX 49520018
         CLC   SMBNEXT(4),HEXZERO                                  IIXX 49523018
         BE    JCLEOD                                              IIXX 49526018
         B     NEXT                                                IIXX 49529018
READQMPA EQU   *                                                   IIXX 49532018
         MVC   QMPA(32),QMNAM           COPY QMPA                  IIXX 49535018
         LA    R1,QMPA                                             IIXX 49538018
         LA    R15,QMPCA                ADDRS OF PARAMETERS        IIXX 49541018
         ST    R15,QMPNTR               PUT INTO POINTER           IIXX 49544018
         MVI   QMPNTR,1                 READ ONE RECORD            IIXX 49547018
         MVC   QMPEX(3),JFCBTTRZ             TTR FOR JFCB          IIXX 49550018
         MVI   QMPEX+3,0                     XERO LAST BYTE        IIXX 49553018
         MVI   QMPOP,QMREAD                  SET UP TO READ        IIXX 49556018
         LA    R15,LOCJFCB                   USE AVAILABLE SPACE   IIXX 49559018
         ST    R15,QMPCA                     STORE IN 'Q'          IIXX 49562018
         L     R15,IEFQMRWA                  GET R/W ADDRESS       IIXX 49565018
         BALR  R14,R15                       GO TO READ            IIXX 49568018
         LTR   R15,R15                     Q.READ OK               IIXX 49571018
         BZ    RJFCBOK                       YES                   IIXX 49574018
         B     NEXT                                                IIXX 49577018
RJFCBOK  EQU   *                                                   IIXX 49580018
         MVC   CAMLIST(LCAM),CAM             SET UP SCRATCH        IIXX 49583018
         LA    R15,VOLIST                    LOCATION OF VOL LIST  IIXX 49586018
         ST    R15,CAMLIST+12                PLACE INTO FIELD      IIXX 49589018
         LA    R15,LOCJFCB                   LOCATION OF DDNAME    IIXX 49592018
         USING JFCB,R15                                            IIXX 49595018
         ST    R15,CAMLIST+4                 PLACE INTO FIELD      IIXX 49598018
         SR    R1,R1                         ZERO REGISTER         IIXX 49601018
         IC    R1,JFCBNVOL                   GET NO. OF VOLUMES    IIXX 49604018
         STH   R1,VOLIST                     PLACE INTO FIELD      IIXX 49607018
         MVC   VOLSER(6),JFCBVOLS            GET VOL SERIAL NUMBER IIXX 49610018
         DROP  R15                                                 IIXX 49613018
         LH    R15,UCB                       GET UCB ADDRESS       IIXX 49616018
         MVC   VOLTYP(4),UCBTYPE(R15)        DEVICE TYPE           IIXX 49619018
         XC    VOLCODE(2),VOLCODE            ZERO FOR DISK         IIXX 49622018
         SR    R0,R0                         NO UCB                IIXX 49625018
         SCRATCH CAMLIST                     ADDRESS OF PARMLIST   IIXX 49628018
         B     NEXT                          CONTINUE              IIXX 49631018
JCLEOD   EQU   *                                                   IIXX 49634018
         LA    R1,ADWORKDS                   ADDRESS OF WORK DS    IIXX 49637018
         MVI   ADWORKDS,X'80'                SET LAST DCB BIT      IIXX 49640018
         CLOSE MF=(E,(1))                    CLOSE WORK DATA SET   IIXX 49643018
OPENNG   EQU   *                                                   IIXX 49646018
         DELETE EP=IEFQMRAW                                        IIXX 49649018
         L     R0,FREELENG                   LENGTH TO FREE        IIXX 49652018
         L     R1,FREELIST                   AREA TO FREE          IIXX 49655018
         FREEMAIN R,LV=(0),A=(1)                                   IIXX 49658018
CONT     EQU   *                                                   IIXX 49661018
         LR    R1,R7                                               IIXX 49664018
         MVI   QMPOP,QMDELE             SET CODE FOR 'DELETE'           49700016
         L     R15,SD79QDEL             LOAD ADDR OF QMGR DELETE RTN    50400016
         BALR  R14,R15                  LINK TO IT                      51100016
         LTR   R15,R15                  CHECK RETURN CODE FROM QMGR     51800016
         BC    8,SD79RETN               0  MEANS NORMAL DELETION        52500016
         MVI   PARWORK2,IOERROR         NON-0  MEANS ERROR IN QMGR      53200016
*                                        DELETE FUNCTION.  INDICATE     53900016
         WTO   'IKA044I I/O ERR,GFX',ROUTCDE=2,DESC=4              IIXX 54900018
*                                                                    *  57400016
***                                                                ***  58100016
***                                                                ***  58800016
*        ON RETURN, INDICATE TO  IEFSD082  THAT ENTRY TO IT          *  59500016
*        IS FROM THIS ROUTINE,  AND EXIT TO  IEFSD082                *  60200016
***                                                                ***  60900016
SD79RETN L     R8,SD79TO82              LOAD INDICATION INTO REGISTER   61600016
         L     R15,SD79OUT              LOAD EXIT ADDRESS               62300016
         LR    R1,R6                    RESTORE INPUT REGISTER          63000016
         BALR  R14,R15             *****     EXIT     *****             63700016
*                                                                    *  64400016
FREEIOB  L     R1,QMEIA            ADDR ECB/IOB                    IIXX 64500018
         SH    R1,H4               ADDR FIRST WORD OF ECB/IOB      IIXX 64600018
         L     R0,0(R1)            SUBPOOL AND LENGTH              IIXX 64700018
         FREEMAIN  R,LV=(0),A=(1)   FREE ECB/IOB                   IIXX 64800018
         B     SD79RETN            OUT                             IIXX 64900018
**********************************************************************  65100016
*                                                                    *  65800016
**********************************************************************  66500016
*                                                                    *  67200016
***                                                                ***  67900016
*        CONSTANTS AND DSECTS                                        *  68600016
***                                                                ***  69300016
*                                                                    *  70000016
         DS    0F                                                       70700016
SD79TO82 DC    CL4'SD79'                                                71400016
SD79OUT  DC    V(IKASD082)              EXIT ADDRESS                    72100016
SD79QDEL DC    V(IEFQDELE)              ADDR OF QMGR DELETE RTN         72800016
H4       DC    H'4'                                                IIXX 73100018
LWORKS   DC    A(GETMAIN)                                          IIXX 73110018
HEXZERO  DC    F'00'                                               IIXX 73120018
         SPACE 2                                                        73121000
*********************************************************************** 73122000
*                                                                       73123000
*        MAINTENANCE AREA                                        A33564 73124000
*                                                                       73125000
*********************************************************************** 73126000
PATCH    DC    3F'0'                                             A33564 73127000
         SPACE 2                                                        73128000
CAM      CAMLST  SCRATCH,0,,0,,OVRD          CTLG MNGMNT CONS.     IIXX 73130018
LCAM     EQU   *-CAM                                               IIXX 73140018
SMBDCBST EQU   *                                                   IIXX 73150018
SMBDCB   DCB   BLKSIZE=176,DDNAME=GJPXXX,DSORG=PS,MACRF=R,RECFM=FBA,   *73160018
               SYNAD=JCLEOD,EODAD=JCLEOD                           IIXX 73170018
SMBDCBEN EQU   *                                                   IIXX 73180018
DCBSIZE  EQU   SMBDCBEN-SMBDCBST                                   IIXX 73190018
OPENSTRT EQU   *                                                   IIXX 73200018
SMBOPEN  OPEN  (SMBDCB,INPUT),MF=L                                 IIXX 73210018
OPENEND  EQU   *                                                   IIXX 73220018
OPENSIZE EQU   OPENEND-OPENSTRT                                    IIXX 73230018
READSTRT EQU   *                                                   IIXX 73240018
         READ  JCLDECB,SF,,,176,MF=L                               IIXX 73250018
READEND  EQU   *                                                   IIXX 73260018
READSIZE EQU   READEND-READSTRT                                    IIXX 73270018
CLOSESTR EQU   *                                                   IIXX 73280018
         CLOSE (SMBDCB,),MF=L                                      IIXX 73290018
CLOSEEND EQU   *                                                   IIXX 73300018
CLOSESZE EQU   CLOSEEND-CLOSESTR                                   IIXX 73310018
*                                                                    *  73500016
**********************************************************************  74200016
*                                                                    *  74900016
         EJECT                                                          75400016
PARLIST  DSECT                                                          75900016
PARCSCB  DS    A                        CSCB POINTER                    76400016
PAROCT   DS    A                        OCT POINTER                     76900016
PARCOCT  DS    A                        OCT CURRENT ENTRY RCD POINTER   77400016
PARECBL  DS    A                        ECB LIST POINTER                77900016
PARQMPAR DS    A                        QMPA POINTER                    78400016
PARSMB   DS    A                        SMB INPUT AREA                  78900016
GPAROCT  DS    A                        OCT POINTER                     79400016
GPARABND DS    A                        ABEND HOOK POINTER              79900016
GPARCANC DS    A                        CANCEL KEY ROUTINE POINTER      80400016
PARWORK2 EQU   PARQMPAR                                                 80900016
*                                                                    *  82600016
**********************************************************************  83300016
         EJECT                                                          84000016
**********************************************************************  84700016
         IEFQMNGR                                                       85400016
**********************************************************************  86100016
         EJECT                                                          86110018
JFCB     DSECT                                                     IIXX 86120018
         IEFJFCBN                                                  IIXX 86130018
         EJECT                                                          86140018
         DCBD  DSORG=PS                                            IIXX 86150018
DCBE     EQU   *                                                   IIXX 86160018
LDCB     EQU   DCBE-IHADCB                                         IIXX 86170018
         EJECT                                                          86180018
WORKAREA DSECT                                                     IIXX 86190018
FREELIST DS    1F                                                  IIXX 86200018
FREELENG DS    1F                                                  IIXX 86210018
IEFQMRWA DS    1F                                                  IIXX 86220018
ADWORKDS DS    A(DCB)                                              IIXX 86230018
*                                                                  IIXX 86240018
**       DESCRIPTION OF THE DSB                                    IIXX 86250018
*                                                                  IIXX 86260018
DSB      EQU   *                                                   IIXX 86270018
SMBNEXT  EQU   DSB+4                                               IIXX 86280018
         DS    CL14                                                IIXX 86290018
DSBFF    DS    CL1                                                 IIXX 86300018
         DS    CL1                                                 IIXX 86310018
DSBTIOT  DS    CL4                                                 IIXX 86320018
DSBDDNAM DS    CL8                                                 IIXX 86330018
JFCBTTRZ DS    F                                                   IIXX 86340018
         DS    H                                                   IIXX 86350018
UCB      DS    H                                                   IIXX 86360018
LDSBTIOT EQU   20                                                  IIXX 86370018
         DS    XL(140)                                             IIXX 86380018
*                                                                  IIXX 86390018
**       DESCRIPTION OF A QMPA-IOB                                 IIXX 86400018
*                                                                  IIXX 86410018
QMPA     DS    176CL1                                              IIXX 86420018
QMPNTR   EQU   QMPA+32                                             IIXX 86430018
QMECBIOB EQU   QMPA+44                                             IIXX 86440018
QMPCA    EQU   QMPA+36                                             IIXX 86450018
QMPEX    EQU   QMPA+40                                             IIXX 86460018
DCB      DS    XL(LDCB)                                            IIXX 86470018
*                                                                  IIXX 86480018
**       DELETE WORK AREA                                          IIXX 86490018
*                                                                  IIXX 86500018
CAMLIST  DS    XL(LCAM)                                            IIXX 86510018
LOCJFCB  DS    XL(JFCBLGTH)                                        IIXX 86520018
VOLIST   DS    XL2                                                 IIXX 86530018
VOLTYP   DS    XL4                                                 IIXX 86540018
VOLSER   DS    XL6                                                 IIXX 86550018
VOLCODE  DS    XL2                                                 IIXX 86560018
         DS    0F                                                  IIXX 86570018
DOPEN    DS    XL(OPENSIZE)                                        IIXX 86580018
DREAD    DS    XL(READSIZE)                                        IIXX 86590018
         DS    0D                                                  IIXX 86600018
WRKAREAL EQU   *                                                   IIXX 86610018
GETMAIN  EQU   WRKAREAL-WORKAREA                                   IIXX 86620018
CLEAR1   EQU   GETMAIN/255                                         IIXX 86630018
CLEAR2   EQU   GETMAIN-(CLEAR1*255)                                IIXX 86640018
         END                                                            86800016
