         TITLE 'IKASD084 - VMS SYSOUT WTR WAIT ROUTINE'                 00600016
IKASD084 CSECT                                                          01200016
*0802,668000,899000,903000,923000,976000,979000                    IIXX 01500018
         SPACE 2                                                        01800016
**********************************************************************  02400016
*                                                                    *  03200016
*TITLE--       IEFSD084 -- SYSTEM OUTPUT WRITER WAIT ROUTINE         *  04000016
*                                                                    *  04800016
* CHART ID              -DF                                             05200016
*STATUS -- CHANGE LEVEL 000                                          *  05600016
*                                                                    *  06400016
*FUNCTION/OPERATION--THE SOLE PURPOSE OF THIS ROUTINE IS TO SERVE    *  07200016
*   AS A MULTIPLE WAIT MODULE WHEN THERE IS NO WORK IN ANY OF THE    *  08000016
*   SYSOUT CLASSES ASSOCIATED WITH THIS WRITER.  EACH SUCH CLASS     *  08800016
*   HAS ASSOCIATED WITH ITSELF AN ECB.  THERE IS A LIST OF ECB PTRS  *  09600016
*   WHICH POINT TO THESE ECB'S.  THIS ROUTINE WAITS ON THAT LIST     *  10400016
*   AND RETURNS CONTROL TO THE MAIN SYSOUT LOGIC RTN (IEFSD082)      *  11200016
*   WHENEVER ANY ONE OR MORE ECB'S IN THAT LIST IS (ARE) POSTED BY   *  12000016
*   QUEUE MANAGER, WHICH HAS RECEIVED WORK FOR SOME CLASS(ES) ASSO-  *  12800016
*   CIATED WITH THIS WRITER.                                         *  13600016
*                                                                    *  14400016
*ENTRY POINT--                                                       *  15200016
*        IEFSD084 - FROM IEFSD082  WHEN NO WORK IS INDICATED BY ALL  *  16000016
*   QUEUES OF THIS WRITER.                                           *  16800016
*                                                                    *  17600016
*INPUT--IN THE PARAMETER REGISTER, PTR TO A 6-WD LIST CONTAINING     *  18400016
*   IN THE ORDER SHOWN, OF WHICH ONLY THE ECB LIST PTR IS USED HERE. *  19200016
*                             CSCB PTR,                              *  20000016
*                             PTR TO OUTPUT DCB,                     *  20800016
*                             WD OF BLANKS (OR FORMS NO.)            *  21600016
*                             PTR TO ECB LIST,                       *  22400016
*                             PTR TO QMGR PARAMETER AREA,            *  23200016
*                             PTR TO SMB/DSB AREA.                   *  24000016
*                                                                    *  24800016
*OUTPUT--SAME AS INPUT                                               *  25600016
*                                                                    *  26400016
*EXTERNAL ROUTINES--NONE                                             *  27200016
*                                                                    *  28000016
*EXIT--TO                                                            *  28800016
*        IEFSD082 - SYSOUT MAIN LOGIC RTN, UPON POSTING OF ANY ECB   *  29600016
*   POINTED TO IN THE ECB LIST.                                      *  30400016
*                                                                    *  31200016
*TABLES/WORKAREAS--NONE.  THE ECB LIST IS MERELY REFERRED TO, NOT    *  32000016
*   ACCESSED, BY THIS ROUTINE.                                       *  32800016
*                                                                    *  33600016
*ATTRIBUTES-REENTRANT                                                *  34400016
*                                                                    *  35200016
*NOTES--THE ROUTINE USES THE  WAIT  SYSTEM MACRO ONLY                *  36000016
*                                                                    *  36800016
**********************************************************************  37600016
***                                                                ***  38400016
*        ESSENTIAL EQUATES                                           *  39200016
***                                                                ***  40000016
R0       EQU   0                                                        40800016
R1       EQU   1                                                        41600016
R2       EQU   2                                                        42400016
R3       EQU   3                                                        43200016
R4       EQU   4                                                        44000016
R5       EQU   5                                                        44800016
R6       EQU   6                                                        45600016
R7       EQU   7                                                        46400016
R8       EQU   8                                                        47200016
R9       EQU   9                                                        48000016
R10      EQU   10                                                       48800016
R11      EQU   11                                                       49600016
R12      EQU   12                                                       50400016
R13      EQU   13                                                       51200016
R14      EQU   14                                                       52000016
R15      EQU   15                                                       52800016
*                                                                    *  53600016
**********************************************************************  54400016
         EJECT                                                          55200016
**********************************************************************  56000016
*        IEFSD084                       THE PROGRAM                  *  56800016
**********************************************************************  57600016
***                                                                ***  58400016
*        ESTABLISH BASE                                              *  59200016
***                                                                ***  60000016
         BALR  R9,0                                                     60800016
         USING *,R9                                                     61600016
***                                                                ***  62400016
*        GET ADDRESS OF ECB LIST, ISSUE MULTIPLE WAIT                *  63200016
***                                                                ***  64000016
         LR    R2,R1                    SAVE INPUT                      64800016
         USING PARLIST,R2               ADDRESSABILITY FOR PARLIST      65600016
         L     R4,PARDCB                OCT HEADER RECORD               65800016
         USING GFXOCTHD,R4              ADDRESSABILITY                  66000016
         TM    OCTSYS,X'08'           Q. WAS MSG. GFX READY ISSUED      66200016
         BO    SETWAIT                A. YES                            66400016
         OI    OCTSYS,X'08'             SET BIT FOR MSG. ISSUED         66600016
         L     R3,PARCSCB               ADDRESS OF CSCB            IIXX 66640018
         USING CHAINBLK,R3              ADDRESSABILITY FOR CSCB    IIXX 66680018
         SR    R0,R0                    CLEAR REG                  IIXX 66720018
         IC    R0,CHUCMP                CONSOLE ID                 IIXX 66760018
         WTO   'IKA051E GFX READY',ROUTCDE=2,DESC=3,               IIXXR66840018
               MCSFLAG=REG0                                        IIXX 66920018
SETWAIT  L     R1,PARECBL               GET PTR TO ECB LIST             67000016
         WAIT  ECBLIST=(1)                                              67200016
***                                                                ***  68000016
*        POSTING OF ANY ONE ECB IN THE LIST CAUSES WAIT TO BE        *  68800016
*        SATISFIED.  RETURN TO BEGINNING OF SYSOUT MAIN LOGIC RTN    *  69600016
***                                                                ***  70400016
         LR    R1,R2                    RESTORE INPUT                   71200016
         XR    R8,R8                    CLEAR IND REG USED BY IEFSD082  72000016
         L     R15,SD84EXIT             LOAD EXIT ADDR                  72800016
         BALR  R14,R15                  *****EXIT*****                  73600016
*                                                                    *  74400016
**********************************************************************  75200016
         EJECT                                                          76000016
**********************************************************************  76800016
***                                                                ***  77600016
*        CONSTANTS AND DSECTS                                        *  78400016
***                                                                ***  79200016
SD84EXIT DC    V(IKASD082)              EXIT ADDRESS                    80000016
         SPACE 2                                                        80080000
*********************************************************************** 80160000
*                                                                       80240000
*        MAINTENANCE AREA                                        A33564 80320000
*                                                                       80400000
*********************************************************************** 80480000
PATCH    DC     2F'0'                                            A33564 80560000
          SPACE 2                                                       80640000
PARLIST  DSECT                                                          80800016
PARCSCB  DS    A                                                        81600016
PARDCB   DS    A                                                        82400016
PARFORM  DS    A                                                        83200016
PARECBL  DS    A                                                        84000016
PARQMPAR DS    A                                                        84800016
PARSMB   DS    A                                                        85600016
PARDSB   EQU   PARSMB                                                   86400016
PARWORK1 EQU   PARECBL                                                  87200016
PARWORK2 EQU   PARQMPAR                                                 88000016
**********************************************************************  88800016
         EJECT                                                          88900016
GFXOCTHD DSECT                                                          89000016
GFXHDSTR EQU   *                       START OF HEADER RECORD           89100016
OCTSYS   DS    CL1                     BASE SYSTEM                      89200016
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                89300016
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          89400016
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       89500016
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       89600016
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              89700016
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              89800016
OCTCTYPE DS    CL1                 INTERNAL FORMAT - FGD JOBCLASS  IIXX 89900018
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             90000016
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       90100016
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       90200016
OCTITYPE DS    CL1                      EXTERNAL JOB CLASS - SGJP  IIXX 90260018
OCTITYPI DS    CL1                      INTERNAL JOB CLASS - SGJP  IIXX 90320018
OCTFGREG DS    CL4                      REGION SIZE GJP                 90400016
OCTFUREG DS    CL4                      REGION SIZE USER FGD            90500016
OCTBUREG DS    CL4                      REGION SIZE USER BGD            90600016
OCTGTCB  DS    CL4                     TCB ADDRESS OF GFX               90700016
OCTHRES  DS    CL4                     RESERVED                         90800016
OCTNAME  DS    CL20                     PROGRAMMER NAME                 90900016
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  91000016
GFXHDEND EQU   *                       END OF HEADER RECORD             91100016
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        91200016
         EJECT                                                          91300016
GFXOCTEN DSECT                                                          91400016
         DS    0F                                                       91500016
GFXENSTR EQU   *                       START OF ENTRY RECORD            91600016
OCTECB   DS    CL4                      ECB                             91700016
OCTUCB   DS    CL4                      UCB ADDRESS                     91800016
OCTUNIT  DS    CL4                      UNIT ADDRESS                    91900016
OCTCOUNT DS    CL4                      JOB COUNT                       92000016
OCTNOTE  DS    CL4                      NOTE                            92100016
OCTABEND DS    A                       ABEND CODE                       92200016
OCTFPART DS    CL2                      PARTITION NUMBER (MFT)     IIXX 92250018
OCTDNOTE DS    CL3                      DIARY DATA SET NOTE FIELD  IIXX 92300018
OCTIERNO DS    CL3                      INTERNAL ERROR NUMBER      IIXX 92350018
**********************************************************************  92400016
****                          ATTRIBUTE 1                          **** 92500016
**********************************************************************  92600016
OCTATTR1 DS    CL2                      ATTRIBUTES                      92700016
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         92800016
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   92900016
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         93000016
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       93100016
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   93200016
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  93300016
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  93400016
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           93500016
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          93600016
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   93700016
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           93800016
OCTBERR1 EQU   X'10'          0-                  1-GJP INTERNAL ERROR  93900016
OCTBERR2 EQU   X'08'          0-                  1-GJP INTERNAL ERR(2) 94000016
**********************************************************************  94100016
****                          ATTRIBUTE 2                          **** 94200016
**********************************************************************  94300016
OCTATTR2 DS    CL2                      ATTRIBUTES                      94400016
OCTBIRRE EQU   X'80'          0-                  1-GJP INTERNAL ERROR  94500016
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      94600016
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              94700016
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           94800016
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         94900016
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           95000016
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       95100016
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            95200016
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  95300016
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  95400016
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        95500016
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         95600016
**********************************************************************  95700016
****                          ATTRIBUTE 3                          **** 95800016
**********************************************************************  95900016
OCTATTR3 DS    CL2                      ATTRIBUTES                      96000016
OCTBIERR EQU   X'80'          0-                  1-GJP INTERNAL ERROR  96100016
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB      96200016
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              96300016
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           96400016
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         96500016
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           96600016
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       96700016
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            96800016
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  96900016
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  97000016
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        97100016
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         97200016
**********************************************************************  97300016
****                          ATTRIBUTE 4                          **** 97400016
**********************************************************************  97500016
OCTATTR4 DS    CL1                      ATTRIBUTES                 IIXX 97520018
OCTBSGJP EQU   X'80'          0-USER/GJP JOB      1-INITIAL PROCESSOR   97540018
****                                                               IIXX 97560018
*                             CONSOLE IDENTIFICATION               IIXX 97580018
****                                                               IIXX 97600018
OCTCONSL DS    CL1                      CONSOLE ID                 IIXX 97620018
GFXENEND EQU   *                       END OF ENTRY RECORD              97700016
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             97800016
         EJECT                                                          98100018
**********************************************************************  98400018
CHAINBLK DSECT                                                          98700018
         IEECHAIN                                                       99000018
         END                                                            99300018
