EXC      TITLE 'EXCCW:  CHANNEL PROGRAM EXECUTORS'                      00040019
*                                                                       00080019
         MACRO                                                          00120019
&LABEL   DK    &A                                                       00160019
&LABEL   DC    AL1(&A)                                                  00200019
         MEND                                                           00240019
*                                                                       00280019
         IHKCDSCT  TUB=YES                                              00320019
         TUBEQU                                                         00360019
* REGISTER DEFINITIONS                                                  00400019
*                                                                       00440019
         AFIOEQU                                                        00480019
*  REGISTERS USED BY REQUESTORS                                         00520019
*                                                                       00560019
ARG1RG   EQU   CCWRG                   # CCW'S                          00600019
ARG2RG   EQU   SRCHRG                  # SEARCH ARGUMENTS               00640019
ARG3RG   EQU   GR2RG                   # BYTES OF TEMPORARY STORAGE     00680019
ARG4RG   EQU   GR3RG                   XACH OF I/O TRACK                00720019
ALL      EQU   X'FF'                                                    00760019
*                                                                       00800019
*                                                                       00840019
         USING IHKEXC,BASERG                                            00880019
         USING RAFKNBX,KBXRG                                            00920019
         USING TUBDSECT,APW2RG                                          00960019
         USING AFCTLDS,FBXRG      ACTIVE FILE CONTROL INFORMATION       01000019
         USING EXCPFWDS,AFWRG     TEMPORARY WORK AND CONSTANT AREA      01040019
         USING CCWMSK,CCWRG       CCW LIST BASE REGISTER                01080019
         USING CNTSRCH,SRCHRG     SEARCH ARGUMENT LIST                  01120019
*        LINK1RG = PRIMARY RETURN                                       01160019
*        LINK2RG = SECONDARY RETURN                                     01200019
*        INTLNKRG = ENTRY POINT ADDRESS                                 01240019
*        ICRG = INDEX TO LINKAGE TABLE ON INITIAL ENTRIES               01280019
*                                                                       01320019
         EXCCWDS TYPE=CSECT                                             01360019
*D038400,A438850-439500,C441000-441200,C444200-444800,          A42692  01365026
*A448600,D450400,D450800-452400,D454400-456800,D459600-460400,  A42692  01370026
*A460000,D463200-466000,C471200,C472000-472400,D473200-473600,  A42692  01375026
*C474800-475600,A477400,A482600,D483600,C483800,D484400-484800, A42692  01380026
*D489200-492800,A490800,A788007-788014,A788301                  A42692  01385026
*C400600-400800,A431800,C508000,C515000-515200,A520200,A567400, A45668  01390026
*A782400-782600                                                 A45668  01395026
*                                                                       01400019
*                                                                       01440019
**********************************************************************  01480019
*                                                                       01520019
* CHKNDX - SAVE THE ADDRESS OF FILE INDEX RECORD IN MASTER INDEX.       01560019
*                                                                       01600019
CHKNDXEX LR    LINK1RG,LINK2RG    SET FOR EXCP RETURN                   01640019
         BAL   LINK2RG,LOCNTRY    LOCATE INDEX ENTRY                    01680019
         L     GR2RG,AVLRECFW     PICK UP ADDRESS OF INDEX RECORD       01720019
         ST    GR2RG,4(GR1RG)          AND SAVE IN MASTER INDEX         01760019
         USING MASTLIST,CCWRG                                           01800019
MASTROUT MVI   MASTCCW1,WRITED    MODIFY CHANNEL PROGRAM FOR OUTPUT     01840019
         MVI   MASTCCW1+4,CC           AND WRITE CHECKING               01880019
         USING CCWMSK,CCWRG                                             01920019
         BALR  LINK1RG,LINK1RG         AND EXECUTE CP AGAIN             01960019
SIMPLE   BALR  LINK1RG,LINK1RG         ALL DONE                         02000019
         BR    LINK1RG                 BACK TO SCHEDULER                02040019
*                                                                       02080019
**********************************************************************  02120019
*                                                                       02160019
* LOCNDX - LOCATE INDEX RECORD THROUGH MASTER INDEX.                    02200019
*                                                                       02240019
LOCNDXEX BALR  LINK1RG,LINK1RG         SIMPLE CHANNEL END               02280019
         BAL   LINK2RG,LOCNTRY    LOCATE INDEX ENTRY                    02320019
         L     GR1RG,4(GR1RG)     PICK UP FILE INDEX TRACK ADDRESS      02360019
         ST    GR1RG,NDXRTKFW          AND SAVE IN FILE CONTROL         02400019
         BR    LINK1RG            THAT'S IT                             02440019
*                                                                       02480019
*********************************************************************** 02520019
*                                                                       02560019
* DELNDX - RESET MASTER INDEX ENTRY FOR THIS FILE TO ITS EMPTY VALUE.   02600019
*                                                                       02640019
DELNDXEX LR    LINK1RG,LINK2RG    SETUP EXCP RETURN                     02680019
         BAL   LINK2RG,LOCNTRY    LOCATE MASTER INDEX ENTRY             02720019
         XC    1(7,GR1RG),1(GR1RG)          AND SET IT TO               02760019
         MVI   0(GR1RG),X'FF'          X'FF00000000000000'              02800019
         B     MASTROUT                GO OUTPUT MODIFIED MASTER INDEX  02840019
MAST1EX  BALR  LINK1RG,LINK1RG    SIMPLE PROGRAM                        02880019
         BAL   LINK2RG,LOCNTRY    LOCATE MASTER INDEX ENTRY             02920019
         L     GR2RG,0(GR1RG)     LOCATE FIRST DATA RECORD ADDRESS      02960019
         ST    GR2RG,SCHTRKFW          TRACK ADDRESS                    03000019
         IC    GR2RG,0(GR1RG)          RECORD NUMBER                    03040019
         STC   GR2RG,SCHRRFW                                            03080019
         MVI   SCSGNMFW,1         SET FOR SEGMENT NUMBER ONE            03120019
         BR    LINK1RG                 DONE                             03160019
*                                                                       03200019
*********************************************************************** 03240019
*                                                                       03280019
* RELES - RELEASE ALL DATA TRACKS IN THIS FILE FOR ALLOCATION.          03320019
*       EACH TRACK REPRESENTED IN THE SEGMENT LIST OF THE INDEX RECORD  03360019
*        IS RELEASED.  ALSO THE FILE CHECKPOINT INFORMATION IS          03400019
*        RETRIEVED.                                                     03440019
*                                                                       03480019
RELESEX  BALR  LINK1RG,LINK1RG         SIMPLE PROGRAM                   03520019
         MVC   FNAMEFW(16),TMPAREA2    FIRST PART OF CHECKPOINT         03560019
         L     SRCHRG,CCWADDR4    LOCATE SEGMENT LIST PREFIX            03600019
         DROP  SRCHRG                                                   03640019
         MVC   FNAMEFW+16(16),0(SRCHRG)     PART TWO OF CHECKPOINT      03680019
         IC    ICRG,NUMSEGFW      PICK UP COUNT OF SEGMENTS             03720019
         LTR   ICRG,ICRG          CHECK FOR NULL FILE                   03760019
         BZ    RELESNDX                JUST RELEASE INDEX TRACK IF SO   03800019
RELESX1  LA    SRCHRG,16(SRCHRG)  BUMP TO NEXT SEGMENT ENTRY            03880019
         L     CYLERG,0(SRCHRG)   PICK UP TRACK ADDRESS                 03920019
         BAL   LINK2RG,PUTRACK         AND RELEASE TRACK FOR ALLOCATION 03960019
         BCT   ICRG,RELESX1            CONTINUE THROUGH ALL SEGMENTS    04000019
RELESNDX L     CYLERG,NDXRTKFW    RELEASE INDEX TRACK                   04040019
         BAL   LINK2RG,PUTRACK                                          04080019
         BR    LINK1RG            RETURN TO SCHEDULER                   04120019
         USING CNTSRCH,SRCHRG                                           04160019
*                                                                       04200019
**********************************************************************  04240019
*                                                                       04280019
* OLDNDX - DETERMINE THE FOLLOWING INDEX RECORD AND FILE                04320019
*        CHARACTERISTICS:    1)   32 BYTES OF FILE NAME AND CHECKPOINT  04360019
*                                 INFORMATION.                          04400019
*                            2)   RECORD NUMBER OF CURRENT INDEX RECORD 04440019
*                            3)   LENGTH OF CURRENT TRACK LIST          04480019
*                            4)   NUMBER OF SEGMENTS IN THE FILE        04520019
*                            5)   NUMBER OF AVAILABLE BYTES ON INDEX    04560019
*                                 TRACK                                 04600019
*                                                                       04640019
OLDNDXEX LH    GR1RG,IOBCSW+6     PICK UP CSW COUNT                     04680019
         LCR   GR1RG,GR1RG             AND COMPUTE TRACK BALANCE        04720019
         STH   GR1RG,BALNDXFW     SAVE NEW TRACK BALANCE                04760019
         BALR  LINK1RG,LINK1RG    I/O COMPLETE                          04800019
         USING ARGLIST,SRCHRG                                           04840019
         IC    GR1RG,ARG4+4       SAVE CURRENT INDEX RECORD NUMBER      04880019
         STC   GR1RG,NDXRTKFW                                           04920019
         IC    ICRG,ARG4+5        PICK UP CURRENT TRACK LIST LENGTH     04960019
         STC   ICRG,TKLSTZFW           AND SAVE                         05000019
         LR    GRORG,ICRG         CHECK IT FOR VALID LENGTH             05040019
         SR    GRERG,GRERG                                              05080019
         SH    GRORG,H16KN                                              05120019
         BC    4,SETIOERR              GREATER THAN OR EQUAL TO 16      05160019
         D     GRERG,F5KN              AND MULTIPLE OF 5 PLUS 16        05200019
         LTR   GRERG,GRERG                                              05240019
         BC    7,SETIOERR              ERROR IF REMAINDER               05280019
         LH    GRORG,ARG4+6       PICK UP LENGTH OF SEGMENT LIST        05320019
         USING CNTSRCH,SRCHRG                                           05360019
         D     GRERG,F16KN             AND COMPUTE NUMBER OF SEGMENTS   05400019
         LTR   GRERG,GRERG             MUST BE MULTIPLE OF 16 BYTES     05440019
         BC    7,SETIOERR                                               05480019
         LTR   GRORG,GRORG             AND 16 OR GREATER                05520019
         BC    8,SETIOERR                                               05560019
         BCTR  GRORG,0            SUBTRACT PREFIX ENTRY                 05600019
         STC   GRORG,NUMSEGFW     SAVE NUMBER OF SEGMENTS               05640019
         BR    LINK1RG                 AND RETURN                       05680019
SETIOERR OI    AFPAR1FS,AFIOERR   TERMINATE MACRO WITH I/O ERROR        05720019
         BR    LINK1RG                 BACK TO SCHEDULER                05760019
*                                                                       05800019
*                                                                       05840019
MASTREQ  L     GR3RG,MASTRKFW     PICK UP MASTER INDEX ADDRESS          05880019
         AH    GR2RG,MASLGHFW     COMPUTE EXTRA STORAGE REQUIREMENT     05920019
         B     STNDXRQ                 COMPLETE STORAGE  REQUEST        05960019
*                                                                       06000019
NDXREQ   L     GR3RG,NDXRTKFW     OPERATION ON INDEX TRACK              06040019
STNDXRQ  IC    CCWRG,2(ICRG,BASERG)    COUNT OF CCW'S                   06080019
         IC    SRCHRG,3(ICRG,BASERG)   AND COUNT OF SEARCH ARGUMENT     06120019
         BR    LINK2RG                 BACK TO SCHEDULE I/O             06160019
*                                                                       06200019
*                                                                       06240019
ONEARG   LH    GR1RG,4(ICRG,BASERG)    MOVE CCW CODE TO LIST            06280019
         STH   GR1RG,CNTDATA1                                           06320019
         LH    LINK1RG,2(ICRG,BASERG)  SETUP EXECUTOR RETURN ADDRESS    06360019
         AR    LINK1RG,BASERG                                           06400019
         BR    LINK2RG            TAKE NON-SORT RETURN                  06440019
*                                                                       06480019
*                       SEARCH PROGRAM - REQUESTOR                      06520019
*                                                                       06560019
SRCHRQ   MVI   SCHOPTFW,BYRECNUM  BACK TO SPECIFIC RECORD               06600019
         CLC   LSTRECFW+1(3),SCHTRKFW+1     BACK TO SAME TRACK?         06640019
         BE    SRCHRQ1                 ALL SET IF YES                   06680019
         LH    GR2RG,SCHRRFW      SET UP FIRST AND LAST RECORDS         06720019
         STH   GR2RG,PRSRRFW                                            06760019
         CLI   LSTRECFW,0              NO, BACKWARD OR FORWARD?         06800019
         MVI   LSTRECFW,X'FF'          ASSUME BACKWARD                  06840019
         BE    SRCHRQ1                 BRANCH IF BACKWARD               06880019
         MVI   LSTRECFW,0              SET FOR FORWARD                  06920019
         B     SRCHRQ1                 COMPLETE CALLING ARGUMENTS       06960019
SRCHXKRQ BAL   INTLNKRG,SETSRCH   SET UP USER OPTION                    07000019
         NI    SCHOPTFW,READKEY   HONOR NEXT KEY OPTION ONLY            07040019
         OI    SCHOPTFW,BYRECNUM                                        07080019
         B     SRCHPTQ1                GO SET UP RECORD NUMBER          07120019
SRCHPTRQ BAL   INTLNKRG,SETSRCH   SET UP USER OPTION                    07160019
         STC   GR2RG,LSTRECFW     ASSUME LAST RECORD                    07200019
         TM    SCHOPTFW,BYRECNUM  FIRST OR LAST RECORD?                 07240019
         BZ    SRCHRQ1                 BRANCH IF NEITHER                07280019
         TM    SCHOPTFW,LAST           CHECK ASSUMPTION                 07320019
         BO    SRCHRQ1                 BRANCH IF LAST RECORD WANTED     07360019
SRCHPTQ1 SRL   GR2RG,8            SET UP FOR FIRST RECORD OF SEGMENT    07400019
         STC   GR2RG,LSTRECFW                                           07440019
SRCHRQ1  MVC   SKEYPTFW+1(3),NXTKEYFW+1     SET UP KEY FIELD POINTER    07480019
         MVC   LSTRECFW+1(3),SCHTRKFW+1     AND TRACK ADDRESS           07520019
         IC    GR2RG,SCSGNMFW     ASSUME NOT AT EOD                     07560019
         CLI   SCSGNMFW,X'FF'          CHECK FOR EOD                    07600019
         BNE   SRCHRQ2                 BRANCH IF NOT                    07640019
         TM    SCHOPTFW,BYRECNUM       SET FILE EXCEPTION IF            07680019
         BZ    SRCHRQ1B                PROCESSING POINT FUNCTION        07720019
         TM    SCHOPTFW,READREC+READKEY     OR ATTEMPTING TO READ       07760019
         BZ    SRCHRQ1A                     BEYOND EOD                  07800019
SRCHRQ1B OI    AFPAR1FS,AFXCPTN                                         07840019
SRCHRQ1A MVI   SCHOPTFW,BYRECNUM  POSITION TO AFTER LAST RECORD OF      07880019
         MVI   LSTRECFW,X'FF'          SEGMENT                          07920019
         IC    GR2RG,NUMSEGFW          AND SET UP CORRECT SEGMENT NUM.  07960019
SRCHRQ2  STC   GR2RG,SEGNUMFW     INITIALIZE SEGMENT NUMBER             08000019
         LA    GR2RG,MINXTND      START WITH MINIMUM                    08040019
         LA    SRCHRG,4                4 SEARCH ARGUMENTS               08080019
         L      GR3RG,LSTRECFW                                          08120019
         AH     GR2RG,LRCHANFW         STORAGE FOR RECORD CHAIN         08160019
         LA     CCWRG,4                CCW'S TO READ CHAIN RECORD       08200019
         TM    STATUSFW,DELETE+SEGDATA                                  08240019
         BC    14,SRQ001               BRANCH IF NO CHAIN RECORD UPDATE 08280019
         LA    CCWRG,9(CCWRG)     ADD 9 CCW'S FOR WRITE-CHECK           08320019
         AH     GR2RG,LTKCHNFW         STORAGE FOR TRACK CHAIN          08360019
SRQ001   TM    SCHOPTFW,BYRECNUM                                        08400019
         BC    8,SRQ003                                                 08440019
         TM    LSTRECFW,X'FF'          SPECIAL CASE IF REC#=X'FF' OR    08480019
         BCR   9,LINK2RG               X'00', JUST READ AND CHECK       08520019
*                                      RECORD CHAIN.                    08560019
*                       READ BY RECORD NUMBER OR SEARCH ON KEY EQUAL    08600019
SRQ002   LA     CCWRG,4(CCWRG)         4 MORE CCW'S                     08640019
         LA     GR2RG,8(GR2RG)         8 BYTES STORAGE FOR KEY          08680019
         TM    SCHOPTFW,READREC        IF READREC IS SET, REQUEST A     08720019
         BCR   8,LINK2RG                  BUFFER BEFORE RETURNING       08760019
         LNR   GR2RG,GR2RG                                              08800019
         BR    LINK2RG                 TO REQUEST I/O                   08840019
SRQ003   TM    SCHOPTFW,HIGHEQ                                          08880019
         BC    8,SRQ002                                                 08920019
*                       READ ALL KEYS                                   08960019
         LH    GR1RG,UNORECFW          NUMBER OF DATA RECORDS           09000019
         AR     CCWRG,GR1RG            ADD 1 CCW FOR EACH KEY           09040019
         SLA   GR1RG,3                                                  09080019
         AR     GR2RG,GR1RG            8 BYTES STORAGE FOR EACH KEY     09120019
         BR    LINK2RG                 REQUEST I/O                      09160019
*                                                                       09200019
*                       SEARCH PROGRAM - EXECUTOR                       09240019
*                       SET UP SEARCH ARGUMENT TABLE                    09280019
*                                                                       09320019
SRCHEX   EQU   *                       FIRST ENTRY IS DUMMY ARGUMENT    09360019
*                                        FOR WRITE-CHECK.               09400019
*                                      SECOND ENTRY READS THE RECORD    09440019
         LA    GR3RG,TMPAREA0            CHAIN INTO TMPAREA0            09480019
         ST    GR3RG,SRCHARG2                                           09520019
         AH    GR3RG,LRCHANFW          NXT AVAILABLE TEMP STORAGE       09560019
         MVI   SRCHCOD2,RDRCHNCW                                        09600019
         TM    SCHOPTFW,BYRECNUM  BRANCH IF NOT READING BY REC #        09640019
         BZ    SHEX004                                                  09680019
         TM    LSTRECFW,X'FF'          IF LSTRECFW FF OR 00, THAT'S ALL 09720019
         BC    9,SHEX006                                                09760019
         IC    ICRG,LSTRECFW      SEARCH RECORD # TO                    09800019
         STC   ICRG,SRCHR3             SEARCH ARGUMENT                  09840019
         TM    STATUSFW,DELETE+SEGDATA MUST TWO SEGMENTS BE COMBINED    09880019
         BC    14,SHEX003              INTO ONE? BRANCH IF NOT.         09920019
         MVI   SRCHCOD2,RDRTCW0        YES, READ TRACK CHAIN TOO        09960019
         MVI   SRCHCOD4,WRITCKCW       AND WRITE CHECK                  10000019
         TM    SCHOPTFW,READKEY   IS NEXT KEY REQUESTED?                10040019
         BZ    SHEX001                 NO.                              10080019
         MVI   SRCHCOD3,REDKWCCW       YES, READ KEY INTO TEMP          10120019
         AH    GR3RG,LTKCHNFW          STORAGE WHILE                    10160019
         ST    GR3RG,SRCHARG3          WRITE-CHECKING.                  10200019
SHEX001  BALR  LINK1RG,LINK2RG    READ TRACK CHAIN                      10240019
*                                                                       10280019
*                       EXTRY AT CHANNEL END (COMBINE SEGMENT)          10320019
*                                                                       10360019
*              REMOVE ELIMINATED EOS FROM TRACK CHAIN.  UPDATE RECORD   10400019
*              CHAIN TO PRODUCE A SINGLE SEGMENT FROM THE TWO PORTIONS. 10440019
*              MODIFY CHANNEL PROGRAM FOR OUTPUT AND EXECUTE PROGRAM    10480019
*                                                                       10520019
         MVI   CCWCMCD3,WRITEKD   SET  UP OUTPUT PROGRAM                10560019
         MVI   CCWFLGS4,CC                                              10600019
         LR    LINK1RG,LINK2RG         AND SAVE ALTERNATE RETURN        10640019
*                                                                       10680019
*              UPDATE TRACK CHAIN BY SAVING OLD EOS ENTRY IN TRACK      10720019
*              CHAIN SAVE AREA, THEN ELIMINATE OLD EOS.                 10760019
*                                                                       10800019
         IC    ICRG,PRERRFW+1          OLD EOS REC#                     10840019
         LA    GR2RG,PRERRFW+1         POINTER TO REC# OF OLD EOS ENTRY 10880019
         L     GR3RG,CCWADDR3          ADDR OF TRACK CHAIN              10920019
         LA    SRCHRG,TMPAREA0-2       ADDR OF RECORD CHAIN             10960019
         DROP    SRCHRG                                                 11000019
         BAL   LINK2RG,UPDTCHN2        UPDATE TRACK CHAIN               11040019
*                                                                       11080019
*              UPDATE RECORD CHAIN                                      11120019
*                                                                       11160019
         TM    SCHOPTFW,READKEY   IF NOT READ OF NEXT KEY,              11200019
         BO    SHEX002                                                  11240019
         STC   ICRG,LSTRECFW           UPDATE LAST RECORD READ          11280019
SHEX002  IC    GR0RG,SCHRRFW      1' REC OF 2' SEG ON TRACK             11320019
         STC   GR0RG,0(ICRG,SRCHRG)    INTO OLD EOS REC ENTRY           11360019
         IC    ICRG,PRERRFW       UPDATE BEGINNING OF SEGMENT           11400019
         STC   ICRG,SEGR1FW            RECORD NUMBER                    11440019
*                                                                       11480019
*                       EXCP AGAIN                                      11520019
*                                                                       11560019
         BALR  LINK1RG,LINK1RG                                          11600019
*                                                                       11640019
*                       ENTRY AT CHANNEL END                            11680019
*                                                                       11720019
         USING CNTSRCH,SRCHRG                                           11760019
         L     GR0RG,CCWADDR3     COMPUTE ADDRESS OF KEY IF READ        11800019
         AH    GR0RG,LTKCHNFW                                           11840019
         ST    GR0RG,CCWADDR7                                           11880019
         B     SHEX008                                                  11920019
*                                                                       11960019
*                       READ KEY OR RECORD BY RECORD NUMBER IF REQESTED 12000019
*                                                                       12040019
SHEX003  TM    SCHOPTFW,READREC+READKEY     CHECK REQUESTS              12080019
         BZ    SHEX006                      NONE                        12120019
         MVI   SRCHCOD3,RDDKEYCW       ASSUME READ KEY ONLY             12160019
         ST    GR3RG,SRCHARG3                                           12200019
         TM    SCHOPTFW,READREC        CHECK ASSUMPTION                 12240019
         BZ    SHEX006                      BRANCH IF RECORD NOT WANTED 12280019
         MVI   SRCHCOD3,GETRECW             NO, READ RECORD             12320019
         B     SHEX005                      GO SET UP BUFFER ADDRESS    12360019
*                                                                       12400019
*                                                                       12440019
SHEX004  TM    SCHOPTFW,HIGHEQ         CHECK FOR HIGH/EQUAL KEY SEARCH  12480019
         BO    SHEX019                      BRANCH IF SO                12520019
         MVI   SRCHCOD3,SRCHKYCW            NO, SEARCH FOR EXACT KEY    12560019
*                       SEARCH KEYS FOR RECORD POSITION                 12600019
*                                                                       12640019
*                       SET UP BUFFER ADDRESS                           12680019
*                                                                       12720019
SHEX005  BAL   INTLNKRG,COUNTREQ       COMPUTE BUFFER ADDRESS           12760019
         BALR  INTLNKRG,INTLNKRG            IN CASE RECORD              12800019
         ST    GR1RG,SRCHARG3               IS TO BE READ               12840019
*                                                                       12880019
*                       READ RECORD CHAIN AND POSITION WITHIN SEGMENT   12920019
*                                                                       12960019
SHEX006  BALR  LINK1RG,LINK2RG              TO GENERATORS (NO SORT)     13000019
*                                                                       13040019
SHEX008  BALR  LINK1RG,LINK1RG         ENDIO                            13080019
*                                                                       13120019
*                       ASYNCHRONOUS ENTRY                              13160019
*                                                                       13200019
         TM    SCHOPTFW,BYRECNUM                                        13240019
         BC    7,SHEX009          BRANCH IF NOT SEARCH KEY EQUAL        13280019
*                                                                       13320019
*              SEARCH ON RECORD NUMBER OR EXACT KEY.                    13360019
*              CHECK VALIDITY OF RECORD CHAIN.  IF SEGMENT DOES NOT     13400019
*              TERMINATE WITHIN THE MAXIMUM NUMBER OF DATA RECORDS ON   13440019
*              TRACK, OR IF SEARCH WAS ON REC# AND THAT REC# IS NOT IN  13480019
*              THIS SEGMENT, SET AFIOERR AND RETURN.  IF READKEY IS     13520019
*              SET, MOVE KEY TO AREA SPECIFIED BY SKEYPTFW.  IF READREC 13560019
*              IS SET, MOVE KEY INTO BUFFER.  MOVE RECORD CHAIN TO FILE 13600019
*              BOX.                                                     13640019
*                                                                       13680019
         TM    AFPAR1FS,AFXCPTN   BRANCH IF SEARCH KEY EQUAL            13720019
         BC    1,SHEX016                 FAILED                         13760019
SHEX009  LA    LINK2RG,SHEX009A   CHECK FOR BEFORE FIRST OR AFTER       13800019
         TM    LSTRECFW,X'FF'          LAST SPECIFIED                   13840019
         BC    9,VCENTRY1              YES, DON'T CHECK FOR RECORD      13880019
         CLI   SRCHR3,1                                                 13920019
         BE    SHEX009B                                                 13960019
         IC    ICRG,SRCHR3             CHECK RECORD CHAIN AND SEE IF    14000019
         STC   ICRG,LSTRECFW             THIS REC# IS IN SEGMENT.       14040019
SHEX009B BAL   LINK2RG,VCENTRY0                                         14080019
SHEX009A BCR   4,LINK1RG               CHAIN NO GOOD; RETURN AFIOERR    14120019
         BC    2,SHEX018               BRANCH IF REC NOT IN SEGMENT     14160019
         TM    SCHOPTFW,READREC        BRANCH IF THERE IS A BUFFER      14200019
         BC    1,SHEX015                                                14240019
         L     GR1RG,CCWADDR7          KEY IS AT SKEYPTFW               14280019
SHEX010  TM    SCHOPTFW,READKEY        IF KEY IS DESIRED, MOVE IT TO    14320019
         BC    8,SHEX012                 AREA SPECIFIED BY SKEYPTFW.    14360019
         L     GR3RG,SKEYPTFW                                           14400019
SHEX011  LH    GR2RG,UMLKDFW           FOR EXECUTING KEY MOVES          14440019
         EX    GR2RG,SCHMVC1                                            14480019
SHEX012  MVC   RCHANFW,TMPAREA0        MOVE RECORD CHAIN TO FILE BOX.   14520019
         BAL   LINK2RG,GENDATA         INITIALIZE SEGRFFW               14560019
         STC   GR2RG,SEGRFFW                                            14600019
         CLI   LSTRECFW,X'FF'          IF LAST RECORD OF SEGMENT        14640019
         BNE   SHEX012A                     INDICATED,                  14680019
         STC   GR2RG,LSTRECFW               INITIALIZE IT NOW.          14720019
SHEX012A SR    GR2RG,GR2RG             SCAN FOR NUMBER OF AVAILABLE     14760019
         LH    GR1RG,UNORECFW             RECORDS ON TRACK              14800019
SHEX013  LA    GR3RG,RCHANFW-1(GR1RG)                                   14840019
         CLI   0(GR3RG),0              IS THIS REC AVAILABLE            14880019
         BNE   SHEX014                                                  14920019
         LA    GR2RG,1(GR2RG)          IF SO, BUMP COUNTER              14960019
SHEX014  BCT   GR1RG,SHEX013                                            15000019
         STC   GR2RG,AVAILNFW                                           15040019
         LTR   GR2RG,GR2RG             IF THERE ARE 1 OR MORE AVAILABLE 15080019
         BCR   8,LINK1RG               RECORDS, BUT PTRKDPFW=0, SET     15120019
         CLI   PTRKDPFW,0              PTRKDPFW=X'FF', INDICATING THAT  15160019
         BCR   7,LINK1RG               THERE IS AN ENTRY IN THE TRACK   15200019
         MVI   PTRKDPFW,X'FF'          LIST FOR THIS SEGMENT, BUT WE    15240019
         BR    LINK1RG                 DON'T KNOW WHERE IT IS.          15280019
*                                                                       15320019
SHEX015  BAL   INTLNKRG,COUNTREQ       IF A BUFFER WAS OBTAINED,        15360019
         BALR  INTLNKRG,INTLNKRG                                        15400019
         TM    AFPAR2FS,MULTIPLE       AND OPERATION IS MULTIPLE,       15440019
         BC    8,SHEX0155                                               15480019
         LA    ICRG,1(ICRG)            UPDATE COUNTFS.                  15520019
         STC   ICRG,COUNTFS                                             15560019
SHEX0155 AH    GR1RG,UADKEYFW          LOCATE KEY IN BUFFER             15600019
         TM    SCHOPTFW,BYRECNUM       IF READ BYRECNUM, MOVE IT TO     15640019
         BC    1,SHEX010                 AREA SPECIFIED BY SKEYPTFW.    15680019
         LR    GR3RG,GR1RG             IF SEARCH ON EXACT KEY, MOVE KEY 15720019
         L     GR1RG,SKEYPTFW            TO BUFFER.                     15760019
         B     SHEX011                                                  15800019
SHEX016  BAL   LINK2RG,VCENTRY1        SRCHKYEQ FAILED, CHECK REC CHAIN 15840019
         BCR   4,LINK1RG               CHAIN NO GOOD, AFIOERR SET,      15880019
SHEX017  OI    AFPAR1FS,AFXCPTN        IF SEARCH WAS ON KEY, SET FILE   15920019
         MVI   LSTRECFW,0              EXCEPTION, POSITION BEFORE FIRST 15960019
         L     LINK1RG,EXRET2LK        IN SEGMENT AND RELEASE BUFFER.   16000019
         B     SHEX012                                                  16040019
SHEX018  TM    SCHOPTFW,BYRECNUM       IF BYRECNUM, CONSIDERED AN I/O   16080019
         BC    8,SHEX017                 ERROR.                         16120019
         OI    AFPAR1FS,AFIOERR                                         16160019
         BR    LINK1RG                                                  16200019
SCHMVC1  MVC   0(0,GR3RG),0(GR1RG)                                      16240019
*                                                                       16280019
*                       SEARCH ON KEY HIGH OR EQUAL.                    16320019
*              SEARCH THROUGH KEYS OF SEGMENT IN LOGICAL ORDER FOR HIGH 16360019
*              OR EQUAL.  IF SEARCH IS NOT SATISFIED SET AFIOERR AND    16400019
*              RETURN TO SCHEDULER.  IF A HIGH KEY IS FOUND, AFXCPTN IS 16440019
*              SET, LSTRECFW IS SET TO THAT REC#, AND IF READKEY IS     16480019
*              SET, THE HIGH KEY IS MOVED TO THE AREA SPECIFIED BY      16520019
*              SKEYPTFW.  IF AN EQUAL KEY IS FOUND, LSTRECFW IS SET TO  16560019
*              THAT REC#.                                               16600019
*                                                                       16640019
SHEX019  MVI   SRCHCOD3,RDALLKCW       READ ALL KEYS INTO TEMP STORAGE. 16680019
         ST    GR3RG,SRCHARG3             STARTING AT THIS ADDRESS      16720019
         BALR  LINK1RG,LINK2RG         TO GENERATORS (NO SORT)          16760019
         BALR  LINK1RG,LINK1RG         ENDIO                            16800019
         BAL   LINK2RG,VCENTRY1        VALIDATE RECORD CHAIN            16840019
         BCR   4,LINK1RG               CHAIN NO GOOD.  RETURN           16880019
         LH    SRCHRG,UMLKDFW          LENGTH OF KEY FOR  COMPARE       16920019
         DROP  SRCHRG                                                   16960019
         IC    ICRG,SEGR1FW            FIRST REC IN SEG                 17000019
         SR    GR2RG,GR2RG             ASSUMED POSITION BEFORE FIRST    17040019
         LA    INTLNKRG,TMPAREA0-2     TO ADDRESS RECORD CHAIN          17080019
         L     CCWRG,CCWADDR5          TO ADDRESS KEYS -CCWRG DESTROYED 17120019
         DROP  CCWRG                                                    17160019
         SH    CCWRG,H16KN                                              17200019
         LA    GR0RG,EOS               TO TERMINATE SEGMENT             17240019
         L     GR3RG,SKEYPTFW          POINTER TO COMPARE KEY           17280019
SHEX020  LR    GR1RG,ICRG              REC #*8 IS INDEX TO KEY LOCATION 17320019
         SLA   GR1RG,3                                                  17360019
         AR    GR1RG,CCWRG             ADDR OF KEY                      17400019
         EX    SRCHRG,SCHCLC           COMPARE KEYS                     17440019
         BNL   SHEX021                 HIGH OR EQUAL SATISFIED          17480019
         LR    GR2RG,ICRG              SAVE PREVIOUS RECORD NUMBER      17520019
         IC    ICRG,0(INTLNKRG,ICRG)   PICK UP NEXT RECORD CHAIN ENTRY  17560019
         CR    ICRG,GR0RG              IF NOT EOS, LOOP BACK TO COM-    17600019
         BL    SHEX020                    PARE KEYS.                    17640019
         OI    AFPAR1FS,AFIOERR        IF SEARCH NOT SATISFIED SET      17680019
         BR    LINK1RG                   AFIOERR AND RETURN TO SCHED.   17720019
SHEX021  STC   ICRG,LSTRECFW           ASSUME EQUAL COMPARE             17760019
         BE    SHEX012                    AND EXIT IF SO                17800019
         TM    SCHOPTFW,READKEY        HIGH COMPARE; IF READKEY IS SET  17840019
         BC    8,SHEX022                  MOVE KEY TO AREA SPECIFIED BY 17880019
         EX    SRCHRG,SCHMVC1             SKEYPTFW.                     17920019
SHEX022  OI    AFPAR1FS,AFXCPTN           SET AFXCPTN                   17960019
         STC   GR2RG,LSTRECFW          POSITION AFTER PREVIOUS RECORD   18000019
         B     SHEX012                                                  18040019
         USING CNTSRCH,SRCHRG                                           18080019
         USING CCWMSK,CCWRG                                             18120019
*                                                                       18160019
*********************************************************************** 18200019
*                                                                       18240019
*                       VALIDATE CHAIN SUBROUTINE                       18280019
*                                                                       18320019
*  BAL   LINK2RG,VCENTRY1                                               18360019
*              FOLLOWS THE SEGMENT THROUGH THE RECORD CHAIN, WHICH IS   18400019
*              ASSUMED TO RESIDE AT TMPAREA0, SEARCHING FOR EOS.  IF NO 18440019
*              EOS IS FOUND BEFORE THE MAXIMUM NUMBER OF RECORDS ON A   18480019
*              DATA TRACK IS EXHAUSTED, AFIOERR IS SET.                 18520019
*  BAL   LINK2RG,VCENTRY0                                               18560019
*              ADDITIONALLY GUARANTEES THAT THE REC# AT LSTRECFW IS IN  18600019
*              THIS SEGMENT.                                            18640019
*                                                                       18680019
*  INPUT REGISTERS:  NO SPECIAL ASSUMPTIONS.                            18720019
*  INPUT:  SEGR1FW HAS THE RECORD NUMBER OF THE FIRST RECORD OF THE     18760019
*              SEGMENT.                                                 18800019
*          LSTRECFW (VCENTRY0) IS THE RECORD# OF THE RECORD TO BE       18840019
*              VERIFIED AS WITHIN THE SEGMENT.                          18880019
*                                                                       18920019
*  OUTPUT REGISTERS:                                                    18960019
*              GR0RG  MAXIMUM NUMBER OF DATA RECORDS MINUS NUMBER OF    19000019
*                      RECORDS IN SEGMENT                               19040019
*              GR1RG  POINTS TO RECORD CHAIN.                           19080019
*              GR2RG  DESTROYED                                         19120019
*              GR3RG  ENTRY AT VCENTRY1 - GR3RG PRESERVED               19160019
*                     ENTRY AT VCENTRY0 - CONTENTS OF LSTRECFW          19200019
*              INTLNKRG X'80', EOS.                                     19240019
*              ICRG   EOS ENTRY OF RECORD CHAIN                         19280019
*                                                                       19320019
*  RETURN:  BR    LINK2RG  CC = 0  NORMAL RETURN.                       19360019
*                          CC = 1  RECORD CHAIN DOES NOT TERMINATE      19400019
*                                  WITHIN MAXIMUM NUMBER OF RECORDS ON  19440019
*                                  TRACK;  I/O ERROR.                   19480019
*                          CC = 2  LSTRECFW IS NOT IN CHAIN.            19520019
*                                                                       19560019
VCENTRY0 IC    ICRG,LSTRECFW           REC# TO BE ASSURED WITHIN        19600019
         LR    GR3RG,ICRG                 SEGMENT                       19640019
         LA    GR2RG,VCL001            LARGE LOOP, INCLUDE REC# COMPARE 19680019
         B     VCINIT                                                   19720019
VCENTRY1 LA    GR2RG,VCL002            SMALL LOOP                       19760019
VCINIT   IC    ICRG,SEGR1FW            START SCAN WITH 1' REC OF SEG    19800019
         LA    INTLNKRG,EOS            TERMINATION COMPARE              19840019
         LA    GR1RG,TMPAREA0-2        (MYTHICAL) REC0 OF RECORD CHAIN  19880019
         LH    GR0RG,UNORECFW          NUMBER OF DATA RECORDS ON TRK    19920019
         BR    GR2RG                                                    19960019
VCL001   CR    GR3RG,ICRG              IF REC# IN CHAIN MATCHES         20000019
         BNE   VCL002                     LSTRECFW, REDUCE LOOP TO      20040019
         BALR  GR2RG,0                    BTPASS THIS COMPARISON.       20080019
VCL002   CH    ICRG,H2KN               REC. # MUST BE IN LEGAL REAGE    20120019
         BL    VCL003                       TOO LOW                     20160019
         CH    ICRG,UDNRECFW                                            20200019
         BH    VCL003                       TO HIGH                     20240019
         IC    ICRG,0(ICRG,GR1RG)      PICK UP RECORD CHAIN ENTRY       20280019
         CR    ICRG,INTLNKRG           CHECK FOR EOS                    20320019
         BH    VCEXIT-VCL002(GR2RG)    IF EOS, AND LSTRECFW IS ALREADY  20360019
*                                      MATCHED, EXIT, OTHERWISE ERROR.  20400019
         BCTR  GR0RG,GR2RG             IF NUMBER RECORDS ON TRACK NOT   20440019
*                                      EXHAUSTED, LOOP, OTHERWISE ERROR 20480019
VCL003   OI    AFPAR1FS,AFIOERR        SET I/O ERROR                    20520019
*                                      IF CHAIN IS NOT VALID, CC = 1.   20560019
VCERROR  BR    LINK2RG                 IF LSTRECFW IS NOT IN SEGMENT,   20600019
*                                           CC = 2.  RETURN TO CALLER.  20640019
SCHCLC   CLC   0(0,GR1RG),0(GR3RG)                                      20680019
VCEXIT   SR    GR2RG,GR2RG             SET CC = 0.                      20720019
         BR    LINK2RG                 RETURN TO CALLER.                20760019
*                                                                       20800019
*                                                                       20840019
SETSRCH  IC    GR2RG,AFPAR2FS     MOVE USER'S OPTION                    20880019
         STC   GR2RG,SCHOPTFW          TO CALLING SEQUENCE AREA         20920019
         LH    GR2RG,SCHRRFW      PICK UP FIRST AND LAST RECORDS        20960019
         STH   GR2RG,PRSRRFW           SAVE                             21000019
         BR    INTLNKRG                AND RETURN TO USER               21040019
*                                                                       21080019
*                       INSERT NEW SEGMENT ON OLD TRACK                 21120019
*                                                                       21160019
*              THIS PROGRAM ADDS A SEGMENT TO THE FILE WHEN INSERT      21200019
*              OVERFLOW OCCURS AND THERE IS AT LEAST ONE AVAILABLE      21240019
*              RECORD AREA IN THE FILE.                                 21280019
*                                                                       21320019
*              THE CHAIN RECORD OF THE SPECIFIED TRACK IS READ INTO     21360019
*                TEMPORARY STORAGE.                                     21400019
*              A NEW END OF SEGMENT ENTRY IS MADE IN BOTH CHAINS AT THE 21440019
*                SPECIFIED RECORD POSITION.                             21480019
*              THE UPDATED TRACK AND RECORD CHAINS ARE WRITTEN BACK.  A 21520019
*                SINGLE DATA RECORD IS WRITTEN IN THE SPECIFIED RECORD  21560019
*                AREA, AND THE TRACK IS WRITE-CHECKED.                  21600019
*                                                                       21640019
*              INPUT:  LSTRECFW - RACH OF RECORD AREA TO BE USED        21680019
*                      SCHTRKFW - XACH OF NEXT SEGMENT                  21720019
*                      SCHRRFW  - RX OF NEXT SEGMENT                    21760019
*                                                                       21800019
*                            REQUESTOR                                  21840019
*                                                                       21880019
OLDINSRQ LA    ARG1RG,20               20 CCW'S                         21920019
         LA    ARG2RG,4                4 SEARCHARGS                     21960019
         LA    ARG3RG,4*L'RCHANFW+6(ARG3RG)  LENGTH OF CHAIN RECORD.    22000019
         L     ARG4RG,LSTRECFW         TRACK                            22040019
         BR    LINK2RG                 RETURN TO ENQUEUE                22080019
*                                                                       22120019
*                       SET UP SEARCH ARGUMENT TABLE                    22160019
*                                                                       22200019
*                                                                       23840019
*                       CHAIN RECORD UPDATE PROGRAM - REQUESTOR         23880019
*                                                                       23920019
*              REQUESTS 5 SEARCH ARGUMENTS                              23960019
*              REQUESTS EXTENDED AREA FOR STANDARD WORK AREA (TO BE     24000019
*                   DEFINED), PLUS THE TRACK-CHAIN'S LENGTH, IF IT WILL 24040019
*                   BE READ.                                            24080019
*              REQUESTS 4 CCWS TO READ THE TRACK CHAIN OR READ A KEY    24120019
*                   WHEN NO WRITES WILL BE DONE.                        24160019
*              REQUESTS 16 CCWS TO OUTPUT THE CHAIN RECORD AND WRITE    24200019
*                   CHECK, PLUS 6 ADDITIONAL CCWS TO READ EACH KEY.     24240019
*                                                                       24280019
NDUPSQRQ OI    AFPAR1FS,MACOMP1   SET FOR SEQUENTIAL PROCESSING         24320019
NDUPRQ   TM    AFPAR1FS,MACOMP1   SHOULD WE PROCEDE TO NEXT SEG?        24360019
         BZ    NDUPRQ1                 BRANCH IF NOT                    24400019
         BAL   INTLNKRG,SEGPOS         YES, CHAIN FOR POSITIONED AFTER  24440019
         BC    12,NDUPRQ1              RECORD OF SEGMENT                24480019
         TM    STATUSFW,DELETE+INSERT+LASTKEY+SEGDATA+FRSTMOVE          24520019
         BZ    NDUPMDQ            AND IF NO UPDATES, LOCATE NEXT SEG    24560019
NDUPRQ1  TM    STATUSFW,LASTMOVE+RECPEND+INSERT+LASTKEY                 24600019
         BC    7,NDUPMDQ          BRANCH IF CHAIN RECORD UPDATED NEEDED 24640019
         CLI   SEGNUMFW,0         NO CHAIN RECORD UPDATE, CHECK         24680019
         BCR   8,LINK1RG               RECORD CHAIN IN CORE             24720019
         BAL   LINK2RG,GENDATA         YES, SET UP FOR INDEX UPDATE     24760019
         BAL   INTLNKRG,NXTAVAIL       MODE                             24800019
         ST    GR1RG,REPSEGFW-1                                         24840019
         STC   ICRG,AVAIL1FW                                            24880019
         BR    LINK1RG                                                  24920019
NDUPMDRQ CLC   AVAILNFW(1),UNORECFW+1  CHECK FOR NO DATA RECORDS        24960019
         BNE   NDUPMDQ                                                  25000019
         MVI   AVAILNFW,X'FF'          SET TRACK RELEASE SWITCH IF SO   25040019
         NI    STATUSFW,X'FF'-RECPEND-LASTMOVE   RESET PENDING UPDATES  25080019
         BR    LINK1RG                 AND IGNORE CHAIN RECORD UPDATE   25120019
NDUPMDQ  LA    ARG1RG,4                MINIMUM OF 4 CCW'S               25160019
         LA    ARG2RG,5                5 SEARCH ARGUMENTS               25200019
         LA    ARG3RG,MINXTND1+6+3*L'RCHANFW                            25240019
*                                      MAXIMUM EXTENDED WORK AREA       25280019
         L     ARG4RG,LSTRECFW                                          25320019
         TM    AVLRECFW,INSRTOVF                                        25360019
         BC    1,CRQ002                BRANCH IF INSERT OVERFLOW        25400019
         TM    STATUSFW,LASTMOVE                                        25440019
         BC    8,CRQX005               BR IF NOT LAST REC MOVED         25480019
CRQ002   TM    STATUSFW,INSERT                                          25520019
         BC    8,CRQ003                                                 25560019
         LA    ARG1RG,6(ARG1RG)        IF INSERT ON, ADD 6 CCW'S        25600019
CRQ003   TM    STATUSFW,LASTKEY                                         25640019
         BC    8,CRQ004                                                 25680019
         LA    ARG1RG,6(ARG1RG)        IF LAST KEY CHANGED, ADD 6 CCW'S 25720019
CRQ004   LA    ARG1RG,12(ARG1RG)       12 CCW'S FOR WRITE-CHECK         25760019
         BR    LINK2RG                 TO ENQUEUE                       25800019
CRQX005  TM    STATUSFW,RECPEND                                         25840019
         BC    1,CRQX007               BRANCH IF RECORD UPDATE PENDING  25880019
         TM    STATUSFW,INSERT+LASTKEY                                  25920019
         BCR   8,LINK2RG               RETURN IF ONLY NECESSARY TO READ 25960019
*                                      TRACK CHAIN                      26000019
         SH    ARG3RG,LTKCHNFW         NO STORAGE FOR TRACK CHAIN       26040019
         BR    LINK2RG                                                  26080019
CRQX007  SH    ARG3RG,LTKCHNFW         NO STORAGE FOR TRACK CHAIN       26120019
         B     CRQ002                                                   26160019
*                                                                       26200019
*              GENERATE THE ARGUMENT LIST FOR CHAIN RECORD UPDATE       26240019
*              AND SAVE INFORMATION FOR INDEX RECORD UPDATE             26280019
*                                                                       26320019
NDUPEX   EQU   *                                                        26360019
*                                                                       26400019
*              GENERATE ASSUMED LIST                                    26440019
*                        DUMMY,  REC# = 0                               26480019
*                        READ TRACK CHAIN, REC#=1                       26520019
*                        WRITE CHECK     , REC#=FF                      26560019
*                        READ KEY WITH CHECKING                         26600019
*                        READ KEY WITH CHECKING                         26640019
*                                                                       26680019
         MVI   SRCHCOD2,RDTCCW         ENTRY 2                          26720019
         LA    GR1RG,TMPAREA1-L'RCHANFW     READ TRACK CHAIN INTO       26760019
         ST    GR1RG,SRCHARG2                 TMPAREA1.                 26800019
         MVI   SRCHCOD3,WRITCKCW       ENTRY 3                          26840019
         MVI   SRCHR3,X'FF'                                             26880019
         MVI   SRCHCOD4,REDKWCCW       ENTRY 4                          26920019
         MVI   SRCHCOD5,REDKWCCW       ENTRY 5                          26960019
*                                                                       27000019
*              TEST ACTUAL REQUIREMENTS FOR CHANNEL PROGRAM             27040019
*                                                                       27080019
         TM    AVLRECFW,INSRTOVF                                        27120019
         BC    1,CUP002                INSERT OVERFLOW                  27160019
         TM    STATUSFW,LASTMOVE                                        27200019
         BC    8,CUP004                NO NEED TO UPDATE TRACK CHAIN    27240019
CUP001   CLI   SEGR1FW,0               IS SEGMENT BEING DELETED         27280019
         BE    CUP005                  YES                              27320019
         BAL   LINK2RG,GENDATA         GENERATE DATA FOR INSERT         27360019
         ST    GR1RG,REPDTRAN          NEED REPLACE DATA IF LAST RECORD 27400019
         ST    GR1RG,INSDTRAN          MOVED                            27440019
         TM    STATUSFW,INSERT                                          27480019
         BC    8,CUP003           BRANCH IF NO NEED FOR INSERT          27520019
         BALR  LINK2RG,LINK2RG           ARGUMENT LIST ENTRY            27560019
         B     CUP005                                                   27600019
CUP002   TM    STATUSFW,INSERT+SEGDATA                                  27640019
         BC    14,CUP001               OVERFLOW AT END OF SEGMENT       27680019
         IC    ICRG,LSTRECFW           LAST RECORD PROCESSED WILL BE    27720019
         LA    LINK1RG,RCHANFW-2(ICRG)   NEW END OF SEGMENT             27760019
         OI    0(LINK1RG),EOS          DUMMY EOS                        27800019
         BAL   LINK2RG,GENDATA         GENERATE DATA FOR INSERT         27840019
         BALR  LINK2RG,LINK2RG           ARGUMENT LIST ENTRY            27880019
         NI    0(LINK1RG),X'FF'-EOS    TURN OFF DUMMY EOS               27920019
         IC    ICRG,0(LINK1RG)         DUMMY FIRST RECORD OF SEG TO     27960019
         STC   ICRG,SEGR1FW              ALLOW REPLACE DATA GENERATION  28000019
         BAL   LINK2RG,GENDATA         GENERATE REPLACE DATA            28040019
         ST    GR1RG,REPDTRAN                                           28080019
CUP003   TM    STATUSFW,LASTKEY        WILL THERE BE A REPLACE SEGMENT? 28120019
         BC    8,CUP005                  NO                             28160019
         LA    GR1RG,REPDTRAN+4          YES, SET UP READ KEY           28200019
         ST    GR1RG,SRCHARG5                                           28240019
         STC   GR2RG,SRCHR5                                             28280019
         B     CUP005                                                   28320019
*                                                                       28360019
CUP004   TM    STATUSFW,RECPEND                                         28400019
         BC    1,CUPX008               RECORD CHAIN UPDATE PENDING      28440019
         MVI   SRCHCOD3,DUMMYCW        NO WRITE CHECKING, RESET         28480019
         MVI   SRCHCOD4,RDKEYCW             CHANNEL PROGRAM CODES       28520019
         MVI   SRCHCOD5,RDKEYCW                                         28560019
         MVI   SRCHCOD2,DUMMYCW                                         28600019
         TM    STATUSFW,INSERT+LASTKEY UNNECESSARY NOW TO WRITE ANY-    28640019
*                                        THING; MUST I READ A KEY?      28680019
         BC    5,CUP001                YES                              28720019
         MVI   SRCHCOD2,RDTCCW    CONTINUE TO NEXT SEGMENT              28760019
CUP005   L     LINK1RG,EXRETLK         RESTORE LINKAGE                  28800019
         BALR  LINK1RG,LINK1RG         EXIT TO GENERATOR                28840019
*                                                                       28880019
*        CHANNEL END APPENDAGE                                          28920019
*              IF THE TRACK-CHAIN WAS READ (LAST RECORD MOVED OR        28960019
*              INSERT OVERFLOW), IT WILL BE UPDATED, AND THE CHANNEL    29000019
*              PROGRAM WILL BE MODIFIED TO OUTPUT THE TRACK-CHAIN AND   29040019
*              COMMAND CHAIN TO THE REMAINING UNEXECUTED CCW'S.  ALSO,  29080019
*              FOR INSERT OVERFLOW, THE RECORD CHAIN IS UPDATED TO      29120019
*              POINT TO THE RECORD TO BE INSERTED, AND SEGR1FW IS       29160019
*              CORRECTED.                                               29200019
*                                                                       29240019
         TM    STATUSFW,LASTMOVE                                        29280019
         BC    8,CUPX012                                                29320019
*                                      LAST RECORD MOVED                29360019
         IC    ICRG,SEGRFFW            OLD EOS REC#                     29400019
         LA    GR2RG,REPDTRAN+3        POINTER TO NEW EOS REC#          29440019
         BAL   LINK2RG,UPDTCHAN        SAVE OLD EOS INFORMATION         29480019
         CLI   SEGR1FW,0                                                29520019
         BE    CUP010                  BRANCH IF SEGMENT DELETED        29560019
         LA    GR2RG,TMPAREA1+1        MOVE OLD EOS ENTRY TO NEW        29600019
         BALR  LINK2RG,LINK2RG           POSITION                       29640019
         TM    AVLRECFW,INSRTOVF                                        29680019
         BC    8,CUP010                                                 29720019
*                                      INSERT OVERFLOW                  29760019
CUP009   IC    ICRG,INSDTRAN+3         NEW EOS REC# = OLD EOS REC#, AND 29800019
         LA    GR2RG,INSDTRAN+3          IS FOUND IN INSERT DATA        29840019
         BAL   LINK2RG,UPDTCHAN        SAVE OLD EOS ENTRY               29880019
         LA    GR2RG,AVLRECFW+1        NEW EOS POINTS TO AVAILABLE      29920019
         BALR  LINK2RG,LINK2RG           RECORD                         29960019
         CLI   AVLRECFW,INSRTOVF       HAS TRACK BEEN FORMATTED YET?    30000019
         BNE   CUP0091                 IF NOT, 1' AVAILABLE RECORD ON   30040019
         LA    GR1RG,INSRTOVF+2        TRACK IS REC 2.  OTHERWISE,      30080019
         B     CUP0092                 AVLRECFW IS 1' AVAILABLE.        30120019
CUP0091  IC    GR1RG,AVLRECFW          UPDATE CHAIN RECORD EOS ENTRY    30160019
CUP0092  STC   GR1RG,RCHANFW-2(ICRG)                                    30200019
         IC    GR1RG,INSDTRAN+2        CORRECT FIRST RECORD OF SEGMENT  30240019
         STC   GR1RG,SEGR1FW             IN FILE BOX                    30280019
*                                      EXCP                             30320019
CUP010   MVI   CCWCMCD3,WRITEKD        CCW3 CHANGED TO WRITE            30360019
        LA    GR1RG,RCHANFW                                             30400019
         ST    GR1RG,CCWADDR4          WRITE RECORD CHAIN FROM RCHANFW. 30440019
         MVI   CCWFLGS4,CC             CCW4 FLAGS TO COMMAND CHAIN      30480019
         L     LINK2RG,EXRET2LK                                         30520019
         BALR  LINK1RG,LINK2RG         EXCP                             30560019
*                                      ENDIO                            30600019
CUP011   BALR  LINK1RG,LINK1RG                                          30640019
*                                                                       30680019
*                       A.S.I.           ENTRY                          30720019
*                                                                       30760019
*              IF THERE IS TO BE AN INDEX UPDATE, SEGMENT DATA AND KEYS 30800019
*              IN TRANSIENT CORE ARE MOVED TO THE OLD RECORD CHAIN      30840019
*              AREA.  IF NO INDEX UPDATE WILL BE DONE, THE NEXT         30880019
*              BEGINNING OF SEGMENT ADDRESS IS OBTAINED FROM THE TRACK  30920019
*              CHAIN.  LAST-RECORD-MOVED AND RECORD-CHAIN-UPDATE-       30960019
*              PENDING BITS ARE RESET.                                  31000019
*                                                                       31040019
         TM    STATUSFW,DELETE+INSERT+LASTKEY+SEGDATA                   31080019
         BC    8,CUPX014               BRANCH IF NO INDEX UPDATE        31120019
*                                      INDEX UPDATE TO FOLLOW           31160019
         BAL   INTLNKRG,NXTAVAIL       GET REC# OF NEXT AVAILABLE REC   31200019
         STC   ICRG,AVAIL1FW             ON TRACK - STORE IN FILE BOX   31240019
         MVC   INSEGFW(11),INSDTRAN+1  MOVE SEGMENT DATA AND KEYS FROM  31280019
         MVC   REPSEGFW(11),REPDTRAN+1  TRANSIENT CORE TO FILE BOX.     31320019
CUP013   NI    STATUSFW,X'FF'-LASTMOVE-RECPEND                          31360019
*                                      RESET BITS                       31400019
         BR    LINK1RG                 RETURN                           31440019
*                                      NO INDEX UPDATE FOLLOWS; TRACK   31480019
*                                      CHAIN HAS BEEN READ              31520019
CUPX014  TM    AVLRECFW,INSRTOVF                                        31560019
         BC    1,CUPX015               BRANCH IF INSERT OVERFLOW        31600019
         LA    GR3RG,TMPAREA1          LOCATE TRACK CHAIN               31640019
         IC    ICRG,SEGRFFW            NEXT SEGMENT ADDRESS FROM TRACK  31680019
         BAL   INTLNKRG,COMPUAD          CHAIN                          31720019
         IC    ICRG,RCHANFW-2(ICRG)      R FROM RECORD CHAIN            31760019
CUPX0145 STC   ICRG,SCHRRFW                                             31800019
         NI    SCHRRFW,X'FF'-EOS  TURN OFF EOS INDICATOR                31840019
         MVC   SCHTRKFW+1(3),0(GR1RG)  SAVE TRACK ADDRESS               31880019
         B     CUP013                                                   31920019
*                       INSERT OVERFLOW                                 31960019
CUPX015  LA    GR1RG,TMPAREA1+1        NEXT SEGMENT ADDRESS IS IN       32000019
         IC    ICRG,TMPAREA1             TRACK CHAIN SAVE AREA          32040019
         B     CUPX0145                                                 32080019
CUPX008  MVI   SRCHCOD2,WRCHANCW       CHANGE 1' LIST ENTRY TO OUTPUT   32120019
         B     CUP001                                                   32160019
CUPX012  TM    AVLRECFW,INSRTOVF                                        32200019
         BC    1,CUP009                BRANCH IF INSERT OVERFLOW        32240019
         B     CUP011                  NO ADDITIONAL I/O; ENDIO         32280019
*********************************************************************** 32320019
*                                                                       32360019
*********************************************************************** 32400019
*                                                                       32440019
*                                                                       32480019
*  UPDTCHAN -           UPDATE TRACK CHAIN ROUTINE                      32520019
*                                                                       32560019
*  SAVES THE OLD EOS ENTRY IN TRACK CHAIN SAVE AREA, AND REMOVES THE    32600019
*  OLD EOS INDICATION FROM THE TRACK CHAIN.  IF RE-ENTERED, MOVES IN A  32640019
*  NEW EOS ENTRY.                                                       32680019
*                                                                       32720019
*  BAL  LINK2RG,UPDTCHAN                                                32760019
*  INPUT:  TRACK CHAIN IS AT TMPAREA1                                   32800019
*          RECORD CAHIN IS AT RCHANFW                                   32840019
*  INPUT REGISTERS:  GR2RG CONTAINS A POINTER TO THE NEW EOS REC#       32880019
*                    ICRG CONTAINS OLD EOS REC#                         32920019
*                                                                       32960019
*  BAL  LINK2RG,UPDTCHN2                                                33000019
*  INPUT REGISTERS:  GR2RG CONTAINS A POINTER TO THE NEW EOS REC#       33040019
*                    ICRG CONTAINS OLD EOS REC#                         33080019
*                    GR3RG POINTS TO THE TRACK CHAIN                    33120019
*                    SRCHRG POINTS TO THE RECORD CHAIN - 2              33160019
*                                                                       33200019
*  OUTPUT REGISTERS:  GR1RG DESTROYED                                   33240019
*                    GR3RG POINTS TO THE TRACK CHAIN                    33280019
*                     INTLNKRG DESTROYED                                33320019
*                     ICRG CONTAINS NEW EOS REC#                        33360019
*                    SRCHRG POINTS TO THE RECORD CHAIN - 2              33400019
*                                                                       33440019
*  RETURN:  BALR  LINK2RG,LINK2RG                                       33480019
*                                                                       33520019
UPDTCHAN LA    GR3RG,TMPAREA1          POINTER TO TRACK CHAIN           33560019
         LA    SRCHRG,RCHANFW-2        REC 0 OF RECORD CHAIN            33600019
UPDTCHN2 STC   ICRG,5(GR3RG)           SAVE - OLD EOS REC#              33640019
         BAL   INTLNKRG,COMPUAD        GET ADDR OF EOS ENTRY            33680019
         MVC   1(3,GR3RG),0(GR1RG)     SAVE - OLD EOS ENTRY             33720019
         MVI   0(GR1RG),0              REMOVE OLD EOS INDICATION        33760019
         IC    ICRG,0(GR2RG)                                            33800019
         IC    GR1RG,0(ICRG,SRCHRG)    SAVE - R OF OLD EOS ENTRY        33840019
         STC   GR1RG,0(GR3RG)                                           33880019
         BALR  LINK2RG,LINK2RG         FIRST RETURN                     33920019
*                                                                       33960019
*  RE-ENTER TO MOVE IN A NEW TRACK-CHAIN EOS ENTRY.                     34000019
*                                                                       34040019
*  BALR  LINK2RG,LINK2RG                                                34080019
*  INPUT REGISTERS:  GR2RG POINTS TO THE (C+1)CH FOR THE NEW EOS ENTRY* 34120026
*                    GR3RG POINTS TO THE TRACK CHAIN                    34160019
*                     ICRG CONTAINS NEW EOS REC#                        34200019
*                                                                       34240019
*  OUTPUT REGISTERS:  GR1RG POINTS TO NEW TRACK-CHAIN EOS ENTRY         34280019
*                     INTLNKRG DESTROYED                                34320019
*                                                                       34360019
*  RETURN:  BR  LINK2RG                                                 34400019
*                                                                       34440019
         BAL   INTLNKRG,COMPUAD                                         34480019
         MVC   0(3,GR1RG),0(GR2RG)                                      34520019
         BR    LINK2RG                                                  34560019
*                                                                       34600019
*********************************************************************** 34640019
*                                                                       34680019
*                                                                       34720019
*  COMPUAD - COMPUTE TRACK CHAIN ENTRY ADDRESS                          34760019
*                                                                       34800019
*       BAL   INTLNKRG,COMPUAD                                          34840019
*  INPUT REGISTERS:  ICRG CONTAINS RECORD #                             34880019
*                    GR3RG POINTS TO 1' BYTE OF TRACK CHAIN             34920019
*  OUTPUT REGISTERS:  GR1RG POINTS TO 1' BYTE OF TRACK CHAIN ENTRY      34960019
*       RETURN:  BR    INTLNKRG                                         35000019
*                                                                       35040019
COMPUAD  LA    GR1RG,0(ICRG,ICRG)                                       35080019
         AR    GR1RG,ICRG              3*REC# = DISPLACEMENT            35120019
         ALR   GR1RG,GR3RG             ADD DISP TO BASE OF TRACK CHAIN  35160019
         BR    INTLNKRG                                                 35200019
*                                                                       35240019
*                      FIRST RECORD MOVED UPDATE                        35280019
*                                                                       35320019
*              WHEN THE FIRST RECORD OF A SEGMENT IS MOVED THE CHAIN    35360019
*              POINTER TO THE FIRST RECORD MUST BE UPDATED.  THE FIRST  35400019
*              RECORD OF A SEGMENT IS POINTED TO BY EITHER THE END OF   35440019
*              SEGMENT POINTER OF THE PREVIOUS SEGMENT (IN ALL CASES    35480019
*              EXCEPT SEGMENT#1), OR THE MASTER INDEX (FOR SEGMENT #1). 35520019
*                                                                       35560019
FRSTMVRQ TM    STATUSFW,FRSTMOVE  CHECK FOR EOS POINTER IN NEED OF      35600019
         BCR   8,LINK1RG               UPDATE;  EXIT IF NOT             35640019
FRSTMDRQ NI    STATUSFW,X'FF'-FRSTMOVE      RESET PENDING UPDATE        35680019
         CLI   SEGNUMFW,1         CHECK FOR FIRST SEGMENT               35720019
         LA    ICRG,CHKNDXBQ      ASSUME FIRST SEGMENT                  35760019
         BNH   MASTREQ                 BRANCH IF SO                     35800019
         LA    ARG1RG,11               11 CCW'S                         35840019
         LA    ARG2RG,3           3 SEARCHARGS                          35880019
         LA    ARG3RG,4*L'RCHANFW+6(ARG3RG)      ADD STORAGE FOR CHAIN  35920019
         L     ARG4RG,PRETRKFW         TRACK                            35960019
         BR    LINK2RG                 REQUEST I/O                      36000019
*                                                                       36040019
*                       SET UP SEARCH ARGUMENT TABLE                    36080019
*                                                                       36120019
FRSTMVEX CLI   SEGNUMFW,1              BRANCH IF NOT CHAIN RECORD UPDAT 36160019
         BNH   FRM002                                                   36200019
         MVI   SRCHCOD2,RDRTCW0        READ CHAIN RECORD, NO CC         36240019
         MVI   SRCHCOD3,WRITCKCW  WRITE-CHECK                           36280019
         BALR  LINK1RG,LINK2RG         TO NO-SORT GENERATORS            36320019
*                                                                       36360019
*                       RETURN AT CHANNEL END                           36400019
*                                                                       36440019
         OI    SEGR1FW,EOS             PRESENT FIRST RECORD OF SEGMENT  36480019
         IC    GR1RG,SEGR1FW             WITH EOS BIT IS NEW EOS R      36520019
         IC    ICRG,PRERRFW+1                                           36560019
         LA    SRCHRG,TMPAREA0-2       TO ADDRESS RECORD CHAIN          36600019
         STC   GR1RG,0(SRCHRG,ICRG)                                     36640019
         LA    GR2RG,PRERRFW+1                                          36680019
         LA    GR3RG,TMPAREA0+L'RCHANFW     POINTS TO TRACK CHAIN       36720019
         BAL   LINK2RG,UPDTCHN2        SAVE OLD TRACK CHAIN EOS         36760019
         STC   ICRG,4(GR3RG)           NEW EOS RECORD #, FOR SAVE       36800019
         LA    GR2RG,LSTRECFW+1                                         36840019
         BALR  LINK2RG,LINK2RG         MOVE IN NEW TRACK-CHAIN ENTRY.   36880019
         OI    CCWFLGS4,CC             CHANGE CHANNEL PROGRAM TO OUTPUT 36920019
FRM003   MVI   CCWCMCD3,WRITEKD           UPDATED RECORD AND WRITE CHEK 36960019
         L     LINK2RG,EXRET2LK                                         37000019
         BALR  LINK1RG,LINK2RG         EXCP AGAIN                       37040019
*                                                                       37080019
         BALR  LINK1RG,LINK1RG         ENDIO                            37120019
         CLI   AVAILNFW,X'FF'          ARE THERE ANY DATA RECORDS       37160019
         BCR   7,LINK1RG                  LEFT ON THIS TRACK            37200019
         L     CYLERG,XAVAILFW         NO, RELEASE TRACK                37240019
         BAL   LINK2RG,PUTRACK                                          37280019
         BR    LINK1RG                 RETURN TO SCHEDULER              37320019
*                                                                       37360019
* UPDATE MASTER INDEX TO POINT TO NEW FIRST RECORD OF FILE              37400019
*                                                                       37440019
FRM002   MVI   SRCHCOD1,FRSTR1CW       READ IN MASTER INDEX             37480019
         BALR  LINK1RG,LINK2RG                                          37520019
         BAL   LINK2RG,LOCNTRY         LOCATE MASTER INDEX ENTRY        37560019
         L     GR2RG,LSTRECFW             AND UPDATE FIRST RECORD OF    37600019
         ST    GR2RG,0(GR1RG)             FILE POINTER                  37640019
         IC    GR2RG,SEGR1FW                                            37680019
         STC   GR2RG,0(GR1RG)                                           37720019
         OI    CCWFLGS3,CC             SET UP FOR WRITE CHECKING        37760019
         CLI   0(GR1RG),ALL            EOD??                            37800019
         BE    FRM003                  YES - BRANCH                     37840019
         NI    0(GR1RG),ALL-EOS        RESET EOS FLAG                   37880019
         B     FRM003                     AND GO OUTPUT UPDATED RECORD  37920019
*                                                                       37960019
*                       FORMAT AND INSERT PROGRAM                       38000019
*                                                                       38040019
*              THIS PROGRAM FORMATS A NEWLY ALLOCATED TRACK FOR DATA    38080019
*              RECORDS AND INSERTS ONE OR MORE (AS SPECIFIED BY         38120019
*              COUNTFS) DATA RECORDS IN THE PROCESS.                    38160019
*                                                                       38200019
NEWINSRQ LH    SRCHRG,UNORECFW    SEARCH ARGUMENT FOR EACH RECORD       38240019
         BAL   INTLNKRG,COUNTREQ  3 CCWS FOR EACH ACTUAL DATA RECORD    38280019
         AR    GR2RG,GR2RG             AND ONE FOR EACH DUMMY RECORD    38320019
         LA    CCWRG,15(SRCHRG,GR2RG)  15 EXTRA FOR CHAIN REC. AND CHEK 38360019
         LA    SRCHRG,3(SRCHRG)        SRCHARG/RECORD (INCL R0 & R1)    38400019
         LA     GR2RG,MINXTND+4*L'RCHANFW+6      +1 FOR WRITE CHECK.    38440019
*                                      STORAGE FOR CHAIN RECORD         38480019
         L      GR3RG,LSTRECFW                                          38520019
         BR    LINK2RG                                                  38560019
*                                                                       38600019
*              EXECUTOR - SETS UP A ONE ENTRY ARGUMENT LIST AND A       38640019
*                         DUMMY RECORD CHAIN.                           38680019
*                                                                       38720019
NEWINSEX XC    TMPAREA0(4*L'RCHANFW+6),TMPAREA0                         38760019
*                                      ZERO OUT CHAIN RECORD            38800019
         MVI   SRCHCOD1,NUINCW         CCW-GENRATOR ROUTINE             38840019
         BAL   INTLNKRG,COUNTREQ       ARGUMENT IS ADDRESS OF THE 1'    38880019
         BALR  INTLNKRG,INTLNKRG         LOGICAL RECORD TO BE WRITTEN,  38920019
         ST    GR1RG,SRCHARG3            STORED IN THE COUNT OF THE 1'  38960019
         ST    GR2RG,FCOUNT3           # DATA RECS IS 2' WD OF COUNT    39000019
         BALR  LINK1RG,LINK2RG         SCHEDULER SENDS TO GENERATOR     39040019
*                                                                       39080019
*                       CHANNEL END ENTRY                               39120019
*                                                                       39160019
NUINEX2  BALR  LINK1RG,LINK1RG         ENDIO                            39200019
*                                                                       39240019
*                      ASYNCHRONOUS ENTRY                               39280019
*                                                                       39320019
         MVC   RCHANFW,TMPAREA0+3*L'RCHANFW+6                           39360019
*                                      MOVE RECORD CHAIN TO FILE BOX    39400019
         IC    GR1RG,COUNTFS+1    ASSUME COUNT SATISFIED IF             39440019
         TM    AFPAR2FS,MULTIPLE       IF MULTIPLE OPERATION            39480019
         BCR   8,LINK2RG                                                39520019
         STC   GR1RG,COUNTFS                                            39560019
         BR    LINK2RG            RETURN AND RELEASE BUFFER             39600019
*                                                                       39640019
*                                                                       39680019
*                       SCAN TRACK LIST                                 39720019
*                                                                       39760019
*              THIS PROGRAM LOCATES THE TRACK LIST ENTRY FOR THE PRE-   39800019
*              SENT TRACK WHEN IT IS KNOWN THAT ONE EXISTS, BUT ITS     39840019
*              POSITION IS UNKNOWN.  IT ALSO IS USED TO LOCATE THE      39880019
*              LARGEST REMAINING HOLE IN THE FILE WHEN ALL AVAILABLE    39920019
*              RECORDS ON THE AVAILABLE RECORD TRACK HAVE JUST BEEN     39960019
*              USED UP.                                                 40000019
*                                                                       40040019
RLSTINRQ CLI   AVLRECFW+1,ZERO         CHECK FOR INSERT RECORD HOLE     40060026
         BZ    RLSTRQ1                 NOT KNOWN                        40120019
         CLC   AVLRECFW+1(3),LSTRECFW+1     GO TO READ TRACK LIST       40160019
         BE    RLSTRQ1                 IF NOT KNOWN                     40200019
RLSTUPRQ TM    STATUSFW,DELETE+INSERT+LASTKEY+SEGDATA                   40240019
         BCR   8,LINK1RG          IF NO INDEX UPDATE, NO TRK LIST SCAN  40280019
         CLI   PTRKDPFW,X'FF'     CHECK FOR TRACK LIST POSITION UNKNOWN 40320019
         BCR   7,LINK1RG               OK IF KNOWN                      40360019
         CLC   AVLRECFW+1(3),LSTRECFW+1                                 40400019
         BC    7,RLSTRQ1          READ TRACK LIST IF NOT SAME AS        40440019
         MVC   PTRKDPFW,ATRKDPFW       AVAILABLE TRACK                  40480019
         BR    LINK1RG                                                  40520019
RLSTRQ1  LA    ARG1RG,4                4 CCW'S                          40560019
         LA    ARG2RG,1                1 SRCHARG                        40600019
         IC    ICRG,TKLSTZFW                                            40640019
         AR    ARG3RG,ICRG             TEMPORARY STORAGE FOR TRACK LIST 40680019
         L     ARG4RG,NDXRTKFW         INDEX TRACK                      40720019
         BR    LINK2RG                 REQUEST I/O                      40760019
*                                                                       40800019
*              USES ONEARG TO SET UP SEARCH ARGUMENT LIST.              40840019
*                                                                       40880019
*                       ENTRY AT CHANNEL END.                           40920019
*                                                                       40960019
RLSTUPEX MVI   SRCHCOD1,RDTLSTCW       READ TRACK LIST                  41000019
         BALR  LINK1RG,LINK2RG            INTO TEMPORARY STORAGE        41040019
         BALR  LINK1RG,LINK1RG         ENDIO                            41080019
*                                                                       41120019
*                       ASYNCHRONOUS ENTRY.                             41160019
*                                                                       41200019
         LA    SRCHRG,TMPAREA0         TRACK LIST LOCATION              41240019
         LA    CCWRG,LSTRECFW+1        THIS TRACK'S ACH                 41280019
         CLI   PTRKDPFW,X'FF'          SEARCH FOR THIS TRACK'S LIST     41320019
         BNE   RTL004                    ENTRY?  BR IF NO               41360019
         BAL   LINK2RG,SCNLSTEQ                                         41400019
         BC    2,RTL003                ENTRY FOUND, BRANCH              41440019
RTL002   OI    AFPAR1FS,AFIOERR        NOT FOUND; SET AFIOERR & RETURN  41480019
         BR    LINK1RG                   TO SCHEDULER.                  41520019
RTL003   STC   GR1RG,PTRKDPFW          STORE ENTRY DISPLACEMENT         41560019
RTL004   CLC   AVLRECFW+1(3),LSTRECFW+1     IS SEARCH FOR AN EXTRA      41600019
         BNE   RTL005                  AVAILABLE AREA; BR IF NO         41640019
         BAL   LINK2RG,SCNLST1         SCAN FOR LARGEST HOLE.           41680019
         BC    8,RTL002                ERROR; NO OTHER AREAS AVAILABLE. 41720019
         BALR  LINK2RG,LINK2RG         INITIALIZE ATRKDPFW, AVLRECFW.   41760019
RTL005   BR    LINK1RG                 RETURN TO SCHEDULER              41800019
*                                                                       41840019
*********************************************************************** 41880019
NDXSEQRQ OI    AFPAR1FS,MACOMP1   SET FOR PROCEDE TO NEXT SEGMENT       41920019
NDXRQ    TM    STATUSFW,FRSTMOVE  CHECK FOR EOS IN NEED OF UPDATE       41960019
         BZ    NDXRQ0                  BRANCH IF NOT                    42000019
NDXINBRQ CLI   SEGNUMFW,1         INDEX RECORD NEEDED TO LOCATE LAST    42040019
         BC    2,NDXRQ1                EOS IF NOT FIRST SEGMENT         42080019
NDXRQ0   TM    STATUSFW,DELETE+INSERT+LASTKEY+SEGDATA                   42120019
         BC    7,NDXRQ1           BRANCH IF ANY UPDATES NEEDED          42160019
         TM    AFPAR1FS,MACOMP1   NONE, IF PROCESSING TO NEXT SEGMENT,  42200019
         BZ    NDXRQ4                  (NO, BRANCH)                     42240019
         CLI   LSTRECFW,0              CHECK FOR BACKSPACE NEEDED       42280019
         BNE   NDXRQ2                  BRANCH IF NOT                    42320019
NDXRQ1   MVI   SCHPOSFW,0         SET INDEX UPDATE TO SEQUENTIAL PROC   42360019
NDXPNTRQ TM    SEGNUMFW,X'FF'     CHECK FOR NOT POSITIONED IN FILE      42400019
         BC    6,NDXQ3                 BRANCH IF POSITIONED SOMEWHERE   42440019
         MVI   SEGNUMFW,1              NO, DUMMY UP FOR SEGMENT ONE     42480019
NDXQ3    LA    CCWRG,6            ASSUME 6 CCW'S                        42520019
         TM    STATUSFW,DELETE+LASTKEY+SEGDATA+INSERT                   42560019
*                                      ARE UPDATES REQUIRED?            42600019
         BZ    RQ001                   NO UPDATES                       42640019
         LA    CCWRG,16                     UPDATES, NEED 16 CCW'S      42680019
RQ001    LA    SRCHRG,3           3 SEARCH ARGUMENTS                    42720019
         SR    GR2RG,GR2RG                                              42760019
         IC     GR2RG,NUMSEGFW         NUMBER OF SEGMENTS IN INDEX      42800019
         SLA    GR2RG,4                *16                              42840019
         IC    ICRG,TKLSTZFW           LENGTH OF TRACK LIST (KEY)       42880019
         LA     GR2RG,MINXTND2+78(ICRG,GR2RG)    MIN EXTENDED AREA +    42920019
*                                 LENGTH INDEX REC + 62                 42960019
         L     GR3RG,NDXRTKFW          INDEX TRACK ADDRESS              43000019
         BR    LINK2RG                                                  43040019
NDXRQ2   MVI   PTRKDPFW,0         RESET TRACK LIST POSITION             43080019
         L     GR1RG,AVLRECFW     DUMMY UP NEXT AVAILABLE TRACK         43120019
         ST    GR1RG,XAVAILFW          ADDRESS                          43160019
         NI    XAVAILFW,X'FF'-INSRTOVF                                  43200019
         IC    GR1RG,ATRKDPFW                                           43240019
         STC   GR1RG,XTRKDPFW                                           43280019
         IC    ICRG,SEGNUMFW      BUMP TO NEXT SEGMENT                  43320019
         LA    ICRG,1(ICRG)                                             43360019
NDXRQ3   STC   ICRG,SCSGNMFW                                            43400019
         BR    LINK1RG                                                  43440019
NDXRQ4   L     GR1RG,LSTRECFW     SET TO POSITION BACK TO SAME TRACK    43480019
         ST    GR1RG,SCHTRKFW                                           43520019
         LH    GR1RG,PRSRRFW                                            43560019
         STH   GR1RG,SCHRRFW                                            43600019
         IC    ICRG,SEGNUMFW           AND PRESERVE SEGMENT NUMBER      43640019
         B     NDXRQ3                                                   43680019
*                                                                       43720019
*              A ONE-SEARCH-ARGUMENT LIST IS SET UP FOR NDXUCW,         43760019
*              WHICH BRANCHES TO THE CCW-GENERATOR ROUTINE, NDXUGN.     43800019
*              CONTROL RETURNS HERE AT CHANNEL END.                     43840019
*                                                                       43880019
NDXUEX2  TM    STATUSFW,DELETE+INSERT+LASTKEY+SEGDATA           A42692  43885026
*                                      ANY UPDATES?             A42692  43890026
         BZ    NDXUEX3                 NO                       A42692  43895026
         LR    LINK1RG,LINK2RG         SET FOR EXCP RETURN      A42692  43900026
         L     CCWRG,PATCH             REG SAVE AREA            A42692  43905026
         STM   GR0RG,LINK2RG,ZERO(CCWRG) SAVE REGISTERS         A42692  43910026
         L     LINK2RG,VND             ADDR OF ENTRY POINT      A42692  43915026
         L     BASERG,CCWSRTLK         BASE FOR GCW             A42692  43920026
         BALR  INTLNKRG,LINK2RG        WRITE INDEX TRACK        A42692  43925026
         L     BASERG,EXBASELK         REESTABLISH BASE         A42692  43930026
         L     CCWRG,PATCH                                      A42692  43935026
         LM    GR0RG,LINK2RG,ZERO(CCWRG) RESTORE REGISTERS      A42692  43940026
         BALR  LINK1RG,LINK1RG         EXECUTE CP AGAIN         A42692  43945026
NDXUEX3  BALR  LINK1RG,LINK1RG         ALL DONE                 A42692  43950026
*                                                                       43960019
*                                                                       44000019
         NI    STATUSFW,X'FF'-DELETE-INSERT-LASTKEY-SEGDATA             44040019
*                                      RESET INDEX UPDATE BITS          44080019
SIZE     EQU   16                      SIZE OF SEGMENT          A42692  44100026
*                                                                       44160019
*              IF THERE IS A PREVIOUS SEGMENT, STORE ITS TRACK ADDRESS  44200019
*              AND FIRST AND LAST RECORD IN FILE BOX.                   44240019
*                                                                       44280019
         DROP  CCWRG                                                    44300026
         CLI   SEGNUMFW,1              IF AT SEGMENT 1                  44320026
         BE    NDXPOS05                   THERE IS NO PREVIOUS SEGMENT  44340026
         IC    ICRG,SEGNUMFW           COMPUTE OFFSET                   44360026
         LR    GR2RG,ICRG                 TO                            44380026
         BCTR  GR2RG,0                    PREVIOUS                      44400026
         SLA   GR2RG,4                    SEGMENT                       44420026
         L     GR1RG,SAV2              ESTABLISH POINTER                44440026
         USING CCWMSK,GR1RG                                             44460026
         L     GR1RG,CCWADDR1             TO BEGINNING OF SEGMENT LIST  44480026
         DROP  GR1RG                                                    44500026
         L     INTLNKRG,0(GR2RG,GR1RG) INITIALIZE PRETRKFW - XACH       44600019
         ST    INTLNKRG,PRETRKFW                                        44640019
         LH    INTLNKRG,6(GR2RG,GR1RG) INITIALIZE PRERRFW - RR          44680019
         STH   INTLNKRG,PRERRFW                                         44720019
*                                                                       44760019
*              DETERMINE TYPE OF POSITIONING                            44800019
*                                                                       44840019
NDXPOS0  TM    SCHPOSFW,REPOST1                                         44880026
         BZ    NDXPOS5                 BRANCH IF SEQUENTIAL POSITIONING 44920019
         TM    SCHPOSFW,BYRECNUM                                        44960019
         BZ    NDXPOS3                 BR IF POSITION BY KEY            45000019
*                        POSITION TO FIRST OR LAST                      45040026
         IC    ICRG,NUMSEGFW           ASSUME LAST                      45080026
         TM    SCHPOSFW,LAST              LAST?                         45120026
         BO    NDXPOSF1                   YES, BRANCH                   45160026
         LA    ICRG,1                  SET TO FIRST SEGMENT             45200026
         B     NDXPOSF1                                                 45280019
NDXPOS05 MVI   PRETRKFW+1,0            SET NO PREVIOUS SEGMENT          45320019
         B     NDXPOS0                                                  45360019
*                                      POSITION TO LAST                 45400019
*                                      POSITION BY KEY                  45720019
*                        USE BINARY SEARCH                              45730026
NDXPOS3  LA    GR0RG,SIZE              LENGTH OF SEGMENT LIST ENTRY     45740026
         L     GR1RG,SAV2              LOCATE CCW                       45750026
         USING CCWMSK,GR1RG                                             45760026
         LH    GR2RG,CCWHCNT1          LENGTH OF                        45770026
         SH    GR2RG,H16KN                SEGMENT LIST                  45780026
         L     GR1RG,CCWADDR1          BEGINNING OF                     45790026
         DROP  GR1RG                                                    45800026
         LA    GR1RG,SIZE(GR1RG)          SEGMENT LIST                  45810026
         LH    ICRG,UMLKDFW            MACHINE LENGTH OF KEY            45840019
         L     SRCHRG,NXTKEYFW         PNTR TO COMPARE-KEY              45880019
         BAL   LINK2RG,BINSERCH        SEARCH                           46160019
         B     NDXPOSF0                   *SEGMENT FOUND                46200026
         B     NDXNOREC                   *NOT FOUND, KEY TOO HIGH      46240026
NDXCOMP  CLC   8(0,INTLNKRG),0(SRCHRG)                                  46280019
*                                                                       46640019
*              IF SEARCH ON KEY IS UNSATISFIED, SET SCSGNMFW EQUAL TO   46680019
*              X'FF', & USE PREVIOUS SEGMENT TO INITIALIZE NEXT SEGMENT 46720019
*              FIELDS.                                                  46760019
*                                                                       46800019
NDXNOREC MVI   SCSGNMFW,X'FF'                                           46840019
         B     NDXPOSF3                ALREADY POINTED TO PREV SEGMENT  46880019
*                       SEQUENTIAL POSITIONING                          46920019
NDXPOS5  TM    AFPAR1FS,MACOMP1                                         46960019
         BZ    NDXPOS6                 BR IF TO SAME SEGMENT            47000019
*                       TO ADJACENT SEGMENT                             47040019
         IC    ICRG,SEGNUMFW           ASSUME POSITIONING               47060026
         BCTR  ICRG,0                     TO PREVIOUS SEGMENT           47080026
         CLI   LSTRECFW,0              GOOD GUESS?                      47100026
         BE    NDXPOSF1                   YES, BRANCH                   47120026
*                        TO NEXT SEGMENT                                47140026
         LA    ICRG,2(ICRG)            ASSUME POSITIONING TO NEXT SEG   47160026
         CLC   SEGNUMFW,NUMSEGFW       BEYOND LAST SEGMENT?             47180026
         BNE   NDXPOSF1                   NO, GOOD GUESS, BRANCH        47200026
*                        EOD                                            47220026
         STC   ICRG,SCSGNMFW           SET SEGMENT # TO TOTAL + 1       47240026
         MVI   SCHRRFW,X'FF'           SET EOD FLAG                     47260026
         MVI   SCHTRKFW+1,0            THERE IS NO SEARCH TRACK         47280026
         B     NDXTKL15                                                 47300026
*                       TO SAME SEGMENT                                 47440019
NDXPOS6  IC    ICRG,SEGNUMFW           ASSUME SAME SEGMENT              47520026
         CLC   SEGNUMFW,NUMSEGFW       JUST DELETED LAST?               47600026
         BNH   NDXPOSF1                   NO, GOOD GUESS, BRANCH        47680026
*                        LAST SEGMENT DELETED                           47760026
         MVI   SCSGNMFW,X'FF'          SET SPECIAL DELETE FLAG          47840026
         BCTR  ICRG,0                  USE LAST (PREVIOUS) SEGMENT      47920026
         B     NDXPOSF2                                                 48000026
*                                                                       48120019
*              A SEGMENT HAS BEEN FOUND AND SCSGNMFW, SCHRRFW,          48160019
*              AND SCHTRKFW WILL BE INITIALIZED                         48180026
*                                                                       48200026
NDXPOSF0 LA    GR2RG,0(INTLNKRG)       POINTER TO SEGMENT               48220026
         L     GR1RG,SAV2              LOCATE BEGINNING OF SEGMENT LIST 48240026
         USING CCWMSK,GR1RG                                             48260026
         S     GR2RG,CCWADDR1          COMPUTE OFFSET TO ENTRY          48280026
         DROP  GR1RG                                                    48300026
         SRA   GR2RG,4                 COMPUTE SEGMENT NUMBER           48320026
         STC   GR2RG,SCSGNMFW             AND SAVE                      48340026
         B     NDXPOSF3                                                 48360026
*                                                                       48380026
NDXPOSF1 STC   ICRG,SCSGNMFW           SAVE SEGMENT NUMBER              48400026
NDXPOSF2 LR    INTLNKRG,ICRG           COMPUTE                          48420026
         SLA   INTLNKRG,4                 OFFSET                        48440026
         L     GR1RG,SAV2              LOCATE BEGINNING                 48460026
         USING CCWMSK,GR1RG                                             48480026
         AL    INTLNKRG,CCWADDR1       COMPUTE ADDRESS OF SEGMENT       48500026
         DROP  GR1RG                                                    48520026
NDXPOSF3 MVC   SCHTRKFW+1(3),1(INTLNKRG)  INITIALIZE SCHTRKFW - ACH     48640019
         LH    GR2RG,6(INTLNKRG)                                        48680019
         STH   GR2RG,SCHRRFW           RR                               48720019
*                                                                       49320019
*        INITIALIZE TRACK LIST DISPLACEMENT (PTRKDPFW) FOR NEW          49360019
*              POSITION.                                                49400019
*                                                                       49440019
NDXTKL15 SR    GR1RG,GR1RG             ASSUME NO TRACK LIST ENTRY       49480019
         LA    SRCHRG,TMPAREA2         ADDR OF TRACK LIST               49520019
         LA    CCWRG,SCHTRKFW+1        SEARCH THIS TRACK'S LIST ENTRY   49560019
         BAL   LINK2RG,SCNLSTEQ                                         49600019
         STC   GR1RG,PTRKDPFW          STORE DISPLACEMENT               49640019
*                                                                       49680019
*              IF INSERT OVERFLOW IS NOT SET, AND THERE ARE AVAILABLE   49720019
*              RECORD AREAS ON THE AVAILABLE RECORD TRACK (AVLRECFW),   49760019
*              AND THAT TRACK IS NOT THE NEXT TRACK TO BE PROCESSED     49800019
*              (SCHTRKFW), THEN NO SCAN IS NECESSARY.                   49840019
*                                                                       49880019
NDXTKL2  LA    INTLNKRG,TMPAREA2+16    LAST ENTRY IF SINGLE ENTRY       49920019
          TM   AVLRECFW,INSRTOVF                                        49960019
         BO    NDXTKL6                 BR IF INSERT OVERFLOW            50000019
         CLI   AVLRECFW+1,ZERO         IF THERE IS NO AVAILABLE RECORD  50020026
          BE   NDXTKL3                      TRACK, BR TO SCAN           50080019
         CLC   AVLRECFW+1(3),SCHTRKFW+1     IF THE AVAILABLE RECORD     50120019
         BE    NDXTKL3            TRACK IS THE NEXT TRACK, BR TO SCAN   50160019
         BR    LINK1RG                 IF NO SCAN NEEDED, RETURN        50200019
*                                                                       50240019
*              TRACK LIST WILL BE SCANNED, AVLRECFW & ATRKDPFW WILL BE  50280019
*              INITIALIZED.                                             50320019
*                                                                       50360019
NDXTKL3  CLI   TKLSTZFW,21                                              50400019
         BL    NDXTKL4                 BR IF NO ENTRIES                 50440019
         BE    NDXTKL5                 BR IF ONLY ONE ENTRY             50480019
         LA    CCWRG,SCHTRKFW+1        EXCLUDED TRACK POINTER           50520019
         BAL   LINK2RG,SCNLST1         SCAN LIST AND                    50560019
         BALR  LINK2RG,LINK2RG              INITIALIZE FILE BOX         50600019
         BR    LINK1RG                 RETURN TO SCHEDULER              50640019
*                                                                       50680019
*              NO TRACK LIST ENTRIES - NO INSERT OVERFLOW               50720019
*                                                                       50760019
NDXTKL4  MVI   AVLRECFW+1,ZERO         SET TO ZERO               A45668 50800026
         BR    LINK1RG                      AND RETURN TO SCHEDULER     50840019
*                                                                       50880019
*              TRACK LIST HAS ONLY ONE ENTRY                            50920019
*                                                                       50960019
NDXTKL5  BAL   LINK2RG,SCNLST4         USE IT TO INITIALIZE FILE BOX    51000019
         BR    LINK1RG                      RETURN TO SCHEDULER         51040019
*                                                                       51080019
*              IF INSERT OVERFLOW IS SET, THE TRACK LIST IS SCANNED TO  51120019
*              LOCATE THE LARGEST HOLE IN THE FILE WHOSE TRACK ADDRESS  51160019
*              IS NOT THE SAME AS AVLRECFW.  XAVAILFW IS SET EQUAL TO   51200019
*              THE RACH OF THE ASSIGNED AVAILABLE RECORD AREA, AND      51240019
*              XTRKDPFW SHOULD BE SET EQUAL TO THE DISPLACEMENT FOR ITS 51280019
*              ASSOCIATED TRACK LIST ENTRY.                             51320019
*                                                                       51360019
NDXTKL6  CLI   TKLSTZFW,21                                              51400019
         BE    NDXTKL8                 IF ONLY 1 ENTRY, USE IT          51440019
         BH    NDXTKL7                 IF MORE THAN 1, BR TO SCAN TRACK 51480019
         MVI   XAVAILFW+1,ZERO         IF THERE ARE NO ENTRIES, SET     51500026
         BR    LINK1RG                      A OF XAVAILFW = 0.          51560019
NDXTKL7  LA    CCWRG,AVLRECFW+1        FOR SCAN, FIND TRACK OTHER THAN  51600019
         BAL   LINK2RG,SCNLST1              AVLRECFW TRACK.             51640019
*                                                                       51680019
*              INITIALIZE XTRKDPFW, XAVAILFW.                           51720019
*                                                                       51760019
NDXTKL8  LA    ICRG,0(GR2RG,INTLNKRG)  POINTS BEYOND ENTRY              51800019
         SR    ICRG,SRCHRG                                              51840019
         STC   ICRG,XTRKDPFW                                            51880019
         IC    ICRG,4(INTLNKRG)        PICK UP R                        51920019
         STC   ICRG,XAVAILFW           INITIALIZE XAVAILFW              51960019
         MVC   XAVAILFW+1(3),0(INTLNKRG)                                52000019
         BR    LINK1RG                 RETURN TO SCHEDULER              52040019
*                                                                       52080019
NDXXMVC  MVC   0(0,GR2RG),0(GR3RG)                                      52120019
*                                                                       52160019
*                                                                       52200019
*                        BINARY SEARCH                                  52240019
*                                                                       52280019
*              A BLOCK OF SEGMENT LIST ENTRIES IS SEARCHED BY A BINARY  52320019
*              SEARCH, TO FIND A KEY HIGH OR EQUAL TO A GIVEN KEY.      52360019
*                                                                       52400019
*  CALLING SEQUENCE:  BAL  LINK2RG,BINSERCH                             52440019
*                                                                       52480019
*  INPUT REGISTERS:  GR0RG = 16                                         52520019
*                    GR1RG POINTS TO 1' BYTE OF BLOCK                   52560019
*                    GR2RG = LENGTH OF BLOCK                            52600019
*                    ICRG = MACHINE LENGTH OF KEY                       52640019
*                    SRCHRG POINTS TO KEY ON WHICH TO SEARCH            52680019
*                                                                       52720019
*  OUTPUT REGISTERS:  GR1RG DESTROYED                                   52760019
*                     INTLNKRG POINTS TO 1' KEY IN LIST WHICH SATISFIES 52800019
*                     COMPARE, OR LAST SEGMENT IF NO RECORD FOUND       52840026
*                     CCWRG DESTROYED                                   52880019
*                                                                       52920019
*  RETURN:  BR  LINK2RG    NORMAL RETURN                                52960019
*           B   4(LINK2RG) NO RECORD FOUND; KEY HIGHER                  53000026
*                            THAN THE LAST LIST KEY.                    53040019
*                                                                       53080019
*                                                                       53120019
*              SCAN LOWER BLOCK                                         53160019
*                                                                       53200019
BNSCH3   AR    GR2RG,GR0RG             INCLUDE HIGH KEY IN LOWER BLOCK  53240019
*                                                                       53280019
BINSERCH LR    CCWRG,GR2RG             SAVE LENGTH OF BLOCK TO SCAN     53320019
         SRA   GR2RG,5                 SPLIT BLOCK IN TWO (ODD ENTRY    53360019
         SLA   GR2RG,4                      IN UPPER BLOCK)             53400019
         LR    INTLNKRG,GR1RG          PNTR TO LAST ENTRY IN LOWER      53440019
         AR    INTLNKRG,GR2RG               BLOCK                       53480019
         EX    ICRG,NDXCOMP                                             53520019
         BL    BNSCH4                  BLOCK KEY LOW; SEARCH UPPER BLK  53560019
         CR    GR2RG,GR0RG             LOWER BLOCK; IS LENGTH 16?       53600019
         BH    BNSCH3                  GT 16; SEARCH LOWER BLOCK        53640019
         BL    BNSCHRET                =0; HIGH COMPARE FOUND           53680019
         SR    INTLNKRG,GR0RG          =16; CHECK 1' KEY OF BLOCK       53720019
         EX    ICRG,NDXCOMP                                             53760019
         BNL   BNSCHRET                1' NOT LOW, USE 1' KEY           53800019
         AR    INTLNKRG,GR0RG          1' LOW, USE 2' KEY               53840019
BNSCHRET BR    LINK2RG                 RETURN TO CALLER                 53880019
*                                                                       53920019
*              SCAN UPPER BLOCK                                         53960019
*                                                                       54000019
BNSCH4   LR    GR2RG,GR1RG             POINT GR1RG TO START OF UPPER    54040019
         AR    GR2RG,CCWRG               BLOCK; GR2RG IS LENGTH         54080019
         LR    GR1RG,INTLNKRG                                           54120019
         AR    GR1RG,GR0RG                                              54160019
         SR    GR2RG,GR1RG                                              54200019
         BP    BINSERCH                SEARCH UPPER BLOCK               54240019
         B     4(LINK2RG)              NO RECORD FOUND; THERE IS NO     54280026
*                                        UPPER BLOCK.                   54320019
*********************************************************************** 54360019
*                                                                       54400019
*  SCAN TRACK LIST SUBROUTINE - THE TRACK LIST IS SEARCHED FOR THE      54440019
*        TRACK ENTRY (OTHER THAN FOR THE SPECIFIED TRACK) WHICH HAS     54480019
*        THE GREATEST NUMBER OF AVAILABLE RECORDING AREAS.  A POINTER   54520019
*        TO THE TRACK ENTRY IS RETURNED.  ON REENTRY, ATRKDPFW &        54560019
*        AVLRECFW ARE INITIALIZED.                                      54600019
*        IF THERE IS ONLY ONE TRACK LIST ENTRY, AND IT IS FOR THE       54640019
*        EXCLUDED TRACK, AN ERROR RETURN IS TAKEN.                      54680019
*                                                                       54720019
*  BAL   LINK2RG,SCNLST1                                                54760019
*  INPUT:  CCWRG POINTS TO ACH OF EXCLUDED TRACK                        54800019
*          SRCHRG POINTS TO THE FIRST BYTE OF THE TRACK-LIST.           54840019
*                                                                       54880019
*  OUTPUT:  GR0RG # AVAIL RECS ON TRACK WITH MOST AVAIL RECS            54920019
*           GR1RG POINTS TO 1' BYTE BEYOND TRACK-LIST                   54960019
*           GR2RG EQUALS 5                                              55000019
*           GR3RG POINTS TO THE LAST BYTE OF THE TRACK-LIST             55040019
*          INTLNKRG POINTS TO 1' BYTE OF ENTRY WITH THE MOST AVAILABLE  55080019
*                 RECORDS.                                              55120019
*           ICRG  # AVAIL RECS IN LAST TRACK-LIST ENTRY                 55160019
*           SRCHRG POINTS TO 1' BYTE OF TRACK-LIST                      55200019
*                                                                       55240019
*  RETURN:  BR  LINK2RG.  CC = 2, NORMAL RETURN                         55280019
*                         CC = 0,  ERROR RETURN                         55320019
*                                                                       55360019
SCNLST1  BAL   INTLNKRG,SCNINIT                                         55400019
         SR    GR0RG,GR0RG             1' COMP # AVAIL RECS WILL BE HI  55440019
         EX    0,SCNCOMP               IS 1' TRK ENTRY EXCLUDED?        55480019
         BNE   SCNLST36                IF NOT, INITIALIZE WITH IT       55520019
         AR    GR1RG,GR2RG             IF EXCLUDED, BUT THERE IS A 2'   55560019
         CLI   TKLSTZFW,21               ENTRY, INITIALIZE WITH 2'      55600019
         BNE   SCNLST36                IF EXCLUDED, BUT ONLY ENTRY,     55640019
         BR    LINK2RG                   TAKE ERROR RETURN;  CC=0       55680019
SCNLST36 IC    ICRG,3(GR1RG)           # AVAIL RECS THIS ENTRY          55720019
         CR    GR0RG,ICRG              IF THIS IS A NEW HIGH, AND IT    55760019
         BNL   SCNLST37                  IS NOT THE EXCLUDED TRACK,     55800019
SCNCOMP  CLC   0(3,GR1RG),0(CCWRG)       SAVE IT AND A POINTER TO IT.   55840019
         BE    SCNLST37                                                 55880019
         LR    INTLNKRG,GR1RG                                           55920019
         LR    GR0RG,ICRG                                               55960019
SCNLST37 BXLE  GR1RG,GR2RG,SCNLST36    LOOP TO SEARCH NEXT ENTRY        56000019
         LTR   GR1RG,GR1RG             SET CC=2, FOR NORMAL RETURN      56040019
SCNLST38 BALR  LINK2RG,LINK2RG         RETURN TO CALLER                 56080019
*                                                                       56120019
*  BALR   LINK2RG,LINK2RG  OR  BAL  LINK2RG,SCNLST4                     56160019
*                                                                       56200019
*  INPUT:  INTLNKRG POINTS TO 1' BYTE OF THE SEGMENT FOR INIT           56240019
*          SRCHRG POINTS TO 1' BYTE OF TRACK-LIST                       56280019
*          GR2RG EQUALS 5                                               56320019
*                                                                       56360019
*  OUTPUT:  INTLNKRG POINTS TO 1' BYTE OF SEGMENT FOR INIT              56400019
*           ICRG HAS R OF SEGMENT                                       56440019
*                                                                       56480019
SCNLST4  LA    ICRG,0(GR2RG,INTLNKRG)  POINTS BEYOND ENTRY              56520019
         SR    ICRG,SRCHRG                                              56560019
         STC   ICRG,ATRKDPFW           DISP FROM START OF TRACK-LIST    56600019
         IC    ICRG,4(INTLNKRG)        INITIALIZE AVLRECFW - R          56640019
         STC   ICRG,AVLRECFW                                            56680019
         MVC   AVLRECFW+1(3),0(INTLNKRG)     - ACH                      56720019
         BR    LINK2RG                                                  56760019
*********************************************************************** 56800019
*                                                                       56840019
*  SCNLSTEQ             SCAN TRACK LIST FOR TRACK ENTRY                 56880019
*                                                                       56920019
*  BAL  LINK2RG,SCNLSTEQ                                                56960019
*                                                                       57000019
*  INPUT REGISTERS:  SRCHRG POINTS TO TRACK LIST                        57040019
*                    CCWRG POINTS TO ACH OF TRACK TO FIND               57080019
*                                                                       57120019
*  OUTPUT REGISTERS:  (IF THERE ARE NO ENTRIES) UNCHANGED               57160019
*                     (IF THERE IS AT LEAST 1 ENTRY)                    57200019
*                     GR1RG DISPLACEMENT TO END OF FOUND ENTRY, OR ZERO 57240019
*                       IF ENTRY NOT FOUND                              57280019
*                     GR2RG = 5                                         57320019
*                     GR3RG POINTS TO LAST BYTE OF TRACK-LIST           57360019
*                     ICRG HAS CONTENTS OF TKLSTZFW                     57400019
*                                                                       57440019
*  RETURNS:  BR LINK2RG   CC = 0  NO ENTRY FOUND                        57480019
*                         CC = 2  ENTRY FOUND                           57520019
*                         CC = 1  THERE ARE NO ENTRIES                  57560019
*                                                                       57600019
SCNLSTEQ CLI   TKLSTZFW,21                                              57640019
         BCR   4,LINK2RG               NO ENTRIES, EXIT WITH CC = 1     57680019
         BAL   INTLNKRG,SCNINIT                                         57720019
SNLSTEQ1 CLC   0(3,GR1RG),0(CCWRG)     COMPARE ENTRY TRACK, GIVEN       57760019
         BE    SNLSTEQ2                ENTRY FOUND                      57800019
         BXLE  GR1RG,GR2RG,SNLSTEQ1    ADVANCE TO NEXT ENTRY            57840019
         SR    GR1RG,GR1RG             NO ENTRY FOUND:  GR1RG WILL      57880019
         BR    LINK2RG                 EQUAL ZERO ON EXIT, CC = 0.      57920019
SNLSTEQ2 AR    GR1RG,GR2RG             IF ENTRY FOUND, DISPLACEMENT TO  57960019
         SR    GR1RG,SRCHRG              END OF ENTRY,  CC = 2.         58000019
         BR    LINK2RG                 RETURN                           58040019
*                                                                       58080019
*  SCNINIT     INITIALIZES REGISTERS TO SCAN TRACK LIST                 58120019
*                                                                       58160019
*  BAL   INTLNKRG,SCNINIT                                               58200019
*                                                                       58240019
*  INPUT REGISTERS:  SRCHRG POINTS TO TRACK LIST                        58280019
*                                                                       58320019
*  OUTPUT REGISTERS:  GR1RG = TRACK LIST LOC + 16                       58360019
*                     GR2RG = 5                                         58400019
*                     GR3RG POINTS TO LAST BYTE OF TRACK LIST           58440019
*                     ICRG HAS CONTENTS OF TKLSTZFW                     58480019
*                                                                       58520019
SCNINIT  LA    GR2RG,5                 INCREMENT FOR SCAN               58560019
         IC    ICRG,TKLSTZFW                                            58600019
         LA    GR1RG,16(SRCHRG)        1' BYTE OF 1' ENTRY              58640019
         LA    GR3RG,0(ICRG,SRCHRG)                                     58680019
         BCTR  GR3RG,INTLNKRG                                           58720019
*                                                                       58760019
*                                                                       58800019
*                                                                       58840019
         USING CCWMSK,CCWRG                                             58880019
SKIPRQ   BAL   INTLNKRG,FSR       SKIP FORWARD ONE RECORD               58920019
         BALR  INTLNKRG,INTLNKRG                                        58960019
         BR    LINK1RG                 AND RETURN TO INTERPRETER        59000019
*                                                                       59040019
*********************************************************************** 59080019
*                                                                       59120019
GETRQ    LR    CCWRG,GR2RG        SAVE STORAGE REQUEST CONSTANT         59160019
         BAL LINK1RG,PROCNT       PICK UP ACTUAL COUNT OF RECORDS       59200019
         LNR   GR2RG,CCWRG        REQUEST BUFFER ALLOCATION             59240019
         LH    CCWRG,UDNRECFW     COMPUTE:  (MAX. REC. CNT. + 1)/2      59280019
         SRA   CCWRG,1                                                  59320019
         CR    SRCHRG,CCWRG            AND COMPARE WITH PROCESS COUNT   59360019
         BH    GETRQ0             TAKE THE SMALLER OF THE TWO           59400019
         LR    CCWRG,SRCHRG            PROCESS COUNT SMALLER            59440019
GETRQ0   SLA   CCWRG,2            FOUR CCW'S FOR EACH 'PAIR'            59480019
RDXKRQ   TM    STATUSFW,RECPEND   WILL OUTPUT RECORD CHAIN IF CHANGED.  59520019
         BO    SEQRQ0                  BRANCH IF YES                    59560019
         B     SEQRQ1                  GO COMPLETE REQUEST              59600019
INSRQ    IC    ICRG,AVAILNFW      PICK UP NUMBER OF AVAILABLE RECORDS   59640019
         LR    GR3RG,ICRG              AND CHECK AGAINST USER'S COUNT   59680019
         BAL   LINK1RG,PROCCNT         USE SMALLER OF TWO               59720019
         LA    CCWRG,0(SRCHRG,SRCHRG)       FOUR CCW'S PER INSERT       59760019
         AR    CCWRG,CCWRG                                              59800019
         B     SEQRQ                   GO COMPLETE REQUEST              59840019
REPRQ    BAL   LINK1RG,PROCNT     COMPUTE NUMBER OF RECORD REPLACES     59880019
         LA    CCWRG,0(SRCHRG,SRCHRG)  THREE CCW'S PER REPLACE          59920019
         AR    CCWRG,SRCHRG                                             59960019
*                                                                       60000019
*********************************************************************** 60040019
*                                                                       60080019
* SEQRQ - CONPLETE REQUESTS FOR GETKEYRQ, GETRQ, REPLRQ, AND INST1RQ.   60120019
*                                                                       60160019
SEQRQ    LA    GR2RG,MINXTND      REQUIRE MINIMIMUM EXTRA STORAGE       60200019
SEQRQ0   LA    CCWRG,15(CCWRG)    MAX 15 CCWS FOR REC. CHAIN AND CHECK  60240019
SEQRQ1   L     GR3RG,LSTRECFW     PICK UP TRACK ADDRESS                 60280019
         LA    SRCHRG,4(SRCHRG)   INSURE ENOUGH FOR MAX. OPERATION      60320019
         L     LINK1RG,EXRET2LK   SET UP RETURN                         60360019
         TM    AFPAR2FS,READKEY+READREC     CHECK FOR READKEY           60400019
         BCR   9,LINK1RG               NO, RETURN TO SCHEDULER          60440019
         LA    CCWRG,6(CCWRG)          YES, ADD ON SIX  CCW'S           60480019
         BR    LINK1RG                 AND RETURN                       60520019
*                                                                       60560019
*********************************************************************** 60600019
*                                                                       60640019
* PROCNT - COMPUTE ACTUAL COUNT OF TO BE PROCESSED FOR GET (USED FOR    60680019
*        REPLACE ALSO).                                                 60720019
* PROCCNT - COMPUTE ACTULE NUMBER OF RECORDS TO BE INSERTED.            60760019
*                                                                       60800019
*        BAL   LINK1RG,PROCNT                                           60840019
*                                                                       60880019
*        BAL   LINK1RG,PROCCNT                                          60920019
*                                                                       60960019
*        INPUT REGISTERS:  GR3RG = COUNT OF AVAILABLE RECORDS IF        61000019
*                                  PROCCNT ENTRY POINT.                 61040019
*                                                                       61080019
*        OUTPUT REGISTERS:  SRCHRG = COUNT OF RECORDS TO BE PROCESSED.  61120019
*                           GR0RG = DESTROYED.                          61160019
*                           GR1RG = DESTROYED.                          61200019
*                           GR2RG = USER'S REQUESTED COUNT.             61240019
*                           GR3RG = MAXIMUM COUNT FOR THIS TRACK (SEG.) 61280019
*                           INTLNKRG = DESTRYOYED.                      61320019
*                           ICRG = RELATIVE LOGICAL RECORD POSITION OF  61360019
*                                  FIRST RECORD IN BLOCK.               61400019
*                           LINK2RG = DESTROYED.                        61440019
*                                                                       61480019
PROCNT   BAL   INTLNKRG,FSR       PICK UP RECORD NUMBER OF NEXT RECORD  61520019
         BAL   LINK2RG,GDCOUNT    COUNT NUMBER OF REMAINING RECORDS     61560019
PROCCNT  BAL   INTLNKRG,COUNTREQ  COUNT USERS REQUEST                   61600019
         LR    SRCHRG,GR2RG       ASSUME USER'S REQUEST                 61640019
         CR    GR2RG,GR3RG        USER'S REQUEST : RECORD REMAINDER     61680019
         BCR   12,LINK1RG         EXIT ON CORRECT ASSUMPTION            61720019
         LR    SRCHRG,GR3RG       NOT ENOUGH, USE REMAINDER.            61760019
         BR    LINK1RG                 AND RETURN                       61800019
*                                                                       61840019
*********************************************************************** 61880019
*                                                                       61920019
INSEX    BAL   INTLNKRG,NXAVAIL1  LOCATE THE FIRST AVAILABLE RECORD     61960019
         BCTR  ICRG,0                  AREA                             62000019
         BAL   LINK1RG,SEQX       GENERATE INSERTS AND UPDATE CHAIN     62040019
         DC    Y(NXAVAIL0-EX)                                           62080019
         DC    Y(INSCW)                                                 62120019
REPEX    MVI   SRCHCOD4,WRITCKCW  SET UP WRITE CHECK REQUEST            62160019
         MVI   SRCHR4,X'FF'                                             62200019
* GETRQ - GET SINGLE OR MULTIPLE RECORDS REQUESTOR ROUTINE.             62240019
         BAL   LINK1RG,SEQX0      SET TO REPLACE NEXT SEQUENTIAL REC.   62280019
         DC    Y(FSRR-EX)              AND UPDATE SEGMENT POSITION      62320019
         DC    Y(REPRECW)                                               62360019
GETEX    BAL   LINK1RG,SEQX0      SET TO READ SEQUENTIAL RECORDS        62400019
         DC    Y(FSRR-EX)              AND UPDATE SEGMENT POSITION      62440019
         DC    Y(GETRECW)                                               62480019
*                                                                       62520019
*********************************************************************** 62560019
*                                                                       62600019
* SEQX - SETUP SEARCH ARGUMENT SKELETON FOR SEQUENTIAL DATA RECORD      62640019
*        PROCESSING AND MODIFY CONTROL INFORMATION TO REFLECT UPDATED   62680019
*        STATUS OF SEGMENT.  COUNTFS UPDATED FOR MULTIPLE OPERATIONS.   62720019
*                                                                       62760019
*        BAL   LINK1RG,SEQX                                             62800019
*        DC    Y(ROUT-EX)         ROUT = ROUTINE TO UPDATE RECORD CHAIN 62840019
*        DC    Y(CCWLIST)         CCWLIST = CP ELEMENT CODE.            62880019
*                                                                       62920019
*        INPUT REGISTERS:  GR3RG = ROUT WORK AND ARGUMENT REGISTER.     62960019
*                          CCWRG = ROUT WORK AND ARGUMENT REGISTER.     63000019
*                          SRCHRG = NEXT SEARCH ARGUMENT PTR. - 8.      63040019
*                          ICRG = ROUT WORK AND ARGUMENT REGISTER.      63080019
*                                                                       63120019
*        OUTPUT REGISTERS:  GR0RG = DESTROYED.                          63160019
*                           GR1RG = DESTROYED.                          63200019
*                           GR2RG = DESTROYED.                          63240019
*                           GR3RG = DESTROYED.                          63280019
*                           INTLNKRG = DESTROYED.                       63320019
*                           CCWRG = DESTROYED.                          63360019
*                           SRCHRG = LAST GENERATED SEARCH ARG PTR.     63400019
*                           ICRG = DESTROYED.                           63440019
*                           LINK2RG = 'ROUT-EX'                         63480019
*                                                                       63520019
SEQX0    IC    ICRG,LSTRECFW      PROCESS SEQUENTIAL RECORDS            63560019
SEQX     LH    LINK2RG,0(LINK1RG) PICK UP DISPLACEMENT OF SUBROUTINE    63600019
         LR    GR0RG,ICRG         SAVE INPUT ARGUMENT                   63640019
         BAL   INTLNKRG,COUNTREQ  PICK UP USER'S COUNT                  63680019
         BALR  INTLNKRG,INTLNKRG       AND COMPUTE LOC. OF FIRST REC.   63720019
         LR    ICRG,GR0RG         RESTORE INPUT ARGUMENT                63760019
         LH    GR0RG,2(LINK1RG)        AND PICK UP CP ELEMENT NUMBER    63800019
SEQX1    LA    SRCHRG,SRCHARG1    BUMP TO NEXT SEARCH ARGUMENT          63840019
         ST    GR1RG,SRCHARG4     SAVE BUFFER POINTER                   63880019
         AH    GR1RG,ULLRECFW          AND BUMP TO NEXT BUFFER          63920019
         ST GR0RG,FCOUNT4         SET UP CP ELEMENT CODE NUMBER         63960019
         BAL   INTLNKRG,0(LINK2RG,BASERG)   LOCATE RECORD AREA          64000019
         STC   ICRG,SRCHR4             AND SAVE FOR SORT AND SEARCH     64040019
         BALR  INTLNKRG,INTLNKRG       UPDATE SEGMENT POSITION          64080019
         BC   10,SEQX2            BRANCH IF POSITIONED AFTER LAST REC.  64120019
         BCT   GR2RG,SEQX1        BACK FOR NEXT IF COUNT NOT ZERO       64160019
         B     SEQX3                   COUNT SATISFIED                  64200019
SEQX2    BCTR  GR2RG,0            CHECK FOR USER COUNT JUST             64240019
         LTR   GR2RG,GR2RG             SATISFIED                        64280019
         BZ    SEQX3                   BRANCH IF YES                    64320019
         OI    AFPAR1FS,AFXCPTN        NO, SET FILE EXCEPTION           64360019
SEQX3    TM    AFPAR2FS,MULTIPLE  WAS THIS A MULTIPLE BUFFER OPERATION  64400019
         BZ    SEQX4                   BRANCH IF NOT                    64440019
         L     CCWRG,BUFFADSS     COMPUTE NEXT LOGICAL BUFFER NUMBER    64480019
         LA    CCWRG,0(CCWRG)          RELATIVE TO BEGINNING OF BUF.    64520019
         SR    GR1RG,CCWRG                                              64560019
         LH    CCWRG,ULLRECFW                                           64600019
         SR    GRERG,GRERG                                              64640019
         DR    GRERG,CCWRG                                              64680019
         STC   GRORG,COUNTFS           AND SAVE FOR NEXT READ OR WRITE  64720019
SEQX4    L     SRCHRG,SRCHRGFW    LOCATE BEGINNING OF SEARCH ARG LIST   64760019
RDXKEX   TM    STATUSFW,RECPEND   CHECK FOR RECORD CHAIN UPDATE PENDING 64800019
         BZ    SEQX5                   BRANCH IF NOT                    64840019
         MVI   SRCHCOD2,WRCHANCW  OUTPUT RECORD CHAIN CCW ELEMENT       64880019
         MVI   SRCHCOD4,WRITCKCW       WITH WRITE CHECKING              64920019
         MVI   SRCHR4,X'FF'                                             64960019
SEQX5    TM    AFPAR2FS,READKEY+READREC     CHECK FOR SPECIAL NEXT KEY  65000019
         BC    9,SEQX7                 BRANCH IF NOT                    65040019
         BAL   INTLNKRG,SEGPOS    IS THERE ANOTHER RECORD IN THE SEG?   65080019
         BC    2,SEQX6                 BRANCH IF NOT                    65120019
         L     GR1RG,NXTKEYFW     SET UP USER'S KEY FIELD POINTER       65160019
         ST    GR1RG,SRCHARG3          AS CP ARGUMENT                   65200019
         BAL   INTLNKRG,FSR       LOCATE NEXT RECORD                    65240019
         STC   ICRG,SRCHR3             SAVE RECORD NUMBER               65280019
         BALR  INTLNKRG,INTLNKRG       AND UPDATE SEGMENT POSITION      65320019
         MVI   SRCHCOD3,GETXKCW   ASSUME WRITE CHECKING BEING DONE      65360019
         CLI   SRCHCOD4,WRITCKCW       CHECK ASSUMPTION                 65400019
         BE    SEQX7                   BRANCH IF CORRECT                65440019
         MVI   SRCHCOD3,RDKEYCW        NO CHECK, SIMPLE KEY READ        65480019
         B     SEQX7                                                    65520019
SEQX6    OI    AFPAR1FS,AFXCPTN   FILE EXCEPTION SET IF NO NEXT KEY     65560019
SEQX7    NI    STATUSFW,X'FF'-RECPEND  RESET PENDING RECORD CHAIN UPDAT 65600019
         L     LINK1RG,EXRETLK    SORT ARGUMENTS                        65640019
         BALR  LINK1RG,LINK1RG         AND GENERATE CHANNEL PROGRAM     65680019
         BALR  LINK1RG,LINK1RG    SIMPLE PROGRAM                        65720019
         TM    AFPAR2FS,READREC    SHOULD BUFFER BE RELEASED?           65760019
         BCR   8,LINK2RG               YES.                             65800019
         BR    LINK1RG                 NO.                              65840019
*                                                                       65880019
**********************************************************************  65920019
*                                                                       65960019
* LOCNTRY - LOCATE ENTRY IN MASTER INDEX.  IT IS ASSUMED THAT THE       66000019
*        MASTER INDEX IS IN TEMPAREA.  AFPAR2FS IS EXAMINED TO          66040019
*        PRIVATE OR GLOBAL FILE REFERENCE.                              66080019
*                                                                       66120019
*        BAL   LINK2RG,LOCNTRY                                          66160019
*                                                                       66200019
*        INPUT REGISTERS:  NO SPECIAL ASSUMPTIONS.                      66240019
*                                                                       66280019
*        OUTPUT REGISTERS:  GR1RG = POINTER TO DOUBLE WORD ENTRY        66320019
*                                   IN MASTER INDEX.                    66360019
*                          ICRG = RELATIVE NUMBER OF FILE (GLOBAL OR    66400019
*                                 PRIVATE).                             66440019
*                                                                       66480019
LOCNTRY  IC    ICRG,GBLNUMFS      PICK UP GLOBAL FILE NUMBER            66520019
         LR    GR1RG,ICRG                                               66560019
         TM    AFPAR2FS,GLOBAL    CHECK FOR GLOBAL FILE                 66600019
         BO    LCNTRY                  BRANCH IF YES                    66640019
         LH    GR1RG,LSEQNOLS       NO,PRIVATE.  COMPUTE PRIVATE        66680019
         BCTR  GR1RG,0                 DISPLACEMENT FROM FIRST          66720019
         MH    GR1RG,PRVCNTKN          PRIVATE FILE                     66760019
         IC    ICRG,ACTNUMFS      PICK UP ACTIVE FILE NUMBER            66800019
         AR    GR1RG,ICRG              AND ADD IT IN                    66840019
LCNTRY   SLA   GR1RG,3            COMPUTE ACTUAL ADDRESS OF ENTRY       66880019
         LA    GR1RG,TMPAREA0(GR1RG)                                    66920019
         BR    LINK2RG                 RETURN                           66960019
*                                                                       67000019
*********************************************************************** 67040019
*                                                                       67080019
* PUTRACK - RELEASE TRACK FOR ALLOCATION.                               67120019
*                                                                       67160019
*        BAL   LINK2RG,PUTRACK                                          67200019
*                                                                       67240019
*        INPUT REGISTERS:  CYLERG = TRACK TO BE RELEASED (XACH).        67280019
*                                                                       67320019
*        OUTPUT REGISTERS:  CYLERG = DESTROYED.                         67360019
*                           CYLORG = DESTROYED.                         67400019
*                           INCRG = DESTROYED.                          67440019
*                                                                       67480019
PUTRACK  LA    CYLERG,0(CYLERG)   PUT TRACK ADDRESS IN STANDARD FORM    67520019
         SRDL    CYLERG,8         SEPARATE HEAD FROM CYLINDER & ACCESS  67560019
         SH    CYLERG,H256KN           ACTUAL CC                 A45668 67580026
         SH    CYLERG,MIDCYLFW    DELETE ACCESS, AND COMPUT REL.CYL.    67600019
         SLL   CYLERG,1                                                 67640019
         BP    DECR               BRANCH FOR CYL. ABOVE MEAN            67680019
         LCR   CYLERG,CYLERG      2*(M-C)=STRING NUMBER                 67720019
MULTI    MH    CYLERG,NUMHEADS    NUMBER OF BITS IN LOWER STRINGS       67760019
         SRL   CYLORG,24            PLUS HEAD NUMBER                    67800019
         AR    CYLORG,CYLERG        = RELATIVE BIT NUMBER               67840019
         SR    CYLERG,CYLERG                                            67880019
         D     CYLERG,F8KN        QUOTIENT IS BYTE DISP IN TAT          67920019
         A     CYLORG,TRACKSFW    ADDR OF BIT                           67960019
         IC    CYLERG,ALTAB2(CYLERG)                                    68000019
         EX    CYLERG,ALOIINST    SET BIT ON (AVAILABLE)                68040019
         C     CYLORG,NXTTRK      CHK IF NEWLY AVAILABLE TRK IS NOW     68080019
         BCR   11,LINK2RG           LEFT-MOST IN TAT. IF NOT, RETURN.   68120019
         ST    CYLORG,NXTTRK        IF SO, THIS IS NEW 'START SEARCH'   68160019
         BR    LINK2RG              ADDR.  RETURN.                      68200019
*                                                                       68240019
DECR     BCT   CYLERG,MULTI       STRING NUMBER = 2*(C-M)-1             68280019
ALOIINST OI    0(CYLORG),0                                              68320019
*********************************************************************** 68360019
*                                                                       68400019
* FSR - FORWARD SPACE ONE RECORD AND CHECK POSITION WITHIN SEGMENT.     68440019
* FSRR - SPACE TO THE NEXT RECORD AND CHECK POSITION WITHIN SEGMENT.    68480019
* SEGPOS - CHECK PRESENT POSITION WITHIN SEGMENT.                       68520019
* SEGPOSR - CHECK POSITION OF RECORD WITHIN SEGMENT.                    68560019
*        FILE MUST BE IN UPDATE MODE.                                   68600019
*                                                                       68640019
*        BAL   INTLNKRG,FSR                                             68680019
*                                                                       68720019
*        BAL   INTLNKRG,FSRR                                            68760019
*                                                                       68800019
*        BAL   INTLNKRG,SEGPOS                                          68840019
*                                                                       68880019
*        BAL   INTLNKRG,SEGPOSR                                         68920019
*                                                                       68960019
*        INPUT REGISTERS:  ENTRY POINTS FSR AND SEGPOS:  NO SPECIAL     69000019
*                                                        ASSUMPTIONS.   69040019
*                          ENTRY POINTS FSRR AND SEGPOSR:  ICRG = THE   69080019
*                                      RECORD NUMBER OF THE LAST RECORD 69120019
*                                      PROCESSED (NEED NOT BE THE SAME  69160019
*                                      AS LSTRECFW).                    69200019
*                                                                       69240019
*        OUTPUT REGISTERS :  ENTRY POINTS FSR AND FSRR:  ICRG = THE     69280019
*                                      RECORD NUMBER OF THE NEXT RECORD 69320019
*                                      IN THE SEGMENT.                  69360019
*                            ENTRY POINTS SEGPOS AND SEGPOSR:  ICRG =   69400019
*                                      RECORD NUMBER OF LAST RECORD     69440019
*                                      PROCESSED IF NOT POSITIONED      69480019
*                                      BEFORE FIRST RECORD IN SEGMENT;  69520019
*                                      OTHERWISE ICRG = 0.              69560019
*                            GR3RG = RECORD CHAIN POINTER TO RECORD     69600019
*                                    REPRESENTED BY ICRG.               69640019
*                           INTLNKRG = CONDITION CODE IN BITS 2 AND 3;  69680019
*                                      PROGRAM MASK IN BITS 4-7;        69720019
*                                      RETURN ADDRESS IN BITS 8-31 TO   69760019
*                                      ROUTINE TO UPDATE SEGMENT        69800019
*                                      POSITION (SEE BELOW).            69840019
*                                                                       69880019
*                                    BALR  INTLNKRG,INTLNKRG            69920019
*                                                                       69960019
*        CONDITION CODE:  00   POSITIONED BEFORE FIRST RECORD           70000019
*                         01   POSITIONED BETWEEN FIRST AND LAST        70040019
*                         10   POSITIONED AFTER LAST RECORD             70080019
*                         11   NEVER SET                                70120019
*                                                                       70160019
FSR      IC    ICRG,LSTRECFW      PICK UP REC. NUM. OF LAST REC. PROC.  70200019
FSRR     LTR   ICRG,ICRG          CHECK FOR BEFORE FIRST                70240019
         IC    ICRG,RCHANFW-2(ICRG)    ASSUME NOT - PICK UP NEXT REC.   70280019
         BC    7,SEGPOS0               BRANCH IF NOT BEFORE FIRST       70320019
         IC    ICRG,SEGR1FW            WRONG ASSUMPTION - PICK UP FIRST 70360019
         B     SEGPOS0                                                  70400019
SEGPOS   IC    ICRG,LSTRECFW      PICK UP LAST REC. PROCESSED REC. NUM. 70440019
SEGPOSR  LTR   ICRG,ICRG               AND CHECK FOR BEFORE FIRST       70480019
         BC    8,SEGPOS1               EXIT IF YES, CC = 00             70520019
SEGPOS0  LA    GR3RG,RCHANFW-2(ICRG)   LOCATE RECORD CHAIN ENTRY        70560019
         CLI   0(GR3RG),EOS            CHECK IT FOR END OF SEGMENT      70600019
*                                 CC = 01 IF NOT, CC = 10 IF END OF SEG 70640019
SEGPOS1  BALR  INTLNKRG,INTLNKRG  PROVIDE RETURN ADDRESS AND EXIT       70680019
*                                                                       70720019
* UPDATE POSITION WITHIN SEGMENT TO AFTER NEXT RECORD.                  70760019
*                                                                       70800019
*        BALR  INTLNKRG,INTLNKRG                                        70840019
*                                                                       70880019
*        INPUT REGISTERS:  ICRG = RECORD NUMBER OF NEXT RECORD.         70920019
*                                                                       70960019
*        OUTPUT REGISTERS:  NO CHANGE.                                  71000019
*                                                                       71040019
*        CONDITION CODE:  NO CHANGE.                                    71080019
*                                                                       71120019
         STC   ICRG,LSTRECFW                                            71160019
         BR    INTLNKRG                RETURN                           71200019
*                                                                       71240019
* COUNTREQ - COMPUTE THE NUMBER OF RECORDS REQUESTED BY THIS OPERATION. 71280019
*        SINGLE RECORD OPERATIONS = ONE RECORD, OTHERWISE COUNTFS IS    71320019
*        EXAMINED.                                                      71360019
*                                                                       71400019
*        BAL   INTLNKRG,COUNTREQ                                        71440019
*                                                                       71480019
*        INPUT REGISTERS - NO SPECIAL ASSUMPTIONS                       71520019
*                                                                       71560019
*        OUTPUT REGISTERS - ICRG = RELATIVE BLOCK POSITION OF FIRST     71600019
*                                  LOGICAL RECORD                       71640019
*                           GR2RG = NUMBER OF RECORDS REQUESTED         71680019
*                           INTLNKRG = RETURN ADD. TO COMPUTE ADDRESS   71720019
*                                   OF FIRST LOGICAL RECORD (SEE BELOW  71760019
*                                   FOR DETAILS).                       71800019
*                                                                       71840019
COUNTREQ LA    GR2RG,1       ASSUME ONE RECORD - SINGLE RECORD REQUEST  71880019
         SR    ICRG,ICRG          ASSUME LOGICAL RECORD NUMBER ZERO     71920019
         TM    AFPAR2FS,MULTIPLE  CHECK USER ARGUMENT                   71960019
         BZ    COUNTRQ1           RETURN IF SINGLE RECORD REQUEST       72000019
         IC    GR2RG,COUNTFS+1    PICK UP UPPER LIMIT                   72040019
         IC    ICRG,COUNTFS            AND SUBTRACT LOWER LIMIT         72080019
         SR    GR2RG,ICRG                                               72120019
COUNTRQ1 BALR  INTLNKRG,INTLNKRG  RETURN AND ALLOW REENTRY.             72160019
*                                                                       72200019
* RETURN TO COMPUTE ADDRESS OF FIRST LOCICAL RECORD.                    72240019
*                                                                       72280019
*        BALR  INTLNKRG,INTLNKRG                                        72320019
*                                                                       72360019
*        INPUT REGISTERS:  ICRG = RELATIVE BLOCK NUMBER OF FIRST        72400019
*                                 LOGICAL RECORD.                       72440019
*                                                                       72480019
*        OUTPUT REGISTERS:  GR1RG = ADDRESS OF 1ST LOG. REC.            72520019
*                                                                       72560019
         LR    GR1RG,ICRG         COMPUTE DISPLACEMENT WITHIN THE       72600019
         MH    GR1RG,ULLRECFW          BUFFER                           72640019
         AL    GR1RG,BUFFADSS     ADD ON ORIGIN OF BUFFER               72680019
         LA    GR1RG,8(GR1RG)                                           72720019
         BR    INTLNKRG                AND EXIT                         72760019
*                                                                       72800019
*********************************************************************** 72840019
*                                                                       72880019
* NXAVAIL1 - INITIALIZE DATA RECORD INSERT CHANNEL PROGRAM              72920019
* NXTAVAIL - PICK UP RECORD NUMBER OF NEXT AVAILABLE RECORD IF ANY.     72960019
* NXAVAIL0 - LOCATE NEXT AVAILABLE RECORD ON TRACK KNOWING THERE IS ONE 73000019
*                                                                       73040019
*        BAL   INTLNKRG,NXAVAIL1                                        73080019
*        BAL   INTLNKRG,NXTAVAIL                                        73120019
*        BAL   INTLNKRG,NXAVAIL0                                        73160019
*                                                                       73200019
*        INPUT REGISTERS:  NO SPECIAL ASSUMPTIONS FOR ENTRY POINTS      73240019
*                          NXAVAIL1 AND AND NXTAVAIL.                   73280019
*                          ICRG = RECORD NUMBER OF PREVIOUSLY ASSIGNED  73320019
*                                 FIRST AVAILABLE RECORD ON THIS TRACK. 73360019
*                                                                       73400019
*        OUTPUT REGISTERS:  ICRG = NEXT AVAILABLE RECORD (UNLESS THERE  73440019
*                                  ARE NONE IN WHICH CASE NXTAVAIL      73480019
*                                  ENTRY MUST HAVE BEEN USED).          73520019
*                                        ____                           73560019
*                           GR3RG = RECORD CHAIN POINTER TO NEXT        73600019
*                                   AVAILABLE RECORD (IF THERE IS ONE   73640019
*                                   OF COURSE).                         73680019
*                             CCWRG = RECORD CHAIN POINTER TO LAST REC. 73720019
*                                   PROCESSED (ONLY SET FOR NXAVAIL1    73760019
*                                   ENTRY POINT).  IF POSITIONED BEFORE 73800019
*                                   FIRST RECORD, LINK2RG POINTS TO     73840019
*                                   SEGR1FW).                           73880019
*                           INTLNKRG = RETURN POINT TO PROCESS A DATA   73920019
*                                     RECORD INSERT (SEE BELOW FOR      73960019
*                                     DETAILS).                         74000019
*                                                                       74040019
NXAVAIL1 IC    ICRG,LSTRECFW      PICK UP RECORD NUMBER OF LAST RECORD  74080019
         LTR   ICRG,ICRG               PROCESS IF IN THIS SEGMENT       74120019
         LA      CCWRG,SEGR1FW    ASSUME NOT                            74160019
         BZ    NXTAVAIL           BRANCH IF SO.    CCWRG = PREVIOUS     74200019
         LA      CCWRG,RCHANFW-2(ICRG) RECORD CHAIN ENTRY.              74240019
NXTAVAIL CLI   AVAILNFW,0         CHECK FOR AVAILABLE RECORDS           74280019
         BCR   8,INTLNKRG              EXIT IF NONE (NXTAVAIL ENTRY)    74320019
         LA    ICRG,1             INITIALIZE LOOP TO FIND FIRST REC.    74360019
NXAVAIL0 LA    ICRG,1(ICRG)       BUMP TO NEXT RECORD CHAIN ENTRY       74400019
         LA    GR3RG,RCHANFW-2(ICRG)   POINT TO ENTRY                   74440019
         CLI   0(GR3RG),0              IS RECORD AREA AVAILABLE?        74480019
         BC    7,NXAVAIL0              BRANCH BACK IF NOT               74520019
         BALR  INTLNKRG,INTLNKRG  YES, PROVIDE REENTRY FORREC. INSERT   74560019
*                                                                       74600019
*        ON RETURN TO THIS POINT, THE RECORD CHAIN WILL BE UPDATED      74640019
*        FOR A DATA RECORD INSERT AND THE COUNT OF AVAILABLE RECORDS    74680019
*        WILL BE DECREMENTED.  THE FILE WILL BE POSITIONED AFTER        74720019
*        THE INSERTED RECORD ON RETURN.                                 74760019
*                                                                       74800019
*        BALR  INTLNKRG,INTLNKRG                                        74840019
*                                                                       74880019
*        INPUT REGISTERS:  ICRG = RECORD NUMBER OF RECORD TO BE         74920019
*                                 INSERTED.                             74960019
*                          GR3RG = CHAIN RECORD POINTER TO RECORD TO    75000019
*                                  BE INSERTED.                         75040019
*                            CCWRG = CHAIN RECORD POINTER TO LAST REC.  75080019
*                                  PROCESSED OR SEGR1FW IF LAST         75120019
*                                  RECORD PROCESSED IS ON PREVIOUS      75160019
*                                  SEGMENT.                             75200019
*                                                                       75240019
*        OUTPUT REGISTERS:  ICRG = UPDATED COUNT OF AVAILABLE RECORDS   75280019
*                                  ON THIS TRACK.                       75320019
*                           GR3RG = DESTROYED.                          75360019
*                             CCWRG = REC. CHAIN POINTER TO INSERTED    75400019
*                                   RECORD (THE UPDATED LAST RECORD     75440019
*                                   PROCESSED).                         75480019
*                                                                       75520019
*        CONDITION CODE:  00   NO MORE RECORDS AVAILABLE ON THIS TRACK  75560019
*                         01   NEVER SET                                75600019
*                         10   MORE AVAILABLE RECORDS ON THIS TRACK     75640019
*                         11   NEVER SET                                75680019
*                                                                       75720019
         MVC   0(1,GR3RG),0(CCWRG)     PERFORM INSERT IN CHAIN          75760019
         STC   ICRG,0(CCWRG)           RECORD                           75800019
         LR      CCWRG,GR3RG      UPDATE LAST RECORD PROCESSED POINTER  75840019
         STC   ICRG,LSTRECFW      UPDATE FILE POSITION                  75880019
         SR    GR3RG,GR3RG             DECREMENT COUNT OF               75920019
         IC    GR3RG,AVAILNFW              AVAILABLE RECORDS            75960019
         BCTR  GR3RG,0                         BY ONE                   76000019
         STC   GR3RG,AVAILNFW                                           76040019
         LCR   GR3RG,GR3RG             SET CONDITION CODE               76080019
         BR    INTLNKRG                RETURN                           76120019
*                                                                       76160019
*********************************************************************** 76200019
*                                                                       76240019
*  GENDATA -            GENERATE SEGMENT DATA                           76280019
*                                                                       76320019
*  LOOPS THROUGH THE RECORD CHAIN TO DETERMINE X#RR (X, NUMBER OF       76360019
*  AVAILABLE RECORD AREAS, FIRST RECORD, LAST RECORD) FOR THE SEGMENT.  76400019
*  ON RE-ENTRY, AN ARGUMENT LIST ENTRY IS SET UP.                       76440019
*                                                                       76480019
*  BALR  LINK2RG,GENDATA                                                76520019
*  INPUT:      SEGR1FW CONTAINS REC# OF 1' REC OF SEGMENT               76560019
*              THE RECORD CHAIN IS AT RCHANFW                           76600019
*  INPUT REGISTERS:  NO SPECIAL ASSUMPTIONS                             76640019
*                                                                       76680019
*  BALR  LINK2RG,GDCOUNT   TO FIND REMAINING COUNT & EOS                76720019
*  INPUT REGISTERS:  ICRG CONTAINS PRESENT REC#                         76760019
*                                                                       76800019
*  BALR  LINK2RG,GDCOUNT2                                               76840019
*  INPUT REGISTERS:  ICRG CONAINS 1' OR PRESENT REC#                    76880019
*                    GR1RG POINTS TO 1' BYTE OF RECORD CHAIN -2         76920019
*                                                                       76960019
*  OUTPUT REGISTERS:  INTLNKRG = X'80'                                  77000019
*                     GR1RG CONTAINS SEGMENT X#RR                       77040019
*                     GR2RG CONTAINS REC# OF EOS RECORD                 77080019
*                     GR3RG CONTAINS # OF RECS IN SEGMENT               77120019
*                     ICRG CONTAINS RECORD CHAIN EOS ENTRY              77160019
*                                                                       77200019
*  RETURN:  BALR  LINK2RG,LINK2RG                                       77240019
*                                                                       77280019
GENDATA  IC    ICRG,SEGR1FW            FIRST REC IN SEGMENT             77320019
         STC   ICRG,WKDATAFW+2                                          77360019
GDCOUNT  LA    GR1RG,RCHANFW-2         POINTER TO (MYTHICAL) REC0 ENTRY 77400019
GDCOUNT2 LA    GR3RG,1                 COUNTER                          77440019
         LA    INTLNKRG,EOS                                             77480019
         LR    GR2RG,ICRG              ASSUME SINGLE RECORD SEGMENT     77520019
         B     GD2                                                      77560019
GD1      LA    GR3RG,1(GR3RG)          BUMP COUNTER                     77600019
         LR    GR2RG,ICRG              SAVE PREVIOUS REC#               77640019
GD2      IC    ICRG,0(ICRG,GR1RG)      PICK UP NEXT RECORD IN CHAIN     77680019
         CR    ICRG,INTLNKRG           IS IT LAST?                      77720019
         BL    GD1                     IF NOT, LOOP                     77760019
         STC   GR2RG,WKDATAFW+3        LAST RECORD IN SEGMENT           77800019
         STC   GR3RG,WKDATAFW+1        NUMBER OF RECORDS IN SEGMENT     77840019
         L     GR1RG,WKDATAFW          RETURN ARGUMENT                  77880019
         BALR  LINK2RG,LINK2RG         RETURN                           77920019
*                                                                       77960019
*                                                                       78000019
*  RETURN:  BR  LINK2RG                                                 78040019
*                                                                       78080019
         ST    GR1RG,INSDTRAN          SET UP INSERT SEGMENT DATA       78120019
         LA    GR1RG,INSDTRAN+4        SET UP ADDRESS FOR READ OF       78160019
         ST    GR1RG,SRCHARG4               KEY FIELD                   78200019
         STC   GR2RG,SRCHR4                 AND RECORD NUMBER           78240019
ONE      EQU   1                                                A45668  78250026
ZERO     EQU   0                                                A45668  78260026
         BR    LINK2RG                 RETURN                           78280019
*                                                                       78320019
*                                                                       78360019
*                                                                       78680019
ALTAB2   DS    0CL8               BIT NUMBER IS INDEX VALUE             78720019
         DC    B'10000000',B'01000000',B'00100000',B'00010000'          78760019
         DC    B'00001000',B'00000100',B'00000010',B'00000001'          78800019
PATCH    DC    A(PATCHAD)                                               78800726
VND      DC    V(NDXUGN2)                                       A42692  78801426
OLDINSEX EQU   *                       1' ARGUMENT IS WRITE-CHECK DUMMY 78802126
         MVI   SRCHCOD2,RDRTCW0        2' READS CHAIN RECORD INTO       78802826
*                                        TMPAREA0, NO CC.               78803526
         MVI   SRCHCOD3,INSCW          3' INSERTS RECORD                78804226
         BAL   INTLNKRG,COUNTREQ       ARGUMENT IS LOGICAL BUFFER ADDR  78804926
         BALR  INTLNKRG,INTLNKRG                                        78805626
         ST    GR1RG,SRCHARG3                                           78806326
         IC    ICRG,LSTRECFW           AVAILABLE RECORD AREA            78807026
         STC   ICRG,SRCHR3                                              78807726
         MVI   SRCHCOD4,WRITCKCW       J' IS WRITE-CHECK.               78808426
         BALR  LINK1RG,LINK2RG         TO NO-SORT GENERATOR DRIVER.     78809126
*                                                                       78809826
*              AT CHANNEL END THE CHANNEL PROGRAM IS MODIFIED, THE      78810526
*              CHAIN RECORD IS UPDATED, AND EXCP RETURN IS TAKEN.       78811226
*                                                                       78811926
         MVI   CCWCMCD3,WRITEKD        CHANGE OP CODE TO WRITE RECORD   78812626
         MVI   CCWFLGS4,CC               CHAIN, CC TO REST OF PGM       78813326
*                                                                       78814026
         LA    GR1RG,TMPAREA0-2        ' REC 0 ENTRY' RECORD CHAIN.     78814726
         OI    SCHRRFW,EOS             FIRST REC OF NXT SEGMENT, WITH   78815426
         IC    GR0RG,SCHRRFW             EOS BIT SET IS REC CHAIN EOS   78816126
         IC    ICRG,LSTRECFW             CONTENT.                       78816826
         STC   GR0RG,0(ICRG,GR1RG)                                      78817526
*                                                                       78818226
         STC   ICRG,TMPAREA0+L'RCHANFW+4    R(OLD) = R(NEW) = EOS POS   78818926
         STC   ICRG,TMPAREA0+L'RCHANFW+5                                78819626
         SR    GR0RG,GR0RG             ZERO OUT TRACK CHAIN SAVE-AREA.  78820326
         ST    GR0RG,TMPAREA0+L'RCHANFW                                 78821026
*                                                                       78821726
         LA    GR3RG,TMPAREA0+L'RCHANFW     SET UP TRACK CHAIN EOS      78822426
         BAL   INTLNKRG,COMPUAD        RETURNS TRK CHN ENTRY ADDR IN    78823126
         MVC   0(3,GR1RG),SCHTRKFW+1     GR1RG                          78823826
*                                                                       78824526
         BALR  LINK1RG,LINK2RG         EXCP AGAIN                       78825226
*                                                                       78825926
         BALR  LINK1RG,LINK1RG         ENDIO                            78826626
*                                                                       78827326
         MVC   RCHANFW,TMPAREA0        MOVE RECORD CHAIN TO FILE BOX.   78828026
         LR    LINK1RG,LINK2RG         RETURN TO RELEASE BUFFER         78828726
         B     SHEX012A                AFTER COUNTING AVAILABLE RECORDS 78829426
PATCHAD  DS    20F                                                      78830126
         DROP  BASERG                                                   78830826
         DROP  KBXRG                                                    78831526
         DROP  APW2RG                                                   78832226
         DROP  FBXRG                                                    78832926
         DROP  AFWRG                                                    78833626
         DROP  CCWRG                                                    78834326
         DROP  SRCHRG                                                   78835026
*                                                                       78840019
*                                                                       78880019
* CCW LIST GENERATOR MODULE LINKAGE TABLE                               78920019
*                                                                       78960019
         GENCCWDS TYPE=DSECT                                            79000019
         CCWMSK 7                                                       79040019
         CNTSRCH 5                                                      79080019
*                                                                       79120019
**********************************************************************  79160019
*                                                                       79200019
* OLNDXCCW - DESCRIPTION OF CHANNEL PROGRAM TO DETERMINE CHARACTERISTIC 79240019
*        OF OLD INDEX RECORD.                                           79280019
*                                                                       79320019
OLNDXCCW DSECT                                                          79360019
         DS    D                  NOT REFERABLE                         79400019
         CCW   SRCHIDEQ,ARG1,CC,5      POSITION TO RECORD ONE THE FIRST 79440019
         CCW   TIC,*-8,0,0             TIME OROUND                      79480019
OLDNDX0  CCW   READKD,FNAMEFW,CC+SILI,16    READ 16 BYTES OF CHECKPOINT 79520019
OLDNDX1  CCW   READC,ARG4,CC,8         READ NEXT COUNT/ID FIELD         79560019
OLDNDX1A CCW   READKD,FNAMEFW,CC+SILI,16    READ 16 BYTES OF CHECKPOINT 79600019
         CCW   SRCHIDHI,ARG3,CC,5      MAY BE LAST IF R0, R1, OR R2     79640019
OLDNDX2  CCW   TIC,OLDNDX4,0,0         BRANCH IF ANY OF THESE THREE     79680019
OLDNDX3  CCW   TIC,OLDNDX1,0,0         LOOP BACK FOR NEXT ID IF NOT     79720019
OLDNDX4  CCW  SRCHIDEQ,ARG2,CC,5      IF R0 OR R1(TWO RECS. ONLY),      79760019
OLDNDX5  CCW   TIC,OLDNDX7,0,0              HAVE READ LAST COUNT/ID     79800019
         CCW   SRCHIDEQ,ARG3,CC,5      NO GOOD, START SECOND TIME       79840019
         CCW   TIC,*-8,0,0                  AROUND, THIS TIME STARTING  79880019
OLDNDX6  CCW   TIC,OLDNDX1,0,0              WITH RECORD NUMBER TWO.     79920019
OLDNDX7  CCW   READD,FNAMEFW+16,CC+SILI,16  READ REST OF CHECKPOINT     79960019
         CCW   SRCHIDEQ,ARG4,CC,5      POSITION TO LAST RECORD ON TRACK 80000019
         CCW   TIC,*-8,0,0                                              80040019
         CCW   ERASE,OLDNDX8,CD,8      DETERMINE TRACK BALANCE          80080019
OLDNDX8  CCW   ERASE,0,SILI,X'FFF8'                                     80120019
*                                                                       80160019
**********************************************************************  80200019
*                                                                       80240019
* ARGLIST - GENERAL ARGUMENT LIST FOR SETTING UP CHANNEL PROGRAMS.      80280019
*                                                                       80320019
ARGLIST  DSECT                                                          80360019
         DS    D                  NOT REFERABLE                         80400019
ARG1     DS    D                                                        80440019
ARG2     DS    D                                                        80480019
ARG3     DS    D                                                        80520019
ARG4     DS    D                                                        80560019
*                                                                       80600019
*********************************************************************** 80640019
*                                                                       80680019
* MASTLIST - GENERAL CCW SKELETON FOR CHANNEL PROGRAMS FOR THE          80720019
*        MASTER INDEX.                                                  80760019
*                                                                       80800019
MASTLIST DSECT                                                          80840019
         DS    D                  NOT REFERABLE                         80880019
         CCW   SRCHIDEQ,ARG1,CC,5      LOCATE MASTER INDEX RECORD       80920019
         CCW   TIC,*-8,0,0                  (RECORD 2)                  80960019
MASTCCW1 CCW   READD,TMPAREA0,0,L'MASLGHFW  READ INDEX RECORD           81000019
         CCW   SRCHIDEQ,ARG1,CC,5      BACK TO RECORD                   81040019
         CCW   TIC,*-8,0,0             FOR WRITE CHECK                  81080019
         CCW   READD,TMPAREA0,SKIP,L'MASLGHFW    WRITE CHECK            81120019
*                                                                       81160019
         EXCPFWDS TYPE=DSECT                                            81200019
         AFCTLDS                                                        81240019
*                                                                       81280019
         RAFKNBX  TYPE=DSECT                                            81320019
*                                                                       81360019
         END                                                            81400019
