LAB      TITLE 'IHKLAB - LINE ADMINISTRATOR EDITING ROUTINE'            00400019
IHKLAB   CSECT                                                          00800019
*A708000                                                         A36802 00900020
*C484000,716000                                                  A36802 01000020
         SPACE 1                                                        01200019
*********************************************************************** 01600019
*                                                                     * 02000019
*STATUS                                                               * 02400019
*                                                                     * 02800019
*   CHANGE LEVEL 0                                                    * 03200019
*                                                                     * 03600019
*FUNCTION                                                             * 04000019
*                                                                     * 04400019
*   UPON ENTRY AT IHKLAB REGISTERS ARE SAVED,ADDRESSABILITY FOR TUB,  * 04800019
*   CLB ESTABLISHED,ADDRESSES OF DECB AND USER BUFFER LOADED INTO     * 05200019
*   APPROPRIATE REGISTERS,AND IF ENTERED FOR THE FIRST TIME (IHKLAB IS* 05600019
*   ENTERED TWICE IN ORDER TO PERFORM ITS FUNCTION) WHICH IS          * 06000019
*   RECOGNIZED BY TUBIDAPN FLAG IN TUB,THEN LENGTH OF DATA TO BE      * 06400019
*   WRITTEN IS TESTED IF ZERO AND IF YES CONTROL IS RETURNED TO CALLER* 06800019
*   OTHERWISE TRAILING BLANKS ARE ELIMINATED,IF NOT OTHERWISE REQUIRED* 07200019
*   NEW LENGTH STORED IN TUBDATAL IN TUB AND SAVED IN TUBPARM2+2 FOR  * 07600019
*   SECOND ENTRY AND CONTROL RETURNED TO CALLER.                      * 08000019
*                                                                     * 08400019
*   IF ENTERED FOR SECOND TIME,FLAG TUBNOCRN IN TUB IS TESTED AND IF  * 08800019
*   NOT THEN CR IS APPENDED AND FOR 1050 AND 2740 EOB IS INSERTED AT  * 09200019
*   THE END OF THE TEXT.                                              * 09600019
*                                                                     * 10000019
*   IF IDLES ARE NEEDED IN THE FRONT OF TEXT,IN THE CASE WHEN PREVIOUS* 10400019
*   READ OPERATION TERMINATED WITHOUT OR PREVIOUS TEXT WRITTEN        * 10800019
*   CONTAINED NUMBER OF CHARACTERS WHICH MAY CAUSE PRINTING ON 'FLY-  * 11200019
*   BACK',THEN THEY ARE ALLOWED AS PART OF TEXT TO BE WRITTEN.        * 11600019
*   TEXT IS THEN MOVED FROM USER BUFFER TO LINE BUFFER,LENGTH IS      * 12000019
*   STORED IN TUBDATAL IN TUB,LENGTH FOR NEXT COMPUTATION FOR IDLES   * 12400019
*   IS SAVED IN TUBIDLEL AND AFTER RESTORING CALLER'S REGISTERS       * 12800019
*   CONTROL IS RETURNED TO THE CALLER.                                * 13200019
*                                                                     * 13600019
*ENTRY POINT                                                          * 14000019
*                                                                     * 14400019
*   IHKLAB IS THE ONLY ENTRY POINT AND IT IS ENTERED BY IHKLAD ONLY.  * 14800019
*                                                                     * 15200019
*INPUT                                                                * 15600019
*                                                                     * 16000019
*   REGISTER 1 POINTS TO A WORD CONTAINING THE ADDRESS OF TUB.        * 16400019
*                                                                     * 16800019
*OUTPUT                                                               * 17200019
*                                                                     * 17600019
*   REGISTER 1 POINTS TO A WORD CONTAINING THE ADDRESS OF TUB         * 18000019
*                                                                     * 18400019
*EXTERNALS                                                            * 18800019
*                                                                     * 19200019
*   NONE                                                              * 19600019
*                                                                     * 20000019
*EXITS                                                                * 20400019
*                                                                     * 20800019
*   NORMAL - RETURN TO CALLER VIA REG 14.IF ENTERED FOR THE FIRST     * 21200019
*            TIME REG 15=0.OTHERWISE REG 15 NE 0.                     * 21600019
*                                                                     * 22000019
*   ERROR  - N/A                                                      * 22400019
*                                                                     * 22800019
*TABLES/WORK AREAS                                                    * 23200019
*                                                                     * 23600019
*   DECB   - BTAM CONTROL BLOCK                                       * 24000019
*   CLB    - CONV.LINE BLOCK                                          * 24400019
*   TUB    - TERM.USER BLOCK                                          * 24800019
*   USER BUFFER/LINE BUFFER (152 BYTES)                               * 25200019
*                                                                     * 25600019
*ATTRIBUTES                                                           * 26000019
*                                                                     * 26400019
*   REENTRANT,RESIDENT                                                * 26800019
*                                                                     * 27200019
*NOTES                                                                * 27600019
*                                                                     * 28000019
*   CHARACTER CODE DEPENDENCIES                                       * 28400019
*                                                                     * 28800019
*      X'15' EBCDIC CARRIAGE RETURN                                   * 29200019
*      X'17' EBCDIC IDLE CHARACTERS                                   * 29600019
*      X'26' EBCDIC END-OF-BLOCK (EOB)                                * 30000019
*      X'40' EBCDIC BLANK                                               30400019
*                                                                     * 30800019
*                                                                     * 31200019
*********************************************************************** 31600019
         EJECT                                                          32000019
*              SYMBOLIC REGISTER ASSIGNMENTS                          * 32400019
         SPACE 2                                                        32800019
BGNRG0   EQU   0              INDEX REGISTER                            33200019
LAPARARG EQU   1              CLB OR TUB ADDRESS FOR LINKAGE            33600019
LATUBRG  EQU   2              BASE ADDRESS REGISTER FOR TUB             34000019
LACLBRG  EQU   3              BASE ADDRESS REGISTER FOR CLB             34400019
LADECBRG EQU   4              ADDRESS OF LINE DECB                      34800019
LNG      EQU   5             POINTER TO END OF DATA                     35200019
LIN      EQU   6             LINE BUFFER ADDRESS                        35600019
BGNLNGRG EQU   7              FOR COMPUTING TEXT LENGTH                 36000019
BGNWKRG0 EQU   8              EVEN WORK REGISTER FOR IHKLAB             36400019
BGNWKRG1 EQU   9              ODD WORK REGISTER FOR IHKLAB              36800019
LAWRKRG0 EQU   10             EVEN WORK RESISTER FOR LA MODULES         37200019
LAWRKRG1 EQU   11             ODD WORK REGISTER FOR LA MODULES          37600019
SCN      EQU   LAWRKRG1                                                 38000019
LABASERG EQU   12             BASE REGISTER FOR LA MODULES              38400019
LALINKRG EQU   15             CONTAINS LINK ADDRESS                     38800019
         SPACE 2                                                        39200019
*              SYMBOLIC DISPLACEMENTS, LENGTHS, AND CONSTANTS         * 39600019
         SPACE 1                                                        40000019
* DISPLACEMENTS -                                                     * 40400019
         SPACE 1                                                        40800019
BGN0     EQU   0                                                        41200019
BGN1     EQU   1                                                        41600019
BGN2     EQU   2                                                        42000019
BGN5     EQU   5                                                        42400019
BGN6     EQU   6                                                        42800019
BGN8     EQU   8                                                        43000019
BGN10    EQU   10                                                       43200019
BGN16    EQU   16                                                       43600019
A34      EQU   18                                                       44000019
         SPACE 1                                                        44400019
* CONSTANTS -                                                         * 44800019
         SPACE 1                                                        45200019
BGNREAD  EQU   X'01'                    BTAM 'DECTYPE' READ FLAG        45600019
BGNBLANK EQU   X'40'                    EBCDIC BLANK                    46000019
BGNCR    EQU   X'15'                    EBCDIC CARRIAGE RETURN          46400019
BGNIDL   EQU   X'17'                    IDLE CHARACTER                  46800019
BGNEOB   EQU   X'26'                    END-OF-BLOCK                    47200019
SEVENF   EQU   X'7F'         GOOD BTAM COMPLETION                       47600019
         EJECT                                                          48000019
         SAVE  (14,12),,LAB70345                                 A36802 48400020
         LR    LABASERG,LALINKRG        ESTABLISH BASE ADDRESS          48800019
         USING TUBDSECT,LATUBRG         ESTABLISH ADDRESSIBILITY OF TUB 49200019
         USING CLBDSECT,LACLBRG         ESTABLISH ADDRESSIBILITY OF CLB 49600019
         USING IHKLAB,LABASERG                                          50000019
         USING IECTDECB,LADECBRG                                        50400019
         L     LATUBRG,BGN0(BGNRG0,LAPARARG) GET ADDRESS OF TUB         50800019
         L     LACLBRG,TUBCLBAD         LOAD CLB ADDRESS IN CLB REG     51200019
BGNCONT  L     LADECBRG,CLBLDECB        GET ADDRESS OF LINE DECB        51600019
         L     LAWRKRG1,TUBUFFAD        GET USER BUFFER ADDRESS         52000019
         LA    LAWRKRG1,BGN0(BGNRG0,LAWRKRG1) CLEAR HIGH ORDER BYTE     52400019
         LH    LNG,TUBDATAL             GET LENGTH OF USER DATA         52800019
         TM    TUBFLG4,TUBIDAPN         ENTERED TO APEND IDLES          53200019
         BO    IDLEJAZZ                 YES, THEN DO IT TO IT           53600019
         OI    TUBFLG4,TUBIDAPN         NO, DO IT TO IT NEXT TIME       54000019
         TM    TUBFLG3,TUBNOCRN         CARRIAGE NOT TO BE RETURNED ?   54400019
         BO    LABEXIT                  IF SO, GO AROUND                54800019
         SPACE                                                          55200019
         AR    SCN,LNG                  COMPUTE DATA END ADDRESS        55600019
         SPACE                                                          56000019
LOP      DS    0H                                                       56400019
         BCTR  SCN,0                    BACK UP ONE POSITION            56800019
         CLI   BGN0(SCN),BGNBLANK       IS DIS A BLANK                  57200019
         BNE   GOOD                     BOUT TIME FINISHED UP           57600019
         BCT   LNG,LOP                  DECREMENT LENGTH                58000019
GOOD     DS    0H                                                       58400019
         STH    LNG,TUBDATAL            SET IT UP FOR LEW MAYBE         58800019
LABEXIT  DS    0H                                                       59200019
         TM    DECTYPE+BGN1,BGNREAD     WAS LAST OPERATION A READ ?     59600019
         BO    *+BGN10                  IF SO, GO AROUND                60000019
         MVC   DECLNGTH,TUBIDLEL        IF WRITE, SAVE LENGTH FOR LATER 60400019
         STH   LNG,TUBIDLEL             SAVE LENGTH FOR IDLE COMP.      60800019
         EJECT                                                          60820019
*********************************************************************** 60840019
*                                                                       60860019
*        THIS SUB-ROUTINE REMOVES IMBEDDED CARRIER RETURN CHARACTERS    60880019
*                                                                       60900019
*********************************************************************** 60920019
         SPACE 2                                                        60940019
         LTR   LNG,LNG                  IS THERE ANY DATA ?             60960019
         BZ    BGNLINK                  IF NOT, EXIT                    60980019
         L     SCN,TUBUFFAD             GET DATA ADDRESS                61000019
CRLOOP   CLI   BGN0(SCN),BGNCR          IS THE CHARACTER A 'CR' ?       61020019
         BNE   *+BGN8                   IF NOT, LEAVE IT ALONE          61040019
         MVI   BGN0(SCN),BGNBLANK       IF SO, REPLACE IT WITH A BLANK  61060019
         LA    SCN,BGN1(SCN)            POINT TO NEXT CHARACTER         61080019
         BCT   LNG,CRLOOP               WHEN ALL DATA SCANNED, QUIT     61100019
         SPACE 2                                                        61120019
*********************************************************************** 61140019
         SPACE 2                                                        61160019
         B     BGNLINK                  HANG IT UP THE FIRST TIME       61200019
         SPACE 3                                                        61600019
IDLEJAZZ DS    0H                                                       62000019
         NI    TUBFLG4,TUBIDAPF         SUPPRESS TRAILING BLANKS NEXT   62400019
         LR    BGNLNGRG,LNG             SAVE LENGTH                     62800019
          AR    LNG,LAWRKRG1            GET END OF USER DATA ADDRESS    63200019
         L     LIN,CLBUFFAD             GET LINE BUFFER ADDRESS         63600019
         LA    LIN,BGN0(LIN)            CLEAR HIGH ORDER BYTE           64000019
         MVC   BGN0(BGN16,LIN),BGNLCC   MOVE IN LINE CONTROL CHARS      64400019
         TM    TUBFLG3,TUBNOCRN         NEED TO INSERT A CR             64800019
         BO    OVERCR                   NO, SKIP CR INSERT              65200019
         SPACE                                                          65600019
         MVI   BGN0(LNG),BGNCR          ADD CR TO END OF USER DATA      66000019
         LA    BGNLNGRG,BGN1(BGNLNGRG)  INCREMENT LENGTH                66400019
         LA    LNG,BGN1(LNG)            UPDATE END OF BUFFER ADDRESS    66800019
         SPACE                                                          67200019
OVERCR   DS    0H                                                       67600019
         TM    CLBDEVTP,CLB2741         IS IT A 2741 ?                  68000019
         BO    BGNSKEOB                 IF SO, DOESN'T NEED EOB         68400019
         MVI   BGN0(LNG),BGNEOB         APPEND EOB                      68800019
         LA    BGNLNGRG,BGN1(BGNRG0,BGNLNGRG) POINT TO END OF TEXT      69200019
         SPACE                                                          69600019
BGNSKEOB EQU   *                                                        70000019
         TM    TUBREQST,TUBIDLEN        DO IDLES NEED TO PRECEDE TEXT   70400019
         BZ    BGNWRPRE                 NOT FOR READ, CHECK A WRITE     70800019
         TM    CLBREQST,CLBSTOPN        MODIFY OR STOP?          A36802 70900020
         BO    BGNOSET                  YES, SKIP RESETTING CR   A36802 71000020
         NI    TUBREQST,TUBIDLEF        TURN OFF FLAG FOR NEXT TIME     71200019
BGNOSET  CLI   BGN0(LADECBRG),SEVENF    ERROR IN LAST OPERATION? A36802 71600020
         BNE   NOTABS                   IF NOT, COMPUTE NECESSARY IDLES 72000019
         LA    BGNLNGRG,BGN16(BGNLNGRG) GET LINE BUFFER LENGTH          72400019
         B     FINUP                    COMPLETE LAB'S FUNCTION         72800019
         SPACE                                                          73200019
BGNWRPRE EQU   *                                                        73600019
         MVI   BGN1(LIN),BGNIDL         OVERLAY CR TO GET ANOTHER       74000019
         SR    BGNWKRG1,BGNWKRG1        CLEAR REG FOR NO IDLES REQ'D    74400019
         TM    CLBDEVTP,CLB2741         IS IT A 2741 ?                  74800019
         BZ    OVERCR1                  IF NOT, NO CHECKING NEEDED      75200019
         LH    15,DECLNGTH              GET LENGTH OF PREVIOUS OPER.    75600019
         TM    DECTYPE+BGN1,BGNREAD     WAS LAST OPERATION A READ ?     76000019
         BZ    NOTABS                   IF NOT, GO COMPUTE IDLES        76400019
         CH    15,EIGHTY                CHECK LENGTH OF THE READ        76800019
         BNH   BGNEX                                                    77200019
         SH    15,EIGHTY                DECREMENT FOR COMPUTATION       77600019
         STH   15,DECLNGTH              PASS IT TO COMPUTER             78000019
         B     NOTABS                   GO GET 'EM                      78400019
OVERCR1  EQU   *                                                        78800019
         TM    BGN5(LADECBRG),BGNREAD   WAS PREVIOUS READ               79200019
         BO    BGNEX                    YES,GO MOVE TEXT                79600019
NOTABS   DS    0H                                                       80000019
         SR    BGNWKRG0,BGNWKRG0        CLEAR EVEN REG FOR DIVIDE       80400019
         LH    BGNWKRG1,BGN6(LADECBRG)  GET LENGTH FOR IDLE COMPUTING   80800019
         LA    BGNWKRG1,A34(BGNWKRG1)   GET QUANTITY FOR IDLE ALGORITHM 81200019
         D     BGNWKRG0,BGNTEN          DIVIDE QUANTITY BY TEN          81600019
        SPACE                                                           82000019
         TM    BGN5(LADECBRG),BGNREAD   LAST OPERATION A READ           82400019
         BO    BGNEX1                   YES, DON'T OVERLAY CR CHAR      82800019
         BCTR  BGNWKRG1,0               NEED ONE LESS IDLE              83200019
         SPACE                                                          83600019
BGNEX1   DS    0H                                                       84000019
         LA    LIN,BGN0(BGNWKRG1,LIN)   POSITION FOR TEXT MOVE          84400019
BGNEX    DS    0H                                                       84800019
         BCTR  BGNLNGRG,0               DECREMENT FOR EXECUTED MOVE     85200019
         EX    BGNLNGRG,BGNMOVE         MOVE USER DATA TO LINE BUFFER   85600019
         LA    BGNLNGRG,BGN2(BGNLNGRG,BGNWKRG1) TOTAL UP LINE BUF SIZE  86000019
         SPACE                                                          86400019
FINUP    DS    0H                                                       86800019
         STH   BGNLNGRG,TUBDATAL        PASS LENTH OF LINE BUFFER ALONG 87200019
BGNLINK  DS    0H                                                       87600019
         SPACE                                                          88000019
     RETURN  (14,12),RC=(15)                                            88400019
         EJECT                                                          88800019
         SPACE 1                                                        89200019
BGNMOVE  MVC   BGN1(0,LIN),BGN0(LAWRKRG1)                               89600019
BGNTEN   DC    F'10'                                                    90000019
BGNLCC   DC    X'0215171717171717'           CTRL CHARCT AND IDLES      90400019
         DC    X'1717171717171717'                                      90800019
IDLES    EQU   BGNLCC+2                                                 91200019
EIGHTY   DC    H'60'                                                    91600019
         SPACE 2                                                        92000019
         EJECT                                                          92400019
         IECTDECB                                                       93200019
         IHKCDSCT  CLB=YES,TUB=YES                                      93600019
         END                                                            94000019
