CC1      TITLE 'IHKCC1 - CENTRAL COMMAND PROCESSOR'                     00100019
IHKCC1   CSECT                                                          00200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00300019
*STATUS                                                               * 00400019
*   CHANGE LEVEL 0                                                    * 00500019
*FUNCTION                                                             * 00600019
*   IHKCC1 CKECKS THE VERB AND THE COMMAND OPERANDS.  IF ANY OPERAND  * 00700019
*   IS INVALID, AN ERROR MESSAGE IS SENT TO THE CENTRAL CONSOLE AND   * 00800019
*   RETURN IS MADE TO THE CALLING ROUTINE.                            * 00900019
*   THE FOLLOWING OPERANDS ARE VALID FOR A SHOW COMMAND.                01000019
*   1. USERS - INDICATE FOR ALL CRJE USERS WHETHER ACTIVE OR INACTIVE.  01100019
*              FOR ALL ACTIVE USERS, SHOW LINEADDRESS AND TIME SINCE    01200019
*              LOGON.                                                   01300019
*   2. USERS,USERID - SAME AS 1.  BUT FOR SPECIFIED USER.               01400019
*   3. JOBS- SHOWS  ALL CRJE JOBS IN SYSTEM.  INDICATES WHETHER       * 01500019
*            COMPLETE OR INCOMPLETE. DISPLAYS USERID WHO SUBMITTED IT * 01600019
*   4. JOBS,JOBNAME- SAME AS FOR 3 BUT ONLY FOR SPECIFIED JOBNAME.    * 01700019
*ENTRY POINTS                                                         * 01800019
*   IHKCC1 IS THE ONLY ENTRY POINT.                                     01900019
*   SEE INPUT FOR ASSOCIATED PARAMETER LIST.                          * 02000019
*INPUT                                                                * 02100019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING     * 02200019
*   THE ADDRESSES OF THE AVT AND THE CIB.                             * 02300019
*OUTPUT                                                               * 02400019
*   N/A                                                               * 02500019
*EXTERNAL REFERENCES                                                  * 02600019
*        IHKAFI - TO MANIPULATE GLOBAL FILES                          * 02700019
*        IHKMSG - ENTRY POINT: IHKMSG                                 * 02800019
*        TO SEND  MESSAGES TO THE CENTRAL CONSOLE.                    * 02900019
*EXITS, NORMAL                                                        * 03000019
*        RETURN TO CALLER WITH ZERO IN REGISTER 15                    * 03100019
*EXITS, ERROR                                                         * 03200019
*        ERROR MESSAGE IS SENT TO CENTRAL CONSOLE                     * 03300019
*        RETURN IS MADE TO CALLER WITH ZERO IN REGISTER 15            * 03400019
*TABLES/WORK AREAS                                                    * 03500019
*   SAVEAREA                                                            03600019
*   TUB - CONTAINED IN MODULE.                                          03700019
*   TUBUFFAD - ADDRESS OF USER BUFFER                                 * 03800019
*   AFIO CONTROL INFORMATION                                          * 03900019
*   USER BUFFER                                                       * 04000019
*   CIB - CONTAINS COMMAND AND OPERANDS                               * 04100019
*   UVR - CONTAINS USER INFORMATION                                   * 04200019
*   AVT                                                               * 04300019
*ATTRIBUTES                                                           * 04400019
*   NON-RESIDENT                                                      * 04500019
*   SERIALLY REUSABLE                                                   04600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 04700019
         EJECT                                                          04800019
*********************************************************************** 04900019
*   REGISTER EQUATES                                                    05000019
*********************************************************************** 05100019
R0       EQU   0                                                        05200019
R1       EQU   1                                                        05300019
R2       EQU   2                                                        05400019
R3       EQU   3                                                        05500019
R4       EQU   4                        RETURN 0 FROM AFIO              05600019
R5       EQU   5                        RETURN 4 FROM AFIO              05700019
RUVR     EQU   6                        UVR BASE                        05800019
R7       EQU   7                        INTERNAL LINKAGE                05900019
RCIB     EQU   8                        CIB BASE                        06000019
RTUB     EQU   9                        TUB BASE                        06100019
R10      EQU   10                       INTERNAL LINKAGE                06200019
RAVT     EQU   11                       AVT BASE                        06300019
RBASE    EQU   12                       IHKCC1 BASE                     06400019
R13      EQU   13                                                       06500019
R14      EQU   14                                                       06600019
R15      EQU   15                                                       06700019
*********************************************************************** 06800019
*   OTHER EQUATES                                                       06900019
*********************************************************************** 07000019
GBLF2    EQU   2                        GLOBAL FILE 2-UVR               07100019
GBLF5    EQU   5                        GLOBAL FILE 5- RJCT             07200019
JOBCOMP  EQU   X'40'                    TEST FOR JOB COMPLETE           07300019
JOBNMLNG EQU   8                        LENGTH OF JOBNAME               07400019
USRIDLNG EQU   7                        LENGTH OF USERID                07500019
LNGTUB1  EQU   7                                                        07600019
SHOWCMD  EQU   X'88'                    SHOW COMMAND VERB IN CIB        07700019
HIBIT    EQU   X'80'                    BIT SET FOR END OF PARAM LIST   07800019
ALLBITS  EQU   X'FF'                                                    07900019
HEXF0    EQU   X'F0'                                                    08000019
HEX0F    EQU   X'0F'                                                    08100019
X00      EQU   X'00'                                                    08200019
X4       EQU   4                                                        08300019
X7       EQU   7                                                        08400019
X8       EQU   X'8'                                                     08500019
X0A      EQU   10                       MAX SIZE FOR INSERT IN MSGS     08600019
BLANK    EQU   C' '                                                     08700019
HRS24    EQU   1440                                                     08800019
THIRTY1  EQU   31                                                       08900019
         EJECT                                                          09000019
*********************************************************************** 09100019
*   SET UP BASE REGISTERS, SAVEAREA                                     09200019
*********************************************************************** 09300019
         USING IHKCC1,RBASE                                             09400019
         USING AVTDSECT,RAVT                                            09500019
         USING TUBDSECT,RTUB                                            09600019
         USING CIBBASE,RCIB                                             09700019
         USING UVRDSECT,RUVR                                            09800019
*                                                                       09900019
         SAVE  (14,12),,IHKCC1-5/18/70                                  10000019
         LR    RBASE,R15                SET UP BASE REGISTER            10100019
         L     RAVT,0(R1)               AVT ADDRESS PASSED              10200019
         L     RCIB,4(R1)               CIB ADDRESS PASSED              10300019
         ST    R13,SAVEAREA+4           SAVE CALLERS SAVEAREA ADDR      10400019
         LA    R1,SAVEAREA                                              10500019
         ST    R1,8(R13)                SAVE SAVEAREA IN CALLERS        10600019
         LR    R13,R1                                                   10700019
*                                                                       10800019
*  INITIALIZE                                                           10900019
*                                                                       11000019
         LA    RTUB,LOCTUB              TUB BASE REGISTER               11100019
         LA    R15,CIBDATA-1                                            11200019
         AH    R15,CIBDATLN             COMPUTE END ADDR OF OP          11300019
         ST    R15,LASTCIB              LAST CHAR OF CIB                11400019
         L     RUVR,TUBUFFAD            WILL READ INTO USER BUFFER      11500019
         MVI   NXTUVR+7,X00             SET TO READ FIRST RECORD        11600019
*********************************************************************** 11700019
*                                                                       11800019
*  CHECK FOR SHOW                                                       11900019
*                                                                       12000019
*********************************************************************** 12100019
         CLI   CIBVERB,SHOWCMD          IS IT SHOW                      12200019
         BNE   RETURN0                  BR = NO, RETURN                 12300019
*                                                                       12400019
*   IS SHOW- CHECK FOR USERS OR JOBS                                    12500019
*                                                                       12600019
         LA    R1,SHOWCC1                                               12700019
         BAL   R14,FINDSUBR             GO LOOK FOR VALID OP            12800019
         B     SHOWBR(R15)              BRANCH TO ROUTINE TO HANDLE OP  12900019
*********************************************************************** 13000019
*                                                                       13100019
* SHOW USERS AND SHOW JOBS                                              13200019
*                                                                       13300019
*********************************************************************** 13400019
READFRST LA    R5,NOUSERS               FIRST TIME-RETURN4- NULL FILE   13500019
READNXUV MVC   TUBGBLKY,NXTUVR          RECORD TO BE READ               13600019
         LA    R4,GETKEY                0    FOUND                      13700019
READUVR  BAL   R14,SETUPPNT             SET UP SWITCHES                 13800019
         RPOINT A,R,FTYPE=XGBL                                          13900019
         B     RTRNAFI(R15)             CHECK IF FOUND                  14000019
*********************************************************************** 14100019
*                                                                       14200019
*  UVR OR RJCT RECORD FOUND- GET NEXT KEY AND ENDUP                     14300019
*                                                                       14400019
*********************************************************************** 14500019
GETKEY   LA    R4,ENDUP1                0    FOUND                      14600019
         LA    R5,SETEOD                4    EOD                        14700019
         LA    R1,ADDRTUB(R13)                                          14800019
         RGET  XK,S,FTYPE=XGBL          GET NEXT KEY                    14900019
         B     RTRNAFI(R15)             CHECK IF FOUND                  15000019
*                                                                       15100019
*   EOD- SET SWITCH                                                     15200019
*                                                                       15300019
SETEOD   OI    OPRSW,OPREOD             SET EOD SWITCH                  15400019
         B     ENDUP2                                                   15500019
ENDUP1   MVC   NXTUVR,TUBGBLKY          SAVE USERID FOR NEXT TIME       15600019
ENDUP2   BAL   R10,CKENDUP                                              15700019
         LA    R14,USERIDL              INSERT USERID OR JOBNAME        15800019
         ST    R14,TUBPARM4                                             15900019
         TM    OPRSW,OPRJOB                                             16000019
         BO    CKJOB                    BR= SHOW JOBS                   16100019
*********************************************************************** 16200019
*                                                                       16300019
*   PROCESS SHOW USERS                                                  16400019
*                                                                       16500019
*********************************************************************** 16600019
         MVC   USERID,UVRUSRID                                          16700019
CKACTIV  TM    UVRCNTL1,UVRACTVN        IS USER ACTIVE                  16800019
         BO    FINDTUB                  BR= YES                         16900019
*********************************************************************** 17000019
*                                                                       17100019
*   INACTIVE USER                                                       17200019
*                                                                       17300019
*********************************************************************** 17400019
NOTACTIV LA    R1,MUSER                                                 17500019
         MVI   TUBPARM4,HIBIT                                           17600019
USRMSG   BAL   R7,SENDMSG               GO SEND MESSAGE                 17700019
*********************************************************************** 17800019
*                                                                       17900019
*  CHECK FOR USERID OR JOBNAME SPECIFIED- IF WAS, RETURN                18000019
*                                                                       18100019
*********************************************************************** 18200019
CKUSRID1 TM    OPRSW,OPUSRJOB                                           18300019
         BO    RETURN0                  USERID OR JOBNAME PROCESSED     18400019
         EJECT                                                          18500019
*********************************************************************** 18600019
*                                                                       18700019
*   SHOW USERS OR SHOW JOBS                                             18800019
*  SET UP TO READ NEXT UVR OR RJCT                                      18900019
*                                                                       19000019
*********************************************************************** 19100019
RDNXTUVR LA    R5,USRNFND               4   NOT FOUND                   19200019
         TM    OPRSW,OPREOD             HAS EOD BEEN REACHED            19300019
         BZ    READNXUV                 BR= NO                          19400019
         B     RETURN0                  BR= YES                         19500019
*********************************************************************** 19600019
*                                                                       19700019
*  SHOW  USERS, USERID AND SHOW JOBS,JOBNAME                            19800019
*   TEST VALID USERID/JOBNAME                                           19900019
*                                                                       20000019
*********************************************************************** 20100019
USRIDVAL L     R1,LASTCIB               LAST IN CIB- COMPUTE LENGTH     20200019
         SR    R1,R3                    AND TEST VALID USERID/JOBNAME   20300019
         ST    R3,TUBPARM4              SAVE ADDRESS OF USERID/JOBNAME  20400019
         ST    R3,TUBPARM5                                              20500019
         LA    R15,USRIDLNG             LENGTH OF USERID                20600019
         TM    OPRSW,OPRJOB                                             20700019
         BZ    CKLNG                    BR= SHOW USERS                  20800019
         LA    R15,JOBNMLNG             JOBNAME LENGTH                  20900019
CKLNG    STC   R1,0(R3)                 STORE LENGTH                    21000019
         LTR   R1,R1                    TEST FOR ZERO LENGTH            21100019
         BZ    INVALUSR                 BR= ZERO LENGTH                 21200019
         CR    R1,R15                                                   21300019
         BH    INVUSRA                  BR= TOO LONG                    21400019
         MVI   TUBGBLKY,BLANK                                           21500019
         MVC   TUBGBLKY+1(LNGTUB1),TUBGBLKY                             21600019
         BCTR  R1,0                                                     21700019
         EX    R1,MVCUSR                SAVE USERID OR JOBNAME          21800019
         LA    R4,ENDUP2                RETURN 0- FOUND                 21900019
         LA    R5,INVALUSR              RETURN 4- NOT FOUND             22000019
         B     READUVR                                                  22100019
*********************************************************************** 22200019
*                                                                       22300019
*  NOT FOUND- CHECK FOR SHOW USERS,USERID  OR JOBS,JOBNAME              22400019
*                                                                       22500019
*********************************************************************** 22600019
USRNFND  BAL   R10,CKENDUP              GO ENDUP                        22700019
         LA    R4,GETNEXT               FIND NEXT HIGHER KEY            22800019
         LR    R5,R4                                                    22900019
         BAL   R14,SETUPPNT             SET UP SWITCHES                 23000019
         RPOINT A,NR,KEY=HIEQ,FTYPE=XGBL                                23100019
         B     RTRNAFI(R15)                                             23200019
         EJECT                                                          23300019
*********************************************************************** 23400019
*                                                                       23500019
*   RETURN 0 AND 4 - POINTS TO NEXT HIGHER RECORD                       23600019
*                                                                       23700019
*********************************************************************** 23800019
GETNEXT  LA    R4,GETKEY                RETURN 0- GO GET NEXT KEY       23900019
         LA    R5,RETURN0               RETURN 4 - EOD                  24000019
         LA    R1,ADDRTUB(R13)          GET NEXT RECORD                 24100019
         RGET  R,S,A,FTYPE=XGBL                                         24200019
         B     RTRNAFI(R15)                                             24300019
*********************************************************************** 24400019
*                                                                       24500019
*   PROCESS RJCT RECORD                                                 24600019
*                                                                       24700019
*********************************************************************** 24800019
         USING RJCTSECT,R5                                              24900019
CKJOB    LA    R5,X8(RUVR)                                              25000019
         MVC   JOBNAME,RJCTJOB                                          25100019
         MVC   PASSWORD+1(7),RJCTUSER   USERID OF SUBMITTER             25200019
         MVI   PASSWORD,X7              INSERT USERID                   25300019
         LA    R1,PASSWORD                                              25400019
         ST    R1,TUBPARM5              INSERTION FOR MESSAGE           25500019
         MVI   TUBPARM5,HIBIT                                           25600019
         LA    R1,MJOBCOM               JOB COMPLETE- SEND MSG          25700019
         TM    RJCTFLGS,JOBCOMP                                         25800019
         BO    USRMSG                   BR= JOB COMPLETE                25900019
JOBINC   LA    R1,MJOBINC               JOB INCOMPLETE                  26000019
         B     USRMSG                   GO SEND MESSAGE                 26100019
*********************************************************************** 26200019
*                                                                       26300019
*  ACTIVE USER- FIND TUB                                                26400019
*                                                                       26500019
*********************************************************************** 26600019
FINDTUB  L     RTUB,IHKYYTUB            POINTER TO FIRST TUB            26700019
         B     CKTUB                    GO SEE IF ANY TUBS              26800019
CKNXTUB  CLC   USERID,TUBUSRID          LOOK FOR SPECIFIED USERID       26900019
         BE    TUBFOUND                 BR= FOUND                       27000019
         L     RTUB,TUBNEXT             NEXT TUB IN CHAIN               27100019
CKTUB    LA    RTUB,0(RTUB)                                             27200019
         LTR   RTUB,RTUB                                                27300019
         BNZ   CKNXTUB                  BR = ANOTHER TUB, GO CHECK      27400019
         LA    RTUB,LOCTUB              NOT FOUND- RESTORE CC1 TUB      27500019
         B     NOTACTIV                 GO SEND INACTIVE USER MESSAGE   27600019
*********************************************************************** 27700019
*                                                                       27800019
*  COMPUTE TIME SINCE LOGON                                             27900019
*                                                                       28000019
*********************************************************************** 28100019
TUBFOUND L     R1,TUBCLBAD              CLB ADDRESS FOR LINE            28200019
         USING CLBDSECT,R1                                              28300019
         MVC   USRLINE+1(L'CLBLINE),CLBLINE SAVE LINEADDRESS            28400019
         LH    R1,TUBTIME               TIME OF LOGON                   28500019
         LA    RTUB,LOCTUB              RESTORE TUB                     28600019
         SR    R14,R14                                                  28700019
         ST    R14,TUBPARM5             CLEAR TO ZEROES                 28800019
         STH   R1,TUBPARM5              LOGON TIME- HRS, MIN            28900019
         MVI   SWITCH2,X00              SET INITIAL SWITCH              29000019
COMPTIME ST    R14,TUBPARM1             CLEAR TO ZEROES                 29100019
         OI    TUBPARM1+3,HEX0F         STORE SIGN                      29200019
         MVC   TUBPARM2,TUBPARM1        CLEAR TO ZEROES                 29300019
         MVO   TUBPARM1+2(2),TUBPARM5+1(1)    00 00 0M MF               29400019
         MVO   TUBPARM2+2(2),TUBPARM5(1)   00 00 0H HF                  29500019
         MP    TUBPARM2,HRMIN           CONVERT HOURS TO MINUTES        29600019
         AP    TUBPARM1,TUBPARM2        HOURS PLUS MINUTES              29700019
         ST    R14,PASSWORD                                             29800019
         MVC   PASSWORD+4(4),TUBPARM1   CLEAR TO ZEROES                 29900019
         CVB   R15,PASSWORD             CONVERT TO BINARY TOTAL MIN     30000019
         TM    SWITCH2,SWTUBTIM         FIR ST TIME THROUGH             30100019
         BO    CKSEC                    BR=NO                           30200019
         ST    R15,TUBPARM4             YES- SAVE LOGON TIME            30300019
         TIME  ,                        PRESENT TIME                    30400019
         ST    R0,TUBPARM5                                              30500019
         OI    SWITCH2,SWTUBTIM         SET SECOND TIME SWITCH          30600019
         B     COMPTIME                 GO CONVERT TO MINUTES           30700019
*********************************************************************** 30800019
*                                                                       30900019
*   SECOND TIME THROUGH- COMPUTE TIME SINCE LOGON                       31000019
*                                                                       31100019
*********************************************************************** 31200019
CKSEC    LA    R1,THIRTY1                                               31300019
         IC    R14,TUBPARM5+2           SECONDS- CHECK FOR >30          31400019
         CR    R14,R1                                                   31500019
         BL    COMPHRS                  BR= LESS THAN 30                31600019
         LA    R15,1(R15)               30 OR MORE- ADD ONE MINUTE      31700019
COMPHRS  LA    R1,HRS24                 CHECK FOR BEYOND 24 HOURS       31800019
         C     R15,TUBPARM4                                             31900019
         BNL   SUBTIME                  BR= LESS THAN 24                32000019
         AR    R15,R1                   ADD 24 HRS                      32100019
SUBTIME  S     R15,TUBPARM4             PRESENT TIME MINUS LOGON        32200019
         BAL   R7,CONVERT               GO CONVERT TO ZONED DECIMAL     32300019
         MVI   PASSWORD,BLANK                                           32400019
         LA    R14,USRLINE              SET UP INSERT OF                32500019
         ST    R14,TUBPARM5             LINEADDRESS, TIME               32600019
         MVI   TUBPARM5,HIBIT                                           32700019
         LA    R1,USERIDL               USERID- FIRST INSERT            32800019
         ST    R1,TUBPARM4                                              32900019
         LA    R1,MUSRACTV              ACTIVE USER MESSAGE             33000019
         B     USRMSG                                                   33100019
         EJECT                                                          33200019
*********************************************************************** 33300019
*   SUPPLIED MESSAGES                                                   33400019
*********************************************************************** 33500019
*                                                                       33600019
*  GETMAIN FAIL                                                         33700019
*                                                                       33800019
SNDOUTSP LA    R2,OUTSP                                                 33900019
         B     INSNOPRN                                                 34000019
*                                                                       34100019
*  ACTIVE AREA I/O ERROR                                                34200019
*                                                                       34300019
AAIOERR  LA    R2,MSGIOER                                               34400019
INSNOPRN OI    OPRSW,OPRERRMS           SWITCH- SUPPLIED MSG            34500019
         LH    R15,0(R2)                LENGTH OF MSG                   34600019
         L     R1,TUBUFFAD                                              34700019
         EX    R15,MVCMSG               MOVE TO USER BUFFER             34800019
         B     INSNOPAR                 GO SEND SUPPLIED MSG            34900019
MVCMSG   MVC   0(0,R1),0(R2)                                            35000019
*********************************************************************** 35100019
*   ERROR MESSAGES                                                      35200019
*********************************************************************** 35300019
*                                                                       35400019
*  OPERAND INVALID/MISSING                                              35500019
*    INSERT FIRST TEN CHAR IN MSG                                       35600019
*                                                                       35700019
OPNFND   LA    R1,MNOTFND                                               35800019
STRCIB   CLI   CIBDATLN+1,X0A           CK FOR LESS THAN TEN            35900019
         BL    INSLNGTH                                                 36000019
         MVI   CIBDATLN+1,X0A           MORE THAN 10- INSERT 10         36100019
INSLNGTH LA    R14,CIBDATLN+1                                           36200019
         ST    R14,TUBPARM5             INSERT FROM CIB                 36300019
INSCMDOP LA    R15,SHOW                 INSERT SHOW COMMAND             36400019
         ST    R15,TUBPARM4                                             36500019
INS2PRM2 MVI   TUBPARM5,HIBIT                                           36600019
         B     SENDMSG0                 GO SEND MESSAGE- RETURN 0       36700019
*                                                                       36800019
*  INVALID USERID OR JOBNAME                                            36900019
*                                                                       37000019
INVUSRA  LA    R15,X0A                  CHECK FOR LONGER THAN 10        37100019
         CR    R1,R15                                                   37200019
         BNH   INVALUSR                 BR= NOT LONGER                  37300019
         STC   R15,0(R3)                LONGER- INSERT 10               37400019
INVALUSR LA    R1,MINVUSR               INVALID USERID MSG              37500019
         TM    OPRSW,OPRJOB                                             37600019
         BZ    INSCMDOP                 BR= SHOW USERS                  37700019
         LA    R1,MINVJOB               INVALID JOBNAME MSG             37800019
INS1PRM1 MVI   TUBPARM4,HIBIT           INSERT JOBNAME OR USERID        37900019
         B     SENDMSG0                 GO SEND MSG- RETURN 0           38000019
         EJECT                                                          38100019
*********************************************************************** 38200019
*   RESPONSE WITH NULL FILE                                             38300019
*  NO CRJE USERS OR NO JOBS                                             38400019
*********************************************************************** 38500019
NOUSERS  LA    R1,MNOUSER               NO USERS MSG                    38600019
         TM    OPRSW,OPRJOB                                             38700019
         BZ    INSNOPAR                 BR= SHOW USERS                  38800019
         LA    R1,MNOJOBS               SHOW JOBS- NO JOBS MSG          38900019
INSNOPAR ST    R1,TUBPARM3                                              39000019
         MVI   TUBPARM3,HIBIT           NO INSERTION                    39100019
         LA    R7,RETURN0                                               39200019
         B     SENDMSGA                                                 39300019
*********************************************************************** 39400019
*                                                                       39500019
*  CHECK IF ENDUP NEEDED                                                39600019
*                                                                       39700019
*********************************************************************** 39800019
CKENDUP  LR    R4,R10                   SET RETURN REGISTER             39900019
         LR    R5,R10                                                   40000019
         TM    OPRSW,OPRENDUP                                           40100019
         BZ    RTRNAFI                  BR= ENDUP NOT NEEDED            40200019
         MVI   GBLNUMFS,GBLF2           GLOBAL FILE- SHOW USERS(UVR)    40300019
         TM    OPRSW,OPRJOB                                             40400019
         BZ    TURNOFF                                                  40500019
         MVI   GBLNUMFS,GBLF5           GLOBAL FILE-SHOW JOBS(RJCT)     40600019
TURNOFF  NI    OPRSW,OPRENDPF           TURN OFF ENDUP SWITCH           40700019
         LA    R1,ADDRTUB(R13)                                          40800019
         ENDUP FTYPE=GBL                                                40900019
         B     RTRNAFI(R15)             CHECK IF FOUND                  41000019
RTRNAFI  B     0(R4)                    RETURN 0                        41100019
         B     0(R5)                    RETURN 4                        41200019
         B     SNDOUTSP                 8                               41300019
         B     AAIOERR                  12                              41400019
*********************************************************************** 41500019
*                                                                       41600019
*   CONVERT TO ZONED DECIMAL                                            41700019
*                                                                       41800019
*********************************************************************** 41900019
CONVERT  CVD   R15,PASSWORD             STORE ON DOUBLEWORD BOUNDARY    42000019
         UNPK  PASSWORD(5),PASSWORD+5(3)                                42100019
         MVI   PASSWORD,X4              STORE LENGTH FOR MSG WRITER     42200019
         OI    PASSWORD+4,HEXF0         STORE SIGN                      42300019
         LA    R14,PASSWORD                                             42400019
         LA    R1,PASSWORD+1                                            42500019
         LA    R15,3                                                    42600019
CKZERO   CLI   0(R1),HEXF0              REMOVE LEADING ZEROES           42700019
         BNE   CONVRTN                                                  42800019
         MVI   0(R1),BLANK              STORE BLANK INSTEAD OF ZERO     42900019
         LA    R1,1(R1)                                                 43000019
         BCT   R15,CKZERO                                               43100019
CONVRTN  BR    R7                       CONVERT FINISHED- RETURN        43200019
*********************************************************************** 43300019
*                                                                       43400019
*   SET  UP SWITCHES, GLOBAL FILE NUMBER                                43500019
*                                                                       43600019
*********************************************************************** 43700019
SETUPPNT MVI   GBLNUMFS,GBLF2           SHOW USERS-UVR GLOBAL FILE      43800019
         TM    OPRSW,OPRJOB                                             43900019
         BZ    SETSW                    BR= SHOW USERS                  44000019
         MVI   GBLNUMFS,GBLF5           SHOW JOBS- GLOBAL FILE          44100019
SETSW    OI    OPRSW,OPRENDUP           SET SWITCH TO ENDUP             44200019
         ST    RUVR,TUBRAFBF            POINTS TO USER BUFFER           44300019
         OI    TUBAFISW,TUBFCTLN        SET TO READ INTO USER BUFFER    44400019
         LA    R1,ADDRTUB(R13)          SAVEADDR WHERE RTUB WILL BE     44500019
         BR    R14                                                      44600019
         EJECT                                                          44700019
*********************************************************************** 44800019
*  SUBROUTINE TO SEARCH FOR SPECIFIED SET OF CHARACTERS                 44900019
*        CHECKS FOR END OF CIB                                          45000019
*        AT ENTRY REGISTER ONE POINTS TO TABLE DEFINING VALID CHARACTER 45100019
*        STRINGS, AND CHARACTER (OR END OF CIB) THAT MUST FOLLOW        45200019
*        SETS SWITCH WITH CODE FROM TABLE                               45300019
*        RETURNS WITH REGISTER 15 CONTAINING BRANCH CODE (FROM TABLE)   45400019
*        AND REGISTER 3 POINTS AT CHAR AFTER OP IN CIB (IF ANY)         45500019
*********************************************************************** 45600019
         SPACE 2                                                        45700019
FINDSUBR SR    R15,R15                                                  45800019
GETLNG   IC    R15,1(R1)                LENGTH OF OPERAND FROM TABLE    45900019
         SR    R2,R2                                                    46000019
         IC    R2,0(R1)                 ENTIRE LENGTH OF OP IN TABLE    46100019
         AR    R2,R1                    POINTS TO BEGIN OF NEXT OP      46200019
         LA    R1,2(R1)                 REG1 POINTS AT OP IN TABLE      46300019
         CH    R15,CIBDATLN                                             46400019
         BH    NXTABLE                  BR= OP IN CIB SHORTER           46500019
         LA    R3,CIBDATA               REG3 POINTS AT OP IN CIB        46600019
         BCTR  R15,0                                                    46700019
         EX    R15,CLCOP                COMPARE OPERANDS-CIB,TABLE      46800019
         LA    R15,1(R15)               RESTORE TO OP LENGTH IN TABLE   46900019
         BNE   NXTABLE                  BR= NOT OP IN TABLE             47000019
         AR    R1,R15                   OP EQUAL-CK NEXT CHAR           47100019
NEXTCHAR CLI   0(R1),X00                                                47200019
         BE    CKCIBEND                 BR= MUST BE END OF CIB          47300019
         CH    R15,CIBDATLN             MUST BE ANOTHER CHAR            47400019
         BNL   CKEND                    BR= NOT ANOTHER IN CIB          47500019
         AR    R3,R15                   POINTS TO CHAR AFTER OP-CIB     47600019
         CLC   0(1,R3),0(R1)            IS IT CHAR IN TABLE             47700019
         BNE   CKEND                    BR= NO                          47800019
GETBRNCH MVC   OPRSW,1(R1)              IS CHAR- SET SWITCH FROM TABLE  47900019
         IC    R15,2(R1)                GET BRANCH FROM TABLE           48000019
         BR    R14                      RETURN                          48100019
*                                                                       48200019
CKCIBEND CH    R15,CIBDATLN             HAS TO BE END OF CIB            48300019
         BE    GETBRNCH                 BR= IS END, OPERAND FOUND       48400019
CKEND    LA    R1,3(R1)                 UPDATE TO NEXT OP IN TABLE      48500019
         CR    R1,R2                                                    48600019
         BL    NEXTCHAR                 BR= CHECK AGAINST THIS CHAR     48700019
*                                                                       48800019
*  POINT TO NEXT ENTRY IN TABLE                                         48900019
*                                                                       49000019
NXTABLE  LR    R1,R2                                                    49100019
         TM    0(R1),ALLBITS                                            49200019
         BO    OPNFND                   BR= NO MORE IN TABLE            49300019
         B     GETLNG                   GO CHECK NEXT OP IN TABLE       49400019
         EJECT                                                          49500019
*********************************************************************** 49600019
*   SUBROUTINE TO SEND MESSAGES                                         49700019
*   SENDMSG0- SETS RETURN TO ZERO                                       49800019
*   SENDMSG- AT LEAST ONE INSERTION                                     49900019
*   SENDMSGA- NO INSERTIONS                                             50000019
*********************************************************************** 50100019
*                                                                       50200019
SENDMSG0 LA    R7,RETURN0                                               50300019
SENDMSG  ST    R1,TUBPARM3              PARAM 3 = ADDR OF MSG           50400019
SENDMSGA ST    RTUB,TUBPARM1            PARAM 1 = ADDR OF TUB           50500019
         BAL   R10,CKENDUP              GO ENDUP IF NECESSARY           50600019
         LA    R1,ZEROES                                                50700019
         ST    R1,TUBPARM2              PARAM 2 = ADDR OF ZERO          50800019
         MVC   0(1,R1),CIBCONID         HIGH ORDER BIT= CONSOLE ID      50900019
         TM    OPRSW,OPRERRMS           IS THIS SEND A SUPPLIED MSG     51000019
         BZ    ENTRMSG                  BR = NO                         51100019
         L     R15,IHKYMSG2             IHKMSG02- SEND SUPPLIED         51200019
         B     GETPARM1                                                 51300019
ENTRMSG  L     R15,IHKYYMSG             IHKMSG- SEND SYSTEM MSG         51400019
GETPARM1 LA    R1,TUBPARM1                                              51500019
         BALR  R14,R15                  GO SEND MESSAGE                 51600019
         B     MSGRTN(R15)                                              51700019
MSGRTN   B     0(R7)                    0    MSG SENT                   51800019
         B     0(R7)                    4    TP LINE ERROR (NOT APPLIC) 51900019
         B     SNDOUTSP                 8    GETMAIN FAIL               52000019
         B     AAIOERR                  12   I/O ERROR                  52100019
         B     0(R7)                    16   NOT USED                   52200019
         B     0(R7)                    20   NOT USED                   52300019
         B     0(R7)                    24   NOT USED                   52400019
*********************************************************************** 52500019
*  EXECUTED INSTRUCTIONS                                                52600019
*********************************************************************** 52700019
MVCUSR   MVC   TUBGBLKY(0),1(R3)        MOVE USERID FROM CIB            52800019
CLCOP    CLC   0(0,R1),0(R3)                                            52900019
*********************************************************************** 53000019
*   RETURN WITH RETURN CODE 0                                           53100019
*********************************************************************** 53200019
RETURN0  BAL   R10,CKENDUP              GO ENDUP IF NECESSARY           53300019
         SR    R15,R15                                                  53400019
         L     R13,4(R13)                                               53500019
         RETURN (14,12),,RC=(15)                                        53600019
*                                                                       53700019
         EJECT                                                          53800019
*********************************************************************** 53900019
*  MESSAGE CODES                                                        54000019
*********************************************************************** 54100019
         DS    0F                                                       54200019
MUSRACTV DC    X'20',C'201'             ACTIVE USER                     54300019
MINVUSR  DC    X'20',C'202'             USERID INVALID/NOT FOUND        54400019
MINVJOB  DC    X'20',C'211'             JOB NOT IN SYSTEM               54500019
MNOTFND  DC    X'20',C'226'             OP MISSING/INVALID              54600019
MNOJOBS  DC    X'20',C'227'             NO JOBS IN SYSTEM               54700019
MJOBINC  DC    X'20',C'231'             JOB INCOMPLETE                  54800019
MNOUSER  DC    X'20',C'247'             NO CRJE USERS                   54900019
MUSER    DC    X'20',C'248'             INACTIVE CRJE USER              55000019
MJOBCOM  DC    X'20',C'257'             JOB COMPLETE                    55100019
         SPACE 2                                                        55200019
*********************************************************************** 55300019
* TABLES PASSED TO FINDSUBR                                             55400019
*   FORMAT- LENGTH OF ENTIRE ENTRY FOR THIS OPERAND(ONE BYTE)           55500019
*           LENGTH OF OPERAND(ONE BYTE), OPERAND(VARIABLELENGTH)        55600019
*           CHARACTER STRINGS REPEAT- CHARACTER THAT MUST FOLLOW        55700019
*           OPERAND OR X'00' IF MUST BE END OF CIB (ONE BYTE),          55800019
*           SWITCH SETTING (ONE BYTE), BRANCH CODE (ONE BYTE)           55900019
*   LAST ENTRY IN TABLE FOLLOWED BY X'FF'                               56000019
*********************************************************************** 56100019
SHOWCC1  DC    X'0D',X'05',C'USERS',C',',X'90',X'00',X'00',X'80',X'04'  56200019
         DC    X'0C',X'04',C'JOBS',C',',X'30',X'00',X'00',X'20',X'04'   56300019
         DC    X'FF'                                                    56400019
*                                                                       56500019
*  BRANCH TABLE  REFERRED TO BY SHOWCC1                                 56600019
*                                                                       56700019
SHOWBR   B     USRIDVAL                 USERS,USERID OR JOBS,JOBNAME    56800019
         B     READFRST                 SHOW USERS OR SHOW JOBS         56900019
         EJECT                                                          57000019
*********************************************************************** 57100019
*   SUPPLIED MESSAGES                                                   57200019
*********************************************************************** 57300019
MSGIOER  WTO   'IHK270I ACTIVE AREA I/O ERROR',MF=L,ROUTCDE=(2,4,10),  X57400019
               DESC=(4),MCSFLAG=(REG0)                                  57500019
OUTSP    WTO   'IHK219I OUT OF MAIN STORAGE',MF=L,ROUTCDE=(2),         X57600019
               DESC=(4),MCSFLAG=(REG0)                                  57700019
*********************************************************************** 57800019
* CONSTANTS                                                             57900019
*********************************************************************** 58000019
ZEROES   DC    F'0'                                                     58100019
HRMIN    DC    P'60'                                                    58200019
*********************************************************************** 58300019
* WORK AREAS                                                            58400019
*   TUB USED FOR WORKING STORAGE                                        58500019
*********************************************************************** 58600019
SAVEAREA DC    18F'0'                                                   58700019
ADDRTUB  EQU   56                       ADDR OF TUB- REG 9              58800019
         IHKCDSCT  TUB=YES                                              58900019
IHKCC1   CSECT                                                          59000019
LOCTUB   DS    0D                                                       59100019
         DC    F'0'                                                     59200019
         DC    A(USRBUFR)                                               59300019
         DC    320X'00'                                                 59400019
         ORG   LOCTUB+16                                                59500019
LASTCIB  DS    F                                                        59600019
USRLINE  DC    X'08000000'                                              59700019
PASSWORD DS    D                                                        59800019
NXTUVR   DS    CL8                                                      59900019
SHOW     DC    X'04',C'SHOW'                                            60000019
*                                                                       60100019
*  SWITCHES                                                             60200019
*                                                                       60300019
OPRSW    DS    C                        OPERAND SWITCH                  60400019
OPRUSR   EQU   X'80'                    SHOW USERS                      60500019
OPRJOB   EQU   X'20'                                                    60600019
OPUSRJOB EQU   X'10'                    USERID OR JOBNAME SPECIFIED     60700019
OPRENDUP EQU   X'04'                                                    60800019
OPRENDPF EQU   X'FB'                                                    60900019
OPREOD   EQU   X'02'                                                    61000019
OPRERRMS EQU   X'01'                                                    61100019
*                                                                       61200019
SWITCH2  DS    C                                                        61300019
SWTUBTIM EQU   X'04'                                                    61400019
SWTUBTMF EQU   X'FB'                                                    61500019
USERIDL  DC    X'8'                     LENGTH TO INSERT IN MSG         61600019
USERID   DS    CL8                                                      61700019
         ORG   USERIDL                                                  61800019
JOBNAMEL DC    X'08'                                                    61900019
JOBNAME  DS    CL8                                                      62000019
         ORG   LOCTUB+TUBSIZE                                           62100019
         DS    0D                                                       62200019
USRBUFR  DS    CL88                                                     62300019
CIBBASE  DSECT                                                          62400019
         IEZCIB                                                         62500019
         IHKCDSCT CLB=YES,AVT=YES,UVR=YES,RJCT=YES                      62600019
         TUBEQU                                                         62700019
         RAFKNBX TYPE=DSECT                                             62800019
         END                                                            62900019
