GET      TITLE 'IHKGET - SUBMIT INPUT RECORD PROCESSOR'                 00100019
IHKGET   CSECT                                                          00120020
*C077000,359000,667000                                           A36818 00140020
*D076000                                                         A36818 00160020
* C523300                                                       A55918  00180002
*********************************************************************** 00200019
*                                                                     * 00300019
*STATUS-                                                              * 00400019
*   CHANGE LEVEL 0                                                    * 00500019
*                                                                     * 00600019
*FUNCTION/OPERATION-                                                  * 00700019
*   THE FUNCTION OF IHKGET IS TO POSITION TO THE DATA SETS FROM WHICH * 00800019
*   THE INPUT JOB STREAM WILL BE BUILT FOR THE O. S. READER/INTEPRETER* 00900019
*                                                                     * 01000019
*   ON THE FIRST ENTRY TO IHKGET FOR THE SUBMIT, IHKGET CLEARS ITS    * 01100019
*   INTERNAL SWITCHES AND COUNTERS, AND INITIALIZES ITS PPT POINTERS  * 01200019
*   TO THE FIRST DSNAME. IF THIS IS NOT THE FIRST ENTRY, IHKGET SETS  * 01300019
*   ITS PPT POINTERS TO THE NEXT DSNAME IN THE PPT. THE INTERNAL      * 01400019
*   SUBROUTINE GETDSN GETS THE DATA SET NAME FROM THE PPT, CHECKS THE * 01500019
*   SYNTAX OF IT, AND IF VALID, THE FILE IS POSITIONED TO READ THE    * 01600019
*   FIRST BLOCK OF RECORDS. IF AN ERROR IS FOUND IN THE DATA SET NAME,* 01700019
*   AN EXIT IS MADE TO THE SUBMIT PROCESSOR WITH AN END-OF-DATA       * 01800019
*   CONDITION AND ERROR MESSAGE TO BE SENT INDICATED.                 * 01900019
*                                                                     * 02000019
*   A SWITCH IS SET INDICATING WHETHER THE FILE IS AN ACTIVE FILE OR  * 02100019
*   A DATA SET FROM A USER LIBRARY. THE COUNT OF DSNAMES PROCESSED IS * 02200019
*   INCREASED BY ONE AND EITHER AN RPOINT OR RFIND IS ISSUED. IF THE  * 02300019
*   FILE IS NOT A DSLIST FILE CONTROL IS RETURNED TO IHKSUB.          * 02400019
*                                                                     * 02500019
*   IF THE DSLIST FILE IS A USER LIBRARY, THE ENTIRE FILE IS READ INTO* 02600019
*   A SECOND PRIVATE ACTIVE FILE. ALL SUBSEQUENT CALLS TO THIS MODULE * 02700019
*   CAUSES PROCESSING DATA SET NAMES FROM THE PRIVATE FILE INSTEAD OF * 02800019
*   THE PPT. WHEN END-OF-FILE IS REACHED, CONTROL IS GIVEN TO THE     * 02900019
*   GETDSN SUBROUTINE TO INSPECT THE NEXT DATA SET NAME IN THE PPT.   * 03000019
*   IF THE DSLIST FILE IS THE USERS ACTIVE FILE, A SWITCH IS SET      * 03100019
*   INDICATING THAT CONDITION. NESTED DSLIST FILES ARE NOT PERMITTED. * 03200019
*                                                                     * 03300019
*   IF THE SUBMIT IS ABORTED OR AFTER ALL DSNAMES HAVE BEEN PROCESSED,* 03400019
*   THE SECOND PRIVATE FILE FOR DSLIST FILES (IF IT EXISTS) IS        * 03500019
*   RELEASED AND THE OLD ACTIVE FILE FOR THE USER IS RECREATED. IF THE* 03600019
*   READER/INTERPRETER DATA SET WAS ALLOCATED BUT NO JOBS COLLECTED,  * 03700019
*   IT IS SCRATCHED. CONTROL IS RETURN TO IHKSUB.                     * 03800019
*                                                                     * 03900019
*ENTRY POINTS-                                                        * 04000019
*        IHKGET IS THE ONLY ENTRY POINT.                              * 04100019
*                                                                     * 04200019
*INPUT-                                                               * 04300019
*   REGISTER ONE MUST CONTAIN THE ADDRESS OF A FOUR WORD PARAMETER    * 04400019
*   LIST. THE FIRST WORD IS NOT USED; THE SECOND POINTS TO THE SUBMIT * 04500019
*   WORK AREA; THE THIRD WORD POINTS TO THE TUB; AND THE FOURTH WORD  * 04600019
*   IS THE ADDRESS OF THE AVT.                                        * 04700019
*                                                                     * 04800019
*OUTPUT-                                                              * 04900019
*   THE NEXT FILE IS POSITIONED AT THE BEGINING.                      * 05000019
*                                                                     * 05100019
*EXTERNAL ROUTINES-                                                   * 05200019
*        IHKAFI- TO MANIPULATE ACTIVE FILES.                          * 05300019
*        IHKBPM- TO READ DATA SET FROM A USER LIBRARY.                * 05400019
*        IHKUTM- GET DDNAME FOR USER LIBRARY AND GET ON LIBRARY I/O   * 05500019
*                QUEUE.                                               * 05600019
*                                                                     * 05700019
*EXITS-NORMAL-                                                        * 05800019
*        RETURN TO IHKSUB WITH A COMPLETION CODE OF 0 IN REGISTER 15  * 05900019
*        EXCEPT IF END-OF-INPUT IS ENCOUNTERED, A RETURN CODE OF 4 IS * 06000019
*        USED.                                                        * 06100019
*                                                                     * 06200019
*EXITS-ERROR-                                                         * 06300019
*        RETURN TO IHKSUB WITH COMPLETION CODE OF 4 IN REGISTER 15 AND* 06400019
*        THE ERROR MESSAGE NUMBER IN THE TUBPARM1 FIELD. A COMPLETION * 06500019
*        CODE OF 8 FOR GETMAIN FAILURE; 12 FOR ACTIVE AREA I/O ERROR; * 06600019
*        AND 16 FOR LIBRARY I/O ERROR.                                * 06700019
*                                                                     * 06800019
*TABLES/WORK AREAS-                                                   * 06900019
*   WORK AREA IS PROVIDED BY IHKSUB.                                  * 07000019
*                                                                     * 07100019
*ATTRIBUTES-                                                          * 07200019
*   NONRESIDENT AND REENTRANT ( USED SERIALLY BY IHKSUB).             * 07300019
*                                                                     * 07400019
*********************************************************************** 07500019
         SAVE  (14,12),,GET71067   SAVE REGISTERS                A36818 07600020
         LR    BAS,GO              GET BASE FOR IHKGET                  07800019
         USING IHKGET,BAS                                               07900019
         USING WORKSECT,SWT                                             08000019
         LM    SWT,AVT,0(PAR)      PICK UP CODE,TUB, AND AVT            08100019
         LA    WOK,SAVE                                                 08200019
         ST    WOK,ATE(SAV)                                             08300019
         ST    SAV,FOUR(WOK)                                            08400019
         LR    SAV,WOK                                                  08500019
         SPACE                                                          08600019
         USING TUBDSECT,TUB                                             08700019
         USING AVTDSECT,AVT                                             08800019
         USING PPTDSECT,PPT                                             08900019
         SPACE 2                                                        09000019
         L     PPT,TUBPPTAD        ADDRESS OF PPT                       09100019
         L     KBX,IHKYYKBX        ADDRESS OF KON BOX                   09200019
         USING RAFKNBX,KBX                                              09300019
         SPACE 2                                                        09400019
         TS    PASSONE             FIRST ENTRY FOR SUBMIT               09500019
         BNZ   GETDSN              NO GET NEXT BLOCK                    09600019
         LA    WOK,ELEVEN          MAX NUMBER OF DSNAMES                09700019
         STH   WOK,COUNT           SET MAX DSNAMES                      09800019
GETDSN0  LA    DSL,PPTPARS         LENGTH OF PARAMETER POINTER          09900019
         LA    DSN,PPTPARS+1       POINTER TO FIRST DSNAME              10000019
         B     GETDSN1             GET FIRST DSNAME                     10100019
GETDSN   EQU   *                                                        10200019
         SPACE 3                                                        10300019
*                   POSITION TO NEXT DATA SET NAME TO READ INPUT        10400019
         SPACE 2                                                        10500019
         TM    SUBSWT,FORCEOD      FORCE END OF INPUT ENTRY             10600019
         BO    EODRTRN             YES CLEAN UP BEFORE LEAVING          10700019
         NI    SUBSWT,ALL-ACTSWT   TURN OFF ACTIVE SWITCH               10800019
         TM    SUBSWT,DSLSWT       PROCESS DS LIST DSNAME               10900019
         BO    LDSLRG              LOAD REGISTER FOR DSLIST POSITION    11000019
         SPACE                                                          11100019
         LM    PPT,DSN,SAVPPT      POINTERS TO NEXT DSNAME PARM         11200019
         SPACE                                                          11300019
GETDSN1  TM    0(DSL),ALL          ALL DSNAMES PROCESSED                11400019
         BNO   GETDSN2             NO PROCESS THIS NAME                 11500019
         SPACE                                                          11600019
         L     PPT,ZIP(PPT)        ADDRESS OF NEXT PPT                  11700019
         LTR   PPT,PPT             ALL DSNAMES PROCESSED                11800019
         BZ    EODRTRN             YES RETURN TO SUB WITH EOD           11900019
         B     GETDSN0             POSITION FOR NEXT NAME               12000019
         SPACE                                                          12100019
GETDSN2  MVI   CURNTLNG,TEN        SET DEFAULT LENGTH TO TEN            12200019
         MVC   CURNTDSN(8),BLANKS  BLANK OUT CURRENT DSNAME             12300019
         MVC   CURNTDSN+8(22),CURNTDSN                                  12400019
         LA    WOK,ALL-PAREN       MASK TO FIND LENGTH                  12500019
         SR    LNG,LNG                                                  12600019
         IC    LNG,0(DSL)          LENGTH OF DSNAME                     12700019
         NR    LNG,WOK             CLEAR STATUS BITS                    12800019
         BCTR  LNG,ZIP             SUBTRACT ONE FOR MOVE                12900019
         TM    0(DSL),PAREN        PARENS ARROUND MEMBER NAME           13000019
         BNZ   INVPRND             YES SEND INVALID OPERAND MESSAGE     13100019
         CH    LNG,MAXLNG          MEMBER NAME EXCEED 8 CHARACTERS      13200019
         BH    INVPRND             YES SEND INVALID OPERAND MESSAGE     13300019
         MVC   TUBUSRNM(8),TUBUSRID SET DEFAULT USER LIBRARY            13400019
         MVC   TUBPMFNM(8),BLANKS  BLANK OUT DSNAME                     13500019
         MVC   KEY(3),BLANKS       SET PROTECT KEY DEFAULT              13600019
         EX    LNG,MVCPMFNM        MOVE DSNAME                          13700019
         EX    LNG,MVCRTDSN        SAVE DSNAME FOR MESSAGES             13800019
         SPACE                                                          13900019
         LA    DSL,2(DSL,LNG)      BUMP TO NEXT LENGTH                  14000019
         LA    DSN,1(DSL)          BUMP TO NEXT PARM                    14100019
         TM    0(DSL),ALL          LAST DSNAME                          14200019
         BO    GETEND1             YES PROCESS IT                       14300019
         TM    0(DSL),PAREN        LAST PARAMETER                       14400019
         BZ    GETEND1             YES PROCESS IT                       14500019
         IC    LNG,0(DSL)          PICK UP LENGTH                       14600019
         NR    LNG,WOK             CLEAR TWO HIGH ORDER BITS OF LENGTH  14700019
         MVC   TUBUSRNM(8),BLANKS  CLEAR USERID                         14800019
         BCTR  LNG,ZIP             SUBTRACT ONE FOR MOVE                14900019
         CH    LNG,MAXLNG          ID LESS THAN NINE CHARACTERS         15000019
         BH    INVOPRND            NO SEND ERROR MESSAGE                15100019
         SPACE                                                          15200019
         EX    LNG,MVCUSRNM        MOVE USERID                          15300019
         EX    LNG,MVCRTUSR        SAVE USER ID FOR MESSAGES            15400019
         LA    GO,SVNTEEN          BUMP MESSAGE PARMS FOR USER ID       15500019
         STH   GO,LNGPARM          SAVE LENGTH                          15600019
         SPACE                                                          15700019
         TM    0(DSL),PAREN        DOES KEY FOLLOW                      15800019
         BNM   GETEND              NO                                   15900019
         SPACE                                                          16000019
         LA    GO,2(DSL,LNG)       GET LENGTH OF KEY FIELD              16100019
         TM    0(GO),PAREN         IS IT IN PAREN AND LAST OPERAND      16200019
         BNO   INVOPRND            NO SEND INVALID OPERAND MESSAGE      16300019
         SR    GO,GO               CLEAR FOR LENGTH                     16400019
         IC    GO,2(DSL,LNG)       GET LENGTH OF KEY                    16500019
         NR    GO,WOK              CLEAR PAREN FLAGS                    16600019
         CH    GO,MAXKEY           KEY LENGTH ACCEPTABLE                16700019
         BH    INVOPRND            NO SEND ERROR MESSAGE                16800019
         LA    WOK,TWNTONE         BUMP MESSAGE PARMS FOR KEY           16900019
         STH   WOK,LNGPARM         SAVE LENGTH                          17000019
         BCTR  GO,ZIP              SUBTRACT ONE FOR MOVE                17100019
         LA    BAC,2(DSN,LNG)      POINT TO AREA TO MOVE                17200019
         EX    GO,MVCKEY           SAVE KEY                             17300019
         EX    GO,MVCRTKEY         SAVE KEY FOR DSNAME MESSAGE          17400019
         SPACE                                                          17500019
         LA    DSN,2(GO,DSN)       BUMP PAST KEY                        17600019
         LA    DSL,2(GO,DSL)                                            17700019
GETEND   LA    DSL,2(DSL,LNG)      BUMP PAST USER ID                    17800019
         LA    DSN,1(DSL)                                               17900019
GETEND1  LH    WOK,COUNT           COUNT OF JOBS                        18000019
         BCT   WOK,GETDSN3                                              18100019
         SPACE 2                                                        18200019
MAXOPRND LH    LNG,M34           SET MESSAGE FOR MAX DSNAMES EXCEEDED   18300019
         B     MSGPROS             BUILD MESSAGE AND EXIT               18400019
         SPACE 3                                                        18500019
*                   ERROR MESSAGE MAX DSNAMES EXCEEDED                  18600019
         SPACE 2                                                        18700019
GETDSN3  STH   WOK,COUNT           SAVE NEW COUNT                       18800019
         SPACE                                                          18900019
GETDSN4  STM   PPT,DSN,SAVPPT      SAVE PPT POSITION                    19000019
         SPACE 2                                                        19100019
FINDDSN  EQU   *                                                        19200019
         CLC   TUBPMFNM(2),ACTIVE  IS THIS THE ACTIVE FILE              19300019
         BE    FINDACT             YES POSITION TO BEGINING OF FILE     19400019
         SPACE 2                                                        19500019
         MVC   TUBGBLKY(8),TUBUSRNM SET USER FILE NAME FOR UTM          19600019
         ST    TUB,UTMPARM         SUPPLY TUB ADDRESS TO IHKUTM         19700019
         LA    PAR,UTMCODE         ADDRESS OF CODE FOR IHKUTM           19800019
         ST    PAR,UTMPARM+4       PUT IN PARM LIST                     19900019
         MVI   UTMCODE,EOMSG       REQUEST DDNAME AND ENQUEUE ON LIB    20000019
         LA    PAR,UTMPARM         UTM PARM LIST                        20100019
         L     GO,IHKYYUTM         ADDRESS OF IHKUTM                    20200019
         BALR  BAC,GO                                                   20300019
         SPACE                                                          20400019
         STM   SWT,AVT,TUBPARM3    RESTORE TUBPARMS TO ORIGINAL VALUE   20500019
         B     *+4(GO)             CHECK RETURN CODE                    20600019
         B     FINDMEM             O. K.                                20700019
         B     NOUSER              USER ID NOT FOUND BY UTM             20800019
         B     GETFAIL                                                  20900019
         B     GETFAIL1            EXIT IF I/O ERROR IN ACTIVE AREA     21000019
         B     NODDNAME                                                 21100019
         B     FINDMEM             O. K.                                21200019
         B     LIBINOP             LIBRARY INOPERATIVE                  21300019
         SPACE 2                                                        21400019
FINDMEM  LA    PAR,TUBPTR(SAV)     POINTER TO TUB ADDRESS               21500019
         OI    WRTSWT,LIBOPEN      INDICATE LIBRARY NOW OPEN            21600019
         RFIND I                                                        21700019
         B     *+4(GO)             CHECK RETURN CODE                    21800019
         B     FOUND               RFIND SUCCESSFUL                     21900019
         B     NOTFOUND            MEMBER NOT FOUND                     22000019
         B     GETFAIL1            GETMAIN FAILED                       22100019
         B     ERRCLOSE            I/O ERROR ON LIBRARY                 22200019
         SPACE                                                          22300019
FOUND    LA    DIR,BPBLDLST+4      ADDRESS OF DIRECTORY ENTRY           22400019
         USING DIRDSECT,DIR                                             22500019
         CLI   DIRUILEN,DIRLNG     IS DATA SET A CRJE DATA SET          22600019
         BNE   READLIB             NOT CRJE DATA SET - ASSUME DATA      22700019
         LH    GO,DIRREAD          NUMBER OF TIMES READ                 22800019
         LA    GO,1(GO)            BUMP BY ONE                          22900019
         STH   GO,DIRREAD          UPDATE FOR STOW OF DIRECTORY ENTRY   23000019
         TM    DIRATTRL,DIRADLST   IS FILE TYPE DSLIST                  23100019
         BO    DLIST               YES                                  23200019
         CLC   DIRKEY(3),KEY       GO KEYS MATCH                        23300019
         BNE   CKUSERS             NO SEE IF IT IS SUBMITORS FILE       23400019
         SPACE 2                                                        23500019
READLIB  SR    GO,GO               SET RETURN CODE                      23600019
         XC    TUBPARM1(4),TUBPARM1 CLEAR MESSAGE NUMBER                23700019
         MVC   TUBPARM1(2),RTRNCODE SET EXCESSIVE COMMA MSG IF EXIST    23800019
         STH   GO,RTRNCODE         RESET RETURN CODE FIELD FOR SUBMIT   23900019
         SPACE                                                          24000019
RETURN   L     SAV,FOUR(SAV)                                            24100019
         RETURN (14,12),,RC=(15)                                        24200019
         SPACE 3                                                        24300019
FINDACT  LA    PAR,TUBPTR(SAV)     POSITION TO BEGINING OF FILE         24400019
         TM    TUBFLG2,TUBEDIT     IS THERE AN ACTIVE AREA              24500019
         BZ    NOTFOUND            NO ACTIVE AREA                       24600019
         RPOINT B,NR,KEY=FIRST                                          24700019
         SPACE                                                          24800019
         CH    GO,RC4              CHECK RETURN FROM I/O                24900019
         BH    GETFAIL1            EXIT ON I/O ERROR OR OUT OF SPACE    25000019
         BE    GETDSN              ON EOD GET NEXT DSNAME               25100019
         OI    SUBSWT,ACTSWT       FLAG AS READING ACTIVE FILE          25200019
         L     DIR,TUBDIRAD        FILE ATTRIBUTES FOR ACTIVE AREA      25300019
         TM    DIRATTRL,DIRADLST   IS ACTIVE FILE DSLIST                25400019
         BZ    READLIB             READ BLOCK OF RECORDS                25500019
         OI    WRTSWT,ACTDSLST     DSLIST FROM ACTIVE AREA              25600019
         XC    CURNTLIN(8),CURNTLIN CLEAR LINE NUMBER-KEY               25700019
         LA    GO,LDSLRG1          YES SET UP TO PROCESS DSLIST         25800019
         B     DSLIST00            CHECK FOR NESTED DSLIST              25900019
         SPACE 2                                                        26000019
ERRCLOSE LA    BUF,RC16            SET RETURN CODE TO 16                26100019
         B     RTRN2               EXIT TO IHKSUB                       26200019
         SPACE 2                                                        26300019
LIBINOP  LH    LNG,M70             LIBRARY INOPERATIVE MESSAGE          26400019
         B     MSGPROS             SET MESSAGE AND RETURN               26500019
         SPACE 2                                                        26600019
NOTFOUND LH    LNG,M38             DATA SET NOT FOUND MESSAGE           26700019
         B     MSGPROS             BUILD MESSAGE TO RETURNED TO IHKSUB  26800019
         SPACE 2                                                        26900019
CKUSERS  CLC   TUBUSRID(8),TUBUSRNM IS FILE SEBMITTORS                  27000019
         BE    READLIB             YES ACCEPT IT                        27100019
*                   ERROR MSG DSNAME DOES NOT EXITS   MESSAGE 338       27200019
         LH    LNG,M69             INVALID KEY MESSAGE                  27300019
         B     MSGPROS             BUILD MESSAGE TO RETURNED TO IHKSUB  27400019
         SPACE 2                                                        27500019
LDSLRG   EQU   *                                                        27600019
         LA    PAR,TUBPTR(SAV)     TUB POINTER FOR I/O                  27700019
         TM    WRTSWT,ACTDSLST     DSLIST FROM ACTIVE AREA              27800019
         BO    LDSLRG1             YES GET FIRST NAME                   27900019
         TM    TUBFLG2,TUBEDIT     USER ACTIVE AREA PRESENT             28000019
         BZ    LDSLRG1             NO CREATE NOT NEEDED                 28100019
         CREATE O,ACTNUM=2                                              28200019
         SPACE 2                                                        28300019
LDSLRG1  EQU   *                                                        28400019
         LA    PAR,TUBPTR(SAV)     TUB POINTER FOR I/O                  28500019
         MVC   TUBNXKEY(8),CURNTLIN MOVE KEY TO TUB                     28600019
         TM    CURNTLIN+7,ALL      FIRST NAME                           28700019
         BNZ   LDSLRG2             NO GET NEXT NAME                     28800019
         SPACE 2                                                        28900019
         RPOINT A,R                                                     29000019
         B     LDSLRG3                                                  29100019
         SPACE 2                                                        29200019
LDSLRG2  EQU   *                                                        29300019
         RPOINT A,NR                                                    29400019
         RGET  R,S,A                                                    29500019
LDSLRG3  EQU   *                                                        29600019
         CH    GO,RC4              CHECK RETURN FROM I/O                29700019
         BH    GETFAIL1            I/O ERROR OR GETMAIN FAILURE         29800019
         BE    LDSLEOD             END OF DATA                          29900019
         TM    WRTSWT,ACTDSLST     DSLIST FROM ACTIVE AREA              30000019
         BO    DSLINSPT            YES CHECK OPERANDS                   30100019
         TM    TUBFLG2,TUBEDIT     ACTIVE FILE 1 EXIST                  30200019
         BZ    DSLINSPT            NO BREAK OUT DSNAME                  30300019
         CREATE O                                                       30400019
         SPACE 2                                                        30500019
DSLINSPT EQU   *                                                        30600019
         SPACE 2                                                        30700019
         L     BUF,TUBRAFBF        POINTER TO DSLIST STATEMENT          30800019
         MVC   CURNTLIN(8),8(BUF)  SAVE LINE SEQ. NUMBER FOR MESSAGE    30900019
         LA    LNG,THIRTY          BUMP MESSAGE LENGTH FOR LINE NO.     31000019
         STH   LNG,LNGPARM         SAVE NEW LENGTH                      31100019
         LA    BUF,15(BUF)         BUMP PAST CONTROL INFO. AND KEY OF   31200019
*                                  RECORD                               31300019
         LA    LNG,STLNG           MSXIMUM LENGTH OF STATEMENT PLUS ONE 31400019
*                                  FOR SEARCH LOOP                      31500019
         TM    WRTSWT,LINENUM      LINE NUMBERS PRESENT                 31600019
         BO    SETDEFLT            YES ONLY SCAN 72 BYTES               31700019
         LA    LNG,ATE(LNG)        BUMP TO SCAN 80 BYTES                31800019
         SPACE                                                          31900019
SETDEFLT MVC   TUBPMFNM(8),BLANKS  CLEAR FILE NAME                      32000019
         MVC   TUBUSRNM(8),TUBUSRID SET DEFAULT USER ID TO USER LOGGED  32100019
*                                  ON                                   32200019
         MVC   KEY(3),BLANKS       SET DEFAULT KEY                      32300019
         SPACE 2                                                        32400019
OPLOOP   LA    BUF,1(BUF)          BUMP TO INSPECT NEXT BYTE            32500019
         BCT   LNG,OPRNCHCK        INSPECT FOR BLANK                    32600019
         SPACE 2                                                        32700019
OPEND    L     PAR,TUBRAFBF        POINTER TO BUFFER                    32800019
         LM    ZIP,PAR,0(PAR)      LENGTH AND ADDRESS FOR FREEMAIN      32900019
         SPACE                                                          33000019
         FREEMAIN R,LV=(0),A=(1)  FREE BUFFER                           33100019
         SPACE                                                          33200019
         TM    PASSONE,BADOP       INVALID OPERAND FOUND                33300019
         BNO   INVOPRND            YES BUILD ERROR MESSAGE AND EXIT     33400019
         TM    PASSONE,LPARF       UNBALANCED PARENTHESES FOUND         33500019
         BZ    BADPAREN            YES BUILD MESSAGE AND EXIT           33600019
         TM    PASSONE,DSNAME      WAS DSNAME FOUND                     33700019
         BZ    FINDDSN             YES PROCESS DSNAME                   33800019
         B     INVOPRND            NO- BUILD ERROR MESSAGE ANE EXIT     33900019
         SPACE 2                                                        34000019
OPRNCHCK CLI   0(BUF),BLANK        IS BYTE A BLANK                      34100019
         BE    OPLOOP              YES GET NEXT BYTE                    34200019
         TM    PASSONE,DSNAME      ALREADY LOCATED MEMBER NAME          34300019
         BZ    USRCK               YES  CHECK FOR USERID                34400019
         LR    DSN,BUF             SAVE BEGINING OF MEMBER NAME         34500019
         SPACE 2                                                        34600019
NAMELOOP OI    PASSONE,DSEXCMMA    SET LAST BYTE NOT COMMA              34700019
         BCT   LNG,NAMECK          SEARCH FOR END OF NAME               34800019
         SPACE                                                          34900019
NAMEDONE LR    WOK,BUF             END OF NAME FOUND                    35000019
         SR    WOK,DSN             FIND LENGTH OF NAME                  35100019
         BCTR  WOK,ZIP             SUBTRACT ONE FOR MOVE                35200019
         CH    WOK,MAXLNG          DOES NAME EXCEED MAXIMUM LENGTH      35300019
         BH    BADOPRND            YES  BUILD MESSAGE AND EXIT          35400019
         SPACE                                                          35500019
         EX    WOK,MVCPMFNM        MOVE NAME TO TUB                     35600019
         SPACE                                                          35700019
         NI    PASSONE,ALL-DSNAME  FLAG DSNAME AS FOUND                 35800019
         B     OPLOOP              LOOK FOR USER ID              A36818 35900020
         SPACE 2                                                        36000019
NAMECK   LA    BUF,1(BUF)          BUMP TO NEXT BYTE                    36100019
         CLI   0(BUF),BLANK        IS IT BLANK                          36200019
         BE    NAMEDONE            YES  NOW AT END OF MEMBER NAME       36300019
         CLI   0(BUF),LPAREN       IS TI A LEFT PARENTHESIS             36400019
         BE    SETPAR1             YES FLAG IT                   A44656 36500021
         CLI   0(BUF),COMMA        IS IT A COMMA                        36600019
         BNE   NAMELOOP            NO CHECK NEXT BYTE                   36700019
         BAL   GO,EXCMMA           CHECK FOR EXCESSIVE COMMAS           36800019
         B     NAMEDONE            MOVE NAME (IF VALID) TO TUB          36900019
         SPACE 2                                                        37000019
BADOPRND NI    PASSONE,ALL-BADOP   SET INVALID OPERAND FOUND SWITCH     37100019
         B     OPEND               GO TO END PROCESSING                 37200019
         SPACE 2                                                        37300019
USRCK    TM    PASSONE,LPARF       LEFT PAREN ALREADY FOUND             37400019
         BZ    USRLOOP             YES  SCAN USER ID                    37500019
         CLI   0(BUF),LPAREN       CHECK FOR LEFT PARENTHESIS           37600019
         BE    SETPAREN            YES FLAG IT                          37700019
         CLI   0(BUF),COMMA        CHECK FOR COMMA                      37800019
         BNE   BADOPRND            SET ERROR CONDITION                  37900019
         BAL   GO,EXCMMA           CHECK FOR EXCESSIVE COMMAS           38000019
         B     OPLOOP              YES INSPECT NEXT BYTE                38100019
         SPACE 2                                                        38200019
SETPAREN NI    PASSONE,ALL-LPARF   INDICATE LEFT PAREN FOUND            38300019
         OI    PASSONE,DSEXCMMA    SET LAST BYTE NOT COMMA              38400019
         B     OPLOOP              INSPECT NEXT BYTE                    38500019
         SPACE 2                                                        38520021
SETPAR1  NI    PASSONE,ALL-LPARF   INDICATE LEFT PAREN FOUND     A44656 38540021
         B     NAMEDONE            END OF MEMBER NAME            A44656 38560021
         SPACE 2                                                        38600019
USRLOOP  TM    PASSONE,DSUID       USER ID ALREADY PROCESSED            38700019
         BZ    INSKEY              YES CHECK KEY                        38800019
         TM    PASSONE,USRST       IS THIS FIRST CHARACTER OF USER ID   38900019
         BZ    USRCKOPR            NO                                   39000019
         NI    PASSONE,ALL-USRST   SET FIRST CHARACTER FOUND            39100019
         LR    DSN,BUF             SAVE ADDRESS OF FIRST CHARACTER      39200019
         LR    WOK,BUF             SAVE ADDRESS OF LAST BYTE            39300019
         SPACE                                                          39400019
USRCKOPR CLI   0(BUF),COMMA        CHECK FOR COMMA                      39500019
         BE    ENDUSR2             YES END OF USER ID                   39600019
         CLI   0(BUF),RPAREN       CHECK FOR RIGHT PARENTHESIS          39700019
         BE    ENDUSR1             YES                                  39800019
         LR    BAC,BUF             SAVE BEGINING OF KEY                 39900019
         LA    WOK,1(WOK)          BUMP END OF ID POINTER               40000019
         CR    WOK,BUF             IS THIS FIRST BYTE OF KEY            40100019
         BL    ENDUSR              YES INITIALIZE USER ID               40200019
         B     OPLOOP              INSPECT NEXT BYTE                    40300019
         SPACE 2                                                        40400019
ENDUSR2  BAL   GO,EXCMMA           CHECK FOR EXCESSIVE COMMAS           40500019
         B     ENDUSR              INITIALIZE USER ID                   40600019
         SPACE                                                          40700019
ENDUSR1  OI    PASSONE,LPARF       SET FLAG- PARENS ARE BALANCED        40800019
         OI    PASSONE,DSEXCMMA    SET LAST BYTE NOT COMMA              40900019
         SPACE                                                          41000019
ENDUSR   SR    WOK,DSN             FIND LENGTH OF USER ID               41100019
         BNH   BADOPRND            IF ZERO, ID DID NOT EXIST            41200019
         BCTR  WOK,ZIP             GET LENGTH FOR MOVE                  41300019
         CH    WOK,MAXLNG          OVER EIGHT CHARACTERS LONG           41400019
         BH    BADOPRND            YES                                  41500019
         MVC   TUBUSRNM(8),BLANKS  BLANK OUT USER ID FOR MOVE           41600019
         SPACE                                                          41700019
         EX    WOK,MVCUSRNM        MOVE USER ID TO TUB                  41800019
         SPACE                                                          41900019
         NI    PASSONE,ALL-DSUID   FLAG USERID AS FOUND                 42000019
         B     OPLOOP                                                   42100019
         SPACE 2                                                        42200019
INSKEY   CLI   0(BUF),RPAREN       IS BYTE A RIGHT PARENTHESIS          42300019
         BE    SETKEY1             YES  SAVE KEY                        42400019
         CLI   0(BUF),COMMA        IS IF A COMMA                        42500019
         BE    SETKEY2             YES END OF KEY                       42600019
         LR    WOK,BUF             SAVE ADDRESS OF THIS BYTE            42700019
         B     OPLOOP              NO GET NEXT BYTE                     42800019
         SPACE 2                                                        42900019
SETKEY2  BAL   GO,EXCMMA           CHECK FOR EXCESSIVE COMMAS           43000019
         B     SETKEY              MOVE KEY FOR PROCESSING              43100019
         SPACE                                                          43200019
SETKEY1  OI    PASSONE,LPARF       PARENS NOW BALANCED                  43300019
         SPACE                                                          43400019
SETKEY   SR    WOK,BAC             GET LENGTH OF KEY MINUS ONE          43500019
         BM    BADOPRND            BAD KEY                              43600019
         CH    WOK,MAXKEY          LENGTH OF KEY EXCEED MAXIMUM         43700019
         BH    BADOPRND            YES SET FOR ERROR                    43800019
         SPACE                                                          43900019
         EX    WOK,MVCKEY          MOVE KEY                             44000019
         SPACE                                                          44100019
         B     OPLOOP              CHECK FOR ANY MORE NON-BLANKS        44200019
         SPACE 3                                                        44300019
EXCMMA   TM    PASSONE,DSEXCMMA    LAST BYTE COMMA                      44400019
         BNZ   EXCMMA1             NO FLAG THIS AS COMMA                44500019
         MVC   RTRNCODE(2),M72     SET UP FOR EXCESSIVE COMMAS MESSAGE  44600019
EXCMMA1  NI    PASSONE,ALL-DSEXCMMA SET BYTE AS COMMA                   44700019
         BR    GO                  RETURN TO CALLER                     44800019
         SPACE 2                                                        44900019
LDSLEOD  EQU   *                                                        45000019
         NI    SUBSWT,ALL-DSLSWT   EXIT FROM DSLIST MODE                45100019
         TM    WRTSWT,ACTDSLST     DSLIST FROM ACTIVE AREA              45200019
         BZ    DSLRELSE            NO RELEASE ACTIVE FILE TWO           45300019
         NI    WRTSWT,ALL-ACTDSLST TURN OFF DSLIST IN ACT. SWITCH       45400019
         B     GETDSN              GET NEXT NAME                        45500019
         SPACE 2                                                        45600019
DSLRELSE LA    PAR,TUBPTR(SAV)     TUB POINTER FOR I/O                  45700019
         RELEASE A                                                      45800019
         LTR   GO,GO               CHECK RETURN FROM I/O                45900019
         BNZ   GETFAIL1            EXIT ON I/O ERROR                    46000019
         TM    TUBFLG2,TUBEDIT     ACTIVE FILE 1 EXIST                  46100019
         BZ    GETDSN              NO GET NEXT DSNAME                   46200019
         CREATE O                                                       46300019
         B     GETDSN              PROCESS NEXT DSNAME                  46400019
         SPACE 2                                                        46500019
DLIST    EQU   *                                                        46600019
         LA    GO,DSLIST01         SET TO READ DSLIST FILE              46700019
DSLIST00 TM    SUBSWT,DSLSWT       ALREADY IN DSLIST MODE               46800019
         BO    DSLNEST             YES SEND ERROR MESSAGE               46900019
         NI    WRTSWT,ALL-LINENUM  SET TO NO LINE NUMBERS IN RECORD     47000019
         TM    DIRATTRO,DIROLNO    LINE NUMBERS IN RECORDS              47100019
         BNO   DLIST0              NO CONTINUE PROCESSING               47200019
         OI    WRTSWT,LINENUM      LINE NUMBERS PRESENT                 47300019
DLIST0   OI    SUBSWT,DSLSWT       SET DSLIST MODE                      47400019
         BR    GO                  PROCESS ACTIVE FILE OR READ LIBRARY  47500019
DSLIST01 LA    PAR,TUBPTR(SAV)     ADDRESS OF TUB FOR I/O               47600019
         SPACE 2                                                        47700019
DSLIST1  CREATE IS,ACTNUM=2                                             47800019
         CH    GO,RC4              CHECK RETURN FROM I/O                47900019
         BE    DSLNOSPC            OUT OF SPACE IN ACTIVE AREA          48000019
         BH    GETFAIL1            EXIT ON I/O ERROR OR GETMAIN FAIL    48100019
         RPOINT B,NR,KEY=FIRST                                          48200019
         CH    GO,RC4              CHECK RETURN FROM I/O                48300019
         BH    GETFAIL1            I/O ERROR OR GETMAIN FAILURE         48400019
         SPACE 3                                                        48500019
DSLREAD  RREAD                                                          48600019
         B     *+4(GO)             CHECK RETURN CODE                    48700019
         B     DSLREAD1            GOOD READ                            48800019
         B     DSLEOD              END OF DATA                          48900019
         B     GETFAIL1            GETMAIN FAILED                       49000019
         B     ERRCLOSE            I/O ERROR ON LIBRARY                 49100019
         SPACE 2                                                        49200019
DSLREAD1 MVC   TUBRAFBF(4),SFBUFF1 MOVE BUFFER ADDRESS TO TUB           49300019
         INSERT M,A                                                     49400019
         CH    GO,RC4              CHECK RETURN FROM I/O                49500019
         BH    GETFAIL1            I/O ERROR OR GETMAIN FAILURE         49600019
         BE    DSLNOSPC            OUT OF SPACE IN ACTIVE AREA          49700019
         B     DSLREAD                                                  49800019
         SPACE 2                                                        49900019
DSLEOD   EQU   *                                                        50000019
         XC    CURNTLIN(8),CURNTLIN CLEAR LINE NUMBER-KEY               50100019
         LA    PAR,TUBPTR(SAV)     TUB POINTER FOR I/O                  50200019
         ENDUP                                                          50300019
         RCLOSE                                                         50400019
         NI    WRTSWT,ALL-LIBOPEN  INDICATE LIBRARY NOT OPEN            50500019
         B     LDSLRG1             PROCESS FIRST DS LIST ENTRY          50600019
         SPACE 2                                                        50700019
DSLNOSPC LH    LNG,M00                                                  50800019
         B     MSGPROS             BUILD MESSAGE AND EXIT               50900019
         SPACE 2                                                        51000019
DSLNEST  LH    LNG,M10             NESTED MESSAGE                       51100019
         B     MSGPROS             BUILD MESSAGE AND EXIT               51200019
         SPACE 2                                                        51300019
EODRTRN  EQU   *                                                        51400019
         XC    TUBPARM1(4),TUBPARM1                                     51500019
RTRN1    LA   BUF,FOUR             SET EOD RETURN TO IHKSUB             51600019
RTRN2    TM    SUBSWT,DSLSWT       NEED TO RELEASE DSLIST FILE          51700019
         BZ    RTRN3               NO                                   51800019
RELACT2  LA    PAR,TUBPTR(SAV)     ADDESS OF TUB                        51900019
         TM    WRTSWT,ACTDSLST     DSLIST FROM ACTIVE AREA              52000019
         BO    RTRN3               YES DON'T RELEASE FILE               52100019
         CREATE O,ACTNUM=2                                              52200019
         RELEASE A                                                      52300019
         TM    TUBFLG2,TUBEDIT                                  A55918  52330002
         BZ    RTRN3               NO, NO ACT FILE1 CREATED THEN A45671 52360021
         CREATE O                                                       52400019
RTRN3    TM    WRTSWT,LIBOPEN      LIBRARY OPEN                         52500019
         BZ    RTRN4               NO DO NOT CLOSE IT                   52600019
         LA    PAR,TUBPTR(SAV)     PARM LIST FOR LIB I/O                52700019
         RCLOSE NOSTOW             CLOSE DCB                            52800019
         NI    WRTSWT,ALL-LIBOPEN  INDICATE LIBRARY NOT OPEN            52900019
RTRN4    TM    SUBSWT,RIDS         WAS DATA SET ALLOCATED               53000019
         BZ    RETURN1             NO GET OUT                           53100019
         TM    SUBSWT,FORCEOD      ENDUP ENTRY                          53200019
         BZ    RETURN1             NO EXIT                              53300019
         LA    WOK,SUBDCB          ADDRESS OF DCB                       53400019
         TM    WRTSWT,RJCWRT       ANY JOBS COLLECTED                   53500019
         BO    RTRN5               YES DON'T SCRATCH R/I DATA SET       53600019
         SPACE 2                                                        53700019
         L     PAR,TUBUFFAD        USE ESER BUFFER FOR SCRATCH LIST     53800019
         LA    PAR,0(PAR)          CLEAR HIGH ORDER BYTE                53900019
         MVC   44(5,PAR),DEVTYPE   MOVE DEVICE COUNT AND 23??           54000019
         USING IHADCB,WOK                                               54100019
         IC   WOK,DCBDEVT          DEVICE TYPE FROM DCB                 54200019
         DROP  WOK                                                      54300019
         STC  WOK,49(PAR)          2311 OR 2314 FOR DEVICE TYPE         54400019
         NI    49(PAR),X'0F'       ONLY USE FOUR LOW BITS               54500019
         MVI   10(PAR),BLANK                                            54600019
         MVC   11(33,PAR),10(PAR)  CLEAR BUFFER FOR DSNAME              54700019
         L    WOK,TUBIRLSA         ADDRESS OF START READER AREA         54800019
         MVC   0(19,PAR),27(WOK)   MOVE DATA SET NAME                   54900019
         USING RJCTSECT,WOK                                             55000019
         LA    WOK,RJCTAD          GET BASE OF RJCT                     55100019
         MVC   50(6,PAR),RJCTVOL   MOVE VOLUME SERIAL                   55200019
         DROP  WOK                                                      55300019
         LA   WOK,9(PAR)           BUMP TO BEGINNING OF JOBNAME-1       55400019
CMCK     LA   WOK,1(WOK)           BUMP TO NEXT CHARACTER               55500019
         CLI  0(WOK),COMMA         IS IT A COMMA                        55600019
         BNE   CMCK                NO INSPECT NEXT                      55700019
         MVC  0(8,WOK),30(PAR)     INSURE BLANKS FOLLOW NAME            55800019
         SPACE 2                                                        55900019
         TS    TUBIRLSA            SET FLAG TO SCRATCH R/I DATA SET     56200019
RETURN1  LR    GO,BUF              SET RETURN CODE                      56500019
         B     RETURN              EXIT BACK TO IHKSUB                  56600019
         SPACE 5                                                        56700019
         SPACE 2                                                        56800019
RTRN5    LA   ZIP,NOTETTR          GET TTR OF LAST DD DUMMY WRITTEN     56900019
POINTTTR POINT (7),(0)             POINT TO RECORD PAST DD DUMMY        57000019
         USING IHADCB,WOK                                               57100019
         SPACE 2                                                        57110019
*              ISSUE STAND-ALONE SEEK TO GET PROPER TRACK BALANCE       57120019
*              SO THAT CLOSE WILL WRITE END OF FILE AT THE RECORD       57130019
*              ON WHICH THE POINT WAS ISSUED.                           57140019
         SPACE                                                          57150019
         LR    PAR,WOK             ADDRESS OF DCB FOR SEEK              57160019
         SVC   25                                                       57170019
         SPACE 2                                                        57180019
         OI    DCBOFLGS,ONEWRT     ALLOW CLOSE TO UPDATE DSCB AND       57200019
*                                  WRITE EOF AFTER LAST COMPLETE JOB    57300019
         L     WOK,DCBIOBA         GET ADDRESS OF IOB                   57320019
         OI    0(WOK),LIBOPEN      INDICATE IN IOB THAT LAST OPERATION  57340019
*                                  WAS A WRITE                          57360019
         DROP  WOK                                                      57400019
         B     RETURN1             EXIT                                 57500019
         SPACE 2                                                        57600019
GETFAIL  LA    GO,ATE              SET GETMAIN FAILURE RETURN CODE      57700019
GETFAIL1 XC    TUBPARM1(4),TUBPARM1 INDICATE NO MESSAGES                57800019
         LR    BUF,GO              SAVE RETURN CODE                     57900019
         B     RTRN2                                                    58000019
          SPACE 2                                                       58100019
NODDNAME LH    LNG,M75             DATA SET NOT FOUND MESSAGE           58200019
         B     MSGPROS             BUILD MESSAGE AND EXIT               58300019
          SPACE 2                                                       58400019
BADPAREN LH    LNG,M13             UNBALANCED PARENS MESSAGE            58500019
         B     MSGPROS                                                  58600019
         SPACE 2                                                        58700019
NOUSER   LH    LNG,M36             DSNAME NOT FOUND MESSAGE             58800019
         B     MSGPROS             BUILD MESSAGE AND EXIT               58900019
         SPACE 2                                                        59000019
INVPRND  CH    LNG,LNGPARM         OPERAND GREATER THAN TEN BYTES       59100019
         BNH   INVPRND1            NO MOVE NAME FOR MESSAGE             59200019
         LA    LNG,TEN             SET LENGTH TO TEN                    59300019
         SPACE                                                          59400019
INVPRND1 EX    LNG,MVCRTDSN        MOVE DSNAME FOR MESSAGE              59500019
         SPACE 2                                                        59600019
INVOPRND LH    LNG,M02             INVALID OPERAND MESSAGE              59700019
          SPACE 2                                                       59800019
MSGPROS  STH   LNG,TUBPARM1        SAVE MESSAGE NUMBER FOR IHKSUB       59900019
         B     RTRN1               EXIT TO IHKSUB                       60000019
         SPACE 3                                                        60100019
*                   EXECUTED INSTRUCTIONS                               60200019
         SPACE 2                                                        60300019
MVCPMFNM MVC   TUBPMFNM(0),0(DSN)  MOVE DSNAME TO TUB                   60400019
MVCUSRNM MVC   TUBUSRNM(0),0(DSN)  MOVE USER ID                         60500019
MVCKEY   MVC   KEY(0),0(BAC)       MOVE KEY                             60600019
MVCRTDSN MVC   CURNTDSN(0),0(DSN)  MOVE DSNAME TO MESSAGE LIST          60700019
MVCRTUSR MVC   CURNTUSR(0),0(DSN)  MOVE USERID TO MESSAGE LIST          60800019
MVCRTKEY MVC   CURNTKEY(0),0(BAC)  MOVE KEY TO MESSAGE LIST             60900019
         SPACE 3                                                        61000019
ZIP      EQU   0                                                        61100019
PAR      EQU   1                                                        61200019
BUF      EQU   2                                                        61300019
LNG      EQU   3                                                        61400019
PPT      EQU   4                                                        61500019
DSL      EQU   5                                                        61600019
DSN      EQU   6                                                        61700019
DIR      EQU   6                                                        61800019
WOK      EQU   7                                                        61900019
KBX      EQU   8                                                        62000019
SWT      EQU   9                                                        62100019
TUB      EQU   10                                                       62200019
AVT      EQU   11                                                       62300019
BAS      EQU   12                                                       62400019
SAV      EQU   13                                                       62500019
BAC      EQU   14                                                       62600019
GO       EQU   15                                                       62700019
FOUR     EQU   4                                                        62800019
ATE      EQU   8                                                        62900019
TEN      EQU   10                                                       63000019
ELEVEN   EQU   11                                                       63100019
SVNTEEN  EQU   17                                                       63200019
TWNTONE  EQU   21                                                       63300019
THIRTY   EQU   30                                                       63400019
LPAREN   EQU   C'('                                                     63500019
RPAREN   EQU   C')'                                                     63600019
PAREN    EQU   X'C0'                                                    63700019
RC12     EQU   12                                                       63800019
RC16     EQU   16                                                       63900019
FORCEOD  EQU   X'80'                                                    64000019
ALL      EQU   X'FF'                                                    64100019
STLNG    EQU   73                  LENGTH OF DSLIST STATEMENT PLUS ONE  64200019
DSNAME   EQU   1                   SET TO 0 IF VALID DSNAME FOUND       64300019
DSUID    EQU   2                   SET TO 0 IF VALID USER ID FOUND      64400019
DSEXCMMA EQU   4                   SET TO 0 WHEN LAST BYTE WAS COMMA    64500019
BADOP    EQU   8                   SET TO 0 WHEN INVALID OPERAND FOUND  64600019
LPARF    EQU   16                  SET TO 0 WHEN UNBALANCED PARENTHESES 64700019
*                                  EXIST                                64800019
USRST    EQU   32                  SET TO 0 WHEN POSITIONED TO USER ID  64900019
RC4      DC    H'4'                                                     65000019
BLANKS   DC    CL8' '                                                   65100019
ACTIVE   DC    C'* '                                                    65200019
DIRLNG   EQU   14                                                       65300019
MAXLNG   DC    H'7'                                                     65400019
MAXKEY   DC    H'3'                                                     65500019
H88      DC    H'88'                                                    65600019
TUBPTR   EQU   60                                                       65700019
M00      DC    C'00'                                                    65800019
M02      DC    C'02'                                                    65900019
M10      DC    C'10'                                                    66000019
M13      DC    H'13'                                                    66100019
M34      DC   C'34'                                                     66200019
M36      DC    C'36'                                                    66300019
M38      DC    C'38'                                                    66400019
M69      DC    C'69'               MESSAGE NUMBER FOR INVALID KEY       66500019
M70      DC    C'70'                                                    66600019
M72      DC    C'72'               MSG NO FOR EXCESSIVE COMMAS   A36818 66700020
M75      DC    C'75'                                                    66800019
EOMSG    EQU   X'80'                                                    66900019
BLANK    EQU   C' '                                                     67000019
COMMA    EQU   C','                                                     67100019
DEVTYPE  DC    X'0001300020'                                            67200019
KEY      DC    CL3' '                                                   67300019
WORKSECT DSECT                                                          67400019
SUBSAVE  DC    18F'0'              SAVE AREA FOR IHKSUB                 67500019
SAVE     DS    18F                 SAVE AREA                            67600019
NOTETTR  DC    F'0'                                                     67700019
RJCTAD   DS    20F                 RJCT                                 67800019
SUBDECB  DS    5F                  DECB FOR WRITES                      67900019
GETRDR   EQU   104                                                      68000019
SUBDCB   DS    22F                 READER/INTERPRETER DATA SET DCB      68100019
WLG      EQU   SUBDCB+62                                                68200019
XLSTPTR  DC    F'0'                                                     68300019
SYNADPTR DC    F'0'                                                     68400019
RTRNCODE DC    F'0'                                                     68500019
UTMPARM  DC    F'0'                                                     68600019
         DC    A(0)                                                     68700019
BLOCKAD  DC    F'0'                ADDRESS OF BLOCK INCLUDING CONTROL   68800019
BUFFAD   DC    A(0)                                                     68900019
SAVPPT   DC    3F'0'                                                    69000019
COUNT    DS    0H                                                       69100019
PPTPTCT  DC    H'10'                                                    69200019
SUBSWT   DS    X                                                        69300019
*              X'80'         FORCE END OF DATA FOR IHKGET               69400019
*              X'40'         PROCESSING JOB STATEMENT CONTINUATION      69500019
*              X'20'         PROCESSING DD DATA                         69600019
*              X'10'         EXEC PRESENT FOR PREVIOUS JOB              69700019
*              X'08'         READER/INTERPRETER DATA SET ALLOCATED      69800019
*              X'04'         INPUT FROM D S LIST                        69900019
*              X'02'         INPUT FROM ACTIVE AREA                     70000019
*              X'01'         OUT OF SPACE ON R/I DATA SET               70100019
CLSGET   EQU   X'80'                                                    70200019
JOBC     EQU   X'40'               JOB CARD CONTINUED SWITCH            70300019
DDDATA   EQU   X'20'               DD DATA SWITCH                       70400019
EXECS    EQU   X'10'               EXEC SWITCH                          70500019
RIDS     EQU   X'08'                                                    70600019
DSLSWT   EQU   4                   BIT 5 OF SUBSWT SET TO 1 IF          70700019
*                                  PROCESSING D S LIST TYPE DSNAME      70800019
ACTSWT   EQU   2                   BIT 6 OF GSUBWT SET TO 1 FOR ACTIVE  70900019
*                                  AREA IN USE                          71000019
NOSPACE  EQU   1                                                        71100019
PASSONE  DC    X'0'                                                     71200019
WRTSWT   DC    X'0'                                                     71300019
ONEWRT   EQU   X'80'               FIRST WRITE SWITCH                   71400019
LIBOPEN  EQU   X'40'                                                    71500019
ACTDSLST EQU   X'20'                                                    71600019
RJCWRT   EQU   X'10'                                                    71700019
LINENUM  EQU   X'08'               LINE NUMBER PRESENT IN DSLIST RECORD 71800019
UTMCODE  DS    X                                                        71900019
LNGPARM  DS    0H                                                       72000019
         DC    X'0'                                                     72100019
CURNTLNG DC    X'0'                                                     72200019
CURNTDSN DC    CL9' '              LENGTH AND CURRENT DSNAME            72300019
CURNTUSR DC    CL9' '                                                   72400019
CURNTKEY DC    CL4' '                                                   72500019
CURNTLIN DC    CL8' '                                                   72600019
RECOUNT  DC    H'0'                COUNT OF RECORDS IN BLOCK            72700019
LDCPARM  DS    0F                                                       72800019
LDCECB   DC    F'0'                ECB FOR LOADER CONTROLLER            72900019
DELTCODE DC    X'0'                                                     73000019
LOADCODE DC    X'0'                                                     73100019
LDCZERO  DC    X'0'                                                     73200019
WORKEND  EQU   *-WORKSECT                                               73300019
         IHKCDSCT TUB=YES                                               73400019
         IHKCDSCT AVT=YES                                               73500019
         IHKCDSCT PPT=YES                                               73600019
         IHKCDSCT DIR=YES                                               73700019
         IHKCDSCT RJCT=YES                                              73800019
         TUBEQU                                                         73900019
         DCBD DSORG=BS,DEVD=DA                                          74000019
         RAFKNBX TYPE=DSECT                                             74100019
         END                                                            74200019
