CC4      TITLE 'IHKCC4 - CENTRAL COMMAND PROCESSOR'                     00100019
IHKCC4   CSECT                                                          00200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00300019
*STATUS                                                               * 00400019
*   CHANGE LEVEL 0                                                    * 00500019
*FUNCTION                                                             * 00600019
*   IHKCC4 CHECKS THE VERB AND THE COMMAND OPERANDS.  IF ANY OPERAND  * 00700019
*   IS INVALID, AN ERROR MESSAGE IS SENT TO THE CENTRAL CONSOLE AND   * 00800019
*   RETURN IS MADE TO THE CALLING ROUTINE.  ONCE THE COMMAND IS       * 00900019
*   VALIDATED THE FOLLOWING PROCESSING IS PERFORMED:                  * 01000019
*   MSG D=USERID - THE USER MESSAGE FILE IS ACCESSED AND ALL DELAYED  * 01100019
*                  MESSAGES FOR THE SPECIFIED USER ARE DELETED.  THE    01200019
*                  DELAYED MESSAGES AVAILABLE SWITCH IN THE UVR IS      01300019
*                  TURNED OFF AND A MESSAGE IS SENT TO THE CONSOLE TO   01400019
*                  INDICATE THAT THE MESSAGES WERE DELETED.             01500019
*   SHOW MSGS,USERID - THE USER MESSAGE FILE IS ACCESSED AND IF THERE   01600019
*                  ARE ANY MESSAGES FOR THE SPECIFIED USER, A HEADER    01700019
*                  MESSAGE IS SENT TO THE CONSOLE FOLLOWED BY THE       01800019
*                  DELAYED MESSAGES QUEUED.  THE USERID IS PLACED       01900019
*                  IN THE FIRST EIGHT BYTES PRECEDING EACH DELAYED      02000019
*                  MESSAGE.  WHEN ALL MESSAGES HAVE BEEN WRITTEN, A     02100019
*                  TRAILER MESSAGE IS SENT TO INDICATE COMPLETION.  IF  02200019
*                  THERE WERE NO MESSAGES QUEUED, A MESSAGE IS SENT TO  02300019
*                  THE CONSOLE.                                         02400019
*   SHOW MSGS ---- THE USER MESSAGE FILE IS ACCESSED AND ALL MESSAGES * 02500019
*                  ARE WRITTEN ON THE CENTRAL CONSOLE AS IN THE SHOW  * 02600019
*                  MSGS,USERID COMMAND.                               * 02700019
*ENTRY POINTS                                                         * 02800019
*        IHKCC4 IS THE ONLY ENTRY POINT                               * 02900019
*        SEE INPUT FOR ASSOCIATED PARAMETER LIST                      * 03000019
*INPUT                                                                * 03100019
*   REGISTER 1 MUST POINT TO A 2 WORD PARAMETER LIST CONTAINING       * 03200019
*   THE ADDRESSES OF THE AVT AND THE CIB.                             * 03300019
*OUTPUT                                                               * 03400019
*   N/A                                                               * 03500019
*EXTERNAL REFERENCES                                                  * 03600019
*        IHKAFI - TO MANIPULATE GLOBAL FILES                          * 03700019
*        IHKMSG - ENTRY POINT: IHKMSG                                 * 03800019
*                 TO SEND MESSAGES TO CENTRAL CONSOLE                 * 03900019
*                 ENTRY POINT: IHKMSG02                               * 04000019
*                 TO SEND BUILT MESSAGES TO CENTRAL CONSOLE           * 04100019
*EXITS, NORMAL                                                        * 04200019
*        RETURN TO CALLER WITH ZERO IN REGISTER 15                    * 04300019
*EXITS, ERROR                                                         * 04400019
*        ERROR MESSAGE SENT TO CENTRAL CONSOLE                        * 04500019
*        RETURN IS MADE TO CALLER WITH ZERO IN REGISTER 15            * 04600019
*TABLES/WORK AREAS                                                    * 04700019
*   18 BYTE SAVE AREA                                                 * 04800019
*   TUB                                                               * 04900019
*   TUBUFFAD - ADDRESS OF USER BUFFER                                 * 05000019
*   AFIO CONTROL INFORMATION                                          * 05100019
*   USER BUFFER                                                       * 05200019
*   CIB - CONTAINS COMMAND AND OPERANDS                               * 05300019
*   UVR - CONTAINS USER INFORMATION                                   * 05400019
*   CCT - CONTAINS MESSAGE COUNT                                      * 05500019
*   AVT                                                               * 05600019
*ATTRIBUTES                                                           * 05700019
*   NON-RESIDENT                                                      * 05800019
*   SERIALLY REUSABLE                                                 * 05900019
*********************************************************************** 06000019
         EJECT                                                          06100019
*********************************************************************** 06200019
*   REGISTER EQUATES                                                    06300019
*********************************************************************** 06400019
         SPACE                                                          06500019
R0       EQU   0                                                        06600019
R1       EQU   1                                                        06700019
RAVT     EQU   2                        REGISTER 2 - AVT                06800019
RCIB     EQU   3                        REGISTER 3 - CIB                06900019
R4       EQU   4                        CIBDATA POINTER                 07000019
R5       EQU   5                        CIBDATA LENGTH                  07100019
RCCT     EQU   6                        REGISTER 6 - CCT                07200019
R7       EQU   7                        RETURN 0 AFIO                   07300019
RTUB     EQU   8                        REGISTER 8 -TUB                 07400019
R9       EQU   9                        INTERNAL LINKAGE                07500019
RBUFR    EQU   10                       REGISTER 10 - USER BUFFER       07600019
RBASE    EQU   11                       REGISTER 11 - BASE              07700019
R12      EQU   12                       RETURN 4, AFIO                  07800019
R13      EQU   13                       SAVE                            07900019
R14      EQU   14                                                       08000019
R15      EQU   15                                                       08100019
*********************************************************************** 08200019
*   OTHER EQUATES                                                       08300019
*********************************************************************** 08400019
MCS20    EQU   X'20'                    INDICATES REQUESTING CONSOLE ID 08500019
HEX78    EQU   X'78'                                                    08600019
CONCOMMA EQU   X'6B'                                                    08700019
BLANK    EQU   X'40'                                                    08800019
GBLF2    EQU   2                        GLOBAL FILE- UVR                08900019
GBLF3    EQU   3                        GLOBAL FILE- DELAYED MSGS       09000019
HEX00    EQU   X'00'                                                    09100019
HEX80    EQU   X'80'                                                    09200019
HEX01    EQU   1                                                        09300019
HEX07    EQU   7                                                        09400019
USRIDLN  EQU   7                        USERID LENGTH                   09500019
X0A      EQU   10                       MAX INSERT SIZE FOR MSGS        09600019
         EJECT                                                          09700019
*********************************************************************** 09800019
*                                                                       09900019
*   SET UP BASE REGISTERS, SAVEAREA                                     10000019
*                                                                       10100019
*********************************************************************** 10200019
         USING IHKCC4,RBASE                                             10300019
         USING AVTDSECT,RAVT                                            10400019
         USING CIBDSECT,RCIB                                            10500019
         USING TUBDSECT,RTUB                                            10600019
         USING CCTDSECT,RCCT                                            10700019
*                                                                       10800019
         SAVE  (14,12),,IHKCC4-11/11/69                                 10900019
         LR    RBASE,R15                SET UP BASE ADDRESS             11000019
         L     RAVT,0(R1)                                               11100019
         L     RCIB,4(R1)               CIB BASE ADDRESS                11200019
         LA    R12,SAVEAREA             SET UP SAVEAREA                 11300019
         ST    R12,8(R13)                                               11400019
         ST    R13,4(R12)                                               11500019
         LR    R13,R12                                                  11600019
         LA    RTUB,LOCTUB              TUB BASE ADDRESS                11700019
         LA    RBUFR,RAFBUF             USER BUFFER                     11800019
         L     RCCT,IHKYYCCT            CCT BASE ADDRESS                11900019
*********************************************************************** 12000019
*   INITIALIZE                                                          12100019
*********************************************************************** 12200019
         MVI   TUBGBLKY+7,HEX00         READ FIRST RECORD               12300019
         MVI   WUSRID,BLANK                                             12400019
         MVC   WUSRID+1(7),WUSRID       MOVE BLANKS TO USERID           12500019
         MVI   SWITCH,HEX00             SET SWITCHES TO ZERO            12600019
         MVI   SWITCH2,HEX00                                            12700019
         LA    R4,CIBDATA                                               12800019
         LH    R5,CIBDATLN                                              12900019
         CLI   CIBVERB,HEX78            IS THIS A MSG COMMAND?          13000019
         BNE   TSTSHOW                  NO, GO TO SHOW COMMAND          13100019
*********************************************************************** 13200019
*                                                                       13300019
*   IS MSG D=USERID                                                     13400019
*                                                                       13500019
*********************************************************************** 13600019
         OI    SWITCH,SDELETE           TURN ON DELETE INDICATOR        13700019
         BAL   R14,INCRE                INCREMENT TO EQUAL SIGN         13800019
         B     SCNUSR                   GO CHECK USERID                 13900019
*********************************************************************** 14000019
*                                                                       14100019
*   SHOW MSGS                                                           14200019
*                                                                       14300019
*********************************************************************** 14400019
TSTSHOW  OI    SWITCH,SHOWMSG           SET SWITCH-SHOW MSGS            14500019
         SH    R5,FOUR                  TEST FOR USERID SPECIFIED       14600019
         BZ    TSTU11                   BR= NO USERID SPECIFIED         14700019
*********************************************************************** 14800019
*                                                                       14900019
*   IS SHOW MSGS, USERID                                                15000019
*                                                                       15100019
*********************************************************************** 15200019
         LA    R4,4(0,R4)                                               15300019
         CLI   0(R4),CONCOMMA           IS NEXT CHAR COMMA              15400019
         BNE   E226                     NO, INVALID OPRND               15500019
*********************************************************************** 15600019
         SPACE                                                          15700019
*     CHECK SPECIFIED USERID FOR LENGTH                                 15800019
         SPACE                                                          15900019
*********************************************************************** 16000019
SCNUSR   BAL   R14,INCRE                INCREMENT TO USERID             16100019
         OI    SWITCH,SUSER             SET USERID SPECIFIED SWITCH ON  16200019
         LA    R14,USRIDLN              USERID LENGTH                   16300019
         CR    R5,R14                   TEST FOR USERID TOO LONG        16400019
         BH    E202B                    BR= TOO LONG                    16500019
         BCTR  R5,0                                                     16600019
         EX    R5,MVEUSRID              SAVE USERID                     16700019
*********************************************************************** 16800019
*                                                                       16900019
*   USERID LENGTH VERIFIED                                              17000019
*                                                                       17100019
*********************************************************************** 17200019
TSTU11   TM    SWITCH,SDELETE           IS THIS A MSG DELETE CMD        17300019
         BNZ   GETDMSGS                 BR= YES                         17400019
*********************************************************************** 17500019
*                                                                       17600019
*   SHOW MSGS(,USERID) - CHECK FOR NULL FILE OR NONE FOR USERID         17700019
*                                                                       17800019
*********************************************************************** 17900019
         LA    R7,SETSW                 RETURN 0 - FIRST RECORD FOUND   18000019
         LA    R12,ENDUP1               RETURN 4 - EOD                  18100019
         BAL   R14,SETUPPNT             GO INITIALIZE FOR RPOINT        18200019
         TM    SWITCH,SUSER             WAS USERID SPECIFIED            18300019
         BZ    FINDREC                  BR= NO                          18400019
         MVC   TUBGBLKY(7),WUSRID                                       18500019
         MVI   TUBGBLKY+7,HEX01                                         18600019
FINDREC  RPOINT A,NR,FTYPE=GBL                                          18700019
         B     RTRNAFI(R15)                                             18800019
SETSW    OI    SWITCH,SINIT             SET SWITCH- RECORD FOUND        18900019
ENDUP1   BAL   R7,CKENDUP               ENDUP                           19000019
CKMSGS   TM    SWITCH,SINIT             WAS FIRST RECORD FOUND          19100019
         BZ    E233                     BR=NO, SEND NO MSGS MSG         19200019
*********************************************************************** 19300019
*                                                                       19400019
*   GO SEND HEADER CRJE MESSAGES START                                  19500019
*                                                                       19600019
*********************************************************************** 19700019
GETMSGS  NI    SWITCH,SINITF            TURN OFF FIRST RECORD SWITCH    19800019
         MVC   WMSGNUM(3),C203                                          19900019
         OI    SWITCH2,SHEADER          SET SWITCH INDICATING HEADER    20000019
         LA    R9,SNDERR7               SNDERR5 RETURNS TO SNDERR7      20100019
         B     SNDERR5                                                  20200019
*                                                                       20300019
*   SENDS HEADER MESSAGE AND RETURNS HERE                               20400019
*                                                                       20500019
DMSGS0   NI    SWITCH2,SHEADERF         TURN OFF HEADER SWITCH          20600019
*********************************************************************** 20700019
*                                                                       20800019
*   MSG D=  AND SHOW MSGS                                               20900019
*                                                                       21000019
*********************************************************************** 21100019
GETDMSGS MVC   WGBLKY(USRIDLN),WUSRID   SET UP KEY                      21200019
         MVI   WGBLKY+7,HEX01                                           21300019
DMSGS1   MVC   TUBGBLKY,WGBLKY                                          21400019
         LA    R7,DMSGS5                RETURN 0- DMSGS5                21500019
         LR    R12,R7                                                   21600019
         BAL   R14,SETUPPNT             INITIALIZE FOR RPOINT           21700019
         TM    SWITCH,SINIT             IS THIS THE FIRST TIME          21800019
         BNZ   DMSGS3                   BR= NO                          21900019
*********************************************************************** 22000019
*                                                                       22100019
*   POINT BEFORE FIRST RECORD OF USERID OR FILE                         22200019
*                                                                       22300019
*********************************************************************** 22400019
         RPOINT B,NR,KEY=HIEQ,FTYPE=XGBL                                22500019
         B     RTRNAFI(R15)                                             22600019
*********************************************************************** 22700019
*                                                                       22800019
*   POINT AFTER LAST RECORD READ                                        22900019
*                                                                       23000019
*********************************************************************** 23100019
DMSGS3   RPOINT A,NR,KEY=HIEQ,FTYPE=XGBL                                23200019
         B     RTRNAFI(R15)                                             23300019
*********************************************************************** 23400019
*                                                                       23500019
*   POINT SUCCESSFUL                                                    23600019
*                                                                       23700019
*********************************************************************** 23800019
DMSGS5   LA    R1,ADDRTUB(R13)                                          23900019
         LA    R7,DMSGS7                RETURN 0- DMSGS7                24000019
         LA    R12,DMSGEOD                                              24100019
         RGET  XK,S,B,FTYPE=XGBL        RETRIEVE KEY, POSITION BEFORE   24200019
         B     RTRNAFI(R15)                                             24300019
*********************************************************************** 24400019
*                                                                       24500019
*   KEY READ                                                            24600019
*                                                                       24700019
*********************************************************************** 24800019
DMSGS7   OI    SWITCH,SINIT             SET RECORD FOUND SW ON          24900019
         TM    SWITCH,SUSER             DID COMMAND SPECIFY A USERID?   25000019
         BZ    DMSGS7B                  NO,PROCESS MSG                  25100019
DMSGS7A  CLC   TUBGBLKY(7),WUSRID       YES,IS MSG FOR SPECIFIED USER?  25200019
         BNE   DMSGEOD                  NO, END PROCESSING              25300019
         OI    SWITCH,SDMSG             YES, SET DELAYED MSG SW ON      25400019
DMSGS7B  MVC   WUSRID(8),TUBGBLKY       SAVE RECORD KEY                 25500019
         TM    SWITCH,SDELETE           IS THIS A DELETE MSG REQUEST?   25600019
         BZ    DMSGS8                   NO, GET MSG                     25700019
*********************************************************************** 25800019
*                                                                       25900019
*   DELETE                                                              26000019
*                                                                       26100019
*********************************************************************** 26200019
DMSGS7D  LH    R7,CCTMSGNO              NUMBER OF MSGS ALLOWED          26300019
         LA    R7,HEX01(R7)             ADD 1- MSG TO BE DELETED        26400019
         STH   R7,CCTMSGNO              UPDATED NUMBER OF MSGS ALLOWED  26500019
         LA    R7,DMSGS7A               RETURN 0                        26600019
         LA    R12,DMSGEOD              RETURN 4- EOD                   26700019
         LA    R1,ADDRTUB(R13)                                          26800019
         RDELETE XK,B,FTYPE=XGBL        DELETE, RETRIEVE NEXT KEY       26900019
         B     RTRNAFI(R15)                                             27000019
*********************************************************************** 27100019
*                                                                       27200019
*   SHOW MSGS (,USERID)                                                 27300019
*                                                                       27400019
*********************************************************************** 27500019
DMSGS8   LA    R1,ADDRTUB(R13)                                          27600019
         LA    R7,DMSGS10               RETURN 0                        27700019
         LA    R12,DMSGEOD                                              27800019
         RGET  R,S,A,FTYPE=XGBL                                         27900019
         B     RTRNAFI(R15)                                             28000019
DMSGS10  MVC   WGBLKY,TUBGBLKY                                          28100019
         B     DMSGS12                  BE, ENDUP                       28200019
*********************************************************************** 28300019
*                                                                       28400019
*   EOD ON GET AND DELETE                                               28500019
*                                                                       28600019
*********************************************************************** 28700019
DMSGEOD  OI    SWITCH2,SMSGEOD          SET EOD SWITCH                  28800019
DMSGS12  BAL   R7,CKENDUP               ENDUP                           28900019
DMSGS15  TM    SWITCH2,SMSGEOD                                          29000019
         BZ    SENDMSG                  BR= NO EOD, SEND MSG            29100019
         TM    SWITCH,SDELETE           IS THIS DELETE                  29200019
         BZ    E213                     BR= NO                          29300019
         TM    SWITCH,SDMSG             YES- WERE THERE ANY             29400019
         BZ    E233                     BR = NO                         29500019
         MVI   WUSRID+7,BLANK           YES- GO TURN OFF BIT IN UVR     29600019
*********************************************************************** 29700019
*                                                                       29800019
*   DELETE ONLY- MESSAGES HAVE BEEN DELETED                             29900019
*   READ UVR- TURN OFF DELAYED MESSAGES BIT                             30000019
*                                                                       30100019
*********************************************************************** 30200019
TSTU1    LA    R7,TSTU3                                                 30300019
         LA    R12,TSTU8                                                30400019
         MVC   TUBGBLKY(8),WUSRID                                       30500019
         OI    SWITCH2,SUVR                                             30600019
         BAL   R14,SETUPPNT                                             30700019
         RPOINT B,R,FTYPE=XGBL                                          30800019
         B     RTRNAFI(R15)                                             30900019
*********************************************************************** 31000019
*                                                                       31100019
*   UVR FOUND                                                           31200019
*                                                                       31300019
*********************************************************************** 31400019
TSTU3    TM    SWITCH,SDMSGDEL          WERE DELAYED MSGS DELETED?      31500019
         BNO   TSTU8                    NO, ENDUP                       31600019
         USING UVRDSECT,RBUFR                                           31700019
         NI    UVRCNTL1,UVRDMSGF        YES, SET UVR DELAYED MSG SW OFF 31800019
         LA    R1,ADDRTUB(R13)                                          31900019
         LA    R7,TSTU8                                                 32000019
         LR    R12,R7                                                   32100019
         REPLACE NXK,B,FTYPE=XGBL                                       32200019
         B     RTRNAFI(R15)                                             32300019
TSTU8    BAL   R7,CKENDUP                                               32400019
         B     E255                     BR= MSGS DELETED, SEND MSG      32500019
*********************************************************************** 32600019
         EJECT                                                          32700019
*   SEND SUPPLIED ERROR MESSAGE TO CENTRAL OPERATOR                     32800019
*   SET UP AND SEND MESSAGE- MOVE ID FIRST, INSERT ROUTING              32900019
*     SET UP DELAYED MESSAGE- MOVE ID FIRST, INSERT ROUTING             33000019
*     AND DESCRIPTOR CODES ON END                                       33100019
*********************************************************************** 33200019
SENDMSG  MVC   RAFMSGID(7),RAFMSGKY                                     33300019
         MVI   RAFMSGID+7,BLANK                                         33400019
         LA    R1,RAFMSGKY                                              33500019
SNDOP3   BCTR  R1,0                     FIND FIRST NON-BLANK FROM RIGHT 33600019
         CLI   0(R1),BLANK                                              33700019
         BE    SNDOP3                                                   33800019
*   DESCRIPTOR CODE=ICR, ROUTING CODE=0                                 33900019
         MVC   1(4,R1),CONCDS           DESCRIPTOR, ROUTING CODES       34000019
         MVC   RAFMCS(2),CONFLGS        MCS FLAG=4000, INDICATES CONID  34100019
         LA    R1,1(0,R1)                                               34200019
         LA    R14,RAFTXTL              BEGINNING OF MESSAGE- LENGTH    34300019
         SR    R1,R14                                                   34400019
         STH   R1,RAFTXTL               TEXT LENGTH                     34500019
SENDOPER ST    RTUB,TUBPARM1            PARAM 1- TUB ADDRESS            34600019
         LA    R1,ZERO                                                  34700019
         ST    R1,TUBPARM2              PARAM 2- POINTS TO ZEROES       34800019
         ST    R14,TUBPARM3             MESSAGE ADDRESS                 34900019
         OI    TUBPARM3,HEX80           NO INSERTIONS                   35000019
         LA    R1,TUBPARM1                                              35100019
         L     R15,IHKYMSG2                                             35200019
         BALR  R14,R15                  GO TO IHKMSG02                  35300019
         B     SNDOPRET(R15)                                            35400019
SNDOPRET B     SNDOEXIT                 0  MESSAGE SENT                 35500019
         B     SNDOEXIT                 4-  NOT USED                    35600019
         B     SNDOUTSP                 8-  GETMAIN FAIL                35700019
         B     AAIOERR                  12-AA I/O ERROR                 35800019
         B     SNDOEXIT                 16- NOT USED                    35900019
         B     SNDOEXIT                 20- NOT USED                    36000019
         B     SNDOEXIT                 24- NOT USED                    36100019
SNDOEXIT OI    SWITCH2,SMSGSENT         SET SWITCH- MSG SENT            36200019
SNDOFINE TM    SWITCH2,SMSGERR          WAS THIS SUPPLIED ERROR MSG     36300019
         BO    CC4RET                   BR=YES                          36400019
         B     DMSGS1                   BR, GET REMAINING MGS           36500019
         EJECT                                                          36600019
*********************************************************************** 36700019
         SPACE                                                          36800019
*   INCREMENT CIBDATA POINTER AND DECREMENT LENGTH COUNT                36900019
*********************************************************************** 37000019
INCRE    BCT   R5,INCRE4                DECREMENT LENGTH COUNTER        37100019
         LA    R4,CIBDATA               NO MORE OPERANDS- ERROR         37200019
         LH    R5,CIBDATLN                                              37300019
         B     E226                     SEND OPERAND MISSING MSG        37400019
INCRE4   LA    R4,1(0,R4)               INCREMENT CIBDATA POINTER       37500019
         BR    R14                      RETURN                          37600019
MVEUSRID MVC   WUSRID(0),0(R4)                                          37700019
*********************************************************************** 37800019
*                                                                       37900019
*   ENDUP                                                               38000019
*                                                                       38100019
*********************************************************************** 38200019
CKENDUP  LR    R12,R7                                                   38300019
         LA    R1,ADDRTUB(R13)                                          38400019
         ENDUP FTYPE=GBL                                                38500019
         B     RTRNAFI(R15)                                             38600019
RTRNAFI  B     0(R7)                                                    38700019
         B     0(R12)                                                   38800019
         B     0(R7)                                                    38900019
         B     AAIOERR                                                  39000019
*********************************************************************** 39100019
*                                                                       39200019
*   INITIALIZE FOR RPOINT                                               39300019
*                                                                       39400019
*********************************************************************** 39500019
SETUPPNT ST    RBUFR,TUBRAFBF                                           39600019
         OI    TUBAFISW,TUBFCTLN        SET RAFIO BUFFER SUPPLIED SW ON 39700019
         LA    R1,ADDRTUB(R13)                                          39800019
         MVI   GBLNUMFS,GBLF3           GLOBAL FILE -DELAYED MSGS       39900019
         TM    SWITCH2,SUVR             IS THIS FOR UVR                 40000019
         BZ    PNTRTN                                                   40100019
         MVI   GBLNUMFS,GBLF2           YES- GLOBAL FILE NUMBER UVR     40200019
         NI    SWITCH2,SUVRF                                            40300019
PNTRTN   BR    R14                                                      40400019
         EJECT                                                          40500019
*********************************************************************** 40600019
*                                                                       40700019
*   SYSTEM MESSAGE ROUTINES                                             40800019
*                                                                       40900019
*********************************************************************** 41000019
         SPACE                                                          41100019
*                                                                       41200019
*   USERID INVALID/NOT FOUND                                            41300019
*                                                                       41400019
E202B    MVC   WMSGNUM(3),C202                                          41500019
         BCTR  R4,0                                                     41600019
         B     ERR2                                                     41700019
*                                                                       41800019
*   OPERAND INVALID/NOT FOUND                                           41900019
*                                                                       42000019
E226     MVC   WMSGNUM(3),C226                                          42100019
         BCTR  R4,0                                                     42200019
*                                                                       42300019
*   CHECK FOR INSERT LENGTH GREATER THAN 10                             42400019
*                                                                       42500019
ERR2     LA    R14,X0A                                                  42600019
         CR    R5,R14                                                   42700019
         BNH   ERR4                                                     42800019
ERR3     LA    R5,X0A                   TOO LONG- INSERT 10             42900019
ERR4     STC   R5,0(R4)                                                 43000019
         ST    R4,TUBPARM5              INSERT OF OPERAND               43100019
         OI    TUBPARM5,HEX80           INSERT TWO                      43200019
         LA    R9,SNDERR8                                               43300019
         B     SNDERR1                  GO SEND MSG                     43400019
*                                                                       43500019
*   NO CRJE MESSAGES                                                    43600019
*                                                                       43700019
E233     MVC   WMSGNUM(3),C233                                          43800019
         B     ERRU                                                     43900019
*                                                                       44000019
*   END OF CRJE MESSAGES MESSAGE                                        44100019
*                                                                       44200019
E213     MVC   WMSGNUM(3),C213                                          44300019
         LA    R9,SNDERR7                                               44400019
         B     SNDERR5                                                  44500019
*                                                                       44600019
*   DELAYED MESSAGES DELETED                                            44700019
*                                                                       44800019
E255     MVC   WMSGNUM(3),C255                                          44900019
ERRU     TM    SWITCH,SUSER             WAS THIS FOR SPECIFIED USER     45000019
         BNZ   ERRU1                    BR= YES                         45100019
         LA    R9,SNDERR7                                               45200019
         B     SNDERR5                  WILL RETURN TO SNDERR7          45300019
ERRU1    LA    R1,WUSRIDL               INSERT USERID                   45400019
         ST    R1,TUBPARM4                                              45500019
         OI    TUBPARM4,HEX80                                           45600019
         LA    R9,SNDERR8               WILL RETURN TO CALLER           45700019
         B     SNDERR5                  WILL GO TO SNDERR8              45800019
*                                                                       45900019
*   INSERT COMMAND VERB                                                 46000019
*                                                                       46100019
SNDERR1  TM    SWITCH,SHOWMSG           IS THIS SHOW COMMAND            46200019
         BZ    SNDERR2                  BR= NO                          46300019
         LA    R1,CONSHOW               INSERT SHOW                     46400019
         B     SNDERR3                                                  46500019
SNDERR2  LA    R1,CONMSG                INSERT MSG                      46600019
*                                                                       46700019
*   SET UP TO SEND MESSAGE TO OPERATOR                                  46800019
*                                                                       46900019
SNDERR3  ST    R1,TUBPARM4                                              47000019
SNDERR5  ST    RTUB,TUBPARM1            PARAM 1- TUB                    47100019
         LA    R1,ZERO                                                  47200019
         ST    R1,TUBPARM2              PARAM 2- POINTS TO ZEROES       47300019
         MVC   0(1,R1),CIBCONID                                         47400019
         LA    R1,WMSGREP               PARAM 3- MSG NUMBER             47500019
         ST    R1,TUBPARM3                                              47600019
         MVI   WMSGREP,MCS20            INDICATES CONSOLE ID            47700019
         BR    R9                                                       47800019
*                                                                       47900019
*   NO INSERTIONS                                                       48000019
*                                                                       48100019
SNDERR7  OI    TUBPARM3,HEX80                                           48200019
*                                                                       48300019
*   SEND MESSAGE TO OPERATOR                                            48400019
*                                                                       48500019
SNDERR8  LA    R1,TUBPARM1                                              48600019
         L     R15,IHKYYMSG                                             48700019
         BALR  R14,R15                  GO TO IHKMSG- SEND SYSTEM MSG   48800019
         B     ERRRET(R15)                                              48900019
ERRRET   B     SNDERRX                  0-  MSG SEND                    49000019
         B     SNDERRX                  4-  TP LINE ERROR(NOT USED)     49100019
         B     SNDOUTSP                 8-  GETMAIN FAIL                49200019
         B     AAIOERR                  12- AA I/O ERROR                49300019
         B     SNDERRX                  16- NOT USED                    49400019
         B     SNDERRX                  20- NOT USED                    49500019
SNDERRX  TM    SWITCH2,SHEADER                                          49600019
         BNZ   DMSGS0                                                   49700019
*********************************************************************** 49800019
*                                                                       49900019
*   RETURN 0                                                            50000019
*                                                                       50100019
*********************************************************************** 50200019
CC4RET   L     R13,4(R13)                                               50300019
         RETURN (14,12),T,RC=0                                          50400019
         EJECT                                                          50500019
*********************************************************************** 50600019
*                                                                       50700019
*   SEND SUPPLIED MESSAGE                                               50800019
*                                                                       50900019
*********************************************************************** 51000019
*                                                                       51100019
*  GETMAIN FAIL                                                         51200019
*                                                                       51300019
SNDOUTSP LA    R7,OUTSP                                                 51400019
         B     INSNOPRN                                                 51500019
*                                                                       51600019
*  ACTIVE AREA I/O ERROR                                                51700019
*                                                                       51800019
AAIOERR  LA    R7,MSGIOER                                               51900019
INSNOPRN LH    R15,0(R7)                                                52000019
         L     R14,TUBUFFAD                                             52100019
         EX    R15,MVCMSG                                               52200019
         OI    SWITCH2,SMSGERR          SET SWITCH- SUPPLIED MSG        52300019
         B     SENDOPER                                                 52400019
MVCMSG   MVC   0(0,R14),0(R7)                                           52500019
         EJECT                                                          52600019
*********************************************************************** 52700019
*                                                                       52800019
*   SUPPLIED MESSAGES                                                   52900019
*                                                                       53000019
*********************************************************************** 53100019
MSGIOER  WTO   'IHK270I ACTIVE AREA I/O ERROR',MF=L,ROUTCDE=(2,4,10),  X53200019
               DESC=(4),MCSFLAG=(REG0)                                  53300019
OUTSP    WTO   'IHK219I OUT OF MAIN STORAGE',MF=L,ROUTCDE=(2),         X53400019
               DESC=(4),MCSFLAG=(REG0)                                  53500019
*********************************************************************** 53600019
*                                                                       53700019
*   CONSTANTS                                                           53800019
*                                                                       53900019
*********************************************************************** 54000019
ZERO     DC    F'0'                                                     54100019
CONCDS   DC    X'08000000'              DESC(ICR), ROUTING(ZERO)        54200019
CONFLGS  DC    XL2'4000'                                                54300019
FOUR     DC    XL2'0004'                                                54400019
CONMSG   DC    X'03D4E2C7'              LENGTH 3 MSG CMD                54500019
CONSHOW  DC    X'04E2C8D6E6'            LENGTH 4 SHOW CMD               54600019
*********************************************************************** 54700019
         SPACE                                                          54800019
*                  MESSAGE NUMBER CONSTANTS                           * 54900019
         SPACE                                                          55000019
*********************************************************************** 55100019
C202     DC    C'202'                   USERID INVALID/NOT FOUND        55200019
C203     DC    C'203'                                                   55300019
C213     DC    C'213'                                                   55400019
C226     DC    C'226'                   INVALID OPRND                   55500019
C233     DC    C'233'                   NO DELAYED MSGS                 55600019
C255     DC    C'255'                   MSGS DELETED                    55700019
         EJECT                                                          55800019
*********************************************************************** 55900019
*   WORK/SAVE AREAS- TUB USED FOR WORK AREA                             56000019
*********************************************************************** 56100019
SAVEAREA DS    18F                      SAVEAREA                        56200019
ADDRTUB  EQU   52                                                       56300019
         IHKCDSCT TUB=YES                                               56400019
IHKCC4   CSECT                                                          56500019
LOCTUB   DS    0D                                                       56600019
         DC    F'0'                                                     56700019
         DC    A(USRBUFR)                                               56800019
         DC    320X'00'                                                 56900019
         ORG   LOCTUB+8                                                 57000019
WGBLKY   DS    D                                                        57100019
SWITCH   DS    C                                                        57200019
SDELETE  EQU   X'80'                                                    57300019
SHOWMSG  EQU   X'40'                                                    57400019
SNOMSGS  EQU   X'20'                                                    57500019
SDMSG    EQU   X'08'                                                    57600019
SDMSGDEL EQU   X'88'                                                    57700019
SINIT    EQU   X'02'                                                    57800019
SINITF   EQU   X'FD'                                                    57900019
SUSER    EQU   X'01'                                                    58000019
SWITCH2  DS    C                                                        58100019
SMSGERR  EQU   X'80'                                                    58200019
SMSGEOD  EQU   X'40'                    EOD ON DELAYED MSGS DATA SET    58300019
SMSGSENT EQU   X'20'                    MSG QUEUED OR DISPLAYED         58400019
SERROR   EQU   X'10'                                                    58500019
SHEADER  EQU   X'08'                                                    58600019
SHEADERF EQU   X'F7'                                                    58700019
SUVR     EQU   X'04'                                                    58800019
SUVRF    EQU   X'FB'                                                    58900019
         DS    C                                                        59000019
WUSRIDL  DC    X'7'                                                     59100019
WUSRID   DS    2F                                                       59200019
WMSGREP  DS    C                                                        59300019
WMSGNUM  DS    CL3                                                      59400019
         ORG   LOCTUB+TUBSIZE                                           59500019
USRBUFR  DS    CL96                                                     59600019
         ORG   USRBUFR                                                  59700019
RAFTXTL  DS    CL2                                                      59800019
RAFMCS   DS    CL2                                                      59900019
RAFBUF   DS    0CL88                                                    60000019
RAFMSGID DS    2F                                                       60100019
RAFREC   DS    18F                                                      60200019
RAFMSGKY DS    2F                                                       60300019
         ORG   USRBUFR+96                                               60400019
CIBDSECT DSECT                                                          60500019
         IEZCIB                                                         60600019
         IHKCDSCT         AVT=YES,UVR=YES,CCT=YES                       60700019
         TUBEQU                                                         60800019
         END                                                            60900019
