EDT      TITLE 'IHKEDT - EDIT AND DELETE(MAJOR) COMMAND PROCESSORS'     00100019
IHKEDT   CSECT                                                          00200019
*A123200,280600,335000,346000,849000,850000                      A43955 00230021
*********************************************************************** 00260021
*STATUS -- CHANGE LEVEL 0                                             * 00300019
*FUNCTION -- EDIT, DELETE, AND EXEC COMMANDS PROCESSOR                * 00400019
*   CHECKS OPERANDS AND ON ANY ERRORS QUEUES MESSAGE, CONTINUES       * 00500019
*   CHECKING, AND RETURNS TO CALLER.  ALL THREE COMMANDS MUST HAVE    * 00600019
*   AT LEAST ONE OPERAND, THE DSNAME, WHICH IS CHECKED FOR LENGTH     * 00700019
*   AND ALPHABETIC FIRST CHARACTER.  OS DATASETS ARE INDICATED BY     * 00800019
*   QUOTES AROUND THE DSNAME.                                         * 00900019
*                                                                     * 01000019
*   DELETE- THE ONLY VALID OPERAND IS THE DSNAME.  OS DATASETS TO BE  * 01100019
*   DELETED MUST BEGIN WITH THE USERID OF THE TERMINAL USER.  IHKEDT  * 01200019
*   PASSES CONTROL TO IHKEOS TO DELETE AN OS DATASET, AND TO IHKED1   * 01300019
*   TO DELETE A CRJE DATASET.                                         * 01400019
*                                                                     * 01500019
*   EXEC- THE ONLY OTHER VALID OPERAND IS L(IST) OR NOL(IST).  FOR A  * 01600019
*   VALID EXEC, IHKEDT INITIALIZES THE GETMAIN AREA TO CONTAIN THE    * 01700019
*   DSNAME, USERID, KEY, RECORD AND BLOCK NUMBERS AND SETS TO ZERO THE  01800019
*   ORIGINAL NUMBER OF BLOCKS.  IHKEDT STORES THE ADDRESS AND LENGTH    01900019
*   OF THIS AREA IN THE TUB, AND PASSES CONTROL TO IHKED1               02000019
*                                                                     * 02100019
*   EDIT- FOR A VALID EDIT, IHKEDT TURNS ON THE BITS IN THE TUB, AS   * 02200019
*   SPECIFIED BY THE OPERANDS, AND TURNS ON THE EDIT BIT.  EDIT IS NOT* 02300019
*   ALLOWED OF ANOTHER USERS DATASET NAMED ACTIVE OR OF ANY OS DATASET  02400019
*   BEGINNING WITH 'CRJE'.  FOR EDIT OF A NEW DATASET, CONTROL IS       02500019
*   PASSED TO IHKIRL.  FOR EDIT OF AN OS DATASET CONTROL IS PASSED TO   02600019
*   IHKEOS, AND FOR EDIT OF AN OLD DATASET CONTROL IS PASSED TO IHKED1. 02700019
*                                                                     * 02800019
*ENTRY POINT --                                                       * 02900019
*        IHKEDT IS THE ONLY ENTRY POINT.  AT ENTRY REGISTER ONE MUST  * 03000019
*        POINT TO A TWO WORD AREA CONTAINING THE ADDRESSES OF THE     * 03100019
*        TUB AND THE AVT.                                             * 03200019
*                                                                     * 03300019
*INPUT --                                                             * 03400019
*   PPT CONTAINS THE OPERANDS.                                        * 03500019
*                                                                     * 03600019
*OUTPUT -- NONE.                                                      * 03700019
*                                                                     * 03800019
*EXTERNAL REFERENCES --                                               * 03900019
*        IHKAVT- CONTAINS ADDRESSES.                                  * 04000019
*        IHKDEF- DEFAULTS FOR EXEC AND EDIT.                          * 04100019
*        IHKGML- GETMAIN LIST                                         * 04200019
*        IHKMSG- ENTRY IHKMSG01- QUEUE ERROR MESSAGES.                * 04300019
*                                                                     * 04400019
*EXITS, NORMAL --                                                       04500019
*        REGISTER 15= MINUS CODE OF MODULE TO BE LOADED.              * 04600019
*                                                                     * 04700019
*EXITS, ERROR --                                                      * 04800019
*        REGISTER 15= 0  ERROR MESSAGE QUEUED.                        * 04900019
*        REGISTER 15= 8  GETMAIN FAILURE                              * 05000019
*        REGISTER 15= 12 ACTIVE AREA I/O ERROR                        * 05100019
*        REGISTER 15= 16 MESSAGE LOST                                 * 05200019
*        REGISTER 15= 20 ACTIVE AREA OUT OF SPACE                     * 05300019
*                                                                     * 05400019
*TABLES, WORK AREAS --                                                * 05500019
*   SAVE AREA                                                         * 05600019
*   CMDEQU- USED FOR COMMAND CODES.                                   * 05700019
*   PPT-  PPTFLG SET FOR IHKED1, IHKIRL, IHKEOS.                      * 05800019
*   PPTPARS- SWITCHES STORED FOR IHKED1, IHKEOS.                        05900019
*   TUB-                                                              * 06000019
*   TUBPARM1- TUBPARM5 USED FOR PARAMETER LIST FOR IHKMSG01.          * 06100019
*   TUBEXCAD- SET TO ADDRESS OF EXEC GETMAIN AREA.                      06200019
*   TUBEXCLG- SET TO LENGTH OF EXEC AREA.                             * 06300019
*   TUBFLG1- TUBSCN, TUBFOR, TUBPL1 - SET AS SPECIFIED.               * 06400019
*   TUBFLG2- TUBEXLST, TUBEDIT, TUBLNUM - SET AS SPECIFIED.           * 06500019
*   TUBFLG3- TUBLNPNT - SET FOR EDIT.                                   06600019
*   TUBPMFNM- DSNAME FOR NON-OS DATASET.                                06700019
*   TUBUSRNM- USERID OF TERMINAL USER OR AS SPECIFIED.                * 06800019
*                                                                     * 06900019
*   USER BUFFER -- DSNAME, KEY, OR MEMBER NAME FOR IHKED1, OR IHKEOS. * 07000019
*                                                                     * 07100019
*ATTRIBUTES -- RE-ENTRANT, NON-RESIDENT, REFRESHABLE.                 * 07200019
         EJECT                                                          07300019
*********************************************************************** 07400019
*                                                                       07500019
*   REGISTER EQUATES                                                    07600019
*                                                                     * 07700019
*********************************************************************** 07800019
REG0     EQU   0                                                        07900019
REG1     EQU   1                                                        08000019
RTUB     EQU   2                  TUB BASE                              08100019
REG3     EQU   3                  PPT BASE                              08200019
REG4     EQU   4                  WORK REGISTER                         08300019
REG5     EQU   5                  WORK REGISTER                         08400019
REG6     EQU   6                  INTERNAL LINKAGE                      08500019
RBUFR    EQU   7                  USER BUFFER BASE                      08600019
REG8     EQU   8                  WORK REGISTER                         08700019
ROPR     EQU   9                  POINTS TO OPERAND                     08800019
REGRTN   EQU   10                 INTERNAL LINKAGE                      08900019
RBASE    EQU   11                 IHKEDT BASE                           09000019
RAVT     EQU   12                 AVT BASE                              09100019
REG13    EQU   13                                                       09200019
REG14    EQU   14                                                       09300019
REG15    EQU   15                                                       09400019
*********************************************************************** 09500019
*                                                                       09600019
*   OTHER EQUATES                                                       09700019
*                                                                       09800019
*********************************************************************** 09900019
RTRN8  EQU   8                    GETMAIN FAIL RETURN CODE              10000019
RTRN16   EQU   16                 MESSAGE LOST RETURN CODE              10100019
LASTOPR  EQU   X'FF'              NO MORE OPERANDS IN PPT               10200019
X0A      EQU   10                       MAX INSERT SIZE FOR MSGS        10300019
LPAREN   EQU   C'('               LEFT PAREN                            10400019
RPAREN   EQU   C')'               RIGHT PAREN                           10500019
PERIOD   EQU   C'.'               PERIOD                                10600019
QUOTE    EQU   C''''              QUOTE- INDICATES OS                   10700019
ENDLST   EQU   X'80'              FLAG FOR LAST PARAMETER               10800019
BLK      EQU   X'40'              BLANK                                 10900019
KEYLNGTH EQU   2                  KEYLENGTH MINUS 1                     11000019
OSDSNL   EQU   X'2B'              OS DATASET NAME LENGTH MINUS 1        11100019
NAMLNG   EQU   X'07'              DSNAME LENGTH MINUS 1                 11200019
USRIDLNG EQU   X'06'              USERID LENGTH MINUS 1                 11300019
MEMLNG   EQU   X'07'              MEMBER NAME LENGTH MINUS 1            11400019
X00      EQU   X'00'                                                    11500019
X1       EQU   1                                                        11600019
X2       EQU   X'02'                                                    11700019
X3       EQU   3                                                        11800019
X5       EQU   5                                                        11900019
X6       EQU   6                                                        12000019
DEC72    EQU   72                                                       12100019
EIGHTY   EQU   80                                                       12200019
C$       EQU   C'$'                                                     12240019
C#       EQU   C'#'                                                     12280019
C@       EQU   C'@'                                                     12320019
CHYPHEN  EQU   C'-'                                              A43955 12340021
CA       EQU   C'A'                                                     12360019
CZ       EQU   C'Z'                                                     12400019
CPERIOD  EQU   C'.'                                                     12440019
HEXF0    EQU   X'F0'                                                    12500019
         EJECT                                                          12600019
*********************************************************************** 12700019
*                                                                       12800019
*   SET UP BASE REGISTERS AND SAVEAREA                                  12900019
*                                                                       13000019
*********************************************************************** 13100019
         USING IHKEDT,RBASE                                             13200019
         USING VDSECT,REG13                                             13300019
         USING TUBDSECT,RTUB                                            13400019
         USING AVTDSECT,RAVT                                            13500019
         USING PPTDSECT,REG3                                            13600019
         USING USRBUFR,RBUFR                                            13700019
         SAVE  (14,12),,IHKEDT-4/23/70                                  13800019
         LR    RBASE,REG15        SET UP BASE                           13900019
         L     RTUB,0(REG1)       SET UP TUB BASE REG                   14000019
         L     RAVT,4(REG1)       PICK UP AVT ADDRESS                   14100019
         LA    REG6,GMLEN1        AREA WITHOUT EXEC                     14200019
         LA    REG5,TUBPARM1                                            14300019
         L     REG1,IHKYYGML                                            14400019
         L     REG3,TUBPPTAD                                            14500019
         CLI   PPTCMD,CMDDOO      IS THIS EXEC COMMAND                  14600019
         BNE   GETM               BR= NO                                14700019
         LA    REG6,GMLEN         YES- GETMAIN FOR EXEC AREA            14800019
GETM     GETMAIN EC,LV=(REG6),A=(REG5),MF=(E,(1))                       14900019
         B     *+4(REG15)                                               15000019
         B     GMGOOD             GETMAIN SUCCESSFUL                    15100019
         B     GMERR              GETMAIN FAIL                          15200019
*********************************************************************** 15300019
*                                                                       15400019
*   GETMAIN SUCCESSFUL                                                  15500019
*                                                                       15600019
*********************************************************************** 15700019
GMGOOD   L     REG1,TUBPARM1                                            15800019
         ST    REG13,4(REG1)      SAVE SAVEAREA ADDRESS                 15900019
         ST    REG1,8(REG13)      SAVE GETMAIN IN CALLERS               16000019
         LR    REG13,REG1                                               16100019
         L     RBUFR,TUBUFFAD     USER BUFFER BASE                      16200019
         NI    EDTSW,EDTOFF       TURN OFF ALL SWITCHES                 16300019
         NI    OPRSW,OPROFF                                             16400019
         USING DEFDSECT,REG4                                            16500019
         L     REG4,IHKYYDEF                                            16600019
         MVC   PPTFLG(1),DEFDEL   MOVE DELETE DEFAULT                   16700019
         MVC   SWDEF,DEFEDIT      MOVE EDIT DEFAULT                     16800019
         MVC   TUBUSRNM,TUBUSRID  STORE USERS USERID                    16900019
         LA    REGRTN,INCREOPR    MSG WRITER SUBR WILL RETURN HERE      17000019
         CLI   PPTCMD,CMDEDT      IS IT EDIT COMMAND                    17100019
         BE    SETEDT             BR=YES                                17200019
         CLI   PPTCMD,CMDDEL      IS IT DELETE                          17300019
         BE    SETDEL             BR= YES                               17400019
         CLI   PPTCMD,CMDDOO      IS IT EXECUTE                         17500019
         BNE   RETURN             BR= NO, RETURN                        17600019
SETEXC   MVC   SWDEF(1),DEFEXEC   IS EXEC, SAVE DEFAULT                 17700019
         OI    PPTFLG,PPTEXC      SET EXEC SWITCH                       17800019
         B     INIROPR            GO PICK UP FIRST OP                   17900019
SETDEL   OI    PPTFLG,PPTDEL      SET DELETE SWITCH                     18000019
         B     INIROPR            GO PICK UP FIRST OP                   18100019
SETEDT   OI    PPTFLG,PPTEDT      SET EDIT SWITCH                       18200019
         B     INIROPR            GO PICK UP FIRST OP                   18300019
         DROP  REG4                                                     18400019
*********************************************************************** 18500019
*                                                                       18600019
*   PICK UP NEXT OPERAND                                                18700019
*                                                                       18800019
*********************************************************************** 18900019
INCREOPR IC    REG5,0(ROPR)       LENGTH OF OPERAND                     19000019
         LA    ROPR,1(ROPR)       BEGIN OF OP                           19100019
         AR    ROPR,REG5          BEGINNING OF NEXT- COUNT              19200019
         B     TSTLAST            GO CHECK FOR MORE OP                  19300019
TSTCONT  IC    REG14,PPTFLG       SAVE FLAG                             19400019
         L     REG3,PPTCHAD       CHECK FOR ANOTHER PPT                 19500019
         LA    REG3,0(REG3)       CLEAR HIGH ORDER BYTE                 19600019
         LTR   REG3,REG3                                                19700019
         BZ    PROCESS            BR = NO MORE PPTS                     19800019
         STC   REG14,PPTFLG       SAVE FLAG IN THIS PPT                 19900019
INIROPR  LA    ROPR,PPTPARS       UPDATE TO BEGIN OF OP                 20000019
TSTLAST  TM    0(ROPR),LASTOPR    CHECK FOR NO MORE OPERANDS            20100019
         BO    TSTCONT            BR= NO MORE, GO LOOK FOR NEXT PPT     20200019
         LA    REG5,SUBOPRF                                             20300019
         IC    REG1,0(ROPR)                                             20400019
         NR    REG5,REG1          OMIT SUBOP BITS IF ANY                20500019
         BCTR  REG5,0             CONTAINS OP LENGTH - ONE              20600019
         LA    REG6,INCREOPR      WILL RETURN FOR NEXT OP               20700019
         TM    0(ROPR),SUBPAREN   CHECK FOR SUBOPERAND                  20800019
         BZ    NOTSUB             BR = NOT SUBOPERAND                   20900019
*********************************************************************** 21000019
*                                                                       21100019
*   PROCESS SUBOPERAND                                                  21200019
*                                                                       21300019
*********************************************************************** 21400019
         NI    0(ROPR),SUBOPRF    TURN OFF SUBOP BIT                    21500019
         TM    EDTSW,EDTSUB       IS SUBOP EXPECTED                     21600019
         BZ    SUBERR             BR=NO                                 21700019
         TM    SWDEFATT,DEFPL1    HAS PL1 BEEN FOUND                    21800019
         BO    PL1SUBOP           BR= YES, MUST BE PL/1 SUBOP           21900019
         TM    EDTSW,EDTUID       TEST FOR USERID PROCESSED             22000019
         BO    TSTKEY             BR= IT HAS, GO TEST KEY               22100019
         OI    EDTSW,EDTUID       SET SWITCH FOR USERID                 22200019
         LA    REG1,TUBUSRNM      WHERE NAME WILL BE STORED             22300019
         MVI   TUBUSRNM+7,BLK                                           22400019
         LA    REG15,USRIDLNG     USERID LENGTH                         22500019
         B     CKNAM1             GO CHECK LENGTH AND STORE             22600019
TSTKEY   OI    PPTFLG,PPTKEY      SET SWITCH FOR KEY                    22700019
         NI    EDTSW,EDTSUB12     NO MORE SUBOPERANDS                   22800019
         LA    REG15,KEYLNGTH     KEY LENGTH                            22900019
         LA    REG1,USRKEY        STORE KEY IN USER BUFFER              23000019
         B     CKNAM1             GO CHECK LENGTH AND STORE             23100019
*********************************************************************** 23200019
*                                                                       23300019
*           TEST OTHER EDIT OPERANDS                                    23400019
*                                                                       23500019
*********************************************************************** 23600019
NOTSUB   NI    EDTSW,EDTSUB12     TURN OFF SUBOP EXPECTED BIT           23700019
         TM    EDTSW,EDTDSNM      HAS DSNAME BEEN FOUND                 23800019
         BZ    CKDSNAME           BR= NO, ASSUME THIS IS DSNAME         23900019
         TM    PPTFLG,PPTDEL      IS THIS DELETE COMMAND                24000019
         BO    EXCESS             BR= YES, EXCESS OP                    24100019
         CLI   0(ROPR),X1                                               24200019
         BE    TSTOPER1           BR= LENGTH IS 1                       24300019
         CLI   0(ROPR),X3                                               24400019
         BE    TSTOPER3           BR= LENGTH OF 3                       24500019
         BL    OPRERR             BR= LENGTH OF 2                       24600019
         CLI   0(ROPR),X5                                               24700019
         BE    TSTOPER5           BR= LENGTH 5                          24800019
         BL    TSTOPR4            BR = OPERAND LENGTH OF 4              24900019
         CLI   0(ROPR),X6                                               25000019
         BE    TSTOPER6           BR= LENGTH 6                          25100019
         B     OPRERR             IS INVALID OP                         25200019
*********************************************************************** 25300019
*                                                                       25400019
*   CHECK FOR DS NAME                                                   25500019
*                                                                       25600019
*********************************************************************** 25700019
CKDSNAME OI    EDTSW,EDTDSNM      INDICATES DS NAME FOUND               25800019
         CLI   1(ROPR),QUOTE      IS FIRST CHAR QUOTE                   25900019
         BE    OSDSPROC           BR= YES, IS OS DATASET                26000019
         TM    PPTFLG,PPTDEL      IF NOT DELETE- SUBOP ALLOWED          26100019
         BO    LNAM               BR= DELETE, NO SUBOP ALLOWED          26200019
         OI    EDTSW,EDTSUB       SET SUBOP EXPECTED SWITCH             26300019
LNAM     LA    REG1,TUBPMFNM      WHERE NAME WILL BE STORED             26400019
         LA    REG15,NAMLNG       DATASET NAME LENGTH                   26500019
*********************************************************************** 26600019
*                                                                       26700019
*   SUBROUTINE- CHECKS FOR LENGTH, STORES NAME AND PADS WITH BLANKS     26800019
*                                                                       26900019
*********************************************************************** 27000019
CKNAM1   LA    REG4,1(ROPR)       FIRST CHAR OF NAME, USERID, OR KEY    27100019
CKNAM3   CR    REG5,REG15         IS IT TOO LONG                        27200019
         BH    OPRERR             IF TOO LONG SEND ERR MSG              27300019
         MVI   0(REG1),BLK        STORE BLANKS                          27400019
         BCTR  REG15,0                                                  27500019
         EX    REG15,MVCBLKS                                            27600019
         EX    REG5,MVCNAM        MOVE NAME                             27700019
         TM    PPTFLG,PPTKEY      IS THIS KEY                           27800019
         BO    CKNAMRTN           BR= YES                               27900019
         LR    REG15,REG5         LENGTH MINUS ONE OF OPERAND           27920019
         AR    REG15,REG4         POINT TO END OF NAME                  27940019
CKNAM2   CLI   0(REG15),C$                                              27960019
         BE    VALIDCHR           BR=IS DOLLAR SIGN                     27980019
         CLI   0(REG15),C@                                              28000019
         BE    VALIDCHR           BR= AT SIGN                           28020019
         CLI   0(REG15),C#                                              28040019
         BE    VALIDCHR           BR= POUND SIGN                        28060019
         SPACE 2                                                        28062021
         CLI   0(REG15),CHYPHEN                                  A43955 28064021
         BNE   TESTPRD            NO, TRY PERIOD                 A43955 28066021
         TM    PPTFLG,PPTOS       OS DATA SET?                   A43955 28068021
         BO    GETNEXT            YES, GO ON                     A43955 28070021
         TM    OPRSW,OPROSMEM     NO, MUST BE OS DATA SET MEMBER A43955 28072021
         BZ    OPRERR             NO, ERROR                      A43955 28074021
         B     GETNEXT            YES, GO ON                     A43955 28076021
         SPACE 2                                                        28078021
TESTPRD  CLI   0(REG15),CPERIOD   IS THIS A PERIOD                      28088021
*                                                                       28100019
         BNE   CKNAM5             BR= NO                                28120019
         TM    PPTFLG,PPTOS       IS PERIOD, MUST BE OS DATASET         28140019
         BZ    OPRERR             BR= NOT OS                            28160019
         B     GETNEXT                                                  28180019
*                                                                       28200019
CKNAM5   CLI   0(REG15),CA                                              28220019
         BL    OPRERR             BR= INVALID                           28240019
         CLI   0(REG15),CZ                                              28260019
         BH    CKNAM4             BR= CHECK NUMERIC                     28280019
*                                                                       28300019
VALIDCHR CR    REG15,REG4         WAS THIS FIRST CHAR                   28320019
         BNE   GETNEXT            BR = NO, CHECK NEXT                   28340019
CKNAMRTN BR    REG6                                                     28360019
CKNAM4   CR    REG15,REG4         IS THIS FIRST CHAR                    28380019
         BE    OPRERR             BR= YES, MUST BE ALPHA                28400019
GETNEXT  BCT   REG15,CKNAM2       GO GET NEXT CHAR                      28420019
*********************************************************************** 28500019
*                                                                       28600019
*   PROCESS OS DS NAME                                                  28700019
*                                                                       28800019
*********************************************************************** 28900019
OSDSPROC TM    PPTFLG,PPTEXC      IS THIS EXEC COMMAND                  29000019
         BO    OPRERR             BR = YES                              29100019
         LR    REG15,ROPR         LOC OF OPERAND                        29200019
         AR    REG15,REG5                                               29300019
         LA    REG4,2(ROPR)       POINT TO FIRST LETTER OF DSNAME       29400019
         CLI   0(REG15),RPAREN    TEST FOR MEMBER NAME                  29500019
         BE    CKDELB             BR= RIGHT PAREN, PROCESS MEMBER       29600019
STODSN   LA    REG1,USRDSNAM      DSNAME WILL BE STORED HERE            29700019
         BCTR  REG5,0                                                   29800019
         BCTR  REG5,0                                                   29900019
         LA    REG15,OSDSNL       DSNAME LENGTH                         30000019
         OI    PPTFLG,PPTOS       SET  OS FLAG                          30050019
         BAL   REG6,CKNAM3        GO CHECK LENGTH AND STORE             30100019
         TM    PPTFLG,PPTDEL      IS THIS DELETE                        30300019
         BZ    CKSYSLIB           BR= NO                                30400019
         LA    REG5,1(REG5)       YES, MUST BEGIN WITH USERID           30500019
         LA    REG14,TUBUSRID     CHECK FOR USERID AS FIRST PART        30600019
         LA    REG15,7                                                  30700019
COMPNXT  CLC   0(1,REG14),0(REG1)                                       30800019
         BNE   INVALNAM           DOES NOT MATCH- INVALID               30900019
         LA    REG14,1(REG14)                                           31000019
         LA    REG1,1(REG1)                                             31100019
         BCT   REG5,DECRUSR                                             31200019
         B     INCREOPR           ALL CHARACTERS EQUAL                  31300019
DECRUSR  CLI   0(REG14),BLK       HAS BLANK BEEN REACHED IN USERID      31350019
         BE    CKPERD             BR= YES, GO CHECK PERIOD              31400019
         BCT   REG15,COMPNXT                                            31450019
CKPERD   CLI   0(REG1),PERIOD     IS NEXT CHAR A PERIOD                 31500019
         BNE   INVALNAM           BR= NO, INVALID                       31600019
         B     INCREOPR                                                 31700019
CKSYSLIB CLC   CRJESYS,0(REG1)    IS EDIT- DOES NAME BEGIN WITH CRJE.   31800019
         BNE   INCREOPR           BR= NO, VALID                         31900019
         B     OPRERR             YES, NOT ALLOWED                      32000019
*********************************************************************** 32100019
*                                                                       32200019
*   PROCESS MEMBER NAME OF OS DATASET                                   32300019
*                                                                       32400019
*********************************************************************** 32500019
CKDELB   SR    REG5,REG5          SET LENGTH COUNT TO ZERO              32600019
PDSDSPR  BCTR  REG15,0            LOOK FOR LEFT PAREN                   32700019
         CLR   REG15,REG4         TEST FOR BEGINNING OF DSNAME          32800019
         BNH   OPRERR             BR= INVALID, NO LEFT PAREN            32900019
         LA    REG5,1(REG5)                                             33000019
         CLI   0(REG15),LPAREN    IS THIS LEFT PAREN                    33100019
         BNE   PDSDSPR            BR= NO                                33200019
         BCTR  REG5,0             LENGTH OF MEMBER NAME                 33300019
         LTR   REG5,REG5          IS THERE A MEMBER NAME                33400019
         BZ    OPRERR             BR= NO, INVALID                       33500019
         OI    OPRSW,OPROSMEM     PROCESSING OS DATA SET MEMBER  A43955 33550021
         BCTR  REG5,0             LENGTH MINUS ONE                      33600019
         LR    REG4,REG15         ADDRESS OF (                          33700019
         LA    REG4,1(REG4)       BEGINNING OF MEMBER NAME              33800019
         LA    REG1,USRMBER       WHERE MEMBER NAME WILL BE STORED      33900019
         LA    REG15,MEMLNG       LENGTH OF MEMBER NAME                 34000019
         BAL   REG6,CKNAM3        GO CHECK LENGTH AND STORE             34100019
         LA    REG8,2(ROPR)       BEGIN OF DS NAME                      34200019
         SR    REG4,REG8          LENGTH OF DSNAME                      34300019
         LR    REG5,REG4                                                34400019
         LA    REG4,2(ROPR)       BEGIN OF DS NAME                      34500019
         OI    PPTFLG,PPTMEMB     SET SWITCH- MEMBER NAME FOUND         34600019
         NI    OPRSW,MEMOFF       TURN OFF PROC OS DS MEMBER SW  A43955 34650021
         B     STODSN             GO PROCESS DS NAME                    34700019
*********************************************************************** 34800019
*                                                                       34900019
*           TEST OPERAND WITH A LENGTH OF 6                             35000019
*                                                                       35100019
*********************************************************************** 35200019
TSTOPER6 TM    PPTFLG,PPTEXC      IS IT EXEC                            35300019
         BO    CKNOLST            BR= YES, GO LOOK FOR NOLIST           35400019
         CLC   DSLIST,1(ROPR)     TEST FOR DSLIST                       35500019
         BE    SETDSL             BR= DSLIST                            35600019
CKNOS    LA    REG1,NOSCAN                                              35700019
         BAL   REG6,SUBRCLC       IS IT NOSCAN                          35800019
         NI    SWDEFEDT,DEFESCNF  YES, TURN OFF SCAN BIT                35900019
         B     CKSCAN                                                   36000019
*********************************************************************** 36100019
*                                                                       36200019
*   IS DSLIST                                                           36300019
*                                                                       36400019
*********************************************************************** 36500019
SETDSL   MVI   SWDEFATT,DEFADLST  SET ATTRIBUTE FOR DSLIST              36600019
*********************************************************************** 36700019
*                                                                       36800019
*   CHECK FOR OPERAND ALREADY PROCESSED                                 36900019
*                                                                       37000019
*********************************************************************** 37100019
CKATTR   LA    REG1,OPRATT        CHECK FOR ATTRIBUTE ALREADY           37200019
TESTOPR  IC    REG15,OPRSW        CHECK FOR SWITCH ALREADY SET          37300019
         NR    REG15,REG1                                               37400019
         LTR   REG15,REG15        IF NON-ZERO BIT ALREADY SET           37500019
         BNZ   OPRMERR            BR= ALREADY SET, INVALID              37600019
         IC    REG15,OPRSW                                              37700019
         OR    REG1,REG15                                               37800019
         STC   REG1,OPRSW         SET SWITCH                            37900019
         B     INCREOPR                                                 38000019
*********************************************************************** 38100019
*                                                                       38200019
*   EXEC COMMAND- MUST BE L(IST) OR NOL(IST)                            38300019
*                                                                       38400019
*********************************************************************** 38500019
CKNOLST  LA    REG1,NOLIST                                              38600019
         BAL   REG6,SUBRCLC       GO CHECK FOR NOLIST                   38700019
         NI    SWDEF,DEFELSTF     TURN OFF LIST- MAY HAVE BEEN DEF      38800019
CKLSTFND LA    REG1,OPRLIST       CHECK FOR LIST/NOLIST                 38900019
         B     TESTOPR                                                  39000019
CKLIST   LA    REG1,LIST                                                39100019
         BAL   REG6,SUBRCLC       GO CHECK FOR LIST                     39200019
         OI    SWDEF,DEFELST      IS LIST, SET BIT                      39300019
         B     CKLSTFND                                                 39400019
*********************************************************************** 39500019
*                                                                       39600019
*           TEST OPERAND WITH A LENGTH OF 1                             39700019
*                                                                       39800019
*********************************************************************** 39900019
TSTOPER1 TM    PPTFLG,PPTEXC      IF IS EXEC- GO LOOK FOR LIST          40000019
         BO    CKLIST                                                   40100019
         LA    REG1,SCAN          NOT EXEC                              40200019
         BAL   REG6,SUBRCLC       IS IT SCAN                            40300019
SETSCN   OI    SWDEFEDT,DEFESCAN  IS SCAN, SET BIT                      40400019
         OI    TUBFLG1,TUBSCN     SET SCAN BIT IN TUB                   40500019
CKSCAN   LA    REG1,OPRSCN        GO CHECK FOR SCAN/NOSCAN ALREADY      40600019
         B     TESTOPR                                                  40700019
*********************************************************************** 40800019
*                                                                       40900019
*           TEST OPERANDS WITH A LENGTH OF 3                            41000019
*                                                                       41100019
*********************************************************************** 41200019
TSTOPER3 TM    PPTFLG,PPTEXC      IF IS EXEC- GO LOOK FOR NOLIST        41300019
         BO    CKNOLST                                                  41400019
         CLC   PL1,1(ROPR)        NOT EXEC                              41500019
         BE    PL1PROC            BR = PL1                              41600019
         CLC   NUM,1(ROPR)        TEST FOR LINE NOS IN LINES            41700019
         BE    SETNUM             BR= NUM                               41800019
         CLC   OLD,1(ROPR)        TEST FOR EXISTING DS                  41900019
         BE    TSTOLD             BR= OLD                               42000019
         CLC   NEW,1(ROPR)        TEST FOR NEW DS                       42100019
         BNE   CKNOS              BR= NOT NEW, GO CHECK NOS(CAN)        42200019
*********************************************************************** 42300019
*   NEW DATASET                                                         42400019
*********************************************************************** 42500019
         TM    PPTFLG,PPTOS       TEST FOR OS DATASET                   42600019
         BO    OPRERR             BR= YES, INVALID                      42700019
         TM    EDTSW,EDTUID       TEST FOR OLD DS REQUESTED             42800019
         BO    OPRERR             BR= YES, INVALID                      42900019
         OI    SWDEFEDT,DEFENEW   SET SWITCH FOR NEW                    43000019
         B     TSTOLDA            GO CHECK FOR NEW/OLD ALREADY          43100019
*********************************************************************** 43200019
*   OPERAND IS NUM                                                      43300019
*********************************************************************** 43400019
SETNUM   OI    SWDEFEDT,DEFENUM   SET SWITCH FOR NUM                    43500019
         OI    TUBFLG2,TUBLNUMN   SET BIT IN TUB                        43600019
SETNUMA  LA    REG1,OPRNUM        CHECK FOR NUM/NONUM ALREADY           43700019
         B     TESTOPR                                                  43800019
*********************************************************************** 43900019
*   OPERAND IS OLD                                                      44000019
*********************************************************************** 44100019
TSTOLD   NI    SWDEFEDT,DEFENEWF  TURN OFF NEW SWITCH                   44200019
TSTOLDA  LA    REG1,OPRNWOD       CHECK FOR NEW/OLD ALREADY             44300019
         B     TESTOPR                                                  44400019
*********************************************************************** 44500019
*                                                                       44600019
*           TEST OPERANDS WITH A LENGTH OF 4                            44700019
*                                                                       44800019
*********************************************************************** 44900019
TSTOPR4  TM    PPTFLG,PPTEXC      IF IS EXECUTE- GO LOOK FOR LIST       45000019
         BO    CKLIST                                                   45100019
         CLC   DATA,1(ROPR)       NOT EXEC, IS IT DATA                  45200019
         BE    SETDATA            BR= DATA                              45300019
         CLC   TEXT,1(ROPR)       TEST FOR TEXT                         45400019
         BNE   TSTOPER1           BR= NOT TEXT, GO CHECK SCAN           45500019
*   TEXT OPERAND                                                        45600019
         MVI   SWDEFATT,DEFATEXT  SET TEXT ATTRIBUTE                    45700019
         B     CKATTR                                                   45800019
SETDATA  MVI   SWDEFATT,DEFADATA  SET DATA ATTRIBUTE                    45900019
         B     CKATTR                                                   46000019
*********************************************************************** 46100019
*                                                                       46200019
*           TEST OPERANDS WITH A LENGTH OF 5                            46300019
*                                                                       46400019
*********************************************************************** 46500019
TSTOPER5 TM    PPTFLG,PPTEXC      IF IS EXEC- ERROR                     46600019
         BO    OPRERR             BR= EXEC                              46700019
         CLC   CLIST,1(ROPR)      IS IT CLIST                           46800019
         BE    SETCLIST           BR= YES                               46900019
         CLC   NONUM,1(ROPR)      NO, IS IT NONUM                       47000019
         BNE   TSTFORT            BR= NO, GO CHECK FORTRAN              47100019
         NI    SWDEFEDT,DEFENUMF  TURN OFF NUM SWITCH                   47200019
         B     SETNUMA            GO CHECK FOR NUM/NONUM ALREADY        47300019
SETCLIST MVI   SWDEFATT,DEFACLST  SET CLIST ATTRIBUTE                   47400019
         B     CKATTR                                                   47500019
TSTFORT   CLC   FORTE,1(ROPR)     TEST FOR FORTRAN E                    47600019
         BE    SETFORTE           BR= YES                               47700019
          CLC   FORTG,1(ROPR) 1   TEST FOR FORTRAN G                    47800019
         BE    SETFORTG           BR= YES                               47900019
          CLC   FORTH,1(ROPR)     TEST FOR FORTRAN H                    48000019
         BNE   OPRERR             BR= NO, INVALID                       48100019
         MVI   SWDEFATT,DEFFORTH  FORTRAN H, SET ATTRIBUTE              48200019
SETFORT  OI    TUBFLG1,TUBFOR     SET FORTRAN BIT IN TUB                48300019
         B     CKATTR                                                   48400019
SETFORTE MVI   SWDEFATT,DEFFORTE  SET FORTRAN E ATTRIBUTE               48500019
         B     SETFORT                                                  48600019
SETFORTG MVI   SWDEFATT,DEFFORTG  SET FORTRAN G ATTRIBUTE               48700019
         B     SETFORT                                                  48800019
*********************************************************************** 48900019
*                                                                       49000019
*           PROCESS PL/1 ATTRIBUTE                                      49100019
*                                                                       49200019
*********************************************************************** 49300019
PL1PROC  OI    EDTSW,EDTSUB       SUBOP EXPECTED                        49400019
         MVI   SWDEFATT,DEFPL1    SET PL/1 ATTRIBUTE                    49500019
         OI    TUBFLG1,TUBPL1     SET PL/1 BIT IN TUB                   49600019
         B     CKATTR                                                   49700019
*********************************************************************** 49800019
*                                                                       49900019
*   PL/1 SUBOPERANDS                                                    50000019
*                                                                       50100019
*********************************************************************** 50200019
PL1SUBOP CLC   C603,0(ROPR)       IS IT C60                             50300019
         BE    PL1SET60           BR= YES                               50400019
         CLC   CHAR60,0(ROPR)     IS IT CHAR60                          50500019
         BE    PL1SET60           BR= YES                               50600019
         CLC   C483,0(ROPR)       IS IT C48                             50700019
         BE    PL1SET48           BR= YES                               50800019
         CLC   CHAR48,0(ROPR)     IS IT CHAR48                          50900019
         BE    PL1SET48           BR= YES                               51000019
         CLI   0(ROPR),X2         IS IT TOO LONG FOR SOURCE MARGIN      51100019
         BH    OPRERR             BR= YES, INVALID                      51200019
         TM    OPRSW,OPRPL1CH     HAS CHAR BEEN FOUND                   51300019
         BO    OPRERR             BR= YES, INVALID- MUST BE LAST        51400019
         TM    1(ROPR),HEXF0      TEST SOURCE MARGIN                    51500019
         BM    OPRERR             BR= NOT NUMERIC                       51600019
         LTR   REG5,REG5          IS MARGIN ONE DIGIT                   51700019
         BZ    EXPACK             BR= YES                               51800019
         TM    2(ROPR),HEXF0      NO, IS SECOND A DIGIT                 51900019
         BM    OPRERR             BR= NO                                52000019
EXPACK   EX    REG5,PACKSM        CONVERT TO BINARY SOURCE MARGIN       52100019
         CVB   REG6,PACKED                                              52200019
         LA    REG15,EIGHTY                                             52300019
         CLR   REG6,REG15         IS SOURCE MARGIN GREATER THAN 80      52400019
         BH    OPRERR             BR= YES                               52500019
         XR    REG15,REG15                                              52600019
         CLR   REG6,REG15         IS IT ZERO                            52700019
         BE    OPRERR             BR= YES, INVALID                      52800019
         TM    EDTSW,EDTSTCOL     HAS FIRST SOURCE MARGIN BEEN FOUND    52900019
         BO    PL1ENDSM           BR= YES, GO STORE ENDING              53000019
         TM    EDTSW,EDTENCOL     HAS ENDING SOURCE MARGIN BEEN FOUND   53100019
         BO    INVMARG            BR= YES, INVALID                      53200019
         STC   REG6,SWDEFBSM      STORE BEGINNING SOURCE MARGIN         53300019
         OI    EDTSW,EDTSTCOL     SET STARTING SOURCE MARGIN SWITCH     53400019
         B     INCREOPR           GO GET NEXT OP                        53500019
PL1ENDSM STC   REG6,SWDEFESM      STORE ENDING SOURCE MARGIN            53600019
         NI    EDTSW,EDTSTCLF     TURN OFF BEGINNING FOUND SWITCH       53700019
         OI    EDTSW,EDTENCOL     SET ENDING MARGIN FOUND SWITCH        53800019
         CLC   SWDEFBSM,SWDEFESM  TEST SOURCE MARGIN RANGE              53900019
         BNL   OPRERR             BR= RANGE INVALID                     54000019
         B     INCREOPR           GO GET NEXT OP                        54100019
PL1SET48 OI    SWDEFEDT,DEFPL148  SET 48 CHARACTER SET SWITCH           54200019
PL1SETCH LA    REG1,OPRPL1CH      CHECK FOR CHAR ALREADY                54300019
         B     TESTOPR                                                  54400019
PL1SET60 NI    SWDEFEDT,PL1OFF    IS 60 CHARACTER SET- TURN OFF 48      54500019
         B     PL1SETCH                                                 54600019
         EJECT                                                          54700019
*********************************************************************** 54800019
*                                                                       54900019
*   OPERANDS PROCESSED                                                  55000019
*   CALL NEXT MODULE IF NOT ERROR                                       55100019
*                                                                       55200019
PROCESS  L     REG3,TUBPPTAD      RESTORE PPT FLAG                      55300019
         STC   REG14,PPTFLG                                             55400019
         LA    REGRTN,RETCD0      WILL RETURN TO RETURN 0               55500019
         TM    EDTSW,EDTDSNM      WAS DSNAME FOUND                      55600019
         BZ    NOOPER             BR= NO                                55700019
         TM    EDTSW,EDTSTCOL     WAS FIRST SOURCE MARGIN BUT NOT LAST  55800019
         BO    INVMARG            BR= YES                               55900019
         TM    SWDEFEDT,DEFENUM   ARE LINE NUMBERS IN LINES             56000019
         BZ    CKERROR            BR= NONUM                             56100019
         CLI   SWDEFESM,DEC72     IS ENDING SOURCE MARGIN LESS THAN 72  56200019
         BH    INVMARG            BR= NO, INVALID WHEN LINE NOS IN LINE 56300019
CKERROR  TM    EDTSW,EDTERR       WAS THERE AN ERROR                    56400019
         BO    RETCD0             BR = YES- DO NOT CONTINUE             56500019
*********************************************************************** 56600019
*                                                                       56700019
*   NO ERRORS- PREPARE TO CALL NEXT MODULE                              56800019
*                                                                       56900019
*********************************************************************** 57000019
         MVC   PPTPARS(5),SWDEF   MOVE SWITCHES TO PPT                  57100019
         TM    PPTFLG,PPTEDT                                            57200019
         BO    PROCESSA           IS EDIT- GO SET FLAG                  57300019
         TM    PPTFLG,PPTEXC      IF IS EXEC-SET UP CORE                57400019
         BO    SETUPEXC           BR= EXEC                              57500019
         B     CKEOS              GO CHECK IF OS                        57600019
*********************************************************************** 57700019
*                                                                       57800019
*   SET UP CORE FOR EXECUTE                                             57900019
*                                                                       58000019
*********************************************************************** 58100019
SETUPEXC MVC   EXDSNAM,TUBPMFNM   DATASET NAME                          58200019
         MVC   EXUSRID,TUBUSRNM   OWNERS NAME                           58300019
         LA    REG1,X1                                                  58400019
         STH   REG1,EXRECNUM      FIRST RECORD TO BE READ               58500019
         STH   REG1,EXBLKNUM      FIRST BLOCK TO BE READ                58600019
         SR    REG1,REG1                                                58700019
         STH   REG1,EXMAXBLK      SET TO ZERO-ORIGINAL NO OF BLOCKS     58800019
         MVC   EXKEY(3),USRKEY    SAVE KEY                              58900019
         LA    REG1,EXDSNAM                                             59000019
         ST    REG1,TUBEXCAD      STORE ADDRESS OF GETMAIN AREA IN TUB  59100019
         LA    REG1,EXCLNG                                              59200019
         STC   REG1,TUBEXCLG      STORE LENGTH IN TUB                   59300019
         LA    REG1,CMDED1DO      EXEC CODE TO CALL IHKED1              59400019
         TM    SWDEF,DEFELST      HAS LIST BEEN SPECIFIED               59500019
         BZ    CALLMOD            BR= NO                                59600019
         OI    TUBFLG2,TUBEXLST   TURN ON LIST BIT                      59700019
         B     CALLMOD                                                  59800019
*********************************************************************** 59900019
*                                                                       60000019
*   EDIT COMMAND                                                        60100019
*   OPERANDS CORRECT- SET TUB                                           60200019
*                                                                       60300019
*********************************************************************** 60400019
PROCESSA OI    TUBFLG2,TUBEDIT    SET EDIT BIT IN TUB                   60500019
         OI    TUBFLG3,TUBLNPMT   TURN ON LINE NUMBER PROMPT            60600019
         TM    SWDEFEDT,DEFENEW   IS IT NEW                             60700019
         BO    CALLIRL            BR= YES, GO CALL IHKIRL               60800019
CKEOS    TM    PPTFLG,PPTOS       IS IT OS                              60900019
         BO    CALLEOS            YES, GO CALL IHKEOS                   61000019
         CLC   TUBPMFNM,ACTIVE    IS DATASET NAME ACTIVE                61100019
         BNE   CALLED1            BR= NO                                61200019
         TM    EDTSW,EDTUID       YES, IS IT SOMEONE ELSES              61300019
         BO    INVEDIT            YES, INVALID                          61400019
*********************************************************************** 61500019
*                                                                       61600019
*   CALL MODULE BY SAVING NEGATIVE CODE IN REGISTER                     61700019
*                                                                       61800019
*********************************************************************** 61900019
CALLED1  LA    REG1,CMDED1DL      EDIT, DELETE CODE TO CALL IHKED1      62000019
CALLMOD  LNR   REG8,REG1                                                62100019
         B     RETURN                                                   62200019
*********************************************************************** 62300019
*                                                                       62400019
*   OS DATASET                                                          62500019
*                                                                       62600019
*********************************************************************** 62700019
CALLEOS  LA    REG1,CMDEOS        CODE TO CALL EOS                      62800019
         B     CALLMOD                                                  62900019
*********************************************************************** 63000019
*                                                                       63100019
*   CALL IRL- NEW DATASET                                               63200019
*                                                                       63300019
*********************************************************************** 63400019
CALLIRL  LA    REG1,CMDIRL        IHKIRL CODE                           63500019
         OI    PPTFLG,ENDLST      SET FOR IRL TO INDICATE EDIT          63600019
         B     CALLMOD                                                  63700019
*********************************************************************** 63800019
*                                                                       63900019
*   ERROR- TURN OFF ANY BITS THAT MIGHT BE SET                          64000019
*                                                                       64100019
*********************************************************************** 64200019
RETCD0   LA    REG15,0            SET RETURN CODE 0                     64300019
RETCD    LR    REG8,REG15                                               64400019
TURNOFF  NI    TUBFLG1,TUBFLG1F                                         64500019
         NI    TUBFLG2,TUBFLG2F                                         64600019
         NI    TUBFLG3,TUBFLG3F                                         64700019
*********************************************************************** 64800019
*                                                                       64900019
*   GENERAL RETURN                                                      65000019
*                                                                       65100019
*********************************************************************** 65200019
RETURN   L     REG5,4(REG13)      SAVE CALLERS SAVEAREA                 65300019
         LA    REG1,GMLEN1        FREE CORE WITHOUT EXEC IF NOT EXEC    65400019
         TM    PPTFLG,PPTEXC      IS IT EXEC                            65500019
         BZ    FREEPART           BR= NO                                65600019
         LTR   REG8,REG8          YES, IS IT ERROR RETURN               65700019
         BL    FREEPART           BR= NO                                65800019
         LA    REG1,GMLEN         YES, FREE EXEC AREA ALSO              65900019
FREEPART LR    REG0,REG1                                                66000019
         LR    REG1,REG13                                               66100019
         FREEMAIN R,LV=(0),A=(1)                                        66200019
         LR    REG15,REG8                                               66300019
         LR    REG13,REG5                                               66400019
RETURN2  RETURN (14,12),,RC=(15)                                        66500019
*********************************************************************** 66600019
*   ERROR RETURN ROUTINES                                               66700019
*********************************************************************** 66800019
GMERR    LA    REG15,RTRN8        SET GETMAIN FAIL RETURN CODE          66900019
         B     RETURN2                                                  67000019
*                                                                       67100019
*                                                                       67200019
RET16    LA    REG8,RTRN16        MESSAGE LOST RETURN                   67300019
         B     TURNOFF                                                  67400019
*********************************************************************** 67500019
*                                                                       67600019
*   COMPARES SPECIFIED OPERANDS                                         67700019
*   BRANCHES TO INVALID OPERAND ROUTINE IF THEY DO NOT MATCH            67800019
*                                                                       67900019
*********************************************************************** 68000019
SUBRCLC  EX    REG5,CLCOP                                               68100019
         BNE   OPRERR                                                   68200019
         BR    REG6                                                     68300019
*                                                                       68400019
         EJECT                                                          68500019
*********************************************************************** 68600019
*           OPERAND ERROR ROUTINES                                      68700019
*********************************************************************** 68800019
*********************************************************************** 68900019
*                                                                       69000019
*   RETURN TO PROCESSING                                                69100019
*                                                                       69200019
INVMARG  LA    REG1,INVALMRG      INVALID SOURCE MARGINS                69300019
         OI    EDTSW,EDT2PARM     SET BIT FOR NO INSERT                 69400019
         B     ENQMSG                                                   69500019
*                                                                       69600019
OPRMERR  LA    REG1,MOPCD         CONTRADICTORY/MULT OP                 69700019
         B     ENQMSG                                                   69800019
*                                                                       69900019
NOOPER   LA    ROPR,DSNAMEL       INSERT DSNAME                         70000019
         LA    REG1,NOOPERCD      REQUIRED OPERAND MISSING              70100019
         B     ENQMSG                                                   70200019
*                                                                       70300019
INVALNAM LA    REG1,MINVNAM                                             70400019
         B     ENQMSG                                                   70500019
*********************************************************************** 70600019
*                                                                       70700019
*   RETURN 0 TO CALLER                                                  70800019
*                                                                       70900019
*********************************************************************** 71000019
*                                                                       71100019
*   INVALID EDIT OF ANOTHER USERS ACTIVE DATASET                        71200019
*                                                                       71300019
INVEDIT  LA    REGRTN,RETCD0                                            71400019
         LA    REG1,MINVEDIT                                            71500019
         OI    EDTSW,EDT2PARM                                           71600019
         B     ENQMSG                                                   71700019
*                                                                       71800019
EXCESS   LA    REG1,EXCESSOP      EXCESSIVE OP                          71900019
         LA    REGRTN,RETCD0                                            72000019
         B     ENQMSG                                                   72100019
*********************************************************************** 72200019
*           COMMON ROUTINE FOR OPERAND ERRORS                           72300019
*********************************************************************** 72400019
SUBERR   TM    EDTSW,EDTSUB1                                            72500019
         BO    MSGRTN             BR= MSG QUEUED                        72600019
         OI    EDTSW,EDTSUB1                                            72700019
OPRERR   LA    REG1,OPERRCD       OPERAND INVALID MSG                   72800019
         B     ENQMSG                                                   72900019
*                                                                       73000019
*********************************************************************** 73100019
*                                                                       73200019
*           ROUTINE TO ENQUEUE MESSAGE FOR USER                         73300019
*                                                                       73400019
*********************************************************************** 73500019
ENQMSG   MVC   TUBPARM5+1(3),0(REG1)                                    73600019
         MVI   TUBPARM5,X00       MESSAGE CODE                          73700019
         IC    REG8,0(ROPR)       OPERAND LENGTH                        73800019
         LA    REG1,TUBPARM5                                            73900019
         ST    REG1,TUBPARM3      PARAMETER 3- MSG CODE                 74000019
         L     REG15,IHKYMSG1     IHKMSG01                              74100019
         LA    REG1,TUBUSRID                                            74200019
         ST    REG1,TUBPARM2      PARAMETER 2- USERID                   74300019
         ST    RTUB,TUBPARM1      PARAMETER 1- TUB                      74400019
         OI    EDTSW,EDTERR       SET ERROR MSG SWITCH                  74500019
         TM    EDTSW,EDT2PARM     ARE THERE ANY INSERTIONS              74600019
         BZ    ENQMSG1            BR= YES                               74700019
         OI    TUBPARM3,ENDLST    FLAG END OF PARAMETER LIST            74800019
         NI    EDTSW,EDT2PARF                                           74900019
         B     ENQMSG2                                                  75000019
ENQMSG1  ST    ROPR,TUBPARM4      PARAMETER 4- INSERT                   75100019
         CLI   0(ROPR),X0A        IS IT GREATER THAN 10                 75200019
         BNH   SETHI              BR= NO                                75300019
         MVI   0(ROPR),X0A        YES, INSERT 10                        75400019
SETHI    OI    TUBPARM4,ENDLST    FLAG LAST PARAMETER                   75500019
ENQMSG2  LA    REG1,TUBPARM1                                            75600019
         BALR  REG14,REG15        GO ENQUEUE MSG                        75700019
         B     *+4(REG15)         TEST RETURN CODE                      75800019
         STC   REG8,0(ROPR)                                             75900019
MSGRTN   B     0(REGRTN)          0  SUCCESSFUL                         76000019
         B     0(REGRTN)          4  NOT USED                           76100019
         B     RETCD              8   GETMAIN FAIL                      76200019
         B     RETCD              12 AA I/O ERROR                       76300019
         B     RETCD              16 MESSAGE LOST                       76400019
         B     RETCD              20  AA OUT OF SPACE                   76500019
         B     RET16              24  INVALID USERID                    76600019
*********************************************************************** 76700019
*           EXECUTED INSTRUCTIONS                                       76800019
*********************************************************************** 76900019
CLCOP    CLC   0(0,REG1),1(ROPR)                                        77000019
MVCNAM   MVC   0(0,REG1),0(REG4)  DS NAME, MEMBER, OR USERID            77100019
MVCBLKS  MVC   1(0,REG1),0(REG1)                                        77200019
PACKSM   PACK  PACKED,1(1,ROPR)   PACK SOURCE MARGIN                    77300019
         EJECT                                                          77400019
*********************************************************************** 77500019
*                                                                       77600019
*   VALID EDIT, EXECUTE, AND DELETE OPERANDS                            77700019
*                                                                       77800019
*********************************************************************** 77900019
PL1      DC    C'PL1'                                                   78000019
DSLIST   DC    C'DSLIST'                                                78100019
NOSCAN   DC    C'NOSCAN'                                                78200019
NUM      DC    C'NUM'                                                   78300019
LIST     DC    C'LIST'                                                  78400019
NOLIST   DC    C'NOLIST'                                                78500019
OLD      DC    C'OLD'                                                   78600019
NEW      DC    C'NEW'                                                   78700019
SCAN     DC    C'SCAN'                                                  78800019
FORTE    DC    C'FORTE'                                                 78900019
FORTG    DC    C'FORTG'                                                 79000019
FORTH    DC    C'FORTH'                                                 79100019
DATA     DC    C'DATA'                                                  79200019
TEXT     DC    C'TEXT'                                                  79300019
CLIST    DC    C'CLIST'                                                 79400019
NONUM    DC    C'NONUM'                                                 79500019
C483     DC    X'03C3F4F8'        C48- 48 CHARACTER SET                 79600019
C603     DC    X'03C3F6F0'        C60- 60 CHARACTER SET                 79700019
CHAR60   DC    X'06C3C8C1D9F6F0'  CHAR 60                               79800019
CHAR48   DC    X'06C3C8C1D9F4F8'  CHAR48                                79900019
*********************************************************************** 80000019
*           MESSAGE CODES                                               80100019
*********************************************************************** 80200019
INVALMRG DC    C'356'                                                   80300019
OPERRCD  DC    C'302'                   OPERAND INVALID                 80400019
NOOPERCD DC    C'317'                   REQUIRED OPERAND MISSING        80500019
MOPCD    DC    C'321'                   MULTIPLE USE OF KEYWORD         80600019
EXCESSOP DC    C'334'                                                   80700019
MINVNAM  DC    C'366'                   NAME MUST BEGIN WITH USERID     80800019
MINVEDIT DC    C'408'                                                   80900019
*********************************************************************** 81000019
*                                                                       81100019
*           CONSTANTS                                                   81200019
*                                                                       81300019
*********************************************************************** 81400019
DSNAMEL  DC    X'06'                                                    81500019
DSNAME   DC    C'DSNAME'                                                81600019
CRJESYS  DC    C'CRJE.'           EDIT NOT ALLOWED                      81700019
ACTIVE   DC    C'ACTIVE  '        EDIT OF ANOTHER USERS NOT ALLOWED     81800019
         EJECT                                                          81900019
*********************************************************************** 82000019
*                                                                       82100019
*           DSECT FOR VARIABLES PARMATER LISTS ETC.                     82200019
*                                                                       82300019
*********************************************************************** 82400019
VDSECT   DSECT                                                          82500019
SAVEA    DS    18F                      SAVE AREA                       82600019
ADDRTUB  EQU   X'1C'                                                    82700019
PACKED   DS    D                                                        82800019
*********************************************************************** 82900019
*           INTERNAL SWITCHES                                           83000019
*********************************************************************** 83100019
*                                                                       83200019
*   DEFAULTS                                                            83300019
*                                                                       83400019
SWDEF    DS    0CL4                                                     83500019
SWDEFEDT DS    X                                                        83600019
PL1OFF   EQU   X'FB'                                                    83700019
SWDEFATT DS    X                                                        83800019
SWDEFBSM DS    X                                                        83900019
SWDEFESM DS    X                                                        84000019
DEFELSTF EQU   X'7F'                                                    84100019
OPRSW    DS    X                  OPERAND FOUND SWITCHES                84200019
OPRSCN   EQU   X'80'              SCAN/NOSCAN                           84300019
OPRNUM   EQU   X'40'              NUM/NONUM                             84400019
OPRNWOD  EQU   X'20'              NEW/OLD                               84500019
OPRLIST  EQU   X'10'              LIST/NOLIST                           84600019
OPRPL1CH EQU   X'08'                                                    84700019
OPRPRGSW EQU   X'04'                                                    84800019
OPRATT   EQU   X'02'              ATTRIBUTE SPECIFIED                   84900019
OPROSMEM EQU   X'01'              PROCESSING OS DATA SET MEMBER  A43955 84950021
OPROFF   EQU   X'00'                      ALL SWITCHES OFF              85000019
MEMOFF   EQU   X'FE'              SET PROCESSING MEMBER SW OFF   A43955 85050021
*                                                                       85100019
EDTSW    DS    X                  INTERNAL SWITCHES                     85200019
EDTUID   EQU   X'80'              USERID PROCESSED                      85300019
EDTSTCOL EQU   X'40'              PL/1-BEGIN SOURCE MARGIN              85400019
EDTSTCLF EQU   X'BF'                                                    85500019
EDTENCOL EQU   X'20'              PL/1- END SOURCE MARGIN               85600019
EDTDSNM  EQU   X'10'              DSNAME                                85700019
EDT2PARM EQU   X'08'              NO INSERTION                          85800019
EDTSUB1  EQU   X'04'              ERROR MSG SENT FOR FIRST SUBOP ERROR  85900019
EDT2PARF EQU   X'F7'                                                    86000019
EDTERR   EQU   X'02'              ERROR MSG QUEUED                      86100019
EDTSUB   EQU   X'01'              SUBOP EXPECTED                        86200019
EDTSUB12 EQU   X'FA'                                                    86300019
EDTOFF   EQU   X'00'                                                    86400019
*                                                                       86500019
GMLEN1   EQU   *-VDSECT                                                 86600019
*                                                                       86700019
*   EXECUTE AREA                                                        86800019
*                                                                       86900019
EXDSNAM  DS    D                  DATASET NAME                          87000019
EXUSRID  DS    CL8                USERID- OWNER OF DATASET              87100019
EXBLKNUM DS    H                  BLOCK NUMBER TO BE READ               87200019
EXRECNUM DS    H                  RECORD NUMBER TO BE READ              87300019
EXKEY    DS    F                  PROTECTION KEY                        87400019
EXMAXBLK DS    H                  ORIGINAL NUMBER OF BLOCKS             87500019
         DS    CL6                FILL OUT TO DOUBLE WORDS              87600019
EXCLNG   EQU   *-EXDSNAM                                                87700019
*********************************************************************** 87800019
*           LENGTH OF VDSECT                                            87900019
GMLEN    EQU   *-VDSECT                                                 88000019
*********************************************************************** 88100019
*   USER BUFFER USED FOR    DSNAME,MEMBER NAME OR KEY                   88200019
*********************************************************************** 88300019
USRBUFR  DSECT                                                          88400019
USRDSNAM DS    CL44                                                     88500019
         DS    CL4                                                      88600019
USRKEY   DS    CL4                                                      88700019
         ORG   USRKEY                                                   88800019
USRMBER  DS    CL8                                                      88900019
*********************************************************************** 89000019
         SPACE 3                                                        89100019
*********************************************************************** 89200019
*           EQUATES FOR PPT SWITCHES                                    89300019
*********************************************************************** 89400019
PPTPRG   EQU   X'80'                                                    89500019
PPTNOPRG EQU   X'7F'                                                    89600019
PPTDEL   EQU   X'40'                                                    89700019
PPTEXC   EQU   X'20'                                                    89800019
PPTOS    EQU   X'10'                    OS SWITCH                       89900019
PPTMEMB  EQU   X'08'                    PDS SWITCH                      90000019
PPTEDT    EQU   X'04'                                                   90100019
PPTKEY   EQU   X'02'                    KEY STORED SWITCH               90200019
SUBPAREN EQU   X'40'                                                    90300019
SUBOPRF  EQU   X'3F'                                                    90400019
         IHKCDSCT TUB=YES,PPT=YES,AVT=YES,DEF=YES                       90500019
         RAFKNBX TYPE=DSECT             RAFIO KONBOX                    90600019
         TUBEQU                                                         90700019
         CMDEQU                                                         90800019
         END                                                            90900019
