ED1      TITLE 'IHKED1 - EDIT AND DELETE(MAJOR) COMMAND PROCESSORS'     00100019
IHKED1   CSECT                                                          00200019
* 098000,106000-107000,150000,152000-153000,162000-163000,       A34581 00220020
* 347000-350000,429000,653000,667000,675000,677000,686000,       A34581 00240020
* 694000-696000,699000-704000,708000,710000-713000,745000,882000,A34581 00260020
* 901000,903000-904000,909000                                    A34581 00280020
*STATUS -- CHANGE LEVEL 0                                             * 00300019
*FUNCTION -- PROCESS EXEC, DELETE OR EDIT CRJE LIBRARY DATASET        * 00400019
*   EXECUTE-  IDENTIFIED BY NO PPT, OR EXEC CODE IN PPT.              * 00500019
*   NEXT LINE IN DATASET IS STORED IN USER BUFFER AND RETURN CODE     * 00600019
*   OF 0 IS MADE.  IF END OF DATA OR ANY ERROR OCCURS, RETURN CODE    * 00700019
*   OF 24 IS MADE.                                                    * 00800019
*                                                                     * 00900019
*   DELETE- DATASET IN USER LIBRARY IS SCRATCHED.                     * 01000019
*                                                                     * 01100019
*   EDIT- DATASET IS BROUGHT INTO THE ACTIVE AREA.  FOR CRJE DATASET, * 01200019
*   THE NUMBER OF TIMES ACCESSED IS UPDATED, AND THE DIRECTORY ENTRY  * 01300019
*   IN CORE IS CHANGED ACORDING  TO SPECIFIED OPERANDS.   FOR CRBE    * 01400019
*   DATASET, THE NUMBER OF TIMES ACCESSED IS UPDATED, AND THE         * 01500019
*   DIRECTORY ENTRY ON DISK AND IN CORE IS EXPANDED TO THE CRJE FORMAT* 01600019
*   AND CHANGED ACCORDING TO SPECIFIED OPERANDS.  FOR OTHER DATASETS  * 01700019
*   THE DIRECTORY ENTRY ON DISK AND IN CORE IS INITIALIZED TO CRJE    * 01800019
*   FORMAT, AND CHANGED ACCORDING TO DEFAULT AND SPECIFIED OPERANDS.  * 01900019
*   DATASETS ARE CHECKED FOR LINE NUMBERS NUMERIC OR XXXXXXXX.        * 02000019
*   FOR XXXXXXXX, THE DATASET IS SEQUENCED.  ANY LINE NUMBER NOT      * 02100019
*   EITHER IS CHANGED TO ZEROES AND A MESSAGE IS QUEUED.              * 02200019
*                                                                     * 02300019
*ENTRY POINT --                                                       * 02400019
*        IHKEDI- ONLY ENTRY POINT.  REGISTER 1 POINTS TO TWO WORD AREA* 02500019
*        CONTAINING ADDRESSES OF TUB AND AVT.                         * 02600019
*                                                                     * 02700019
*INPUT -- COMMAND CODE IN PPT IDENTIFIES COMMAND.  IF NO PPT EXISTS,  * 02800019
*   INDICATES EXEC.  FOR EDIT AND DELETE, PPT CONTAINS SWITCHES       * 02900019
*   STORED BY IHKEDT INDICATING OPERANDS SPECIFIED.  FOR EXEC, GETMAIN* 03000019
*   AREA SET UP BY IHKEDT AND POINTED TO IN TUB CONTAINS DATASET      * 03100019
*   INFORMATION.                                                      * 03200019
*                                                                     * 03300019
*OUTPUT --  EXEC STORES NEXT LINE IN USER BUFFER.  ANY ERROR ON DELETE* 03400019
*   CAUSES MESSAGE TO BE QUEUED.  FOR ERROR ON EDIT, ANY BITS IN TUB  * 03500019
*   THAT MIGHT HAVE BEEN TURNED ON ARE TURNED OFF, ACTIVE AREA IS     * 03600019
*   RELEASED, DIRECTORY ENTRY FREED, AND MESSAGE QUEUED.              * 03700019
*                                                                     * 03800019
*EXTERNAL REFERENCES --                                               * 03900019
*        IHKMSG- QUEUE MESSAGE FOR USER, SEND MESSAGE TO OPERATOR     * 04000019
*        IHKAFI- CREATE ACTIVE AREA, INSERT DATASET                   * 04100019
*        IHKBPM- SCRATCH OR FIND AND READ DATASET                     * 04200019
*        IHKDEF- DEFAULT INCREMENT                                    * 04300019
*        IHKGML- GETMAIN LIST                                         * 04400019
*        IHKKBX- CONTAINS DIRECTORY ENTRY AFTER RFIND                 * 04500019
*        IHKNUM- CHECK LINE NUMBER FOR NUMERIC                        * 04600019
*        IHKUTM- VERIFY USERID AND QUEUE FOR LIBRARY I/O              * 04700019
*EXITS, NORMAL --                                                     * 04800019
*        REGISTER 15=0                                                * 04900019
         EJECT                                                          05000019
*                                                                     * 05100019
*EXITS, ERROR --                                                      * 05200019
*        REGISTER 15= 8  GETMAIN FAILURE                              * 05300019
*        REGISTER 15= 12 ACTIVE AREA I/O ERROR                        * 05400019
*        REGISTER 15= 16 MESSAGE LOST                                 * 05500019
*        REGISTER 15= 20 ACTIVE AREA OUT OF SPACE                     * 05600019
*        REGISTER 15= 24 EXEC- END OF DATA, DISK ERROR OR NON CRJE    * 05700019
*                     OR CLIST DATASET                                * 05800019
*                                                                     * 05900019
*TABLES/WORK AREAS --                                                 * 06000019
*   PPT- PARAMETER POSITION TABLE                                     * 06100019
*   PPTCMD- CHECKED TO IDENTIFY COMMAND                               * 06200019
*   PPTFLG- SWITCHES SET BY IHKEDT, CHECKED BY IHKED1                 * 06300019
*   PPTPARS- SWITCHES STORED BY IHKEDT, MOVED TO WORK AREA BY IHKED1  * 06400019
*                                                                     * 06500019
*   TUB- TERMINAL USER BLOCK                                          * 06600019
*   TUBCNTFS- CHECK FOR NUMBER OF LINES READ                          * 06700019
*   TUBDATAL- SET TO LENGTH OF LINE FOR EXEC OR 1 IF BLANK LINE.      * 06800019
*   TUBDIRAD- ADDRESS OF DIRECTORY ENTRY, STORED BY IHKED1            * 06900019
*   TUBFLG1-  TUBPL1, TUBFOR, TUBSCN SET IF DEFAULT OR OLD DATASET    * 07000019
*   SPECIFIES, TURNED OFF ON ERROR                                    * 07100019
*   TUBFLG2- TUBLNUMN SET IF DEFAULT OR OLD DATASET SPECIFIED,        * 07200019
*   TURNED OFF ON ERROR                                               * 07300019
*   TUBGBLKY- USERID OF DATASET STORED TO GO TO IHKUTM                * 07400019
*   TUBNXKEY-ZERO STORED TO INDICATE FIRST RECORD, FIRST LINE         * 07500019
*   NUMBER STORED FOR FIRST INSERT INTO ACTIVE AREA                   * 07600019
*   TUBPARM1- TUBPARM5- USED FOR PARAMETER LIST TO IHKMSG, IHKUTM,    * 07700019
*   IHKNUM, USED AS WORK AREA                                         * 07800019
*   TUBPMFNM-DATASET NAME, SET BY IHKEDT FOR EDIT AND DELETE, BY      * 07900019
*   IHKED1 FOR EXEC                                                   * 08000019
*   TUBPPTAD- USED FOR PPT ADDRESS                                    * 08100019
*   TUBRAFBF- ADDRESS OF BUFFER TO BE INSERTED, STORED BY IHKED1      * 08200019
*   TUBUFFAD- ADDRESS OF USER BUFFER, KEY STORED BY IHKEDT, WORK AREA * 08300019
*   IN COMPUTING FIRST LINE NUMBER, NEXT LINE STORED BY EXEC.         * 08400019
*   TUBUSRID- USRID, CHECKED BY IHKED1                                * 08500019
*   TUBUSRNM- USERID OF DATASET, STORED BY IHKEDT FOR EDIT AND DELETE,* 08600019
*   STORED BY IHKED1 FOR EXEC                                         * 08700019
*                                                                     * 08800019
*ATTRIBUTES -- NON-RESIDENT, SERIAL, REFRESHABLE                      * 08900019
*                                                                     * 09000019
*NOTES -- NONE                                                        * 09100019
         EJECT                                                          09200019
*********************************************************************** 09300019
*   REGISTERS                                                         * 09400019
*********************************************************************** 09500019
REG0     EQU   0                        REGISTER 0                      09600019
REG1     EQU   1                        REGISTER 1                      09700019
RKON     EQU   2                        REGISTER 2 - KONBOX      A34581 09800020
REG3     EQU   3                        REGISTER 3- EXEC, DEF BASE      09900019
REG4     EQU   4                        REGISTER 4- DIRECTORY BASE      10000019
REG5     EQU   5                        REGISTER 5                      10100019
REG6     EQU   6                        REGISTER 6- RETURN REG          10200019
REG7     EQU   7                        REGISTER 7                      10300019
REG8     EQU   8                        REGISTER 8                      10400019
REG9     EQU   9                        REGISTER 9                      10500019
RBASE    EQU   10                       REGISTER 10 - IHKED1 BASEA34581 10600020
RTUB     EQU   11                       REGISTER 11 - TUB BASE   A34581 10700020
RAVT     EQU   12                       REGISTER 12- AVT BASE           10800019
REG13    EQU   13                       REGISTER 13- SAVEAREA           10900019
REG14    EQU   14                       REGISTER 14                     11000019
REG15    EQU   15                       REGISTER 15                     11100019
*********************************************************************** 11200019
*   EQUATES                                                             11300019
*********************************************************************** 11400019
RTRN8    EQU   8                        GETMAIN FAIL RETURN CODE        11500019
RTRN20   EQU   20                       AA OUT OF SPACE RETURN          11600019
RTRN24   EQU   24                       EXEC RETURN- TERMINATE          11700019
X0F      EQU   X'0F'                                                    11800019
X00      EQU   X'00'                                                    12000019
X08      EQU   8                                                        12100019
FIRSTREC EQU   8                                                        12200019
HEXF0    EQU   C'0'                                                     12300019
HEXF9    EQU   C'9'                                                     12400019
CRBEAOF  EQU   X'3F'                    CRBE-TURN OFF UNUSED BITS       12450019
CRBELNG  EQU   X'FB'                    TURN OFF RECORD LENGTH BIT-CRBE 12500019
CRBELINM EQU   X'40'                    CRBE-LINE NUMBERS IN LINES      12550019
CRBELEN  EQU   9                        CRBE DATASET LENGTH             12600019
NUMZONE  EQU   X'F0'                    NUMERIC ZONE                    12700019
UILEN    EQU   14                       USER DATA LENGTH                12800019
BLK      EQU   C' '                                                     12900019
ONE      EQU   1                                                        13000019
ENDLST   EQU   X'80'                    END PARAMETER LIST              13100019
UTMCD    EQU   X'80'                    UTM CODE- VERIFY USERID, ENQ    13200019
UTMINOP  EQU   X'04'                    UTM CODE- DECLARE LIBRARY INOP  13300019
UILENCLR EQU   X'1F'                                                    13400019
MAXREC   EQU   10                                                       13500019
LINUMLNG EQU   8                                                        13600019
RECLINLN EQU   88                                                       13700019
RECLNG   EQU   80                                                       13800019
SHORTREC EQU   72                                                       13900019
REC1     EQU   16                                                       14100019
         EJECT                                                          14200019
*********************************************************************** 14300019
*     SAVE REGISTERS, SET UP BASE REGISTERS                           * 14400019
*********************************************************************** 14500019
         USING IHKED1,RBASE                                             14600019
         USING OSDSECT,REG13                                            14700019
         USING TUBDSECT,RTUB                                            14800019
         USING AVTDSECT,RAVT                                            14900019
         SAVE  (14,12),,ED170270                                 A34581 15000020
         LR    RBASE,REG15              SET UP IHKED1 BASE              15100019
         LM    RTUB,RAVT,0(REG1)        SET UP TUB, AVT          A34581 15200020
         LA    REG5,GMLEN               LENGTH OF GETMAIN               15400019
         LA    REG8,GMERR               GETMAIN ERROR RETURN            15500019
         BAL   REG6,SUBRGETM            GO GET CORE FOR  WORK/SAVE AREA 15600019
GMGOOD   L     REG1,TUBPARM4                                            15800019
         ST    REG13,4(REG1)            SAVE REGISTER 13                15900019
         ST    REG1,8(REG13)            SAVE GETMAIN IN CALLERS         16000019
         LR    REG13,REG1               SET UP SAVEAREA                 16100019
         USING RAFKNBX,RKON                                      A34581 16200020
         L     RKON,IHKYYKBX            GET ADDRESS OF KONBOX    A34581 16300020
         L     REG3,TUBPPTAD            SWITCHES IN PPT                 16400019
         NI    EDTSW,EDTOFF             SET ALLBITS TO ZERO             16500019
         MVI   MSGINS,X08               LENGTH FOR INSERT               16600019
         USING PPTDSECT,REG3                                            16800019
         LA    REG3,0(REG3)                                             16900019
         LTR   REG3,REG3                TEST FOR PPT                    17000019
         BZ    SETUPEXC                 BR= NO PPT, MUST BE EXEC        17100019
         CLI   PPTCMD,CMDED1DO          TEST CMD CODE FOR EXEC          17200019
         BE    SETUPEXC                 BR= EXEC                        17300019
*********************************************************************** 17400019
*                                                                       17500019
*   EDIT AND DELETE COMMANDS                                          * 17600019
*                                                                       17700019
*********************************************************************** 17800019
NOTEXEC  MVC   EPTFLG,PPTFLG            PICK UP SWITCHES                17900019
         NI    EPTFLG,PPTDEL            TURN OFF ALL BUT DELETE BIT     17950019
         MVC   SWDEF(5),PPTPARS                                         18000019
         LA    REG6,SCRATA              RETURN FROM UTM SUBROUTINE      18100019
         TM    EPTFLG,PPTDEL            IS THIS DELETE                  18200019
         BO    GOTOUTM                  YES, GO TO UTM                  18300019
*********************************************************************** 18400019
*                                                                       18500019
*   EDIT COMMAND  CREATE ACTIVE AREA, POSITION TO BEGINNING           * 18600019
*                                                                       18700019
*********************************************************************** 18800019
         L     REG1,TUBUFFAD            PICK UP KEY PASSED              18900019
         MVC   KEYSTO(3),48(REG1)                                       19000019
         LA    REG3,CREGOOD             0  SUCCESSFUL RETURN            19100019
         LA    REG9,RETCD20             RETURN 4- AA OUT OF SPACE       19200019
         LA    REG1,ADDRTUB(REG13)                                      19300019
         CREATE IS                      CREATE ACTIVE FILE              19400019
         B     AFIRTN(REG15)            TEST RETURN CODES               19500019
*********************************************************************** 19600019
*                                                                       19700019
*   CREAT SUCCESSFUL                                                    19800019
*                                                                       19900019
*********************************************************************** 20000019
CREGOOD  LA    REG1,ADDRTUB(REG13)                                      20100019
         OI    EDTSW,EDTREL             INDICATES ACTIVE AREA           20200019
         MVI   TUBNXKEY+7,X00           POINT TO FIRST RECORD           20300019
         LA    REG3,RTNGOOD             RETURN 0,4                      20400019
         LR    REG9,REG3                                                20500019
         RPOINT B,NR                    POSITION TO BEGNING OF FILE     20600019
         B     AFIRTN(REG15)                                            20700019
*********************************************************************** 20800019
*                                                                       20900019
*   EXECUTE COMMAND- PICK UP DATASET INFORMATION                      * 21000019
*                                                                       21100019
*********************************************************************** 21200019
         USING EXECDSCT,REG3                                            21300019
SETUPEXC L     REG3,TUBEXCAD            ADDRESS OF EXEC DATA            21400019
         MVC   TUBPMFNM,EXDSNAM         DATASET NAME                    21500019
         MVC   TUBUSRNM,EXUSRID         USERID                          21600019
         MVC   KEYSTO(3),EXKEY          KEY                             21700019
         MVI   EPTFLG,PPTEXC            SET SWITCH- EXEC                21800019
         DROP  REG3                                                     21900019
         EJECT                                                          22000019
*********************************************************************** 22100019
*                                                                       22200019
*   SUBROUTINE TO GO TO IHKUTM                                          22300019
*    VERIFY USERID AND ENQUEUE FOR LIBRARY I/O OR DECLARE LIBRARY INOP  22400019
*                                                                       22500019
*********************************************************************** 22600019
RTNGOOD  LA    REG6,UTMGOOD             WILL RETURN TO UTMGOOD          22700019
GOTOUTM  MVI   TUBPARM5,UTMCD           VERIFY USERID, ENQ FOR I/O      22800019
SUBRUTM  MVC   TUBGBLKY,TUBUSRNM        SET UP USERID FOR UTM           22900019
         LA    REG1,TUBPARM5            UTM CODE                        23000019
         ST    REG1,TUBPARM3            PARAMETER 2- POINTS TO UTM CODE 23100019
         ST    RTUB,TUBPARM2            PARAMETER 1- TUB                23200019
         LA    REG1,TUBPARM2            PUT LIST ADDR INTO PARM REG     23300019
         L     REG15,IHKYYUTM           LOAD ADDRESS OF UTM             23400019
         BALR  REG14,REG15                                              23500019
         B     UTMRTN(REG15)                                            23600019
UTMRTN   B     0(REG6)                  0  SUCCESSFUL                   23700019
         B     INVUID                   4  INVALID USERID               23800019
         B     RETCD                    8  GETMAIN FAIL                 23900019
         B     RETCD                    12 I/O ERROR                    24000019
         B     DDNAMBLK                 16 NO DD CARD                   24100019
         B     0(REG6)                  20 NOT USED                     24200019
         B     LIBRINOP                 24 LIBRARY INOPERATIVE          24300019
         B     RETCD0                   28 BAD REQUEST CODE             24400019
*********************************************************************** 24500019
*                                                                       24600019
*   DELETE COMMAND- RETURNS FROM IHKUTM                                 24700019
*   SCRATCH DATASET AND RETURN                                          24800019
*                                                                       24900019
*********************************************************************** 25000019
SCRATA   LA    REG1,ADDRTUB(REG13)                                      25100019
         LA    REG3,RETCD0              0  SUCCESSFUL RETURN            25200019
         LA    REG9,NFOUND              4  NOT FOUND                    25300019
         RSCRATCH                                                       25400019
         B     CLOSRTN(REG15)                                           25500019
*********************************************************************** 25600019
*                                                                       25700019
*   EDIT AND EXECUTE- RETURN FROM SUBRUTM                               25800019
*                                                                       25900019
*********************************************************************** 26000019
UTMGOOD  LA    REG1,ADDRTUB(REG13)                                      26100019
         LA    REG3,GETDIR              0  SUCCESSFUL RETURN            26200019
         LA    REG9,NFOUND              4  NOT FOUND                    26300019
         OI    EDTSW,EDTCLS             SET SWITCH TO CLOSE             26400019
         RFIND I                        FIND DATA SET                   26500019
*   TEST RETURN CODE                                                    26600019
         B     CLOSRTN(REG15)                                           26700019
*********************************************************************** 26800019
*                                                                       26900019
*   EDIT AND EXECUTE COMMANDS                                           27000019
*                                                                       27100019
*********************************************************************** 27200019
         USING DIRDSECT,REG4            DIRECTORY ENTRY                 27300019
GETDIR   TM    EPTFLG,PPTEXC            IS THIS EXEC                    27400019
         BZ    SETUPDIR                 BR= EDIT COMMAND                27500019
         LA    REG4,BPBLDLST+4          ADDRESS OF DIRECTORY ENTRY      27600019
         B     CKLENGTH                 GO CHECK FOR CRJE DATASET       27700019
*********************************************************************** 27800019
*                                                                       27900019
*   EDIT COMMAND- GET CORE FOR DIRECTORY                                28000019
*                                                                       28100019
*********************************************************************** 28200019
SETUPDIR LA    REG5,DIRSIZE             EDIT- GET CORE FOR DIRECTORY    28300019
         LA    REG8,RETCD8              GETMAIN FAIL RETURN             28400019
         BAL   REG6,SUBRGETM            GO GET CORE                     28500019
         OI    EDTSW,EDTDIR              SET SWITCH- INDICATES DIREC    28600019
         L     REG4,TUBPARM4                                            28700019
         ST    REG4,TUBDIRAD            DIRECTORY ADDRESS               28800019
         MVC   0(DIRSIZE,REG4),BPBLDLST+4   GET DIRECTORY ENTRY         28900019
*********************************************************************** 29000019
*                                                                       29100019
*   EDIT AND EXECUTE- CHECK FOR CRJE DATASET, THEN CHECK KEY            29200019
*                                                                       29300019
*********************************************************************** 29400019
         USING DEFDSECT,REG3                                            29500019
CKLENGTH L     REG3,IHKYYDEF            GET ADDRESS OF DEFAULT TABLE    29600019
         TM    DIRUILEN,UILEN           TEST FOR CRJE DIRECTORY         29700019
         BO    CKUSRKEY                 IS CRJE-GO CHECK KEY            29800019
         OI    EDTSW,EDTCRJNO           SET SWITCH- NON-CRJE DATASET    29900019
         TM    EPTFLG,PPTEXC            NOT CRJE DATASET- IS THIS EXEC  30000019
         BO    EDTREQ                   BR= YES                         30100019
         TM    DIRUILEN,CRBELEN         IS IT CRBE                      30200019
         BO    UPDATDIR                 IS CRBE- GO UPDATE DIRECTORY    30300019
*********************************************************************** 30400019
*                                                                       30500019
*   CONVERT NON-CRJE DIRECTORY TO CRJE FORMAT                           30600019
*                                                                       30700019
*********************************************************************** 30800019
TESTDIR  MVC   DIRINC,DEFINCRE          PUT INCREMENT INTO DIR ENTRY    30900019
         MVC   DIRKEY,BLANKS            BLANK OUT KEY FIELD             31000019
         TM    DIRUILEN,CRBELEN         TEST FOR CRBE DIR ENTRY         31100019
         MVI   DIRUILEN,UILEN           PUT LENGTH IN DIRECTORY         31200019
         BNO   DIRPROC1                 IF NOT, BRANCH                  31300019
         NI    DIRATTRL,CRBELNG         TURN OFF CRBE LONG RECORD BIT   31400019
         NI    DIRATTRO,CRBEAOF         TURN OFF UNUSED SWITCHES        31500019
         TM    DIRATTRO,CRBELINM        ARE LINE NUMBERS IN LINES       31510019
         BZ    CKCRBEAT                 BR= NO                          31520019
         MVI   DIRATTRO,DIROLNO         YES- SET BIT IN DIRECTORY       31530019
CKCRBEAT CLI   DIRATTRL,X00             IS ATTRIBUTE ZERO               31540019
         BE    SETDIRAT                 BR= YES, GO STORE ATTRIBUTE     31550019
         B     NOPROCT                  CONTUNUE PROCESSING             31600019
*********************************************************************** 31700019
*                                                                       31800019
*   CRJE DATASET- CHECK KEY IF KEY PROTECTED                            31900019
*                                                                       32000019
*********************************************************************** 32100019
CKUSRKEY CLC   TUBUSRID,TUBUSRNM        IS THIS USERS OWN DATASET       32200019
         BE    UPDATDIR                 BR= YES, DO NOT CHECK KEY       32300019
         CLC   DIRKEY,BLANKS            IS KEY= BLANKS                  32400019
         BE    UPDATDIR                 BR= YES, NOT KEY PROTECTED      32500019
         CLC   DIRKEY,KEYSTO            TEST FOR EQUAL KEYS             32600019
         BNE   KEYUNEQ                  IF NOT,ENQUEUE ERR MSG          32700019
*********************************************************************** 32800019
*                                                                       32900019
*   COMPUTE NUMBER OF TIMES ACCESSED                                    33000019
*                                                                       33100019
*********************************************************************** 33200019
UPDATDIR LA    REG15,ONE                                                33300019
         AH    REG15,DIRSAV                                             33400019
         TM    EPTFLG,PPTEXC            IS IT EXC                       33500019
         BO    CKCLIST                  BR= YES                         33600019
*********************************************************************** 33700019
*                                                                       33800019
*   EDIT COMMAND  UPDATE NUMBER OF TIMES ACCESSED                       33900019
*     UPDATE DIRECTORY ENTRY                                            34000019
*                                                                       34100019
*********************************************************************** 34200019
         STH   REG15,DIRSAV             UPDATE NUMBER OF TIMES ACCESSED 34300019
         MVC   BPBLDLST+4(DIRSIZE),0(REG4)                              34400019
         TM    DIRUILEN,CRBELEN         IS THIS CRBE                    34500019
         BO    TESTDIR                  BR= GO PROCESS CRBE             34600019
NOPROCT  TM    OPRSW,OPRATT             WAS ATTRIBUTE SPECIFIED         35100019
         BO    SETDIRAT                 BR= ATTRIBUTE SPECIFIED         35200019
         TM    DIRATTRL,DIRPL1          IS DATASET PL/1                 35300019
         BO    SETUBPL1                 BR= PL/1                        35400019
         B     ATNPL1                                                   35500019
*********************************************************************** 35600019
*                                                                       35700019
*   EXECUTE- CHECK FOR CLIST                                            35800019
*                                                                       35900019
*********************************************************************** 36000019
CKCLIST  TM    DIRATTRL,DIRACLST        IS IT CLIST                     36100019
         BZ    INVALATR                 BR= NO, ENQ INVALID EXEC MSG    36200019
         TM    DIRATTRO,DIROLNO         ARE THERE LINE NUMBERS IN LINES 36300019
         BZ    CKFRST                   BR= NO                          36400019
         OI    EDTSW,EDTNUM             SET SWITCH- LINE NUMBERS IN LNS 36500019
CKFRST   LH    REG1,DIRNOBLK            NUMBER OF BLOCKS                36600019
         LA    REG14,DIRSAV             NUMBER OF TIMES ACCESSED        36700019
         DROP  REG4                                                     36800019
         USING EXECDSCT,REG4                                            36900019
         L     REG4,TUBEXCAD                                            37000019
         LA    REG3,EXCLINE             0 RETURN FROM READ              37100019
         LA    REG9,RETCD24             4 RETURN                        37200019
         SR    REG5,REG5                INITIALIZE BLOCK NUMBER         37300019
         CH    REG5,EXMAXBLK            IS THIS FIRST TIME DATASET READ 37400019
         BNE   READDS                   BR= NO                          37500019
*                                                                       37600019
*   FIRST TIME DATASET TO BE READ                                       37700019
*                                                                       37800019
         STH   REG1,EXMAXBLK            SAVE INITIAL NUMBER OF BLOCKS   37900019
         STH   REG15,0(REG14)           UPDATE NUMBER OF TIMES ACCESSED 38000019
         B     READDS                                                   38100019
*********************************************************************** 38200019
*                                                                       38300019
*   DATASET NOT CRJE OR CRBE- INITIALIZE DIRECTORY  ENTRY               38400019
*                                                                       38500019
*********************************************************************** 38600019
         USING DIRDSECT,REG4                                            38700019
DIRPROC1 TIME  ,                  GET CREATION DATE                     38800019
         ST    REG1,TUBPARM3            STORE CREATION AND LAST         38900019
         MVC   DIRCRE,TUBPARM3+1          MODIFIED DATES                39000019
         MVC   DIRMODAT,TUBPARM3+1                                      39100019
         SR    REG1,REG1                                                39200019
         STC   REG1,DIRATTRO            INITIALIZE ATTRIBUTE            39300019
         STH   REG1,DIRSAV              INITILIZE SAVE COUNTER          39400019
         MVC   DIRPL1BS(2),DIRSAV       INIT PL/1 AND FORTRAN ATTR      39500019
         TM    SWDEFEDT,DEFENUM         ARE LINE NUMBERS IN LINES       39600019
         BZ    SETDIRAT                 BR= NO                          39700019
         OI    TUBFLG2,TUBLNUMN         LINE NUMBERS IN LINES-SET TUB   39800019
*********************************************************************** 39900019
*                                                                       40000019
*   INITIALIZE ATTRIBUTE IN DIRECTORY  ENTRY                            40100019
*                                                                       40200019
*********************************************************************** 40300019
SETDIRAT MVC   DIRATTRL(1),SWDEFATT     ATTRIBUTE SPECIFIED             40400019
         TM    DIRATTRL,DIRPL1          IS THIS PL/1                    40500019
         BZ    ATNPL1                   NO GO CHECK FORTRAN             40600019
         MVC   DIRPL1BS(2),SWDEFBSM     PUT PL/1 SOURCE MARGINS IN DIR  40700019
         TM    SWDEFEDT,DEFPL148        IS THIS PL/1, 48 CHAR SET       40800019
         BZ    SETUBPL1                 BR= NO                          40900019
         OI    DIRATTRL,DIRPL148        YES- SET 48 CHAR BIT            41000019
SETUBPL1 OI    TUBFLG1,TUBPL1           SET PL/1 SW IN TUB              41100019
         B     TSTLINUM                                                 41200019
*********************************************************************** 41300019
*                                                                       41400019
*   NOT PL/1, CHECK FORTRAN                                             41500019
*                                                                       41600019
*********************************************************************** 41700019
ATNPL1   TM    DIRATTRL,DIRFORTH        TEST FOR FORTRAN ATTRIBUTE      41800019
         BZ    TESTSCAN                 IF NOT TEST FOR SCAN            41900019
         OI    TUBFLG1,TUBFOR           SET FORTRAN SW IN TUB           42000019
         B     TSTLINUM                                                 42100019
TESTSCAN TM    TUBFLG1,TUBSCN           TEST FOR SCAN REQUE>TED         42200019
         BO    SYNATERR                 IF YES, ENQUEUE ERROR MSG       42300019
*********************************************************************** 42400019
*                                                                       42500019
*   CHECK FOR LINE NUMBER SPECIFIED OR INDICATED IN DIRECTORY           42600019
*                                                                       42700019
*********************************************************************** 42800019
TSTLINUM NI    DIRATTRO,DIROLDF         TURN OFF OLD BIT         A34581 42830020
         CLC   TUBUSRNM,TUBUSRID        IS THIS USERS OWN DATASETA34581 42860020
         BNE   TSTLINA                  BR= NO,DO NOT SET OLD BITA34581 42890020
         OI    DIRATTRO,DIROLD          SET OLD BIT FOR ALL OTHERA34581 42920020
TSTLINA  TM    TUBFLG2,TUBLNUMN         WAS NUM  SPECIFIED       A34581 42950020
         BZ    CKNONUM                  BR= LINE NUMBER NOT SPECIFIED   43000019
         OI    DIRATTRO,DIROLNO         SET DIRECTORY-LINE NUMBERED     43100019
         B     SETUPRD                                                  43200019
CKNONUM  TM    OPRSW,OPRNUM             WAS NONUM SPECIFIED             43300019
         BZ    CKLINUM                  BR= NONUM NOT SPECIFIED         43400019
         NI    DIRATTRO,DIROLNOF        TURN OFF BIT IN DIRECTORY       43500019
         B     SETUPRD                                                  43600019
CKLINUM  TM    DIRATTRO,DIROLNO         CHECK FOR DEFAULT OF NUM        43800019
         BZ    SETUPRD                                                  43900019
         OI    TUBFLG2,TUBLNUMN         NUM DEFAULT- SET TUB            44000019
*********************************************************************** 44100019
*                                                                       44200019
*   EDIT- SET UP TO CHECK LINE NUMBER                                   44300019
*                                                                       44400019
*********************************************************************** 44500019
SETUPRD  L     REG5,DEFSTLNO            GET DEFAULT FIRST LINE NUMBER   44600019
         DROP  REG3                                                     44700019
         S     REG5,DIRINC                                              44800019
READEDIT LA    REG3,CKXES               0 RETURN                        44900019
         LA    REG9,RETCD0              4 RETURN- EOD                   45000019
*********************************************************************** 45100019
*                                                                       45200019
*   EDIT AND EXECUTE- READ DATASET                                      45300019
*                                                                       45400019
*********************************************************************** 45500019
READDS   LA    REG1,ADDRTUB(REG13)                                      45600019
         RREAD                                                          45700019
         B     CLOSRTN(REG15)                                           45800019
*********************************************************************** 45900019
*                                                                       46000019
*   SUCCESSFUL READ- EDIT COMMAND                                       46100019
*   CHECK FOR XXXXXXXX THEN SEQUENCE                                    46200019
*     IF NOT X CHECK FOR NUMERIC LINE NUMBER                            46300019
*                                                                       46400019
*********************************************************************** 46500019
CKXES    L     REG9,SFBUFF1                                             46600019
         LR    REG7,REG9                BUFFER ADDRESS                  46700019
         LA    REG7,FIRSTREC(REG7)      POINT TO FIRST LINE KEY         46800019
         L     REG15,TUBUFFAD           USE USER BUFFER FOR WORK AREA   46900019
         LH    REG8,TUBCNTFS            GET NUMBER OF LINES IN BUFFER   47000019
SEQDS2   A     REG5,DIRINC              INCREMENT LINE NUMBER           47100019
         CLC   XXX,0(REG7)              IS LINE NUMBER ALL X            47200019
         BNE   CKNUMRIC                 BR=NO                           47300019
         CVD   REG5,0(REG15)            CONVERT LINE NUMBER             47400019
         UNPK  0(8,REG7),4(4,REG15)     PUT LINE NO INTO KEY FIELD      47500019
         OI    7(REG7),NUMZONE          PUT NUMERIC ZONE IN LAST POS    47600019
         TM    TUBFLG2,TUBLNUMN         TEST FOR NUM SPECIFIED          47620019
         BZ    NXTSEQ                   BR= NUM NOT SPECIFIED           47640019
         MVC   80(8,REG7),0(REG7)       STORE LINE NUMBER IN 73-80      47660019
NXTSEQ   LA    REG7,88(REG7)            INCREMENT TO NEXT LINE          47700019
         BCT   REG8,SEQDS2              CONTINUE IF NOT LAST LINE       47800019
INS      LA    REG1,ADDRTUB(REG13)      LINE NUMBERS ALL CHECKED        47900019
         ST    REG9,TUBRAFBF            RESTORE BUFFER ADDRESS          48000019
         LA    REG3,READEDIT            0 RETURN                        48100019
         LA    REG9,RETCD20             4 RETURN- AA OUT OF SPACE       48200019
         INSERT M                       INSERT LINES INT ACTIVE AREA    48300019
         B     AFIRTN(REG15)                                            48400019
*********************************************************************** 48500019
*                                                                       48600019
*   LINE NUMBER NOT XXXXXXXX  CHECK FOR NUMERIC                         48700019
*                                                                       48800019
*********************************************************************** 48900019
CKNUMRIC LR    REG14,REG7               LINE NUMBER ADDRESS             49000019
         LA    REG1,LINUMLNG            LINE NUMBER LENGTH              49100019
CHKNEXT  CLI   0(REG14),HEXF0           IS IT LESS THAN ZERO            49200019
         BL    INVNUM                   BR= YES, INVALID                49300019
         CLI   0(REG14),HEXF9           IS IT GREATER THAN 9            49400019
         BH    INVNUM                   BR= YES, INVALID                49500019
         LA    REG14,1(REG14)                                           49600019
NXTCHAR  BCT   REG1,CHKNEXT                                             49700019
         B     NXTSEQ                   ALL NUMERIC                     49800019
         EJECT                                                          49900019
*********************************************************************** 50000019
*                                                                       50100019
*   EXEC COMMAND                                                        50200019
*                                                                       50300019
*********************************************************************** 50400019
         USING EXECDSCT,REG4                                            50500019
EXCLINE  LA    REG5,ONE(REG5)           UPDATE NUMBER OF BLOCKS READ    50600019
         CH    REG5,EXBLKNUM                                            50700019
         BNL   GETREC                   BR= CORRECT BLOCK               50800019
         BAL   REG6,FREEREAD            FREE BLOCK                      50900019
         B     READDS                   GO READ NEXT BLOCK              51000019
*********************************************************************** 51100019
*                                                                       51200019
*   CHECK IF INITIAL NUMBER OF BLOCKS EXCEEDED                          51300019
*                                                                       51400019
*********************************************************************** 51500019
GETREC   LH    REG15,EXBLKNUM           BLOCK TO BE READ                51600019
         CH    REG15,EXMAXBLK           DOES IT EXCEED ORIGINAL NUMBER  51700019
         BH    BLKEXC                   BR= EXCEEDED                    51800019
*********************************************************************** 51900019
*                                                                       52000019
*   FIND RECORD AND MOVE TO USER BUFFER                                 52100019
*   UPDATE RECORD TO BE READ AND UPDATE BLOCK NUMBER IF WAS LAST RECORD 52200019
*                                                                       52300019
*********************************************************************** 52400019
         LH    REG9,EXRECNUM            RECORD TO BE PROCESSED          52500019
         CH    REG9,TUBCNTFS            IS IT GREATER THAN NUMBER READ  52600019
         BH    SETEOD                   BR= SHORT BLOCK                 52700019
         LA    REG9,ONE(REG9)                                           52800019
         LA    REG8,RECLINLN            NUMBER OF CHAR IN RECORD        52900019
         LR    REG1,REG8                                                53000019
         MH    REG8,EXRECNUM            MULTIPLY BY RECORD TO BE READ   53100019
         SR    REG8,REG1                                                53200019
         CLI   EXRECNUM+1,MAXREC         IS RECORD LAST IN BLOCK        53300019
         BNE   UPDATREC                 BR= NOT LAST IN BLOCK           53400019
         LA    REG9,ONE                 READ FIRST IN BLOCK NEXT TIME   53500019
         LA    REG15,ONE(REG15)         UPDATE BLOCK NUMBER             53600019
         STH   REG15,EXBLKNUM                                           53700019
UPDATREC STH   REG9,EXRECNUM            UPDATE RECORD NUMBER            53800019
         L     REG14,SFBUFF1            ADDRESS OF BUFFER               53900019
         AR    REG14,REG8               RECORD TO BE PROCESSED          54000019
         L     REG1,TUBUFFAD                                            54100019
         MVC   0(RECLNG,REG1),REC1(REG14) MOVE ENTIRE RECORD            54200019
*********************************************************************** 54300019
*                                                                       54400019
*   STORE RECORD LENGTH.  CHECK FOR BLANK LINE- STORE LENGTH OF ONE.    54500019
*                                                                       54600019
*********************************************************************** 54700019
         LA    REG14,RECLNG             RECORD LENGTH                   54800019
         TM    EDTSW,EDTNUM                                             54900019
         BZ    SETDATEL                 BR= LINE NUMBERS NOT IN LINES   55000019
         LA    REG14,SHORTREC           SET SHORT RECORD-LINE NUMBERED  55100019
SETDATEL BCTR  REG1,0                                                   55200019
         AR    REG14,REG1                                               55300019
NEXTCHAR CR    REG14,REG1                                               55400019
         BNH   BLNKLINE                 BR= ALL BLANKS                  55500019
         CLI   0(REG14),BLK                                             55600019
         BNE   STORDATL                 BR= NON-BLANK FOUND             55700019
         BCT   REG14,NEXTCHAR                                           55800019
BLNKLINE LA    REG14,1(REG1)            BLANK LINE- SET LENGTH ONE      55900019
STORDATL SR    REG14,REG1                                               56000019
         STH   REG14,TUBDATAL                                           56100019
         SR    REG8,REG8                SET RETURN CODE ZERO            56200019
FREERDEX LA    REG6,RETURN                                              56300019
*********************************************************************** 56400019
*                                                                       56500019
*   FREE BUFFER READ                                                    56600019
*                                                                       56700019
*********************************************************************** 56800019
FREEREAD L     REG14,SFBUFF1                                            56900019
         LM    REG0,REG1,0(REG14)                                       57000019
         FREEMAIN R,LV=(0),A=(1)                                        57100019
         BR    REG6                                                     57200019
SETEOD   LA    REG8,24                                                  57300019
         B     FREERDEX                 GO FREE BUFFER                  57400019
         EJECT                                                          57500019
*********************************************************************** 57600019
*           SPECIFIC ERROR ROUTINES                                     57700019
*             ENQUEUE MESSAGE AND RETURN                                57800019
*********************************************************************** 57900019
*                                                                       58000019
*   DS NOT FOUND                                                        58100019
*                                                                       58200019
NFOUND   LA    REG1,NFNDCD                                              58300019
         MVC   MSGINS+1(8),TUBPMFNM     INSERT DS NAME                  58400019
         B     ENQRTN0                                                  58500019
*                                                                A34581 58510020
*   DIRECTORY FULL                                               A34581 58520020
*                                                                A34581 58530020
DIRFULL  LA    REG1,MDIRFULL                                     A34581 58540020
         OI    EDTSW,EDTNCLS            CLOSE IS NOT TO BE DONE  A34581 58550020
         B     FLGLST                                            A34581 58560020
*                                                                       58600019
*           NO DD CARD FOR USER'S LIBRARY                               58700019
*                                                                       58800019
DDNAMBLK MVC   MSGINS+1(8),TUBGBLKY     INSERT USERID-OWNER OF DATASET  58900019
         LA    REG1,NODDCDCD                                            59000019
         B     ENQRTN0                                                  59100019
*                                                                       59200019
*   USER LIBRARY I/O ERROR                                              59300019
*                                                                       59400019
DSKERRF  OI    EDTSW,EDTIOER                                            59500019
         MVC   MSGINS+1(L'BPPARMFS),BPPARMFS  GET DDNAME                59600019
         TM    EDTSW,EDTCLS             IS CLOSE NEEDED                 59700019
         BO    EDTREQ                   BR=YES,CLOSE NOSTOW             59800019
IOERROR  NI    EDTSW,EDTCLSF            TURN OFF CLOSE BIT              59900019
         MVI   TUBPARM5,UTMINOP         UTM CODE                        60000019
         BAL   REG6,SUBRUTM             GO DECLARE LIBRARY INOPERATIVE  60100019
         MVI   MSGINS1,X08                                              60200019
         MVC   MSGINS1+1(L'TUBUSRNM),TUBUSRNM                           60300019
         LA    REG14,MSGINS1                                            60400019
         ST    REG14,TUBPARM5           ONE INSERTION                   60500019
         OI    TUBPARM5,ENDLST                                          60600019
         LA    REG1,DERRCDC             I/O ERROR MSG                   60700019
*                                                                       60800019
*   SEND MESSAGE TO CENTRAL                                             60900019
*                                                                       61000019
SNDMSGC  LA    REG14,ZEROES                                             61100019
         OI    EDTSW,EDTMSGC            SET SWITCH-MSG TO CENTRAL       61200019
         BAL   REG6,ENQMSGC             ENQUEUE MSG FOR CENTRAL         61300019
*                                                                       61400019
*   LIBRARY INOPERATIVE                                                 61500019
*                                                                       61600019
LIBRINOP LA    REG1,INOPMSG                                             61700019
         B     FLGLST                                                   61800019
*                                                                       61900019
*   INITIAL NUMBER OF BLOCKS EXCEEDED                                   62000019
*                                                                       62100019
BLKEXC   LA    REG1,MBLKEXC                                             62200019
         B     FLGLST                                                   62300019
*                                                                       62400019
*   EXEC- DATASET NOT CLIST                                             62500019
*                                                                       62600019
INVALATR LA    REG1,EXCATR                                              62700019
         B     FLGLST                                                   62800019
*                                                                       62900019
*   EXEC- DATASET NOT CRJE                                              63000019
*                                                                       63100019
EDTREQ   LA    REG1,ADDRTUB(REG13)                                      63200019
         RCLOSE NOSTOW                                                  63300019
         TM    EDTSW,EDTIOER            WAS THIS I/O ERROR              63400019
         BO    IOERROR                  BR= YES                         63500019
         BAL   REG3,RCLOS2              NO, TURN OFF BIT, BR ON RETURN  63600019
         LA    REG1,MEDTREQ             SEND EDIT REQUIRED MSG          63700019
         B     FLGLST                   NO INSERTION                    63800019
*                                                                       63900019
*   EXEC AND EDIT - INVALID KEY                                         64000019
*                                                                       64100019
KEYUNEQ  LA    REG1,INVKEYCD            INVALID KEY                     64200019
         B     FLGLST                                                   64300019
*                                                                       64400019
*   EXEC, EDIT, AND DELETE-  INVALID USERID                             64500019
*                                                                       64600019
INVUID   LA    REG1,UIDINUCD            INVALID USERID                  64700019
         B     FLGLST                   NO INSERTION                    64800019
*                                                                       64900019
*   ACTIVE AREA OUT OF SPACE                                            65000019
*                                                                       65100019
RETCD20  LA    REG1,MAAOUT              GO SEND MESSAGE                 65200019
         O     REG1,HIBIT               NO INSERTION             A34581 65300020
         BAL   REG6,ENQMSG3                                             65400019
         LA    REG8,RTRN20              SET RETURN CODE                 65500019
         B     RETURN                                                   65600019
*********************************************************************** 65700019
*   ENQUEUE MESSAGE AND RETURN TO PROCESSING                            65800019
*********************************************************************** 65900019
*                                                                       66000019
*   LINE NUMBER NOT X AND NON-NUMERIC                                   66100019
*                                                                       66200019
INVNUM   TM    EPTFLG,EPTNUM            IS THIS THE FIRST TIME          66240019
         BO    SETZERO                  BR= NO                          66280019
         OI    EPTFLG,EPTNUM            SEND MSG ONLY ONCE              66320019
         MVC   MSGINS+1(LINUMLNG),0(REG7)                               66360019
         LA    REG1,INVALNUM                                            66400019
         OI    EDTSW,EDTNCLS            SET SWITCH NOT TO CLOSE         66500019
         BAL   REG6,ENQMSG3             GO SEND MSG                     66600019
SETZERO  MVI   0(REG7),NUMZONE          SET LINE NUMBER TO ZEROES       66800019
         MVC   1(7,REG7),0(REG7)                                        66900019
         B     NXTSEQ                                                   67000019
*                                                                       67100019
*   ATTRIBUTE INCONSISTENT WITH SCAN                                    67200019
*                                                                       67300019
SYNATERR LA    REG1,ATTINVCD            ATTRIBUTE INCONSISTENT W SCAN   67400019
         OI    EDTSW,EDTNCLS            SET SWITCH NOT TO CLOSE  A34581 67460020
         O     REG1,HIBIT               NO INSERTION             A34581 67520020
         BAL   REG6,ENQMSG3             GO ENQ MSG                      67600019
         NI    TUBFLG1,TUBSCNF          TURN OFF SCAN BIT IN TUB        67800019
         B     TSTLINUM                                                 67900019
         EJECT                                                          68000019
*********************************************************************** 68100019
*                                                                       68200019
*           ROUTINE TO ENQUEUE MESSAGE FOR USER                         68300019
*                                                                       68400019
*********************************************************************** 68500019
FLGLST   O     REG1,HIBIT               NO INSERTION- SET HIGH BIA34581 68600020
ENQRTN0  LA    REG6,RETCD0               RETURN CODE 0                  68700019
ENQMSG   TM    EPTFLG,PPTEXC            IS THIS EXEC                    68800019
         BZ    ENQMSG3                  BR= NO                          68900019
         LA    REG6,RETCD24             EXEC- SET RETURN CODE           69000019
ENQMSG3  LA    REG14,TUBUSRID                                           69100019
ENQMSGC  ST    REG14,TUBPARM2           PARAMETER 2- USERID OR ZEROES   69200019
         ST    REG1,TUBPARM3            PARAMETER 3- MSG NUMBER         69300019
         LA    REG15,MSGINS                                             69700019
         ST    REG15,TUBPARM4           PARAMETER 4- INSERT             69800019
ENQMSG2  TM    EDTSW,EDTNCLS            SHOULD CLOSE BE DONE            70500019
         BO    GETMSG                   BR= NO                          70600019
         BAL   REG3,SUBCLOSE            GO CLOSE IF NECESSARY           70700019
         OI    EPTFLG,PPTERR            SET FLAG - ERROR         A34581 70750020
GETMSG   L     REG15,IHKYYMSG           IHKMSG - FOR CENTRAL     A34581 70820020
         TM    EDTSW,EDTMSGC                                            70900019
         BO    ENQMSG4                  BR = MSG FOR CENTRAL     A34581 70980020
         L     REG15,IHKYMSG1           ENTRY- IHKMSG01          A34581 71060020
         OI    TUBPARM4,ENDLST          ONE INSERTION            A34581 71140020
ENQMSG4  NI    EDTSW,EDTMSGCF           TURN OFF SWITCH FOR CENTRA34581 71220020
         ST    RTUB,TUBPARM1            PARAMETER 1 - TUB        A34581 71300020
         LA    REG1,TUBPARM1                                            71400019
         BALR  REG14,REG15              ENQUEUE MESSAGE                 71500019
         B     *+4(REG15)               TEST RETURN CODE                71600019
         B     0(REG6)                  0   SUCCESSFUL                  71700019
         B     0(REG6)                  4   NOT USED                    71800019
         B     RETCD                    8   GETMAIN FAILURE             71900019
         B     RETCD                    12 I/O ERROR                    72000019
         B     RETCD                    16 MESSAGE LOST                 72100019
         B     RETCD                    20 AA OUT OF SPACE              72200019
         B     0(REG6)                  24 INVALID USERID               72300019
         EJECT                                                          72400019
*********************************************************************** 72500019
*   SUBROUTINE TO CLOSE  IF NECESSARY                                   72600019
*********************************************************************** 72700019
SUBCLOSE TM    EDTSW,EDTCLS             SHOULD CLOSE BE DONE            72800019
         BZ    CLOSRTN                  BR= NO                          72900019
         LA    REG1,ADDRTUB(REG13)                                      73000019
         TM    EDTSW,EDTCRJNO           WAS THIS NON-CRJE DATASET       73100019
         BZ    CLOSE                    BR=NO                           73200019
         L     REG4,TUBDIRAD                                            73300019
         LTR   REG4,REG4                IS THERE A DIRECTORY            73400019
         BZ    CLOSE                    BR= NO                          73500019
         MVC   BPBLDLST+4(DIRSIZE),0(REG4) SAVE DIRECTORY               73600019
CLOSE    RCLOSE                                                         73700019
RCLOS2   NI    EDTSW,EDTCLSF            TURN OFF CLOSE SWITCH           73800019
         LR    REG9,REG3                                                73900019
         B     CLOSRTN(REG15)                                           74000019
CLOSRTN  B     0(REG3)                  0   SUCCESSFUL                  74100019
         B     0(REG9)                  4   EOV                         74200019
         B     CKCLOS                   8   GETMAIN FAIL                74300019
         B     DSKERRF                  12  I/O ERROR                   74400019
         B     DIRFULL                  16  DIRECTORY FULL       A34581 74500020
*********************************************************************** 74600019
*   RETURN ROUTINES                                                     74700019
*********************************************************************** 74800019
GMERR    LA    REG15,RTRN8              SAVEAREA GETMAIN FAILURE        74900019
         B     RETURN4                                                  75000019
RETCD8   LA    REG8,RTRN8               DIRECTORY ENTRY GETMAIN FAIL    75100019
         B     RETURN                                                   75200019
         SPACE 2                                                        75300019
RETCD24  LA    REG8,RTRN24                                              75400019
         B     RETURN                                                   75500019
*                                                                       75600019
*   GETMAIN FAIL- CHECK IF RETURN FROM RFIND                            75700019
*                                                                       75800019
CKCLOS   LA    REG1,GETDIR                                              75900019
         CR    REG1,REG3                                                76000019
         BNE   RETCD                                                    76100019
         NI    EDTSW,EDTCLSF            IS FROM RFIND- DO NOT CLOSE     76200019
RETCD    LR    REG8,REG15               SAVE RETURN CODE                76300019
         B     RETURN                                                   76400019
         EJECT                                                          76500019
*********************************************************************** 76600019
*                                                                       76700019
*   GET CORE                                                            76800019
*                                                                       76900019
*********************************************************************** 77000019
         DROP REG4                                                      77100019
SUBRGETM LA    REG4,TUBPARM4                                            77200019
         L     REG1,IHKYYGML                                            77300019
         GETMAIN EC,LV=(REG5),A=(REG4),MF=(E,(1))                       77400019
         LTR   REG15,REG15                                              77500019
         BNZ   0(REG8)                                                  77600019
GETMRTN  BR    REG6                                                     77700019
*********************************************************************** 77800019
*                                                                       77900019
*   GENERAL RETURN FROM AFIO                                            78000019
*                                                                       78100019
*********************************************************************** 78200019
AFIRTN   B     0(REG3)                  0   SUCCESSFUL                  78300019
         B     0(REG9)                  4  EOD OR AA OUT OF SPACE       78400019
         B     RETCD                    8 GETMAIN FAIL                  78500019
         B     RETCD                    12 I/O ERROR                    78600019
         EJECT                                                          78700019
*********************************************************************** 78800019
*    RETURN TO CALLER                                                   78900019
*********************************************************************** 79000019
RETCD0   LA    REG8,0                   RETURN CODE 0                   79100019
RETURN   BAL   REG3,SUBCLOSE            GO CLOSE IF NECESSARY           79200019
CKEDTREL TM    EDTSW,EDTREL             WAS ACTIVE AREA CREATED         79300019
         BZ    RETURN1                  BR= NO                          79400019
         TM    EPTFLG,PPTERR            WAS THERE AN ERROR              79500019
         BO    FREEDIR                  BR= YES                         79600019
         LTR   REG8,REG8                CHECK FOR ERROR RETURN          79700019
         BZ    ENDUP                    BR= NOT ERROR RETURN            79800019
*********************************************************************** 79900019
*                                                                       80000019
*   ACTIVE AREA CREATED                                                 80100019
*   ERROR RETURN CODE OR ERROR                                          80200019
*    FREE DIRECTORY IF THERE IS ONE AND RELEASE ACTIVE AREA             80300019
*                                                                       80400019
*********************************************************************** 80500019
FREEDIR  LA    REG0,DIRSIZE                                             80600019
         L     REG1,TUBDIRAD                                            80700019
         LA    REG1,0(REG1)                                             80800019
         TM    EDTSW,EDTDIR             TEST FOR DIRECTORY ENTRY        80900019
         BZ    RELESE                   BR= NO DIRECTORY                81000019
         FREEMAIN R,LV=(0),A=(1)        FREE DIRECTORY                  81100019
         SR    REG1,REG1                                                81200019
         ST    REG1,TUBDIRAD                                            81300019
RELESE   LA    REG1,ADDRTUB(REG13)                                      81400019
         RELEASE A                      FREE UP ACTIVE AREA             81500019
         B     RELRTN(REG15)                                            81600019
RELRTN   B     RETURN1                  0   SUCCESSFUL                  81700019
         B     RETURN1                  4   NOT USED                    81800019
         B     SETRETCD                 8   GET MAIN FAIL               81900019
SETRETCD LR    REG8,REG15               12 I/O ERROR                    82000019
         B     RETURN1                                                  82100019
*********************************************************************** 82200019
*                                                                       82300019
*   ACTIVE AREA CREATED- NO ERRORS, ENDUP                               82400019
*                                                                       82500019
*********************************************************************** 82600019
ENDUP    LA    REG1,ADDRTUB(REG13)                                      82700019
         ENDUP                                                          82800019
         B     RELRTN(REG15)                                            82900019
*********************************************************************** 83000019
*                                                                       83100019
*   IF EDIT, CHECK FOR ERROR RETURN OR ERROR- IF SO, TURN OFF EDIT BITS 83200019
*                                                                       83300019
*********************************************************************** 83400019
RETURN1  TM    EPTFLG,PPTEXC            IS THIS EXEC                    83500019
         BO    RETURN2                  BR= YES                         83600019
         LTR   REG8,REG8                IS IT ERROR RETURN              83700019
         BNZ   TURNOFF                  BR= YES                         83800019
         TM    EPTFLG,PPTERR            WAS ERROR MADE                  83900019
         BZ    RETURN2                  BR= NO                          84000019
TURNOFF  NI    TUBFLG1,TUBFLG1F         TURN OFF ANY BITS SET- EDIT     84100019
         NI    TUBFLG2,TUBFLG2F                                         84200019
RETURN2  L     REG7,4(REG13)            SAVE CALLERS SAVEAREA           84300019
         LA    REG0,GMLEN                                               84400019
         LR    REG1,REG13                                               84500019
         FREEMAIN R,LV=(0),A=(1)        FREE SAVEAREA                   84600019
         LR    REG13,REG7                                               84700019
         LR    REG15,REG8                                               84800019
RETURN4  RETURN (14,12),,RC=(15)                                        84900019
         EJECT                                                          85000019
*********************************************************************** 85100019
*   MESSAGE CODES                                                       85200019
*********************************************************************** 85300019
         DS    0F                                                       85400019
DERRCDC  DC    X'0',C'241'                                              85500019
UIDINUCD DC    X'0',C'333'              USERID INVALID                  85600019
NFNDCD   DC    X'0',C'338'              DS NOT FOUND                    85700019
MBLKEXC  DC    X'0',C'345'              INITIAL BLOCKS EXCEEDED-EXEC    85800019
MAAOUT   DC    X'0',C'357'              ACTIVE AREA OUT OF SPACE        85900019
ATTINVCD DC    X'0',C'360'              ATTRIBUTE INVALID- SCAN         86000019
INVKEYCD DC    X'0',C'369'              KEY INVALID                     86100019
INOPMSG  DC    X'0',C'370'              LIBRARY INOPERATIVE             86200019
EXCATR   DC    X'0',C'371'              ATTRIBUTE INVALID- EXEC         86300019
NODDCDCD DC    X'0',C'375'              NO DD CARD                      86400019
MEDTREQ  DC    X'0',C'393'              EDIT OF DATASET REQUIRED        86500019
INVALNUM DC    X'0',C'402'              LINE NUMBER NOT X OR NUMERIC    86600019
MDIRFULL DC    X'0',C'413'                                       A34581 86650020
*********************************************************************** 86700019
*                                                                       86800019
*   CONSTANTS                                                           86900019
*                                                                       87000019
*********************************************************************** 87100019
ZEROES   DC    F'0'                                                     87200019
HIBIT    DC    X'80000000'                                       A34581 87250020
XXX      DC    C'XXXXXXXX'                                              87300019
BLANKS   DC    CL3' '                                                   87400019
         SPACE 1                                                        87500019
*********************************************************************** 87600019
*   SAVEAREA, SWITCHES                                                  87700019
*********************************************************************** 87800019
OSDSECT  DSECT                                                          88000019
SAVEA    DS    18F                                                      88100019
ADDRTUB  EQU   X'40'                    TUB BASE REGISTER        A34581 88200020
KEYSTO   DS    F                        PROTECTION KEY                  88300019
MSGINS1  DS    CL9                      INSERT AREA FOR MSG             88400019
MSGINS   DS    CL9                      INSERT AREA FOR MSG             88500019
EPTFLG   DS    X                        FLAG PASSED IN PPT              88600019
EPTNUM   EQU   X'80'                    SEND INVALID LINE NUM MSG ONCE  88650019
PPTDEL   EQU   X'40'                    DELETE COMMAND                  88700019
PPTEXC   EQU   X'20'                    EXEC COMMAND                    88800019
PPTEXCF  EQU   X'DF'                                                    88900019
PPTERR   EQU   X'01'                    ERROR MSG HAS BEEN ENQUEUED     89000019
PPTNOERR EQU   X'FE'                                                    89100019
EDTSW    DS    X                                                        89500019
EDTCRJNO EQU   X'80'                    NON-CRJE DATASET                89600019
EDTNUM   EQU   X'40'                    EXEC ONLY- LINE NUMBERED DS     89700019
EDTDIR   EQU   X'40'                    EDIT ONLY- DIRECTORY            89800019
EDTMSGC  EQU   X'20'                    MESSAGE FOR CENTRAL             89900019
EDTMSGCF EQU   X'DF'                                                    90000019
EDTIOER  EQU   X'10'                    I/O ERROR                       90200019
EDTCLS   EQU   X'04'                    CLOSE IS NECESSARY              90500019
EDTCLSF  EQU   X'FB'                                                    90600019
EDTREL   EQU   X'02'                    ACTIVE AREA IS CREATED          90700019
EDTNCLS  EQU   X'01'                    CLOSE IS NOT TO BE DONE         90800019
EDTOFF   EQU   X'00'                                                    91000019
*                                                                       91100019
*   SWITCHES PASSED IN PPT                                              91200019
*                                                                       91300019
SWDEF    DS    0CL4                                                     91400019
SWDEFEDT DS    X                                                        91500019
SWDEFATT DS    X                                                        91600019
SWDEFBSM DS    X                                                        91700019
SWDEFESM DS    X                                                        91800019
         SPACE 1                                                        91900019
OPRSW    DS    X                                                        92000019
OPRNUM   EQU   X'40'                                                    92100019
OPRNONUM EQU   X'BF'                                                    92200019
OPRATT   EQU   X'02'                                                    92300019
GMLEN    EQU   *-OSDSECT                                                92400019
*                                                                       92500019
*   EXEC GETMAIN AREA                                                   92600019
*                                                                       92700019
EXECDSCT DSECT                                                          92800019
EXDSNAM  DS    D                                                        92900019
EXUSRID  DS    D                                                        93000019
EXBLKNUM DS    H                                                        93100019
EXRECNUM DS    H                                                        93200019
EXKEY    DS    F                                                        93300019
EXMAXBLK DS    H                                                        93400019
         DS    CL6                FILL OUT TO DOUBLE WORD               93500019
         IHKCDSCT TUB=YES,DIR=YES,AVT=YES,DEF=YES,PPT=YES               93700019
         CMDEQU                                                         93800019
         TUBEQU                         EQUATES FOR TUB                 93900019
         RAFKNBX TYPE=DSECT             RAFIO KONBOX                    94000019
         END                                                            94100019
