 TITLE 'IKDCTL' CONTROL ROUTINE FOR SGJP                                00200017
*STATUS: CHANGE LEVEL 0                                               * 00400017
*FUNCTION/OPERATION: PERFORM CONTROL FUNCTIONS FOR PROCESSOR ROUTINES.* 00800017
*   IT'S OPERATIONS INCLUDE:                                          * 01000017
*   1)IF ENTERED PRIOR TO LOGON, LOAD THE LOGON PROCESSOR;  IF ENTERED* 01200017
*   AFTER BEGIN JOB, GET A PROCESSOR SELECT RECORD TO DETERMINE IF THE* 01400017
*   SUBSEQUENT PROCESSOR IS TO BE LINKED TO OR LOADED                 * 01600017
*   2)LINK TO THE CANCEL JOB, BEGIN JOB, LOGOFF OR BEGIN PROCEDURE    * 01800017
*   PROCESSORS                                                        * 02000017
*   3)LOAD THE LOGON, SPECIFY JOB STEP, DESCRIBE DATA, ENTER DATA,    * 02200017
*   WRITE MESSAGE OR RECALL PROCESSORS, GET AN EXTRACT RECORD FROM THE* 02400017
*   SUBSYSTEM AND BALR TO THE PROCESSOR                               * 02600017
*   4)ANALYZE RETURN CODES FROM PROCESSORS AND PERFORM ONE OF THE     * 02800017
*         X'00' DELETE LOADED PROCESSOR, TRANSMIT MESSAGE TO THE SUB- * 03000017
*               SYSTEM AND GET ANOTHER PROCESSOR SELECT RECORD        * 03200017
*         X'04' TRANSMIT A MESSAGE TO THE SUBSYSTEM AND GET ANOTHER   * 03400017
*               EXTRACT RECORD                                        * 03600017
*         X'08' ISSUE RETURN                                          * 03800017
*         X'0C' DELETE LOADED PROCESSOR AND GET ANOTHER PROCESSOR     * 04000017
*               SELECT RECORD                                         * 04200017
*ENTRY POINTS: IKDCTL.  ENTERED VIA XCTL FROM INITIALIZATION(SGJPINIT)* 04400017
*INPUT: REGISTER 0 CONTAINS ENTRY CODE FROM SGJPINIT:                 * 04600017
*         X'04' ENTERED AT LOGON                                      * 04800017
*         X'08' ENTERED AFTER BEGIN JOB                               * 05000017
*   REGISTER 1 CONTAINS THE ADDRESS OF THE CONSOLE CONTROL TABLE FROM * 05200017
*   SGJPINIT.                                                         * 05400017
*   3)PROCESSOR SELECT RECORD RECEIVED FROM 1130 SUBSYSTEM INDICATING * 05600017
*   WHICH PROCESSOR HAS BEEN SELECTED AND IF IT IS TO BE LINKED TO OR * 05800017
*   LOADED.                                                           * 06000017
*   4)EXTRACT RECORD FROM SUBSYSTEM                                   * 06200017
*   5)RETURN CODE FROM PROCESSORS VIA REGISTER 15:                    * 06400017
*        X'00' NORMAL RETURN                                          * 06600017
*        X'04' REPEAT                                                 * 06800017
*        X'08' RETURN FROM BEGIN JOB OR LOGOFF                        * 07000017
*        X'06' CANCEL CURRENT PROCESSOR                               * 07200017
*OUTPUT: 1)  CODE FOR IKDIOR IN REGISTER 0  X'04'=READ X'08'=WRITE    * 07400017
*   2)ADDRESS OF CONSOLE CONTROL TABLE IN REGISTER 1 FOR PROCESSORS   * 07600017
*   AND IKDIOR.                                                       * 07800017
*   3)MESSAGE SENT TO SUBSYSTEM TO INDICATE PREVIOUS EXTRACT RECORD   * 08000017
*   WAS ACCEPTED BY THE PROCESSOR.                                    * 08200017
*EXTERNAL ROUTINES: IKDIOR FOR I/O OPERATIONS; PROCESSOR ROUTINES       08400017
*EXITS: 1BRANCH TO IKDIOR FOR READ/WRITE OPERATIONS                   * 08600017
*       2)LINK OR BRANCH TO PROCESSOR ROUTINES                        * 08800017
*       3)RETURN UPON RECEIPT OF AN 08 CODE                           * 09000017
*TABLES/WORKAREAS: CCT, I/O BUFFER                                    * 09200017
*ATTRIBUTES: REENTRANT                                                * 09400017
*NOTES: N/A                                                           * 09600017
         EJECT                                                          09800017
IKACCT   DSECT                                                          10000017
         SPACE                                                          10200017
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         10400017
         SPACE                                                          10600017
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    10800017
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     11000017
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       11200017
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             11400017
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  11600017
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  11800017
*                   SET.                                                12000017
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      12200017
*                   SECOND.                                             12400017
         SPACE 2                                                        12600017
         SPACE 2                                                        12800017
*                             SECTION ONE                               13000017
         SPACE                                                          13200017
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     13400017
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    13600017
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  13800017
         SPACE                                                          14000017
         DS    0F                                                       14200017
CCTUNAME DS    5F                  USER'S NAME                          14400017
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         14600017
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     14800017
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       15000017
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    15200017
*                                       AT LAST BEGIN JOB               15400017
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   15600017
*                                       LAST BEGIN JOB                  15800017
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 16000017
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    16200017
*                                       JOB                             16400017
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    16600017
*                                       JOB                             16800017
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     17000017
*                                       CESSOR                          17200017
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         17400017
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         17600017
CCTJCTR  DS    H                   JOB COUNTER                          17800017
CCTHIST  DS    109F                HISTORY OF OPERATIONS                18000017
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   18200017
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  18400017
CCTSSTAT DS    C                   SESSION STATUS                       18600017
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              18800017
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              19000017
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    19200017
         EJECT                                                          19400017
         SPACE 2                                                        19600017
*                             SECTION TWO                               19800017
         SPACE                                                          20000017
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   20200017
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  20400017
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 20600017
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              20800017
         SPACE                                                          21000017
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     21200017
*                                       FRAME                           21400017
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  21600017
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     21800017
*                                       MULTIPLE DISPLAY FRAME (ENT)    22000017
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   22200017
CCTDISM  DS    C                   DISPLAY MASK                         22400017
CCTCSM   DS    C                   COMMAND SELECT MASK                  22600017
CCTPSTAT DS    CL2                 GJP STATUS                           22800017
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              23000017
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  23200017
CCTPWKAE EQU   *                                                        23400017
         SPACE 2                                                        23600017
*                             SECTION THREE                             23800017
         SPACE                                                          24000017
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    24200017
*                   INTO SECTION ONE OR TWO                             24400017
         SPACE                                                          24600017
CCTDGMP  DS    F                  POINTER TO DGM                        24800017
CCTDATAP DS    F                  POINTER TO DATA NUMBER                25000017
CCTCSTP  DS    F                  POINTER TO CST                        25200017
CCTCPSTP DS    F                  POINTER TO CURRENT PST                25400017
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            25600017
CCTDORP  DS    F                  POINTER TO DOR MODULE                 25800017
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              26000017
CCTDIARP DS    F                  POINTER TO DIA                        26200017
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      26400017
CCTACTP  DS    F                  POINTER TO ACT                        26600017
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     26800017
CCTIERRP DS    F                  POINTER TO IERR                       27000017
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              27200017
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               27400017
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                27600017
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 27800017
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 28000017
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   28200017
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                28400017
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                28600017
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               28800017
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              29000017
CCTPECB  DS    F                  PROCESSOR'S ECB                       29200017
CCTWECB  DS    F                  WTOR ECB                              29400017
CCTDIAWA DS    CL136               DIARY WORK AREA                      29600017
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    29800017
CCTCSAVE DS    CL72                CTL SAVE AREA                        30000017
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                30200017
CCTASAVE DS    CL72                DAT SAVE AREA                        30400017
*                                                                       30600017
* THESE ARE THE CHANGES MADE TO THE CONSOLE CONTROL TABLE OF GJP.       30800017
* CONTENTS NOT NEEDED BY SGJP ARE REPLACED AS INDICATED BELOW           31000017
*                                                                       31200017
IKDCCT   EQU   IKACCT              THREE CHARACTER PREFIX IS REPLACED   31400017
CCTCWKA  EQU   CCTCSTP             CONTROL ROUTINE WORKAREA             31600017
CCTBUFFP EQU   CCTGWRKP            POINTER TO BTAM BUFFER               31800017
CCTRECLN EQU   CCTDGMP             LENGTH OF DATA TO BE TRANSMITTED     32000017
CCTIORP  EQU   CCTDORP             POINTER TO I/O ROUTINE               32200017
CCTMSGP  EQU   CCTDMRP             POINTER TO MESSAGE ROUTINE           32400017
CCTSTAT  EQU   CCTACTP             SGJP STATUS BYTES                    32600017
CCTIELST EQU   CCTLPWRK+68         AREA USED FOR GTNIT/GTEND PARAM LIST 32700017
CCTRDLST EQU   CCTIELST+24         AREA USED FOR GTRED PARAMETER LIST   32800017
CCTWRLST EQU   CCTRDLST+16         AREA USED FOR GTWRT PARAMETER LIST   32900017
CCTTSLST EQU   CCTWRLST+20         AREA USED FOR GTCLT PARAMETER LIST   33000017
CCTDSREF EQU   CCTTSLST+12         DATA SET REFERENCE NUMBER            33100017
CCTSTCOD EQU   CCTDSREF+4          WORD TO CONTAIN RESULTS OF INIT,TEST 33200017
CCTDATYP EQU   CCTSTCOD+4          WORD TO CONTAIN DATA TYPE CODE       33300017
CCTCTLOP EQU   CCTDATYP+4          WORD CONTAINING CODE DENOTING DEST-  33400017
*                                  INATION OF DATA                      33500017
CCTTSTCD EQU   CCTCTLOP+4          WORD TO CONTAIN CODE REPRESENTING    33600017
*                                  THE I/O OPERATION TO BE TESTED BY    33700017
*                                  GTCLT                                33800017
CCTIOECB EQU   CCTTSTCD+4         ECB USED IN WTOR ON I/O ERRORS        33900017
CCTREPAR EQU   CCTIOECB+4         AREA USED FOR WTOR REPLY              34000017
CCTERLST EQU   CCTREPAR+4          AREA FOR IERR MODEL PARAMETER LIST   34600017
CCTPWKAL EQU   CCTPWKAE-CCTPWKA                                         35200017
         EJECT                                                          35400017
IKDCTL   CSECT                                                          35600017
*                                                                       35800017
*      GENERAL REGISTERS AND EQUATES                                    36000017
*                                                                       36200017
RPAR0    EQU   0                                                        36400017
RPAR1    EQU   1                                                        36600017
RCCT     EQU   2                                                        36800017
RBAL     EQU   4                                                        37200017
RSADR    EQU   5                                                        37400017
RWKAREA  EQU   6                                                        37600017
RWKARPTR EQU   7                                                        37660017
RMSGADRS EQU   8                                                        37720017
RBUFF    EQU   9                                                        37800017
RBASE    EQU   10                                                       38000017
RWORK    EQU   11                                                       38200017
RLNTH    EQU   11                                                       38260017
RLCHAR   EQU   12                                                       38320017
RMISC    EQU   12                                                       38400017
RNUC     EQU   12                                                       38600017
RSAVE    EQU   13                                                       38800017
RRET     EQU   14                                                       39000017
RBR      EQU   15                                                       39200017
*                                                                       39400017
ZERO     EQU   0                                                        39440017
CRDCODE  EQU   0                                                        39480017
ONE      EQU   1                                                        39520017
TWO      EQU   2                                                        39560017
LMSGLNTH EQU   2                                                        39600017
THREE    EQU   3                                                        39640017
KEYLNTH  EQU   3                                                        39680017
FOUR     EQU   4                                                        39720017
PSRLNTH  EQU   4                                                        39760017
CMSGLNGT EQU   4                                                        39800017
CWRCODE  EQU   4                                                        39840017
FIVE     EQU   5                                                        39880017
DUNIT    EQU   5                   DISPLACEMENT OF UNIT IN PARAM LIST   39920017
LKLDCD   EQU   5                                                        39960017
JMSGLNTH EQU   6                                                        40000017
KEY      EQU   6                                                        40040017
SEVEN    EQU   7                                                        40080017
EIGHT    EQU   8                                                        40120017
JOBCOUNT EQU   8                                                        40160017
CTRAWCD  EQU   8                                                        40200017
TWELVE   EQU   12                                                       40240017
EXTNOTE  EQU   12                                                       40280017
MAXLNTH  EQU   12                                                       40320017
CTWAWCD  EQU   12                                                       40360017
SIXTEEN  EQU   16                                                       40400017
FBCKGRND EQU   16                                                       40440017
CRDONCD  EQU   24                                                       40480017
SGLINE   EQU   26                                                       40500017
CWRONCD  EQU   28                                                       40520017
SVNTYTWO EQU   72                                                       40560017
SVNTYTHR EQU   73                                                       40600017
SVNTYSIX EQU   76                                                       40640017
NUMBER   EQU   200                                                      40680017
SUPLIST  EQU   336                                                      40720017
HEX00    EQU   X'00'                                                    40760017
HEX01    EQU   X'01'                                                    40800017
HEX08    EQU   X'08'                                                    40840017
HEX10    EQU   X'10'                                                    40880017
HEX1C    EQU   X'1C'                                                    40900017
CENDCODE EQU   X'14'                                                    40920017
HEX21    EQU   X'21'                                                    40960017
HEX26    EQU   X'26'                                                    41040017
HEX40    EQU   X'40'                                                    41080017
HEX80    EQU   X'80'                                                    41120017
HEX83    EQU   X'83'                                                    41160017
HEXC0    EQU   X'C0'                                                    41200017
HEXC4    EQU   X'C4'                                                    41240017
HEXCF    EQU   X'CF'                                                    41280017
HEXF0    EQU   X'F0'                                                    41320017
HEXFF    EQU   X'FF'                                                    41360017
D        EQU   C'D'                                                     41400017
K        EQU   C'K'                                                     41440017
M        EQU   C'M'                                                     41480017
N        EQU   C'N'                                                     41680017
         EJECT                                                          42000017
*                                                                       42200017
*      HOUSE KEEPING                                                    42400017
*                                                                       42600017
         SAVE  (2,12)         SAVE REGISTERS                            42800017
         BALR  RBASE,0                  SET UP PROGRAM BASE             43000017
         USING *,RBASE                                                  43200017
         LR    RCCT,RPAR1               GET CONSOLE CONTROL TABLE ADDR. 43400017
         USING IKACCT,RCCT              SET UP BASE FOR CCT             43600017
         ST    RSAVE,CCTCSAVE+FOUR     SAVE CALLER'S SAVE ADDRESS       43800017
         LA    RWORK,CCTCSAVE           CHAIN                           44000017
         ST    RWORK,EIGHT(RSAVE)              SAVE                     44200017
         LR    RSAVE,RWORK                       AREAS                  44400017
         LA    RWKAREA,CCTCWKA          GET POINTER TO CONTROL WORKAREA 44600017
         MVC   ZERO(EIGHT,RWKAREA),PROMODEL   PUT MODEL INTO WORKAREA   44700017
         L     RBUFF,CCTBUFFP    SET POINTER TO BUFFER                  44900017
         CLC   CCTCCR(THREE),LOGN     DETERMINE IF LOGON TIME           45000017
         BE    CLOGN               IF SO, BRANCH                        45200017
         CLC   CCTCCR(THREE),BEG      DETERMINE IF BEGIN JOB TIME       45300017
         BE    TSTMSGBT               IF YES, BRANCH                    45400017
*                                                                       45700017
* BRANCH TO INTERNAL ERROR ROUTINE AND TERMINATE JOB                    45800017
*                                                                       45900017
         LR    RPAR1,RCCT          CCT ADDRESS                          46000017
         LA    RPAR0,IERRPAR       ERROR MSG ADDRESS                    46100017
         L     RBR,CCTIERRP        IKAIERR ADDRESS                      46200017
         BALR  RRET,RBR            GO TO IERR                           46250017
         LR    RPAR0,RBR           PUT CODE IN REG15                    46300017
         B     FASTSTOP            BRANCH TO TERMINATE                  46350017
*                                                                       46400017
*      INPUT FROM INITIALIZATION INDICATES LOGON TIME.                  46600017
*                                                                       46800017
CLOGN    MVI   CCTSTAT,D           INDICATE MODULE TO BE LOADED         47000017
         MVI   CCTPECB,HEX00       CLEAR PROCESSOR ECB                  47200017
         MVI   CCTCSM,HEX01        SET COMMAND SELECT MASK              47400017
         EJECT                                                          47600017
*                                                                       47800017
*      LOGON, DESCRIBE DATA, SPECIFY JOB STEP, ENTER DATA, WRITE        48000017
*      MESSAGE AND RECALL PROCESSORS WILL BE LOADED                     48200017
*                                                                       48400017
CLOAD    LA    RPAR0,CRDONCD      PARAMETER CODE TO READ                48460017
         LA    RWORK,CCTPWKAL     GET LENGTH OF WORKAREA                48520017
         LA    RWORK,TWO(RWORK)    ADD TWO BYTES                        48580017
         ST    RWORK,CCTRECLN     PUT LENGHT IN CCT                     48640017
         BAL   RBAL,CREQIO        GO TO PERFORM I/O                     48700017
         CLC   CCTCCR(THREE),LOF   WAS LOGOFF SELECTED                  48730017
         BE    CEXTRCD     IF YES, BRANCH TO WAIT FOR I/O               48760017
         LOAD  EPLOC=(RWKAREA)          LOAD SELECTED PROCESSOR         48800017
         LR    RSADR,RPAR0              GET AND SAVE PROCESSORS ADDRESS 49000017
*                                                                       49200017
*    IKDCTL PREPARES PARAMETERS FOR IKDIOR TO READ AN EXTRACT RECORD    49400017
*      FROM THE 1130 SUBSYSTEM.                                         49600017
*                                                                       49800017
CEXTRCD  LA    RPAR0,CTRAWCD      CODE TO TEST READ AND WAIT            50300017
         BAL   RBAL,CREQIO         GO TO PERFROM I/O                    50800017
         LR    RBR,RSADR                GET ADDRESS OF PROCESSER        51000017
         CLC   CCTCCR(THREE),LOF   WAS LOGOFF SELECTED                  51030017
         BE    LINKLOF            BRANCH TO RESET CSM                   51060017
         LR    RPAR1,RCCT                                               51100017
         BALR  RRET,RBR                 BRANCH TO THE LOADED PROCESSOR  51200017
         CH    RBR,CANC           WAS PROCESSOR CANCELLED               51260017
         BE    CCNCL              IF YES, BANCH TO HNDL RETURN CODE     51320017
         B     CKSTOP              BRANCH TO                            51400017
LINKLOF  MVI   CCTCSM,HEX00       CLEAR SELECT MASK                     51460017
         B     CLINK              BRANCH TO LINK TO LOOGOFF PROCESSOR   51520017
*                                                                       51600017
*      INPUT FROM INITIALIZATION INDICATES BEGIN JOB TIME               51800017
*                                                                     * 52000017
TSTMSGBT MVC   ZERO(FOUR,RBUFF),NONE   PUT NONE MESSAGE IN BUFFER       52004017
         LA    RWORK,FOUR          GET A COUNT OF FOUR                  52008017
         ST    RWORK,CCTRECLN     SET RECORD LENGTH                     52012017
         LA    RPAR0,CWRCODE      SET CODE TO WRITE                     52016017
         BAL   RBAL,CREQIO                                              52020017
         TM    CCTPSTAT+1,X'40'    IS THERE A MESSAGE TO BE DISPLAYED   52024017
         BZ    NOMSG               BRANCH IF NO                         52028017
TESTLOF  TM    CCTCSM,HEX08        IS ONLY LOGOFF AVAILABLE             52036017
         BZ    MSGONLY             BRANCH IF NOT                        52045017
         LA    RWORK,ZERO          GET HEADER CODE FOR LOGOFF           52054017
         STH   RWORK,ZERO(RBUFF)   PUT CODE INTO BUFFER                 52063017
         B     MSGHNDLE            GO TO PUT MESSAGES INTO BUFFER       52072017
MSGONLY  LA    RWORK,TWO           GET HEADER CODE FOR MESSAGES         52081017
         STH   RWORK,ZERO(RBUFF)   PUT CODE INTO BUFFER                 52090017
MSGHNDLE LA    RBUFF,TWO(RBUFF)    SET BUFFER POINTER TO NEXT LOCATION  52099017
         SR    RLNTH,RLNTH         CLEAR A REGISTER TO USE FOR DATA LNT 52108017
         LA    RLNTH,TWO           ADD TWO TO LENGTH                    52117017
         BAL   RBAL,PROCMSG        GO TO MOVE ANY MESSAGES FROM PWKA TO 52126017
         B     GOTOIO              BUFFER                               52135017
NOMSG    LA    RWORK,ONE           GET HEADER CODE FOR NO MESSAGE       52144017
         STH   RWORK,ZERO(RBUFF)   PUT CODE INTO BUFFER                 52153017
         LA    RLNTH,TWO           SET LENGTH OF DATA TO BE TRANSMITTED 52162017
GOTOIO   ST    RLNTH,CCTRECLN      PUT LENGTH INTO CCT                  52171017
         LA    RPAR0,CWRCODE       GET CODE TO WRITE                    52180017
         BAL   RBAL,CREQIO         BRANCH TO GO TO I/O ROUTINE          52189017
CBEGN    EQU   *                                                        52200017
         MVI   CCTPWKA,HEX40    PUT BLANK IN WORKAREA                   52250017
         MVC   CCTPWKA+1(200),CCTPWKA                                   52300017
         MVC   CCTPWKA+200(151),CCTPWKA                                 52350017
         LA    RPAR0,CRDCODE            PARAMETER CODE TO READ          52400017
         LA    RWORK,MAXLNTH      GET LENGTH OF MAXIMUM PSR             52600017
*                                  TO BE RECEIVED                       52800017
         ST    RWORK,CCTRECLN      PUT IN RECORD LENGTH FOR IKDIOR      53000017
         BAL   RBAL,CREQIO                                              53200017
         MVC   CCTCWKA+FOUR(THREE),CCTCCR  PUT COMMAND KEY INTO CTL AR. 53400017
         L     RWORK,CCTHSN        GET HISTORY SEQUENCE NUMBER          53650017
         LA    RWORK,ONE(RWORK)    INCREMENT BY ONE                     53710017
         STH   RWORK,CCTHSN+TWO    RESTORE IN CCT                       53770017
         CLI   CCTSTAT,D           DETERMINE IF PROCESSOR IS TO BE      53830017
         BNE   CLINK       LOADED.  IF NOT, BRANCH                      53900017
         B     CLOAD       BRANCH TO LOAD PROCESSOR                     54100017
         EJECT                                                          54600017
*                                                                       54800017
*      CANCEL JOB, BEGIN JOB, BEGIN PROCEDURE AND LOGOFF PROCESSORS     55000017
*      WILL BE LINKED TO                                                55200017
*                                                                       55400017
CLINK    CLC   CCTCCR(KEYLNTH),CAN  IS PROCESSOR CANCEL JOB             55480017
         BNE   CSMSET         IF NOT BRANCH                             55560017
         MVI   CCTCSM,HEX01        PUT INITIAL SELECT MASK IN CCT       55640017
CSMSET   LR    RPAR1,RCCT      ADDRESS OF CCT                           55720017
         LA    RBR,CCTPWKA+SUPLIST      LOAD ADDR OF SUPEVIS- PARM LIST 56000017
         MVI   ZERO(RBR),HEX00     CLEAR AREA                           56200017
         MVC   ONE(SEVEN,RBR),ZERO(RBR)       BEFORE LINK               56400017
         LA    RWKAREA,CCTCWKA          ADDRESS OF PROCESSOR NAME       56600017
         LINK  EPLOC=(RWKAREA),MF=(E,(1)),SF=(E,(15))  LINK TO PROCESSR 56800017
         CLC   CCTCCR(THREE),LOF   WAS PROCESSOR LOGOFF                 56801017
         BNE   BRANCHT            IF NOT, BRANCH TO BRANCH TABLE        56802017
         B     CKSTOP             IF YES, BRANCH TO CHECK STOP BITS     56803017
         EJECT                                                          56804017
*                                                                       56808017
* CHECK OCT IF OPERATOR ISSUED MEDIUM OR FAST STOP                      56812017
*                                                                       56816017
RCVT     EQU   3                                                        56820017
ROCT     EQU   4                                                        56824017
RGFXLIST EQU   7                                                        56828017
ROCTENT  EQU   8                                                        56832017
RENTCTR  EQU   12                                                       56836017
CKSTOP   L     RCVT,HEX10          GET CVT ADDRESS                      56842017
         USING CVT,RCVT                                                 56848017
         L     RGFXLIST,CVTQOCR                                         56852017
         USING GRAPLIST,RGFXLIST                                        56856017
         L     ROCT,GOCT           GET OCT ADDRESS                      56860017
         USING GFXOCTHD,ROCT                                            56864017
         LA    ROCTENT,GFXHDSZE+GFXHDSTR   GET OCT RECORD ENTRY         56868017
         USING GFXOCTEN,ROCTENT                                         56872017
         LH    RENTCTR,OCTUNBR     OCT RECORD NUMBER                    56876017
ENTSEACH CLC   CCTUNIT(THREE),OCTUNIT+ONE  IS THIS OCT ENTRY NEEDED     56880017
         BE    STOP                IF YES, BRANCH                       56884017
         LA    ROCTENT,GFXENSTR+GFXENSZE  UPDATE ENTRY                  56888017
         BCT   RENTCTR,ENTSEACH    GO BACK AND CONTINUE SEARCH          56892017
NOTFOUND LA    RPAR0,MSG11         GET MESSAGE ADDRESS                  56896017
         LR    RPAR1,RCCT                                               56900017
         L     RBR,CCTIERRP        ERROR ROUTINE ADDRESS                56904017
         BR    RBR                 GO TO IKAIERR                        56908017
STOP     TM    OCTATTR2,HEX08      IS THIS MEDIUM STOP                  56912017
         BO    MSTOP               IF SO, BRANCH                        56916017
         DROP  3,4,7,8                                                  56920017
CKFSTOP  EQU   *                                                   EXTR 56922019
         L     RWKARPTR,CCTTIME    GET COMM PARAM LIST ADDRESS     EXTR 56924019
         L     RMSGADRS,0(RWKARPTR)     POINTER TO ECB             EXTR 56926019
         TM    ZERO(RMSGADRS),HEX10 IS THIS FAST STOP                   56929017
         BZ    BRANCHT            BRANCH IF NOT                         56932017
         B     SVCLOF             IMMEDIATE TERMINATION                 56942017
MSTOP    LA    RBR,TWELVE          SET A 12 RETURN CODE                 56962017
         MVI   CCTCSM,HEX08        SET LOGOFF CODE                      56965017
         CLC   CCTCCR(THREE),LOF     WAS LOGOFF IM CONTROL              56968017
         BE    SVCLOF       IF YES, BRANCH                              56971017
BRANCHT  EQU   *                                                        56976017
         B     CRETABLE(RBR)            BRANCH TO RETURN CODE TABLE     57000017
*                                                                       57200017
*      BRANCH ON RETURN CODES FROM PROCESSORS                           57400017
*                                                                       57600017
CRETABLE EQU   *                                                        57800017
         B     CNORMRET                 NORMAL CONDITION                58000017
         B     CREPEAT                  REPEAT (ENTER DATA)             58200017
         B     CFORBCK             DETERMINE IF FOREGROUND OR BACKGRND  58400017
         B     CCNCL                    CANCEL KEY DETECTED             58800017
         B     SVCLOF     BRANCH TO ISSUE SVC80                         58900017
         B     CCNCL                                                    59100017
         DS    XL4'0'              DUMMY ENTRY                          59130017
         B     FASTSTOP            ENTERED IERR BRANCH TO TERMINATE     59160017
         EJECT                                                          59200017
CNORMRET CLI   CCTSTAT,K           WAS PROCESSOR LINKED TO              59500017
         BE    CBEGN                    IS SO, GO BACK FOR ANOTHER PSR  59800017
         DELETE EPLOC=(RWKAREA)         DELETE LOADED PROCESSOR         60000017
WRITOK   CLC   CCTCCR(KEYLNTH),SPE        WAS PROCESSOR SPECIFY JOB     60020017
         BNE   MASKSET             BRANCH IF NOT                        60040017
         MVI   CCTCSM,HEX26        UPDATE COMMAND SELECT MASK           60060017
MASKSET  EQU   *                                                        60080017
         MVC   ZERO(CMSGLNGT,RBUFF),COKMESSG  PUT MESSAGE INTO BUFFER   60100017
         CLC   CCTCCR(THREE),LOGN  WAS PROCESSOR LOGON                  60102017
         BNE   NOTLON             IF NOT, BRANCH                        60104017
         L     RWORK,CCTGEND      GET ADDRESS OF SYSGEN DATA            60106017
         MVC   FOUR(FOUR,RBUFF),SGLINE(RWORK) PUT LN CT SYS TYP IN CCT  60108017
         LA    RWORK,EIGHT        SET RECORD LENGTH TO EIGHT            60110017
         B     MSGSET                                                   60112017
NOTLON   EQU   *                                                        60114017
         LA    RWORK,CMSGLNGT     SET DATA LENGTH                       60120017
MSGSET   EQU   *                                                        60160017
         BAL   RBAL,CWRITE              GO TO WRITE MESSAGE             60200017
         B     CBEGN                    GO FOR ANOTHER PROC SELECT RCD  60400017
CREPEAT  MVC   ZERO(CMSGLNGT,RBUFF),COKMESSG  PUT MSG INTO BUFFER       60500017
         LA    RWORK,CMSGLNGT                SET DATA LENGTH            60720017
         BAL   RBAL,CWRITE              GO TO WRITE MESSAGE             60800017
         LA    RPAR0,CRDONCD      SET CODE TO READ ONLY                 60820017
         LA    RWORK,CCTPWKAL     GET LENGTH OF WORKAREA                60840017
         LA    RWORK,TWO(RWORK)    INCREMENT BY TWO                     60860017
         ST    RWORK,CCTRECLN     PUT LENGTH IN CCT                     60880017
         BAL   RBAL,CREQIO        GO TO PERFORM I/O                     60900017
         L     RWORK,CCTHSN       GET HISTORY SEQUENCE NUMBER           60920017
         LA    RWORK,ONE(RWORK)    INCREMENT BY ONE                     60940017
         STH   RWORK,CCTHSN+TWO    RESTORE IN CCT                       60960017
         B     CEXTRCD                  GET ANOTHER EXTRACT RECORD      61000017
CCNCL    DELETE  EPLOC=(RWKAREA)   DE3 ETE LOADED PROCESSOR             61020017
         TM    CCTPSTAT+ONE,HEX40  ANY MESSAGES TO BE DISPLAYED         61021017
         BO    MSGTOBED           IF YES BRANCH                         61022017
         CLI   CCTCSM,HEX08        IS CSM SET FOR LOGOFF                61032017
         BNE   TESTWRI             IF NOT, BRANCH                       61042017
         LA    RWORK,LMSGLNTH     SET LENGTH OF LOGOFF MESSAGE          61080017
         MVC   ZERO(LMSGLNTH,RBUFF),LFMSG  PUT LOGOFF MESSAGE IN BUFFER 61100017
         BAL   RBAL,CWRITE                                              61120017
         B     CBEGN              GO GET LOGOFF PSR                     61123017
TESTWRI  CLI   CCTSTAT+TWO,M       WAS END KEY FUNCTION PERFORMED       61126017
         BNE   TESTN            IF NOT, BRANCH                          61129017
         MVI   CCTSTAT+TWO,HEX00   ZERO M SWITCH                        61132017
         CLC   CCTCCR(KEYLNTH),WRI WAS KEY FOR WRITE MESSAGE            61135017
         BE    WRITOK             IF YES GO WRITE OK MESSAGE            61138017
         CLC   CCTCCR(THREE),REC        WAS RECALL IN CONTROL           61139017
         BE    CBEGN               IF YES, BRANCH                       61140017
         MVC   ZERO(JMSGLNTH,RBUFF),JLMSG  PUT JOBLIB MSG IN BUFFER     61141017
         LA    RWORK,JMSGLNTH     SET MESSAGE LENGTH                    61144017
         BAL   RBAL,CWRITE        GO FOR I/O OPERATION                  61147017
         B     CBEGN              GO GET NEXT PSR                       61150017
MSGTOBED L     RBUFF,CCTBUFFP     INITIALIZE POINTER TO BUFFER          61159017
         SR    RLNTH,RLNTH        CLEAR A LENGTH REGISTER               61162017
         BAL   RBAL,PROCMSG       GO TO HANDLE MESSAGES                 61165017
         ST    RLNTH,CCTRECLN     PUT LENGTH INTO CCT                   61168017
         LA    RPAR0,CWRCODE      SET CODE TO WRITE                     61171017
         BAL   RBAL,CREQIO        GO TO PERFORM I/O                     61174017
DECHSN   CLC   CCTCCR(THREE),REC    WAS PROCESSOR RECALL                61175017
         BE    CBEGN              IF YES, BRANCH                        61176017
         L     RWORK,CCTHSN      GET HSN                                61177017
         BCTR  RWORK,ZERO          DECREMENT BY ONE                     61180017
         STH   RWORK,CCTHSN+TWO    RESTORE INTO CCT                     61183017
         B     CBEGN              GO TO READ A PSR                      61186017
TESTN    CLI   CCTSTAT+TWO,N   WAS WTOR REQUESTES                       61186117
         BNE   DECHSN     IF NOT, BRANCH                                61186217
         MVI   CCTSTAT+TWO,HEX00   CLEAR INDICATOR                      61186317
         B     CBEGN          GO READ A PSR                             61186417
*                                                                       61186617
* INFORM GFX THAT LOGOFF HAS OCCURRED                                   61187217
*                                                                       61187817
SVCLOF   EQU   *                                                        61188417
         MVC   CCTPWKA(LPARM),SVCPARM  PUT SVC LIST INTO WORKAREA       61189017
         MVC   CCTPWKA(FOUR),PLOG  MOVE CONSTANT FOR LOGOFF INTO LIST   61189617
         MVC   CCTPWKA+DUNIT(THREE),CCTUNIT  PUT UNIT ADDRESS INTO LIST 61190217
         LR    RPAR1,RCCT        SET POINTER TO CCT                     61190417
         LA    RPAR0,CCTPWKA       GET POINTER TO LIST                  61190617
         SVC   80                 INFORM GFX                            61190817
         L     RWKARPTR,CCTTIME    GET COMM PARAM LIST ADDRESS     EXTR 61191019
         L     RMSGADRS,0(RWKARPTR)     POINTER TO ECB             EXTR 61191219
         TM    ZERO(RMSGADRS),HEX10      IS THIS FAST STOP              61191417
         BZ    CRETURN       IF NOT, BRANCH TO NORMAL RETURN            61191617
         CLC   CCTCCR(THREE),LOF    IS PROCESSOR LOGOFF                 61191817
         BE    CRETURN            IF YES, GO TO RETURN                  61192017
         CLC   CCTCCR(THREE),BEG  IS PROCESSOR BEGIN JOB                61192217
         BE    CRETURN            IF YES, GO TO RETURN                  61192417
FASTSTOP CLI   CCTSTAT,D           WAS PROCESSOR LOADED                 61193217
         BNE   GOSCH               IF NOT, BRANCH                       61193817
         DELETE EPLOC=(RWKAREA)    YES, DELETE PROCESSOR                61194417
GOSCH    MVC   CCTCWKA(EIGHT),SCHMOD  PUT SCHEDULAR NAME IN WORKAREA    61195017
         LR    RPAR1,RCCT          SET CCT ADDRESS                      61195617
         O     RPAR1,HBITON        SIGNAL LOGOFF TIME                   61196217
         LA    RPAR0,HEX1C        SET REG0 TO HEX 1C                    61196517
         LA    RBR,CCTPWKA+SUPLIST  LOAD ADDRESS OF PARAMETER LIST      61196817
         MVI   ZERO(RBR),HEX00     CLEAR AREA                           61197417
         MVC   ONE(SEVEN,RBR),ZERO(RBR)  FOR PARAMETER LIST             61198017
         LINK  EPLOC=(RWKAREA),MF=(E,(1)),SF=(E,(15))  GO TO IKASCH     61198617
         B     CRETURN             BRANCH TO RETURN                     61199217
         EJECT                                                          61200017
CFORBCK  EQU   *                                                        62200017
         MVC   CCTPWKA(LPARM),SVCPARM MOVE PARMLIST INTO WORKAREA       63400017
         MVC   CCTPWKA+DUNIT(THREE),CCTUNIT  PUT LINE ADDRSS IN LIST    63600017
         LA    RWORK,CCTPWKA+NUMBER  GET ADDRESS OF AN AREA             63800017
         N     RWORK,DOUBLE        PUT IT ON DOUBLE WORD BOUNDRY        64000017
         LH    RMISC,CCTJCTR      GET JOB COUNT                         64200017
         CVD   RMISC,ZERO(RWORK)   CONVERT IT TO DECIMAL                64300017
         UNPK  CCTPWKA+SVNTYTWO(FIVE),FIVE(THREE,RWORK)  CHANGE TO EBC  64400017
         OI    CCTPWKA+SVNTYSIX,HEXF0   CHANGE LOW ORDER ZONE           64500017
         MVC   CCTPWKA+JOBCOUNT(FOUR),CCTPWKA+SVNTYTHR  PUT IN SVC LIST 64600017
         MVC   CCTPWKA+EXTNOTE(FOUR),CCTENOTE  PUT EXT NOTE IN LIST     64700017
         TM    CCTPSTAT,HEX10      IS THIS BACKGROUND JOB               64800017
         BC    1,BACKGD           BRANCH IF YES                         65320017
         MVI   CCTPWKA+FBCKGRND,HEX00   SET FG INDICATOR                65370017
SVC80    TM    CCTSSTAT,HEX40      IS EXT1 CURRENT DATA SET             65420017
         BZ    LDCCTADD           IF NOT, BRANCH                        65480017
         OI    CCTPWKA+EXTNOTE+THREE,HEXF0  INDICATE CURRENT DATA SET   65520017
LDCCTADD EQU   *                                                        65560017
         LR    RPAR1,RCCT          ADDRESS OF CCT AND                   65600017
         LA    RPAR0,CCTPWKA       ADDRESS OF PARAM LIST FOR SVCROUTINE 65800017
         SVC   80                  ISSUE SVC ROUTINE                    66000017
         TM    CCTPSTAT,HEX10      IS THIS BACKGROUND JOB               66060017
         BC    1,BACKGRND         BRANCH IF YES                         66120017
CRETURN  L     RSAVE,CCTCSAVE+FOUR   RESTORE REGISTER 13                66220017
         LR    RPAR1,RCCT          CCT ADDRESS                          66400017
         LA    RWORK,EIGHT         SET UP REGISTER WITH 8               66500017
         SR    RPAR1,RWORK         DECREMENT CCT ADDR BY 8              66600017
         L     RPAR0,ZERO(RPAR1)   GET LENGTH OF CCT                    66700017
         FREEMAIN R,LV=(0),A=(1)   FREE CORE                            67000017
         RETURN   (14,12),RC=0     RETURN TO OS                         67400017
*                                                                       67600017
* IT IS A BACKGROUND JOB                                                67800017
*                                                                       68000017
BACKGD   MVI   CCTPWKA+FBCKGRND,HEXFF   PUT BG CODE IN SVC LIST         68060017
         B     SVC80              BRANCH TO ISSUE SVC 80                68120017
BACKGRND MVI   CCTJDCBP,HEX80      SET OPTION BYTE FOR CLOSE            68320017
         LA    RPAR1,CCTJDCBP      LOAD PARAMETER ADDRESS               68600017
         CLOSE MF=(E,(1))                                               68800017
         MVI   CCTJDCBP,HEX83      SET OPTION BYTE FOR OPEN             69000017
         LA    RPAR1,CCTJDCBP      LOAD PARAMETER ADDRESS               69200017
         OPEN  MF=(E,(1))                                               69400017
         MVI   CCTJDCBP,HEX00      CLEAR OPTION BYTE                    69600017
         LA    RPAR0,NOTE1         NOTE NUMBER ADDRESS                  69800017
         L     RPAR1,CCTEDCBP      DCB ADDRESS                          70000017
         POINT (1),(0)                                                  70200017
         LOAD  EP=IKDNUC                                                71600017
         LR    RNUC,RPAR0          GET ADDRESS OF LOADED ROUTINE        71800017
         MVC   CCTIORP(FOUR),ZERO(RNUC)    PUT ADDRESSES OF IKDIOR,     71900017
         MVC   CCTMSGP(FOUR),FOUR(RNUC)    IKDMSG,                      72000017
         MVC   CCTJCLGP(FOUR),EIGHT(RNUC)                               72100017
         MVC   CCTDIARP(FOUR),TWELVE(RNUC) IKADIA &                     72200017
         MVC   CCTGEND(FOUR),SIXTEEN(RNUC) IKASGD IN CCT                72300017
         LOAD  EP=IKAIERR         GET ERROR ROUTINE IN CORE             72840017
         ST    RPAR0,CCTIERRP      PUT ADDRESS IB CCT                   72880017
         LA    RPAR0,TWELVE       SET INIT PSWD CODE TO TWELVE          72890017
         ST    RPAR0,CCTIELST     PUT INTO CCT                          72900017
         LA    RPAR0,SIXTEEN       SET INITIALIZATION CODE              72920017
         BAL   RBAL,CREQIO        GO TO INITIALIZE PTOP                 72960017
         OI    CCTPSTAT,HEXC0      REINITIALIZE                         73160017
         NI    CCTPSTAT,HEXCF      CCTPSTAT                             73360017
         MVI   CCTDISM,HEX00       RESET DISM                           73560017
         MVI   CCTCSM,HEX21        RESET COMMAND SELECT MASK            73760017
         B     CBEGN               GET A PSR                            73960017
         EJECT                                                          74400017
*                                                                       74600017
*      THE FOLLOWING CODE SETS UP FOR AND PERFORMS THE BRANCH TO THE    74800017
*      I/O ROUTINE TO WRITE TO THE 1130 SYSTEM                          75000017
*                                                                       75200017
CWRITE   EQU   *                                                        75400017
         LA    RPAR0,CWRCODE            CODE FOR WRITE                  75600017
         ST    RWORK,CCTRECLN           UPDATE CCT WITH LENGTH          76000017
CREQIO   EQU   *                                                        76600017
         L     RBR,CCTIORP         ADDRESS OF I/O ROUTINE               76800017
         LR    RPAR1,RCCT          ADDRESS OF CCT                       77000017
         BALR  RRET,RBR            GO TO I/O ROUTINE                    77200017
         LTR   RBR,RBR             WAS IKAIERR ENTERED                  77300017
         BNE   FASTSTOP            IF YES, BRANCH TO RETURN             77400017
         BR    RBAL                RETURN TO CALLER                     77500017
         EJECT                                                          77600017
*                                                                       77604017
* THIS SUBROUTINE MOVES ANY MESSAGES FROM THE PROCESSOR WORKAREA,       77608017
* AND PLACES THEM INTO THE T/O BUFFER FROM WHICH THEY WILL BE SENT TO   77612017
* THE 1130 SUBSYSTEM TO BE DISPLAYED.                                   77616017
*                                                                       77620017
PROCMSG  LA    RWKARPTR,CCTPWKA    SET POINTER TO PROCESSOR WORKAREA    77624017
TESTLAST TM    ZERO(RWKARPTR),HEXC0  TEST FOR LAST MESSAGE              77628017
         BM    NOTLAST             NOT LAST, SO BRANCH                  77632017
         MVI   CCTPSTAT+ONE,HEX00       TURN OFF MSG SWITCH             77636017
NOTLAST  L     RMSGADRS,ZERO(RWKARPTR)  GET MESSAGE ADDRESS             77640017
         SLL   RMSGADRS,TWO             SHIFT OUT OPTION BYTE           77644017
         SRL   RMSGADRS,TWO             RESTORE POSITION                77648017
         SR    RLCHAR,RLCHAR       CLEAR LENGTH OF MESSAGE REGISTER     77652017
         IC    RLCHAR,ZERO(RMSGADRS)    GET LENGTH OF MESSAGE           77656017
         MVC   ONE(ONE,RBUFF),ZERO(RMSGADRS)  PUT LENGTH INTO BUFFER    77660017
         CLI   CCTPSTAT+ONE,HEX00   IS THIS LAST MESSAGE                77664017
         BE    SETLAST              IF YES, BRANCH                      77668017
         MVI   ZERO(RBUFF),HEX00    INDICATE NOT LAST MESSAGE           77672017
         B     MOVEMSG              BRANCH                              77676017
SETLAST  MVI   ZERO(RBUFF),HEX80    INDICATE LAST MESSAGE               77680017
MOVEMSG  LA    RBUFF,TWO(RBUFF)     SET BUFFER POINTER TO NEXT LOCATION 77684017
         LA    RLNTH,TWO(RLNTH)     INCREMENT LENGTH BY TWO             77688017
         BCTR  RLCHAR,ZERO          DECREMENT COUNT BY ONE              77692017
         EX    RLCHAR,MOVEDATA     EXECUTE MOVE TO PUT DATA INTO BUFFER 77696017
         LA    RLCHAR,ONE(RLCHAR)   INCREMENT BY ONE                    77700017
         AR    RBUFF,RLCHAR        SET BUFFER POINTER TO NEXT LOCATION  77704017
         AR    RLNTH,RLCHAR        SET CURRENT LENGTH                   77708017
         TM    ZERO(RMSGADRS),HEX01 IS COUNT ODD OR EVEN                77712017
         BZ    EVENCT              COUNT IS EVEN, BRANCH                77716017
         MVI   ZERO(RBUFF),HEX40   PUT BLANK IN BUFFER                  77720017
         LA    RBUFF,ONE(RBUFF)    INCREMENT PTR BY ONE                 77724017
         LA    RLNTH,ONE(RLNTH)    INCREMENT LENGTH BY ONE              77728017
EVENCT   CLI   CCTPSTAT+ONE,HEX00  WAS THIS LAST MESSAGE                77732017
         BE    RTRN                BRANCH TO RETRUN                     77736017
         LA    RWKARPTR,FOUR(RWKARPTR)  INCREMENT PTR TO NEXT MESSAGE   77740017
         B     TESTLAST            BRANCH TO CONTINUE                   77744017
RTRN     BR    RBAL                RETURN TO CALLER                     77748017
*                                                                       77756017
MOVEDATA MVC   ZERO(ZERO,RBUFF),ONE(RMSGADRS)  MOVE MESSAGE             77760017
*                                                                       77764017
         EJECT                                                          77768017
*                                                                       77800017
*      CONSTANTS AND DSECT FOR CONSOLE CONTROL TABLE                    78000017
*                                                                       78200017
PROMODEL DC    C'IKAPLON0'         PROCESSOR MODEL NAME                 78290017
LOGN     DC    C'LON'              LOGON KEY                            78380017
BEG      DC    C'BEG'              BEGIN JOB KEY                        78470017
SPE      DC    C'SPE'              SPECIFY JOB STEP COMMANDLKEY         78560017
PLOG     DC    C'PLOG'            SVC CODE FOR LOGOFF                   78650017
SCHMOD   DC    C'IKASCH  '         SCHEDULAR INTERFACE MODULE NAME      78740017
LOF      DC    C'LOF'       CONSTANT FOR LOGOFF PROCESSOR               78860017
CAN      DC    C'CAN'     CONSTANT FOR CANCEL JOB                       78920017
COKMESSG DC    C'EXOK'             OK MESSAGE                           78940017
LFMSG    DC    C'LF'               LOGOFF MSG                           79060017
JLMSG    DC    C'JOBLIB'          JOBLIB MESSAGE                        79120017
WRI      DC    C'WRI'              KEY FOR WRITE MSG                    79140017
REC      DC    C'REC'             RECALL COMMAND KEY                    79150017
NONE     DC    C'NONE'             NONE MESSAGE                         79160017
         DS    0F                                                       79200017
NOTE1    DC    X'00000001'         NOTE NUMBER                          79400017
HBITON   DC    X'80000000'         HI BIT MASK                          79600017
DOUBLE   DC    X'FFFFFFF8'         DOUBLE WORD BOUNDARY MASK            79800017
CANC     DC    H'12'              CANCEL RETURN CODE                    79900017
*                                                                       80000017
* PARAMETER LIST TO PASS TO SVC ROUTINE                                 80200017
*                                                                       80400017
SVCPARM  DS    0F                                                       80600017
SVCCODE  DC    C'PBEG'             CODE FOR BEGIN JOB                   80800017
SVCINFTN EQU   *                                                        81000017
SVCUNIT  DC    F'0'                LINE ADDRESS                         81200017
SVCJBCNT DC    F'0'                JOB COUNTER                          81400017
SVCENOTE DC    F'0'                NOTE NUMBER                          81600017
SVGFBCK  DC    X'00'               FORE OR BACKGROUND JOB               81800017
SVCEND   EQU   *                                                        82000017
LPARM    EQU   SVCEND-SVCPARM      LENGTH OF SVC PARAMETER LIST         82200017
*                                                                       82400017
* PARAMETER LIST TO PASS TO INTERNAL ERROR ROUTINE                      82401017
*                                                                       82402017
         DS    0F                                                       82403017
MSG11    DC    CL3'011'           MESSAGE NUMBER                        82404017
         DC    CL5'CTL  '         MODULE KEY WORD                       82405017
         DC    X'40'              CONTROL BITS                          82406017
         DC    AL3(OCTMESG)        ADDRESS OF MESSAGE                   82407017
*                                                                       82408017
OCTMESG  DC    H'4'           LENGTH OF ENTRY                           82409017
         DC    C'UNIT'        CONSTANT                                  82410017
IERRPAR  EQU   *                                                        82411017
MSGNO    DC    CL3'039'       MSG NO                                    82412017
         DC    CL5'CTL  '     IDENTIFIER                                82413017
         DC    X'00'          STATUS BIT                                82414017
         DC    XL4'00000000'  SPACE FOR POINTER                         82415017
         EJECT                                                          82416017
CVT      DSECT                                                          82417017
         CVT   SYS=VMS                                                  82418017
*                                                                       82419017
* GFX LIST POINTED TO BY CVT                                            82420017
*                                                                       82421017
GRAPLIST DSECT                                                          82422017
GOCT     DS    1F             POINTER TO OCT                            82423017
GGAPR    DS    1F             POINTER TO GAPR                           82424017
GCANC    DS    1F             POINTER TO CANCEL ROUTINE                 82425017
GFXOCTHD DSECT                                                          82426017
GFXHDSTR EQU   *                       START OF HEADER RECORD           82427017
OCTSYS   DS    CL1                     BASE SYSTEM                      82428017
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                82429017
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          82430017
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       82431017
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       82432017
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              82433017
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              82434017
         DS    0H                                                       82435017
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             82436017
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       82437017
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       82438017
         DS    0F                                                       82439017
OCTFGREG DS    CL4                      REGION SIZE GJP                 82440017
OCTFUREG DS    CL4                      REGION SIZE USER FGD            82441017
OCTBUREG DS    CL4                      REGION SIZE USER BGD            82442017
OCTHRES  DS    CL8                      RESERVED                        82443017
OCTNAME  DS    CL20                     PROGRAMMER NAME                 82444017
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  82445017
GFXHDEND EQU   *                       END OF HEADER RECORD             82446017
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        82447017
         EJECT                                                          82448017
GFXOCTEN DSECT                                                          82449017
         DS    0F                                                       82450017
GFXENSTR EQU   *                       START OF ENTRY RECORD            82451017
OCTECB   DS    CL4                      ECB                             82452017
OCTUCB   DS    CL4                      UCB ADDRESS                     82453017
OCTUNIT  DS    CL4                      UNIT ADDRESS                    82454017
OCTCOUNT DS    CL4                      JOB COUNT                       82455017
OCTNOTE  DS    CL4                      NOTE                            82456017
OCTABEND DS    A                       ABEND CODE                       82457017
OCTRESD  DS    CL8                      RESERVED                        82458017
**********************************************************************  82459017
****                          ATTRIBUTE 1                          **** 82460017
**********************************************************************  82461017
OCTATTR1 DS    CL2                      ATTRIBUTES                      82462017
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         82463017
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   82464017
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         82465017
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       82466017
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   82467017
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  82468017
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  82469017
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           82470017
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          82471017
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   82472017
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           82473017
**********************************************************************  82474017
****                          ATTRIBUTE 2                          **** 82475017
**********************************************************************  82476017
OCTATTR2 DS    CL2                      ATTRIBUTES                      82477017
OCTBIRRE EQU   X'80'          0-                  1-GJP INTERNAL ERROR  82478017
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      82479017
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              82480017
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           82481017
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         82482017
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           82483017
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       82484017
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            82485017
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  82486017
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  82487017
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        82488017
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         82489017
**********************************************************************  82490017
****                          ATTRIBUTE 3                          **** 82491017
**********************************************************************  82492017
OCTATTR3 DS    CL2                      ATTRIBUTES                      82493017
OCTBIERR EQU   X'80'          0-                  1-GJP INTERNAL ERROR  82494017
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB      82495017
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              82496017
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           82497017
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         82498017
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           82499017
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       82500017
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            82501017
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  82502017
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  82503017
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        82504017
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         82505017
**********************************************************************  82506017
****                          ATTRIBUTE 4                          **** 82507017
**********************************************************************  82508017
OCTATTR4 DS    CL2                      ATTRIBUTES                      82509017
*                                                                       82510017
GFXENEND EQU   *                       END OF ENTRY RECORD              82511017
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             82512017
         EJECT                                                          82513017
         EJECT                                                          82600017
*                                                                       82800017
         END                                                            83000017
