IPT      TITLE 'IHKIPT - INPUT COMMAND PROCESSOR'                       00100019
IHKIPT   CSECT                                                          00200019
*********************************************************************** 00300019
*                                                                     * 00400019
*STATUS:                                                              * 00500019
*   CHANGE LEVEL 0                                                    * 00600019
*                                                                     * 00700019
*FUNCTION:                                                            * 00800019
*   THIS ROUTINE MAKES THE PREPARATION FOR THE USER TO ENTER INTO     * 00900019
*   INPUT MODE FOR EITHER INSERTION OR REPLACEMENT OR A COMBINATION   * 01000019
*   OF THE TWO. THE ROUTINE ACCEPTS A STARTING LINE NUMBER, AND, IF   * 01100019
*   REPLACEMENT IS NOT SPECIFIED, IT ACCEPTS AN INCREMENT. WHEN NO    * 01200019
*   INCREMENT IS SPECIFIED WITH THE LINE NUMBER, THEN THE DEFAULT     * 01300019
*   INCREMENT IS OBTAINED FROM THE DIRECTORY ENTRY, EXCEPT WHEN       * 01400019
*   INSERTION IS SPECIFIED, IN WHICH CASE THE DEFAULT INCREMENT IS    * 01500019
*   ONE. THE 'PROMPT' OR 'NOPROMPT' OPERAND INDICATES WHETHER OR NOT  * 01600019
*   LINE NUMBER PROMPTS ARE REQUESTED. WHEN NO LINE NUMBER IS         * 01700019
*   ENTERED WITH THE SUBCOMMAND, THEN THE CALL CODE FOR IHKIRL01      * 01800019
*   IS PLACED IN REGISTER 15 BEFORE RETURNING TO THE CALLER.          * 01900019
*   OTHERWISE, THE CALL CODE FOR IHKIRL IS PLACED IN REGISTER 15.     * 02000019
*                                                                     * 02100019
*INPUT:                                                               * 02200019
*   INPUT IS THE FOLLOWING PARAMETER LIST ADDRESSED BY REGISTER 1:    * 02300019
*   (1) ADDRESS OF THE TUB                                            * 02400019
*   (2) ADDRESS OF THE AVT                                            * 02500019
*                                                                     * 02600019
*OUTPUT:                                                              * 02700019
*   PARAMETERS ARE SET UP IN THE PPT AS PRESCRIBED BY IHKIRL BEFORE   * 02800019
*   IHKIPT RETURNS TO IHKCMD REQUESTING THAT IHKIRL BE CALLED.        * 02900019
*                                                                     * 03000019
*EXTERNAL REFERENCES:                                                 * 03100019
*        IHKMSG - TO QUEUE MESSAGES FOR THE USER                      * 03200019
*        IHKAFI - TO MANUPULATE ACTIVE AREA                           * 03300019
*        IHKNUM - FOR NUMERIC VERIFICATION                            * 03400019
*                                                                     * 03500019
*EXITS,NORMAL:                                                        * 03600019
*   RETURN BY REGISTER 14 TO CALLING ROUTINE WITH ONE OF THE          * 03700019
*   FOLLOWING CODES IN REGISTER 15:                                   * 03800019
*   (1) NEGATIVE OF IHKIRL COMMAND VERB CODE IF LINE NUMBER WITH      * 03900019
*   SUBCOMMAND.                                                       * 04000019
*   (2) NEGATIVE OF IHKIRL01 COMMAND VERB CODE IF NO LINE NUMBER      * 04100019
*   WITH SUBCOMMAND.                                                  * 04200019
*                                                                     * 04300019
*EXITS,ERROR:                                                         * 04400019
*   RETURN BY REGISTER 14 TO CALLING ROUTINE WITH ONE OF THE          * 04500019
*   FOLLOWING CODES IN REGISTER 15:                                   * 04600019
*   4- TP LINE ERROR                                                  * 04700019
*   8- GETMAIN FAILED                                                 * 04800019
*   12-AFIO I/O ERROR                                                 * 04900019
*                                                                     * 05000019
*TABLES/WORK AREAS:                                                   * 05100019
*   18 WORD SAVE AREA                                                 * 05200019
*   TUB                                                               * 05300019
*        TUBPPTAD - ADDRESS OF PPT                                    * 05400019
*        TUBDIRAD - ADDRESS OF DIRECTORY ENTRY                        * 05500019
*        TUBLNPMT - LINE NUMBER PROMPTS SWITCH                        * 05600019
*   PPT                                                               * 05700019
*                                                                     * 05800019
*ATTRIBUTES:                                                          * 05900019
*   REENTRANT AND NONRESIDENT                                         * 06000019
*                                                                     * 06100019
*NOTES:                                                               * 06200019
*   THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL             * 06300019
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 06400019
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING           * 06500019
*   HAS BEEN ARRANGED SO THAT THE REDEFINITION OF 'CHARACTER'         * 06600019
*   CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE         * 06700019
*   FOR THE NEW DEFINITIONS.                                          * 06800019
*                                                                     * 06900019
*********************************************************************** 07000019
         SPACE 2                                                        07100019
*        REGISTER EQUATES                                               07200019
         SPACE                                                          07300019
REG0     EQU   0                        SYSTEM REGISTER                 07400019
REG1     EQU   1                        POINTER TO PARM LIST            07500019
REG2     EQU   2                        CONTAINS RETURN CODE            07600019
REG3     EQU   3                        WORK REGISTER                   07700019
BUFREG   EQU   4                        POINTER TO USER BUFFER          07800019
REG5     EQU   5                        WORK REGISTER                   07900019
COUNTER  EQU   6                        OPERAND COUNTER                 08000019
POINT    EQU   7                        POINTER TO OPERANDS             08100019
DIRREG   EQU   8                        POINTER TO DIRECTORY            08200019
PPTREG   EQU   9                        POINTER TO PPT                  08300019
IRLREG   EQU   9                        POINTER TO PPT - FOR IRL        08400019
AVTREG   EQU   10                       POINTER TO AVT                  08500019
BASEREG  EQU   11                       BASE REGISTER                   08600019
TUBREG   EQU   12                       POINTER TO THE TUB              08700019
REG13    EQU   13                       POINTER TO SAVE AREA            08800019
BRANCH   EQU   14                       RETURN POINT                    08900019
RETREG   EQU   15                       RETURN CODE                     09000019
         SPACE 2                                                        09100019
*        NUMERIC EQUATES                                                09200019
         SPACE                                                          09300019
ZERO     EQU   0                                                        09400019
ONE      EQU   1                                                        09500019
TWO      EQU   2                                                        09600019
THREE    EQU   3                                                        09700019
FOUR     EQU   4                                                        09800019
SIX      EQU   6                                                        09900019
SEVEN    EQU   7                                                        10000019
EIGHT    EQU   8                                                        10100019
RC8      EQU   8                                                        10200019
TEN      EQU   10                                                       10300019
TWELVE   EQU   12                                                       10400019
TWENTY   EQU   20                                                       10500019
         SPACE 1                                                        10600019
BLANK    EQU   C' '                     BLANK                           10700019
HEXFF    EQU   X'FF'                    HEX FF                          10800019
HEX00    EQU   X'00'                    HEX 00                          10900019
I        EQU   C'I'                     LETTER I                        11000019
LASTPARM EQU   X'80'                    SETS BIT FOR LAST PARAMETER     11100019
OFF      EQU   X'3F'                    PAREN BITS - 0 AND 1            11200019
P        EQU   C'P'                     LETTER P                        11300019
PAREN1   EQU   X'80'                    LAST ELEMENT IN PARENS          11400019
PAREN2   EQU   X'40'                    ELEMENT IN PARENS               11500019
R        EQU   C'R'                     LETTER R                        11600019
SIGN1    EQU   X'F0'                    BIT SETTING FOR EBCDIC SIGN     11700019
ZERORI   EQU   X'9F'                    ZERO REPLACE AND INSERT SWS     11800019
         EJECT                                                          11900019
*        SAVE REGISTERS AND SET BASE REGISTER                           12000019
         SPACE 1                                                        12100019
         SAVE  (14,12),,*               SAVE REGISTERS                  12200019
         LR    BASEREG,RETREG           INITIALIZE BASE REGISTER        12300019
         USING IHKIPT,BASEREG                                           12400019
         SPACE 2                                                        12500019
*        SET REGISTERS FOR DSECTS                                       12600019
         SPACE 1                                                        12700019
         L     TUBREG,ZERO(REG1)        ADDRESS OF TUB                  12800019
         USING TUBDSECT,TUBREG                                          12900019
         L     AVTREG,FOUR(REG1)        ADDRESS OF AVT                  13000019
         USING AVTDSECT,AVTREG                                          13100019
         L     PPTREG,TUBPPTAD          ADDRESS OF PPT                  13200019
         USING PPTDSECT,PPTREG                                          13300019
         L     DIRREG,TUBDIRAD          ADDRESS OF DIRECTORY ENTRY      13400019
         USING DIRDSECT,DIRREG                                          13500019
         L     BUFREG,TUBUFFAD          ADDRESS OF USER BUFFER          13600019
         USING BUFFER,BUFREG                                            13700019
         SPACE 2                                                        13800019
*        GET MAIN STORAGE TO MAKE CODE REENTRANT                        13900019
         SPACE 1                                                        14000019
         LA    REG3,LEN                 LENGTH                          14100019
         LA    REG5,TUBPARM1            ADDR OF GETMAIN IN TUBPARM1     14200019
         L     REG1,IHKYYGML            ADDRESS OF GETMAIN LIST         14300019
         GETMAIN EC,LV=(3),A=(5),MF=(E,(1))                             14400019
         LTR   RETREG,RETREG            WAS GETMAIN SUCCESSFUL ?        14500019
         BZ    LDGET                    IF YES, SET DSECT FOR GETMAIN   14600019
         LA    REG2,RC8                 RETURN CODE 8 - GETMAIN FAILED  14700019
         B     RETURN                   RETURN TO CALLER                14800019
LDGET    DS    0H                                                       14900019
         LR    REG1,REG13               SAVE CALLER'S REG13 IN REG1     15000019
         L     REG13,TUBPARM1           REG13 POINTS TO GETMAIN AREA    15100019
         USING GETAREA,REG13                                            15200019
         ST    REG1,SAVEAREA+4          SAVE CALLER'S REG13 IN SAVEAREA 15300019
         ST    REG13,EIGHT(REG1)        SAVE REG13 IN CALLER'S SAVEAREA 15400019
         EJECT                                                          15500019
*        INITIALIZE                                                     15600019
         SPACE 1                                                        15700019
         SR    REG2,REG2                RETURN CODE SET TO 0            15800019
*        ZERO FLAGS IN PPT INDICATING REPLACE AND INSERT                15900019
         NI    PPTFLG,ZERORI                                            16000019
         MVC   SWITCHES(TWO),ZEROS      SET ALL SWITCHES TO 0           16100019
         LA    POINT,PPTPARS            POINTS TO 1ST LENGTH BYTE       16200019
         LA    COUNTER,ONE              SET OPERAND COUNTER TO 1        16300019
         SPACE 1                                                        16400019
*        SET DEFAULT IN TUB                                             16500019
         L     REG3,IHKYYDEF            ADDRESS OF DEFAULT TABLE        16600019
         USING DEFDSECT,REG3                                            16700019
         TM    DEFINP,DEFIREP           LINE NO. PROMPTS REQUESTED ?    16800019
         DROP  REG3                                                     16900019
         BO    SETREP                   IF YES, SET SWITCH IN TUB       17000019
         NI    TUBFLG3,TUBLNPMF         TURN OFF SWITCH IN TUB          17100019
         B     TEST                     TEST FOR OPERANDS               17200019
SETREP   DS    0H                                                       17300019
         OI    TUBFLG3,TUBLNPMT         SET LINE NO. PROMPT SWITCH      17400019
         SPACE 2                                                        17500019
*        TEST FOR OPERANDS IN COMMAND                                   17600019
         SPACE 1                                                        17700019
TEST     DS    0H                                                       17800019
         CLI   ZERO(POINT),HEXFF        ARE THERE ANY OPERANDS ?        17900019
         BNE   TP                       IF YES, TEST FOR PARENS         18000019
         CLC   PPTCHAD+1(THREE),ZEROS   IS THERE ANOTHER PPT ?          18100019
         BE    CALLIRL1                 IF NOT, NO OPERANDS             18200019
         L     PPTREG,PPTCHAD           GET ADDRESS OF NEXT PPT         18300019
         LA    PPTREG,ZERO(PPTREG)      CLEAR HIGH-ORDER BYTE           18400019
         LA    POINT,PPTPARS            POINT TO NEXT OPERAND           18500019
         SPACE 2                                                        18600019
*        TEST FOR PARENTHESES                                           18700019
         SPACE 1                                                        18800019
TP       DS    0H                                                       18900019
         TM    ZERO(POINT),PAREN2       IS OPERAND IN PARENS ?          19000019
         BO    NOPAREN                  IF YES, ERROR                   19100019
         EJECT                                                          19200019
*        CALL IHKNUM TO CHECK FOR NUMERICS                              19300019
         SPACE 1                                                        19400019
START    DS    0H                                                       19500019
         ST    POINT,TUBPARM2           1ST PARM POINTS TO LENGTH BYTE  19600019
         LR    REG3,POINT                                               19700019
         LA    REG3,ONE(REG3)           REG3 CONTAINS ADDRESS OF DATA   19800019
         ST    REG3,TUBPARM3            2ND PARM POINTS TO DATA         19900019
         LA    REG3,BUFF1                                               20000019
         ST    REG3,TUBPARM4            3RD PARM POINTS TO USER BUFFER  20100019
         OI    TUBPARM4,LASTPARM        SET LAST PARM BIT               20200019
         LA    REG1,TUBPARM2            REG1 POINTS TO PARM LIST        20300019
         L     RETREG,IHKYYNUM          ADDRESS OF IHKNUM               20400019
         BALR  BRANCH,RETREG            CALL IHKNUM                     20500019
         LTR   RETREG,RETREG            TEST RETURN CODE                20600019
*        IF MORE THAN 8 CHARACTERS,OR IF ALL CHARACTERS ARE NOT NUMERIC 20700019
*        THEN CHECK OPERAND AS A NON-NUMERIC                            20800019
         BNZ   LEN1                                                     20900019
         SPACE 2                                                        21000019
*        SAVE NUMERICS                                                  21100019
         SPACE 1                                                        21200019
         TM    SWITCHES,SWLINENO        IS LINE NO. SWITCH SET ?        21300019
         BO    INCREMNT                 IF YES, SAVE INCREMENT          21400019
         MVC   TUBNXKEY(EIGHT),BUFF1    SAVE LINE NO.                   21500019
         OI    SWITCHES,SWLINENO        SET LINE NO. SWITCH             21600019
         B     NEXT                     CHECK FOR ANOTHER OPERAND       21700019
INCREMNT DS    0H                                                       21800019
         PACK  BUFF2(EIGHT),BUFF1(EIGHT) CONVERT INCREMENT FROM         21900019
         CVB   REG3,BUFF2               EBCDIC TO BINARY                22000019
         ST    REG3,SAVEINC             SAVE INCREMENT                  22100019
         OI    SWITCHES,SWINC           SET INCREMENT SWITCH            22200019
         LTR   REG3,REG3                INCREMENT = 0 ?                 22300019
         BZ    INVINC                   IF YES, THEN INCREMENT INVALID  22400019
         B     NEXT                     CHECK FOR ANOTHER OPERAND       22500019
         EJECT                                                          22600019
*        CHECK FOR TYPE OF OPERAND                                      22700019
         SPACE 1                                                        22800019
LEN1     DS    0H                                                       22900019
         CLI   ZERO(POINT),ONE          LENGTH=1 ?                      23000019
         BNE   LEN3                     IF NOT, CHECK FOR LENGTH=3      23100019
         CLI   ONE(POINT),P             OPERAND='P' ?                   23200019
         BNE   CHKR                     IF NOT, CHECK FOR OPERAND='R'   23300019
CHKREPN  DS    0H                                                       23400019
         OI    TUBFLG3,TUBLNPMT         LINE NO. PROMPTS REQUESTED      23500019
         OI    SWITCHES,SWPROMPT        SET PROMPT SWITCH               23600019
         B     NEXT                     CHECK FOR ANOTHER OPERAND       23700019
CHKR     DS    0H                                                       23800019
         TM    SWITCHES,SWLINENO        IS LINE NO. SWITCH SET ?        23900019
         BZ    ERROR                    LINE NO. MUST PRECEDE R AND I   24000019
         CLI   ONE(POINT),R             OPERAND='R' ?                   24100019
         BNE   CHKI                     IF NOT, CHECK FOR OPERAND='I'   24200019
         TM    SWITCHES,SWRORI          REPLACE OR INSERT SET ?         24300019
         BNZ   MULT                     IF YES, ERROR IN OPERAND        24400019
         TM    SWITCHES,SWINC           IS INCREMENT SWITCH SET ?       24500019
         BO    ERROR                    NO INCREMENT WITH R OPERAND     24600019
         OI    SWITCHES,SWREPL          SET REPLACE SWITCH              24700019
         B     NEXT                     CHECK FOR ANOTHER OPERAND       24800019
CHKI     DS    0H                                                       24900019
         CLI   ONE(POINT),I             OPERAND='I' ?                   25000019
         BNE   ERROR                    IF NOT, ERROR IN OPERAND        25100019
         TM    SWITCHES,SWRORI          REPLACE OR INSERT SET ?         25200019
         BNZ   MULT                     IF YES, ERROR IN OPERAND        25300019
         TM    SWITCHES,SWINC           IS INCREMENT SWITCH SET ?       25400019
         BO    SETSWINS                 IF YES, INCREMENT DETERMINED    25500019
         LA    REG3,ONE                                                 25600019
         ST    REG3,SAVEINC             DEFAULT INCREMENT = 1           25700019
         OI    SWITCHES,SWINC           SET INCREMENT SWITCH            25800019
SETSWINS DS    0H                                                       25900019
         OI    SWITCHES,SWINS           SET INSERT SWITCH               26000019
         B     NEXT                     CHECK FOR ANOTHER OPERAND       26100019
         EJECT                                                          26200019
LEN3     DS    0H                                                       26300019
         CLI   ZERO(POINT),THREE        LENGTH=3 ?                      26400019
         BNE   LEN6                     IF NOT, CHECK FOR LENGTH=6      26500019
         CLC   ONE(THREE,POINT),NOPROMPT OPERAND='NOP' ?                26600019
         BNE   ERROR                    IF NOT, ERROR IN OPERAND        26700019
CHKREPF  DS    0H                                                       26800019
         NI    TUBFLG3,SWLNPRTF         TURN OFF LINE NO. PROMPT SWITCH 26900019
         OI    SWITCHES,SWPROMPT        SET PROMPT SWITCH               27000019
         B     NEXT                     CHECK FOR ANOTHER OPERAND       27100019
         SPACE 2                                                        27200019
LEN6     DS    0H                                                       27300019
         CLI   ZERO(POINT),SIX          LENGTH=6 ?                      27400019
         BNE   LEN8                     IF NOT, CHECK FOR LENGTH=8      27500019
         CLC   ONE(SIX,POINT),PROMPT    OPERAND='PROMPT' ?              27600019
         BNE   ERROR                    IF NOT, ERROR IN OPERAND        27700019
         B     CHKREPN                  SET FOR LINE PROMPTS            27800019
         SPACE 1                                                        27900019
LEN8     DS    0H                                                       28000019
         CLI   ZERO(POINT),EIGHT        LENGTH=8 ?                      28100019
         BNE   ERROR                    IF NOT, ERROR IN OPERAND        28200019
         CLC   ONE(EIGHT,POINT),NOPROMPT OPERAND='NOPROMPT' ?           28300019
         BNE   ERROR                    IF NOT, ERROR IN OPERAND        28400019
         B     CHKREPF                  SET FOR NO LINE PROMPTS         28500019
         SPACE 2                                                        28600019
*        INCREMENT TO NEXT OPERAND                                      28700019
         SPACE 1                                                        28800019
INC      DS    0H                                                       28900019
         NI    ZERO(POINT),OFF          TURN OFF PAREN BITS             29000019
         SR    REG3,REG3                                                29100019
         IC    REG3,ZERO(POINT)         LENGTH OF OPERAND               29200019
         AR    POINT,REG3               POINT TO END OF OPERAND         29300019
         LA    POINT,ONE(POINT)         POINT TO LENGTH BYTE OF NEXT OP 29400019
         BR    REG5                     RETURN                          29500019
         EJECT                                                          29600019
*        CHECK FOR ANOTHER OPERAND                                      29700019
         SPACE 1                                                        29800019
NEXT     DS    0H                                                       29900019
         BAL   REG5,INC                 INCREMENT TO NEXT OPERAND       30000019
         CLI   ZERO(POINT),HEXFF        IS THERE ANOTHER OPERAND IN PPT 30100019
         BNE   INCCNT                   IF YES, INCREMENT COUNTER       30200019
         SPACE 1                                                        30300019
PPTCHAIN DS    0H                                                       30400019
         CLC   PPTCHAD+1(THREE),ZEROS   IS THERE ANOTHER PPT ?          30500019
         BE    CHKERR                   IF NOT, HAVE ERRORS OCCURRED    30600019
         L     PPTREG,PPTCHAD           RESET PPT POINTER TO NEW PPT    30700019
         LA    POINT,PPTPARS            RESET POINT TO 1ST OP LENGTH    30800019
         SPACE 1                                                        30900019
INCCNT   LA    COUNTER,ONE(COUNTER)     ADD ONE TO COUNTER              31000019
         CL    COUNTER,F4               NO. OF OPERANDS EXCEEDS 4 ?     31100019
         BH    EXCESS                   IF YES, EXCESSIVE OPERANDS      31200019
         TM    SWITCHES,SWPROMPT        IS PROMPT SWITCH SET ?          31300019
         BO    EXCESS                   IF YES, EXCESSIVE OPERANDS      31400019
         TM    ZERO(POINT),PAREN2       OPERAND IN PARENS ?             31500019
         BO    NOPAREN                  IF YES, SEND ERROR MESSAGE      31600019
         TM    SWITCHES,SWREPL          HAS 'R' OPERAND BEEN ENTERED ?  31700019
         BO    LEN1                                                     31800019
         TM    SWITCHES,SWINC           IS INCREMENT SWITCH SET ?       31900019
         BZ    START                    IF NOT, CHECK FOR NUMERICS      32000019
         B     LEN1                     CHECK OPERANDS                  32100019
         SPACE 2                                                        32200019
MSGPT    DS    0H                                                       32300019
         LA    REG1,MSG                                                 32400019
         ST    REG1,TUBPARM4            3RD PARM POINTS TO MSG NO.      32500019
         LA    REG1,TUBUSRID                                            32600019
         ST    REG1,TUBPARM3            2ND PARM POINTS TO USERID       32700019
         ST    TUBREG,TUBPARM2          1ST PARM POINTS TO THE TUB      32800019
         LA    REG1,TUBPARM2            REG1 POINTS TO PARM LIST        32900019
         BR    REG3                     RETURN                          33000019
         SPACE 2                                                        33100019
*        CALL MESSAGE WRITER                                            33200019
         SPACE 1                                                        33300019
CALLMSG  DS    0H                                                       33400019
         BAL   REG3,MSGPT               SET UP PARAMETERS               33500019
         OI    TUBPARM4,LASTPARM        SET LAST PARM BIT               33600019
CALLMSG1 DS    0H                                                       33700019
         L     RETREG,IHKYMSG1          ADDRESS OF MESSAGE WRITER       33800019
         BALR  BRANCH,RETREG            CALL MESSAGE WRITER             33900019
         LTR   RETREG,RETREG            TEST RETURN CODE                34000019
         BCR   8,REG5                   GOOD RETURN                     34100019
         LR    REG2,RETREG              SAVE RETURN CODE                34200019
         B     RESTORE                  PREPARE TO RETURN TO CALLER     34300019
         EJECT                                                          34400019
*        INVALID INCREMENT - 0                                          34500019
         SPACE                                                          34600019
INVINC   DS    0H                                                       34700019
         OI    SWITCHES,SWERR           SET ERROR SWITCH                34800019
         MVC   MSG(FOUR),MSG343         GET CANNED MSG NUMBER           34900019
         LA    REG5,NEXT                CHECK NEXT OPND AFTER MSG WTR   35000019
         B     CALLMSG                  GO TO CALL FOR MSG WRITER       35100019
         SPACE 2                                                        35200019
*        SEND 'CANNOT INSERT RECORD' MESSAGE                            35300019
         SPACE 1                                                        35400019
ERR      DS    0H                                                       35500019
         MVC   MSG(FOUR),MSG346         CANNOT INSERT RECORD            35600019
         B     BADLINE                  SEND MESSAGE                    35700019
         SPACE 2                                                        35800019
*        SEND 'LINE DOES NOT EXIST' MESSAGE                             35900019
         SPACE 1                                                        36000019
DNE      DS    0H                                                       36100019
         MVC   MSG(FOUR),MSG349         LINE DOES NOT EXIST             36200019
         SPACE 2                                                        36300019
BADLINE  DS    0H                                                       36400019
         MVI   BUFF1,EIGHT              LENGTH OF OPERAND               36500019
         MVC   BUFF1+1(EIGHT),TUBNXKEY  PUT LINE NO. INTO OPERAND FIELD 36600019
         LA    REG3,BUFF1                                               36700019
         ST    REG3,TUBPARM5            4TH PARM POINTS TO OPERAND      36800019
         OI    TUBPARM5,LASTPARM        SET LAST PARM BIT               36900019
         LA    REG5,SEVEN                                               37000019
COMP     DS    0H                                                       37100019
         CLI   ONE(REG3),SIGN1          IS LEADING DIGIT A ZERO ?       37200019
         BNE   SET                      IF NOT, SET UP PARAMETERS       37300019
         MVI   ONE(REG3),BLANK          REPLACE LEADING ZERO WITH BLANK 37400019
         LA    REG3,ONE(REG3)           POINT TO NEXT DIGIT             37500019
         BCT   REG5,COMP                CONTINUE IF LESS THAN 7 ZEROS   37600019
SET      DS    0H                                                       37700019
         BAL   REG3,MSGPT               SET UP PARAMETERS               37800019
         LA    REG5,RESTORE             PREPARE TO RETURN AFTER MSG     37900019
         B     CALLMSG1                 GO TO CALL FOR MSG WTR          38000019
         SPACE 2                                                        38100019
*        'EXCESSIVE OPERANDS'                                           38200019
         SPACE 1                                                        38300019
EXCESS   DS    0H                                                       38400019
         MVC   MSG(FOUR),MSG334         'EXCESSIVE OPERANDS' MESSAGE    38500019
         OI    SWITCH2,SWEND            EXCESSIVE OPER - END PROCESSING 38600019
         B     SEND                     SEND MESSAGE                    38700019
         SPACE 2                                                        38800019
         EJECT                                                          38900019
*        SEND 'OPERAND INVALID' MESSAGE                                 39000019
         SPACE 1                                                        39100019
NOPAREN  DS    0H                                                       39200019
         TM    ZERO(POINT),PAREN1       OPERAND LAST IN PARENS ?        39300019
         BO    ERROR                    IF NOT, DO NOT SET SWITCH       39400019
         OI    SWITCHES,SWPAREN         SET PARENS SWITCH               39500019
ERROR    DS    0H                                                       39600019
         MVC   MSG(FOUR),MSG302         'OPERAND INVALID' MESSAGE       39700019
         B     SEND                     SEND MESSAGE                    39800019
         SPACE 2                                                        39900019
*        'MULTIPLE OPERANDS'                                            40000019
         SPACE 1                                                        40100019
MULT     DS    0H                                                       40200019
         MVC   MSG(FOUR),MSG321         'MULTIPLE OPERANDS' MESSAGE     40300019
         SPACE 2                                                        40400019
SEND     DS    0H                                                       40500019
         LA    REG1,TEN                                                 40600019
         NI    ZERO(POINT),OFF          TURN OFF PAREN BITS             40700019
         IC    REG2,ZERO(POINT)         OPERAND LENGTH                  40800019
         CLR   REG1,REG2                PARAMETER LENGTH < 11 ?         40900019
         BNL   OK                       IF YES, LENGTH OK               41000019
         STC   REG1,ZERO(POINT)         REPLACE LENGTH WITH 10          41100019
OK       DS    0H                                                       41200019
         ST    POINT,TUBPARM5           4TH PARM POINTS TO OPERAND      41300019
         OI    TUBPARM5,LASTPARM        SET LAST PARM BIT               41400019
         BAL   REG3,MSGPT               SET UP PARAMETERS               41500019
         BAL   REG5,CALLMSG1            GO TO CALL FOR MSG WTR          41600019
         STC   REG2,ZERO(POINT)         RESET OPERAND LENGTH            41700019
         SR    REG2,REG2                RESET RETURN CODE TO 0          41800019
         OI    SWITCHES,SWERR           SET ERROR SWITCH                41900019
         TM    SWITCH2,SWEND            EXCESSIVE OPERANDS CAUSED MSG ? 42000019
         BO    RESTORE                  IF YES, RETURN TO CALLER        42100019
         TM    SWITCHES,SWPAREN         ANOTHER ELEMENT IN PARENS ?     42200019
         BZ    NEXT                     IF NOT, GET NEXT OPERAND        42300019
GOINC    DS    0H                                                       42400019
         BAL   REG5,INC                 INCREMENT TO NEXT ELEMENT       42500019
         TM    ZERO(POINT),PAREN1       LAST IN PARENS ?                42600019
         BZ    GOINC                    IF NOT, GET NEXT ELEMENT        42700019
         NI    SWITCHES,SWPARENF        TURN OFF PAREN SWITCH           42800019
         B     NEXT                     CHECK FOR ANOTHER OPERAND       42900019
         EJECT                                                          43000019
*        CHECK FOR ERRORS IN OPERANDS                                   43100019
         SPACE 1                                                        43200019
CHKERR   DS    0H                                                       43300019
         TM    SWITCHES,SWERR           IS ERROR SWITCH SET ?           43400019
         BO    RESTORE                  IF YES, RETURN TO CALLER        43500019
         TM    SWITCHES,SWLINENO        IS LINE NO. SWITCH SET ?        43600019
         BO    RPTRL                    IF YES, PUT LINE NO. IN KEY     43700019
         SPACE 2                                                        43800019
*        SET UP TO CALL IHKIRL01                                        43900019
         SPACE 1                                                        44000019
CALLIRL1 DS    0H                                                       44100019
         MVC   TUBDATAL(TWO),ZEROS      PUT 0 IN TUBDATAL               44200019
         LA    REG2,CMDIMP              CALL CODE FOR IHKIRL01          44300019
         LNR   REG2,REG2                LOAD NEGATIVE OF CODE           44400019
         B     RESTORE                  PREPARE TO RETURN TO CALLER     44500019
         SPACE 2                                                        44600019
*        SEE IF REPLACE SWITCH OR INSERT SWITCH IS SET                  44700019
         SPACE 1                                                        44800019
RPTRL    DS    0H                                                       44900019
         TM    SWITCHES,SWREPL          IS REPLACE SWITCH SET ?         45000019
         BO    PR                       IF YES, POINT FOR REPLACE       45100019
         TM    SWITCHES,SWINS           IS INSERT SWITCH SET ?          45200019
         BO    PI                       IF YES, POINT FOR INSERT        45300019
         SPACE 2                                                        45400019
PN       DS    0H                                                       45500019
         BAL   REG5,RPTRR               POINT TO RECORD                 45600019
         B     SET02                    SET 02 SWITCH IN PPT FOR IRL    45700019
         B     PREV                     POINT TO PREVIOUS RECORD        45800019
SET02    DS    0H                                                       45900019
         OI    SWITCHES,SW02            SET SWITCH FOR IHKIRL           46000019
         B     SETUP                    SET UP FOR IHKIRL               46100019
         SPACE 2                                                        46200019
*        INSERT LINE                                                    46300019
         SPACE 1                                                        46400019
PI       DS    0H                                                       46500019
         BAL   REG5,RPTRR               POINT TO RECORD                 46600019
         B     ERR                      'CANNOT INSERT RECORD' MSG      46700019
         B     PREV                     POINT TO PREVIOUS RECORD        46800019
         SPACE 2                                                        46900019
*        REPLACE LINE                                                   47000019
         SPACE 1                                                        47100019
PR       DS    0H                                                       47200019
         BAL   REG5,RPTRR               POINT TO RECORD                 47300019
         B     SETUP                    SET UP FOR IHKIRL               47400019
         B     DNE                      RECORD DOES NOT EXIST           47500019
         EJECT                                                          47600019
*        POINT TO SPECIFIC RECORD                                       47700019
         SPACE 1                                                        47800019
RPTRR    DS    0H                                                       47900019
         BAL   REG3,RAF                 SET UP FOR RAFIO                48000019
         RPOINT B,NR                                                    48100019
         CL    RETREG,F4                TEST RETURN CODE                48200019
         BCR   4,REG5                   IF 0, THEN RECORD FOUND         48300019
         BC    8,FOUR(REG5)             IF 4,THEN RECORD DOES NOT EXIST 48400019
         LR    REG2,RETREG              SAVE RETURN CODE                48500019
         B     RESTORE                  PREPARE TO RETURN TO CALLER     48600019
         SPACE 2                                                        48700019
*        POINT TO PREVIOUS EXISITING RECORD                             48800019
         SPACE 1                                                        48900019
PREV     DS    0H                                                       49000019
         BAL   REG3,RAF                 SET UP FOR RAFIO                49100019
         RPOINT A,NR,KEY=HIEQ                                           49200019
         CL    RETREG,F4                TEST RETURN CODE                49300019
         BNH   SETUP                    IF 0 OR 4, GOOD RETURN CODE     49400019
         LR    REG2,RETREG              SAVE RETURN CODE                49500019
         B     RESTORE                  PREPARE TO RETURN TO CALLER     49600019
         SPACE 2                                                        49700019
*        SET UP POINTER TO TUB FOR RAFIO                                49800019
         SPACE 1                                                        49900019
RAF      DS    0H                                                       50000019
         ST    TUBREG,TUBPARM3          ADDRESS OF TUB                  50100019
         LA    REG1,TUBPARM3            REG1 POINTS TO PARM LIST        50200019
         BR    REG3                     RETURN                          50300019
         EJECT                                                          50400019
*        SET PARAMETERS FOR CALLING IHKIRL                              50500019
         SPACE 1                                                        50600019
SETUP    DS    0H                                                       50700019
         TM    SWITCHES,SWINC           IS INCREMENT SWITCH SET ?       50800019
         BO    SETPARM                  IF YES, INCREMENT ALREADY SET   50900019
         MVC   SAVEINC(FOUR),DIRINC     GET INCREMENT FROM DIRECTORY    51000019
SETPARM  DS    0H                                                       51100019
         L     PPTREG,TUBPPTAD          ADDRESS OF PPT                  51200019
*        TURN OFF ALL SWITCHES EXCEPT INSERT AND REPLACE                51300019
         NI    SWITCHES,SWOFF                                           51400019
         OC    PPTFLG(ONE),SWITCHES     SET INSERT OR REPLACE SWITCH    51500019
         DROP  PPTREG                                                   51600019
         USING IRLPPT,IRLREG                                            51700019
         OI    FLAGS,INPUT              IHKIRL CALLED BY IHKIPT         51800019
         MVC   LN(EIGHT),TUBNXKEY       PUT LINE NO. INTO PPT           51900019
         MVC   INCRE(FOUR),SAVEINC      PUT INCREMENT INTO PPT          52000019
         LA    REG2,CMDIRL              CALL CODE FOR IHKIRL            52100019
         LNR   REG2,REG2                LOAD NEGATIVE OF CODE           52200019
         SPACE 2                                                        52300019
*        RESTORE REGISTERS AND FREE GETMAIN AREA                        52400019
         SPACE 1                                                        52500019
RESTORE  DS    0H                                                       52600019
         LR    REG1,REG13               CONTAINS ADDRESS OF GETAREA     52700019
         L     REG13,SAVEAREA+4         RESTORE CALLER'S REGISTER 13    52800019
         LA    REG0,LEN                 LENGTH OF GETMAIN               52900019
         FREEMAIN R,LV=(0),A=(1)                                        53000019
         SPACE 1                                                        53100019
RETURN   LR    RETREG,REG2              SET RETURN CODE IN REGISTER 15  53200019
         L     BRANCH,TWELVE(REG13)                                     53300019
         LM    ZERO,TWELVE,TWENTY(REG13)                                53400019
         BR    BRANCH                                                   53500019
         SPACE 3                                                        53600019
*        DEFINE STORAGE AND CONSTANTS                                   53700019
         SPACE 1                                                        53800019
         DS    0F                                                       53900019
ZEROS    DC    F'0'                                                     54000019
F4       DC    F'4'                                                     54100019
MSG302   DC    XL4'00F3F0F2'            INVALID OPERAND                 54200019
MSG321   DC    XL4'00F3F2F1'            MULTIPLE OPERANDS               54300019
MSG334   DC    XL4'00F3F3F4'            EXCESSIVE OPERANDS              54400019
MSG343   DC    XL4'00F3F4F3'            INVALID INCREMENT - 0           54500019
MSG346   DC    XL4'00F3F4F6'            CANNOT INSERT RECORD            54600019
MSG349   DC    XL4'00F3F4F9'            LINE DOES NOT EXIST             54700019
NOPROMPT DC    C'NO'                    NOPROMPT OPERAND                54800019
PROMPT   DC    C'PROMPT'                PROMPT OPERAND                  54900019
         EJECT                                                          55000019
IRLPPT   DSECT                                                          55100019
FLAGS    DS    C                        PPT FLAGS                       55200019
INPUT    EQU   X'01'                    INPUT - FOR IRL                 55300019
         DS    CL5                                                      55400019
LN       DS    CL8                      LINE NUMBER                     55500019
INCRE    DS    F                        INCREMENT                       55600019
         SPACE 2                                                        55700019
BUFFER   DSECT                                                          55800019
BUFF     DS    22F                      USED BY IHKMSG                  55900019
BUFF1    DS    D                        WORK AREA                       56000019
BUFF2    DS    D                        WORK AREA                       56100019
SAVEINC  DS    F                        SAVE AREA FOR INCREMENT         56200019
MSG      DS    CL4                      MESSAGE NUMBER                  56300019
SWITCHES DS    C                        SWITCHES                        56400019
SWLINENO EQU   X'80'                    LINE NO.SWITCH                  56500019
SWLNPRTF EQU   X'7F'                    LINE NO. PROMPT SWITCH - OFF    56600019
SWRORI   EQU   X'60'                    REPLACE OR INSERT               56700019
SWINS    EQU   X'40'                    INSERT OPERAND                  56800019
SWREPL   EQU   X'20'                    REPLACE OPERAND                 56900019
SWOFF    EQU   X'62'                    TURN OFF ALL BUT INS AND REP    57000019
SWERR    EQU   X'10'                    ERROR SWITCH                    57100019
SWINC    EQU   X'08'                    INCREMENT SWITCH                57200019
SWPROMPT EQU   X'04'                    PROMPT SWITCH                   57300019
SW02     EQU   X'02'                    REPLACE                         57400019
SWPAREN  EQU   X'01'                    OPERAND IN PARENS               57500019
SWPARENF EQU   X'FE'                                                    57600019
SWITCH2  DS    C                        SWITCHES                        57700019
SWEND    EQU   X'80'                    END PROCESSING                  57800019
         SPACE 2                                                        57900019
*        GETMAIN DSECT                                                  58000019
         SPACE 1                                                        58100019
GETAREA  DSECT                                                          58200019
SAVEAREA DS    18F                      SAVE AREA                       58300019
LEN      EQU   *-GETAREA                                                58400019
         SPACE 3                                                        58500019
         CMDEQU                                                         58700019
         SPACE 1                                                        58800019
         IHKCDSCT TUB=YES,AVT=YES,PPT=YES,DIR=YES,DEF=YES               58900019
         TUBEQU                                                         59000019
         END                                                            59100019
