CC7      TITLE 'IHKCC7 - CENTRAL COMMAND PROCESSOR'                     00100019
IHKCC7   CSECT                                                          00200019
*********************************************************************** 00300019
*STATUS                                                                 00400019
*   CHANGE LEVEL 0                                                      00500019
*FUNCTION                                                               00600019
*   IHKCC7 CHECKS THE VERB AND THE COMMAND OPERANDS.  IF ANY OPERAND  * 00700019
*   IS INVALID, AN ERROR MESSAGE IS SENT TO THE CENTRAL CONSOLE AND   * 00800019
*   RETURN IS MADE TO THE CALLING ROUTINE.                              00900019
*   THE FOLLOWING OPERANDS ARE VALID FOR A USERID COMMAND.              01000019
*   2. A(DD) = - ADDS SPECIFIED USERID AND PASSWORD TO USER LIST.       01100019
*              USERID MUST NOT ALREADY BE IN USER LIST                  01200019
*              USERID AND PASSWORD MUST BEGIN WITH ALPHABETIC CHARACTER 01300019
*              AND MUST CONTAIN ONLY ALPHAMERIC CHARACTERS.             01400019
*   3. D(ELETE) = - DELETES SPECIFIED USERID AND PASSWORD FROM USER     01500019
*              LIST.                                                    01600019
*              IF NO MORE USERS ARE ALLOWED, INDICATED BY A ZERO IN     01700019
*              CCTUSERS, AN ERROR MESSAGE IS SENT.                      01800019
*ENTRY POINTS                                                           01900019
*   IHKCC7 IS THE ONLY ENTRY POINT.                                     02000019
*   SEE INPUT FOR ASSOCIATED PARAMETER LIST.                            02100019
*INPUT                                                                  02200019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING       02300019
*   THE ADDRESSES OF THE AVT AND THE CIB.                               02400019
*OUTPUT                                                                 02500019
*   N/A                                                                 02600019
*EXTERNAL REFERENCES                                                    02700019
*        IHKAFI - TO MANIPULATE GLOBAL FILES                            02800019
*        IHKMSG - ENTRY POINTS:  IHKMSG AND IHKMSG02                    02900019
*        TO SEND  MESSAGES TO THE CENTRAL CONSOLE.                      03000019
*EXITS, NORMAL                                                          03100019
*        RETURN TO CALLER WITH ZERO IN REGISTER 15                      03200019
*EXITS, ERROR                                                           03300019
*        ERROR MESSAGE IS SENT TO CENTRAL CONSOLE                       03400019
*        RETURN IS MADE TO CALLER WITH ZERO IN REGISTER 15              03500019
*TABLES/WORK AREAS                                                      03600019
*   SAVEAREA                                                            03700019
*   TUB - CONTAINED IN MODULE.                                          03800019
*   TUBUFFAD - ADDRESS OF USER BUFFER                                   03900019
*   AFIO CONTROL INFORMATION                                            04000019
*   USER BUFFER                                                         04100019
*   CIB - CONTAINS COMMAND AND OPERANDS                                 04200019
*   UVR - CONTAINS USER INFORMATION                                     04300019
*   AVT                                                                 04400019
*ATTRIBUTES                                                             04500019
*   NON-RESIDENT                                                        04600019
*   SERIALLY REUSABLE                                                   04700019
*********************************************************************** 04800019
         EJECT                                                          04900019
*********************************************************************** 05000019
*   REGISTER EQUATES                                                    05100019
*********************************************************************** 05200019
R0       EQU   0                                                        05300019
R1       EQU   1                                                        05400019
R2       EQU   2                        WORK REGISTER                   05500019
R3       EQU   3                        BRANCH FROM AFIO, RETURN 0      05600019
R4       EQU   4                        BRANCH FROM AFIO, RETURN 4      05700019
R5       EQU   5                        BRANCH FROM AFIO                05800019
RUVR     EQU   6                        UVR BASE IN USER BUFFER         05900019
R7       EQU   7                        INTERNAL LINKAGE                06000019
RCIB     EQU   8                        CIB BASE                        06100019
RTUB     EQU   9                        TUB BASE                        06200019
RCCT     EQU   10                       CCT BASE                        06300019
RAVT     EQU   11                       AVT BASE                        06400019
RBASE    EQU   12                       IHKCC7 BASE                     06500019
R13      EQU   13                                                       06600019
R14      EQU   14                                                       06700019
R15      EQU   15                                                       06800019
*********************************************************************** 06900019
*   OTHER EQUATES                                                       07000019
*********************************************************************** 07100019
USRIDCMD EQU   X'84'                    USERID COMMAND VERB IN CIB      07200019
X0A      EQU   10                       MAXIMUM INSERT FOR MSGS         07300019
DOLLAR   EQU   C'$'                     DOLLAR-VALID FOR USERID,PASS    07400019
AT       EQU   C'@'                     AT SIGN-VALID FOR USERID,PASSW  07500019
POUND    EQU   C'#'                     POUND-VALID FOR USERID,PASSW    07600019
LNGKYPAS EQU   8                        LENGTH FOR PASSWORD,TUBGBLKY    07700019
USRIDLNG EQU   7                        LENGTH OF USERID                07800019
PASSWDLN EQU   X'8'                     PASSWORD LENGTH                 07900019
GBLF2    EQU   2                        UVR GLOBAL FILE                 08000019
HIBIT    EQU   X'80'                                                    08100019
X1       EQU   1                                                        08200019
X00      EQU   X'00'                                                    08300019
HEXA     EQU   C'A'                                                     08400019
HEXZ     EQU   C'Z'                                                     08500019
BLANK    EQU   C' '                                                     08600019
HEX09    EQU   C'9'                                                     08700019
ALLBITS  EQU   X'FF'                                                    08800019
COMMA    EQU   C','                                                     08900019
RPAREN   EQU   C')'                                                     09000019
LPAREN   EQU   C'('                                                     09100019
         EJECT                                                          09200019
*********************************************************************** 09300019
*   SET UP BASE REGISTERS, SAVEAREA                                     09400019
*********************************************************************** 09500019
*                                                                       09600019
         USING IHKCC7,RBASE                                             09700019
         USING AVTDSECT,RAVT                                            09800019
         USING CCTDSECT,RCCT                                            09900019
         USING TUBDSECT,RTUB                                            10000019
         USING CIBBASE,RCIB                                             10100019
         USING UVRDSECT,RUVR                                            10200019
*                                                                       10300019
         SAVE  (14,12),,IHKCC7-11/11/69                                 10400019
         LR    RBASE,R15                SET UP BASE REGISTER            10500019
         L     RAVT,0(R1)               AVT ADDRESS PASSED              10600019
         L     RCIB,4(R1)               CIB ADDRESS PASSED              10700019
         ST    R13,SAVEAREA+4           SAVE CALLERS SAVEAREA ADDR      10800019
         LA    R1,SAVEAREA                                              10900019
         ST    R1,8(R13)                SAVE SAVEAREA IN CALLERS        11000019
         LR    R13,R1                                                   11100019
         L     RCCT,IHKYYCCT            INITIALIZE CCT                  11200019
         LA    RTUB,LOCTUB              LOAD TUB BASE                   11300019
*                                                                       11400019
*  INITIALIZE                                                           11500019
*                                                                       11600019
         LH    R4,CIBDATLN              COMPUTE END ADDR OF OP          11700019
         LA    R15,CIBDATA-1                                            11800019
         AR    R15,R4                                                   11900019
         ST    R15,LASTCIB              LAST CHARACTER IN CIB           12000019
         L     RUVR,TUBUFFAD            READ UVR IN USER BUFFER         12100019
         MVI   OPRSW,X00                SET SWITCH TO ZERO              12200019
*********************************************************************** 12300019
*                                                                       12400019
*   CHECK FOR USERID                                                    12500019
*                                                                       12600019
*********************************************************************** 12700019
CKVERB   CLI   CIBVERB,USRIDCMD         IS THIS USERID COMMAND          12800019
         BNE   RETURN0                  BR = NO, RETURN                 12900019
*********************************************************************** 13000019
*                                                                       13100019
*  USERID COMMAND                                                       13200019
*                                                                       13300019
*********************************************************************** 13400019
CKUSRCMD LA    R1,USERIDC                                               13500019
         ST    R1,CMDADDR               COMMAND TO INSERT IN MSG        13600019
         LA    R1,USRDCC7               TABLE OF OPERANDS               13700019
         BAL   R14,FINDSUBR                                             13800019
         B     USRDBR(R15)              BRANCH TO RTN TO HANDLE OP      13900019
         EJECT                                                          14000019
*********************************************************************** 14100019
*                                                                       14200019
*  USERID,R(ESUME)                                                      14300019
*                                                                       14400019
*********************************************************************** 14500019
USRRESUM NI    CCTOPT,CCTSUPF           TURN OFF SUPPRESS BIT           14600019
         LA    R1,MRESUM                USERIDS RESUMED MSG             14700019
         B     INSNOPAR                 GO SEND MSG                     14800019
*********************************************************************** 14900019
*                                                                       15000019
*  USERID,S(UPPRESS                                                     15100019
*                                                                       15200019
*********************************************************************** 15300019
USRSUPRS OI    CCTOPT,CCTSUP            TURN ON SUPPRESS BIT            15400019
         LA    R1,MSUPRS                USERIDS SUPPRESSED MSG          15500019
         B     INSNOPAR                 GO SEND MSG                     15600019
*********************************************************************** 15700019
*                                                                       15800019
*  USERID,A(DD)=                                                        15900019
*                                                                       16000019
*********************************************************************** 16100019
USRADD   OI    OPRSW,OPRADD             SET SWITCH-ADD                  16200019
         B     CKPAREN                  GO CHECK PAREN                  16300019
*********************************************************************** 16400019
*                                                                       16500019
*  USERID,D(ELETE)=                                                     16600019
*                                                                       16700019
*********************************************************************** 16800019
USRDEL   OI    OPRSW,OPRDEL             SET SWITCH-DELETE               16900019
CKPAREN  LA    R3,1(R3)                 NOW POINTS AT LEFT PAREN        17000019
         CLI   0(R3),LPAREN             IS IT LEFT PAREN                17100019
         BNE   NOPAREN                  BR=NO,INVALID                   17200019
         LR    R14,R3                   POINTS AT LEFT PAREN            17300019
CKNEXT   LA    R14,X1(R14)              LOOK FOR RIGHT PAREN            17400019
         CLI   0(R14),RPAREN                                            17500019
         BE    CKLAST                   BR= RIGHT PAREN                 17600019
         CL    R14,LASTCIB              IS THIS END OF CIB              17700019
         BL    CKNEXT                   BR= NO                          17800019
NOPAREN  LA    R1,MNOPAREN              PAREN NOT BALANCED              17900019
         B     CKCIBLNG                 GO SEND ILLEGAL DELIMITER MSG   18000019
*                                                                       18100019
*   RIGHT PAREN FOUND- CHECK FOR ANY OPERANDS AFTER                     18200019
*                                                                       18300019
CKLAST   CL    R14,LASTCIB              IS IT LAST CHARACTER            18400019
         BE    CKPASSWD                 BR= YES, VALID                  18500019
         L     R15,LASTCIB              OPERAND AFTER RIGHT PAREN       18600019
         SR    R15,R14                                                  18700019
         STC   R15,0(R14)               STORE LENGTH OF INVALID OP      18800019
         LA    R1,MNOTFND               OP INVALID/NOT FOUND MSG        18900019
         LA    R2,X0A                   CHECK FOR GREATER THAN 10       19000019
         CR    R15,R2                                                   19100019
         BNH   INSCMD2                  BR= NOT GREATER THAN 10         19200019
         STC   R2,0(R14)                STORE 10                        19300019
         B     INSCMD2                                                  19400019
         EJECT                                                          19500019
*********************************************************************** 19600019
*                                                                       19700019
*   BOTH PAREN FOUND- CHECK PASSWORD, USERID FOR LENGTH, VALID CHAR     19800019
*                                                                       19900019
*********************************************************************** 20000019
CKPASSWD LR    R14,R3                   LEFT PAREN                      20100019
         L     R1,LASTCIB                                               20200019
         BCTR  R1,0                     POINT TO END OF PASSWORD        20300019
CKPASWD2 LA    R14,1(R14)               LOOK FOR COMMA                  20400019
         CR    R14,R1                   IS IT AT END OF CIB             20500019
         BH    OPNFND                   BR=YES, NO COMMA FOUND          20600019
         CLI   0(R14),COMMA             IS THIS COMMA                   20700019
         BNE   CKPASWD2                 BR= NO                          20800019
         SR    R1,R14                   LENGTH OF PASSWORD              20900019
         STC   R1,0(R14)                STORE LENGTH WHERE COMMA IS     21000019
         ST    R14,ADRPASSW             SAVE ADDRESS OF PASSWORD        21100019
         BCTR  R14,0                                                    21200019
         ST    R14,LASTCIB              LAST CHAR OF USERID             21300019
         LA    R14,X1(R14)                                              21400019
         OI    OPRSW,OPRPASSN           SET SWITCH FOR PASSWORD CHECK   21500019
         LA    R15,PASSWDLN             LENGTH OF PASSWORD              21600019
         LA    R5,PASSWORD              PASSWORD WILL BE STORED HERE    21700019
         BAL   R7,CKUSRPAS              CHECK LENGTH, VALID CHAR        21800019
         NI    OPRSW,OPRPASSF           TURN OFF PASSWORD SWITCH        21900019
*********************************************************************** 22000019
*                                                                       22100019
*   CHECK USERID LENGTH                                                 22200019
*                                                                       22300019
*********************************************************************** 22400019
USRIDVAL L     R1,LASTCIB               LAST IN USERID-COMPUTE LENGTH   22500019
         SR    R1,R3                    TEST VALID USERID               22600019
         ST    R3,TUBPARM4              SAVE ADDRESS OF USERID          22700019
         ST    R3,TUBPARM5                                              22800019
         STC   R1,0(R3)                 STORE USERID LENGTH             22900019
         LA    R15,USRIDLNG             VALID USERID LENGTH             23000019
         LA    R5,TUBGBLKY              USERID WILL BE STORED HERE      23100019
         LR    R14,R3                                                   23200019
         BAL   R7,CKUSRPAS              CHECK LENGTH, VALID CHAR        23300019
*********************************************************************** 23400019
*                                                                       23500019
*  FIND UVR FOR THIS USER                                               23600019
*                                                                       23700019
*********************************************************************** 23800019
FINDUVR  TM    OPRSW,OPRADD             IS THIS ADD                     23900019
         BZ    GETUVR                   NO- DO NOT CHECK COUNT          24000019
         SR    R1,R1                                                    24100019
         CH    R1,CCTUSERS              CHECK IF ANY MORE ALLOWED       24200019
         BE    MAXUSERS                 BR= NO                          24300019
GETUVR   OI    OPRSW,OPRENDUP           SET SWITCH- ENDUP NECESSARY     24400019
         OI    TUBAFISW,TUBFCTLN        SET TO READ INTO USER BUFFER    24500019
         ST    RUVR,TUBRAFBF            READ UVR INTO USER BUFFER       24600019
         MVI   GBLNUMFS,GBLF2           UVR GLOBAL FILE                 24700019
         LA    R4,CKENDUP1              0    FOUND                      24800019
         LA    R5,USRNFND               4    NOT FOUND                  24900019
         LA    R1,ADDRTUB(R13)                                          25000019
         RPOINT B,R,FTYPE=XGBL          POINT BEFORE, RETRIEVE          25100019
         B     RTRNAFI(R15)             CHECK IF FOUND                  25200019
*********************************************************************** 25300019
*                                                                       25400019
*  NOT FOUND- CHECK FOR USERID A=                                       25500019
*                                                                       25600019
*********************************************************************** 25700019
USRNFND  TM    OPRSW,OPRADD                                             25800019
         BZ    INVALUSR                 NOT ADD=, IS INVALID USERID     25900019
         BAL   R7,CKENDUP               GO ENDUP                        26000019
         MVI   UVRFMAIN,X00             INITIALIZE NEW UVR              26100019
         MVC   UVRFMAIN+1(87),UVRFMAIN  CLEAR TO ZEROS                  26200019
         MVC   UVRUSRID,TUBGBLKY        USERID                          26300019
         MVC   UVRPASSW,PASSWORD        PASSWORD                        26400019
         MVC   UVRDDNAM,BLANKS          CLEAR DDNAME TO BLANKS          26500019
         LA    R4,INSERTUV              RETURN 0 AND 4                  26600019
         LR    R5,R4                                                    26700019
         LA    R1,ADDRTUB(R13)          POINT TO CORRECT PLACE          26800019
         RPOINT A,NR,KEY=HIEQ,FTYPE=XGBL POINT AFTER NEXT LOWER KEY     26900019
         B     RTRNAFI(R15)                                             27000019
*********************************************************************** 27100019
*                                                                       27200019
*  INSERT UVR RECORD                                                    27300019
*                                                                       27400019
*********************************************************************** 27500019
INSERTUV LA    R4,USRADDED              0    INSERTED                   27600019
         LA    R5,AAOUTSP               4    OUT OF SPACE- AA           27700019
         LA    R1,ADDRTUB(R13)                                          27800019
         INSERT S,A,FTYPE=GBL           INSERT NEW UVR                  27900019
         B     RTRNAFI(R15)                                             28000019
*********************************************************************** 28100019
*                                                                       28200019
*  DECREASE NUMBER OF USERS ALLOWED TO BE ADDED                         28300019
*                                                                       28400019
*********************************************************************** 28500019
USRADDED LH    R1,CCTUSERS                                              28600019
         BCTR  R1,0                                                     28700019
         STH   R1,CCTUSERS                                              28800019
         LA    R1,MUSRADD               MSG- USER ADDED                 28900019
         B     INS1PRM2                 GO SEND MSG, RETURN             29000019
*********************************************************************** 29100019
*                                                                       29200019
*   UVR RECORD FOUND- CHECK FOR USERID COMMAND                          29300019
*                                                                       29400019
*********************************************************************** 29500019
CKENDUP1 TM    OPRSW,OPRADD             IS IT USERID A=                 29600019
         BO    PREVUSER                 YES- GO ENDUP, SEND MSG         29700019
         CLC   PASSWORD,UVRPASSW        ARE PASSWORDS EQUAL             29800019
         BNE   INVALPAS                 BR=NO                           29900019
         TM    UVRCNTL1,UVRACTVN        IS USER ACTIVE                  30000019
         BO    DELACTV                  IF USER ACTIVE, MAY NOT DELETE  30100019
         LA    R4,DELENDUP              0,4- GO ENDUP                   30200019
         LR    R5,R4                                                    30300019
         LA    R1,ADDRTUB(R13)          NOT ACTIVE- DELETE              30400019
         RDELETE NXK,FTYPE=GBL          DELETE USER                     30500019
         B     RTRNAFI(R15)                                             30600019
*********************************************************************** 30700019
*                                                                       30800019
*  DELETE SUCCESSFUL                                                    30900019
*                                                                       31000019
*********************************************************************** 31100019
DELENDUP LA    R15,1                    INCREASE NUMBER OF USERS        31200019
         AH    R15,CCTUSERS                                             31300019
         STH   R15,CCTUSERS                                             31400019
         LA    R1,MDELUSR               USER DELETED MSG                31500019
         B     INS1PRM2                 GO SEND MSG                     31600019
         EJECT                                                          31700019
*********************************************************************** 31800019
*                                                                       31900019
*   SUPPLIED ERROR MESSAGES                                             32000019
*                                                                       32100019
*********************************************************************** 32200019
*                                                                       32300019
*  GETMAIN FAIL                                                         32400019
*                                                                       32500019
SNDOUTSP LA    R1,OUTSP                                                 32600019
         B     INSNOPRN                                                 32700019
*                                                                       32800019
*  ACTIVE AREA I/O ERROR                                                32900019
*                                                                       33000019
AAIOERR  LA    R1,MSGIOER                                               33100019
INSNOPRN OI    OPRSW,OPRERRMS                                           33200019
INSNOPAR ST    R1,TUBPARM3                                              33300019
         MVI   TUBPARM3,HIBIT           NO INSERTIONS                   33400019
         LA    R7,RETURN0                                               33500019
         B     SENDMSGA                                                 33600019
*********************************************************************** 33700019
*                                                                       33800019
*   SYSTEM ERROR MESSAGES                                               33900019
*                                                                       34000019
*********************************************************************** 34100019
*                                                                       34200019
*   AA OUT OF SPACE                                                     34300019
*                                                                       34400019
AAOUTSP  LA    R1,MAAOUTSP                                              34500019
         B     INSNOPAR                                                 34600019
*                                                                       34700019
*  OPERAND INVALID/MISSING                                              34800019
*    INSERT FIRST TEN CHAR IN MSG                                       34900019
*                                                                       35000019
OPNFND   LA    R1,MNOTFND                                               35100019
CKCIBLNG CLI   CIBDATLN+1,X0A           CK FOR LESS THAN TEN            35200019
         BL    INSCMDOP                                                 35300019
         MVI   CIBDATLN+1,X0A                                           35400019
INSCMDOP LA    R14,CIBDATLN+1                                           35500019
INSCMD2  MVC   TUBPARM4,CMDADDR         INSERT COMMAND                  35600019
INS2PARM ST    R14,TUBPARM5                                             35700019
INS2PRM2 MVI   TUBPARM5,HIBIT           TWO INSERTIONS                  35800019
         B     SENDMSG0                                                 35900019
*                                                                       36000019
*   USERID PREVIOUSLY ASSIGNED                                          36100019
*                                                                       36200019
PREVUSER LA    R1,MPRVUSR                                               36300019
INS1PRM2 MVI   TUBPARM4,HIBIT           ONE INSERTION                   36400019
         B     SENDMSG0                                                 36500019
*                                                                       36600019
*  USERID D=,  USER ACTIVE                                              36700019
*                                                                       36800019
DELACTV  LA    R1,MUSRACTV                                              36900019
         B     INS1PRM2                 ONE INSERTION                   37000019
*                                                                       37100019
*  INVALID USERID                                                       37200019
*                                                                       37300019
INVUSRA  LA    R15,X0A                                                  37400019
         CR    R1,R15                   CHECK FOR MORE THAN 10          37500019
         BNH   INVALUSR                                                 37600019
         STC   R15,0(R3)                INSERT 10                       37700019
INVALUSR LA    R1,MINVUSR                                               37800019
         MVC   TUBPARM4,CMDADDR         INSERT COMMAND                  37900019
         B     INS2PRM2                 TWO INSERTIONS                  38000019
*                                                                       38100019
*   MAX USERS- NO MORE ALLOWED                                          38200019
*                                                                       38300019
MAXUSERS LA    R1,MXUSRS                                                38400019
         B     INS1PRM2                                                 38500019
*                                                                       38600019
*   INVALID PASSWORD                                                    38700019
*                                                                       38800019
INVPASA  LA    R15,X0A                                                  38900019
         CR    R1,R15                                                   39000019
         BNH   INVALPAS                                                 39100019
         STC   R15,0(R14)                                               39200019
INVALPAS LA    R1,MINVPASS                                              39300019
         L     R14,ADRPASSW                                             39400019
         ST    R14,TUBPARM4                                             39500019
         B     INS1PRM2                 ONE INSERTION                   39600019
         EJECT                                                          39700019
*********************************************************************** 39800019
*                                                                       39900019
*  CHECK IF ENDUP NEEDED                                                40000019
*                                                                       40100019
*********************************************************************** 40200019
CKENDUP  LR    R4,R7                                                    40300019
         LR    R5,R7                                                    40400019
         TM    OPRSW,OPRENDUP                                           40500019
         BZ    RTRNAFI                                                  40600019
         MVI   GBLNUMFS,GBLF2                                           40700019
         NI    OPRSW,OPRENDF                                            40800019
         LA    R1,ADDRTUB(R13)                                          40900019
         ENDUP FTYPE=GBL                                                41000019
         B     RTRNAFI(R15)             CHECK IF FOUND                  41100019
RTRNAFI  B     0(R4)                    RETURN 0                        41200019
         B     0(R5)                    RETURN 4                        41300019
         B     SNDOUTSP                 8                               41400019
         B     AAIOERR                  12                              41500019
*********************************************************************** 41600019
*                                                                       41700019
*   CHECK LENGTH, VALID CHARACTERS OF PASSWORD AND USERID               41800019
*     VALID CHARACTERS ARE ALPHABETIC, NUMERIC, DOLLAR, AT,             41900019
*     AND POUND SIGNS.  MUST BEGIN WITH ALPHABETIC.                     42000019
*   STORE IN ADDRESS SPECIFIED IN REGISTER 5                            42100019
*                                                                       42200019
*********************************************************************** 42300019
CKUSRPAS LTR   R1,R1                                                    42400019
         BZ    CKINVAL                  BR= LENGTH ZERO                 42500019
         CR    R1,R15                                                   42600019
         BH    CKINVALA                 BR= TOO LONG                    42700019
         MVC   0(LNGKYPAS,R5),BLANKS    MOVE BLANKS IN SPECIFIED LOC    42800019
         BCTR  R1,0                                                     42900019
         EX    R1,MVCPASKY              MOVE TO PASSWORD OR TUBGBLKY    43000019
         CLI   0(R5),HEXA                                               43100019
         BL    CKINVAL                  BR= FIRST NOT ALPHABETIC        43200019
         CLI   0(R5),HEXZ                                               43300019
         BH    CKINVAL                  BR= FIRST NOT ALPHABETIC        43400019
NXTCHAR  CLI   0(R5),BLANK              CHECK CHARACTERS                43500019
         BE    CKALPRTN                 BR= BLANK, FINISHED             43600019
         CLI   0(R5),DOLLAR                                             43700019
         BE    CKALPRTN                 BR= DOLLAR SIGN                 43800019
         CLI   0(R5),AT                                                 43900019
         BE    CKALPRTN                 BR= AT SIGN                     44000019
         CLI   0(R5),POUND                                              44100019
         BE    CKALPRTN                 BR= POUND SIGN                  44200019
         CLI   0(R5),HEXA               CHECK FOR LESS THAN A           44300019
         BL    CKINVAL                  BR= INVALID CHAR                44400019
         CLI   0(R5),HEX09              CHECK FOR GREATER THAN 9        44500019
         BH    CKINVAL                  BR= INVALID                     44600019
         LA    R5,X1(R5)                UPDATE TO NEXT CHAR             44700019
         BCT   R15,NXTCHAR              BR= MORE TO BE CHECKED          44800019
CKALPRTN BR    R7                       ALL CORRECT- RETURN             44900019
CKINVALA TM    OPRSW,OPRPASSN           IS THIS PASSWORD                45000019
         BO    INVPASA                  BR= PASSWORD TOO LONG           45100019
         B     INVUSRA                  USERID TOO LONG                 45200019
CKINVAL  TM    OPRSW,OPRPASSN           IS THIS PASSWORD                45300019
         BO    INVALPAS                 BR= PASSWORD INVALID            45400019
         B     INVALUSR                 USERID INVALID                  45500019
*                                                                       45600019
MVCPASKY MVC   0(0,R5),1(R14)                                           45700019
*                                                                       45800019
         EJECT                                                          45900019
*********************************************************************** 46000019
*                                                                       46100019
*  SUBROUTINE TO SEARCH FOR SPECIFIED SET OF CHARACTERS                 46200019
*        CHECKS FOR END OF CIB                                          46300019
*        AT ENTRY REGISTER ONE POINTS TO TABLE DEFINING VALID CHARACTER 46400019
*        STRINGS, AND CHARACTER (OR END OF CIB) THAT MUST FOLLOW        46500019
*        RETURNS WITH REGISTER 15 CONTAINING BRANCH CODE (FROM TABLE)   46600019
*        AND REGISTER 3 POINTS AT CHAR AFTER OP IN CIB (IF ANY)         46700019
*                                                                       46800019
*********************************************************************** 46900019
FINDSUBR SR    R15,R15                                                  47000019
GETLNG   IC    R15,0(R1)                LENGTH FROM TABLE-REG 15        47100019
         LA    R1,1(R1)                 REG1 POINTS AT OP IN TABLE      47200019
         CH    R15,CIBDATLN                                             47300019
         BH    NXTABLE                  BR= OP IN CIB SHORTER           47400019
         LA    R3,CIBDATA               REG3 POINTS AT OP IN CIB        47500019
         BCTR  R15,0                                                    47600019
         EX    R15,CLCOP                COMPARE OP TO OP IN TABLE       47700019
         LA    R15,1(R15)               RESTORE TO OP LENGTH IN TABLE   47800019
         BNE   NXTABLE                  BR= NOT OP IN TABLE             47900019
         AR    R1,R15                   OP EQUAL-CK NEXT CHAR           48000019
         CLI   0(R1),X00                                                48100019
         BE    CKCIBEND                 BR= MUST BE END OF CIB          48200019
         CH    R15,CIBDATLN             MUST BE ANOTHER CHAR            48300019
         BNL   NXTABLE1                 BR= NOT ANOTHER IN CIB          48400019
         AR    R3,R15                                                   48500019
         CLC   0(1,R3),0(R1)            IS IT CHAR IN TABLE             48600019
         BNE   NXTABLE1                 BR= NO, LOOK AT NEXT IN TABLE   48700019
*                                                                       48800019
*   OPERAND VALID                                                       48900019
*                                                                       49000019
GETBRNCH LA    R1,1(R1)                 IS CHAR/ GET BRANCH FROM TABLE  49100019
         IC    R15,0(R1)                                                49200019
         BR    R14                      RETURN                          49300019
*                                                                       49400019
*  POINT TO NEXT ENTRY IN TABLE                                         49500019
*                                                                       49600019
NXTABLE  AR    R1,R15                                                   49700019
NXTABLE1 LA    R1,2(R1)                 NOW POINTS AT NEXT              49800019
         TM    0(R1),ALLBITS            ANY MORE IN TABLE               49900019
         BO    OPNFND                   BR= NO MORE IN TABLE            50000019
         B     GETLNG                   GO CHECK NEXT                   50100019
*                                                                       50200019
CKCIBEND CH    R15,CIBDATLN             HAS TO BE END OF OP             50300019
         BE    GETBRNCH                 BR= IS END                      50400019
         B     NXTABLE1                 IS NOT END OF OP, SEE IF MORE   50500019
*                                                                       50600019
         EJECT                                                          50700019
*********************************************************************** 50800019
*   SUBROUTINE TO SEND MESSAGES                                         50900019
*   SENDMSG0- SETS RETURN TO ZERO                                       51000019
*   SENDMSG- AT LEAST ONE INSERTION                                     51100019
*   SENDMSGA- NO INSERTIONS                                             51200019
*                                                                       51300019
*********************************************************************** 51400019
SENDMSG0 LA    R7,RETURN0                                               51500019
SENDMSG  ST    R1,TUBPARM3              PARAM 3 = ADDR OF MSG           51600019
SENDMSGA ST    RTUB,TUBPARM1            PARAM 1 = ADDR OF TUB           51700019
         LR    R2,R7                                                    51800019
         BAL   R7,CKENDUP               GO ENDUP IF NECESSARY           51900019
         LR    R7,R2                                                    52000019
         LA    R1,ZEROES                                                52100019
         ST    R1,TUBPARM2              PARAM 2 = ADDR OF ZERO          52200019
         MVC   0(1,R1),CIBCONID         HIGH ORDER BYTE=CONSOLE ID      52300019
         TM    OPRSW,OPRERRMS           IS THIS SEND A SUPPLIED MSG     52400019
         BZ    ENTRMSG                  BR = NO                         52500019
         L     R15,IHKYMSG2             GO TO IHKMSG02                  52600019
         B     GETPARM1                                                 52700019
ENTRMSG  L     R15,IHKYYMSG             GO TO IHKMSG                    52800019
GETPARM1 LA    R1,TUBPARM1                                              52900019
         BALR  R14,R15                                                  53000019
         B     MSGRTN(R15)                                              53100019
MSGRTN   B     0(R7)                    0    MSG SENT                   53200019
         B     0(R7)                    4    TP LINE ERROR (NOT APPLIC) 53300019
         B     SNDOUTSP                 8    GETMAIN FAIL               53400019
         B     AAIOERR                  12   AA I/O ERROR               53500019
         B     0(R7)                    16   NOT USED                   53600019
         B     0(R7)                    20   NOT USED                   53700019
         B     0(R7)                    24   NOT USED                   53800019
*                                                                       53900019
*                                                                       54000019
*  EXECUTED INSTRUCTIONS                                                54100019
*                                                                       54200019
CLCOP    CLC   0(0,R1),0(R3)                                            54300019
*                                                                       54400019
*                                                                       54500019
*   RETURN WITH RETURN CODE 0                                           54600019
*                                                                       54700019
RETURN0  L     R13,4(R13)                                               54800019
         RETURN (14,12),,RC=0                                           54900019
*                                                                       55000019
         EJECT                                                          55100019
*********************************************************************** 55200019
*                                                                       55300019
*  MESSAGE CODES                                                        55400019
*                                                                       55500019
*********************************************************************** 55600019
         DS    0F                                                       55700019
MUSRACTV DC    X'20',C'201'             ACTIVE USER                     55800019
MINVUSR  DC    X'20',C'202'             USERID INVALID/NOT FOUND        55900019
MPRVUSR  DC    X'20',C'204'             USERID PREVIOUSLY ASSIGNED      56000019
MINVPASS DC    X'20',C'205'             INVALID PASSSWORD               56100019
MDELUSR  DC    X'20',C'207'             USER DELETED                    56200019
MUSRADD  DC    X'20',C'208'             USER ADDED                      56300019
MSUPRS   DC    X'20',C'221'             LOGONS SUPPRESSED               56400019
MNOTFND  DC    X'20',C'226'             OP MISSING/INVALID              56500019
MRESUM   DC    X'20',C'229'             LOGONS RESUMED                  56600019
MAAOUTSP DC    X'20',C'240'             AA OUT OF SPACE                 56700019
MXUSRS   DC    X'20',C'252'             USER LIST FULL                  56800019
MNOPAREN DC    X'20',C'254'             PAREN MISSING USERID A= OR D=   56900019
*********************************************************************** 57000019
*   SUPPLIED ERROR MESSAGES                                             57100019
*********************************************************************** 57200019
MSGIOER  WTO   'IHK270I ACTIVE AREA I/O ERROR',MF=L,ROUTCDE=(2,4,10),  X57300019
               DESC=(4),MCSFLAG=(REG0)                                  57400019
OUTSP    WTO   'IHK219I OUT OF MAIN STORAGE',MF=L,ROUTCDE=(2),         X57500019
               DESC=(4),MCSFLAG=(REG0)                                  57600019
         EJECT                                                          57700019
*********************************************************************** 57800019
*                                                                       57900019
* TABLES PASSED TO FINDSUBR                                             58000019
*   FORMAT- LENGTH OF OPERAND(ONE BYTE), OPERAND (VARIABLE LENGTH),     58100019
*   CHARACTER THAT MUST FOLLOW OPERAND OR X'00' TO INDICATE MUST        58200019
*   BE END OF CIB (ONE BYTE), BRANCH CODE(ONE BYTE)                     58300019
*   LAST ENTRY IN TABLE FOLLOWED BY X'FF'                               58400019
*                                                                       58500019
*********************************************************************** 58600019
USRDCC7  DC    X'01',C'S',X'0',X'0'                                     58700019
         DC    X'08',C'SUPPRESS',X'0',X'00'                             58800019
         DC    X'01',C'R',X'0',X'04'                                    58900019
         DC    X'06',C'RESUME',X'0',X'04'                               59000019
         DC    X'01',C'A',C'=',X'08'                                    59100019
         DC    X'03',C'ADD',C'=',X'08'                                  59200019
         DC    X'01',C'D',C'=',X'0C'                                    59300019
         DC    X'06',C'DELETE',C'=',X'0C'                               59400019
         DC    X'FF'                                                    59500019
*                                                                       59600019
*   BRANCH TABLES REFERRED BY USRDCC7                                   59700019
*                                                                       59800019
USRDBR   B     USRSUPRS                 USERID S(UPPRESS)               59900019
         B     USRRESUM                 USERID R(ESUME)                 60000019
         B     USRADD                   USERID A(DD)=                   60100019
         B     USRDEL                   USERID D(ELETE)=                60200019
         EJECT                                                          60300019
*********************************************************************** 60400019
*                                                                       60500019
*   WORK/SAVE AREAS- TUB USED FOR WORK AREA                             60600019
*                                                                       60700019
*********************************************************************** 60800019
SAVEAREA DC    18F'0'                                                   60900019
ADDRTUB  EQU   56                       ADDR OF TUB- REG 9              61000019
         IHKCDSCT  TUB=YES                                              61100019
IHKCC7   CSECT                                                          61200019
LOCTUB   DS    0D                                                       61300019
         DC    F'0'                                                     61400019
         DC    A(USRBUFR)                                               61500019
         DC    320X'00'                                                 61600019
         ORG   LOCTUB+8                                                 61700019
PASSWORD DS    D                                                        61800019
LASTCIB  DS    F                                                        61900019
CMDADDR  DS    F                                                        62000019
ADRPASSW DS    F                                                        62100019
ZEROES   DC    F'0'                                                     62200019
BLANKS   DC    C'        '                                              62300019
*                                                                       62400019
*  SWITCHES                                                             62500019
*                                                                       62600019
OPRSW    DS    C                        OPERAND SWITCH                  62700019
OPRINVAL EQU   X'80'                                                    62800019
OPRADD   EQU   X'20'                    USERID ADD                      62900019
OPRDEL   EQU   X'10'                    USERID DELETE                   63000019
OPRUSRID EQU   X'08'                    USERID SPECIFIED                63100019
OPRENDUP EQU   X'04'                    ENDUP NECESSARY                 63200019
OPRENDF  EQU   X'FB'                    TURN ENDUP SWITCH OFF           63300019
OPRERRMS EQU   X'02'                    SUPPLIED MESSAGE                63400019
OPRPASSN EQU   X'01'                                                    63500019
OPRPASSF EQU   X'FE'                                                    63600019
*                                                                       63700019
SHOW     DC    X'04',C'SHOW'                                            63800019
USERIDC  DC    X'06',C'USERID'                                          63900019
         ORG   LOCTUB+TUBSIZE                                           64000019
         DS    0D                                                       64100019
USRBUFR  DS    CL88                                                     64200019
CIBBASE  DSECT                                                          64300019
         IEZCIB                                                         64400019
         IHKCDSCT         AVT=YES,CCT=YES,UVR=YES                       64500019
         TUBEQU                                                         64600019
         RAFKNBX TYPE=DSECT                                             64700019
         END                                                            64800019
