DEQ      TITLE 'IHKDEQ - DEQUEUE - JOB END PROCESSOR'                   00200019
IHKDEQ   CSECT                                                          00400019
*A264000,324000,338000,516000,626000,744000                      A36803 00440020
*C208000,320000,482000,486000,494000,498000-502000,506000-510000 A36803 00480020
*C522000,812000                                                  A36803 00520020
*D264000                                                         A36803 00560020
*A656000,676000,686000,708000                                    A36810 00568020
*C012000,152000-154000,208000,314000                             A36810 00576020
*A319000,480000,840000                                           A39400 00584020
*C102000,208000-212000                                           A39400 00592020
*********************************************************************** 00600019
*                                                                     * 00800019
*STATUS-                                                              * 01000019
*   CHANGE LEVEL 1                                               A36810 01200020
*                                                                     * 01400019
*FUNCTION/OPERATION:                                                  * 01600019
*   IHKDEQ PROVIDES CRJE WITH A MEANS OF RECOGNIZING WHEN CRJE JOBS   * 01800019
*   (ENTERED VIA THE SUBMIT COMMANE) COMPLETE AND NOTIFYING THE CRJE  * 02000019
*   USER THAT HIS JOB HAS COMPLETED.                                  * 02200019
*   AT ENTRY IHKDEQ SETS A FLAG, BIT 9 OF CCTOPT IN THE CCT, TO       * 02400019
*   INDICATE THAT IT IS PROCESSING JOB OUTPUT. THIS IS DONE SO THAT   * 02600019
*   THE CRJE STOP MODULE (IHKSTP) WILL KNOW WHETHER JOB TERMINATION IS* 02800019
*   BEING PROCESSED (IHKDEQ WILL RECOGNISE STOP, BUT IF IHKSDQ IS     * 03000019
*   WAITING FOR WORK, IHKSTP MUST FORCE AN ENTRY INTO IT TO BRING IT  * 03200019
*   OUT OF THE WAIT).                                                 * 03400019
*   AFTER SETTING THE FLAG, IHKDEQ CHECKS FOR STOP CRJE PENDING, IF   * 03600019
*   PENDING IHKDEQ RETURNS TO IHKSDQ. IF NOT PENDING IHKDEQ BRANCHES  * 03800019
*   TO THE O S QUEUE MANAGER DEQUEUE ROUTINE (IEFQMDQ2) TO LOOK FOR   * 04000019
*   WORK. IF THERE ARE NO JOBS ON THE QUEUE, DEQ RETURNS TO IHKSDQ. IF* 04200019
*   IEFQMDQ2 ENCOUNTERED AN I/O ERROR, THE ABNORMAL STOP BIT IS SET   * 04400019
*   AND CONTROL IS RETURNED TO IHKSDQ. IF A JOB IS FOUND, THE         * 04600019
*   FOLLOWING PROCESSING IS PERFORMED:                                * 04800019
*                                                                     * 05000019
*   A. CALL IHKRJC TO SEARCH FOR THE RJCT HAVING JOB NAME OF JOB      * 05200019
*      DEQUEUED. IF THE ENTRY IS FOUND GO TO C. IF NOT FOUND, THE NAME* 05400019
*      IS CHECKED FOR 'JOBFAIL). IF THAT IS NOT THE NAME IHKDT2 IS    * 05600019
*      CALLED TO DELETE THE JOB AND THEN BRANCH AGAIN TO IEFQMDQ2.    * 05800019
*                                                                     * 06000019
*   B. IF THE NAME IS 'JOBFAIL', THE DDNAME IN THE DSB IS CHECKED FOR * 06200019
*      '@' AS THE FIRST CHARACTER. IF IT IS, THE RJCT IS SEARCHED FOR * 06400019
*      AN ENTRY HAVING THAT DDNAME. IF THE ENTRY IS FOUND, A NOTIFY   * 06600019
*      MESSAGE IS SENT, THE JOB IS DELETED (IHKDT2), AND IEFQMDQ2 IS  * 06800019
*      CALLED TO DEQUEUE THE NEXT JOB. IF THE ENTRY IS NOT FOUND,     * 07000019
*      IHKDEQ CHECKS FOR ANY MORE DSB'S. IF NONE, THE ENTRY IS DELETED* 07200019
*      (IHKDTZ) AND IEFQMDQZ IS CALLED. IF NOT THE LAST DSB, IEFQMSSS * 07400019
*      IS CALLED TO READ THE NEXT DSB AND PROCESSING IS RESUMED AT B. * 07600019
*                                                                     * 07800019
*   C. IF THE RJCT ENTRY WAS FOUND FOR THE JOB, IHKDEQ DETERMINES     * 08000019
*      WHETHER THE SMB/DSR READ BY IEFQMDQ2 IS A DSB. IF IT IS NOT GO * 08200019
*      TO D. IF IT IS THE DDNAME IN THE DSB IS COMPARED TO THE DDNAME * 08400019
*      IN THE RJCT ENTRY. IF THEY ARE NOT EQUAL GO TO D. IF THEY ARE  * 08600019
*      EQUAL, THEN THE USER SPECIFIED THAT NO OUTPUT WAS TO RETURN ON * 08800019
*      THE CRJE SYSOUT CLASS. A NOTIFY MESSAGE IS SENT, THE ENTRY IS  * 09000019
*      DELETED AND IEFQMDQ2 IS CALLED AGAIN.                          * 09200019
*                                                                     * 09400019
*   D. IS THE JOB ALREADY MARKED COMPLETE? IF YES, CALL IHKDT2 AND GO * 09600019
*      TO IEFQMDQ2. IF THE JOB WAS NOT MARKED COMPLETE, MARK IT       * 09800019
*      COMPLETE, SEND THE NOTIFY MESSAGE, WRITE THE RJCT ENTRY TO THE * 10000019
*      ACTIVE AREA, CALL IHKSRV TO FREE UP THE IOB, AND GO TO    A39400 10100020
*      IEFQMDQ2.                                                 A39400 10200020
*                                                                     * 10400019
*ENTRY POINTS-                                                        * 10600019
*        IHKDEQ IS THE ONLY ENTRY POINT. AT ENTRY REGISTER ONE WILL   * 10800019
*   CONTAIN THE ADDRESS OF THE CRJE ADDRESS VECTOR TABLE (IHKAVT).    * 11000019
*                                                                     * 11200019
*INPUT-                                                               * 11400019
*   AS DESCRIBED IN ENTRY POINTS.                                     * 11600019
*                                                                     * 11800019
*OUTPUT-                                                              * 12000019
*   THE JOB IS DEQUEUED FROM THE O S OUTPUT QUEUE AND THE RJCT ENTRY  * 12200019
*   IS UPDATED IN THE ACTIVE AREA.                                    * 12400019
*                                                                     * 12600019
*EXTERNAL ROUTINES-                                                   * 12800019
*        IEFQMDQ2- O. S. QUEUE MANAGER DEQUEUE                        * 13000019
*        IEFQMSSS- O. S. QUEUE MANAGER READ                           * 13200019
*        IHKRJC  - RJCT MANAGER                                       * 13400019
*        IHKRER02- DELETE O. S. QUEUE ENTRY AND RJCT ENTRY            * 13600019
*        IHKDSP  - CRJE DISPATCHER FOR DUMMY WAIT                     * 13800019
*        IHKMSG  - CRJE MESSAGE WRITER                                * 14000019
*                                                                     * 14200019
*EXITS-NORMAL-                                                        * 14400019
*   RETURN TO IHKSDQ.                                                 * 14600019
*                                                                     * 14800019
*EXITS-ERROR-                                                         * 15000019
*   IF IHKAFI ENCOUNTERED AN ERROR, RETURN IS MADE TO IHKSDQ WITHA36810 15100020
*   ABNORMAL AND STOP PENDING BITS SET IN THE CRJE CCT.  IF      A36810 15200020
*   IHKDEQ CANNOT PERFORM ITS FUNCTION BECAUSE OF AN ABEND OF    A36810 15300020
*   THE LOADER/CONTROLLER OR SERVICE TASK CONTROL IS RETURNED TO A36810 15400020
*   IHKSDQ TO AWAIT CLOSEDOWN.                                   A36810 15500020
*                                                                     * 15600019
*TABLES/WORK AREAS-                                                   * 15800019
*   AN 18 WORD SAVE AREA IS PROVIDED, AN 80 BYTE RJCT BUFFER, A 176   * 16000019
*   BYTE SMB/DSB BUFFER, AND A 44 BYTE QMPA AND QMPE BUFFER AREA ARE  * 16200019
*   USED.                                                             * 16400019
*                                                                     * 16600019
*ATTRIBUTES-                                                          * 16800019
*   SERIALLY REUSABLE AND NON-RESIDENT                                * 17000019
*                                                                     * 17200019
*********************************************************************** 17400019
ZIP      EQU   0                                                        17600019
PAR      EQU   1                                                        17800019
MSG      EQU   2                                                        18000019
TUB      EQU   3                                                        18200019
RET      EQU   4                                                        18400019
WOK      EQU   5                                                        18600019
ZAP      EQU   6                                                        18800019
CCT      EQU   7                                                        19000019
AVT      EQU   8                                                        19200019
SECB     EQU   9                                                        19400019
QMPA     EQU   10                                                       19600019
RJCT     EQU   11                                                       19800019
BAS      EQU   12                                                       20000019
SAV      EQU   13                                                       20200019
BAC      EQU   14                                                       20400019
GO       EQU   15                                                       20600019
         SAVE  (14,12),,DEQ71085   SAVE CALLER'S REGISTERS       A36810 20800020
         LR    BAS,GO              ESTABLISH ADDRESSIBILITY      A39400 21000020
         USING IHKDEQ,BAS                                        A39400 21200020
         LA    WOK,SAVE            ADDRESS OF SAVE AREA                 21400019
         ST    SAV,4(WOK)          CHAIN SAVE AREAS                     21600019
         ST    WOK,8(SAV)                                               21800019
         LR    SAV,WOK                                                  22000019
         SPACE 3                                                        22200019
         LR    AVT,PAR             GET ADDRESS OF AVT                   22400019
         LA    RJCT,RJCTM                                               22600019
         LA    QMPA,QMPAM                                               22800019
         USING RJCTSECT,RJCT                                            23000019
         USING IOPARAMS,QMPA                                            23200019
         USING AVTDSECT,AVT                                             23400019
         USING CCTDSECT,CCT                                             23600019
         ST    AVT,SRCHAVT         SAVE ADDRESS OF AVT                  23800019
         L     CCT,IHKYYCCT        ADDRESS OF SYSTEM TABLE              24000019
         LA    TUB,DUMTUB          ADDRESS OF DUMMY TUB                 24200019
         USING TUBDSECT,TUB                                             24400019
         L     SECB,IHKYYDQE       ADDRESS OF QMGR ECB                  24600019
         OI    CCTOPT+1,DEQIP      INDICATE DEQUEUER PROCESSING         24800019
         SPACE 3                                                        25000019
DEQ01    MVI   QMPOP,QMDTOP        FUNCTION CODE FOR DEQUEUE            25200019
         TM    CCTOPT,STOPC        IS STOP PENDING                      25400019
         BO    RETURN              YES RETURN FOR CLOSEDOWN             25600019
         XC    0(8,SECB),0(SECB)   ZERO ECB                             25800019
         ST    SECB,QMCAN          STORE ECB ADDRESS IN QMPA            26000019
         MVC   QMTPY(ONE),CCTSYSCI FILL IN SYSOUT CLASS                 26200019
         MVI   QMPNC,ZIP           CLEAR RECORD COUNT            A36803 26400020
         MVI   SRVCODE,QMDQ2       SET CODE TO DEQUEUE                  26600019
         BAL   RET,SRVGO           CALLIHKSRV TO DEQUEUE                26800019
         SPACE                                                          27000019
*                        CHECK RETURN FROM DEQUEUE                      27200019
         B     *+4(GO)                                                  27400019
         B     DEQGOT              PROCESS TERMINATED JOB               27600019
         B     RETURN              WAIT FOR WORK IN DISPATCHER          27800019
B        B     B                   NO SUCH RETURN CODE                  28000019
         SPACE                                                          28200019
*                        I/O ERROR FROM Q MGR                           28400019
KMASYOYO BAL   RET,SENDCTRL        SEND DISK ERROR MESSAGE              28600019
RETURN   L     SAV,4(SAV)          RESTORE SAVE AREA POINTER            28800019
         TM    CCTOPT+1,CCTSRTUP   ENTRY FROM START UP                  29000019
         BZ    ENDIT               NO RETURN TO IHKSDQ                  29200019
         MVC   IHKYYSC1(4),IHKYYSCB INCLUDE LINE STCBS INDISP LIST      29400019
         L     WOK,IHKYYSC3        ADDRESS OF CENTRAL COMMANDS STCB     29600019
         L     GO,4(WOK)           ECB LIST ENTRY FOR CENTRAL CMDS.     29800019
         MVI   0(GO),ZIP           INDICATE NO LONGER END OF ECB LIST   30000019
         L     WOK,IHKYDSP1        ADDRESS OF CURRENT PRIORITY FOR      30200019
*                                  STCB IN DISPATCHER                   30400019
         LA    GO,FOR              PRIORITY OF JOB TERMINATION          30600019
         ST    GO,ZIP(WOK)         INSURE PROPER PRIORITY AFTER START   30800019
ENDIT    NI    CCTOPT+1,DEQNP      INDICATE SYS DEQUEUER NOT IN PROCESS 31000019
*                                  AND START UP COMPLETE                31200019
         RETURN (14,12)            RETURN TO IHKSDQ              A36810 31400020
         SPACE 3                                                        31600019
*                        PROCESS DEQUEUED ENTRY FROM Q MANAGER          31800019
DEQGOT   EQU   *                                                 A36803 31900020
         MVI   SRVCODE,FREEIOB     CALL SRV TO FREE THE IOB      A39400 31930020
         BAL   RET,SRVGO                                         A39400 31960020
         MVC   SAVTTR(4),RECORDM   SAVE TTR OF FIRST RECORD      A36803 32000020
         MVI   JFSWT,ZIP           CLEAR FIRST PASS SWITCH              32200019
DEQGOT01 MVI   TUBGBLNM,RJCTAB     SET GLOBAL FILE TO RJCT              32400019
         MVC   TUBGBLKY(8),QMNAM   GET JOBNAME FROM Q MANAGER    A36803 32500020
         LA    PAR,RJCTM-8                                              32600019
         ST    PAR,TUBRAFBF        SET BUFFER ADDRESS                   32800019
         OI    TUBAFISW,TUBFCTLN   INDICATE BUFFER CONTROL              33000019
         LA    PAR,TUBAD           PARM LIST FOR IHKAFI                 33200019
         RPOINT B,R,FTYPE=XGBL                                          33400019
         SPACE                                                          33600019
         MVC   RJCTQMPA(48),QMPAM  MOVE QMPA TO RJCT BUFFER             33800019
         MVC   RJCTTTR0(4),SAVTTR  SET FIRST TTR POINTER IN RJCT A36803 33900020
         MVC   RJCTQMPE+4(3),RJCTTTR0 MOVE TTR                          34000019
         CH    GO,FOUR             TEST RETURN FROM IHKAFI              34200019
         BH    AFIERR              I/O ERROR                            34400019
         BE    DEQDLT              CHECK FOR NAME OF JOBFAIL            34600019
         TM    RJCTFLGS,DELJOB     IS JOB TO BE DELETED                 34800019
         BO    DEQDELT1            YES    DO IT                         35000019
         TM    RJCTFLGS,COMP       JOB ALREADY COMPLETE                 35200019
         BO    DEQDELT             YES DELETE THIS JOB                  35400019
         OI    RJCTFLGS,COMP       MARK JOB COMPLETE                    35600019
         TM    RJCTFLGS,STOP       NOTIFY ALREADY SENT                  35800019
         BO    DEQGOT02            YES SKIP NOTIFY MESSAGE              36000019
         OI    RJCTFLGS,STOP       TURN NOTIFY SENT                     36200019
         BAL   RET,WRITNOT         SEND NOTIFY                          36400019
         LTR   GO,GO               WRITE GO O  K                        36600019
         BZ    DEQ01               LOOK FOR NEXT JOB                    36800019
         SPACE 2                                                        37000019
         MVI   TUBGBLNM,RJCTAB     SET RJCT FILE NUMBER                 37200019
         MVC   TUBGBLKY(8),QMNAM   JOBNAME FOR KEY                      37400019
         OI    TUBAFISW,TUBFCTLN   INDICATE BUFFER CONTROL              37600019
         LA    PAR,RJCTM-8         ADDRESS OF BUFFER                    37800019
         ST    PAR,TUBRAFBF        PUT IN TUB                           38000019
         LA    PAR,TUBAD           ADDRESS OF TUB POINTER               38200019
         RPOINT B,R,FTYPE=XGBL                                          38400019
         LTR   GO,GO               GOOD RETURN FROM IHKAFI              38600019
         BNZ   AFIERR              I/O ERROR ON FILE                    38800019
         NI    RJCTFLGS,ALL-STOP   TURN OFF NOTIFY SENT BIT             39000019
DEQGOT02 REPLACE NXK,B,FTYPE=XGBL                                       39200019
         LTR   GO,GO               GOOD RETURN FROM IHKAFI              39400019
         BNZ   AFIERR              ERROR ABORT CRJE                     39600019
         ENDUP FTYPE=GBL                                                39800019
         B     DEQ01               GET NEXT JOB                         40000019
         SPACE 2                                                        40200019
AFIERR   LA    PAR,TUBAD           ADDRESS OF TUB POINTER               40400019
         ENDUP FTYPE=GBL           GET OFF GLOBAL QUEUE                 40600019
         OI    CCTOPT1,CCTCLS+CCTATERM SET STOP FLAGS                   40800019
         LA    WOK,BADEND          POST CODE FOR STOP                   41000019
         SLL   WOK,24              SHIFT TO HIGH ORDER BYTE             41200019
         L     RET,IHKYYSC3        ADDRESS OF CENTRAL COMMANDS STCB     41400019
         L     PAR,4(RET)          ADDRESS OF ECB                       41600019
         O     WOK,0(PAR)          OR STOP BIT INTO ECB                 41800019
         LR    ZIP,WOK             PLACE ECB POST CODE INTO REGISTER 0  42000019
         LA    PAR,0(PAR)          ZERO HIGH ORDER BYTE                 42100021
         SPACE                                                          42200019
         POST  (1),(0)             POST STOP                            42400019
         SPACE                                                          42600019
         LA    WOK,ACTERR          ADDRESS OF ERROR MESSAGE             42800019
         ST    WOK,MSGDEST+4       PLACE IN PARM LIST                   43000019
         LA    PAR,MSGPARM         ADDRESS OF PARM LIST                 43200019
         L     GO,IHKYMSG2         ADDRESS OF MESSAGE WRITER            43400019
         BALR  BAC,GO              SEND MESSAGE TO CENTRAL OPERATOR     43600019
         B     RETURN              RETURN TO IHKSDQ TO WAIT FOR CLOSE   43800019
         SPACE 3                                                        44000019
DEQDELT1 LA    PAR,TUBAD           PARM LIST FOR IHKAFI                 44200019
         RDELETE NXK,A,FTYPE=XGBL                                       44400019
         LTR   GO,GO               GOOD RETURN                          44600019
         BNZ   AFIERR              NO INDICATE ERROR                    44800019
         LH    GO,CCTJOBS          COUNT OF JOBS IN SYSTEM              45000019
         LA    GO,ONE(GO)          BUMP COUNT BY ONE                    45200019
         STH   GO,CCTJOBS          UPDATE COUNT OF JOBS                 45400019
         ENDUP FTYPE=GBL                                                45600019
DELT     MVC   MSGM(3),MDLT        JOB DELETED MESSAGE                  45800019
         MVI   MRVP,8              SET LENGTH OF PARMS ON MESSAGE       46000019
         MVC   MPARM(8),QMNAM      MOVE JOB NAME TO MESSAGE             46200019
         BAL   RET,SENDR           SEND DELETED MESSAGE TO USER         46400019
         B     DEQDELT2            DELETE JOB FROM O. S.                46600019
         SPACE 2                                                        46800019
DEQDLT   CLC   QMNAM(8),JOBFAIL    JOBNAME JOBFAIL                      47000019
         BNE   DEQDELT             NO DELETE JOB                        47200019
         TS    JFSWT               FIRST PASS THRU HERE                 47400019
         BNZ   DEQDELT             NO DELETE JOB                        47600019
         CLC   RJCTTTR0(3),ZERO    DSB/SMB PRESENT                      47800019
         BE    DEQDELT             NO DELET JOB                         48000019
         MVI   SRVCODE,GETIOB      SRV CODE TO GET AN IOB        A39400 48030020
         BAL    RET,SRVGO                                        A39400 48060020
NEXTSMB  LA    BAC,RECORDM+ID      ADDRESS OF SMB ID             A36803 48100020
         LA    GO,SMBEND           END OF SMB                    A36803 48200020
MORESMB  LR    MSG,BAC             GET ADDRESS OF MESSAGE        A36803 48300020
         TM    0(MSG),DSB          IS RECORD A SMB                      48400019
         BC    9,QREAD             READ NEXT DSB/SMB             A36803 48460020
         CR    MSG,GO              END OF SMB                    A36803 48520020
         BNL   QREAD               YES- JOBNAME NOT FOUND        A36803 48580020
         SR    PAR,PAR             CLEAR FOR INSERTS             A36803 48640020
         IC    PAR,1(MSG)          GET LENGTH                    A36803 48700020
         CLI   0(MSG),SMBC         IS SMB CONDENSED                     48800019
         BNE   SMBNC               NO PROCESS NON-CONDENSED SMB         49000019
         SPACE                                                          49200019
         AR    BAC,PAR             ADDRESS OF NEXT MESSAGE       A36803 49400020
         IC    PAR,2(MSG)          GET LENGTH OF FIRST OPERND IN SMB    49600019
         LTR   PAR,PAR             FIRST FIELD BLANKS            A36803 49700020
         BE    MORESMB             YES SKIP TO NEXT MESSAGE      A36803 49800020
         LA    MSG,2(MSG)          ADDRESS OF MSG TEXT           A36803 49900020
         B     SMBNAME             GET JOBNAME                   A36803 50000020
         SPACE                                                          50400019
SMBNC    IC    PAR,0(MSG)          LENGTH OF MESSAGE             A36803 50500020
         LA    BAC,1(BAC,PAR)      ADDRESS OF NEXT MESSAGE       A36803 50600020
         LA    PAR,2               INDEX FOR COMPARE             A36803 50700020
SMBNC1   LA    PAR,1(PAR)          BUMP OFFSET IN TEXT           A36803 50800020
         LA    WOK,0(PAR,MSG)      BUMP TO NEXT BYTE             A36803 50900020
         CLI   0(WOK),BLANK        CHECK FOR BLANK                      51200019
         BNE   SMBNC1              CHECK NEXT BYTE                      51400019
         SPACE                                                          51600019
SMBNAME  CLC   SLASH(2),1(MSG)     CHECK FOR //                  A36803 51650020
         BNE   MORESMB             NO, CHECK NEXT MSG IN SMB     A36803 51700020
         LA    WOK,1(PAR,MSG)      ADDRESS OF NEXT OPERAND       A36803 51750020
SMBMOVE  MVI   0(WOK),BLANK        CLEAR TO BLANKS AFTER NAME           51800019
         MVC   1(7,WOK),0(WOK)                                          52000019
         MVC   QMPAM(8),3(MSG)     MOVE NAME FOR SEARCH OF RJCT  A36803 52200020
         B     DEQGOT01                                                 52400019
         SPACE 2                                                        52600019
DEQDELT  OI    RJCTFLGS,COMP       FLAG JOB COMPLETE FOR DT2            52800019
         LA    PAR,TUBAD                                                53000019
         ENDUP FTYPE=GBL                                                53200019
         SPACE                                                          53400019
         MVC   MSGM(3),MCDLT       CODE FOR JOB DELETED MESSAGE         53600019
         LA    MSG,CENDLT          ADDRESS OF JOBNAME PARMS             53800019
         ST    MSG,MSGVP           STORE ADDRESS IN PARM LIST           54000019
         LA    MSG,ZERO            SET FOR DESTINATION CENTRAL          54200019
         BAL   RET,SNDCTRL         SEND MESSAGE                         54400019
         SPACE 2                                                        54600019
DEQDELT2 EQU   *                                                        54800019
         LA    ZAP,CMDRER01        LOAD CODE FOR IHKRER01               55000019
         BAL   RET,LDCGO           LOAD   IHKRER01                      55200019
         SPACE                                                          55400019
         L     GO,0(PAR)           ADDRESS OF IHKRER01                  55600019
         LA    PAR,SRCHBUF         ADDRESS OF PARM LIST                 55800019
         SPACE                                                          56000019
         BALR  BAC,GO              DELETE JOB                           56200019
         SPACE                                                          56400019
         SLL   ZAP,ATE             SHIFT LOAD CODE TO DELETE            56600019
         BAL   RET,LDCGO           DELETE IHKRER01                      56800019
         SPACE                                                          57000019
         B     DEQ01                                                    57200019
         SPACE 3                                                        57400019
*                   SEND NOTIFY MESSAGE                                 57600019
WRITNOT  MVI   MRVP,19             SET LENGTH TO 19                     57800019
         TM    QMSTA,BUM           DID JOB END NORMALLY                 58000019
         BZ    NORMEN              YES                                  58200019
         OI    RJCTFLGS,BADEND     NO MARK ABNORMAL END IN RJCT         58400019
         MVC   MPARM(10),ABNM      MOVE ABNM TO MSG                     58600019
         B     MJOBNM                                                   58800019
NORMEN   MVC   MPARM(10),NORM      MOVE NORM INTO MSG                   59000019
MJOBNM   MVC   MNAME(8),RJCTJOB     MOVE JOBNAME INTO MSG               59200019
         MVI   MPARM+10,COMP       INSERT BLANK BEFORE JOB NAME         59400019
         LA    PAR,TUBAD           ADDRESS OF TUB POINTER               59600019
         REPLACE NXK,B,FTYPE=XGBL                                       59800019
         LTR   GO,GO               GOOD RETURN FROM IHKAFI              60000019
         BNZ   AFIERR              I/O ERROR ON FILE                    60200019
         MVC   MSGM(3),MNOT        RESET MESSAGE TO NOTIFY              60400019
SENDR    LA    MSG,MRVP                                                 60600019
         ENDUP FTYPE=GBL                                                60800019
         ST    MSG,MSGVP           SET VARIABLE PARMS                   61000019
         MVI   MSGVP,X'80'                                              61200019
         LA    MSG,RJCTUSER        USERS ID                             61400019
         ST    MSG,MSGDEST         SET USER AS RECIPIENT OF MESSAGE     61600019
         LA    PAR,MSGPARM         ADDRESS OF PARM LIST                 61800019
         L     GO,IHKYMSG1         MESSAGE WRITER ENTRY POINT           62000019
         BALR  BAC,GO              SEND MESSAGE                         62200019
         BR    RET                 RETURN TO CALLER                     62400019
         SPACE 5                                                        62600019
QREAD    MVI   QMPOP,QMREAD        SET OPERATION TO READ         A36803 62610020
         MVI   SRVCODE,QMSSS       REQUEST IEFQMSSS FORM IHKSRV  A36803 62620020
         MVC   QMPEX(4),RECORDM+4  GET TTR FOR READ              A36803 62630020
         MVI   QMPNC,ONE           SET RECORD COUNT              A36803 62640020
         SPACE 1                                                 A36803 62650020
         BAL   RET,SRVGO           EXIT TO IHKSRV TO READ SMB    A36803 62660020
         SPACE 1                                                 A36803 62670020
         CH    GO,FOUR             CHECK RETURN CODE             A36803 62680020
         BL    NEXTSMB             PROCESS SMB                   A36803 62690020
         BE    DEQDELT             END OF SMBS- DELETE JOB       A36803 62700020
         SPACE 1                                                 A36803 62710020
         LA    PAR,TUBAD           ENDUP BEFORE SENDING I/O      A36803 62720020
         ENDUP FTYPE=GBL           ERROR MESSAGE                 A36803 62730020
         B     KMASYOYO            SEND ERROR MSG AND EXIT       A36803 62740020
         SPACE 3                                                 A36803 62750020
SENDCTRL MVC   MSGM(3),MDISK       SET OFFSET TO DISK ERROR             62800019
         LA    MSG,ZERO            SET DESTINATION TO CENTRAL           63000019
         ST    MSG,MSGVP           PUT IN PARM LIST                     63200019
SNDCTRL  MVI   MSGVP,X'80'         SET LAST PARM IN LIST                63400019
         ST    MSG,MSGDEST                                              63600019
         LA    PAR,MSGPARM         ADDRESS OF PARM LIST                 63800019
         L     GO,IHKYYMSG         ADDRESS OF MESSAGE WRITER            64000019
         BALR  BAC,GO              SEND MESSAGE                         64200019
         BR    RET                 RETURN TO MAIN BODY OF CODE          64400019
         SPACE 2                                                        64600019
*              SET UP PARMS AND GO TO LOADER/CONTROLLER FOR LOAD OR     64800019
*              DELETE OF IHKRER01                                       65000019
         SPACE                                                          65200019
LDCGO    STH   ZAP,LDCCODE         SET CODE OF LOAD OR DELETE           65400019
         MVI   LDCECB,ZIP          CLEAR WAIT BIT OF ECB                65600019
         TM    IHKYYLCE,COMP       IHKLDC TERMINATED             A36810 65660020
         BO    RETURN              YES EXIT                      A36810 65720020
         LA    ZIP,LDCPARM         PARM LIST FOR POST CODE              65800019
         LA    PAR,CCTJLECB        ECB TO BE POSTED                     66000019
         SPACE                                                          66200019
         POST  (1),(0)                                                  66400019
         SPACE                                                          66600019
         LA    PAR,LDCPARM         ADDRESS OF COMPLETION ECB FOR WAIT   66800019
         L     GO,IHKYYDSP         ADDRESS OF DISPATCHER                67000019
         SPACE                                                          67200019
         BALR  BAC,GO              TAKE DUMMY PASS THROUGH DISPATCHER   67400019
         SPACE                                                          67600019
         TM    3(PAR),ONE          L/C TERMINATE WHILE WAITING   A36810 67660020
         BO    RETURN              YES EXIT                      A36810 67720020
         BR    RET                 RETURN TO MAIN BODY OF CODE          67800019
         SPACE 3                                                        68000019
*              INTERFACE TO IHKSRV FOR DEQUEUE AND READS BY O S QMGR    68200019
         SPACE                                                          68400019
SRVGO    MVI   SRVECB,ZIP          CLEAR POST AND WAIT BITS OF ECB      68600019
         TM    IHKYYSRE,COMP       SERVICE TASK TERMINATED       A36810 68660020
         BO    RETURN              YES EXIT                      A36810 68720020
         LA    ZIP,SRVECBAD        PARM LIST FOR POST CODE              68800019
         LA    PAR,CCTJSECB        IHKSRV ECB TO POST                   69000019
         SPACE                                                          69200019
         POST (1),(0)                                                   69400019
         SPACE                                                          69600019
         LA    PAR,SRVECB          ECB POSTED WHEN REQUEST COMPLETE     69800019
         L     GO,IHKYYDSP         ADDRESS OF CRJE DISPATCHER           70000019
         SPACE                                                          70200019
         BALR  BAC,GO              WAIT FOR DQUEUE OR READ              70400019
         SPACE                                                          70600019
         L     GO,0(PAR)           GET RETURN CODE                      70800019
         TM    3(PAR),ONE          SERVICE TASK TERMINATE        A36810 70860020
         BO    RETURN              YES EXIT                      A36810 70920020
         LA    GO,0(GO)            CLEAR HIGH ORDER BYTE                71000019
         BR    RET                 RETURN TO MAIN CODE                  71200019
         SPACE 3                                                        71400019
SAVE     DC    18F'0'                                                   71600019
BLANK    EQU   C' '                                                     71800019
ALL      EQU   X'FF'                                                    72000019
FOR      EQU   4                                                        72200019
STOPC    EQU   8                                                        72400019
DEQIP    EQU   X'40'                                                    72600019
DEQNP    EQU   X'3F'                                                    72800019
MCDLT    DC    C'272'                                                   73000019
CENDLT   DC    X'8'                                                     73200019
QMPAM    DC    8F'0'                                                    73400019
         DC    A(QMPAEM)                                                73600019
QMPAEM   DC    A(RECORDM)                                               73800019
         DC    F'0'                                                     74000019
RECORDM  DC    XL176'0'                                                 74200019
DUMBUF   EQU   RECORDM+40                                               74400019
SMBEND   EQU   RECORDM+176                                       A36803 74460020
QMSSS    EQU   12                  CODE TO EXICUTE IEFQMSSS      A36803 74520020
DUMTUB   DC    F'0'                DUMMY TUB                            74600019
         DC    X'40'                                                    74800019
         DC    AL3(DUMBUF)         ADDRESS OF DUMMY USER BUFFER         75000019
         DC    330X'0'                                                  75200019
RJCTM    DC    20F'0'                                                   75400019
SRCHBUF  DC    A(RJCTM)                                                 75600019
SRCHPARM DC    A(0)                                                     75800019
TUBAD    DC    A(DUMTUB)                                                76000019
SRCHAVT  DC    F'0'                                                     76200019
STOP     EQU   X'80'                                                    76400019
DSB      EQU   X'FF'                                                    76600019
DELJOB   EQU   X'08'                                                    76800019
BUM      EQU   X'08'                                                    76900019
WRITE    EQU   12                                                       77000019
INACT    EQU   16                                                       77200019
BADEND   EQU   X'10'                                                    77400019
RJCTAB   EQU   5                                                        77600019
FOUR     DC    H'4'                                                     77800019
ABNM     DC    C'ABNORMALLY'                                            78000019
NORM     DC    C'NORMALLY  '                                            78200019
COMP     EQU   X'40'                                                    78400019
ZERO     DC    F'0'                                                     78600019
MSGPARM  DC    A(DUMTUB)                                                78800019
MSGDEST  DC    A(0)                                                     79000019
         DC    A(MSGOFF)                                                79200019
MSGVP    DC    A(MSGVP)                                                 79400019
MSGOFF   DC    X'00'                                                    79600019
MSGM     DC    C'329'                                                   79800019
MDLT     DC    C'331'                                                   80000019
MNOT     DC    C'329'                                                   80200019
MDISK    DC    C'246'                                                   80400019
MRVP     DC    X'8'                                                     80600019
MPARM    DC   11C' '                                                    80800019
MNAME    DC    8C' '                                                    81000019
JOBFAIL  DC    C'JOBFAIL '                                       A36803 81100020
SLASH    DC    C'//'                                             A36803 81200020
SAVTTR   DC    F'0'                                              A36803 81300020
SMBC     EQU   X'FE'                                                    81400019
ID       EQU   14                                                       81600019
JFSWT    DC    X'0'                                                     81800019
ONE      EQU   1                                                        82000019
LDCPARM  DS    0F                                                       82200019
LDCECB   DC    F'0'                                                     82400019
LDCCODE  DC    3X'0'                                                    82600019
ATE       EQU   8                                                       82800019
SRVCODE  DC    X'0'                                                     83000019
SRVECBAD DC    A(SRVECB)                                                83200019
SRVCODAD DC    A(SRVCODE)                                               83400019
SRVPARMS DC    A(QMPAM)                                                 83600019
SRVECB   DC    F'0'                                                     83800019
QMDQ2    EQU   16                                                       84000019
FREEIOB  EQU   X'1C'               SRV CODE TO FREEMAIN IOB      A39400 84060020
GETIOB   EQU   X'20'               SRV CODE TO GETMAIN IOB       A39400 84120020
ACTERR WTO 'IHK242I ACTIVE AREA I/O ERROR-ABNORMAL CRJE CLOSE DOWN',   X84200019
               DESC=(4),ROUTCDE=(2,4,10),MF=L                           84400019
         IEFQMNGR                                                       84600019
QMPAE    DS    0CL8                                                     84800019
QMPCA    DS    CL4                                                      85000019
QMPEX    DS    CL4                                                      85200019
RECTTRH  DS    CL4                                                      85400019
RECTTRN  DS    CL4                                                      85600019
         DS    CL4                                                      85800019
         DS    CL2                                                      86000019
RECSTAT  DS    CL2                                                      86200019
         DS    CL4                                                      86400019
RECDDNAM DS    CL8                                                      86600019
         CMDEQU                                                         87000019
         IHKCDSCT RJCT=YES,AVT=YES,CCT=YES,TUB=YES                      87200019
         END                                                            87400019
