CC2      TITLE 'IHKCC2 - CENTRAL COMMAND PROCESSOR'                     00100019
IHKCC2   CSECT                                                          00200019
*A329300-330500,567500                                           A36804 00220020
*C109000                                                         A36804 00240020
*D330000                                                         A36804 00260020
* D 329900-330200, C 109000                                     OS63559 00280028
*********************************************************************** 00300019
*STATUS                                                                 00400019
*   CHANGE LEVEL 0                                                      00500019
*FUNCTION                                                               00600019
*   IHKCC2 CKECKS THE VERB AND THE COMMAND OPERANDS.  IF ANY OPERAND  * 00700019
*   IS INVALID, AN ERROR MESSAGE IS SENT TO THE CENTRAL CONSOLE AND   * 00800019
*   RETURN IS MADE TO THE CALLING ROUTINE.                              00900019
*   THE FOLLOWING OPERANDS ARE VALID FOR A SHOW COMMAND.                01000019
*   1. BRDCST - DISPLAYS ON CONSOLE ALL BROADCAST MESSAGES.             01100019
*   2. LERB OR LERB,LINEADDRESS- LISTS CURRENT VALUES SINCE LAST        01200019
*   CRJE STARTUP OF ALL LINE ERROR ACCUMULATORS  FOR ALL LINES BEING    01300019
*   USED BY CRJE OR SPECIFIED LINE.  LINE MUST BE OPEN, AND, IF PART    01400019
*   OF A LINE GROUP, MUST BE IN USE.  THE LIST INDICATES FOR EACH       01500019
*   LINE, THE ERROR-COUNTER VALUES, AND THE TRANSMISSION COUNT.         01600019
*   THE FOLLOWING OPERANDS ARE VALID FOR A MODIFY COMMAND.              01700019
*   1. A=XXX OR (XXX,XXX,...)- ACTIVATE LINE(S)                         01800019
*   1. D=XXX OR (XXX,XXX,...)- DEACTIVATE LINE(S)                       01900019
*   CHECKS FOR VALID LINEADDRESS (LENGTH OF 3) AND FINDS CLB.           02000019
*   CHECKS FOR MODIFY IN PROCESS.  WHEN FINISHED PROCESSING FOR EACH    02100019
*   LINE, STORES CONSOLE ID AND SETS MODIFY BIT IN CLB.                 02200019
*   DEACTIVATE-  SETS CLBSTOPN.  IF NOT SIMULATED LINE, ISSUES HALTIO   02300019
*   FOR READ.                                                           02400019
*   ACTIVATE- CHECKS FOR LINE OPEN AND POSTS.                           02500019
*ENTRY POINTS                                                           02600019
*   IHKCC2 IS THE ONLY ENTRY POINT.                                     02700019
*   SEE INPUT FOR ASSOCIATED PARAMETER LIST.                            02800019
*INPUT                                                                  02900019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING       03000019
*   THE ADDRESSES OF THE AVT AND THE CIB.                               03100019
*OUTPUT                                                                 03200019
*   N/A                                                                 03300019
*EXTERNAL REFERENCES                                                    03400019
*        IHKAFI - TO MANIPULATE GLOBAL FILES                            03500019
*        IHKMSG - ENTRY POINTS:  IHKMSG AND IHKMSG02                    03600019
*        TO SEND  MESSAGES TO THE CENTRAL CONSOLE.                      03700019
*EXITS, NORMAL                                                          03800019
*        RETURN TO CALLER WITH ZERO IN REGISTER 15                      03900019
*EXITS, ERROR                                                           04000019
*        ERROR MESSAGE IS SENT TO CENTRAL CONSOLE                       04100019
*        RETURN IS MADE TO CALLER WITH ZERO IN REGISTER 15              04200019
*TABLES/WORK AREAS                                                      04300019
*   SAVEAREA                                                            04400019
*   TUB - CONTAINED IN MODULE.                                          04500019
*   TUBUFFAD - ADDRESS OF USER BUFFER                                   04600019
*   AFIO CONTROL INFORMATION                                            04700019
*   USER BUFFER                                                         04800019
*   CIB - CONTAINS COMMAND AND OPERANDS                                 04900019
*   AVT                                                                 05000019
*ATTRIBUTES                                                             05100019
*   NON-RESIDENT                                                        05200019
*   SERIALLY REUSABLE                                                   05300019
*********************************************************************** 05400019
         EJECT                                                          05500019
*********************************************************************** 05600019
*   REGISTER EQUATES                                                    05700019
*********************************************************************** 05800019
R0       EQU   0                                                        05900019
R1       EQU   1                                                        06000019
R2       EQU   2                                                        06100019
R3       EQU   3                        WORK REGISTER                   06200019
R4       EQU   4                        WORK REGISTER                   06300019
RCLB     EQU   5                        CLB BASE                        06400019
R6       EQU   6                        USED FOR CLB LIST               06500019
R7       EQU   7                        INTERNAL LINKAGE                06600019
R8       EQU   8                        WORK REGISTER                   06700019
RTUB     EQU   9                        TUB BASE                        06800019
RCIB     EQU   10                       CIB BASE                        06900019
RAVT     EQU   11                       AVT BASE                        07000019
RBASE    EQU   12                       IHKCC2 BASE                     07100019
R13      EQU   13                                                       07200019
R14      EQU   14                                                       07300019
R15      EQU   15                                                       07400019
*********************************************************************** 07500019
*   OTHER EQUATES                                                       07600019
*********************************************************************** 07700019
SHOWVRB  EQU   X'88'                    SHOW COMMAND VERB IN CIB        07800019
MDFYVRB  EQU   X'44'                    MODIFY COMMAND VERB IN CIB      07900019
DEBNMEXT EQU   X'10'                    DEB OFFSET- NUMBER OF EXTENTS   08000019
DEBUCBAD EQU   32                       OFFSET IN DEB TO UCB ADDRESS    08100019
IOBUCBX  EQU   32                       OFFSET TO UCB POINTER IN IOB    08200019
DCBOPEN  EQU   X'10'                    OPEN FLAG IN DCB FLAG           08300019
READBIT  EQU   X'01'                                                    08400019
POST48   EQU   X'48'                                                    08500019
RESETFLG EQU   1                                                        08600019
HALTIO   EQU   33                                                       08700019
COMMA    EQU   C','                                                     08800019
LPAREN   EQU   C'('                                                     08900019
RPAREN   EQU   C')'                                                     09000019
HEX40    EQU   X'40'                                                    09100019
HEXFF    EQU   X'FF'                                                    09200019
THREE    EQU   3                                                        09300019
FOUR     EQU   4                                                        09400019
HEXF0    EQU   X'F0'                                                    09500019
X0A      EQU   10                       MAX INSERT SIZE FOR MSGS        09600019
X00      EQU   0                                                        09700019
HIBIT    EQU   X'80'                                                    09800019
         EJECT                                                          09900019
*********************************************************************** 10000019
*   SET UP BASE REGISTERS, SAVEAREA                                     10100019
*********************************************************************** 10200019
         USING IHKCC2,RBASE                                             10300019
         USING AVTDSECT,RAVT                                            10400019
         USING TUBDSECT,RTUB                                            10500019
         USING CIBBASE,RCIB                                             10600019
         USING CLBDSECT,RCLB                                            10700019
*                                                                       10800019
         SAVE  (14,12),,CC273100                                OS63559 10900028
         LR    RBASE,R15                SET UP BASE ADDRESS             11000019
         L     RAVT,0(R1)                                               11100019
         L     RCIB,4(R1)               AVT, CIB ADDRESSES PASSED       11200019
         ST    R13,SAVEAREA+4           SAVE CALLERS SAVEAREA           11300019
         LA    R1,SAVEAREA                                              11400019
         ST    R1,8(R13)                SAVE SAVEAREA IN CALLERS        11500019
         LR    R13,R1                                                   11600019
*                                                                       11700019
         LH    R4,CIBDATLN              COMPUTE END ADDR OF CIB         11800019
         LA    R15,CIBDATA-1                                            11900019
         AR    R15,R4                                                   12000019
         ST    R15,LASTCIB              ADDR OF LAST BYTE IN CIB        12100019
         LA    RTUB,LOCTUB              SET UP TUB BASE                 12200019
         MVI   OPRSW,X00                SET SWITCH TO ZERO              12300019
*                                                                       12400019
* CHECK FOR SHOW OR MODIFY                                              12500019
*                                                                       12600019
CKVERB   CLI   CIBVERB,SHOWVRB                                          12700019
         BE    CKSHOWOP                 B= SHOW                         12800019
         CLI   CIBVERB,MDFYVRB                                          12900019
         BE    CKMODOP                  B= MODIFY                       13000019
         B     RETURN0                                                  13100019
*********************************************************************** 13200019
*                                                                       13300019
*  SHOW COMMAND-  LOOK FOR LERB OR BRDCST                               13400019
*                                                                       13500019
*********************************************************************** 13600019
CKSHOWOP LA    R1,SHOWCMDL                                              13700019
         ST    R1,CMDPTER               SHOW COMMAND FOR INSERT         13800019
         LA    R1,SHOWCC2               OPERAND TABLE FOR SHOW          13900019
         BAL   R14,FINDSUBR                                             14000019
         B     SHOWBR(R15)              BRANCH TO ROUTINE TO HANDLE OP  14100019
*********************************************************************** 14200019
*                                                                       14300019
*  SHOW LERB- ALL LINES                                                 14400019
*                                                                       14500019
*********************************************************************** 14600019
SHWLERB  OI    OPRSW,OPRLERB            SET SWITCH- LERB FOR ALL        14700019
*********************************************************************** 14800019
*                                                                       14900019
*  SHOW LERB FOR ALL OR SPECIFIED, OR FIND SPECIFIED CLB FOR MODIFY     15000019
*                                                                       15100019
*********************************************************************** 15200019
FINDLINA L     R6,IHKYYCLB              FIRST CLB IN LIST               15300019
GETNXTCL L     RCLB,0(R6)               CLB ADDRESS                     15400019
         TM    OPRSW,OPRLERB            IS THIS SHOW LERB FOR ALL       15500019
         BO    GETDECB                  BR= YES                         15600019
         CLC   CLBLINE,1(R3)            IS THIS THE SPECIFIED LINEADDR  15700019
         BNE   FINDLINB                 BR= NO                          15800019
GETDECB  L     R15,CLBLDECB             SHOW LERB- DECB ADDRESS         15900019
         USING DECSDECB,R15                                             16000019
         L     R1,DECDCBAD              FIND RELATIVE LINE NUMBER       16100019
         SR    R4,R4                                                    16200019
         IC    R4,DECRLN                RELATIVE LINE NUMBER            16300019
         USING IHADCB,R1                                                16400019
         TM    OPRSW,OPRMOD             IS THIS MODIFY                  16500019
         BM    MODFYLIN                 BR= YES                         16600019
         TM    DCBOFLGS,DCBOPEN         IS DCB OPEN                     16700019
         BO    PRTLERB                  BR= YES                         16800019
         TM    OPRSW,OPRLERBL           NO= IS LINEADDRESS SPECIFIED    16900019
         BO    NOTOPEN                  BR= YES, SEND MSG NOT OPEN      17000019
         B     FINDLINB                 GO FIND NEXT LINE               17100019
*********************************************************************** 17200019
*                                                                       17300019
*   SET UP TO SHOW LERB                                                 17400019
*                                                                       17500019
*********************************************************************** 17600019
PRTLERB  L     R15,DCBDEBAD             DEB ADDRESS                     17700019
         SR    R14,R14                                                  17800019
         IC    R14,DEBNMEXT(R15)        NUMBER OF EXTANTS               17900019
         CR    R4,R14                                                   18000019
         BH    FINDLINB                 BR= LINE NOT IN USE, IGNORE     18100019
         LR    R0,R4                    RELATIVE LINE NUMBER            18200019
         IC    R15,CIBCONID             INSERT CONSOLE ID               18220019
         SLL   R15,24                                                   18240019
         LA    R1,0(R1)                 DCB ADDRESS                     18260019
         OR    R1,R15                   CONSOLE ID IN HIGH ORDER BYTE   18280019
         L     R15,IHKYYLPT             LERPRT  CLEAR = NO              18300019
         BALR  R14,R15                  GO SHOW LERB                    18400019
*********************************************************************** 18500019
*                                                                       18600019
*  CHECK FOR LINEADDRESS SPECIFIED- SHOW LERB                           18700019
*                                                                       18800019
*********************************************************************** 18900019
LERPRTRT TM    OPRSW,OPRLERBL           TEST FOR LINEADDRESS SPECIFIED  19000019
         BO    RETURN0                  BR= CMD DONE                    19100019
FINDLINB TM    0(R6),HIBIT              ANY  MORE CLB                   19200019
         BZ    NEXTCLB                  BR= YES                         19300019
         TM    OPRSW,OPRLERB            NO= IF LINEADD SPECIFIED,ERROR  19400019
         BO    RETURN0                                                  19500019
         B     INVLINAD                 NOT FOUND- MODIFY OR SHOW LERB  19600019
NEXTCLB  LA    R6,FOUR(R6)                                              19700019
         B     GETNXTCL                                                 19800019
         EJECT                                                          19900019
*********************************************************************** 20000019
*                                                                       20100019
*  SHOW LERB,LINADDRESS                                                 20200019
*                                                                       20300019
*********************************************************************** 20400019
SHWLERBL OI    OPRSW,OPRLERBL           SET SWITCH- LERB,LINEADDRESS    20500019
         LA    R7,RETURN0               MSG ROUTINE- RETURN OF ZERO     20600019
         L     R15,LASTCIB              LAST BYTE IN CIB                20700019
*********************************************************************** 20800019
*                                                                       20900019
*  CHECK VALID LINEADDRESS FOR BOTH SHOW LERB AND MODIFY                21000019
*   IF VALID, GO FIND CLB                                               21100019
*                                                                       21200019
*********************************************************************** 21300019
CKVALLIN SR    R15,R3                   COMPUTE LENGTH OF OP            21400019
         STC   R15,0(R3)                LENGTH OF OP                    21500019
         LA    R1,THREE                                                 21600019
         ST    R3,TUBPARM4              ADDRESS OF OPERAND              21700019
         MVI   TUBPARM4,HIBIT                                           21800019
         CR    R1,R15                   MUST BE 3                       21900019
         BNE   INVLINAD                 BR= LONGER THAN THREE           22000019
         B     FINDLINA                 BR= VALID, GO FIND CLB          22100019
*********************************************************************** 22200019
*                                                                       22300019
*  SHOW BRDCST                                                          22400019
*                                                                       22500019
*********************************************************************** 22600019
SHWBRD   LA    R1,CIBCONID              CONSOLE ID                      22700019
         ST    R1,TUBPARM2                                              22800019
         MVI   TUBPARM2,HIBIT                                           22900019
         L     R15,IHKYMSG3                                             23000019
         BAL   R7,SNDBRD                GO TO IHKMSG- SEND BRDCST       23100019
         B     RETURN0                                                  23200019
*********************************************************************** 23300019
*                                                                       23400019
*  MODIFY COMMAND- CHECK FOR A= OR D=                                   23500019
*                                                                       23600019
*********************************************************************** 23700019
CKMODOP  LA    R1,MODCMDL                                               23800019
         ST    R1,CMDPTER               MODIFY COMMAND FOR INSERT       23900019
         LA    R1,MODCC2                OPERAND TABLE FOR MODIFY        24000019
         BAL   R14,FINDSUBR             GO CHECK OPERAND                24100019
         B     MODBR(R15)               GO TO ROUTINE                   24200019
*********************************************************************** 24300019
*                                                                       24400019
*  MODIFY A=                                                            24500019
*                                                                       24600019
*********************************************************************** 24700019
MODACT   OI    OPRSW,OPRMODA            SET SWITCH FOR ACTIVATE         24800019
         B     MFINDLIN                 GO CHECK FOR PAREN              24900019
         EJECT                                                          25000019
*********************************************************************** 25100019
*                                                                       25200019
*  MODIFY D=                                                            25300019
*                                                                       25400019
*********************************************************************** 25500019
MODDEACT OI    OPRSW,OPRMODD            SET SWITCH FOR DEACTIVATE       25600019
*********************************************************************** 25700019
*                                                                       25800019
*  MODIFY COMMAND- FIND EACH LINEADDRESS, CK VALIDITY, FIND CLB         25900019
*                                                                       26000019
*********************************************************************** 26100019
MFINDLIN CLI   1(R3),LPAREN             IS THERE MORE THAN 1            26200019
         BE    CKRPAREN                 BR=LEFT PAREN, CHECK FOR )      26300019
         OI    OPRSW,OPRNOPRN           NO PAREN- ONE LINE ONLY         26400019
         B     MFINDLN2                                                 26500019
CKRPAREN LA    R3,1(R3)                 POINT TO FIRST CHAR IN OP       26600019
         L     R15,LASTCIB              CHECK FOR END PAREN             26700019
         CLI   0(R15),RPAREN                                            26800019
         BNE   INVPAREN                 BR= NO RIGHT PAREN              26900019
         BCTR  R15,0                    CHANGE POINTER TO LAST BYTE     27000019
         ST    R15,LASTCIB              POINT TO LAST CHAR OF LAST LINE 27100019
MFINDLN2 LR    R15,R3                                                   27200019
MNXTCHAR LA    R15,1(R15)               FIND END OF LINEADDRESS         27300019
         C     R15,LASTCIB                                              27400019
         BNL   ENDFND                   BR= END OF CIB                  27500019
         CLI   0(R15),COMMA             NOT END OF CIB- IS IT COMMA     27600019
         BNE   MNXTCHAR                 BR= NO                          27700019
         BCTR  R15,0                                                    27800019
         TM    OPRSW,OPRNOPRN           ARE THERE PAREN                 27900019
         BO    INVPAREN                 BR= NO, BUT COMMA FOUND         28000019
         B     COMFND                   BR= COMMA FOUND                 28100019
*********************************************************************** 28200019
*                                                                       28300019
*   END OF CIB REACHED                                                  28400019
*                                                                       28500019
*********************************************************************** 28600019
ENDFND   OI    OPRSW,OPREND             NO MORE LINES SPECIFIED         28700019
*                                                                       28800019
*  END OF CIB REACHED OR COMMA FOUND                                    28900019
*                                                                       29000019
COMFND   LA    R7,MNXTLIN                                               29100019
         B     CKVALLIN                 GO CHECK VALID LINEADDRESS      29200019
         EJECT                                                          29300019
*********************************************************************** 29400019
*                                                                       29500019
*   CLB FOR LINE FOUND- MODIFY                                          29600019
*                                                                       29700019
*********************************************************************** 29800019
MODFYLIN TM    CLBSTATS,CLBMODYN        IS MODIFY IN PROCESS            29900019
         BO    MDFYON                   BR= YES, SEND MSG               30000019
         TM    OPRSW,OPRMODA            IS THIS MODIFY A=               30100019
         BO    SETACTV                  BR= YES                         30200019
         TM    CLBSTATS,CLBACTVN        NO- IS IT ACTIVE                30300019
         BO    DEACTV                   BR= YES, GO DEACTIVATE          30400019
         LA    R1,MNOTACTV              SEND LINE NOT ACTIVE MSG        30500019
         B     SENDMSG                                                  30600019
*********************************************************************** 30700019
*   LINE ACTIVE- DEACTIVATE                                             30800019
*********************************************************************** 30900019
DEACTV   OI    CLBREQST,CLBSTOPN        IS ACTIVE- SET STOP BIT         31000019
         CLI   CLBDEVTP,CLBDUMMY                                        31100019
         BE    STRCONID                 BR= SIMULATED LINE              31200019
         TM    DECTYPE+1,READBIT        IS IT READ                      31300019
         BZ    STRCONID                 BR= NO                          31400019
         TM    DECSDECB,HEX40                                           31500019
         BO    STRCONID                                                 31600019
         DROP  R15                                                      31680019
         SR    R15,R15                  CLEAR REGISTER FOR INSERT       31760019
         IC    R15,DCBEIOBX             OFFSET INTO IOB                 31840019
         MR    R14,R4                   GET OFFSET TO IOB               31920019
         A     R15,DCBIOBAD             ADD TO ADDRESS OF IOB BASE      32000019
         OI    1(R15),RESETFLG          SET RESETPL FLAG IN IOB         32080019
         SR    R8,R8                    CLEAR REGISTER FOR INSERT       32160019
         IC    R8,IOBUCBX(R15)          OFFSET TO UCB ADDRESS           32240019
         SLL   R8,2                     MULTIPLY BY FOUR                32400019
         L     R14,DCBDEBAD             ADDRESS OF DEB                  32500019
         L     R1,DEBUCBAD(R14,R8)      ADDRESS OF UCB FOR HALTIO       32600019
         SPACE                                                          32700019
         SVC   HALTIO                   ISSUE HALTIO                    32800019
         SPACE                                                          32900019
         LTR   R15,R15                  STOPPED SUCCESSFULLY     A36804 32930020
         BZ    STRCONID                 IF SO, KEEP GOING        A36804 32960020
         B     CKSTOP                   NO, BETTER POST HIM OUT  A36804 33050020
*********************************************************************** 33100019
*                                                                       33200019
*  MODIFY A=,  SET ACTIVE                                               33300019
*                                                                       33400019
*********************************************************************** 33500019
SETACTV  TM    CLBSTATS,CLBACTVN        IS LINE ALREADY ACTIVE          33600019
         BZ    CKSTOP                   BR= NO, GO ACTIVATE             33700019
         LA    R1,MACTV                 YES- SEND LINE ALREADY ACTIVE   33800019
         B     SENDMSG                                                  33900019
CKSTOP   TM    CLBSAECB+1,HEXFF         IS LINE OPEN                    34000019
         BO    NOTOPEN                  BR=NO                           34100019
         L     R1,CLBLDECB                                              34200019
         LA    R1,0(R1)                 SET HIGH ORDER BYTE TO ZERO     34250021
         POST  (R1)                                                     34300019
*********************************************************************** 34400019
*                                                                       34500019
*  PICK UP NEXT LINEADDRESS, IF ANY, IN MODIFY COMMAND                  34600019
*                                                                       34700019
*********************************************************************** 34800019
STRCONID MVC   CLBMCSCD(1),CIBCONID     SAVE CONSOLE ID FOR THIS MODIFY 34900019
         OI    CLBSTATS,CLBMODYN        INDICATE MODIFY IN PROGRESS     35000019
         TM    OPRSW,OPRMODA            TEST FOR ACTIVATE               35100019
         BZ    MNXTLIN                  BR= MODIFY D=                   35200019
         LA    R1,MMODACT               SEND ACTIVATE BEING PROC        35300019
         B     SENDMSG                                                  35400019
MNXTLIN  TM    OPRSW,OPREND             WAS LAST IN CIB FOUND           35500019
         BO    RETURN0                  BR= YES                         35600019
         SR    R15,R15                                                  35700019
         IC    R15,0(R3)                LENGTH OF OP                    35800019
         AR    R3,R15                                                   35900019
         LA    R3,1(R3)                 NOW POINTS TO NEXT LINE         36000019
         B     MFINDLN2                                                 36100019
         EJECT                                                          36200019
*********************************************************************** 36300019
*   MESSAGE ROUTINES                                                    36400019
*********************************************************************** 36500019
*                                                                       36600019
*  LINEADDRESS  INVALID/NOT FOUND                                       36700019
*                                                                       36800019
INVLINAD LA    R1,MINVLINE                                              36900019
         B     SENDMSG                                                  37000019
*                                                                       37100019
*  LINEADDRESS FOUND BUT NOT OPEN                                       37200019
*                                                                       37300019
NOTOPEN  LA    R1,MNOTOPN                                               37400019
         B     SENDMSG                                                  37500019
*                                                                       37600019
*   MODIFY IN PROCESS                                                   37700019
*                                                                       37800019
MDFYON   LA    R1,MMDFYN                                                37900019
         B     SENDMSG                                                  38000019
*                                                                       38100019
*   OPERAND INVALID/NOT FOUND                                           38200019
*                                                                       38300019
OPNFND   LA    R1,MNOTFND                                               38400019
INSDATA  CLI   CIBDATLN+1,X0A           TEST FOR INSERT TOO LONG        38500019
         BL    INSCMDOP                                                 38600019
         MVI   CIBDATLN+1,X0A           TOO LONG- INSERT 10             38700019
INSCMDOP LA    R14,CIBDATLN+1                                           38800019
         MVC   TUBPARM4,CMDPTER                                         38900019
INS2PARM ST    R14,TUBPARM5             INSERT TWO PARAMETERS           39000019
         MVI   TUBPARM5,HIBIT                                           39100019
         B     SENDMSG0                                                 39200019
*                                                                       39300019
*   DELIMITER MISSING (PAREN)                                           39400019
*                                                                       39500019
INVPAREN LA    R1,MINVPARN                                              39600019
         B     INSDATA                                                  39700019
*********************************************************************** 39800019
*   SEND SUPPLIED MESSAGE                                               39900019
*********************************************************************** 40000019
SNDOUTSP LA    R2,OUTSP                 OUT OF MAIN STORAGE             40100019
         B     INSNOPRN                                                 40200019
AAIOERR  LA    R2,MSGIOER               ACTIVE AREA I/O ERROR           40300019
INSNOPRN OI    OPRSW,OPRERRMS           SET SWITCH- SUPPLIED MSG        40400019
         LH    R15,0(R2)                                                40500019
         L     R1,TUBUFFAD                                              40600019
         EX    R15,MVCMSG               MOVE TO USER BUFFER             40700019
         B     SENDMSG0                                                 40800019
MVCMSG   MVC   0(0,R1),0(R2)                                            40900019
         EJECT                                                          41000019
*********************************************************************** 41100019
*                                                                       41200019
*  SUBROUTINE TO SEARCH FOR SPECIFIED SET OF CHARACTERS                 41300019
*        CHECKS FOR END OF CIB                                          41400019
*        AT ENTRY REGISTER ONE POINTS TO TABLE DEFINING VALID CHARACTER 41500019
*        STRINGS, AND CHARACTER (OR END OF CIB) THAT MUST FOLLOW        41600019
*        RETURNS WITH REGISTER 15 CONTAINING BRANCH CODE (FROM TABLE)   41700019
*        AND REGISTER 3 POINTS AT CHAR AFTER OP IN CIB (IF ANY)         41800019
*                                                                       41900019
*********************************************************************** 42000019
FINDSUBR SR    R15,R15                                                  42100019
GETLNG   IC    R15,0(R1)                LENGTH FROM TABLE-REG 15        42200019
         LA    R1,1(R1)                 REG1 POINTS AT OP IN TABLE      42300019
         CH    R15,CIBDATLN                                             42400019
         BH    NXTABLE                  BR= OP IN CIB SHORTER           42500019
         LA    R3,CIBDATA               REG3 POINTS AT OP IN CIB        42600019
         BCTR  R15,0                                                    42700019
         EX    R15,CLCOP                COMPARE OPERANDS                42800019
         LA    R15,1(R15)               RESTORE TO OP LENGTH IN TABLE   42900019
         BNE   NXTABLE                  BR= NOT OP IN TABLE             43000019
         AR    R1,R15                   OP EQUAL-CK NEXT CHAR           43100019
         CLI   0(R1),X00                                                43200019
         BE    CKCIBEND                 BR= MUST BE END OF CIB          43300019
         CH    R15,CIBDATLN             MUST BE ANOTHER CHAR            43400019
         BNL   NXTABLE1                 BR= NOT ANOTHER IN CIB          43500019
         AR    R3,R15                                                   43600019
         CLC   0(1,R3),0(R1)            IS IT CHAR IN TABLE             43700019
         BNE   NXTABLE1                 BR= NOT THIS OPERAND            43800019
*                                                                       43900019
*   OPERAND FOUND                                                       44000019
*                                                                       44100019
GETBRNCH LA    R1,1(R1)                 IS CHAR/ GET BRANCH FROM TABLE  44200019
         IC    R15,0(R1)                                                44300019
         BR    R14                      RETURN                          44400019
*                                                                       44500019
*  POINT TO NEXT ENTRY IN TABLE                                         44600019
*                                                                       44700019
NXTABLE  AR    R1,R15                                                   44800019
NXTABLE1 LA    R1,2(R1)                 NOW POINTS AT NEXT              44900019
         TM    0(R1),HEXFF                                              45000019
         BO    OPNFND                   BR= NO MORE IN TABLE            45100019
         B     GETLNG                                                   45200019
*                                                                       45300019
CKCIBEND CH    R15,CIBDATLN             HAS TO BE END OF OP             45400019
         BE    GETBRNCH                 BR= IS END                      45500019
         B     NXTABLE1                                                 45600019
         EJECT                                                          45700019
*********************************************************************** 45800019
*   SUBROUTINE TO SEND MESSAGES                                         45900019
*   SENDMSG0- SETS RETURN TO ZERO                                       46000019
*   SENDMSG- AT LEAST ONE INSERTION                                     46100019
*   SENDMSGA- NO INSERTIONS                                             46200019
*********************************************************************** 46300019
SENDMSG0 LA    R7,RETURN0                                               46400019
SENDMSG  ST    R1,TUBPARM3              PARAM 3 = ADDR OF MSG           46500019
SENDMSGA LA    R1,ZEROES                                                46600019
         ST    R1,TUBPARM2              PARAM 2 = ADDR OF ZERO          46700019
         MVC   0(1,R1),CIBCONID         HIGH ORDER BIT= CONSOLE ID      46800019
         TM    OPRSW,OPRERRMS           IS THIS SEND SUPPLIED MSG       46900019
         BZ    ENTRMSG                  BR=NO                           47000019
         MVI   TUBPARM3,HIBIT                                           47100019
         L     R15,IHKYMSG2                                             47200019
         B     SNDBRD                                                   47300019
ENTRMSG  L     R15,IHKYYMSG                                             47400019
SNDBRD   ST    RTUB,TUBPARM1            PARAM 1 = ADDR OF TUB           47500019
         LA    R1,TUBPARM1                                              47600019
         BALR  R14,R15                                                  47700019
         B     MSGRTN(R15)                                              47800019
MSGRTN   B     0(R7)                    0    MSG SENT                   47900019
         B     0(R7)                    4    TP LINE ERROR (NOT APPLIC) 48000019
         B     SNDOUTSP                 8    GETMAIN FAIL               48100019
         B     AAIOERR                  12   AA I/O ERROR               48200019
         B     0(R7)                    16   NOT USED                   48300019
         B     0(R7)                    20  NOT USED                    48400019
         B     0(R7)                    24  NOT USED                    48500019
*********************************************************************** 48600019
*   RETURN TO CALLER                                                    48700019
*********************************************************************** 48800019
*                                                                       48900019
RETURN0  SR    R15,R15                                                  49000019
         L     R13,4(R13)                                               49100019
         RETURN (14,12),,RC=(15)                                        49200019
*********************************************************************** 49300019
*                                                                       49400019
*  EXECUTED INSTRUCTIONS                                                49500019
*                                                                       49600019
*********************************************************************** 49700019
CLRBUFR  MVC   1(0,R1),0(R1)                                            49800019
CLCOP    CLC   0(0,R1),0(R3)                                            49900019
         EJECT                                                          50000019
*********************************************************************** 50100019
*   FORMAT- LENGTH OF OPERAND(ONE BYTE), OPERAND (VARIABLE LENGTH),     50200019
*   CHARACTER THAT MUST FOLLOW OPERAND OR X'00' TO INDICATE MUST        50300019
*   BE END OF CIB (ONE BYTE), BRANCH CODE(ONE BYTE)                     50400019
*********************************************************************** 50500019
*                                                                       50600019
*  TABLES PASSED TO FINDSUBR                                            50700019
*                                                                       50800019
SHOWCC2  DC    X'04',C'LERB',X'0',X'00'                                 50900019
         DC    X'04',C'LERB',C',',X'04'                                 51000019
         DC    X'06',C'BRDCST',X'0',X'08'                               51100019
         DC    X'FF'                                                    51200019
MODCC2   DC    X'01',C'A',C'=',X'00'                                    51300019
         DC    X'01',C'D',C'=',X'04'                                    51400019
         DC    X'FF'                                                    51500019
*                                                                       51600019
*  BRANCH TABLES                                                        51700019
*                                                                       51800019
SHOWBR   B     SHWLERB                                                  51900019
         B     SHWLERBL                                                 52000019
         B     SHWBRD                                                   52100019
MODBR    B     MODACT                                                   52200019
         B     MODDEACT                                                 52300019
         EJECT                                                          52400019
*********************************************************************** 52500019
*                                                                       52600019
*  MESSAGE CODES                                                        52700019
*                                                                       52800019
*********************************************************************** 52900019
         DS    0F                                                       53000019
MINVLINE DC    X'20',C'210'             LINEADDRESS INVALID/NOT FOUND   53100019
MNOTFND  DC    X'20',C'226'             OPERAND INVALID/NOT FOUND       53200019
MMODACT  DC    X'20',C'243'             LINE BEING ACTIVATED            53300019
MNOTACTV DC    X'20',C'251'             LINE NOT ACTIVE                 53400019
MINVPARN DC    X'20',C'254'             INVALID DELIMITER               53500019
MMDFYN   DC    X'20',C'258'             MODIFY IN PROCESS               53600019
MNOTOPN  DC    X'20',C'264'             LINE NOT OPEN                   53700019
MACTV    DC    X'20',C'265'             LINE ALREADY ACTIVE             53800019
MUNSUCC  DC    X'20',C'271'             RESETPL UNSUCCESSFUL            53900019
*********************************************************************** 54000019
*   SUPPLIED MESSAGES                                                   54100019
*********************************************************************** 54200019
MSGIOER  WTO   'IHK270I ACTIVE AREA I/O ERROR',MF=L,ROUTCDE=(2,4,10),  X54300019
               DESC=(4),MCSFLAG=(REG0)                                  54400019
OUTSP    WTO   'IHK219I OUT OF MAIN STORAGE',MF=L,ROUTCDE=(2),         X54500019
               DESC=(4),MCSFLAG=(REG0)                                  54600019
         EJECT                                                          54700019
*********************************************************************** 54800019
*                                                                       54900019
*   WORK/SAVE AREAS- TUB USED FOR WORKING STORAGE                       55000019
*                                                                       55100019
*********************************************************************** 55200019
SAVEAREA DC    18F'0'                                                   55300019
         IHKCDSCT TUB=YES                                               55400019
IHKCC2   CSECT                                                          55500019
LOCTUB   DS    0D                                                       55600019
         DC    F'0'                                                     55700019
         DC    A(USRBUFR)                                               55800019
         DC    320X'00'                                                 55900019
         ORG   LOCTUB+8                                                 56000019
CMDPTER  DS    F                                                        56100019
LASTCIB  DS    F                                                        56200019
ZEROES   DC    F'0'                                                     56300019
SHOWCMDL DC    X'04'                                                    56400019
SHOWCMD  DC    C'SHOW'                                                  56500019
MODCMDL  DC    X'06'                                                    56600019
MODFYCMD DC    C'MODIFY'                                                56700019
R002     DC    H'4'                     HALFWORD CONSTANT        A36804 56750020
OPRSW    DS    C                                                        56800019
OPRLERB  EQU   X'80'                    SHOW LERB                       56900019
OPRLERBL EQU   X'40'                    SHOW LERB,LINENUMBER,,          57000019
OPRMODA  EQU   X'20'                    MODIFY A=                       57100019
OPRMODD  EQU   X'10'                    MODIFY D=                       57200019
OPREND   EQU   X'08'                                                    57300019
OPRNOPRN EQU   X'04'                                                    57400019
OPRERRMS EQU   X'02'                                                    57500019
OPRMOD   EQU   X'30'                    MODIFY- A OR D                  57600019
         ORG   LOCTUB+TUBSIZE                                           57700019
USRBUFR  DS    CL88                                                     57800019
         DCBD  DSORG=(CX),DEVD=(DA)                                     57900019
         IECTDECB                                                       58000019
CIBBASE  DSECT                                                          58100019
         IEZCIB                                                         58200019
         IHKCDSCT          AVT=YES,CLB=YES                              58300019
         END                                                            58400019
