AFI      TITLE 'IHKAFI - ACTIVE AREA I/O CONTROL/COMMAND INTERPRETER'   00060019
         MACRO                                                          00068020
&LABEL   DK    &A                                                       00076020
&LABEL   DC    AL1(&A)                                                  00084020
         MEND                                                           00092020
IHKAFI   CSECT                                                          00100020
*A150200-150800,D197100,D204000-205600,A204400,D209400,         A45668  00101026
*A210200-210400,A398100,A456300,C571000-571400,A594900,         A45668  00102026
*A608100,A768300,C831000-831600,A834200-834400,A848100,         A45668  00103026
*A904300-904500                                                 A45668  00104026
* 088200-090000,092400,094800,136800-137400                      A34594 00108020
*C094800,537600                                                  A36813 00114020
*********************************************************************** 00120019
*********************************************************************** 00180019
*                           I H K A F I                               * 00240019
*                                                                     * 00300019
*  STATUS -                                                           * 00360019
*      CHANGE LEVEL 0                                                 * 00420019
*                                                                     * 00480019
*  FUNCTION/OPERATION -                                               * 00540019
*      MODULE IHKAFI FUNCTIONS AS THE MACRO INTERPRETER AND I/O       * 00600019
*      SCHEDULER FOR THE CRJE ACTIVE FILE I/O(AFIO) FACILITY.         * 00660019
*      THE MACROS THAT ARE ISSUED BY VARIOUS CRJE COMPONENTS TO       * 00720019
*      DRIVE AFIO ARE:                                                * 00780019
*                CREATE                                               * 00840019
*                RELEASE                                              * 00900019
*                RPOINT                                               * 00960019
*                ENDUP                                                * 01020019
*                INSERT                                               * 01080019
*                RDELETE                                              * 01140019
*                REPLACE                                              * 01200019
*                RGET                                                 * 01260019
*                RSKIP                                                * 01320019
*      EACH MACRO HAS AN INTERPRETER WITHIN IHKAFI. EACH INTERPRETER  * 01380019
*      GENERATES LINKAGE AND PARAMETERS TO THE PROPER ROUTINES IN     * 01440019
*      IHKEXC AND IHKGCW TO CAUSE PROPER GENERATION AND EXECUTION OF  * 01500019
*      THE DESIRED CHANNEL PROGRAM.                                   * 01560019
*      ON RETURN FROM EXCP (EXCEPT DURING WARM START) THE IOB ECB AND * 01568000
*      SENSE BYTES ARE CHECKED FOR ERROR.IF AN ERROR CONDITION IS     * 01576000
*      FOUND A SYNADAF MACRO IS ISSUED TO ANALYZE THE ERROR AND FORMAT* 01584000
*      AN ERROR MSG DESCRIBING THE ERROR.THE ERROR MSG IS PRINTED ON  * 01592000
*      THE CENTRAL OPERATOR'S PRINTER-KEYBOARD.                       * 01600000
*                                                                     * 01608000
*                                                                     * 01620019
*      LINKAGE BETWEEN IHKAFI, IHKEXC AND IHKGCW IS NON-STANDARD      * 01680019
*      AS DOCUMENTED. ALL CALLS TO AFIO,HOWEVER, RESULT IN ENTRY      * 01740019
*      TO IHKAFI AND ALL RETURNS TO CALLER ARE MADE FROM ONE          * 01800019
*      POINT IN IHKAFI                                                * 01860019
*                                                                     * 01920019
*      STANDARD REGISTER SAVE CONVENTIONS ARE USED IN IHKAFI. CALLS   * 01980019
*      TO IHKEXC AND IHKGCW FROM IHKAFI ENTAIL NO REGISTER            * 02040019
*      SAVING CONVENTIONS AT ALL. IHKEXC AND IHKGCW MAKE NO           * 02100019
*      CALLS OR BRANCHES TO ANY MODULE EXCEPT THEMSELVES OR           * 02160019
*      IHKAFI.                                                        * 02220019
*                                                                     * 02280019
*      THE MAJOR FUNCTIONS OF IHKAFI ARE:                             * 02340019
*            1-  INITIALIZATION.                                      * 02400019
*            2-  IF GLOBAL FILE REQUEST- GET GLOBAL QUEUE.            * 02460019
*            3-  SET UP LINKAGE AND ENTRY TO PROPER MACRO INTERPRETER.* 02520019
*            4-  GO TO MACRO INTERPRETER.                             * 02580019
*            5-  GET ON QUEUE FOR EXTENDED WORK AREA.                 * 02640019
*            6-  ASSIGN STORAGE FOR I/O AND GENERATE CCW LIST IN      * 02700019
*                IHKGCW.                                              * 02760019
*            7-  GET BUFFER IF REQUIRED.                              * 02820019
*            8-  EXCP                                                 * 02880019
*            9-  WAIT FOR I/O COMPLETION IN CRJE DISPATCHER           * 02940019
*            10- CHECK RESULTS OF I/O                                 * 03000019
*            11- CHECK IF OPERATION COMPLETE - IF NOT, BACK TO        * 03060019
*                INTERPRETER.                                         * 03120019
*            12- FREE BUFFER IF REQUIRED.                             * 03180019
*            13- GET OFF EXTENDED WORK AREA QUEUE.                    * 03240019
*            14- SET RETURN CODE.                                     * 03300019
*            15- RETURN.                                              * 03360019
*                                                                     * 03420019
*  ENTRY POINTS -                                                     * 03480019
*      IHKAFI IS THE ONLY ENTRY POINT.                                * 03540019
*                                                                     * 03600019
*  INPUT -                                                            * 03660019
*      REGISTER 1 MUST CONTAIN A POINTER TO THE ADDRESS OF THE TUB.   * 03720019
*                                                                     * 03780019
*  OUTPUT -                                                           * 03840019
*      POINTER TO DATA RETRIEVED IN TUBRAFBF ON RGET AND 'WITH RE-    * 03900019
*      TRIEVAL' REQUESTS.                                             * 03960019
*                                                                     * 04020019
*  EXTERNAL ROUTINES -                                                * 04080019
*      IHKEXC                                                         * 04140019
*      IHKGCW                                                         * 04200019
*      IHKRNQ                                                         * 04260019
*      OS EXCP                                                        * 04320019
*      IHKDSP                                                         * 04380019
*                                                                     * 04440019
*  EXITS -                                                            * 04500019
*      1. TO CRJE DISPATCHER TO AWAIT I/O COMPLETION.                 * 04560019
*      2. TO OS FOR EXCP                                              * 04620019
*      3. TO CALLER WITH RETURN CODE REGISTER 15.                     * 04680019
*                                                                     * 04740019
*  RETURN CODES -                                                     * 04800019
*      THE RETURN CODES FOR EACH AFIO MACRO ARE:                      * 04860019
*          CREATE-                                                    * 04920019
*                 0-  NORMAL                                          * 04980019
*                 4-  NO TRACKS AVAILABLE IN ACTIVE AREA              * 05040019
*                 8-  GETMAIN FAILED                                  * 05100019
*                 12- I/O ERROR                                       * 05160019
*                                                                     * 05220019
*          RELEASE -                                                  * 05280019
*                 0-  NORMAL                                          * 05340019
*                 4-  NOT USED                                        * 05400019
*                 8-  GETMAIN FAILED                                  * 05460019
*                 12- I/O ERROR                                       * 05520019
*                                                                     * 05580019
*          RPOINT                                                     * 05640019
*                 0-  NORMAL                                          * 05700019
*                 4-  RECORD DOES NOT EXIST                           * 05760019
*                 8-  GETMAIN FAILED                                  * 05820019
*                 12- I/O ERROR                                       * 05880019
*                                                                     * 05940019
*          ENDUP                                                      * 06000019
*                 0-  NORMAL                                          * 06060019
*                 4-  NOT USED                                        * 06120019
*                 8-  GETMAIN FAILED                                  * 06180019
*                 12- I/O ERROR                                       * 06240019
*                                                                     * 06300019
*          INSERT -                                                   * 06360019
*                 0-  NORMAL                                          * 06420019
*                 4-  OUT OF SPACE                                    * 06480019
*                 8-  GETMAIN FAILED                                  * 06540019
*                 12- I/O ERROR                                       * 06600019
*                                                                     * 06660019
*          RDELETE -                                                  * 06720019
*                 0-  NORMAL                                          * 06780019
*                 4-  EOD                                             * 06840019
*                 8-  GETMAIN FAILED                                  * 06900019
*                 12- I/O ERROR                                       * 06960019
*                                                                     * 07020019
*          REPLACE -                                                  * 07080019
*                 0-  NORMAL                                          * 07140019
*                 4-  EOD                                             * 07200019
*                 8-  GETMAIN FAILED                                  * 07260019
*                 12- I/O ERROR                                       * 07320019
*                                                                     * 07380019
*          RGET -                                                     * 07440019
*                 0-  NORMAL                                          * 07500019
*                 4-  EOD                                             * 07560019
*                 8-  GETMAIN FAILED                                  * 07620019
*                 12- I/O ERROR                                       * 07680019
*                                                                     * 07740019
*          RSKIP -                                                    * 07800019
*                 0-  NORMAL                                          * 07860019
*                 4-  EOD                                             * 07920019
*                 8-  GETMAIN FAILED                                  * 07980019
*                 12- I/O ERROR                                       * 08040019
*                                                                     * 08100019
*  TABLES/WORKAREAS -                                                 * 08160019
*      IHKNBX                                                         * 08220019
*      TERMINAL USERS BLOCK - TUB                                     * 08280019
*      IHKEXF - EXTENDED WORK AREA                                    * 08340019
*      IHKIRP - RESTRICTED WORK AREA                                  * 08400019
*                                                                     * 08460019
*  ATTRIBUTES -                                                       * 08520019
*      RESIDENT AND REUSEABLE.                                        * 08580019
*********************************************************************** 08640019
*********************************************************************** 08700019
*                                                                       08760019
*                                                                       09060019
* ACTIVE FILE INPUT/OUTPUT INTERPRETER AND SCHEDULER.                   09120019
*                                                                       09180019
         USING RAFKNBX,KBXRG                                            09300019
         USING TUBDSECT,APW2RG                                          09360019
         USING IHKAFI,BASERG                                            09420019
         SAVE  (14,12),,AFI72059       SAVE CALLER'S REGISTERS          09480026
         XR    ICRG,ICRG                                                09540019
         LR    BASERG,LINK2RG          LOAD R10 FROM BRANCH REG R15     09600019
         L     APW2RG,0(GR1RG)         LOAD PTR TO TUB FROM PARM REG    09660019
         L     KBXRG,KONBXPTR          PTR TO KONBOX                    09720019
         LA    GR1RG,TUBSAVE                                            09780019
         ST REGD,TUBSAVE+4             SAVE PREVIOUS SAVEAREA PTR       09840019
         ST GR1RG,8(REGD)              SAVE THIS SAVEAREA PTR           09900019
         LR    REGD,GR1RG              POINT 13 TO AFIO SAVEAREA        09960019
*                                                                       10020019
*        SAVE USER ARGUMENT AND SETUP MACRO INTERPRETER TABLE BASE      10080019
*                                                                       10140019
         TM    AFPAR2FS,GLOBAL    IF THIS IS A GLOBAL FILE REQUEST,     10200019
         BZ    AFIO1                   (NO)                             10260019
         BAL   INTLNKRG,GETGBASE  LOCATE GLOBAL FILE CONTROL            10320019
         USING AFCTLDS,GR1RG                                            10380019
         LA    GR2RG,GBQCTLFW                                           10440019
         DROP  GR1RG                                                    10500019
         LA    GR1RG,GBLQLMFW          AND GLOBAL ENQUEUEING ELEMENT    10560019
         C     GR1RG,0(GR2RG)     CHECK FOR FIRST ON QUEUE              10620019
         BE    AFIO1                   BRANCH IF YES                    10680019
         BAL   INTLNKRG,AFRNQ          GO GET ON QUEUE                  10740019
AFIO1    BAL   LINK2RG,GTFBASE0   SETUP FILE CONTROL ADDRESSING         10800019
         USING AFCTLDS,FBXRG                                            10860019
         BAL  INTLNKRG,LOCINTR0     LOCATE MACRO INTERPRETER            10920019
         L     AFWRG,AREA1FW      ADDRESS RESTRICTED WORK AREA          10980019
         USING EXCPFWDS,AFWRG                                           11040019
         BAL   GR1RG,GETFNUM      PICK UP FILE NUMBER                   11100019
         LR    GR1RG,ICRG         COMPUTE INDEX TO BASE OF BUFFER       11160019
         MH    GR1RG,H6KN              DISCRIPTION TABLE BY MACRO       11220019
         TM    AFPAR2FS,MULTIPLE  CHECK FOR MULTIPLE OPERATION          11280019
         BZ    AFIO3                   BRANCH IF NOT                    11340019
         LA    GR3RG,1(GR3RG)          YES, BUMP MACRO INDEX            11400019
AFIO3    IC    ICRG,BUFFDEFF(GR3RG)    PICK UP MACRO BUFFER INDEX       11460019
         STC   ICRG,BUFNUMFW           AND SAVE BUFFER CONDITION BITS   11520019
         NI    BUFNUMFW,X'0F'                                           11580019
         SRA   ICRG,4             ISOLATE BUFFER TYPE INDEX             11640019
         AR    GR1RG,ICRG              AND ADD USER FILE NUMBER         11700019
         LA    GR1RG,BUFTYPFW-6(GR1RG) TO COMPUTE ADDRESS OF BUFFER     11760019
         OC    BUFNUMFW(1),0(GR1RG)    INDEX TO BE USED FOR OPERATION   11820019
         BAL   INTLNKRG,SETCON    ESTABLISH WORK CONSTANTS FOR MACRO    11880019
NEXTIO   BAL   LINK1RG,0(LINK2RG,BASERG)    ENTER MACRO INTERPRETER     11940019
         B     IOREQ             *I/O PROGRAM REQUEST, GO QUEUE REQUEST 12000019
*                                                                       12060019
* RETURN TO USER                                                        12120019
*                                                                       12180019
RETURN   TM    AFPAR2FS,GLOBAL+XLOOSIV SHOULD EXCLUSIVE CONTROL         12240019
         BC    9,RET1                  BE RELEASED?                     12300019
         L     GR1RG,GBLQLMFW          YES, DEQUEUE                     12360019
         ST    GR1RG,GBQCTLFW          GLOBAL FILE REQUEST              12420019
         LA    GR1RG,0(GR1RG)          CLEAR BYTE 0                     12480019
         LA    LINK1RG,GBQCTLFW+4      ADDR OF CTL ELEMENT 2ND WORD     12540019
         CR    GR1RG,LINK1RG           LAST ENTRY ON QUE??              12600019
         BE    NODEQ                   YES  -  BRANCH                   12660019
         OI    4(GR1RG),NQFLAG         POST NEXT NQ ENTRY READY         12720019
NODEQ    EQU   *                                                        12780019
RET1     EQU   *                                                        12840019
         DROP  AFWRG                                                    12900019
         NI    TUBAFPR1,C0KN                                            12960019
         SR    LINK2RG,LINK2RG                                          13020019
         IC    LINK2RG,TUBAFPR1                                         13080019
         SRL   LINK2RG,SETRET                                           13140019
         TM    AFPAR1FS,AFIOERR             SET USER CONDITION CODE     13200019
         BALR  AFPARG,0                AND SAVE FOR RETURN              13260019
EXIT     EQU   *                                                        13320019
         L     REGD,TUBSAVE+4          RESTORE SAVE REGISTER            13380019
         L     LINK1RG,12(REGD)                                         13440019
         LM    GR1RG,FBXRG,24(13)                                       13500019
         BR    LINK1RG        RETURN TO CALLER                          13560019
NOCORE   EQU   *                                                        13620019
         L     LINK1RG,AFQELMFW         GET OFF WORK AREA QUEUE  A34594 13630020
         ST    LINK1RG,AFQCTLFW                                  A34594 13640020
         LA    LINK1RG,0(LINK1RG)                                A34594 13650020
         LA    LINK2RG,AFQCTLFW+4       SECOND WORD OF CTL ELEMENA34594 13660020
         CR    LINK1RG,LINK2RG          LAST ENTRY ON QUEUE?     A34594 13670020
         BE    NODQ1                    YES, BRANCH              A34594 13680020
         OI    4(LINK1RG),NQFLAG        POST NEXT ENTRY ON WORK QA34594 13690020
NODQ1    MVI   TUBAFPR1,CD              SET GETMAIN FAIL RETURN  A34594 13700020
         B     RETURN                                            A34594 13710020
*                                                                       13800019
* SETUP LINKAGE AND ENTRY TO I/O REQUESTOR                              13860019
*                                                                       13920019
         USING AFCTLDS,FBXRG                                            13980019
         USING EXCPFWDS,AFWRG                                           14040019
*                                                                       14100019
IOREQ    IC    ICRG,0(LINK1RG)    PICK UP REQUESTOR ROUTINE CODE        14160019
         SLR   LINK1RG,BASERG     COMPUTE HALF WORD RETURN ADDRESS      14220019
         STH   LINK1RG,REZOOMLK        AND SAVE FOR RETURN              14280019
         SR    CCWRG,CCWRG        INITIALIZE REGISTERS FOR REQUESTOR    14340019
         LR    SRCHRG,CCWRG                                             14400019
         LA    GR2RG,MINXTND                                            14460019
         BAL   LINK1RG,EXNTRY0    ENTRY REQUESTOR ROUTINE               14520019
         DROP  BASERG                                                   14580019
         L     BASERG,AFIOEP     *NOIO RETURN; ESTABLISH BASE           14640019
         USING IHKAFI,BASERG                                            14700019
         B     BACK2INT                AND RETURN TO MACRO INTERPRETER  14760019
         DROP  BASERG                                                   14820019
         STC   CCWRG,NCCWSFW     *NQIO RETURN;  SAVE NUMBER CCW'S,      14880019
         STC   SRCHRG,NSRCHFW           NUMBER OF SEARCH ARGUMENTS      14940019
         STH    GR2RG,XTNDFW            EXTENDED WORK AREA REQUIREMENT  15000019
         MVI   TRKFW+2,ZERO            ZERO HIGH ORDER TRACK    A45668  15020026
         STC   GR3RG,TRKFW+3           H                        A45668  15040026
         SRL   GR3RG,EIGHT                                      A45668  15060026
         SH    GR3RG,H256KN                  CC                  A45668 15070026
         STH   GR3RG,TRKFW             CC                       A45668  15080026
*                                                                       15120019
* ENQUEUE REQUEST FOR EXTENDED WORK AREA                                15180019
*                                                                       15240019
         L     BASERG,AFIOEP      ESTABLISH PROGRAM BASE                15300019
         USING IHKAFI,BASERG                                            15360019
         DROP  AFWRG                                                    15420019
         LA    GR1RG,AFQELMFW     LOAD ARGUMENTS FOR ENQUEUEING I/O     15480019
         LA    GR2RG,AFQCTLFW          REQUEST                          15540019
         BAL   INTLNKRG,AFRNQ          GO GET ON QUEUE                  15600019
         BAL   LINK2RG,GETFBASE   REESTABLISH FILE CONTROL BASE REG.    15660019
         USING AFCTLDS,FBXRG                                            15720019
         USING EXCPFWDS,AFWRG                                           15780019
         BAL   INTLNKRG,SETCON    SET UP CONSTANTS IN EXTENDED WORK     15840019
*                                                                       15900019
* ASSIGN STORAGE FOR NEXT I/O OPERATION AND GENERATE CCW LIST           15960019
*                                                                       16020019
         TM    XTNDFW,X'80'       IS A BUFFER ASSIGNMENT REQUESTED      16080019
         BZ    NOBUFF                  BRANCH IF NOT                    16140019
         TM    BUFNUMFW,BUFATT    ONLY ASSIGN BUFFER IF NONE            16200019
         BO    NOBUFF                  ATTACHED ALREADY                 16260019
         TM    TUBAFISW,BUFCTL         IS USER CONTROLLING BUFFERS?     16320019
         BO    NOBUFF1                 YES - BRANCH                     16380019
         LH     GR1RG,BLKSZFW     PICK UP BLOCKSIZE                     16440019
         AH    GR1RG,H8KN              BUMP LNGTH BY 8 FOR CTL WORDS    16500019
         ST    GR1RG,GETCORE           STORE LNGTH IN GETMAIN LIST      16560019
         LA    GR1RG,BUFFADSS          PTR TO BUFFER ADDRESS            16620019
         ST    GR1RG,GETCORE+4         STORE PTR INTO GETMAIN LIST      16680019
         LA    GR1RG,GETCORE           ADDRESS OF GETMAIN LIST          16740019
         GETMAIN  ,MF=(E,(1))          GET A BUFFER                     16800019
         LTR   LINK2RG,LINK2RG         WAS GETMAIN SUCCESSFUL           16860019
         BNZ   NOCORE                  NO  -  BRANCH                    16920019
         L     GR1RG,BUFFADSS          PICKUP PTR TO ALLOCATED CORE     16980019
         L     LINK2RG,GETCORE         LNGTH OF ALLOCATED CORE          17040019
         ST    LINK2RG,0(GR1RG)        STORE LNGTH IN 1ST CTL WORD      17100019
         ST    GR1RG,4(GR1RG)          STORE PTR IN 2ND CTL WORD        17160019
         DROP  AFWRG                                                    17220019
NOBUFF1  EQU   *                                                        17280019
         BAL   LINK2RG,GETFBASE   REESTABLISH FILE CONTROL BASE         17340019
         USING AFCTLDS,FBXRG                                            17400019
         USING EXCPFWDS,AFWRG                                           17460019
         OI    BUFNUMFW,BUFATT    INDICATE BUFFER ATTACHED TO FILE      17520019
NOBUFF   LH    CCWRG,XTNDFW       COMPUTE BEGINNING OF CCW LIST - 8     17580019
         LPR   CCWRG,CCWRG                                              17640019
         LA    CCWRG,EXTENDFW-1(CCWRG)      INSURE DOUBLE WORD BOUNDARY 17700019
         N     CCWRG,X3BIT0KN                                           17760019
         ST    CCWRG,CCWRGFW           AND SAVE                         17820019
         LA    SRCHRG,8(CCWRG)    SETUP IOB CCW LIST POINTER            17880019
         ST    SRCHRG,IOBSTART                                          17940019
         SR    ICRG,ICRG                                                18000019
         IC    ICRG,NCCWSFW       COMPUTE BEGINNING OF SEARCH ARGUMENT  18060019
         SLA   ICRG,3                  LIST - 8                         18120019
         LA    SRCHRG,0(ICRG,CCWRG)                                     18180019
         ST    SRCHRG,SRCHRGFW         AND SAVE                         18240019
         SR    ICRG,ICRG          COMPUTE LENGTH OF SEARCH ARGUMENT     18300019
         IC    ICRG,NSRCHFW            LIST                             18360019
         LR    GR0RG,ICRG         PROVIDE TABLE INITIALIZER WITH COUNT  18420019
         SLA   ICRG,3                  OR SEARCH ARGUMENTS.             18480019
         LA    ICRG,7(ICRG)       CLEAR LASR CCW AND SET UP             18540019
         EX    ICRG,CLEARGS            DUMMY CHANNEL PROGRAM ELEMENTS   18600019
         SR    ICRG,ICRG          SETUP ENTRY TO CCW INITIALIZER        18660019
         LH    LINK1RG,REZOOMLK        ROUTINE                          18720019
         IC    ICRG,1(LINK1RG,BASERG)                                   18780019
         BAL   LINK1RG,EXNTRY0         AND GO THERE                     18840019
         DROP  BASERG                                                   18900019
         SR    INTLNKRG,INTLNKRG *SORT RETURN, SET FOR SORT OF SEARCH   18960019
         BALR  BASERG,0                ARGUMENT LIST                    19020019
         USING *,BASERG                                                 19080019
         B     SORTARGS                                                 19140019
         DROP  BASERG                                                   19200019
         LA    INTLNKRG,SORTLGH  *NOSORT RETURN, SET FOR NOSORT ENTRY   19260019
SORTARGS ST    LINK1RG,EXRETLK    SAVE EXECUTOR RETURN ADDRESS          19320019
         L     CCWRG,CCWRGFW      SETUP TEMPORARY STORAGE BASE          19380019
         L     SRCHRG,SRCHRGFW         REGISTERS                        19440019
         L     BASERG,CCWSRTLK    BASE REGISTER FOR CCW GENERATORS      19500019
         USING GENCCWDS,BASERG                                          19560019
         LA    INTLNKRG,SORTNTR(INTLNKRG)   COMPUTE PROGRAM ENTRY POINT 19620019
         DROP  BASERG                                                   19680019
         IC    ICRG,NSRCHFW       PROVIDE CCW GENERATOR WITH SEARCH     19740019
         LR    GR0RG,ICRG              ARGUMENT COUNT                   19800019
         BALR  LINK2RG,0          GENERATE CCW LIST FROM SEARCH         19860019
         USING *,LINK2RG               ARGUMENT                         19920019
         BAL   LINK2RG,EXNTRY2         LIST                             19980019
         DROP  LINK2RG                                                  20040019
         L     BASERG,AFIOEP      ESTABLISH PROGRAM BASE                20100019
         USING IHKAFI,BASERG                                            20160019
*                                                                       20220019
*        COMPLETE SEARCH ARGUMENT LIST                                  20280019
*                                                                       20340019
         L     GR1RG,TRKFW             SEARCH ARGUMENTS - CCHH  A45668  20440026
         L     SRCHRG,SRCHRGFW    LOCATE SEARCH ARGUMENT LIST           20640019
         IC    ICRG,NSRCHFW            AND COUNT                        20700019
NXTCCHH  LA    SRCHRG,8(SRCHRG)   LOOP THROUGH LIST SETTING UP          20760019
         ST     GR1RG,0(SRCHRG)        FIRST WORD                       20820019
         BCT   ICRG,NXTCCHH            OF EACH SEARCH ARGUMENT          20880019
         ST     GR1RG,IOBSEEK+4                                         21000019
         MVC   IOBSEEK+3(FOUR),IOBSEEK+4                        A45668  21020026
         MVI   IOBSEEK+7,ZERO          R                        A45668  21040026
         L     CCWRG,CCWRGFW      CHECK FIRST CCW FOR LEGALITY          21060019
         USING CCWMSK,CCWRG            TO PREVENT SYSTEM ABEND ON SIO   21120019
         CLI   CCWCMCD1,SRCHIDEQ       SEARCH COUNT/ID LEGAL            21180019
         BE    EXCP                                                     21240019
         CLI   CCWCMCD1,READHA         OR READ HOME ADDRESS             21300019
         DROP  CCWRG                                                    21360019
         BNE   ERRSET                  USER I/O ERROR EXIT IF NOT       21420019
*                                                                       21480019
*        SAVE EXECUTOR RETURN AND START CHANNEL PROGRAM                 21540019
*                                                                       21600019
EXCP     NI    ECB,RSTECB                                               21660019
         EXCP  IOB                ISSUE I/O SVC                         21720019
         L     LINK2RG,DISPEP          DISPATCHER ENTRY POINT           21780019
         LA    GR1RG,ECB                                                21840019
         BALR  LINK1RG,LINK2RG         GO TO DISPATCHER AND WAIT        21900019
*                                         FOR I/O COMPLETION            21960019
CHKIO    EQU   *                                                        22020019
*                                                                       22080019
*   CHECK RESULTS OF I/O OPERATION - TWO SITUATIONS THAT IOS MAY        22140019
*   REGARD AS ERRORS ARE ACCEPTABLE CONDITIONS TO AFIO.  THESE          22200019
*   ARE 'NO RECORD FOUND' CONDITION ON A SEARCH EQUAL COMMAND           22260019
*   THAT REFERENCES RECORD 1 AND A 'TRACK OVERRUN' CONDITION ON         22320019
*   AN ERASE COMMAND.                                                   22380019
*                                                                       22440019
         CLI   IOBECBCC,COMPCOD0       GOOD I/OXX                       22500019
         BNE   IONOGD                  NO - BRANCH                      22560019
         L     GR4RG,IOBCSW            LOCATE                           22620019
         LA    GR4RG,0(0,GR4RG)           LAST                          22680019
         SH    GR4RG,H16KN                   CSW                        22740019
         USING CCWMSK,GR4RG                                             22800019
         L     LINK1RG,CCWADDR0                                         22860019
         USING CNTSRCH,LINK1RG                                          22920019
         TM    IOBCSW+5,ILI            CHECK FOR NO RECORD FOUND        22980019
         BZ    CHKOK                   GOOD IF NOT                      23040019
         CLI   CCWCMCD1,SRCHKEEQ       SEARCH EQUAL CMD?                23100019
         BNE   CHKOK                   NO - BRANCH                      23160019
         CLI   SRCHR0,ONE              REFERENCING RECORD ONE??         23220019
         BNE   CHKOK                   NO - BRANCH                      23280019
         OI    AFPAR1FS,AFXCPTN        YES - SET FILE EXCEPTION         23340019
         B     CHKOK                   GET OUT                          23400019
IONOGD   EQU   *                                                        23460019
         CLI   IOBECBCC,COMPCOD1       POSSIBLY IGNORE CHECKING         23520019
         BNE   ERROR                   YES - IGNORE                     23580019
         L     GR4RG,IOBCSW            LOCATE                           23640019
         LA    GR4RG,0(0,GR4RG)            LAST                         23700019
         SH    GR4RG,H16KN                     CSW                      23760019
         USING CCWMSK,GR4RG                                             23820019
         L     LINK1RG,CCWADDR0                                         23880019
         USING CNTSRCH,LINK1RG                                          23940019
         TM    IOBCSW+5,ILI            CHECK FOR NO RECORD FOUND        24000019
         BZ    CHKOVRN                 GO CHECK FOR OVERRUN             24060019
         CLI   CCWCMCD1,SRCHKEEQ       SEARCH EQUAL CMD?                24120019
         BNE   CHKOVRN                 NO - BRANCH                      24180019
         CLI   SRCHR0,ONE              REFERENCING RECORD ONE??         24240019
         BNE   CHKOVRN                 NO - BRANCH                      24300019
         OI    AFPAR1FS,AFXCPTN        SET FILE EXCEPTION               24360019
         B     CHKOK                                                    24420019
CHKOVRN  EQU   *                                                        24480019
         TM    IOBSENS1,TRKOVRUN       TRACK OVERRUN??                  24540019
         BZ    ERROR                                                    24600019
         CLI   CCWCMCD1,ERASE          OVERRUN ON ERASE COMMAND??       24660019
         BNE   ERROR                                                    24720019
         B     CHKOK                                                    24780019
ERROR    EQU   *                                                        24840019
         OI    AFPAR1FS,AFIOERR        SET I/O ERROR INDICATION         24900019
CHKOK    EQU   *                                                        24960019
         DROP  AFWRG                                                    25020019
         DROP  GR4RG                                                    25080019
         DROP  LINK1RG                                                  25140019
         BAL   LINK2RG,GETFBASE   ESTABLISH FILE CONTROL BASE REGISTER  25200019
         USING AFCTLDS,FBXRG                                            25260019
         USING EXCPFWDS,AFWRG                                           25320019
         BAL   LINK2RG,ERRCHK     CHECK FOR I/O ERRORS                  25380019
*                                                                       25440019
*        RETURN TO EXECUTOR AFTER CHANNEL END (NEEDS ERROR TESTS)       25500019
*                                                                       25560019
         BAL   LINK1RG,EXNTRY     CHANNEL END ENTRY TO EXCUTOR          25620019
         DROP  BASERG                                                   25680019
         L     BASERG,AFIOEP     *ENDIO RETURN, ESTABLISH PROGRAM BASE  25740019
         USING IHKAFI,BASERG                                            25800019
         B     ENDIO                   AND SETUP REENTRY TO EXECUTO     25860019
         DROP  BASERG                                                   25920019
         L     BASERG,AFIOEP     *EXCP RETURN, ESTABLISH PROGRAM BASE   25980019
         USING IHKAFI,BASERG                                            26040019
         ST    LINK1RG,EXRETLK         SAVE RETURN TO EXECUTOR          26100019
         B     EXCP                    AND GO RESTART CHANNEL PROGRAM   26160019
ENDIO    ST    LINK1RG,EXRETLK    SAVE RETURN ADDRESS                   26220019
         BAL   LINK1RG,EXNTRY          AND REENTER FOR ASI CLEANUP      26280019
         DROP  BASERG                                                   26340019
         L     BASERG,AFIOEP     *NORMAL ASI RETURN, ESTABLISH BASERG   26400019
         USING IHKAFI,BASERG                                            26460019
         B     ENDIO1             GO CHECK FOR I/O ERROR                26520019
         DROP  BASERG                                                   26580019
         L     BASERG,AFIOEP     *RELEASE BUFFER RETURN FROM ASI.       26640019
         USING IHKAFI,BASERG                                            26700019
         TM    BUFNUMFW,BUFATT    MAKE SURE BUFFER ATTACHED             26760019
         BZ    ENDIO1                  BRANCH IF NOT                    26820019
         TM    AFPAR2FS,MULTIPLE       AND EMPTY IF MULTIPLE BUFFER     26880019
         BZ    FREEBLOC                                                 26940019
         CLC   COUNTFS(1),COUNTFS+1                                     27000019
         BE    FREEBLOC                                                 27060019
ENDIO1   BAL   LINK2RG,ERRCHK     CHECK FOR I/O ERROR SET               27120019
         B     NOBUFRL                 BRANCH IF NO ERROR               27180019
ERRSET   OI    AFPAR1FS,AFIOERR   SET I/O ERROR INDICATION              27240019
ERRCHK   TM    AFPAR1FS,AFIOERR   CHECK FOR I/O ERROR                   27300019
         BCR   14,LINK2RG         EXIT IF NOT                           27360019
*                                 ERROR,PUT FILE INTO POINT MODE S21016 27365000
*                                                                       27370000
         TM    TUBAFISW,WMSTRT     IS IHKAWS USING AFIO?         S21016 27375000
         BO    ERRCHK1             YES-BYPASS SYNADAF ROUTINE    S21016 27380000
*                                                                S21016 27385000
*****************************************************************S21016 27390000
*                                                               *S21016 27395000
*              ACTIVE AREA I/O ERROR ANALYSIS ROUTINE           *S21016 27400000
*                                                               *S21016 27405000
*****************************************************************S21016 27410000
*                                                                S21016 27415000
         SYNADAF ACSMETH=EXCP,PARM1=IOB  FIND OUT WHAT WENT WRONGS21016 27420000
         MVC   SNADWRD,SIXTY8(R1)  SAVE ACTUAL ERROR MESSAGE     S21016 27425000
         LA    R1,MSG242A          SAVE PARM LIST ADDRESS        S21016 27430000
         WTO   ,MF=(E,(R1))        TELL OPERATOR WHAT WENT WRONG S21016 27435000
         SYNADRLS                  RELEASE WORK AREA             S21016 27440000
*                                                                S21016 27445000
*                                                                S21016 27450000
*                                                                S21016 27455000
ERRCHK1  EQU   *                                                 S21016 27460000
         MVI   STATUSFW,0                                        S21016 27465000
         MVI   SEGNUMFW,0                                               27480019
         NI    AVLRECFW,X'FF'-INSRTOVF                                  27540019
         LA    LINK1RG,RETURN-AFIO-2   SET RETURN TO EXIT TO USER       27600019
         STH   LINK1RG,REZOOMLK                                         27660019
         TM    BUFNUMFW,BUFATT    RELEASE BUFFER IF ONE ATTACHED        27720019
         BZ    NOBUFRL                 BRANCH IF NO BUFFER ATTACHED     27780019
FREEBLOC EQU   *                                                        27840019
         TM    TUBAFISW,BUFCTL         IS USER CONTROLLING BUFFERS?     27900019
         BO    NOBUFRL1                YES - BRANCH                     27960019
         ST    GR0RG,TUBLBXAF                                           28020019
         L     LINK2RG,TUBRAFBF        LOAD PTR TO BUFFER               28080019
         LM    GR0RG,GR1RG,0(LINK2RG)  LOAD LENGTH AND POINTER          28140019
*                                           CONTROL WORDS               28200019
         FREEMAIN  R,LV=(0),A=(1)      RELEASE BUFFER                   28260019
         L     GR0RG,TUBLBXAF                                           28320019
         DROP  AFWRG                                                    28380019
NOBUFRL1 EQU   *                                                        28440019
         BAL   LINK2RG,GETFBASE   RESTORE RAFIO BASE TO CONTROL INFO.   28500019
         USING AFCTLDS,FBXRG                                            28560019
         USING EXCPFWDS,AFWRG                                           28620019
         NI    BUFNUMFW,X'FF'-BUFATT   NO MORE BUFFER                   28680019
NOBUFRL  L     LINK1RG,AFQELMFW   DEQUEUE I/O REQUEST                   28740019
         ST    LINK1RG,AFQCTLFW                                         28800019
         LA    LINK1RG,0(LINK1RG)      CLEAR BYTE 0                     28860019
         LA    LINK2RG,AFQCTLFW+4      ADDR OF CTL ELEMENT 2ND WORD     28920019
          CR    LINK1RG,LINK2RG         LAST ENTRY ON QUE??             28980019
         BE    NODQ                    YES  -  BRANCH                   29040019
         OI    4(LINK1RG),NQFLAG       POST NEXT NQ ENTRY READY         29100019
NODQ     EQU   *                                                        29160019
         LR    GR1RG,AFWRG        SWITCH TO RESTRICTED WORK AREA        29220019
         L     AFWRG,AREA1FW           SAVING PRESENT DEFINITION        29280019
         MVC   VARIOFW,VARIOFW-EXCPFWDS(GR1RG)                          29340019
BACK2INT LH    LINK2RG,REZOOMLK   CONTINUE WITH TABLE INTERPRETER       29400019
         LA    LINK2RG,2(LINK2RG)      BUMP TO INTERPRETER RETURN       29460019
         B     NEXTIO                                                   29520019
*                                                                       29580019
         DROP  AFWRG                                                    29640019
         DROP  FBXRG                                                    29700019
*                                                                       29760019
LOCINTR0 NI    AFPAR1FS,X'0F'     RESET MACRO EXECUTION CONTROL BITS    29820019
LOCINTR  LA    LINK2RG,X'0F'      PICK UP MACRO CODE NUMBER             29880019
         IC    GR3RG,AFPAR1FS                                           29940019
         NR    GR3RG,LINK2RG                                            30000019
         AR    GR3RG,GR3RG        PICK UP HALF WORD DISPLACEMENT        30060019
         LH    LINK2RG,MACTAB(GR3RG)   TO BEGINNING OF INTERPRETER      30120019
         BR    INTLNKRG                AND RETURN                       30180019
*                                                                       30240019
*                                                                       30300019
GETFBASE L     AFWRG,AREA2FW      ADDRESS EXTENDED WORK/CONSTANT AREA   30360019
GTFBASE0 LA    FBXRG,AFCTLFW                                            30420019
         USING AFCTLDS,FBXRG                                            30480019
         TM    AFPAR2FS,GLOBAL    CHECK FOR GLOBAL                      30540019
         BCR   8,LINK2RG               PRIVATE, EXIT                    30600019
         BAL   INTLNKRG,GETGBASE       AND ADDRESS GLOBAL FILE CONTROL  30660019
         LR    FBXRG,GR1RG                                              30720019
         BALR  LINK2RG,LINK2RG    RETURN WITH ADDRESS OF 'SETCON'       30780019
         USING EXCPFWDS,AFWRG                                           30840019
SETCON   BAL   GR1RG,GETFNUM      PICK UP FILE NUMBER AND NEXTKEY PTR.  30900019
         ST    GR2RG,NXTKEYFW          SAVE KEY FIELD POINTER           30960019
         IC    ICRG,RECTYPFW-1(ICRG)   PICK UP RECORD DISCRIPTION       31020019
         LA    GR1RG,RECTABFW(ICRG)    INDEX AND COMPUTE ADDRESS        31080019
         MVC   VARIO1FW,0(GR1RG)  MOVE RECORD DISCRIPTION TO WORK AREA  31140019
         IC    ICRG,BUFNUMFW      PICK UP BUFFER DISCRIPTION INDEX      31200019
         SRA   ICRG,4                                                   31260019
         LR    GR1RG,ICRG                                               31320019
         MH    GR1RG,BUFTLGFW     COMPUTE ADDRESS OF BUFFER DISCRIPTION 31380019
         LA    GR1RG,BUFTABFW(GR1RG)        CONSTANTS                   31440019
         MVC   VARIO2FW,0(GR1RG)       AND MOVE TO WORK AREA            31500019
         BR    INTLNKRG           EXIT                                  31560019
         DROP  AFWRG                                                    31620019
GETFNUM  IC    ICRG,ACTNUMFS      ASSUME PRIVATE FILE REFERENCE         31680019
         USING TUBDSECT,GR2RG                                           31860019
         LA    GR2RG,NEXKYFS                                            31920019
         DROP  GR2RG                                                    31980019
         TM    AFPAR2FS,GLOBAL    CHECK FOR GLOBAL                      32040019
         BCR   8,GR1RG                 EXIT IF NOT                      32100019
         IC    ICRG,GBLNUMFS           YES, SET UP FOR GLOBAL FILE      32160019
         LA    GR2RG,GBLKEYFS                                           32220019
         BR    GR1RG                                                    32280019
*                                                                       32340019
         DROP  FBXRG                                                    32400019
*                                                                       32460019
*                                                                       32520019
GETGBASE LR    GR1RG,ICRG         COMPUTE RELATIVE POSITION WITHIN      32580019
         IC    GR1RG,GBLNUMFS          KONBOX                           32640019
         BCTR  GR1RG,0                                                  32700019
         MH    GR1RG,GBFCLGKN                                           32760019
         LA    GR1RG,GBFORGFW(GR1RG)   AND ABSOLUTE LOCATION            32820019
         BR    INTLNKRG                                                 32880019
*                                                                       32940019
AFRNQ    EQU   *                                                        33000019
         MVI   4(GR1RG),ZERO           RESET ECB                        33060019
         LA    GR3RG,4(GR2RG)          POINT TO 2ND WORD OF CTL LEMNT   33120019
         ST    GR3RG,0(GR1RG)          POINT QUELEMENT TO IT            33180019
         CLC   1(3,GR1RG),1(GR2RG)     IS QUE EMPTY??                   33240019
         BNE   NOTFIRST                NO - BRANCH                      33300019
         ST    GR1RG,0(GR2RG)          ENQUEUE THIS ELEMENT AS          33360019
         ST    GR1RG,4(GR2RG)              FIRST ON QUEUE               33420019
         B     AFRNQ1                                                   33480019
NOTFIRST EQU   *                                                        33540019
*   PLACE THIS ELEMENT INTO THE QUEUE AND UPDATE THE CHAIN              33600019
         L     GR3RG,4(GR2RG)          POINT TO LAST ELEMENT ON QUE     33660019
         ST    GR1RG,0(GR3RG)          CHAIN THAT ELEMENT TO THIS ONE   33720019
         ST    GR1RG,4(GR2RG)          POINT 2ND WORD OF CTL ELEMENT    33780019
*                                          TO THIS QUE ELEMENT          33840019
         LA    GR1RG,4(GR1RG)          LOAD ECB PTR FOR DISPATCHER      33900019
         L     LINK2RG,DISPEP                                           33960019
         BALR  LINK1RG,LINK2RG         WAIT IN DISPATCHER UNTIL         34020019
*                                          POSTED ON TOP OF QUEUE       34080019
AFRNQ1   EQU   *                                                        34140019
         BR    INTLNKRG                RETURN TO CALLER                 34200019
*                                                                       34260019
*        SETUP ALL REGISTERS FOR THE CHANNEL PROGRAM GENERATOR AND      34320019
*        EXECUTOR.                                                      34380019
*                                                                       34440019
         USING EXCPFWDS,AFWRG                                           34500019
EXNTRY0  L     INTLNKRG,EXBASELK  COMPUTE ROUTINE ENTRY POINT IN THE    34560019
         AH    INTLNKRG,0(ICRG,INTLNKRG)    EXECUTOR MODULE             34620019
         B     EXNTRY1                 GO SETUP BASE AND RETURNS        34680019
EXNTRY   L     CCWRG,CCWRGFW      ESTABLISH BASE REGISTERS FOR CCW LIST 34740019
         L     SRCHRG,SRCHRGFW         AND SEARCH ARGUMENT LIST         34800019
         L     INTLNKRG,EXRETLK   PICK UP RETURN ADDRESS                34860019
EXNTRY1  L     BASERG,EXBASELK    SETUP EXECUTOR BASE REGISTER          34920019
         DROP  BASERG                                                   34980019
         LA    LINK2RG,8(LINK1RG) SETUP ALTERNATE RETURN ADDRESS        35040019
         ST    LINK1RG,EXRETLK    SAVE PRIMARY RETURN ADDRESS           35100019
EXNTRY2  ST    LINK2RG,EXRET2LK   SAVE ALTERNATE RETURN ADDRESS         35160019
         BR    INTLNKRG           GO TO SPECIFIED ENTRY                 35220019
*                                                                       35280019
         DROP  AFWRG                                                    35340019
*                                                                       35400019
CLEARGS  XC    0(0,SRCHRG),0(SRCHRG)   CLEAR SEARCH ARG LIST + LAST CCW 35460019
GETCORE  GETMAIN  EC,LV=88,A=GETCORE+4,MF=L                             35520019
*                                                                       35580019
*        TABLE OF STARTING TABLE DISPLACEMENTS FOR THE VARIEOUS MACROS  35640019
*                                                                       35700019
MACTAB   DS    0H                 ORIGIN OF MACRO INTERPRETER BASES     35760019
CREATMAC DC    Y(CREATONE-AFIO)   CREATE MACRO INTERPRETER              35820019
         DC    Y(RELESNTR-AFIO)   RELEASE                               35880019
         DC    Y(POINTNTR-AFIO)   POINT                                 35940019
         DC    Y(ENDUPNTR-AFIO)   ENDUP                                 36000019
         DC    Y(INSRTNTR-AFIO)   INSERT                                36060019
         DC    Y(DELETNTR-AFIO)   DELETE                                36120019
         DC    Y(REPLCNTR-AFIO)   REPLACE                               36180019
RGETMAC  DC    Y(GETNTR-AFIO)     RGET                                  36240019
         DC    Y(SKIPNTR-AFIO)    SKIP                                  36300019
*                                                                       36360019
* BUFFER INDEX TABLE BY MACRO TYPE                                      36420019
*                                                                       36480019
BUFFDEFF EQU   *                  ORIGIN OF BUFFER DEFINITIONS BY MACRO 36540019
         DK    NOBUF                   CREATE  (NO BUFFER)              36600019
         DK    NOBUF                                                    36660019
         DK    NOBUF                   RELEASE (NO BUFFER)              36720019
         DK    NOBUF                                                    36780019
         DK    SPNTBUF                 POINT                            36840019
         DK    MPNTBUF                                                  36900019
         DK    NOBUF                   ENDUP   (NO BUFFER)              36960019
         DK    NOBUF                                                    37020019
         DK    SINSBUF+BUFATT          INSERT                           37080019
         DK    MINSBUF+BUFATT                                           37140019
         DK    NOBUF                   DELETE  (NO BUFFER)              37200019
         DK    NOBUF                                                    37260019
         DK    SREPBUF+BUFATT          REPLACE                          37320019
         DK    MREPBUF+BUFATT                                           37380019
         DK    SGETBUF                 RGET                             37440019
         DK    MGETBUF                                                  37500019
         DK    NOBUF                   SKIP    (NO BUFFER)              37560019
         DK    NOBUF                                                    37620019
*                                                                       37680019
         USING IHKAFI,BASERG                                            37740019
         USING AFCTLDS,FBXRG                                            37800019
         USING EXCPFWDS,AFWRG                                           37860019
*                                                                       37920019
**********************************************************************  37980019
*                                                                       38040019
* CREATNTR - CREATE MACRO INTERPRETER ROUTINE.                          38100019
*                                                                       38160019
CREATONE EQU   *                                                        38220019
         DROP  AFWRG                                                    38280019
M0029    EQU   *                                                        38340019
         USING EXCPFWDS,AFWRG                                           38400019
         BAL   LINK2RG,ALLOCIF    FIRST CREATE ALSO CAUSES THE          38460019
         ST     GRDRG,MASTRKFW         MASTER INDEX TO BE ALLOCATED     38520019
         TM    TUBAFISW,WMSTRT         IS IHKAWS USING AFIO             38580019
         BO    NOFORMT                 YES - SKIP M.I. FORMATTING       38640019
         BALR  LINK1RG,LINK1RG         FORMAT MASTER INDEX              38700019
         DK    GENMASBQ                                                 38760019
         DK    GENMASBX                                                 38820019
NOFORMT  EQU   *                                                        38880019
         LA    LINK2RG,CREATNTR-AFIO   SET ONE WAY SWITCH FOR           38940019
         STH   LINK2RG,CREATMAC        SUBSEQUENT ENTRIES               39000019
CREATNTR EQU   *                                                        39060019
         TM    TUBAFISW,WMSTTOVR       HAS WARMSTART COMPLETED          39120019
         BZ    CREATNT1                NO - BRANCH                      39180019
         NI    TUBAFISW,ALL-WMSTTOVR   YES - TURN OFF SWITCH            39240019
         L     GRORG,TRACKSFW          ADDRESS OF TAT                   39300019
         MVI   0(GRORG),ALLTRKS        REINITIALIZE TAT TO SHOW NO      39360019
*                                      TRACKS ALLOCATED                 39420019
         B     M0029                   1ST CREATE (IS) IS BEING         39480019
*                                      ISSUED SINCE WMSTRT BEGAN -      39540019
*                                      EVERYTHING BACK TO NORMAL        39600019
*                                      PROCEED AS WITH NORMAL STARTUP   39660019
CREATNT1 EQU   *                                                        39720019
         XC    FCTLFW,FCTLFW           INITIALIZE FILE CONTROL INFO     39780019
*                                                                       39840019
* SETUP RELATIVE FILE NUMBER INDEX                                      39900019
*                                                                       39960019
         IC    ICRG,GBLNUMFS      ASSUME GLOBAL FILE                    40020019
         TM    AFPAR2FS,GLOBAL    CHECK ASSUMPTION                      40080019
         BO    CREAT0                  BRANCH IF CORRECT                40140019
         IC    ICRG,ACTNUMFS           NO, PICK UP INITIAL PRIVATE NUM  40200019
         AH    ICRG,GBLCNTKN           AND COMPUTE ACTUAL REL. FILE NUM 40260019
         STC   ICRG,ACTNUMFS                                            40320019
*                                                                       40380019
* COMPUTE NUMBER OF DATA RECORDS PER DATA TRACK USING THE FOLLOWING     40440019
*        FORMULA:                                                       40500019
*                                                                       40560019
*        N = (UMAXAVAL+ULKDDFW*UC3FW/UC4FW-ULKDDFW-UC1FW-6)/            40620019
*              ((ULKDDFW+4)*UC3FW/UC4FW+UC12FW)                         40680019
*                                                                       40740019
CREAT0   IC    ICRG,RECTYPFW-1(ICRG)   LOCATE RECORD DESCRIPTION        40800019
         LA    INTLNKRG,RECTABFW(ICRG)      CONSTANT AREA IN KON BOX    40860019
         DROP  AFWRG                                                    40920019
         USING VARIO1FW,INTLNKRG       AND USE IT TEMPORARILY           40980019
         LH    GRORG,ULKDDFW      APPROXIMATE RECORD LENGTH WITH        41040019
         LA    GRORG,4(GRORG)          EXTRA FOUR BYTES FOR CHAIN       41100019
         MH    GRORG,UC3FW             RECORD.  COMPUTE TOLERANCE.      41160019
         SRA   GRORG,9            DIVIDE BY 512                       R 41220019
         AH    GRORG,UC12FW                                             41280019
         LR   GRD2RG,GRORG        SAVE EFFECTIVE LENGTH OF EACH RECORD  41340019
         LH    GRORG,ULKDDFW      COMPUTE EFFECTIVE TOTAL NUMBER        41400019
         MH    GRORG,UC3FW             OF BYTES ON TRACK                41460019
         SRA   GRORG,9                                                R 41520019
         SH    GRORG,ULKDDFW                                            41580019
         AH    GRORG,UMAXAVAL                                           41640019
         SH    GRORG,UC1FW                                              41700019
         SH    GRORG,H6KN                                               41760019
         SR    GRERG,GRERG        COMPUTE MAX. NUMBER OF DATA RECORDS   41820019
         DR    GRERG,GRD2RG                                             41880019
         CH    GRORG,LRCHANFW     CHECK FOR EXCESS OF MAXIMUM ALLOWABLE 41940019
         BC    12,CREAT0A              BRANCH IF NOT                    42000019
         LH    GRORG,LRCHANFW          USE MAXIMUM                      42060019
CREAT0A  STH   GRORG,ULDCFW       SET UP USER CONSTANTS                 42120019
         LA    GRDRG,0(GRORG,GRORG)    COMPUTE LENGTH OF TRACK CHAIN    42180019
         LA    GRDRG,6(GRORG,GRDRG)                                     42240019
         STH   GRDRG,ULKCFW            AND SAVE                         42300019
         BCTR  GRORG,0            MACHINE LENGTH OF RECORD CHAIN        42360019
         STH   GRORG,UMLDCFW                                            42420019
         LA    GRORG,2(GRORG)          AND MAXIMUM RECORD NUMBER        42480019
         STH   GRORG,UDNRECFW                                           42540019
         DROP  INTLNKRG                                                 42600019
         USING EXCPFWDS,AFWRG     BACK TO NORMAL WORK/CONSTANT AREA     42660019
         TM    AFPAR2FS,OLDFILE   CHECK FOR FILE ALREADY EXISTS         42720019
         BO    CREAT1                  BRANCH IF YES                    42780019
         BAL   LINK2RG,ALLOCIF    ALLOCATE TRACK FOR INDEX RECORD       42840019
         ST    GRDRG,NDXRTKFW          AND ASSIGN                       42900019
         MVC   FNAMEFW(8),TUBUSRID     USERID TO PREFIX                 42960019
*                                      FOR ACTIVE AREA RECOVERY         43020019
         BALR  LINK1RG,LINK1RG    INITIALIZE INDEX TRACK                43080019
         DK    NDXINTBQ                                                 43140019
         DK    NDXINTBX                                                 43200019
         XC    FNAMEFW,FNAMEFW    COMPLETE CONTROL BLOCK INITIALIZATION 43260019
         MVI   NDXRTKFW,1              INDEX RECORD ONE                 43320019
         MVI   TKLSTZFW,16             NO TRACK LIST ENTRIES            43380019
         MVI   SEGR1FW,X'FF'           AT END OF DATA                   43440019
         BALR  LINK1RG,LINK1RG    UPDATE MASTER INDEX RECORD            43500019
         DK    CHKNDXBQ                                                 43560019
         DK    CHKNDXBX                                                 43620019
         B     4(LINK1RG)              EXIT TO USER                     43680019
CREAT1   BALR  LINK1RG,LINK1RG    LOCATE INDEX RECORD THROUGH           43740019
         DK    LOCNDXBQ                MASTER INDEX                     43800019
         DK    LOCNDXBX                                                 43860019
         BALR  LINK1RG,LINK1RG         AND DETERMINE INDEX RECORD       43920019
         DK    OLDNDXBQ                CHARACTERISTICS                  43980019
         DK    OLDNDXBX                                                 44040019
         B     4(LINK1RG)              EXIT TO USER                     44100019
*                                                                       44160019
*********************************************************************** 44220019
*                                                                       44280019
* RELEASE - MACRO INTERPRETER TO RELASE ALL EXTERNAL STORAGE FOR THE    44340019
*        PRESENT FILE.  THE MASTER INDEX ENTRY IS DELETED, AND          44400019
*        THE FILE CHECKPOINT INFORMATION IS RETRIEVED.                  44460019
*                                                                       44520019
RELESNTR BALR  LINK1RG,LINK1RG    HANDLE ANY PENDING UPDATE THAT        44580019
         DK    NDUPBQ                  MAY EFFECT THE INDEX RECORD      44640019
         DK    NDUPBX                                                   44700019
         BALR  LINK1RG,LINK1RG                                          44760019
         DK    RLSTUPBQ                                                 44820019
         DK    RLSTUPBX                                                 44880019
         BALR  LINK1RG,LINK1RG                                          44940019
         DK    NDXBQ                                                    45000019
         DK    NDXBX                                                    45060019
         MVI   SEGNUMFW,0         FILE IS NO LONGER POSITIONED          45120019
         MVI   PTRKDPFW,0                                               45180019
         BALR  LINK1RG,LINK1RG    DELETE MASTER INDEX ENTRY FOR THIS    45240019
         DK    DELNDXBQ                FILE.                            45300019
         DK    DELNDXBX                                                 45360019
         BALR  LINK1RG,LINK1RG    RELEASE ALL DATA TRACKS AND INDEX     45420019
         DK    RELESBQ                 TRACK                            45480019
         DK    RELESBX                                                  45540019
         XC    FCTLFW,FCTLFW      RESET FILE CONTROL INFORMATION        45600019
         B     4(LINK1RG)              AND RETURN TO USER               45660019
*                                                                       45720019
*********************************************************************** 45780019
*                                                                       45840019
* POINT - HANDLE ANY PENDING UPDATES IN THE FILE AND POSITION ACCORDING 45900019
*        TO THE USER'S REQUEST.  IF THE FILE IS NULL, BEFORE FIRST,     45960019
*        OR AFTER LAST RECORD WITH NO RETRIEVAL (KEY OR RECORD) ARE     46020019
*        LEGAL; ALL OTHER REQUESTS WILL CAUSE FILE EXCEPTION ON A       46080019
*        NULL FILE.  IF THERE ARE NO PENDING UPDATES AND THE REQUEST    46140019
*        IS FOR THE FIRST RECORD OF THE FILE, THE FIRST RECORD OF       46200019
*        THE FILE IS LOCATED THROUGH THE MASTER INDEX RATHER THAN       46260019
*        THE FILE INDEX.  FILE EXCEPTION IS SET IF REQUEST IS FOR       46320019
*        AN EXACT KEY AND THE KEY DOES NOT EXIST.  IS THIS CASE, THE    46380019
*        FILE WILL BE POSITIONED BEFORE THE FIRST RECORD OF THE SEGMENT 46440019
*        IN WHICH THE RECORD SHOULD HAVE BEEN FOUND (OR THE LAST IF     46500019
*        THE KEY IS HIGHER THAN ANY IN THE FILE).  FILE EXCEPTION IS    46560019
*        SET IF A HIGH/EQUAL KEY IS REQUESTED AND THE KEY DOES NOT      46620019
*        EXIST (POSITIONING IS NORMAL).                                 46680019
*                                                                       46740019
*        BAL   LINK1RG,POINTNTR                                         46800019
*        DS    2H                 REQUEST FOR I/O PROGRAM               46860019
*        DS    0H                 MACRO COMPLETE                        46920019
*                                                                       46980019
POINTNTR TM    AFPAR2FS,BYRECNUM  IF 'FIRST' OR 'LAST' OPTIONS          47040019
         BO    POINTX                  USED, BRANCH                     47100019
         L     GR1RG,NXTKEYFW     SET UP USER ARGUMENT ON BASIS         47160019
         TM    7(GR1RG),X'FF'          OF LAST BYTE OF KEY FIELD        47220019
         BM    POINTX                  FOR MACRO COMPATABILITY          47280019
         BZ    POINTY                                                   47340019
         OI    AFPAR2FS,LAST+READKEY                                    47400019
POINTY   OI    AFPAR2FS,BYRECNUM                                        47460019
POINTX   CLI   NUMSEGFW,0         CHECK FOR NULL FILE                   47520019
         BNE   POINT0                  BRANCH IF NOT                    47580019
         TM    STATUSFW,INSERT    CHECK FURTHER FOR PENDING             47640019
         BO    POINT0                  SEGMENT INSERT                   47700019
         TM    AFPAR2FS,BYRECNUM            ALLOW BEFORE FIRST          47760019
         BZ    XCPTNRET                     OR AFTER LAST               47820019
         TM    AFPAR2FS,READREC+READKEY     WITH NO RETRIEVAL           47880019
         BC    7,XCPTNRET                                               47940019
         TM    AFPAR2FS,BEFORE+LAST                                     48000019
         BM    4(LINK1RG)                                               48060019
         B     XCPTNRET                                                 48120019
*                                                                       48180019
* FILE NOT NULL.  HANDLE ANY CHAIN RECORD UPDATES.                      48240019
*                                                                       48300019
POINT0   BALR  LINK1RG,LINK1RG    UPDATE CHAIN RECORD IF NECESSARY      48360019
         DK    NDUPBQ                                                   48420019
         DK    NDUPBX                                                   48480019
*                                                                       48540019
* CHECK FOR SPECIAL FIRST RECORD POINT WITH NO UPDATES PENDING          48600019
*                                                                       48660019
         TM    AFPAR2FS,BYRECNUM  CHECK FOR SPECIAL POSITIONING         48720019
         BZ    POINT1                  BRANCH IF NOT BY RECORD NUMBER   48780019
         TM    AFPAR2FS,LAST                                            48840019
         BO    POINT1                  BRANCH IF LAST RECORD            48900019
         TM    STATUSFW,DELETE+INSERT+LASTKEY+SEGDATA+FRSTMOVE          48960019
         BC    7,POINT1                BRANCH IF UPDATES PENDING        49020019
         BALR  LINK1RG,LINK1RG    GOOD:  READ MASTER INDEX              49080019
         DK    MAST1BQ                                                  49140019
         DK    MAST1BX                                                  49200019
         B     POINT2             GO SETUP SEARCH PROGRAM               49260019
*                                                                       49320019
* UPDATE INDEX RECORD IF NECESSARY AND LOCATE PROPER SEGMENT.           49380019
*                                                                       49440019
POINT1   BALR  LINK1RG,LINK1RG    LOCATE TRACK LIST ENTRY IF NECESSARY. 49500019
         DK    RLSTUPBQ                                                 49560019
         DK    RLSTUPBX                                                 49620019
         IC    ICRG,AFPAR2FS      PASS ALONG USER ARGUMENT              49680019
         STC   ICRG,SCHPOSFW                                            49740019
         OI    SCHPOSFW,REPOST1        AND SET FOR INDEX RECORD SCAN    49800019
         BALR  LINK1RG,LINK1RG    UPDATE AND SCAN INDEX RECORD FOR      49860019
         DK    NDXPNTBQ                PREVIOUS AND NEXT SEGMENT ADDS.  49920019
         DK    NDXPNTBX                                                 49980019
         BALR  LINK1RG,LINK1RG    UPDATE PREVIOUS EOS POINTER IF        50040019
         DK    FRSTMVBQ                NECESSARY.                       50100019
         DK    FRSTMVBX                                                 50160019
*                                                                       50220019
* READ RECORD CHAIN AND POSITION WITHIN NEW SEGMENT                     50280019
*                                                                       50340019
POINT2   BALR  LINK1RG,LINK1RG    POSITION WITHIN NEW SEGMENT (READ     50400019
         DK    SRCHPTBQ                KEY/RECORD IF SPECIFIED).        50460019
         DK    SRCHPTBX                                                 50520019
         B     UPDOUT             FINAL POSITIONING AND EXIT.           50580019
*                                                                       50640019
*********************************************************************** 50700019
*                                                                       50760019
* ENDUP:  MACRO INTERPRETER.                                            50820019
*                                                                       50880019
ENDUPNTR BALR  LINK1RG,LINK1RG    HANDLE PENDING UPDATES FOR THIS       50940019
         DK    NDUPBQ                  SEGMENT                          51000019
         DK    NDUPBX                                                   51060019
         BALR  LINK1RG,LINK1RG    SCAN TRACK LIST IF NECESSARY          51120019
         DK    RLSTUPBQ                                                 51180019
         DK    RLSTUPBX                                                 51240019
         BALR  LINK1RG,LINK1RG    UPDATE INDEX RECORD IF NECESSARY      51300019
         DK    NDXBQ                                                    51360019
         DK    NDXBX                                                    51420019
         BALR  LINK1RG,LINK1RG    COMPLETE SEGMENT CHAIN IF NECESSARY   51480019
         DK    FRSTMVBQ                                                 51540019
         DK    FRSTMVBX                                                 51600019
         MVI   SEGNUMFW,0         FILE NOT POSITIONED                   51660019
         B     4(LINK1RG)         ESIT TO USER                          51720019
*                                                                       51780019
*********************************************************************** 51840019
*                                                                       51900019
* INSERT - MACRO INTERPRETER.  HANDLE SINGLE OR MULTIPLE INSERT         51960019
*        REQUEST.  IF INSUFFICIENT ROOM ON EXISTING TRACK, A HOLE IS    52020019
*        LOCATED (SINGLE INSERT ONLY) IF THERE IS ONE; OTHERWISE, A     52080019
*        NEW TRACK IS ALLOCATED AND FORMATTED.  IF THERE ARE NO MORE    52140019
*        TRACKS, THE FILE EXCEPTION RETURN IS TAKEN.                    52200019
*                                                                       52260019
*        BAL   LINK1RG,INSRTNTR                                         52320019
*        DS    2H                 I/O PROGRAM REQUEST                   52380019
*        DS    0H                 RETURN TO USER                        52440019
*                                                                       52500019
INSRTNTR CLI   AVAILNFW,0         CHECK FOR AVAILABLE RECORDS ON TRACK  52560019
         BE    INSRTIF3                BRANCH IF NOT                    52620019
         OI    STATUSFW,SEGDATA+RECPEND     REC. CHAIN MODIFIED.        52680019
         BAL   INTLNKRG,SEGPOS    CHECK POSITION WITHIN SEGMENT         52740019
         BC    4,INSRTIF2              INBETWEEN FIRAT AND LSST         52800019
         BC    8,INSRTIF1              BEFORE FIRST                     52860019
         OI    STATUSFW,LASTKEY+LASTMOVE    AFTER LAST                  52920019
         B     INSRTIF2                                                 52980019
INSRTIF1 OI    STATUSFW,FRSTMOVE       BEFORE FIRST                     53040019
INSRTIF2 BAL   INTLNKRG,INSPEND   CHECK FOR INSERT SEGMENT PENDING      53100019
         BALR  LINK1RG,LINK1RG    SCHEDULE SIMPLE INSERT PROGRAM        53160019
         DK    INSBQ                                                    53220019
         DK    INSBX                                                    53280019
         TM    AFPAR1FS,AFXCPTN   WAS MULTIPLE INSERT COMPLETE?         53340019
         BZ    UPDOUT                  YES, OR IT WAS A SINGLE INSERT   53400019
         NI    AFPAR1FS,X'FF'-AFXCPTN  NO, MUST ALLOCATE NEW TRACK      53460019
*                                                                       53520019
* NO MORE SPACE ON PRESENT TRACK.  LOCATE A HOLE OR ALLOCATE A NEW TRK  53580019
*                                                                       53640019
INSRTIF3 CLC   NUMSEGFW,MXNMSGFW  CHECK FOR MAXIMUM INDEX SIZE          53700019
         BNL   XCPTNRET            EXIT IF SO                    A36813 53760020
         BAL   LINK2RG,INSALOC    HANDLE NEW TRACK ALLOCATION FOR INSRT 53820019
         BALR  LINK1RG,LINK1RG    READ AND SCAN TRACK LIST IF NECESSARY 53880019
         DK    RLSTINBQ                                                 53940019
         DK    RLSTINBX                                                 54000019
         BAL   INTLNKRG,SEGPOS    DETERMINE POSITION WITHIN SEGMENT     54060019
         BC    8,INSRTIF8              BEFORE FIRST RECORD              54120019
         BC    2,INSRTIF5              AFTER LAST RECORD                54180019
         TM    STATUSFW,DELETE+INSERT  MIDDLE, CHECK PENDING UPDATES    54240019
         BC    7,UPDATE1               YES, EXIT TO HANDLE UPDATES      54300019
         OI    STATUSFW,INSERT+SEGDATA SPLIT SEGMENT INTO TWO SEGMENTS  54360019
INSRTIF5 OI    AVLRECFW,INSRTOVF  SET INSERT OVERFLOW ON                54420019
         BALR  LINK1RG,LINK1RG    UPDATE CHAIN RECORD                   54480019
         DK    NDUPMDBQ                                                 54540019
         DK    NDUPMDBX                                                 54600019
         BALR  LINK1RG,LINK1RG    UPDATE INDEX RECORD IF NECESSARY.     54660019
         DK    NDXSEQBQ                AND PROCEDE TO NEXT SEGMENT      54720019
         DK    NDXSEQBX                                                 54780019
         BALR  LINK1RG,LINK1RG    UPDATE PREVIOUS END OF SEGMENT        54840019
         DK    FRSTMVBQ                POINTER IF NECESSARY             54900019
         DK    FRSTMVBX                                                 54960019
         CLC   AVLRECFW+1(3),SCHTRKFW+1                                 55020019
         BE    UPDATE4            BRANCH IF INSERT ON NEXT SEG'S TRK.   55080019
         BAL   LINK2RG,SETXAVAL   SETUP NEXT SEGMENT FOR INSERT(S)      55140019
INSRTIF6 OI    STATUSFW,INSERT         SEGMENT INSERT PENDING           55200019
         BAL   INTLNKRG,SETSEGR1  CHECK FOR NEW TRACK TO FORMAT         55260019
         BZ    INSRTIF7                BRANCH IF YES.                   55320019
*                                                                       55380019
* GENERATE NEW SEGMENT ON OLD TRACK.                                    55440019
*                                                                       55500019
         BALR  LINK1RG,LINK1RG         NO, INSERT RECORD ON AN EXISTING 55560019
         DK    OLDINSBQ                TRACK                            55620019
         DK    OLDINSBX                                                 55680019
         B     UPDOUT                  AND RETURN TO USER.              55740019
*                                                                       55800019
* GENERATE NEW SEGMENT AND FORMAT NEWLY ALLOCATED TRACK.                55860019
*                                                                       55920019
INSRTIF7 BALR  LINK1RG,LINK1RG    FORMAT TRACK AND INSERT ONE OR MORE   55980019
         DK    NEWINSBQ                RECORDS, GENERATING CHAIN RECORD 56040019
         DK    NEWINSBX                                                 56100019
         B     UPDOUT                  RETURN TO USER.                  56160019
*                                                                       56220019
* INSERT BEFORE FIRST RECORD OF SEGMENT.                                56280019
*                                                                       56340019
INSRTIF8 BALR  LINK1RG,LINK1RG    HANDLE PENDING UPDATES ON PRESENT     56400019
         DK    NDUPBQ                  TRACK IF ANY.                    56460019
         DK    NDUPBX                                                   56520019
         CLI   NUMSEGFW,0         CHECK FOR NULL FILE.                  56580019
         BNE   INSRTIF9                BRANCH IF NOT.                   56640019
         MVI   SEGNUMFW,1              YES, PROCESSING FIRST SEGMENT    56700019
INSRTIF9 BALR  LINK1RG,LINK1RG    UPDATE INDEX RECORD (IF NECESSARY)    56760019
         DK    NDXINBBQ                AND LOCATE PREVIOUS SEGMENT      56820019
         DK    NDXINBBX                                                 56880019
         CLC   AVLRECFW+1(3),PRETRKFW+1                                 56940019
         BE    UPDATE4B           BRANCH IF INSERT ON PREV. SEG'S TRK.  57000019
         BAL   LINK2RG,SETXAVAL   SETUP CONTROL FOR INSERT              57060019
         MVI   AVLRECFW+1,ZERO      NO EXTRA TRACK IN THIS CASE         57100026
         BAL   INTLNKRG,SETSEGR1       AND UPDATE PREVIOUS EOS ENTRY    57180019
         BALR  LINK1RG,LINK1RG    HANDLE PREVIOUS END OF SEGMENT        57240019
         DK    FRSTMDBQ                POINTER UPDATE NOW.              57300019
         DK    FRSTMDBX                                                 57360019
         B     INSRTIF6                GO DO INSERT(S).                 57420019
*                                                                       57480019
*********************************************************************** 57540019
*                                                                       57600019
* DELETE - MACRO INTERPRETER.  DELETE THE NEXT OR THE PREVIOUS RECORD   57660019
*        IN THIS OR THE NEXT SEGMENT.  IF ALREADY POSITIONED AT THE     57720019
*        END OR BEGINNING OF THE FILE RESPECTIVELY, FILE EXCEPTION      57780019
*        RETURN IS TAKEN.  IF THE DELETED RECORD IS THE LAST IN THE     57840019
*        SEGMENT, THE ENTIRE SEGMENT IS DELETED.                        57900019
*                                                                       57960019
DELETNTR BAL   LINK2RG,EOSEODIF   CHECK FOR END OF SEGMENT AND DATA     58020019
         IC    ICRG,SEGR1FW       IF FIRST RECORD IS ALSO LAST RECORD,  58080019
         BAL   INTLNKRG,SEGPOSR        THIS SEGMENT MUST BE DELETED     58140019
         BC    4,DELRCF2               BRANCH IF MORE THAN ONE RECORD   58200019
         TM    STATUSFW,DELETE+INSERT  IS SEGMENT DELETE LEGAL NOW?     58260019
         BC    7,UPDATE2               NO, PERFORM UPDATES NOW          58320019
*                                                                       58380019
* SEGMENT DELETE                                                        58440019
*                                                                       58500019
DELRCF1  MVI   STATUSFW,DELETE+RECPEND+LASTMOVE+FRSTMOVE                58560019
         IC    ICRG,0(GR3RG)      SETUP SEGMENT DELETE                  58620019
         STC   ICRG,LSTRECFW                                            58680019
         MVI   SEGR1FW,0                                                58740019
         BAL   INTLNKRG,BUMPAVL   BUMP AVAILABLE COUNT                  58800019
         BALR  LINK1RG,LINK1RG    READ AND SCAN TRACK LIST IF           58860019
         DK    RLSTUPBQ                NECESSARY.                       58920019
         DK    RLSTUPBX                                                 58980019
         BALR  LINK1RG,LINK1RG    UPDATE CHAIN RECORD IF ALL RECORDS    59040019
         DK    NDUPMDBQ                NOT DELETED                      59100019
         DK    NDUPMDBX                                                 59160019
         BALR  LINK1RG,LINK1RG    DELETE SEGMENT DEFINITION FROM        59220019
         DK    NDXBQ                   INDEX RECORD                     59280019
         DK    NDXBX                                                    59340019
         L     GR1RG,LSTRECFW     SAVE TRACK ADDRESS FOR POSSIBLE       59400019
         ST    GR1RG,XAVAILFW          RELEASE                          59460019
         IC    ICRG,LSTRECFW      SAVE RECORD NUMBER OF LAST RECORD     59520019
         STC   ICRG,SEGR1FW            FOR CHAIN RECORD UPDATE          59580019
         CLI   SCSGNMFW,X'FF'     LAS LAST SEGMENT BEEN DELETED?        59640019
         BE    DELRCF1A                BRANCH IF YES.                   59700019
         L     GR1RG,SCHTRKFW     MAKE IT LOOK LIKE WE WERE ON THE      59760019
         ST    GR1RG,LSTRECFW          NEXT TRACK                       59820019
         CLC   PRETRKFW+1(3),SCHTRKFW+1                                 59880019
         BNE   UPDATE5A           BRANCH IF DELETED SEGMENT NOT NESTED. 59940019
         MVI   STATUSFW,DELETE+SEGDATA CAUSE SEGMENTS TO BE COMBINED    60000019
         IC    ICRG,SCSGNMFW      DECREMENT SEGMENT NUMBER BY ONE       60060019
         BCTR  ICRG,0                                                   60120019
         STC   ICRG,SCSGNMFW                                            60180019
         B     UPDATE5A           GO COMBINE SEGMENTS                   60240019
DELRCF1A MVI   LSTRECFW+1,ZERO         NO TRK PAST EOD                  60300019
         BALR  LINK1RG,LINK1RG         UPDATE PREVIOUS EOS              60360019
         DK    FRSTMVBQ                                                 60420019
         DK    FRSTMVBX                                                 60480019
         IC    ICRG,NUMSEGFW      PICK UP NUMBER OF SEGMENTS LEFT.      60540019
         STC   ICRG,SCSGNMFW           AND SAVE AS NEW SEGMENT NUMBER   60600019
         LTR   ICRG,ICRG          IS FILE NOW EMPTY?                    60660019
         BC    7,DELRCF1B              BRANCH IF NO, TO GO TO LAST SEG  60720019
         XC    NULLFCFW,NULLFCFW  RESET TO NULL FILE CONTROL            60780019
         MVI   SEGR1FW,X'FF'           AND PROVIDE DUMMY EOD            60840019
         B     DELRCF1D                AND TAKE USER'S EXIT             60900019
DELRCF1B MVI   LSTRECFW,0    POSITION AFTER LAST RECORD OF FILE         60960019
         BALR  LINK1RG,LINK1RG                                          61020019
         DK    SRCHBQ                                                   61080019
         DK    SRCHBX                                                   61140019
DELRCF1D TM    AFPAR2FS,READREC+READKEY                                 61200019
         BC    9,4(LINK1RG)       EXIT IF NO KEY RETRIEVAL REQUESTED.   61260019
         B     XCPTNRET           FILE EXCEPTION IF KEY NOT READ.       61320019
*                                                                       61380019
* DELETE NEXT RECORD (NOT SEGMENT)                                      61440019
*                                                                       61500019
DELRCF2  BAL   LINK2RG,PREVOPT    HANDLE PREVIOUS OPTION IF REQUESTED   61560019
         OI    STATUSFW,RECPEND+SEGDATA  SET ASSUMED UPDATE CONDITIONS  61620019
         BAL   INTLNKRG,SEGPOS    EXAMINE PRESENT SEGMENT POSITION      61680019
         BC    7,DELRCF3               BRANCH IF NOT BEFORE FIRST REC   61740019
         OI    STATUSFW,FRSTMOVE  FIRST RECORD MOVES WITH THIS DELETE   61800019
         IC    ICRG,SEGR1FW       LOCATE RECORD CHAIN ENTRY OF RECORD   61860019
         LA    GR3RG,RCHANFW-2(ICRG)                                    61920019
         IC    ICRG,RCHANFW-2(ICRG)    AND INITIALIZE THE NEW           61980019
         STC   ICRG,SEGR1FW            FIRST RECORD IN SEGMENT          62040019
         B     DELRCF5            GO CHECK FILE UPDATE BITS             62100019
DELRCF3  LR    GR2RG,GR3RG        SAVE POINTER TO LAST RECORD PROCESSED 62160019
         IC    ICRG,RCHANFW-2(ICRG)    LOCATE DELETE RECORD             62220019
         BAL   INTLNKRG,SEGPOS0                                         62280019
         BC    4,DELRCF4               BRANCH IF NOT LAST RECORD        62340019
         OI    STATUSFW,LASTKEY+LASTMOVE    LAST RECORD DELETED         62400019
DELRCF4  IC    ICRG,0(GR3RG)      REMOVE RECORD FROM RECORD CHAIN       62460019
         STC   ICRG,0(GR2RG)                                            62520019
DELRCF5  BAL   INTLNKRG,INSPEND   CHECK FOR PENDING INSERT SEGMENT      62580019
         BAL   INTLNKRG,BUMPAVL   BUMP AVAILABLE RECORD COUNT           62640019
         B     DELSKIP                 AND GO READ KEY IF WANTED        62700019
*                                                                       62760019
*********************************************************************** 62820019
*                                                                       62880019
* BUMPAVL - MAKE RECORD AVAILABLE AND BUMP THE AVAILABLE COUNT OF       62940019
*        AVAILABLE RECORDS ON THIS TRACK BY ONE.                        63000019
*                                                                       63060019
*        BAL   INTLNKRG,BUMPAVL                                         63120019
*                                                                       63180019
*        INPUT REGISTERS:  GR3RG = RECORD CHAIN POINTER TO RECORD       63240019
*                                  BEING DELETED.                       63300019
*                                                                       63360019
*        OUTPUT REGISTERS:  ICRG = UPDATED COUNT OF AVAILABLE RECORDS   63420019
*                                  ON THIS TRACK.                       63480019
*                                                                       63540019
BUMPAVL  MVI   0(GR3RG),0         MAKE RECORD AVAILABLE                 63600019
         IC    ICRG,AVAILNFW      BUMP AVAILABLE RECORD COUNT           63660019
         LA    ICRG,1(ICRG)                                             63720019
         STC   ICRG,AVAILNFW                                            63780019
         BR    INTLNKRG                AND RETURN                       63840019
*                                                                       63900019
*********************************************************************** 63960019
*                                                                       64020019
* REPLACE - MACRO INTERPRETER.  REPLACE THE NEXT OR PREVIOUS RECORD.    64080019
*        IF THAT RECORD DOES NOT EXIST, FILE EXCEPTION IS SET.          64140019
*                                                                       64200019
REPLCNTR BAL   LINK2RG,EOSEODIF   CHECK FOR END OF SEGMENT AND DATA     64260019
         BAL   LINK2RG,PREVOPT    HANDLE PREVIOUS OPTION IF SET         64320019
         BALR  LINK1RG,LINK1RG    SCHEDULE REPLACE I/O PROGRAM          64380019
         DK    REPBQ                                                    64440019
         DK    REPBX                                                    64500019
         TM    AFPAR1FS,AFXCPTN   CHECK FOR NEXT KEY NOT IN SEGMENT     64560019
         BZ    UPDOUT                  OUT IF OK                        64620019
         NI    AFPAR1FS,ALL-AFXCPTN    RESET EOD FLAG                   64680019
         B     UPDATE3                 GET NEXT KEY                     64740019
*                                                                       64800019
*********************************************************************** 64860019
*                                                                       64920019
* GET - MACRO INTERPRETER.  READ THE NEXT OR THE PREVIOUS SINGLE        64980019
*        DATA RECORD OR THE NEXT MULTIPLE DATA RECORDS.  IF THERE       65040019
*        ARE NO RECORDS TO READ% FILE EXCEPTION RETURN IS TAKEN.        65100019
*                                                                       65160019
GETNTR   BAL   LINK2RG,EOSEODIF   CHECK FOR END OF DATA OR SEGMENT      65220019
         BAL   LINK2RG,PREVOPT    HANDLE PREVIOUS OPTION IF SET         65280019
GETMNXT  TM    AFPAR2FS,READREC+READKEY     CHECK FOR NEXT KEY ONLY     65340019
         BM    UPDATE3                 BRANCH IF SO                     65400019
         BALR  LINK1RG,LINK1RG    READ NEXT BLOCK OF DATA RECORD(S)     65460019
         DK    GETBQ                                                    65520019
         DK    GETBX                                                    65580019
         TM    AFPAR1FS,AFXCPTN   CHECK FOR INCOMPLETE GET MULTIPLE     65640019
         BZ    UPDOUT                  BRANCH IF COMPLETE               65700019
         NI    AFPAR1FS,X'FF'-AFXCPTN  RESET FILE EXCEPTION             65760019
         BAL   INTLNKRG,SEGPOS         INCOMPLETE, CHECK FOR EOD        65820019
         CLI   0(GR3RG),X'FF'                                           65880019
         BNE   UPDATE1                 CONTINUE IF NOT END OF DATA      65940019
         B     UPDOUT                  AND RETURN WITH PARTIAL BLOCK    66000019
*                                                                       66060019
*********************************************************************** 66120019
*                                                                       66180019
* SKIP - MACRO INTERPRETER.  SKIP THE NEXT OR PREVIOUS RECORD.  IF      66240019
*        THAT RECORD DOES NOT EXIST, FILE EXCEPTION EXIT IS TAKEN.      66300019
*                                                                       66360019
SKIPNTR  BAL   LINK2RG,EOSEODIF   CHECK FOR END OF SEGMENT OR DATA      66420019
         BAL   LINK2RG,PREVOPT    HANDLE PREVIOUS OPTION IF SET ON      66480019
         BALR  LINK1RG,LINK1RG    SKIP ONE RECORD                       66540019
         DK    SKIPBQ                                                   66600019
         DK    0                                                        66660019
         B     DELSKIP                 AND READ NEXT KEY IF REQUIRED    66720019
*                                                                       66780019
*********************************************************************** 66840019
*                                                                       66900019
* UPDATE - HANDLE SEGMENT TO SEGMENT UPDATING OF CHAIN RECORDS AND      66960019
*        INDEX RECORD, EXCEPT FOR SEGMENT DELETE AND INSERT OVERFLOW.   67020019
*                                                                       67080019
DELSKIP  TM    AFPAR2FS,READREC+READKEY     IF NEXT KEY NOT REQUESTED   67140019
         BC    9,UPDOUT                     EXIT TO USER.               67200019
UPDATE3  BAL   INTLNKRG,SEGPOS    DETERMINE POSITION WITHIN SEGMENT     67260019
         BC    13,READXK          BRANCH IF NOT POSITIONED AFTER LAST   67320019
         OI    AFPAR1FS,MACOMP1   SET TO PROCEDE TO NEXT SEGMENT        67380019
         CLI   0(GR3RG),X'FF'     CHECK FOR LAST RECORD OF FILE         67440019
         BNE   UPDATE                  BRANCH IF NOT                    67500019
XCPTNRET OI    AFPAR1FS,AFXCPTN        END OF DATA, SET FILE EXCEPTION  67560019
         B     4(LINK1RG)              AND RETURN TO USER               67620019
READXK   BALR  LINK1RG,LINK1RG    READ NEXT KEY IN SEGMENT              67680019
         DK    RDXKBQ                                                   67740019
         DK    RDXKBX                                                   67800019
         B     UPDOUT                  AND ESTABLISH FINAL POSITIONING  67860019
UPDATE4B MVC   SCHTRKFW+1(3),PRETRKFW+1     SET TO POSITION             67920019
         LH    GR1RG,PRERRFW                TO PREVIOUS                 67980019
         STH   GR1RG,SCHRRFW                SEGMENT                     68040019
         IC    ICRG,SCSGNMFW                AND DECREMENT               68100019
         BCTR  ICRG,0                       SEGMENT                     68160019
         STC   ICRG,SCSGNMFW                NUMBER                      68220019
UPDATE4  NI    AVLRECFW,X'FF'-INSRTOVF RESET INSERT OVERFLOW CONDITION  68280019
         OI    AFPAR1FS,MACOMP1   SET TO RETURN TO MACRO INTERPRETER    68340019
         B     UPDATE4A           READ IN CHAIN RECORD OF NEW SEGMENT   68400019
UPDATE1  OI    AFPAR1FS,MACOMP1   SET TO PROCEDE TO NEXT SEGMENT        68460019
UPDATE2  OI    AFPAR1FS,MACOMP2   SET TO RETURN TO MACRO INTERPRETER    68520019
UPDATE   BALR  LINK1RG,LINK1RG    UPDATE CHAIN RECORD IF NECESSARY      68580019
         DK    NDUPBQ                                                   68640019
         DK    NDUPBX                                                   68700019
         BALR  LINK1RG,LINK1RG    READ AND SCAN TRACK LIST IF           68760019
         DK    RLSTUPBQ                NECESSARY                        68820019
         DK    RLSTUPBX                                                 68880019
         BALR  LINK1RG,LINK1RG    UPDATE INDEX RECORD IF NECESSARY      68940019
         DK    NDXBQ                                                    69000019
         DK    NDXBX                                                    69060019
UPDATE5A BALR  LINK1RG,LINK1RG    UPDATE PREVIOUS END OF SEGMENT        69120019
         DK    FRSTMVBQ                POINTER IF NECESSARY             69180019
         DK    FRSTMVBX                                                 69240019
         TM    AFPAR1FS,MACOMP2   SHOULD WE RETURN TO MACRO INTERPRETER 69300019
         BZ    UPDATE5                 BRANCH IF NOT                    69360019
UPDATE4A BALR  LINK1RG,LINK1RG    POSITION WITHIN NEWLY LOCAT5D         69420019
         DK    SRCHBQ                  SEGMENT                          69480019
         DK    SRCHBX                                                   69540019
         BAL   INTLNKRG,LOCINTR0  LOCATE BEGINNING OF MACRO INTERPRETER 69600019
         B     0(LINK2RG,BASERG)       AND REENTER INTERPRETER          69660019
UPDATE5  BALR  LINK1RG,LINK1RG    READ RECORD CHAIN AND FIRST KEY       69720019
         DK    SRCHXKBQ                                                 69780019
         DK    SRCHXKBX                                                 69840019
UPDOUT   LA    LINK1RG,4(LINK1RG)      SET UP EXIT ADDRESS              69900019
         TM    AFPAR2FS,BEFORE         CHECK FOR REPOSITIONING OPTION   69960019
         BCR   8,LINK1RG                                                70020019
         TM    AFPAR1FS,AFXCPTN        WITHOUT FILE EXCEPTION,          70080019
         BCR   7,LINK1RG                                                70140019
         CLI   LSTRECFW,0              OR POSITION BEFORE FIRST         70200019
         BCR   8,LINK1RG                                                70260019
         BAL   LINK2RG,BSR             BACKSPACE ONE RECORD IF BEFORE   70320019
         BR    LINK1RG                                                  70380019
*                                                                       70440019
*                                                                       70500019
* EOSEODIF - CHECK FOR END OF SEGMENT OR END OF DATA.  END OF SEGMENT   70560019
*        CAUSES THE ENDUP PROGRAM TO GAIN CONTROL ( AT 'SETEND1') TO    70620019
*        LOCATE THE NEXT SEGMENT BEFORE REENTERING THE MACRO            70680019
*        INTERPRETER.  END OF DATA CAUSES FILE EXCEPTION RETURN TO      70740019
*        USER.                                                          70800019
*                                                                       70860019
*        BAL   LINK2RG,EOSEODIF                                         70920019
*        DS    0H                 FIRST RECORD OF SEGMENT ON THIS TRACK 70980019
*                                                                       71040019
*        INPUT REGISTERS:  NO SPECIAL ASSUMPTIONS.                      71100019
*                                                                       71160019
*        OUTPUT REGISTERS:  INTLNKRG - DESTROYED                        71220019
*                           GR1RG - DESTROYED.                          71280019
*                           GR2RG - DESTROYED.                          71340019
*                           GR3RG - DESTROYED.                          71400019
*                                                                       71460019
EOSEODIF OI    SEGNUMFW,0         CHECK FOR FILE NOT POSITIONED.        71520019
         BC    8,XCPTNRET              EXIT WITH EXCEPTION IF SO        71580019
         BALR  GR2RG,0                 NO, SAVE 01 CONDITION CODE       71640019
         BAL   INTLNKRG,SEGPOS    CHECK SEGMENT POSITIONING             71700019
         TM    AFPAR2FS,NEXT      SETUP CONDITION CODE OF 01 IF         71760019
         BALR  GR1RG,0                 FORWARD OPERATION.               71820019
         NR    GR1RG,GR2RG             00 IF BACKWARD OPERATION.        71880019
         OR    GR1RG,INTLNKRG     IS FIRST RECORD OF OPERATION WITHIN   71940019
         SPM   GR1RG                   SEGMENT.                         72000019
         BCR   6,LINK2RG          EXIT IF IN SEGMENT.                   72060019
*                                                                       72120019
* CHECK FOR END OF DATA                                                 72180019
*                                                                       72240019
         SPM   INTLNKRG           PROCESSING IN WHICH DIRECTION?        72300019
         BZ    EODBACK                 BRANCH IF GOING BACKWARDS        72360019
         CLI   0(GR3RG),X'FF'     FORWARD, CHECK FOR EOD                72420019
         B     EODCK1                  CC = 00 IS EOD                   72480019
EODBACK  TM    SEGNUMFW,X'FF'-1   CHECK FOR BACKWARD EOD                72540019
EODCK1   BC    8,XCPTNRET         EXIT TO USER IF AT EOD (CC = 00)      72600019
         B     UPDATE1            ONLY EOS, PROCEDE TO NEXT SEG. FIRST  72660019
*                                                                       72720019
*********************************************************************** 72780019
*                                                                       72840019
* INSPEND - RESET UPDATE BITS THAT REFERENCE FIELDS IN THE INDEX RECORD 72900019
*        IF THIS SEGMENT HAS NO ENTRY IN THE INDEX RECORD.              72960019
*                                                                       73020019
*        BAL   INTLNTRG,INSPEND                                         73080019
*                                                                       73140019
*        INPUT AND OUTPUT REGISTERS:  NO SPECIAL ASSUMPTIONS.           73200019
*                                                                       73260019
INSPEND  TM    STATUSFW,INSERT    IF SEGMENT INSERT IS PENDING,         73320019
         BCR   14,INTLNKRG             NO                               73380019
         NI    STATUSFW,X'FF'-LASTKEY-SEGDATA                           73440019
         BR    INTLNKRG           RESET SEGMENT UPDATE CONDITIONS       73500019
*                                                                       73560019
*********************************************************************** 73620019
*                                                                       73680019
* SEGPOS - CHECK PRESENT POSITION WITHIN SEGMENT.                       73740019
* SEGPOSR - CHECK POSITION OF RECORD WITHIN SEGMENT.                    73800019
*        FILE MUST BE IN UPDATE MODE.                                   73860019
*                                                                       73920019
*        BAL   INTLNKRG,SEGPOS                                          73980019
*                                                                       74040019
*        BAL   INTLNKRG,SEGPOSR                                         74100019
*                                                                       74160019
*        INPUT REGISTERS:  ICRG = RECORD NUMBER OF THE LAST RECORD      74220019
*                                 PROCESSED (NEED NOT BE THE SAME AS    74280019
*                                 LSTRECFW) IF SEGPOSR ENTRY POINT.     74340019
*                                                                       74400019
*        OUTPUT REGISTERS:   ENTRY POINTS SEGPOS AND SEGPOSR:  ICRG =   74460019
*                                      RECORD NUMBER OF LAST RECORD     74520019
*                                      PROCESSED IF NOT POSITIONED      74580019
*                                      BEFORE FIRST RECORD IN SEGMENT;  74640019
*                                      OTHERWISE ICRG = 0.              74700019
*                            GR3RG = RECORD CHAIN POINTER TO RECORD     74760019
*                                    REPRESENTED BY ICRG.               74820019
*                           INTLNKRG = CONDITION CODE IN BITS 2 AND 3;  74880019
*                                      PROGRAM MASK IN BITS 4-7.        74940019
*                                                                       75000019
*        CONDITION CODE:  00   POSITIONED BEFORE FIRST RECORD           75060019
*                         01   POSITIONED BETWEEN FIRST AND LAST        75120019
*                         10   POSITIONED AFTER LAST RECORD             75180019
*                         11   NEVER SET                                75240019
*                                                                       75300019
SEGPOS   IC    ICRG,LSTRECFW      PICK UP LAST REC. PROCESSED REC. NUM. 75360019
SEGPOSR  LTR   ICRG,ICRG               AND CHECK FOR BEFORE FIRST       75420019
         BC    8,SEGPOS1               EXIT IF YES, CC = 00             75480019
SEGPOS0  LA    GR3RG,RCHANFW-2(ICRG)   LOCATE RECORD CHAIN ENTRY        75540019
         CLI   0(GR3RG),EOS            CHECK IT FOR END OF SEGMENT      75600019
*                                 CC = 01 IF NOT, CC = 10 IF END OF SEG 75660019
SEGPOS1  BALR  INTLNKRG,INTLNKRG  EXIT WITH CONDITION CODE IN INTLNKRG  75720019
*                                                                       75780019
*********************************************************************** 75840019
*                                                                       75900019
* SETXAVAL - SETUP CONTROL INFORMATION FOR INSERT ON AVAILABLE TRACK.   75960019
*                                                                       76020019
*        BAL   LINK2RG,SETXAVAL                                         76080019
*                                                                       76140019
*        INPUT REGISTERS:  NO SPECIAL ASSUMPTIONS.                      76200019
*                                                                       76260019
*        OUTPUT REGISTERS:  GR1RG = DESTROYED.                          76320019
*                                                                       76380019
SETXAVAL NI    AVLRECFW,X'FF'-INSRTOVF TURN OFF INSERT OVERFLOW IND.    76440019
         L     GR1RG,AVLRECFW     SETUP NEW TRACK ADDRESS               76500019
         ST    GR1RG,LSTRECFW                                           76560019
         IC    GR1RG,ATRKDPFW          PRESERVE TRACK LIST POSITION     76620019
         STC   GR1RG,PTRKDPFW                                           76680019
         L     GR1RG,XAVAILFW     SAVE NEW AVAILABLE RECORD AREA        76740019
         ST    GR1RG,AVLRECFW          ADDRESS IF THERE IS ONE          76800019
         NI    AVLRECFW,X'FF'-INSRTOVF                                  76860019
         IC    GR1RG,XTRKDPFW          PRESERVING TRACK LIST            76880019
         STC   GR1RG,ATRKDPFW          DISPLACEMENT                     76900019
         IC    GR1RG,SCSGNMFW     UPDATE SEGMENT NUMBER                 76920019
         STC   GR1RG,SEGNUMFW                                           76980019
         BR    LINK2RG                 AND RETURN.                      77040019
*                                                                       77100019
*********************************************************************** 77160019
*                                                                       77220019
* SETSEGR1 - TEST FOR NEW TRACK JUST ALLOCATED AND SETUP FIRST RECORD   77280019
*        NUMBER.                                                        77340019
*                                                                       77400019
*        BAL   INTLNKRG,SETSEGR1                                        77460019
*                                                                       77520019
*        INPUT REGISTERS:  NO SPECIAL ASSUMPTIONS.                      77580019
*                                                                       77640019
*        OUTPUT REGISTERS:  ICRG = RECORD NUMBER OF FIRST INSERT RECORD 77700019
*                                  (SEGR1 SET TO THIS VALUE) OR ZERO.   77760019
*                                                                       77820019
*        CONDITION CODE:  00   NEW TRACK JUST ALLOCATED.                77880019
*                         01   NEVER SET                                77940019
*                         10   INSERT ON EXISTING TRACK                 78000019
*                         11   NEVER SET                                78060019
*                                                                       78120019
SETSEGR1 IC    ICRG,LSTRECFW      PICK UP RECORD NUMBER OF INSERT REC.  78180019
         STC   ICRG,SEGR1FW       UPDATE RECORD ONE CONTROL             78240019
         STC   ICRG,SEGRFFW                                             78300019
         LTR   ICRG,ICRG          NOW CHECK FOR FORMATTING NEW TRACK    78360019
         BCR   7,INTLNKRG              EXIT IF NOT                      78420019
         MVI   SEGR1FW,2               YES, SET UP NEW FIRST RECORD     78480019
         BR    INTLNKRG                AND EXIT                         78540019
*                                                                       78600019
*********************************************************************** 78660019
*                                                                       78720019
* PREVOPT - CHECK FOR USER REQUEST OF PREVIOUS RECORD IN SEGMENT        78780019
*        AS THE FIRST RECORD TO BE PROCESSED BY THIS MACRO.             78840019
*        FILE MUST BE IN UPDATE MODE AND IT MUST BE KNOWN THAT A        78900019
*        PREVIOUS RECORD EXISTS.  IF THE PRESENT OR GIVEN RECORD NUMBER 78960019
*        IS THE FIRST RECORD IN THE SEGMENT, THEN LSTRECFW WILL BE      79020019
*        SET TO ZERO (POSITIONED BEFORE FIRST RECORD OF SEGMENT).       79080019
* BSR - BACKSPACE OVER SINGLE RECORD IN SEGMENT.                        79140019
*                                                                       79200019
*        BAL   LINK2RG,PREVOPT                                          79260019
*                                                                       79320019
*        BAL   LINK2RG,BSR                                              79380019
*                                                                       79440019
*        INPUT REGISTERS - NO SPECIAL ASSUMPTIONS.                      79500019
*                                                                       79560019
*        OUTPUT REGISTERS - ICRG = NUMBER OF LAST RECORD PROCESSED IF   79620019
*        (IF BACKSPACE             NOT POSITIONED BEFORE FIRST.         79680019
*        PERFORMED)         GR3RG = NUMBER OF 'NEW' LAST RECORD         79740019
*                                   PROCESSED (OR 0) IF 'BEOFRE'        79800019
*                                   OPTION USED.                        79860019
*                           INTLNKRG = SAME AS ICRG IF 'BEFORE' OPTION  79920019
*                                   USED.                               79980019
*                                                                       80040019
*                                                                       80100019
* CHECK FOR BACKWARD OPERATION.                                         80160019
*                                                                       80220019
PREVOPT  TM    AFPAR2FS,NEXT      OPTION REQUESTED?                     80280019
         BCR   7,LINK2RG               NO, EXIT                         80340019
*                                                                       80400019
BSR      IC    ICRG,SEGR1FW       PICK UP FIRST RECORD IN SEGMENT       80460019
         LR    INTLNKRG,ICRG           TO START LOOP AND COMPARE        80520019
         SR    GR3RG,GR3RG        ASSUME POSITIONED BEFORE FIRST        80580019
         IC    ICRG,LSTRECFW      LAST RECORD PROCESSED FOR END COMPARE 80640019
         B     BSR2               START LOOP                            80700019
BSR1     LR    GR3RG,INTLNKRG     SAVE PREVIOUS RECORD POSITION (OR 0)  80760019
         IC INTLNKRG,RCHANFW-2(INTLNKRG)  PICK UP REC. NUM. OF NEXT REC 80820019
BSR2     CR    INTLNKRG,ICRG      IS THIS THE PRESENT LAST REC. PROC    80880019
         BNE   BSR1                    BRANCH IF NOT                    80940019
         STC   GR3RG,LSTRECFW          YES, SAVE PREVIOUS RECORD NUMBER 81000019
         BR    LINK2RG                 AS NEW LAST RECORD PROCESSED     81060019
*                                                                       81120019
*********************************************************************** 81180019
*                                                                       81240019
* INSALOC - DETERMINE WHETHER OR NOT A NEW TRACK SHOULD BE ALLOCATED    81300019
*        TO THIS FILE TO PROCESS AN OVERFLOW OF INSERTS IN THE          81360019
*        PRESENT SEGMENT.  IF NECESSARY, THE TRACK IS ALLOCATED.        81420019
* ALLOCIF - ALLOCATE THE NEXT CLOSEST TRACK TO THE CENTER OF THE        81480019
*        ACTIVE FILE EXTENT AND PLACE ITS ADDRESS IN AVLRECFW WITH A    81540019
*        RECORD NUMBER OF ZERO.  ATRKDPFW IS ALSO SET = ZERO.           81600019
*                                                                       81660019
*        BAL   LINK2RG,INSALOC                                          81720019
*                                                                       81780019
*        BAL   LINK2RG,ALLOCIF                                          81840019
*                                                                       81900019
*        INPUT REGISTERS:  NO SPECIAL ASSUMPTIONS.                      81960019
*                                                                       82020019
*        OUTPUT REGISTERS:   GRDRG = 0ACH OF ASSIGNED TRACK.            82080019
*                            GRORG = DESTROYED.                         82140019
*                           GRERG = DESTROYED.                          82200019
*                           HEADRG = DESTROYED.                         82260019
*                           INTLNKRG = DESTROYED IF INSALOC ENTRY.      82320019
*                                                                       82380019
INSALIF  TM    AFPAR2FS,MULTIPLE  MULTIPLE INSERT ALWAYS CAUSES         82440019
         BCR   1,INTLNKRG              TRACK ALLOCATION                 82500019
         CLI   TKLSTZFW,21        CHECK FOR HOLES IN FILE               82560019
         BCR   6,INTLNKRG                                               82620019
         OI    PTRKDPFW,0         NOT SURE, MAY HAVE JUST USED LAST ONE 82680019
         BR    INTLNKRG                                                 82740019
INSALOC  BAL   INTLNKRG,INSALIF   SHOULD NEW TRACK BE ALLOCATED?        82800019
         BCR   10,LINK2RG              RETURN IF NOT                    82860019
ALLOCIF  L     GRORG,NXTTRK       ADDR OF FIRST POSSIBLE AVAILABLE    R 82920019
         L     GRDRG,TRACKSFW+4     TRACK; END OF TABLE               R 82980019
         SR    GRDRG,GRORG          MACHINE LENGTH TO SEARCH          R 83040019
         LA    GRERG,C256              TAT LENGTH               A45668  83100026
ALLOCI2  CR    GRDRG,GRERG             COMPARE TO 256           A45668  83160026
         BL    ALTRANS2           BRANCH IF SINGLE TRT WILL DO        R 83220019
         SR    GRDRG,GRERG         CLEAR 3 HIGH ORDER BYTES             83250019
         TRT   0(256,GRORG),TRTABLE    NO, CHECK FIRST 256 BYTES      R 83280019
         BC    7,ALOCNOW          A HIT                               R 83340019
         AR    GRORG,GRERG        NO, NO TRACKS. CHECK REST OF TAT    R 83400019
         SR    GRDRG,GRERG             SUBTACT 256              A45668  83420026
         B     ALLOCI2                 COMPARE FOR LAST BYTES   A45668  83440026
ALTRANS2 EX    GRDRG,TRTINST                                          R 83460019
         BC    8,ALOCFAIL         NO TRACKS AVAILABLE; BRANCH         R 83520019
ALOCNOW  IC    GR4RG,ALTAB3-1(R2) FUNCTION BYTE YIELDS FIRST          R 83580019
         EX    GR4RG,XIINST         AVAILABLE TRACK, TURN OFF.        R 83640019
         ST    R1,NXTTRK          ADDR OF HIT. NONE POSSIBLE EARLIER. R 83700019
         S     R1,TRACKSFW        BYTE NUMBER IN TAT                  R 83760019
         SLA   R1,3                 TIMES 8                           R 83820019
         BCTR  R2,0                 PLUS FUNCTION BYTE - 1            R 83880019
         AR    GRORG,R2             = BIT NO. (RELATIVE HEAD)         R 83940019
         SR    GRERG,GRERG                                            R 84000019
         LH    GR4RG,NUMHEADS                                         R 84060019
         DR    GRERG,GR4RG        STRING NUMBER, R = HEAD             R 84120019
         LH    GRDRG,MIDCYLFW     00AM WHERE M IS MIDCYL              R 84180019
         ST    GRORG,F1WORK                                           R 84240019
         SRA   GRORG,1            DIVIDE BY 2                         R 84300019
         TM    F1WORK+3,B'00000001'                                   R 84360019
         BZ    ALEVEN             BRANCH IF EVEN STRING NO.           R 84420019
         LCR   GRORG,GRORG                                            R 84480019
         BCTR  GRORG,0            -(N+1) WHERE STRING WAS 2N+1        R 84540019
ALEVEN   SR    GRDRG,GRORG        00AC                                R 84600019
         LA    GRDRG,256(GRDRG)     00  C+1  C                   A45668 84630026
         SLA   GRDRG,8            0AC0                                R 84660019
         AR    GRDRG,GRERG        0ACH, RETURN ARGUMENT                 84720019
         ST    GRDRG,AVLRECFW          SAVE ADDR OF ASSIGNED TRACK      84780019
         MVI   ATRKDPFW,0              AND INDICATE NO TRACK LIST ENTRY 84840019
         BR    LINK2RG            RETURN WITH ALLOCATED TRACK           84900019
ALOCFAIL L     GRERG,TRACKSFW+4                                       R 84960019
         ST    GRERG,NXTTRK                                           R 85020019
         B     XCPTNRET                                               R 85080019
*                                                                     R 85140019
TRTINST  TRT   0(0,GRORG),TRTABLE                                     R 85200019
XIINST   NI    0(R1),0                                                R 85260019
DISPEP   DC    V(IHKDSP)                                                85320019
KONBXPTR DC    V(IHKNBX)                                                85380019
         DROP  BASERG                                                   85440019
         DROP  KBXRG                                                    85500019
         DROP  AFWRG                                                    85560019
*                                                                S21016 85566000
*     WORK AREA FOR WRITE TO OPERATOR I/O ERROR ANALYSIS         S21016 85572000
*                                                                S21016 85578000
         DS    0H                                                S21016 85584000
MSG242A  DC    H'76',H'0'                                        S21016 85590000
         DC    C'IHK260I CRJE,'                                         85596000
SNADWRD  DS    CL58                                              S21016 85602000
SIXTY8   EQU   68                                                S21016 85608000
*                                                                       85620019
*                                                                       85680019
*********************************************************************** 85740019
*                                                                       85800019
*                                                                       85860019
* CCW LIST REFERENCE SYMBOLS.                                           85920019
*                                                                       85980019
         CCWMSK 1                                                       86040019
*                                                                       86100019
* SEARCH ARGUMENT LIST REFERENCE SYMBOLS                                86160019
*                                                                       86220019
         CNTSRCH 1                                                      86280019
*                                                                       86340019
* LINKAGE FOR CHANNEL PROGRAM EXECUTOR MODULE.                          86400019
*                                                                       86460019
         EXCCWDS TYPE=DSECT                                             86520019
*                                                                       86580019
* LINKAGE FOR CHANNEL PROGRAM GENERATOR MODULE.                         86640019
*                                                                       86700019
         GENCCWDS TYPE=DSECT                                            86760019
*                                                                       86820019
*                                                                       86880019
* ACTIVE FILE WORK AND CONSTANT AREA.                                   86940019
*                                                                       87000019
         EXCPFWDS TYPE=DSECT                                            87060019
*                                                                       87120019
* DATA CONTROL BLOCK DEFINITION                                         87180019
*                                                                       87240019
         DCBD  DSORG=(DA),DEVD=(DA)                                     87300019
*                                                                       87360019
* DATA EXTENT BLOCK DEFINITION.                                         87420019
*                                                                       87480019
         DEBDS                                                          87540019
*                                                                       87600019
* APPENDAGE VECTOR TABLE DEFINITION.                                    87660019
*                                                                       87720019
*                                                                       87780019
* SYSTEM CONSTANT/WORK AREA.                                            87840019
*                                                                       87900019
*                                                                       87960019
*                                                                       88020019
*                                                                       88080019
*                                                                       88140019
* ACTIVE FILE CONTROL INFORMATION.                                      88200019
*                                                                       88260019
         AFCTLDS                                                        88320019
         AFIOEQU                  DEFINE REGISTERS AND OTHER CONSTANTS  88380019
         RAFKNBX  TYPE=DSECT                                            88440019
*                                                                       88500019
         IHKCDSCT   TUB=YES                                             88560019
*                                                                       88620019
         TUBEQU                                                         88680019
*                                                                       88740019
*                                                                       88800019
*  ENVIRONMENT SWITCH SETTINGS                                          88860019
WMSTTOVR EQU   X'20'                                                    88920019
WMSTRT   EQU   X'40'                   ACTIVE AREA RECOVERY - IHKAWS    88980019
BUFCTL   EQU   X'80'                                                    89040019
ALL      EQU   X'FF'                                                    89100019
ALLTRKS  EQU   X'FF'                                                    89160019
*                                                                       89220019
* COMPLETION FLAGS                                                      89280019
*                                                                       89340019
NQFLAG   EQU   X'40'                   ENQUEUEING RTN COMPLETION FLAG   89400019
AFCOMP2  EQU   2                                                        89460019
COMFLAG  EQU   X'40'         COMMON ECF COMPLETION FLAG                 89520019
*                                                                       89580019
* MACRO BUFFER INDEX DEFINITIONS                                        89640019
*                                                                       89700019
NOBUF    EQU   0*16               POINT WITH RETRIEVAL BUFFER DEF.      89760019
SPNTBUF  EQU   0*16                                                     89820019
MPNTBUF  EQU   0*16                                                     89880019
SINSBUF  EQU   1*16               INSERT SINGLE BUFFER                  89940019
MINSBUF  EQU   2*16               INSERT MULTIPLE BUFFER                90000019
SREPBUF  EQU   3*16               REPLACE BUFFER                        90060019
MREPBUF  EQU   3*16                                                     90120019
SGETBUF  EQU   4*16               RGET SINGLE BUFFER                    90180019
MGETBUF  EQU   5*16               MULTIPLE RGET BUFFER                  90240019
RSTECB   EQU   X'00'                                                    90300019
ZERO     EQU   X'00'                                                    90360019
ONE      EQU   X'01'                                                    90420019
EIGHT    EQU   8                                                A45668  90430026
FOUR     EQU   4                                                A45668  90440026
C256     EQU   256                                              A45668  90450026
COMPCOD0 EQU   X'7F'                                                    90480019
COMPCOD1 EQU   X'41'                                                    90540019
C0KN     EQU   X'C0'                                                    90600019
SETRET   EQU   4                                                        90660019
AFIO     EQU   IHKAFI                                                   90720019
REGD     EQU   13                                                       90780019
R1       EQU   1                  HARDWARE DETERMINED (TRT INST)      R 90840019
R2       EQU   2                  HARDWARE DETERMINED (TRT INST)      R 90900019
GR4RG    EQU   4                                                        90960019
GR5RG    EQU   5                                                        91020019
*                                                                       91080019
* REGISTERS ON ENTRY TO MODULE                                          91140019
*                                                                       91200019
*        AFPARG = USER ARGUMENT                                         91260019
*                                                                       91320019
         END                                                            91380019
