 TITLE 'IKDINPRO' INITIAL PROCESSOR                                     00700017
*STATUS: CHANGE LEVEL 000                                             * 01500017
*FUNCTION/OPERATION: ESTABLISH INITIAL COMMUNICATION WITH AN 1130/2250* 02500017
*   SUBSYSTEM UPON DETECTION OF A CANCEL KEY ATTENTION AT THE 2250.   * 03000017
*   IT'S OPERATIONS INCLUDE:                                          * 03500017
*   1) ISSUE GETMAIN FOR A BTAM DCB, A READ/WRITE DECB, AN I/O BUFFER * 04000017
*   AN A WORK AREA                                                    * 04500017
*   2) OPEN THE BTAM DCB                                              * 05000017
*   3) ISSUE BTAM READ INITIAL. UPON COMPLETION OF I/O, MATCH THE     * 05500017
*   PASSWORD RECEIVED FROM THE SUBSYSTEM WITH THAT OF SGJP.  IF THEY  * 06000017
*   MATCH, ISSUE BTAM READ CONTINUE TO SIGNIFY THE MATCH TO THE SUB-  * 06500017
*   SYSTEM, AND CONTINUE. IF THEY DO NOT MATCH, ISSUE BTAM WRITE RESET* 07000017
*   TO SIGNIFY THE NO-MATCH TO THE SUBSYSTEM, AND GO BACK AND READ    * 07500017
*   INITIAL.                                                          * 08000017
*   4)CLOSE BTAM DCB                                                  * 08500017
*   5)ISSUE SVC 80 TO CAUSE THE SETTING OF THE APPROPRIATE ATTRIBUTE  * 09000017
*   BITS IN GFX'S OVERALL CONTROL TABLE.                              * 09500017
*   6) ISSUE FREEMAIN TO RELEASE STORAGE                              * 10000017
*ENTRY POINTS: ENTERED AT IKDINPRO FROM OPERATING SYSTEM VIA LINK     * 10800017
*INPUT: PARAMETER LIST CONTAINING ADDRESS OF TELECOMMUNICATIONS LINE  * 11600017
*OUTPUT: ADDRESS OF PARAMETER LIST IN REGISTER 0 FOR SVC ROUTINE.     * 12500017
*   PARAMETER LIST CONTAINS:                                          * 13000017
*   +0 INPUT CODE                                                     * 13700017
*   +4 LINE ADDRESS                                                   * 14400017
*EXTERNAL ROUTINES: BTAM I/O MODULES, SVC80                           * 15100017
*EXITS-NORMAL: RETURN TO OPERATING SYSTEM VIA RETURN MACRO            * 15800017
*     -ERROR: RETURN TO OPERATING SYSTEM VIA RETURN MACRO             * 16500017
*TABLES/WORKAREAS: BUFFER                                             * 17200017
*ATTRIBUTES: REUSABLE                                                 * 17900017
*NOTES: N/A                                                           * 18600017
         EJECT                                                          19500017
IKDINPRO CSECT                                                          20000017
*3302,263200-263500,332800-333100,336400-338400,394200,775200,     R018 20100018
*     779200-783200                                                R018 20200018
*     312000-312500,729800                                         R018 20300018
* 461000-463000                                                  A40766 20350020
*                                                                       20500017
* GENERAL REGISTERS                                                     21000017
*                                                                       21500017
RPAR0    EQU   0                                                        22000017
RPAR1    EQU   1                                                        22500017
RINCR    EQU   2                                                        23000017
RCOUNT   EQU   2                                                        23200017
RWORK    EQU   3                                                        23500017
RDECB    EQU   4                                                        24000017
RBUFFER  EQU   5                                                        24500017
RDCB     EQU   6                                                        25000017
RCVT     EQU   7                                                        25100017
ROCT     EQU   8                                                        25200017
RBAL     EQU   9                                                        25270017
RCODE    EQU   10                                                       25340017
RSEC     EQU   11                                                       25410017
RBASE    EQU   12                                                       25500017
RSAVE    EQU   13                                                       26000017
RBR      EQU   15                  EQUATE                               26100017
MSGLNTH  EQU   10                                                       26200017
*                                                                       26210017
* EQUATES                                                               26220017
*                                                                       26230017
ZERO     EQU   0              EQUATE FOR ZERO                           26240017
ONE      EQU   1              EQUATE FOR ONE                            26250017
TWO      EQU   2              EQUATE FOR TWO                            26260017
THREE    EQU   3              EQUATE FOR THREE                          26270017
FOUR     EQU   4              EQUATE FOR FOUR                           26280017
FIVE     EQU   5                                                        26285017
SIX      EQU   6                                                        26290017
EIGHT    EQU   8              EQUATE FOR EIGHT                          26300017
NINE     EQU   9              EQUATE FOR NINE                           26310017
SIXTEEN  EQU   16                                                  R018 26320000
XX       EQU   20             DISPLACEMENT IN TCB FOR ABEND HOOK FLAG   26335017
ONTWSVN  EQU   127                                                      26360017
UNOPENED EQU   X'10'               ON FOR SUCCESSFUL OPEN               26370017
DBLEZERO EQU   X'00'                                                    26380017
STOPBIT  EQU   X'10'          STOP BIT MASK                             26390017
HEX20    EQU   X'20'               EQUATE                               26395017
POSTCODE EQU   X'7F'          COMPLETION CODE                           26400017
CANCEL   EQU   C'C'                                                     26410017
RETRY    EQU   C'R'                                                     26420017
         EJECT                                                          26430017
         SAVE  (14,12)             SAVE REGISTERS                       26500017
         BALR  RBASE,0             SET UP BASE                          27000017
         USING *,RBASE                                                  27500017
         ST    RSAVE,INPROSAV+FOUR   SAVE CALLERS SAVE ADDRESS          28500017
         LA    RWORK,INPROSAV      CHAIN SAVE AREAS                     30000017
         ST    RWORK,EIGHT(RSAVE)   CHAIN SAVE AREAS                    30500017
         LR    RSAVE,RWORK         SET R13 TO OUR SAVE ADDRESS          31000017
         L     RCVT,CVTPTR              GET ADDR OF CVT                 31010017
         USING DCVT,RCVT                ADDRESSABILITY                  31020017
         L     RWORK,CVTTCBP            GET ADDR OF TCB POINTER         31030017
         L     RWORK,FOUR(RWORK)        ADDR OF TCB                     31040017
         OI    XX(RWORK),HEX20     SET BIT FOR ABEND ROUTINE            31050017
         ST    RPAR1,ADPARM        SAVE ADDRESS OF PARAMETER LIST       31100017
         EXTRACT ANSWAREA,FIELDS=COMM   GET ADDR OF COMM.PARM.LIST EXTR 31150019
         L     RPAR1,ANSWAREA           POINTER TO COMM.PARM.LIST  EXTR 31200019
         L     RPAR1,FOUR(RPAR1)        GET CIB ADDRESS            EXTR 31250019
         LR    RINCR,RPAR1                                              31300017
         LA    RINCR,ONTWSVN(RINCR) SET END OF CIB ADDRESS              31400017
SCANCIB  CLC   ZERO(NINE,RPAR1),ENTRYEQU  SCAN CIB FOR OCT HEADER       31500017
         BE    FOUNDADR            FOUND OCTENTRY= IN CIB               31600017
         LA    RPAR1,ONE(RPAR1)   NOT FOUND, INCREMENT BY ONE           31700017
         CR    RINCR,RPAR1              Q. LIMIT REACHED                31800017
         BNE   SCANCIB                  NO, CONTINUE SEARCHING          31900017
         B     RETURN                   EXIT WHEN END REACHED           32000017
FOUNDADR L     RCVT,CVTPTR         SET BASE FOR CVT                     32300017
         USING DCVT,RCVT                                                32400017
         L     ROCT,CVTQOCR        ADDRESS OF LIST OF POINTERS          32500017
         LTR   ROCT,ROCT          IS REGISTER ZERO                      32530017
         BE    RETURN             IF YES BRANCH TO RETURN               32560017
         L     ROCT,ZERO(ROCT)    GET ADDRESS OF OCT HEADER             32630017
         USING GFXOCTHD,ROCT                                            32700017
         LH    RWORK,OCTUNBR       GET NUMBER OF 2250'S ATTACHED        32730017
         ST    RWORK,NUNITS                                             32760017
         LA    ROCT,GFXHDSZE(ROCT) SET BASE FOR OCT ENTRY               32800017
         USING GFXOCTEN,ROCT                                            32900017
         L     RINCR,NUNITS        GET NUMBER OF UNITS                  32950017
*    SEARCH FOR THE ENTRY IN THE OCT                                    33000017
SCANENT  CLC   NINE(THREE,RPAR1),OCTUNIT+ONE  IS THIS CORRECT ENTRY     33050017
         BE    FOUNDENT            YES, BRANCH                          33100017
         LA    ROCT,GFXENSZE(ROCT)  NO, GO TO CHECK NEXT ENTRY          33200017
         BCT   RINCR,SCANENT       CONTINUE SEARCH                      33250017
         MVC   NOTINCIB+SIXTEEN(THREE),NINE(RPAR1) ADDR NOT FOUND  R018 33270000
NOTINCIB WTO   'IKA059I XXX - INVALID UNIT ADDRESS IN CIB',ROUTCDE=2,  *33290000
               DESC=4                                              R018 33310000
         B     RETURN                                                   33340017
FOUNDENT MVC   SVCUNIT+ONE(THREE),OCTUNIT+ONE  MOVE UNIT ADDRESS INTO   33440017
         MVC   KLOFUTN+ONE(THREE),OCTUNIT+ONE  SVC PARAMETER LISTS      33540017
         MVC   WTO5+SIXTEEN(THREE),OCTUNIT+ONE  SET UP UNIT NAME   R018 33640000
*                                                     IN MESSAGE   R018 33740000
         MVC   IOMSG+XX(THREE),OCTUNIT+ONE  PUT UNIT ADDRESS IN    R018 33840000
         MVC   INITMSG+XX(THREE),OCTUNIT+ONE  TWO ERROR MSGS       R018 33940000
         CLC   OCTATTR1(8),ZEROS8       Q. OCT ENTRY VALID         R018 33990018
         BE    RETURN                   NO - TERMINATE             R018 34040018
MINUSONE EQU   X'FFF0'                                                  34100017
         CHAP  MINUSONE            CHANGE PRIORITY                      34800017
*                                                                       35500017
* OPEN BTAM DCB                                                         36000017
*                                                                       36500017
         LA    RPAR1,BTAMOPEN      SET REG 1 TO POINT TO DCB LIST       37500017
         IC    RWORK,CHAR   GET OPTION BYTE                             38000017
         STC   RWORK,BTAMOPEN     SET OPTION BYTE IN OUEN LIST          38500017
         OPEN  BTAMDCB,MF=(E,(1))                                       39000017
         TM    OPENFLAG,UNOPENED   Q. OPEN SUCCESSFUL                   39070017
         BO    SETPWD00           YES, GO TO MOVE FIRST PASSWORD        39140017
*                                                                       39210017
*    INDICATE DCB NOT OPENED                                            39280017
*                                                                       39350017
WTO5     WTO   'IKD005I XXX - DCB NOT OPENED',ROUTCDE=(2,8),DESC=4 R018 39420000
*                                                                       39490017
*    ISSUE LOGOFF'S SVC                                                 39560017
*                                                                       39630017
LOGOFF   EQU   *                   COMMON ENTRY POINT                   39700017
         LA    RPAR0,KLOF          ADDR OF PARM LIST                    39770017
         SVC   80                  NOTIFY GFX                           39840017
         B     RETURN              END PROCESSING                       39910017
SETPWD00 MVC   PASSWD(SIX),PASSWD00  PUT FIRST PASSWORD IM MODEL        39940017
         LA    RCOUNT,FIVE          SET A COUNT OF FIVE                 39970017
         EJECT                                                          40000017
*                                                                       40500017
* ISSUE BTAM READ TO GET PASSWORD FROM THE 1130. WAIT FOR I/O COMPLET-  41000017
* ION                                                                   41500017
*                                                                       42000017
ISREAD   SR    RCODE,RCODE         SET INDICATOR REGISTER TO ZERO       42500017
         LA    RDECB,BTAMREAD                                           43000017
         XC    ZERO(FOUR,RDECB),ZERO(RDECB)  CLEAR  ECB                 43500017
         LA    RBUFFER,INBUFFR     SET POINTER TO I/O AREA              44000017
         LA    RDCB,BTAMDCB       SET POINTER TO DCB                    44500017
         READ  (RDECB),TI,(RDCB),(RBUFFER),14,,1,MF=E                   45500017
         CH    RBR,KXX             Q. ENABLE COMMAND GOOD IN OPEN       45560017
         BE    WTO5                NO - EXIT                            45620017
         LA    RSEC,ONESEC         SET POINTER TO SECOND                45700017
WAITIMER STIMER WAIT,TUINTVL=(11)  SET TIMER FOR ONE SECOND             45900017
         L     RWORK,ANSWAREA      GET POINTER TO PARAMETER LIST A40766 46100020
         L     RWORK,ZERO(RWORK)    GET POINTER TO ECB           A40766 46300020
         TM    ZERO(RWORK),STOPBIT  WAS STOP COMMAND ISSUED             46500017
         BO    LOGOFF                   BRANCH TO LOGOFF                46700017
         CLI   ZERO(RDECB),DBLEZERO WAS ECB POSTED                      46900017
         BNE   TESTCOD             IF SO, CHECK COMPLETION CODE         47100017
         B     WAITIMER                                                 47300017
TESTCOD  CLI   ZERO(RDECB),POSTCODE   CHECK FOR GOOD I/O                47600017
         BNE   INIOERR             IF ERROR, BRANCH                     48000017
         CLC   INBUFFR+SIX(SIX),PASSWD  CHECK FOR PASSWORD MATCH        48500017
         BNE   PASSWDER            NO MATCH SO BRANCH                   49000017
*                                                                       49500017
* PASSWORDS MATCH                                                       50000017
*                                                                       50500017
MATCH    EQU   *                                                        50800017
         XC    ZERO(FOUR,RDECB),ZERO(RDECB)  CLEAR  ECB                 51200017
         READ  (RDECB),TT,(RDCB),(RBUFFER),14,,1,MF=E                   52000017
         WAIT  ECB=(RDECB)                                              52500017
*                                                                       53030017
* READS INDICATING SUCCESSFUL INITIALIZATION ARE COMPLETE.  NOW XMIT    53060017
* END MASSAGE TO THE 1130.                                              53090017
*                                                                       53120017
ISWRITE  LA    RCODE,ONE        SET INDICATOR TO ONE                    53150017
         MVC   INBUFFR(MSGLNTH),ENDMSG   PUT MESSAGE INTO BUFFER        53180017
         XC    ZERO(FOUR,RDECB),ZERO(RDECB)  CLEAR ECB                  53210017
         WRITE (RDECB),TIXR,(RDCB),(RBUFFER),10,,1,MF=E  WRITE MESSAGE  53240017
         WAIT  ECB=(RDECB)         WAIT FOR I/O COMPLETE                53270017
         CLI   ZERO(RDECB),POSTCODE     CHECK FOR GOOD I/O              53310017
         BNE   INIOERR             IF NOT GOOD BRANCH                   53360017
         CLC   PASSWD(SIX),PASSWD01  IS THIS SECOND PASSWORD            53380017
         BE    BTAMEND            IF YES, BRANCH TO CLOSE BTAM          53400017
         MVC   PASSWD(SIX),PASSWD01  PUT SECOND PASSWORD INTO MODEL     53420017
         LA    RCOUNT,FIVE        RESET A COUNT OF FIVE                 53440017
         B     ISREAD            GO TO ISSUE BTAM READ                  53460017
SET00    MVC   PASSWD(SIX),PASSWD00  RESET 00 IN MODEL                  53468017
         B     MATCH                 BRANCH TO READ CONTINUE            53476017
SET01    MVC   PASSWD(SIX),PASSWD01  RESET 01 IN MODEL                  53484017
         B     MATCH              BRANCH TO READ CONTINUE               53492017
         EJECT                                                          53500017
*                                                                       54000017
* I/O IS COMPLETED. CLOSE BTAM DCB                                      54500017
BTAMEND  EQU   *                                                        55200017
         IC    RWORK,CHAR                                               56000017
         STC   RWORK,BTAMOPEN                                           56500017
         LA    RPAR1,BTAMOPEN      SET POINTER TO DCB                   57000017
         CLOSE BTAMDCB,MF=(E,(1))                                       57500017
*                                                                       58500017
* SET UP FOR SVC EXIT TO POST BITS IN GFX'S OVERALL CONTROL TABLE       59000017
*                                                                       59500017
         LA    RPAR0,SVCPARM       SET POINTER TO PARAMETER LIST        60500017
         SVC   80                       ISSUE CALL TO SVC 80            61500017
*                                                                       62500017
* PROCESSING IS COMPLETED. FREE STORAGE AND RETURN TO O/S               63000017
*                                                                       63500017
RETURN   L     RSAVE,INPROSAV+FOUR      RESTORE REGISTER 13             64500017
         RETURN (14,12),RC=0                                            65500017
INIOERR  LA    RPAR1,IOMSG         SET R1 TO POINT TO MESSAGE           65800017
         BAL   RBAL,WTOR           GO WRITE MESSAGE                     66100017
         LTR   RCODE,RCODE         CHECK IF ERROR ON READ OR WRITE      66400017
         BE    ISREAD              ERROR ON READ                        66700017
         B     ISWRITE             ERROR ON WRITE                       67000017
PASSWDER EQU   *                                                        67500017
         CLC   INBUFFR+SIX(SIX),PASSWD00      WAS PASSWORD 00 RE AD     67600017
         BE    SET00                                                    67700017
         CLC   INBUFFR+SIX(SIX),PASSWD01 WAS 01 READ                    67800017
         BE    SET01              IF YES, BRANCH                        67900017
         XC    ZERO(FOUR,RDECB),ZERO(RDECB)   CLEAR ECB                 68200017
         WRITE (RDECB),TR,(RDCB),(RBUFFER),,,1,MF=E                     69000017
         WAIT  ECB=(RDECB)        WAIT FOR I/O COMPLETION               69050017
         CLI   ZERO(RDECB),POSTCODE     CHECK FOR GOOD I/O              69100017
         BNE   INIOERR             IF NOT GOOD, BRANCH                  69150017
         LTR   RCOUNT,RCOUNT     IS INITIALIZATION COUNT ZERO           69200017
         BNE   DECNT              IF NOT, BRANCH                        69250017
         LA    RPAR1,INITMSG       SET R1 TO POINT TO MESSAGE           69300017
         BAL   RBAL,WTOR           GO TO WRITE MESSAGE                  69600017
         B     ISREAD              RE-ISSUE A READ                      69700017
DECNT    BCTR  RCOUNT,0           SUBTRACT COUNT BY ONE                 69730017
         B     ISREAD             GO ISSUE A READ                       69760017
WTOR     XC    WTORECB(FOUR),WTORECB   CLEAR ECB                        69800017
         XC    WTOREPLY(FOUR),WTOREPLY CLEAR REPLY AREA                 69900017
         WTOR  ,,,,MF=(E,(1))      WTOR                                 70150017
         WAIT  ECB=WTORECB                                              70200017
         CLI   WTOREPLY,CANCEL     WAS REQUEST CANCELLED                70250017
         BE    LOGOFF              IF SO, RETURN                        70300017
         CLI   WTOREPLY,RETRY      WAS RETRY REQUESTED                  70350017
         BNE   WTOR                IF NOT, WRITE AGAIN                  70400017
         BR    RBAL                GO BACK TO RETRY                     70450017
         EJECT                                                          70500017
*                                                                       71000017
* CONSTANTS AND WORKAREAS                                               71500017
*                                                                       72000017
PASSWD   DC    C'      '          AREA FOR PASSWORD MODEL               72100017
PASSWD00 DC    C'SGJP00'          PASSWORD 00                           72200017
PASSWD01 DC    C'SGJP01'          PASSWORD 01                           72300017
ZEROS8   DC    X'0000000000000000'      EIGHT BYTES OF ZERO        R018 72400018
ENTRYEQU DC    CL9'OCTENTRY='      START OF OCT HEADER IDENTIFIER       72600017
* PARAMETERS FOR SVC ROUTINE                                            72910017
SVCPARM  DS    0F                  PARAMETER LIST ON FULL WORD BOUNDARY 72920017
SVCCODE  DC    C'NPRO'             INITIAL PROCESSOR CODE               72930017
SVCUNIT  DC    C'0XXX'             SPACE FOR UNIT NUMBER                72940017
NUNITS   DC    F'0'                WORD CONTAINING # OF UNITS           72950017
KLOF     DC    C'PLOG'             LOG OFF CODE                         72955017
KLOFUTN  DC    C' ...'             UNIT IDENTIFICATION                  72960017
WTORECB  DC    F'0'                WTOR ECB                             72965017
WTOREPLY DC    F'0'                WTOR REPLY AREA                      72970017
ONESEC   DC    F'38462'            ONE SECOND TIMER ELEMENT             72975017
KXX      DC    H'20'               X'14' CONSTANT                       72985017
INPROSAV DS    18F                 SAVE AREA                            72990017
INBUFFR  DS    10F                 BUFFER                               73000017
ANSWAREA DS    1F             ANSWER AREA FOR EXTRACT MACRO        EXTR 73050019
ADPARM   DC    F'0'                POINTER TO INPUT PARAMETER LIST      73100017
CHAR     DC    X'80'               OPTION BYTE CONSTANT                 73200017
ENDMSG   DC    X'1002'             DLE STX                              73560017
         DC    X'98'               MESSAGE IDENTIFIER                   73620017
         DC    X'69'         DATA SET REFERENCE NUMBER                  73680017
         DC    X'00'               SEQUENCE NUMBER                      73740017
         DC    X'04'               LENGTH OF HEADER                     73800017
         DC    X'0800'             EOT IDENTIFIER                       73860017
         DC    C'SP'               OPTIONAL DATA                        73920017
BTAMOPEN OPEN  BTAMDCB,MF=L                                             74120017
BTAMREAD READ  READDECB,TI,,,14,,1,MF=L                                 75020017
BTAMDCB  DCB   DSORG=CX,MACRF=(R,W),DDNAME=SUBSYS,DEVD=BS               75920017
OPENFLAG EQU   BTAMDCB+48          LOCATION OF OPEN FLAGS               76120017
*                                                                       76320017
* WTOR'S IN L-FORM                                                      76720017
*                                                                       77120017
IOMSG    WTOR  'IKD002D XXX - LINE ERROR',WTOREPLY,1,WTORECB,MF=L,     *77320000
               ROUTCDE=(2,8),DESC=4                                R018 77520000
INITMSG  WTOR  'IKD001D XXX - INITIALIZATION FAILURE',WTOREPLY,1,      *77920000
               WTORECB,MF=L,ROUTCDE=2,DESC=4                       R018 78320000
         EJECT                                                          79000017
DCVT     DSECT                                                          85050017
         CVT                                                            85100017
         EJECT                                                          85120017
GFXOCTHD DSECT                                                          85150017
GFXHDSTR EQU   *                       START OF HEADER RECORD           85200017
OCTSYS   DS    CL1                     BASE SYSTEM                      85250017
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                85300017
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          85350017
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       85400017
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       85450017
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              85500017
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              85550017
         DS    0H                                                       85600017
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             85650017
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       85700017
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       85750017
         DS    0F                                                       85800017
OCTFGREG DS    CL4                      REGION SIZE GJP                 85850017
OCTFUREG DS    CL4                      REGION SIZE USER FGD            85900017
OCTBUREG DS    CL4                      REGION SIZE USER BGD            85950017
OCTHRES  DS    CL8                      RESERVED                        86000017
OCTNAME  DS    CL20                     PROGRAMMER NAME                 86050017
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  86100017
GFXHDEND EQU   *                       END OF HEADER RECORD             86150017
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        86200017
         EJECT                                                          86250017
GFXOCTEN DSECT                                                          86300017
         DS    0F                                                       86350017
GFXENSTR EQU   *                       START OF ENTRY RECORD            86400017
OCTECB   DS    CL4                      ECB                             86450017
OCTUCB   DS    CL4                      UCB ADDRESS                     86500017
OCTUNIT  DS    CL4                      UNIT ADDRESS                    86550017
OCTCOUNT DS    CL4                      JOB COUNT                       86600017
OCTNOTE  DS    CL4                      NOTE                            86650017
OCTABEND DS    A                       ABEND CODE                       86700017
OCTRESD  DS    CL8                      RESERVED                        86750017
**********************************************************************  86800017
****                          ATTRIBUTE 1                          **** 86850017
**********************************************************************  86900017
OCTATTR1 DS    CL2                      ATTRIBUTES                      86950017
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         87000017
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   87050017
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         87100017
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       87150017
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   87200017
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  87250017
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  87300017
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           87350017
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          87400017
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   87450017
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           87500017
**********************************************************************  87550017
****                          ATTRIBUTE 2                          **** 87600017
**********************************************************************  87650017
OCTATTR2 DS    CL2                      ATTRIBUTES                      87700017
OCTBIRRE EQU   X'80'          0-                  1-GJP INTERNAL ERROR  87750017
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      87800017
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              87850017
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           87900017
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         87950017
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           88000017
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       88050017
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            88100017
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  88150017
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  88200017
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        88250017
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         88300017
**********************************************************************  88350017
****                          ATTRIBUTE 3                          **** 88400017
**********************************************************************  88450017
OCTATTR3 DS    CL2                      ATTRIBUTES                      88500017
OCTBIERR EQU   X'80'          0-                  1-GJP INTERNAL ERROR  88550017
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB      88600017
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              88650017
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           88700017
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         88750017
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           88800017
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       88850017
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            88900017
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  88950017
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  89000017
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        89050017
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         89100017
**********************************************************************  89150017
****                          ATTRIBUTE 4                          **** 89200017
**********************************************************************  89250017
OCTATTR4 DS    CL2                      ATTRIBUTES                      89300017
*                                                                       89350017
GFXENEND EQU   *                       END OF ENTRY RECORD              89400017
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             89450017
         EJECT                                                          89500017
         END                                                            90500017
