BST      TITLE 'IHKBST - LIBRARY I/O STARTUP ROUTINE'                   00200019
IHKBST   CSECT                                                          00400019
*A474600-475200,A476500-477500,A802600-803200                   A45668  00500026
*********************************************************************** 00600019
*                                                                     * 00800019
*STATUS-                                                              * 01000019
*   CHANGE LEVEL 0                                                    * 01200019
*                                                                     * 01400019
*FUNCTION/OPERATION-                                                  * 01600019
*   THIS ROUTINE IS GIVEN CONTROL BY IHKCIP AT CRJE START UP. IHKBST  * 01800019
*   GENERATES THE CRJE GLOBAL FILES IN THE ACTIVE AREA BY COPYING THE * 02000019
*   MEMBERS OF THE CRJE SYSTEM LIBRARY (CRJE.SYSLIB) INTO THE ACTIVE  * 02200019
*   AREA. WHERE COUNTS OF THE (UMBER OF ENTRIES IN A GLOBAL FILE ARE  * 02400019
*   MAINTAINED, THE COUNT (IN THE CCT) IS MODIFIED AS THE FILES ARE   * 02600019
*   COPIED.                                                           * 02800019
*   AFTER GENERATING THE ACTIVE GLOBAL FILES, ALL DASD DEVICES, FOR   * 03000019
*   WHICH A DD CARD IS PROVIDED WITH THE DDNAME LIBXXX, ARE SEARCHED  * 03200019
*   FOR CRJE USER LIBRARIES (NAME OF CRJE.LIB.USERID). WHEN A USER    * 03400019
*   LIBRARY IS FOUND, THE DDNAME FOR THE VOLUME ON WHICH THE LIBRARY  * 03600019
*   IS FOUND IS SAVED IN THE LAST EIGHT BYTES OF THAT USER'S ENTRY IN * 03800019
*   THE USER'S GLOBAL FILE.                                           * 04000019
*   IF I/O ERRORS OCCUR WHILE ACCESSING THE ACTIVE AREA OR THE SYSTEM * 04200019
*   LIBRARY, RETURN IS MADE TO IHKCIP TO CLOSEDOWN CRJE.              * 04400019
*                                                                     * 04600019
*ENTRY POINTS-                                                        * 04800019
*        IHKBST IS THE ONLY ENTRY POINT.                              * 05000019
*                                                                     * 05200019
*INPUT-                                                               * 05400019
*   AT ENTRY REGISTER ONE CONTAINS THE ADDRESS OF THE AVT.            * 05600019
*                                                                     * 05800019
*OUTPUT-                                                              * 06000019
*   ALL ACTIVE GLOBAL FILES ARE GENERATED AND THE DDNAMES FOR USER    * 06200019
*   LIBRARIES ARE INSERTED INTO THE USER'S ENTRIES IN THE USERS GLOBAL* 06400019
*   FILE.                                                             * 06600019
*                                                                     * 06800019
*EXTERNAL ROUTINES-                                                   * 07000019
*        IHKAFI - TO ACCESS THE GLOBAL FILES IN THE ACTIVE AREA       * 07200019
*        IHKBPM - TO ACCESS USER LIBRARIES                            * 07400019
*        IHKRNQ - TO QUEUE FOR LIBRARY I/O                            * 07600019
*                                                                     * 07800019
*EXITS-NORMAL                                                         * 08000019
*   RETURN TO IHKCIP WITH RETURN CODE OF ZERO IN REGISTER FIFTEEN     * 08200019
*                                                                     * 08400019
*EXITS-ERROR                                                          * 08600019
*   RETURN TO IHKCIP WITH RETURN CODE IN REGISTER FIFTEEN             * 08800019
*        4  - MAXIMUM USERS EXCEEDED                                  * 09000019
*        8  - I/O ERROR IN ACTIVE FILE                                * 09200019
*        12 - I/O ERROR IN SYSTEM LIBRARY                             * 09400019
*                                                                     * 09600019
*TABLES/WORK AREAS-                                                   * 09800019
*   18 WORD SAVE AREA                                                 * 10000019
*   352 BYTE DSCB BUFFER                                              * 10200019
*                                                                     * 10400019
*   CCT                                                               * 10600019
*        CCTBRDNO - DECREMENTED BY NUMBER OF BRDCST MESSAGES IN SYSTEM* 10800019
*        CCTJOBS  - DECREMENTED BY NUMBER OF JOBS IN SYSTEM           * 11000019
*        CCTMSGNO - DECREMENTED BY NUMBER OF USER MESSAGES IN SYSTEM  * 11200019
*        CCTUSERS - DECREMENTED BY NUMBER OF USERS IN SYSTEM          * 11400019
*                                                                     * 11600019
*   UVR                                                               * 11800019
*        UVRCNTL1- CLEARED TO ZERO EXCEPT FOR DELAYED MESSAGE         * 12000019
*                  AVAILABLE (BIT 1) AND DELAYED MESSAGE LOST (BIT 5) * 12200019
*        UVRDDNAM- SET TO BLANKS OR DDNAME OF USER'S LIBRARY          * 12400019
*        UVRLNSEQ- SET TO ZERO                                        * 12600019
*                                                                     * 12800019
*ATTRIBUTES-                                                          * 13000019
*   SERIALLY REUSABLE AND NON-RESIDENT                                * 13200019
*                                                                     * 13400019
*********************************************************************** 13600019
         SPACE 2                                                        13800019
KSYSNO   EQU   1                                                        14000019
KSYSSZ   EQU   12                       NO OF BYTES OF INFO IN BLDL     14200019
SYSMSGFL EQU   1                   SYSTEM MESSAGES FILE                 14400019
USERS    EQU   2                                                        14600019
MESSAGES EQU   3                                                        14800019
BRDCST   EQU   4                                                        15000019
JBTBLS   EQU   5                   JOB TABLE FILE                       15200019
ZIP      EQU   0                                                        15400019
GR1RG    EQU   1                                                        15600019
GR2RG    EQU   2                                                        15800019
BUFRG    EQU   2                                                        16000019
W1RG     EQU   3                                                        16200019
CCC      EQU   4                                                        16400019
CCT      EQU   5                                                        16600019
ISMBUFRG EQU   6                                                        16800019
OUTRG    EQU   6                                                        17000019
KBXRG    EQU   8                                                        17200019
LBXRG    EQU   9                                                        17400019
BASERG   EQU   10                                                       17600019
FBXRG    EQU   12                                                       17800019
SAV      EQU   13                                                       18000019
BAC      EQU   14                                                       18200019
GO       EQU   15                                                       18400019
         TITLE 'BPAM RETRIEVAL OF SYSTEM FILES'                         18600019
         SAVE  (14,12),,BST72059                                        18800026
         LR    BASERG,GO           SET UP BASE REGISTER                 19000019
         USING IHKBST,BASERG                                            19200019
         LA    W1RG,BSTSAVE        ADDRESS OF SAVE AREA                 19400019
         ST    W1RG,8(SAV)         CHAIN SAVE AREAS                     19600019
         ST    SAV,4(W1RG)                                              19800019
          LR    SAV,W1RG            CHANGE SAVE AREA POINTER            20000019
         LR    LBXRG,GR1RG        AVT BASE                              20200019
         USING AVTDSECT,LBXRG     ADDRESS ACON DSECT                    20400019
         L     KBXRG,IHKYYKBX      ADDRESS OF KON BOX                   20600019
         USING RAFKNBX,KBXRG      ADDRESS KONBOX DSECT                  20800019
         L     FBXRG,IHKYYTUB     GET TUB FOR AFIO AND BPAM I/O         21000019
         USING TUBDSECT,FBXRG                                           21200019
         L     CCT,IHKYYCCT       GET CCT                               21400019
         LA    CCC,BSTSAVE         BORROW 2 BYTES FOR COUNT             21600019
*                                                                       21800019
* SET UP PARAMENTERS FOR BPAM NON-STANDARD ACCESS                       22000019
*                                                                       22200019
         LA    W1RG,BPLIST              GET ADDRESS OF PARM LIST        22400019
         ST    W1RG,BPPTRFS             STORE IN KBX FOR BPAM           22600019
*                                                                       22800019
* SET UP BUILD LIST FOR BPAM                                            23000019
*                                                                       23200019
         MVI   BPBLDLST+1,KSYSNO        INITIALIZE FF                   23400019
         MVI   BPBLDLST+3,KSYSSZ        INITIALIZE LL                   23600019
         MVC   BPBLDLST+4(8),CSYSMFKN  SET UP FOR SYSTEM MESSAGE FILE   23800019
*                                                                       24000019
* GENERATE AN ACTIVE SYSTEM FILE                                        24200019
* OPEN BPAM FILE, LOCATE SPECIFIED MEMBERS, POSITION TO READ FIRST      24400019
*                                                                       24600019
REGSTART MVI   GBLNUMFS,SYSMSGFL                                        24800019
         LA    GR1RG,BPQELMFW           QUEUE ELEMENT THIS LINE         25000019
         LA    GR2RG,BPQCTLFW           BPAM QUEUE CONTROL WORDS        25200019
         SPACE 2                                                        25400019
         L     GO,IHKYYRNQ         ADDRESS OF ENQ ROUTINE FOR LIBIO     25600019
         CALL  (15),((1),(2))                                           25800019
         SPACE 2                                                        26000019
SYGEN1   EQU   *                                                        26200019
         LA    GR1RG,IHKYYTUB      GET POINTER TO TUB FOR I/O           26400019
         RFIND I,,NS                                                    26600019
         CH    GO,RC4              CHECK RETURN FROM I/O                26800019
         BNL   SYFNDERR            CHECK OUT RETURN CODE                27000019
*                                                                       27200019
* CREATE ACTIVE FILE                                                    27400019
*                                                                       27600019
SYGEN3   EQU   *                                                        27800019
         CREATE IS,FTYPE=GBL                                            28000019
         LTR   GO,GO               CHECK RETURN FROM I/O                28200019
         BNZ   SYABEND2                 EXIT IF ANY I/O ERRORS          28400019
         MVI   GBLKEYFS+7,0             INITIALIZE FOR POINT 0          28600019
         RPOINT B,NR,FTYPE=GBL                                          28800019
         CH    GO,RC4              CHECK RETURN FROM I/O                29000019
         BH    SYABEND2            EXIT IF ERROR                        29200019
*                                                                       29400019
SYGEN2   RREAD                                                          29600019
         CH    GO,RC4              CHECK RETURN FROM I/O                29800019
         BE    SYGEN4                  EOD                              30000019
          BH    SYABEND1                PDS I/O ERROR                   30200019
         L     BUFRG,SFBUFF1            POINT TO BUFFER                 30400019
         LA    BUFRG,8(BUFRG)                                           30600019
         LH    W1RG,COUNTFS             GET RECORD COUNT                30800019
         LH    GO,0(CCC)           GET OLD COUNT OF RECORDS IN FILE     31000019
         SR    GO,W1RG             UPDATE COUNT                         31200019
         STH   GO,0(CCC)           SAVE NEW COUNT                       31400019
         CLI   GBLNUMFS,USERS     CREATING USERS FILE?                  31600019
         BE    SYUSERS1           YES                                   31800019
*                                                                       32000019
* INSERT                                                                32200019
*                                                                       32400019
SYGEN2A  EQU   *                                                        32600019
         L     OUTRG,SFBUFF1      GET BLOCK JUST READ                   32800019
         ST    OUTRG,TUBRAFBF     PUT IT IN TUB FOR INSERT              33000019
         LA    GR1RG,IHKYYTUB      GET POINTER TO TUB FOR I/O           33200019
         INSERT M,FTYPE=GBL                                             33400019
         LTR   GO,GO               CHECK RETURN FROM I/O                33600019
        BNZ   SYABEND2                  A.F. I/O ERROR                  33800019
         B    SYGEN2                    READ NEXT BLOCK                 34000019
*                                                                       34200019
*  CHECK TYPE OF NON-NORMAL RETURN FROM RFIND.                          34400019
SYFNDERR BH     SYABEND1          I/O ERROR                             34600019
         CLI   GBLNUMFS,SYSMSGFL  MEMBER NOT FOUND.  IS IT UMF?         34800019
         BE    SYABEND1            YES NO FILES  ABEND STARTUP          35000019
         LA    GR1RG,IHKYYTUB      GET POINTER TO TUB FOR I/O           35200019
       CREATE IS,FTYPE=GBL        ELSE OK, CREATE GLOBAL FILE AND       35400019
         LTR   GO,GO               CHECK RETURN FROM I/O                35600019
         BNZ   SYABEND2           "ABEND" IF I/O ERROR OR NO-SPACE.     35800019
*                                                                       36000019
SYGEN4   EQU   *                                                        36200019
         ENDUP FTYPE=GBL                                                36400019
         LTR   GO,GO               CHECK RETURN FROM I/O                36600019
         BNZ   SYABEND2                 ABEND IF I/O ERROR              36800019
         SR    GO,GO              CLEAR FIFTEEN FOR BRANCH TABLE        37000019
         IC    GO,GBLNUMFS        GET LAST GLOBAL FILE NUMBER           37200019
         SLL   GO,2               MULTIPLY BY FOUR                      37400019
         B     *(GO)              BRANCH TO SET UP NEXT FILE OR EXIT    37600019
         B     USRFILE            SET UP USERS FILE                     37800019
         B     USMESSGS           SET UP USER MESSAGES FILE             38000019
         B     BROAD              SET UP BROADCAST MESSAGES FILE        38200019
         B     RJCTS              SET UP JOB TABLE FILE                 38400019
         SPACE 4                                                        38600019
         RCLOSE                                                         38800019
         LTR   GO,GO               CHECK RETURN FROM I/O                39000019
         BNZ   SYABEND1                 EXIT IF I/O ERROR               39200019
         TITLE 'DEVICE SEARCH FOR RITS LIBRARIES'                       39400019
         SPACE 2                                                        39600019
RA       EQU   4                        BASE FOR TIOT AND CVT           39800019
RB       EQU   5                        BASE FOR UCB AND DSCB           40000019
W1       EQU   6                                                        40200019
W2       EQU   2                        W2/W3 = EVEN/ODD PAIR           40400019
W3       EQU   3                                                        40600019
SYRTSUT  EQU   *                                                        40800019
         MVI   GBLNUMFS,USERS           INDICATE USER FILE              41000019
* LOCATE THE TIOT FOR THIS TASK                                         41200019
         L     RA,CVTPTR                LOCATE CVT                      41400019
         USING CVT,RA                                                   41600019
         L     RA,CVTTCBP               LOCATE NEXT AND LAST T ASKS     41800019
         DROP  RA                                                       42000019
         L     RA,4(RA)                 POINT TO CURRENT TASK           42200019
         USING TCB,RA                                                   42400019
         L     RA,TCBTIO                LOCATE TIOT                     42600019
         USING TIOT,RA                                                  42800019
* SCAN THROUGH DD ENTRIES IN TIOT                                       43000019
         LA    RA,TIOELNGH              LOCATE FIRST DD ENTRY           43200019
         USING TIOELNGH,RA                                              43400019
NEXTDD   SR    W1,W1                                                    43600019
         IC    W1,TIOELNGH              PICK UP LENGTH OF NEXT DD ENTRY 43800019
         LTR   W1,W1                      AND CHECK FOR END OF TIOT     44000019
         BZ    END                        GET OUT IF END OF TIOT        44200019
         LA    W1,0(W1,RA)              W1 = NEXT DD ENTRY              44400019
         ST    W1,W1SAV                 SAVE W1                         44600019
         CLC   TIOEDDNM(3),CLIBKN      CRBE LIB FILE DD NAME?           44800019
         BNE   NOINT1                   SKIP IF NOT                     45000019
         MVC   LISTDD,TIOEDDNM          DD NAME FOR USER FILE           45200019
* VALIDATE THAT DEVICE IS D.A.                                          45400019
         LA    RA,TIOESTTB              BUMP TO FIRST DEVICE ENTRY      45600019
         ST    RA,RASAV                 SAVE RA                         45800019
         USING TIOESTTB,RA                                              46000019
NEXTDEV  L     RB,TIOESTTB              PICK UP NEXT UCB POINTER        46200019
         USING UCB,RB                                                   46400019
         CLI   UCBTYP+2,X'20'           CHECK FOR D.A. DEVICE           46600019
         BNE   NOINT1              BRANCH IF NOT                        46800019
         CLI   UCBTYP+3,X'01'      IS DEVICE A 2311 ?                   47000019
         BE    DO2311              YES                                  47200019
         CLI   UCBTYP+3,X'08'      IS DEVICE A 2314 ?                   47400019
         BE    D02314A                 YES                      A45668  47460026
         CLI   UCBTYP+3,TYP3330        IS DEVICE A 3330?        A45668  47520026
         BNE   NOINT1              NO OTHERS ARE SUPPORTED              47600019
         MVI   TRK@CYL+3,TKS3330       MAKE 19 TRACKS PER CYL   A45668  47650026
         MVI   TRK@CYL1,TKS3330-1      FOR A 3330 CALCULATION   A45668  47700026
         B     DO2314                  CALCULATE VTOC ADDR      A45668  47720026
D02314A  EQU   *                                                A45668  47750026
         MVI   TRK@CYL+3,X'14'     MAKE 20 TRACKS PER CYL               47800019
         MVI   TRK@CYL1,X'13'       FOR A 2314 CALCULATION              48000019
         B     DO2314              CALCULATE VTOC ADDRESS FOR 2314      48200019
DO2311   DS    0H                                                       48400019
         MVI   TRK@CYL+3,X'0A'     MAKE 10 TRACKS PER CYL               48600019
         MVI   TRK@CYL1,X'09'       FOR 2311 CALCULATION                48800019
DO2314   DS    0H                                                       49000019
         MVC   VOLSER,SRTEVOLI     VOLID FROM UCB                       49200019
* PREPARE TO READ FORMAT 4 VTOC RECORD                                  49400019
         LH    W3,VTOCTT                PICK UP AND CONVERT TTR OF VTOC 49600019
         SR    W2,W2                                                    49800019
         D     W2,TRK@CYL         DIV. BY TRACKS/CYL                    50000019
         STH   W3,SEEKCC               CC                               50200019
         STH   W2,SEEKHH                HH                              50400019
         IC    W2,VTOCR                 R                               50600019
         STC   W2,SEEKR                                                 50800019
         DROP  RB                                                       51000019
* READ FIRST DSCB                                                       51200019
         OBTAIN CAMLST                  ISSUE SVC                       51400019
         LTR   15,15                    TEST FOR ERROR                  51600019
         BNZ   SYABEND3                 BRNACH IF ANY ERROR             51800019
* PROCESS FIRST DSCB (FORMAT 4)                                         52000019
RDOK1    L     RB,CAMLST+12             ADDRESS DSCB                    52200019
         USING DSCB,RB                                                  52400019
         CLI   DSIDFMT,X'F4'            CHECK FOR FORMAT 4 ( CHAR.)     52600019
         BE    RDOK3                    BRANCH IF FOUND                 52800019
         CLI   DSIDFMT,X'04'            CHECK FOR FORMAT 4 BINARY       53000019
         BNE   SYABEND3                                                 53200019
RDOK3    MVC   LSTDSCB1,DS4HPCHR        SAVE LAST FORMAT 1 CCHHR        53400019
         MVC   HIRDSCB,DS4DEVDT         SAVE HIGH R FOR DSCB TRACKS     53600019
NEXTDS   CLC   LSTDSCB1,SEEKADD         CHCK FOR LAST FORMAT 1 DSCB     53800019
         BZ    NOINTRES                 GO TO NEXT DEVICE IF END        54000019
         CLC   HIRDSCB,SEEKR            WAS THAT THE HIGHEST RECORD     54200019
         BE    NEXTRK                   BRANCH IF YES                   54400019
         IC    W2,SEEKR                 BUMP TO NEXT RECORD             54600019
         LA    W2,1(W2)                                                 54800019
         STC   W2,SEEKR                                                 55000019
         B     RDDSCB                   READ NEXT DSCB                  55200019
NEXTRK   MVI   SEEKR,1                  BACK TO RECORD ONE              55400019
         CLC   SEEKHH+1(1),TRK@CYL1    WAS THAT THE LAST HEAD?          55600019
         BE    NEXTCC                     BRANCH IF SO                  55800019
         LH    W2,SEEKHH                  NO, BUMP HEAD NUMBER          56000019
         LA    W2,1(W2)                                                 56200019
         STH   W2,SEEKHH                                                56400019
         B     RDDSCB                   READ NEXT DSCB                  56600019
NEXTCC   SR    W2,W2                    BACK TO HEAD ZERO               56800019
         STH   W2,SEEKHH                                                57000019
         LH    W2,SEEKCC                BUMP TO NEXT CYLINDER           57200019
         LA    W2,1(W2)                                                 57400019
         STH   W2,SEEKCC                                                57600019
* READ NEXT DSCB AND CHECK FOR FORMAT 1                                 57800019
RDDSCB   OBTAIN CAMLST                                                  58000019
         LTR   15,15                    TEST FOR ERRORS                 58200019
         BZ    RDOK2                    BRANCH IF OK                    58400019
         LA    W2,8                                                     58600019
         CR    W2,15                    COMPARE FOR FORMAT ZERO DSCB    58800019
          BNE   SYABEND3                                                59000019
RDOK2    CLI   DSIDFMT,C'1'             IS THIS FORMAT 1                59200019
         BE    STDSNM                   BRANCH IF FORMAT 1              59400019
         CLI   DSIDFMT,X'01'            CHECK FOR FORMAT 1 (BINARY)     59600019
         BNE   NEXTDS                   BRANCH BACK FOR NEXT DSCB       59800019
STDSNM   CLC   DSNAME(9),CDSNMKN        IS IT A RITS DATA SET ?         60000019
         BNE   NEXTDS                   BRANCH IF NOT RITS D S          60200019
         MVC   GBLKEYFS(8),DSNAME+9     MOVE USERID TO GLOBAL KEY       60400019
         LA    GR1RG,IHKYYTUB      GET POINTER TO TUB FOR I/O           60600019
         RPOINT B,R,FTYPE=GBL          POS BEFORE & RETRIEVE USER REC   60800019
         CH    GO,RC4              CHECK RETURN FROM I/O                61000019
         BH    SYABEND2                                                 61200019
         BE    SYNDS                   FILE NOT EXIST                   61400019
         L    ISMBUFRG,BUFFADSS                                         61600019
         USING UVRDSECT,ISMBUFRG                                        61800019
         MVC   UVRDDNAM,LISTDD          MOVE DDNAME TO USER'S RECORD    62000019
         REPLACE NXK,FTYPE=GBL          REPLACE OLD RECORD WITH NEW     62200019
         LTR   GO,GO               CHECK RETURN FROM I/O                62400019
         BNZ   SYABEND2                 I/O ERROR                       62600019
         ENDUP FTYPE=GBL                                                62800019
         LTR   GO,GO               CHECK RETURN FROM I/O                63000019
         BNZ   SYABEND2                 I/O ERROR                       63200019
SYNDS    EQU   *                                                        63400019
         L     RB,CAMLST+12             POINT TO CAMLST WORK AREA       63600019
         B     NEXTDS                   GET NEXT DSCB                   63800019
         DROP  RB                                                       64000019
* CHECK FOR MORE DEVICES.                                               64200019
         USING TIOELNGH,RA                                              64400019
NOINT1   LR    RA,W1                                                    64600019
         B     NEXTDD                  POINT TO NEXT DD ENTRY           64800019
         DROP  RA                                                       65000019
NOINTRES L     RA,RASAV                                                 65200019
SYABEND3 EQU   NOINTRES                                                 65400019
         LA    RA,4(RA)                 BUMP TO NEXT DEVICE OR DD ENTRY 65600019
         C     RA,W1SAV                 COMPARE ADDR. OF NEXT DD TO RA  65800019
         BL    NEXTDEV                  BRANCH IF MORE DEVICES          66000019
         B     NEXTDD                   POINT TO NEXT DD ENTRY          66200019
END      EQU   *                                                        66400019
         SR    GO,GO              SET GOOD RETURN CODE                  66600019
ENDBAD   L     SAV,BSTSAVE+4      RESTORE REGISTER THIRTEEN             66800019
         RETURN (14,12),T,RC=(15)                                       67000019
         TITLE 'ABNORMAL ROUTINES, PARAMETERS, CONSTANTS, DSECTS'       67200019
SYABEND1 EQU   *                                                        67400019
         LA    GO,IOELIB          RETURN CODE I/O ERROR ON SYSLIB       67600019
         B     ENDBAD             RETURN TO IHKCIP                      67800019
SYABEND2 EQU   *                                                        68000019
         LA    GO,IOEACT          SET RETURN CODE I/O ERROR IN ACTIVE   68200019
         B     ENDBAD             RETURN TO IHKCIP                      68400019
         USING CCTDSECT,CCT                                             68600019
USRFILE  MVI   GBLNUMFS,USERS           PREPARE TO CREATE USER FILE     68800019
*                                                                       69000019
*                                                                       69200019
* SET UP BUILD LIST FOR "USERS"                                         69400019
*                                                                       69600019
         MVC   BPBLDLST+4(8),CUSER8KN                                   69800019
         LA    CCC,CCTUSERS        ADDRESS OF COUNT OF USERS            70000019
         B     BUILD               DO BLDL ON MEMBER                    70200019
USMESSGS MVI   GBLNUMFS,MESSAGES       SET GBL NUM TO STD. MSG. FILE    70400019
* SET UP BUILD LIST FOR "MESSAGES"                                      70600019
         MVC   BPBLDLST+4(8),CMESSKN    PUT FILE NAME IN LIST           70800019
         LA    CCC,CCTMSGNO        ADDRESS OF COUNT OF USER MESSAGES    71000019
         B     BUILD               DO BLDL ON MEMBER                    71200019
BROAD    MVI   GBLNUMFS,BRDCST    SET GBL. NUM. TO BROADCAST            71400019
         MVC   BPBLDLST+4(8),CBRDCSTK SET FILE NAME IN LIST             71600019
         LA    CCC,CCTBRDNO        ADDRESS OF COUNT OF BROADCAST MSGS   71800019
         B     BUILD               DO BLDL ON MEMBER                    72000019
RJCTS    MVI   GBLNUMFS,JBTBLS    SET GBL. NUM. TO JOB TABLE            72200019
         MVC   BPBLDLST+4(8),CJOBSKN  SET FILE NAME IN LIST             72400019
         LA    CCC,CCTJOBS         ADDRESS OF COUNT OF RJCTS            72600019
         SPACE 2                                                        72800019
BUILD    MVI   BPBLDLST+1,NUMENT   SET NUMBER OF ENTRIES TO ONE         73000019
         MVI   BPBLDLST+3,LNGENT   SET LENGTH OF ENTRY TO 14            73200019
         L     GR1RG,BPDCBPTR      ADDRESS OF DCB                       73400019
         SPACE                                                          73600019
         BLDL  (1),BPBLDLST        GET TTR OF MEMBER                    73800019
         SPACE                                                          74000019
         MVI   BPBLDLST+15,ZIP     SET USER DATA LENGTH TO ZERO         74200019
         CH    GO,RC4              CHECK RETURN CODE FROM BLDL          74400019
         BNL   SYFNDERR            IF NOT ZERO CHECK FOR TYPE ERROR     74600019
         B     SYGEN1             MOVE FILE TO ACTIVE AREA              74800019
         SPACE 5                                                        75000019
SYUSERS1 EQU   *                                                        75200019
*                                                                       75400019
* BUFRG POINTS TO NEXT RECORD TO EDIT                                   75600019
* W1RG HAS COUNT OF REMAINING RECORDS TO EDIT                           75800019
*                                                                       76000019
         DROP  ISMBUFRG                                                 76200019
         USING UVRDSECT+8,BUFRG                                         76400019
         LTR   GO,GO               MAXIMUN USERS EXCEEDED               76600019
         BL    SYSABND4            YES SEND MESSAGE AND EXIT            76800019
SYUSERS2 MVC   UVRDDNAM,BLANKS          BLANK OUT DDNAME                77000019
         NI    UVRCNTL1,CLEAR      CLEAR STATUS BYTE                    77200019
         XC    UVRLNSEQ(5),UVRLNSEQ RESET LINE SEQUENCE NUMBER          77400019
         LA    BUFRG,80(BUFRG)                                          77600019
         BCT   W1RG,SYUSERS2            BRANCH IF MORE RECS IN BUFFER   77800019
         B     SYGEN2A                                                  78000019
         SPACE 3                                                        78200019
SYSABND4 WTO   'IHK252I USER LIST FULL',DESC=(5),MCSFLAG=(REG0)         78400019
         LA    GO,MAXUSR           SET RETURN CODE                      78600019
         B     ENDBAD              EXIT TO IHKCIP                       78800019
         SPACE 3                                                        79000019
CLEAR    EQU   X'4C'                                                    79200019
NUMENT   EQU   1                                                        79400019
LNGENT   EQU   14                                                       79600019
MAXUSR   EQU   4                                                        79800019
IOELIB   EQU   12                                                       80000019
IOEACT   EQU   8                                                        80200019
TYP3330  EQU   X'09'                                            A45668  80260026
TKS3330  EQU   X'13'                                            A45668  80320026
BSTSAVE  DC    18F'0'                                                   80400019
CSYSMFKN DC    CL8'SYSMSGS'                                             80600019
CUSER8KN DC    CL8'USERS'         FILE NAME FOR VALID CRJE USERS        80800019
CMESSKN  DC    CL8'USRMSGS'                                             81000019
CBRDCSTK DC    CL8'BRDCST'        NAME OF BROADCAST FILE                81200019
CJOBSKN  DC    CL8'JBTBLS'        FILE NAME FOR JOB TABLE               81400019
BLANKS   DC    CL8' '                                                   81600019
* READ A DSCB FROM THE VTOC --  BY LOCATION(TRACK AND RECORD ADDR.)     81800019
CAMLST   CAMLST SEEK,SEEKADD,VOLSER,DSCBBUF                             82000019
         DS    0H                       NEXT DSCB CCHHR                 82200019
SEEKADD  DS    0CL5                                                     82400019
SEEKCC   DS    H                        CC                              82600019
SEEKHH   DS    H                        HH                              82800019
SEEKR    DS    C                        R                               83000019
VOLSER   DS    CL6                      VOLUME SERIAL NUMBER            83200019
         DS    0H                       CCHHR OF LAST ACTIVE FORMAT 1   83400019
LSTDSCB1 DS    0CL5                       DSCB                          83600019
LSTD1CC  DS    H                        CC                              83800019
LSTD1HH  DS    H                        HH                              84000019
LSTD1R   DS    C                        R                               84200019
HIRDSCB  DS    C                        NO. OF DSCB RECORDS PER TRACK   84400019
BPLIST   DS    0A                                                       84600019
LIBPTRFS DC    A(DSSYSLIB)                                              84800019
DDPTRFS  DC    A(DDSYSLIB)                                              85000019
TRK@CYL  DC    F'20'                   NUMBER OF TRAKS PER CYL ON 2314  85200019
TRK@CYL1 DC    FL1'19'            HIGHEST (LAST) HEAD                   85400019
DDSYSLIB DC    CL8'LIB1'                                                85600019
DSSYSLIB DC    CL8'SYSLIB'                                              85800019
BLNK2    DC    C'  '                   BLANK                            86000019
DSCBBUF  DC    88F'0'                                                   86200019
CDSNMKN  DC    C'CRJE.LIB.'                                             86400019
CLIBKN   EQU   CDSNMKN+5                                                86600019
RC4      DC    H'4'                                                     86800019
WORK1CS  DC    D'0'                                                     87000019
         TITLE 'DSECTS'                                                 87200019
         RAFKNBX TYPE=DSECT                                             87400019
LISTDD   EQU   BPPARMFS                                                 87600019
W1SAV    EQU   WORK1CS                                                  87800019
RASAV    EQU   WORK1CS+4                                                88000019
SAVEPTR  EQU   WORK1CS                                                  88200019
         IHKCDSCT TUB=YES,AVT=YES,CCT=YES,UVR=YES                       88400019
         TUBEQU                                                         88600019
TIOT     DSECT                                                          88800019
         IEFTIOT1                                                       89000019
         SPACE 2                                                        89200019
CVT      DSECT                                                          89400019
         CVT                                                            89600019
         SPACE 2                                                        89800019
* TASK CONTROL BLOCK (NOT COMPLETE)                                     90000019
TCB      DSECT                                                          90200019
         DS    3F                                                       90400019
TCBTIO   DS    F                        TIOT POINTER                    90600019
         SPACE 2                                                        90800019
UCB      DSECT                                                          91000019
         IEFUCBOB                                                       91200019
VTOCTT   EQU   SRTEFSCT                                                 91400019
VTOCR    EQU   SRTEFSCT+2                                               91600019
         SPACE 2                                                        91800019
DSCB     DSECT                                                          92000019
DSNAME   DS    CL44                     DSNAME (FORMAT1)                92200019
DSIDFMT  DS    C                        DSCB FORMAT ID                  92400019
DS4HPCHR DS    CL5                      LAST FORMAT 1 DSCB CCHHR        92600019
         DS    12H                                                      92800019
DS4DEVDT DS    C                        NUMBER OF DSCB'S PER TRACK      93000019
         END                                                            93200019
