CCS      TITLE 'IHKCCS - SCAN ROUTINE'                                  00500019
*STATUS                                                               * 01000019
*   CHANGE LEVEL 0.                                                   * 01500019
*                                                                     * 02000019
*FUNCTION/OPERATION                                                     02500019
*   GIVEN A CHARACTER STRING AND A STARTING LOCATION, THIS ROUTINE    * 03000019
*   SCANS IN THE DIRECTION OF HIGH CORE STORAGE, THE SCAN TERMINATING * 03500019
*   WITH THE FIRST CHARACTER OBSERVED WHICH BELONGS TO THE CHARACTER  * 04000019
*   STRING. ALTERNATIVELY, A SCAN MAY BE MADE FOR THE FIRST NON-BLANK * 04500019
*   CHARACTER. THE USER MUST SPECIFY EITHER A MAXIMUM NUMBER OF       * 05000019
*   CHARACTERS OVER WHICH TO SCAN, OR ELSE THE ADDRESS OF A STOPPING  * 05500019
*   LOCATION PAST WHICH NO SCANNING IS TO BE DONE.                    * 06000019
*                                                                     * 06500019
*ENTRY POINTS                                                         * 07000019
*  IHKCCS IS THE ONLY ENTRY POINT.                                    * 07500019
*                                                                     * 08000019
*  PARAMETERS PASSED MUST HAVE THE FOLLOWING FORM:                    * 08500019
*    REGISTER 1 HAS THE ADDRESS OF A 3-WORD-PARAMETERLIST HAVING      * 09000019
*     - IN THE FIRST WORD THE STARTING ADDR OF THE SCAN,              * 09500019
*     - IN THE SECOND WORD THE STOPPING ADDRESS OF THE SCAN, (IF A    * 10000019
*       MAXIMUM SCAN-LENGTH IS SPECIFIED, THE CONTENTS OF THIS WORD   * 10500019
*       IS ARBITRARY),                                                * 11000019
*     - IN THE THIRD WORD THE ADDRESS OF THE FOLLOWING LIST OF        * 11500019
*       PARAMETERS.                                                   * 12000019
*                                                                     * 12500019
*     THIS LIST OF PARAMETERS STARTS ON A HALF-WORD-BOUNDARY AND HAS  * 13000019
*       - IN THE FIRST HALF-WORD THE MAXIMUM SCAN-LENGTH. (IF A       * 13500019
*         STOPPING ADDRESS IS SPECIFIED THIS HALF-WORD MUST CONTAIN   * 14000019
*         BINARY ZERO),                                               * 14500019
*       - IN THE SECOND HALFWORD THE NUMBER OF CHARACTERS TO WHICH    * 15000019
*         THE SCAN IS SENSITIVE. IF THIS NUMBER IS BINARY ZERO,       * 15500019
*         SCAN IS MADE FOR THE FIRST NON-BLANK CHARACTER.             * 16000019
*       - IN THE FOLLOWING BYTES A CHARACTER-STRING C1C2C3...CN       * 16500019
*         CONTAINING THE CHARACTERS TO WHICH SCAN IS SENSITIVE. THE   * 17000019
*         MAXIMUM LENGTH OF THIS STRING IS 12.                        * 17500019
*                                                                     * 18000019
*INPUT                                                                * 18500019
*   THE PARAMETER LIST DESCRIBED ABOVE.                               * 19000019
*                                                                     * 19500019
*OUTPUT                                                               * 20000019
*    THE RESULTS OF THE SCAN, DESCRIBED UNDER EXITS.                  * 20500019
*                                                                     * 21000019
*EXITS-NORMAL                                                         * 21500019
*   REGISTER 15 CONTAINS ONE OF THE FOLLOWING INDICATORS-             * 22000019
*   1.ZERO IF NO SENSITIVE CHARACTER OR NON-BLANK WAS FOUND.          * 22500019
*   2.FOUR IF A FIND WAS MADE ON A REQUEST TO SCAN FOR THE FIRST NON- * 23000019
*     BLANK CHARACTER.                                                * 23500019
*   3.4J IF A HIT WAS MADE ON THE J-TH CHARACTER OF THE CHARACTER     * 24000019
*     STRING C1C2C3...CJ...CN.                                        * 24500019
*   REGISTER 1, IN ALL CASES OF A FIND, CONTAINS THE ADDRESS OF THE   * 25000019
*   CHARACTER FOUND. IT CONTAINS ZERO IF NO FIND WAS MADE.            * 25500019
*                                                                     * 26000019
*EXITS-ERROR                                                          * 26500019
*   N/A                                                               * 27000019
*                                                                     * 27500019
*TABLES/WORK AREAS                                                    * 28000019
*   A 256 BYTE WORK AREA LABELLED TRTTAB IS USED TO BUILD A TRANSLATE * 28500019
*   TABLE SENSITIVE TO THE PROPER NUMBER OF CHARACTERS.               * 29000019
*                                                                     * 29500019
*ATTRIBUTES                                                           * 30000019
*   SERIALLY REUSABLE.                                                * 30500019
*                                                                     * 31000019
*NOTES                                                                * 31500019
*   THE OPERATION OF THIS MODULE DEPENDS UPON THE INTERNAL            * 32000019
*   REPRESENTATION OF THE EXISTING EXTERNAL  CHARACTER SET. NAMELY,   * 32500019
*   IF THIS CHARACTER SET WERE ENLARGED, THE TRANSLATE TABLE BUILT    * 33000019
*   UPON ENTRY TO THIS ROUTINE WOULD HAVE TO BE ENLARGED BY CHANGING  * 33500019
*   THE INSTRUCTION                                                   * 34000019
*                   TRTTAB  DS  CL256                                 * 34500019
*   WHICH OCCURS IN THIS PROGRAM.  THIS INSTRUCTION ASSUMES A         * 35000019
*   CHARACTER SET OF 256 CHARACTERS. FURTHER, IF THE POSITION OF THE  * 35500019
*   BLANK CHARACTER WITHIN THE CHARACTER CODE TABLE, WHICH IS ARRANGED* 36000019
*   IN ORDER ACCORDING TO THE DECIMAL EQUIVALENT OF THE HEXADECIMAL   * 36500019
*   REPRESENTATION OF EACH CHARACTER, WERE CHANGED FROM THE SIXTY     * 37000019
*   FOURTH TO SOME OTHER POSITION, THEN THE INSTRUCTION               * 37500019
*              MVI     TRTTAB+64,HEX00                                * 38000019
*   WOULD HAVE TO BE MODIFIED TO REFLECT THIS NEW POSITION OF THE     * 38500019
*   BLANK CHARACTER. THIS IS THE THIRD INSTRUCTION PRECEDING THE      * 39000019
*   LABEL  -RETURN-.                                                  * 39500019
*                                                                     * 40000019
*                                                                     * 40500019
IHKCCS   CSECT                                                          41000019
R0       EQU   0                                                        41500019
R1       EQU   1                                                        42000019
R2       EQU   2                                                        42500019
R3       EQU   3                                                        43000019
R4       EQU   4                                                        43500019
R5       EQU   5                                                        44000019
R6       EQU   6                                                        44500019
R7       EQU   7                                                        45000019
R8       EQU   8                                                        45500019
R9       EQU   9                                                        46000019
R10      EQU   10                                                       46500019
R11      EQU   11                                                       47000019
R12      EQU   12                  BASE REG                             47500019
R13      EQU   13                                                       48000019
R14      EQU   14                                                       48500019
R15      EQU   15                                                       49000019
HEX00    EQU   X'00'                                                    49500019
HEX04    EQU   X'04'                                                    50000019
MXL      EQU   255                                                      50500019
         SAVE  (14,12),,IHKCCS                                          51000019
         BALR  R12,0               ESTABLISH ADDRESSIBILITY             51500019
         USING *,R12                                                    52000019
         ST    R13,SAVE+4          STORE ADDRESS OF HIS SAVE IN MY      52500019
*                                  SAVE AREA.                           53000019
         LA    R4,SAVE                                                  53500019
         ST    R4,8(R13)           STORE ADDRESS OF MY SAVE AREA IN     54000019
*                                  HIS SAVE AREA.                       54500019
         L     R14,8(0,R1)         HAS ADDR OF SUB-PARAMETERLIST.       55000019
         LH    R7,2(0,R14)         GET NUMBER OF SENSITIVE CHARACTERS   55500019
         LTR   R7,R7                                                    56000019
         BNZ   SEVERAL             BRANCH IF NOT SENSITIVE TO ALL       56500019
*                                  EXCEPT BLANK                         57000019
         LA    R6,A                SET SWITCH FOR SCAN LOOP             57500019
         MVI   TRTTAB,HEX04        BUILD TRANSLATE TABLE SENSITIVE TO   58000019
*                                   ALL CHARACTERS EXCEPT BLANK         58500019
         MVC   TRTTAB+1(MXL),TRTTAB                                     59000019
         MVI   TRTTAB+64,HEX00                                          59500019
         B     SCAN                ENTER SCAN LOOP                      60000019
A        LA    R15,4               SET RETURN CODE FOR HIT ON NON-      60500019
*                                  BLANK                                61000019
RETURN   STM   R15,R1,16(R13)      SET UP RETURN LINKAGE                61500019
         RETURN (14,12),T                                               62000019
SEVERAL  LA    R8,TRTTAB           R8 HAS ADDRESS OF TRT TABLE          62500019
         MVI   0(R8),HEX00                                              63000019
         MVC   1(MXL,R8),0(R8)     ZERO TRT-TABLE                       63500019
         LA    R9,4(0,R14)         HAS ADDR OF FIRST SENSITIVE CHAR     64000019
         LA    R10,1               R10 HAS INCREMENT                    64500019
         LR    R11,R9                                                   65000019
         AR    R11,R7                                                   65500019
         SR    R11,R10             REGISTER 11 HAS ADDRESS OF LAST      66000019
*                                  CHARACTER.                           66500019
         SR    R9,R10              REGISTER 9 HAS ADDRESS OF FIRST      67000019
*                                  CHARACTER MINUS ONE.                 67500019
         SR    R6,R6                                                    68000019
BUILDTAB BXH   R9,R10,BUILT        BRANCH IF TRT TABLE IS BUILT         68500019
         AH    R6,FOUR             SET RETURN CODE                      69000019
         SR    R7,R7                                                    69500019
         IC    R7,0(R9)            GET CHARACTER                        70000019
         AR    R7,R8               GET CHARACTER POSITION IN TRT TABLE  70500019
         STC   R6,0(R7)            PUT RETURN CODE IN TRT TABLE         71000019
         B     BUILDTAB            GO BACK FOR MORE                     71500019
BUILT    LA    R6,B                SET SWITCH FOR SCAN LOOP             72000019
         B     SCAN                ENTER SCAN LOOP                      72500019
B        LR    R15,R2              PUT RETURN CODE IN REGISTER 15       73000019
         B     RETURN              RETURN TO CALLER                     73500019
SCAN     L     R5,0(0,R1)          HAS SCAN-START-ADDR.                 74000019
         LA    R4,MXL              LENGTH REGISTER FOR TRT INSTRUCTION  74500019
*                                  NOW HAS 255                          75000019
         LH    R3,0(0,R14)         GET MAX SCAN-LENGTH                  75500019
         LTR   R3,R3               IS MAXIMUN SCAN LENGTH SPECIFIED     76000019
         BNZ   ALTER               BRANCH IF SPECIFIED                  76500019
         L     R3,4(0,R1)          GET SCAN-STOP-ADDR                   77000019
         SR    R3,R5               SUBTRACT START SCAN ADDR             77500019
         LTR   R3,R3               CHECK FOR NEGATIVE DIFFERENCE        78000019
         BM    SET                 BRANCH IF NEGATIVE                   78500019
GET      LA    R7,256              GET INTERNAL SCAN DISPLACEMENT       79000019
         SR    R2,R2                                                    79500019
         SR    R1,R1               CLEAR REGISTERS 1 AND 2              80000019
COMPARE  CR    R3,R7                                                    80500019
         BL    LT256               BRANCH IF LESS THAN 256              81000019
*                                  CHARACTERS TO SCAN.                  81500019
         SR    R3,R7               DECREMENT MAXIMUN SCAN LENGTH BY 256 82000019
EXEC     EX    R4,LOOK             SCAN FOR SENSITIVE CHARACTERS.       82500019
         BC    8,MORE              BRANCH IF NO HIT                     83000019
         BR    R6                  BRANCH TO A OR B AS INDICATED BY     83500019
*                                  REGISTER 6                           84000019
LOOK     TRT   0(0,R5),TRTTAB      SCAN INSTRUCTION                     84500019
ALTER    LA    R2,1                MAXIMIM SCAN LENGTH MUST BE          85000019
         SR    R3,R2               DECREMENTED BY ONE                   85500019
         B     GET                                                      86000019
LT256    LR    R4,R3               ALTER SCAN LENGTH                    86500019
         LA    R3,0                SET MORE SWITCH OFF IE MO EQ ZERO    87000019
         B     EXEC                                                     87500019
MORE     LTR   R3,R3                                                    88000019
         BZ    SET                 BRANCH IF NO MORE TO SCAN            88500019
         AR    R5,R7               UPDATE SCAN START ADDRESS            89000019
         B     COMPARE                                                  89500019
SET      EQU   *                                                        90000019
         SR    R15,R15             SET NO HIT RETURN CODE               90500019
         B     RETURN                                                   91000019
*                                                                       91500019
*  PROGRAM SECTION FOR TABLES, SAVE AREAS, CONSTANTS                    92000019
*                                                                       92500019
SAVE     DS    3F                  SAVE AREA                            93000019
TRTTAB   DS    CL256               TRANSLATE AND TEST TABLE             93500019
FOUR     DC    H'4'                                                     94000019
         LTORG                                                          94500019
         ENTRY IHKCCS                                                   95000019
         END                                                            95500019
