LAP      TITLE 'IHKLAP - LINE ADMINISTRATOR READ/WRITE ROUTINE'         00200019
IHKLAP   CSECT                                                          00400019
*A265000,D386000,A384300-387300                                 A40209  00500026
* C268000                                                       OX00340 00520002
* C385500                                                       OX00340 00540002
* A385600-385700                                                OX00340 00560002
*********************************************************************** 00600019
*                                                                     * 00800019
*STATUS                                                               * 01000019
*                                                                     * 01200019
*   CHANGE LEVEL 0                                                    * 01400019
*                                                                     * 01600019
*FUNCTION                                                             * 01800019
*                                                                     * 02000019
*   UPON ENTRY CALLER'S REGISTERS ARE SAVED,ADDRESSABILITY FOR CLB,TUB* 02200019
*   AND CCT ESTABLISHED AND TEST FOR TUB IS MADE.                     * 02400019
*   IF NOT TUB, IT IS ASSUMED THAT PARAMETER PASSED IS CLB IN WHICH   * 02600019
*   CASE READ INITIAL FOR ONLY FOUR CHARACTERS IS ISSUED.SINCE LINE   * 02800019
*   BUFFER IS NOT YET EXISTING,UNUSED WORD IN DECB IS USED AS INPUT   * 03000019
*   AREA,THIS WILL PERMIT THE USER TO START THE SESSION BY ENTERING   * 03200019
*   ANY CHARACTER(S) FOLLOWED BY ENDING SEQUENCE.                     * 03400019
*   SAVE AREA 72 BYTES IS PROVIDED AND BTAM MACRO READ INITIAL IS     * 03600019
*   INITIATED.                                                        * 03800019
*   AFTER OPERATION IS STARTED,BTAM RETURNS THE CONTROL WITH RETURN   * 04000019
*   CODE IN REG 15 WHICH IS STORED IN CLBRTNCD IN CLB BEFORE THE      * 04200019
*   CONTROL IS RETURNED TO CALLER.                                    * 04400019
*   IN THE CASE OF NON-ZERO RETURN CODE (20) INDICATING LINE ERROR AT * 04600019
*   OPEN,MACRO LOPEN IS ISSUED TO RECOVER.IF LOPEN SUCCEEDS,THEN READ * 04800019
*   INITIAL OPERATION IS RESTARTED.                                   * 05000019
*                                                                     * 05200019
*   IF TUB PASSED AS PARAMETER,THE CURRENT REQUEST IN TUB IS CHECKED, * 05400019
*   AND FOR WRITE,THE TEXT IS TRANSLATED INTO TRANSMISSION CODE,TEST  * 05600019
*   IS MADE WHETHER SPECIFIED N-NUMBER OF LINES WRITTEN IS REACHED AND* 05800019
*   IF YES,TUBREAKN FLAG IN TUB IS SET AND ACCORDING TO THE TYPE OF   * 06000019
*   TERMINAL NECESSARY LINE CONTROL CHARACTERS ARE PROVIDED IN LINE   * 06200019
*   BUFFER BY CHANGING POINTER OF LINE BUFFER WHERE THE TEXT TO BE    * 06400019
*   WRITTEN IS ALREADY PREPARED BY IHKLAB AND IHKLEW MODULES.         * 06600019
*   DEPENDING ON THE PREVIOUS OPERATION PERFORMED ON THE LINE,PROPER  * 06800019
*   TYPE OF BTAM WRITE MACRO IS ISSUED.                               * 07000019
*                                                                     * 07200019
*   IF REQUEST FOR WRITE WITH RESPONSE,BTAM MACRO FRO COMBINED        * 07400019
*   OPERATION IS USED WHERE TEXT IS WRITTEN AND TERMINAL IS PROMPTED  * 07600019
*   WITH READ WITHOUT RETURNING CONTROL AFTER WRITE OPERATION.        * 07800019
*   AFTER OPERATION IS STARTED,BTAM RETURNS CONTROL WITH RETURN CODE  * 08000019
*   IN REG 15 WHICH IS STORED IN CLBRTNCD IN CLB AND CONTROL IS       * 08200019
*   RETURNED TO THE CALLER.                                           * 08400019
*                                                                     * 08600019
*   IF REQUEST FOR READ,DEPENDING ON PREVIOUS OPERATION PERFORMED ON  * 08800019
*   THE LINE,PROPER TYPE OF BTAM MACRO IS ISSUED.                     * 09000019
*   AFTER OPERATION IS STARTED,CONTROL IS RETURNED ON THE SAME WAY AS * 09200019
*   FOR OPERATIONS DESCRIBED PREVIOUSLY.                              * 09400019
*                                                                     * 09600019
*ENTRY POINT:                                                         * 09800019
*                                                                     * 10000019
*   IHKLAP IS THE ONLY ENTRY POINT AND ACCESSIBLE ONLY TO IHKLAD      * 10200019
*                                                                     * 10400019
*OUTPUT                                                               * 10600019
*                                                                     * 10800019
*   PARAMETER LIST ADDRESS IN REG 1,PASSED TO IHKLAD,CONTAINING THE   * 11000019
*   ADDRESS OF CLB OR TUB.                                            * 11200019
*                                                                     * 11400019
*EXTERNALS:                                                           * 11600019
*                                                                     * 11800019
*   BY USING BTAM READ/WRITE MACRO BRANCH AND LINK TO BTAM IS MADE    * 12000019
*   WHERE LINE OPERATION IS INITIATED.                                * 12200019
*                                                                     * 12400019
*EXITS:                                                               * 12600019
*                                                                     * 12800019
*   NORMAL - RETURN TO IHKLAD VIA REG 14 AND RETURN CODE STORED IN CLB* 13000019
*                                                                     * 13200019
*   ERROR  - RETURN TO IHKLAD VIA REG 14 AND RETURN CODE STORED IN CLB* 13400019
*                                                                     * 13600019
*TABLES AND WORK AREAS:                                               * 13800019
*                                                                     * 14000019
*   IHKCCT - CRJE CONTROL TABLE                                       * 14200019
*   CLB     - CONV.LINE BLOCK                                         * 14400019
*   TUB     - TERM.USER BLOCK                                         * 14600019
*   DECB    - BTAM CONTROL BLOCK                                      * 14800019
*   LINE BUFFER - 152 BYTES                                           * 15000019
*                                                                     * 15200019
*ATTRIBUTES:                                                          * 15400019
*                                                                     * 15600019
*   SERIALLY REUSABLE,RESIDENT                                        * 15800019
*                                                                     * 16000019
*NOTES                                                                * 16200019
*                                                                     * 16400019
*   NONE                                                              * 16600019
*                                                                     * 16800019
*********************************************************************** 17000019
         EJECT                                                          17200019
         EXTRN IHKCCT,IHKAVT                                            17400019
         SPACE 1                                                        17600019
*              SYMBOLIC REGISTER ASSIGNMENTS                          * 17800019
         SPACE 2                                                        18000019
PNTRG0   EQU   0                        INDEX REGISTER - NOT USED       18200019
LAPARARG EQU   1                        ADDRESS OF PARAMETER LIST       18400019
LATUBRG  EQU   2                        BASE ADDRESS REGISTER FOR TUB   18600019
LACLBRG  EQU   3                        BASE ADDRESS REGISTER FOR CLB   18800019
LADECBRG EQU   4                        ADDRESS OF DECB FOR LINE        19000019
PNTLARG  EQU   5                        ADDRESS OF TERMINAL LIST        19200019
LR5      EQU   PNTLARG                                                  19400019
PNTLNGRG EQU   6                        LENGTH OF TEXT TO BE WRITTEN    19600019
LR6      EQU   PNTLNGRG                                                 19800019
PNTRCTRG EQU   7                        CURRENT NUMBER RECORDS SENT     20000019
PNTBUFRG EQU   8                        BUFFER ADDRESS FOR I/O OPER.    20200019
LR8      EQU   PNTBUFRG                                                 20400019
PNTREG9  EQU   9                        NOT USED                        20600019
LAWRKRG0 EQU   10                       EVEN WORK REGISTER - LA MODULES 20800019
LR10     EQU   LAWRKRG0                                                 21000019
LAWRKRG1 EQU   11                       ODD WORK REGISTER - LA MODULES  21200019
LABASERG EQU   12                       BASE ADDRESS REGISTER           21400019
LASAVERG EQU   13                       ADDRESS OF CALLER'S SAVE AREA   21600019
LARTRNRG EQU   14                       CALLER'S ADDRESS FOR LINKAGE    21800019
LALINKRG EQU   15                       PROVIDES LINKAGE TO IHKPNT      22000019
         SPACE 2                                                        22200019
*              SYMBOLIC DISPLACEMENTS AND CONSTANTS                   * 22400019
         SPACE 2                                                        22600019
PNT0     EQU   0                                                        22800019
PNT1     EQU   1                                                        23000019
PNT2     EQU   2                                                        23200019
PNT10    EQU   10                                                       23400019
PNT4     EQU   4                                                        23600019
PNT6     EQU   6                                                        23800019
PNT8     EQU   8                                                        24000019
PNT12    EQU   12                                                       24200019
PNT32    EQU   32                                                       24400019
M8       EQU   8                        BRANCH MASK                     24600019
         SPACE 2                                                        24800019
TUBWRDOF EQU   X'F9'                    READ/WRITE FLAG                 25000019
PNTREADN EQU   X'01'                    BTAM 'DECTYPE' READ FLAG        25200019
PNTNAK   EQU   X'04'                    BTAM 'DECFLAGS' NEG. RESP. FLAG 25400019
IOHALT   EQU   X'48'                    IOHALT POST CODE                25600019
WRAPBITN EQU   X'21'                                                    25800019
WRAPBITF EQU   X'81'                                                    26000019
POLL     EQU   X'15'                                                    26200019
ADDRESS  EQU   X'13'                                                    26400019
IDLE     EQU   X'17'                   IDLE CHARACTER           A40209  26500026
         EJECT                                                          26600019
         SAVE  (14,12),,LAP72306       SAVE CALLERS REGISTERS           26800002
         LR    LABASERG,LALINKRG        ESTABLISH BASE ADDRESS          27000019
         USING TUBDSECT,LATUBRG         SPECIFY BASE REGISTER FOR TUB   27200019
         USING CLBDSECT,LACLBRG         SPECIFY BASE REGISTER FOR CLB   27400019
         USING IHKLAP,LABASERG          SPECIFY IHKLAP BASE REGISTER    27600019
         USING CCTDSECT,PNTREG9         SPECIFY BASE REGISTER FOR CCT   27800019
         USING IECTDECB,LADECBRG                                        28000019
         L     PNTREG9,VCONCCT          GET ADDRESS OF CCT              28200019
         L     LATUBRG,PNT0(PNTRG0,LAPARARG)                            28400019
         LA    LAPARARG,PNTSAVE         GET SAVE AREA ADD IN REG        28600019
         ST    LAPARARG,PNT8(LASAVERG)  STORE SAVE AREA ADD IN CALLER'S 28800019
         ST    LASAVERG,PNTSAVE+PNT4    SAVE CALLER'S SAVEAREA ADDRESS  29000019
         LR    LASAVERG,LAPARARG        PROVIDE SAVE AREA ADD FOR BTAM  29200019
         TM    TUBREQST,TUBIDENT        IS THIS A TUB?                  29400019
         BO    LAPCLBAD                 IF YES, GO GET CLB ADDR         29600019
         LR    LACLBRG,LATUBRG          OTHERWISE, THIS IS CLB ADDRESS  29800019
         SR    LATUBRG,LATUBRG          INDICATE NO TUB ALLOCATED       30000019
         B     LAPDECBD                 SKIP LOADING CLB ADDR           30200019
         SPACE 2                                                        30400019
*********************************************************************** 30600019
* THIS ROUTINE TESTS FOR TUB AND ISSUES 'READ TI' IF TEST IS NEGATIVE.* 30800019
* A TEST IS MADE FOR A WRITE REQUEST AND BRANCH TO WRITE ROUTINE IS   * 31000019
* TAKEN IF TEST IS POSITIVE. OTHERWISE THE APPROPRIATE READ IS ISSUED * 31200019
* DEPENDING UPON TYPE LINE AND TERMINAL.                              * 31400019
*********************************************************************** 31600019
         SPACE 2                                                        31800019
LAPCLBAD L     LACLBRG,TUBCLBAD         GET CLB ADDR FROM TUB           32000019
         LA    LACLBRG,PNT0(LACLBRG)    CLEAR HIGH ORDER BYTE           32200019
LAPDECBD L     LADECBRG,CLBLDECB        GET ADDRESS OF DECB FOR LINE    32400019
         LA    LADECBRG,PNT0(PNTRG0,LADECBRG) CLEAR HIGH ORDER BYTE     32600019
         L     PNTLARG,CLBTRLST         GET TERMINAL LIST ADDRESS       32800019
         LA    PNTLARG,PNT0(PNTRG0,PNTLARG) CLEAR HIGH ORDER BYTE       33000019
         TM    CLBREQST,CLBRDTIN        IS IT A 'CREAD I' REQUEST ?     33200019
         BO    LAPRDIN                  IF SO, GO AROUND                33400019
         LTR   LATUBRG,LATUBRG          IF NO TUB ALLOCATED AND NOT     33600019
         BZ    NOSPACE                  CREAD I, GETAMIN FOR TUB FAILED 33800019
         TM    TUBREQST,TUBWRITN        IS CURRENT REQUEST A WRITE?     34000019
         BO    LAPWRITE                 YES, BRANCH TO WRITE ROUTINE    34200019
LAPCONT1 L     PNTBUFRG,TUBUFFAD        GET USER BUFFER ADDRESS         34400019
         LA    PNTBUFRG,PNT0(PNTBUFRG)  CLEAR HIGH ORDER BYTE           34600019
         LH    PNTLNGRG,H136            GET NORMAL READ LENGTH          34800019
         TM    TUBSTATS,TUBREAKN        IS IT A BREAK REQUEST?          35000019
         BNO   LAPCKTUB                 IF NOT,GO CHECK FOR TUB         35200019
         TM    CLBDEVTP,CLB1050         IS THE TERMINAL A 1050?         35400019
         BO    LAPBREAK                 IF SO, TAKE SPECIAL ACTION      35600019
         EJECT                                                          35800019
LAPCKTUB BAL   LALINKRG,WRAPOLL                                         36000019
         TM    DECFLAGS,PNTNAK          NEGATIVE RESPONSE FLAG SET?     36200019
         BNO   LAPCONT                  IF NOT, CONTINUE CHECKING       36400019
         TM    CLBDEVTP,CLBDIAL         IS IT A DIAL LINE?              36600019
         BO    LAPRCONV                 IF SO, USE CONVERSATIONAL READ  36800019
         B     LAPRDINT                 IF NOT, USE INITIAL READ        37000019
         SPACE 2                                                        37200019
* HERE READ INITIAL IS ISSUED FOR ONLY FOUR CHARACTERS                  37400019
         SPACE 2                                                        37600019
LAPRDIN  LA    PNTBUFRG,DECWAREA        ADDR OF DUMMY READ AREA         37800019
         LH    PNTLNGRG,H4              GET LENGTH FOR INITIAL READ     38000019
         BAL   LALINKRG,WRAPOLL                                         38200019
         SPACE 2                                                        38400019
LAPRDINT TM    CLBREQST,CLBMPT         ISSUE EOT BEFORE READ I? A40209  38430026
         BZ    LAPRDINU                NO                       A40209  38460026
         NI    CLBREQST,X'FF'-CLBMPT   TURN OFF FLAG            A40209  38490026
* WRITE CONTINUE CONVERSATIONAL FOR READ I                      A40209  38520026
         LA    PNTBUFRG,CLBSAVE     POINT TO SPARE WORD IN CLB  A55172  38550002
*                                      FOR BUFFER               A55172  38560002
         MVI   0(PNTBUFRG),X'5E'       INSERT TERMINAL CODE IDLEA55172  38570002
         WRITE (LADECBRG),TTV,,((PNTBUFRG),(PNTBUFRG)),((PNTLNGRG),1), X38580026
               (PNTLARG),MF=E                                   A40209  38610026
         B     LAPSUPRS                CHECK FOR TIME-OUT SUPPRESSION   38640026
*                                                               A40209  38670026
LAPRDINU READ  (LADECBRG),TI,,(PNTBUFRG),(PNTLNGRG),(PNTLARG),MF=E      38700026
*                                                               A40209  38730026
         SPACE 2                                                        38800019
LAPSUPRS TM    CLBFEATR,CLBSUPRS        DOES TERMINAL HAVE TIMEOUT SUP. 39000019
         BZ    LAPRTCOD                 IF NOT, GO BACK TO IHKLAD       39200019
         STC   LALINKRG,CLBRTNCD        SAVE BTAM RETURN CODE           39400019
         LA    LAPARARG,PNT32(LASAVERG) POINT TO PARAMETER LIST         39600019
         L     LALINKRG,AVT             GET AVT ADDRESS                 39800019
         USING AVTDSECT,LALINKRG                                        40000019
         L     LALINKRG,IHKYYLAY        GET ADDRESS OF IHKLAY           40200019
         DROP  LALINKRG                                                 40400019
         BALR  LARTRNRG,LALINKRG        GO TO IHKLAY                    40600019
         B     LAPRTCOD+PNT4                                            40800019
         EJECT                                                          41000019
LAPCONT  TM    DECTYPE+PNT1,PNTREADN    CHECK LAST COMMAND              41200019
         BO    LAPRDCT                  IF READ GO ISSUE READ CONT      41400019
         TM    CLBDEVTP,CLB2741D        DIAL LINE OR 2741 TERMINAL?     41600019
         BNZ   LAPRCONV                 IF YES, BRANCH TO ISSUE READ TV 41800019
         B     LAPRDINT                 OTHERWISE, ISSUE 'READ TI'      42000019
LAPBREAK BAL   LALINKRG,OPENPOLL                                        42200019
         TM    CLBDEVTP,CLBDIAL         IS IT A DIAL LINE ?             42400019
         BZ    LAPRDINT                 IF NOT, USE READ 'TI'           42600019
LAPRCONV BAL   LALINKRG,OPENPOLL                                        42800019
         SPACE 2                                                        43000019
         READ  (LADECBRG),TV,,(PNTBUFRG),136,(PNTLARG),MF=E             43200019
         B     LAPRTCOD                 GO CHECK RET CODE               43400019
         SPACE 2                                                        43600019
LAPRDCT  READ  (LADECBRG),TT,,(PNTBUFRG),136,MF=E                       43800019
         B     LAPRTCOD                 GO CHECK RET CODE               44000019
         EJECT                                                          44200019
*********************************************************************** 44400019
* THIS ROUTINE TRANSLATES TEXT TO BE WRITTEN AND SIMULATES A 'BREAK'  * 44600019
* FOR THOSE TERMINALS WITHOUT BREAK FEATURE. THE RESPONSE FLAG IS     * 44800019
* TESTED (FOR 'CWRITE R') AND A WRITE-READ COMBINATION FOLLOWS IF FLAG* 45000019
* IS ON. OTHERWISE, APPROPRIATE WRITE IS ISSUED DEPENDING UPON TYPE   * 45200019
* LINE AND TERMINAL.                                                  * 45400019
*********************************************************************** 45600019
         SPACE 2                                                        45800019
LAPWRITE L     PNTBUFRG,CLBUFFAD        GET LINE BUFFER ADDRESS         46000019
         LA    PNTBUFRG,PNT0(PNTRG0,PNTBUFRG) CLEAR HIGH ORDER BYTE     46200019
         NI    TUBREQST,TUBWRITF        TURN OFF WRITE REQUEST FLAG     46400019
         LH    PNTLNGRG,TUBDATAL        GET TEXT LENGTH                 46600019
         TM    DECTYPE+PNT1,PNTREADN    IS IT A READ REQUEST ?          46800019
         BO    *+PNT12                  IF YES, SKIP TEST OF RESPONSE   47000019
         CLI   DECTPCOD,PNT6            IF LAST COMMAND WAS READ RESP   47200019
         BE    LAPDSL                   TO ADDRESSING, DO NOT TRANSLATE 47400019
         L     LAWRKRG1,CLBTRNEC        GET ADDRESS OF TRANSLATE TABLE  47600019
         LA    LAWRKRG1,PNT0(PNTRG0,LAWRKRG1) CLEAR HIGH ORDER BYTE     47800019
         EX    PNTLNGRG,LAPTRINS        TRANSLATE TEXT IN LINE BUFFER   48000019
         CLI   DECSDECB,IOHALT          WAS IOHALT ISSUED ?             48200019
         BE    LAPDSL                   IF SO, CHECK NO FURTHER         48400019
LAPCKRD  TM    DECTYPE+PNT1,PNTREADN    WAS LAST OPERATION A READ ?     48600019
         BNO   LAPRECCT                 IF NOT, GO UPDATE N-LINES COUNT 48800019
         SR    LAPARARG,LAPARARG        TO SHOW LAST BTAM MACRO A READ  49000019
         LH    PNTRCTRG,PNTONE          GET NON ZERO IN SWITCH REG      49200019
         B     LAPSTCT                  AND GO TO CHECK FOR RESP        49400019
NOSPACE  L     PNTBUFRG,CLBUFFAD        GET ADDR OF MESSAGE TO BE SENT  49600019
         LA    PNTBUFRG,0(PNTBUFRG)     CLEAR HIGH ORDER BYTE           49800019
         LH    PNTLNGRG,DECLNGTH        GET MESSAGE LENGTH              50000019
         B     LAPCKRSP                 GO BACK INTO THE MAIN STREAM    50200019
LAPRECCT TM    CLBFEATR,CLBREAK         TERMINAL HAVE BREAK FEATURE?    50400019
         BO    LAPCKRSP                 IF YES, SKIP RECORD UPDATE      50600019
         TM    CLBREQST,CLBSTOPN        IS 'STOP' OR 'MODIFY' IN EFFECT 50800019
         BO    LAPCKRSP                 IF SO, FORGET RECORD COUNT      51000019
         TM    TUBFLG3,TUBOVERN         IS REQUEST FOR OVERRIDE N-LINES 51200019
         BO    LAPCKRSP                 IF YES, SKIP RECORD UPDATE      51400019
         LH    PNTRCTRG,TUBRECCT        GET CURRENT RECORD COUNT IN TUB 51600019
         LA    PNTRCTRG,PNT1(PNTRG0,PNTRCTRG) ADD ONE TO COUNT          51800019
         CH    PNTRCTRG,CCTBRK          IS COUNT MAXIMUM                52000019
         BL    LAPSTCT                  BRANCH IF NOT                   52200019
         TM    TUBREQST,TUBREADN        IS IT READ REQUEST              52400019
         BO    LAPZERO                  IF SO, DO NOT SET BREAK FLAG    52600019
         OI    TUBSTATS,TUBREAKN        TURN ON BREAK FLAG              52800019
         OI    TUBREQST,TUBREADN        SET READ REQUEST FLAG           53000019
         EJECT                                                          53200019
LAPZERO  SR    PNTRCTRG,PNTRCTRG        ZERO RECORD COUNT               53400019
LAPSTCT  STH   PNTRCTRG,TUBRECCT        STORE UPDATED COUNT IN TUB      53600019
LAPCKRSP TM    DECFLAGS,PNTNAK          NEG. RESP TO POLLING-LAST READ? 53800019
         BZ    LAPDSL1                  IF NOT, CARRY ON                54000019
         TM    CLBDEVTP,CLB2740         IS IT A 2740 TERMINAL ?         54200019
         BZ    LAPDSL                   IF NOT, GO POLL THE BEAST       54400019
         MVI   DECFLAGS,PNT0            IF IT IS, IGNORE NAK FLAG       54600019
LAPDSL1  LTR   LATUBRG,LATUBRG          IF NO TUB ALLOCATED, IT IS      54800019
         BZ    LAPWRTT                  OUT-OF-SPACE MESSAGE            55000019
         CLI   TUBUSRID,PNT0            IS THERE A USERID ?             55200019
         BE    *+PNT12                  IF NOT, ALLOW ONLINE TERM. TEST 55400019
         TM    TUBREQST,TUBREADN        RESPONSE EXPECTED               55600019
         BO    LAPRESP                  YES, PROCEED COMBINED OPER TTV  55800019
         LTR   LAPARARG,LAPARARG        WAS LAST BTAM MACRO A READ?     56000019
         BNZ   LAPWRCT                  IF NOT, BR TO ISSUE 'WRITE TT'  56200019
         TM    CLBDEVTP,CLB2741         IS IT 2741                      56400019
         BO    LAPWRTT                  YES, GO WRITE IT OUT            56600019
         TM    DECFLAGS,PNTNAK          NEG. RESP TO POLLING-LAST READ? 56800019
         BNO   LAPWRTT                  NO, ISSUE WRITE TT (EOA INCL )  57000019
LAPDSL   BAL   LALINKRG,OPENADDR                                        57200019
         TM    CLBDEVTP,CLBDIAL         DIAL LINE?                      57400019
         BO    LAPWRCNV                 IF YES, BR TO DIAL LINE ROUTINE 57600019
         LA    PNTBUFRG,PNT1(PNTRG0,PNTBUFRG)     WRITE AREA POINTER    57800019
         SPACE 2                                                        58000019
         WRITE (LADECBRG),TI,,(PNTBUFRG),(PNTLNGRG),(PNTLARG),MF=E      58200019
         B     LAPRTCOD                 GO CHECK RET CODE               58400019
         EJECT                                                          58600019
LAPWRCNV LA    PNTBUFRG,PNT1(PNTRG0,PNTBUFRG)     WRITE AREA POINTER    58800019
         SPACE 2                                                        59000019
         WRITE (LADECBRG),TV,,(PNTBUFRG),(PNTLNGRG),(PNTLARG),MF=E      59200019
         B     LAPRTCOD                 GO CHECK RET CODE               59400019
         SPACE 2                                                        59600019
LAPRESP  TM    TUBSTATS,TUBREAKN        ARE WE SIMULATING A BREAK ?     59800019
         BO    LAPWRCT1                 IF SO, DON'T USE WRITE/READ     60000019
         NI    TUBREQST,TUBWRDOF        TURN OFF WRITE/READ REQ IN TUB  60200019
         NI    TUBFLG3,TUBOVERF         TURN OFF OVERRIDE FLAG          60400019
         LTR   LAPARARG,LAPARARG        PREVIOUS COMMAND READ           60600019
         BZ    LAPWRTTV                 ES,INCLUDE EOA                  60800019
         LA    PNTBUFRG,PNT1(PNTRG0,PNTBUFRG) POINT TO LINE BUFFER+1    61000019
         BCTR  PNTLNGRG,PNTRG0          ADJUST DATA LENGTH              61200019
LAPWRTTV L     LAWRKRG0,TUBUFFAD        GET USER BUFFER ADD(READ AREA)  61400019
         LA    LAWRKRG0,PNT0(PNTRG0,LAWRKRG0)     CLEAR HIGH ORDER BYTE 61600019
         BAL   LALINKRG,WRAPOLL                                         61800019
         SPACE 2                                                        62000019
 WRITE (LADECBRG),TTV,,((LR10),(LR8)),(136,(LR6)),(LR5),MF=E            62200019
         B     LAPSUPRS                 CHECK FOR TIMEOUT SUPPRESSION   62400019
         EJECT                                                          62600019
LAPWRCT  LTR   PNTRCTRG,PNTRCTRG       BREAK OCCURED                    62800019
         BNZ   LAPWRCT1                 O, DO NOT SET READ REQ          63000019
         OI    TUBREQST,TUBREADN       OTHERWISE SET READ REQ FOR       63200019
*                                      USER RESPONSE TO BREAK           63400019
LAPWRCT1 LA    PNTBUFRG,PNT1(PNTRG0,PNTBUFRG) POINT TO LINE BUFFER+1    63600019
         BCTR  PNTLNGRG,PNTRG0          ADJUST DATA LENGTH              63800019
         SPACE 2                                                        64000019
LAPWRTT  WRITE (LADECBRG),TT,,(PNTBUFRG),(PNTLNGRG),MF=E                64200019
         B     LAPRTCOD                 GO CHECK RET CODE               64400019
         SPACE 2                                                        64600019
WRAPOLL  TM    CLBDEVTP,CLB1050         IS IT A 1050 ?                  64800019
         BCR   M8,LALINKRG              IF NOT, DON'T WORRY ABOUT IT    65000019
         TM    CLBDEVTP,CLBDIAL         IS IT A DIAL LINE ?             65200019
         BZ    *+PNT10                  IF NOT, ASSUME LEASED           65400019
DIALPOLL MVI   PNT2(PNTLARG),POLL       INSERT POLLING CHARACTER        65600019
         BR    LALINKRG                                                 65800019
         MVI   PNT1(PNTLARG),POLL       MAKE SURE IT'S A POLLING LIST   66000019
         MVI   PNT2(PNTLARG),WRAPBITN   MAKE SURE IT'S A WRAPLIST       66200019
         BR    LALINKRG                                                 66400019
OPENPOLL TM    CLBDEVTP,CLB1050         IS IT A 1050 ?                  66600019
         BCR   M8,LALINKRG                                              66800019
         TM    CLBDEVTP,CLBDIAL         IS IT A DIAL LINE ?             67000019
         BO    DIALPOLL                 IF SO, GO HANDLE IT             67200019
         MVI   PNT1(PNTLARG),POLL       MAKE SURE IT'S A POLLING LIST   67400019
         MVI   PNT2(PNTLARG),WRAPBITF   MAKE SURE IT'S AN OPENLIST      67600019
         BR    LALINKRG                                                 67800019
OPENADDR TM    CLBDEVTP,CLB1050         IS IT A 1050 ?                  68000019
         BCR   M8,LALINKRG                                              68200019
         TM    CLBDEVTP,CLBDIAL         IS IT A DIAL LINE ?             68400019
         BZ    *+PNT10                  IF NOT, ASSUME LEASED           68600019
         MVI   PNT2(PNTLARG),ADDRESS    MAKE IT AN ADDRESSING LIST      68800019
         BR    LALINKRG                                                 69000019
         MVI   PNT1(PNTLARG),ADDRESS    MAKE IT AN ADDRESSING LIST      69200019
         MVI   PNT2(PNTLARG),WRAPBITF   MAKE SURE IT'S AN OPENLIST      69400019
         BR    LALINKRG                                                 69600019
         EJECT                                                          69800019
*********************************************************************** 70000019
* THIS ROUTINE CHECKS RETURN CODE IN REGISTER 15 AFTER EACH I/O       * 70200019
* OPERATION. UPON NORMAL OR ABNORMAL RETURN FROM BTAM, RETURN CODE    * 70400019
* IS STORED IN CLB  AND CONTROL RETURNED TO IHKLAD.                   * 70600019
*********************************************************************** 70800019
         SPACE 2                                                        71000019
LAPRTCOD STC   LALINKRG,CLBRTNCD        STORE RETURN CODE IN CLB        71200019
         LTR   LALINKRG,LALINKRG        GOOD RETURN CODE?               71400019
         BZ    LAPLINK                  IF YES, PREPARE TO RETURN       71600019
         CLI   CLBREQST,CLBRDTIN        WAS IT READ INIT FOR 4 CHARS    71800019
         BNE   LAPLINK                  IF NOT,RETURN TO IHKLAD         72000019
         CH    LALINKRG,PNT14H          WAS IT LINE ERROR AT OPEN?      72200019
         BNE   LAPLINK                  IF NOT,RETURN TO IHKLAD         72400019
         L     LALINKRG,LOPEN           GET ADDRESS OF OPEN RETRY       72600019
         LR    LAPARARG,LADECBRG        PASS IT DECB ADDRESS            72800019
         BALR  LARTRNRG,LALINKRG                                        73000019
         LTR   LALINKRG,LALINKRG        DID LOPEN CLEAR THE PROBLEM?    73200019
         BNZ   LAPLINK                  IF NOT,RETURN TO IHKLAD         73400019
         B     LAPRDINT                 OTHERWISE,RE-ISSUE READ INIT    73600019
LAPLINK  L     LASAVERG,PNTSAVE+PNT4    RESTORE CALLER'S SAVEAREA       73800019
         LM    LARTRNRG,LABASERG,PNT12(LASAVERG) RESTORE REGISTERS      74000019
         BR    LARTRNRG                 RETURN TO IHKLAD                74200019
         EJECT                                                          74400019
* CONSTANTS -                                                         * 74600019
         SPACE 2                                                        74800019
PNTSAVE  DC    18F'0'                   SAVEAREA FOR BTAM READ/WRITE    75000019
PNTONE   DC    H'1'                     TO INITIALIZE RECORD COUNT      75200019
H4       DC    H'4'                     LENGTH FOR READ PRIOR TO LOGON  75400019
H136     DC    H'136'                   LENGTH FOR NORMAL READS         75600019
PNT14H   DC    H'20'                    LINE ERROR AT OPEN RETURN CODE  75800019
VCONCCT  DC    A(IHKCCT)                ADDRESS OF CCT                  76000019
LOPEN    DC    V(IECTLOPN)              BTAM OPEN LINE ERROR RETRY      76200019
AVT      DC    A(IHKAVT)                                                76400019
LAPTRINS TR    0(0,PNTBUFRG),0(LAWRKRG1) TRANSLATE INSTRUCTION          76600019
         EJECT                                                          76800019
         IECTDECB                                                       77000019
         IHKCDSCT   CLB=YES,TUB=YES,CCT=YES,AVT=YES                     77200019
         END                                                            77400019
