CC6      TITLE 'IHKCC6 - CENTRAL COMMAND PROCESSOR'                     00100019
IHKCC6   CSECT                                                          00200019
*********************************************************************** 00300019
*STATUS                                                                 00400019
*   CHANGE LEVEL 0                                                      00500019
*FUNCTION                                                               00600019
*   IHKCC6 CHECKS THE VERB AND THE COMMAND OPERANDS.  IF ANY OPERAND  * 00700019
*   IS INVALID, AN ERROR MESSAGE IS SENT TO THE CENTRAL CONSOLE AND   * 00800019
*   RETURN IS MADE TO THE CALLING ROUTINE.                              00900019
*   THE FOLLOWING OPERANDS ARE VALID FOR A SHOW COMMAND.                01000019
*   1. SESS- SET BIT OR INCREASE COUNT IN CCT.  ALL LOGONS AND          01100019
*   LOGOFFS WILL BE DISPLAYED ON CONSOLE.                               01200019
*   2. SESS,USERID - LOGON AND LOGOFF OF SPECIFIED USER WILL BE         01300019
*              DISPLAYED ON CONSOLE.    THIS COMMAND NOT ALLOWED        01400019
*              WHEN A GENERAL SHOW SESS IS IN EFFECT.                   01500019
*   3. SESSREL- TURNS OFF BIT OR DECREASES COUNT IN CCT.  LOGONS AND    01600019
*   LOGOFFS WILL NO LONGER BE DISPLAYED                                 01700019
*   4. SESSREL,USERID- LOGON AND LOGOFF OF SPECIFIED USER WILL NO       01800019
*              LONGER BE DISPLAYED.  THIS COMMAND NOT ALLOWED WHEN      01900019
*              GENERAL SHOW SESS IN EFFECT.                             02000019
*   WHEN MCS IS NOT IN THE SYSTEM, THE BIT IS SET OR TURNED OFF  IN     02100019
*   CCT FOR SESS OR SESSREL.  WHEN MCS IS IN THE SYSTEM, IHKCC6 SETS    02200019
*   OR TURNS OFF THE BIT IN THE UCM OF THE REQUESTING CONSOLE AND       02300019
*   INCREASES OR DECREASES THE COUNT IN THE CCT.  FOR A SPECIFIED USER, 02400019
*   WHEN MCS IS NOT IN THE SYSTEM, A BIT IS SET OR TURNED OFF IN THE    02500019
*   UVR.  WHEN MCS IS IN THE SYSTEM, THE REQUESTING CONSOLE ID IS       02600019
*   STORED IN THE UVR.                                                  02700019
*ENTRY POINTS                                                           02800019
*   IHKCC6 IS THE ONLY ENTRY POINT.                                     02900019
*   SEE INPUT FOR ASSOCIATED PARAMETER LIST.                            03000019
*INPUT                                                                  03100019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING       03200019
*   THE ADDRESSES OF THE AVT AND THE CIB.                               03300019
*OUTPUT                                                                 03400019
*   N/A                                                                 03500019
*EXTERNAL REFERENCES                                                    03600019
*        IHKAFI - TO MANIPULATE GLOBAL FILES                            03700019
*        IHKMSG - ENTRY POINTS:  IHKMSG AND IHKMSG02                    03800019
*        TO SEND  MESSAGES TO THE CENTRAL CONSOLE.                      03900019
*EXITS, NORMAL                                                          04000019
*        RETURN TO CALLER WITH ZERO IN REGISTER 15                      04100019
*EXITS, ERROR                                                           04200019
*        ERROR MESSAGE IS SENT TO CENTRAL CONSOLE                       04300019
*        RETURN IS MADE TO CALLER WITH ZERO IN REGISTER 15              04400019
*TABLES/WORK AREAS                                                      04500019
*   SAVEAREA                                                            04600019
*   TUB - CONTAINED IN MODULE.                                          04700019
*   TUBUFFAD - ADDRESS OF USER BUFFER                                   04800019
*   AFIO CONTROL INFORMATION                                            04900019
*   USER BUFFER                                                         05000019
*   CIB - CONTAINS COMMAND AND OPERANDS                                 05100019
*   UVR - CONTAINS USER INFORMATION                                     05200019
*   AVT                                                                 05300019
*ATTRIBUTES                                                             05400019
*   NON-RESIDENT                                                        05500019
*   SERIALLY REUSABLE                                                   05600019
*********************************************************************** 05700019
         EJECT                                                          05800019
*********************************************************************** 05900019
*                                                                       06000019
*   REGISTER EQUATES                                                    06100019
*                                                                       06200019
*********************************************************************** 06300019
R0       EQU   0                                                        06400019
R1       EQU   1                                                        06500019
RUCM     EQU   2                        REGISTER 2  UCM BASE            06600019
R3       EQU   3                        POINTER TO OPERAND              06700019
R4       EQU   4                        WORK REGISTER, RETURN 0 AFIO    06800019
R5       EQU   5                        RETURN 4 FROM AFIO              06900019
RUVR     EQU   6                        UVR BASE                        07000019
R7       EQU   7                        INTERNAL LINKAGE                07100019
RCIB     EQU   8                        CIB BASE                        07200019
RTUB     EQU   9                        TUB BASE                        07300019
RCCT     EQU   10                       CCT BASE                        07400019
RAVT     EQU   11                       AVT BASE                        07500019
RBASE    EQU   12                       IHKCC6 BASE                     07600019
R13      EQU   13                                                       07700019
R14      EQU   14                                                       07800019
R15      EQU   15                                                       07900019
*********************************************************************** 08000019
*                                                                       08100019
*   OTHER EQUATES                                                       08200019
*                                                                       08300019
*********************************************************************** 08400019
ADDRCVT  EQU   16                       CVT ADDRESS                     08500019
UCMMSGEF EQU   X'F7'                    TURNS OFF SESS BIT-UCM          08600019
SHOWCMD  EQU   X'88'                    SHOW COMMAND VERB               08700019
GBLF2    EQU   2                        UVR GLOBAL FILE                 08800019
USRIDLNG EQU   7                        LENGTH OF USERID                08900019
X0A      EQU   10                       MAX INSERT SIZE FOR MSGS        09000019
X1       EQU   1                                                        09100019
ALLBITS  EQU   X'FF'                                                    09200019
HIBIT    EQU   X'80'                                                    09300019
X00      EQU   X'00'                                                    09400019
         EJECT                                                          09500019
*********************************************************************** 09600019
*********************************************************************** 09700019
*                                                                       09800019
*   SET UP BASE REGISTERS, SAVEAREA                                     09900019
*                                                                       10000019
         USING IHKCC6,RBASE                                             10100019
         USING AVTDSECT,RAVT                                            10200019
         USING CCTDSECT,RCCT                                            10300019
         USING TUBDSECT,RTUB                                            10400019
         USING CIBBASE,RCIB                                             10500019
         USING UVRDSECT,RUVR                                            10600019
         USING UCMDSECT,RUCM                                            10700019
*                                                                       10800019
         SAVE  (14,12),,IHKCC6-11/24/69                                 10900019
         LR    RBASE,R15                SET UP BASE REGISTER            11000019
         L     RAVT,0(R1)               AVT ADDRESS PASSED              11100019
         L     RCIB,4(R1)               CIB ADDRESS PASSED              11200019
         ST    R13,SAVEAREA+4           SAVE CALLERS SAVEAREA ADDR      11300019
         LA    R14,SAVEAREA                                             11400019
         ST    R14,8(R13)               SAVE SAVEAREA IN CALLERS        11500019
         LR    R13,R14                                                  11600019
*                                                                       11700019
*  INITIALIZE                                                           11800019
         L     RCCT,IHKYYCCT            INITIALIZE CCT                  11900019
         LA    RTUB,LOCTUB              SET UP TUB BASE                 12000019
*                                                                       12100019
         LH    R4,CIBDATLN              COMPUTE END ADDR OF OP          12200019
         LA    R15,CIBDATA-1                                            12300019
         AR    R15,R4                                                   12400019
         ST    R15,LASTCIB                                              12500019
         L     RUVR,TUBUFFAD            READ UVR IN USER BUFFER         12600019
         MVI   OPRSW,X00                SET SWITCH TO ZERO              12700019
         LA    R1,ADDRCVT               GET ADDRESS OF CVT              13200019
         L     R1,0(R1)                                                 13300019
         USING CVTDSECT,R1                                              13400019
GEYUCM   L     RUCM,CVTCUCB                                             13500019
         LA    RUCM,0(RUCM)             POINTER TO UCM BASE             13600019
*********************************************************************** 13700019
*                                                                       13800019
*   CHECK FOR SHOW COMMAND                                              13900019
*                                                                       14000019
*********************************************************************** 14100019
         CLI   CIBVERB,SHOWCMD          IS IT SHOW                      14200019
         BNE   RETURN0                  BR = NO, RETURN                 14300019
         LA    R1,SHOW                                                  14400019
         ST    R1,CMDADDR               COMMAND FOR INSERT              14500019
*********************************************************************** 14600019
*                                                                       14700019
*   IS SHOW - CHECK FOR SESS OR SESSREL                                 14800019
*                                                                       14900019
*********************************************************************** 15000019
         LA    R1,SHOWCC1                                               15100019
         BAL   R14,FINDSUBR             GO LOOK FOR VALID OP            15200019
         B     SHOWBR(R15)              BRANCH TO ROUTINE TO HANDLE OP  15300019
*********************************************************************** 15400019
*                                                                       15500019
*  SHOW SESS, USERID                                                    15600019
*                                                                       15700019
*********************************************************************** 15800019
SHWSESSU OI    OPRSW,OPRUSRID           SET TO INDICATE USERID          15900019
*********************************************************************** 16000019
*                                                                       16100019
*  SHOW SESS                                                            16200019
*                                                                       16300019
*********************************************************************** 16400019
SHWSESS  OI    OPRSW,OPRSESS            SET SWITCH-SESS                 16500019
SHWSESSA TM    UCMMODE,UCMMCS                                           16600019
         BO    SESSMCS                  BR= MCS IN SYSTEM               16700019
*********************************************************************** 16800019
*                                                                       16900019
*   MCS NOT IN SYSTEM- SHOW SESS                                        17000019
*                                                                       17100019
*********************************************************************** 17200019
         CLI   CCTSESS,X00                                              17300019
         BNE   SESSET                   BR= SESS ALREADY SET            17400019
         TM    OPRSW,OPRUSRID           IS THIS SESS OR SESSREL,USERID  17500019
         BO    USRIDVAL                 YES- FIND UVR                   17600019
SETSESON SR    R1,R1                    SET SESS ON                     17700019
         IC    R1,CCTSESS                                               17800019
         LA    R1,X1(R1)                                                17900019
         STC   R1,CCTSESS               INCREASE SESS COUNT IN CCT      18000019
         B     SESSET                   GO SEND SESS IN EFFECT MSG      18100019
*********************************************************************** 18200019
*                                                                       18300019
*  SHOW SESSREL                                                         18400019
*                                                                       18500019
*********************************************************************** 18600019
SHWSRL   OI    OPRSW,OPRSESRL           SET SWITCH- SESSREL             18700019
         TM    UCMMODE,UCMMCS                                           18800019
         BO    SESSMCS                  BR =MCS IN SYSTEM               18900019
*********************************************************************** 19000019
*                                                                       19100019
*   MCS NOT IN SYSTEM- SHOW SESSREL                                     19200019
*                                                                       19300019
*********************************************************************** 19400019
         CLI   CCTSESS,X00              IS SESS IN EFFECT               19500019
         BE    SESRLNO1                 BR= NO, SEND NOT IN EFFECT MSG  19600019
SESSREL  SR    R1,R1                    TURN OFF SESS                   19700019
         IC    R1,CCTSESS                                               19800019
         BCTR  R1,0                                                     19900019
         STC   R1,CCTSESS               DECREASE SESS COUNT IN CCT      20000019
         LA    R1,MSESRL                GO SEND SESS RELEASED MSG       20100019
         B     INSNOPAR                                                 20200019
*********************************************************************** 20300019
*                                                                       20400019
*  SHOW  SESSREL, USERID                                                20500019
*                                                                       20600019
*********************************************************************** 20700019
SHWSRLU  OI    OPRSW,OPRUSRSR           SET FOR SESSREL,USERID          20800019
         B     SHWSESSA                                                 20900019
*********************************************************************** 21000019
*                                                                       21100019
*   MCS IN SYSTEM                                                       21200019
*                                                                       21300019
*********************************************************************** 21400019
         USING UCMLIST,R4                                               21460019
SESSMCS  L     R4,UCMVEA                UCM BASE ADDRESS FOR ENTRY      21520019
NEXTUCM  CLC   UCMID,CIBCONID           LOOK FOR REQUESTING CONSOLE     21800019
         BE    MCSFOUND                 BR= CONSOLE FOUND               21900019
         A     R4,UCMVEZ                GET ADDRESS OF NEXT UCM ENTRY   22000019
         CL    R4,UCMVEL                WAS THAT THE LAST               22100019
         BH    RETURN0                  BR= YES, IGNORE                 22200019
         B     NEXTUCM                                                  22300019
MCSFOUND L     R1,UCMCOMPC              ADDRESS OF OTHER HALF, IF ANY   22320019
         LA    R1,0(R1)                                                 22340019
         LTR   R1,R1                    IS THIS A COMPOSITE CONSOLE     22360019
         BZ    TESTSESA                 BR= NO                          22380019
         LR    R4,R1                    YES, POINT TO SECOND HALF       22400019
TESTSESA TM    OPRSW,OPRSESS            IS THIS SESS                    22420019
         BZ    MCSSREL                  BR= IS SESSREL                  22500019
*********************************************************************** 22600019
*                                                                       22700019
*   MCS - SESS                                                          22800019
*                                                                       22900019
*********************************************************************** 23000019
         TM    UCMMSG,UCMMSGE           IS SESS SET FOR THIS CONSOLE    23100019
         BZ    SETMCS                   BR= SESS NOT SES                23200019
         B     SESSET                   GO SEND SESS IN EFFECT MSG      23400019
*********************************************************************** 23500019
*                                                                       23600019
*   MCS- SESS NOT SET FOR THIS CONSOLE                                  23700019
*                                                                       23800019
*********************************************************************** 23900019
SETMCS   TM    OPRSW,OPRUSRID           IS THIS FOR SPECIFIC USER       24000019
         BZ    CONSESS                  BR= NO, GO SET SESS             24100019
         B     USRIDVAL                 GO SET FOR THIS USER            24300019
CONSESS  OI    UCMMSG,UCMMSGE           SET SESS FOR THIS CONSOLE       24400019
         B     SETSESON                 GO UPDATE CCT                   24600019
*********************************************************************** 24700019
*                                                                       24800019
*   MCS - SESSREL                                                       24900019
*                                                                       25000019
*********************************************************************** 25100019
MCSSREL  TM    UCMMSG,UCMMSGE           IS SESS SET                     25200019
         BO    MCSOFF                   BR= SESS SET                    25300019
         TM    OPRSW,OPRUSRID           IS THIS FOR SPECIFIC USER       25500019
         BO    USRIDVAL                 GO SET FOR USER                 25600019
         B     SESRLNO1                 BR= NO, SEND NOT IN EFFECT MSG  25700019
MCSOFF   TM    OPRSW,OPRUSRID           IS THIS FOR SPECIFIC USER       25800019
         BZ    MCSOFFA                  BR= NO                          25900019
         B     SESSET                   GO SEND SESS IN EFFECT MSG      26100019
MCSOFFA  NI    UCMMSG,UCMMSGEF          TURN OFF SESS BIT- UCM          26200019
         B     SESSREL                  GO UPDATE CCT                   26400019
*********************************************************************** 26500019
*                                                                       26600019
*   CHECK USERID                                                        26700019
*                                                                       26800019
*********************************************************************** 26900019
USRIDVAL L     R1,LASTCIB               LAST BYTE IN CIB                27000019
         SR    R1,R3                    LENGTH OF SPECIFIED USERID      27100019
         ST    R3,TUBPARM4              SAVE ADDRESS OF USERID          27200019
         ST    R3,TUBPARM5                                              27300019
         LA    R15,USRIDLNG             MAXIMUM VALID USERID LENGTH     27400019
         STC   R1,0(R3)                 STORE USERID LENGTH             27500019
         LTR   R1,R1                    IS IT ZERO LENGTH               27600019
         BZ    INVALUSR                 BR= YES, INVALID                27700019
         CR    R1,R15                   IS IT TOO LONG                  27800019
         BH    INVUSRA                  BR= YES, INVALID                27900019
*********************************************************************** 28000019
*                                                                       28100019
*  FIND UVR FOR THIS USER                                               28200019
*                                                                       28300019
*********************************************************************** 28400019
SETUSRUV MVC   TUBGBLKY,BLANKS                                          28500019
         BCTR  R1,0                                                     28600019
         EX    R1,MVCUSR                MOVE USERID TO KEY              28700019
         OI    OPRSW,OPRENDUP           SET SWITCH TO ENDUP             28800019
         OI    TUBAFISW,TUBFCTLN        SET TO READ INTO USER BUFFER    28900019
         ST    RUVR,TUBRAFBF            USER BUFFER ADDRESS             29000019
         MVI   GBLNUMFS,GBLF2           UVR GLOBAL FILE                 29100019
         LA    R4,SETSESS               0    FOUND                      29200019
         LA    R5,INVALUSR              4    NOT FOUND                  29300019
         LA    R1,ADDRTUB(R13)                                          29400019
         RPOINT B,R,FTYPE=XGBL          POINT BEFORE                    29500019
         B     RTRNAFI(R15)             CHECK IF FOUND                  29600019
*********************************************************************** 29700019
*                                                                       29800019
*   UVR RECORD FOUND - CHECK FOR MCS                                    29900019
*                                                                       30000019
*********************************************************************** 30100019
SETSESS  TM    UCMMODE,UCMMCS           IS MCS IN SYSTEM                30200019
         BZ    UVRNOMCS                 BR= NO                          30300019
         LA    R1,UVRMXCON              MAXIMUM NUMBER IN UVR           30400019
         LA    R3,UVRCID1                                               30500019
CKCONSET CLC   CIBCONID,0(R3)           CHECK FOR SET ALREADY           30600019
         BE    CKSESSA                  BR= SESS SET FOR THIS CONSOLE   30700019
         LA    R3,1(R3)                                                 30800019
         BCT   R1,CKCONSET                                              30900019
*********************************************************************** 31000019
*                                                                       31100019
*   MCS- SESS NOT SET FOR THIS CONSOLE                                  31200019
*                                                                       31300019
*********************************************************************** 31400019
         TM    OPRSW,OPRSESRL           IS THIS SESSREL                 31500019
         BO    SESRLNOT                 BR= YES, SEND NOT IN EFFECT MSG 31600019
*********************************************************************** 31700019
*                                                                       31800019
*   MCS - SHOW SESS                                                     31900019
*                                                                       32000019
*********************************************************************** 32100019
         LA    R3,UVRCID1                                               32200019
         LA    R1,UVRMXCON                                              32300019
CKCON00  CLI   0(R3),X00                CHECK FOR AVAILABLE             32400019
         BE    SETSESSA                 BR= AVAILABLE                   32500019
         LA    R3,1(R3)                                                 32600019
         BCT   R1,CKCON00                                               32700019
         LA    R1,MCONFULL              NONE AVAILABLE                  32800019
         B     INS1PRM2                 GO SEND MSG                     32900019
SETSESSA MVC   0(1,R3),CIBCONID         STORE CONSOLE IS                33000019
         B     REPLUVR                  GO REPLACE UVR                  33100019
*********************************************************************** 33200019
*                                                                       33300019
*   MCS - SESS SET FOR THIS CONSOLE                                     33400019
*                                                                       33500019
*********************************************************************** 33600019
CKSESSA  TM    OPRSW,OPRSESRL           IS THIS SESSREL                 33700019
         BZ    SESENDUP                 BR= NO                          33800019
         MVI   0(R3),X00                SET CONSOLE ID TO ZERO IN UVR   33900019
REPLUVR  LA    R1,ADDRTUB(R13)          REPLACE                         34000019
         LA    R4,SESENDUP              0,4 RETURN                      34100019
         LR    R5,R4                                                    34200019
         REPLACE NXK,FTYPE=GBL                                          34300019
         B     RTRNAFI(R15)                                             34400019
*********************************************************************** 34500019
*                                                                       34600019
*   MCS NOT IN SYSTEM                                                   34700019
*                                                                       34800019
*********************************************************************** 34900019
UVRNOMCS TM    UVRCNTL1,UVRSESS         IS SESS IN EFFECT FOR THIS USER 35000019
         BZ    CKSESRL1                 BR= NO                          35100019
*********************************************************************** 35200019
*                                                                       35300019
*   NO MCS - SESS SET                                                   35400019
*                                                                       35500019
*********************************************************************** 35600019
         TM    OPRSW,OPRSESRL           IS THIS SESSREL                 35700019
         BZ    SESENDUP                 BR= NO                          35800019
         NI    UVRCNTL1,UVRSESSF        SESS SET- RELEASE               35900019
         B     REPLUVR                  GO REPLACE UVR                  36000019
*********************************************************************** 36100019
*                                                                       36200019
*   NO MCS- SESS NOT SET                                                36300019
*                                                                       36400019
*********************************************************************** 36500019
CKSESRL1 TM    OPRSW,OPRSESRL           IS THIS SESSREL                 36600019
         BO    SESRLNOT                 BR= YES, SEND NOT IN EFFECT MSG 36700019
         OI    UVRCNTL1,UVRSESS         SET SESS BIT IN UVR             36800019
         B     REPLUVR                                                  36900019
*********************************************************************** 37000019
*                                                                       37100019
*   SEND MESSAGE FOR THIS USER                                          37200019
*                                                                       37300019
*********************************************************************** 37400019
SESENDUP LA    R1,MSESRL                                                37500019
         TM    OPRSW,OPRSESRL           IS THIS SESSREL                 37600019
         BO    INS1PRM2                 SEND MSG- RELEASED              37700019
         LA    R1,MSESS                                                 37800019
         B     INS1PRM2                 SEND MSG- SESS IN EFFECT        37900019
         EJECT                                                          38000019
*********************************************************************** 38100019
*                                                                       38200019
*   SUPPLIED ERROR MESSAGES                                             38300019
*                                                                       38400019
*********************************************************************** 38500019
*                                                                       38600019
*  GETMAIN FAIL                                                         38700019
*                                                                       38800019
SNDOUTSP LA    R1,OUTSP                                                 38900019
         B     INSNOPRN                                                 39000019
*                                                                       39100019
*  ACTIVE AREA I/O ERROR                                                39200019
*                                                                       39300019
AAIOERR  LA    R1,MSGIOER                                               39400019
INSNOPRN OI    OPRSW,OPRERRMS           SET SWITCH- SUPPLIED MSG        39500019
         B     INSNOPAR                                                 39600019
*********************************************************************** 39800019
*                                                                       39900019
*   SYSTEM MESSAGE ROUTINES                                             40000019
*                                                                       40100019
*********************************************************************** 40200019
*                                                                       40300019
*                                                                       40400019
*  OPERAND INVALID/MISSING                                              40500019
*    INSERT FIRST TEN CHAR IN MSG                                       40600019
*                                                                       40700019
OPNFND   LA    R1,MNOTFND                                               40800019
CKCIBLNG CLI   CIBDATLN+1,X0A           CK FOR LESS THAN TEN            40900019
         BL    INSCMDOP                                                 41000019
         MVI   CIBDATLN+1,X0A           MORE THAN 10- INSERT 10         41100019
INSCMDOP LA    R14,CIBDATLN+1                                           41200019
         MVC   TUBPARM4,CMDADDR         INSERT COMMAND                  41300019
INS2PARM ST    R14,TUBPARM5                                             41400019
INS2PRM2 MVI   TUBPARM5,HIBIT           TWO INSERTS                     41500019
         B     SENDMSG0                                                 41600019
*********************************************************************** 41700019
*                                                                       41800019
*  SESS IN EFFECT                                                       41900019
*                                                                       42000019
*********************************************************************** 42100019
SESSET   LA    R1,MSESS                                                 42200019
INSNOPAR ST    R1,TUBPARM3                                              42300019
         MVI   TUBPARM3,HIBIT           NO INSERTS                      42400019
         LA    R7,RETURN0               WILL RETURN 0                   42500019
         B     SENDMSGA                                                 42600019
*                                                                       42700019
*  INVALID USERID                                                       42800019
*                                                                       42900019
INVUSRA  LA    R15,X0A                  CHECK FOR MORE THAN 10          43000019
         CR    R1,R15                                                   43100019
         BNH   INVALUSR                                                 43200019
         STC   R15,0(R3)                TOO LONG- INSERT 10             43300019
INVALUSR LA    R1,MINVUSR                                               43400019
         MVC   TUBPARM4,CMDADDR         INSERT COMMAND                  43500019
         B     INS2PRM2                                                 43600019
*                                                                       43700019
*  SHOW  SESSREL,USRID BUT NOT IN EFFECT                                43800019
*                                                                       43900019
SESRLNOT LA    R1,MSESRLF                                               44000019
INS1PRM2 MVI   TUBPARM4,HIBIT           ONE INSERT                      44100019
         B     SENDMSG0                                                 44200019
*                                                                       44300019
*   SESSREL BUT SESS NOT IN EFFECT                                      44400019
*                                                                       44500019
SESRLNO1 LA    R1,MSESRLF                                               44600019
         B     INSNOPAR                                                 44700019
*********************************************************************** 44800019
*                                                                       44900019
*  CHECK IF ENDUP NEEDED                                                45000019
*                                                                       45100019
*********************************************************************** 45200019
CKENDUP  LR    R4,R7                                                    45300019
         LR    R5,R7                                                    45400019
         TM    OPRSW,OPRENDUP           IS ENDUP NECESSARY              45500019
         BZ    RTRNAFI                  BR= NO                          45600019
         MVI   GBLNUMFS,GBLF2           UVR GLOBAL FILE                 45700019
         NI    OPRSW,OPRENDF                                            45800019
         LA    R1,ADDRTUB(R13)                                          45900019
         ENDUP FTYPE=GBL                                                46000019
         B     RTRNAFI(R15)             CHECK IF FOUND                  46100019
RTRNAFI  B     0(R4)                    RETURN 0                        46200019
         B     0(R5)                    RETURN 4                        46300019
         B     SNDOUTSP                 8  GETMAIN FAIL                 46400019
         B     AAIOERR                  12 ACTIVE AREA I/O ERROR        46500019
         EJECT                                                          46600019
*********************************************************************** 46700019
*                                                                       46800019
*                                                                       46900019
*  SUBROUTINE TO SEARCH FOR SPECIFIED SET OF CHARACTERS                 47000019
*        CHECKS FOR END OF CIB                                          47100019
*        AT ENTRY REGISTER ONE POINTS TO TABLE DEFINING VALID CHARACTER 47200019
*        STRINGS, AND CHARACTER (OR END OF CIB) THAT MUST FOLLOW        47300019
*        RETURNS WITH REGISTER 15 CONTAINING BRANCH CODE (FROM TABLE)   47400019
*        AND REGISTER 3 POINTS AT CHAR AFTER OP IN CIB (IF ANY)         47500019
*                                                                       47600019
*********************************************************************** 47700019
FINDSUBR SR    R15,R15                                                  47800019
GETLNG   IC    R15,0(R1)                LENGTH FROM TABLE-REG 15        47900019
         LA    R1,1(R1)                 REG1 POINTS AT OP IN TABLE      48000019
         CH    R15,CIBDATLN                                             48100019
         BH    NXTABLE                  BR= OP IN CIB SHORTER           48200019
         LA    R3,CIBDATA               REG3 POINTS AT OP IN CIB        48300019
         BCTR  R15,0                                                    48400019
         EX    R15,CLCOP                COMPARE OPERANDS                48500019
         LA    R15,1(R15)               RESTORE TO OP LENGTH IN TABLE   48600019
         BNE   NXTABLE                  BR= NOT OP IN TABLE             48700019
         AR    R1,R15                   OP EQUAL-CK NEXT CHAR           48800019
         CLI   0(R1),X00                                                48900019
         BE    CKCIBEND                 BR= MUST BE END OF CIB          49000019
         CH    R15,CIBDATLN             MUST BE ANOTHER CHAR            49100019
         BNL   NXTABLE1                 BR= NOT ANOTHER IN CIB          49200019
         AR    R3,R15                   CHECK CARH IN CIB               49300019
         CLC   0(1,R3),0(R1)            IS IT CHAR IN TABLE             49400019
         BNE   NXTABLE1                 BR= NO, GO GET NEXT ENTRY       49500019
GETBRNCH LA    R1,1(R1)                 OPERAND FOUND                   49600019
         IC    R15,0(R1)                SET BRANCH CODE                 49700019
         BR    R14                      RETURN                          49800019
*                                                                       49900019
*  POINT TO NEXT ENTRY IN TABLE                                         50000019
*                                                                       50100019
NXTABLE  AR    R1,R15                                                   50200019
NXTABLE1 LA    R1,2(R1)                 NOW POINTS AT NEXT              50300019
         TM    0(R1),ALLBITS                                            50400019
         BO    OPNFND                   BR= NO MORE IN TABLE            50500019
         B     GETLNG                   GO CHECK CIB AGAINST THIS ENTRY 50600019
*                                                                       50700019
CKCIBEND CH    R15,CIBDATLN             HAS TO BE END OF OP             50800019
         BE    GETBRNCH                 BR= IS END                      50900019
         B     NXTABLE1                 GO LOOK FOR ANOTHER ENTRY       51000019
*                                                                       51100019
         EJECT                                                          51200019
*********************************************************************** 51300019
*                                                                       51400019
*   SUBROUTINE TO SEND MESSAGES                                         51500019
*   SENDMSG0- SETS RETURN TO ZERO                                       51600019
*   SENDMSG- AT LEAST ONE INSERTION                                     51700019
*   SENDMSGA- NO INSERTIONS                                             51800019
*                                                                       51900019
*********************************************************************** 52000019
SENDMSG0 LA    R7,RETURN0                                               52100019
SENDMSG  ST    R1,TUBPARM3              PARAM 3 = ADDR OF MSG           52200019
SENDMSGA ST    RTUB,TUBPARM1            PARAM 1 = ADDR OF TUB           52300019
         LR    R3,R7                                                    52400019
         BAL   R7,CKENDUP               GO ENDUP IF NECESSARY           52500019
         LR    R7,R3                                                    52600019
         LA    R1,ZEROES                                                52700019
         ST    R1,TUBPARM2              PARAM 2 = ADDR OF ZERO          52800019
         MVC   0(1,R1),CIBCONID         HIGH ORDER BYTE=CONSOLE ID      52900019
         TM    OPRSW,OPRERRMS           IS THIS SEND A SUPPLIED MSG     53000019
         BZ    ENTRMSG                  BR = NO                         53100019
         L     R15,IHKYMSG2             YES, IHKMSG02                   53200019
         B     GETPARM1                                                 53300019
ENTRMSG  L     R15,IHKYYMSG             SEND SYSTEM MSG- IHKMSG         53400019
GETPARM1 LA    R1,TUBPARM1                                              53500019
         BALR  R14,R15                                                  53600019
         B     MSGRTN(R15)                                              53700019
MSGRTN   B     0(R7)                    0    MSG SENT                   53800019
         B     0(R7)                    4    TP LINE ERROR (NOT APPLIC) 53900019
         B     SNDOUTSP                 8    GETMAIN FAIL               54000019
         B     AAIOERR                  12   AA I/O ERROR               54100019
         B     0(R7)                    16   NOT USED                   54200019
         B     0(R7)                    20   NOT USED                   54300019
         B     0(R7)                    24   NOT USED                   54400019
*********************************************************************** 54500019
*                                                                       54600019
*  EXECUTED INSTRUCTIONS                                                54700019
*                                                                       54800019
*********************************************************************** 54900019
MVCUSR   MVC   TUBGBLKY(0),1(R3)        MOVE USERID FROM CIB            55000019
CLCOP    CLC   0(0,R1),0(R3)                                            55100019
*********************************************************************** 55200019
*                                                                       55300019
*   RETURN WITH RETURN CODE 0                                           55400019
*                                                                       55500019
*********************************************************************** 55600019
RETURN0  L     R13,4(R13)                                               55700019
         RETURN (14,12),,RC=0                                           55800019
*                                                                       55900019
         EJECT                                                          56000019
*********************************************************************** 56100019
*                                                                       56200019
*  MESSAGE CODES                                                        56300019
*                                                                       56400019
*********************************************************************** 56500019
         DS    0F                                                       56600019
MINVUSR  DC    X'20',C'202'             USERID INVALID/NOT FOUND        56700019
MNOTFND  DC    X'20',C'226'             OP MISSING/INVALID              56800019
MCONFULL DC    X'20',C'238'             UVR CONSOLE SESS FULL           56900019
MSESRLF  DC    X'20',C'239'             SESSREL BUT SESS NOT IN EFFECT  57000019
MSESS    DC    X'20',C'249'             SESS IN EFFECT                  57100019
MSESRL   DC    X'20',C'250'             SESS RELEASED                   57200019
         EJECT                                                          57300019
*********************************************************************** 57400019
*                                                                       57500019
* TABLES PASSED TO FINDSUBR                                             57600019
*   FORMAT- LENGTH OF OPERAND(ONE BYTE), OPERAND (VARIABLE LENGTH),     57700019
*   CHARACTER THAT MUST FOLLOW OPERAND OR X'00' TO INDICATE MUST        57800019
*   BE END OF CIB (ONE BYTE), BRANCH CODE(ONE BYTE)                     57900019
*   LAST ENTRY IN TABLE FOLLOWED BY X'FF'                               58000019
*                                                                       58100019
*********************************************************************** 58200019
SHOWCC1  DC    X'04',C'SESS',X'0',X'00'                                 58300019
         DC    X'04',C'SESS',C',',X'04'                                 58400019
         DC    X'07',C'SESSREL',X'0',X'08'                              58500019
         DC    X'07',C'SESSREL',C',',X'0C'                              58600019
         DC    X'FF'                                                    58700019
*                                                                       58800019
*   BRANCH TABLE REFERRED TO BE SHOWCC1                                 58900019
*                                                                       59000019
SHOWBR   B     SHWSESS                  SHOW SESS                       59100019
         B     SHWSESSU                 SHOW SESS, USERID               59200019
         B     SHWSRL                   SHOW SESSREL                    59300019
         B     SHWSRLU                  SHOW SESSREL,USERID             59400019
         EJECT                                                          59500019
*********************************************************************** 59600019
*                                                                       59700019
*   SUPPLIED ERROR MESSAGES                                             59800019
*                                                                       59900019
*********************************************************************** 60000019
MSGIOER  WTO   'IHK270I ACTIVE AREA I/O ERROR',MF=L,ROUTCDE=(2,4,10),  X60100019
               DESC=(4),MCSFLAG=(REG0)                                  60200019
OUTSP    WTO   'IHK219I OUT OF MAIN STORAGE',MF=L,ROUTCDE=(2),         X60300019
               DESC=(4),MCSFLAG=(REG0)                                  60400019
*********************************************************************** 61400019
*                                                                       61500019
*   WORK/SAVE AREAS- TUB USED FOR WORK AREA                             61600019
*                                                                       61700019
*********************************************************************** 61800019
SAVEAREA DC    18F'0'                                                   61900019
ADDRTUB  EQU   56                       ADDR OF TUB- REG 9              62000019
         IHKCDSCT  TUB=YES                                              62200019
IHKCC6   CSECT                                                          62300019
LOCTUB   DS    0D                                                       62400019
         DC    F'0'                                                     62500019
         DC    A(USRBUFR)                                               62600019
         DC    320X'00'                                                 62700019
         ORG   LOCTUB+8                                                 62800019
OPRSESS  EQU   X'80'                    SHOW SESS                       62900019
LASTCIB  DS    F                        LAST BYTE IN CIB                63000019
CMDADDR  DS    F                        ADDRESS OF COMMAND INSERT       63100019
ZEROES   DC    F'0'                     FOR PARAMETER LIST-IHKMSG       63200019
BLANKS   DC    C'        '                                              63300019
*                                                                       63400019
*  SWITCHES                                                             63500019
*                                                                       63600019
OPRSW    DS    C                        OPERAND SWITCH                  63700019
OPRSESRL EQU   X'40'                    SHOW SESSREL                    63800019
OPRUSRID EQU   X'20'                    USERID SPECIFIED                63900019
OPRENDUP EQU   X'04'                    ENDUP NECESSARY                 64000019
OPRENDF  EQU   X'FB'                    TURN ENDUP SWITCH OFF           64100019
OPRERRMS EQU   X'02'                    SUPPLIED MESSAGE                64200019
OPRUSRSR EQU   X'60'                    SESSREL,USERID                  64300019
*                                                                       64400019
SHOW     DC    X'04',C'SHOW'                                            64500019
         ORG   LOCTUB+TUBSIZE                                           64600019
         DS    0D                                                       64700019
USRBUFR  DS    CL88                                                     64800019
CIBBASE  DSECT                                                          65000019
         IEZCIB                                                         65100019
UCMDSECT DSECT                                                          65300019
         IEECUCM                                                        65400019
CVTDSECT DSECT                                                          65500019
         CVT                                                            65600019
         IHKCDSCT         AVT=YES,CCT=YES,UVR=YES                       65700019
         TUBEQU                                                         65800019
         RAFKNBX TYPE=DSECT                                             65900019
         END                                                            66000019
