LAD      TITLE 'IHKLAD - LINE ADMINISTRATOR ENTRY AND CONTROL ROUTINE'  00100019
IHKLAD   CSECT                                                          00200019
*A384100-384700                                                 A40209  00210026
*A510500                                                        A45668  00220026
* 279000,390000,398000,531000                                    A34584 00230020
* 329000,346000,451000,785000                                    A34585 00260020
*A433500                                                         A36802 00270020
*C279000,433300-433500                                           A36802 00280020
*C279000,668000                                                  A51330 00286026
*A836000,864000                                                  A51330 00292026
* C299000                                                       OX00342 00293002
* C279000                                                       OX00342 00294002
* A277000                                                       OX00342 00295002
* A433010-433090                                                OX00342 00296002
* C433100                                                       OX00342 00297002
* C881000                                                       OX00342 00298002
         SPACE 2                                                        00300019
*********************************************************************** 00400019
*                                                                     * 00500019
*STATUS                                                               * 00600019
*                                                                     * 00700019
*   CHANGE LEVEL 0                                                    * 00800019
*                                                                     * 00900019
*FUNCTION                                                             * 01000019
*                                                                     * 01100019
*   UPON ENTRY CALLER'S REGISTERS ARE SAVED,PARAMETER LIST ADDRESS IS * 01200019
*   STORED AND PASSED PARAMETER IS TESTED FOR TUB OR CLB.             * 01300019
*                                                                     * 01400019
*   IF CLB  - GETMAIN FOR LINE SAVE AREA (72 BYTES) IS ISSUED AND IF  * 01500019
*             SUCCESSFUL,THE ADDRESS IS STORED IN CLB,ADDRESSES OF    * 01600019
*             CALLER'S AND LINE SAVE AREA ARE CHAINED ACCORDING TO THE* 01700019
*             STANDARD CONVENTIONS,ACTIVE FLAG (CLBACTVN) IS SET IN   * 01800019
*             CLB AND BRANCH AND LINK TO IHKLAP IS MADE.              * 01900019
*             IF GETMAIN FAILS,RETURN WITH NON-ZERO VALUE IN REG 15   * 02000019
*             TO THE CALLER IS MADE AND CLBREQST FLAGS IN CLB ARE     * 02100019
*             TURNED OFF.                                             * 02200019
*             AFTER THE CONTROL FROM IHKLAP IS RECEIVED,RETURN CODE   * 02300019
*             IS CHECKED AND IF GOOD BTAM COMPLETION CODE (REG 15=0)  * 02400019
*             BRANCH AND LINK TO DISPATCHER FOR WAIT ON COMPLETION OF * 02500019
*             LINE OPERATION IS MADE.                                 * 02600019
*             IF BAD BTAM COMPLETION CODE(REG 15 NE 0),CLBINOPN FLAG  * 02700019
*             IN CLB IS POSTED,LINE SAVE AREA FREEMAIN-ED AND CONTROL * 02800019
*             RETURNED TO THE CALLER WITH REG 15 NE 0.                * 02900019
*                                                                     * 03000019
*             WHEN LINE OPERATION COMPLETES,DISPATCHER GIVES CONTROL  * 03100019
*             BACK TO IHKLAD WHERE TEST FOR EXISTENCE OF TUB IS MADE. * 03200019
*             IF TUB NOT YET ALLOCATED,GETMAIN FOR LINE BUFFER AND TUB* 03300019
*             IS ISSUED.FOR SUCCESSFUL GETMAIN ADDRESS OF LINE BUFFER * 03400019
*             IS STORED IN THE CLB, TUB CHAIN UPDATED, TUB ADDRESS    * 03500019
*             IN AVT UPDATED.TUB IDENTIFIER FLAG (TUBIDENT) IS SET IN * 03600019
*             TUB,SEQUENCE NUMBER (CLBLNSEQ) STORED IN TUB,REQUEST    * 03700019
*             FLAGS IN CLB (CLBRDTIN) ARE RESET AND CONTROL IS        * 03800019
*             RETURNED TO THE CALLER WITH ZERO LENGTH SPECIFIED IN    * 03900019
*             TUBDATAL FIELD IN TUB AND REG 15=0.                     * 04000019
*             IF GETMAIN FAILS,THE MESSAGE 'NO VACANCY' CANNED IN     * 04100019
*             IHKLAD IS SENT TO THE TERMINAL AND CONTROL IS RETURNED  * 04200019
*             TO THE CALLER WITH REG 15 NE 0.                         * 04300019
*                                                                     * 04400019
*   IF TUB -  INFORMATION IS MOVED FROM TUB TO CLB,CALLER'S SAVE AREA * 04500019
*             SAVED AND TEST FOR RESET FLAG IN TUB (TUBRSETN) AND FOR * 04600019
*             READ INITIAL (TUBRDTIN) IS MADE.                        * 04700019
*             IF RESET REQUESTED,TUB IS DEALLOCATED,TUB CHAIN UPDATED * 04800019
*             AND IF NECESSARY ADDRESSES OF FIRST AND LAST TUB IN AVT * 04900019
*             ARE UPDATED AS WELL.LINE BUFFER AND TUB ARE FREEMAIN-ED * 05000019
*             AND CONTROL RETURNED TO THE CALLER WITH REG 15=0.       * 05100019
*             IF READ INITIAL REQUESTED,FOR DIAL LINE WRITE WITH RESET* 05200019
*             IS ISSUED TO PREVENT THE PRINTING OF UNWANTED DATA,THEN * 05300019
*             LINE BUFFER AND TUB DEALLOCATED AND THE REST IS SAME AS * 05400019
*             FOR FIRST PART OF HANDLING RESET REQUEST.               * 05500019
*             IF READ INITIAL REQUEST FLAG IN CLB (CLBRDTIN) SET,     * 05600019
*             BRANCH AND LINK TO IHKLAP IS MADE.                      * 05700019
*                                                                     * 05800019
*             IF REQUEST IN TUB (TUBREQST) IS FOR WRITE OR WRITE WITH * 05900019
*             RESPONSE BRANCH AND LINK TO TEXT FORMATING MODULE IHKLAB* 06000019
*             IS MADE.AFTER RETURN,TUBTABAD FIELD IN TUB IS TESTED AND* 06100019
*             IF ANYTHING SPECIFIED AND IHKLAB RETURNED WITH ZERO IN  * 06200019
*             REG 15 THEN IHKLEW MODULE IS CALLED.AFTER RETURN FROM   * 06300019
*             IHKLEW,MODULE IHKLAB IS CALLED FOR THE SECOND TIME.     * 06400019
*             IF TUBTABAD IS NOT SPECIFIED,THEN IHKLAB MODULE IS      * 06500019
*             CALLED FOR SECOND TIME TO PERFORM THE SECOND PART OF ITS* 06600019
*             FUNCTION.IF TUBTABAD IS SPECIFIED AND IHKLAB MODULE     * 06700019
*             RETURNS NON-ZERO IN REG 15,THE MODULE IHKLAB IS CALLED  * 06800019
*             FOR THE SECOND TIME.                                    * 06900019
*                                                                     * 07000019
*             AFTER RECEIVING CONTROL FROM IHKLAB,BRANCH AND LINK TO  * 07100019
*             MODULE IHKLAP IS MADE WHERE LINE OPERATION IS TO BE     * 07200019
*             INITIATED.                                              * 07300019
*                                                                     * 07400019
*             FOR THE READ REQUEST SPECIFIED IN TUB (TUBREADN),OVERIDE* 07500019
*             FLAG IN TUB (TUBOVERN) IS RESET AND BRANCH AND LINK TO  * 07600019
*             MODULE IHKLAP IS MADE.                                  * 07700019
*                                                                     * 07800019
*             AFTER RECEIVING CONTROL FROM IHKLAP,BTAM RETURN CODE IS * 07900019
*             CHECKED AND IF GOOD THEN BRANCH AND LINK TO DISPATCHER  * 08000019
*             TO WAIT FOR COMPLETION OF LINE OPERATION.               * 08100019
*                                                                     * 08200019
*   AFTER THE LINE OPERATION IS COMPLETED,DISPATCHER RETURNS CONTROL, * 08300019
*   AND IF GOOD BTAM COMPLETION CODE THE TYPE OF OPERATION IS CHECKED.* 08400019
*   IF IT WAS WRITE REQUEST,THEN THE CONTROL IS RETURNED AND WRITE    * 08500019
*   REQUEST FLAG IN TUB.                                              * 08600019
*   IF IT WAS READ REQUEST,THEN DATA RECEIVED IS TRANSLATED TO        * 08700019
*   INTERNAL EBCDIC CODE AND FOLLOWING TESTS ARE PERFORMED AND        * 08800019
*   NECESSARY ACTIONS ARE TAKEN:                                      * 08900019
*                                                                     * 09000019
*          A. IF TEXT STARTS WITH ENDING SEQUENCE AND BREAK IS NOT    * 09100019
*             FLAGGED IN TUB CONTROL IS RETURNED WITH ZERO LENGTH     * 09200019
*             SPECIFIED IN TUB (TUBDATAL=0).                          * 09300019
*             IF BREAK FLAG POSTED,CONTROL IS RETURNED WITH ZERO      * 09400019
*             LENGTH AND BREAK FLAG RESET.                            * 09500019
*                                                                     * 09600019
*          B. IF TEXT ENDS WITH BACK SPACE CHARACTER FOLLOWED BY      * 09700019
*             ENDING SEQUENCE,LINE OF INPUT IS CANCELLED AND BRANCH   * 09800019
*             AND LINK TO IHKLAP IS MADE WHERE ANOTHER READ OPERATION * 09900019
*             IS TO BE INITIATED.                                     * 10000019
*                                                                     * 10100019
*          C. IF BREAK FLAG SET AND LINE OF TEXT STARTS WITH SPACE    * 10200019
*             CHARACTER FOLLOWED BY ENDING SEQUENCE,THEN OVERRIDE FLAG* 10300019
*             IS SET AND CONTROL RETURNED TO THE CALLER.              * 10400019
*                                                                     * 10500019
*   OTHERWISE,LINE OF TEXT IS SCANNED FOR NON-SIGNIFICANT CHARACTERS  * 10600019
*   SUCH AS LINE FEED AND BACK SPACE,WHICH ARE ELIMINATED AND VALID   * 10700019
*   TEXT IS PROVIDED IN USER BUFFER (LINE BUFFER +16).                * 10800019
*                                                                     * 10900019
*   WHEN SCANNING,IF HORIZ.TAB CHARACTER IS ENCOUNTERED AND TUBTABAD  * 11000019
*   IN TUB SPECIFIED,BRANCH AND LINK TO IHKLAT MODULE IS MADE.        * 11100019
*   AFTER RECEIVING CONTROL FROM IHKLAT,SCAN IS CONTINUED.            * 11200019
*   WHEN EOB OR EOT CHARACTER IS FOUND,THE LENGTH OF VALID TEST IS    * 11300019
*   STORED IN TUB (TUBDATAL) AND IN DECB (DECLNGTH) AND CONTROL IS    * 11400019
*   RETURNED TO THE CALLER WITH READ REQUEST FLAG IN TUB RESET.       * 11500019
*   CALLERS REGISTERS ARE RESTORED,ZERO CODE STORED IN REG 15,PARAM.  * 11600019
*   LIST ADDRESS IN REG 1 AND BRANCH ON REG 14.                       * 11700019
*                                                                     * 11800019
*   FOR BAD COMPLETION POSTED BY BTAM AFTER RECEIVING CONTROL FROM    * 11900019
*   DISPATCHER,IHKLAD MAKES FOLLOWING TEST AND TAKES APROPRIATE ACTION* 12000019
*   WHEN RECOVERY IS POSSIBLE:                                        * 12100019
*                                                                     * 12200019
*           - FOR TERMINAL 2741 AND BREAK FLAG SET IN DECB,TUBREAKN   * 12300019
*             AND TUBREADN FLAGS ARE SET IN TUB,WRITE REQUEST IN TUB  * 12400019
*             (TUBWRITN) RESET AND BRANCH AND LINK TO IHKLAP.         * 12500019
*                                                                     * 12600019
*           - IF NEGATIVE RESPONSE TO POLLING POSTED AND TUBREAKN FLAG* 12700019
*             IN TUB SET,CONTROL IS RETURNED WITH ZERO LENGTH IN TUB. * 12800019
*             TUBREAKN FLAG IS RESET.                                 * 12900019
*             IF TUBREAKN IS NOT SET,TERMINAL ON DIAL IS RE-POLLED OR * 13000019
*             DESELECTED.                                             * 13100019
*                                                                     * 13200019
*           - IF LOST DATA CONDITION POSTED,ON READ OPERATION,MESSAGE * 13300019
*             'LINE TOO LONG,REENTER LINE' IS SENT TO THE TERMINAL,AND* 13400019
*             USER IS PROMPTED TO ENTER LINE OF TEXT.                 * 13500019
*                                                                     * 13600019
*           - IF TIME OUT OCCURS ON A TEXT OPERATION,MESSAGE'TIME OUT'* 13700019
*             IS SENT TO THE TERMINAL AND USER IS PROMPTED TO RE-ENTER* 13800019
*             LINE OF TEXT.                                           * 13900019
*                                                                     * 14000019
*           - IF TIME OUT ON RESPONSE TO POLLING,ERROR FLAG TUBTIMEN  * 14100019
*             IN TUB IS POSTED AND RETURN WITH NON-ZERO IN REG 15 IS  * 14200019
*             MADE.                                                   * 14300019
*                                                                     * 14400019
*           - IF NON-TEXT TIME OUT,TERMINAL IS CONSIDERED OFF-LINE/   * 14500019
*             ON HOOK AND ERROR FLAG (TUBOFFLN) IN TUB IS SET AND     * 14600019
*             RETURN WITH REG 15 NE ZERO IS MADE.                     * 14700019
*                                                                     * 14800019
*   FOR ANY OTHER ERROR CONDITION,ERROR FLAG TUBTIMEN IN TUB IS SET   * 14900019
*   AND CONTROL RETURNED WITH NON ZERO IN REG 15.                     * 15000019
*                                                                     * 15100019
*ENTRY POINT:                                                         * 15200019
*                                                                     * 15300019
*   IHKLAD IS THE ONLY ENTRY POINT AND IT IS ALWAYS ENTERED WHEN ANY  * 15400019
*   OF LINE ADMINISTRATOR MODULES ARE CALLED.                         * 15500019
*                                                                     * 15600019
*INPUT:                                                               * 15700019
*                                                                     * 15800019
*   PARAMETER LIST ADDRESS IN REG 1 CONTAINING THE ADDRESS OF CLB OR  * 15900019
*   TUB.REGISTER 13 CONTAINS CALLER'S SAVE AREA ADDRESS,REG 14        * 16000019
*   CONTAINS RETURN ADDRESS,REGISTER 15 CONTAINS ADDRESS OF IHKLAD.   * 16100019
*                                                                     * 16200019
*OUTPUT:                                                              * 16300019
*                                                                     * 16400019
*   PARAMETER LIST ADDRESS IN REG 1 CONTAINING THE ADDRESS OF CLB OR  * 16500019
*   TUB.REG 13 CONTAINS CALLER'S SAVE AREA ADD,REG 14 CONTAINS RETURN * 16600019
*   ADD AND REG 15 CONTAINS EITHER ZERO OR NON-ZERO.                  * 16700019
*                                                                     * 16800019
*EXTERNALS:                                                           * 16900019
*                                                                     * 17000019
*   IHKDSP - TO WAIT FOR COMPLETION OF LINE I/O OPERATION.            * 17100019
*   IHKLAB - TO FORMAT TEXT SENT TO THE TERMINAL.                     * 17200019
*   IHKLEW - TO INSERT TABS IF OUT TABS ARE SPECIFIED.                * 17300019
*   IHKLAT - TO HANDLE TABSETTING INFORMATION.                        * 17400019
*   IHKLAP - TO INITIATE LINE I/O OPERATIONS.                         * 17500019
*                                                                     * 17600019
*EXITS:                                                               * 17700019
*                                                                     * 17800019
*   NORMAL - RETURN TO CALLING ROUTINE WITH REG 15=0.                 * 17900019
*                                                                     * 18000019
*   ERROR - RETURN TO CALLING ROUTINE WITH REG 15 NON-ZERO            * 18100019
*                                                                     * 18200019
*TABLES/WORK AREAS:                                                   * 18300019
*                                                                     * 18400019
*   IHKAVT - ADDRESS VECTOR TABLE                                     * 18500019
*   IHKCCT - CRJE CONTROL TABLE                                       * 18600019
*   CLB    - CONV.LINE BLOCK                                          * 18700019
*   TUB    - TERM.USER BLOCK                                          * 18800019
*   DECB   - BTAM CONTROL BLOCK                                       * 18900019
*   LINE BUFFER (152 BYTES)                                           * 19000019
*                                                                     * 19100019
*ATTRIBUTES :                                                         * 19200019
*                                                                     * 19300019
*   REENTRANT,RESIDENT,REFRESHABLE                                    * 19400019
*                                                                     * 19500019
*NOTES:                                                               * 19600019
*                                                                     * 19700019
*   NONE.                                                             * 19800019
*                                                                     * 19900019
*********************************************************************** 20000019
         EJECT                                                          20100019
*                                                                     * 20200019
*        R E G I S T E R S                                              20300019
*                                                                       20400019
*                                                                       20500019
LADREG0  EQU   0                                                        20600019
LR0      EQU   LADREG0                                                  20700019
LAPARARG EQU   1              PARAMETER LIST ADDRESS                    20800019
LATUBRG  EQU   2              TERMINAL/USER BLOCK ADDRESS               20900019
LR2      EQU   LATUBRG                                                  21000019
LACLBRG  EQU   3              CONVERSATIONAL LINE BLOCK ADDRESS         21100019
LADECBRG EQU   4              BTAM DATA EVENT CONTROL BLOCK ADDRESS     21200019
LAAREARG EQU   5              INPUT/OUTPUT AREA ADDRESS                 21300019
LADREG6  EQU   6              ERROR MESSAGE LENGTH                      21400019
LADAVTRG EQU   7              ADDRESS VECTOR TABLE BASE REGISTER        21500019
LADREG8  EQU   8              UNUSED                                    21600019
LADREG9  EQU   9              UNUSED                                    21700019
LR9      EQU   LADREG9                                                  21800019
LAWRKRG0 EQU   10             EVEN WORK REGISTER                        21900019
LAWRKRG1 EQU   11             ODD WORK REGISTER                         22000019
LR11     EQU   LAWRKRG1                                                 22100019
LABASERG EQU   12             BASE REGISTER                             22200019
LASAVERG EQU   13             SAVEAREA ADDRESS REGISTER                 22300019
LARTRNRG EQU   14             RETURN ADDRESS REGISTER                   22400019
LALINKRG EQU   15             LINKAGE REGISTER                          22500019
*                                                                       22600019
*                                                                       22700019
*        E Q U A T E D  C O N S T A N T S                               22800019
*                                                                       22900019
LADZEROB EQU   0              ZERO FOR IMMEDIATE INSTRUCTIONS           23000019
LADWRCCW EQU   1              WRITE CHANNEL COMMAND                     23100019
LAD00    EQU   X'00'                                                    23200019
LAD7F    EQU   X'7F'          BTAM GOOD COMPLETION CODE                 23300019
LADTEXT  EQU   X'91'          BTAM TP-CODE FOR READ/WRITE TEXT          23400019
LADCR    EQU   X'15'          CARRIER RETURN CHARACTER                  23500019
LADLF    EQU   X'25'          LINE FEED CHARACTER                       23600019
LADEOT   EQU   X'37'          END OF TRANSMISSION CHARACTER             23700019
LADBS    EQU   X'16'          BACKSPACE CHARACTER                       23800019
LADSP    EQU   X'40'                                                    23900019
LADHT    EQU   X'05'          HORIZONTAL TAB CHARACTER                  24000019
LADCHK   EQU   X'8'           DATA CHECK SENSE BIT                      24100019
LADWRRD  EQU   X'06'          READ/WRITE REQUEST                        24200019
CLBRSETN EQU   X'10'                                                    24300019
CLBRSETF EQU   X'EF'                                                    24400019
UE       EQU   X'1'           UNIT EXCEPTION                            24500019
FOXFOX   EQU   X'FF'          END OF TEXT INDICATOR                     24600019
IOHALT   EQU   X'48'          I/O HAKT POST CODE                        24700019
INHIBIT  EQU   X'0A'          INHIBIT COMMAND                           24800019
DISABLE  EQU   X'08'          DISABLE ISSUED BY BTAM ERP                24900019
WRITETTV EQU   X'0F'          BTAM WRITE 'TTV' OP-CODE                  25000019
READTTTP EQU   X'02'          BTAM READ 'TT' OR 'TP' COMMON BIT         25100019
WRITEEOT EQU   X'02'          BTAM TP-CODE FOR WRITE EOT CCW            25150019
         EJECT                                                          25200019
LAD0     EQU   0                                                        25300019
LAD1     EQU   1                                                        25400019
LADTIME  EQU   1              SENSE OF TIME OUT IN BTAM DECB            25500019
LAD2     EQU   2                                                        25600019
LADBREAK EQU   2              BREAK FLAG IN BTAM DECB                   25700019
LADLOST  EQU   2              SENSE OR LOST DATA IN BTAM DECB           25800019
LAD3B    EQU   3                                                        25900019
LAD4B    EQU   4                                                        26000019
LADNGRSP EQU   4                                                        26100019
LAD6B    EQU   6                                                        26200019
LAD8B    EQU   8                                                        26300019
LAD12B   EQU   12                                                       26400019
LAD16    EQU   16                                                       26500019
LADSAVEL EQU   20                                                       26600019
TUBNEW3  EQU   20                                                       26700019
TUBNEW1  EQU   21                                                       26800019
TUBNEW4  EQU   24                                                       26900019
TUBNEW0  EQU   25                                                       27000019
LAD28B   EQU   28                                                       27100019
LAD32B   EQU   32                                                       27200019
LAD72    EQU   72                                                       27300019
LADUSBFL EQU   136            LENGTH OF USER BUFFER                     27400019
LADBUFFL EQU   152                                                      27500019
LAD256   EQU   256                                                      27600019
HEX00    EQU   X'00'                                                    27700002
         EJECT                                                          27800019
         SAVE  (14,12),,LAD72306       SAVE CALLERS REGISTERS           27900002
         LR    LABASERG,LALINKRG        SET UP BASE REGISTER            28000019
         USING IHKLAD,LABASERG          CSECT BASE REGISTER             28100019
         USING TUBDSECT,LATUBRG         DSECT BASE REGISTER FOR TUB     28200019
         USING CLBDSECT,LACLBRG         DSECT BASE REGISTER FOR CLB     28300019
         USING IECTDECB,LADECBRG        DSECT BASE REGISTER FOR DECB    28400019
         USING AVTDSECT,LADAVTRG        DSECT BASE REGISTER FOR AVT     28500019
         L     LADAVTRG,LADAVT          GET AVT ADDRESS                 28600019
         L     LATUBRG,0(0,LAPARARG)    GET CONTROL BLOCK ADDRESS       28700019
         LA    LATUBRG,LADZEROB(LATUBRG) CLEAR HIGH ORDER BYTE          28800019
         TM    TUBREQST,TUBIDENT        IS IT A TUB ?                   28900019
         BO    LADNOCLB                 IF SO, GO AROUND ALLOCATION     29000019
         SPACE 2                                                        29100019
* AT REQUEST WITH CLB AS PARAMETER SAVE AREA IS PROVIDED, ADDRESS IS    29200019
* INSERTED IN CLB AND SAVED IN CALLER'S SAVE AREA + 8                   29300019
* CALLER'S SAVE AREA ADDRESS IS SAVED IN LINE SAVE AREA + 4             29400019
* REG 13 IS LOADED WITH LINE SAVE AREA ADDRESS, CLB ACTIVE FLAG IS SET  29500019
* ADDRESS OF PARAMETER IS STORED IN REG 1 AND LINK TO IHKLAP IS MADE    29600019
* WHERE READ INITIAL IS SUPPOSED TO BE ISSUED.                          29700019
* NOTE. WHEN CALLER COMES WITH REQUEST PASSING CLB ADDRESS AS PARAMETER 29800019
*       THEN IT IS ASSUMED THAT READ INITIAL IS TO BE ISSUED.           29900019
         SPACE 2                                                        30000019
         LR    LACLBRG,LATUBRG          MOVE CLB ADDRESS TO BASE REG    30100019
         SR    LATUBRG,LATUBRG          INDICATE NO TUB PRESENT         30200019
LADCONT4 L     LADECBRG,CLBLDECB        GET LINE DECB ADDRESS           30300019
         ST    LASAVERG,CLBSAVE+LAD4B   SET SAVE AREA ADDR IN CLB       30400019
         LH    LR0,H72                  GET SAVEAREA LENGTH             30500019
         LA    LALINKRG,CLBSAVAD        ADDR TO PASS BACK AREA GOTTEN   30600019
         BAL   LAWRKRG0,GETMAIN         LINK TO GETMAIN ROUTINE         30700019
         LTR   LALINKRG,LALINKRG        WAS REQUEST SATISFIED?          30800019
         BNZ   LADBDRT1                 GETMAIN FAILED RET TO SYS ADM   30900019
         L     LAPARARG,CLBSAVAD        GET ADDR OF NEW SAVEAREA        31000019
         ST    LASAVERG,LAD4B(LAPARARG) SAVE CALLER'S SAVE AREA ADDR    31100019
         ST    LAPARARG,LAD8B(LASAVERG) STORE SAVE AREA ADD CALLER      31200019
         LR    LASAVERG,LAPARARG        GET SAVE AREA ADDR IN REG 13    31300019
         MVI   CLBSTATS,CLBACTVN        FLAG CLB AS ACTIVE              31400019
LADINIT1 LA    LAPARARG,LAD32B(LASAVERG) GET PARA. LIST ADDRESS         31500019
         B     LADBEGIN                 LINK TO IHKLAP TO SIO/READ IN   31600019
         EJECT                                                          31700019
LADNOCLB L     LACLBRG,TUBCLBAD         GET CLB ADDRESS FROM TUB        31800019
         LA    LACLBRG,0(LACLBRG)       CLEAR HIGH ORDER BYTE           31900019
LADCONT5 L     LAPARARG,CLBSAVAD        GET LINE SAVE AREA ADD  AND     32000019
         ST    LAPARARG,LAD8B(LASAVERG) STORE IN CALLER'S SAVE AREA+8   32100019
         ST    LASAVERG,LAD4B(LAPARARG) SAVE CALLER'S SAVE AREA ADDR    32200019
         ST    LASAVERG,TUBSAVE+LAD4B   IN SAVE AREA AND TUB            32300019
         L     LADECBRG,CLBLDECB        GET LINE DECB ADDRESS           32400019
         LR    LASAVERG,LAPARARG        SAVE AREA ADDR IN PROPER REG    32500019
         LA    LAPARARG,LAD28B(LASAVERG) GET PARA. LIST ADDRESS         32600019
         TM    TUBREQST,TUBRDTIN        IS IT A 'CREAD I OR R' REQUEST? 32700019
         BNO   LADBGN                   IF NOT, DON'T DISABLE THE LINE  32800019
LADWRTN  TM    CLBDEVTP,CLBDIAL         DIAL LINE ?              A34585 32900020
         BZ    LADTUBDE                 IF SO, WRITE 'TN' IS NOT NEEDED 33000019
         TM    DECERRST,DISABLE         DID BTAM DISABLE THE LINE ?     33100019
         BO    LADTUBDE                 IF SO, DON'T DO IT AGAIN        33200019
         WRITE (LADECBRG),TN,MF=E                                       33300019
         LTR   LALINKRG,LALINKRG                                        33400019
         BNZ   LADTUBDE                                                 33500019
         LR    LAPARARG,LADECBRG        PASS DECB ADDRESS TO DISPATCHER 33600019
         L     LALINKRG,IHKYYDSP        GET THE ADDRESS OF DISP         33700019
         BALR  LARTRNRG,LALINKRG        LINK TO IT                      33800019
         SPACE 2                                                        33900019
* HERE LINE BUFFER AND TUB AREA IS DEALLOCATED (FREEMAIN-ED)            34000019
* TUB CHAINING IS TO BE UPDATED                                         34100019
* IF TUB TO BE DEALLOCATED IS FIRST OR LAST IN CHAIN,ADDRESSES IN AVT   34200019
* ARE TO BE UPDATED                                                     34300019
* IF TUB IS THE ONLY ONE IN CHAIN, ADDRESSES IN AVT ARE ZEROIZED        34400019
         SPACE 2                                                        34500019
LADTUBDE LTR   LATUBRG,LATUBRG          TUB EXIST?               A34585 34550020
         BZ    LADINIT1                 NO, RE-ISSUE 'CREAD I'   A34585 34600020
         L     LR11,IHKYYTUB+LAD4B      ELSE GET LAST TUB IN CHAIA34585 34650020
         L     LR9,IHKYYTUB             GET FIRST                       34700019
         TM    TUBREQST,TUBRSETN        IF CREAD 'R', NO I/O IS NEEDED  34720019
         BO    *+LAD12B                 GO ON ABOUT YOUR BUSINESS       34740019
         TM    CLBREQST,CLBSTOPN        IS STOP FLAG SET ?              34760019
         BO    LADRTRN1                 IF SO, DON'T START ANY I/O      34780019
         CLR   LR2,LR9                  IS THIS TUB FIRST IN CHAIN      34800019
         BE    LADTUBF                  YES,UPDATE AVT AND NEXT TUB     34900019
         CLR   LR2,LR11                 AND CHECK IF LAST IN CHAIN      35000019
         BE    LADTUBL                  YES,UPDATE AVT AND PREV INCHAIN 35100019
         EJECT                                                          35200019
* TUB TO BE DEALLOCATED IS IN THE MIDDLE OF THE CHAIN.                  35300019
* TUBNEXT OF THE PRECEEDING TUB IS UPDATED BY THE ADDRESS OF THE TUB    35400019
* NEXT IN THE CHAIN OF THE TUB TO BE DEALLOCATED.                       35500019
* TUBPREV OF THE FOLLOWING TUB IS UPDATED BY THE ADDRESS OF TUB         35600019
* PRECEEDING THE TUB TO BE DEALLOCATED.                                 35700019
         SPACE 2                                                        35800019
         L     LR9,TUBPREV              OTHERWISE GET ADD OF PREV TUB   35900019
         MVC   TUBNEW0(LAD3B,LR9),TUBNEXT+LAD1 UPDATE TUBNEXT           36000019
         L     LR9,TUBNEXT              GET ADD OF NEXT TUB IN CHAIN    36100019
         MVC   TUBNEW1(LAD3B,LR9),TUBPREV+LAD1 UPDATE TUBPREV           36200019
         SPACE 2                                                        36300019
* HERE LINE BUFFER AND TUB ARE FREEMAINED IF READ INIT OR RESET REQ     36400019
* IF RESET IS REQ LINE SAVE AREA IS FREEMAINED AS WELL AND CONTROL      36500019
* IS RETURNED TO CALLER WITH LINE ACTIVE FLAG TURNED OFF (CLBACTV) AND  36600019
* RET CODE IN REG 15 IS ZERO WITH CLB AS PARAMETER                      36700019
* IF REQ IS FOR READ I NIT, CLB ADD IS SET IN PARAM REG                 36800019
* AND LINK TO IHKLAP IS MADE WHERE READ INIT IS ISSUED                  36900019
* REG 13 CONTAINS ADD OF CALLER'S SAVE AREA (LASAVERG)                  37000019
* REG 2 CONTAINS ADD OF TUB (LATUBRG)                                   37100019
* REG 3 CONTAINS CLB ADD (LACLBRG)                                      37200019
         SPACE 2                                                        37300019
LADDEALL L     LAPARARG,TUBFQEB         GET ADDRESS OF QUEUED MESSAGE   37400019
         LTR   LAPARARG,LAPARARG        IS THERE A QUEUED MESSAGE?      37600019
         BZ    LADNOMSG                 IF NOT, SKIP FREEMAIN           37700019
         LA    LADREG0,LAD72            ELSE, GET FREEMAIN LENGTH       37800019
         FREEMAIN R,LV=(0),A=(1)                                        37900019
LADNOMSG L     LAPARARG,CLBUFFAD        GET ADDR OF AREA TO BE FREED    38000019
         LA    LADREG0,LADBUFFL+TUBSIZE GET LENGTH OF AREA TO FREEMAIN  38200019
         NI    TUBREQST,FOXFOX-TUBIDENT-TUBIDLEN TURN OFF UNWANTED BITS 38300019
         OC    CLBREQST(LAD1),TUBREQST  COPY REQUEST FLAGS TO CLB       38400019
         TM    CLBDEVTP,CLB2741D       2741 OR DIAL-UP?         A40209  38410026
         BZ    NORSET                  NO                       A40209  38420026
         TM    CLBDEVTP,CLBDIAL        DIAL-UP?                 A40209  38430026
         BO    NORSET                  YES                      A40209  38440026
         OI    CLBREQST,CLBMPT         ISSUE EOT BEFORE READ I FOR NON  38450026
*                                                               A40209  38460026
NORSET   EQU   *                       SWITCHED 2741'S          A40209  38470026
         FREEMAIN R,LV=(0),A=(1)                                        38500019
         SR    LATUBRG,LATUBRG          INDICATE NO TUB ALLOCATED       38600019
         ST    LATUBRG,CLBUFFAD         CLEAR STATUS AND BUFFER ADDRESS 38700019
         TM    CLBREQST,CLBRSETN        LINE TO BE RESET?               38800019
         BNO   LADINIT1                 IF NOT, GO ISSUE READ INITIAL   38900019
FREESAVE LR    LAPARARG,LASAVERG        ADDRESS OF AREA TO FREE  A34584 39000020
         L     LASAVERG,LAD4B(LAPARARG)                                 39200019
         LA    LADREG0,LAD72            GET LENGTH                      39300019
         FREEMAIN R,LV=(0),A=(1)                                        39400019
         MVI   CLBREQST,LAD00           CLEAR ALL REQUEST FLAGS         39500019
         ST    LATUBRG,CLBSAVAD         CLEAR SAVE AREA ADDR AND RTNCD  39600019
         LR    LALINKRG,LACLBRG         RETURN CLB ADDRESS              39700019
         B     LADRTRN2                 RETURN TO CALLER         A34584 39800020
         EJECT                                                          39900019
LADERRIN CLI   DECSENS0,LADCHK          WAS THERE A DATA CHECK ?        40000019
         BE    GOBACK                   IF SO, IGNORE IT                40100019
         TM    CLBDEVTP,CLB2741         2741 TERMINAL?                  40200019
         BO    LADSKIP                  SKIP NEG. RESP IF YES           40300019
         OI    DECFLAGS,LADNGRSP        SET FLAG FOR INITIAL OPERATION  40400019
LADSKIP  TM    DECSENS0,LADLOST         WAS IT LOST DATA ?              40500019
         BO    GOBACK                   IF SO, IGNORE IT                40600019
         OI    TUBSTATS,TUBTIMEN                                        40700019
         B     LADBDRTN                 PASS BACK ERROR RETURN CODE     40800019
LADBGN   TM    TUBREQST,TUBWRITN        IS IT WRITE REQUEST?            40900019
         BNO   LADBEG1                  IF NOT, TURN OFF OVERRIDE FLAG  41000019
         SPACE 2                                                        41100019
* HERE IHKLAB IS CALLED FOR FIRST TIME TO PERFORM FIRST PART OF ITS     41200019
* FUNCTION                                                              41300019
         SPACE 2                                                        41400019
         L     LALINKRG,IHKYYLAB        GET ADDRESS OF BEGIN ROUTINE    41500019
         BALR  LARTRNRG,LALINKRG        LINK TO IT                      41600019
         SR    LAWRKRG0,LAWRKRG0        OTHERWISE CLEAR REG FOR COMP    41700019
         C     LAWRKRG0,TUBOUTAB        TABSET SPECIFIED?               41800019
         BE    LADLAB2                  IF NOT, DON'T GO TO IHKLEW      41900019
         L     LALINKRG,IHKYYLEW        IF ZERO GET ADDRESS IHKLEW      42000019
         BALR  LARTRNRG,LALINKRG        AND LINK TO IT                  42100019
         SPACE 2                                                        42200019
* HERE IHKLAB IS CALLED FOR SECOND TIME TO PERF SECOND PART OF ITS      42300019
* FUNCTION                                                              42400019
         SPACE 2                                                        42500019
LADLAB2  L     LALINKRG,IHKYYLAB        GET ADD OF IHKLAB               42600019
         BALR  LARTRNRG,LALINKRG        AND LINK TO IT AGAIN            42700019
         B     LADBEGIN      GO TO LINK TO IHKLAP TO INIT OPERATION     42800019
         SPACE 2                                                        42900019
* HERE COMES WHEN REQUEST FOR READ IS RECEIVED(CREAD)                   43000019
         SPACE 2                                                        43100019
LADBEG1  NI    TUBFLG3,TUBOVERF         TURN OFF FLAG FOR OVERRIDE      43200019
LADBEGIN L     LALINKRG,IHKYYLAP        GET ADDRESS OF POINT-TO-POINT   43300019
         TM    TUBSTATS,TUBREAKN                                        43301002
         BZ    STEST                                                    43302002
         L     LARTRNRG,IHKYYCCT                                        43303002
         USING CCTDSECT,LARTRNRG                                        43304002
         TM    CCTOPT1,CCTSUP                                           43305002
         DROP  LARTRNRG                                                 43306002
         BZ    STEST                                                    43307002
         CLI   TUBUSRID,HEX00                                           43308002
         BE    LADCHBRK                                                 43309002
STEST    TM    CLBREQST,CLBSTOPN                                        43310002
         BNO   NOSTOP                   IF NOT, CONTINUE ON             43320019
         TM    TUBREQST,TUBREADN        READ REQUEST OUTSTANDING?A36802 43330020
         BO    STOP                     IF YES, FORGET IT        A36802 43340020
         NI    TUBREQST,TUBIDLEF        MAKE SURE NO C R         A36802 43350020
NOSTOP   EQU   *                                                        43360019
         BALR  LARTRNRG,LALINKRG        ROUTINE AND LINK TO IT          43400019
LADBTCK  CLI   CLBRTNCD,LADZEROB        CHECK READ/WRITE RETURN CODE    43500019
         BNE   LADGETBF                 IF NON ZERO TEST FOR TUB        43600019
         LR    LAPARARG,LADECBRG        PASS DECB ADDRESS TO DISPATCHER 43700019
         L     LALINKRG,IHKYYDSP        ADDRESS OF CRJE DISPATCHER      43800019
         BALR  LARTRNRG,LALINKRG        LINK TO DISPATCHER FOR WAIT     43900019
         TM    CLBSTATS,CLBTQUEN        IS THIS LINE ON THE TIMER Q?    44000019
         BZ    LADGETBF                 IF NOT, DON'T GO TO IHKLAY      44100019
         LA    LAPARARG,LAD32B(LASAVERG) POINT TO PARAMETER LIST        44200019
         L     LALINKRG,IHKYYLAY        GET ADDRESS OF IHKLAY           44300019
         BALR  LARTRNRG,LALINKRG        LET HIM LOOK AT IT              44400019
         EJECT                                                          44500019
LADGETBF LTR   LATUBRG,LATUBRG          IS THERE A TUB ALLOCATED?       44600019
         BNZ   LADGOTUB                 IF SO, GO AROUND ALLOCATION     44700019
         CLI   CLBREQST,LAD0            ARE ANY REQUEST FLAGS SET ?     44800019
         BNE   *+LAD12B                 IF SO, CONTINUE CHECKING        44900019
         OI    CLBREQST,CLBRDTIN        OTHERWISE, SET 'CRED I' FLAGS   45000019
         B     LADWRTN                  AND GO ISSUE READ INIT   A34585 45100020
         NI    CLBREQST,CLBRDTIF        TURN OFF 'CREAD I' FLAGS        45200019
         LA    LR0,TUBSIZE+LADBUFFL     GET LENGTH NEEDED               45300019
         LA    LALINKRG,CLBUFFAD        ADDR FOR PASSING BACK AREA      45400019
         BAL   LAWRKRG0,GETMAIN         LINK TO GETMAIN ROUTINE         45500019
         LTR   LALINKRG,LALINKRG        GETMAIN O.K.                    45600019
         BNZ   LADNOSP                  NO,GO SEND MESSAGE TO USER      45700019
         L     LATUBRG,CLBUFFAD         GET ADDR OF AREA GOTTEN         45800019
         LA    LATUBRG,LADBUFFL(LATUBRG) POINT BEYOND BUFFER TO TUB     45900019
         XC    TUBSTATS(LAD256),TUBSTATS     CLEAR THE NEW TUB          46000019
         XC    TUBSTATS+LAD256(TUBSIZE-LAD256),TUBSTATS+LAD256          46100019
         L     LR9,IHKYYTUB             GET FIRST IN CHAIN FROM AVT     46300019
         L     LR11,IHKYYTUB+LAD4B      GET LAST IN CHAIN FROM AVT      46400019
         LTR   LR9,LR9                  IS FIRST ZERO(NO TUB ALLOC)?    46500019
         BNZ   LADCHAIN                 NO, GO CHAIN THIS TUB           46600019
         ST    LR2,IHKYYTUB             OTHERWISE SET ADDR IN AVT FOR   46700019
         ST    LR2,IHKYYTUB+LAD4B       FIRST AND LAST IN CHAIN AND     46800019
         B     LADTUBUP                 GO TO UPDATE INFORMATIOM IN TUB 46900019
         SPACE 1                                                        47000019
GETMAIN  L     LAPARARG,IHKYYGML        GET ADDR OF GETMAIN LIST        47100019
         ST    LR0,LAD0(LAPARARG)       STORE LENGTH NEEDED IN LIST     47200019
         ST    LALINKRG,LAD4B(LAPARARG) STORE ADDR TO PASS IT BACK IN   47300019
         SVC   4                                                        47400019
         BR    LAWRKRG0                 RETURN TO CALLER                47500019
         SPACE 1                                                        47600019
LADTUBF  L     LR9,TUBNEXT              GET ADD OF NEXT IN CHAIN        47700019
         LTR   LR9,LR9                  IS THIS THE ONLY TUB IN CHAIN   47800019
         BZ    LADNOTUB                 YES, UPDATE ADD IN AVT (ZEROS)  47900019
         ST    LR9,IHKYYTUB             DEQUEUE FROM START OF CHAIN     48000019
         MVC   TUBNEW3(LAD4B,LR9),LADZEROW SET TUBPREV TO ZERO          48100019
         B     LADDEALL                 GO FREEMAIN AND CHECK FOR RESET 48200019
LADNOTUB ST    LR9,IHKYYTUB             STORE ZEROS IN AVT, FIRST AND   48300019
         ST    LR9,IHKYYTUB+LAD4B       LAST SHOULD CONTAIN ZERO        48400019
         B     LADDEALL                 GO FREEMAIN AND CHECK FOR RESET 48500019
LADTUBL  L     LR11,TUBPREV             GET ADD OF PREV IN CHAIN        48600019
         ST    LR11,IHKYYTUB+LAD4B      STORE IT IN AVT AS LAST         48700019
         MVC   TUBNEW4(LAD4B,LR11),LADZEROW SET TUBNEXT TO ZERO         48800019
         B     LADDEALL                 GO FREEMAIN AND CHECK FOR RESET 48900019
         EJECT                                                          49000019
* HERE COMES WHEN NEW TUB IS TO BE ALLOCATED.                           49100019
* ADDRESS OF TUB IS INSERTED IN AVT AS LAST TUB IN CHAIN                49200019
* TUBNEXT IN THE NEXT TO THE LAST TUB CONTAINS ADDRESS OF NEW ALLOC TUB 49300019
* TUBPREV IN NEW ALLOC TUB CONTAINS THE ADD OF THE NEXT TO THE LAST IN  49400019
* CHAIN.                                                                49500019
         SPACE 2                                                        49600019
LADCHAIN ST    LR2,IHKYYTUB+LAD4B       INSERT ADD OF NEW TUB(NOW LAST) 49700019
         ST    LR2,TUBNEW4(LR11)        UPDATE TUBNEXT IN PREV TUB      49800019
         ST    LR11,TUBPREV             UPDATE TUBPREV IN NEW TUB       49900019
         SPACE 2                                                        50000019
* HERE INFORMATION IN NEW ALLOC TUB IS INSERTED(USER BUFF ADD)          50100019
* TUB IDENTIFIER FLAG IS SET IN TUB                                     50200019
* CALLER'S SAVE AREA ADD STORED IN TUBSAVE                              50300019
* LENGTH OF ZERO IS SET IN TUBDATAL FOR SYS ADM TO PROMPT WITH          50400019
* UNDERSCORE                                                            50500019
* TUB ADDRESS IS STORED IN PARAMETER REGISTER AND CONTROL IS RETURNED   50600019
* TO CALLER.                                                            50700019
* 'CREAD I' FLAGS IN CLB ARE TURNED OFF                                 50800019
         SPACE 2                                                        50900019
LADTUBUP ST    LACLBRG,TUBCLBAD         PUT CLB ADDRESS IN TUB          51000019
         MVI   AVLRECFX,LAD1           INITIALIZE TO 1 FOR AFIO A45668  51050026
         L     LAPARARG,CLBUFFAD        GET ADDRESS OF LINE BUFFER      51100019
         LA    LAPARARG,LAD16(LADREG0,LAPARARG) INCREMENT FOR USER BUFF 51200019
         ST    LAPARARG,TUBUFFAD        PUT ADDRESS IN TUB              51300019
         OI    TUBREQST,TUBIDENT        TURN IDENTIFIER BIT BACK ON     51400019
         MVC   TUBSAVE+LAD4B(LAD4B),LAD4B(LASAVERG)                     51500019
         SR    LAWRKRG0,LAWRKRG0        CLEAR REGISTER                  51600019
         MVC   TUBLNSEQ+LAD1(LAD1),CLBLNSEQ LINE SEQ NUMBER IN TUB      51700019
         MVI   TUBIDLEL+LAD1,LAD72      SET IDLE CHARACTER COUNT        51800019
         OI    TUBREQST,TUBIDLEN        SET FLAG FOR SENDING CR         51900019
         OI    TUBFLG1,TUBMID           CAUSE MSG NUMBERS INCLUDED      52000019
         TM    CLBREQST,CLBSTOPN        IS 'MODIFY' STOP BIT ON         52100019
         BO    LADBDRTN                 GO BACK WITH ERROR RETURN CODE  52200019
         CLI   DECSDECB,IOHALT          WAS IOHALT ISSUED BY IHKLAY ?   52207019
         BE    LADERR1                  IF SO, KILL THE LINE            52214019
         CLI   DECSDECB,LAD7F           GOOD BTAM COMPL CODE            52300019
         BNE   LADERRIN                 NO,TAKE ERROR EXIT              52400019
GOBACK   TM    DECCSWST,UE              IS UNIT EXCEPTION SET ?         52500019
         BNO   LADGDRTN                 IF NOT, CARRY ON                52600019
         TM    CLBDEVTP,CLB2741         IF SO, IS IT A 2741 ?           52700019
         BO    LADGDRTN                 IF SO, EOT IS NORMAL            52800019
         OI    DECFLAGS,LADNGRSP        OTHERWISE, SET FLAG FOR NEXT    52900019
         B     LADGDRTN                 RETURN WITH ZERO LENGTH         53000019
LADNOSP  CLI   CLBRTNCD,LAD0            START I/O SUCCESSFUL?    A34584 53020020
         BNE   FREESAVE                 IF NOT TREAT AS CREAD R  A34584 53040020
         TM    CLBREQST,CLBSTOPN        STOP IN PROGRESS?        A34585 53060020
         BO    FREESAVE                 YES, FREE SAVEAREA, EXIT A34585 53080020
         CLI   DECSDECB,LAD7F           LINE ERRORS?             A34585 53100020
         BNE   FREESAVE                 YES, FREE SAVEAREA, EXIT A34585 53120020
         TM    CLBFEATR,CLBCORRE        IS IT A CORRES TERMINAL? A34584 53140020
         BNO   *+LAD12B                 IF NOT, IT IS BCD OR EBCD       53200019
         LA    LAPARARG,LADMSCOR        GET ADDR OF CORRES. MESSAGE     53300019
         B     *+LAD8B                                                  53400019
         LA    LAPARARG,LADMSBCD        GET ADDR OF BCD/EBCD MESSAGE    53500019
         ST    LAPARARG,CLBUFFAD        STORE MSG ADDR IN CLB           53600019
         LA    LAPARARG,MSGLEN          GET MESSAGE LENGTH              53700019
         TM    CLBDEVTP,CLB2741         IS IT A 2741 TERMINAL ?         53800019
         BZ    *+LAD6B                  IF NOT, LEAVE LENGTH ALONE      53900019
         BCTR  LAPARARG,LADREG0         IF SO, DECREMENT LENGTH         54000019
         STH   LAPARARG,DECLNGTH        STORE MESSAGE LENGTH IN DECB    54100019
         B     LADINIT1                 GO TO IHKLAP TO WRITE IT        54200019
         EJECT                                                          54300019
* HERE THE COMPLETION OF LINE I/O OPERATION IS CHECKED AFTER THE        54400019
* CONTROL IS RECEIVED FROM DISPATCHER.                                  54500019
         SPACE 2                                                        54600019
LADGOTUB TM    CLBREQST,CLBSTOPN        IS'MODIFY' STOP ON?             54700019
         BO    STOP                     YES, RETURN WITH NON ZERO       54800019
         CLI   DECSDECB,LAD7F           GOOD BTAM COMPLETION CODE?      54900019
         BNE   LADERROR                 IF NOT, TAKE ERROR EXIT         55000019
         CLI   DECFLAGS,LADZEROB        ARE ANY STATUS FLAGS SET?       55100019
         BNE   LADERROR                 IF NOT, TAKE ERROR EXIT         55200019
         CLI   DECTPCOD,LADTEXT         WAS LAST COMMAND TEXT OPER.?    55300019
         BNE   LADNOTXT                 IF NOT, IS REQUEST SATISFIED    55400019
         CLI   DECCMCOD,LADWRCCW        IF SO, WAS IT A WRITE COMMAND?  55500019
         BE    LADNOTXT                 TO CHECK FOR REQUEST SATISFIED  55600019
         NI    TUBSTATS,TUBERPF         MAKE SURE RETRY FLAGS ARE OFF   55700019
         LH    LAPARARG,DECLNGTH        GET LENGTH OF MESSAGE AREA      55800019
         SH    LAPARARG,DECCOUNT        SUBTRACT RESIDUAL COUNT         55900019
         LTR   LAPARARG,LAPARARG        IS THERE ANY DATA ?             56000019
         BNZ   *+LAD12B                 IF SO, GO PROCESS IT            56100019
         MVI   DECSENS0,LADCHK          IF NOT, CONSIDER AS LINE ERROR  56200019
         B     BAD2740                  AND GO SEND ERROR MESSAGE       56300019
         BCTR  LAPARARG,LADREG0         DECREMENT LENGTH FOR TRANSLATE  56400019
         L     LAAREARG,TUBUFFAD        INPUT AREA FOR READ OPERATION   56500019
         LA    LAAREARG,LAD0(LADREG0,LAAREARG) CLEAR HIGH ORDER BYTE    56600019
         TM    TUBFLG2,TUBEDIT          IS USER IN EDIT MODE ?          56700019
         BNO   LADTXTCK                 IF NOT, DON'T WORRY             56800019
         TM    TUBSTATS,TUBREAKN        IS THIS A BREAK ?               56900019
         BNO   LADTXTCK                 IF NOT, DON'T WORRY             57000019
         L     LALINKRG,TUBDIRAD        GET DIRECTORY ENTRY ADDR        57100019
         USING DIRDSECT,LALINKRG                                        57200019
         TM    DIRATTRL,DIRATEXT        IS HE IN TEXT MODE ?            57300019
         BNO   LADTXTCK                 IF NOT, GO AHEAD                57400019
         DROP  LALINKRG                                                 57500019
         OI    TUBREQST,TUBTEXTN        IF SO, SET FLAG IN TUB          57600019
LADTXTCK TM    TUBREQST,TUBTEXTN        CHECK UPPER/LOWER CASE          57700019
         BZ    LADTXTUP                 DETERMINE TRANSLATE TABLE       57800019
         L     LAWRKRG0,CLBTRNLW        UPPER/LOWER CASE PRESERVATION   57900019
         B     LADTRANS                                                 58000019
LADTXTUP L     LAWRKRG0,CLBTRNUP        ALL UPPER CASE TRANSLATION      58100019
LADTRANS EX    LAPARARG,LADTRINS   TRANSLATE                            58200019
         SPACE 2                                                        58300019
* HERE CHECKING FOR SPECIAL SEQUENCE IS DONE.                           58400019
* NOTE. TEST FOR EOA (CIRCLE D) AS FIRST CHARACTER IS MADE              58500019
* AND IF YES THEN THE TEXT IS SHIFTED FOR ONE POSITION TO THE LEFT      58600019
* AND THEREFORE EOA IS OVERLAYED.                                       58700019
         SPACE 2                                                        58800019
         TM    CLBDEVTP,CLB1050         IS THIS A 1050 LINE ?           58900019
         BZ    LADSEQSC                 IF NOT, FORGET IT               59000019
         CLI   DECTYPE+LAD1,WRITETTV    IF SO, WAS IT A WRITE 'TTV' ?   59100019
         BE    CLOBBER                  IF SO, CLOBBER CIRCLE D         59200019
         TM    DECTYPE+LAD1,READTTTP    WAS IT A READ 'TT' OR 'TP' ?    59300019
         BO    LADSEQSC                 IF SO, THERE IS NO CIRCLE D     59400019
         EJECT                                                          59500019
CLOBBER  MVC   LAD0(LADUSBFL,LAAREARG),LAD1(LAAREARG) OTHERWISE SHIFT   59600019
         BCTR  LAPARARG,LADREG0         DECREMENT COUNT ACCORDINGLY     59700019
LADSEQSC LA    LAWRKRG0,LAD0(LAPARARG,LAAREARG) POINT TO LAST CHAR      59800019
         CLI   LAD0(LAWRKRG0),LADEOT    IS IT EOT?                      59900019
         BNE   NOTEOT                   IF NOT, IT MUST BE EOB          60000019
         TM    CLBDEVTP,CLB2741         IS IT A 2741 ?                  60100019
         BO    NOTEOT                   IF SO, EOT IS NORMAL            60200019
         OI    DECFLAGS,LADNGRSP        OTHERWISE, SET NEG. RESP. FLAG  60300019
NOTEOT   MVI   LAD0(LAWRKRG0),FOXFOX    SET END OF TEXT CHARACTER       60400019
         CLC   LAD0(LAD2,LAAREARG),CRFOX IS IT NULL LINE?               60500019
         BE    LADCHBRK                 IF SO, PROCESS IT               60600019
         CLI   0(LAAREARG),FOXFOX       IS IT NULL LINE?                60700019
         BNE   LADSCAN1                 IF NOT, CONTINUE SCAN           60800019
         TM    TUBSTATS,TUBREAKN        IS IT RESPONSE TO BREAK ?       60900019
         BO    LADCHBRK                 IF SO, DON'T RETURN CARRIAGE    61000019
         OI    TUBREQST,TUBIDLEN        SET FLAG FOR CR AND IDLES       61100019
LADCHBRK MVC   TUBDATAL,LADZEROW        SET ZERO LENGTH IN TUB          61200019
         NI    TUBFLG3,TUBNOCRF         MAKE SURE IT'S OFF              61300019
         B     LADGDRTN                 RETURN TO CALLER                61400019
LADSCAN1 BCTR  LAWRKRG0,LADREG0         BACK UP ONE CHARACTER           61500019
         CLI   LAD0(LAWRKRG0),LADCR     DOES TEXT END WITH CR?          61600019
         BNE   NOCR                                                     61700019
         NI    TUBREQST,TUBIDLEF        MAKE SURE THE CARRIAGE IS LEFT  61800019
         MVI   LAD0(LAWRKRG0),FOXFOX    IF SO, SET END OF TEXT CHAR     61900019
         BCTR  LAWRKRG0,LADREG0         BACK UP ONE MORE CHARACTER      62000019
         B     NOCR+LAD4B                                               62100019
NOCR     OI    TUBREQST,TUBIDLEN        SET FLAG FOR CR AND IDLES       62200019
         CLI   0(LAWRKRG0),LADBS        IS PRIOR CHARACTER A BACKSPACE  62300019
         BNE   LADOVER1                 IF NOT, CONTINUE SCAN           62400019
         OI    TUBREQST,TUBREADN        TURN ON READ REQUEST FLAG       62500019
         NI    TUBREQST,TUBWRITF        TO OMIT WRITE 'TTV'             62600019
         LA    LAPARARG,LAD28B(LASAVERG) GET PARA. LIST ADDRESS         62700019
         B     LADBGN                   LINK TO IT                      62800019
LADOVER1 LA    LADREG9,LAD1(LAWRKRG0)   POINT TO END OF TEXT            62900019
         SR    LADREG9,LAAREARG         NUMBER OF CHARACTERS            63000019
         TM    TUBSTATS,TUBREAKN        IS THE BREAK FLAG SET?          63100019
         BZ    LADSCAN2                 IF NO, CONTINUE SCAN            63200019
         CLI   LAD0(LAAREARG),LADSP     IS TEXT CHARACTER A SPACE?      63300019
         BNE   LADSCAN2                 IF NOT, GO TO SCAN INPUT        63400019
         LR    LAPARARG,LAAREARG        BEGINNING OF TEXT               63500019
         EJECT                                                          63600019
* FIRST CHARACTER IS SPACE AND REST OF TEXT IS INVESTIGATED             63700019
         SPACE 2                                                        63800019
LADOVER2 LA    LAPARARG,LAD1(LAD0,LAPARARG) GET NEXT INPUT CHARACTER    63900019
         CLI   LAD0(LAPARARG),LADSP     IS IT A SPACE?                  64000019
         BE    LADOVER2                 IF YES, GO GET NEXT CHARACTER   64100019
         CLI   LAD0(LAPARARG),FOXFOX    IS IT END OF TEXT ?             64200019
         BNE   LADSCAN2                 OTHERWISE GO TO SCAN INPUT      64300019
         OI    TUBFLG3,TUBOVERN         SET OVERRIDE FLAG               64400019
         LA    LAWRKRG0,LAD1            TO SET DATA LENGTH IN TUB TO 1  64500019
         STH   LAWRKRG0,TUBDATAL                                        64600019
         B     LADGDRTN                                                 64700019
LADSCAN2 LR    LAWRKRG0,LAAREARG        SET UP FOR DATA SCAN            64800019
         LR    LAWRKRG1,LAAREARG        SET UP FOR DATA SCAN            64900019
         CLI   LAD0(LAWRKRG0),LADCR     IS FIRST CHARACTER A CR?        65000019
         BNE   LADSCAN9                 IF NOT, CONTINUE SCAN           65100019
         LA    LAWRKRG0,LAD1(LADREG0,LAWRKRG0) INCREMENT POINTER        65200019
LADSCAN9 CLI   LAD0(LAWRKRG0),FOXFOX    ARE WE AT END OF TEXT?          65300019
         BE    LADCONT1                 IF SO, EXIT                     65400019
         CLI   LAD0(LAWRKRG0),LADLF     LINE FEED CHARACTER?            65500019
         BE    LADECR                   IF SO, STRIP IT OUT             65600019
         CLI   LAD0(LAWRKRG0),LADBS     BACKSPACE CHARACTER?            65700019
         BNE   LADLAT                   NO,CHECK FOR HT CHARACTER       65800019
         CR    LAWRKRG1,LAAREARG        TOO MANY BACKSPACES ENTERED     65900019
         BE    LADECR                   IF SO, DON'T BACK UP ANYMORE    66000019
         BCTR  LAWRKRG1,LADREG0         DECREMENT USER BUFFER POINTER   66100019
LADECR   BCTR  LADREG9,LADREG0          DECREMENT LENGTH FOR LF/BS CHAR 66200019
         B     LADINCR                  INCREMENT THE BUFFER AND CONT   66300019
LADLAT   CLI   LAD0(LAWRKRG0),LADHT     H T CHARACTER?                  66400019
         BNE   LADSCAN3                 NO,IT IS VALID CHAR,GO MOVE     66500019
         SR    LADREG8,LADREG8          OTHERWISE CHECK IF TABSET REQ   66600019
         C     LADREG8,TUBTABAD         SPECIFIED IN TUB                66700019
         BZ    LADLINK4                 SEND ERROR MESSAGE       A51330 66800026
         LA    LAPARARG,TUBPRMLS        GET PARAM LIST ADDRESS          66900019
         ST    LATUBRG,TUBPARM1         STORE TUB ADDRESS               67000019
         ST    LAWRKRG0,TUBPARM2        STORE ADDR OF TAB CHARACTER     67100019
         ST    LAWRKRG1,TUBPARM3        STORE END OF DATA POINTER       67200019
         STH   LADREG9,TUBDATAL         SAVE LENGTH OF REMAINING TEXT   67300019
         L     LALINKRG,IHKYYLAT        GET ADDRESS OF IHKLAT AND       67400019
         BALR  LARTRNRG,LALINKRG        LINK TO IT                      67500019
         BCTR  LADREG9,LADREG0          DECREMENT LENGTH FOR HT CHAR    67600019
         B     LADBRERR(LALINKRG)       BRANCH ACCORDING TO RET CODE    67700019
*********************************************************************** 67800019
LADSCAN3 BCTR  LADREG9,LADREG0          DECREMENT LENGTH OF REMNG TEXT  67900019
LADSCANB MVC   LAD0(LAD1,LAWRKRG1),LAD0(LAWRKRG0) MOVE TO USER BUFFER   68000019
         LA    LAWRKRG1,LAD1(LADREG0,LAWRKRG1) INCREMENT USER BFR PTR   68100019
LADINCR  LA    LAWRKRG0,LAD1(LADREG0,LAWRKRG0) INCREMENT LINE BFR PTR   68200019
         B     LADSCAN9                                                 68300019
LADBRERR B     LADCONT                  NORMAL RETURN CONT SCAN         68400019
         B     LADLINK1                 ERROR, LINK TO MSG WRITER       68500019
LADCONT  L     LAWRKRG0,LAD4B(LADREG0,LAPARARG)                         68600019
         LR    LAWRKRG1,LAWRKRG0        DITTO                           68700019
         B     LADSCAN9                                                 68800019
         EJECT                                                          68900019
LADNOTXT TM    TUBREQST,TUBREADN        WAS IT A READ REQUEST?          69000019
         BO    LADREAD1                 IF SO, USE NORMAL LINKAGE       69100019
LADGDRTN NI    TUBSTATS,TUBREAKF-TUBERPN MAKE SURE THE FLAGS ARE OFF    69200019
         NI    TUBREQST,TUBRQSTF        TURN OFF TUB REQUEST FLAGS      69300019
         L     LASAVERG,TUBSAVE+LAD4B   REG 13 HAS CALLER'S SAVE AR ADD 69400019
         LR    LALINKRG,LATUBRG         RETURN TUB ADDRESS              69500019
LADRSTOR L     LARTRNRG,LAD12B(LASAVERG) RESTORE RETURN ADDRESS         69600019
         LM    LADREG0,LABASERG,LADSAVEL(LASAVERG) RESTORE ALL REGS     69700019
         ST    LALINKRG,LAD0(LAD0,LAPARARG) RETURN PARAMETER            69800019
         SR    LALINKRG,LALINKRG        RETURN CODE OF ZERO             69900019
         BR    LARTRNRG                 MAKE GOOD RETURN                70000019
LADCONT1 SR    LAWRKRG1,LAAREARG        SUBTRACT FOR DATA LENGTH        70100019
         STH   LAWRKRG1,TUBDATAL        PUT LENGTH IN TUB               70200019
         TM    TUBREQST,TUBIDLEN        NECESSARY TO RETURN CARRIAGE ?  70300019
         BZ    TURNOFF                  IF NOT, DON'T WORRY ABOUT IT    70400019
         TM    TUBFLG3,TUBNOCRN         WAS CARRIAGE RETURNED LAST TIME 70500019
         BZ    TURNOFF                  IF SO, DON'T WORRY ABOUT IT     70600019
         AH    LAWRKRG1,TUBIDLEL        BUT ADD LENGTH IF IT WASN'T     70700019
TURNOFF  NI    TUBFLG3,TUBNOCRF         TURN OFF FLAG TO AVOID MISTAKES 70800019
         STH   LAWRKRG1,DECLNGTH        ALSO IN DECB FOR IHKLAB         70900019
         LTR   LAWRKRG1,LAWRKRG1        IS IT ZERO LENGTH ?             71000019
         BZ    LADGDRTN                 IF SO, GO BACK TO CALLER NORMAL 71100019
LADCONT2 TM    TUBSTATS,TUBREAKN        IS BREAK FLAG SET               71200019
         BO    LADRTRN1+LAD8B           IF SO,RETURN WITH NON-ZERO CODE 71300019
         B     LADGDRTN                 GO BACK TO CALLER               71400019
         EJECT                                                          71500019
* HERE ERROR CONDITION POSTED IN DECB BY BTAM IS ANALYZED               71600019
* BREAK(INTERRUPT) CONDITION AT 2741 IS HANDLED                         71700019
* FOR NEGATIVE RESPONSE TO POLLING OR ADDRESSING TERMINAL IS RE POLLED  71800019
* OR DE SELECTED                                                        71900019
* FOR LOST DATA AND IF WRITE OPERATION ERROR IS FLAGGED REQUESTING      72000019
* RESET FOR THE LINE (SYS ADM ISSUES CREAD R), IF READ OPERATION        72100019
* MESSAGE TO TERMINAL IS SENT AND OPERATION RESUMED                     72200019
* FOR TIME OUT ON TEXT MESSAGE IS SENT TO TERMINAL AND OPERATION IS     72300019
* RESUMED                                                               72400019
* FOR TIME OUT ON RESPONSE TO POLLING ERROR IS FLAGGED AND RETURN TO    72500019
* CALLER WITH NON ZERO RET CODE                                         72600019
* FOR NON TEXT TIME OUT ERROR IS FLAGGED AND RETURN TO CALLER WITH NON  72700019
* ZERO RET CODE                                                         72800019
* FOR ALL OTHER ERROR CONDITIONS FLAG IS SET IN TUB AND RET TO CALLER   72900019
         SPACE 2                                                        73000019
LADERROR NI    TUBFLG3,TUBNOCRF         MAKE SURE CARRIAGE IS RETURNED  73100019
         TM    DECFLAGS,LADBREAK        IS BREAK FLAG SET?              73200019
         BZ    LADNOBRK                 IF NOT, CONTINUE ANALYSIS       73300019
         OI    TUBSTATS,TUBREAKN        TURN ON BREAK INDICATOR         73400019
LADREAD  OI    TUBREQST,TUBREADN        TURN ON READ REQUEST FLAG       73500019
LADREAD1 NI    TUBREQST,TUBWRITF        TURN OFF WRITE REQUEST FLAG     73600019
         LA    LAPARARG,LAD28B(LASAVERG) GET PARA. LIST ADDRESS         73700019
         B     LADBEG1                  GO RESET OVERRIDE FLAG          73800019
LADNOBRK TM    DECERRST,DISABLE         DID BTAM DISABLE THE LINE ?     73900019
         BO    OFFLINE                  IF SO, FLAG IT AS OFFLINE       74000019
         CLI   DECERRST,LAD00           ANY CATASTROPHIC ERROR FLAGS ?  74100019
         BNE   LADERR1                  IF SO, FORGET IT !              74200019
         TM    DECFLAGS,LADNGRSP        NEGATIVE RESPONSE TO POLLING?   74300019
         BO    LADNEG                   IF SO, CHECK INTO IT            74400019
         CLI   DECSENS0,LADTIME         IS IT TIMEOUT ?                 74500019
         BNE   BAD2740                  IF NOT, CONTINUE CHECKING       74600019
         TM    CLBDEVTP,CLB1050         IF SO, IS IT A 1050 ?           74700019
         BNO   OFFLINE                  IF NOT, TERMINAL IS OFFLINE     74800019
BAD2740  TM    TUBSTATS,TUBERPN         MAXIMUM RETRIES REACHED ?       74900019
         BO    LADERRMX                 IF SO, EXIT                     75000019
         TM    TUBSTATS,TUBERP1N        IS FIRST RETRY FLAG ON ?        75100019
         BZ    *+LAD8B                  IF NOT, GO SET IT               75200019
         OI    TUBSTATS,TUBERP2N        IF SO, SET SECOND RETRY FLAG    75300019
         OI    TUBSTATS,TUBERP1N                                        75400019
         TM    CLBDEVTP,CLB2741         IS TERMINAL A 2741?             75410019
         BNO   NOT41                    IF NOT, DON'T WORRY ABOUT IT    75420019
         TM    DECCSWST,UE              UNIT EXCEPTION STATUS?          75430019
         BNO   NOT41                    IF NOT, LOOK FURTHER            75440019
         TM    DECTYPE+LAD1,LAD1        IF SO, WAS IT A READ OPERATION? 75450019
         BNO   NOT41                    IF NOT, LOOK FURTHER            75460019
         CLI   DECTPCOD,WRITEEOT        IF SO, WAS IT ON THE WRITE EOT? 75470019
         BE    LADREAD1                 IF SO, RESTART THE OPERATION    75480019
NOT41    EQU   *                                                        75490019
         CLI   DECSENS0,LADLOST         IS IT LOST DATA ?               75500019
         BE    LADLINK1                 IF SO, GO WRITE MESSAGE         75600019
         CLI   DECSENS0,LADCHK          IS IT DATA CHECK ?              75700019
         BNE   MORECHEK                 IF NOT, CONTINUE CHECKING       75800019
         CLI   DECTPCOD,LADTEXT         WAS IT A TEXT OPERATION ?       75900019
         BNE   LADERRMX                 IF NOT, FORGET IT               76000019
         CLI   DECCMCOD,LADWRCCW        IF SO, WAS IT A WRITE ?         76100019
         BE    LADERRMX                 IF SO, FORGET IT                76200019
         EJECT                                                          76300019
         TM    CLBDEVTP,CLB1050         IS IT A 1050 ?                  76400019
         BZ    LADLINK3                 IF NOT, SEND MESSAGE            76500019
         TM    DECCSWST,UE              IS UNIT EXCEPTION SET ?         76600019
         BO    LADLINK3                 IF SO, READ 'TP' WON'T WORK     76700019
         READ  (LADECBRG),TP,MF=E       IF SO, ISSUE READ REPEAT        76800019
         STC   15,CLBRTNCD              STORE RETURN CODE FOR ANALYSIS  76900019
         B     LADBTCK                  GO TO DISPATCHER                77000019
MORECHEK CLI   DECSENS0,LADTIME         IS IT TIMEOUT ?                 77100019
         BNE   LADERRMX                 IF NOT, ERROR WAS PRETTY BAD    77200019
         CLI   DECTPCOD,LADTEXT         IF SO, WAS IT TEXT OPERATION    77300019
         BE    LADLINK2                 IF SO, GO SEND MESSAGE          77400019
LADERRMX TM    CLBDEVTP,CLBDIAL         WAS IT A DIAL LINE ?            77500019
         BO    OFFLINE                  IF SO, DISABLE IT ?             77600019
         CLI   DECSENS0,LADLOST         WAS IT LOST DATA ?              77700019
         BNE   LADERR1                                                  77800019
OFFLINE  MVI   TUBSTATS,TUBOFFLN        FLAG TERMINAL AS OFFLINE/ONHOOK 77900019
         B     LADBDRTN                                                 78000019
LADERR1  MVI   TUBSTATS,TUBTIMEN  SET TIME OUT FLAG(UNREC ERROR)        78100019
LADBDRTN LTR   LATUBRG,LATUBRG          IS THERE A TUB??                78200019
         BNZ   LADRTRN1+LAD4B           IF SO, GO AROUND                78300019
LADBDRT1 LR    LALINKRG,LACLBRG         ADDRESS OF PROPER CONTROL BLOCK 78400019
         MVI   CLBREQST,LAD00           CLEAR ALL REQUEST FLAGS  A34585 78500020
         L     LASAVERG,CLBSAVE+LAD4B   ADDR OF CALLER'S SAVE AREA      78600019
         B     LADRTRN2                                                 78700019
STOP     NI    TUBFLG3,TUBNOCRF         MAKE SURE CARRIAGE IS RETURNED  78800019
         CLI   DECSDECB,IOHALT          WAS IOHALT ISSUED BY STOP/MODFY 78900019
         BE    STOPPED                  IF SO, CHECK IT OUT             78920019
         CLI   DECSDECB,LAD7F           IF NOT, WAS THERE AN ERROR      78940019
         BNE   LADERRMX                 IF SO, FORGET IT                78960019
         CLI   DECFLAGS,LAD0            HOW ABOUT ERROR FLAGS           78980019
         BNE   LADERRMX                 IF ANY, PUNT IMMEDIATELY        79000019
         B     LADRTRN1+LAD8B           OTHERWISE, CARRY ON             79020019
STOPPED  EQU  *                                                         79040019
         CLI   DECCMCOD,INHIBIT         WAS HALTED COMMAND AN INHIBIT ? 79100019
         BNE   LADRTRN1                 IF NOT, CARRY ON                79200019
         CLI   DECTPCOD,LADTEXT         WAS IT A TEXT OPERATION ?       79300019
         BNE   LADRTRN1                 IF NOT, WE CAN WRITE TO TERM.   79400019
         OI    TUBSTATS,TUBTIMEN        SET FLAG TO PREVENT 'CWRITE'S   79500019
LADRTRN1 OI    DECFLAGS,LADNGRSP        MAKE SURE NAK FLAG IS SET       79600019
         OI    TUBREQST,TUBIDLEN        SET FLAG TO RETURN THE CARRIAGE 79700019
         LR    LALINKRG,LATUBRG         ADDRESS OF PROPER CONTROL BLOCK 79800019
         NI    TUBREQST,TUBRQSTF        TURN OFF REQ FLAGS              79900019
         L     LASAVERG,TUBSAVE+LAD4B   REG 13 HAS CALLER'S SAVE AR ADD 80000019
         EJECT                                                          80100019
*        RESTORE ALL REGISTERS EXCEPT LALINKRG (15), WHICH              80200019
*        CONTAINS THE ADDRESS OF THE CONTROL BLOCK TO BE RETURNED       80300019
         SPACE 2                                                        80400019
LADRTRN2 L     LARTRNRG,LAD12B(LASAVERG) RESTORE RETURN ADDRESS         80500019
         LM    LADREG0,LABASERG,LADSAVEL(LASAVERG)                      80600019
         ST    LALINKRG,LAD0(LADREG0,LAPARARG) SAVE TUB/CLB ADDR IN     80700019
         BR    LARTRNRG                 PARAMETER LIST AND RETURN       80800019
         SPACE 1                                                        80900019
LADNEG   TM    TUBSTATS,TUBREAKN        WAS IT A SIMULATED BREAK?       81000019
         BO    LADGDRTN                 IF SO, RETURN TO CALLER         81100019
         SPACE 2                                                        81200019
*        IF THE LAST OPERATION WAS A READ, IT IS A DIAL LINE, SINCE     81300019
*        LEASED LINES USE THE WRAP POLLING FUNCTION.                    81400019
         SPACE 2                                                        81500019
         TM    DECTYPE+LAD1,LAD1        WAS IT A READ OPERATION?        81600019
         BO    LADREAD                  IF SO, GO TRY IT AGAIN          81700019
         OI    TUBREQST,TUBWRITN        OTHERWISE, SET WRITE FLAG       81800019
         B     LADREAD1+LAD4B           AND GO TRY THAT AGAIN           81900019
         EJECT                                                          82000019
*HERE LOST DATA CONDITION IS HANDLED                                    82100019
* IF READ, MESSAGE IS SENT AND OPERATION RESUMED                        82200019
* OTHERWISE,ERROR FLAG (TUBTIMEN) IS SET IN TUB AND RETURN NON-ZERO     82300019
         SPACE 2                                                        82400019
LADLINK1 TM    DECTYPE+LAD1,LAD1        WAS READ OPERATION              82500019
         BNO   LADERR1                  NO,FLAG TUBTIMEN                82600019
         LA    LADREG8,LADMS373         GET ADD OF MSG                  82700019
         LA    LADREG9,L'LADMS373       GET MESSAGE LENGTH              82800019
         OI    DECCSWST,UE              FORCE INITIAL OPERATION         82900019
         B     LADSEND                  GO SEND THE MSG                 83000019
LADLINK2 LA    LADREG8,LADMS388         GET ADD OF MSG                  83100019
         LA    LADREG9,L'LADMS388       GET MESSAGE LENGTH              83200019
         OI    DECFLAGS,LADNGRSP        SET NEG. RESP. FLAG FOR WRI\)   83300019
         B     LADSEND                  GO SEND IT                      83400019
LADLINK3 LA    LADREG8,LADMS406         GET MESSAGE ADDRESS             83500019
         LA    LADREG9,L'LADMS406       GET MESSAGE LENGTH              83600019
         B     LADSEND                  GO TO SEND MESSAGE       A51330 83620026
LADLINK4 LA    LADREG8,LADMS414         GET ADDRESS OF MESSAGE   A51330 83640026
         LA    LADREG9,L'LADMS414       GET LENGTH OF MESSAGE    A51330 83660026
         OI    DECCSWST,UE              FORCE INITIAL OPERATION  A51330 83680026
LADSEND  L     LADREG6,TUBUFFAD         GET USER BUFFER ADDRESS         83700019
         TM    TUBFLG1,TUBMID           MESSAGE ID'S REQUESTED ?        83800019
         BO    *+LAD12B                 IF SO, DON'T ADJUST LENGTH      83900019
         SH    LADREG9,LADATE           SUBTRACT MESSAGE ID LENGTH      84000019
         AH    LADREG8,LADATE           POINT BEYOND MESSAGE ID         84100019
         STH   LADREG9,TUBDATAL         STORE IT IN TUB                 84200019
         BCTR  LADREG9,LADREG0          DECREMENT LENGTH FOR EXECUTE    84300019
         EX    LADREG9,LADMOVE          EXECUTE MOVE INSTRUCTION        84400019
         OI    TUBREQST,LADWRRD+TUBIDLEN SET WRITE/READ AND CR/LF FLAGS 84500019
         LA    LAPARARG,LAD28B(LASAVERG) GET PARAMETER LIST ADDRESS     84600019
         TM    DECCSWST,UE              IS UNIT EXCEPTION SET ?         84700019
         BZ    LADBGN                   IF NOT, SEND THE MESSAGE AS IS  84800019
         TM    CLBDEVTP,CLB2741         IF SO, IS IT A 2741 ?           84900019
         BO    LADBGN                   IF SO, UNIT EXCEPTION IS NORMAL 85000019
         OI    DECFLAGS,LADNGRSP        OTHERWISE, HAVE TO RE-SELECT    85100019
         B     LADBGN                   GO WRITE THE MESSAGE            85200019
         EJECT                                                          85300019
*        D E F I N E D  C O N S T A N T S                               85400019
         SPACE 2                                                        85500019
*********************************************************************** 85600019
LADAVT   DC    V(IHKAVT)                ADDRESS VECTOR TABLE ADDRESS    85700019
LADZEROW DC    F'0'           ZERO WORD FOR FULL AND HALF INSTRUCTIONS  85800019
LADATE   DC    H'8'                                                     85900019
H72      DC    H'72'                                                    86000019
CRFOX    DC    X'15FF'                                                  86100019
LADMS373 DC    C'IHK373  LINE TOO LONG, REENTER LINE'                   86200019
LADMS388 DC    C'IHK388  TIMEOUT'                                       86300019
LADMS406 DC    C'IHK406  TP LINE ERROR, REENTER LINE'                   86400019
LADMS414 DC    C'IHK414  NO INPUT TABS SPECIFIED, REENTER LINE'  A51330 86450026
         SPACE 1                                                        86500019
*********************************************************************** 86600019
*        CANNED MESSAGE SENT WHEN GETMAIN FAILS FOR TUB AND BUFFER      86700019
         SPACE 1                                                        86800019
*        EOA  CR  IHK300 OUT OF MAIN STORAGE  CR  EOT                   86900019
LADMSBCD DC    X'16DBF3F0C507151581CCA9A681CCED81C9E2F3CA81A5A6CCD2E2'  87000019
         DC    X'EEEBDB3D'                                              87100019
LADMSCOR DC    X'16DBCCB2AC07131381D1A6A081D1E781C3CFCCA581D2A0D1CACF'  87200019
         DC    X'E2A9DB3D'                                              87300019
MSGLEN   EQU   30                                                       87400019
*********************************************************************** 87500019
LADMOVE  MVC   0(1,LADREG6),0(LADREG8)           MOVE INSTRUCTION       87600019
LADTRINS TR    0(0,LAAREARG),0(LAWRKRG0)         TRANSLATE INSTRUCTIN   87700019
*********************************************************************** 87800019
 TITLE   'D S E C T S  U S E D  I N  T H I S  M O D U L E'              87900019
         IECTDECB                                                       88000019
         IHKCDSCT  CCT=YES,CLB=YES,TUB=YES,AVT=YES,DIR=YES              88100002
         END                                                            88200019
