CC8      TITLE 'IHKCC8 - CENTRAL COMMAND PROCESSOR'                     00100019
IHKCC8   CSECT                                                          00200019
*********************************************************************** 00300019
*STATUS                                                                 00400019
*   CHANGE LEVEL 0                                                      00500019
*FUNCTION                                                               00600019
*   IHKCC8 CHECKS THE VERB AND THE COMMAND OPERANDS.  IF ANY OPERAND  * 00700019
*   IS INVALID, AN ERROR MESSAGE IS SENT TO THE CENTRAL CONSOLE AND   * 00800019
*   RETURN IS MADE TO THE CALLING ROUTINE.                              00900019
*   THE FOLLOWING OPERANDS ARE VALID FOR A MSG COMMAND:               * 01000019
*   1. M='TEXT' - SEND A MESSAGE COMPOSED OF THE SPECIFIED TEXT TO    * 01100019
*   ALL ACTIVE USERS.                                                 * 01200019
*   2. M='TEXT',U=USERID - SEND THE MESSAGE COMPOSED OF THE SPECIFIED * 01300019
*   TEXT TO THE SPECIFIED USER IF HE IS ACTIVE.                       * 01400019
*   3. M='TEXT',U=USERID,Q - SEND THE MESSAGE COMPOSED OF THE         * 01500019
*   SPECIFIED TEXT TO THE USER SPECIFED IF HE IS ACTIVE.  OTHERWISE   * 01600019
*   PLACE IT ON THE DELAYED MESSAGE DATA SET FOR FUTURE DELIVERY.     * 01700019
*   THE OPERANDS OF THE MSG COMMAND ARE KEYWORD RATHER THAN           * 01800019
*   POSITIONAL.  A MESSAGE IS SENT TO CENTRAL TO INDICATE WHETHER OR    01900019
*   NOT THE MESSAGE WAS SENT.  THE TEXT CANNOT EXCEED FORTY CHARACTERS. 02000019
*   THE FOLLOWING OPERANDS ARE VALID FOR A SHOW COMMAND:                02100019
*   1. SHOW ACTIVE- SHOWS ALL ACTIVE USERS.  MESSAGE SHOWS USERID,      02200019
*   LINEADDRESS, AND TIME IN MINUTES SINCE LOGON.  IF THERE ARE NO      02300019
*   ACTIVE USERS, THAT IS INDICATED.                                    02400019
*   2. SHOW ACTIVE,NUMBER- SHOWS NUMBER OF ACTIVE USERS.                02500019
*ENTRY POINTS                                                           02600019
*   IHKCC8 IS THE ONLY ENTRY POINT.                                     02700019
*   SEE INPUT FOR ASSOCIATED PARAMETER LIST.                            02800019
*INPUT                                                                  02900019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING       03000019
*   THE ADDRESSES OF THE AVT AND THE CIB.                               03100019
*OUTPUT                                                                 03200019
*   N/A                                                                 03300019
*EXTERNAL REFERENCES                                                    03400019
*        IHKAFI - TO MANIPULATE GLOBAL FILES                            03500019
*        IHKMSG - ENTRY POINTS:  IHKMSG AND IHKMSG02                    03600019
*        TO SEND  MESSAGES TO THE CENTRAL CONSOLE.                      03700019
*        ENTRY POINT : IHKMSG01                                       * 03800019
*        TO SEND MESSAGES TO TERMINAL USERS.                          * 03900019
*EXITS, NORMAL                                                          04000019
*        RETURN TO CALLER WITH ZERO IN REGISTER 15                      04100019
*EXITS, ERROR                                                           04200019
*        ERROR MESSAGE IS SENT TO CENTRAL CONSOLE                       04300019
*        RETURN IS MADE TO CALLER WITH ZERO IN REGISTER 15              04400019
*TABLES/WORK AREAS                                                      04500019
*   SAVEAREA                                                            04600019
*   AVT                                                                 04700019
*   CIB - CONTAINS COMMAND AND OPERANDS                                 04800019
*   CLB- LINEADDRESS USED.                                              04900019
*   TUB - CONTAINED IN MODULE.                                          05000019
*   TUBUFFAD - ADDRESS OF USER BUFFER                                   05100019
*   USER BUFFER                                                         05200019
*   UVR - CONTAINS USER INFORMATION                                     05300019
*ATTRIBUTES                                                             05400019
*   NON-RESIDENT                                                        05500019
*   SERIALLY REUSABLE                                                   05600019
*********************************************************************** 05700019
         EJECT                                                          05800019
*********************************************************************** 05900019
*   REGISTER EQUATES                                                    06000019
*********************************************************************** 06100019
R0       EQU   0                                                        06200019
R1       EQU   1                                                        06300019
R2       EQU   2                                                        06400019
R3       EQU   3                        CURRENT OPERAND                 06500019
RNEXT    EQU   4                        NEXT OPERAND                    06600019
RLAST    EQU   5                        LAST CHARACTER IN CIB           06700019
R6       EQU   6                        WORK REGISTER                   06800019
R7       EQU   7                        USED FOR RETURN FROM MSG RTN    06900019
RCIB     EQU   8                        CIB BASE                        07000019
RTUB     EQU   9                        TUB BASE                        07100019
RCMD     EQU   10                       POINTS TO COMMAND FOR INSERT    07200019
RAVT     EQU   11                       AVT BASE                        07300019
RBASE    EQU   12                       IHKCC8 BASE                     07400019
R13      EQU   13                                                       07500019
R14      EQU   14                                                       07600019
R15      EQU   15                                                       07700019
*********************************************************************** 07800019
*   OTHER EQUATES                                                       07900019
*********************************************************************** 08000019
SHOWCMD  EQU   X'88'                    SHOW COMMAND VERB               08100019
MSGCMD   EQU   X'78'                    MSG COMMAND CODE                08200019
X0A      EQU   10                       MAX INSERT SIZE FOR MSGS        08300019
HRS24    EQU   1440                     24 HOURS- MINUTES               08400019
TXTLNG   EQU   40                       MAXIMUM LENGTH OF TEXT          08500019
USRIDLNG EQU   7                        LENGTH OF USERID                08600019
HIBIT    EQU   X'80'                                                    08700019
X00      EQU   X'00'                                                    08800019
COMMA    EQU   C','                                                     08900019
QUOTE    EQU   C''''                                                    09000019
THIRTY1  EQU   31                                                       09100019
BLANK    EQU   C' '                                                     09200019
X4       EQU   4                                                        09300019
HEX0F    EQU   X'0F'                                                    09400019
HEXF0    EQU   X'F0'                                                    09500019
X1       EQU   1                                                        09600019
ALLBITS  EQU   X'FF'                                                    09700019
         EJECT                                                          09800019
*********************************************************************** 09900019
*                                                                       10000019
*   SET UP BASE REGISTERS, SAVEAREA                                     10100019
*                                                                       10200019
*********************************************************************** 10300019
         USING IHKCC8,RBASE                                             10400019
         USING AVTDSECT,RAVT                                            10500019
         USING TUBDSECT,RTUB                                            10600019
         USING CIBBASE,RCIB                                             10700019
*                                                                       10800019
         SAVE  (14,12),,IHKCC8-11/13/69                                 10900019
         LR    RBASE,R15                SET UP BASE REGISTER            11000019
         L     RAVT,0(R1)               AVT ADDRESS PASSED              11100019
         L     RCIB,4(R1)               CIB ADDRESS PASSED              11200019
         ST    R13,SAVEAREA+4           SAVE CALLERS SAVEAREA ADDR      11300019
         LA    R1,SAVEAREA                                              11400019
         ST    R1,8(R13)                SAVE SAVEAREA IN CALLERS        11500019
         LR    R13,R1                                                   11600019
*                                                                       11700019
*  INITIALIZE                                                           11800019
*                                                                       11900019
         LA    RNEXT,CIBDATA            INITIALIZE CURRENT OP           12000019
         LA    RTUB,LOCTUB              SET UP TUB BASE                 12100019
         LA    RLAST,CIBDATA-1                                          12200019
         AH    RLAST,CIBDATLN                                           12300019
         MVI   OPRSW,X00                SET SWITCH TO ZERO              12400019
CKVERB   CLI   CIBVERB,MSGCMD           IS THIS MSG                     12500019
         BE    CKMSGCMD                 BR=YES                          12600019
         CLI   CIBVERB,SHOWCMD          NO, IS IT SHOW                  12700019
         BNE   RETURN0                  BR= NO, RETURN                  12800019
         LA    RCMD,SHOW                LOOK FOR ACTIVE OR ACTIVE,      12900019
         LA    R1,SHOWCC8               TABLE OF OPERANDS FOR SHOW      13000019
         B     FINDSUBR                                                 13100019
*********************************************************************** 13200019
*                                                                       13300019
*  MSG COMMAND - GO CHECK OPERANDS                                      13400019
*                                                                       13500019
*********************************************************************** 13600019
CKMSGCMD LA    RCMD,MSG                 POINTS TO COMMAND INSERT        13700019
         LA    R1,MSGCC8                TABLE OF OPERANDS FOR MSG       13800019
         B     FINDSUBR                 GO CHECK OPERANDS               13900019
*********************************************************************** 14000019
*                                                                       14100019
*  Q OPERAND                                                            14200019
*                                                                       14300019
*********************************************************************** 14400019
CKQ      LA    RNEXT,X1(R3)             UPDATE TO NEXT OPERAND          14500019
         B     GETNXTOP                                                 14600019
         EJECT                                                          14700019
*********************************************************************** 14800019
*                                                                       14900019
*  TEXT SPECIFIED                                                       15000019
*                                                                       15100019
*********************************************************************** 15200019
CKTEXT   LA    R3,X1(R3)                                                15300019
         ST    R3,ADRTEXT               SAVE ADDRESS OF TEXT            15400019
         CLI   0(R3),QUOTE              IS FIRST CHAR A QUOTE           15500019
         BNE   NOQUOTE                  BR= NO, INVALID                 15600019
TXTADD   LA    R1,QUOTE                                                 15700019
         BAL   R7,FINDCHAR              GO LOOK FOR NEXT QUOTE          15800019
         LTR   R1,R1                                                    15900019
         BZ    NOQUOTE                  BR= NONE FOUND                  16000019
*********************************************************************** 16100019
*                                                                       16200019
*  QUOTE FOUND- CHECK FOR END OF CIB OR DOUBLE QUOTE                    16300019
*                                                                       16400019
*********************************************************************** 16500019
NXTQUOT  LA    R2,X1(R14)               NEXT CHAR AFTER QUOTE           16600019
         CR    R14,RLAST                IS QUOTE LAST CHAR IN CIB       16700019
         BE    LSTXT                    BR= END OF CIB                  16800019
         CLI   0(R2),QUOTE                                              16900019
         BE    MVCTXT                   BR=DOUBLE QUOTE, MOVE TEXT      17000019
         CLI   0(R2),COMMA              IS THERE A COMMA AFTER QUOTE    17100019
         BNE   OPNFND                   BR= NO, INVALID                 17200019
         LA    R2,X1(R2)                IS COMMA, CHECK NEXT            17300019
         CR    R2,RLAST                 IS THERE OPERAND AFTER COMMA    17400019
         BH    OPNFND                   BR= NO, INVALID                 17500019
         B     LSTXT                                                    17600019
*********************************************************************** 17700019
*                                                                       17800019
*   DOUBLE QUOTE- REMOVE THE FIRST                                      17900019
*                                                                       18000019
*********************************************************************** 18100019
MVCTXT   BCTR  RLAST,0                                                  18200019
         LR    R1,RLAST                                                 18300019
         SR    R1,R2                    NUMBER TO MOVE                  18400019
         EX    R1,MVCTEXT               MOVE REST OF CIB TO LEFT        18500019
         LA    R1,QUOTE                                                 18600019
         B     ADDLNG                   GO LOOK FOR NEXT QUOTE          18700019
MVCTEXT  MVC   1(0,R14),2(R14)                                          18800019
*********************************************************************** 18900019
*                                                                       19000019
*   END OF TEXT- LAST QUOTE FOUND                                       19100019
*                                                                       19200019
*********************************************************************** 19300019
LSTXT    LR    RNEXT,R2                 SAVE ADDRESS OF NEXT OP, IF ANY 19400019
         LTR   R15,R15                  IS LENGTH VALID                 19500019
         BZ    INVLNG                   LENGTH OF ZERO                  19600019
         LA    R1,TXTLNG                                                19700019
         CR    R15,R1                                                   19800019
         BH    INVLNG                   TEXT TOO LONG                   19900019
         B     GETNXTOP                 GO CHECK NEXT OP                20000019
*********************************************************************** 20100019
*                                                                       20200019
*   LOOK FOR SPECIFIED CHARACTER                                        20300019
*   CHARACTER PASSED IN REGISTER ONE                                    20400019
*   REGISTER 3 POINTS TO BYTE BEFORE TEXT TO BE EXAMINED,               20500019
*   LENGTH WILL BE STORED IN BYTE BEFORE TEXT                           20600019
*   LENGTH KEPT IN REGISTER 15                                          20700019
*                                                                       20800019
*********************************************************************** 20900019
FINDCHAR SR    R6,R6                                                    21000019
         SR    R15,R15                                                  21100019
         LA    R14,X1(R3)               POINTS AT FIRST CHAR OF OPERAND 21200019
NXTCHAR  IC    R6,0(R14)                PUT CHAR INTO REGISTER          21300019
         CR    R6,R1                    COMPARE WITH CHARACTER PASSED   21400019
         BE    CHARFND                  BR= FOUND, RETURN               21500019
ADDLNG   LA    R15,X1(R15)              INCREASE LENGTH                 21600019
         LA    R14,X1(R14)                                              21700019
         CR    R14,RLAST                IS THIS END OF CIB              21800019
         BNH   NXTCHAR                  BR= NO                          21900019
         SR    R1,R1                                                    22000019
CHARFND  STC   R15,0(R3)                STORE LENGTH OF OPERAND         22100019
         BR    R7                       RETURN                          22200019
*********************************************************************** 22300019
*                                                                       22400019
*  MSG   U=                                                             22500019
*                                                                       22600019
*********************************************************************** 22700019
USRIDVAL LA    R1,COMMA                                                 22800019
         BAL   R7,FINDCHAR              GO LOOK FOR COMMA               22900019
         ST    R3,TUBPARM5              SAVE ADDRESS                    23000019
         LTR   R15,R15                  IS LENGTH ZERO                  23100019
         BZ    INVALUSR                 BR= YES                         23200019
         LA    R1,USRIDLNG              IS IT TOO LONG                  23300019
         CR    R15,R1                                                   23400019
         BH    INVALUSR                 BR= YES                         23500019
         MVI   WUSRID,BLANK             STORE BLANKS IN USERID          23600019
         MVC   WUSRID+1(USRIDLNG),WUSRID                                23700019
         BCTR  R15,0                                                    23800019
         EX    R15,MVCUSR               MOVE USERID TO KEY              23900019
         LA    RNEXT,X1(R14)            BEGINNING OF NEXT OP            24000019
*********************************************************************** 24100019
*                                                                       24200019
*  CHECK FOR MORE OPERANDS                                              24300019
*                                                                       24400019
*********************************************************************** 24500019
GETNXTOP CR    RNEXT,RLAST                                              24600019
         BNH   CKMSGCMD                 BR= MORE OPERANDS               24700019
*********************************************************************** 24800019
*                                                                       24900019
*  NO MORE OPERANDS                                                     25000019
*                                                                       25100019
*********************************************************************** 25200019
NOMOROP  TM    OPRSW,OPRTEXT            WAS TEXT FOUND                  25300019
         BZ    NOTEXT                   BR= NO                          25400019
         TM    OPRSW,OPRUSRID           WAS USERID FOUND                25500019
         BO    LOOKTUBS                 BR= USERID SPECIFIED            25600019
         TM    OPRSW,OPRMQ              WAS Q SPECIFIED                 25700019
         BO    QALL                     BR= YES, INVALID WHEN NO USERID 25800019
*********************************************************************** 25900019
*                                                                       26000019
*   PROCESSING FOR SHOW ACTIVE AND MSG COMMANDS                         26100019
*   SEARCH TUBS                                                         26200019
*     FIRST TIME THROUGH- COUNT FOR ACTIVE,NUMBER                       26300019
*       MSG FOR USER- LOOK FOR SPECIFIED USERID                         26400019
*       MSG FOR ALL OR SHOW ACTIVE- SET BIT                             26500019
*     SECOND TIME THROUGH- SHOW ACTIVE AND MSG FOR ALL ONLY             26600019
*       WHEN BIT SET- TURN OFF AND SEND MSG                             26700019
*                                                                       26800019
*********************************************************************** 26900019
LOOKTUBS OI    OPRSW,OPRFIRST           FIRST TIME                      27000019
         SR    R15,R15                                                  27100019
SRCHTUBS L     RTUB,IHKYYTUB            FIRST TUB                       27200019
         B     CKZERTUB                 GO CHECK FOR ANY TUBS           27300019
CKVALID  CLI   TUBUSRID,X00             IS THIS A VALID USERID          27400019
         BE    GETNXTUB                 BR= NOT VALID USER              27500019
         TM    OPRSW,OPRFIRST                                           27600019
         BZ    CKBIT                    BR= NOT FIRST TIME              27700019
*********************************************************************** 27800019
*                                                                       27900019
*   FIRST TIME THROUGH- CHECK ACTIVE,NUMBER THEN SPECIFIED USERID       28000019
*                                                                       28100019
*********************************************************************** 28200019
         TM    OPRSW,OPRNUM             IS THIS ACTIVE,NUMBER           28300019
         BZ    CKUSRID                  BR= NO                          28400019
         LA    R15,X1(R15)              YES, ADD TO COUNT               28500019
         B     GETNXTUB                 GO GET NEXT                     28600019
CKUSRID  TM    OPRSW,OPRUSRID           IS IT MSG FOR SPECIFIC USER     28700019
         BZ    SETUBIT                  BR= NO                          28800019
         CLC   TUBUSRID,WUSRID          YES- IS IT THIS USER            28900019
         BNE   GETNXTUB                 BR= NO                          29000019
*********************************************************************** 29100019
*                                                                       29200019
*  SEND TEXT TO ALL ACTIVE USERS  OR TO SPECIFIC USER                   29300019
*                                                                       29400019
*********************************************************************** 29500019
SENDUSR  LA    RTUB,LOCTUB              RESTORE TUB BASE                29600019
         LA    R1,WUSRID                                                29700019
         ST    R1,TUBPARM2              ADDRESS OF USERID               29800019
         LA    R15,CENTRAL              FROM CENTRAL                    29900019
         OI    OPRSW,OPRMSG             SET SWITCH- MSG SENT TO USER    30000019
         L     R14,ADRTEXT              ADDRESS OF TEXT                 30100019
         MVI   ZEROES,X00               RESTORE TO ZERO                 30200019
         LA    R1,ZEROES                                                30300019
GOSENDMS ST    R15,TUBPARM4             FIRST INSERT                    30400019
         ST    R14,TUBPARM5             SECOND INSERT                   30500019
         MVI   TUBPARM5,HIBIT           TWO INSERTS                     30600019
         BAL   R7,SENDMSGC              GO SEND MESSAGE                 30700019
         TM    OPRSW,OPRUSRID           WAS THIS FOR ONE USERID         30800019
         BO    MSGQ                     BR= YES, GO SEND MSG QUEUED MSG 30900019
         B     SRCHTUBS                 NO- GO LOOK FOR NEXT            31000019
*********************************************************************** 31100019
*                                                                       31200019
*   FIRST TIME THROUGH- SET BIT IN TUB                                  31300019
*                                                                       31400019
*********************************************************************** 31500019
SETUBIT  OI    TUBFLG1,TUBCMSGN                                         31600019
         B     GETNXTUB                                                 31700019
*********************************************************************** 31800019
*                                                                       31900019
*   SECOND TIME THROUGH                                                 32000019
*                                                                       32100019
*********************************************************************** 32200019
CKBIT    TM    TUBFLG1,TUBCMSGN         IS BIT SET                      32300019
         BZ    GETNXTUB                 BR= BIT NOT SET                 32400019
         NI    TUBFLG1,TUBCMSGF         TURN OFF BIT                    32500019
         OI    OPRSW,OPRSNDMS           INDICATES MSG SENT              32600019
         MVC   WUSRID,TUBUSRID          SAVE USERID                     32700019
         TM    OPRSW,OPRACTIV           IS THIS SHOW ACTIVE             32800019
         BZ    SENDUSR                  BR= NO, IS MSG                  32900019
*********************************************************************** 33000019
*                                                                       33100019
*   SHOW ACTIVE                                                         33200019
*  COMPUTE TIME SINCE LOGON                                             33300019
*********************************************************************** 33400019
*                                                                       33500019
         NI    OPRSW,OPRTIMEF           SET INITIAL SWITCH TO ZERO      33600019
         L     R1,TUBCLBAD              CLB ADDRESS                     33700019
         USING CLBDSECT,R1                                              33800019
         MVC   USRLINE+1(L'CLBLINE),CLBLINE SAVE LINEADDRESS            33900019
         LH    R1,TUBTIME               TIME OF LOGON                   34000019
         LA    RTUB,LOCTUB              RESTORE TUB                     34100019
         SR    R14,R14                                                  34200019
         STH   R1,TUBPARM5              LOGON TIME- HRS, MIN            34300019
COMPTIME MVI   PASSWORD+7,HEX0F                                         34400019
         MVI   TUBPARM2+3,HEX0F                                         34500019
         MVO   PASSWORD+4(4),TUBPARM5+1(1)  00 00 0M MF                 34600019
         MVO   TUBPARM2,TUBPARM5(1)     00 00 0H HF                     34700019
         MP    TUBPARM2,HRMIN           CONVERT HOURS TO MINUTES        34800019
         AP    PASSWORD+4(4),TUBPARM2   TOTAL MINUTES                   34900019
         ST    R14,PASSWORD             CLEAR TO ZEROES                 35000019
         CVB   R15,PASSWORD             CONVERT MINUTES TO BINARY       35100019
         TM    OPRSW,OPRTIME            FIRST TIME THROUGH              35200019
         BO    CKSEC                    BR=NO                           35300019
         ST    R15,TUBPARM4             YES- SAVE LOGON TIME            35400019
         TIME  ,                        PRESENT TIME                    35500019
         ST    R0,TUBPARM5              SAVE PRESENT TIME               35600019
         OI    OPRSW,OPRTIME            SET SECOND TIME SWITCH          35700019
         B     COMPTIME                                                 35800019
CKSEC    LA    R1,THIRTY1               THIRTY-ONE                      35900019
         IC    R14,TUBPARM5+2           SECONDS- CHECK FOR >30          36000019
         CR    R14,R1                                                   36100019
         BL    COMPHRS                                                  36200019
         LA    R15,1(R15)               IS MORE THAN 30, ADD ONE MINUTE 36300019
COMPHRS  LA    R1,HRS24                 CHECK FOR MORE THAN 24 HOURS    36400019
         C     R15,TUBPARM4             HAS TIME CYCLED BACK TO ZERO    36500019
         BNL   SUBTIME                  BR= NO                          36600019
         AR    R15,R1                   ADD 24 HRS                      36700019
SUBTIME  S     R15,TUBPARM4             PRESENT MINUS LOGON TIME        36800019
         BAL   R7,CONVERT               GO CONVERT TO ZONED             36900019
         MVI   PASSWORD,BLANK                                           37000019
         LA    R14,USRLINE              INSERT LINEADDRESS, TIME        37100019
         LA    R15,USRIDLN              INSERT USERID                   37200019
         LA    R1,MUSRACTV              USER ACTIVE MSG                 37300019
         B     GOSENDMS                 GO SEND MSG                     37400019
*********************************************************************** 37500019
*                                                                       37600019
*   GET NEXT TUB- IF NO MORE, CHECK FOR FIRST TIME                      37700019
*                                                                       37800019
*********************************************************************** 37900019
GETNXTUB L     RTUB,TUBNEXT                                             38000019
CKZERTUB LA    RTUB,0(RTUB)             IS THERE ANOTHER                38100019
         LTR   RTUB,RTUB                                                38200019
         BNZ   CKVALID                  BR= YES                         38300019
         LA    RTUB,LOCTUB              NO, RESTORE TUB BASE            38400019
         TM    OPRSW,OPRFIRST           IS THIS FIRST TIME              38500019
         BZ    CKMSGSNT                 BR= NO                          38600019
         NI    OPRSW,OPRFRSTF           YES, TURN OFF BIT               38700019
         TM    OPRSW,OPRNUM             IS THIS ACTIVE,NUMBER           38800019
         BZ    USRFND                   BR= NO                          38900019
         BAL   R7,CONVERT               YES, CONVERT NUMBER             39000019
         B     NUMACTV                  GO SEND MSG                     39100019
*********************************************************************** 39200019
*                                                                       39300019
*   NO MORE TUBS- FIRST TIME THROUGH                                    39400019
*   CHECK FOR SPECIFIED USER- IF NOT FOUND, CHECK FOR Q                 39500019
*                                                                       39600019
*********************************************************************** 39700019
USRFND   TM    OPRSW,OPRUSRID           WAS THIS FOR SPECIFIC USER      39800019
         BZ    SRCHTUBS                 BR=NO                           39900019
         TM    OPRSW,OPRMQ              USER NOT ACTIVE- CHECK FOR Q    40000019
         BO    SENDUSR                  BR= Q SPECIFIED, EQN MSG        40100019
*********************************************************************** 40200019
*                                                                       40300019
*  MSG NOT SENT- USER NOT ACTIVE                                        40400019
*                                                                       40500019
*********************************************************************** 40600019
NOTACTIV LA    R1,MNOTACT                                               40700019
         B     INSUSR                                                   40800019
*********************************************************************** 40900019
*                                                                       41000019
*   NO MORE TUBS- SECOND TIME THROUGH                                   41100019
*                                                                       41200019
*********************************************************************** 41300019
CKMSGSNT TM    OPRSW,OPRSNDMS           WAS ANY MSG SENT                41400019
         BZ    NOACTIVE                 BR= NO, SEND NO ACTIVE USERS    41500019
         TM    OPRSW,OPRACTIV           IS THIS SHOW ACTIVE             41600019
         BO    RETURN0                  BR= YES, RETURN                 41700019
*********************************************************************** 41800019
*                                                                       41900019
*  MSG SENT TO ACTIVE USERS                                             42000019
*                                                                       42100019
*********************************************************************** 42200019
MSGSENQ  LA    R1,MMSGENQ               SEND MSG QUEUED MSG             42300019
         B     INSNOPAR                 NO INSERTIONS                   42400019
         EJECT                                                          42500019
*********************************************************************** 42600019
*                                                                       42700019
*   SUPPLIED ERROR MESSAGES                                             42800019
*                                                                       42900019
*********************************************************************** 43000019
*                                                                       43100019
*  GETMAIN FAIL                                                         43200019
*                                                                       43300019
SNDOUTSP LA    R1,OUTSP                                                 43400019
         B     INSNOPRN                                                 43500019
*                                                                       43600019
*  ACTIVE AREA I/O ERROR                                                43700019
*                                                                       43800019
AAIOERR  LA    R1,MSGIOER                                               43900019
INSNOPRN OI    OPRSW,OPRERRMS           SET SWITCH- SUPPLIED MSG        44000019
INSNOPAR ST    R1,TUBPARM3                                              44100019
         MVI   TUBPARM3,HIBIT           NO INSERTIONS                   44200019
         LA    R7,RETURN0                                               44300019
         B     SENDMSGB                 GO SEND MSG, RETURN 0           44400019
*********************************************************************** 44500019
*                                                                       44600019
*   SYSTEM ERROR MESSAGES                                               44700019
*                                                                       44800019
*********************************************************************** 44900019
*                                                                       45000019
*  OPERAND INVALID/MISSING                                              45100019
*    INSERT FIRST TEN CHAR IN MSG                                       45200019
*                                                                       45300019
OPNFND   LA    R1,MNOTFND                                               45400019
CKCIBLNG BCTR  RNEXT,0                  INSERT FROM CIB                 45500019
         SR    RLAST,RNEXT                                              45600019
         STC   RLAST,0(RNEXT)                                           45700019
CKLNG10  CLI   0(RNEXT),X0A             CHECK FOR MORE THAN 10          45800019
         BNH   INSCMD1                                                  45900019
         MVI   0(RNEXT),X0A             TOO LONG, INSERT 10             46000019
INSCMD1  LR    R14,RNEXT                                                46100019
INSCMD2  ST    RCMD,TUBPARM4                                            46200019
INS2PARM ST    R14,TUBPARM5             TWO INSERTIONS                  46300019
INS2PRM2 MVI   TUBPARM5,HIBIT                                           46400019
         B     SENDMSG0                                                 46500019
*                                                                       46600019
*   ACTIVE AREA OUT OF SPACE                                            46700019
*                                                                       46800019
AAOUTSP  LA    R1,MAAOUTSP                                              46900019
         B     INSNOPAR                                                 47000019
*                                                                       47100019
*   DELIMITER INVALID                                                   47200019
*                                                                       47300019
NOQUOTE  LA    R1,MNOQUOTE                                              47400019
         B     CKCIBLNG                                                 47500019
*                                                                       47600019
*   TEXT LENGTH INVALID                                                 47700019
*                                                                       47800019
INVLNG   LA    R1,MINVLNG                                               47900019
         L     RNEXT,ADRTEXT                                            48000019
         B     CKLNG10                                                  48100019
*                                                                       48200019
*  USERID NOT FOUND BY MSG                                              48300019
*                                                                       48400019
INVUSR2  LA    RNEXT,USRIDLN                                            48500019
         B     INVUSR1                                                  48600019
*                                                                       48700019
*  Q SPECIFIED BUT NO USERID                                            48800019
*                                                                       48900019
QALL     LA    R14,CHARQ                                                49000019
         B     GETINVOP                                                 49100019
*                                                                       49200019
*  NO TEXT SPECIFIED                                                    49300019
*                                                                       49400019
NOTEXT   LA    R14,TEXT                                                 49500019
GETINVOP LA    R1,MNOTFND                                               49600019
         B     INSCMD2                                                  49700019
*                                                                       49800019
*  INVALID USERID                                                       49900019
*                                                                       50000019
INVALUSR L     RNEXT,TUBPARM5                                           50100019
INVUSR1  LA    R1,MINVUSR                                               50200019
         B     CKLNG10                                                  50300019
*                                                                       50400019
*   DELAYED DATA SET FULL                                               50500019
*                                                                       50600019
MAXMSGS  LA    R1,MMAXMSG                                               50700019
         B     INSNOPAR                                                 50800019
*********************************************************************** 50900019
*                                                                       51000019
*   OTHER SYSTEM MESSAGE ROUTINES                                       51100019
*                                                                       51200019
*********************************************************************** 51300019
*                                                                       51400019
*   NUMBER OF OR NO ACTIVE USERS                                        51500019
*                                                                       51600019
NOACTIVE LA    R14,NO                                                   51700019
NUMACTV  LA    R1,MNOACTV                                               51800019
         B     INS1PRM1                                                 51900019
*                                                                       52000019
*  MSG QUEUED FOR DELIVERY                                              52100019
*                                                                       52200019
MSGQ     LA    R1,MMSGENQ                                               52300019
INSUSR   LA    R14,USRIDLN                                              52400019
INS1PRM1 ST    R14,TUBPARM4                                             52500019
INS1PRM2 MVI   TUBPARM4,HIBIT                                           52600019
         B     SENDMSG0                                                 52700019
*********************************************************************** 52800019
*                                                                       52900019
*   CONVERT TO ZONED DECIMAL                                            53000019
*                                                                       53100019
*********************************************************************** 53200019
CONVERT  CVD   R15,PASSWORD             STORE ON DOUBLEWORD BOUNDARY    53300019
         UNPK  PASSWORD(5),PASSWORD+5(3)                                53400019
         MVI   PASSWORD,X4              STORE LENGTH FOR MSG WRITER     53500019
         OI    PASSWORD+4,HEXF0                                         53600019
         LA    R14,PASSWORD                                             53700019
         LA    R1,PASSWORD+1                                            53800019
         LA    R15,3                                                    53900019
CKZERO   CLI   0(R1),HEXF0                                              54000019
         BNE   CONVRTN                                                  54100019
         MVI   0(R1),BLANK                                              54200019
         LA    R1,1(R1)                                                 54300019
         BCT   R15,CKZERO                                               54400019
CONVRTN  BR    R7                                                       54500019
         EJECT                                                          54600019
*********************************************************************** 54700019
*                                                                       54800019
*                                                                       54900019
*  SUBROUTINE TO SEARCH FOR SPECIFIED SET OF CHARACTERS                 55000019
*        CHECKS FOR END OF CIB                                          55100019
*        AT ENTRY REGISTER ONE POINTS TO TABLE DEFINING VALID CHARACTER 55200019
*        STRINGS, AND CHARACTER (OR END OF CIB) THAT MUST FOLLOW        55300019
*        SETS SWITCH FROM TABLE                                         55400019
*        BRANCHES USING BRANCH CODE FROM TABLE                          55500019
*        REGISTER 3 POINTS AT CHAR AFTER OPERAND IN CIB (IF ANY)        55600019
*                                                                       55700019
*********************************************************************** 55800019
FINDSUBR SR    R15,R15                                                  55900019
GETLNG   IC    R15,0(R1)                LENGTH FROM TABLE-REG 15        56000019
         LA    R1,1(R1)                 REG1 POINTS AT OP IN TABLE      56100019
         CH    R15,CIBDATLN                                             56200019
         BH    NXTABLE                  BR= OP IN CIB SHORTER           56300019
         LR    R3,RNEXT                                                 56400019
         BCTR  R15,0                                                    56500019
         EX    R15,CLCOP                                                56600019
         LA    R15,1(R15)               RESTORE TO OP LENGTH IN TABLE   56700019
         BNE   NXTABLE                  BR= NOT OP IN TABLE             56800019
         AR    R1,R15                   OP EQUAL-CK NEXT CHAR           56900019
         AR    R3,R15                                                   57000019
         CLI   0(R1),X00                SHOULD IT BE END OF CIB         57100019
         BE    CKCIBEND                 BR= YES, GO SEE IF IT IS        57200019
         CR    R3,RLAST                 MUST BE ANOTHER CHAR            57300019
         BNL   NXTABLE1                 BR= NOT ANOTHER IN CIB          57400019
         CLC   0(1,R3),0(R1)            IS IT CHAR IN TABLE             57500019
         BNE   NXTABLE1                 BR= NO                          57600019
GETBRNCH IC    R15,2(R1)                OPERAND FOUND                   57700019
         IC    R2,OPRSW                                                 57800019
         NR    R15,R2                   TEST IF SWITCH ALREADY SET      57900019
         LTR   R15,R15                                                  58000019
         BNZ   OPNFND                   BR= OPERAND ALREADY FOUND       58100019
         IC    R15,2(R1)                                                58200019
         OR    R2,R15                                                   58300019
         STC   R2,OPRSW                 SET SWITCH                      58400019
         IC    R15,1(R1)                BRANCH CODE                     58500019
         B     BRANCH(R15)              BRANCH TO ROUTINE               58600019
*                                                                       58700019
*  POINT TO NEXT ENTRY IN TABLE                                         58800019
*                                                                       58900019
NXTABLE  AR    R1,R15                                                   59000019
NXTABLE1 LA    R1,3(R1)                 NOW POINTS AT NEXT              59100019
         TM    0(R1),ALLBITS                                            59200019
         BO    OPNFND                   BR= NO MORE IN TABLE            59300019
         B     GETLNG                                                   59400019
*                                                                       59500019
CKCIBEND CR    R3,RLAST                 HAS TO BE END OP CIB            59600019
         BH    GETBRNCH                 BR= IS END                      59700019
         B     NXTABLE1                                                 59800019
         EJECT                                                          59900019
*********************************************************************** 60000019
*                                                                       60100019
*   SUBROUTINE TO SEND MESSAGES                                         60200019
*   SENDMSG0- SETS RETURN TO ZERO                                       60300019
*   SENDMSG- AT LEAST ONE INSERTION                                     60400019
*   SENDMSGA- NO INSERTIONS                                             60500019
*                                                                       60600019
*********************************************************************** 60700019
SENDMSG0 LA    R7,RETURN0                                               60800019
SENDMSGC ST    R1,TUBPARM3              PARAM 3 = ADDR OF MSG           60900019
SENDMSGB ST    RTUB,TUBPARM1            PARAM 1 = ADDR OF TUB           61000019
         TM    OPRSW,OPRMSG                                             61100019
         BO    MSGUSER                  BR= SEND MSG TO USER            61200019
         LA    R15,ZEROES                                               61300019
         ST    R15,TUBPARM2             PARAM 2 = ADDR OF ZERO          61400019
         MVC   0(1,R15),CIBCONID        HIGH ORDER BIT= CONSOLE ID      61500019
CKERRMS  TM    OPRSW,OPRERRMS           IS THIS SEND A SUPPLIED MSG     61600019
         BZ    ENTRMSG                  BR = NO                         61700019
         L     R15,IHKYMSG2             IHKMSG02                        61800019
         B     GETPARM1                                                 61900019
MSGUSER  L     R15,IHKYMSG1             IHKMSG01                        62000019
         NI    OPRSW,OPRMSGF            TURN OFF MSG TO USER SWITCH     62100019
         B     GETPARM1                                                 62200019
ENTRMSG  L     R15,IHKYYMSG             IHKMSG                          62300019
GETPARM1 LA    R1,TUBPARM1                                              62400019
         BALR  R14,R15                                                  62500019
         B     MSGRTN(R15)                                              62600019
MSGRTN   B     0(R7)                    0    MSG SENT                   62700019
         B     0(R7)                    4    TP LINE ERROR (NOT APPLIC) 62800019
         B     SNDOUTSP                 8    GETMAIN FAIL               62900019
         B     AAIOERR                  12   AA I/O ERROR               63000019
         B     MAXMSGS                  16   NOT USED                   63100019
         B     AAOUTSP                                                  63200019
         B     INVUSR2                  24   INVALID USERID             63300019
*                                                                       63400019
*  EXECUTED INSTRUCTIONS                                                63500019
*                                                                       63600019
MVCUSR   MVC   WUSRID(0),1(R3)          MOVE USERID FROM CIB            63700019
CLCOP    CLC   0(0,R1),0(R3)                                            63800019
*********************************************************************** 63900019
*                                                                       64000019
*   RETURN WITH RETURN CODE 0                                           64100019
*                                                                       64200019
*********************************************************************** 64300019
RETURN0  L     R13,4(R13)                                               64400019
         RETURN (14,12),,RC=0                                           64500019
         EJECT                                                          64600019
*********************************************************************** 64700019
*                                                                       64800019
*  MESSAGE CODES                                                        64900019
*                                                                       65000019
*********************************************************************** 65100019
         DS    0F                                                       65200019
MUSRACTV DC    X'20',C'201'             USER ACTIVE                     65300019
MINVUSR  DC    X'20',C'202'             USERID INVALID/NOT FOUND        65400019
MINVLNG  DC    X'20',C'206'             INVALID TEXT LENGTH             65500019
MNOTFND  DC    X'20',C'226'             OP MISSING/INVALID              65600019
MMAXMSG  DC    X'20',C'236'             MAX DELAYED MSGS REACHED        65700019
MAAOUTSP DC    X'20',C'240'             ACTIVE AREA OUT OF SPACE        65800019
MNOACTV  DC    X'20',C'245'             NO ACTIVE USERS                 65900019
MNOTACT  DC    X'20',C'248'             INACTIVE USER                   66000019
MNOQUOTE DC    X'20',C'254'             DELIMITER INVALID               66100019
MMSGENQ  DC    X'20',C'256'             MSG QUEUED FOR DELIVERY         66200019
         EJECT                                                          66300019
*********************************************************************** 66400019
*                                                                       66500019
* TABLES PASSED TO FINDSUBR                                             66600019
*   FORMAT- LENGTH OF OPERAND(ONE BYTE), OPERAND (VARIABLE LENGTH),     66700019
*   CHARACTER THAT MUST FOLLOW OPERAND OR X'00' TO INDICATE MUST        66800019
*   BE END OF CIB (ONE BYTE), BRANCH CODE(ONE BYTE)                     66900019
*  SWITCH SETTING(ONE BYTE)                                             67000019
*  LAST ENTRY IN TABLE FOLLOWED BY X'FF'                                67100019
*                                                                       67200019
*********************************************************************** 67300019
MSGCC8   DC    X'01',C'M',C'=',X'00',X'01'                              67400019
         DC    X'01',C'U',C'=',X'04',X'20'                              67500019
         DC    X'01',C'Q',C',',X'08',X'40'                              67600019
         DC    X'01',C'Q',X'00',X'08',X'40'                             67700019
         DC    X'FF'                                                    67800019
SHOWCC8  DC    X'06',C'ACTIVE',X'00',X'0C',X'10'                        67900019
         DC    X'0D',C'ACTIVE,NUMBER',X'00',X'0C',X'18'                 68000019
         DC    X'FF'                                                    68100019
BRANCH   B     CKTEXT                   M=                              68200019
         B     USRIDVAL                 U=                              68300019
         B     CKQ                      Q OR Q,                         68400019
         B     LOOKTUBS                 SHOW ACTIVE(,NUMBER)            68500019
         EJECT                                                          68600019
*********************************************************************** 68700019
*                                                                       68800019
*   SUPPLIED ERROR MESSAGES                                             68900019
*                                                                       69000019
*********************************************************************** 69100019
MSGIOER  WTO   'IHK270I ACTIVE AREA I/O ERROR',MF=L,ROUTCDE=(2,4,10),  X69200019
               DESC=(4),MCSFLAG=(REG0)                                  69300019
OUTSP    WTO   'IHK219I OUT OF MAIN STORAGE',MF=L,ROUTCDE=(2),         X69400019
               DESC=(4),MCSFLAG=(REG0)                                  69500019
*********************************************************************** 69600019
*  CONSTANTS                                                            69700019
*********************************************************************** 69800019
NO       DC    X'02',C'NO'                                              69900019
MSG      DC    X'03',C'MSG'                                             70000019
*********************************************************************** 70100019
*                                                                       70200019
*   WORK/SAVE AREAS- TUB USED FOR WORK AREA                             70300019
*                                                                       70400019
*********************************************************************** 70500019
SAVEAREA DC    18F'0'                                                   70600019
ADDRTUB  EQU   56                       ADDR OF TUB- REG 9              70700019
         IHKCDSCT  TUB=YES                                              70800019
IHKCC8   CSECT                                                          70900019
LOCTUB   DS    0D                                                       71000019
         DC    F'0'                                                     71100019
         DC    A(USRBUFR)                                               71200019
         DC    320X'00'                                                 71300019
         ORG   LOCTUB+8                                                 71400019
ADRTEXT  DS    F                        ADDRESS OF TEXT                 71500019
USRLINE  DC    X'08000000'              LINEADDRESS OF USER             71600019
PASSWORD DS    D                                                        71700019
ZEROES   DC    F'0'                                                     71800019
HRMIN    DC    P'60'                                                    71900019
*                                                                       72000019
*  SWITCHES                                                             72100019
*                                                                       72200019
OPRSW    DS    C                        OPERAND SWITCH                  72300019
OPRMSG   EQU   X'80'                    MSG COMMAND                     72400019
OPRMSGF  EQU   X'7F'                                                    72500019
OPRMQ    EQU   X'40'                    MSG Q                           72600019
OPRTIME  EQU   X'40'                    FIRST TIME- COMPUTE TIME        72700019
OPRTIMEF EQU   X'BF'                                                    72800019
OPRUSRID EQU   X'20'                    USERID SPECIFIED- MSG           72900019
OPRACTIV EQU   X'10'                    SHOW ACTIVE                     73000019
OPRNUM   EQU   X'08'                    SHOW ACTIVE,NUMBER              73100019
OPRSNDMS EQU   X'04'                    INDICATES MSG SENT              73200019
OPRERRMS EQU   X'02'                    SUPPLIED MESSAGE                73300019
OPRTEXT  EQU   X'01'                    MSG TEXT FOUND                  73400019
OPRFIRST EQU   X'01'                    FIRST TIME- SEARCH TUBS         73500019
OPRFRSTF EQU   X'FE'                                                    73600019
USRIDLN  DC    X'08'                    USERID LENGTH                   73700019
WUSRID   DS    CL8                      USERID-MUST BE ON FULL WORD     73800019
CENTRAL  DC    X'08',C'CENTRAL '                                        73900019
SHOW     DC    X'04',C'SHOW'                                            74000019
TEXT     DC    X'04',C'TEXT'                                            74100019
CHARQ    DC    X'01',C'Q'                                               74200019
*                                                                       74300019
         ORG   LOCTUB+TUBSIZE                                           74400019
         DS    0D                                                       74500019
USRBUFR  DS    CL88                                                     74600019
CIBBASE  DSECT                                                          74700019
         IEZCIB                                                         74800019
         IHKCDSCT         AVT=YES,CLB=YES                               74900019
         TUBEQU                                                         75000019
         RAFKNBX TYPE=DSECT                                             75100019
         END                                                            75200019
