         TITLE 'IKASD081 - VMS SYSOUT WTR CLASSNAME SET-UP'             00100016
IKASD081 CSECT                                                          00200016
*0802,306000,318950                                                BH0D 00250017
*2453,208000,253200-258800,290000,319380-319420,336000-342000,     CIB0 00260018
*     644000,648000,650600                                         CIB0 00270018
*2453,281000,318160,318950,319240,330600,793200,846200             IIXX 00280018
         SPACE 2                                                        00300016
**********************************************************************  00600016
*                                                                    *  00800016
*TITLE-- IEFSD081 - SYSTEM OUTPUT WRITER                             *  01000016
*                   CLASSNAME SET-UP ROUTINE                         *  01200016
*                                                                    *  01400016
* CHART ID              -DB                                             01460016
*                                                                       01520016
*STATUS -- CHANGEL LEVEL 000                                         *  01600016
*                                                                    *  01800016
*FUNCTION/OPERATION--THE ROUTINE IS ENTERED INITIALLY FROM           *  02000016
*   IEFSD080 IN RESPONSE TO A 'START WTR' COMMAND  OR  FROM          *  02200016
*   THE SYSOUT WRITER 'COMMAND' MODULE IEFSD083 IN RESPONSE TO A     *  02400016
*   'MODIFY' COMMAND.  IT GETS MAIN STORAGE FOR, AND SETS UP A       *  02600016
*   LIST OF ECB POINTERS AND CORRESPONDING ECB AND QUEUE MANAGER     *  02800016
*   COMMUNICATION ELEMENTS, ACCORDING TO THE SYSOUT CLASSES INDI-    *  03000016
*   CATED IN THE COMMAND SCHEDULING CHAIN BLOCK (CSCB):              *  03200016
*   FOR  N  CLASSES  (N NEVER GREATER THAN 8), N+1  ECB PTRS AND     *  03400016
*   N  8-BYTE ELEMENTS ARE SET UP IN (CONTIGUOUS) GOT CORE, AS       *  03600016
*   SHOWN--                                                          *  03800016
*              *********                                             *  04000016
*              *ECB PTR*  (FIRST ONE POINTS TO ECB IN CSCB)          *  04200016
*              *********                                             *  04400016
*              *ECB PTR******                                        *  04600016
*              *********     *    ********************************** *  04800016
*              *ECB PTR*****  *****               *CLASS*   LINK   * *  05000016
*              *********    *     *      ECB      *NAME *   FIELD  * *  05200016
*              *   .   *     *    ********************************** *  05400016
*              *   .   *      *****               *CLASS*   LINK   * *  05600016
*              *   .   *          *      ECB      *NAME *   FIELD  * *  05800016
*              *   .   *          ********************************** *  06000016
*              *********          *                 .              * *  06200016
*              *ECB PTR****       *                 .              * *  06400016
*              *********   *      *                 .              * *  06600016
*                           *     *                 .              * *  06800016
*                            *    ********************************** *  07000016
*                             *****               *CLASS*   LINK   * *  07200016
*                                 *      ECB      *NAME *   FIELD  * *  07400016
*                                 ********************************** *  07600016
*                                                                    *  07800016
*   ECB'S  & PTRS TAKE UP 4 BYTES, CLASSNAMES (CONVERTED TO QUEUE    *  08000016
*   MANAGER CODES 3 THROUGH 38) 1 BYTE, LINKFIELDS 3 BYTES, EACH.    *  08200016
*   THE CLASSNAME ECB'S ARE INITIALIZED AS POSTED.                   *  08400016
*                                                                    *  08600016
*ENTRY POINT--                                                       *  08800016
*        IEFSD081 - EITHER FROM  IEFSD080(INITIALIZATION RTN) OR     *  09000016
*   FROM IEFSD083 (COMMAND ROUTINE)                                  *  09200016
*                                                                    *  09400016
*INPUT--THIS ROUTINE RECEIVES IN REGISTER 1 A PTR TO A 6-WORD PARAM- *  09600016
*   ETER LIST, OF WHICH ONLY THE FIRST WORD (PTR TO CSCB) IS USED    *  09800016
*                                                                    *  10000016
*OUTPUT--THE ROUTINE ADDS TO THE PARAMETER LIST A PTR TO THE ECB LIST*  10200016
*   WHICH IT CONSTRUCTS.  IT PASSES THE ADDRESS OF THAT LIST AS      *  10400016
*   RECEIVED, IN REG. 1.  THE 6 WDS OF THE LIST   CONTAIN, IN ORDER -*  10600016
*                             CSCB PTR,                              *  10800016
*                             PTR TO OUTPUT DCB,                     *  11000016
*                             WD OF BLANKS,                          *  11200016
*                             PTR TO ECB LIST,                       *  11400016
*                             NOTHING,                               *  11600016
*                             NOTHING.                               *  11800016
*                                                                    *  12000016
*EXTERNAL ROUTINES--NONE                                             *  12200016
*                                                                    *  12400016
*EXIT--UNCONDITIONALLY TO                                            *  12600016
*        IEFSD082 - THE MAINLINE LOGIC PROCESSING ROUTINE OF THE     *  12800016
*   SYSOUT WRITER (OR TO A MODULE WHICH USES  XCTL  TO  TRANSFER     *  13000016
*   CONTROL TO IEFSD082).                                            *  13200016
*                                                                    *  13400016
*TABLES/WORK AREAS--                                                 *  13600016
*   THE CSCB CONTAINS 8 BYTES OF CLASSNAME INFORMATION (IN EBCDIC)   *  13800016
*   WHICH ARE MOVED INTO TWO UNUSED WORDS OF THE PARAMETER LIST      *  14000016
*   THE ECB LIST IS PRECEDED BY 12 BYTES -- 4 BYTES FOR LIST LENGTH, *  14200016
*   4 BYTES FOR TTR-STORAGE, 4 BYTES FOR SWITCHES.                   *  14400016
*                                                                    *  14600016
*ATTRIBUTES--THIS ROUTINE IS REENTRANT                               *  14800016
*                                                                    *  15000016
*NOTES--THE FOLLOWING SYSTEM MACROS ARE USED                         *  15200016
*        GETMAIN,IEECHAIN (DESCRIBES CSCB)                           *  15400016
*                                                                    *  15600016
**********************************************************************  15800016
*        ESSENTIAL EQUATES                                           *  16000016
**********************************************************************  16200016
RPAR0    EQU   0                                                   EXTR 16300019
R0       EQU   0                                                        16400016
RPAR1    EQU   1                                                   EXTR 16500019
R1       EQU   1                                                        16600016
R2       EQU   2                                                        16800016
R3       EQU   3                                                        17000016
R4       EQU   4                                                        17200016
R5       EQU   5                                                        17400016
R6       EQU   6                                                        17600016
R7       EQU   7                                                        17800016
R8       EQU   8                                                        18000016
R9       EQU   9                                                        18200016
R10      EQU   10                                                       18400016
R11      EQU   11                                                       18600016
R12      EQU   12                                                       18800016
R13      EQU   13                                                       19000016
R14      EQU   14                                                       19200016
R15      EQU   15                                                       19400016
*                                                                    *  19600016
UNRWR    EQU   32                       UNIT RECORD WRITER SWITCH       19800016
PUNSH    EQU   64                       PUNCH              SWITCH       20000016
FTFTWO   EQU   128                      1442               SWITCH       20200016
COMMA    EQU   X'6B'                                                    20400016
KYWDER   EQU   X'BB'                                                    20600016
ONE      EQU   1                        EQUATE                     CIB0 20700018
TWO      EQU   2                        EQUATE                          20800018
MFT      EQU   X'02'                                                    20900016
**********************************************************************  21000016
         EJECT                                                          21200016
**********************************************************************  21400016
*        IEFSD081                       THE PROGRAM                  *  21600016
**********************************************************************  21800016
***                                                                ***  22000016
*        ESTABLISH BASE                                              *  22200016
***                                                                ***  22400016
         BALR  R9,0                                                     22600016
         USING *,R9                                                     22800016
***                                                                ***  23000016
*        MOVE CLASSNAME INDICATION FROM CSCB TO WORK AREA IN PARLIST *  23200016
***                                                                ***  23400016
         LR    R6,R1                    SAVE INPUT REG                  23600016
         USING PARLIST,R6               ADDRESSABILITY FOR PARLIST      23800016
*                                                                  EXTR 23809019
*        GETMAIN FOR EXTRACT MACRO WORK AREA                       EXTR 23818019
*                                                                  EXTR 23827019
         LA    RPAR0,WORKSIZE           SIZE OF GETMAIN            EXTR 23836019
         GETMAIN R,LV=(0)                                          EXTR 23845019
*                                                                  EXTR 23854019
*        ADDRESSABILITY FOR EXTRACT MACRO WORK AREA                EXTR 23863019
*                                                                  EXTR 23872019
         LR    R2,RPAR1                 SET XR2 FOR BASE           EXTR 23881019
         USING EXTRCTWK,R2                                         EXTR 23890019
         MVC   EXTRCTMC(EXTRCTSZ),EXTRCT     MAKE MACRO REENTRANT  EXTR 23899019
         LA    RPAR1,EXTRCTMC           ADDRS OF LIST FORMAT       EXTR 23908019
         LA    R5,ANSWAREA              ADDRS OF ANSWER AREA       EXTR 23917019
         EXTRACT (R5),FIELDS=COMM,MF=(E,(1)) EXECUTE MACRO         EXTR 23926019
         L     R5,ANSWAREA              PTR TO COMM.PARM.LIST      EXTR 23935019
         LR    RPAR1,R2                 ADDRS OF FREEMAIN          EXTR 23944019
         LA    RPAR0,WORKSIZE           SIZE OF FREEMAIN           EXTR 23953019
         FREEMAIN R,LV=(0),A=(1)        FREE MACRO WORKAREA        EXTR 23962019
         DROP  R2                                                  EXTR 23971019
         MVC   SPLCIB(4),4(R5)          POINTER TO CIB             EXTR 23980019
         L     R2,PARCSCB               GET CSCB ADDRESS                24000016
         USING CHAINBLK,R2              ADDRESSABILITY FOR CSCB         24200016
***                                                                     24400016
*        ROUTINE LOOKS AT COMMAND INPUT BUFFER AND PLACES INFORMATION   24600016
*        INTO THE OCT HEADER RECORD BY KEYWORD                          24800016
***                                                                     25000016
         L     R4,SPLCIB                ADDRESS OF CIB                  25240016
         LR    R11,R4                   SAVE CIB POINTER           CIB0 25300018
         USING CIBD,R11                 SET ADDRESSABILITY FOR CIB CIB0 25360018
         CLC   CIBDATLN(TWO),SD81ZERO   Q. PARAMETERS ENTERED      CIB0 25420018
         BE    FREECIB                  FREE CIB IF NONE           CIB0 25480018
         LA    R4,CIBDATA               SET POINTER TO INPUT PARMS CIB0 25540018
         LA    R3,CIBDATA+ONE           SET POSITION COUNTER       CIB0 25600018
         AH    R11,CIBDATLN             SET END OF CIB             CIB0 25660018
         LA    R11,CIBDATA-CIBNEXT(R11)     FOR COMPARISON         CIB0 25720018
         DROP  R11                                                 CIB0 25780018
INPUTCHK CR    R3,R11                   Q. PAST CIB LIMIT          CIB0 25840018
         BH    FREECIB                  COUNTER POINTS PAST CIB         25960016
         TM    0(R4),X'C0'            Q.IS THIS A CHARACTER             26040016
         BC    12,NOTCHAR               NO                              26120016
         TM    0(R4),X'30'            Q.IS THIS NUMERIC                 26200016
         BO    NOTCHAR                  YES                             26280016
         LA    R5,KEYWORDT              KEYWORD TABLE ADDRESS           26400016
CMPLOOP  LH    R10,0(R5)                SIZE OF COMPARE                 26600016
         BCTR  R10,R0                   REDUCE BY ONE FOR EXECUTE       26800016
         EX    R10,COMPARE              COMPARE TO KEYWORD              27000016
         BE    KEYFIND                  A MATCH IS FOUND                27200016
         LA    R5,ENTRYLNG(R5)          BUMP TO NEXT KEYWORD ENTRY      27400016
         CLI   0(R5),X'FF'              END OF TABLE                    27600016
         BNE   CMPLOOP                  NO,CHECK NEXT KEYWORD           27800016
         MVC   BADKEY+16(4),BLANK       CLEAR KEYWD. AREA OF MSG.       27900016
         MVC   BADKEY+16(4),0(R4)       MOVE BAD KEY INTO MESSAGE       28000016
         SR    R0,R0               CLEAR REG                       IIXX 28040018
         IC    R0,CHUCMP           LOAD CONSOLE ID IN REG 0        IIXX 28080018
BADKEY   WTO   'IKA013I XXXX BAD KEY',DESC=5,                      IIXXR28120018
               MCSFLAG=REG0                                        IIXX 28160018
         B     CLEANUP                                                  28200016
KEYFIND  AH    R4,0(R5)       BUMP PTR TO FLO IN CIB BY KEYWORD LNGTH   28400016
         AH    R3,0(R5)                 ADD KEYSIZE TO COUNTER          28500016
         L     R7,PARDCB      ADDRESS OF OCT HEADER RECORD              28600016
         AH    R7,OCTDISPD(R5)         POINT TO POS. IN OCT WHERE INFO. 28700016
*                                       GOES                            28800016
         SR    R10,R10                  SET R10 TO ZERO                 28840016
COMLOOP  CLI   1(R4),COMMA             Q. IS THIS A COMMA               28880016
         BE    GETNAT                  A. YES                           28920016
         LA    R3,1(R3)                 INCREMENT COUNTER               28960016
         CR    R3,R11                   Q. PAST CIB LIMIT          CIB0 29000018
         BH    GETNAT                  A. YES                           29040016
         LA    R10,1(R10)               INCREMENT                       29080016
         LA    R4,1(R4)                                                 29120016
         CH    R10,INFOSZED(R5)        Q. DID WE EXCEED PARM, SIZE      29160016
         BH    BADPAR                  A. YES                           29200016
         B     COMLOOP                 A. NO                            29240016
*                                                                       29280016
GETNAT   EQU   *                                                        29320016
         LTR   R10,R10                 Q. IS PARM. LENGTH ZERO          29360016
         BZ    BADPAR                  A. YES                           29400016
         LR    R15,R10                  SAVE LENGTH                     29440016
         LA    R12,INFOTYPD(R5)         LOAD ADDRESS OF PARAM.INFO.TYPE 29480016
         CLI   1(R12),X'C0'            Q. DOES IT INDICATE ALPHA        29510016
         BE    TESTCHAR                A. YES                           29540016
         CLI   1(R12),X'F0'            Q. DOES IT INDICATE NUMERIC      29570016
         BE    TESTNUM                 A. YES                           29600016
         CLI   1(R12),X'CF'            Q. DOES IT INDICATE ALPHA + NUM. 29630016
         BE    MIXED                   A. YES                           29660016
         CLI   1(R12),X'D6'            Q. DOES IT INDICATE CLASS A-O    29690016
         BE    CLASS                   A. YES                           29720016
*                                                                       29840016
RESTORE  EQU   *                                                        29880016
         LR    R10,R15                  RESTORE LENGTH                  29920016
PAD      CH    R15,INFOSZED(R5)        Q.IS LENGTH EQU MAX.SIZE         29960016
         BE    MOVTOCT                 A.YES                            30000016
         BH    BADPAR                                                   30040016
         MVI   0(R7),X'F0'              PAD OCT FIELD WITH HIGH ZEROS   30080016
         LA    R7,1(R7)                 BUMP REGISTERS                  30120016
         LA    R15,1(R15)                                               30160016
         B     PAD                                                      30200016
*                                                                       30240016
MOVTOCT  EQU   *                                                        30280016
         BCTR  R10,R0                   REDUCE FOR EXECUTE              30320016
         EX    R10,MOVEINFO             MOVE PARAMETER TO OCT           30360016
         LA    R10,2(R10)               INCREMENT LENGTH FIELD          30400016
         AR    R3,R10                   ADD TO COUNTER                  30440016
         AR    R4,R10                   POINT PAST COMMA                30480016
         CLI   1(R12),X'F0'             Q. NUMERIC VALUE           BH0D 30530017
         BNE   INPUTCHK                 NO                         BH0D 30580017
         CLI   2(R5),C'R'               Q. PRIORITY OR REGION      BH0D 30630017
         BE    INPUTCHK                 NO TEST OF REGION          BH0D 30680017
         L     R7,PARDCB                ADDR OF OCT HEADER RECORD  BH0D 30730017
         AH    R7,OCTDISPD(R5)          ADD DISPLACEMENT FOR LOCATIBH0D 30780017
         CLC   0(2,R7),VALPRI           Q. PRIORITY LESS THAN 14   BH0D 30830017
         BL    INPUTCHK                 YES, CONTINUE              BH0D 30880017
         B     SPECIAL                  NO, INVALID PARAMETER      BH0D 30930017
NOTCHAR  CLI   0(R4),COMMA            Q. IS IT A COMMA                  31000016
         BNE   INPUTERR                 NO                              31400016
         LA    R4,1(R4)                 INCREMENT PAST COMMA            31600016
         LA    R3,1(R3)                 INCREMENT COUNTER               31700016
         B     INPUTCHK                 CHECK NEXT CHARACTER            31800016
BADPAR   EQU   *                                                        31802016
         MVC   BADIMP+16(4),BLANK       BLANK OUT KEYWORD AREA OF MSG   31804016
         LA    R12,BADIMP               ADDRESS OF MSG.                 31806016
         LH    R10,0(R5)                KEYWORD LENGTH                  31808016
         BCTR  R10,R0                   REDUCE FOR EXECUTE              31810016
         EX    R10,MVEBAD               MOVE KEYWORD TO MSG.            31812016
*                                                                       31814016
         SR    R0,R0               CLEAR REG                       IIXX 31814818
         IC    R0,CHUCMP           CONSOLE ID                      IIXX 31815618
BADIMP   WTO   'IKA040I XXXX PARM LNG INVALID',DESC=5,             IIXXR31816418
               MCSFLAG=REG0                                        IIXX 31817218
*                                                                       31818016
         B     CLEANUP                                                  31820016
* * *                                                                   31822016
TESTCHAR TM    0(R4),X'C0'             Q. IS THIS ALPHA                 31824016
         BC    12,NOTALPHA             A. NO - GO TO ERROR MSG.         31826016
         TM    0(R4),X'30'             Q. IS IT NUMERIC                 31826616
         BO    NOTALPHA                A. YES - GO TO ERROR MSG.        31827216
         BCTR  R4,R0                    POINT TO PRECEEDING CHAR.       31828016
         BCTR  R3,R0                    REDUCE COUNTER                  31830016
         BCTR  R10,R0                   REDUCE LENGTH                   31832016
         LTR   R10,R10                 Q. IS LENGTH ZERO                31834016
         BZ    RESTORE                 A. YES                           31836016
         B     TESTCHAR                                                 31838016
*                                                                       31840016
TESTNUM  TM    0(R4),X'F0'             Q. IS THIS NUMERIC               31842016
         BC    12,NOTNUM               A. NO - GO TO ERROR MSG.         31844016
         BCTR  R4,R0                    POINT TO PRECEEDING CHAR.       31846016
         BCTR  R3,R0                    REDUCE COUNTER                  31848016
         BCTR  R10,R0                   REDUCE LENGTH                   31850016
         LTR   R10,R10                 Q. IS LENGTH ZERO                31852016
         BZ    RESTORE                 A. YES                           31854016
         B     TESTNUM                                                  31856016
*                                                                       31858016
MIXED    TM    0(R4),X'C0'             Q. IS THIS ALPHA OR NUMERIC      31861016
         BE    SPECIAL                 Q. NO - GO TO ERROR MSG.         31864016
MIXOK    BCTR  R4,R0                    POINT TO PRECEEDING CHAR.       31868016
         BCTR  R3,R0                    REDUCE COUNTER                  31870016
         BCTR  R10,R0                   REDUCE LENGTH                   31872016
         LTR   R10,R10                 Q. IS LENGTH ZERO                31874016
         BZ    RESTORE                 A. YES                           31876016
         B     MIXED                                                    31878016
*                                                                       31880016
CLASS    CLI   0(R4),X'D6'             Q. IS THIS A THRU O              31880216
         BH    BADCLASS                A. NO - GO TO ERROR MSG.         31880416
         BCTR  R4,R0                    POINT TO PRECEEDING CHAR.       31880616
         BCTR  R3,R0                    REDUCE COUNTER                  31880816
         BCTR  R10,R0                   REDUCE LENGTH                   31881016
         LTR   R10,R10                 Q. IS LENGTH ZERO                31881216
         BZ    RESTORE                 A. YES                           31881416
         B     CLASS                                                    31881616
*                                                                       31881816
SPECIAL  MVC   SPECHAR+16(4),BLANK                                      31882816
         LA    R12,SPECHAR              ADDRESS OF MSG.                 31884016
         LH    R10,0(R5)                KEYWORD LENGTH                  31886016
         BCTR  R10,R0                   REDUCE FOR EXECUTE              31888016
         EX    R10,MVEBAD               MOVE KEYWORD TO MSG.            31890016
*                                                                       31892016
         SR    R0,R0               CLEAR REG                       IIXX 31893018
         IC    R0,CHUCMP           CONSOLE ID                      IIXX 31894018
SPECHAR  WTO   'IKA042I XXXX INVALID',DESC=5,                      IIXXR31895018
               MCSFLAG=REG0                                        IIXX 31896018
*                                                                       31898016
         B     CLEANUP                                                  31900016
*                                                                       31902016
NOTNUM   MVC   PARMER+26(8),CNUM        BUILD ERROR MSG.                31903016
         B     CONTERM                                                  31904016
*                                                                       31905016
BADCLASS MVC   PARMER+26(8),CATHRUO     BUILD ERROR MSG                 31906016
         B     CONTERM                                                  31907016
*                                                                       31908016
NOTALPHA MVC   PARMER+26(8),CALPHA      BUILD ERROR MSG                 31910016
CONTERM  MVC   PARMER+21(4),BLANK       BLANK OUT KEYWORD AREA OF MSG.  31912016
         LA    R12,PARMER               ADDRESS OF MSG.                 31914016
         LH    R10,0(R5)                KEYWORD LENGTH                  31916016
         BCTR  R10,R0                   REDUCE FOR EXECUTE              31918016
         EX    R10,MVEBAD2              MOVE KEYWORD TO MSG             31920016
*                                                                       31922016
         SR    R0,R0               CLEAR REG                       IIXX 31922818
         IC    R0,CHUCMP           CONSOLE ID                      IIXX 31923618
PARMER   WTO   'IKA041I MAKE XXXX YYYYYYYY',DESC=5,                IIXXR31924418
               MCSFLAG=REG0                                        IIXX 31925218
*                                                                       31926016
* *                                                                     31928016
*                                                                       31930016
CLEANUP  XC    PARWORK2(4),PARWORK2     CLEAR WORD IN PARMLIST          31932016
         MVI   PARWORK2,KYWDER          MOVE IN ERROR CODE (FOR 83)     31934016
         L     R1,SPLCIB                ADDRESS OF CIB                  31936016
         LA    R1,0(,R1)                ZERO HIGH ORDER BYTE       CIB0 31938018
         LA    R0,SPLCIB                SET ORIGIN POINTER         CIB0 31940018
         QEDIT ORIGIN=(0),BLOCK=(1)     FREE CIB BLOCK             CIB0 31942018
         XC     SPLCIB(4),SPLCIB        CLEAR POINTER TO CIB            31944016
         LR    R1,R6                    RESTORE ADDRESS OF PARLIST      31946016
         L     R15,SD81CLN              ****************                31948016
         BALR  R14,R15                  ** EXIT TO 83 **                31950016
*                                       ****************                31952016
INPUTERR EQU   *                                                        32000016
***                                                                     32400016
*        FREE UP CIB CORE AND ZERO SECOND WORD OF SPL                   32600016
***                                                                     32800016
FREECIB  EQU   *                                                        33000016
* CONVERT THE CLASS DESIGNATION TO AN INTERNAL FORMAT WHICH WILL BE     33010016
* USED IN DETERMINING THE PARTITION NUMBER FOR GJP WHEN IN THE MFT      33020016
* ENVIRONMENT. A THROUGH O BECOMES HEX 28 THROUGH 36                    33030016
         L     R12,PARDCB               OCT HEADER RCD                  33040016
         USING GFXOCTHD,R12             ADDRESSABILITY                  33050016
***                                                                IIXX 33051018
*        CHECK UNIQUENESS OF GJP SYSOUT CLASS                      IIXX 33052018
***                                                                IIXX 33053018
         CLC   OCTGSMB,OCTPRINT         Q. MSGF = PRT              IIXX 33054018
         BNE   TESTSYS                  NO, CONTINUE               IIXX 33055018
*                                                                  IIXX 33056018
         SR    R0,R0                    ZERO REGISTER,             IIXX 33057018
         IC    R0,CHUCMP                GET CONSOLE ID             IIXX 33058018
         WTO   'IKA053I MAKE MSGF UNIQUE',DESC=5,                  IIXXR33059018
               MCSFLAG=REG0                                        IIXX 33060018
         B     CLEANUP                  END                        IIXX 33061018
*                                                                  IIXX 33062018
TESTSYS  TM    OCTSYS,MFT               Q. MFT SYSTEM              IIXX 33063018
         BZ    FREECIB1                 NO,BRANCH                       33070016
         XC    PARWORK2(4),PARWORK2     ZERO WORK AREA                  33080016
         MVC   PARWORK2+3(1),OCTFTYPE   CLASS DESIGNATION               33090016
         LA    R1,39                    SET UP FOR A THRU I             33100016
         TM    PARWORK2+3,X'10'       Q.IS CLASS J THRU O               33110016
         BZ    ADDLOW                    NO,BRANCH                      33120016
         LA    R1,48                    SET UP FOR J THRU O             33130016
ADDLOW   NI    PARWORK2+3,X'0F'         SET BYTES 0 THRU 3 TO ZERO      33140016
         A     R1,PARWORK2              GET INTERNAL FORMAT NUMBER      33150016
         STC   R1,OCTCTYPE              SAVE IN OCT                     33160016
         CLI   OCTITYPE,0               Q. WAS 'CLSI=' ENTERED        S 33160916
         BE    FREECIB1                 NO, CONTINUE                  S 33161816
         MVC   PARWORK2+3(1),OCTITYPE   GET CLASS DESIGNATION         S 33162716
         LA    R1,39                    SET UP FOR A THRU I           S 33163616
         TM    PARWORK2+3,X'10'        Q. CLASS J THRU O              S 33164516
         BZ    ADDLOWI                  NO, BRANCH                    S 33165416
         LA    R1,48                    SET UP FOR J THRU O           S 33166316
ADDLOWI  NI    PARWORK2+3,X'0F'         SET BITS 0 THRU 3 ZERO        S 33167216
         A     R1,PARWORK2              GET INTERNAL FORMAT NUMBER    S 33168116
         STC   R1,OCTITYPI              SAVE IN OCT                   S 33169016
         DROP  R12                                                      33170016
FREECIB1 EQU   *                                                        33180016
         L     R1,SPLCIB                ADDRESS OF CIB                  33200016
         LA    R1,0(,R1)                ZERO HIGH ORDER BYTE       CIB0 33300018
         LR    R12,R1                   SAVE IT                         33400016
         LA    R0,SPLCIB                SET ORIGIN POINTER         CIB0 33700018
         QEDIT ORIGIN=(0),BLOCK=(1)     FREE CIB BLOCK             CIB0 34000018
         XC    SPLCIB(4),SPLCIB         CLEAR POINTER TO CIB            34300016
MOVECLSS L     R8,PARDCB                ADDRESS OF OCT HEADER RCD       34600016
         USING GFXOCTHD,R8                                              34800016
         L     R4,16(0,0)               ADDRESS OF CVT                  34810016
         USING GFXCVT,R4                                                34820016
         L     R5,CVTTCBP               PTR TO DBL WORD CONTAINING TCB  34830016
*                                       ADDRESSES (NEXT AND CURRENT)    34840016
         MVC   OCTGTCB(4),4(R5)         MOVE CURRENT TCB ADDRESS INTO   34850016
*                                       OCT HEADER                      34860016
         XC    PARWORK2(8),PARWORK2     CLEAR WORK AREA                 34900016
         MVC   PARWORK2(1),OCTGSMB      MOVE CLASS NAME TO WORK AREA    35000016
*                                        THE CLASSNAMES ARE NOW IN THE  35200016
*                                        PARAMETER LIST WORK AREA,      35400016
*                                        SUCCESSIVE AND LEFT-JUSTIFIED  35600016
*                                        THEREIN, FOLLOWED BY BLANKS    35800016
*                                        IF LESS THAN 8 CLASSNAMES      36000016
***                                                                ***  36200016
*        FIND HOW MUCH MAIN STORAGE NEEDED FOR 'ECB-LIST'            *  36400016
***                                                                ***  36600016
         LA    R4,7                     NUMBER OF POSSIBLE CLASSNAMES   36800016
*                                        PAST THE FIRST                 37000016
         SR    R5,R5                    CLEAR WORK REGISTER             37200016
SD81COMP IC    R5,PARWORK2(R4)          GET CHAR. FROM WORK AREA        37400016
         CL    R5,SD81CLAS              COMPARE FOR CLASS INDIC.        37600016
         BH    SD81GOT                  BRANCH, CHARACTER IS CLASSNAME  37800016
         BCT   R4,SD81COMP              BRANCH, CHARACTER NOT CLASSNM   38000016
*                                                                    *  38200016
SD81GOT  LR    R5,R4                    LOAD FROM INDEX REG             38400016
         SLL   R5,2                      4 X NO. OF CLASSES PAST FIRST  38600016
         LR    R7,R5                                                    38800016
         AR    R7,R5                     8 X (N-1)                      39000016
         AR    R7,R5                    12 X (N-1)                      39200016
         LA    R0,28(R7)                LOAD R7 CONT. + 28 = 12N+8+8    39400016
         LH    R10,OCTUNBR              NO. OF SYSGENED 2250'S          39600016
         SLL   R10,2                    NO.X4                           39800016
         AR    R0,R10                   ADD TO GETMAIN AREA 2250 ECB'S  40000016
         CH    R0,SD81FRTY              CHECK LENGTH FOR LESS THAN 40   40200016
         BNL   SD81GETC                 NOT LESS, GO GET                40400016
         LA    R0,40                    OTHERWISE, LOAD 40 TO GET       40600016
*                                        MINIMUM USED LATER FOR MSG     40800016
*                                        SPACE BY  IEFSD083             41000016
***                                                                ***  41200016
*        GET STORAGE FOR ECB-LIST (N+1 ECB PTRS, 8N BYTES FOR ECB'S  *  41400016
*        AND OTHER INFO, WHERE N=NO. OF CLASSNAMES INDICATED, PLUS   *  41600016
*        4 BYTES TO REMEMBER LENGTH, PLUS 12 EXTRA BYTES IF TOTAL    *  41800016
*        IS BELOW 40,  FOR POSSIBLE USE AS MSG SPACE BY  IEFSD083    *  42000016
***                                                                ***  42200016
SD81GETC GETMAIN R,LV=(0)                                               42400016
***                                                                ***  42600016
*        PREPARE ECB-LIST - ECB POINTERS WILL PRECEDE THE CORRESPOND-*  42800016
*        ING ECB-AND-LINK ELEMENTS IN THE CONTIGUOUS PIECE OF STORAGE*  43000016
*        OBTAINED ABOVE (SEE PROLOGUE FOR DIAGRAM)                   *  43200016
***                                                                ***  43400016
         ST    R0,0(R1)                 STORE LENGTH                    43600016
         L     R8,SD81PSTD              LOAD MODEL POSTED ECB           43800016
         XC    4(8,R1),4(R1)            CLEAR 8 BYTES PAST LNGTH FLD    44000016
         LA    R1,12(R1)                INCRMT PAST LNGTH AND 8 BYTES   44200016
         LA    R3,CHECB                 GET ADDR OF ECB IN CSCB         44400016
         ST    R3,0(R1)                 STORE IN 4 BYTES BEFORE         44600016
*                                        SYSOUT CLASS ECB PTRS          44800016
         LA    R1,4(R1)                 POINT R1 TO FIRST OF THESE      45000016
         AR    R5,R1                    R5 CONTAINS THAT ADDRESS        45200016
*                                        PLUS   4N-4  (N AS ABOVE)      45400016
         LA    R7,4(R7)                 R7 CONTAINS 12N-12+4 = 12N-8    45600016
         AR    R7,R10                   INCREMENT AROUND 2250 ECB PNTRS 45800016
         AR    R7,R1                     AND NOW POINTS TO LAST ECB     46000016
         LA    R4,PARWORK2(R4)          R4 NOW PTS TO LAST CLASS NAME   46200016
*                                                                       46400016
         LR    R10,R7                   PICK UP LAST ECB PTR AND        46600016
*                                        CATE LAST IN LIST OF PTRS      46800016
***                                                                ***  47000016
*        THE FOLLOWING INSTRUCTIONS INITIALIZE ECB'S AS POSTED,      *  47200016
*        STORE ECB PTRS IN LIST, AND CONVERT THE INCOMING            *  47400016
*        ALPHAMERIC CLASS NAMES TO 'NNS' AS REQUIRED BY QUEUE        *  47600016
*        MANAGER,  ACCORDING TO THE FOLLOWING PATTERNS               *  47800016
*              CLASSNAMES=  A THROUGH I   BECOME   NN= 3 THROUGH 11  *  48000016
*                           J THROUGH R   BECOME      12 THROUGH 20  *  48200016
*                           S THROUGH Z   BECOME      21 THROUGH 28  *  48400016
*                           0 THROUGH 9   BECOME      29 THROUGH 38  *  48600016
*        THESE BINARY NUMBERS WILL BE STORED AFTER EACH ECB          *  48800016
***                                                                ***  49000016
SD81STPT ST    R10,0(R5)                STORE ECB POINTER               49200016
         LA    R12,29                   29 MUST BE ADDED TO BOTTOM 4    49400016
*                                        BITS OF NUMERICS FOR CONVER-   49600016
*                                        SION                           49800016
         TM    0(R4),48                 TEST FOR  --110000  CONFIG.     50000016
*                                        WHERE BITS 0 AND 1 OF THE      50200016
*                                        CHAR. ARE ASSUMED TO BE 1 BE-  50400016
*                                        CAUSE MAST. SCHED.  PASSES ON  50600016
*                                        VALID ALPHAMERICS ONLY         50800016
         BO    SD81GETB                 BRANCH ON --11----  PATTERN     51000016
*                                        (NUMERIC  0-9)                 51200016
         LA    R12,2                    2  MUST BE ADDED TO BOTTOM 4    51400016
*                                        BITS OF ALPHA (A-J) CHAR.      51600016
*                                        FOR PROPER CONVERSION          51800016
         BZ    SD81GETB                 BRANCH ON --00----  PATTERN     52000016
*                                        (A THROUGH I).                 52200016
         LA    R12,11                   11 MUST BE ADDED TO BOTTOM      52400016
*                                        4 BITS OF ALPHA CHAR. J-R      52600016
         TM    0(R4),32                 TEST WITH 00010000  MASK        52800016
         BZ    SD81GETB                 BRANCH ON ---0----  PATTERN     53000016
*                                        (J THROUGH R).  OTHERWISE      53200016
*                                       HAVE      ---1----  PATTERN     53400016
*                                        (S THROUGH Z), FOR WHICH 19    53600016
         LA    R12,19                    MUST BE ADDED TO BOTM 4 BITS   53800016
SD81GETB IC    R11,0(R4)                GET CLASS NAME CHAR.            54000016
         N     R11,SD81000F             GET RID OF ALL EXC. BTM 4 BITS  54200016
         AR    R11,R12                  ADD PROPER NUMBER TO BOTTOM 4   54400016
         STC   R11,4(R7)      STORE CONVERTED CLASS NAME                54600016
         ST    R8,0(R7)                 STORE POSTED ECB                54800016
***                                                                ***  55000016
*        ADD TO PARAMETER LIST                                       *  55200016
***                                                                ***  55400016
         SH    R1,SD81FOUR                                              55600016
         ST    R1,PARECBL               STORE ADDR OF ECB LIST          55800016
*                                        IN PARLIST SLOT                56000016
***                                                                     56200016
*        ADD POINTERS TO 2250 ECB'S TO ECB POINTER LIST                 56400016
***                                                                     56600016
         L     R10,PARDCB               OCT HDR RECORD ADDRESS          56800016
         USING GFXOCTHD,R10                                             57000016
         LH    R11,OCTUNBR              NUMBER OF SYSGENED GJP 2250'S   57200016
         LA    R10,GFXHDSZE(R10)        BUMP TO ENTRY RECORDS           57400016
         DROP  R10                                                      57600016
         USING GFXOCTEN,R10             BASE FOR ENTRY RECORDS          57800016
ECBLOOP  LA    R5,4(R5)                 BUMP TO NEXT SLOT IN ECB LIST   58000016
         LA    R10,OCTECB               ADDRESS OF ECB IN OCT           58200016
         ST    R10,0(R5)                PUT IT INTO THE ECB LIST        58400016
         LA    R10,GFXENSZE(R10)        BUMP TO NEXT OCT ENTRY RCD      58600016
         BCT   R11,ECBLOOP              BRANCH IF MORE TO STORE         58800016
         OC    0(4,R5),SD81BT1N         BIT 0-1 LAST ECB PNTR IN LIST   59000016
SD81NEXT EQU   *                                                        60200016
**********************************************************************  60400016
*        EXIT                                                        *  60600016
**********************************************************************  60800016
         LR    R1,R6                    RESTORE ADDR OF PARLIST         61000016
         XR    R8,R8                    CLEAR IND REG USED BY IEFSD082  61200016
         L     R15,SD81EXIT             **************                  61400016
         BALR  R14,R15                  **** EXIT ****                  61600016
*                                       **************                  61800016
MOVEINFO MVC   0(0,R7),1(R4)            MOVE INPUT INFO INTO OCT        62000016
COMPARE  CLC   0(0,R4),KEYWORDD(R5)     IS THIS THE KEYWORD             62200016
MVEBAD   MVC   16(0,R12),KEYWORDD(R5)   MOVE KEYWORD TO MSG.            62240016
MVEBAD2  MVC   21(0,R12),KEYWORDD(R5)   MOVE KEYWORD TO MSG.            62280016
* * * *                                                                 62320016
         EJECT                                                          62400016
**********************************************************************  62600016
*        CONSTANTS  AND  DSECTS                                      *  62800016
**********************************************************************  63000016
         DS    0F                                                       63200016
SD81CLAS DC    X'000000C0'                                              63400016
SD81PSTD DC    X'40000000'              MODEL OF POSTED  ECB            63600016
SD81BT1N DC    X'80000000'                                              63800016
SD81000F DC    X'0000000F'                                              64000016
SD81FOUR DC    H'4'                                                     64200016
SD81ZERO DC    H'0'                     CONSTANT                   CIB0 64400018
SD81EXIT DC    V(IKASD082)                                              64600016
VALPRI   DC    C'14'                    MAXIMUM VALUE FOR PRIORITY BH0D 64900017
SD81FRTY DC    H'40'                                                    65000016
BLANK    DC    X'40404040'                                              65070016
SD81CLN  DC    V(IKASD083)                                              65080016
CALPHA   DC    C'ALPHA   '                                              65090016
CNUM     DC    C'NUMERIC '                                              65100016
CATHRUO  DC    C'A THRU O'                                              65110016
EXTRCTBG EQU   *                                                   EXTR 65112019
EXTRCT   EXTRACT ,,MF=L                 LIST FORM OF EXTRACT MACRO EXTR 65114019
EXTRCTED EQU   *                                                   EXTR 65116019
EXTRCTSZ EQU   EXTRCTED-EXTRCTBG        SIZE OF MACRO              EXTR 65118019
**********************************************************************  65120016
         EJECT                                                          65200016
KEYWORDT DS    0F                                                       65400016
ENTRYSRT EQU   *                                                        65600016
KEYSIZE  DC    X'0004'                                                  65800016
KEYWORD  DC    CL4'MSGF'                                                66000016
INFOSIZE DC    X'0001'                                                  66200016
INFOTYP  DC    X'00CF'                                                  66300016
OCTDISP  DC    AL2(OCTGSMB-GFXOCTHD)                                    66400016
ENTRYEND EQU   *                                                        66600016
         DC    X'0003'                                                  66800016
         DC    CL4'PRT'                                                 67000016
         DC    X'0001'                                                  67200016
         DC    X'00C0'                                                  67300016
         DC    AL2(OCTPRINT-GFXOCTHD)                                   67400016
         DC    X'0003'                                                  67600016
         DC    CL4'PCH'                                                 67800016
         DC    X'0001'                                                  68000016
         DC    X'00C0'                                                  68100016
         DC    AL2(OCTPUNCH-GFXOCTHD)                                   68200016
         DC    X'0004'                                                  68400016
         DC    CL4'MSGB'                                                68600016
         DC    X'0001'                                                  68800016
         DC    X'00CF'                                                  68900016
         DC    AL2(OCTBSMB-GFXOCTHD)                                    69000016
         DC    X'0004'                                                  69200016
         DC    CL4'CLSF'                                                69400016
         DC    X'0001'                                                  69600016
         DC    X'00D6'                                                  69700016
         DC    AL2(OCTFTYPE-GFXOCTHD)                                   69800016
         DC    X'0004'                                                  70000016
         DC    CL4'CLSB'                                                70200016
         DC    X'0001'                                                  70400016
         DC    X'00D6'                                                  70500016
         DC    AL2(OCTBTYPE-GFXOCTHD)                                   70600016
         DC    X'0004'                  FOUR BYTE FIELD               S 70630016
         DC    CL4'CLSI'                INITIAL PROCESSOR JOB CLASS   S 70660016
         DC    X'0001'                  INFORMATION LENGTH            S 70690016
         DC    X'00D6'                  CLASSES 'A' TO 'O'            S 70720016
         DC    AL2(OCTITYPE-GFXOCTHD)   DISPLACEMENT IN OCT           S 70750016
         DC    X'0004'                                                  70800016
         DC    CL4'PRIF'                                                71000016
         DC    X'0002'                                                  71200016
         DC    X'00F0'                                                  71300016
         DC    AL2(OCTFPRI-GFXOCTHD)                                    71400016
         DC    X'0004'                                                  71600016
         DC    CL4'PRIB'                                                71800016
         DC    X'0002'                                                  72000016
         DC    X'00F0'                                                  72100016
         DC    AL2(OCTBPRI-GFXOCTHD)                                    72200016
         DC    X'0004'                                                  72210016
         DC    CL4'RGNG'                                                72220016
         DC    X'0004'                                                  72230016
         DC    X'00F0'                                                  72240016
         DC    AL2(OCTFGREG-GFXOCTHD)                                   72250016
         DC    X'0004'                                                  72260016
         DC    CL4'RGNF'                                                72270016
         DC    X'0004'                                                  72280016
         DC    X'00F0'                                                  72290016
         DC    AL2(OCTFUREG-GFXOCTHD)                                   72300016
         DC    X'0004'                                                  72310016
         DC    CL4'RGNB'                                                72320016
         DC    X'0004'                                                  72330016
         DC    X'00F0'                                                  72340016
         DC    AL2(OCTBUREG-GFXOCTHD)                                   72350016
TABLEND  DC    X'FF'                                                    72400016
ENTRYLNG EQU    ENTRYEND-ENTRYSRT       LENGTH OF AN ENTRY              72600016
KEYSIZED EQU   KEYSIZE-KEYWORDT         KEYWORD SIZE DISPLACEMENT       72800016
KEYWORDD EQU   KEYWORD-KEYWORDT         KEYWDRD DISPLACEMENT            73000016
INFOSZED EQU   INFOSIZE-KEYWORDT        INFORMATION SIZE DISPLACEMENT   73200016
INFOTYPD EQU   INFOTYP-KEYWORDT         INFORMATION TYPE DISPLACEMENT   73300016
OCTDISPD EQU   OCTDISP-KEYWORDT         OCT HDR DISPLACEMENT            73400016
          SPACE 2                                                       73420000
*********************************************************************** 73440000
*                                                                       73460000
*        MAINTENANCE AREA                                        A33564 73480000
*                                                                       73500000
*********************************************************************** 73520000
PATCH    DC    18F'0'                                            A33564 73540000
         EJECT                                                          73600016
***                                                                     73800016
**********************************************************************  74000016
TCBAR    DSECT                                                          74200016
         DS    2F                                                       74400016
TCBDEB   DS    1F                                                       74600016
TCBTIO   DS    1F                                                       74800016
**********************************************************************  75000016
DEBAR    DSECT                                                          75200016
         DS    8F                                                       75400016
DEBUCB   DS    1F                                                       75600016
**********************************************************************  75800016
EXTRCTWK DSECT                                                          75810019
         DS    0F                                                  EXTR 75820019
EXTRCTMC DS    XL(EXTRCTSZ)                                        EXTR 75830019
ANSWAREA DS    1F                                                  EXTR 75840019
WORKEND  EQU   *                                                   EXTR 75850019
WORKSIZE EQU   WORKEND-EXTRCTWK                                    EXTR 75860019
*********************************************************************** 75900016
         EJECT                                                          75920016
GFXOCTHD DSECT                                                          76020016
GFXHDSTR EQU   *                       START OF HEADER RECORD           76120016
OCTSYS   DS    CL1                     BASE SYSTEM                      76220016
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                76320016
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          76420016
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       76520016
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       76620016
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              76720016
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              76820016
OCTCTYPE DS    CL1                      CLASS GFD JOB INTERNAL FORMAT   76870016
         DS    0H                                                       76920016
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             77020016
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       77120016
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       77220016
*    MFT ONLY - 'CLSI=' MAY SPECIFY JOBCLASS FOR INITIAL PROCESSOR    S 77270016
OCTITYPE DS    CL1                      JOBCLASS FOR SGJP - EXTERNAL  S 77320016
OCTITYPI DS    CL1                      JOBCLASS FOR SGJP - INTERNAL  S 77370016
OCTFGREG DS    CL4                      REGION SIZE GJP                 77420016
OCTFUREG DS    CL4                      REGION SIZE USER FGD            77520016
OCTBUREG DS    CL4                      REGION SIZE USER BGD            77620016
OCTGTCB  DS    CL4                     TCB ADDRESS OF GFX               77720016
OCTHRES  DS    CL4                     RESERVED                         77820016
OCTNAME  DS    CL20                     PROGRAMMER NAME                 77920016
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  78020016
GFXHDEND EQU   *                       END OF HEADER RECORD             78120016
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        78220016
         EJECT                                                          78320016
GFXOCTEN DSECT                                                          78420016
         DS    0F                                                       78520016
GFXENSTR EQU   *                       START OF ENTRY RECORD            78620016
OCTECB   DS    CL4                      ECB                             78720016
OCTUCB   DS    CL4                      UCB ADDRESS                     78820016
OCTUNIT  DS    CL4                      UNIT ADDRESS                    78920016
OCTCOUNT DS    CL4                      JOB COUNT                       79020016
OCTNOTE  DS    CL4                      NOTE                            79120016
OCTABEND DS    A                       ABEND CODE                       79220016
OCTFPART DS    CL2                      PARTITION NUMBER (MFT)     IIXX 79270018
OCTDNOTE DS    CL3                      DIARY DATA SET NOTE FIELD  IIXX 79320018
OCTIERNO DS    CL3                      INTERNAL ERROR NUMBER      IIXX 79370018
**********************************************************************  79420016
****                          ATTRIBUTE 1                          **** 79520016
**********************************************************************  79620016
OCTATTR1 DS    CL2                      ATTRIBUTES                      79720016
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         79820016
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   79920016
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         80020016
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       80120016
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   80220016
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  80320016
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  80420016
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           80520016
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          80620016
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   80720016
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           80820016
OCTBERR1 EQU   X'10'          0-                  1-GJP INTERNAL ERROR  80920016
OCTBERR2 EQU   X'08'          0-                  1-GJP INTERNAL ERR(2) 81020016
**********************************************************************  81120016
****                          ATTRIBUTE 2                          **** 81220016
**********************************************************************  81320016
OCTATTR2 DS    CL2                      ATTRIBUTES                      81420016
OCTBIRRE EQU   X'80'          0-                  1-GJP INTERNAL ERROR  81520016
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      81620016
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              81720016
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           81820016
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         81920016
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           82020016
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       82120016
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            82220016
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  82320016
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  82420016
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        82520016
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         82620016
**********************************************************************  82720016
****                          ATTRIBUTE 3                          **** 82820016
**********************************************************************  82920016
OCTATTR3 DS    CL2                      ATTRIBUTES                      83020016
OCTBIERR EQU   X'80'          0-                  1-GJP INTERNAL ERROR  83120016
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB      83220016
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              83320016
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           83420016
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         83520016
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           83620016
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       83720016
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            83820016
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  83920016
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  84020016
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        84120016
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         84220016
**********************************************************************  84320016
****                          ATTRIBUTE 4                          **** 84420016
**********************************************************************  84520016
OCTATTR4 DS    CL1                      ATTRIBUTES                 IIXX 84540018
OCTBSGJP EQU   X'80'          0-USER/GJP JOB      1-INITIAL PROCESSOR   84560018
****                                                               IIXX 84580018
*                             CONSOLE IDENTIFICATION               IIXX 84600018
****                                                               IIXX 84620018
OCTCONSL DS    CL1                      CONSOLE ID                 IIXX 84640018
GFXENEND EQU   *                       END OF ENTRY RECORD              84720016
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             84820016
         EJECT                                                          88800016
**********************************************************************  89000016
UCBAR    DSECT                                                          89200016
         IEFUCBOB                                                       89400016
**********************************************************************  89600016
         EJECT                                                          89800016
**********************************************************************  90000016
CHAINBLK DSECT                                                          90200016
         IEECHAIN                                                       90400016
         EJECT                                                          90800016
PARLIST  DSECT                                                          91000016
PARCSCB  DS    A                                                        91200016
PARDCB   DS    A                                                        91400016
PARFORM  DS    A                                                        91600016
PARECBL  DS    A                                                        91800016
PARQMPAR DS    A                                                        92000016
PARSMB   DS    A                                                        92200016
PARDSB   EQU   PARSMB                                                   92400016
PARWORK1 EQU   PARECBL                                                  92600016
PARWORK2 EQU   PARQMPAR                                                 92800016
SPLCIB   EQU   PARSMB                                                   92850019
**********************************************************************  92900016
**********************************************************************  93000016
**********************************************************************  93050016
GFXCVT   DSECT                                                          93100016
         CVT                                                            93150016
         EJECT                                                          93160018
CIBD     DSECT                                                          93170018
         IEZCIB                                                         93180018
         END                                                            93200016
