EOS      TITLE 'IHKEOS - EDIT COMMAND PROCESSOR FOR OS DATA SETS'       00100019
IHKEOS   CSECT                                                   A34599 00120020
*A001000,359000                                                  A34599 00140020
*C139000,360000                                                  A34599 00160020
*D072000                                                         A34599 00180020
*A247100,248000,330600-331200,334600-335200,3362600-363200       S21085 00180821
*A705600-706200,897500                                           S21085 00181621
*D248000,331000,335000,363000,706000                             S21085 00182421
*C139000,251000,285000,308000,328000,338000,369000,371000,390000 S21085 00183221
*C392000                                                         S21085 00184021
*A103000,436000,449000,654000,678000                             A36810 00185020
*C004000,045000,139000,436000,672000,679000                      A36810 00190020
*D671000                                                         A36810 00195020
* C139000,D247100-247700                                         60626  00197027
*********************************************************************** 00200019
*STATUS                                                               * 00300019
*   CHANGE LEVEL 1                                               A36810 00400020
*FUNCTION                                                             * 00500019
*   THIS MODULE RECEIVES CONTROL FROM THE SYSTEM ADMINISTRATOR BY A   * 00600019
*   LOAD-DELETE REQUEST FROM IHKEDT TO READ A DATA SET INTO A USER'S  * 00700019
*   ACTIVE FILE, OR TO SCRATCH AN OS DATA SET.  IF AN OS DATA SET IS  * 00800019
*   TO BE READ INTO AN ACTIVE FILE, IHKIRL IS CALLED TO CREATE THE    * 00900019
*   DIRECTORY ENTRY AND ACTIVE FILE.  THE LOADER/CONTROLLER IS THEN   * 01000019
*   CALLED TO LOAD THE IHKOPN MODULE.  AFTER THE MODULE IS LOADED,    * 01100019
*   IT IS ATTACHED AS A SUBTASK AND CONTROL IS PASSED TO IT TO OPEN   * 01200019
*   OR SCRATCH THE DATA SET.  IF THE DATA SET WAS SCRATCHED, THE      * 01300019
*   IHKEOS MODULE IS DETACHED AND CONTROL IS RETURNED TO THE CALLING  * 01400019
*   ROUTINE.  IF THE DATA SET WAS OPNED, A GETMAIN IS ISSUED FOR A    * 01500019
*   BUFFER.  A BLOCK IS READ AND INSERTED INTO THE ACTIVE AREA, EACH  * 01600019
*   RECORD USING AS MANY LINES AS NECESSARY TO HOLD IT.  IF THE       * 01700019
*   DATA SET HAS A FIXED RECORD FORMAT AND THE RECORD LENGTH IS       * 01800019
*   BETWEEN 80 AND 120, THE TUBLONGN FLAG IS SET TO INDICATE THAT     * 01900019
*   THE DATA SET IS TO BE LISTED ON A SINGLE LINE PER RECORD.  WHEN   * 02000019
*   EOD IS ENCOUNTERED ON THE DATA SET, IHKOPN IS DETACHED AND        * 02100019
*   CONTROL IS RETURNED TO THE CALLING ROUTINE                        * 02200019
*ENTRY POINT                                                          * 02300019
*        IHKEOS - TO READ AN OS DATA SET INTO AN ACTIVE FILE, OR TO   * 02400019
*        SCRATCH AN OS DATA SET                                       * 02500019
*INPUT                                                                * 02600019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING THE * 02700019
*   ADDRESSES OF THE TUB AND AVT.                                     * 02800019
*OUTPUT                                                               * 02900019
*   N/A                                                               * 03000019
*EXTERNAL REFFERENCES                                                 * 03100019
*        IHKDSP - TO ISSUE WAITS                                      * 03200019
*        IHKAFI - TO MANIPULATE THE ACTIVE FILE                       * 03300019
*        IHKMSG - TO QUEUE MESSAGES                                   * 03400019
*        BSAM   - TO READ DATA SET                                    * 03500019
*        BPAM   - TO READ DATA SET                                    * 03600019
*        IHKOPN - TO OPEN OR SCRATCH DATA SET                         * 03700019
*        IHKLDC - TO LOAD AND DELETE IHKOPN                           * 03800019
*EXITS, NORMAL                                                        * 03900019
*   RETURN TO CALLING ROUTINE WITH 0 IN REGISTER 15                   * 04000019
*EXITS, ERROR                                                         * 04100019
*   RETURN TO CALLING ROUTINE WITH ONE OF THE FOLLOWING RETURN CODES  * 04200019
*   IN REGISTER 15                                                    * 04300019
*   8  - GETMAIN FAILURE                                              * 04400019
*   12 - ACTIVE AREA I/O ERROR OR IHKLDC ABEND                   A36810 04500020
*   16 - MESSAGE LOST                                                 * 04600019
*   20 - ACTIVE AREA OUT OF SPACE                                     * 04700019
*TABLES/WORK AREAS                                                    * 04800019
*   18 WORD SAVE AREA                                                 * 04900019
*   DCB                                                               * 05000019
*   DSCB                                                              * 05100019
*   JFCB                                                              * 05200019
*   DIRECTORY ENTRY                                                   * 05300019
*   TUB                                                               * 05400019
*   TUBUFFAD - CONTAINS USER BUFFER ADDRESS                           * 05500019
*   TUBLNOMN - INDICATES LINE NUMBERS CONTAINED IN LINE               * 05600019
*   TUBLONGN - INDICATES LRECL BETWEEN 80 AND 120                     * 05700019
*   TUBAFISW - INDICATES BUFFER CONTROL USED                          * 05800019
*   TUBPPTAD - CONTAINS ADDRESS OF PPT                                * 05900019
*   TUBDIRAD - CONTAINS ADDRESS OF DIRECTORY ENTRY                    * 06000019
*   TUBNXKEY - ACTIVE FILE POINTER                                    * 06100019
*   TUBPRMLS - PARAMETER AREA                                         * 06200019
*   TUBRAFBF - CONTAINS ADDRESS OF IHKAFI BUFFER                      * 06300019
*   USER BUFFER                                                       * 06400019
*   VARIABLE LENGTH READ BUFFER                                       * 06500019
*   888 BYTE IHKAFI BUFFER                                            * 06600019
*   PPT - CONTAINS PROCESSING SWITCHES                                * 06700019
*ATTRIBUTES                                                           * 06800019
*   REENTRANT AND NONRESIDENT                                         * 06900019
*********************************************************************** 07000019
         EJECT                                                          07100019
         CMDEQU                                                         07300019
         SPACE 3                                                        07400019
*********************************************************************** 07500019
*           EQUATES                                                     07600019
*********************************************************************** 07700019
         SPACE 1                                                        07800019
NUMZONE  EQU   X'0F'                    PACKED DECIMAL SIGN             07900019
UILEN    EQU   14                       USER DATA LENGTH                08000019
MAXVOL   EQU   20                       MAX VOLS ALLOWED FOR DELETE     08100019
ENDLST   EQU   X'80'                    END OF PARAMETER LIST           08200019
F120     EQU   120                                                      08300019
INSBFL   EQU   888                      INSERT BUFFER LENGTH            08400019
NUMSIGN  EQU   X'F0'                    PACKED DECIMAL ZONR             08500019
BLK      EQU   C' '                     BLANK FOR CLEARING FIELDS       08600019
X04      EQU   X'04'                    HEX 40                          08700019
X0F      EQU   X'0F'                    HEX 0F                          08800019
X00      EQU   X'00'                    HEX 00                          08900019
ALLBITS  EQU   X'FF'                    TEST FOR ALL BITS OFF           09000019
OPEN     EQU   X'10'                    TEST FOR OPEN SUCCESSFUL        09100019
EXJFCB   EQU   X'87'                    CODE FOR EXLIST                 09200019
BUFCTRL  EQU   X'80'                    BUFFER CONTROL ON               09300019
BUFCTRLF EQU   X'7F'                    BUFFER CONTROL OFF              09400019
RECLNGTH EQU   88                       INSERT LINE LENGTH              09500019
OPNCD    EQU   28                       CODE FOR IHKSRV                 09600019
LOAD     EQU   16                       SHIFT ADDRESS FOR LOAD          09700019
DELOPN   EQU   24                       SHIFT ADDRESS FOR DELETE        09800019
CLRPOST  EQU   X'00'                    CLEAR POST BIT IN ECB           09900019
OPNABEND EQU   X'00'                    LAST PORTION OG ABEND CODE      10000019
PASABEND EQU   X'91'                    PASSWORD NOT GIVEN              10100019
SUPRMODE EQU   X'1F'                    SUPERVISOR MODE FOR ATTACH      10200019
PPMODE   EQU   X'7F'                    PROB PROG MODE FOR ATTACH       10300019
POST     EQU   X'40'                    POST CODE FOR ECB        A36810 10350020
RC0      EQU   0                        GOOD RETURN CODE                10400019
RC8      EQU   8                        GETMAIN FAILURE RETURN CODE     10500019
RC12     EQU   12                       RETURN CODE OF 12               10600019
RC16     EQU   16                       RETURN CODE OF 16               10700019
RC20     EQU   20                       RETURN CODE OF 20               10800019
MAXLEN   EQU   10                       MAXIMUM DSNAME LENGTH FOR MSG   10900019
MAXMEMBL EQU   8                        MAX LENGTH OF MEMBER NAME       11000019
         SPACE 3                                                        11100019
*********************************************************************** 11200019
*           REGISTER EQUATES                                            11300019
*********************************************************************** 11400019
         SPACE 1                                                        11500019
REG0     EQU   0                                                        11600019
REG1     EQU   1                                                        11700019
RTUB     EQU   2                                                        11800019
REG3     EQU   3                                                        11900019
REG4     EQU   4                                                        12000019
REG5     EQU   5                                                        12100019
REG6     EQU   6                                                        12200019
REG7     EQU   7                                                        12300019
REG8     EQU   8                                                        12400019
RDCB     EQU   9                                                        12500019
REG10    EQU   10                                                       12600019
RBASE    EQU   11                                                       12700019
RAVT     EQU   12                                                       12800019
REG13    EQU   13                                                       12900019
REG14    EQU   14                                                       13000019
REG15    EQU   15                                                       13100019
         EJECT                                                          13200019
         USING IHKEOS,RBASE                                             13300019
         USING OSDSECT,REG13                                            13400019
         USING TUBDSECT,RTUB                                            13500019
         USING AVTDSECT,RAVT                                            13600019
         USING IHADCB,RDCB                                              13700019
*                                                                       13800019
         SAVE  (14,12),,EOS73050                                 60626  13900027
         LR    RBASE,REG15              SET UP BASE REGISTER            14000019
         L     RTUB,0(REG1)             SET UP TUB BASE REGISTER        14100019
         L     RAVT,4(REG1)             SET UP AVT BASE                 14200019
         LA    REG5,GMLEN               SET UP FOR GETMAIN              14300019
         LA    REG14,GMERR                                              14400019
         BAL   REG6,SUBRGETM            GET SAVE AND WORK AREAS         14500019
GMGOOD   L     REG1,TUBPARM4                                            14600019
         ST    REG13,4(REG1)            SAVE REGISTER 13                14700019
         ST    REG1,8(REG13)            SAVE CALLERS SAVE AREA ADDR     14800019
         LR    REG13,REG1                                               14900019
         L     REG15,TUBUFFAD                                           15000019
         MVC   OSDSNAM(56),0(REG15)     MOVE DSNAME AND MEMBER NAME     15100019
         LA    RDCB,ADDRDCB             SET UP DCB BASE                 15200019
         L     REG1,TUBPPTAD                                            15300019
         MVC   PPTFLG,0(REG1)           MOVE SWITCHES TO WORK AREA      15400019
         MVC   SWDEF(5),6(REG1)                                         15500019
         NI    EDTSW,EDTUID             SET ALL OTHER BITS TO 0         15600019
*                                                                       15700019
PROCESS  TM    PPTFLG,PPTDEL            TEST FOR DELETE                 15800019
         BO    PROCOS                   IF YES, DONT CREATE DIR ENTRY   15900019
         EJECT                                                          16000019
*********************************************************************** 16100019
*           CALL IHKIRL TO CREATE DIRECTORY ENTYRY                      16200019
*********************************************************************** 16300019
         OI    0(REG1),PPTEDT           SET EDIT FLAG                   16400019
         ST    RTUB,TUBPARM1            SET UP PARM LIST FOR IRL        16500019
         ST    RAVT,TUBPARM2            SET UP PARM LIST FOR IRL        16600019
         LA    REG1,TUBPARM1            GET ADDRESS OF LIST             16700019
         L     REG15,IHKYYIRL           GET ADDRESS OF LIST             16800019
         BALR  REG14,REG15              CALL IHKIRL                     16900019
         LR    REG8,REG15               SAVE RETURN CODE                17000019
         LTR   REG8,REG8                TEST RETURN CODE                17100019
         BNZ   RETURN2                  IF BAD, RETURN                  17200019
         OI    EDTSW,EDTREL             SET ACTIVE AREA SW              17300019
         EJECT                                                          17400019
*********************************************************************** 17500019
*          GO TO IHKOPN TO OPEN OR DELETE DATA SET                      17600019
*********************************************************************** 17700019
         SPACE 1                                                        17800019
PROCOS   LA    REG7,CMDOPN              GET IHKOPN COMMAND CODE         17900019
         SLL   REG7,LOAD                SET UP FOR LOAD OF IHKOPN       18000019
         BAL   REG6,LDELOPN             LOAD IHKOPN                     18100019
         SPACE 3                                                        18200019
*********************************************************************** 18300019
*          BUILD LINKAGE FOR IHKSRV TO ATTACH IHKOPN                    18400019
*********************************************************************** 18500019
         L     REG15,TUBUFFAD                                           18600019
         LA    REG15,60(REG15)          POINT TO IHKOPN PARAMETERS      18700019
         ST    RTUB,0(REG15)            TUB ADDR TO PARAMETER LIST      18800019
         ST    RAVT,4(REG15)            AVT ADDR TO PARAMETER LIST      18900019
         ST    REG13,8(REG15)           WORK AREA ADDR TO PARAMETER LST 19000019
         LA    REG14,EODPROC            GET EOD ROUTINE ADDRESS         19100019
         ST    REG14,12(REG15)          STORE IN PARAMETER LIST         19200019
         LA    REG14,OSIOERR            GET I/O ERROR ROUT ADDRESS      19300019
         ST    REG14,16(REG15)          STORE IN PARAMETER LIST         19400019
         LR    REG1,REG15               PUT LIST ADDRESS INTO REG1      19500019
*                                       FOR ATTACH                      19600019
         LA    REG5,40(REG15)           GET RETURN ECB ADDRESS          19700019
         MVI   0(REG5),CLRPOST          CLEAR POST BIT IN RETURN ECB    19800019
         LA    REG4,1              VALUE TO DECREMENT DISPATCHING PRTY  19850019
         LNR   REG4,REG4           SET TO MINUS 1                       19900019
         ATTACH EP=IHKOPN,SM=PROB,ROLL=(NO,NO),DPMOD=(4),ECB=(REG5),   X19950019
               JSTCB=NO,SVAREA=YES,SZERO=YES,KEY=ZERO,GIVEJPQ=NO        20000019
         L     REG15,TUBUFFAD                                           20100019
         ST    REG1,108(REG15)                                          20200019
         LR    REG1,REG5                GET RETURN ECB ADDR FOR IHKDSP  20300019
         L     REG15,IHKYYDSP           GET DISPATCHER ADDRESS          20400019
         BALR  REG14,REG15              WAIT IN DISPATCHER              20500019
         SPACE 3                                                        20600019
*********************************************************************** 20700019
*          TEST IHKOPN RETURN                                           20800019
*********************************************************************** 20900019
         SPACE 1                                                        21000019
*          TEST FOR ABEND OF IHKOPN                                     21100019
         SPACE 1                                                        21200019
         L     REG15,TUBUFFAD           GET RETURN ECB ADDRESS          21300019
         LA    REG15,100(REG15)                                         21400019
         CLI   1(REG15),OPNABEND        TEST FOR OPEN ABEND             21500019
         BE    TSTOPRET                 IF NOT, TEST RETURN CODE        21600019
         CLI   1(REG15),PASABEND        TEST FOR PASSWORD NOT GIVEN     21700019
         BE    PASSERR                  IF YES, ENQ PASSWORD MESSAGE    21800019
         B     OPNERR                   IF NOT, ENQ OPEN ERR MSG        21900019
         SPACE 1                                                        22000019
*********************************************************************** 22100019
*          TEST RETURN CODE                                             22200019
*********************************************************************** 22300019
TSTOPRET L     REG15,0(REG15)           GET RETURN CODE                 22400019
         LA    REG15,0(REG15)           ELEMINATE HIGH ORDER BITS       22500019
         B     *+4(REG15)               BRANCH TO PROPER ROUTINE        22600019
         B     EDITEOS                  EDIT OPEN SUCCESSFUL     0      22700019
         B     RETCD8                   GETMAIN FAILURE          4      22800019
         B     OSIOERR                  DISK ERROR               8      22900019
         B     OSNFND                   DS NOT FOUND            12      23000019
         B     MULTVOL                  DS ON MULTIPLE VOLUMES  16      23100019
         B     NOTMOUNT                 VOLUME NOT MOUNTED      20      23200019
         B     RETCD0                   SCRATCH GOOD            24      23300019
         B     EXPDATE                  EXPIRATION DATE NOT REACHED 28  23400019
         B     ORGERR                   DS ORGNIZATION INVALID  32      23500019
         B     OPNERR                   NO DD CARD              36      23600019
         B     MEMBNFND                 MEMBER NOT FOUND        40      23700019
         B     POERR                    NO MEMBER FOR PARTIONED DS      23800019
*                                                                       23900019
*                                                                       24000019
EDITEOS  LH    REG5,DS1BLKL             GET CORE FOR BUFFER             24100019
         LA    REG14,RETCD8                                             24200019
         BAL   REG6,SUBRGETM                                            24300019
         OI    EDTSW,EOSBUFR                                            24400019
         MVC   SAVLRECL,DS1LRECL        SAVE RECORD LENGTH              24500019
         MVC   SAVRECFM,DS1RECFM        SAVE RECORD FORMAT              24600019
         MVC   SAVBLKL,DS1BLKL                                          24700019
NONUM    MVC   MAXLNLEN,H80             SET MAX LINE LENGTH      S21085 24780021
*                                       OF 80                    S21085 24790021
NUM      TM    SAVRECFM,DS1F            TEST FOR FIXED RECORDS   S21085 24800021
         BZ    INITINS                  IF NOT, SKIP LENGTH TEST        24900019
         LH    REG1,DS1LRECL            TEST                            25000019
         CH    REG1,MAXLNLEN            FOR RECORD BETWEEN       S21085 25100021
         BNH   INITINS                  80 AND 120                      25200019
         LA    REG15,F120                                               25300019
         CR    REG1,REG15               TEST FOR LRECL GT 120           25400019
         BH    INITINS                  IF NOT, DONT SET SWITCH         25500019
         OI    TUBFLG3,TUBLONGN         SKIP LONG LINE SWITCH           25600019
INITINS  LA    REG3,INSERTBF                                            25700019
         ST    REG3,TUBRAFBF            INITIALIZE INSERT BUFFER        25800019
         ST    REG3,4(REG3)                                             25900019
         LA    REG15,INSBFL             GET ENDING ADDRESS OF BUFFER    26000019
         ST    REG15,0(REG3)                                            26100019
         AR    REG15,REG3                                               26200019
         BCTR  REG15,0                                                  26300019
         ST    REG15,ENDINBUF           SAVE ENDING ADDRESS             26400019
         L     REG10,TUBPARM4                                           26500019
         LR    REG8,REG5                                                26600019
         ST    REG10,BUFADR             SAVE BUFFER ADDRESS             26700019
         LA    REG3,8(REG3)             POINT TO FIRST LINE             26800019
READ     L     REG10,BUFADR             SET UP FOR READ                 26900019
         MVC   CDECB+6(2),SAVBLKL       PUT BLOCK LEN IN ECB            27000019
         READ CDECB,SF,(RDCB),(REG10)  READ BLOCK                       27100019
         L     REG15,IHKYYDSP           GET DISPATCHER ADDRESS          27200019
         LA    REG1,CDECB               GET DECB ADDRESS                27300019
         BALR  REG14,REG15              WAIT FOR COMPLETION OF READ     27400019
GOTOCHK  CHECK CDECB                    CHECK COMPLETION                27500019
         TM    SAVRECFM,DS1U            TEST FOR UNDEFINED RECORDS      27600019
         BO    UNDEF                    IF YES, PROCESS                 27700019
         TM    SAVRECFM,DS1F            TEST FOR FIXED RECORDS          27800019
         BZ    VAR                      IF NOT SET UP FOR OTHER RECORDS 27900019
         TM    SAVRECFM,DS1B            TEST FOR BLOCKED RECORDS        28000019
         BO    UNDEF                    IF YES, TEST FOR SHORT BLOCK    28100019
BLOCKED1 LH    REG7,SAVLRECL            GET RECORD LENGTH               28200019
         ST    REG7,RECLEN              INITILIZE RECORD LEN FIELD      28300019
         ST    REG7,REMLEN              SET UP REMAINING LENGTH         28400019
         CH    REG7,MAXLNLEN            TEST FOR LRECL GT 80     S21085 28500021
         BH    RLGT80                   IF YES BRANCH                   28600019
MVCREC1  LR    REG15,REG7               SET UP FOR EX INST              28700019
MVCREC   MVI   8(REG3),BLK              CLEAR OUT INSERT BUF AREA       28800019
         MVC   9(79,REG3),8(REG3)                                       28900019
         BCTR  REG15,0                  SET UP REG FOR EX MOVE          29000019
         EX    REG15,MVCLN              MOVE RECORD TO OUTPUT BUFFER    29100019
         MVC   0(8,REG3),TUBNXKEY       SET KEY                         29200019
         TM    TUBFLG2,TUBLNUMN         TEST FOR LINE NOS IN LINE       29300019
         BZ    NOLNO                    IF NOT CONTINUE                 29400019
         MVC   80(8,REG3),TUBNXKEY      IF YES PUT LINE NO INTO LINE    29500019
NOLNO    LA    REG3,88(REG3)            INCREMENT TO NEXT BUFFER        29600019
         C     REG3,ENDINBUF            TEST FOR END OF BUFFER          29700019
         BNL   INSERT                   IF YES INSERT BUFFER            29800019
INSRET   PACK  LNOCALC,TUBNXKEY         CALC NEXT LINE NO               29900019
         CVB   REG15,LNOCALC                                            30000019
         L     REG14,TUBDIRAD                                           30100019
         USING DIRDSECT,REG14                                           30200019
         A     REG15,DIRINC                                             30300019
         DROP  REG14                                                    30400019
         CVD   REG15,LNOCALC                                            30500019
         UNPK  TUBNXKEY,LNOCALC                                         30600019
         OI    TUBNXKEY+7,NUMSIGN       SET GOOD ZONE PATTERN           30700019
         CLC   RECLEN+2(2),MAXLNLEN     TEST FOR LRECL GT 80     S21085 30800021
         BH    RLGT80A                  IF YES TEST LAST PORTION OF REC 30900019
         TM    SAVRECFM,DS1B            TEST FOR BLOCKED RECORDS        31000019
         BZ    READ                     IF NOT READ NEXT RECORD         31100019
         TM    SAVRECFM,DS1V            TEST FOR VARIABLE RECORDS       31200019
         BO    VARRECB                  IF YES BRANCH                   31300019
         AR    REG10,REG7               INCREMENT TO NEXT RECORD        31400019
         C     REG10,ENDRDBUF           TEST FOR END OF READ BUFFER     31500019
         BNL   READ                     IF YES READ NEXT BLOCK          31600019
         B     MVCREC1                  MOVE NEXT RECORD TO INSERT BUF  31700019
BLOCKED  LR    REG15,REG10              CALC END OF BLOCK ADDR          31800019
         AR    REG15,REG7                                               31900019
         ST    REG15,ENDRDBUF           SAVE ENDING ADDRESS             32000019
         B     BLOCKED1                 CONTINUE PROCESSING             32100019
         SPACE 3                                                        32200019
*********************************************************************** 32300019
*           PROCESS RECORDS WITH A LENGTH GREATER THAN 80 BYTES         32400019
*********************************************************************** 32500019
RLGT80A  TM    EDTSW,EOSLPOR            TEST FOR END OF RECORD          32600019
         BO    RLGT80B                  IF YES, TEST FOR READ NEEDED    32700019
         AH    REG10,MAXLNLEN           INCR TO NEXT PORTION     S21085 32800021
*                                         OF RECORD                     32900019
RLGT80   L     REG15,REMLEN             GET REMAINING LENGTH            33000019
         CH    REG15,MAXLNLEN           TEST FOR OVER FULL       S21085 33060021
*                                       RECORD REMAINING         S21085 33120021
         BH    RLGT80C                  IF NOT INS LAST PORTION         33200019
         OI    EDTSW,EOSLPOR            SET END OF RECORD SWITCH        33300019
         B     MVCREC                   MOVE RECORD TO INSERT BUFFER    33400019
RLGT80C  SH    REG15,MAXLNLEN           CALC REMAINING LENGTH    S21085 33460021
*                                       OF RECORD                S21085 33520021
*                                       AFTER INSERT                    33600019
         ST    REG15,REMLEN             STORE REMAINING LENGTH          33700019
RLGT80E  LH    REG15,MAXLNLEN           SET UP LENGTH FOR MOVE   S21085 33800021
         B     MVCREC                   MOVE RECORD TO INSERT BUFFER    33900019
RLGT80B  NI    EDTSW,EOSLPORF           TURN OFF END OF RECORD SWITCH   34000019
         TM    SAVRECFM,DS1B            TEST FOR BLOCKED RECORDS        34100019
         BZ    READ                     IF NOT READ NEXT RECORD         34200019
         A     REG10,REMLEN             INCREMENT POINTER TO NEXT REC   34300019
         C     REG10,ENDRDBUF           TEST FOR END OF BLOCK           34400019
         BNL   READ                     IF YES READ NEXT BLOCK          34500019
         TM    SAVRECFM,DS1V            TEST FOR VARIABLE RECORDS       34600019
         BO    VARREC2                  IF YES, PROCESS                 34700019
         LH    REG15,SAVLRECL           REINITIALIZE REMAINING LENGTH   34800019
         ST    REG15,REMLEN             SAVE REMANING LENGTH            34900019
         B     RLGT80                   PROCESS LAST PORTION OF RECORD  35000019
         SPACE 3                                                        35100019
*********************************************************************** 35200019
*           PROCESS VARIABLE LENGTH RECORDS                             35300019
*********************************************************************** 35400019
VAR      LH    REG15,0(REG10)           GET BLOCK SIZE                  35500019
         AR    REG15,REG10              GET ENDING ADDR OF BLOCK        35600019
         BCTR  REG15,0                                                  35700019
         ST    REG15,ENDRDBUF                                           35800019
         LA    REG10,4(REG10)           INCREMENT PTR PAST BLOCK LENGTH 35900019
VARREC2  MVC   TUBPARM1(2),0(REG10)     ALIGN LENGTH ON BOUNDARY A34599 35950020
         LH    REG7,TUBPARM1            PICK UP RECORD LENGTH    A34599 36020020
         S     REG7,F4                  TAKE OUT LEN BYTES FROM REC LEN 36100019
         ST    REG7,RECLEN              SAVE RECORD LENGTH              36200019
         CH    REG7,MAXLNLEN            TEST FOR RECORD LENGTH   S21085 36260021
*                                       GREATER THAN MAX         S21085 36320021
         BH    VARGT80                  IF YES INITILIZE REMLEN         36400019
VARREC1  LA    REG10,4(REG10)           INCR RECD PTR PAST REC LENGTH   36500019
         LR    REG15,REG7               SET UP LENGTH FOR MOVE          36600019
         B     MVCREC                   INSERT RECORD INTO INSERT BUF   36700019
VARGT80  LR    REG15,REG7               SET UP TO CALC REMAINING LENGTH 36800019
         SH    REG15,MAXLNLEN                                    S21085 36900021
         ST    REG15,REMLEN             INITILIZE REMLEN                37000019
         LH    REG15,MAXLNLEN           SET UP LENGTH FOR MOVE   S21085 37100021
         LA    REG10,4(REG10)           SKIP LENGYH BYTES               37200019
         B     MVCREC                   MOVE LINE TO BUFFER             37300019
VARRECB  A     REG10,RECLEN             INCREMENT POINTER TO NEXT REC   37400019
         C     REG10,ENDRDBUF           TEST FOR END OF BLOCK           37500019
         BNL   READ                     IF YES READ NEXT BLOCK          37600019
         B     VARREC2                  PROCESS NEXT RECORD             37700019
         SPACE 3                                                        37800019
*********************************************************************** 37900019
*           PROCESS UNDEFINED RECORDS                                   38000019
*********************************************************************** 38100019
UNDEF    L     REG14,CDECB+16           GET ADDR OF IOB                 38200019
         LH    REG15,14(REG14)          GET RESIDUAL COUNT              38300019
         LR    REG7,REG8                                                38400019
         SR    REG7,REG15               CALC RECORD LENGTH              38500019
         TM    SAVRECFM,DS1B            TEST FOR BLOCKED RECORDS        38600019
         BO    BLOCKED                  IF YES FIND END OF BUFFER       38700019
         ST    REG7,RECLEN              STORE RECORD LENGTH             38800019
         ST    REG7,REMLEN              SAVE REMAINING LENGTH           38850019
         LR    REG15,REG7               SET UP LENGTH FOR MOVE          38900019
         CH    REG7,MAXLNLEN            TEST FOR REC LEN GT MAX  S21085 39000021
         BNH   MVCREC                   IF NOT PUT REC IN INSERT BUF    39100019
         LH    REG15,MAXLNLEN                                    S21085 39200021
         B     RLGT80                                                   39300019
         SPACE 3                                                        39400019
*********************************************************************** 39500019
*           INSERT LINES INTO ACTIVE AREA                               39600019
*********************************************************************** 39700019
INSERT   LA    REG15,10                 PUT NO OF RECORDS TO BE         39800019
         BAL   REG3,INSERT1             INSERT BLOCK                    39900019
NXTGET   L     REG3,TUBRAFBF                                            40000019
         LA    REG3,8(REG3)       POINT TO FIRST LINE                   40100019
         B     INSRET                   CONTINUE PROCESSING             40200019
INSERT1  OI    TUBAFISW,BUFCTRL         SET BUFFER CONTROL SW           40300019
         STH   REG15,TUBCNTFS           GET NUMBER OF LINES             40400019
         LA    REG1,ADDRTUB(REG13)      BUILD PARAMETER LIST FOR IHKAFI 40500019
         INSERT M,A                     INSERT LINES INTO ACTIVE AREA   40600019
         C     REG15,F4                 TEST RETURN CODE                40700019
         BH    SAVRET                   IF DISK ERR OR GETMAIN FAILED,  40800019
*                                         RETURN                        40900019
         BE    OUTSPA                   IF A.A. OUT OF SPACE, ENQUEUE   41000019
*                                         ERR MSG AND RETURN            41100019
         BR    REG3                     EXIT                            41200019
*                                                                       41300019
*   EOD ON INPUT                                                        41400019
*                                                                       41500019
EODPROC  L     REG10,TUBRAFBF           CHECK FOR LINES LEFT IN         41600019
         CR    REG3,REG10               INSERT BUFFER                   41700019
         BNH   RETCD0                   IF NOT, RETURN                  41800019
         SR    REG3,REG10                                               41900019
         LA    REG10,RECLNGTH           TEST FOR LESS THAN 1 LINE       42000019
         CR    REG3,REG10                                               42100019
         BL    RETCD0                   IF LESS, RETURN                 42200019
         LR    REG15,REG3               CALC NUMBER OF LINES            42300019
         LA    REG14,0                                                  42400019
         LA    REG1,88                                                  42500019
         DR    REG14,REG1                                               42600019
         BAL   REG3,INSERT1             INSERT BLOCK                    42700019
         B     RETCD0                   RETURN                          42800019
*                                                                       42900019
         SPACE 3                                                        43000019
*********************************************************************** 43100019
*          SET UP PARAMETERS FOR AND GO TO IHKLDC TO LOAD OR DELETE     43200019
*          IHKOPN                                                       43300019
*********************************************************************** 43400019
         SPACE 1                                                        43500019
LDELOPN  TM    IHKYYLCE,POST            TEST FOR IHKLDC ABEND    A36810 43550020
         BO    RETCD12                  IF YES, RETURN           A36810 43600020
         L     REG15,TUBUFFAD                                    A36810 43650020
         LA    REG15,60(REG15)          POINT TO PARAMETER AREA         43700019
         XC    0(8,REG15),0(REG15)      CLEAR IHK2DC PARAMETER AREA     43800019
         ST    REG7,4(REG15)            PUT LOAD REQUEST CODE INTO AREA 43900019
         L     REG14,TUBCLBAD           SET UP CLB ADDRESSABILITY       44000019
         USING CLBDSECT,REG14                                           44100019
         LA    REG1,CLBLCECB            GET ADDRESS OF CLB ECB          44200019
         DROP  REG14                                                    44300019
         LR    REG0,REG15               GET ADDRESS OF RETURN ECB       44400019
         SVC   2                        ISSUE POST SVC                  44500019
         L     REG1,TUBUFFAD            GET ADDRESS OF RETURN ECB       44600019
         LA    REG1,60(REG1)                                            44700019
         L     REG15,IHKYYDSP           GET ADDRESS OF DISPATCHER       44800019
         BALR  REG14,REG15              WIAT IN DISPATCHER              44900019
         TM    IHKYYLCE,POST            TEST FOR IHKLDC ABEND    A36810 44930020
         BO    RETCD12                  IF YES, RETURN           A36810 44960020
         BR    REG6                     EXIT                            45000019
         SPACE 3                                                        45100019
*********************************************************************** 45200019
*           SUBROUTINE FOR GETMAINS                                     45300019
*********************************************************************** 45400019
         SPACE 1                                                        45500019
SUBRGETM LA    REG4,TUBPARM4            GET AREA FOR AREA ADDRESS       45600019
         ST    REG14,TUBPARM3           SAVE RETURN ADDRESS             45700019
         L     REG1,IHKYYGML            GET LIST ADDRESS                45800019
         GETMAIN EC,LV=(REG5),A=(REG4),MF=(E,(1))                       45900019
         LTR   REG15,REG15              TEST RETURN CODE                46000019
         BZ    GETMRTN                  IF ERROR, EXIT TO ERR ROUTINE   46100019
         L     REG14,TUBPARM3           RESTORE EXEI ADDRESS            46200019
         BR    REG14                    EXIT                            46300019
GETMRTN  BR    REG6                     ERROR EXIT                      46400019
         EJECT                                                          46500019
*********************************************************************** 46600019
*           ERROR ROUTINES                                              46700019
*********************************************************************** 46800019
         SPACE 3                                                        46900019
*********************************************************************** 47000019
*   DS NOT FOUND                                                        47100019
*********************************************************************** 47200019
         SPACE 1                                                        47300019
NFOUNDB  BAL   REG14,STRNAM8            SET UP DSNAME                   47400019
NFOUNDA  LA    REG1,NFNDCD              GET MESSAGE CODE                47500019
         B     ENQRTN0                  QUEUE MESSAGE AND RETURN        47600019
         SPACE 3                                                        47700019
*********************************************************************** 47800019
*           MEMBER NAME NOT FOUND                                       47900019
*********************************************************************** 48000019
         SPACE 1                                                        48100019
MEMBNFND LA    REG1,OSMEMBER            GET MEMBER NAME                 48200019
         B     NFOUNDB                  QUEUE MESSAGE                   48300019
         SPACE 3                                                        48400019
*********************************************************************** 48500019
*           DATA SET NOT FOUND                                          48600019
*********************************************************************** 48700019
         SPACE 1                                                        48800019
OSNFND   LA    REG15,MAXLEN             GET MAX LENGTH                  48900019
         LA    REG1,OSDSNAM             SET UP DSNAME                   49000019
         BAL   REG14,STRNAM10                                           49100019
         B     NFOUNDA                  QUEUE MESSAGE                   49200019
         SPACE 3                                                        49300019
*********************************************************************** 49400019
*           NO MEMBER NAME FOR PARTIONED DATA SET                       49500019
*********************************************************************** 49600019
         SPACE 1                                                        49700019
POERR    LA    REG15,10                 GET MAX OS DSNAME LENGTH        49800019
         LA    REG1,OSDSNAM             GET ADDR OF DSNAME              49900019
         BAL   REG14,STRNAM10           BUT DSNAME IN PARAMETER         50000019
         LA    REG1,POERRCD             GET MESSAGE NUMBER              50100019
         B     ENQRTN0                  ENQ MSG AND RETURN              50200019
*                                                                       50300019
STRNAM8  LA    REG15,MAXMEMBL           GET MAX MEMBER NAME LENGTH      50400019
         SPACE 3                                                        50500019
*********************************************************************** 50600019
*          SET UP DSNAME OR MEMBER NAME FOR MESSAGE                     50700019
*********************************************************************** 50800019
         SPACE 1                                                        50900019
STRNAM10 L     REG4,TUBUFFAD            LOCATE NAME                     51000019
         LA    REG4,88(REG4)                                            51100019
         STC   REG15,0(REG4)            STORE LENGTH                    51200019
         BCTR  REG15,0                                                  51300019
         EX    REG15,MVCNAM             MOVE NAME                       51400019
         BR    REG14                    EXIT                            51500019
         SPACE 3                                                        51600019
*********************************************************************** 51700019
*          I/O ERROR ON OS DATA SET                                     51800019
*********************************************************************** 51900019
         SPACE 1                                                        52000019
OSIOERR  LA    REG1,DERRCDU             GET MESSAGE CODE                52100019
         B     FLGLST                   QUEUE MESSAGE                   52200019
         SPACE 3                                                        52300019
*********************************************************************** 52400019
*           EXPIRATION DATE NOT REACHED                                 52500019
*********************************************************************** 52600019
         SPACE 1                                                        52700019
EXPDATE  LA    REG1,EXPMSG              GET MESSAGE CODE                52800019
         B     FLGLST                   QUEUE MESSAGE                   52900019
         SPACE 3                                                        53000019
*********************************************************************** 53100019
*           DATA SET RESIDES ON MULTIPLE VOLUMES                        53200019
*********************************************************************** 53300019
         SPACE 1                                                        53400019
MULTVOL  LA    REG1,MVOLCD              GET MESSAGE CODE                53500019
         B     FLGLST                   QUEUE MESSAGE                   53600019
         SPACE 3                                                        53700019
*********************************************************************** 53800019
*            DATA SET ORGNIZATION INVALID                               53900019
*********************************************************************** 54000019
         SPACE 1                                                        54100019
ORGERR   LA    REG1,INVORGCD            GET MESSAGE CODE                54200019
         B     FLGLST                   QUEUE MESSAGE                   54300019
         SPACE 3                                                        54400019
*********************************************************************** 54500019
*           OPEN FAILED                                                 54600019
*********************************************************************** 54700019
         SPACE 1                                                        54800019
OPNERR   LA    REG1,OPNERCD             GET MESSAGE CODE                54900019
         B     FLGLST                   QUEUE MESSAGE                   55000019
         SPACE 3                                                        55100019
*********************************************************************** 55200019
*           VOLUME NOT MOUNTED                                          55300019
*********************************************************************** 55400019
         SPACE 1                                                        55500019
NOTMOUNT LA    REG1,NMNTCD              GET MESSAGE CODE                55600019
         B     FLGLST                   QUEUE MESSAGE                   55700019
         SPACE 3                                                        55800019
*********************************************************************** 55900019
*           PASSWORD NOT GIVEN BY CENTRAL OPERATOR ON OPEN              56000019
*********************************************************************** 56100019
         SPACE 1                                                        56200019
PASSERR  LA    REG1,PASSCD              GET MESSAGE NUMBER              56300019
         B     FLGLST                   ENQUEUE MESSAGE                 56400019
         SPACE 3                                                        56500019
*********************************************************************** 56600019
*           GETMAIN FAILURE                                             56700019
*********************************************************************** 56800019
         SPACE 1                                                        56900019
OUTSPA   OI    EDTSW,EDT2PARM           SET NO INSERT SW                57000019
         LA    REG1,OUTSPCDU            GET MESSAGE CODE                57100019
         BAL   REG6,ENQMSG              ENQUEUE MSG FOR USER            57200019
         B     RETCD20                  SET RETURN CODE OF 20           57300019
         SPACE 3                                                        57400019
*********************************************************************** 57500019
*                                                                       57600019
*           ROUTINE TO ENQUEUE MESSAGE FOR USER                         57700019
*                                                                       57800019
*********************************************************************** 57900019
         SPACE 1                                                        58000019
FLGLST   OI    EDTSW,EDT2PARM           SET 2 PARAMETER SWITCH          58100019
ENQRTN0  LA    REG6,RETCD0              GET RETURN ROUTINE ADDRESS      58200019
ENQMSG   LA    REG14,TUBPARM5           FINISH PARAMETER LIST           58300019
         ST    REG14,TUBPARM3                                           58400019
         L     REG15,IHKYMSG1           LOAD MSG WRITER EP ADDRESS      58500019
         LA    REG14,TUBUSRID                                           58600019
         ST    REG14,TUBPARM2                                           58700019
         OI    PPTFLG,PPTERR                                            58800019
         TM    EDTSW,EDT2PARM           TEST FOR 2 PARAMETERS           58900019
         BO    ENQMSG1                  IF YES  FLAG END OF PARM LIST   59000019
ENQMSGC  ST    REG4,TUBPARM4                                            59100019
         OI    TUBPARM4,ENDLST                                          59200019
         B     ENQMSG2                  ENQUEUE ERR MESSAGE             59300019
ENQMSG1  OI    TUBPARM3,ENDLST                                          59400019
         NI    EDTSW,EDT2PARF           TURN OFF 2 PARAMETER SW         59500019
ENQMSG2  MVC   TUBPARM5+1(3),0(REG1)                                    59600019
         MVI   TUBPARM5,X00                                             59700019
         ST    RTUB,TUBPARM1            SET UP 1ST PARM                 59800019
         LA    REG1,TUBPARM1                                            59900019
         BALR  REG14,REG15              ENQUEUE MESSAGE                 60000019
         B     *+4(REG15)               TEST RETURN CODE                60100019
         B     0(REG6)                  EXIT                            60200019
         B     0(REG6)                  EXIT                            60300019
         B     RETCD8                   GETMAIN FAILURE                 60400019
         B     RETCD12                  AA I/O ERROR                    60500019
         B     RETCD16                  MESSAGE LOST                    60600019
         B     RETCD20                  AA OUT OF SPACE                 60700019
         SPACE 3                                                        60800019
*********************************************************************** 60900019
*           GETMAIN ERROR ROUTINE                                       61000019
*********************************************************************** 61100019
         SPACE 1                                                        61200019
GMERR    LA    REG15,RC8                SET GETMAIN FAILURE RETURN CODE 61300019
         NI    TUBFLG1,TUBFLG1F         TURN OFF ALL EDIT FLAGS IN TUB  61400019
         NI    TUBFLG2,TUBFLG2F                                         61500019
         NI    TUBFLG3,TUBFLG3F                                         61600019
         B     RETURN4                  RETURN                          61700019
         SPACE 3                                                        61800019
*********************************************************************** 61900019
*           RETURN ROUTINE                                              62000019
*********************************************************************** 62100019
         SPACE 1                                                        62200019
SAVRET   LR    REG8,REG15               SAVE RETURN CODE                62300019
         B     RETURN                   CONTINUE                        62400019
RETCD0   LA    REG8,RC0                 SET GOOD RETURN CODE            62500019
RETURN   TM    EDTSW,EDTREL             TEST RELEASE SWITCH             62600019
         BZ    RETURN1                  IF NOT SET, SKIP RELEASE        62700019
         TM    PPTFLG,PPTERR            TEST FOR ERROR                  62800019
         BO    FREEDIR                  IF SET, RELEASE ACTIVE FILE     62900019
         LTR   REG8,REG8                TEST FOR ERROR RETURN CODE      63000019
         BZ    ENDUP                    IF NONE, SKIP RELEASE           63100019
FREEDIR  LA    REG1,DIRSIZE             GET DIRECTORY SIZE              63200019
         LR    REG0,REG1                                                63300019
         L     REG1,TUBDIRAD            GET DIRECTORY ADDRESS           63400019
         LA    REG1,0(REG1)                                             63500019
         LTR   REG1,REG1                CHECK FOR DIRECTORY ENTRY       63600019
         BZ    RELESE                   IF NONE, DONT FREE AREA         63700019
         FREEMAIN R,LV=(0),A=(1)        FREE UP DIRECTORY ENTRY         63800019
         SR    REG1,REG1                                                63900019
         ST    REG1,TUBDIRAD                                            64000019
RELESE   LA    REG1,ADDRTUB(REG13)                                      64100019
         RELEASE A                      FREE UP ACTIVE AREA             64200019
         B     RETURN1                  RETURN                          64300019
ENDUP    LA    REG1,ADDRTUB(REG13)      BUILD PARAMETER LIST FOR IHKAFI 64400019
*           INSURE THAT ALL PENDING UPDATES ARE DONE ON ACTIVE FILE     64500019
         ENDUP                                                          64600019
RETURN1  TM    EDTSW,EOSBUFR            TEST FOR READ BUFFER            64700019
         BZ    RETURN3                  IF NOT THERE, DONT FREE AREA    64800019
         LH    REG1,SAVBLKL             GET BUFFER LENGTH               64900019
         LR    REG0,REG1                                                65000019
         L     REG1,BUFADR              GET BUFFER ADDRESS              65100019
         FREEMAIN R,LV=(0),A=(1)        FREE BUFFER                     65200019
RETURN3  L     REG5,TUBUFFAD                                            65300019
         LA    REG5,100(REG5)           GET IHKOPN ECB ADDRESS          65400019
         TM    IHKYYLCE,POST            TEST FOR IHKLDC ABEND    A36810 65430020
         BO    FLGOFF                   IF YES, TURN OFF EDIT SW A36810 65460020
         CLI   1(REG5),OPNABEND         TEST FOR ABEND OF IHKOPN        65500019
         BNE   RETURN6                  IF YES, DONT LINK TO IHKOPN     65600019
         MVI   0(REG5),CLRPOST          CLEAR POST BIT IN IHKOPN'S ECB  65700019
         LA    REG5,4(REG5)             GET ADDRESS OF ECB              65800019
         LR    REG1,REG5                                                65900019
         SVC   2                        ISSUE POST                      66000019
         S     REG5,F4                  POINT TO IHKOPN ECB             66100019
         LR    REG1,REG5                                                66200019
         L     REG15,IHKYYDSP           GET DISPATCHER ADDRESS          66300019
         BALR  REG14,REG15              WAIT                            66400019
RETURN6  L     REG5,TUBUFFAD            GET IHKOPN TCB ADDRESS          66500019
         LA    REG5,108(REG5)                                           66600019
         DETACH (REG5)                  DETACH IHKOPN                   66700019
         LA    REG7,CMDOPN              GET COMMAND CODE OF IHKOPN      66800019
         SLL   REG7,DELOPN              SET UP FOR DELETE OF IHKOPN     66900019
         BAL   REG6,LDELOPN            DELETE IHKOPN                    67000019
RETURN2  TM    PPTFLG,PPTERR            TEST FOR ERROR           A36810 67100020
         BO    FLGOFF                   IF  YES, TURN OFF TUB FLAGS     67300019
         LTR   REG8,REG8                TEST FOR BAD RET CD             67400019
         BZ    RETURN5                  IF YES, DON'T TURN OFF EDIT SW  67500019
FLGOFF   NI    TUBFLG1,TUBFLG1F         TURN OFF ANY BITS SET           67600019
         NI    TUBFLG2,TUBFLG2F                                         67700019
         NI    TUBFLG3,TUBFLG3F                                         67800019
RETURN5  L     REG7,4(REG13)                                     A36810 67850020
         NI    TUBAFISW,BUFCTRLF        RESET BUFFER CONTROL SW  A36810 67920020
         LA    REG1,GMLEN               GET SAVE AND WORK AREA LENGTH   68000019
         LR    REG0,REG1                                                68100019
         LR    REG1,REG13               GET AREA ADDRESS                68200019
         FREEMAIN R,LV=(0),A=(1)        FREE SAVE AND WORK AREA         68300019
         LR    REG13,REG7                                               68400019
         LR    REG15,REG8                                               68500019
RETURN4  RETURN (14,12),,RC=(15)        RETURN TO CALLER                68600019
RETCD8   LA    REG8,RC8                 SET RETURN CODE OF 8            68700019
         B     RETURN                   RETURN                          68800019
RETCD12  LA    REG8,RC12                SET RETURN CODE OF 12           68900019
         B     RETURN                   RETURN                          69000019
RETCD16  LA    REG8,RC16                SET RETURN CODE OF 16           69100019
         B     RETURN                   RETURN                          69200019
RETCD20  LA    REG8,RC20                SET RETURN CODE OF 20           69300019
         B     RETURN                   RETURN                          69400019
         EJECT                                                          69500019
*********************************************************************** 69600019
*                                                                       69700019
*           CONSTANTS                                                   69800019
*                                                                       69900019
*********************************************************************** 70000019
NODATE   DC    XL3'00'                  NO DATE PROTECTION              70100019
BLANKS   DC    CL8' '                   BLANKS FOR CLEARING FIELDS      70200019
F4       DC    F'4'                     FULLWORD CONSTANT OF 4          70300019
F24      DC    F'24'                    FULLWORD CONSTANT OF 24         70400019
H8       DC    H'8'                     HALFWORD CONSTANT OF 8          70500019
H72      DC    H'72'                    LINE LENGTH OF 72        S21085 70560021
H80      DC    H'80'                    LINE LENGTH OF 80        S21085 70620021
DDNAME   DC    C'CR'                    1ST 2 CHARACTERS OF DDNAME      70700019
         SPACE 3                                                        70800019
*********************************************************************** 70900019
*           MESSAGE CODES                                               71000019
*********************************************************************** 71100019
EXPMSG   DC    C'404'                   EXPIRATION DATE NOT REACHED     71200019
NMNTCD   DC    C'304'                                                   71300019
NFNDCD   DC    C'338'                   DS NOT FOUND                    71400019
DERRCDU  DC    C'332'                   DISK ERROR     (USER)           71500019
OUTSPCDU DC    C'357'                   OUT OF SPACE  (USER)            71600019
ATTINVCD DC    C'360'                   ATTRIBUTE INCONSISTANT S/SCAN   71700019
MVOLCD   DC    C'384'                                                   71800019
INVORGCD DC    C'339'                                                   71900019
OPNERCD  DC    C'347'                                                   72000019
POERRCD  DC    C'401'                   CANNOT EDIT ALL OF PO DS        72100019
PASSCD   DC    C'407'                   PASSWORD PROTECTED              72200019
         SPACE 3                                                        72300019
*********************************************************************** 72400019
*           EXECUTED INSTRUCTIONS                                       72500019
*********************************************************************** 72600019
         SPACE 1                                                        72700019
MVCLN    MVC   8(0,REG3),0(REG10)                                       72800019
MVCNAM   MVC   1(0,REG4),0(REG1)                                        72900019
         SPACE 3                                                        73000019
*                                                                       73100019
*   CODSS SET BY SCRATCH                                                73200019
*                                                                       73300019
SNODSCB  EQU   X'01'         VTOC DOES NOT CONTAIN DSCB                 73400019
SNOEXPIR EQU   X'03'         EXPIR DATE NOT REACHED                     73500019
SIOERR   EQU   X'04'         I/O ERROR                                  73600019
SNODEVIC EQU   X'05'         NO DEVICE FOR MOUNTING                     73700019
SNOMNT   EQU   X'06'         UNABLE TO MOUNT                            73800019
*                                                                       73900019
*   CAMLIST CODES                                                       74000019
*                                                                       74100019
*        CAMLST NAME,OSDSNAM,,VOLLIST   CAMLST FOR LOCATE MACRO         74200019
*        CAMLST SEARCH,OSDSNAM,CURRVOL,DSCBWORK  LST FOR OBTAIN MACRO   74300019
*CAM3    CAMLST  SCRATCH,OSDSNAM,,VOLLIST,,OVRD                         74400019
*CAM4    CAMLST SCRATCH,OSDSNAM,,VOLLIST                                74500019
*REMOVE  CAMLST UNCAT,EOSDSNAM                                          74600019
LOCOD    EQU   68            LOCATE                                     74700019
OBTCOD   EQU   193           OBTAIN                                     74800019
SCRCOD   EQU   65            SCRATCH                                    74900019
UNCCOD   EQU   12            UNCATALOG                                  75000019
OVRDCOD  EQU   80            PURGE                                      75100019
NOPRCOD  EQU   64            NO PURGE                                   75200019
*                                                                       75300019
*                                                                       75400019
*********************************************************************** 75500019
*                                                                       75600019
*           DSECT FOR VARIABLES PARMATER LISTS ETC.                     75700019
*                                                                       75800019
*********************************************************************** 75900019
*                                                                       76000019
OSDSECT  DSECT                                                          76100019
SAVEA    DS    18F                                                      76200019
ADDRTUB  EQU   X'1C'                                                    76300019
OSDSNAM  DS    CL44                                                     76400019
         DS    CL4                                                      76500019
KEYSTO   DS    CL3                                                      76600019
         ORG   KEYSTO                                                   76700019
OSMEMBER DS    CL8                                                      76800019
CURRNUM  DS    H                                                        76900019
SAVLRECL DS    H                                                        77000019
CURRVOL  DS    F                                                        77100019
ENDRDBUF DS    F                                                        77200019
BUFADR   DS    F                                                        77300019
ENDINBUF DS    F                                                        77400019
RECLEN   DS    F                                                        77500019
REMLEN   DS    F                                                        77600019
LNOCALC  DS    D                                                        77700019
SAVBLKL  DS    CL2                                                      77800019
SAVRECFM DS    X                                                        77900019
*********************************************************************** 78000019
*        INTERNAL SWITCHES - STORED IN PPT                              78100019
*********************************************************************** 78200019
*           EQUATES FOR PPT SWITCHES                                    78300019
PPTEDT   EQU   X'80'                    EDIT FLAG                       78400019
PPTPRG   EQU   X'80'                                                    78500019
PPTNOPRG EQU   X'7F'                                                    78600019
PPTDEL   EQU   X'40'                                                    78700019
PPTOS    EQU   X'10'                    OS SWITCH                       78800019
PPTMEMB  EQU   X'08'                    PDS SWITCH                      78900019
PPTNMNT  EQU   X'04'                                                    79000019
PPTKEY   EQU   X'02'                    KEY STORED SWITCH               79100019
PPTERR   EQU   X'01'                                                    79200019
PPTNOERR EQU   X'FE'                                                    79300019
         SPACE 1                                                        79400019
PPTFLG   DS    X                                                        79500019
SWDEF    DS    0CL4                                                     79600019
SWDEFEDT DS    X                                                        79700019
PL1OFF   EQU   X'FB'                                                    79800019
FORTOFF  EQU   X'FC'                                                    79900019
SWDEFATT DS    X                                                        80000019
SWDEFBSM DS    X                                                        80100019
SWDEFESM DS    X                                                        80200019
ATTOFF   EQU   X'00'                                                    80300019
         SPACE 1                                                        80400019
*********************************************************************** 80500019
*           PROCESSING SWITCHES                                         80600019
*********************************************************************** 80700019
EDTSW    DS    X                                                        80800019
EDTUID   EQU   X'80'                                                    80900019
EDTOPN   EQU   X'40'                                                    81000019
EDTOPNF  EQU   X'BF'                                                    81100019
EOSLPOR  EQU   X'20'                                                    81200019
EOSLPORF EQU   X'DF'                                                    81300019
EOSMSG   EQU   X'10'                                                    81400019
EOSMSGF  EQU   X'EF'                                                    81500019
EDT2PARM EQU   X'08'                    TWO PARAMETERS FOR MSG WTR      81600019
EDT2PARF EQU   X'F7'                    TURN OFF 2 PARM SW              81700019
EOSREAD  EQU   X'04'                                                    81800019
EOSREADF EQU   X'FB'                                                    81900019
EDTREL   EQU   X'02'                                                    82000019
EOSBUFR  EQU   X'01'                                                    82100019
EDTOFF   EQU   X'00'                      ALL SWITCHES OFF              82200019
         SPACE 1                                                        82300019
*                                                                       82400019
CAMLIST  DS    0F            ALIGN ON FULL WORD BOUNDARY                82500019
CAMFLG1  DS    AL1           THREE BYTES OF FLAGS INDICATING            82600019
CAMFLG2  DS    AL1           THE FUNCTION TO BE PERFORMED               82700019
CAMFLG3  DS    AL1                                                      82800019
CAMOPT3  DS    AL1           NO OPTION THREE                            82900019
CAMNAM   DS    A             PARAMETER TWO                              83000019
CAMPARM3 DS    A             PARAMETER THREE                            83100019
CAMPARM4 DS    A             PARAMETER FOUR                             83200019
*                                                                       83300019
         DS    0D                                                       83400019
NUMVOL   DS    H                   NUMBER OF VOLUME POINTERS            83500019
VOLID    DS    CL12                1- 20 VOL ID                         83600019
         ORG   VOLID                                                    83700019
DEVCODE  DS    4C                  DEVICE CODE                          83800019
LOCVOL   DS    6C            VOLUME SERIAL NUMBER                       83900019
SCRERR   DS    C                                                        84000019
         DS    0D                                                       84100019
ADDRDCB  DS    CL96                                                     84200019
INSERTBF DS    0D                                                       84300019
         ORG   NUMVOL                                                   84400019
VOLLIST  DS    265C                                                     84500019
ZEROFLD  EQU   X'0A'               ZERO FIELD- 10 BYTES                 84600019
         SPACE 3                                                        84700019
*********************************************************************** 84800019
*           DSECT FOR DSCB (DATA PORTION)                               84900019
*********************************************************************** 85000019
DSCBWORK DS    0D                                                       85100019
DS1FMTIO DS    C                        FORMAT IDENTIFIER               85200019
DS1DSSN DS     CL6                      DATA SET SERIAL NO              85300019
DS1VOLSQ DS    CL2                      VOLUME SEQUENCE NO              85400019
DS1CREDT DS    CL3                      CREATION DATE                   85500019
DS1EXPDT DS    CL3                      EXPIRATION DATE                 85600019
DS1NOEPV DS    C                        NUMBER OF EXTENTS               85700019
DS1NOBDB DS    C                        NO BYTES USED IN LAST DIR BLK   85800019
         DS    C                        RESERVED                        85900019
DS1SUSCO DS    CL13                     SYSTEM CODE                     86000019
         DS    CL7                      RESERVED                        86100019
DS1DSORG DS    CL2                      DATA SET ORGNIZATION            86200019
DS1PS    EQU   X'40'                      SEQUENTIAL                    86300019
DS1PO    EQU   X'02'                      PARTIONED                     86400019
DS1RECFM DS    X                        RECORD FORMAT                   86500019
DS1F     EQU   X'80'                      FIXED                         86600019
DS1V     EQU   X'40'                      VARIABLE                      86700019
DS1U     EQU   X'C0'                      UNDEFINED                     86800019
DS1B     EQU   X'10'                      BLOCKED                       86900019
DS1OPTCD DS    C                        OPTION CODE                     87000019
DS1BLKL  DS    CL2                      BLOCK LENGTH                    87100019
DS1LRECL DS    CL2                      LOGICAL RECORD LENGTH           87200019
DS1KEYL  DS    C                        KEY LENGTH                      87300019
DS1RKP   DS    CL2                      RELATIVE KEY POSITION           87400019
DS1DSIND DS    C                        DATA SET INDICATORS             87500019
DS1PASS  EQU   X'10'                    PASSWORD PROTECTED              87600019
DS1SCALO DS    CL4                      SECONDARY ALLOCATION            87700019
DS1LSTAR DS    CL3                      LAST BLOCK POINTER              87800019
DS1TRBAL DS    CL2                      COUNT                           87900019
         DS    CL2                      RESERVED                        88000019
DS1EXT1  DS    CL10                     FIRST EXTENT                    88100019
DS1EXT2  DS    CL10                     SECOND EXTENT                   88200019
DS1EXT3  DS    CL10                     THIRD EXTENT                    88300019
DS1PTRDS DS    CL5                      POINTER TO FORMAT 2 DSCB        88400019
         ORG   INSERTBF                                                 88500019
         DS    CL888                    INSERT BUFFER                   88600019
         SPACE 3                                                        88700019
*********************************************************************** 88800019
*            DSECT FOR JFCB                                             88900019
*********************************************************************** 89000019
JFCB     DS    0XL176                                                   89100019
JFCBDSN  DS    CL44                                                     89200019
         DS    XL43                                                     89300019
JFCBIND2 DS    X                                                        89400019
         DS    XL30                                                     89500019
JFCBVOLS DS    CL30                                                     89600019
         DS    CL28           REST OF DSCB WORKAREA                     89700019
MAXLNLEN DS    H                        MAX LINE LENGTN          S21085 89750021
GMLEN    EQU   *-OSDSECT                                                89800019
*                                                                       89900019
*********************************************************************** 90000019
*                                                                       90100019
*                                                                       90200019
*   DSECTS FOR OS PROCESSING                                            90300019
*                                                                       90400019
*           DSECTS FOR CONTROL BLOCKS                                   90500019
*                                                                       90600019
*********************************************************************** 90700019
         DCBD  DSORG=(PS,PO),DEVD=(DA)                                  90800019
DCBDLEN  EQU   *-IHADCB                                                 90900019
         SPACE 3                                                        91000019
IRLPARMS DSECT                                                          91100019
IRLSW    DS    X                          PROCESSING SWITCHES           91200019
IRLINS   EQU   X'40'                        INSERT ONLY                 91300019
IRLREP   EQU   X'20'                        REPLACE ONLY                91400019
IRLOFF   EQU   X'80'                        ALL SWITCHES OFF            91500019
         DS    CL5                                                      91600019
IRLSTAD  DS    CL8                        BEGNING LINE NO               91700019
IRLINC   DS    F                          DATA SET INCREMENT            91800019
         IHKCDSCT TUB=YES,DIR=YES,AVT=YES,DEF=YES,CLB=YES               91900019
         RAFKNBX TYPE=DSECT                                             92000019
         TUBEQU                         EQUATES FOR TUB                 92100019
         END                                                            92200019
