CMD      TITLE 'IHKCMD - CRJE SYSTEM ADMINISTRATOR'                     00050019
IHKCMD   CSECT                                                          00060020
* 085500,087500,104500-105500,365000,456000-457000,664000-672000 A34585 00062020
* 827000,850000,859000-859500,876500,878000-878500               A34585 00064020
* 515630                                                         A34590 00066020
*A653570-653920,930700                                           A36805 00068020
*C087500,654000,655500                                           A36805 00070020
*A350200,457150-457400,457550-457950,605000,622500,633020-633440 A36806 00072020
*C087500,345000                                                  A36806 00074020
*D350000-350500,600500-609500,619000-627500                      A36806 00076020
*A570000                                                         A36808 00078020
*C087500                                                         A36808 00080020
*A029500,350000,399500,422500,597500,605000,613000,633440,829500 A36810 00082020
*A894000,930500                                                  A36810 00084020
*C002500,053000-054500,087500,090500,350200,597500,687000,692500 A36810 00086020
*D168500-169000,202000-203500,884000                             A36810 00088020
*A222000                                                         A40202 00090020
*C087500,572500,577500                                           A40202 00092020
*D218000-219000                                                  A40202 00094020
*A364000                                                         A50750 00096026
*C087500                                                         A50750 00098026
* C087500                                                       OX00341 00098302
* C499000                                                       OX00341 00098602
*C087500,364200                                                 A57811  00099027
*********************************************************************** 00100019
*                                                                     * 00150019
*STATUS                                                               * 00200019
*   CHANGE LEVEL 1                                               A36810 00250020
*                                                                     * 00300019
*FUNCTION                                                             * 00350019
*   AS RESPONSE TO THE FIRST CREAD I ISSUED, LINE ADMINISTRATOR       * 00400019
*   RETURNS TO IHKCMD WITH A ZERO-LENGTH-RECORD IN THE USERBUFFER.    * 00450019
*   IHKCMD THEN PROMPTS THE USER FOR HIS FIRST COMMAND. THE COMMAND   * 00500019
*   CONTAINED IN THE USERBUFFER AS IT WAS TYPED IN AT THE TERMINAL IS * 00550019
*   CHECKED FOR VALIDITY AND A PPT IS BUILT. IF THE COMMAND IS CONTI- * 00600019
*   NUED ON A SECOND LINE, ANOTHER PPT IS ALLOCATED AND CHAINED TO THE* 00650019
*   PREVIOUS ONE.                                                     * 00700019
*   BEFORE CONTROL IS PASSED TO THE APPROPRIATE COMMAND-PROCESSOR,    * 00750019
*   IHKCMD TAKES THE FOLLOWING ACTIONS:                               * 00800019
*   - IF LOGON-SUPPRESSION NO USER IS LOGGED ON. HE GETS A MESSAGE AND* 00850019
*     A CREAD I IS ISSUED.                                            * 00900019
*   - THE FIRST COMMAND MUST BE LOGON. A USER GETS TWO CHANCES TO     * 00950019
*     ENTER A LOGON, BEFORE A CREAD I IS ISSUED.                      * 01000019
*   - A ZERO-LENGTH-RECORD IN MAJOR COMMAND MODE IS IGNORED.          * 01050019
*   - FOR A ZERO-LENGTH-RECORD IN EDIT MODE, THE COMMAND CODE FOR     * 01100019
*     IHKIRL01 IS INSERTED INTO THE PPT.                              * 01150019
*   - FOR A ZERO-LENGTH-RECORD IN CORRECTION MODE, THE COMMAND CODE   * 01200019
*     FOR IHKIRL02 IS INSERTED INTO THE PPT.                          * 01250019
*   - IF AN ACTIVE FILE HAS THE TEXT ATTRIBUTE, TUBTEXTN-FLAG IS SET  * 01300019
*     BEFORE CREAD FOR NEXT COMMAND IS ISSUED. FOR VERIFICATION, THE  * 01350019
*     COMMAND VERB AND THE OPERANDS (EXCEPT THE TWO TEXT-OPERANDS ON  * 01400019
*     CHANGE AN THE ENTIRE IMPLICIT COMMAND) ARE TRANSLATED TO UPPER  * 01450019
*     CASE.                                                           * 01500019
*   - IF A CLIST IS BEING PROCESSED, LOGON, LOGOFF AND EXEC ARE RE-   * 01550019
*     JECTED.                                                         * 01600019
*   - A COMMAND WITH UNPAIRED PARENTHESES IN ITS OPERANDS IS REJECTED.* 01650019
*   - A COMMAND WITH UNPAIRED QUOTES IN ITS OPERANDS IS REJECTED.     * 01700019
*   - DOUBLE QUOTES ARE RESOLVED TO SINGLE QUOTES.                    * 01750019
*   - A COMMAND CONTAINING A ZERO-LENGTH OPERAND, E.G. (), IS REJECTED* 01800019
*   - OPERANDS LONGER THAN 56 CHARACTERS ARE INVALID (EXCEPT IMPLICIT * 01850019
*     COMMAND).                                                       * 01900019
*   - THE TEXT OPERANDS ON CHANGE HAVE A MAX. LENGTH OF 40 CHARACTERS.* 01950019
*   - IF OPERANDS ON A COMMAND ARE SEPARATED BY MULTIPLE COMMAS, A    * 02000019
*     WARNING IS SENT TO THE USER.                                    * 02050019
*   - FOR A LISTBC COMMAND THE BROADCAST MESSAGES REQUIRED FLAG IS SET* 02100019
*     AND CONTROL IS GIVEN TO THE POINT IN IHKCMD WHERE ALL COMMAND-  * 02150019
*     PROCESSORS RETURN TO.                                           * 02200019
*   - IF LOGON IS ENTERED WHILE A USER IS ALREADY LOGGED ON, CONTROL  * 02250019
*     IS GIVEN FIRST TO LOGOFF PROCESSOR.                             * 02300019
*                                                                     * 02350019
*   WHEN THE PPT IS BUILT UP, THE COMMAND CODE IS CHECKED TO DETERMINE* 02400019
*   WHETHER THE APPROPRIATE COMMAND PROCESSOR IS RESIDENT OR NON-RESI-* 02450019
*   DENT. LOADER/CONTROLLER IS INVOKED TO LOAD NON-RESIDENT PROCESSORS* 02500019
*   THEN CONTROL IS PASSED TO THE PROCESSOR WITH REGISTER 1 POINTING  * 02550019
*   TO A PARAMETERLIST WHICH CONTAINS THE ADDRESS OF THE TUB AND THE  * 02600019
*   ADDRESS OF THE AVT.                                               * 02650019
*   UPON RETURN, NON-RESIDENT COMMAND PROCESSORS ARE DELETED IMMEDIA- * 02700019
*   TELY, THEN REGISTER 15 IS CHECKED. IF IT IS NEGATIVE, THEN IT CON-* 02750019
*   TAINS THE NEGATIVE COMMAND-CODE OF THE ROUTINE TO BE GIVEN CONTROL* 02800019
*   NEXT. THIS ROUTINE ALSO CAN BE RESIDENT OR NON-RESIDENT. IF RE-   * 02850019
*   GISTER 15 IS NOT NEGATIVE, IT CONTAINS THE RETURN-CODE AND THE    * 02900019
*   ACTION TO BE PERFORMED IS CHOSEN ACCORDINGLY.                     * 02950019
*   WHEN A NONRESIDENT COMMAND PROCESSOR IS TO BE LOADED OR      A36810 02960020
*   DELETED, A CHECK IS MADE TO SEE IF THE LOADER/CONTROLLER HAS A36810 02970020
*   ABENDED.  IF IT HAS, CONTROL IS PASSED TO IHKERR VIA A LINK  A36810 02980020
*   MACRO.                                                       A36810 02990020
*                                                                     * 03000019
*   RETURN-CODE 00 AND EXEC NOT BEING PROCESSED                       * 03050019
*   - ALL QUEUED MESSAGES ARE SENT.                                   * 03100019
*   - IF NO USER IS LOGGED ON THE PPT'S ARE DEALLOCATED, THE SAVE-AREA* 03150019
*     IS FREED AND A CREAD I IS ISSUED.                               * 03200019
*   - IF USER IS LOGGED ON THE PPT'S ARE DEALLOCATED AND A CREAD 15   * 03250019
*     ISSUED.                                                         * 03300019
*   RETURN-CODE 00 AND EXEC BEING PROCESSED                           * 03350019
*   - IF CONTROL IS RETURNED FROM IHKED1DO, THE USER-BUFFER CONTAINS  * 03400019
*     THE NEXT COMMAND WHICH MUST BE ANALYZED BY IHKCMD. IF TUBEXLST  * 03450019
*     IS SET, THE COMMAND IS WRITTEN AT THE TERMINAL BEFORE IT IS     * 03500019
*     ANALYZED.                                                       * 03550019
*   - IF CONTROL WAS NOT RETURNED FROM IHKED1DO, ALL QUEUED MESSAGES  * 03600019
*     ARE SENT, THE PPT'S ARE DEALLOCATED AND A DUMMY PPT IS USED, TO * 03650019
*     GO TO IHKED1DO TO GET THE NEXT COMMAND FROM THE CLIST.          * 03700019
*                                                                     * 03750019
*   RETURN-CODE 04 (BREAK, LINE-ERROR OR CLOSE-DOWN) AND REGISTER 1   * 03800019
*   POINTS TO THE CLB.                                                * 03850019
*   - FLAGS IN THE CCT AND THE CLB SPECIFY THE MESSAGE TO BE SENT TO  * 03900019
*     THE CENTRAL OPERATOR AND WHETHER A CREAD I, A CREAD R AND/OR A  * 03950019
*     LINK TO IHKDSP TO WAIT ON THE LINE-ECB HAS TO BE ISSUED.        * 04000019
*   RETURN-CODE 04 (BREAK, LINE-ERROR OR CLOSE-DOWN) AND REGISTER 1   * 04050019
*   POINTS TO THE TUB                                                 * 04100019
*   - IF TUBRAKEN IS SET A BREAK HAS OCCURED AND THE COMMAND TO BE    * 04150019
*     ANALYZED IS ALREADY IN THE USER-BUFFER. IF EXEC IS NOT IN PROG- * 04200019
*     RESS, THE COMMAND IS ANALYZED AND PROCESSING CONTINUES NORMALLY.* 04250019
*     IF EXEC IS IN PROGRESS AND THE COMMAND IN THE USER-BUFFER IS NOT* 04300019
*     END, THE EXEC PROCESS IS TERMINATED AND THE NEW COMMAND IS ANA- * 04350019
*     LYZED. IF THE NEW COMMAND IS END, ONLY THE CURRENTLY ACTIVE     * 04400019
*     COMMAND IS TERMINATED AND CONTROL IS GIVEN TO IHKED1DO TO GET   * 04450019
*     THE NEXT COMMAND FROM THE CLIST.                                * 04500019
*   - IF TUBRAKEN IS NOT SET, THE SESSION OF THE USER MUST BE TERMI-  * 04550019
*     NATED EITHER BECAUSE OF A 'MODIFY D', A 'STOP' OR A LINE-ERROR. * 04600019
*     THE TERMINATION PROCESS IS ALWAYS THE SAME. IF EXEC IS IN PROG- * 04650019
*     RESS, IT IS TERMINATED AND THE EXEC-BUFFER IS FREED. IF THE USER* 04700019
*     IS IN EDIT-MODE, CONTROL IS GIVEN FIRST TO SAVE, THEN TO END AND* 04750019
*     THEN TO LOGOFF. IF THE USER IS NOT IN EDIT MODE, HE IS LOGGED   * 04800019
*     OFF. THE MESSAGES QUEUED OR SENT TO THE USER REFLECT THE CAUSE  * 04850019
*     OF THE TERMINATION OF HIS SESSION. THE CENTRAL OPERATOR EVEN-   * 04900019
*     TUALLY GETS A MESSAGE AND THEN A CREAD I OR A CREAD R IS ISSUED.* 04950019
*                                                                     * 05000019
*   RETURN-CODE 08 (GETMAIN FAILURE)                                  * 05050019
*   - AN OUT-OF-SPACE MESSAGE IS SENT TO THE TERMINAL AND T3 THE CENT-* 05100019
*     RAL OPERATOR. IF EXEC IS IN PROGESS, IT IS TERMINATED AND THEN  * 05150019
*     THE USER IS PROMPTED FOR THE NEXT COMMAND.                      * 05200019
*                                                                     * 05250019
*   RETURN-CODE 12 (ACTIVE AREA I/O ERROR OR SUBTASK ABEND)      A36810 05300020
*   THE TUBAARRN FLAG IS TURNED ON AND CONTROL IS PASSED TO      A36810 05350020
*   IHKERR.  THIS IS DONE BY USING A DUMMY PPT IN CASE NO USER   A36810 05400020
*   IS LOGGED ON OR WITH A REAL PPT IF THERE IS A USER.          A36810 05450020
*                                                                     * 05500019
*   RETURN-CODE 16 (ERROR MESSAGE LOST)                               * 05550019
*   - IF EXEC IS IN PROGRESS IT IS TERMINATED, THEN THE USER IS PROMP-* 05600019
*     TED FOR HIS NEXT COMMAND.                                       * 05650019
*                                                                     * 05700019
*   RETURN-CODE 20 (ACTIVE AREA OUT OF SPACE)                         * 05750019
*   - A MESSAGE IS SENT TO THE CENTRAL OPERATOR. IF EXEC IS IN        * 05800019
*     PROGRESS, IT IS TERMINATED, THEN THE USER IS PROMPTED FOR HIS   * 05850019
*     NEXT COMMAND.                                                   * 05900019
*                                                                     * 05950019
*   RETURN-CODE 24 (EOF IN CLIST)                                     * 06000019
*   - EXEC IS TERMINATED AND USER IS PROMPTED FOR HIS NEXT COMMAND.   * 06050019
*                                                                     * 06100019
*   IF ZERO IS RETURNED IN REGISTER 15 FROM THE INSTALLATION EXIT FOR * 06150019
*   USER COMMANDS, THE USER IS PROMPTED FOR THE NEXT COMMAND. IF THE  * 06200019
*   RETURN-CODE IS NON-ZERO, THE CONTENTS OF THE USER-BUFFER (120     * 06250019
*   BYTES) ARE WRITTEN AT THE TERMINAL BEFORE THE USER IS PROMPTED FOR* 06300019
*   ANOTHER COMMAND.                                                  * 06350019
*                                                                     * 06400019
*   THE RETURN-CODES MENTIONED ABOVE ARE VALID ALSO FOR THE MESSAGE-  * 06450019
*   WRITER.                                                           * 06500019
*                                                                     * 06550019
*ENTRY POINT                                                          * 06600019
*   IHKCMD                                                            * 06650019
*                                                                     * 06700019
*INPUT                                                                * 06750019
*   N/A                                                               * 06800019
*                                                                     * 06850019
*OUTPUT                                                               * 06900019
*   N/A                                                               * 06950019
*                                                                     * 07000019
*EXTERNAL REFERENCES                                                  * 07050019
*   ADDRESS VECTOR TABTLE - IHKAVT                                    * 07100019
*                                                                     * 07150019
*EXIT NORMAL                                                          * 07200019
*   RETURN TO DISPATCHER                                              * 07250019
*                                                                     * 07300019
*EXIT ERROR                                                           * 07350019
*   N/A                                                               * 07400019
*                                                                     * 07450019
*TABLES/WORK AREA                                                     * 07500019
*   GETMAINED SAVE-AREA                                               * 07550019
*   CCT                                                               * 07600019
*   CLB                                                               * 07650019
*   TUB                                                               * 07700019
*   USER BUFFER                                                       * 07750019
*   PPT                                                               * 07800019
*   IHKMCL  -  LIST OF MAJOR COMMANDS                                 * 07850019
*   IHKSCL  -  LIST OF EDIT SUBCOMMANDS                               * 07900019
*   IHKAVT  -  ADDRESS-VECTOR-TABLE                                   * 07950019
*   DIR     -  DIRECTORY ENTRY                                        * 08000019
*   CSCB    -  TO FIND PROC-NAME TO STOP CRJE ON AA I/O ERROR         * 08050019
*                                                                     * 08100019
*ATTRIBUTES                                                           * 08150019
*   REENTRANT, RESIDENT, NON-REFRESHABLE                              * 08200019
*                                                                     * 08250019
*NOTES                                                                * 08300019
*                                                                     * 08350019
*                                                                     * 08400019
*********************************************************************** 08450019
         EJECT                                                          08500019
         LR    R10,R14             SET BASE-REGISTER.                   08600019
         USING IHKCMD,R10                                               08650019
         B     AFTLBEL                                                  08700019
         DC    C'CMD72306'                 MODULE IDENTIFIER            08750002
AFTLBEL  DS    0H                                                       08800019
         L     R12,VCONAVT         LOAD BASE FOR AVT-DSECT.             08850019
         USING AVTDSECT,R12                                             08900019
         USING PPTDSECT,R11                                             08950019
         LR    R4,R1               LOAD BASE FOR CLB-DSECT.             09000019
         B     CREADI1             TEST FOR CLOSEDOWN            A36810 09050020
*                                                                       09100019
CREADIFR EQU   *                                                        09150019
         BAL   R2,DEALLC           GO AND DEALLOCATE PPT'S.             09200019
         BAL   R2,FRSAREA          GO AND FREE SAVE-AREA.               09250019
         LR    R15,R4              HAS TUB-ADDR.                        09300019
         LR    R4,R6               HAS CLB-ADDR.                        09350019
         B     CREADI                                                   09400019
*                                                                       09450019
BADCOMP  EQU   *                                                        09500019
         USING CLBDSECT,R4                                              09550019
         MVI   CLBSAECB,X'40'                                           09600019
         NI    CLBSTATS,CLBMODYF   RESET MODIFY FLAG             A34585 09620020
*                                                                       09650019
DISPATCH L     R1,CLBLDECB         GET ECB-ADDR.                        09700019
         LA    R13,CLBSAVE         R13 HAS CLB-SAVEAREA.                09750019
         MVI   0(R1),X'00'         POST DECB INOPERATIVE.               09800019
         L     R15,IHKYYDSP        DISPATCHER-ADDR.                     09850019
         BALR  R14,R15             LINK TO IT.                          09900019
         MVI   CLBSAECB,CLRPOST         CLEAR POST BIT IN STOP          09950019
*                                                                       10000019
CREADI1  TM    CLBREQST,CLBSTOPN   TEST FOR STOP OR MODIFY       A34585 10010020
         BO    BADCOMP             IF YES, WAIT                  A34585 10020020
CREADI0  EQU   *                                                        10050019
         LR    R15,R4              HAS CLB-ADDR.                        10100019
CREADI   EQU   *                                                        10150019
         LA    R13,CLBSAVE         R13 HAS CLB-SAVE-AREA.               10200019
         OI    4(15),X'3' REQUEST FLAG FOR CREAD I                      10250019
         BAL   R9,CREAD            GO AND ISSUE CREAD I.                10300019
         L     R4,0(0,R1)          LOAD BASE FOR TUB-DSECT.             10350019
         USING TUBDSECT,R4                                              10400019
         TM    TUBREQST,TUBIDENT   TEST FOR TUB RETURNED         A34585 10450020
         BZ    RTNCD08             IF CLB, SEND OUT OF SPACE MSG A34585 10500020
         LR    R5,R15              SAVE RETURN CODE              A34585 10550020
         LA    R6,LNGSA            HAS LENGTH OF SAVE-AREA.             10600019
         BAL   R14,GETMAIN         GO AND ISSUE GETMAIN.                10650019
         L     R13,TUBPARM3        HAS SAVE-AREA-ADDR.                  10700019
         LTR   R5,R5               TEST CREAD I RETURN           A34585 10710020
         BNZ   RTNCD04             IF BAD, KNOCK DOWN LINE       A34585 10720020
         MVC   TUBDATAL,ZERLNG     INDICATE 0 DATA LENGTH        A34585 10730020
FRMCMD02 EQU   *                                                        10750019
         BAL   R2,DEALLC           GO AND DEALLOCATE PPT'S.             10800019
         LA    R8,L6(0,R11)        HAS ADDR OF FIRST FREE BYTE.         10850019
         BAL   R14,STORADDR        GO AND STORE THIS ADDR.              10900019
         LH    R7,TUBDATAL         R7 HAS DATA-LENGTH.                  10950019
         CH    R7,ZERLNG           IS IT ZERO-LENGTH-RECORD?            11000019
         BNE   NOZLR                 NO, BRANCH.                        11050019
*                                    YES, GO ON.                        11100019
         CLI   TUBUSRID,HEX00      IS USER LOGED ON?                    11150019
         BE    CKSUP                 NO, BRANCH.                        11200019
*                                    YES, GO ON.                        11250019
         TM    TUBPPTFL,TUBCNTEN   LINE CONTINUATION EXPECTED?          11300019
         BO    CLRPPTFL              YES, BRANCH.                       11350019
*                                    NO, GO ON.                         11400019
TSTEDT   EQU   *                                                        11450019
         TM    TUBFLG2,TUBEDIT     IS USER IN EDIT-MODUS?               11500019
         BZ    GETLINE               NO, BRANCH.                        11550019
*                                    YES, GO ON.                        11600019
         TM    TUBFLG3,TUBCORRN    IS USER IN CORRECTION-MODUS?         11650019
         BO    CRINCORR              YES, BRANCH.                       11700019
*                                    NO, GO ON.                         11750019
         MVI   PPTCMD,CMDIMP       INSERT CODE FOR IMPLICIT-COMMAND.    11800019
         B     STOREIT                                                  11850019
*                                                                       11900019
CKSUP    L     R14,IHKYYCCT        HAS CCT-ADDR.                        11950019
         USING CCTDSECT,R14                                             12000019
         TM    CCTOPT1,CCTSUP      SUPPRESS LOGON?                      12050019
         DROP  R14                                                      12100019
         BZ    TSTEDT                NO, BRANCH.                        12150019
*                                    YES, GO ON.                        12200019
         SR    R7,R7                                                    12250019
         LA    R6,MSG301           GET MESSAGE CODE ADDR                12300019
         BAL   R2,SENDIT1          GO AND SEND MESSAGE.                 12350019
         B     NOUSRID                                                  12400019
*                                                                       12450019
CRINCORR EQU   *                                                        12500019
         MVI   PPTCMD,CMDCMODE     CODE FOR CORRECTION-MODE.            12550019
         B     STOREIT                                                  12600019
*                                                                       12650019
NOZLR    EQU   *                                                        12700019
         L     R1,TUBUFFAD         GET ADDR OF USER-BUFFER.             12750019
         LA    R1,0(0,R1)          CLEAR HIGHORDER-BYTE.                12800019
         LA    R6,0(R7,R1)                                              12850019
         BCTR  R6,0                R6 HAS ADDR OF LAST CHAR IN BUFFER.  12900019
         CLI   TUBEXCLG,HEX00      IS EXEC-COMMAND IN PROCESS?          12950019
         BNE   SCFNB1                YES, BRANCH.                       13000019
*                                    NO, GO ON.                         13050019
         CLI   0(R6),DASH          IS LAST CHAR A CONTINUATION SIGN?    13100019
         BNE   SCFNB1                NO, BRANCH.                        13150019
*                                    YES, GO ON.                        13200019
         OI    TUBPPTFL,TUBCNTSN   SET THIS-LINE-WILL-BE-CONTINUED-FLAG 13250019
         BCTR  R7,0                ADJUST LENGTH OF LINE AND            13300019
         BCTR  R6,0                  ADDR OF LAST CHAR.                 13350019
SCFNB1   TM    TUBPPTFL,TUBCNTEN   IS CONTINUATION EXPECTED?            13400019
         BO    LNECNT                YES, BRANCH.                       13450019
*                                    NO, GO ON.                         13500019
         XC    SCNDELSL,SCNDELSL   CLEAR SCANLENGTH.                    13550019
         ST    R6,SCSTOP           SCAN-STOP-ADDR TO PARAMETERLIST.     13600019
         BAL   R2,SCNBLK           GO AND SCAN FOR FIRST NON-BLANK.     13650019
*                                  BACK FROM SCAN-ROUTINE.              13700019
         B     EMPTLN                BRANCH, ALL CHARACTERS ARE BLANK.  13750019
*                                    GO ON, NON-BLANK FOUND.            13800019
         LA    R6,ONE(R6)                                               13850019
         SR    R6,R1               R6 HAS NUMBER OF CHAR NOT YET        13900019
*                                    SCANNED.                           13950019
         LR    R7,R6               SO HAS R7.                           14000019
         LA    R5,NINE                                                  14050019
         CLR   R6,R5               LESS THAN 9 CHAR LEFT FOR SCAN?      14100019
         BL    LT9                   YES, BRANCH.                       14150019
*                                    NO, GO ON                          14200019
         LR    R6,R5               R6 HAS 9. MAX LENGTH OF VERB+1.      14250019
LT9      STC   R6,SCDELISL+ONE     SCANLENGTH TO PARAMETERLIST.         14300019
         LR    R3,R1               R3 POINTS TO BEGIN OF VERB.          14350019
         BAL   R2,SCDELI           GO AND SCAN FOR FIRST DELIMITER.     14400019
*                                  BACK FROM SCAN-ROUTINE.              14450019
         B     NOTFND3               BRANCH, NO DELIMITER WAS FOUND.    14500019
         B     FND3C                 BRANCH, COMMA FOUND.               14550019
         B     FND3                 BRANCH, BLANK WAS FOUND.            14600019
*                                                                       14650019
FND3C    OI    TUBPPTFL,TUBWARNN   SET FLAG 'WARNING MUST BE SENT'.     14700019
         B     FND3                                                     14750019
*                                                                       14800019
NOTFND3  CLR   R6,R5               WAS SCANLENGTH 9CHAR?                14850019
         BNE   FND32                 NO, BRANCH.                        14900019
*                                    YES, ISSUE ERROR MESSAGE.          14950019
         BCTR  R3,0                BUILD PARAMETER                      15000019
         BCTR  R6,0                  FOR MESSAGE                        15050019
         STC   R6,0(0,R3)            WRITER.                            15100019
         LR    R7,R3                                                    15150019
WHTMD    EQU   *                                                        15200019
         TM    TUBFLG2,TUBEDIT     IS USER IN EDIT MODUS?               15250019
         BO    SUB1                  YES, BRANCH.                       15300019
*                                    NO, GO ON.                         15350019
         LA    R6,MSG305           GET MESSAGE CODE ADDR.               15400019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           15450019
*                                                                       15500019
SUB1     LA    R6,MSG391           GET MESSAGE CODE ADDR.               15550019
         B     SENDIT                                                   15600019
*                                                                       15650019
LNECNT   ST    R6,SCSTOP           SCAN-STOP-ADDR TO PARAMETERLIST.     15700019
         XC    SCNDELSL,SCNDELSL   CLEAR SCANLENGTH.                    15750019
         CLI   PPTCMD,CMDCGN       CONTINUATION FOR CHANGE-COMMAND?     15800019
         BE    CTCHNGE                YES, BRANCH.                      15850019
*                                     NO, GO ON.                        15900019
LNECNT1  EQU   *                                                        15950019
         SR    R7,R7               CLEAR PARENTHESIS COUNT.             16000019
         BAL   R2,SCNDEL           GO AND SCAN FOR NON-DELIMITER.       16050019
*                                  BACK FROM SCAN-ROUTINE.              16100019
         B     NOTFND1               BRANCH, NO NON-DELIMITER FOUND.    16150019
         B     NDELFD                BRANCH, NON-DELIMITER FOUND.       16200019
*                                                                       16250019
CTCHNGE  EQU   *                                                        16300019
         IC    R0,PPTFLG           LOAD ONLY  LAST THREE BITS           16350019
         SLL   R0,CH29(0)            OF PPT-FLAGBYTE INTO R0,           16400019
         SRL   R0,CH29(0)            THEY ARE USED AS PARAMETER-COUNT.  16450019
         B     LNECNT1                                                  16500019
NOTFND1  EQU   *                                                        16550019
         TM    TUBPPTFL,TUBCNTSN   WILL THIS LINE BE CONTINUED?         16600019
         BZ    CLRPPTFL              NO, BRANCH.                        16650019
*                                    YES, GO ON.                        16700019
         B     GETLINE                                                  16750019
*                                                                       16800019
*                                                                       16950019
FND3     EQU   *                     GO ON, A BLANK OR A COMMA WAS      17000019
*                                      FOUND.                           17050019
         LR    R9,R1                                                    17100019
         SR    R9,R3               R9 HAS LENGTH OF VERB OR LENGTH OF   17150019
*                                    FIRST PARAMETER FOR IMPLICIT       17200019
*                                    COMMAND.                           17250019
         B     FND31                                                    17300019
*                                                                       17350019
FND32    LR    R9,R6               R9 HAS LENGTH OF VERB OR LENGTH OF   17400019
*                                    FIRST PARAMETER FOR IMPLICIT       17450019
*                                    COMMAND.                           17500019
FND31    EQU   *                                                        17550019
*                                  WITH THE FOLLOWING INSTRUCTIONS THE  17600019
*                                    FIRST CHARACTER IS TESTED IF IT IS 17650019
*                                    NUMERIC.                           17700019
         TM    0(R3),MSKF0                                              17750019
         BC    14,MODTEST          BRANCH, CHAR IS NOT NUMERIC.         17800019
*                                                                       17850019
         TM    0(R3),MSK08                                              17900019
         BZ    NUM                 BRANCH, CHAR IS NUMERIC.             17950019
*                                                                       18000019
         TM    0(R3),MSK06                                              18050019
         BZ    NUM                 BRANCH, CHAR IS NUMERIC.             18100019
*                                                                       18150019
MODTEST  EQU   *                                                        18200019
         TM    TUBPPTFL,TUBRAKEN   IS BREAK-FLAG SET?                   18250019
         BO    ISITEND               YES, BRANCH.                       18300019
*                                    NO, GO ON.                         18350019
MODTEST1 EQU   *                                                        18400019
         TM    TUBFLG2,TUBEDIT     IS USER IN EDIT MODUS?               18450019
         BO    EDIT                  YES, BRANCH.                       18500019
*                                    NO, GO ON                          18550019
         L     R5,IHKYYMCL         GET ADDR OF MAJOR-COMMANDLIST.       18600019
         B     LSTSCN                                                   18650019
*                                                                       18700019
ISITEND  CH    R9,H3               IS LENGTH EQ 3?                      18750019
         BNE   MODTEST1              NO, BRANCH.                        18800019
*                                    YES, GO ON.                        18850019
         CLC   0(L'END,R3),END     IS IT END?                           18900019
         BNE   MODTEST1            NO, BRANCH.                          18950019
*                                    YES, GO ON.                        19000019
         CLI   TUBEXCLG,HEX00      EXEC COMMAND IN EFFECT               19010019
         BE    MODTEST1            IF NOT, PROCESS END COMMAND          19020019
         MVI   PPTCMD,CMDEND       INSERT END-COMMAND-CODE.             19050019
         B     ENDLNE                                                   19100019
*                                                                       19150019
EDIT     EQU   *                                                        19200019
         L     R5,IHKYYSCL         GET ADDR OF SUB-COMMANDLIST.         19250019
*                                                                       19300019
LSTSCN  SR     R6,R6                                                    19350019
         SR    R8,R8                                                    19400019
         IC    R6,0(R5)            GET NUMBER OF ENTRIES IN LIST.       19450019
         LA    R5,ONE(R5)          R5 HAS ADDR OF FIRST ENTRY.          19500019
NXTVRB   IC    R8,0(R5)            R8 HAS LENGTH OF FIRST VERB IN LIST. 19550019
         CLR   R9,R8               IS IT THE LENGTH WE ARE LOOKING FOR? 19600019
         BE    CORLNG                YES, BRANCH.                       19650019
*                                    NO, GO ON.                         19700019
TKNXT    LA    R5,TWO(R5,R8)       R5 HAS ADDR OF NEXT ENTRY            19750019
         BCT   R6,NXTVRB           GET NEXT ENTRY IF THERE IS ONE.      19800019
*                                    ISSUE ERROR MESSAGE OTHERWISE.     19850019
         NI    TUBPPTFL,TUBCNTSF        TURN OFF CONTINUATION SWITCH    19900019
         BCTR  R3,0                BUILD PARAMETER                      19950019
         STC   R9,0(0,R3)            FOR MSG WTR.                       20000019
         LR    R7,R3                                                    20050019
         B     WHTMD                                                    20100019
*                                                                       20150019
*                                                                       20400019
CORLNG   EQU   *                                                        20450019
         BCTR  R9,0                ADJUST LENGTH FOR COMPARE.           20500019
         EX    R9,OCSTRING         CONVERT STRING TO UPPER CASE.        20550019
         EX    R9,CLC              IS IT COMMAND WE ARE LOOKING FOR?    20600019
         LA    R9,ONE(R9)                                               20650019
         BNE   TKNXT                 NO, BRANCH.                        20700019
*                                    YES, GO ON.                        20750019
         LA    R5,ONE(R5,R8)       R5 POINTS TO CODE FOR THIS VERB.     20800019
         CLI   TUBEXCLG,HEX00      IS EXEC-COMMAND IN PROCESS?          20850019
         BE    MVCCODE               NO, BRANCH.                        20900019
*                                    YES, GO ON.                        20950019
         TM    TUBPPTFL,TUBRAKEN        TEST FOR BREAK                  21000019
         BO    MVCCODE             IF YES,CHECK FOR END                 21050019
         CLI   0(R5),CMDLGN        IS IT LOGON-COMMAND?                 21100019
         BE    ULAWCMD               YES, BRANCH.                       21150019
*                                    NO, GO ON.                         21200019
         CLI   0(R5),CMDLGF        IS IT LOGOFF-COMMAND?                21250019
         BE    ULAWCMD               YES, BRANCH.                       21300019
*                                    NO, GO ON.                         21350019
         CLI   0(R5),CMDDOO        IS IS EXEC-COMMAND?                  21400019
         BE    ULAWCMD               YES, BRANCH.                       21450019
*                                    NO, GO ON.                         21500019
MVCCODE  EQU   *                                                        21550019
         CLI   TUBUSRID,HEX00      USER LOGGED ON?                      21600019
         BE    LGONNTS               NO, BRANCH.                        21650019
*                                    YES, GO ON.                        21700019
MVCCODE1 EQU   *                                                        21750019
         MVC   PPTCMD,0(R5)        MOVE CODE TO PARAMETER POSITION      21950019
*                                    TABLE.                             22000019
         TM    TUBFLG3,TUBCORRN    IS USER IN CORRECTION-MODUS?         22050019
         BO    CORRMDS               YES, BRANCH.                       22100019
*                                    NO, GO ON.                         22150019
AFTMVCCD EQU   *                                                        22200019
         CLI   PPTCMD,USRCD        TEST FOR USER COMMAND         A40202 22210020
         BE    USERCMD             IF IT IS, PROCESS IT          A40202 22220020
         SPACE 1                                                 A40202 22230020
         CLR   R9,R7               IS THERE MORE THAN JUST THE VERB?    22250019
         BE    STOREIT               NO, BRANCH.                        22300019
*                                    YES, GO ON.                        22350019
         LA    R1,ONE(R3,R9)       R1 HAS ADDR OF CHAR WHERE FIRST      22400019
*                                    PARAMETER COULD START.             22450019
         LA    R9,ONE(R9)          IS THERE MORE THAN ONE BYTE LEFT     22500019
         CLR   R9,R7                 AFTER THE COMMAND VERB?            22550019
         BNL   STOREIT               NO, BRANCH.                        22600019
*                                      YES, GO ON                       22650019
         SR    R7,R9               R7 HAS NUMBER OF CHAR TO BE SCANNED. 22700019
         XC    SCNDELSL,SCNDELSL   CLEAR SCANLENGTH.                    22750019
         STC   R7,SCNDELSL+ONE     SCANLENGTH TO PARAMETER-LIST.        22800019
         SR    R7,R7               CLEAR PARENHESISCOUNT.               22850019
         SR    R0,R0               CLEAR PARAMETERCOUNT USED FOR        22900019
*                                     CHANGE COMMAND.                   22950019
         BAL   R2,SCNDEL           GO AND SCAN FOR FIRST NON-DELIMITER. 23000019
*                                  BACK FROM SCAN-ROUTINE.              23050019
         B     STOREIT               BRANCH, NO NON-DELIMITER FOUND.    23100019
         TM    TUBPPTFL,TUBCOMAN   TEST FOR COMMA FOUND                 23150019
         BZ    NDELFD              IF  NOT, PROCESS COMMAND             23200019
         OI    TUBPPTFL,TUBWARNN   IF YES, SET WARRNING TO BE SENT SW   23250019
         B     NDELFD                BRANCH, NON-DELIMITER FOUND.       23300019
*                                                                       23350019
CKIFEND  EQU   *                                                        23400019
         NI    TUBPPTFL,TUBRAKEF   CLEAR BREAK-FLAG.                    23450019
         BAL   R2,SENDENQ          GO AND SEND ALL ENQUEUED MSGS.       23500019
         CLI   TUBEXCLG,HEX00      IS EXEC-COMMAND IN PROCESS?          23550019
         BE    WLLBCONT              NO, BRANCH.                        23600019
*                                    YES, GO ON.                        23650019
         MVI   PPTFLG,HEX00        CLEAR PPT-FLAGS.                     23700019
         CLI   PPTCMD,CMDEND       IS IT END-COMMAND?                   23750019
         BE    DEALLPPT              YES, BRANCH.                       23800019
*                                    NO, GO ON.                         23850019
         BAL   R2,FREEXBUF         GO AND FREE EXEC'S BUFFER.           23900019
         SR    R7,R7                                                    23950019
         LA    R6,MSG380           GET MESSAGE CODE ADDR.               24000019
         BAL   R2,SENDIT1          GO AND SEND MESSAGE.                 24050019
         B     WLLBCONT                                                 24100019
*                                                                       24150019
CORRMDS  EQU   *                                                        24200019
         CLI   PPTCMD,CMDCGN       IS IT CHANGE-COMMAND?                24250019
         BE    AFTMVCCD              YES, BRANCH.                       24300019
*                                    NO, ISSUE ERROR-MESSAGE.           24350019
         BCTR  R3,0                BUILD PARAMETER                      24400019
         STC   R9,0(0,R3)            FOR MSG WTR.                       24450019
         LR    R7,R3                                                    24500019
         LA    R6,MSG379           GET MESSAGE CODE ADDR.               24550019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           24600019
*                                                                       24650019
ULAWCMD  EQU   *                                                        24700019
         BCTR  R3,0                BUILD PARAMETER                      24750019
         STC   R9,0(0,R3)            FOR MSG WTR.                       24800019
         LR    R7,R3                                                    24850019
         LA    R6,MSG309           GET MESSAGE CODE ADDR.               24900019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           24950019
*                                                                       25000019
NDELFD   EQU   *                                                        25050019
         NI    TUBPPTFL,TUBCOMAF   CLEAR 'COMMA FOUND FLAG'.            25100019
         LR    R3,R1               KEEP BEGIN-ADDR OF PARAMETER.        25150019
         CLI   PPTCMD,CMDCGN       IS IT CHANGE-COMMAND?                25200019
         BE    CHANGE                YES, BRANCH.                       25250019
*                                    NO, GO ON.                         25300019
         CLI   0(R1),QTE           CHECK FIRST CHAR FOR QUOTE.          25350019
         BE    ICQTE                 BRANCH IF QUOTE.                   25400019
*                                    GO ON OTHERWISE.                   25450019
         CLI   0(R1),LEFTPAR       IS FIRST CHAR '('?                   25500019
         BE    LPAR                  YES, BRANCH.                       25550019
*                                    NO, GO ON.                         25600019
         CLI   0(R1),RGTHPAR       IS FIRST CHAR ')'?                   25650019
         BE    RPAR                  YES, BRANCH.                       25700019
*                                    NO, GO ON.                         25750019
         NI    TUBPPTFL,TUBNULPF   CLEAR NULL-PARAMETER-FLAG.           25800019
SCANBCLR EQU   *                                                        25850019
         XC    SCBCLRSL,SCBCLRSL   CLEAR SCAN-LENGTH.                   25900019
         BAL   R2,SCBCLR           GO AND SCAN FOR ' ,()'.              25950019
*                                  BACK FROM SCAN-ROUTINE.              26000019
         B     NCHFNDNQ              BRANCH, NONE OF THESE CHAR FOUND.  26050019
         B     MOVE                  BRANCH, BLANK FOUND.               26100019
         B     MOVEC                 BRANCH, COMMA FOUND.               26150019
         B     MOVE                  BRANCH, LEFT PARENTHESIS FOUND.    26200019
         B     MOVE                  BRANCH, RIGTH PARENTHESIS FOUND.   26250019
*                                                                       26300019
MOVEC    OI    TUBPPTFL,TUBCOMAN   SET FLAG 'COMMA FOUND'.              26350019
         B     MOVE                                                     26400019
*                                                                       26450019
NCHFNDNQ L     R1,SCSTOP           R1 HAS ADDR OF LAST CHAR.            26500019
         LA    R1,ONE(R1)                                               26550019
         OI    PPTFLG,CMDE         END OF LINE REACHED, SET FLAG.       26600019
MOVE     BAL   R2,MOVE1                                                 26650019
*                                  BACK FROM MOVE-ROUTINE.              26700019
         TM    PPTFLG,CMDE           END OF LINE REACHED?               26750019
         BO    NTFND                 YES, BRANCH.                       26800019
*                                    NO, GO ON.                         26850019
         LTR   R7,R7               IS PARENTHESIS-COUNT ZERO?           26900019
         BZ    PARFLST               YES, BRANCH.                       26950019
*                                    NO, GO ON.                         27000019
         OI    0(R8),PARFLG        SET FLAG 'PARAMETER WAS IN           27050019
*                                    PARENTHESES'                       27100019
PARFLST  CLI   0(R1),LEFTPAR       WAS CHAR FOUND A '('?                27150019
         BE    LPAR                  YES, BRANCH.                       27200019
*                                    NO, GO ON.                         27250019
         CLI   0(R1),RGTHPAR       WAS CHAR FOUND A ')'?                27300019
         BE    RPAR                  YES, BRANCH.                       27350019
*                                    NO, GO ON.                         27400019
SCAN     XC    SCNDELSL,SCNDELSL   CLEAR SCANLENGTH. STOP-ADDR IS USED. 27450019
         LA    R1,ONE(R1)                                               27500019
         BAL   R2,SCNDEL           GO AND SCAN FOR FIRST NON-DELIMITER. 27550019
*                                  BACK FROM SCAN-ROUTINR.              27600019
         B     NTFND                 BRANCH, NO NON-DELIMITER FOUND.    27650019
         B     NDELFD                BRANCH, NON-DELIMITER FOUND.       27700019
*                                                                       27750019
NTFND    EQU   *                                                        27800019
         CLI   PPTCMD,CMDCGN       IS IT CHANGE-COMMAND?                27850019
         BE    ENDLNE                YES, BRANCH.                       27900019
*                                    NO, GO ON.                         27950019
         LTR   R7,R7               IS PARENTHESIS-COUNT ZERO?           28000019
         BZ    ENDLNE                YES, BRANCH.                       28050019
*                                    NO, GO ON.                         28100019
UNBAL    LA    R6,MSG313           GET MESSAGE CODE ADDR.               28150019
         SR    R7,R7                                                    28200019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           28250019
*                                                                       28300019
LPAR     LA    R7,ONE(R7)          PARENTHESIS-COUNT PLUS ONE.          28350019
         OI    TUBPPTFL,TUBNULPN   SET NULL-PARAMETER-FLAG.             28400019
         LR    R5,R1               HAS ADDR OF LEFT PARENTHESIS.        28450019
         B     SCAN                                                     28500019
*                                                                       28550019
RPAR     BCTR  R7,0                PARENTHESIS-COUNT MINUS ONE.         28600019
         LTR   R7,R7               IS PARENTHESES-COUNT ZERO?           28650019
         BM    UNBAL              NEGITIVE, ENQ UNBALANCED MESSAGE      28700019
         BP    TSTNLFL            POSITIVE, TEST NULL PARM              28750019
*                                    YES, GO ON.                        28800019
         OI    0(R8),PARFLGLS      SET FLAG 'LAST PARAMETER IN          28850019
*                                    PARENTHESES'.                      28900019
TSTNLFL  EQU   *                                                        28950019
         TM    TUBPPTFL,TUBNULPN   NULL-PARAMETER-FLAG STILL SET?       29000019
         BZ    SCAN                  NO, BRANCH.                        29050019
*                                    YES, SEND ERROR-MSG.               29100019
         NI    TUBPPTFL,TUBNULPF   CLEAR NULL-PARAMETER-FLAG.           29150019
         BCTR  R5,0                BUILD PARAMETER                      29200019
         SR    R1,R5                 FOR MSG WTR.                       29250019
         LA    R8,L10              MAX LENGTH OF                        29300019
         CR    R1,R8                 PARAMETER                          29350019
         BL    STCR1                 IS 10 CHAR.                        29400019
*                                                                       29450019
         LR    R1,R8                                                    29500019
STCR1    STC   R1,0(0,R5)                                               29550019
         LR    R7,R5                                                    29600019
NULLPAR  EQU   *                                                        29650019
         LA    R6,MSG302           GET MESSAGE CODE ADDR.               29700019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           29750019
*                                                                       29800019
STOREIT  EQU   *                                                        29850019
         LA    R8,PPTPARS                                               29900019
         BAL   R14,STORADDR        STORE ADDR OF NEXT FREE BYTE.        29950019
ENDLNE   EQU   *                                                        30000019
         L     R8,PPTCHAD          HAS ADDR OF NEXT FREE BYTE.          30050019
         MVI   0(R8),FF            INSERT STOP-CHARACTER.               30100019
         BAL   R2,ALLOCPPT         GO AND ALLOCATE A PPT.               30150019
         TM    TUBPPTFL,TUBWARNN   MUST WARNING BE SENT?                30200019
         BZ    CKBRK                 NO, BRANCH.                        30250019
*                                    YES, GO ON.                        30300019
         LA    R6,MSG372           GET MESSAGE CODE ADDR.               30350019
         SR    R7,R7                                                    30400019
         BAL   R2,SENDIT1          GO AND SEND MESSAGE.                 30450019
*                                                                       30500019
CKBRK    EQU   *                                                        30550019
         TM    TUBPPTFL,TUBRAKEN   BREAK OCCURED?                       30600019
         BO    CKIFEND               YES, BRANCH.                       30650019
*                                    NO, GO ON.                         30700019
WLLBCONT TM    TUBPPTFL,TUBCNTSN   WILL THIS LINE BE CONTINUED?         30750019
         BO    CHKCHNGE              YES, BRANCH.                       30800019
*                                    NO, GO ON.                         30850019
CLRPPTFL MVI   PPTCHAD,HEX00       CLEAR FLAGS.                         30900019
         NI    TUBPPTFL,TUBCNTEF   CLEAR CONTINUATION-EXPECTED-FLAG.    30950019
         NI    TUBPPTFL,TUBCOMAF   CLEAR COMMA-FOUND-FLAG.              31000019
         B     ENDPTCH                                                  31050019
*                                                                       31100019
CHKCHNGE EQU   *                                                        31150019
         CLI   PPTCMD,CMDCGN       IS IT CHANGE-COMMAND?                31200019
         BNE   GETLINE               NO, BRANCH.                        31250019
*                                    YES, GO ON.                        31300019
         NI    PPTFLG,CLPTCT       CLEAR OLD PARAMETER-COUNT .          31350019
         IC    R8,PPTFLG            SAVE PARAMETER-                     31400019
         OR    R0,R8                 COUNT IN LAST THREE BITS           31450019
         STC   R0,PPTFLG             OF PPT-FLAGBYTE.                   31500019
         B     GETLINE                                                  31550019
*                                                                       31600019
CKUSRID  EQU   *                                                        31650019
         CLI   TUBUSRID,HEX00      USER LOGGED ON?                      31700019
         BE    BLDLNKAD              NO, BRANCH.                        31750019
*                                    YES, GO ON.                        31800019
         LA    R3,CMDLGF           GO FIRST TO LOGOFF-PROCESSOR.        31850019
         SR    R9,R9               NO ROUTINE MUST BE DELETED.          31900019
         B     BLDPARML                                                 31950019
*                                                                       32000019
ENDPTCH  L     R11,TUBPPTAD        GET ADDR OF FIRST PPT AS BASE.       32050019
         CLI   PPTCMD,CMDLBC       IS IT LISTBC-COMMAND?                32100019
         BE    LISTBC                YES, BRANCH.                       32150019
*                                    NO, GO ON.                         32200019
         CLI   PPTCMD,CMDLGN       IS IT LOGON-COMMAND?                 32250019
         BE    CKUSRID               YES, BRANCH.                       32300019
*                                    NO, GO ON.                         32350019
         CLI   PPTCMD,CMDLGF       IS IT LOGOFF-COMMAND?                32400019
         BNE   BLDLNKAD              NO, BRANCH.                        32450019
*                                    YES, GO ON.                        32500019
         BAL   R2,SENDENQ          GO AND SEND ALL ENQUEUED MSGS.       32550019
BLDLNKAD MVI   PPTCHAD,HEX00       CLEAR FLAGS.                         32600019
         SR    R9,R9               NO ROUTINE MUST BE DELETED.          32650019
DELRQVD  SR    R3,R3                                                    32700019
         IC    R3,PPTCMD           HAS COMMAND CODE.                    32750019
BLDPARML EQU   *                                                        32800019
         SLL   R3,SCT24(0)                                              32850019
         LTR   R3,R3               ROUTINE RESIDENT?                    32900019
         BM    NONRESGO              NO, BRANCH.                        32950019
*                                    YES, GO ON.                        33000019
         SRL   R3,SCT22(0)         SHIFT BACK AND MULTIPLY BY FOUR.     33050019
         SH    R3,H4                                                    33100019
         LA    R15,IHKYYCMD        POINTS TO POINTER TO FIRST RESIDENT  33150019
*                                    COMMAND PROCESSOR IN AVT.          33200019
         L     R15,0(R3,R15)       HAS ADDR OF COMMAND PROCESSOR.       33250019
GOTOCMDP EQU   *                                                        33300019
         LR    R5,R12              HAS ADDR OF AVT.                     33350019
         LA    R1,OFSR4(0,R13)     R1 POINTS TO WORD WHERE R4 IS SAVED  33400019
*                                    BY CALLED PROGRAM. SO AFTER THE    33450019
*                                    SAVE R1 POINTS TO PARAMETERLIST    33500019
*                                    CONTAINING THE ADDR OF THE TUB     33550019
*                                    (R4) AND THE ADDR OF THE AVT (R5)  33600019
         BALR  R14,R15                                                  33650019
         EJECT                                                          33700019
*********************************************************************** 33750019
*                                                                     * 33800019
*              BACK FROM COMMAND-PROCESSOR                            * 33850019
*                                                                     * 33900019
*********************************************************************** 33950019
         TM    PPTCMD,NRES         ROUTINE RESIDENT?                    34000019
         BO    NONRESBK              NO, BRANCH.                        34050019
*                                    YES, GO ON.                        34100019
ISR15NEG EQU   *                                                        34150019
         LTR   R15,R15             REQUEST TO ENTER AN OTHER            34200019
*                                    MODULE PASSED BACK?                34250019
         BC    11,BACKPROC           NO, BRANCH.                        34300019
*                                    YES, GO ON.                        34350019
         SR    R9,R9               NO ROUTINE MUST BE DELETED.          34400019
R15ISNEG LPR   R3,R15              HAS CODE OF MODULE TO BE ENTERED.    34450019
LDLGF    STC   R3,PPTCMD           CODE TO PPT                   A36806 34500020
         CLI   PPTCMD,CMDLGN       TEST FOR LOGON                       34550019
         BNE   DELRQVD             IF NOT GO TO LDC                     34600019
         NI    TUBPPTFL,TUBLGNRF   TURN OFF LOGON RETRY SWITCH          34650019
         B     DELRQVD                                                  34700019
*                                                                       34750019
BACKPROC LR    R5,R15              HAS RETURN-CODE.                     34800019
         CH    R5,H16              TEST FOR 16 RETURN CODE              34850019
         BE    SNDENQ              IF YES, SEND ALL ENQUEDED MESSAGES   34900019
         CH    R5,H4               LINE ERROR OCCURED?                  34950019
         BNL   BRLST               DONT SEND ENQUEDED MSGS       A36810 35020020
*                                    NO, GO ON.                         35100019
SNDENQ   EQU   *                                                        35150019
         TM    TUBREQST,TUBIDENT        TEST FOR TUB                    35200019
         BZ    BRLST                    IF NOT, TEST RETURN CODE        35250019
         CLI   TUBUSRID,HEX00      USER LOGGED ON?                      35300019
         BE    BRLST                 NO, BRANCH.                        35350019
*                                    YES, GO ON.                        35400019
         CLI   PPTCMD,CMDED1DO     BACK FROM EXEC?                      35450019
         BE    BRLST                 YES, BRANCH.                       35500019
*                                    NO, GO ON.                         35550019
         BAL   R2,SENDENQ          GO AND SEND ALL ENQUEUED MSGS.       35600019
BRLST    B     BRLST1(R5)                                               35650019
BRLST1   B     RTNCD00             BRANCH, GOOD RETURN.                 35700019
         B     RTNCD04             BRANCH, NON-ZERO RETURN FROM LINEAD. 35750019
         B     RTNCD08             BRANCH, GETMAIN FAILED.              35800019
         B     RTNCD12             BRANCH, ACTIVE AREA I/O-ERROR.       35850019
         B     RTNCD16             BRANCH, ERROR MESSAGE LOST.          35900019
         B     RTNCD20             BRANCH, ACTIVE AREA OUT OF SPACE.    35950019
         B     RTNCD24             BRANCH, EOF FOR EXEC.                36000019
*RETURN FROM ERROR RECOVERY ROUTINES.                                   36050019
         B     RTNCD28             BRANCH, GO TO BADCOMP.               36100019
         B     RTNCD28             BRANCH, GO TO DISPATCH.              36150019
         B     CREADIFR            BRANCH TO CREADIFR.                  36200019
         B     CREADI0             BRANCH TO CREADI0.                   36250019
*                                                                       36300019
RTNCD28  EQU   *                                                        36350019
         BAL   R2,FRSAREA          GO AND FREE SAVE-AREA.               36400019
         TM    TUBREQST,TUBIDENT   DOES R4 HAVE ADDR TUB         A50750 36410026
         BZ    BADCOMP                 NO, MUST BE CLB           A57811 36420027
         L     R4,TUBCLBAD         YES, LOAD CLB ADDR INTO R4    A50750 36430026
         B     BADCOMP                                                  36450019
         EJECT                                                          36550019
*********************************************************************** 36600019
*              GOOD RETURN FROM COMMAND-PROCESSOR                     * 36650019
*********************************************************************** 36700019
RTNCD00  EQU   *                                                        36750019
         TM    TUBREQST,TUBIDENT        TEST FOR TUB                    36800019
         BZ    CREADI0                  IF NONE, ISSUE CREAD I          36850019
         CLI   PPTCMD,CMDED1DO     BACK FROM EXEC-PROCESSOR?            36900019
         BE    BKFREXEC              YES, BRANCH.                       36950019
*                                    NO, GO ON.                         37000019
         TM    TUBFLG3,TUBCORRN    IS USER IN CORRECTION-MODE?          37050019
         BO    RDFRLN                YES, BRANCH.                       37100019
*                                    NO, GO ON.                         37150019
         CLI   TUBEXCLG,HEX00      IS EXEC-COMMAND IN PROCESS?          37200019
         BNE   DEALLPPT              YES, BRANCH.                       37250019
*                                    NO, GO ON.                         37300019
ISUSRON  EQU   *                                                        37350019
         CLI   TUBUSRID,HEX00      IS USER LOGED ON?                    37400019
         BNE   RDFRLN                YES, BRANCH.                       37450019
         CLI   PPTCMD,CMDLGN       TEST FOR LOGON COMMAND               37500019
         BNE   NOUSRID             IF NOT, ISSUE CREAD I                37550019
         TM    TUBPPTFL,TUBLGNRN   TEST FOR SECOND LOGON ATTEMPT        37600019
         BO    NOUSRID             IF YES, ISSUE CREAD I                37650019
         OI    TUBPPTFL,TUBLGNRN   SET ONE ATTEMPT AT LOGON FLAG        37700019
         B     RDFRLN              READ FROM LINE                       37750019
*                                    NO, GO ON.                         37800019
NOUSRID  EQU   *                                                        37850019
         NI    TUBPPTFL,TUBLGNRF   CLEAR FLAG 'ASKED ONCE FOR LOGON'.   37900019
         B     CREADIFR                                                 37950019
*                                                                       38000019
BKFREXEC EQU   *                                                        38050019
         TM    TUBFLG2,TUBEXLST    LIST COMMAND BEFORE PROCESSING?      38100019
         BZ    FRMCMD02              NO, BRANCH.                        38150019
*                                    YES, GO ON.                        38200019
         L     R3,TUBUFFAD         HAS USER-BUFFER-ADDR.                38250019
         LH    R6,TUBDATAL         HAS LENGTH OF COMMAND.               38300019
         LTR   R6,R6               IS LENGTH ZERO?                      38350019
         BZ    FRMCMD02              YES, BRANCH.                       38400019
*                                    NO, GO ON.                         38450019
         BAL   R14,GETMAIN         GO AND ISSUE GETMAIN.                38500019
         L     R8,TUBPARM3         HAS ADDR OF AREA.                    38550019
         BCTR  R6,0                ADJUST LENGTH FOR EXECUTE.           38600019
         EX    R6,MVCCMDTO         MOVE COMMAND TO AREA.                38650019
         LR    R15,R4              HAS TUB-ADDR.                        38700019
         BAL   R9,CWRITE           GO AND ISSUE CWRITE.                 38750019
         LTR   R5,R15              BAD COMPLETION?                      38800019
         BNZ   FREEUP                YES, BRANCH.                       38850019
*                                    NO, GO ON.                         38900019
         EX    R6,MVCCMDFR         MOVE CMD BACK TO USER-BUFFER.        38950019
         LA    R6,ONE(0,R6)        RE-ADJUST LENGTH.                    39000019
         STH   R6,TUBDATAL         RESTORE LENGTH OF COMMAND.           39050019
FREEUP1  EQU   *                                                        39100019
         BAL   R14,FREEMAIN        GO AND RELEASE BUFFER.               39150019
         LTR   R5,R5               BAD COMPLETION?                      39200019
         BNZ   RTNCD04               YES, BRANCH.                       39250019
*                                    NO, GO ON.                         39300019
         B     FRMCMD02                                                 39350019
*                                                                       39400019
FREEUP   EQU   *                                                        39450019
         LA    R6,ONE(0,R6)        RE-ADJUST LENGTH.                    39500019
         B     FREEUP1                                                  39550019
*                                                                       39600019
DEALLPPT NI    TUBPPTFL,TUBRAKEF   CLEAR BREAK-FLAG.                    39650019
         NI    TUBPPTFL,TUBCNTSF   CLEAR LINE-WILL-BE-CONTINUED-FLAG.   39700019
         BAL   R2,DEALLC           GO AND DEALLOCATE PPT'S.             39750019
GETDYPPT LA    R11,DUMMYPPT        GET DUMMY PPT TO GO TO EXEC.         39800019
         B     BLDLNKAD                                                 39850019
*                                                                       39900019
*                                                                       39950019
EMPTLN   NI    TUBPPTFL,TUBCNTSF   CLEAR LINE - WILL - BE        A36810 39960020
*                                      CONTINUED - FLAG          A36810 39970020
GETLINE  EQU   *                                                        40000019
         NI    PPTFLG,CMDEF        CLEAR END-OF-COMMAND-FOUND-FLAG.     40050019
         TM    TUBPPTFL,TUBCNTSN   WILL THIS LINE BE CONTINUED?         40100019
         BZ    TSTEXEC               NO, BRANCH.                        40150019
*                                    YES, GO ON.                        40200019
         NI    TUBPPTFL,TUBCNTSF   CLEAR LINE-WILL-BE-CONTINUED-FLAG.   40250019
         OI    TUBPPTFL,TUBCNTEN   SET FLAG 'CONTINUATION EXPECTED'.    40300019
TSTEXEC  EQU   *                                                        40350019
         CLI   TUBEXCLG,HEX00      IS EXEC-COMMAND IN PROCESS?          40400019
         BNE   GETDYPPT              YES, BRANCH.                       40450019
*                                    NO, GO ON.                         40500019
RDFRLN   EQU   *                                                        40550019
         BAL   R2,DEALLC           GO AND DEALLOCATE PPT'S.             40600019
         TM    TUBFLG2,TUBEDIT     IS USER IN EDIT-MODE?                40650019
         BZ    RDFRLN1               NO, BRANCH.                        40700019
*                                    YES, GO ON.                        40750019
         L     R14,TUBDIRAD        HAS ADDR OF DIRECTORY-ENTRY.         40800019
         USING DIRDSECT,R14                                             40850019
         TM    DIRATTRL,DIRATEXT   HAS DATASET TEXT-ATTRIBUTE?          40900019
         BZ    RDFRLN1               NO, BRANCH.                        40950019
*                                    YES, GO ON.                        41000019
         OI    TUBREQST,TUBTEXTN   SET LOWER-CASE-PRESERVATION-FLAG.    41050019
         DROP  R14                                                      41100019
RDFRLN1  EQU   *                                                        41150019
         LR    R15,R4              R15 HAS ADDR OF TUB.                 41200019
         L     R5,TUBUFFAD         HAS USERBUFFER ADDR.                 41250019
         MVC   0(TWO,R5),PROMPT    PROMPT TO USERBUFFER.                41300019
         MVC   TUBDATAL,H2         MOVE DATALENGTH.                     41350019
         OI    TUBFLG3,TUBNOCRN    SET FLAG 'NO CARRIER RETURN'.        41400019
         OI    4(15),X'6' REQUEST FLAG FOR CWRITE R                     41450019
         BAL   R9,CREAD            GO AND ISSUE CWRITE R.               41500019
         L     R4,0(0,R1)                                               41550019
         LTR   R15,R15             IS COMPLETION GOOD?                  41600019
         BNZ   RTNCD04               NO, BRANCH.                        41650019
*                                    YES, GO ON.                        41700019
         B     FRMCMD02                                                 41750019
*                                                                       41800019
*********************************************************************** 41850019
*              LINKAGE TO MESSAGE-WRITER                              * 41900019
*********************************************************************** 41950019
NEXTELM  MVC   D16(L11,R1),0(R7)   MOVE PARAMETER TO THE                42000019
         LA    R7,D16(0,R1)          END OF THE USER-BUFFER             42050019
         ST    R7,D12(0,R1)          AND ADJUST PARAMETERLIST.          42100019
         LA    R8,FOUR(0,R1)                                            42150019
         B     SETENDLT                                                 42200019
*                                                                       42250019
LGONNTS  CLI   0(R5),CMDLGN        IS IT A LOGON COMMAND?        A36810 42260020
         BE    MVCCODE1            YES, BRANCH                   A36810 42270020
SENDIT   LA    R2,NORETRN                                               42300019
         NI    TUBPPTFL,TUBCNTSF   TURN OFF CONTINUATION EXPECTED FLG   42350019
         CLI   TUBUSRID,HEX00      USER LOGGED ON?                      42400019
         BNZ   SENDIT1               YES, BRANCH.                       42450019
*                                    NO, GO ON.                         42500019
         TM    TUBPPTFL,TUBLGNRN   ASKED ALREADY ONCE FOR LOGON?        42550019
         BO    NOUSRID               YES, GO AND DROP LINE.             42600019
*                                    NO, GO ON.                         42650019
         OI    TUBPPTFL,TUBLGNRN   SET FLAG 'ASKED ONCE FOR LOGON'.     42700019
         CLI   PPTCMD,CMDLGN      TEST FOR LOGON ENTERED                42750019
         BE    SENDIT3            IF YES, DON'T CHANGE MESSAGE CODE     42800019
         LA    R6,MSG308           CHANGE MESSAGE CODE ADDR.            42850019
SENDIT3  SR    R7,R7                    RESET PARN COUNT                42900019
SENDIT1  LR    R5,R4               HAS TUB-ADDR.                        42950019
SENDIT2  NI    TUBPPTFL,TUBCNTEF   CLEAR CONTINUATION-EXPECTED-FLAG.    43000019
         NI    TUBPPTFL,TUBWARNF   RESET FLAG.                          43050019
         L     R1,TUBUFFAD         HAS USER-BUFFER ADDR.                43100019
         LA    R1,ENDUBF(0,R1)     POINTS TO USERBUFFER PLUS 88.        43150019
         LR    R8,R1               SO HAS R8.                           43200019
         STM   R4,R7,0(R1)         BUILD PARAMETERLIST.                 43250019
         CLC   D12(FOUR,R1),ZERO   HAS PARAMETERLIST FOUR WORDS?        43300019
         BNE   NEXTELM               YES, BRANCH.                       43350019
*                                    NO, GO ON.                         43400019
SETENDLT OI    D8(R8),ENDLIST                                           43450019
         L     R15,IHKYYMSG             GET MESSAGE WRITER ADDRESS      43500019
         BALR  R14,R15                  LINK FOR MESSAGE TO BE WRITTEN  43550019
         TM    TUBFLG4,TUBSTOP     STOP-FLAG SET?                       43600019
         BO    BRR2                  YES, IGNORE ALL BAD RETURNS.       43650019
*                                    NO, GO ON.                         43700019
         LTR   R5,R15              BAD COMPLETION?                      43750019
         BNZ   BRLST                 YES, BRANCH.                       43800019
*                                    NO, GO ON.                         43850019
BRR2     BR    R2                  TAKE NEXT INSTRUCTION WHEN ENTERED   43900019
*                                    AT SENDIT OR SENDIT2. GO BACK WHEN 43950019
*                                    ENTERED AT SENDIT1.                44000019
*                                                                       44050019
*********************************************************************** 44100019
RTNCD16  EQU   *                                                        44150019
NORETRN  EQU   *                                                        44200019
         TM    TUBFLG3,TUBCORRN    IS USER IN CORRECTION-MODE?          44250019
         BO    RDFRLN                YES, BRANCH.                       44300019
*                                    NO, GO ON.                         44350019
         CLI   TUBEXCLG,HEX00      IS EXEC-COMMAND IN PROCESS?          44400019
         BE    RDFRLN                NO, BRANCH.                        44450019
*                                    YES, GO ON.                        44500019
ENDEXEC  BAL   R2,FREEXBUF         GO AND FREE EXEC'S BUFFER.           44550019
         SR    R7,R7                                                    44600019
         LA    R6,MSG380           GET MESSAGE CODE ADDR.               44650019
         BAL   R2,SENDIT1          GO AND SEND MESSAGE.                 44700019
         B     RDFRLN                                                   44750019
         EJECT                                                          44800019
*********************************************************************** 44850019
*              EOF FROM EXEC-PROCESSOR                                * 44900019
*********************************************************************** 44950019
RTNCD24  EQU   *                                                        45000019
         BAL   R2,FREEXBUF         GO AND FREE EXEC'S BUFFER.           45050019
         LA    R11,ZERO            NO MORE RECOGNITION OF CMDED1DO.     45100019
         SR    R5,R5               SET 0 RETURN CODE                    45150019
         B     SNDENQ                                                   45200019
         SPACE 5                                                        45250019
*********************************************************************** 45300019
*              GETMAIN FAILED                                         * 45350019
*********************************************************************** 45400019
RTNCD08  EQU   *                                                        45450019
         LA    R5,ZERO                                                  45500019
         LA    R6,MSG219           OUT-OF-SPACE-MESSAGE.                45550019
         LA    R1,36(R13)          PICK UP PARM LIST ADDR        A34585 45590020
         L     R15,IHKYMSG2        GET MSG WRITER ADDRESS        A34585 45630020
         BALR  R14,R15             LINK TO IT                    A34585 45670020
         TM    TUBREQST,TUBIDENT        TUB EXIST ?              A34595 45690020
         BZ    BADCOMP             IF NOT, WAIT                  A34585 45710020
         CLI   PPTCMD,CMDLGF       TEST FOR LOGOFF               A36806 45715020
         BNE   RTNCD08B            IF NOT, CONTINUE              A36806 45720020
         CLI   TUBUSRID,HEX00      TEST FOR LOGOFF COMPLETE      A36806 45725020
         BNE   RTNCD08C            IF NOT TRY AGAIN              A36806 45730020
         B     ISUSRON             ISSUE PROMPT                  A36806 45735020
RTNCD08B EQU   *                                                 A36806 45740020
         BAL   R2,SDMSG300         GO AND SEND OUT-OF-SPACE-MSG.        45750019
         CLI   PPTCMD,CMDLGN       TEST FOR LOGON                A36806 45755020
         BNE   RTNCD08A            IF NOT, CONTINUE              A36806 45760020
RTNCD08C EQU   *                                                 A36806 45765020
         TM    TUBFLG2,TUBLGNAB    TEST FOR LOGON ABEND          A36806 45770020
         BZ    ISUSRON             IF NOT, PROMPT                A36806 45775020
         LA    R3,CMDLGF           GET LOGOFF COMMAND CODE       A36806 45780020
         SR    R9,R9               INDICATE NO DELETE            A36806 45785020
         B     LDLGF               LOAD LOGOFF                   A36806 45790020
RTNCD08A EQU   *                                                 A36806 45795020
         CLI   TUBEXCLG,HEX00      IS EXEC-COMMAND IN PROCESS?          45800019
         BE    ISUSRON               NO, BRANCH.                        45850019
*                                    YES, GO ON.                        45900019
         B     ENDEXEC                                                  45950019
         SPACE 5                                                        46000019
*********************************************************************** 46050019
*              ACTIVE AREA OUT OF SPACE                               * 46100019
*********************************************************************** 46150019
RTNCD20  BAL   R2,SENDENQ          SEND ALL ENQUEDED MESSAGES           46200019
         LA    R5,ZERO             2ND WORD OF PARMLIST POINTS TO ZERO. 46250019
         LA    R6,MSG240           HAS MESSAGE CODE ADDR.               46300019
         SR    R7,R7                                                    46350019
         LA    R2,NORETRN          DO NOT RETURN FROM MSG-WTR-LINKAGE.  46400019
         B     SENDIT2                                                  46450019
         EJECT                                                          46500019
*********************************************************************** 46550019
*                                                                     * 46600019
*              PROCESS IMPLICIT-COMMAND                               * 46650019
*                                                                     * 46700019
*********************************************************************** 46750019
         USING TUBDSECT,R4                                              46800019
NUM      NI    TUBPPTFL,TUBWARNF   RESET FLAG.                          46850019
         TM    TUBFLG2,TUBEDIT     IS USER IN EDIT-MODE?                46900019
         BO    IMPCMDV               YES, BRANCH.                       46950019
*                                     NO, GO ON.                        47000019
         BCTR  R3,0                BUILD PARAMETER                      47050019
         STC   R9,0(0,R3)            FOR MSG WTR.                       47100019
         LR    R7,R3                                                    47150019
         LA    R6,MSG305           GET MESSAGE CODE ADDR.               47200019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           47250019
*                                                                       47300019
IMPCMDV  EQU   *                                                        47350019
         L     R8,SCSTOP           GET ADDR OF LAST CHAR IN USER-BUFF.  47400019
         TM    TUBPPTFL,TUBCNTSN   WILL THIS LINE BE CONTINUED?         47450019
         BZ    NOADJ                 NO, BRANCH.                        47500019
*                                    YES, RE-ADJUST RECORCLENGTH. DASH  47550019
         LA    R8,ONE(0,R8)          AS LAST CHAR IN IMPLICIT-COMMAND.  47600019
         LTR   R15,R15             DELIMITER FOUND?                     47650019
         BZ    FALSDEL               NO, BRANCH.                        47700019
*                                    YES, GO ON.                        47750019
NOADJ    LH    R6,H32                                                   47800019
         LR    R7,R1                                                    47850019
         LR    R2,R15              KEEP RETURN-CODE FROM SCAN.          47900019
         BAL   R14,GETMAIN         GO GET MINIMUM-LENTH PPT.            47950019
         L     R11,TUBPARM3                                             48000019
         LA    R11,0(0,R11)                                             48050019
         ST    R11,TUBPPTAD        PPT-ADDR TO TUB AND CLEAR FLAGS.     48100019
         STC   R6,PPTLNG           STORE PPT-LENGTH.                    48150019
         XC    PPTCHAD,PPTCHAD                                          48200019
         MVI   PPTCMD,CMDIMP       INSERT CODE FOR IMPLICIT-COMMAND.    48250019
         ST    R3,PPTFLG+DBW       ADDR OF FIRST PARAMETER TO 3RD WORD  48300019
*                                    OF PPT.                            48350019
         STC   R9,PPTPARS          LENGTH OF FIRST PARAMETER TO 6TH     48400019
*                                    BYTE OF PPT.                       48450019
         MVI   PPTPARS+ONE,XZERO   ASSUME NO SECOND PARAMETER.          48500019
         LTR   R2,R2               WAS A DELIMITER FOUND?               48550019
         BZ    BLDLNKAD              NO, BRANCH.                        48600019
*                                    YES, GO ON.                        48650019
         LA    R8,0(0,R8)          CLEAR HIGHORDER-BYTE IN R8.          48700019
         SR    R8,R7               R6 HAS LENGTH OF 2ND PARAMETER.      48750019
         STC   R8,PPTPARS+ONE      STORE IT INTO 7TH BYTE OF PPT.       48800019
         LA    R7,ONE(0,R7)        HAS ADDR OF 2ND PARAMETER.           48850019
         ST    R7,PPTFLG+TRW       STORE IT INTO 4TH WORD OF PPT.       48900019
         B     BLDLNKAD                                                 48950019
*                                                                       49000019
FALSDEL  LA    R7,DELM                                                  49050019
         B       SMSGFD                                                 49100019
         EJECT                                                          49150019
*********************************************************************** 49200019
*                                                                     * 49250019
*              MOVE PARAMETER TO THE PPT AND INSERT LENGTH-INDICATOR  * 49300019
*                                                                     * 49350019
*********************************************************************** 49400019
MOVE1    LR    R5,R1               R5 HAS ADDR OF CHAR SUCCEEDING THE   49450019
*                                    PARAMETER.                         49500019
         SR    R5,R3               R5 HAS NUMBER OF BYTES TO BE MOVED.  49550019
         CH    R5,MXPARLNG        IS PARAMETER GT 56 CHAR?              49600019
         BH    ISSUMSG               YES, BRANCH.                       49650019
*                                    NO, GO ON.                         49700019
         L     R8,PPTCHAD                                               49750019
         STC   R5,0(R8)            STORE LENGTH INDICATOR.              49800019
         CLI   0(R8),HEX00         HAS PARAMETER ZERO-LENGTH?           49850019
         BCR   8,R2                                                     49900002
*                                    NO, GO ON.                         49950019
         CLI   PPTCMD,CMDCGN       IS IT CHANGE-COMMAND?                49960019
         BE    UPPERCS3              YES, BRANCH.                       49970019
*                                    NO, GO ON.                         49980019
UPPERCS4 EQU   *                                                        49990019
         BCTR  R5,0                ADJUST LENGTH FOR 'OR' AND 'MOVE'.   50000019
         TM    TUBFLG2,TUBEDIT     IS USER IN EDIT-MODE?                50250019
         BZ    UPPERCS2              NO, BRANCH.                        50300019
*                                    YES, GO ON.                        50350019
         L     R14,TUBDIRAD        HAS ADDR OF DIRECTORY-ENTRY.         50400019
         USING DIRDSECT,R14                                             50450019
         TM    DIRATTRL,DIRATEXT   HAS DATASET TEXT-ATTRIBUTE?          50500019
         DROP  R14                                                      50550019
         BZ    UPPERCS2              NO, BRANCH.                        50600019
*                                    YES, GO ON.                        50650019
         EX    R5,OCSTRING         CONVERT PARAMETER TO UPPER CASE.     50700019
UPPERCS2 EQU   *                                                        50750019
         EX    R5,MVPAR            MOVE CHARACTERS.                     50800019
         LA    R5,ONE(R5)                                               50850019
CKIFEOP  EQU   *                                                        50900019
         LA    R6,ONE(R5,R8)       R6 HAS ADDR OF NEXT FREE PPT-BYTE.   50950019
         IC    R9,PPTFLG           SAVE FLAGBYTE.                       51000019
         ST    R6,PPTCHAD                                               51050019
         STC   R9,PPTFLG           STORE FLAGBYTE.                      51100019
         BCR   15,R2                                                    51150019
*                                                                       51200019
UPPERCS3 CH    R0,H4               IS PARAMETER-COUNT GT 4?             51250019
         BH    UPPERCS4              YES, BRANCH.                       51300019
*                                    NO, GO ON.                         51350019
         CH    R0,H3               PARAMETER-COUNT EQ 3?                51400019
         BE    TSTTXTLG              YES, BRANCH.                       51450019
*                                    NO, GO ON.                         51500019
         CH    R0,H1               IS PARAMETER-COUNT EQ 1?             51503019
         BNE   UPPERCS5              NO, BRANCH.                        51506019
*                                    YES, GO ON.                        51509019
         ST    R1,TUBPARM5         SAVE SCAN POINTER                    51512019
         ST    R3,TUBPARM4         SAVE OPERAND POINTER                 51515019
         SPACE 1                                                        51518019
*                                  CHECK OPERAND FOR NUMERICS           51521019
         SPACE 1                                                        51524019
         ST    R3,TUBPARM2         STORE 2ND PARAMETER                  51527019
         OI    TUBPARM2,ENDLIST    FLAG END OF PARAMETER LIST           51530019
         ST    R8,TUBPARM1         STORE 1ST PARAMETER                  51533019
         LA    R1,TUBPARM1         GET LIST ADDRESS                     51536019
         L     R15,IHKYYNUM        GET ADDRESS OF IHKNUM                51539019
         BALR  R14,R15             CHECK OPERAND FOR NUMERICS           51542019
         L     R3,TUBPARM4         RESTORE OPERAND POINTER              51545019
         L     R1,TUBPARM5         RESTORE OPERAND POINTER              51548019
         LTR   R15,R15             TEST RETURN                          51551019
         BZ    UPPERCS4            IF GOOD, CONTINUE                    51554019
*                                  IF BAD, QUEUE ERROR MESSAGE          51557019
         BCTR  R3,0                POINT 1 BYTE BEFORE OPERAND          51560019
         CH    R5,H10              LINE NO LENGTH < 10 ?         A34590 51561020
         BNH   STORELEN            YES, BR TO SAVE TRUE LENGTH   A34590 51562020
         LH    R5,H10              ELSE SET LENGTH TO TEN        A34590 51563020
STORELEN STC   R5,0(R3)            SAVE INSERT LENGTH            A34590 51564020
         LR    R7,R3               GET 2ND PARAMETER                    51566019
         LA    R6,MSG307           GET MESSAGE NUMBER                   51569019
         B     SENDIT              SEND MESSAGE TO USER                 51572019
UPPERCS5 CH    R0,H4               IS PARAMETER COUNT EQ 4?             51575019
         BNE   UPPERCS4              NO, BRANCH.                        51600019
*                                    YES, GO ON.                        51650019
TSTTXTLG EQU   *                                                        51700019
         CH    R5,MXTXTLN          HAS TEXT MORE THAN 40 CHAR?          51750019
         BH    TXTOOLN               YES, BRANCH.                       51800019
*                                    NO, GO ON.                         51850019
         BCTR  R5,0                SET UP REG 5 FOR MOVE                51880019
         B     UPPERCS2            MOVE TEXT TO PPT                     51910019
*                                                                       51950019
ISSUMSG  EQU   *                                                        52000019
         BCTR  R3,0                BUILD PARAMETER                      52050019
         MVI   0(R3),LX10            FOR MSG WTR.                       52100019
         LR    R7,R3                                                    52150019
         LA    R6,MSG302           GET MESSAGE CODE ADDR.               52200019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           52250019
*                                                                       52300019
TXTOOLN  CH    R0,H3               PARAMETER-COUNT EQ 3?                52350019
         BNE   TEXT2                 NO, BRANCH.                        52400019
*                                    YES, GO ON.                        52450019
         LA    R7,TXT1                                                  52500019
         B     TXTOOLNG                                                 52550019
*                                                                       52600019
TEXT2    LA    R7,TXT2                                                  52650019
         B     TXTOOLNG                                                 52700019
         EJECT                                                          52750019
*********************************************************************** 52800019
*                                                                     * 52850019
*              ALLOCATE PPT AND MOVE CONTENT OF USER-BUFFER.          * 52900019
*                                                                     * 52950019
*********************************************************************** 53000019
ALLOCPPT L     R6,PPTCHAD          HAS ADDR OF LAST CHAR IN PPT.        53050019
         LA    R11,0(0,R11)        CLEAR HIGH-                          53100019
         LA    R6,0(0,R6)            ORDER BYTES.                       53150019
         SR    R6,R11                                                   53200019
         LA    R6,ONE(0,R6)        HAS NUMBER OF CHAR IN USER-BUFFER.   53250019
         CH    R6,H32              MORE THAN MINIMUM?                   53300019
         BH    LNGAV                 YES, BRANCH.                       53350019
*                                    NO, GO ON.                         53400019
ALCMNPPT EQU   *                                                        53450019
         LH    R6,H32              CONTINUE WITH MINIMUM-LENGTH.        53500019
LNGAV    BAL   R14,GETMAIN         GO AND ISSUE GETMAIN.                53550019
         STC   R6,PPTLNG           STORE LENGTH OF PPT.                 53600019
         BCTR  R6,0                ADJUST LENGTH FOR MVC.               53650019
         L     R8,TUBPARM3         HAS ADDR OF PPT.                     53700019
         EX    R6,MVCPPT           MOVE CONTENT OF USER-BUFFER.         53750019
         BAL   R14,FNDLPPT         GO AND FIND LAST PPT.                53800019
         BAL   R14,STORADDR        GO AND STORE ADDR.                   53850019
         LA    R14,TUBPPTAD                                             53900019
         CR    R14,R11             NO PPT ALLOCATED YET?                53950019
         BE    CLEARED               YES, BRANCH.                       54000019
*                                    NO, GO ON.                         54050019
         MVI   PPTFLG,HEX00        CLEAR FLAGS.                         54100019
CLEARED  EQU   *                                                        54150019
         LR    R11,R8              HAS ADDR OF PPT ALLOCATED RIGHT NOW. 54200019
         MVC   PPTCHAD+ONE(L'ZERO),ZERO                                 54250019
         BCR   15,R2               GO BACK.                             54300019
         EJECT                                                          54350019
*********************************************************************** 54400019
*              FIND LAST PPT IN CHAIN                                 * 54450019
*********************************************************************** 54500019
FNDLPPT  LA    R11,TUBPPTAD                                             54550019
         CLC   ZERO,TUBPPTAD+ONE   PPT ALLOCATED?                       54600019
         BCR   8,R14                 NO, BRANCH.                        54650019
*                                    YES, GO ON.                        54700019
         L     R11,TUBPPTAD        HAS ADDR OF FIRST PPT.               54750019
LSTPPT   CLC   ZERO,PPTCHAD+ONE    IS ANOTHER PPT ALLOCATED?            54800019
         BCR   8,R14                 NO, GO BACK.                       54850019
*                                    YES, GO ON.                        54900019
         L     R11,PPTCHAD         GET NEXT PPT.                        54950019
         B     LSTPPT                                                   55000019
         SPACE 5                                                        55050019
*********************************************************************** 55100019
*              STORE ADDR AND SAVE HIGHORDER BYTE                     * 55150019
*********************************************************************** 55200019
STORADDR IC    R6,0(0,R11)                                              55250019
         ST    R8,0(0,R11)                                              55300019
         STC   R6,0(0,R11)                                              55350019
         BCR   15,R14                                                   55400019
         SPACE 5                                                        55450019
*********************************************************************** 55500019
*              LISTBC-COMMAND-PROCESSOR                               * 55550019
*********************************************************************** 55600019
LISTBC   EQU   *                                                        55650019
         CLC   ZERO,PPTCHAD+ONE    IS OTHER PPT ALLOCATED?              55700019
         BNE   WRONG1                YES, BRANCH.                       55750019
*                                    NO, GO ON.                         55800019
         CLI   PPTPARS,FF          IS OPERAND IN PPT?                   55850019
         BNE   WRONG2                YES, BRANCH.                       55900019
*                                    NO GO ON.                          55950019
         OI    TUBFLG1,TUBBRD      BRD-MESSAGES REQUIRED, SET FLAG.     56000019
         SR    R15,R15                                                  56050019
         B     BACKPROC                                                 56100019
*                                                                       56150019
WRONG1   L     R11,PPTCHAD         HAS ADDR OF NEXT PPT.                56200019
WRONG2   LA    R7,PPTPARS          POINTS TO LENGTH OF OPERAND.         56250019
         CLI   PPTPARS,X10         IS LENGTH GT 10?                     56300019
         BNH   DONE                  NO, BRANCH.                        56350019
*                                    YES, GO ON.                        56400019
         MVI   PPTPARS,X10         MAX LENGTH IS 10.                    56450019
DONE     LA    R6,MSG334           GET MESSAGE CODE ADDR.               56500019
         B     SENDIT                                                   56550019
         SPACE 5                                                        56600019
*********************************************************************** 56650019
*              INTERFACE FOR INSTALLATION-SUPPLIED COMMAND-PROCESSORS * 56700019
*********************************************************************** 56750019
USERCMD  LA    R1,TUBPARM1         USED AS PARAMETERLIST.               56800019
         ST    R4,TUBPARM1         PARAMETERLIST POINTS TO TUB (UCCT).  56850019
         L     R14,IHKYYCCT        GET CCT ADDRESS                      56900019
         USING CCTDSECT,R14                                             56950019
         L     R15,CCTUSR         GET USER EXIT ADDRESS                 57000019
         LTR   R15,R15                  USER EXIT EXIST?         A36808 57010020
         BZ    WHTMD                    NO, BR - INVALID COMMAND A36808 57020020
         DROP  R14                                                      57050019
         BALR  R14,R15             LINK TO IT.                          57100019
*                                                                       57150019
         LTR   R15,R15                                                  57200019
         BZ    GETLINE             NO MESSAGE, GET NEXT COMMAND  A40202 57250020
*                                  SEND CONTENTS OF USER-BUFFER         57300019
*                                    (120 BYTES) TO TERMINAL.           57350019
         LR    R15,R4              R15 HAS ADDR OF TUB.                 57400019
         LA    R3,C120                                                  57450019
         STH   R3,TUBDATAL                                              57500019
         BAL   R9,CWRITE           GO AND ISSUE CWRITE.                 57550019
         LTR   R15,R15             BAD COMPLETION?                      57600019
         BNZ   RTNCD04               YES, BRANCH.                       57650019
*                                    NO, GO ON.                         57700019
         B     GETLINE             GET NEXT COMMAND              A40202 57750020
*                                                                       57800019
         EJECT                                                          57850019
*********************************************************************** 57900019
*                                                                     * 57950019
*              DEALLOCATE PPT'S IF NO LINE-CONTINUATION               * 58000019
*                                                                     * 58050019
*********************************************************************** 58100019
DEALLC   EQU   *                                                        58150019
         CLC   ZERO,TUBPPTAD+ONE   IS PPT ALLOCATED?                    58200019
         BE    BACKR2                NO, BRANCH.                        58250019
*                                    YES, GO ON.                        58300019
         L     R11,TUBPPTAD        HAS ADDR OF FIRST PPT.               58350019
         TM    TUBPPTFL,TUBCNTEN   IS CONTINUATION EXPECTED?            58400019
         BO    NODEALLC              YES, BRANCH.                       58450019
*                                    NO, GO ON.                         58500019
NEXTPPT  L     R9,PPTCHAD          HAS ADDR OF NEXT PPT.                58550019
         LA    R9,0(0,R9)          CLEAR HIGH-ORDER BYTE.               58600019
         LR    R8,R11              HAS ADDR OF PPT TO BE FREED.         58650019
         SR    R6,R6                                                    58700019
         IC    R6,PPTLNG           HAS LENGTH OF PPT.                   58750019
         BAL   R14,FREEMAIN        GO AND FREEMAIN AREA.                58800019
         LTR   R11,R9              HAS NEXT PPT-ADDR IF THERE IS ONE.   58850019
         BC    7,NEXTPPT           BRANCH IF THERE IS ANOTHER PPT.      58900019
*                                    GO ON OTHERWISE.                   58950019
         MVC   TUBPPTAD+ONE,ZERO   CLEAR PPTADDR IN TUB.                59000019
BACKR2   LA    R1,ZERO                                                  59050019
BACKR21  L     R11,TUBUFFAD        HAS ADDR OF USERBUFFER.              59100019
         LA    R11,0(0,R11)                                             59150019
         SH    R11,H8              POINTS TO USERBUFFER MINUS 8.        59200019
         MVC   0(6,R11),0(R1)      MOVE ZERO OR FIRST 6 BYTES OF PPT.   59250019
         BCR   15,R2               GO BACK.                             59300019
NODEALLC BAL   R14,FNDLPPT         GO AND FIND LAST PPT.                59350019
         LA    R1,PPTCHAD          POINTS TO LAST PPT.                  59400019
         B     BACKR21                                                  59450019
         EJECT                                                          59500019
*********************************************************************** 59550019
*              NON-RESIDENT ROUTINE MUST BE LOADED.                   * 59600019
*********************************************************************** 59650019
NONRESGO EQU   *                                                        59700019
         BAL   R2,TSTAB            TEST FOR IHKLDC ABEND         A36810 59730020
         SLL   R3,ONE(0)           SET UP LOAD CODE              A36810 59760020
         SRL   R3,SCT25(0)                                              59800019
         LA    R5,SVR8R9(0,R13)    SAVE FOR R8 AND R9 USED AS PARMLIST. 59850019
         XC    0(L8,R5),0(R5)      CLEAR PARAMETERLIST.                 59900019
         STC   R3,RQLOD(R5)        CODE OF ROUTINE TO BE LOADED.        59950019
         STC   R9,RQDEL(R5)        CODE OF ROUTINE TO BE DELETED.       60000019
         BAL   R2,LDEL             LOAD PROCESSOR                A36806 60500020
         BAL   R2,TSTAB            TEST FOR IHKLDC ABEND         A36810 60700020
         L     R15,0(0,R1)         HAS ENTRY-POINT OF ROUTINE.          61000019
         B     GOTOCMDP                                                 61050019
         SPACE 5                                                        61100019
*********************************************************************** 61150019
*              NON-RESIDENT ROUTINE MUST BE DELETED.                  * 61200019
*********************************************************************** 61250019
NONRESBK EQU   *                                                        61300019
         BAL   R2,TSTAB            TEST FOR IHKLDC ABEND         A36810 61320020
         LR    R7,R15              KEEP RETURN-CODE.                    61350019
         LA    R5,SVR8R9(0,R13)    SAVE FOR R8 AND R9 USED AS PARMLIST. 61400019
         XC    0(L8,R5),0(R5)      CLEAR PARAMETERLIST.                 61450019
         IC    R3,PPTCMD           HAS COMMAND-CODE.                    61500019
         STC   R3,RQDEL(R5)        CODE OF ROUTINE TO PARAMETERLIST.    61550019
         NI    RQDEL(R5),CLNRES    CLEAR NON-RESIDENT-FLAG.             61600019
         LTR   R15,R15             REQUEST TO ENTER AN OTHER MODULE?    61650019
         BC    4,DELLOD              YES, BRANCH.                       61700019
*                                    NO, GO ON.                         61750019
DELETE   EQU   *                                                        61800019
         BAL   R2,LDEL             DELETE MODULE                 A36806 62250020
         LR    R15,R7              RESTORE RETURN-CODE FROM COMMAND-    62800019
         B     ISR15NEG              PROCESSOR.                         62850019
*                                                                       62900019
DELLOD   LPR   R9,R15                                                   62950019
         SLL   R9,SCT24(0)                                              63000019
         LTR   R9,R9               REQUEST TO ENTER RESIDENT ROUTINE?   63050019
         BC    11,DELETE             YES, BRANCH.                       63100019
*                                    NO, GO ON.                         63150019
         SR    R9,R9                                                    63200019
         IC    R9,RQDEL(R5)        HAS CODE OF ROUTINE TO BE DELETED.   63250019
         B     R15ISNEG                                                 63300019
         SPACE 5                                                 A36806 63302020
**************************************************************** A36806 63304020
*              LOAD AND/OR DELETE MODULE                         A36806 63306020
**************************************************************** A36806 63308020
LDEL     EQU   *                                                 A36806 63310020
         TM    TUBREQST,TUBIDENT   TEST FOR TUB                  A36806 63312020
         BO    LDEL1               IF YES, GET CLB ADDR FROM TUB A36806 63314020
         LR    R8,R4               GET CLB ADDR                  A36806 63316020
         B     LDEL2               POST IHKLDC                   A36806 63318020
LDEL1    EQU   *                                                 A36806 63320020
         L     R8,TUBCLBAD         GET CLB ADDR                  A36806 63322020
         USING CLBDSECT,R8                                       A36806 63324020
LDEL2    EQU   *                                                 A36806 63326020
         LA    R1,CLBLCECB         GET IHKLDC'S ECB              A36806 63328020
         DROP  R8                                                A36806 63330020
         LR    R0,R5               GET RETURN ECB ADDR           A36806 63332020
         SVC   2                   POST IHKLDC                   A36806 63334020
         LR    R1,R5               GET RETURN ECB ADDR FOR DSP   A36806 63336020
         LM    R8,R9,SVR8R9(R13)   PUT PARM LIST INTO REGS 8 & 9 A36806 63338020
         L     R15,IHKYYDSP        GET ADDR OF IHKDSP            A36806 63340020
         BALR  R14,R15             WAIT FOR IHKLDC               A36806 63342020
         BR    R2                  EXIT                          A36806 63344020
         SPACE 5                                                 A36810 63344220
**************************************************************** A36810 63344420
*              TEST FOR IHKLDC ABEND                           * A36810 63344620
**************************************************************** A36810 63344820
TSTAB    TM    IHKYYLCE,POST       TEST FOR IHKLDC ABEND         A36810 63345020
         BZ    0(R2)               IF NOT, CONTINUE              A36810 63345220
         B     LINKERR             IF NOT, LINK TO IHKERR        A36810 63345420
         SPACE 5                                                 A36810 63345620
**************************************************************** A36810 63345820
*              LINK TO IHKERR IN CASE OF IHKLDC ABEND            A36810 63346020
**************************************************************** A36810 63346220
LINKERR  EQU   *                                                 A36810 63346420
         LR    R5,R12              ADDRESS OF AVT IN REGISTER 5  A36810 63346620
         STM   R4,R5,OFSR4(R13)    STORE TUB AND AVT ADDRESSES   A36810 63346820
         LA    R1,OFSR4(0,R13)     R1 POINTS TO WHERE R4 AND R5  A36810 63347020
*                                  ARE SAVED BY CALLED PROGRAM.  A36810 63347220
*                                  I.E., R1 POINTS TO A PARM LISTA36810 63347420
*                                  THAT CONTAINS THE ADDRESSES   A36810 63347620
*                                  OF THE TUB AND THE AVT        A36810 63347820
         LINK  EP=IHKERR           LINK TO IHKERR                A36810 63348020
         B     RTNCD28             BRANCH, GO TO BADCOMP         A36810 63348220
         SPACE 5                                                        63350019
*********************************************************************** 63400019
*              FREEMAIN AREA GOT BY EXEC-PROCESSOR                    * 63450019
*********************************************************************** 63500019
FREEXBUF L     R8,TUBEXCAD         HAS ADDR OF GETMAIN-AREA.            63550019
         SR    R6,R6                                                    63600019
         IC    R6,TUBEXCLG         HAS LENGTH OF GETMAIN-AREA.          63650019
         BAL   R14,FREEMAIN        GO AND FREEMAIN AREA.                63700019
         XC    TUBEXCAD,TUBEXCAD   CLEAR ADDR AND LENGTH OF AREA.       63750019
         NI    TUBPPTFL,TUBRAKEF   CLEAR BREAK-FLAG.                    63800019
         NI    TUBFLG2,TUBXLSTF    CLEAR FLAG 'LIST COMMANDS BEFORE     63850019
*                                    PROCESSING'.                       63900019
         BR    R2                  GO BACK.                             63950019
         SPACE 5                                                        64000019
*********************************************************************** 64050019
*              GETMAIN                                                * 64100019
*********************************************************************** 64150019
GETMAIN  LA    R6,0(R6)                  ELEM HIGH ORDER BITS           64200019
         ST    R14,TUBPARM2             SAVE EXIT ADDRESS               64250019
         L     R1,IHKYYGML                                              64300019
         GETMAIN EC,LV=(R6),A=TUBPARM3,MF=(E,(1))  GET AREA             64350019
         L     R14,TUBPARM2             RESTORE EXIT ADDRESS            64400019
         LTR   R15,R15             BAD COMPLETION?                      64450019
         BCR   8,R14                 NO, GO BACK.                       64500019
*                                    YES, GO ON.                        64550019
         B     RTNCD08                                                  64600019
         SPACE 5                                                        64650019
*********************************************************************** 64700019
*              FREEMAIN                                               * 64750019
*********************************************************************** 64800019
FREEMAIN LA    R8,0(0,R8)          CLEAR HIGHORDERBYTE.                 64850019
         ST    R14,TUBPARM2             SAVE EXIT ADDRESS               64900019
         FREEMAIN R,A=(R8),LV=(R6)                                      64950019
         L     R14,TUBPARM2             RESTORE EXIT ADDRESS            65000019
         BR    R14                 GO BACK.                             65050019
*                                                                       65100019
         SPACE 5                                                        65150019
*********************************************************************** 65200019
*              SEND OUT-OF-SPACE-MESSAGE                              * 65250019
*********************************************************************** 65300019
SDMSG300 L     R5,TUBUFFAD         HAS USER-BUFFER-AADR.                65350019
         TM    TUBFLG1,TUBMID      TEST FOR MSG ID'S REQUESTED   A36805 65357020
         BO    SMSG300A            IF YES, INCLUDE ID            A36805 65364020
         MVC   0(LM300N,R5),MSG300+8  MOVE MSG WITHOUT ID        A36805 65371020
         LA    R5,LM300N           GET LENGTH                    A36805 65378020
         STH   R5,TUBDATAL         PUT INTO TUB                  A36805 65385020
         B     SMSG300B            SEND MESSAGE                  A36805 65392020
SMSG300A MVC   0(L'MSG300,R5),MSG300  MSG TO USER BUFFER         A36805 65412020
         LA    R5,L'MSG300         LENGTH OF MSG TO                     65450019
         STH   R5,TUBDATAL           TUBDATAL.                          65500019
SMSG300B LR    R15,R4              GET TUB ADDRESS               A36805 65550020
         BAL   R9,CWRITE           GO AND ISSUE CWRITE.                 65600019
         LTR   R15,R15             GOOD COMPLETION?                     65650019
         BNZ   RTNCD04               NO, BRANCH.                        65700019
         BR    R2                    YES, GO BACK.                      65750019
         SPACE 5                                                        65800019
*********************************************************************** 65850019
*              CWRITE, CREAD                                          * 65900019
*********************************************************************** 65950019
         CNOP  0,4                                                      66000019
CWRITE   OI    4(15),X'4' REQUEST FOR CWRITE                            66050019
CREAD    BAL   1,*+8 LOAD ADD OF NEXT IN REG 1                          66100019
         DC    F'0' FULL WORD                                           66150019
         ST    15,0(0,1) STORE ADDRESS IN PARM LIST                     66200019
         L     15,IHKYYLAD GET ENTRY POINT ADDRESS                      66250019
         BALR  14,15 LINK TO LINE ADMINISTRATOR                         66300019
         BR    R9                                                       66350019
         SPACE 5                                                        67250019
*********************************************************************** 67300019
*              FREE SAVE AREA                                         * 67350019
*********************************************************************** 67400019
FRSAREA  LA    R13,0(0,R13)        CLEAR HIGHORDER BYTE.                67450019
         LTR   R13,R13             AREA ALREADY FREED?                  67500019
         BCR   8,R2                  YES, GO BACK.                      67550019
*                                    NO, GO ON.                         67600019
         TM    TUBREQST,TUBIDENT   IS TUB-ADDR IN R4?                   67650019
         BZ    CLBINR4               NO, BRANCH.                        67700019
*                                    YES, GO ON.                        67750019
         L     R6,TUBCLBAD         HAS CLB-ADDR.                        67800019
         USING CLBDSECT,R6                                              67850019
         B     CLBINR6                                                  67900019
*                                                                       67950019
CLBINR4  LR    R6,R4                                                    68000019
CLBINR6  LA    R7,CLBSAVE          HAS ADDR OF CLBSAVE.                 68050019
         DROP  R6                                                       68100019
         CR    R7,R13              IS IT CLBSAVE.                       68150019
         BCR   8,R2                  YES, GO BACK.                      68200019
*                                    NO, GO ON.                         68250019
         FREEMAIN R,LV=72,A=(R13)  FREE SAVE AREA.                      68300019
         SR    R13,R13                                                  68350019
         BR    R2                  GO BACK.                             68400019
         SPACE 5                                                        68450019
*********************************************************************** 68500019
*              SEND ALL ENQUEUED MESSAGES                             * 68550019
*********************************************************************** 68600019
SENDENQ  EQU   *                                                        68650019
         LR    R7,R5               SAVE RETURN CODE              A36810 68700020
         L     R1,TUBUFFAD         GET USER BUFFER ADDR.                68750019
         LA    R1,ENDUBF(R0,R1)    POINT TO USERBUFFERS LAST 5 WORDS.   68800019
         LR    R5,R4               FIRST TWO WORDS POINT TO TUB.        68850019
         LA    R6,CLEANUP          THIRD WORD HAS MESSAGE CODE.         68900019
         STM   R4,R6,0(R1)                                              68950019
         OI    D8(R1),ENDLIST                                           69000019
         L     R15,IHKYYMSG          SEND ALL ENQUEUED MESSAGES.        69050019
         BALR  R14,R15             LINK TO MESSAGE WRITER.              69100019
         LTR   R5,R15              BAD COMPLETION?                      69150019
         BNZ   BRLST                 YES, BRANCH.                       69200019
         LR    R5,R7               RESTORE RETURN CODE           A36810 69250020
         BR    R2                    NO, GO BACK.                       69300019
*                                                                       69350019
         EJECT                                                          69400019
*********************************************************************** 69450019
*                                                                     * 69500019
*              PROCESS CHANGE-COMMAND                                 * 69550019
*                                                                     * 69600019
*********************************************************************** 69650019
         USING TUBDSECT,R4                                              69700019
CHANGE   EQU   *                                                        69750019
         CH    R0,H4               IS PARAMETER-COUNT LT 4?             69800019
         BNL   PCLT11                NO, BRANCH.                        69850019
*                                    YES, GO ON.                        69900019
*                                    NUMERIC.                           69950019
         LTR   R0,R0               IS PARAMETERCOUNT LT 1?              70000019
         BC    13,PCLT11             YES, BRANCH.                       70050019
*                                    NO, GO ON.                         70100019
*                                  WITH THE FOLLOWING INSTRUCTIONS THE  70150019
         TM    0(R1),MSKF0                                              70200019
         BC    14,NONNUM1            BRANCH, CHAR IS NOT NUMERIC.       70250019
*                                                                       70300019
         TM    0(R1),MSK08                                              70350019
*                                    FIRST CHARACTER IS TESTED IF IT IS 70400019
         BZ    NUM1                  BRANCH, CHAR IS NUMERIC.           70450019
*                                                                       70500019
         TM    0(R1),MSK06                                              70550019
         BZ    NUM1                  BRANCH, CHAR IS NUMERIC.           70600019
*                                                                       70650019
NONNUM1  LA    R0,VAL2             SET PARAMETERCOUNT TO TWO.           70700019
         MVC   SCVACHSR,0(R1)      SENSITIVE CHAR TO PARAMETERLIST      70750019
SCCHCMD  LR    R3,R1               R3 HAS BEGIN OF PARAMETER.           70800019
         LA    R1,ONE(R1)          R1 HAS SCAN-START-ADDR.              70850019
         BAL   R2,SCVACH           GO AND SCAN FOR THIS CHARACTER.      70900019
*                                  BACK FROM SCAN-ROUTINE.              70950019
         B     VCHNTF                BRANCH, CHAR NOT FOUND.            71000019
*                                    GO ON, CHAR FOUND.                 71050019
BRTMVE   EQU   *                                                        71100019
         AH    R0,H1               ADD ONE TO PARAMETER-COUNT.          71150019
         BAL   R2,MOVE1            GO AND MOVE PARAMETER TO PPT.        71200019
*                                  BACK FROM MOVE-ROUTINE.              71250019
         TM    PPTFLG,CMDE         END OF COMMAND FOUND?                71300019
         BO    ENDLNECH              YES, BRANCH.                       71350019
*                                    NO, GO ON.                         71400019
         CH    R0,H4               IS PARAMETER-COUNT EQ 4?             71450019
         BNE   SCCHCMD               NO, BRANCH.                        71500019
*                                    YES, GO ON.                        71550019
         B     SCAN                                                     71600019
*                                                                       71650019
NUM1     CH    R0,H1               IS PARAMETER-COUNT EQ 1?             71700019
         BE    PCLT1                 YES, BRANCH.                       71750019
*                                    NO, ISSUE ERROR-MESSAGE.           71800019
         BCTR  R1,0                BUILD PARAMETER                      71850019
         MVI   0(R1),LX1             FOR MSG WTR.                       71900019
         LR    R7,R1                                                    71950019
SMSGFD   EQU   *                                                        72000019
         LA    R6,MSG315           GET MESSAGE CODE ADDR.               72050019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           72100019
*                                                                       72150019
VCHNTF   EQU   *                                                        72200019
         LA    R6,MSG314           GET MESSAGE CODE ADDR.               72250019
         SR    R7,R7                                                    72300019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           72350019
*                                                                       72400019
         TM    TUBPPTFL,TUBCNTSN   WILL THIS LINE BE CONTINUED?         72450019
         L     R1,SCSTOP           R1 HAS ADDR OF LAST CHAR IN          72500019
*                                     USER BUFFER.                      72550019
         LA    R1,ONE(R1)                                               72600019
         BZ    STEOCMD               NO, BRANCH.                        72650019
*                                    YES, GO ON.                        72700019
         LA    R1,ONE(R1)          READJUST END OF PARAMETER.           72750019
         NI    TUBPPTFL,TUBCNTSF   CLEAR LINE-WILL-BE-CONTINUED-FLAG.   72800019
STEOCMD  OI    PPTFLG,CMDE         SET END OF COMMAND FOUND FLAG.       72850019
         B     BRTMVE                                                   72900019
*                                                                       72950019
PCLT1    AH    R0,H1               ADD ONE TO PARAMETER-COUNT.          73000019
         NI    TUBPPTFL,TUBNULPF   CLEAR NULL-PARAMETER-FLAG.           73050019
         B     SCANBCLR                                                 73100019
*                                                                       73150019
PCLT11   CLI   0(R1),LEFTPAR       IS FIRST CHAR '('?                   73200019
         BNE   NOLPR                 NO, BRANCH.                        73250019
*                                    YES, GO ON.                        73300019
         LA    R7,ONE(R7)          ADD ONE TO PARENTHESES-COUNT.        73350019
         B     SCAN                                                     73400019
*                                                                       73450019
NOLPR    CLI   0(R1),RGTHPAR       IS FIRST CHAR ')'?                   73500019
         BNE   PCLT1                 NO, BRANCH.                        73550019
*                                    YES, GO ON.                        73600019
         BCTR  R7,0                                                     73650019
         B     SCAN                                                     73700019
*                                                                       73750019
ENDLNECH CH    R0,H3               IS PARAMETER-COUNT EQ 3?             73800019
         BE    VCHNTF                YES, BRANCH.                       73850019
*                                    NO, GO ON.                         73900019
         B     ENDLNE                                                   73950019
         EJECT                                                          74000019
*********************************************************************** 74050019
*                                                                     * 74100019
*              PROCESS PARAMETER IN QUOTES                            * 74150019
*                                                                     * 74200019
*********************************************************************** 74250019
ICQTE    EQU   *                                                        74300019
         NI    TUBPPTFL,TUBNULPF   CLEAR NULL-PARAMETER-FLAG.           74350019
         LR    R3,R1               HAS ADDR OF QUOTE.                   74400019
         LA    R1,ONE(R1)          R1 HAS SCAN-START-ADDR.              74450019
         OI    PPTFLG,QTEBALN      SET FLAG 'QUOTE FOUND'.              74500019
RESSCAN  EQU   *                                                        74550019
         XC    SCQOTESL,SCQOTESL   CLEAR SCANLENGTH. STOP-ADDR IS USED. 74600019
         BAL   R2,SCQOTE           GO AND SCAN FOR QUOTE.               74650019
*                                  BACK FROM SCAN-ROUTINE.              74700019
         B     QTENTFD               BRANCH,NO QUOTE FOUND.             74750019
*                                    GO ON, QUOTE FOUND.                74800019
         XI    PPTFLG,QTEBALN      TURN FLAG 'QUOTE FOUND'.             74850019
         CL    R1,SCSTOP           IS THIS QUOTE THE LAST CHAR?         74900019
         BE    SETECMD               YES, BRANCH.                       74950019
*                                    NO, GO ON.                         75000019
         CLI   ONE(R1),QTE         IS NEXT CHAR A QUOTE?                75050019
         BNE   TSTIFDE               NO, BRANCH.                        75100019
*                                    YES, GO ON.                        75150019
         XI    PPTFLG,QTEBALN      TURN FLAG 'QUOTE FOUND'.             75200019
         L     R14,SCSTOP          HAS ADDR OF LAST CHAR IN USERBUFFER. 75250019
         BCTR  R14,0                                                    75300019
         ST    R14,SCSTOP          HAS NEW STOP-ADDR.                   75350019
         SR    R14,R1              HAS LENGTH FOR MOVE OPERATION.       75400019
         EX    R14,MVUBF           MOVE REMAINDER OF USER BUFFER.       75450019
         LA    R1,ONE(0,R1)        HAS NEW SCAN-START-ADDR.             75500019
         CL    R1,SCSTOP           IS IT LAST CHARACTER?                75550019
         BE    SETECMD1              YES, BRANCH.                       75600019
*                                    NO, GO ON.                         75650019
         B     RESSCAN                                                  75700019
*                                                                       75750019
TSTIFDE  EQU   *                                                        75800019
         CLI   ONE(R1),BLANK       IS NEXT CHAR A BLANK?                75850019
         BE    CKINULL               YES, BRANCH.                       75900019
*                                    NO, GO ON.                         75950019
         CLI   ONE(R1),COMMA       IS NEXT CHAR A COMMA?                76000019
         BE    CKINULLC              YES, BRANCH.                       76050019
*                                    NO, GO ON.                         76100019
         CLI   ONE(R1),RGTHPAR     IS IT RIGHT PARENTHESIS?             76150019
         BE    CKINULL               YES, BRANCH.                       76200019
*                                    NO, SEND ERROR MSG.                76250019
         LA    R6,MSG314           GET MESSAGE CODE ADDR.               76300019
         SR    R7,R7                                                    76350019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           76400019
*                                                                       76450019
CKINULLC OI    TUBPPTFL,TUBCOMAN   SET FLAG 'COMMA FOUND'.              76500019
CKINULL  LR    R5,R1               HAS ADDR OF QUOTE FOUND.             76550019
         SR    R5,R3               HAS PARAMETER-LENGTH.                76600019
         CH    R5,H1               ZERO-LENGTH-PARAMETER?               76650019
         BE    NULLPARQ              YES, BRANCH.                       76700019
*                                      NO, GO ON.                       76750019
         LA    R1,ONE(0,R1)        HAS ADDR OF FIRST DELIMITER.         76800019
         TM    PPTFLG,QTEBALN      QUOTES BALANCED?                     76850019
         BZ    MOVE                  YES, BRANCH.                       76900019
*                                    NO, GO ON.                         76950019
QTENTFD  EQU   *                                                        77000019
         LA    R6,MSG311           GET MESSAGE CODE ADDR.               77050019
         SR    R7,R7                                                    77100019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           77150019
*                                                                       77200019
TXTOOLNG EQU   *                                                        77250019
         LA    R6,MSG319           GET MESSAGE CODE ADDR.               77300019
         B     SENDIT              BRANCH TO MSG WTR LINKAGE.           77350019
*                                                                       77400019
NULLPARQ LA    R7,DOUBQT           GO SEND                              77450019
         B     NULLPAR               ERROR MESSAGE.                     77500019
*                                                                       77550019
SETECMD1 CLI   0(R1),QTE           IS THIS LAST CHAR A QUOTE?           77600019
         BNE   SETECMD               NO, BRANCH.                        77650019
*                                    YES, GO ON.                        77700019
         XI    PPTFLG,QTEBALN      TURN FLAG 'QUOTE FOUND'.             77750019
SETECMD  OI    PPTFLG,CMDE         END OF LINE REACHED, SET FLAG.       77800019
         B     CKINULL                                                  77850019
         EJECT                                                          77900019
*********************************************************************** 77950019
*                                                                     * 78000019
*              LINKAGES TO SCAN-ROUTINE (IHKCCS)                      * 78050019
*                                                                     * 78100019
*********************************************************************** 78150019
*                                                                       78200019
*                                  PARAMETER-LIST.                      78250019
SCSTART  DS    F                     SCAN-START-ADDR.                   78300019
SCSTOP   DS    F                     SCAN-STOP-ADDR.                    78350019
SCPADDR  DS    F                     ADDR OF OTHER PARAMETERS.          78400019
*                                                                       78450019
         SPACE 2                                                        78500019
*INSTRUCTIONS COMMON TO ALL LINKAGES.                                   78550019
COMINSTR EQU   *                                                        78600019
         ST    R14,SCPADDR         ADDR OF OTHER PARAMETERS TO LIST.    78650019
         ST    R1,SCSTART          SCAN-START-ADDR TO PARAMETER-LIST.   78700019
         LA    R1,SCSTART          HAS ADDR OF PARAMETERLIST.           78750019
         L     R15,IHKYYCCS        GET ADDR OF SCAN-ROUTINE.            78800019
         BALR  R14,R15             BRANCH TO SCAN-ROUTINE.              78850019
*                                                                       78900019
         B     0(R2,R15)           GO BACK.                             78950019
*                                                                       79000019
         SPACE 2                                                        79050019
*SCAN FOR VARIABLE CHARACTER                                            79100019
         CNOP  0,4                                                      79150019
SCVACH   BAL   R14,COMINSTR        LOAD ADDR OF PARAMETERS AND BRANCH.  79200019
SCVACHSL DC    H'0'                  SCAN LENGTH.                       79250019
SCVACHNC DC    H'1'                  ONE SENSITIVE CHARACTER.           79300019
SCVACHSR DS    CL1                   SENSITIVE CHARACTERS.              79350019
         SPACE 2                                                        79400019
*SCAN FOR BLANK, COMMA, LEFT OR RIGTH PARENTHESIS, SLASH.               79450019
         CNOP  0,4                                                      79500019
SCBCLR   BAL   R14,COMINSTR        LOAD ADDR OF PARAMETERS AND BRANCH.  79550019
SCBCLRSL DC    H'0'                  SCAN LENGTH.                       79600019
SCBCLRNC DC    H'4'                  FOUR SENSITIVE CHARS.              79650019
SCBCLRSR DC    C' ,()'               SENSITIVE CHARS.                   79700019
         SPACE 2                                                        79750019
*SCAN FOR QUOTE                                                         79800019
         CNOP  0,4                                                      79850019
SCQOTE   BAL   R14,COMINSTR        LOAD ADDR OF PARAMETERS AND BRANCH.  79900019
SCQOTESL DC    H'0'                  SCAN LENGTH.                       79950019
SCQOTENC DC    H'1'                  ONE SENSITIVE CHARACTER.           80000019
SCQOTESR DC    X'7D'                 SENSITIVE CHARACTERS.              80050019
         SPACE 2                                                        80100019
*SCAN FOR DELIMITER (COMMA OR BLANK)                                    80150019
         CNOP  0,4                                                      80200019
SCDELI   BAL   R14,COMINSTR        LOAD ADDR OF PARAMETERS AND BRANCH.  80250019
SCDELISL DC    H'0'                  SCAN LENGTH.                       80300019
SCDELINC DC    H'2'                  TWO SENSITIVE CHARACTERS.          80350019
SCDELISR DC    C', '                 SENSITIVE CHARACTERS.              80400019
         SPACE 2                                                        80450019
*SCAN FOR NON-BLANK                                                     80500019
         CNOP  0,4                                                      80550019
SCNBLK   BAL   R14,COMINSTR        LOAD ADDR OF PARAMETERS AND BRANCH.  80600019
SCNDELSL DC    H'0'                  SCAN LENGTH.                       80650019
SCNDELNC DC    H'0'                  NO SENSITIVE CHAR. SCAN FOR        80700019
*                                      NON-BLANK.                       80750019
         SPACE 2                                                        80800019
*SCAN FOR NON-DELIMITER                                                 80850019
SCNDEL   LA    R14,SCNDELSL        HAS ADDR OF OTHER PARAMETERS.        80900019
         ST    R14,SCPADDR         ADDR OF OTHER PARAMETERS TO LIST.    80950019
         ST    R1,SCSTART          SCAN-START-ADDR TO PARAMETER-LIST.   81000019
         LA    R1,SCSTART          HAS ADDR OF PARAMETERLIST.           81050019
         L     R15,IHKYYCCS        GET ADDR OF SCAN-ROUTINE.            81100019
         BALR  R14,R15             BRANCH TO SCAN-ROUTINE.              81150019
*                                                                       81200019
         B     BRNDEL(R15)                                              81250019
BRNDEL   BC    15,0(R2,R15)        GO BACK, NO NON-BLANK FOUND.         81300019
*                                  CONTINUE PROCESSING NON-BLANK FOUND. 81350019
         CLI   0(R1),COMMA         IS CHAR FOUND A COMMA?               81400019
         BC    7,0(R2,R15)           NO, GO BACK.                       81450019
*                                    YES, GO ON.                        81500019
         TM    TUBPPTFL,TUBCOMAN   COMMA FOUND PREVIOUSLY?              81550019
         BO    WARNING               YES, BRANCH.                       81600019
*                                    NO, GO ON.                         81650019
         OI    TUBPPTFL,TUBCOMAN   SET FLAG 'COMMA FOUND'.              81700019
LASTCHAR CL    R1,SCSTOP           IS IT LAST CHAR IN STRING?           81750019
         BCR   8,R2                  YES, GO BACK (NO NON-DELIMITER     81800019
*                                      FOUND).                          81850019
*                                    NO, GO ON.                         81900019
         LA    R1,ONE(R1)          R1 HAS NEW SCAN START ADDR.          81950019
         B     SCNDEL                                                   82000019
*                                                                       82050019
WARNING  OI    TUBPPTFL,TUBWARNN   SET FLAG 'WARNING MUST BE SENT'.     82100019
         B     LASTCHAR                                                 82150019
         EJECT                                                          82200019
*********************************************************************** 82250019
*                                                                     * 82300019
*              NON-ZERO-RETURN FROM LINE-ADMINISTRATOR                * 82350019
*                                                                     * 82400019
*********************************************************************** 82450019
         DS    0H                                                       82500019
RTNCD04  EQU   *                                                        82550019
         USING TUBDSECT,R4                                              82600019
         TM    TUBREQST,TUBIDENT   IS IT THE TUB?                       82650019
         BZ    RTNCD08               NO, BRANCH                  A34585 82700020
*                                    YES, GO ON.                        82750019
         L     R14,TUBCLBAD        GET CLB ADDRESS                      82800019
         USING CLBDSECT,R14        ESTABLISH ADDRESSABILITY             82850019
         TM    CLBREQST,CLBSTOPN   TEST FOR STOP OR MODIFY              82900019
         BO    LINER               IF YES, DON'T TEST BREAK FLAG        82950019
         TM    TUBFLG4,TUBSTOP     TEST FOR DEACTIVATE OF C.U.   A36810 82960020
         BO    LINER               YES, DONT TEST FOR BREAK      A36810 82970020
         DROP  R14                                                      83000019
         TM    TUBSTATS,TUBREAKN   BREAKFLAG SET?                       83050019
         BZ    LINER                 NO, BRANCH.                        83100019
*                                    YES, GO ON.                        83150019
         OI    TUBPPTFL,TUBRAKEN   BREAK OCCURED - SET FLAG.            83200019
         NI    TUBSTATS,TUBREAKF   TURN OFF TUB-BREAK-FLAG.             83250019
         B     FRMCMD02                                                 83300019
*                                                                       83350019
LINER    CLI   TUBUSRID,HEX00      IS USER LOGGED ON?                   83400019
         BE    DELPPTSL              NO, BRANCH.                        83450019
*                                    YES, GO ON.                        83500019
         CLC   ZERO,TUBPPTAD+ONE   PPT ALLOCATED?                       83550019
         BNE   CDTOPPT               YES, BRANCH.                       83600019
*                                    NO, GO ON.                         83650019
         L     R11,TUBUFFAD                                             83700019
         BAL   R2,ALCMNPPT         GO AND ALLOCATE MIN-LENGTH PPT.      83750019
CDTOPPT  MVI   PPTCMD,CMDERR       CODE FOR ERROR RECOVERY ROUTINE.     83800019
         B     BLDLNKAD                                                 83850019
*                                                                       83900019
DELPPTSL BAL   R2,DEALLC           GO AND DEALLOCATE PPT'S.             83950019
CLBBK    LA    R11,DYPPTERR        USE DUMMY PPT TO GO TO IHKERR.       84000019
         B     BLDLNKAD                                                 84050019
*                                                                       84100019
*********************************************************************** 84150019
*                                                                     * 84200019
*              ACTIVE AREA I/O ERROR                                  * 84250019
*                                                                     * 84300019
*********************************************************************** 84350019
RTNCD12  EQU   *                                                        84400019
         OI    TUBPPTFL,TUBAARRN   AA I/O-ERROR, SET FLAG.              84450019
         CLI   TUBUSRID,HEX00      IS USER LOGGED ON?                   84500019
         BE    DELPPTSL              NO, BRANCH.                        84550019
*                                    YES, GO ON.                        84600019
         CLC   ZERO,TUBPPTAD+ONE   IS PPT ALLOCATED?                    84650019
         BNE   CDTOPPT1              YES, BRANCH.                       84700019
*                                    NO, GO ON.                         84750019
         L     R11,TUBUFFAD                                             84800019
         BAL   R2,ALCMNPPT         GO AND ALLOCATE MIN-LENGTH PPT.      84850019
CDTOPPT1 MVI   PPTCMD,CMDERR       CODE FOR AA-ERR-RECOVERY-ROUTINE.    84900019
         B     BLDLNKAD                                                 84950019
         EJECT                                                          85050019
*********************************************************************** 85100019
*                                                                     * 85150019
*              CONSTANTS AND STORAGE                                  * 85200019
*                                                                     * 85250019
*********************************************************************** 85300019
DUMMYPPT DC    F'0',X'0',AL1(CMDED1DO),X'FF' DUMMY PPT TO GO TO         85350019
*                                    EXEC-PROCESSOR.                    85400019
DYPPTERR DC    F'0',X'0',AL1(CMDERR) DUMMY PPT TO GO TO IHKERR.         85450019
VCONAVT  DC    A(IHKAVT)                                                85500019
         EXTRN IHKAVT                                                   85550019
         DS    0F                                                       85600019
CLEANUP  DC    X'02F0F0F0'                                              85650019
         DS    0F                                                       85700019
MSG219   DC    H'31'                                                    85750019
         DC    H'0'                                                     85800019
         DC    C'IHK219I OUT OF MAIN STORAGE'                           85850019
         DS    0F                                                       86000019
MSG240   DC    X'00'                                                    86050019
         DC    C'240'                                                   86100019
MSG301   DC    X'02'                                                    86150019
         DC    C'301'                                                   86200019
MSG302   DC    X'02'                                                    86250019
         DC    C'302'                                                   86300019
MSG305   DC    X'02'                                                    86350019
         DC    C'305'                                                   86400019
MSG307   DC    X'02',C'307'        INVALID LINE NUMBER, CHANGE CMD      86420019
MSG308   DC    X'02'                                                    86450019
         DC    C'308'                                                   86500019
MSG309   DC    X'02'                                                    86550019
         DC    C'309'                                                   86600019
MSG311   DC    X'02'                                                    86650019
         DC    C'311'                                                   86700019
MSG313   DC    X'02'                                                    86750019
         DC    C'313'                                                   86800019
MSG314   DC    X'02'                                                    86850019
         DC    C'314'                                                   86900019
MSG315   DC    X'02'                                                    86950019
         DC    C'315'                                                   87000019
MSG319   DC    X'02'                                                    87050019
         DC    C'319'                                                   87100019
MSG334   DC    X'02'                                                    87150019
         DC    C'334'                                                   87200019
MSG372   DC    X'02'                                                    87250019
         DC    C'372'                                                   87300019
MSG379   DC    X'02'                                                    87350019
         DC    C'379'                                                   87400019
MSG380   DC    X'02'                                                    87450019
         DC    C'380'                                                   87500019
MSG391   DC    X'02'                                                    87550019
         DC    C'391'                                                   87600019
ZERO     DC    X'000000'                                                87700019
         DC    X'000000'                                                87750019
H1       DC    H'1'                                                     87900019
H2       DC    H'2'                                                     87950019
H3       DC    H'3'                                                     88000019
H4       DC    H'4'                                                     88050019
H10      DC    H'10'               MAX LINE NUMBER LENGTH        A34590 88070020
H16      DC    H'16'               RETURN CODE OF 16                    88100019
MXTXTLN  DC    H'40'                                                    88150019
H32      DC    H'32'               MINIMUM-LENGTH OF PPT.               88200019
MXPARLNG DC    H'56'               MAX PARAMETER-LENGTH.                88250019
ZERLNG   DC    H'0'                ZERO-LENGTH-RECORD.                  88300019
H8       DC    H'8'                                                     88350019
MSG300   DC    CL27'IHK300  OUT OF MAIN STORAGE'                        88450019
PROMPT   DC    X'6D16'             UNDERSCORE-BACKSPACE.                88500019
TXT1     DC    X'01F1'                                                  88550019
TXT2     DC    X'01F2'                                                  88600019
DELM     DC    X'01',C'-'                                               88650019
DOUBQT   DC    X'027D7D'           DOUBLE QUOTE.                        88700019
END      DC    CL3'END'                                                 88750019
         EJECT                                                          88800019
*********************************************************************** 88850019
*                                                                     * 88900019
*              INSTRUCTIONS REACHED BY 'EX'                           * 88950019
*                                                                     * 89000019
*********************************************************************** 89050019
MVCPPT   MVC   0(0,R8),0(R11)      MOVE CMD-BUFFER.                     89100019
MVPAR    MVC   ONE(0,R8),0(R3)     MOVE PARAMETER.                      89150019
OCSTRING OC    0(0,R3),OCFLD       CONVERT CHAR-STRING TO UPPER CASE.   89200019
CLC      CLC   ONE(0,R5),0(R3)                                          89250019
MVUBF    MVC   0(0,R1),ONE(R1)     MOVE REMAINDER OF USER BUFFER.       89300019
MVCCMDTO MVC   0(0,R8),0(R3)                                            89350019
MVCCMDFR MVC   0(0,R3),0(R8)                                            89400019
         SPACE 5                                                        89410020
OCFLD    DC    54X'40'             USED FOR CONVERSION TO UPPER CASE    89420020
         EJECT                                                          89450019
*********************************************************************** 89500019
*                                                                     * 89550019
*              EQUATES                                                * 89600019
*                                                                     * 89650019
*********************************************************************** 89700019
R0       EQU   0                                                        89750019
R1       EQU   1                                                        89800019
R2       EQU   2                                                        89850019
R3       EQU   3                                                        89900019
R4       EQU   4                                                        89950019
R5       EQU   5                                                        90000019
R6       EQU   6                                                        90050019
R7       EQU   7                                                        90100019
R8       EQU   8                                                        90150019
R9       EQU   9                                                        90200019
R10      EQU   10                                                       90250019
R11      EQU   11                                                       90300019
R12      EQU   12                                                       90350019
R13      EQU   13                                                       90400019
R14      EQU   14                                                       90450019
R15      EQU   15                                                       90500019
QTEBALN  EQU   X'20'               QUOTE FOUND - ON.                    90550019
CMDEF    EQU   X'EF'               ENDOF COMMAND OFF.                   90600019
L6       EQU   6                                                        90650019
L10      EQU   10                                                       90700019
L11      EQU   11                                                       90750019
LNGSA    EQU   72                  LENGTH OF SAVE-AREA.                 90800019
LX1      EQU   X'01'                                                    90850019
LX10     EQU   X'0A'                                                    90900019
X10      EQU   X'0A'                                                    90950019
SCT22    EQU   22                                                       91000019
SCT24    EQU   24                                                       91050019
SCT25    EQU   25                                                       91100019
RQLOD    EQU   5                                                        91150019
RQDEL    EQU   4                                                        91200019
NRES     EQU   X'80'               NON-RESIDENT ROUTINE.                91250019
CLNRES   EQU   X'7F'               CLEAR NON-RESIDENT FLAG.             91300019
D8       EQU   8                                                        91350019
L8       EQU   8                                                        91400019
SVR8R9   EQU   52                  OFFSET IN SAVE-AREA.                 91450019
PARFLG   EQU   X'40'               PARAMETER WAS IN PARENTHESES.        91500019
PARFLGLS EQU   X'80'               LAST PARAMETER IN PARENTHESES.       91550019
VAL2     EQU   2                                                        91600019
FF       EQU   X'FF'                                                    91650019
CLPTCT   EQU   X'F8'               CLEAR PARAMETER-COUNT IN PPTFLG.     91700019
FOUR     EQU   4                                                        91750019
BLANK    EQU   C' '                                                     91800019
COMMA    EQU   C','                                                     91850019
CH29     EQU   29                                                       91900019
QTE      EQU   X'7D'                                                    91950019
CMDE     EQU   X'10'                                                    92000019
ONE      EQU   1                                                        92050019
RGTHPAR  EQU   C')'                                                     92100019
LEFTPAR  EQU   C'('                                                     92150019
MSKF0    EQU   X'F0'                                                    92200019
MSK08    EQU   X'08'                                                    92250019
MSK06    EQU   X'06'                                                    92300019
NINE     EQU   9                                                        92350019
TWO      EQU   2                                                        92400019
DASH     EQU   C'-'                                                     92450019
XZERO    EQU   X'00'                                                    92500019
TRW      EQU   12                                                       92550019
DBW      EQU   8                                                        92600019
ENDLIST  EQU   X'80'                                                    92650019
D16      EQU   16                                                       92700019
ENDUBF   EQU   88                                                       92750019
HEX00    EQU   X'00'                                                    92800019
OFSR4    EQU   36                                                       92850019
C120     EQU   120                                                      92900019
D12      EQU   12                                                       92950019
CLRPOST  EQU   X'00'                    CLEAR ECB POST BIT              93000019
CLRMCS   EQU   X'00'              CLEAR OUT MCS CODE FROM CLB           93050019
POST     EQU   X'40'               ECB POST CODE                 A36810 93060020
LM300N   EQU   19                  MSG 300 W/O ID LENGTH         A36805 93070020
*********************************************************************** 93100019
*              CODES FOR COMMAND PROCESSORS                           * 93150019
*********************************************************************** 93200019
USRCD    EQU   X'00'               CODE FOR USER-SUPPLIED COMMANDS.     93250019
         CMDEQU                                                         93300019
         SPACE 5                                                        93350019
         IHKCDSCT CCT=YES,CLB=YES,TUB=YES,AVT=YES,PPT=YES,DIR=YES       93400019
         END                                                            93450019
