 TITLE 'IKDIOR' INPUT/OUTPUT ROUTINE                                    00200017
*STATUS: CHANGE LEVEL 000                                             * 00400017
*FUNCTION/OPERATION: REQUEST I/O FUNCTIONS OF PTOP AS DIRECTED BY     * 00600017
*   CALLING ROUTINE. ITS OPERATION INCLUDE:                           * 00700017
*   1) UPON REQUEST PREPARE FOR AND ISSUE A CALL TO IKDGTNIT. UPON    * 00800017
*   INITIALIZATION BEING COMPLETED SUCCESSFULLY, PREPARE PARAMETER    * 00900017
*   LISTS FOR REMAINING CALLS TO PTOP SUBROUTINES                     * 01000017
*   2) CALL PTOP SUBROUTINES AS DIRECTED BY CALLING ROUTINE           * 01100017
*   3) UPON COMPLETION OF A READ, EXAMINE THE DATA RECEIVED AND       * 01200017
*   PERFORM AS FOLLOWS:                                               * 01300017
*   A-IF DATA WAS A PROCESSOR SELECT RECORD, MOVE THE LINK/LOAD INDIC-* 01400017
*   ATOR INTO CCTSTAT AND PLACE THE COMMAND KEY INTO THE CCTPWKA      * 01500017
*   B-IF DATA WAS AN EXTRACT RECORD, POST THE PROCESSOR ECB WITH THE  * 01600017
*   ATTENTION TYPE CODE,AND, UPON AN END KEY ATTENTION, MOVE THE      * 01700017
*   EXTRACT RECORD FROM THE I/O BUFFER TO THE PROCESSOR WORKAREA      * 01800017
*ENTRY POINTS: IKDIOR VIA BALR BY IKDINIT, IKDCTL, IKDMSG, IKDPLOF0   * 02200017
*   AND IKDPREC0                                                      * 02300017
*INPUT: PARAMETERS FROM CALLING ROUTINE                               * 02500017
*   A-REGISTER 1 CONTAINS POINTER TO CONSOLE CONTROL TABLE            * 02560017
*   B-REGISTER 0 CONTAINS FUNCTION CODE, WHERE                        * 02620017
*   X'00' READ AND TEST                                               * 02680017
*   X'04' WRITE AND TEST                                              * 02740017
*   X'08' TEST LAST READ                                              * 02800017
*   X'0C' TEST LAST WRITE                                             * 02860017
*   X'10' INITIALIZE                                                  * 02920017
*   X'14' TERMINATE                                                   * 02980017
*   X'18' READ                                                        * 03040017
*   X'1C' WRITE                                                       * 03100017
*   X'20' WRITE ASYNCHRONOUS TO RESTART                               * 03160017
*   X'24' WRITE ASYNCHRONOUS TO TERMINATE                             * 03220017
*   2) DATA MOVED FROM I/O BUFFER TO I/O AREA BY IKDGTRED             * 03400017
*   3) RETURN CODES FROM IKDGTNIT AND IKDGTCLT INDICATING STATUS OF   * 03500017
*   PREVIOUS I/O REQUEST                                              * 03600017
*OUTPUT: CALLING SEQUENCE FOR PTOP ROUTINES                           * 03800017
*       ROUTINE              PARAMETER             SOURCE             * 03900017
*       *******              *********             ******             * 04000017
*        GTNIT-------------WRITE BUFFER-----------IKDIOR              * 04100017
*                         READ BUFFER             IKDIOR              * 04200017
*                          ASYNCHRONOUS ROUTINE    N/A                * 04300017
*                          STATUS CODE            IKDIOR              * 04400017
*                          PASSWORD               IKDIOR              * 04500017
*                          DATA SET REFERENCE     IKDIOR              * 04600017
*        GTRED-------------DATA SET REFERENCE-----IKDIOR              * 04700017
*                          TEMP ARRAY             CALLING ROUTINE     * 04800017
*                          ELEMENT COUNT          CALLING ROUTINE     * 04900017
*                          DATA TYPE              IKDIOR              * 05000017
*        GTWRT-------------DATA SET REFERENCE-----IKDIOR              * 05100017
*                          TEMP ARRAY             CALLING ROUTINE     * 05200017
*                          ELEMENT COUNT          CALLING ROUTINE     * 05300017
*                          DATA TYPE              IKDIOR              * 05400017
*                          CONTROL OPTION         IKDIOR              * 05500017
*        GTCLT-------------DATA SET REFERENCE-----IKDIOR              * 05600017
*                          TEST CODE              IKDIOR              * 05700017
*                          STATUS CODE            IKDIOR              * 05800017
*        GTEND-------------DATA SET REFERENCE-----IKDIOR              * 05900017
*   2) DATA MOVED FROM I/O AREA TO I/O BUFFER BY IKDGTWRT             * 06000017
*EXTERNAL ROUTINES: 1) GTNIT TO INITIALIZE PTOP                       * 06100017
*   2) GTRED FOR READ REQUESTS                                        * 06200017
*   3) GTWRT FOR WRITE REQUESTS                                       * 06300017
*   4) GTCLT TO TEST PREVIOUS READS OR WRITES                         * 06400017
*   5) GTEND TO TERMINATE PTOP                                        * 06500017
*EXITS: 1) CALL GTNIT TO INITIALIZE                                   * 06800017
*   2) CALL GTRED TO READ                                             * 06900017
*   3) CALL GTWRT TO WRITE                                            * 07000017
*   4) CALL GTCLT TO TEST                                             * 07100017
*   5) CALL GTEND TO TERMINATE                                        * 07200017
*   6) RETURN TO CALLER                                               * 07300017
*TABLES/WORKAREAS: CCT  BTAM I/O BUFFER                               * 07500017
*ATTRIBUTES: RESIDENT IN PARTITION DURING SGJP; REENTRANT             * 07700017
*NOTES: N/A                                                           * 07800017
         EJECT                                                          08000017
IKACCT   DSECT                                                          08100017
         SPACE                                                          08200017
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         08300017
         SPACE                                                          08400017
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    08500017
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     08600017
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       08700017
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             08800017
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  08900017
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  09000017
*                   SET.                                                09100017
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      09200017
*                   SECOND.                                             09300017
         SPACE 2                                                        09400017
         SPACE 2                                                        09500017
*                             SECTION ONE                               09600017
         SPACE                                                          09700017
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     09800017
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    09900017
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  10000017
         SPACE                                                          10100017
         DS    0F                                                       10200017
CCTUNAME DS    5F                  USER'S NAME                          10300017
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         10400017
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     10500017
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       10600017
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    10700017
*                                       AT LAST BEGIN JOB               10800017
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   10900017
*                                       LAST BEGIN JOB                  11000017
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 11100017
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    11200017
*                                       JOB                             11300017
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    11400017
*                                       JOB                             11500017
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     11600017
*                                       CESSOR                          11700017
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         11800017
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         11900017
CCTJCTR  DS    H                   JOB COUNTER                          12000017
CCTHIST  DS    109F                HISTORY OF OPERATIONS                12100017
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   12200017
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  12300017
CCTSSTAT DS    C                   SESSION STATUS                       12400017
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              12500017
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              12600017
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    12700017
         EJECT                                                          12800017
         SPACE 2                                                        12900017
*                             SECTION TWO                               13000017
         SPACE                                                          13100017
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   13200017
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  13300017
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 13400017
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              13500017
         SPACE                                                          13600017
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     13700017
*                                       FRAME                           13800017
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  13900017
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     14000017
*                                       MULTIPLE DISPLAY FRAME (ENT)    14100017
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   14200017
CCTDISM  DS    C                   DISPLAY MASK                         14300017
CCTCSM   DS    C                   COMMAND SELECT MASK                  14400017
CCTPSTAT DS    CL2                 GJP STATUS                           14500017
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              14600017
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  14700017
CCTPWKAE EQU   *                                                        14800017
         SPACE 2                                                        14900017
*                             SECTION THREE                             15000017
         SPACE                                                          15100017
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    15200017
*                   INTO SECTION ONE OR TWO                             15300017
         SPACE                                                          15400017
CCTDGMP  DS    F                  POINTER TO DGM                        15500017
CCTDATAP DS    F                  POINTER TO DATA NUMBER                15600017
CCTCSTP  DS    F                  POINTER TO CST                        15700017
CCTCPSTP DS    F                  POINTER TO CURRENT PST                15800017
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            15900017
CCTDORP  DS    F                  POINTER TO DOR MODULE                 16000017
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              16100017
CCTDIARP DS    F                  POINTER TO DIA                        16200017
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      16300017
CCTACTP  DS    F                  POINTER TO ACT                        16400017
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     16500017
CCTIERRP DS    F                  POINTER TO IERR                       16600017
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              16700017
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               16800017
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                16900017
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 17000017
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 17100017
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   17200017
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                17300017
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                17400017
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               17500017
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              17600017
CCTPECB  DS    F                  PROCESSOR'S ECB                       17700017
CCTWECB  DS    F                  WTOR ECB                              17800017
CCTDIAWA DS    CL136               DIARY WORK AREA                      17900017
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    18000017
CCTCSAVE DS    CL72                CTL SAVE AREA                        18100017
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                18200017
CCTASAVE DS    CL72                DAT SAVE AREA                        18300017
*                                                                       18400017
* THESE ARE THE CHANGES MADE TO THE CONSOLE CONTROL TABLE OF GJP.       18500017
* CONTENTS NOT NEEDED BY SGJP ARE REPLACED AS INDICATED BELOW           18600017
*                                                                       18700017
IKDCCT   EQU   IKACCT              THREE CHARACTER PREFIX IS REPLACED   18800017
CCTCWKA  EQU   CCTCSTP             CONTROL ROUTINE WORKAREA             18900017
CCTBUFFP EQU   CCTGWRKP            POINTER TO BTAM BUFFER               19000017
CCTRECLN EQU   CCTDGMP             LENGTH OF DATA TO BE TRANSMITTED     19100017
CCTIORP  EQU   CCTDORP             POINTER TO I/O ROUTINE               19200017
CCTMSGP  EQU   CCTDMRP             POINTER TO MESSAGE ROUTINE           19300017
CCTSTAT  EQU   CCTACTP             SGJP STATUS BYTES                    19400017
CCTIELST EQU   CCTLPWRK+68         AREA USED FOR GTNIT/GTEND PARAM LIST 19480017
CCTRDLST EQU   CCTIELST+24         AREA USED FOR GTRED PARAMETER LIST   19560017
CCTWRLST EQU   CCTRDLST+16         AREA USED FOR GTWRT PARAMETER LIST   19640017
CCTTSLST EQU   CCTWRLST+20         AREA USED FOR GTCLT PARAMETER LIST   19720017
CCTDSREF EQU   CCTTSLST+12         DATA SET REFERENCE NUMBER            19800017
CCTSTCOD EQU   CCTDSREF+4          WORD TO CONTAIN RESULTS OF INIT,TEST 19880017
CCTDATYP EQU   CCTSTCOD+4          WORD TO CONTAIN DATA TYPE CODE       19960017
CCTCTLOP EQU   CCTDATYP+4          WORD CONTAINING CODE DENOTING DEST-  20040017
*                                  INATION OF DATA                      20120017
CCTTSTCD EQU   CCTCTLOP+4          WORD TO CONTAIN CODE REPRESENTING    20200017
*                                  THE I/O OPERATION TO BE TESTED BY    20280017
*                                  GTCLT                                20360017
CCTIOECB EQU   CCTTSTCD+4         ECB USED IN WTOR ON I/O ERRORS        20440017
CCTREPAR EQU   CCTIOECB+4         AREA USED FOR WTOR REPLY              20520017
CCTERLST EQU   CCTREPAR+4          AREA FOR IERR MODEL PARAMETER LIST   20610017
CCTPWKAL EQU   CCTPWKAE-CCTPWKA                                         20700017
RMNDR    EQU   CCTPWKAL-256                                             20800017
         EJECT                                                          20900017
IKDIOR   CSECT                                                          21000017
*                                                                       21100017
* REGISTERS                                                             21200017
*                                                                       21300017
RPAR0    EQU   0                                                        21400017
RPAR1    EQU   1                                                        21500017
RBUFF    EQU   2                                                        21600017
RCCT     EQU   3                                                        21700017
RSTCODE  EQU   4                                                        21800017
RWORK    EQU   5                                                        21900017
RHOLD    EQU   6                                                        22000017
RREAD    EQU   7                                                        22100017
RWRITE   EQU   8                                                        22200017
RTEST    EQU   9                                                        22300017
RBASE    EQU   10                                                       22400017
RBAL     EQU   11                                                       22500017
R12      EQU   12                                                       22550017
RSAVE    EQU   13                                                       22600017
RRET     EQU   14                                                       22700017
RBR      EQU   15                                                       22800017
*                                                                       22900017
* EQUATES                                                               23000017
*                                                                       23100017
ZERO     EQU   0                                                        23150017
CDCHAR   EQU   0                                                        23200017
DSREF    EQU   0                                                        23300017
ONE      EQU   1                                                        23350017
PSR      EQU   1                                                        23400017
EXT      EQU   2                                                        23500017
THREE    EQU   3                                                        23550017
PSRLNTH  EQU   3                                                        23600017
TWO      EQU   2              EQUATE FOR TWO                            23630017
TSTRCODE EQU   1                   CODE TO TEST READ                    23660017
TSTWCODE EQU   2                   CODE TO TEST WRITE                   23720017
TSTRAWCD EQU   3                   CODE TO TEST READ AND WAIT           23780017
TSTWAWCD EQU   4                   CODE TO TEST WRITE AND WAIT          23840017
TESTCD   EQU   4                                                        23900017
FOUR     EQU   4                                                        23930017
FIVE     EQU   5                                                        23960017
SIX      EQU   6                                                        23980017
ADLENGTH EQU   4                                                        24000017
IOARRAY  EQU   4                                                        24100017
WRTBUF   EQU   4                                                        24200017
CTLCHAR  EQU   7                                                        24300017
EIGHT    EQU   8                                                        24350017
REDBUF   EQU   8                                                        24400017
STATCODT EQU   8                                                        24500017
ELCOUNT  EQU   8                                                        24600017
PROCLNTH EQU   8                                                        24620017
PTOP     EQU   8                                                        24650017
CBITE    EQU   8                                                        24660017
RADDR    EQU   12                                                       24670017
ASYRTN   EQU   12                                                       24700017
DATYP    EQU   12                                                       24800017
CTLOP    EQU   16                                                       24900017
PASSWD   EQU   16                                                       25000017
TWENTY   EQU   20                                                       25020017
SIXEIGHT EQU   68                                                       25040017
SIXNINE  EQU   69                                                       25060017
NINENINE EQU   99                                                       25080017
STATCODI EQU   20                                                       25100017
FIFTY2   EQU   52                  EQUATE                               25150017
TWO56    EQU   256                                                      25200017
TWO58    EQU   258                                                      25300017
TWO68    EQU   268                                                      25320017
TWO80    EQU   280                                                      25340017
TWO81    EQU   281                                                      25360017
HEX00    EQU   X'00'                                                    25620017
HEX01    EQU   X'01'                                                    25640017
HEX04    EQU   X'04'                                                    25660017
ENDKY    EQU   X'04'                                                    25700017
CANKY    EQU   X'08'                                                    25800017
HEX10    EQU   X'10'                                                    25820017
HEX1C    EQU   X'1C'                                                    25840017
HEX40    EQU   X'40'                                                    25860017
HEX7F    EQU   X'7F'                                                    25880017
POSTCODE EQU   X'7F'                                                    25900017
HEX81    EQU   X'81'                                                    25907017
HEX83    EQU   X'83'                                                    25914017
A        EQU   C'A'                                                     25921017
C        EQU   C'C'                                                     25928017
D        EQU   C'D'                                                     25935017
E        EQU   C'E'                                                     25942017
K        EQU   C'K'                                                     25949017
M        EQU   C'M'                                                     25956017
N        EQU   C'N'                                                     25963017
O        EQU   C'O'                                                     25970017
R        EQU   C'R'                                                     25977017
W        EQU   C'W'                                                     25984017
         EJECT                                                          26000017
         SAVE  (14,12)                                                  26100017
         BALR  RBASE,0             SET UP BASE                          26200017
         USING *,RBASE             ESTABLISH ADDRESSIBILITY             26300017
         LR    RCCT,RPAR1                                               26400017
         USING IKDCCT,RCCT         SET UP ADDRESSABILITY FOR CCT        26500017
         ST    RSAVE,CCTASAVE+FOUR   SAVE CALLER'S SAVE AREA ADDRESS    26530017
         LA    RWORK,CCTASAVE                                           26560017
         ST    RWORK,EIGHT(RSAVE)    CHAIN SAVE AREAS                   26590017
         LR    RSAVE,RWORK                                              26620017
         SR    R12,R12            CLEAR REGISTER 12                     26630017
*                                                                       26650017
* HOUSEKEEPING COMPLETE. BRANCH ON THE CONTENTS OF REGISTER ZERO WHICH  26700017
* CONTAINS THE FUNCTION CODE TO REQUEST THE NEEDED PTOP FUNCTION        26800017
*                                                                       26900017
         LR    RWORK,RPAR0        PUT I/O CODE IN RWORK                 26950017
         B     IOTAB(RWORK)       BRANCH ON RWORK                       27020017
IOTAB    B     CALLREAD            BRANCH TO READ AND TEST              27100017
         B     CALLWRIT            BRANCH TO WRITE AND TEST             27180017
         B     CALLTSTR            BRANCH TO TEST READ                  27260017
         B     CALLTSTW            BRANCH TO TEST WRITE                 27340017
         B     CALLINIT            BRANCH TO INITIALIZE                 27420017
         B     CALLEND             BRANCH TO TERMINATE                  27500017
         B     READONLY            BRANCH TO READ                       27580017
         B     WRITONLY            BRANCH TO WRITE                      27660017
         B     WRITRST        X'20'     RESTART CODE                    27770017
         B     WRITTRM        X'24'     TERMINATE CODE                  27780017
         EJECT                                                          27800017
*                                                                       27900017
* PARAMETER TO READ                                                     28000017
*                                                                       28100017
CALLREAD MVI   CCTSTAT+THREE,W     PUT WAIT CODE IN CCT                 28120017
         B     SETRLNTH            BRANCH TO SET READ LENGTH            28140017
READONLY MVI   CCTSTAT+THREE,O     PUT READ ONLY CODE IN CCT            28160017
SETRLNTH L     RPAR1,CCTRECLN      GET DATA LENTH                       28180017
         SRA   RPAR1,ONE           DIVIDE BY TWO                        28220017
         ST    RPAR1,CCTRECLN      PUT LENGTH BACK INTO CCT             28260017
         LA    RPAR1,CCTRDLST      GET ADDRESS OF READ PARAMETER LIST   28300017
*                                                                       28400017
* PARAMETER LIST READY, CALL GTRED                                      28500017
*                                                                       28600017
         CALL  GTRED,MF=(E,(1))                                         28700017
         B     CALLTSTR            GO TO TEST READ                      28800017
*                                                                       28900017
* PARAMETER TO WRITE.                                                   29000017
*                                                                       29100017
CALLWRIT MVI   CCTSTAT+THREE,W     PUT CODE TO WAIT IN CCT              29120017
         B     SETWLNTH            GO TO SET READ LENGTH                29140017
WRITONLY MVI   CCTSTAT+THREE,O     PUT WRITE ONLY CODE IN CCT           29160017
SETWLNTH L     RBUFF,CCTBUFFP      GET BUFFER ADDRESS                   29180017
         A     RBUFF,CCTRECLN      ADD RECORD LENGTH TO BUFFER ADDRESS  29218017
*                                                                       29227017
* RBUFF NOW POINTS TO NEXT AVAILABLE BUFFER LOCATION                    29236017
*                                                                       29245017
         L     RPAR1,CCTRECLN      GET DATA LENGTH                      29254017
         SRA   RPAR1,ONE           DIVIDE LENGTH BY TWO                 29263017
         STH   RPAR1,ZERO(RBUFF)   PUT INTO NEXT BUFFER LOCATION        29272017
         LA    RPAR1,ONE(RPAR1)    INCREMENT DATA LENGTH BY ONE         29281017
         ST    RPAR1,CCTRECLN      PUT INTO CCT AS NEW DATA LENGTH      29290017
         LA    RPAR1,CCTWRLST      GET ADDRESS OF WRITE PARAMETER LIST  29300017
*                                                                       29400017
* PARAMETER LIST READY, CALL GTWRT                                      29500017
*                                                                       29600017
         CALL  GTWRT,MF=(E,(1))                                         29700017
         B     CALLTSTW            GO TO TEST WRITE                     29800017
         EJECT                                                          29900017
*                                                                       30000017
* PARAMETER TO TEST LAST READ AND WAIT                                  30100017
*                                                                       30200017
CALLTSTR CLI   CCTSTAT+THREE,O     WAS WAIT SPECIFIED                   30250017
         BNE   WAITREAD            NO, BRANCH                           30300017
         LA    RWORK,TSTRCODE      SET CODE TO TEST READ                30350017
         B     BALREAD             GO TO TEST READ                      30400017
WAITREAD LA    RWORK,TSTRAWCD      SET CODE TO TEST READ AND WAIT       30450017
BALREAD  BAL   RBAL,CALLCLT        GO TO CALL SUBROUTINE                30500017
         LTR   RTEST,RTEST        CHECK FOR ZERO RETURN CODE            30600017
         BE    CALLREAD           IF ZERO, RETRY I/O                    30700017
         B     RDCMPLT             GO TO TEST TYPE READ COMPLETED       30800017
*                                                                       30900017
* PARAMETER TO TEST LAST WRITE AND WAIT                                 31000017
*                                                                       31100017
CALLTSTW CLI   CCTSTAT+THREE,O     WAS WAIT SPECIFIED                   31150017
         BNE   WAITWRIT            NO, BRANCH                           31200017
         LA    RWORK,TSTWCODE      SET CODE TO TEST WRITE               31250017
         B     BALWRIT             GO TO TEST WRITE                     31300017
WAITWRIT LA    RWORK,TSTWAWCD      SET CODE TO TEST WRITE AND WAIT      31350017
BALWRIT  BAL   RBAL,CALLCLT        GO TO CALL SUBROUTINE                31400017
         LTR   RTEST,RTEST        CHECK FOR ZERO RETURN CODE            31500017
         BE    CALLWRIT           IF ZERO, RETRY I/O                    31600017
         TM    CCTSSTAT,HEX10      IS EXTRACT RECORD EXPECTED           31610017
         BZ    TESTSMB             IF NOT, BRANCH TO TEST SMB BIT       31620017
         MVI   CCTPECB,POSTCODE    POST ECB COMPLETE                    31630017
         MVI   CCTPECB+THREE,ENDKY WITH END KEY                         31640017
         CLC   CCTCCR(THREE),WRICON IS WRITE MESSAGE CURRENT PROCESSOR  31650017
         BNE   DIORTRN            IF NOT, BRANCH                        31660017
         MVI   CCTSTAT+TWO,N       INDICATE REPLY WAS SENT              31670017
         B     DIORTRN             BRANCH TO RETURN                     31680017
TESTSMB  TM    CCTPSTAT+ONE,HEX01  IS SMB IN CONTROL                    31690017
         BZ    DIORTRN            IF MOT BRANCH                         31720017
         LA    RPAR1,FOUR          SET READ LENGTH IN CCT               31740017
         ST    RPAR1,CCTRECLN                                           31760017
         B     CALLREAD            GO TO READ END KEY INDICATION        31780017
*                                                                       31800017
* THIS SUBROUTINE PREPARES PARAMETERS FOR GTCLT.  UPON RETURN FROM PTOP 31900017
* IT USES A BRANCH TABLE TO RESOLVE RETURN CODES                        32000017
*                                                                       32100017
CALLCLT  MVI   CCTSTAT+THREE,HEX00  CLEAR TEST CODE IN CCT              32200017
         ST    RWORK,CCTTSTCD      PUT CODE IN CONSOLE CONTROL TABLE    32300017
         LA    RPAR1,CCTTSLST      GET ADDRESS OF TEST PARAMETER LIST   32400017
*                                                                       32500017
* PARAMETER LIST READY, CALL OTCLT                                      32600017
*                                                                       32700017
         CALL  GTCLT,MF=(E,(1))                                         32800017
         L     RTEST,CCTSTCOD      GET STATUS CODE RETURNED BY PTOP     32900017
         SLL   RTEST,TWO           SHIFT TO MAKE MULTIPLE OF FOUR       33000017
         B     RTNTAB(RTEST)       GO TO RETURN CODE TABLE              33100017
*                                                                       33200017
* BRANCH TABLE FOR POSSIBLE RETURN CODES FROM PTOP                      33300017
*                                                                       33400017
RTNTAB   B     PMSG3               BRANCH TO PREPARE ERROR MESSAGE 3    33500017
         B     REGISTER            I/O COMPLETED SUCCESSFULLY           33700017
         B     DIORTRN             I/O PENDING                          33800017
         B     DIORTRN             I/O STARTED BUT NOT COMPLETE         33900017
         B     PMSG3               BRANCH TO PREPARE ERROR MESSAGE 3    34000017
         B     PMSG3               BRANCH TO PREPARE ERROR MESSAGE 3    34100017
         B     PMSG2               BRANCH TO PREPARE ERROR MESSAGE 2    34200017
         B     REGISTER           WRONG LENGTH SPECIFIED                34300017
RETRYIO  SR    RTEST,RTEST         SET CODE TO INDICATE RETRY PREVIOUS  34450017
REGISTER BR    RBAL                OPERATION. SEND CODE TO CALLING PT   34500017
*                                  TO INDICATE THIS                     34600017
PMSG2    MVC   CCTERLST(PSRLNTH),M302  SET MSG CODE AND OPTION BYTE FOR 34620017
         MVI   CCTERLST+CBITE,HEX83  FOR IKAIERR                        34640017
         B     GOTOIERR            GO TO BRANCH TO IERR                 34660017
PMSG3    MVC   CCTERLST(PSRLNTH),M303  SET MSG CODE AND OPTION BYTE     34680017
         MVI   CCTERLST+CBITE,HEX83  FOR IKAIERR                        34700017
GOTOIERR LA    RPAR0,CCTERLST      SET ADDRESS TO PARAMETER LIST        34720017
         LR    RPAR1,RCCT          SET POINTER TO CCT                   34740017
         L     RBR,CCTIERRP        GET ADDRESS OF IKAIERR               34760017
         BALR  RRET,RBR            GO TO ERROR ROUTINE                  34780017
         LTR   RBR,RBR             TEST RETURN CODE FROM IERR           34800017
         BNZ   GTEND               TERMINATE IF NON-ZERO                34810017
         CLC   CCTERLST(PSRLNTH),M304   WAS THIS MSG ISSUED             34820017
         BE    GTEND                    YES                             34830017
         CLI   CCTREPAR,R          DID USER REQUEST RETRY               34840017
         BNE   RTSTRPLY            IF NOT, TEST AGAIN                   34860017
         B     RETRYIO             IF YES, RETURN TO RETRY I/O          34880017
RTSTRPLY CLI   CCTREPAR,C          DID USER REQUEST CANCEL              34900017
         BNE   GOTOIERR            INVALID CHARACTER. GO BACK TO IERR   34920017
         MVC   CCTERLST(PSRLNTH),M304  PUT MESSAGE CODE IN LIST         34940017
         MVI   CCTERLST+CBITE,HEX81  PUT OPTION BYTE IN LIST            34960017
         B     GOTOIERR            GO TO IKAIERR                        34980017
         EJECT                                                          35005017
*                                                                       35010017
**   INFORM SUBSYSTEM IF RESTART OR TERMINATE                           35015017
*                                                                       35020017
WRITTRM  LA    RPAR0,TERMNAT       ADDRESS OF TERMINATE CODE            35026017
         B     WRITASYN            GO TO WRITE                          35032017
WRITRST  LA    RPAR0,RESTART       ADDRESS OF RESTART CODE              35038017
WRITASYN LA    RWORK,TWO                ASYNCHRONOUS TRANSMISSION       35045017
         ST    RWORK,CCTCTLOP      PUT IN CONTROL OP OF CCT             35060017
         MVC   CCTGACBP,CCTWRLST+FOUR   SAVE CURRENT I/O AREA ADDRESS   35062017
         ST    RPAR0,CCTWRLST+FOUR      SET ADDRESS OF DATA TO BE SENT  35064017
         L     RPAR1,CCTIELST+TWENTY  GET CONTENTS OF IELST             35064517
         LTR   RPAR1,RPAR1        IS CONTENTS ZERO                      35065017
         BE    SETRC04            IF YES, BRANCH TO RETURN              35065517
         LA    RPAR1,CCTWRLST           GET ADDRESS OF LIST             35066017
         CALL  GTWRT,MF=(E,(1))         AND PASS TO PTOP                35068017
         MVC   CCTWRLST+FOUR(FOUR),CCTGACBP   RESTORE CURRENT I/O ADDR  35070017
         LH    RWORK,CTLOPT             GET CODE TO INDICATE            35072017
         ST    RWORK,CCTCTLOP           USE OF MAINLINE                 35074017
         L     RBUFF,CCTBUFFP      GET BUFFER ADDRESS                   35080017
         A     RBUFF,CCTRECLN      ADD TO IT RECORD LENGTH              35100017
         L     RPAR1,CCTRECLN      GET RECORD LENGTH                    35120017
         SRA   RPAR1,ONE           DIVIDE BY TWO                        35140017
         STH   RPAR1,ZERO(RBUFF)    PUT INTO NEXT BUFFER LOCATION       35160017
         LA    RPAR1,ONE(RPAR1)    INCREMENT BY ONE                     35180017
         ST    RPAR1,CCTRECLN      SET RECORD LENGTH                    35200017
         LA    RPAR1,CCTWRLST      GET ADDRESS OF LIST                  35220017
         CALL  GTWRT,MF=(E,(1))    CALL GTWRIT                          35240017
*                                                                       35250017
*    WAIT TO LET THE 1130 READ THE MESSAGE                              35260017
*                                                                       35270017
         LA    RPAR1,INTERVAL           ADDR OF VALUE                   35280017
         STIMER WAIT,TUINTVL=(1)        WAIT FOR COMPLETION             35290017
         LA    RWORK,TSTWCODE           GET CODE TO TEST                35300017
         ST    RWORK,CCTTSTCD           LAST WRITE                      35310017
         LA    RPAR1,CCTTSLST           ADDR OF PARAMETER LIST          35320017
         CALL  GTCLT,MF=(E,(1))                                         35330017
*                                                                       35340017
*    CLOSE THE LINE TO PREVENT I/O ERRORS                               35350017
*                                                                       35360017
GTEND    EQU   *                                                        35370017
         LA    RPAR1,CCTIELST           ADDR OF PARAMETER LIST          35380017
         CALL  GTEND,MF=(E,(1))                                         35390017
         LA    RWORK,ZERO      GET A ZERO                               35400017
         ST    RWORK,CCTIELST+TWENTY    PUT IN STATCODE POINTER         35410017
         B     SETRC04                  GO SET 'MUST TERMINATE' CODE    35420017
         EJECT                                                          35600017
*                                                                       35700017
* A READ HAS BEEN COMPLETED. DETERMINE IF THE DATA IN THE BUFFER IS     35800017
* A PROCESSOR SELECT RECORD OR AN EXTRACT RECORD                        35900017
*                                                                       36000017
RDCMPLT  EQU   *                                                        36100017
         L     RBUFF,CCTBUFFP     GET ADDRESS OF BUFFER                 36200017
         CLI   CDCHAR(RBUFF),E     IS DATA AN EXTRACT RECORD            36300017
         BE    EXTRCD              IF YES, BRANCH                       36400017
         CLI   CDCHAR(RBUFF),D     CHECK IF PSR AND PROCESSOR IS TO BE  36500017
         BE    MOVEKEY            LOADED.  IF TES, BRANCH               36600017
         CLI   CDCHAR(RBUFF),K     CHECK IF PSR AND PROCESSOR IS TO BE  36700017
         BNE   DIORTRN            LINKED TO.  IF NOT, BRANCH            36800017
MOVEKEY  EQU   *                                                        36900017
         MVC   CCTSTAT(ONE),CDCHAR(RBUFF) PUT LINK/LOAD IND INTO CCT    36950017
         MVC   CCTCCR(THREE),ONE(RBUFF)  PUT COMMAND KEY INTO CCT       36958017
         CLC   CCTCCR(PSRLNTH),CONBEGPR  WAS BEGIN PROCEDURE SELECTD    36966017
         BNE   CHEKCHAR            IF NOT BRANCH                        36974017
         MVC   CCTCCR(PSRLNTH),BEGCON  PUT BEGIN JOB KEYWORD IN CCT     36982017
         MVI   CCTPWKA,HEX40       BLANK OUT 70 BYTES IN WORK AREA      36986017
         MVC   CCTPWKA+ONE(SIXNINE),CCTPWKA                             36990017
         MVI   CCTPWKA+TWO80,HEX40 BLANK OUT 21 BYTES IN WORKAREA       36994017
         MVC   CCTPWKA+TWO81(TWENTY),CCTPWKA+TWO80                      36998017
         MVC   CCTPWKA(PSRLNTH),BEGCON   PUT BEGIN KEY INTI PWKA        37006017
         MVC   CCTPWKA+TWO68(PROCLNTH),FOUR(RBUFF)  PUT PROCEDURE NAME  37014017
         B     MOVEA               INTO WORKAREA AND BRANCH             37022017
CHEKCHAR CLC   CCTCCR(PSRLNTH),RECCON  CHECK IF RECALL WAS SELECTED     37030017
         BE    MOVED          BRANCH TO INSERT D IN PROCESSOR NAME      37038017
         CLC   CCTCCR(PSRLNTH),LOFCON  CHECK IF LOGOFF WAS SELECTED     37046017
         BNE   MOVEA          BRANCH TO PUT A IN PROCESSOR NAME         37146017
MOVED    MVI   CCTCWKA+TWO,D  PUT D IN MODULE NAME                      37246017
         B     DIORTRN        BRANCH TO RETURN                          37346017
MOVEA    MVI   CCTCWKA+TWO,A  PUT A IN MODULE NAME                      37446017
         B     DIORTRN        BRANCH TO RETURN                          37546017
         EJECT                                                          37700017
EXTRCD   MVI   CCTPECB,POSTCODE  POST PROCESSOR ECB COMPLETE            37750017
         CLC   EXT(EXT,RBUFF),CANCODE CHECK FOR CANCEL KEY FROM 1130    37800017
         BE    POSTCAN        BRANCH TO POST ECB WITH CANCEL CODE       37850017
         MVC   CCTPWKA(TWO56),EXT(RBUFF)  PUT FIRST 256 CHARACTERS OF   37900017
*                                 EXTRACT RECORD INTO CCT               38000017
         MVC   CCTPWKA+TWO56(RMNDR),TWO58(RBUFF)  PUT REMAINDER OF      38100017
*                                 EXTRACT RECORD INTO CCT               38200017
         MVI   CCTPECB+THREE,ENDKY   OTHERWISE, POST ECB WITH END       38500017
         CLC   CCTCCR(PSRLNTH),WRICON   WAS CURRENT COMMAND KEY FOR WRI 38830017
         BE    MOVEM          BRANCH TO INDICATE WRITE MESSAGE          38860017
         CLC   CCTCCR(PSRLNTH),ENTDATA CHECK FOR ENTER DATA PSR         38900017
         BNE   DIORTRN            IF NOT FOUND, BRANCH TO RETURN        39000017
MOVEM    MVI   CCTSTAT+TWO,M   INDICATE WRITE MESSAGE                   39560017
         B     DIORTRN         BRANCH TO RETURN                         39620017
POSTCAN  MVI   CCTPECB+THREE,CANKY  PUT CANCEL CODE IN ECB              39680017
         MVI   CCTSTAT+TWO,HEX00    ZERO MSG INDICATOR                  39740017
         B     DIORTRN         BRANCH TO RETURN                         39800017
         EJECT                                                          39900017
*                                                                       40000017
* PARAMETER TO INITIALIZE.                                              40100017
*                                                                       40200017
CALLINIT LA    RHOLD,FIVE          SET A COUNT                          40240017
         SR    R12,R12             SET R12 TO ZERO                      40241017
RETRY00  EQU   *                                                        40242017
         L     RPAR1,CCTIELST     GET PASSWORD CODE FROM INIT LIST      40245017
         B     PSWDTAB(RPAR1)     BRANCH ON RPAR1                       40250017
*                                                                       40255017
PSWDTAB  B     SETPWD0            BRANCH TO SET PTR TO PASSWORD 00      40260017
         B     SETPWD1            BRANCH TO SET PTR TO PASSWORD 01      40265017
         B     SETPWD2            BRANCH TO SET PTR TO PASSWORD 02      40270017
         L     RPAR1,CCTIELST+PASSWD   GET PREVIOUS PASSWORD CODE       40275017
         B     PSWDTAB(RPAR1)        BRANCH TO BRANCH TABLE             40280017
SETPWD0  LA    RPAR1,PASSWD00     GET 00 ADDRESS                        40285017
         B     STPSWD             BRANCH TO STORE IN LIST               40290017
SETPWD1  LA    RPAR1,PASSWD01     GET 00 ADDRESS                        40295017
         B     STPSWD             BRANCH TO STORE IN LIST               40300017
SETPWD2  LA    RPAR1,PASSWD02     GET 02 ADDRESS                        40305017
STPSWD   ST    RPAR1,CCTIELST+PASSWD PUT IN ITITIALIZATION LIST         40310017
PASWDSET LA    RPAR1,NINENINE     GET A NUMBER                          40315017
         ST    RPAR1,CCTDSREF     PUT AS DATA SET REFERENCE             40320017
REDOINIT LA    RPAR1,CCTIELST      SET PTR ININ LIST                    40360017
         LA    RWORK,CCTDSREF      PREPARE PARAMETERS FOR CALL TO GTNIT 40400017
         ST    RWORK,DSREF(RPAR1)  FIRST IS ADDRESS OF THE DATA SET     40500017
*                                  REFERENCE  THEN PUT ADDLESS OF THE   40600017
*                                  I/O BUFFER INTO THE SECOND AND THIRD 40700017
*                                  WORDS OF THE LIST                    40800017
         LA    RWORK,BUFFLNTH     GET BUFFER LENGTH ADDRESS             40830017
         ST    RWORK,CCTBUFFP     STORE IN CCT                          40860017
         MVC   WRTBUF(ADLENGTH,RPAR1),CCTBUFFP                          40900017
         LA    RWORK,ZEROPTR       GET POINTER TO ZERO                  40960017
         ST    RWORK,REDBUF(RPAR1)      PUT IN CCT                      41020017
* FOR THE TIME BEING, THERE IS NO ASYNCHRONOUS ROUTINE. THERE WILL BE   41100017
* NO INITIALIZATION OF THIS PARAMETER                                   41200017
*                                                                       41300017
         LA    RWORK,CCTSTCOD      PUT POINTER TO STATUS CODE IN SIXTH  41600017
         ST    RWORK,STATCODI(RPAR1) WORD OF LIST                       41700017
         MVC   CCTERLST(MLSTLNTH),MODLIST PUT MODEL PARAMETERS INTO CCT 41720017
         LA    RWORK,CCTREPAR      GET REPLY ADDRESS AND PUT IN CCT     41740017
         ST    RWORK,CCTERLST+RADDR                                     41760017
         MVI   CCTERLST+RADDR,HEX01  PUT REPLY LENGTH IN CCT            41780017
*                                                                       41800017
* PARAMETER LIST READY, CALL GTNIT                                      41900017
*                                                                       42000017
         CALL  GTNIT,MF=(E,(1))                                         42100017
*                                                                       42200017
* CHECK RETURN CODES FROM GTNIT TO DETERMINE IF ATTEMPT TO INITIALIZE   42300017
* WAS SUCCESSFUL                                                        42400017
*                                                                       42500017
         L     RSTCODE,CCTSTCOD    GET RETURN CODE FROM PTOP            42600017
         LTR   RSTCODE,RSTCODE                                          42700017
         BZ    INITCOMP            INITIALIZATION OK, SO BRANCH         42900017
         BP    DECOUNT            IF NOT, BRANCH                        42920017
         L     RWORK,CCTIELST+PASSWD   GET PASSWORD POINTER             42940017
         CLC   ZERO(SIX,RWORK),PASSWD01  WAS 01 USED                    42960017
         BNE   DECOUNT            IF NOT, BRANCH                        42980017
         SR    RWORK,RWORK        CLEAR A REGISTER                      43000017
         ST    RWORK,CCTIELST     PUT A ZERO IN CCT                     43020017
         LA    RHOLD,TWO          SET ATTEMPT COUNT TO TWO              43040017
         LA    R12,ONE            SET R12 SWITCH TO 1                   43060017
         B     RETRY00            GO TO RETRY INITIALIZATION            43080017
*                                                                       43100017
* RETURN CODE IS NEGATIVE INDICATING PASSWORDS DO NOT MATCH             43200017
* OR RETURN CODE IS POSITIVE INDICATING COMMUNICATIONS LINKAGE PROBLEM  43300017
*                                                                       43400017
DECOUNT  EQU   *                                                        43450017
         BCTR  RHOLD,ZERO          DECREMENT COUNT BY ONE               43500017
         LTR   RHOLD,RHOLD         CHECK FOR 0 COUNT                    43600017
         BNE   TESTSTOP           BRANCH TO TEST STOP BIT               43700017
         MVC   CCTERLST(PSRLNTH),M301 IF 5 RETRIES GO TO IKAIERR. SET   43800017
         MVI   CCTERLST+CBITE,HEX83   MSG CODE AND OPTION BYTE          43900017
         MVC   CCTPWKA+TWO56(FOUR),CCTBUFFP  SAVE THE CONTENTS          43920017
         LA    RBAL,CCTPWKA+FIFTY2      SET UP THE ADDRESS              43940017
         ST    RBAL,CCTBUFFP            OF AN AREA                      43960017
         BAL   RBAL,GOTOIERR       GO TO BRANCH TO IKAIERR              44000017
         MVC   CCTBUFFP(FOUR),CCTPWKA+TWO56  RESTORE THE CONTENTS       44030017
         LA    RHOLD,FIVE         RESET COUNT TO FOVE                   44060017
         B     REDOINIT           RETRY INITIALIZATILN                  44120017
TESTSTOP L     RWORK,CCTTIME      GET START PARAMETER LIST              44200017
         L     RPAR1,FOUR(RWORK)  GET ECB POINTER                       44300017
         TM    ZERO(RPAR1),HEX10  WAS FAST STOP ISSUED                  44400017
         BZ    REDOINIT           IF NOT, GO RETRY                      44500017
         MVC   CCTPWKA(EIGHT),KLOF      MOVE IN CONSTANT,               44510017
         MVC   CCTPWKA+FIVE(THREE),CCTUNIT   AND UNITNAME               44520017
         LA    RPAR0,CCTPWKA            GET PARAMETERS                  44530017
         SR    RPAR1,RPAR1              ZERO - NO CCT                   44540017
         SVC   80                       INTERFACE FOR ENDING SGJP       44550017
         B     SETRC04            GO SET A NON-ZERO RETURN CODE         44600017
*                                                                       44700017
* INITIALIZATION HAS SUCCESSFULLY COMPLETED. RETURN TO CALLER           44800017
* AFTER PREPARING PARAMETER LISTS FOR FUTURE CALLS TO PTOP ROUTINES     44900017
*                                                                       45000017
INITCOMP EQU   *                                                        45100017
         LTR   R12,R12            IS R12 EQUAL TO ZERO                  45130017
         BNE   CALLEND            IF NOT, BRANCH                        45160017
         LA    RREAD,CCTRDLST      SET POINTER TO READ PARAMETER LIST   45200017
         LA    RWRITE,CCTWRLST     SET POINTER TO WRITE PARAMETER LIST  45300017
         LA    RTEST,CCTTSLST      SET POINTER TO TEST PARAMETER LIST   45400017
         LA    RWORK,CCTDSREF      GET POINTER TO DATA SET REFERENCE    45500017
         ST    RWORK,DSREF(RREAD)  PUT DSREF PTR IN READ PARAMETER LIST 45600017
         ST    RWORK,DSREF(RWRITE)                  WRITE               45700017
         ST    RWORK,DSREF(RTEST)                   TEST                45800017
*                                                                       45900017
         LOAD  EP=IKDUATBL        GET ADDRESS OF UNIT ASSIGNMENT TABLE  45920017
         LA    RWORK,NINENINE     GET DATA SET REFERENCE NIMBER         45940017
         BCTR  RWORK,0            DECREMENT BY ONE                      45960017
         SLA   RWORK,TWO          MULTIPLY BY FOUR                      45980017
         AR    RWORK,RPAR0        GET ENTRY ADDRESS TO TABLE            46000017
         L     RWORK,ZERO(RWORK)    GET GTCB ADDRESS                    46020017
         L     RWORK,FOUR(RWORK)     GET BUFFER ADDRESS                 46040017
         LA    RWORK,SIX(RWORK)   SET POINTER TO I/O ARRAY              46060017
         ST    RWORK,IOARRAY(RREAD)  PUT POINTER INTO READ PARAM LIST   46100017
         ST    RWORK,IOARRAY(RWRITE)                  WRITE             46200017
         ST    RWORK,CCTBUFFP      RESET POINTER TO BUFFER              46250017
*                                                                       46300017
         LA    RWORK,CCTRECLN       GET POINTER TO DATA LENGTH          46400017
         ST    RWORK,ELCOUNT(RREAD)  PUT INTO READ PARAMETER LIST       46500017
         ST    RWORK,ELCOUNT(RWRITE)          WRITE                     46600017
*                                                                       46700017
         LH    RWORK,DATATYPE        GET CODE TO INDICATE TYPE OF DATA  46800017
         ST    RWORK,CCTDATYP        TO BE TRANSFERRED AND PUT INTO CCT 46900017
         LA    RWORK,CCTDATYP        GET POINTER TO THE DATA TYPE CODE  47000017
         ST    RWORK,DATYP(RREAD)    PUT INTO READ PARAMETER LIST       47100017
         ST    RWORK,DATYP(RWRITE)            WRITE                     47200017
*                                                                       47300017
         LH    RWORK,CTLOPT        GET CODE TO INDICATE DETINATION OF   47400017
*                                  DATA (1=MAIN LINE 2= ASYNCHRONOUS)   47500017
         ST    RWORK,CCTCTLOP      PUT INTO CCT                         47600017
         LA    RWORK,CCTCTLOP      GET POINTER TO CONTROL OPTION        47700017
         ST    RWORK,CTLOP(RWRITE) PUT INTO WRITE PARAMETER LIST        47800017
*                                                                       47900017
         LA    RWORK,CCTTSTCD      GET POINTER TO TEST CODE             48000017
         ST    RWORK,TESTCD(RTEST) PUT IN TEST PARAMETER LIST           48100017
         LA    RWORK,CCTSTCOD      GET POINTER TO STATUS CODE           48200017
         ST    RWORK,STATCODT(RTEST)  PUT IN TEST PARAMETER LIST        48300017
         DELETE EP=IKDUATBL                                             48350017
         B     DIORTRN             BRANCH TO RETURN                     48400017
*                                                                       48500017
* PARAMETER TO TERMINATE                                                48600017
*                                                                       48700017
CALLEND  EQU   *                                                        48800017
         L     RPAR1,CCTIELST+TWENTY  GET CONTENTS OF IELST             48820017
         LTR   RPAR1,RPAR1        IS CONTENTS ZERO                      48840017
         BE    DIORTRN            IF YES, BRANCH TO RETURN              48860017
         LA    RPAR1,CCTIELST      SET REG1 TO POINT TO PARAM LIST      48900017
*                                  TO TERMINATE                         49000017
*                                                                       49100017
* PARAMETER LIST READY, CALL GTEND                                      49200017
*                                                                       49300017
         CALL  GTEND,MF=(E,(1))                                         49400017
         LA    RWORK,ZERO      GET A ZERO                               49401017
         ST    RWORK,CCTIELST+TWENTY    PUT IN STATCODE POINTER         49402017
         LTR   R12,R12            IS R12 EQUAL TO ZERO                  49403017
         BNE   SETR120            IF NOT, BRANCH                        49404017
         L     RPAR1,CCTIELST+PASSWD   GET POINTER TO PASSWORD          49405017
         CLC   ZERO(SIX,RPAR1),PASSWD01 WAS PASSWORD 1 USED             49410017
         BE    SETFOUR            IF YES,BRANCH                         49415017
         LA    RPAR1,EIGHT        GET AN EIGHT                          49420017
         ST    RPAR1,CCTIELST+PASSWD  PUT PREVIOUS PASSWORD CODE IN CCT 49425017
         B     DIORTRN            BRANCH TO RETURN                      49430017
SETR120  LA    RPAR1,FOUR          SET PASSWORD CODE FOR 01             49431017
         ST    RPAR1,CCTIELST     PUT IN CCT                            49432017
         B     CALLINIT           GO TO ATTEMPT INITIALIZATION          49433017
SETFOUR  LA    RPAR1,FOUR         GET A FOUR                            49435017
         ST    RPAR1,CCTIELST+PASSWD  PUT PREVIOUS PASSWORD CODE IN CCT 49440017
         B     DIORTRN             BRANCH TO RETURN                     49450017
SETRC04  LA    RBR,HEX1C          SET A RETURN CODE TO TERMINATE        49500017
         ST    RBR,CCTPECB              STORE IT IN ECB                 49530017
         MVI   CCTPECB,POSTCODE         WITH COMPLETION                 49560017
         B     RCSET               GO TO RETURN                         49600017
DIORTRN  SR    RBR,RBR            SET A RETURN CODE OF ZERO             49700017
RCSET    L     RSAVE,CCTASAVE+FOUR   RESTORE REGISTER 13                49800017
         RETURN (14,12),RC=(15)       RETURN TO CALLER                  49900017
         EJECT                                                          50000017
*                                                                       50100017
* CONSTANTS                                                             50200017
*                                                                       50300017
PASSWD00 DC    C'SGJP00'          PASSWORD 00                           50320017
PASSWD01 DC    C'SGJP01'          PASSWORD 01                           50340017
PASSWD02 DC    C'SGJP02'          PASSWORD 02                           50360017
CTLOPT   EQU   *                                                        50380017
DATATYPE DC    H'1'                DATA TYPE                            50420017
ENTDATA  DC    C'ENT'              KEY FOR ENTER DATA                   50460017
CANCODE  DC    C'FF'                       CANCEL PARAMETER FRAME       50500017
WRICON   DC    C'WRI'                      WRITE MESSAGE                50540017
CONBEGPR DC    C'PRO'                      BEGIN PROCEDURE              50580017
BEGCON   DC    C'BEG'                      BEGIN JOB                    50620017
RECCON   DC    C'REC'                      RECALL                       50660017
LOFCON   DC    C'LOF'                      LOGOFF                       50700017
         DS    0H                                                       50762017
RESTART  DC    H'2'                     RESTART SGJP                    50764017
TERMNAT  DC    H'1'                     TERMINATE SGJP                  50766017
         DS    0F                                                       50770017
BUFFLNTH DC    F'1000'             LENGTH OF I/O BUFFER                 50775017
ZEROPTR  DC    F'0'               FULL WORD OF ZERO                     50777017
INTERVAL DC    F'76924'                 TWO SECONDS                     50778017
MODLIST  DC    CL3'000'            MESSAGE NUMBER                       50780017
         DC    CL5'IOR'            MODULE ID                            50790017
         DC    X'00'               CONTROL BYTE                         50800017
         DC    X'000000'           BINARY ZERO                          50810017
         DC    F'0'                LENGTH AND ADDRESS OF REPLY          50820017
MODLISTE EQU   *                                                        50830017
MLSTLNTH EQU   MODLISTE-MODLIST    LENGTH OF PARAMETER LIST             50840017
M301     DC    CL3'301'            MESSAGE NUMBER 301                   50870017
M302     DC    CL3'302'            MESSAGE NUMBER 302                   50900017
M303     DC    CL3'303'            MESSAGE NUMBER 303                   50930017
M304     DC    CL3'304'            MESSAGE NUMBER 304                   50960017
KLOF     DC    C'PLOG UTN'              CONSTANT FOR GFX INTERFACE      50980017
         END                                                            51000017
