         TITLE 'IKDMSG   DISPLAY MESSAGE ROUTINE'                       00200017
IKDMSG   START 0                                                        00400017
*                                                                       00600017
*ROUTINE NAME      IKDMSG                                               00800017
*                                                                       01000017
*CHART ID          JA                                                   01200017
*                                                                       01400017
*FUNCTION          PROVIDE AN INTERFACE TO THE 1130/2250 SUBSYSTEM IN   01600017
*                  ORDER TO PASS MESSAGES AND/OR INTENSIFICATION DATA   01800017
*                                                                       01840017
*                  AFTER WRITING THE MESSAGES TO THE SUBSYSTEM,         01880017
*                  A READ IS ISSUED TO READ BACK ANOTHER EXTRACT        01920017
*                  RECORD UNLESS A BIT IS ON IN THE 'CCTSSTAT'.         01960017
*                                                                       02000017
*ATTRIBUTES:       RESIDENT,REENTERABLE                                 02200017
*                                                                       02400017
*ENTRY POINT       IKDMSG                                               02600017
*                                                                       02800017
*EXITS           IKDIOR, RETURN TO CALLER                               03000017
*                                                                       03200017
*INPUT:            REGISTER 0 CONTAINS ADDRESS OF PARAMETER LIST        03400017
*                                                                       03600017
*                  REGISTER 1 CONTAINS ADDRESS OF CCT                   03800017
*                                                                       04000017
*                  FORMAT OF PARAMETER LIST ENTRY:                      04200017
*                                                                       04400017
*                                                                       04600017
*                  DISPL      0      1                                  04800017
*                            ***************************                05000017
*                            *      * ADDR OF MSG TEXT *                05200017
*                            * BITS *       OR         *                05400017
*                            *      *   INPUT MAPPING  *                05600017
*                            *      *       OR         *                05800017
*                            *      *    MSG NUMBER    *                06000017
*                            ***************************                06200017
*                                                                       06400017
*                  BIT 0  - 1  LAST ENTRY IN PARAMETER LIST             06600017
*                      1  - 0  PST INTENSIFICATION                      06800017
*                         - 1  MESSAGE TEXT                             07000017
*                      2       NOT USED                                 07200017
*                      3       NOT USED                                 07400017
*                      4  - 0  BASIC CHARACTER SIZE FOR MESSAGE TEXT    07600017
*                         - 1  LARGE CHARACTER SIZE FOR MESSAGE TEXT    07800017
*                      5  - 1  INTENSIFY MESSAGE LINE                   08000017
*                      6  - 0  MSG ADDRESS SUPPLIED                     08200017
*                         - 1  MSG NUMBER SUPPLIED                      08400017
*                      7       NOT USED                                 08600017
*                                                                       08800017
*                  MESSAGE TEXT FORMAT:                                 09000017
*                                                                       09200017
*                  DISPL      0       1                                 09400017
*                            **************************                 09600017
*                            *       *                *                 09800017
*                            *TEXT   *  MESSAGE TEXT  *                 10000017
*                            *LENGTH *                *                 10200017
*                            *       *                *                 10400017
*                            **************************                 10600017
*                                                                       10800017
*                  NOTE - TEXT LENGTH DOES NOT INCLUDE THE ONE BYTE     11000017
*                         FOR THE TEXT LENGTH FIELD                     11200017
*                       - TEXT MUST FIT ON ONE LINE ON SCREEN           11400017
*                       - TEXT WILL BE POSITIONED AT X=0, SO ANY        11600017
*                    DESIRED LEADING BLANKS MUST BE INCLUDED            11800017
*                                                                       12000017
*OUTPUT            REGISTER 0 CONTAINS I/O CODE FOR IKDIOR              12200017
*                                                                       12400017
*                  REGISTER 1 CONTAINS ADDR OF CONSOLE CONTROL TABLE    12600017
*                                                                       12800017
*                  I/O AREA CONTAINS DATA TO BE TRANSMITTED             13000017
*                  TO THE 1130/2250 SUBSYSTEM IN THIS FORMAT            13200017
*                                                                       13400017
*                        INTENSIFICATION          BIT 1 = 0             13600017
*                                              OR BIT 1 & BIT 6 = 1     13800017
*                  ************************                             14000017
*                  * BITS * INPUT MAPPING *                             14200017
*                  *      * OR MSG NUMBER *                             14400017
*                  ************************                             14600017
*                                                                       14800017
*                        MESSAGE TEXT             BIT 1 = 1             15000017
*                                                 AND BIT 6 = 0         15200017
*                  ***************************                          15400017
*                  * BITS *  TEXT  * MESSAGE *                          15600017
*                  *      * LENGTH *  TEXT   *                          15800017
*                  ***************************                          16000017
*                                                                       16200017
*                  BIT 7  - 0  END OF INFORMATION                       16250017
*                         - 1  MORE INFORMATION                         16300017
*                                                                       16350017
*EXTERNAL REFERENCES     NONE                                           16400017
*                                                                       16600017
*ERROR CONDITIONS:                                                      16800017
*                                                                       17000017
*TABLES AND WORKAREAS   CONSOLE CONTROL TABLE, I/O BUFFER               17200017
         EJECT                                                          17400017
*                                                                       17600017
*   REGISTER EQUATES                                                    17800017
*                                                                       18000017
RPAR0    EQU   0                                                        18200017
RPAR1    EQU   1                                                        18400017
RBASE    EQU   2                                                        18600017
RPARM    EQU   3                                                        18800017
RWRK0    EQU   4                                                        19000017
RWRK1    EQU   5                                                        19200017
RCCT     EQU   6                                                        19400017
RWKAR    EQU   7                                                        19600017
RGWRK    EQU   8                                                        19800017
RWRK2    EQU   9                                                        20000017
RBUFR    EQU   10                                                       20200017
RBUFZ    EQU   11                                                       20400017
RTRM     EQU   12                       RETURN REGISTER                 20500017
RSAVE    EQU   13                                                       20600017
RRET     EQU   14                                                       20800017
RBR      EQU   15                                                       21000017
*                                                                       21200017
*   INPUT PARAMETER DISPLACEMENTS                                       21400017
*                                                                       21600017
ENTRYBIT EQU   0                                                        21800017
ENTRYADD EQU   0                                                        22000017
ENTRYMAP EQU   2                                                        22200017
ENTRYNUM EQU   3                                                        22400017
MSGLEN   EQU   0                                                        22600017
MSGTEXT  EQU   1                                                        22800017
*                                                                       23000017
LAST     EQU   X'80'                                                    23200017
MSGENTRY EQU   X'40'                                                    23400017
MSGLGSZ  EQU   X'08'                                                    23600017
MSGINT   EQU   X'04'                                                    23800017
MSGNUMBR EQU   X'02'                                                    24000017
*                                                                       24200017
*                                                                       24400017
*   MISC EQUATES                                                        24600017
*                                                                       24800017
ENTRYLEN EQU   4                                                        25000017
IOSIZE   EQU   964                      SIZE OF BTAM BUFFER             25100017
EXTRCD   EQU   354                      SIZE OF EXTRACT RECORD          25300017
BMAXLEN  EQU   74                                                       25400017
LMAXLEN  EQU   49                                                       25600017
ZERO     EQU   0                   EQUATE                               25610017
ONE      EQU   1                   EQUATE                               25620017
TWO      EQU   2                   EQUATE                               25630017
THREE    EQU   3                   EQUATE                               25640017
FOUR     EQU   4                   EQUATE                               25650017
EIGHT    EQU   8                   EQUATE                               25660017
XTRCDSW  EQU   16                  EXTRACT RECORD SWITCH                25670017
FF       EQU   255                 X'FF' FOR BIT MANIPULATION           25680017
WRICOD   EQU   X'04'               WRITE CODE FOR IKDIOR                25690017
REDCOD   EQU   X'00'               READ CODE FOR IKDIOR                 25700017
BLANK    EQU   X'40'               EQUATE                               25710017
         SPACE 5                                                        25900017
*                                                                       26000017
*                                                                       26200017
*    WORK AREA FOR IKDMSG                                               26400017
*                                                                       26600017
MSGWORK  DSECT                                                          26800017
*                                                                       27000017
REGSAVE  DS    18F                                                      27200017
GEN14SV  DS    F                                                        27400017
*                                                                       27600017
         DS    0D                                                       27800017
MSGWAZ   EQU   *-REGSAVE                                                28000017
         EJECT                                                          28200017
IKACCT   DSECT                                                          28400017
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         28600017
         SPACE                                                          28800017
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    29000017
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     29200017
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       29400017
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             29600017
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  29800017
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  30000017
*                   SET.                                                30200017
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      30400017
*                   SECOND.                                             30600017
         SPACE 2                                                        30800017
         SPACE 2                                                        31000017
*                             SECTION ONE                               31200017
         SPACE                                                          31400017
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     31600017
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    31800017
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  32000017
         SPACE                                                          32200017
         DS    0F                                                       32400017
CCTUNAME DS    5F                  USER'S NAME                          32600017
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         32800017
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     33000017
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       33200017
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    33400017
*                                       AT LAST BEGIN JOB               33600017
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   33800017
*                                       LAST BEGIN JOB                  34000017
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 34200017
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    34400017
*                                       JOB                             34600017
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    34800017
*                                       JOB                             35000017
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     35200017
*                                       CESSOR                          35400017
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         35600017
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         35800017
CCTJCTR  DS    H                   JOB COUNTER                          36000017
CCTHIST  DS    109F                HISTORY OF OPERATIONS                36200017
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   36400017
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  36600017
CCTSSTAT DS    C                   SESSION STATUS                       36800017
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              37000017
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              37200017
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    37400017
         EJECT                                                          37600017
         SPACE 2                                                        37800017
*                             SECTION TWO                               38000017
         SPACE                                                          38200017
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   38400017
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  38600017
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 38800017
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              39000017
         SPACE                                                          39200017
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     39400017
*                                       FRAME                           39600017
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  39800017
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     40000017
*                                       MULTIPLE DISPLAY FRAME (ENT)    40200017
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   40400017
CCTDISM  DS    C                   DISPLAY MASK                         40600017
CCTCSM   DS    C                   COMMAND SELECT MASK                  40800017
CCTPSTAT DS    CL2                 GJP STATUS                           41000017
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              41200017
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  41400017
         SPACE 2                                                        41600017
*                             SECTION THREE                             41800017
         SPACE                                                          42000017
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    42200017
*                   INTO SECTION ONE OR TWO                             42400017
         SPACE                                                          42600017
CCTDGMP  DS    F                  POINTER TO DGM                        42800017
CCTDATAP DS    F                  POINTER TO DATA NUMBER                43000017
CCTCSTP  DS    F                  POINTER TO CST                        43200017
CCTCPSTP DS    F                  POINTER TO CURRENT PST                43400017
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            43600017
CCTDORP  DS    F                  POINTER TO DOR MODULE                 43800017
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              44000017
CCTDIARP DS    F                  POINTER TO DIA                        44200017
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      44400017
CCTACTP  DS    F                  POINTER TO ACT                        44600017
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     44800017
CCTIERRP DS    F                  POINTER TO IERR                       45000017
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              45200017
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               45400017
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                45600017
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 45800017
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 46000017
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   46200017
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                46400017
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                46600017
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               46800017
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              47000017
CCTPECB  DS    F                  PROCESSOR'S ECB                       47200017
CCTWECB  DS    F                  WTOR ECB                              47400017
CCTDIAWA DS    CL136               DIARY WORK AREA                      47600017
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    47800017
CCTCSAVE DS    CL72                CTL SAVE AREA                        48000017
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                48200017
CCTASAVE DS    CL72                DAT SAVE AREA                        48400017
*                                                                       48600017
* THESE ARE THE CHANGES MADE TO THE CONSOLE CONTROL TABLE OF GJP.       48800017
* CONTENTS NOT NEEDED BY SGJP ARE REPLACED AS INDICATED BELOW           49000017
*                                                                       49200017
IKDCCT   EQU   IKACCT              THREE CHARACTER PREFIX IS REPLACED   49400017
CCTCWKA  EQU   CCTCSTP             CONTROL ROUTINE WORKAREA             49600017
CCTBUFFP EQU   CCTGWRKP            POINTER TO BTAM BUFFER               49800017
CCTRECLN EQU   CCTDGMP             LENGTH OF DATA TO BE TRANSMITTED     50000017
CCTIORP  EQU   CCTDORP             POINTER TO I/O ROUTINE               50200017
CCTMSGP  EQU   CCTDMRP             POINTER TO MESSAGE ROUTINE           50400017
CCTSTAT  EQU   CCTACTP             SGJP STATUS BYTES                    50600017
CCTIELST EQU   CCTLPWRK+68         AREA USED FOR GTNIT/GTEND PARAM LIST 50700017
CCTRDLST EQU   CCTIELST+24         AREA USED FOR GTRED PARAMETER LIST   50800017
CCTWRLST EQU   CCTRDLST+16         AREA USED FOR GTWRT PARAMETER LIST   50900017
CCTTSLST EQU   CCTWRLST+20         AREA USED FOR GTCLT PARAMETER LIST   51000017
CCTDSREF EQU   CCTTSLST+12         DATA SET REFERENCE NUMBER            51100017
CCTSTCOD EQU   CCTDSREF+4          WORD TO CONTAIN RESULTS OF INIT,TEST 51200017
CCTDATYP EQU   CCTSTCOD+4          WORD TO CONTAIN DATA TYPE CODE       51300017
CCTCTLOP EQU   CCTDATYP+4          WORD CONTAINING CODE DENOTING DEST-  51400017
*                                  INATION OF DATA                      51500017
CCTTSTCD EQU   CCTCTLOP+4          WORD TO CONTAIN CODE REPRESENTING    51600017
*                                  THE I/O OPERATION TO BE TESTED BY    51700017
*                                  GTCLT                                51800017
CCTIOECB EQU   CCTTSTCD+4         ECB USED IN WTOR ON I/O ERRORS        51900017
CCTREPAR EQU   CCTIOECB+4         AREA USED FOR WTOR REPLY              52000017
CCTERLST EQU   CCTREPAR+4          AREA FOR IERR MODEL PARAMETER LIST   52600017
         EJECT                                                          53200017
IKDMSG   CSECT                                                          53400017
         SAVE  (14,12)                                                  53600017
         LR    RCCT,RPAR1               ADDR OF CCT                     53800017
         LR    RPARM,RPAR0              ADDR OF PARAMETER LIST          54000017
         BALR  RBASE,ZERO          SET UP BASE REGISTER                 54200017
         USING *,RBASE                                                  54400017
         USING IKACCT,RCCT                                              54600017
*                                                                       54800017
*    GET SPACE FOR WORK AREA                                            55000017
*                                                                       55200017
         GETMAIN R,SP=18,LV=MSGWAZ                                      55400017
         LR    RWKAR,RPAR1              ADDR OF WORK AREA               55600017
         USING MSGWORK,RWKAR                                            55800017
         ST    RSAVE,REGSAVE+FOUR  STORE CALLING SAVE AREA ADDRESS      56000017
         LA    RWRK0,REGSAVE                                            56200017
         ST    RWRK0,EIGHT(,RSAVE)      STORE CALLED SAVE AREA ADDRESS  56400017
         LR    RSAVE,RWRK0              ADDR OF REG SAVE AREA TO REG 13 56600017
*                                                                       56800017
*   TEST IF PARAMETER LIST IS ON FULL WORD BOUNDARY                     57000017
*                                                                       57200017
         LA    RWRK0,THREE         TURN ON 2 LOW ORDER BITS             57400017
         NR    RWRK0,RPARM                                              57600017
         BM    BADBNDRY            ZERO IF NOT ON FULL WORD BOUNDARY    57800017
         EJECT                                                          58000017
*    INITIALIZE POINTERS                                                58200017
*                                                                       58400017
         SR    RGWRK,RGWRK              ZERO FOR ARITHMETIC             58600017
INIT     EQU   *                                                        58800017
         L     RBUFR,CCTBUFFP           GET ADDR OF I/O AREA            59000017
         LA    RBUFZ,IOSIZE(,RBUFR)     GET LAST POSITION               59200017
*                                                                       59400017
INPLOOP  NI    ENTRYBIT(RPARM),FF-ONE   TURN OFF BIT SEVEN              59600017
         TM    ENTRYBIT(RPARM),MSGENTRY TEST IF ENTRY IS FOR MSG        59800017
         BO    MSGTXT                   ON FOR MESSAGE TEXT             60000017
         B     INTENS                   OFF FOR INTENSIFICATION         60200017
TESTLAST TM    ENTRYBIT(RPARM),LAST     IS THIS THE LAST ENTRY          60400017
         BO    ENDDMSG                  BRANCH IF YES                   60600017
         LA    RPARM,ENTRYLEN(RPARM)    ADDR OF NEXT ENTRY IN PARM LIST 60800017
         B     INPLOOP                  BRANCH TO SERVICE NEXT ENTRY    61000017
*                                                                       61200017
ENDDMSG  EQU   *                                                        61400017
         BAL   RRET,LINKIOW             WRITE TO SUBSYSTEM              61600017
*                                                                       61610017
*    TEST IF AN EXTRACT RECORD IS EXPECTED                              61620017
         TM    CCTSSTAT,XTRCDSW         Q. EXTRACT RECORD EXPECTED      61630017
         BO    EXIT                     NO                              61640017
*                                                                       61650017
*    READ NEW EXTRACT RECORD                                            61700017
         BAL   RRET,LINKIOR             READ FROM SUBSYSTEM             61800017
         EJECT                                                          62000017
EXIT     NI    CCTSSTAT,FF-XTRCDSW      TURN OFF EXTRACT RECORD SW.     62100017
         L     RSAVE,FOUR(RSAVE)        ADDR OF CALLING SAVE AREA       62200017
         LR    RTRM,RBR                 SAVE RETURN REGISTER            62500017
         FREEMAIN R,SP=18,A=(RWKAR),LV=MSGWAZ                           62600017
         LR    RBR,RTRM                 RESTORE RETURN REGISTER         62700017
         RETURN (14,12),RC=(15)                                         62800017
*                                                                       63000017
*    ERRONEOUS INPUT PARAMETER LIST                                     63200017
*                                                                       63400017
BADBNDRY EQU   *                                                        63600017
         LR    RPAR1,RCCT                                               63800017
         LA    RPAR0,ERR019                                             64000017
         L     RBR,CCTIERRP             GO TO IKAIERR                   64200017
         BALR  RRET,RBR                 FOR ERROR MSG                   64400017
         B     EXIT                     TERMINATE                       64600017
*                                                                       64800017
ERR019   DS    0F                       ALIGNMENT                       65000017
         DC    C'019'                   MSG NO.                         65200017
         DC    C'MSG  '                 MODULE NAME                     65400017
         DC    XL1'81'                  ATTRIBUTE                       65600017
         DC    XL3'00'                  NOT USED                        65700017
*                                                                       65810017
NOFIT    EQU   *                                                        65820017
         LR    RPAR1,RCCT               ADDR OF CCT                     65830017
         LA    RPAR0,ERR026             ADDR OF PARM LIST               65840017
         L     RBR,CCTIERRP             ADDR OF INTERNAL ERROR RTNE     65850017
         BALR  RRET,RBR                 PUT OUT ERROR MSG               65860017
         B     MSGSIZ                   CONTINUE PROCESSING             65870017
ERR026   DS    0F                       ALIGNMENT                       65890017
         DC    C'026'                   MSG NO.                         65910017
         DC    C'MSG  '                 MODULE NAME                     65930017
         DC    XL1'01'                  ATTRIBUTE                       65950017
         DC    XL3'00'                  NOT USED                        65970017
         EJECT                                                          66000017
***  MESSAGE TEXT                                                       66200017
MSGTXT   EQU   *                                                        66400017
         TM    ENTRYBIT(RPARM),MSGNUMBR IS THIS A MESSAGE NUMBER        66600017
         BO    INTENS                   YES                             66800017
         L     RWRK0,ENTRYBIT(,RPARM)   GET ADDR OF MSG                 67000017
         IC    RGWRK,MSGLEN(,RWRK0)     GET TEXT LENGTH                 67200017
**   TEXT MUST FIT ON ONE LINE ON SCREEN                                67400017
         LA    RWRK1,BMAXLEN            BASIC                           67600017
         TM    ENTRYBIT(RPARM),MSGLGSZ  IS LARGE SIZE SPECIFIED         67800017
         BZ    CMAXSIZ                  NO                              68000017
         LA    RWRK1,LMAXLEN            LARGE                           68200017
CMAXSIZ  CR    RWRK1,RGWRK              IS MAXIMUM SIZE EXCEEDED        68400017
         BH    MSGSIZ                   NO                              68600017
         LR    RGWRK,RWRK1              TRUNCATE THE MESSAGE TEXT       68800017
         B     NOFIT                    ISSUE ERROR MSG                 68900017
MSGSIZ   EQU   *                                                        69000017
         LA    RWRK1,TWO(RGWRK,RBUFR)   ADJUST FOR SIZE                 69200017
         CR    RWRK1,RBUFZ              TEST IF SPACE AVAILABLE         69400017
         BH    NOSPACE                  NO - WRITE OUT BUFFER           69600017
         MVC   ZERO(ONE,RBUFR),ENTRYBIT(RPARM)  MOVE IN FIRST BYTE      69800017
         EX    RGWRK,MVMSG              MOVE MESSAGE TO I/O AREA        70000017
         TM    MSGLEN(RWRK0),ONE        Q. EVEN NO. OF BYTES            70020017
         BZ    EVEN                     YES                             70040017
         LA    RWRK2,TWO(RGWRK,RBUFR)   GET END OF AREA                 70060017
         MVI   ZERO(RWRK2),BLANK        INSERT A BLANK                  70080017
         LA    RGWRK,ONE(,RGWRK)        INCREMENT FOR AN EVEN NO.       70100017
EVEN     EQU   *                                                        70120017
         STC   RGWRK,ONE(RBUFR)         MOVE IN TEXT LENGTH,            70220017
*                                       WHICH MAY HAVE BEEN TRUNCATED   70400017
         LA    RBUFR,TWO(RGWRK,RBUFR)   GET NEXT SPACE IN I/O BUFFER    70500017
         LA    RWRK2,TWO(,RGWRK)        SIZE OF THIS ENTRY              70600017
         B     TESTLAST                 TEST IF LAST ENTRY              70700017
*                                                                       71000017
*                                                                       71200017
***  INTENSIFICATION                                                    71400017
INTENS   EQU   *                                                        71600017
         LA    RWRK1,ENTRYLEN(,RBUFR)   ADJUST FOR SIZE                 71800017
         CR    RWRK1,RBUFZ              TEST IF SPACE AVAILABLE         72000017
         BH    NOSPACE                  NO - WRITE OUT BUFFER           72200017
         MVC   ENTRYADD(ENTRYLEN,RBUFR),ENTRYBIT(RPARM)                 72400017
*                                       MOVE THE WORD INTO I/O BUFFER   72600017
         LA    RBUFR,ENTRYLEN(,RBUFR)   GET NEXT SPACE IN I/O BUFFER    72700017
         LA    RWRK2,ENTRYLEN           SIZE OF THIS ENTRY              72900017
         B     TESTLAST                 TEST IF LAST ENTRY              73000017
         EJECT                                                          73200017
**   WRITE OUT BUFFER                                                   73400017
NOSPACE  EQU   *                                                        73600017
         SR    RBUFR,RWRK2              DECREMENT FOR LAST ENTRY        73650017
         OI    ZERO(RBUFR),ONE          INDICATE MORE INFORMATION       73700017
         AR    RBUFR,RWRK2              RE-POSITION THE POINTER         73750017
         LA    RRET,INIT                RETURN FROM LINKIOW             73800017
*                                                                       74000017
*    LINK TO IKDIOR TO WRITE TO SUBSYSTEM                               74200017
*                                                                       74400017
LINKIOW  ST    RRET,GEN14SV             SAVE RETURN ADDR                74600017
         LA    RPAR0,WRICOD             WRITE CODE                      74800017
         S     RBUFR,CCTBUFFP           GET LENGTH OF RECORD            75000017
         ST    RBUFR,CCTRECLN           TO BE TRANSMITTED               75200017
         LR    RPAR1,RCCT               ADDR OF CCT                     75400017
         L     RBR,CCTIORP              ADDR OF IKDIOR                  75600017
         BALR  RRET,RBR                 PERFORM I/O                     75800017
         L     RRET,GEN14SV             RESTORE RETURN ADDR             76000017
         CH    RBR,TRMCOD               Q. TERMINATE CODE               76100017
         BCR   7,RRET                   NO, CONTINUE                    76200017
         B     EXIT                     RETURN                          76300017
*                                                                       76400017
*    LINK TO IKDIOR TO READ FROM SUBSYSTEM                              76600017
*                                                                       76800017
LINKIOR  ST    RRET,GEN14SV             SAVE RETURN ADDR                77000017
         LA    RPAR0,REDCOD             READ CODE                       77200017
         LA    RBUFR,EXTRCD             GET LENGTH OF EXTRACT RECORD    77400017
         ST    RBUFR,CCTRECLN           TO BE RECEIVED                  77600017
         LR    RPAR1,RCCT               ADDR OF CCT                     77800017
         L     RBR,CCTIORP              ADDR OF IKDIOR                  78000017
         BALR  RRET,RBR                 PERFORM I/O                     78200017
         L     RRET,GEN14SV             RESTORE RETURN ADDR             78400017
         CH    RBR,TRMCOD               Q. TERMINATE CODE               78460017
         BCR   7,RRET                   NO, CONTINUE                    78520017
         B     EXIT                     RETURN                          78580017
         EJECT                                                          78640017
*                                                                       78700017
*    CONSTANTS                                                          78760017
*                                                                       78820017
TRMCOD   DS    H'28'                    MUST TERMINATE                  78880017
*                                                                       79000017
*                                                                       79200017
*   INSTRUCTIONS TO BE EXECUTED                                         79400017
*                                                                       79600017
MVMSG    MVC   ONE(ZERO,RBUFR),MSGLEN(RWRK0)  MOVE MSG TEXT TO I/O AREA 79800017
*                                                                       80000017
*                                                                       80200017
         CNOP  0,8                      ADJUST TO DOUBLE-WORD BOUNDARY  80400017
         END                                                            80600017
