IRL      TITLE 'IHKIRL - INSERT-REPLACE-LINENUM, TEXT PROCESSOR'        00070019
*********************************************************************** 00140019
*                                                                     * 00148000
*A795900                                                         A44641 00156000
*C091700                                                         A47928 00164000
*A611100                                                         A47928 00172000
*                                                                     * 00180000
*********************************************************************** 00188000
*                                                                     * 00196000
*STATUS                                                               * 00210019
*   CHANGE LEVEL 0                                                    * 00280019
*FUNCTION                                                             * 00350019
*   THIS ROUTINE SERVICES REQUESTS TO CREATE AN ACTIVE FILE, MODIFY   * 00420019
*   THE AN EXISTING ACTIVE FILE, AND CREATE A DIRECTORY ENTRY.  IT    * 00490019
*   ALSO PROCESSES THE IMPLICIT AND DELETE SUBCOMMANDS.               * 00560019
*   WHEN CONTROL IS PASSED TO THE IHKIRL ENTRY POINT FROM IHKEDT, A   * 00630019
*   NEW ACTIVE FILE IS CREATED, A DIRECTORY ENTRY IS CREATED, AND IF  * 00700019
*   NEW WAS SPECIFIED, LINES ARE INSERTED INTO THE ACTIVE FILE AS     * 00770019
*   DESCRIBED UNDER THE INSERT ONLY REQUEST.                          * 00840019
*   WHEN A DELETE SUBCOMMAND IS ENTERED, THE OPERANDS ARE CHECKED AND * 00910019
*   IF AN ERROR IS DETECTED, AN ERROR MESSAGE IS QUEUED FOR THE USER. * 00980019
*   WHEN THE COMMAND HAS BEEN ACCEPTED AND ONLY ONE LINE IS SPECIFIED,* 01050019
*   THAT LINE IS DELETED IF IT EXISTS.  IF IT DOES NOT EXIST, A       * 01120019
*   MESSAGE IS QUEUED FOR THE USER.  WHEN A RANGE OF LINES IS         * 01190019
*   SPECIFIED, ALL EXISTING LINES WITHIN THAT RANGE ARE DELETED.  IF  * 01260019
*   THERE ARE NO LINES WITHIN THE RANGE, A MESSAGE IS QUEUED FOR THE  * 01330019
*   USER.                                                             * 01400019
*   IF THE REQUEST IS FOR INSERT ONLY, THE USER IS PROMPTED WITH A    * 01470019
*   LINE NUMBER AND THE REPLY TEXT IS INSERTED INTO THE ACTIVE FILE.  * 01540019
*   THE NEXT LINE NUMBER IS CALCULATED AND THE USER IS AGAIN PROMPTED.* 01610019
*   THIS CONTINUES UNTIL THE USER ENTERS A NULL LINE OF INPUT, OR THE * 01680019
*   CALCULATED LINE NUMBER IS GREATER THAN OR EQUAL TO A LINE ALLREADY* 01750019
*   EXISTING IN THE ACTIVE FILE.                                      * 01820019
*   IF THE REQUEST IS FOR INSERTION OR REPLACEMENT, THE USER IS       * 01890019
*   PROMPTED WITH A LINE NUMBER AND THE LINE IS INSERTED INTO OR      * 01960019
*   REPLACES AN EXISTING LINE IN THE ACTIVE FILE.  THE NEXT LINE      * 02030019
*   NUMBER IS CALCULATED AND THE USER IS AGAIN PROMPTED.  THIS        * 02100019
*   CONTINUES UNTILL THE USER ENTERS A NULL LINE OF INPUT.            * 02170019
*   WHEN THE REQUEST IS FOR REPLACEMENT ONLY, THE LINE NUMBER IN THE  * 02240019
*   SUBCOMMAND IS USED TO PROMPT THE USER.  THE REPLY TEXT REPLACES   * 02310019
*   THE EXISTING LINE IN THE ACTIVE FILE.  THE USER IS THEN PROMPTED  * 02380019
*   WITH THE NEXT EXISTING LINE NUMBER.  THIS CONTINUES UNTILL THE    * 02450019
*   USER ENTERS A NULL LINE OR EOD IS HIT ON THE ACTIVE FILE.         * 02520019
*   IF THE USER HAS REQUESTED THAT INPUT LINES BE SYNTAX CHECKED.     * 02590019
*   EACH INPUT LINE, EXCEPT THOSE ENTERED WITH THE IMPLICIT SUBCOMMAND* 02660019
*   ARE CHECKED FOR A CONTINUATION CHARACTER (-) AT THE END OF THE    * 02730019
*   LINE.  IF THERE IS A CONTINUATION CHARACTER, IT IS REMOVED AND    * 02800019
*   THE LINE IS PUT INTO THE ACTIVE FILE.  WHEN A LINE WITHOUT A      * 02870019
*   CONTINUATION CHARACTER IS DETECTED, IT IS PUT INTO THE ACTIVE FILE* 02940019
*   AND THE LINE NUMBER RANGE SINCE THE LAST NONCONTINUATION LINE IS  * 03010019
*   PASSED TO THE SYNTAX CHECKER INTERFACE (IHKSYN).  IF THE RETURN   * 03080019
*   CODE  FROM THE INTERFACE IS GOOD, THE USER IS PROMPTED FOR THE    * 03150019
*   NEXT LINE AND PROCESSING CONTINUES.  IF A SYNTAX ERROR OCCURRED,  * 03220019
*   CONTROL IS RETURNED TO THE SYSTEM ADMINISTRATOR.  THIS MODULE IS  * 03290019
*   REENTERED AT THE IHKIRL02 ENTRY POINT.  IF NO CORRECTIONS HAVE    * 03360019
*   MADE, NORMAL PROCESSING IS RESUMED.  IF CORRECTIONS WERE MADE, THE* 03430019
*   RANGE IS AGAIN PASSED TO THE INTERFACE AND THE CYCLE REPEATS      * 03500019
*ENTRY POINTS                                                         * 03570019
*        IHKIRL - TO INSERT, REPLACE LINES IN THE ACTIVE FILE, DELETE * 03640019
*        SUBCOMMAND PROCESSOR, AND TO CREATE ACTIVE FILE AND DIRECTORY* 03710019
*        ENTRY                                                        * 03780019
*        IHKIRL01 - TO PROCESS IMPLICIT COMMAND, AN INPUT SUBCOMMAND  * 03850019
*        WITH NO OPERANDS, AND A NULL LINE IN EDIT MODE               * 03920019
*        IHKIRL02 - TO PROCESS A NULL LINE IN CORRECTION MODE         * 03990019
*INPUT                                                                * 04060019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING THE * 04130019
*   ADDRESSES OF THE TUB AND AVT                                      * 04200019
*OUTPUT                                                               * 04270019
*   N/A                                                               * 04340019
*EXTERNAL REFFERENCES                                                 * 04410019
*        IHKLAD - TO PROMPT USER FOR INPUT LINES                      * 04480019
*        IHKSYN - TO PASS LINES TO SYNTAX CHECKERS                    * 04550019
*        IHKAFI - TO MANIPULATE ACTIVE FILE                           * 04620019
*        IHKMSG - TO QUEUE AND SEND MESSAGES                          * 04690019
*EXITS, NORMAL                                                        * 04760019
*   RETURN TO CALLING ROUTINE WITH ZERO IN REGISTER 15                * 04830019
*EXITS, ERROR                                                         * 04900019
*   RETURN TO CALLING ROUTINE WITH ONE OF THE FOLLOWING RETURN CODES  * 04970019
*   IN REGISTER 15                                                    * 05040019
*   4  - LINE ERROR                                                   * 05110019
*   8  - GETMAIN FAILURE                                              * 05180019
*   12 - ACTIVE AREA I/O ERROR                                        * 05250019
*   16 - MESSAGE LOST                                                 * 05320019
*   20 - ACTIVE AREA OUT OF SPACE                                     * 05390019
*TABLES/WORK AREAS                                                    * 05460019
*   AVT                                                               * 05530019
*   18 WORD SAVE AREA                                                 * 05600019
*   TUB                                                               * 05670019
*   TUBDIRAD - DIRECTORY ENTRY ADDRESS                                * 05740019
*   TUBSCN - SYNTAX SCAN REQUESTED                                    * 05810019
*   TUBFOR - ACTIVE FILE HAS FORTRAN ATTRIBUTE                        * 05880019
*   TUBPL1 - ACTIVE FILE HAS PL/1 ATTRIBUTE                           * 05950019
*   TUBCORCN - SYNTAX ERRORS CORRECTED                                * 06020019
*   TUBCORRN - SYNTAX ERRORS OCCURRED                                 * 06090019
*   TUBIRLSA - ADDRESS OF IHKSYN PARAMETERS                           * 06160019
*   TUBTEXTN - UPPER/LOWER CASE PRESIVATION                           * 06230019
*   TUBDATAL - LINE LENGTH                                            * 06300019
*   TUBLNPMT - LINE NUMBER PROMPTS REQUESTED                          * 06370019
*   TUBLNUMN - LINE NUMBERS CONTAINED IN LINE                         * 06440019
*   TUBNXKEY - ACTIVE FILE POINTER                                    * 06510019
*   TUBPRMLS - PARAMETER AREA                                         * 06580019
*   TUBRAFBF - IHKAFI BUFFER ADDRESS                                  * 06650019
*   TUBUFFAD - USER BUFFER ADDRESS                                    * 06720019
*   USER BUFFER - USED AS IHKAFI BUFFER                               * 06790019
*   PPT - CONTAINS DELETE AND IMPLICIT SUBCOMMANDS                    * 06860019
*   DIRECTORY ENTRY                                                   * 06930019
*   CCT                                                               * 07000019
*   CCTPL1 - PL/1 SYNTAX CHECKER IN SYSTEM                            * 07070019
*   CCTFOR - FORTRAN SYNTAX CHECKER IN SYSTEM                         * 07140019
*ATTRIBUTES                                                           * 07210019
*   REENTRANT AND RESIDENT                                            * 07280019
*********************************************************************** 07350019
IHKIRL   CSECT                                                          07420019
*                                                                       07490019
BASE     EQU   11                                                       07560019
KBXRG    EQU   6                                                        07630019
REG0     EQU   0                                                        07700019
REG1     EQU   1                                                        07770019
REG2     EQU   2                                                        07840019
REG3     EQU   3                                                        07910019
REG4     EQU   4                                                        07980019
REG5     EQU   5                                                        08050019
REG6     EQU   6                                                        08120019
REG7     EQU   7                                                        08190019
REG8     EQU   8                                                        08260019
REG9     EQU   9                                                        08330019
REG10    EQU   10                                                       08400019
REG11    EQU   11                                                       08470019
REG12    EQU   12                                                       08540019
REG13    EQU   13                                                       08610019
REG14    EQU   14                                                       08680019
REG15    EQU   15                                                       08750019
         SPACE 3                                                        08820019
*********************************************************************** 08890019
*          INITILIZATION                                                08960019
*********************************************************************** 09030019
         SPACE 1                                                        09100019
         SAVE  (14,12),,IRL72060        SAVE CALLER'S REGS       A47928 09170000
         LR    BASE,15                  LOAD BASE REGISTER              09240019
         USING IHKIRL,BASE              ESTABLISH ADDRESSABILITY        09310019
         L     REG5,0(REG1)                                             09380019
         USING TUBDSECT,REG5            ESTABLISH ADDRBLTY FOR TUB      09450019
         L     REG8,4(REG1)             ESTABLISH ADDRBLTY FOR AVT      09520019
         USING AVTDSECT,REG8                                            09590019
         L     REG1,IHKYYGML            GET ADDRESS OF GETMAIN LIST     09660019
         LA    REG2,TUBPARM1            GET ADDRESS FOR GETMAIN         09730019
         GETMAIN EC,LV=GMLEN,A=(REG2),MF=(E,(1))  GET AREA              09800019
         LTR   REG15,REG15              TEST RETURN                     09870019
         BNZ   GMERR                    IF CORE NOT AVAIBLE, ENQ MSG    09940019
         L     REG2,TUBPARM1            GET AREA ADDRESS                10010019
         ST    REG13,4(REG2)            STANDARD LINKAGE                10080019
         ST    REG2,8(REG13)                                            10150019
         LR    REG13,REG2                                               10220019
         USING VDSECT,REG13             ESTABLISH ADDRBLTY FOR DSECT    10290019
GMGOOD   L     REG1,24(REG13)           RESTORE PARAMETER REGISTER      10360019
         L     REG3,TUBPPTAD                                            10430019
         USING IRLPARMS,REG3            EST ADDRBLTY FOR IPT PARMS      10500019
         NI    IRLSW2,IRL2OFF           TURN OFF ALL SWITCHES           10570019
         NI    DELSW,DELOFF             TURN OFF DELETE SWEICHES        10640019
         CLI   IRLPARMS+5,CMDDTE        TEST FOR DELETE COMMAND         10710019
         BE    DELPROC                  IF YES, PROCESS                 10780019
         TM    IRLSW,IRLEDT             TEST IF FROM EDIT               10850019
         BZ    NOTEDT                   IF NOT, SKIP DIRECTORY CREATION 10920019
         SPACE 3                                                        10990019
*********************************************************************** 11060019
*          CREATE ACTIVE FILE                                           11130019
*********************************************************************** 11200019
         SPACE 1                                                        11270019
         LA    REG1,40(REG13)           BUILD PARM LIST FOR IHKAFI      11340019
         CREATE IS                      CREATE ACTIVE FILE              11410019
         C     REG15,F4                 TEST RETURN CODE                11480019
         BE    OUTSPAA1                 IF A.A. OUT OF SPACE, ENQ MSG   11550019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   11620019
         LA    REG1,40(REG13)           BUILD PARM LIST FOR IHKAFI      11690019
         MVI   TUBNXKEY+7,X00                                           11760019
         RPOINT B,NR                    POSITION TO BEGNING OF FILE     11830019
         C     REG15,F4                 TEST RETURN CODE                11900019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   11970019
*                                                                       12040019
*   GET CORE FOR DIRECTORY ENTRY                                        12110019
*                                                                       12180019
         LA    REG4,TUBDIRAD            SET UP TO GET CORE FOR          12250019
         L     REG1,IHKYYGML            DIRECTORY ENTRY                 12320019
         GETMAIN EC,LV=DIRSIZE,A=(REG4),MF=(E,(1))  GET CORE            12390019
         LTR   REG15,REG15              TEST RETRUN CODE                12460019
         BNZ   GMFAIL                   IF BAD, RETURN                  12530019
         L     REG4,TUBDIRAD            ESTABLISH ADDRESSABILITY FOR    12600019
         USING DIRDSECT,REG4            DIRECTORY ENTRY                 12670019
         DROP  REG3                                                     12740019
         USING PPTDSECT,REG3                                            12810019
         SPACE 1                                                        12880019
*********************************************************************** 12950019
*           ROUTINE TO CREATE DIRECTORY ENTRY FOR NEW DATA SET          13020019
*********************************************************************** 13090019
         SPACE 1                                                        13160019
NEWDIREC MVC   DIRFNAME,TUBPMFNM        PUT DSNAME IN DIREDTORY         13230019
         TM    PPTFLG,PPTOS             TEST FOR OS DATA SET            13300019
         BZ    DIRPROC1                 IF NOT, DONT BLANK OUT DSNAME   13370019
         MVC   DIRFNAME,BLANK           BLANK OUT DSNAME                13440019
DIRPROC1 TIME  ,                        GET CREATION DATE               13510019
         ST    REG1,DIRINC              STORE CREATION AND LAST         13580019
         MVC   DIRCRE,DIRINC+1          MODIFIED DATES                  13650019
         MVC   DIRMODAT,DIRINC+1                                        13720019
         MVI   DIRUILEN,UILEN           PUT LENGTH IN DIRECTORY         13790019
         L     REG1,ZEROS                                               13860019
         STC   REG1,DIRATTRO            INITILIZE ATTRIBUTES            13930019
         STH   REG1,DIRSAV              INITILIZE SAVE COUNTER          14000019
         MVC   DIRPL1BS(2),DIRSAV       INIT PL/1 AND FORTRAN ATTR      14070019
         TM    PPTPARS,DEFENUM          TEST FOR LINE NOS IN LINE       14140019
         BZ    DIRPNLO                  IF NOT, DON'T SET SWITCHES      14210019
         OI    TUBFLG2,TUBLNUMN         SET SWITCH IN TUB               14280019
         OI    DIRATTRO,DIROLNO         SET BIT FOR LINE NOS IN LINE    14350019
DIRPNLO  TM    PPTFLG,PPTKEY            TEST FOR KEY STORED             14420019
         BZ    DIRNKEY                  IF NOT BLANK OUT KEY AREA       14490019
         L     REG1,TUBUFFAD            GET ADDRESS OF EDIT SWITCHES    14560019
         MVC   DIRKEY,48(REG1)          PUT KEY IN DIRECTORY            14630019
         B     DIRIINC                  CONTINUE                        14700019
DIRNKEY  MVC   DIRKEY,BLANK             CLEAR OUT KEY AREA              14770019
DIRIINC  L     REG15,IHKYYDEF           ESTABLISH ADDRBLTY FOR DEF      14840019
         USING DEFDSECT,REG15                                           14910019
         L     REG2,DEFINCRE            GET DEFAULT INCREMENT           14980019
         ST    REG2,DIRINC              PUT INCREMENT INTO DIRECTORY    15050019
         ST    REG2,PPTINC              SAVE INCREMENT                  15120019
         DROP  REG15                                                    15190019
         L     REG14,TUBUFFAD           GET WORK AREA ADDRESS           15260019
         LA    REG14,80(REG14)                                          15330019
         CVD   REG2,0(REG14)                                            15400019
         UNPK  TUBNXKEY,0(8,REG14)      PUT STARTING LINE NO INTO TUB   15470019
         OI    TUBNXKEY+7,XF0           PUT NUMERIC ZONE IN LAST BYTE   15540019
*                                                                       15610019
*   SET DIRECTORY ATTRIBUTES                                            15680019
*                                                                       15750019
SETDIRAT MVC   DIRATTRL(1),PPTPARS+1    OR OLD WITH ATTR SPECIFIED      15820019
         TM    DIRATTRL,DIRPL1          TEST FOR PL/1                   15890019
         BZ    ATNPL1                   IF NOT, CHECK FOR FORTRAN       15960019
         MVC   DIRPL1BS(2),PPTPARS+2    PUT PL/1 SOURCE MARGINS IN DIR  16030019
SETUBPL1 OI    TUBFLG1,TUBPL1           SET PL/1 SW IN TUB              16100019
         TM    PPTPARS,DEFPL148         IS THIS PL1 WITH 48 CHAR SET    16170019
         BZ    SETSCAN                  NO, TEST FOR SCAN REQUESTED     16240019
         OI    DIRATTRL,DIRPL148        YES, SET 48 CHAR BIT IN TUB     16310019
         B     SETSCAN                  CONTINUE                        16380019
ATNPL1   TM    DIRATTRL,DIRFORTH        TEST FOR FORTRAN ATTRIBUTE      16450019
         BZ    DIRRTN                   IF NOT TEST FOR SCAN            16520019
         OI    TUBFLG1,TUBFOR           SET FORTRAN SW IN TUB           16590019
SETSCAN  TM    PPTPARS,DEFESCAN         TEST FOR SCAN SPECIFIED         16660019
         BZ    DIRRTN                                                   16730019
         OI    TUBFLG1,TUBSCN     YES - IS PL0U OR FORTRAN              16800019
         B     DIRRTN                                                   16870019
*                                                                       16940019
DIRRTN   TM    PPTFLG,PPTOS             TEST FOR OS DATA SET            17010019
         BO    RETURN                   IF YES, RETURN                  17080019
         NI    PPTFLG,PPTOFF            TURN OFF PPT SWITCHES           17150019
         OI    PPTFLG,PPTINS            SET INSERT ONLY SW              17220019
         OI    IRLSW2,IRLNOLIM          SET NO MAX LINE NUMBER SWITCH   17290019
         DROP  REG3                                                     17360019
         USING IRLPARMS,REG3                                            17430019
         SPACE 1                                                        17500019
*********************************************************************** 17570019
         SPACE 3                                                        17640019
*********************************************************************** 17710019
*          SET UP FOR SYNTAX SCAN                                       17780019
*********************************************************************** 17850019
         SPACE 1                                                        17920019
NOTEDT   BAL   REG12,SETUPSCN           SET UP FOR SCAN IF NECESSARY    17990019
         SPACE 3                                                        18060019
*********************************************************************** 18130019
*          CHECK PARAMETERS FROM IHKIPT                                 18200019
*********************************************************************** 18270019
         SPACE 1                                                        18340019
NOSNGM   OI    IRLSW,IRLFST             SET FIRST TIME SWITCH           18410019
         TM    IRLSW,IRLIPT             TEST IF FROM INPUT COMMAND      18480019
         BZ    TSTPMT                   IF NOT, PROMPT USERFOR LINE     18550019
         TM    IRLSW,IRLINS             TEST FOR INSERT ONLY            18620019
         BZ    TSTPMT                   IF NOT CONTINUE PROCESSING      18690019
         L     REG2,TUBUFFAD            GET SAVE AREA ADDRESS           18760019
         MVC   0(8,REG2),TUBNXKEY       SAVE LINE NO                    18830019
         LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     18900019
         RPOINT A,NR,KEY=HIEQ           POINT AFTER LAST RECORD         18970019
         C     REG15,F4                 TEST RETURN CODE                19040019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   19110019
         LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     19180019
         RGET  XK,S,B                   RETREVE NEXT LINE NO            19250019
         C     REG15,F4                 TEST RETURN CODE                19320019
         BE    SETNOLIM                 IF EOD, SET NO LIMIT SW         19390019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   19460019
         MVC   IRLMAX,TUBNXKEY          SAVE MAX KEY                    19530019
         TM    TUBFLG1,TUBSCN           TEST FOR SCAN REQUESTED         19600019
         BZ    RESKEY                   IF NOT, SKIP SAVING MAX KEY     19670019
         USING CORDSECT,REG10                                           19740019
         MVC   CORMAX,TUBNXKEY          SAVE MAX LINE NO                19810019
RESKEY   MVC   TUBNXKEY,0(REG2)         RESTORE ORIGONAL LINE NO        19880019
         SPACE 3                                                        19950019
*********************************************************************** 20020019
*           END OF INITILIZATION                                        20090019
*********************************************************************** 20160019
         EJECT                                                          20230019
*********************************************************************** 20300019
*          PROMPT USER FOR LINE                                         20370019
*********************************************************************** 20440019
         SPACE 1                                                        20510019
TSTPMT   LA    REG1,40(REG13)           BUILD PARM LIST FOR IHKAFI      20580019
*    INSURE ALL PENDING UPDATES ARE DONE                                20650019
         ENDUP                                                          20720019
         L     REG15,TUBDIRAD           SET UP ADDRESSABILITY FOR       20790019
         USING DIRDSECT,REG15             DIRECTORY ENTRY               20860019
         TM    DIRATTRL,DIRATEXT        TEST FOR TEXT ATTRIBURE         20930019
         BZ    TSTPMT1                  IF NOT, DONT SET TEXT SW        21000019
         OI    TUBREQST,TUBTEXTN        SET TEXT FLAG FOR LINE ADMIN.   21070019
         DROP  REG15                                                    21140019
TSTPMT1  TM    TUBFLG3,TUBLNPMT         TEST FOR LINE NO PROMPTS REQ    21210019
         BZ    NOPMT                    IF NOT, READ FROM LINE          21280019
         L     REG2,TUBUFFAD            SET UP TO ISSUE PROMPT          21350019
         LA    REG2,0(REG2)             ELEMINATE HIGH ORDER BITS       21420019
         MVC   0(8,REG2),TUBNXKEY       PUT LINE NO INTO BUFFER         21490019
         MVC   8(2,REG2),BLANK                                          21560019
         BAL   REG14,ELEM0              ELEMINATE LEADING 0S            21630019
         LH    REG2,H10                                                 21700019
         STH   REG2,TUBDATAL                                            21770019
         OI    TUBFLG3,TUBNOCRN         TURN ON NO CARRIR RET BIT       21840019
         LA    REG15,TUBDSECT                                           21910019
         CWRITE R                       ISSUE PROMPT                    21980019
TSTRD    LTR   REG15,REG15              TEST RETURN                     22050019
         BNZ   PMTERR                   IF ERROR, RETURN                22120019
         L     REG2,ZEROS                                               22190019
         CH    REG2,TUBDATAL            TEST FOR CR                     22260019
         BE    SETRET                   IF YES RETURN                   22330019
TSTFORT  TM    TUBFLG1,TUBFOR           TEST FOR FORTRAN ATTR           22400019
         BO    SCNPROC                  IF YES PROCESS LINE             22470019
         TM    TUBFLG1,TUBPL1           TEST FOR PL1 ATTRIBUTE          22540019
         BO    SCNPROC                  PROCESS PL/1 LINE               22610019
         SPACE 3                                                        22680019
*********************************************************************** 22750019
*          PUT LINE INTO ACTIVE FILE                                    22820019
*********************************************************************** 22890019
         SPACE 1                                                        22960019
RETFORT  LH    REG2,TUBDATAL            GET ADDRESS OF END OF TEXT      23030019
         L     REG15,TUBUFFAD                                           23100019
         AR    REG2,REG15                                               23170019
         LH    REG14,TUBDATAL           GET LENGTH OF TEXT              23240019
         LH    REG15,H80                                                23310019
         SR    REG15,REG14                                              23380019
         TM    TUBFLG2,TUBLNUMN         TEST FOR LINE NOS IN LINE       23450019
         BZ    TST80                    IF NOT, TEST FOR 80 CHAR        23520019
         CLC   TUBDATAL,H72             TEST FOR LINE TOO LONG          23590019
         BNH   LENOK1                   IF NOT, CONTINUE                23660019
         OI    IRLSW2,IRLENER           SET LENGTH ERR SW               23730019
         B     LENOK1                   CONTINUE                        23800019
TST80    CLC   TUBDATAL,H80             TEST FOR LINE TOO LONG          23870019
         BNH   LENOK1                   IF NOT, CONTINUE                23940019
         OI    IRLSW2,IRLENER           SET LENGTH ERR SW               24010019
LENOK1   CH    REG15,ZEROS              TEST FOR MAX LINE               24080019
         BNH   LENOK                    IF YES, DONT INSERT BLANKS      24150019
         BCTR  REG15,0                  SET UP LENGTH FOR EX INST       24220019
         MVI   0(REG2),BLK              INSERT BLANKS                   24290019
         EX    REG15,MVCBLK                                             24360019
LENOK    L     REG2,TUBUFFAD                                            24430019
         MVC   86(50,REG2),30(REG2)     MOVE DATA                       24500019
         MVC   56(30,REG2),0(REG2)                                      24570019
         MVC   16(80,REG2),56(REG2)                                     24640019
         MVC   8(8,REG2),TUBNXKEY       PUT LINE NO IN KEY AREA         24710019
         TM    TUBFLG2,TUBLNUMN         TEST FOR LINE NOS IN LIEN       24780019
         BZ    NOLNO                    IF NOT, CONTINUE                24850019
         MVC   88(8,REG2),8(REG2)       PUT LINE NO INTO LAST 8 BYTES   24920019
NOLNO    OI    TUBAFISW,TUBFCTLN        SET BUFFER CONTROL SW           24990019
         MVC   TUBRAFBF,TUBUFFAD        SET UP BUFFER ADDR FOR IHKAFI   25060019
         TM    IRLSW,IRLREP+IRLREP2     TEST REPLACE SW                 25130019
         BNZ   REPONLY                  IF SET REPLACE LINE             25200019
         LA    REG1,40(REG13)           BUILD PARM LIST FOR IHKAFI      25270019
         RPOINT A,NR,KEY=HIEQ           POINT BEFORD LINE               25340019
         C     REG15,F4                 TEST RETURN CODE                25410019
         BH    RETURN1                  IF ERROR, RETURN                25480019
         LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     25550019
         INSERT S,A                     INSERT LINE                     25620019
         C     REG15,F4                 TEST RETURN CODE                25690019
         BE    OUTSPAA                  IF A.A.OUT OF SPACE, RETURN     25760019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   25830019
INSGOOD  TM IRLSW2,IRLENER              TEST FOR LENGTH ERR             25900019
         BZ    NOERR                    IF NOT, CONTINUE                25970019
         BAL   REG7,LENERR              SEND ERR MSG                    26040019
NOERR    TM    IRLSW2,IRL1LN            TEST FOR 1 LINE ONLY            26110019
         BO    RETURN                   IF YES, RETURN                  26180019
         TM    TUBFLG1,TUBSCN           TEST FOR SYNTAX SCAN REQUESTED  26250019
         BO    SYNSCN                   IF YES PASS LINE TO SCAN        26320019
SYNRET   TM    IRLSW,IRLREP             TEST REPLACE SW                 26390019
         BO    TSTPMT                   IF SET GET NEXT LINE            26460019
         SPACE 3                                                        26530019
*********************************************************************** 26600019
*          CALCULATE NEXT LINE NUMBER AND SET UP TO PROCESS NEXT LINE   26670019
*********************************************************************** 26740019
         SPACE 1                                                        26810019
CALCLNO  L     REG15,TUBUFFAD           GET WORK AREA ADDRESS           26880019
         PACK  0(8,REG15),TUBNXKEY      CALC NEXT LINE NO               26950019
         CVB   REG2,0(REG15)                                            27020019
         A     REG2,IRLINC                                              27090019
         C     REG2,F9S                TEST FOR MAX LINE NO             27160019
         BH   MAXLNO                    IF YES, ENQUEUE ERR MSG         27230019
         CVD   REG2,0(REG15)            STORE NEXT LINE NO              27300019
         UNPK  TUBNXKEY,0(8,REG15)                                      27370019
         OI    TUBNXKEY+7,XF0                                           27440019
         TM    IRLSW,IRLIPT             TEST IF ENTERED FROM INPUT PROC 27510019
         BZ    TSTPMT                   IF NOT, PROMPT FOR NEXT LINE    27580019
         NI    IRLSW,IRLREP2F           TURN OFF REPLACE LINE SW        27650019
         LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     27720019
         ENDUP                                                          27790019
         LTR   REG15,REG15              TEST RETURN CODE                27860019
         BC    7,RETURN                 IF I/O OR GETMAIN ERR, RETURN   27930019
         TM    IRLSW,IRLINS             TEST IF INSERT ONLY             28000019
         BO    TSTMAX                   IF YES, TEST MAX LINE NO        28070019
*                                                                       28140019
NOTMAX   LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     28210019
         RPOINT B,NR                    POINT TO NEXT LINE              28280019
         C     REG15,F4                 TEST RETURN CODE                28350019
         BE    PNTHIEQ                  IF LINE NOT FOUND, FIND PREV    28420019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   28490019
         TM    IRLSW,IRLINS             TEST FOR INSERT ONLY            28560019
         BO    LINEXMSG                 IF YES, ENQUEUE MSG AND RETURN  28630019
         OI    IRLSW,IRLREP2            SET REPLACE LINE SWITCH         28700019
         B     TSTPMT                   IF NOT GET NEXT LINE            28770019
PNTHIEQ  LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     28840019
         RPOINT A,NR,KEY=HIEQ           POINT AFTER PREVIOUS RECORD     28910019
         C     REG15,F4                 TEST RETURN CODE                28980019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   29050019
         B     TSTPMT                   GET NEXT LINE                   29120019
         SPACE 3                                                        29190019
*********************************************************************** 29260019
*          GET LINE FROM USER (NO PROMPT)                               29330019
*********************************************************************** 29400019
         SPACE 1                                                        29470019
NOPMT    LA    REG15,TUBDSECT           PUT ADDR OF TUB INTO PARM REG   29540019
         CREAD                                                          29610019
         B     TSTRD                    TEST RETURN                     29680019
TSTMAX   TM    IRLSW2,IRLNOLIM          TEST FOR NO LINE NO LIMIT       29750019
         BO    NOTMAX                   IF YES, CONTINUE PROCESSING     29820019
         CLC   TUBNXKEY,IRLMAX          TEST FOR MAX LINE NO EXCEEDED   29890019
         BL    NOTMAX                   IF NOT CONTINUE PROCESSING      29960019
         B     LINEXMSG                 IF YES, SEND MSG AND RETURN     30030019
SETNOLIM OI    IRLSW2,IRLNOLIM          SET NO LIMIT SWITCH             30100019
         B     TSTPMT                   CONTINUE PROCESSING             30170019
         SPACE 3                                                        30240019
*********************************************************************** 30310019
*          CHECK LINE FOR CONTINUATION CHARACTER                        30380019
*********************************************************************** 30450019
         SPACE 1                                                        30520019
SCNPROC  LH    REG2,TUBDATAL            FIND LAST CHAR OF LINE          30590019
         L     REG4,TUBUFFAD                                            30660019
         AR    REG4,REG2                                                30730019
         BCTR  REG4,0                                                   30800019
         CLI   0(REG4),CONTCH           TEST FOR CONTINUATION CHAR      30870019
         BNE   CONTOFF                  IF NOT, TURN OFF CONT SWITCH    30940019
         MVI   0(REG4),BLK              BLANK OUT CONTINUATION CH       31010019
         SH    REG2,H1                                                  31080019
         STH   REG2,TUBDATAL                                            31150019
         OI    IRLSW,IRLCONT            SET CONTINUATION SWITCH         31220019
         B     RETFORT                                                  31290019
CONTOFF  NI    IRLSW,IRLCONTF           TURN OFF PL/1 CONT SW           31360019
         B     RETFORT                  CONTINUE PROCESSING             31430019
         SPACE 3                                                        31500019
*********************************************************************** 31570019
*          REPLACE LINE IN ACTIVE FILE                                  31640019
*********************************************************************** 31710019
         SPACE 1                                                        31780019
REPONLY  LA    REG1,40(REG13)           BUILD PARM LIST FOR IHKAFI      31850019
         RPOINT B,NR                    POINT BEFORE LINE NUMBER        31920019
         LTR   REG15,REG15              TEST RETURN CODE                31990019
         BNZ   RETURN1                  IF ERROR, RETURN                32060019
         TM    IRLSW,IRLREP2            TEST FOR REPLACE THIS LINE ONLY 32130019
         BO    REPONLY1                 IF YES, REPLACE WITHOUT         32200019
*                                       LINE NUMBER RETREVIAL           32270019
         LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     32340019
         REPLACE XK                     REPLACE RECORD                  32410019
REPONLY2 C     REG15,F4                 TEST RETURN CODE                32480019
         BL    INSGOOD                  IF GOOD, CONTINUE               32550019
         BE    EOD2                     IF EOD, ENQUEUE MESSAGE         32620019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   32690019
REPONLY1 LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     32760019
         REPLACE NXK                    REPLACE LINE, NO KEY RETREIVAL  32830019
         B     REPONLY2                 TEST RETURN CODE                32900019
         SPACE 3                                                        32970019
*********************************************************************** 33040019
*          END OF DATA ON REPLACE                                       33110019
*********************************************************************** 33180019
         SPACE 1                                                        33250019
EOD      TM    IRLSW2,IRL1LN            TEST FOR IMPLICIT CMD           33320019
         BO    INSGOOD                  IF YES RETURN                   33390019
         TM    DELSW,DEL1LN             TEST FOR DELETE 1 LINE          33460019
         BO    RETURN                   IF YES, RETURN                  33530019
         CLI   IRLPARMS+5,CMDDTE        TEST FOR DELETE COMMAND         33600019
         BNE   EOD1                     IF NOT, ENQUEUE EOD MESSAGE     33670019
         L     REG15,TUBUFFAD                                           33740019
         CLC   TUBNXKEY,8(REG15)        TEST FOR EOD BEFORE END RANGE   33810019
         BNL   RETURND                  IF YES, RETURN                  33880019
EOD1     LA    REG6,EODCD               SET UP PARAMETER LIST FOR EOD   33950019
         BAL   REG9,CALLMSG1            ENQUEUE MSG FOR USER            34020019
         CLI   IRLPARMS+5,CMDDTE        TEST FOR DELETE                 34090019
         BE    RETURND                  IF YES, RETURN                  34160019
         B     SETRET                   RETURN                          34230019
EOD2     TM    IRLSW,IRLREP             TEST REPLACE SWITCH             34300019
         BZ    INSGOOD                  IF NOT SET, CONTINUE            34370019
         B     EOD                      IF SET, ENQUEUE EOD MESSAGE     34440019
         SPACE 3                                                        34510019
*********************************************************************** 34580019
*          PROCESS LINES FOR SYNTAX SCAN                                34650019
*********************************************************************** 34720019
         SPACE 1                                                        34790019
SYNSCN   TM    TUBFLG3,TUBCORRN         TEST FOR CORRECTION MODE        34860019
         BO    RETURN                   RETURN IF SET                   34930019
         TM    IRLSW,IRLFST             TEST FOR 1ST LINE AFTER SCAN    35000019
         BO    SYNFST                   IF YES STORE 1ST LINE NO        35070019
SYNPBLD  MVC   CORCUR,TUBNXKEY          PUT LINE NO INTO INTFCE PARM    35140019
         LH    REG15,CORCTR                                             35210019
         LA    REG15,1(REG15)           INCREMENT CONT LINE COUNTER     35280019
         STH   REG15,CORCTR             STORE NEW COUNTER VALUE         35350019
         TM    IRLSW,IRLCONT            TEST FOR CONTINUATION LINE      35420019
         BO    SYNMAXT                  IF YES, TEST FOR MAX LINES      35490019
SYNPBLD1 L     REG12,IHKYYKBX           GET ADDRESS OF KONBOX           35560019
         USING RAFKNBX,REG12            SET UP ODDRESSABILITY           35630019
         LA    REG1,SYNQCTEL            SET UP TO ENQUEUE FOR SCAN      35700019
         ST    REG1,TUBPARM4            INTERFACE                       35770019
         LA    REG1,QEL                                                 35840019
         ST    REG1,TUBPARM3                                            35910019
         MVI   QEL+4,X00                                                35980019
         LA    REG1,TUBPARM3            GET PARM LIST ADDRESS           36050019
         L     REG15,IHKYYRNQ           GET ADDRESS OF QUEUEING ROUTINE 36120019
         BALR  REG14,REG15              ENQUEUE FOR INTERFACE           36190019
         LTR   REG15,REG15              TEST RETURN CODE                36260019
         BNZ   GMFAIL                   IF GETMAIN FAILED, RETRUN       36330019
         NI    TUBAFISW,TUBFCTLF        TURN OFF BUFFER CNTL SW         36400019
         LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKSYN     36470019
         L     REG15,IHKYYSYN                                           36540019
         BALR  REG14,REG15              PASS LINE TO SCAN               36610019
         L     REG14,QEL                GET POINTER TO NEXT Q ELEMENT   36680019
         ST    REG14,SYNQCTEL           POINT CNTRL ELEMENT FO NEXT EL. 36750019
         LA    REG14,0(REG14)           CLEAR HIGH ORDER BYTE           36820019
         LA    REG1,SYNQCTEL+4                                          36890019
         CR    REG14,REG1               TEST FOR LAST ELEMENT           36960019
         BE    SYNRTST                  IF YES, DON'T POST              37030019
         OI    4(REG14),BLK             POST NEXT ELEMENT READY         37100019
SYNRTST  B     *+4(REG15)               TEST RETURN CODE FROM IHKSYN    37170019
         B     SETFST                   SET FIRST LINE SW IF GOOD       37240019
         B     RETURN                   IF ERROR, RETURN                37310019
         B     GMERR                    IF GETMAIN FAILED, RETURN       37380019
         B     RETURN1                  RETURN IF AA I/O ERROR          37450019
         B     RETURN1                  RETURN IF MESSAGE LOST          37520019
         B     SYNLEVER                 IF LEVEL OF CKR WRONG, RETURN   37590019
SETFST   OI    IRLSW,IRLFST             SET 1ST LINE SW                 37660019
         MVC   TUBNXKEY,CORCUR          RESTORE KEY AREA OF TUB         37730019
         LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     37800019
         RPOINT A,NR                    POINT AFTER LAST LINE           37870019
         C     REG15,F4                 TEST RETURN CODE                37940019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   38010019
         B     SYNRET                   GET NEXT LINE                   38080019
SYNFST   MVC   CORFST,TUBNXKEY          PUT 1ST LINE NO INTO INTFC LST  38150019
         L     REG15,ZEROS              INITILIZE CTR FOR IHKSYN        38220019
         STH   REG15,CORCTR                                             38290019
         NI    IRLSW,IRLNFST            RESET 1ST LINE SW               38360019
         B     SYNPBLD                  CONTINUE                        38430019
SYNATERR NI    TUBFLG1,TUBSCNF          RESET SCAN REQ SW               38500019
         LA    REG6,INVATRCD            BUILD PARM LIST FOR ATTR INV    38570019
         BAL   REG9,SNDMSG              SEND MESSAGE TO USER            38640019
         BR    REG12                    CONTINUE                        38710019
SYNMAXT  L     REG15,IHKYYCCT           SET UP ADDRESSABILITY FOR CCT   38780019
         USING CCTDSECT,REG15                                           38850019
         TM    TUBFLG1,TUBFOR           TEST FOR FORTRAN SCAN           38920019
         BZ    SYNMAXT1                 IF NOT, TEST MAX PL/1 LINES     38990019
         CLC   CORCTR,CCTFRTMX          TEST FOR MAX NO OF LINES        39060019
         BL    SYNRET                   IF NOT, CONTINUE PROCESSING     39130019
SYNMAXT2 LA    REG6,MAXSCNCD             SET UP PARAMETER LIST FOR      39200019
         LA    REG9,18                     IHKMSG01 TO SEND LINES NOT   39270019
         STC   REG9,MSGP2L                 SCANNED MESSAGE              39340019
         MVC   MSGP2C(8),CORFST                                         39410019
         LA    REG2,MSGP2C              ELEMINATE LEADING 0S IN LINE    39480019
         BAL   REG14,ELEM0              NUMBER                          39550019
         MVC   MSGP2C+10(8),CORCUR      MOVE CURRENT LINE NO TO PARM    39620019
         LA    REG2,MSGP2C+10           ELEMINATE LEADING 0S IN LINE    39690019
         BAL   REG14,ELEM0              NUMBER                          39760019
         MVC   MSGP2C+8(2),BLANK                                        39830019
         LA    REG15,MSGP2L                                             39900019
         BAL   REG9,SNDMSG2             SEND MESSAGE                    39970019
         B     SYNPBLD1                 SCAN LINES                      40040019
SYNMAXT1 CLC   CORCTR,CCTPL1MX          TEST FOR MAX NO OF LINES        40110019
         BL    SYNRET                   IF NOT, CONTINUE PROCESSING     40180019
         B     SYNMAXT2                 IF YES, ENQ MSG AND SCAN        40250019
SYNLEVER NI    TUBFLG1,TUBSCNF          TURN OFF SCAN FLAG              40320019
         B     SETRET                   RETURN                          40390019
         DROP  REG15                                                    40460019
         SPACE 3                                                        40530019
*********************************************************************** 40600019
*          ELEMINATE LEADING 0S                                         40670019
*********************************************************************** 40740019
         SPACE 1                                                        40810019
ELEM0    LH    REG9,H6                  SET UP TO BLANK OUT LEADING 0'S 40880019
         LR    REG12,REG2                 IN LINE NO                    40950019
COMPLZ   CLI   0(REG12),ZERO            TEST FOR 0                      41020019
         BNE   REPLZ                    IF NOT REPLACE LEADING 0S       41090019
         LA    REG12,1(REG12)           INCREMENT TO NEXT NUMBER        41160019
         BCT   REG9,COMPLZ              IF LAST CONTINUE                41230019
REPLZ    CR    REG12,REG2               TEST FOR KEY ALL NONZERO        41300019
         BE    0(REG14)                 IF IT IS, EXIT                  41370019
         SR    REG12,REG2                                               41440019
         BCTR  REG12,0                  SET UP LENGTH FOR EX INST       41510019
         EX    REG12,INSLZ              BLANK OUT LEADING 0'S           41580019
         BR    REG14                    EXIT                            41650019
         SPACE 3                                                        41720019
*********************************************************************** 41790019
*          CHECK FOR SYNTAX SCAN TO BE INVOKED, AND IF IT IS, SET UP    41860019
*          FOR IT                                                       41930019
*********************************************************************** 42000019
         SPACE 1                                                        42070019
SETUPSCN TM    TUBFLG1,TUBSCN           TEST FOR SYNTAX SCAN REQUESTED  42140019
         BZ    0(REG12)                 IF NOT SKIP SCAN GETMAIN        42210019
         L     REG4,IHKYYCCT            GET ADDRESS OF CRJE CNTRL TABLE 42280019
         USING CCTDSECT,REG4            SET UP ADDRESSABILITY FOR CCT   42350019
         TM    TUBFLG1,TUBPL1           TEST FOR PL/1 ATTRIBUTE         42420019
         BZ    NOTPL1                   IF NOT, TEST FOR FORTRAN ATTR   42490019
         TM    CCTOPT,CCTPL1            TEST FOR PL/1 SYNTAX CHECKER    42560019
         BZ    SYNCHERR                 IF NONE SEND ERROR MSG          42630019
         B     GETSCNA                  GET AREA FOR SCAN PARM LIST     42700019
NOTPL1   TM    TUBFLG1,TUBFOR           TEST FOR FORTRAN ATTRIBUTE      42770019
         LA    REG15,MSGP2C             GET ADDRESS OF 2ND PARM         42840019
         BZ    SYNATERR                 IF NOT SEND ERROR MSG           42910019
         TM    CCTOPT2,CCTFORT          TEST FOR FORTRAN CHECKER        42980019
         BZ    SYNCHERR                 IF NOT IN SYSTEM ENQ ERR MSG    43050019
         DROP  REG4                                                     43120019
GETSCNA  L     REG1,IHKYYGML            GET ADDRESS OF GETMAIN LIST     43190019
         LA    REG10,TUBIRLSA           GET ADDRESS FOR GETMAIN         43260019
         GETMAIN EC,LV=CORLEN,A=(REG10),MF=(E,(1))  GET AREA            43330019
         LTR   REG15,REG15              TEST RETURN CODE                43400019
         BNZ   GMERR1                   IF BAD SEND ERROR MSG           43470019
         L     REG10,TUBIRLSA           STORE SCAN AREA ADDRESS         43540019
         MVC   CORCTR,ZEROS             INITILIZE SYNTAX INTFCE COUNTER 43610019
         MVC   CORINC,IRLINC            PUT INCREMENT INTO SCAN AREA    43680019
         BR    REG12                    EXIT                            43750019
         EJECT                                                          43820019
*********************************************************************** 43890019
*                                                                       43960019
*          TEST OPERANDS OF DELETE COMMAND                              44030019
*                                                                       44100019
*********************************************************************** 44170019
         SPACE 1                                                        44240019
         DROP  REG3                                                     44310019
         USING PPTDSECT,REG3                                            44380019
DELPROC  LA    REG9,PPTPARS             GET ADDRESS OF OPERANDS         44450019
         BAL   REG14,TSTLAST            TEST FOR LAST OPERAND IN PPT    44520019
         L     REG15,TUBUFFAD           GET STORAGE AREA ADDRESS        44590019
         BAL   REG12,TSTNUM             TEST OPERAND FOR NUMERICS       44660019
         OI    DELSW,DEL1OPR            SET ONE OPERAND SW              44730019
         BAL   REG12,INCRE              INCREMENT TO NEXT OPERAND       44800019
         BAL   REG14,TSTLAST            TEST FOR LAST OPERAND IN PPT    44870019
         OI    DELSW,DEL2OPR            SET 2 OPERAND SW                44940019
         L     REG15,TUBUFFAD           GET STORAGE AREA ADDRESS        45010019
         LA    REG15,8(REG15)                                           45080019
         BAL   REG12,TSTNUM             TEST OPERAND FOR NUMERICS       45150019
         BAL   REG12,INCRE              INCREMENT TO NEXT OPERAND       45220019
         BAL   REG14,TSTLAST            TEST FOR LAST OPERAND IN PPT    45290019
         B     EXCOP                    IF NOT, ENQ EXCESSIVE OPERANDS X45360019
                                          MESSAGE                       45430019
*********************************************************************** 45500019
*   TEST FOR LAST OPERAND IN PPT                                        45570019
*********************************************************************** 45640019
         SPACE 1                                                        45710019
TSTLAST  TM    0(REG9),LASTOPER         TEST FOR LAST OPERAND           45780019
         BO    TSTLAST1                 IF YES, TEST FOR ANOTHER PPT    45850019
         SR    REG2,REG2                                                45920019
         IC    REG2,0(REG9)             GET OPERAND LENGTH              45990019
         BR    REG14                    RETURN                          46060019
         SPACE 3                                                        46130019
*********************************************************************** 46200019
*          TEST FOR CONTINUATION PPT                                    46270019
*********************************************************************** 46340019
         SPACE 1                                                        46410019
TSTLAST1 CLC   PPTCHAD+1(3),ZEROS       TEST FOR ANOTHER PPT            46480019
         BE    TSTLAST2                 IF NOT, PROCESS COMMAND         46550019
         L     REG3,PPTCHAD             GET ADDRESS OF NEXT PPT         46620019
         LA    REG9,PPTPARS             POINT TO OPERAND                46690019
         B     TSTLAST                  TEST FOR OPERAND                46760019
         SPACE 3                                                        46830019
*********************************************************************** 46900019
*          PROCESS DELETE COMMAND                                       46970019
*********************************************************************** 47040019
         SPACE 1                                                        47110019
TSTLAST2 TM    DELSW,DELERR             TEST FOR OPERAND ERROR          47180019
         BO    RETURN                   IF YES,  RETURN                 47250019
         L     REG3,TUBPPTAD            GET ADDRESS OF ORIGINAL PPT     47320019
         TM    DELSW,DEL2OPR            TEST FOR 2 OPERANDS             47390019
         BO    TWOPER                   IF YES, PROCESS                 47460019
         TM    DELSW,DEL1OPR            TEST FOR 1 OPERAND              47530019
         BO    ONEOPER                  IF YES PROCESS                  47600019
         SPACE 3                                                        47670019
*********************************************************************** 47740019
*          NO OPERANDS                                                  47810019
*********************************************************************** 47880019
         SPACE 1                                                        47950019
         BAL   REG14,PTENDAF            POINT TO END OF ACTIVE FILE     48020019
         LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     48090019
         RDELETE NXK,REC=PREVIOUS       DELETE LAST LINE OF ACTIVE FILE 48160019
         LTR   REG15,REG15              TEST RETURN                     48230019
         BC    7,DISKERR                IF BAD, RETURN W/ I/O ERR CODE  48300019
         B     RETURN                   RETURN                          48370019
         SPACE 3                                                        48440019
*********************************************************************** 48510019
*          ONE OPERAND                                                  48580019
*********************************************************************** 48650019
         SPACE 1                                                        48720019
ONEOPER  OI    DELSW,DEL1LN             SET 1 LINE SW                   48790019
         L     REG15,TUBUFFAD           GET ADDRESS OF LINE NO          48860019
         SPACE 3                                                        48930019
*********************************************************************** 49000019
*          DELETE LINES                                                 49070019
*********************************************************************** 49140019
         SPACE 1                                                        49210019
DELPOINT MVC   TUBNXKEY,0(REG15)        PUT LINE NO IN TUB              49280019
         LA    REG1,40(REG13)           BUILD PARM LIST FOR IHKAFI      49350019
         RPOINT B,NR                    POINT BEFORE LINE NO            49420019
         C     REG15,F4                 TEST RETURN CODE                49490019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   49560019
         BE    DELNOLNO                 IF LINE DOESNT EXIST,ENQ MSG    49630019
DELINE   LA    REG1,40(REG13)           BUILD PARM LIST FOR IHKAFI      49700019
         OI    DELSW,DELDEL             SET LINE DELETED SW             49770019
         RDELETE XK                     DELETE LINE                     49840019
         C     REG15,F4                 TEST RETURN CODE                49910019
         BE    EOD                      IF EOD, PROCESS                 49980019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   50050019
         TM    DELSW,DEL1LN             TEST FOR 1 OPERAND              50120019
         BO    RETURN                   IF YES, RETURN                  50190019
         L     REG15,TUBUFFAD                                           50260019
         CLC   TUBNXKEY,8(REG15)        TEST FOR LINE EXCEEDS MAX       50330019
         BH    RETURND                  IF YES, RETURN                  50400019
         B     DELINE                   DELETE NEXT LINE                50470019
         SPACE 3                                                        50540019
*********************************************************************** 50610019
*   IF LINE NO DOES NOT EXIST, POINT AFTER PREVIOUS LINE                50680019
*********************************************************************** 50750019
         SPACE 1                                                        50820019
DELNOLNO TM    DELSW,DEL1LN             TEST FOR 1 LINE                 50890019
         BO    NOLINE                   IF YES, ENQ ERR MSG             50960019
         LA    REG1,40(REG13)           BUILD PARM LIST FOR IHKAFI      51030019
         RPOINT A,NR,KEY=HIEQ           POINT BEFORE LINE NO            51100019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   51170019
         C     REG15,F4                 TEST RETURN CODE                51240019
         LA    REG1,40(REG13)           BUILD PARM LIST FOR IHKAFI      51310019
         RGET  XK,S,B                   GET NEXT KEY                    51380019
         C     REG15,F4                 TEST RETURN CODE                51450019
         BH    RETURN1                  IF ERROR, RETURN                51520019
         BE    NOLRG                    IF EOD, ENQ MSG                 51590019
         L     REG15,TUBUFFAD                                           51660019
         CLC   8(8,REG15),TUBNXKEY      TEST FOR LINES IN RANGE         51730019
         BL    NOLRG                    IF NONE, ENQ MSG                51800019
         B     DELINE                   DELETE LINES                    51870019
         SPACE 3                                                        51940019
*********************************************************************** 52010019
*    TEST RANGE FOR TWO OPERANDS                                        52080019
*********************************************************************** 52150019
         SPACE 1                                                        52220019
TWOPER   L     REG15,TUBUFFAD           GET ADDRESS OF OPERANDS         52290019
         CLC   0(8,REG15),8(REG15)      TEST FOR 2ND LINE NO GT THAN 1  52360019
         BNL   RANGERR                  IF NOT, ENQ ERR MSG             52430019
         B     DELPOINT                 IF YES, DELETE LINES            52500019
         EJECT                                                          52570019
*********************************************************************** 52640019
*                                                                       52710019
*          DELETE PROCESSING SUBROUTINES                                52780019
*********************************************************************** 52850019
         SPACE 3                                                        52920019
*********************************************************************** 52990019
*          INCREMENT TO NEXT OPERAND                                    53060019
*********************************************************************** 53130019
         SPACE 1                                                        53200019
INCRE    AR    REG9,REG2                POINT TO NEXT OPERAND LENGTH    53270019
         SR    REG2,REG2                                                53340019
         IC    REG2,0(REG9)             GET OPERAND LENGTH              53410019
         BR    REG12                    RETURN                          53480019
         SPACE 3                                                        53550019
*********************************************************************** 53620019
*          TEST OPERANDS FOR ALL NUMERICS                               53690019
*********************************************************************** 53760019
         SPACE 1                                                        53830019
TSTNUM   ST    REG9,TUBPARM1            PUT 1ST OPERAND INTO LIST       53900019
         LA    REG9,1(REG9)             GET ADDRESS OF LINE NUMBER      53970019
         ST    REG9,TUBPARM2            STORE IN LIST                   54040019
         ST    REG15,TUBPARM3           STORE RECEIVING FIELD INTO LIST 54110019
         OI    TUBPARM3,ENDLST          FLAG END OF LIST                54180019
         LA    REG1,TUBPARM1            GET ADDRESS OF LIST             54250019
         L     REG15,IHKYYNUM           GET ADDRESS OF IHKNUM           54320019
         BALR  REG14,REG15              CALL IHKNUM TO TEST LINE NO     54390019
         LTR   REG15,REG15              TEST RETURN CODE                54460019
         BC    7,OPRERR                 IF BAD, ENQ ERROR MESSAGE       54530019
         BR    REG12                    IF GOOD, EXIT                   54600019
         EJECT                                                          54670019
*********************************************************************** 54740019
*                                                                       54810019
*           ERROR RECOVERY ROUTINES                                     54880019
*                                                                       54950019
*********************************************************************** 55020019
         SPACE 1                                                        55090019
         DROP  REG3                                                     55160019
         USING IRLPARMS,REG3                                            55230019
         SPACE 3                                                        55300019
*********************************************************************** 55370019
*           DISK ERROR RECOVERY ROUTINE                                 55440019
*********************************************************************** 55510019
         SPACE 1                                                        55580019
DISKERR  LA    REG15,12                 SET DISK ERR RETURN CODE        55650019
         B     RETURN1                  RETURN                          55720019
         SPACE 3                                                        55790019
*********************************************************************** 55860019
*           LINE EXISTS FOR INSERT ONLY ERROR RECOVERY PROCEDURE        55930019
*********************************************************************** 56000019
         SPACE 1                                                        56070019
LINEXMSG LA    REG6,LINEXCD             BUILD PARM LIST FOR LINE        56140019
         MVC   MSGP2C(8),IRLMAX         EXISTS MESSAGE                  56210019
         MVI   MSGP2L,B8                                                56280019
         LA    REG15,MSGP2L                                             56350019
         LA    REG2,1(REG15)                                            56420019
         BAL   REG14,ELEM0              ELEMINATE LEADING 0S            56490019
          BAL  REG9,CALLMSG2             ENQUEUE MSG FOR USER           56560019
         B     SETRET                   TEST RETURN CODE                56630019
         SPACE 3                                                        56700019
*********************************************************************** 56770019
*          MAXIMUM LINE NUMBER EXCEEDED                                 56840019
*********************************************************************** 56910019
         SPACE 1                                                        56980019
MAXLNO   LA    REG6,MAXLNCD             BUILD PARM LIST FOR MAX LINE    57050019
         BAL   REG9,CALLMSG1            ENQUEUE MSG                     57120019
         B     SETRET                   RETURN                          57190019
         SPACE 3                                                        57260019
*********************************************************************** 57330019
*           MESSAGE ERROR RECOVERY PROCEDURE                            57400019
*********************************************************************** 57470019
         SPACE 1                                                        57540019
MSGBAD   LA    REG15,16                 SET MSG ERR RETURN CODE         57610019
         B     RETURN1                  RETURN                          57680019
         SPACE 3                                                        57750019
*********************************************************************** 57820019
*           PROMPT ERROR RECOVERY ROUTINE                               57890019
*********************************************************************** 57960019
         SPACE 1                                                        58030019
PMTERR   LA    REG15,4                  SET LINE ERR RETURN CODE        58100019
         B     RETURN1                  RETURN                          58170019
         SPACE 3                                                        58240019
*********************************************************************** 58310019
*           GETMAIN ERROR RECOVERY ROUTINE                              58380019
*********************************************************************** 58450019
         SPACE 1                                                        58520019
GMERR    LA    REG15,8                  SET GETMAIN ERR RETURN CODE     58590019
         L     REG2,4(REG13)            GET CLLER'S SAVE AREA ADDRESS   58660019
         ST    REG15,16(REG2)           SAVE RETURN CODE                58730019
         B     RETURN2                  RETURN                          58800019
GMERR1   LA    REG15,GMRET              SET GETMAIN ERR RETURN CODE     58870019
         L     REG2,4(REG13)            GET CALLER'S SAVE AREA ADDRESS  58940019
         OI    IRLSW,IRLRET             SET FINAL RETURN SWITCH         59010019
         B     RETURN1                  RETURN                          59080019
         SPACE 3                                                        59150019
*********************************************************************** 59220019
*           NO SYNTAX CHECKER AVAIBLE                                   59290019
*********************************************************************** 59360019
         SPACE 1                                                        59430019
SYNCHERR LA    REG6,SYNCHCD             BUILD PARM LIST FOR MSG WRITER  59500019
         BAL   REG9,SNDMSG              SEND MSG TO USER                59570019
         NI    TUBFLG1,TUBSCNF          TURN OFF SCAN FLAG              59640019
         BR    REG12                    CONTINUE PROCESSING WITHOUT     59710019
*                                         SYNTAX SCAN                   59780019
         SPACE 3                                                        59850019
*********************************************************************** 59920019
*           OUT OF SPACE ACTIVE AREA ERROR RECOVERY PROCEEDURE          59990019
*********************************************************************** 60060019
         SPACE 1                                                        60130019
*                                                                       60200019
OUTSPAA1 NI    TUBFLG1,TUBFLG1F         TURN OFF EDIT TUB FLAGS         60270019
         NI    TUBFLG2,TUBFLG2F         TURN OFF EDIT TUB FLAGS         60340019
OUTSPAA LA     REG6,BUFERCD             BUILD PARM LIST FOR MSG WRITER  60410019
         BAL   REG9,CALLMSG1            ENQUEUE MSG                     60480019
         LA    REG15,20                 SET OUT OF SPACE A.A. RET CD    60550019
         B     RETURN1                  RETURN                          60620019
         SPACE 3                                                        60690019
*********************************************************************** 60760019
*          EXCESSIVE OPERANDS ON DELETE COMMAND                         60830019
*********************************************************************** 60900019
         SPACE 1                                                        60970019
EXCOP    LA    REG6,EXCOPCD             BUILD PARM LIST FOR MSG WRITER  61040019
         NI    0(REG9),SUBOPRF          ELEM SUBOPERAND BITS FROM LEN   61110019
         LA    REG15,ZEROS              NO MESSAGE INSERT        A47928 61140000
         BAL   REG9,CALLMSG2            ENQ MSG                         61180019
         B     RETURN                   EXIT                            61250019
         SPACE 3                                                        61320019
*********************************************************************** 61390019
*          LINE NUMBER RANGE INVALID ON DELETE COMMAND                  61460019
*********************************************************************** 61530019
         SPACE 1                                                        61600019
RANGERR  LA    REG6,RANGECD             BUILD PARM LIST FOR MSG WRITER  61670019
         B     CALLMSG                  ENQ MSG AND RETURN              61740019
         SPACE 3                                                        61810019
*********************************************************************** 61880019
*          LINE DOES NOT EXIST FOR SINGLE DELETE                        61950019
*********************************************************************** 62020019
         SPACE 1                                                        62090019
NOLINE   LA    REG6,NOLINECD            BUILD PARM LIST FOR LINE DOES   62160019
         MVI   MSGP2L,B8                  NOT EXIST MSG                 62230019
         MVC   MSGP2C(8),TUBNXKEY                                       62300019
         LA    REG15,MSGP2L                                             62370019
         LA    REG2,1(REG15)                                            62440019
         BAL   REG14,ELEM0              ELEMINATE LEADING 0S            62510019
         BAL   REG9,CALLMSG2            ENQ MSG FOR USER                62580019
         B     RETURN                   RETURN                          62650019
         SPACE 3                                                        62720019
*********************************************************************** 62790019
*          LINE NUMBER INVALID                                          62860019
*********************************************************************** 62930019
         SPACE 1                                                        63000019
OPRERR   LA    REG6,OPRERRCD            BUILD PARM LIST FOR LINE NO     63070019
         LR    REG15,REG9                 INVALID                       63140019
         BCTR  REG15,0                                                  63210019
         NI    0(REG15),SUBOPRF         TURN OFF SUBOPERAND BITS        63280019
         SR    REG2,REG2                                                63350019
         IC    REG2,0(REG15)            SET CORRECT LENGTH              63420019
         ST    REG9,TUBIRLSA            SAVE OPERAND ADDRESS            63490019
         BAL   REG9,CALLMSG2            ENQ MSG FOR USER                63560019
         L     REG9,TUBIRLSA            RESTORE OPERAND ADDRESS         63630019
         OI    DELSW,DELERR             SET ERROR SW                    63700019
         BR    REG12                    CONTINUE TESTING OPERANDS       63770019
         SPACE 3                                                        63840019
         DROP  REG3                                                     63910019
         USING IRLPARMS,REG3                                            63980019
*********************************************************************** 64050019
*                                                                       64120019
*           RETURN ROUTINE                                              64190019
*                                                                       64260019
*********************************************************************** 64330019
         SPACE 1                                                        64400019
SETRET   OI    IRLSW2,IRLRET            SET FINAL RETURN SW             64470019
         OI    TUBFLG3,TUBLNPMT         SET LINE NO PROMPT SW           64540019
RETURN   L     REG15,ZEROS              SET GOOD RETURN CODE            64610019
RETURN1  L     REG2,4(REG13)                                            64680019
         ST    REG15,16(REG2)           SAVE RETURN CODE                64750019
         TM    TUBFLG1,TUBSCN           TEST FOR SCAN SPECIFIED         64820019
         BZ    RETURN3                  IF NOT SKIP FREEMAIN            64890019
         TM    IRLSW2,IRL1LN            TEST FOR INPLICIT CMD           64960019
         BO    RETURN3                  IF YES, DON'T SAVE SWITCHES     65030019
         TM    DELSW,DEL1LN             TEST FOR IMPLICIT DELETE        65100019
         BO    RETURN3                  IF YES, DON'T SAVE SWITCHES     65170019
         MVC   CORSW,IRLSW              SAVE SWITCHES                   65240019
         MVC   CORSW1,IRLSW2                                            65310019
         TM    IRLSW2,IRLRET            TEST FOR FINAL RETURN           65380019
         BZ    RETURN3                  IF NOT SKIP FREEMAIN            65450019
         LA    REG0,CORLEN              SET UP TO FREE SCAN PARMS       65520019
         L     REG1,TUBIRLSA                                            65590019
         FREEMAIN R,LV=(0),A=(1)        FREE SCAN PARAMETER AREA        65660019
RETURN3  LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     65730019
         ENDUP                                                          65800019
         LTR   REG15,REG15              TEST RETURN CODE                65870019
         BC    8,RETURN4                IF GOOD, CONTINUE               65940019
         ST    REG15,16(REG2)           IF BAD, SAVE RETURN CODE        66010019
RETURN4  LR    REG1,REG13               SET UP FOR FREEMAIN             66080019
         NI    TUBAFISW,TUBFCTLF        TURN OFF BUFFER CONTROL SW      66150019
         L     REG13,SAVEA+4            GET ADDR OF CALLERS SAVE AREA   66220019
         LA    REG0,GMLEN                                               66290019
         FREEMAIN R,LV=(0),A=(1)        FREE SAVE AND WORK AREAS        66360019
RETURN2  RETURN (14,12),T               RETURN TO CALLING ROUTINE       66430019
RETURND  TM    DELSW,DELDEL             TEST FOR LINES DELETED          66500019
         BO    RETURN                   IF YES, RETURN                  66570019
         SPACE 3                                                        66640019
***************                                                         66710019
*    IF NO LINES DELETED, ENQ MSG FOR USER                              66780019
***************                                                         66850019
         SPACE 1                                                        66920019
NOLRG    LA    REG6,NOLNRGCD            BUILD PARM LIST FOR MSG WRITER  66990019
         B     CALLMSG                  ENQUEUE MSG AND RETURN          67060019
         EJECT                                                          67130019
         DROP  REG3                                                     67200019
*********************************************************************** 67270019
*                                                                       67340019
*           ENTRY FOR IMPLICIT COMMAND                                  67410019
*                                                                       67480019
*********************************************************************** 67550019
         SPACE 3                                                        67620019
*********************************************************************** 67690019
*          INITILIZATION                                                67760019
*********************************************************************** 67830019
         SPACE 1                                                        67900019
IHKIRL01 SAVE  (14,12),,*               SAVE CALLERS REGISTERS          67970019
         USING IHKIRL01,REG15           TEMPORARY BASE REGISTER         68040019
         L     BASE,IRLEP               LOAD BASE REGISTER              68110019
         DROP  REG15                                                    68180019
         L     REG5,0(REG1)             SET UP ADDRESSABILITY FOR TUB   68250019
         L     REG8,4(REG1)             SET UP ADDRESSABILITY FOR AVT   68320019
         LA    REG2,TUBPARM1            SET UP FOR GETMAIN              68390019
         L     REG1,IHKYYGML                                            68460019
         GETMAIN EC,LV=GMLEN,A=(REG2),MF=(E,(1))  GET AREA FOR SAVE    X68530019
                                                    AND WORK AREAS      68600019
         LTR   REG15,REG15              TEST RETURN CODE                68670019
         BNZ   GMERR                    IF BAD RETURN                   68740019
         L     REG2,TUBPARM1            GET SAVE AREA ADDRESS           68810019
         ST    REG2,8(REG13)            STORE SAVE AREA ADDRESS         68880019
         ST    REG13,4(REG2)            SAVE CALLERS SAVE AREA ADDR     68950019
         LR    REG13,REG2               PUT SAVE AREA ADDR INTO REG 13  69020019
         L     REG3,TUBPPTAD            SET UP ADDRESSABILITY FOR PPT   69090019
         USING PPTDSECT,REG3                                            69160019
         NI    IRLSW2,IRL2OFF           SET OFF PROCESSING SWITCHES     69230019
         NI    DELSW,DELOFF             TURN OFF DELETE SWITCHES        69300019
         L     REG12,ZEROS                                              69370019
         CH    REG12,TUBDATAL           TEST FOR NULL LINE              69440019
         BE    CRPROC                   IF YES, PROCESS                 69510019
         L     REG10,TUBIRLSA           SET UP ADDR FOR SCAN AREA       69580019
         SPACE 1                                                        69650019
*********************************************************************** 69720019
*           CHECK COMMAND OPERANDS                                      69790019
*********************************************************************** 69860019
         SPACE 1                                                        69930019
         L     REG6,PPTDSECT+8          FIND ADDRESS OF LINE NO         70000019
         LA    REG4,PPTDSECT+6          FIND ADDRESS OF LINE LENGTH     70070019
         ST    REG4,TUBPARM1            STORE IN PARAMETER LIST         70140019
         ST    REG6,TUBPARM2            STORE LINE NO ADDR IN PARM LIST 70210019
         LA    REG7,TUBNXKEY            PUT RECEVING FIELD ADDR IN      70280019
         ST    REG7,TUBPARM3            PARAMETER LIST                  70350019
         OI    TUBPARM3,ENDLST          FLAG END OF PARM LIST           70420019
         LA    REG1,TUBPARM1            GET PARM LIST ADDRESS           70490019
         L     REG15,IHKYYNUM                                           70560019
         BALR  REG14,REG15              CHECK LINE NO FOR NUMERICS      70630019
         LTR   REG15,REG15              TEST RETURN CODE                70700019
         BNZ   LNOERR                   IF ERROR ENQUEUE MESSAGE        70770019
         NI    PPTFLG,PPTOFF            SET SWITCHES FOR INS OR REPL    70840019
         TM    TUBFLG3,TUBCORRN         TEST FOR CORRECTION MODE        70910019
         BO    LNORGTST                 IF YES, TEST FOR LINE NO RANGE  70980019
         SPACE 3                                                        71050019
*********************************************************************** 71120019
*          SET UP TO PUT LINE INTO ACTIVE FILE                          71190019
*********************************************************************** 71260019
         SPACE 1                                                        71330019
RNGRET   LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     71400019
         RPOINT B,NR                    POINT TO LINE                   71470019
         C     REG15,F4                 TEST RETURN CODE                71540019
         BE    NORECF                   IF LINE DOES NOT EXIST, PROCESS 71610019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   71680019
         OI    PPTFLG,PPTREP            SET REPLACE ONLY SW             71750019
POINTRET LA    REG6,PPTDSECT+7          POINT TO TEXT LENGTH            71820019
         TM    PPTDSECT+7,XFF           TEST FOR TEXT                   71890019
         BZ    DELETE                   IF NOT PRESENT DELETE LINE      71960019
         L     REG9,PPTDSECT+12         GET ADDRESS OF TEXT             72030019
         SR    REG4,REG4                                                72100019
         IC    REG4,0(REG6)             PICK UP LENGTH OF TEXT          72170019
         STH   REG4,TUBDATAL            SET UP TEXT LENGTH              72240019
         DROP  REG3                                                     72310019
         USING IRLPARMS,REG3                                            72380019
         OI    IRLSW2,IRL1LN            SET IMPLICIT CMD SW             72450019
         L     REG15,TUBUFFAD                                           72520019
         MVC   0(80,REG15),0(REG9)      PUT TEXT INTO USER BUFFER       72590019
         B     RETFORT                  PROCESS LINE                    72660019
         SPACE 3                                                        72730019
*********************************************************************** 72800019
*          SET UP TO DELETE LINE                                        72870019
*********************************************************************** 72940019
         SPACE 1                                                        73010019
DELETE   OI    DELSW,DEL1LN             SET 1 LINE SWITCH               73080019
         B     DELINE                   DELETE LINE                     73150019
         SPACE 3                                                        73220019
*********************************************************************** 73290019
*          TEST FOR LINE IN RANGE OF LINES SCANNED (CORRECTION MODE)    73360019
*********************************************************************** 73430019
         SPACE 1                                                        73500019
LNORGTST CLC   TUBNXKEY,CORFST          TEST FOR CORRCETION LINE NO     73570019
         BL    NINRANGE                 WITHIN RANGE OF LINES           73640019
         CLC   TUBNXKEY,CORCUR          SCANNED                         73710019
         BH    NINRANGE                 IF NOT, ENQUEUE MESSAGE         73780019
         OI    TUBFLG3,TUBCORCN         TURN ON CORR MADE SW            73850019
         B     RNGRET                   CONTINUE PROCESSING             73920019
NINRANGE LA    REG6,NIRGCD                                              73990019
         LA    REG15,MSGP2              SET UP LINE NO FOR MSG          74060019
         MVI   0(REG15),B8                                              74130019
         MVC   1(8,REG15),TUBNXKEY                                      74200019
         LA    REG2,1(REG15)                                            74270019
         BAL   REG14,ELEM0                                              74340019
         BAL   REG9,CALLMSG2            ENQUEUE LINE NOT IN RANGE MSG   74410019
         B     RETURN                   RETURN                          74480019
NORECF   TM    IRLPARMS+7,XFF           TEST FOR DELETE COMMAND         74550019
         BZ    NOLINE                   IF YES, ENQ ERR MSG             74620019
         LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     74690019
         RPOINT A,NR,KEY=HIEQ           POINT AFTER PREVIOUS RECORD     74760019
         C     REG15,F4                 TEST RETURN CODE                74830019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   74900019
         OI    IRLSW,IRLINS             SET INSERT ONLY SW              74970019
         B     POINTRET                 CONTINUE PROCESSING             75040019
         SPACE 3                                                        75110019
*********************************************************************** 75180019
*          PROCESS CR IN EDIT MODE OR INPUT COMMAND WITH NO OPERANDS    75250019
*********************************************************************** 75320019
         SPACE 1                                                        75390019
CRPROC   L     REG15,TUBDIRAD           SET UP DIRECTORY ENTRY          75460019
         USING DIRDSECT,REG15           ADDRESSABILITY                  75530019
         MVC   IRLINC,DIRINC            PUT DATA SET INCREMENT INTO PPT 75600019
         DROP  REG15                                                    75670019
         BAL   REG12,SETUPSCN           SET UP FOR SCAN IF NECESSARY    75740019
         OI    IRLSW,IRLFST             SET FIRST TIME SWITCH           75810019
CRPROC2  BAL   REG14,PTENDAF            POINT TO END OF ACTIVE FILE     75880019
CRPROC1  OI    IRLSW,IRLINS             SET INSERT ONLY SWITCH          75950019
         B     CALCLNO                  PROCESS LINES FROM USER         76020019
NOTHERE  CLI   IRLPARMS+5,CMDDTE        TEST FOR DELETE                 76090019
         BE    NOLRG                    IF YES, ENQUEUE NO LINE MSG     76160019
         L     REG15,TUBDIRAD           GET ADDRESS OF DIR ENTRY        76230019
         USING DIRDSECT,REG15                                           76300019
         L     REG14,DIRINC             GET 1ST LINE NO                 76370019
         DROP  REG15                                                    76440019
         L     REG15,TUBUFFAD           GET WORK AREA ADDRESS           76510019
         CVD   REG14,0(REG15)                                           76580019
         UNPK  TUBNXKEY,0(8,REG15)      PUT 1ST LINE NO INTO TUB        76650019
         OI    TUBNXKEY+7,XF0           SET SIGN TO NUMERIC ZONE        76720019
         OI    IRLSW,IRLINS             SET INSERT ONLY SWITCH          76790019
         B     TSTPMT                   PROCESS LINES                   76860019
PTENDAF  LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     76930019
         ST    REG14,TUBPARM5           SAVE RETURN REGISTER            77000019
         MVI   TUBNXKEY+7,ENDACT        INDICATE END OF ACTIVE AREA     77070019
         RPOINT A,NR                    POINT AFTER LAST RECORD         77140019
         C     REG15,F4                 TEST RETURN CODE                77210019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   77280019
         TM    TUBNXKEY+7,ENDACT        TEST FOR NULL FILE              77350019
         BO    NOTHERE                  IF IT IS, SET UP KEY            77420019
         L     REG14,TUBPARM5           RESTORE RETURN REGISTER         77490019
         BR    REG14                    EXIT                            77560019
         EJECT                                                          77630019
*********************************************************************** 77700019
*                                                                       77770019
*           ENTRY POINT FROM SYNTAX SCAN ERROR CORRECTION MODE          77840019
*                                                                       77910019
*********************************************************************** 77980019
         SPACE 1                                                        78050019
IHKIRL02 SAVE  (14,12),,*               SAVE REGISTERS                  78120019
         USING IHKIRL02,REG15           TEMPORARY BASE                  78190019
         L     BASE,IRLEP               LOAD BASE REGISTER              78260019
         DROP  REG15                                                    78330019
         L     REG5,0(REG1)             SET UP ADDRESSABILITY FOR TUB   78400019
         L     REG8,4(REG1)             SET UP ADDRESSABILITY FOR AVT   78470019
         L     REG10,TUBIRLSA           GET GETMAIN AREA ADDRESS        78540019
         LA    REG2,TUBPARM1            GET WORK AND SAVE AREA          78610019
         L     REG1,IHKYYGML                                            78680019
         GETMAIN EC,LV=GMLEN,A=(REG2),MF=(E,(1))                        78750019
         LTR   REG15,REG15              TEST RETURN CODE                78820019
         BNZ   GMERR                    IF BAD RETURN                   78890019
         L     REG2,TUBPARM1            GET AREA ADDRESS                78960019
         ST    REG2,8(REG13)            STORE SAVE AREA ADDRESS         79030019
         ST    REG13,4(REG2)            STORE CALLRE'S SAVE AREA ADDR   79100019
         LR    REG13,REG2                                               79170019
         L     REG3,TUBPPTAD            SET UP ADDRESSABILITY FOR PPT   79240019
         NI    TUBFLG3,TUBCORRF         TURN OFF CORRECTION MODE SW     79310019
         NI    DELSW,DELOFF             TURN OFF DELETE SWITCHES        79380019
         MVC   IRLSW,CORSW              RESTORE SWITCHES                79450019
         MVC   IRLSW2,CORSW1                                            79520019
         MVC   IRLINC,CORINC            SET UP INCREMENT                79590019
         MVC   IRLMAX,CORMAX       RESTORE MAX LINE NUM          A44641 79620000
         TM    TUBFLG3,TUBCORCN         TEST FOR CORRECTIONS MADE       79660019
         BO    CORMADE                  IF YES, TURN OFF SWITCH         79730019
         MVC   TUBNXKEY,CORCUR          SET UP TO CALC NEXT LINE NO     79800019
         OI    IRLSW,IRLFST             SET 1ST TIME SCAN SW            79870019
         LA    REG1,40(REG13)           SET UP PARM LIST FOR IHKAFI     79940019
         RPOINT A,NR,KEY=HIEQ                                           80010019
         C     REG15,F4                 TEST RETURN CODE                80080019
         BH    RETURN1                  IF I/O OR GETMAIN ERR, RETURN   80150019
         B     CALCLNO                  CONTINUE PROCESSING             80220019
CORMADE  NI    TUBFLG3,TUBCORCF         TURN OFF-CORRECTIONS MADE SW    80290019
         B     SYNPBLD1                 GIVE LINES TO SYNTAX CHECKER    80360019
         EJECT                                                          80430019
*********************************************************************** 80500019
*                                                                       80570019
*           ERROR RECOVERY ROUTINES FOR IHKIRL01                        80640019
*                                                                       80710019
*********************************************************************** 80780019
         SPACE 3                                                        80850019
*********************************************************************** 80920019
*           INVALID LINE NUMBER                                         80990019
*********************************************************************** 81060019
         SPACE 1                                                        81130019
LNOERR   LA    REG6,LNOERRCD            SET UP PARM LIST FOR MSG WRITER 81200019
CALLMSG  BAL   REG9,CALLMSG1            ENQUEUE MSG                     81270019
         B     RETURN                   RETURN                          81340019
         SPACE 3                                                        81410019
         SPACE 3                                                        81480019
         SPACE 3                                                        81550019
*********************************************************************** 81620019
*           LINE TRUNCATED                                              81690019
*********************************************************************** 81760019
         SPACE 1                                                        81830019
LENERR   LA    REG6,LNTRCCD             SET UP PARM LIST FOR MSG WRITER 81900019
         TM    TUBFLG2,TUBLNUMN         TEST FOR LINE NOS IN LINE       81970019
         BZ    LENERR2                  IF NOT  MOVE 80 FOR LENGTH      82040019
         LA    REG15,C72                SET UP MSG INSERT               82110019
LENERR1  BAL   REG9,SNDMSG2             SEND MESSAGE TO USER            82180019
         ST    REG2,TUBRAFBF            RESTORE TUBRAFBF                82250019
         NI    IRLSW2,IRLENERF          SET LENGTH ERR SW OFF           82320019
         BR    REG7                     EXIT                            82390019
LENERR2  LA    REG15,C80                SET UP MESSAGE INSERT           82460019
         B     LENERR1                  CONTINUE PROCESSING             82530019
         EJECT                                                          82600019
*********************************************************************** 82670019
*                                                                       82740019
*           SUBROUTINES TO CALL MESSAGE WRITER                          82810019
*                                                                       82880019
*********************************************************************** 82950019
         SPACE 1                                                        83020019
CALLMSG1 BAL   REG14,BLDMP1             BUILD PARM LIST FOR MSG WRITER  83090019
         B     CALMSG                   CONTINUE                        83160019
CALLMSG2 BAL   REG14,BLDMP2             BUILD PARM LIST FOR MSG WRITER  83230019
CALMSG   LA    REG15,TUBUSRID           SET UP 1ST PARMATER             83300019
         ST    REG15,TUBPARM3                                           83370019
         ST    REG5,TUBPARM2                                            83440019
         LA    REG1,TUBPARM2            GET PARAMETER LIST ADDR         83510019
         L     REG15,IHKYMSG1           LOAD ADDRESS OF MSG WRITER      83580019
         BALR  REG14,REG15              ENQUEUE MSG FOR USER            83650019
TSTMSGRT LTR   REG15,REG15              TEST RETURN CODE                83720019
         BC    7,MSGBAD                 IF BAD, RETURN                  83790019
         BR    REG9                     EXIT                            83860019
         SPACE 3                                                        83930019
*********************************************************************** 84000019
*           SEND MESSAGE TO CENTRAL OPERATOR                            84070019
*********************************************************************** 84140019
         SPACE 1                                                        84210019
CALCMSG1 BAL   REG14,BLDMP1             BUILD PARM LIST FOR MSG WRITER  84280019
         B     CALCMSG                  CONTINUE                        84350019
CALCMSG2 BAL   REG14,BLDMP2             BUILD PARM LIST FOR MSG WRITER  84420019
CALCMSG  LA    REG2,ZEROS                                               84490019
         ST    REG2,TUBPARM3                                            84560019
SNDMSG1  ST    REG5,TUBPARM2                                            84630019
         LA    REG1,TUBPARM2            GET ADDRESS OF PARAMETER LIST   84700019
         L     REG15,IHKYYMSG           GET MSG WRITER ADDRESS          84770019
         BALR  REG14,REG15              SEND MSG                        84840019
         B     TSTMSGRT                 TEST RETURN CODE                84910019
         SPACE 3                                                        84980019
*********************************************************************** 85050019
*           SEND MESSAGE TO TERMINAL USER                               85120019
*********************************************************************** 85190019
         SPACE 1                                                        85260019
SNDMSG   BAL   REG14,BLDMP1             BUILD PARM LIST FOR MSG WRITER  85330019
SNDMSG3  ST    REG5,TUBPARM3            FINISG PARM LIST                85400019
         B     SNDMSG1                  SEND MSG TO USER                85470019
SNDMSG2  BAL   REG14,BLDMP2             BUILD PARAMETER LIST            85540019
         B     SNDMSG3                  SEND MESSAGE                    85610019
         SPACE 3                                                        85680019
*********************************************************************** 85750019
*           BUILD MSG WRITER PARM LIST                                  85820019
*********************************************************************** 85890019
         SPACE 1                                                        85960019
BLDMP2   ST    REG15,TUBPARM5           PUT 3RD PARM IN LIST            86030019
         OI    TUBPARM5,ENDLST          FLAG END OF LIST                86100019
         ST    REG6,TUBPARM4            PUT 2ND PARM IN LIST            86170019
         BR    REG14                    ENQUEUE MSG                     86240019
BLDMP1   ST    REG6,TUBPARM4            PUT 2ND PARM IN LIST            86310019
         OI    TUBPARM4,ENDLST          FLAG END OF LIST                86380019
         BR    REG14                    ENQUEUE MSG                     86450019
         SPACE 3                                                        86520019
*********************************************************************** 86590019
*           SET GETMAIN FAILED RETURN CODE                              86660019
*********************************************************************** 86730019
         SPACE 1                                                        86800019
GMFAIL   LA    REG15,8                  SET RETURN CD FOR GETMAIN FAIL  86870019
         B     RETURN1                  RETURN                          86940019
         EJECT                                                          87010019
*********************************************************************** 87080019
*                                                                       87150019
*           CONSTANTS                                                   87220019
*                                                                       87290019
*********************************************************************** 87360019
         SPACE 1                                                        87430019
ZEROS    DC    F'0'                     FULLWORD CONST OF 0             87500019
F4       DC    F'4'                     FULL WORD CONST OF 4            87570019
F9S      DC    F'99999999'              FULL WORD CONST OF 99999999     87640019
H1       DC    H'1'                     HALFWORD CONST OF 1             87710019
H6       DC    H'6'                     HALFWORD CONSTANT OF 6          87780019
H10      DC    H'10'                    HALFWORD CONST OF 10            87850019
H20      DC    H'20'                    HALFWORD CONST OF 20            87920019
H72      DC    H'72'                    HALFWORD CONST OF 72            87990019
H80      DC    H'80'                    HALFWORD CONST OF 80            88060019
C72      DC    X'02F7F2'                CHARACTER CONSTANT OF 72        88130019
C80      DC    X'02F8F0'                CHARACTER CONSTANT OF 80        88200019
CONTCH   EQU   X'60'                    STATEMENT CONT CHARACTER        88270019
BLK      EQU   X'40'                    BLANK CHARACTER                 88340019
ENDLST   EQU   X'80'                    END OF PARAMETER LIST           88410019
ENDACT   EQU   X'FF'                    LAST LINE OF ACTIVE FILE        88480019
BGNACT   EQU   X'00'                    1ST LINE OF ACTIVE FILE         88550019
LASTOPER EQU   X'FF'                    LAST OPERAND IN PPT             88620019
SUBOPRF  EQU   X'3F'                    TURN OFF SUBOPERAND BITS        88690019
X00      EQU   X'00'                    RESET END OF PARM LIST FLAG     88760019
XF0      EQU   X'F0'                    HEX F0                          88830019
XFF      EQU   X'FF'                    HEX FF                          88900019
B8       EQU   X'08'                    BINARY 8 (ONE BYTE)             88970019
UILEN    EQU   X'0E'                    USER INFO LENGTH FOR DIR ENTRY  89040019
ZERO     EQU   C'0'                     CHARACTER 0                     89110019
PPTOFF   EQU   X'00'                    TURN OFF PPT SWITCHES           89180019
PPTINS   EQU   X'40'                    INSERT ONLY SW                  89250019
PPTREP   EQU   X'20'                    REPLACE ONLY                    89320019
PPTDEL   EQU   X'42'                    DELETE COMMAND CODE             89390019
PPTOS    EQU   X'10'                    OS DATA SET EDITED              89460019
PPTKEY   EQU   X'02'                    KEY SPECIFIED IN EDIT CMD       89530019
GMRET    EQU   8                        GETMAIN FAILED RETURN CODE      89600019
MVCBLK   MVC   1(0,REG2),0(REG2)        BLANK OUT END OF BUFFER         89670019
INSLZ    MVC   0(0,REG2),BLANK          BLANK OUT LEADING 0S IN LINE NO 89740019
IRLEP    DC    A(IHKIRL)                ADCON FOR SECONDARY ENTRY PT    89810019
BLANK    DC    CL8' '                   8 BYTES OF BLANKS               89880019
         ENTRY IHKIRL01                                                 89950019
         ENTRY IHKIRL02                                                 90020019
         SPACE 3                                                        90090019
*********************************************************************** 90160019
*           MESSAGE CODES                                               90230019
*********************************************************************** 90300019
         SPACE 1                                                        90370019
EODCD    DC    X'00F3F6F1'              END OF DATA                     90440019
LNOERRCD DC    X'00F3F0F7'              LINE NUMBER INVALID             90510019
LINEXCD  DC    X'00F3F5F9'              LINE NUMBER EXISTS, INSERT      90580019
BUFERCD  DC    X'00F3F5F7'              OUT FO SPACE (USER)             90650019
INVATRCD DC    X'00F3F6F0'              INVALID ATTRIBUTE               90720019
LNTRCCD  DC    X'00F3F1F6'              LINE TRUNCATED                  90790019
NIRGCD   DC    X'00F3F6F4'              LINE NOT IN RANGE               90860019
SYNCHCD  DC    X'00F3F8F7'              SYNTAX CHECKRE NOT IN SYSTEM    90930019
MAXLNCD  DC    X'00F3F4F8'              MAX LINE NUMBER EXCEEDED        91000019
EXCOPCD  DC    X'00F3F3F4'              EXCDSSIVE OPERANDS              91070019
RANGECD  DC    X'00F3F6F7'              LINE NO RANGE INVALID           91140019
NOLINECD DC    X'00F3F4F9'              LINE DOES NOT EXIST             91210019
OPRERRCD DC    X'00F3F0F2'              INVALID OPREAND                 91280019
NOLNRGCD DC    X'00F3F4F0'              NO LINES IN RANGE               91350019
MAXSCNCD DC    X'00F3F6F8'              MAX SCAN CONT LINES REACHED     91420019
         EJECT                                                          91490019
*********************************************************************** 91560019
*                                                                       91630019
*           DSECT FOR PARAMETERS FROM EDIT & INPUT                      91700019
*                                                                       91770019
*********************************************************************** 91840019
         SPACE 1                                                        91910019
IRLPARMS DSECT                                                          91980019
IRLSW    DS    C                        IRL SWITCHES                    92050019
IRLEDT   EQU   X'80'                    EDIT SW                         92120019
IRLINS   EQU   X'40'                    INSERT ONLY                     92190019
IRLREP   EQU   X'20'                    REPLACE ONLY                    92260019
IRLFST   EQU   X'10'                    1ST TIME THROUGH                92330019
IRLNFST  EQU   X'EF'                    NOT 1ST TIME THROUGH            92400019
IRLCONT  EQU   X'04'                    PL/1 CONTINUATION STMT          92470019
IRLCONTF EQU   X'FB'                    OFF                             92540019
IRLREP2  EQU   X'02'                    REPLACE THIS LINE SW            92610019
IRLREP2F EQU   X'FD'                    LINE REPLACE SW OFF             92680019
IRLIPT   EQU   X'01'                    ENTERED FROM INPUT              92750019
         DS    CL5                      NOT USED BY IRL                 92820019
IRLSTAD  DS    CL8                      STARTING LINE NO                92890019
IRLINC   DS    F                        INCREMENT                       92960019
IRLMAX   DS    CL8                      MAX LINE NO SAVE AREA           93030019
         EJECT                                                          93100019
*********************************************************************** 93170019
*                                                                       93240019
*           DSECT FOR VARIABLES, STORAGE AND WORKAREAS                  93310019
*                                                                       93380019
*********************************************************************** 93450019
         SPACE 1                                                        93520019
VDSECT   DSECT                                                          93590019
SAVEA    DS    18F                      SAVE AREA                       93660019
MSGP2    DS    0CL20                    MESSAGE PARAMETER               93730019
QEL      DS    2F                       SCAN QUEUE ELEMENT              93800019
         ORG   MSGP2                                                    93870019
MSGP2L   DS    C                        PARM LENGTH                     93940019
MSGP2C   DS    CL18                     PARM                            94010019
IRLSW2   DS    X                        PROCESSING SWITCHES             94080019
IRLRET   EQU   X'40'                      FINAL RETURN SW               94150019
IRLENER  EQU   X'20'                    LINE LENGTH ERROR               94220019
IRLENERF EQU   X'DF'                    OFF                             94290019
IRL1LN   EQU   X'10'                    IMPLICIT COMMAND                94360019
IRLNOLIM EQU   X'08'                    NO LIMIT                        94430019
IRL2OFF  EQU   X'00'                    ALL SWITCHES OFF                94500019
         SPACE 1                                                        94570019
*********************************************************************** 94640019
*          PROCESSING SWITCH FOR DELETE COMMAND                         94710019
*********************************************************************** 94780019
         SPACE 1                                                        94850019
DELSW    DS    X                        DELETE PROCESSING SWITCH        94920019
DEL1OPR  EQU   X'80'                    1 OPERAND                       94990019
DEL2OPR  EQU   X'40'                    2 OPERANDS                      95060019
DELERR   EQU   X'20'                    OPERAND ERR SW                  95130019
DEL1LN   EQU   X'10'                    DELETE 1 LINE                   95200019
DELDEL   EQU   X'08'                    LINE DELETED                    95270019
DELOFF   EQU   X'00'                      OFF                           95340019
GMLEN    EQU   *-VDSECT                 LENGTH OF GETMAIN AREA          95410019
         EJECT                                                          95480019
*********************************************************************** 95550019
*                                                                       95620019
*           AREA FOR CORRECTION MODE SAVE AREA                          95690019
*                                                                       95760019
*********************************************************************** 95830019
         SPACE 1                                                        95900019
CORDSECT DSECT                                                          95970019
CORFST   DS    CL8                      1ST LINE NO                     96040019
CORCUR   DS    CL8                      CURRENT LINE NO                 96110019
CORCTR   DS    H                        LINE COUNTER                    96180019
CORSW    DS    X                        IRL SWITCH SAVE AREA            96250019
CORSW1   DS    X                        IRL SWITCH 1 SAVE AREA          96320019
CORINC   DS    F                        INCREMENT FOR OPREATION         96390019
CORMAX   DS    CL8                      MAX LINE NO INSERT              96460019
CORLEN   EQU   *-CORDSECT               DSECT LENGTH                    96530019
         EJECT                                                          96600019
*********************************************************************** 96670019
*                                                                       96740019
*           DSECTS FOR CRJE CONTROL BLOCKS                              96810019
*                                                                       96880019
*********************************************************************** 96950019
         SPACE 1                                                        97020019
         IHKCDSCT TUB=YES,PPT=YES,AVT=YES,DIR=YES,CCT=YES,DEF=YES       97090019
         TUBEQU                         EQUATES FOR TUB                 97160019
         CMDEQU                         EQUATES FOR COMMAND CODES       97230019
         RAFKNBX TYPE=DSECT                                             97300019
PPTINC   EQU   PPTFLG+16                INCREMENT SAVE AREA             97370019
         END                                                            97440019
