CDP      TITLE 'IHKCDP - LIBRARY CONDENSE ROUTINE'                      00100019
*********************************************************************** 00200019
*                                                                     * 00300019
*STATUS                                                               * 00400019
*   CHANGE LEVEL 0                                                    * 00500019
*                                                                     * 00600019
*FUNCTION/OPERATION-                                                  * 00700019
*   THE FUNCTION OF THIS MODULE IS TO RECOVER THE LOST SPACE WITHIN A * 00800019
*   PARTITIONED DATA SET. CONDENSE IS A SERIALLY RESUABLE RESOURCE.   * 00900019
*   WHEN IHKCDP GAINS CONTROL, IT REQUESTS EXCLUSIVE CONTROL OF GLOBAL* 01000019
*   FILE 6 (UTILITY SORT FILE RESERVED FOR CONDENSE). IHKRNQ IS USED  * 01100019
*   TO GET IHKCDP ON THE LIBRARY I/O QUEUE. SINCE CONDENSE IS TIME    * 01200019
*   CONSUMING, IHKCDP ONLY TAKES EXCLUSIVE CONTROL OF LIBRARY I/O WHEN* 01300019
*   IT IS THE ONLY FUNCTION REQUESTING THE RESOURCE.                  * 01400019
*   WHEN IHKCDP GAINS CONTROL OF LIBRARY I/O, THE USER'S LIBRARY IS   * 01500019
*   OPENED FOR INPUT TO READ THE DIRECTORY. ALL DIRECTORY ENTRIES ARE * 01600019
*   READ AND SORTED INTO GLOBAL FILE #6 WITH THE TTR OF THE MEMBER AND* 01700019
*   FIVE BLANKS AS THE KEY. WHEN ALL MEMBERS HAVE BEEN SORTED BY TTR, * 01800019
*   THE OUTPUT DCB (CONTAINED IN IHKCDP MODULE) IS OPENED AND THE     * 01900019
*   UTILITY SORT FILE IS POSITIONED TO THE BEGINING (MEMBER WITH      * 02000019
*   LOWEST TTR). THE ADDRESS OF THE NEXT BLOCK TO BE READ (WHEN       * 02100019
*   PROCESSING THE FIRST MEMBER, THE ADDRESS IS THE BLOCK FOLLOWING   * 02200019
*   THE DIRECTORY) IS MOVED FROM THE INPUT DCB TO THE OUTPUT DCB, AND * 02300019
*   THE TTR IN THE OUTPUT DCB FOR THE BEGINING OF THIS MEMBER IS      * 02400019
*   UPDATED TO THE ADDRESS MOVED.                                     * 02500019
*   A MEMBER FROM THE UTILITY SORT FILE (LOWEST TTR NOT PROCESSED) IS * 02600019
*   RETRIEVED, AND THE INPUT DCB IS POSITIONED TO THE BEGINING OF THAT* 02700019
*   MEMBER. THE MEMBER IS THEN READ USING THE INPUT DCB AND THE TYPE  * 02800019
*   OF OPERATION IS THEN DETERMINED.                                  * 02900019
*   THREE MODES OF OPERATION CAN EXIST: SKIP, COPY OR DUMP. IN SKIP   * 03000019
*   MODE THE MEMBER IS ALREADY LOCATED IN ITS MOST CONDENSED FORM IN  * 03100019
*   THE DATA SET, NO UNUSED SPACE HAS BEEN ENCOUNTERED. IN COPY MODE  * 03200019
*   AT LEAST TWO TRACKS OF UNUSED SPACE HAVE BEEN ENCOUNTERED. THE    * 03300019
*   MEMBER IS TO BE COPIED FROM ITS OLD POSITION IN THE DATA SET TO A * 03400019
*   NEW ONE SO THAT NO UNUSED SPACE EXISTS. TWO TRACKS OF UNUSED SPACE* 03500019
*   MUST EXIST BECAUSE THE RECORDS ARE WRITTEN USING A WRITE OF COUNT,* 03600019
*   KEY, AND DATA. THIS FORM OF WRITE ERASES THE PORTION OF THE TRACK * 03700019
*   FOLLOWING DATA. IF A BLOCK TO BE WRITTEN WILL NOT FIT ON THE      * 03800019
*   CURRENT TRACK, THE ACCESS METHOD (BSAM) WILL WRITE IT ON THE NEXT * 03900019
*   TRACK AND ERASE THE REMAINDER OF THE TRACK. THUS, BEFORE A MEMBER * 04000019
*   CAN BE COPIED. AT LEAST TWO TRACKS OF UNUSED SPACE MUST BE        * 04100019
*   AVAILABLE SO THAT NO DATA IS LOST. IF CRJE IS MODIFIED TO HANDLE  * 04200019
*   GREATER THAN TRACK BLOCKING, THE CONDENSE ALGORITHN MUST ALSO BE  * 04300019
*   MODIFIED.                                                         * 04400019
*   IF A MEMBER NEEDS TO BE COPIED BUT TWO UNUSED TRACKS DO NOT EXIST,* 04500019
*   DUMP MODE IS ENTERED TO PROVIDE AT LEAST TWO TRACKS. IN DUMP MODE * 04600019
*   THE MEMBER IS SPILLED TO A SECOND PRIVATE FILE IN THE ACTIVE AREA,* 04700019
*   KEEPING A COUNT OF THE NUMBER OF RECORDS AND NUMBER OF MEMBERS    * 04800019
*   DUMPED. WHEN THE LAST MEMBER OF THE PDS HAS BEEN COPIED, ALL FILES* 04900019
*   THAT WERE SPILLED WILL BE COPIED BACK TO THE PDS.                 * 05000019
*   EACH MEMBER, USING THE INPUT DCB, IS READ AND EITHER SKIPPED,     * 05100019
*   COPIED, OR DUMPED.                                                * 05200019
*   EACH MEMBER, USING THE INPUT DCB, IS READ AND EITHER SKIPPED,     * 05300019
*   COPIED, OR DUMPED. FOR EACH MEMBER SKIPPED OR COPIED, THE UTILITY * 05400019
*   SORT FILE ENTRY IS DELETED. ON A COPY THE NEW TTR OF THE MEMBER   * 05500019
*   IS STOWED IN THE DIRECTORY. FOR EACH MEMBER DUMPED, THE UTILITY   * 05600019
*   SORT FILE ENTRY IS REPLACED USING THE COUNT OF RECORDS DUMPED AS  * 05700019
*   THE KEY. THE ACTUAL DATA RECORDS ARE SPILLED SEQUENTIALLY TO THE  * 05800019
*   PRIVATE FILE THAT WAS CREATED.                                    * 05900019
*   WHEN ALL MEMBERS OF THE PDS HAVE BEEN READ, THE SPILLED MEMBERS   * 06000019
*   (IF ANY) ARE COPIED BACK TO THE PDS, THE DIRECTORY ENTRY IS       * 06100019
*   STOWED, AND THE UTILITY SORT FILE ENTRY IS DELETED.               * 06200019
*                                                                     * 06300019
*ENTRY POINTS-                                                        * 06400019
*        IHKCDP IS THE ONLY ENTRY POINT.                              * 06500019
*                                                                     * 06600019
*INPUT-                                                               * 06700019
*   AT ENTRY REGISTER ONE CONTAINS THE ADDRESS OF A TWO WORD PARAMETER* 06800019
*   LIST. WORD ONE IS THE ADDRESS OF THE TUB. WORD TWO IS THE ADDRESS * 06900019
*   OF THE AVT.                                                       * 07000019
*                                                                     * 07100019
*OUTPUT-                                                              * 07200019
*   LIBRARY IN CONDENSED FORM.                                        * 07300019
*                                                                     * 07400019
*EXTERNAL ROUTINES-                                                   * 07500019
*        IHKAFI - TO ACCESS ACTIVE AREA.                              * 07600019
*        IHKBPM - TO ACCESS USER LIBRARY.                             * 07700019
*        IHKRNQ - TO GET ON LIBARY I/O QUEUE.                         * 07800019
*        BPAM   - STOW, TO UPDATE DIRECTORY ENTRIES                   * 07900019
*        SVC 25 - STAND ALONE SEEK                                    * 08000019
*                                                                     * 08100019
*EXITS-NORMAL                                                         * 08200019
*   RETURN TO IHKCMD WITH CODE IN REGISTER FIFTEEN TO DELETE IHKCDP   * 08300019
*   AND LOAD IHKSAV. TUBPARM5 HAS COMPLETED CODE OF ZERO.             * 08400019
*                                                                     * 08500019
*EXITS-ERROR                                                          * 08600019
*   SAME AS NORMAL EXCEPT TUBPARM5 WILL HAVE:                         * 08700019
*        4  -  ACTIVE AREA I/O ERROR, LIBRARY NOT MODIFIED            * 08800019
*        8  -  ACTIVE AREA I/O ERROR, LIBRARY MODIFIED                * 08900019
*        12 -  LIBRARY I/O ERROR, LIBRARY NOT MODIFIED                * 09000019
*        16 -  LIBRARY I/O ERROR, LIBRARY MODIFICATION STARTED        * 09100019
*        20 -  GETMAIN FAILURE                                        * 09200019
*                                                                     * 09300019
*TABLES/WORK AREAS-                                                   * 09400019
*   A 72 BYTE SAVE AREA AND AN 888 BYTE LIBRARY I/O BUFFER ARE        * 09500019
*   GETMAINED.                                                        * 09600019
*                                                                     * 09700019
*   TUB - ACTIVE FILE AND LIBRARY I/O FIELDS ARE MODIFIED FOR THE     * 09800019
*        VARIOUS MACROS.                                              * 09900019
*                                                                     * 10000019
*ATTRIBUTES-                                                          * 10100019
*   REENTRANT AND NONRESIDENT. MADE SERIALLY REUSABLE BY ENQUEUING ON * 10200019
*        GLOBAL FILE 9 QUEUE.                                         * 10300019
*                                                                     * 10400019
*********************************************************************** 10500019
         SPACE 5                                                        10600019
*                                                                       10700019
* REGISTER DEFINITIONS                                                  10800019
*                                                                       10900019
         REQU                                                           11000019
WK1RG    EQU   1                       WORK REGISTERS, BASES            11100019
WK2RG    EQU   2                          (EVEN)                        11200019
WK3RG    EQU   3                          (ODD)                         11300019
LNKRG    EQU   4                       INTERNAL LINKAGE REGISTER        11400019
R1       EQU   1                       OS MACRO PARAMETER REG.          11500019
R2       EQU   2                       NQ PARAMETER REG.                11600019
SAV      EQU   13                                                       11700019
R13      EQU   13                      OS SAVE AREA REGISTER            11800019
ZIP      EQU   0                                                        11900019
BAC      EQU   14                                                       12000019
GO       EQU   15                                                       12100019
R15      EQU   15                      OS RETURN CODE REGISTER          12200019
         SPACE 5                                                        12300019
*                                                                       12400019
*                                                                       12500019
*                                                                       12600019
* ENQUEUE CONDENSATION REQUEST AS LOW PRIORITY BPAM FUNCTION            12700019
*                                                                       12800019
IHKCDP   CSECT                                                          12900019
         SAVE  (14,12),,*                                               13000019
         LR    BASERG,GO           SET UP BASE REGISTER                 13100019
         USING IHKCDP,BASERG                                            13200019
         L     FBXRG,0(R1)         ADDRESS OF TUB                       13300019
         USING TUBDSECT,FBXRG                                           13400019
         L     LBXRG,4(R1)         ADDRESS OF AVT                       13500019
         USING AVTDSECT,LBXRG     ADDRESS ACON DSECT                    13600019
         LA    WORK,SAVLNG         LENGTH FOR GETMAIN OF SAVE AREA      13700019
         LA    KBXRG,TUBPARM1      ADDRESS OF GOTTEN CORE IN TUBPARM1   13800019
         L     R1,IHKYYGML         ADDRESS OG PARM LIST                 13900019
         GETMAIN EC,LV=(6),A=(8),MF=(E,(1))                             14000019
         LTR   GO,GO               GETMAIN SUCCESSFUL                   14100019
         LA    GO,R20              SET RETURN CODE ON FAILURE           14200019
         BNZ   CDPEXT              NO GET OUT                           14300019
CDPGO    L     WORK,TUBPARM1       ADDRESS OF SAVE AREA                 14400019
         ST    WORK,8(SAV)         CHAIN SAVE AREAS                     14500019
         ST    SAV,4(WORK)                                              14600019
          LR    SAV,WORK            CHANGE SAVE AREA POINTER            14700019
         ST    FBXRG,TUBPARM2      TUB ADDRESS FOR AFIO AND BPAM CALLS  14800019
         L     KBXRG,IHKYYKBX      ADDRESS OF KON BOX                   14900019
         USING RAFKNBX,KBXRG      ADDRESS KONBOX DSECT                  15000019
         MVI   GBLNUMFS,GBUTFILE       QUEUE UP FOR GLOBAL FILE         15100019
          LA    R1,TUBPARM2         TUB POINTER FOR I/O                 15200019
         CREATE IS,FTYPE=XGBL          FILE USED FOR DIRECTORY SORT     15300019
         NI    SWITCCS,X'FF'-ERR1-ERR2-ERR3      RESET ERROR MESSAGES   15400019
         XC    DUMPCNT(2),DUMPCNT         AND DUMPED FILE COUNT         15500019
         ST    FBXRG,SAVETUB       TUB ADDRESS FOR AFIO AND BPAM CALLS  15600019
         LTR   GO,GO               CHECK RETURN FROM I/O                15700019
         BNZ   CDERR1                   EXIT ON ERROR OR NO SPACE       15800019
NOTLAST  LA    R1,BPQELMFW             GET ON BPAM QUEUE                15900019
         LA    R2,BPQCTLFW                                              16000019
         L     GO,IHKYYRNQ         ADDRESS OF ENQ ROUTINE FOR LIBIO     16100019
         CALL  (15),((1),(2))                                           16200019
         LTR   GO,GO               GETMAIN FAIL IN IHKRNQ               16300019
         BNZ   CDEND5              YES GET OUT                          16400019
         L     R1,BPQELMFW         Q ELIMENT                            16500019
         ST    R1,BPQCTLFW         STORE IN Q CONTROL ( DEQUEUE )       16600019
         LA    R1,0(R1)            CLEAR HIGH ORDER BYTE                16700019
         LA    R2,BPQCTLFW+4       POINTER TO LAST ON QUEUE             16800019
         CR    R1,R2               AM I ONLY ONE ON Q                   16900019
         BE    GETONQ              YES GET BACK ON Q                    17000019
*              INSURE THAT CONDENSE IS ONLY FUNCTION WAITING FOR BPAM   17100019
*              IF NOT ONLY, GET OFF Q AND GET ON END OF Q               17200019
         OI    4(R1),NQFLAG        POST NEXT REQUESTOR ON Q             17300019
         B     NOTLAST             GET ON BOTTOM OF Q                   17400019
*                                                                       17500019
GETONQ   EQU   *                                                        17600019
         LA    R1,BPQELMFW             GET ON BPAM QUEUE                17700019
         LA    R2,BPQCTLFW                                              17800019
         L     GO,IHKYYRNQ         ADDRESS OF ENQ ROUTINE FOR LIBIO     17900019
         CALL  (15),((1),(2))                                           18000019
         L     R1,TUBPPTAD         ADDRESS OF PPT WHICH HAS DDNAME      18100019
         MVC   BPPARMFS(8),24(R1)  GET DDNAME FOR LIB I/O               18200019
         LTR   GO,GO               GOOD RETURN FROM UTM                 18300019
         BC    7,CDEND5                   UNLESS ERROR                  18400019
         MVC   GBLKEYFS+3(5),K8X40KN   SET FOR 3 BYTE KEYS              18500019
         OI    TUBAFISW,BUFCNTRL   INDICATE TO IHKAFI AND IHKBPM        18600019
*                                  THAT IHKCDP IS SUPPLYING ITS         18700019
*                                  OWN BUFFER                           18800019
         LA    R2,SFBUFF1          LIB I/O BUFFER ADDRESS               18900019
         L     R1,IHKYYGML         ADDRESS OF GETMAIN LIST              19000019
         GETMAIN EC,LV=888,A=(2),MF=(E,(1))                             19100019
         LTR   GO,GO               GETMAIN SUCCESSFUL                   19200019
         BNZ   CDEND5              NO RETURN CONTROL TO SAVE            19300019
         L     R1,SFBUFF1          ADDRESS OF GOTTEN CORE               19400019
         LA    ZIP,BUFLNG          SUBPOOL 0 AND LENGTH OF 880          19500019
         STM   ZIP,R1,0(R1)        PUT CONTROL INFO. IN BUFFER          19600019
         SPACE 2                                                        19700019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 19800019
         RBPAMASK F                    PREPARE TO READ LIBRARY DIRECTOR 19900019
         RFIND                                                          20000019
         CH    GO,RC4              CHECK RETURN FROM I/O                20100019
         BH    CDERR3                   EXIT ON I/O ERROR               20200019
         SPACE 3                                                        20300019
*                                                                       20400019
* SORT LIBRARY DIRECTORY INTO ACTIVE FILE                               20500019
*                                                                       20600019
CDDIR1   LA    R1,SAVETUB          TUB ADDRESS FOR I/O                  20700019
         RREAD                                                          20800019
         CH    GO,RC4              CHECK RETURN FROM I/O                20900019
         BH    CDERR3                   EXIT ON I/O ERROR               21000019
         BE    CDCPY1                   BRANCH IF PHYSICAL EOD          21100019
         CLI   GBLKEYFS+7,0            HAS LAST ACTIVE BLOCK BEEN READ? 21200019
         BE    CDDIR1                     BRANCH IF YES.                21300019
         MVC   DIRCNT(2),H2KN          SET FOR 2 PROCESSED BYTES        21400019
*                                                                       21500019
* PROCESS NEXT DIRECTORY BLOCK ENTRY                                    21600019
*                                                                       21700019
CDDIR2   EQU   *                                                        21800019
         L     WK1RG,SFBUFF1           ADDRESS DIRECTORY BLOCK          21900019
         USING FDIDSDS,WK1RG                                            22000019
         LH    WK2RG,DIRCNT            PICK UP BLOCK DISPLACEMENT       22100019
         CH    WK2RG,ACTDATA           BLOCK COMPLETELY PROCESSED?      22200019
         BNL   CDDIR1                     BRANCH IF YES                 22300019
         LA    WK1RG,ACTDATA(WK2RG)    ADDRESS NEXT MEMBER              22400019
         USING NAME,WK1RG                                               22500019
         CLC   NAME,BPAMEOD            CHECK FOR LAST ENTRY             22600019
         BNE   CDDIR4                     BRANCH IF NO                  22700019
         DROP  WK1RG                                                    22800019
         MVI   GBLKEYFS+7,0            SET TO POSITION TO BEGINNING     22900019
         B     CDDIR1                     AND GO READ NEXT              23000019
*                                                                       23100019
* SET UP RAFIO RECORD AND BUMP TO NEXT DIRECTORY ENTRY                  23200019
*                                                                       23300019
CDDIR4   BAL    BAC,GETBUF          GET AFIO BUFFER                     23400019
         L     WK1RG,SFBUFF1           ADDRESS NEXT MEMBER AGAIN        23500019
         USING FDIDSDS,WK1RG                                            23600019
         LH    WK2RG,DIRCNT                                             23700019
         LA    WK1RG,ACTDATA(WK2RG)                                     23800019
         USING NAME,WK1RG                                               23900019
         L     WK3RG,BUFFADSS             AND RAFIO BUFFER              24000019
         USING BUFFERDS,WK3RG                                           24100019
         MVC    BUFNAME(GBLTEXT),NAME  MOVE DIRECTORY ENTRY             24200019
         MVC   GBLKEYFS(3),TTR            AND GENERATE KEY              24300019
         MVC   BUFKEY(8),GBLKEYFS  MOVE KEY TO RECORD                   24400019
         MVC   BUFNAME+GBLTEXT(8),TUBUSRID MOVE IDENTIFIER              24500019
         DROP  WK3RG                                                    24600019
         SR    WK3RG,WK3RG             BUMP TO NEXT DIRECTORY ENTRY     24700019
         NI    DATALEN,B'00011111'                                      24800019
         IC    WK3RG,DATALEN                                            24900019
         AR    WK3RG,WK3RG                                              25000019
         DROP  WK1RG                                                    25100019
         LA    WK2RG,FDIDS-NAME(WK2RG,WK3RG)                            25200019
         STH   WK2RG,DIRCNT               AND SAVE                      25300019
*                                                                       25400019
* OUTPUT RAFIO RECORD                                                   25500019
*                                                                       25600019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 25700019
         RPOINT A,NR,KEY=HIEQ,FTYPE=XGBL   SORT ENTRY BY TTR            25800019
         CH    GO,RC4              CHECK RETURN FROM I/O                25900019
         BH    CDERR4                   MUST ALREADY EXIST              25960019
         BL    CDERR3              IF FOUND, LIBRARY IS CLOBBERED       26020019
         INSERT S,FTYPE=XGBL              AND INSERT RECORD             26100019
         LTR   GO,GO               CHECK RETURN FROM I/O                26200019
         BC    8,CDDIR2                BACK FOR NEXT IF NO ERRORS       26300019
         B     CDERR4                     ACTIVE FILE ERROR             26400019
         SPACE 3                                                        26500019
*                                                                       26600019
* MEMBER BY MEMBER COPY OF LIBRARY                                      26700019
*                                                                       26800019
CDCPY1   BAL   LNKRG,CDSWICH0          SWITCH TO OUTPUT DATA SET        26900019
         RBPAMASK O                    SET TO OPEN DATA SET             27000019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 27100019
         RFIND                                                          27200019
         BAL   LNKRG,CDSWICH0             AND SWITCH BACK               27300019
         CH    GO,RC4              CHECK RETURN FROM I/O                27400019
         BH    CDERR3                   EXIT ON I/O ERROR               27500019
         USING IHADCB,WK2RG            ADDRESS CONDENSE DCB             27600019
         NI    DCBOFLGS,X'FF'-TRKBALOK      DETERMINE NEW TRACK BALANCE 27700019
         LH    WK3RG,DCBBLKSI          SET UP ACTUAL BLOCK SIZE FOR     27800019
         LH    WK2RG,DCBLRECL             INPUT DATA SET                27900019
         DROP  WK2RG                                                    28000019
         USING IHADCB,WK1RG                                             28100019
         STH   WK3RG,DCBBLKSI                                           28200019
         STH   WK2RG,DCBLRECL                                           28300019
         DROP  WK1RG                                                    28400019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 28500019
         RPOINT B,NR,FTYPE=XGBL        START WITH SMALLEST TTR          28600019
         MVI   GBLKEYFS+7,C' '                                          28700019
         CH    GO,RC4              CHECK RETURN FROM I/O                28800019
         BH    CDERR4                   EXIT ON ERROR                   28900019
*                                                                       29000019
* UPDATE OUTPUT MEMBER ADDRESS                                          29100019
*                                                                       29200019
CDCPY2   L     WK1RG,BPDCBPTR          LOCATE INPUT DCB                 29300019
         L     WK2RG,CDDCBPT              AND OUTPUT DCB                29400019
         USING IHADCB,WK2RG                                             29500019
         MVC   DCBFDAD,DCBFDAD-IHADCB(WK1RG)     LOCATE LAST EOD        29600019
         NOTE  (WK2RG)                    AND GENERATE TTR0             29700019
         AL    R1,F256KN                  OF NEXT (FIRST) MEMBER        29800019
         ST    R1,DCBRELAD                                              29900019
         DROP  WK2RG                                                    30000019
*                                                                       30100019
* LOCATE NEXT INPUT MEMBER                                              30200019
*                                                                       30300019
CDCPY3   BAL   LNKRG,CDGETDIR          SET UP NEXT BLDL LIST            30400019
         BC    8,CDDUMP1                  BRANCH IF LAST MEMBER DONE    30500019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 30600019
         RFIND I                       LOCATE BEGINNING OF MEMBER       30700019
         LTR   GO,GO               CHECK RETURN FROM I/O                30800019
         BC    7,CDERR3                   EXIT ON ERROR                 30900019
         MVC   CDTTRSAV(3),BPBLDLST+12 SAVE TTR OF MEMBER               31000019
         XC    RECOUNT(2),RECOUNT         AND ZERO RECORD COUNT         31100019
*                                                                       31200019
* READ NEXT INPUT BLOCK OR EOD                                          31300019
*                                                                       31400019
CDCPY4    LA    R1,SAVETUB          TUB POINTER FOR I/O                 31500019
         RREAD                                                          31600019
         CH    GO,RC4              CHECK RETURN FROM I/O                31700019
         BH    CDERR3                   EXIT ON I/O ERROR               31800019
         BE    CDCPY8                   BRANCH ON END OF DATA           31900019
         BAL   LNKRG,CDCPMODE          DETERMINE COPY MODE              32000019
         B     CDCPY4                     SKIP                          32100019
         BC    12,CDCPY5                  DUMP                          32200019
*                                                                       32300019
* COPY BLOCK IN PLACE                                                   32400019
*                                                                       32500019
         MVC   COUNTFS(1),COUNTFS+1       COPY.  SET UP RECORD COUNT    32600019
         BAL   LNKRG,CDPUTBLK             AND OUTPUT BPAM BLOCK         32700019
         B     CDCPY4                  BACK FOR NEXT INPUT BLOCK        32800019
*                                                                       32900019
* DUMP BLOCK TO RAFIO INTERMEDIATE FILE                                 33000019
*                                                                       33100019
CDCPY5   SR    WK2RG,WK2RG             UPDATE COUNT OF DUMPED           33200019
         IC    WK2RG,COUNTFS+1            RECORDS                       33300019
         LH    WK1RG,RECOUNT                                            33400019
         AR    WK2RG,WK1RG                                              33500019
         STH   WK2RG,RECOUNT                                            33600019
         LTR   WK1RG,WK1RG             WAS COUNT ZERO                   33700019
         BC    7,CDCPY6                   BRANCH IF NOT                 33800019
         LH    WK1RG,DUMPCNT              YES, UPDATE COUNT OF          33900019
         LTR   WK1RG,WK1RG                DUMPED FILES                  34000019
         LA    WK1RG,1(WK1RG)                                           34100019
         STH   WK1RG,DUMPCNT                                            34200019
         BC    7,CDCPY6                IS THIS THE FIRST DUMPED FILE?   34300019
         MVC   GBLKEYFS(3),CDTTRSAV       YES, SAVE TTR KEY             34400019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 34500019
         CREATE IS,ACTNUM=2            GENERATE A USER UTILITY FILE     34600019
         LTR   GO,GO               CHECK RETURN FROM I/O                34700019
         BC    7,CDERR4                 FOR DUMPED FILES. EXIT ON ERROR 34800019
CDCPY6   MVC   BUFFADSS(4),SFBUFF1 MOVE BLOCK TO AFIO BUFFER            34900019
         LA    R1,SAVETUB          TUB POINTER FOR I/O                  35000019
         INSERT M                         AND DUMP IT                   35100019
         LTR   GO,GO               CHECK RETURN FROM I/O                35200019
         BZ    CDCPY4                     BACK FOR NEXT BLOCK IF NO ERR 35300019
         B     CDERR4                     EXIT ON ERROR                 35400019
*                                                                       35500019
* PROCESS END OF MEMBER CONDITION                                       35600019
*                                                                       35700019
CDCPY8   BAL   LNKRG,CDCPMODE          END OF MEMBER, CHECK MODE        35800019
         B     CDCPY2                     SKIP                          35900019
         BC    12,CDCPY9                  DUMP                          36000019
         BAL   LNKRG,CDSTOW               COPY, UPDATE DIRECTORY        36100019
         B     CDCPY3                     AND GET NEXT MEMBER           36200019
*                                                                       36300019
* SAVE RECORD COUNT OF DUMPED MEMBER                                    36400019
*                                                                       36500019
CDCPY9   BAL   BAC,GETBUF          GET AFIO BUFFER                      36600019
         L     WK3RG,BUFFADSS             ADDRESS IT                    36700019
         USING BUFFERDS,WK3RG                                           36800019
         MVC    BUFNAME(GBLTEXT),BPBLDLST+4   RECONSTRUCT DIRECTORY     36900019
         MVC   BUFKEY(3),BPBLDLST+12 WITH RECORD COUNT                  37000019
         MVC   BUFKEY(5),K8X40KN   RATHER THAN TTR                      37100019
         DROP  WK3RG                                                    37200019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 37300019
         REPLACE NXK,A,REC=PREVIOUS,FTYPE=XGBL    AND REPLACE PRESENT   37400019
         LTR   GO,GO               CHECK RETURN FROM I/O                37500019
         BC    8,CDCPY3                CONTINUE TO NEXT MEMBER          37600019
         B     CDERR4                     UNLESS ERROR                  37700019
         SPACE 3                                                        37800019
*                                                                       37900019
* COPY BACK DUMPED MEMBERS                                              38000019
*                                                                       38100019
CDDUMP1  LH    WK1RG,DUMPCNT           ANY MEMBERS DUMPED?              38200019
         LTR   WK1RG,WK1RG                                              38300019
         BZ    CDEND0                     BRANCH IF NOT                 38400019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 38500019
         RPOINT B,NR,KEY=FIRST         POSITION TO FIRST DUMPED MEMBER  38600019
         LTR   GO,GO               CHECK RETURN FROM I/O                38700019
         BC    7,CDERR4                   EXIT ON ERROR                 38800019
         RPOINT B,NR,FTYPE=XGBL        POSITION TO DIRECTORY ENTRY OF   38900019
         LTR   GO,GO               CHECK RETURN FROM I/O                39000019
         BC    7,CDERR4                   FIRST ONE.  EXIT ON ERROR     39100019
*                                                                       39200019
* GET DIRECTORY IMFO AND RECORD COUNT FOR NEXT MEMBER                   39300019
*                                                                       39400019
CDDUMP2  BAL   LNKRG,CDGETDIR          GET NEXT DIRECTORY ENTRY         39500019
         BE    CDERR4                   EOD = ERROR                     39600019
CDDUMP3  LH    WK2RG,BPCNTSAV          PICK UP MAXIMUM RECORD COUNT     39700019
         LH    WK1RG,RECOUNT              AND REMAINDER COUNT           39800019
         LTR   WK1RG,WK1RG                                              39900019
         BZ    CDDUMP5                    BRANCH IF NO RECORDS LEFT     40000019
*                                                                       40100019
* OUTPUT NEXT BLOCK                                                     40200019
*                                                                       40300019
         CR    WK1RG,WK2RG             TRUNCATED BLOCK NEXT?            40400019
         BNL   CDDUMP4                    NO, BRANCH                    40500019
         LR    WK2RG,WK1RG                YES, RESET TO SMALLER         40600019
CDDUMP4  SR    WK1RG,WK2RG             UPDATE REMAINING RECORD COUNT    40700019
         STH   WK1RG,RECOUNT              AND SAVE                      40800019
         STH   WK2RG,COUNTFS           SETUP RAFIO RECORD COUNT         40900019
         MVC   BUFFADSS(4),SFBUFF1 PROVIDE BUFFER FOR IHKAFI            41000019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 41100019
         RGET  R,M,A                   GET THE NEXT BLOCK               41200019
         LTR   GO,GO               CHECK RETURN FROM I/O                41300019
         BC    7,CDERR4                   EXIT ON ERROR                 41400019
         BAL   LNKRG,CDPUTBLK             AND RESTORE BLOCK TO LIBRARY  41500019
         B     CDDUMP3                 BACK FOR NEXT BLOCK              41600019
*                                                                       41700019
* UPDATE DIRECTORY AND CHECK FOR END OF DUMP RESTORE                    41800019
*                                                                       41900019
CDDUMP5  BAL   LNKRG,CDSTOW            UPDATE DIRECTORY                 42000019
         LH    WK1RG,DUMPCNT              AND DECREMENT FILE COUNT      42100019
         SH    WK1RG,H1KN                                               42200019
         STH   WK1RG,DUMPCNT                                            42300019
         BP    CDDUMP2                 BACK FOR NEXT FILE IF MORE       42400019
         BCTR  WK1RG,0                 INDICATE DUMP RESTORE            42500019
         STH   WK1RG,DUMPCNT              SUCCESSFUL                    42600019
*                                                                       42700019
* SPECIAL SVC 25 PROCESSING FOR EMPTY (OR CONDENSED) LIBRARY            42800019
*                                                                       42900019
CDEND0   TM    SWITCCS,ERR3            IS LIBRARY EMPTY?                43000019
         BO    CDEND1                     BRANCH IF NO                  43100019
         L     R1,CDDCBPT              ADDRESS CONDENSATION DCB         43200019
         USING IHADCB,R1                                                43300019
         SVC   SEEK                    INDICATE DSCB IS TO BE UPDATED   43400019
         DROP  R1                                                       43500019
         OI    SWITCCS,ERR3            LIBRARY MODIFIED                 43600019
         SPACE 3                                                        43700019
*                                                                       43800019
* CLOSE DATA SETS AND RELEASE TEMPORARY ACTIVE FILES                    43900019
*                                                                       44000019
CDEND1   L     WK3RG,CDDCBPT           ADDRESS CONDENSATION DCB         44100019
         USING IHADCB,WK3RG                                             44200019
         TM    DCBOFLGS,OPEN           CHECK FOR DCB OPEN               44300019
         BZ    CDEND3                     NO (DIDN'T GET FAR)           44400019
         TM    SWITCCS,ERR1+ERR2       CHECK FOR ANY ERRORS             44500019
         BZ    CDEND2                     BRANCH IF NOT                 44600019
         NI    DCBOFLGS,X'FF'-TRKBALOK PREVENT DSCB UPDATE ON CLOSE     44700019
CDEND2   CLOSE ,MF=(E,BPOPEN)          CLOSE CONDENSE DATA SET          44800019
         DROP  WK3RG                                                    44900019
CDEND3    L     WK1RG,SFBUFF1       GET POINTER TO BUFFER               45000019
          LM    ZIP,R1,0(WK1RG)     GET LENGTH AND ADDRESS TO FREE      45100019
         FREEMAIN R,A=(1),LV=(0)   RELEASE BUFFER                       45200019
         SPACE                                                          45300019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 45400019
         RCLOSE NOSTOW                                                  45500019
         LH    WK1RG,DUMPCNT           ANY FILES DUMPED?                45600019
         LTR   WK1RG,WK1RG                                              45700019
         BZ    CDEND5                     BRANCH IF NOT                 45800019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 45900019
         RELEASE A                     RELEASE PRIVATE FILE             46000019
         CREATE O                      RECREATE USER FILE (IF ANY)      46100019
         SPACE                                                          46200019
CDEND5   LA    R1,SAVETUB          TUB ADDRESS FOR I/O                  46300019
         RELEASE A,FTYPE=GBL           RELEASE GLOBAL SORT FILE         46400019
         SR    GO,GO               SET GOOD RETURN CODE                 46500019
         NI    SWITCCS,ERR1+ERR2+ERR3 CLEAR SWITCH EXCEPT ERROR BITS    46600019
         IC    GO,SWITCCS          PUT CODE IN REGISTER 15              46700019
          SLL   GO,2                MULTIPLY BY FOUR                    46800019
          SH    GO,H4KN             SUBTRACT FOUR                       46900019
         LTR   GO,GO               IF MINUS UTM HAD DISK ERROR          47000019
         BM    CDRET               IF SO SET RC=20                      47100019
CDBPRET  EQU   *                                                        47200019
         NI    TUBAFISW,ALL-BUFCNTRL  TURN OFF BUFFER CONTROL           47300019
         LA    R1,0(SAV)           AREA TO FREE                         47400019
         L     SAV,4(SAV)          RESTORE SAVE AREA POINTER            47500019
         LA    ZIP,SAVLNG          LENGTH TO FREE                       47600019
         FREEMAIN R,LV=(0),A=(1)                                        47700019
CDPEXT   ST    GO,TUBPARM5         SAVE RETURN CODE FOR IHKSAV          47800019
         LA    GO,CMDSAV           LOADER/CONTROLLER CODE FOR IHKSAV    47900019
         LNR   GO,GO               INDICATE TO SYSTEM ADDMINISTRATOR    48000019
*                  (IHKCMD) TO DELETE ME AND LOAD IHKSAV                48100019
         RETURN (14,12),T,RC=(15)                                       48200019
CDRET    LA    GO,R20              IF SO SET RC=20                      48300019
         B     CDBPRET             RETURN                               48400019
         SPACE 3                                                        48500019
*                                                                       48600019
* ERROR EXITS                                                           48700019
*                                                                       48800019
CDERR1   OI    SWITCCS,ERR2            NO ROOM FOR GLOBAL FILE          48900019
         B     CDEND5                  RELEASE GLOBAL FILE AND EXIT     49000019
CDERR3   OI    SWITCCS,ERR1            USER LIBRARY I/O ERROR           49100019
         B     CDEND1                     CLOSE DCB'S AND EXIT          49200019
CDERR4   OI    SWITCCS,ERR2            ACTIVE FILE ERROR                49300019
         B     CDEND1                     DISPOSE OF DATA SETS/EXIT     49400019
         SPACE 3                                                        49500019
*                                                                       49600019
* OUTPUT BPAM BLOCK AND CHECK FOR ERRORS                                49700019
*                                                                       49800019
CDPUTBLK ST    LNKRG,SAVELKCS          SAVE LINKAGE                     49900019
         BAL   LNKRG,CDSWITCH          SWITCH TO BPAM OUTPUT            50000019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 50100019
         RWRITE                                                         50200019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 50300019
         L     GO,IHKYYWTR         WAIT AND CHECK ROUTINE               50400019
         BALR  BAC,GO                                                   50500019
         LTR   GO,GO               CHECK RETURN FROM I/O                50600019
         BAL   LNKRG,CDSWICH0             SWITCH BACK TO INPUT          50700019
         L     LNKRG,SAVELKCS          RESTORE LINKAGE                  50800019
CDPUTRET BCR   8,LNKRG                    AND EXIT IF NO ERRORS         50900019
         B     CDERR3                     EXIT ON ERRORS                51000019
         SPACE 3                                                        51100019
*                                                                       51200019
* DO BPAM STOW (NO CLOSE)                                               51300019
*                                                                       51400019
CDSTOW   L     R1,CDDCBPT              ADDRESS CONDENSATION DCB         51500019
         USING IHADCB,R1                                                51600019
         SPACE 2                                                        51700019
*                                                                       51800019
*        THE FOLLOWING CODE WRITES TWO BYTES AT THE END OF THE MEMBER   51900019
*        TO INSURE THAT THE END OF FILE MARK CAN BE WRITTEN BY STOW.    52000019
*        IF THE WRITE IS GOOD, THE DCB IS RESTORED TO INDICATE THE      52100019
*        WRITE NEVER OCCURRED AND A STOW IS ISSUED WHICH WRITES AN EOD  52200019
*        THAT OVERLAYS MY DUMMY WRITE.                                  52300019
*                                                                       52400019
         SPACE 2                                                        52500019
         ST    LNKRG,SAVLKCS       SAVE LINKAGE REGISTER                52600019
         MVC   SAVFDAD(8),DCBFDAD  SAVE CCHHR                           52700019
         MVC   SAVTRBAL(2),DCBTRBAL SAVE TRACK BALANCE                  52800019
         MVC   SAVLRECL(2),DCBLRECL SAVE LOGICAL RECORD LENGTH          52900019
         MVI   COUNTFS,ONE         SET FOR IHKBPM TO COMPUTE BLOCKSIZE  53000019
         MVC   DCBLRECL(2),H2KN    SET LRECL FOR SHORT WRITE            53100019
         SPACE                                                          53200019
         BAL   LNKRG,CDPUTBLK      WRITE DUMMY EOD AND CHECK RESULTS    53300019
         SPACE                                                          53400019
         L     R1,CDDCBPT              ADDRESS CONDENSATION DCB         53500019
         MVC   DCBFDAD(8),SAVFDAD  RESTORE CCHHR TO DCB                 53600019
         MVC   DCBTRBAL(2),SAVTRBAL RESTORE TRACK BALANCE               53700019
         MVC   DCBLRECL(2),SAVLRECL RESTORE LOGICAL RECORD LENGTH       53800019
         L     LNKRG,SAVLKCS       RESTORE LINKAGE REGISTER             53900019
         STOW  (R1),BPBLDLST+4,R       UPDATE DIRECTORY                 54000019
         LTR   R15,R15                 SET COMPLETION CODE              54100019
         B     CDPUTRET                   AND GO CHECK IT               54200019
         DROP  R1                                                       54300019
         SPACE 3                                                        54400019
*                                                                       54500019
* SWITCH BPAM DATA SET WITH CONDENSATION DATA SET CONTROL               54600019
*                                                                       54700019
*        ON EXIT WK1RG = UPDATED BPDCBPTR,  WK2RG = UPDATED CDDCBPTR    54800019
*        CONDITION CODE UNCHANGED FOR CDSWICH0 ENTRY.  CDSWITCH ENTRY   54900019
*        SETS WRITE PERFORMED INDICATION.                               55000019
*                                                                       55100019
CDSWITCH OI    SWITCCS,ERR3            INDICATE WRITE DONE              55200019
CDSWICH0 IC    WK1RG,BPAMSWCS          SWITCH BPAM ARGUMENT BYTES       55300019
         MVC   BPAMSWCS(1),CDAMSWCS                                     55400019
         STC   WK1RG,CDAMSWCS                                           55500019
         L     WK2RG,BPDCBPTR             AND DCB POINTERS              55600019
         L     WK1RG,CDDCBPT                                            55700019
         ST    WK2RG,CDDCBPT                                            55800019
         ST    WK1RG,BPDCBPTR                                           55900019
         BR    LNKRG                   RETURN                           56000019
         SPACE 3                                                        56100019
*                                                                       56200019
* READ NEXT DIRECTORY RECORD AND SETUP BLDL LIST                        56300019
*                                                                       56400019
*        ON EXIT CC0 IS NORMAL,  CC1 INDICATES EOD                      56500019
*                                                                       56600019
CDGETDIR EQU   *                                                        56700019
         BAL   BAC,GETBUF          SET AFI BUFFER TO TUBUFFAD           56800019
          LA    R1,SAVETUB          TUB POINTER FOR I/O                 56900019
         RGET  R,S,A,FTYPE=XGBL        GET COPY OF NEXT ENTRY           57000019
         CH    GO,RC4              CHECK RETURN FROM I/O                57100019
         BH    CDERR4                   EXIT ON I/O ERROR               57200019
         BCR   8,LNKRG                  EXIT WITH CC=0 IF EOD           57300019
         L     WK1RG,BUFFADSS          ADDRESS RECORD READ              57400019
         USING BUFFERDS,WK1RG                                           57500019
         MVC   BPBLDLST+4(GBLTEXT),BUFNAME       SET UP BLDL LIST       57600019
         DROP  WK1RG                                                    57700019
         BR    LNKRG                      AND RETURN                    57800019
         SPACE 3                                                        57900019
*                                                                       58000019
* DETERMINE MODE OF COPY                                                58100019
*                                                                       58200019
*        BAL   LNKRG,CDCPMODE                                           58300019
*        DS    2H                      SKIP MODE                        58400019
*        DS    H                       COPY IF CC=2/3, DUMP IF CC=0/1   58500019
*                                                                       58600019
CDCPMODE TM    SWITCCS,ERR3            IF COPY HAS STARTED,             58700019
         BO    4(LNKRG)                   EXIT WITH CC=3                58800019
         L     WK1RG,BPDCBPTR          LOCATE THE TWO DATA SETS         58900019
         L     WK2RG,CDDCBPT                                            59000019
         USING IHADCB,WK1RG                                             59100019
         CLC   DCBRELAD(3),DCBRELAD-IHADCB(WK2RG)     EQUAL POSITIONS?  59200019
         BCR   8,LNKRG                 EXIT IF NO HOLES YET             59300019
         LH    WK3RG,DCBRELAD          COMPUTE DIFFERENCE OF TRACKS     59400019
         DROP  WK1RG                                                    59500019
         USING IHADCB,WK2RG                                             59600019
         BCTR  WK3RG,0                    CC0 = +1     DUMP             59700019
         SH    WK3RG,DCBRELAD             CC1 =  0     DUMP             59800019
         B     4(LNKRG)                   CC2 GT 1     COPY             59900019
GETBUF   EQU   *                                                        60000019
         LA    ZIP,EQ88            LENGTH OF GETMAIN                    60100019
         L     R1,TUBUFFAD         USER BUFFER FOR AFIO BUFFER          60200019
         STM   ZIP,R1,0(R1)                                             60300019
         ST    R1,BUFFADSS         PUT BUFFER POINTER IN AFI BUFFER     60400019
         BR    BAC                                                      60500019
         SPACE 3                                                        60600019
*                                                                       60700019
* PROGRAM CONSTANT AND WORK AREAS                                       60800019
*                                                                       60900019
SAVLNG   EQU   72                                                       61000019
CPWORKCS DS    D                                                        61100019
EQ88     EQU   88                                                       61200019
R20      EQU   20                                                       61300019
SAVELKCS DS    F                                                        61400019
SAVLKCS  DC    F'0'                SAVE LINKAGE REGISTER                61500019
SAVFDAD  DC    2F'0'                                                    61600019
SAVTRBAL DC    H'0'                                                     61700019
SAVLRECL DC    H'0'                                                     61800019
ONE      EQU   1                                                        61900019
SAVETUB  DS    F                                                        62000019
H1KN     DC    H'1'                                                     62100019
ALL      EQU   X'FF'                                                    62200019
BUFCNTRL EQU   X'80'                                                    62300019
BUFLNG   EQU   888                                                      62400019
CDDCBPT  DC    A(CDDCB)                                                 62500019
CDDCB    DCB   DSORG=PO,MACRF=(W),OPTCD=W                               62600019
         DS    2F                      APPENDAGE VECTOR SAVE AREA       62700019
         OPEN  (0),MF=L                OPEN/CLOSE LIST                  62800019
         DS    CL2                     SAVE AREA FOR DSCB DIRCT FIELD   62900019
*                                                                       63000019
RC4      DC    H'4'                                                     63100019
SWITCCS  DS    X                                                        63200019
*                                                                       63300019
*SWITCCS  DS    X  THREE BITS (ERR1, ERR2, ERR3 DEFINDED BELOW) GIVE    63400019
*                  STATUS OF CONDENSATION.  001 IS NORMAL, 01X OR 10X   63500019
*                  INDICATES AN ERROR, AND 000 CAN ONLY OCCURE IF THE   63600019
*                  RUSER MACRO FAILS.  11X IS NEVER GIVEN.              63700019
*                                                                       63800019
         SPACE 5                                                        63900019
*                                                                       64000019
* MISCELLANEOUS CONSTANTS                                               64100019
*                                                                       64200019
SEEK     EQU   25                      SVC TO COMPUTE TRACK BALANCE     64300019
GBUTFILE EQU   6                       UTILITY FILE FOR DIRECTORY SORT  64400019
NQFLAG   EQU   X'40'                   NQ COMPLETION FLAG               64500019
GBLTEXT  EQU   40                      LENGTH OF SORT FILE TEXT         64600019
         SPACE 5                                                        64700019
*                                                                       64800019
*                                                                       64900019
* DSECTS REFERENCED                                                     65000019
*                                                                       65100019
         CMDEQU                                                         65200019
         IHKCDSCT TUB=YES,AVT=YES                                       65300019
         TUBEQU                                                         65400019
         RAFKNBX TYPE=DSECT                                             65500019
         FDIDS                                                          65600019
         BUFFERDS                                                       65700019
ISMBUFRG EQU   6                                                        65800019
BUFKEY   EQU   BUFOUTSS            KEY OF UTILITY  ( TTR + 5 BLANKS )   65900019
BUFNAME  EQU   BUFOUTSS+8          MEMBER NAME                          66000019
         DCBD  DSORG=(PO),DEVD=(DA)                                     66100019
DCBCEAP  DS    F                       OS CHANNEL END APPENDAGE SAVE    66200019
DCBABAP  DS    F                       OS ABEND APPENDAGE SAVE          66300019
BPOPEN   OPEN  (0),MF=L                OPEN/CLOSE LIST                  66400019
BPSDIRCT DS    CL2                     SAVE AREA FOR DSCB DIRCT FIELD   66500019
         SPACE 5                                                        66600019
*                                                                       66700019
* WORKING STORAGE AREAS                                                 66800019
*                                                                       66900019
*BPAMSWCS DS    X                      BPAM SWITCH BYTE                 67000019
NS       EQU   B'00000100'             NONSTANDARD LIBRARY              67100019
*                                                                       67200019
*BPBLDLST DS    0H                     BPAM BLDL LIST USED              67300019
RECOUNT  EQU   BPBLDLST+12             TT DOUBLES AS RECORD COUNT       67400019
*                                                                       67500019
*BPCNTSAV DS    H                      MAXIMUM RECORDS/BLOCK (BPAM)     67600019
*                                                                       67700019
*BPDCBPTR DS    A                      NORMAL BPAM DCB POINTER (MODFID) 67800019
*                                                                       67900019
*BUFFADSS DS    A                      RAFIO BUFFER ADDRESS CONTROL     68000019
*                                                                       68100019
*CDDCBPTR DS    A                      SPECIAL CONDENSE DCB PTR (MODFD) 68200019
*                                                                       68300019
*COUNTFS  DS    H                      LOGICAL RECORDS/BLOCK CONTROL    68400019
*                                                                       68500019
*CPWORKCS DS    D                      COMMAND PROCESSOR WORK AREA      68600019
DUMPCNT  EQU   CPWORKCS                COUNT OF FILES DUMPED            68700019
DIRCNT   EQU   DUMPCNT+2               PROCESSED DIRECTORY BYTES COUNT  68800019
CDAMSWCS EQU   DIRCNT+2                ALTERNATE BPAM SWITCH BYTE       68900019
CDTTRSAV EQU   CDAMSWCS+1              SAVE AREA FOR MEMBER TTR         69000019
*                                                                       69100019
*ECFMSKLS DS    F                      WAIT FOR BPAM QUEUE PLUS I/O     69200019
*                                                                       69300019
*GBLKEYFS DS    CL8                    GLOBAL FILE KEY FIELD (POINT)    69400019
*                                                                       69500019
*GBLNUMFS DS    X                      GLOBAL FILE NUMBER (UTILITY)     69600019
*                                                                       69700019
*RITSAVE  DS    18F                    CRBE STANDARD OS SAVE AREA       69800019
*                                                                       69900019
*SAVELKCS DS    F                      INTERNAL LINKAGE SAVE            70000019
*                                                                       70100019
*SFBUFF1  DS    A                      BPAM BUFFER ADDRESS CONTROL      70200019
*                                                                       70300019
*SWITCCS  DS    X                      COMMAND-SERVICE SWITCHES         70400019
ERR1     EQU   B'00000100'             USER LIBRARY I/O ERROR           70500019
ERR2     EQU   B'00000010'             SYSTEM/UTILITY FILE I/O ERROR    70600019
ERR3     EQU   B'00000001'             USER LIBRARY MODIFIED            70700019
*                                                                       70800019
* DATA MANAGEMENT CONTROL BLOCK REFERENCES                              70900019
*                                                                       71000019
*DCBBLKSI DS    H                      BPAM PHYSICAL BLOCK SIZE         71100019
*                                                                       71200019
*DCBFDAD  DS    CL8                    FULL DEVICE ADDRESS              71300019
*                                                                       71400019
*DCBLRECL DS    H                      BPAM LOGICAL BLOCK SIZE          71500019
*                                                                       71600019
*DCBOFLGS DS    X                                                       71700019
TRKBALOK EQU   B'10000000'             TRACK BALANCE IS VALID           71800019
OPEN     EQU   B'00010000'             DCB IS OPEN                      71900019
*                                                                       72000019
*DCBRELAD DS    F                      TTR OF MEMBER                    72100019
         END                                                            72200019
