LAY      TITLE 'IHKLAY - PROGRAMMED TIMEOUT MODULE'                     00200019
*********************************************************************** 00400019
*                                                                     * 00600019
*STATUS                                                               * 00800019
*                                                                     * 01000019
*   CHANGE LEVEL 0                                                    * 01200019
*                                                                     * 01400019
*FUNCTION                                                             * 01600019
*                                                                     * 01800019
*   THE PURPOSE OF THIS MODULE IS TO PREVENT A PERMANENT WAIT FROM    * 02000019
*   OCCURRING ON READ RESPONSE TO POLLING (INHIBIT) FOR 1050X         * 02200019
*   TERMINALS ON LEASED LINES.  THE MODULE IS LOADED ONLY IF ONE OR   * 02400019
*   MORE SUCH TERMINALS IS FOUND AT START-UP.  THE INITIAL CALL IS    * 02600019
*   PLACED FROM IHKCIP TO PASS THE ADDRESS OF THE AVT AND ALLOW THE   * 02800019
*   MODULE TO INCLUDE ITS STCB IN THE PRIORITY ONE CIRCLE AND ADD     * 03000019
*   ITS ECB TO THE END OF THE ECBLIST.  THEREAFTER, THE MODULE IS     * 03200019
*   CALLED BY EITHER IHKLAD OR IHKLAP.  WHICH OF THE TWO IS THE       * 03400019
*   CALLER IS DETERMINED BY CHECKING TO SEE IF THE LINE DECB IS       * 03600019
*   POSTED; IF SO, IHKLAD IS THE CALLER.                              * 03800019
*                                                                     * 04000019
*   ON A CALL FROM IHKLAP, THE COMPLETION TIME IS COMPUTED AND STORED * 04200019
*   IN THE CLB AND THE CLB IS THEN ENQUEUED.  IF THIS IS THE FIRST    * 04400019
*   CLB ON THE QUEUE, AN STIMER MACRO IS ISSUED, SPECIFYING THE       * 04600019
*   LAYTIMER ROUTINE AS THE EXIT.  CONTROL IS THEN RETURNED TO THE    * 04800019
*   CALLER AFTER SETTING THE ENQUEUED FLAG.                           * 05000019
*                                                                     * 05200019
*   THE MODULE IS CALLED FROM IHKLAD WHEN THERE IS AN I/O COMPLETION  * 05400019
*   ON A LINE WITH THE ENQUEUED FLAG SET.  IT FIRST LINKS TO THE      * 05600019
*   DEQUEUE SUB-ROUTINE TO REMOVE THE CLB FROM THE QUEUE AND, IF      * 05800019
*   NECESSARY, ISSUE AN STIMER FORTHE FIRST CLB ON THE QUEUE.  THE    * 06000019
*   DEQUEUE SUB-ROUTINE ALSO SCANS THE QUEUE TO DETERMINE IF ANY      * 06200019
*   CLB'S ON THE QUEUE CAN BE REMOVED BECAUSE OF POSITIVE RESPONSE    * 06400019
*   TO POLLING ALREADY RECEIVED OR IF THE COMPLETION TIME IS WITHIN   * 06600019
*   A CERTAIN PRE-DEFINED LIMIT.  IHKLAY THEN CHECKS FOR A HALTIO.    * 06800019
*   IF NOT, IT RETURNS TO THE CALLER TO ALLOW NORMAL PROCESSING TO    * 07000019
*   CONTINUE.  IF THE HALTIO WAS ISSUED, IT THEN CHECKS TO SEE        * 07200019
*   IF MODIFY OR STOP IS IN PROGRESS, SINCE THEY ALSO ISSUE IOHALTS.  * 07400019
*   IF YES, IT RETURNS TO THE CALLER.  OTHERWISE, IT ASSUMES THE      * 07600019
*   IOHALT WAS ISSUED ELSEWHERE IN THE MODULE AND POSTS THE DECB      * 07800019
*   AS PERMANENT I/O ERROR AND SHOULD-NOT-OCCUR, AFTER WHICH IT       * 08000019
*   RETURNS TO THE CALLER.                                            * 08200019
*                                                                     * 08400019
*   THE LAYTIMER ROUTINE GETS CONTROL ASYNCHRONOUSLY FROM OS WHEN     * 08600019
*   THE OUTSTANDING TIME INTERVAL EXPIRES.  IT FIRST CHECKS FOR       * 08800019
*   LINE I/O COMPLETED OR STOP OR MODIFY IN PROGRESS, ANY OF WHICH    * 09000019
*   RESULT IN IMMEDIATE RETURN TO OS.  IF NONE OF THESE, IT THEN      * 09200019
*   CHECKS FOR A READ TI AND ZERO IN THE INPUT BUFFER, FOR WHICH      * 09400019
*   IT ISSUES THE HALTIO.  IF NOT A READ TI, IT FIRST CHECKS FOR      * 09600019
*   POSITIVE RESPONSE TO TEXT BEFORE CHECKING FOR ZERO IN THE INPUT   * 09800019
*   BUFFER.  IF IOHALT IS NOT ISSUED, THE ECB FOR THE LAYPOST         * 10000019
*   ROUTINE IS POSTED.  IN EITHER CASE, CONTROL IS THEN RETURNED      * 10200019
*   TO OS.                                                            * 10400019
*                                                                     * 10600019
*   WHEN THE LAYPOST ROUTINE GETS CONTROL FROM THE CRJE DISPATCHER,   * 10800019
*   IT IMMEDIATELY LINKS TO THE DEQUEUE SUB-ROUTINE DESCRIBED ABOVE.  * 11000019
*   IF THE OPERATION IS A READ TI, IT THEN CHECKS FOR NEGATIVE        * 11200019
*   RESPONSE TO POLLING.  IF NOT, IT RETURNS TO THE DISPATCHER.       * 11400019
*   IF SO, IT LINKS TO THE ENQUEUE SUB-ROUTINE AS DESCRIBED IN THE    * 11600019
*   SECOND PARAGRAPH AND THEN RETURNS TO THE DISPATCHER.  IF IT       * 11800019
*   WAS NOT A READ TI, THE ROUTINE FIRST CHECKS FOR A POSITIVE        * 12000019
*   RESPONSE TO TEXT.  IF NOT YET RECEIVED, IT LINKS TO THE ENQUEUE   * 12200019
*   SUB-ROUTINE AND THEN RETURNS TO THE DISPATCHER.  IF POSITIVE      * 12400019
*   RESPONSE TO POLLING HAS BEEN RECEIVED, IT IMMEDIATELY RETURNS     * 12600019
*   TO THE DISPATCHER.  OTHERWISE, IT LINKS TO THE ENQUEUE            * 12800019
*   SUB-ROUTINE AND THEN RETURNS TO THE CALLER.                       * 13000019
*                                                                     * 13200019
*ENTRY POINTS                                                         * 13400019
*                                                                     * 13600019
*   IHKLAY                                                            * 13800019
*                                                                     * 14000019
*INPUT                                                                * 14200019
*                                                                     * 14400019
*   CLB ADDRESS                                                       * 14600019
*                                                                     * 14800019
*OUTPUT                                                               * 15000019
*                                                                     * 15200019
*   NONE                                                              * 15400019
*                                                                     * 15600019
*EXTERNAL REFERENCES                                                  * 15800019
*                                                                     * 16000019
*   NONE                                                              * 16200019
*                                                                     * 16400019
*EXITS-NORMAL                                                         * 16600019
*                                                                     * 16800019
*   RETURN TO CALLER                                                  * 17000019
*                                                                     * 17200019
*EXITS-ERROR                                                          * 17400019
*                                                                     * 17600019
*   NONE                                                              * 17800019
*                                                                     * 18000019
*TABLES/WORK AREAS                                                    * 18200019
*                                                                     * 18400019
*   CLB                                                               * 18600019
*   DECB                                                              * 18800019
*   UCB                                                               * 19000019
*   IOB                                                               * 19200019
*   DEB                                                               * 19400019
*                                                                     * 19600019
*ATTRIBUTES                                                           * 19800019
*                                                                     * 20000019
*   NON-RESIDENT,REENTRANT                                            * 20200019
*                                                                     * 20400019
*NOTES                                                                * 20600019
*                                                                     * 20800019
*   NONE                                                              * 21000019
*                                                                     * 21200019
*********************************************************************** 21400019
         EJECT                                                          21600019
IHKLAY   CSECT                                                          21800019
         SPACE 2                                                        22000019
PARM     EQU   1              PARAMETER PASSING                         22200019
CLB      EQU   2              CLB BASE ADDRESS                          22400019
DECB     EQU   3              DECB BASE ADDRESS                         22600019
AREA     EQU   4              INPUT AREA ADDRESS                        22800019
WORK5    EQU   5                                                        23000019
WORK6    EQU   6                                                        23200019
WORK7    EQU   7                                                        23400019
WORK8    EQU   8                                                        23600019
WORK9    EQU   9                                                        23800019
INTLNK   EQU   10             INTERNAL LINKAGE REGISTER                 24000019
AVT      EQU   11             AVT BASE ADDRESS                          24200019
BASE     EQU   12             IHKLAY BASE ADDRESS                       24400019
SAVE     EQU   13                                                       24600019
RTRN     EQU   14                                                       24800019
LINK     EQU   15                                                       25000019
         SPACE 2                                                        25200019
ZERO     EQU   0              BINARY ZERO                               25400019
ONE      EQU   1              BINARY ONE                                25600019
CIRCLEN  EQU   X'40'          NEGATIVE RESPONSE IN 1050 CODE            25800019
CIRCLEY  EQU   X'76'          POSITIVE RESPONSE IN 1050 CODE (TEXT)     26000019
CIRCLED  EQU   X'16'          POSITIVE RESPONSE IN 1050 CODE (POLLING)  26200019
POSTED   EQU   X'40'          POSTED ECB COMPLETION                     26400019
HALTIO   EQU   X'21'          HALTIO SVC CODE                           26600019
IOBUCBX  EQU   X'20'          OFFSET TO UCB POINTER IN IOB              26800019
DEBUCBAD EQU   X'20'          OFFSET TO UCB POINTER IN DEB              27000019
ENTERED  EQU   X'80'          FIRST PASS HAS BEEN EXECUTED              27200019
EIGHT    EQU   8                                                        27400019
LAST     EQU   X'80'          INDICATION OF LAST ENTRY IN A LIST        27600019
LASTOFF  EQU   X'7F'          TO RESET INDICATION OF LAST ENTRY IN LIST 27800019
FOUR     EQU   4                                                        28000019
TWELVE   EQU   12                                                       28200019
IOERROR  EQU   X'41'          POST CODE FOR I/O ERROR                   28400019
TIMEOUT  EQU   X'01'          LINE TIMEOUT INDICATION                   28600019
ERROR    EQU   X'40'          SHOULD-NOT-OCCUR ERROR INDICATION         28800019
D124     EQU   124                                                      29000019
READTI   EQU   X'01'          READ INITIAL IN PROGRESS                  29200019
HALTED   EQU   X'48'          I/O WAS HALTED BY HIO                     29400019
IOBRESET EQU   X'01'          IOB RESET FLAG FOR IOS                    29600019
         EJECT                                                          29800019
         SAVE  (14,12),T,IHKLAY11/20/69 SAVE CALLER'S REGISTERS         30000019
         LR    BASE,LINK                                                30200019
         USING IHKLAY,BASE         ESTABLISH CSECT ADDRESSIBILITY       30400019
         TM    SWITCH,ENTERED      FIRST TIME ENTERED?                  30600019
         BO    CHKSIT              IF NOT, GO CHECK ENTRY CONDITIONS    30800019
         OI    SWITCH,ENTERED      SET SWITCH FOR PERMANENT BYPASS      31000019
         L     AVT,ZERO(ZERO,PARM) LOAD AVT ADDR FROM PARAMETER LIST    31200019
         ST    AVT,AVTAD           SAVE FOR FUTURE USE                  31400019
         USING AVTDSECT,AVT        ESTABLISH AVT DSECT ADDRESSIBILITY   31600019
         L     WORK5,IHKYYSCB      GET POINTER TO FIRST LINE STCB       31800019
         LR    WORK6,WORK5                                              32000019
COMP1    C     WORK5,ZERO(ZERO,WORK6) END OF STCB CHAIN?                32200019
         BE    FOUND1              IF YES, GO MODIFY END OF CHAIN       32400019
         L     WORK6,ZERO(ZERO,WORK6) ELSE GET NEXT STCB                32600019
         B     COMP1               CONTINUE SEARCH                      32800019
FOUND1   ST    WORK5,STCB          ADD LAYPOST STCB TO END OF CHAIN     33000019
         LA    WORK5,STCB                                               33200019
         ST    WORK5,ZERO(ZERO,WORK6)                                   33400019
         L     WORK5,IHKYYECD      GET POINTER TO DISPATCHER ECB LIST   33600019
         LA    WORK5,EIGHT(ZERO,WORK5) POINT TO FIRST LINE ECB          33800019
COMP2    TM    ZERO(WORK5),LAST    REACHED CURRENT END OF LIST?         34000019
         BO    FOUND2              IF YES, GO MODIFY END OF LIST        34200019
         LA    WORK5,FOUR(ZERO,WORK5) ELSE POINT TO NEXT ECB            34400019
         B     COMP2               CONTINUE SEARCH                      34600019
FOUND2   NI    ZERO(WORK5),LASTOFF                                      34800019
         LA    WORK5,FOUR(ZERO,WORK5) POINT TO NEW END OF LIST          35000019
         LA    WORK6,STCB+TWELVE   GET START-UP ECB                     35200019
         ST    WORK6,ZERO(ZERO,WORK5) ININITIALIZE ECB LIST             35400019
         OI    ZERO(WORK5),LAST    FLAG END OF ECB LIST                 35600019
         ST    WORK5,STCB+FOUR     PRIME LAYPOST STCB                   35800019
RETURN   LM    RTRN,BASE,TWELVE(SAVE) RESTORE CALLER'S REGISTERS        36000019
         BR    RTRN                AND RETURN                           36200019
         EJECT                                                          36400019
CHKSIT   L     CLB,ZERO(ZERO,PARM) LOAD CLB ADDR FROM PARAMETER LIST    36600019
         USING CLBDSECT,CLB        ESTABLISH CLB DSECT ADDRESSIBILITY   36800019
         TM    CLBREQST,CLBRDTIN        IS THIS A 'CREAD I' ?           36860019
         BZ    RETURN                   IF NOT, DON'T BOTHER            36920019
         L     DECB,ZERO(ZERO,CLB) GET LINE DECB ADDRESS                37000019
         USING IECTDECB,DECB       ESTABLISH DECB DSECT ADDRESSIBILITY  37200019
         TM    DECSDECB,POSTED     LINE ECB POSTED?                     37400019
         BNO   CHKRET              IF NOT, ENTERED FOR ENQUEUEING       37600019
         BAL   INTLNK,DEQUEUE      ELSE GO DEQUEUE AND ISSUE STIMER     37800019
         B     RETURN              AND RETURN                           38700019
CHKRET   CLI   CLBRTNCD,ZERO       GOOD START I/O IN IHKLAP?            39600019
         BNE   RETURN              IF NOT, RETURN AND LET IHKLAD HANDLE 39800019
         LA    INTLNK,RETURN       ELSE SET UP TO RETURN AFTER ENQUEUE  40000019
ENQUEUE  TIME BIN                  GET CURRENT TIME                     40200019
         A     ZERO,INTERVAL       ADD TIMEOUT INTERVAL TO GET END TIME 40400019
         ST    ZERO,CLBSTOP        SAVE ENDTIME IN CLB                  40600019
         L     AREA,DECAREA        GET INPUT AREA ADDRESS               40800019
         MVI   ZERO(AREA),ZERO          IF SO, CLEAR FIRST BYTE         41400019
         L     PARM,QPTR           GET POINTER TO FIRST CLB ON QUEUE    41600019
         LTR   PARM,PARM           QUEUE EMPTY?                         41800019
         BZ    ENQFIRST            IF YES, GO ENQUEUE THIS CLB FIRST    42000019
COMP3    CLC   D124(FOUR,PARM),NULL ELSE IS THIS END OF QUEUE?          42200019
         BE    ENQLAST             IF YES, ADD CURRENT CLB ON END OF Q  42400019
         L     PARM,D124(ZERO,PARM) ELSE POINT TO NEXT CLB ON QUEUE     42600019
         B     COMP3               AND CONTINUE SEARCH                  42800019
         EJECT                                                          43000019
ENQLAST  ST    CLB,D124(ZERO,PARM) ADD CURRENT CLB TO END OF QUEUE      43200019
         OI    CLBSTATS,CLBTQUEN   INDICATE CLB IS QUEUED               43400019
         BR    INTLNK              RETURN TO CALLER                     43600019
ENQFIRST ST    CLB,QPTR            ENQUEUE THIS CLB FIRST               43800019
         OI    CLBSTATS,CLBTQUEN   INDICATE CLB IS ENQUEUED             44000019
         MVC   TIME(FOUR),INTERVAL PRIME INTERVAL FOR STIMER            44200019
         STIMER REAL,LAYTIMER,BINTVL=TIME                               44400019
         BR    INTLNK              RETURN TO CALLER                     44600019
DEQUEUE  L     WORK5,QPTR          GET POINTER TO FIRST CLB ON QUEUE    44800019
         LR    WORK9,CLB           SAVE CLB ADDRESS                     45000019
         LR    WORK8,DECB          SAVE DECB ADDRESS                    45200019
         CR    WORK5,CLB           THIS CLB FIRST ON QUEUE?             45400019
         BE    FIRST               IF YES, GO TO TREAT AS FIRST         45600019
         BAL   LINK,DEQMID         ELSE GO DEQUEUE FROM MIDDLE          45800019
         BR    INTLNK              AND RETURN TO CALLER                 46000019
FIRST    TTIMER CANCEL             CANCEL ANY OUTSTANDING STIMER        46200019
         MVI   ECB,ZERO            PREVENT LAYPOST FROM GAINING CONTROL 46400019
         L     WORK7,CLBQUEUE      SAVE POINTER TO NEXT CLB ON QUEUE    46600019
         BAL   LINK,DEQFIRST       GO TO DEQUEUE FIRST                  46800019
GETNEXT  LR    CLB,WORK7           GET POINTER TO NEXT CLB ON QUEUE     47000019
         LTR   CLB,CLB             QUEUE NOW PROCESSED?                 47200019
         BZ    TESTIME             IF YES, GO CHECK FOR NEW STIMER      47400019
         L     DECB,ZERO(ZERO,CLB) ELSE GET LINE DECB ADDRESS           47600019
         TM    DECSDECB,POSTED     LINE ECB POSTED?                     47800019
         BNO   ISREAD                   IF NOT, CONTINUE CHECKING       48000019
LOAD1    L     WORK7,CLBQUEUE      SAVE POINTER TO NEXT CLB ON QUEUE    48200019
         BAL   LINK,DEQMID         GO TO DEQUEUE THIS CLB               48400019
         B     GETNEXT             AND CONTINUE TO SEARCH THE QUEUE     48600019
         EJECT                                                          50000019
ISREAD   L     WORK5,DECAREA       GET ADDRESS OF INPUT BUFFER          50200019
         CLI   ZERO(WORK5),CIRCLED POSITIVE RESPONSE TO POLL?           50400019
         BE    LOAD1               IF YES, GO DEQUEUE AND CONTINUE      50600019
         L     WORK7,CLBQUEUE      ELSE SKIP DEQUEUEING                 50800019
         B     GETNEXT             AND CONTINUE TO PROCESS QUEUE        51000019
TESTIME  L     CLB,QPTR            GET FIRST CLB ON CLEANED UP QUEUE    51200019
         LTR   CLB,CLB             QUEUE NOW EMPTY?                     51400019
         BZ    ENDUP               PREPARE TO RETURN IF YES             51600019
         TIME  BIN                 ELSE GET CURRENT TIME                51800019
         L     WORK5,CLBSTOP       AND END TIME FROM THIS CLB           52000019
         CR    WORK5,ZERO          END TIME PASSED?                     52200019
         BNH   RENQ                IF YES, GO TO RE-ENQUEUE             52400019
         SR    WORK5,ZERO          ELSE COMPUTE REMAINING INTERVAL      52600019
         CH    WORK5,TOLER         OUTSTANDING INTERVAL WITHIN TOLERANC 52800019
         BNH   RENQ                IF YES, GO TO RE-ENQUEUE             53000019
         ST    WORK5,TIME          ELSE PRIME TIME FIELD FOR STIMER     53200019
         STIMER REAL,LAYTIMER,BINTVL=TIME                               53400019
ENDUP    LR    CLB,WORK9           RESTORE ORIGINAL CLB ADDRESS         53600019
         LR    DECB,WORK8          RESTORE ORIGINAL DECB ADDRESS        53800019
         BR    INTLNK              RETURN TO CALLER                     54000019
RENQ     L     WORK7,CLBQUEUE      SAVE POINTER TO NEXT CLB ON QUEUE    54200019
         LR    DECB,CLB           SAVE CLB ADDRESS FOR AFTER DEQUEUE    54300019
         BAL   LINK,DEQMID         DEQUEUE FROM TOP OF QUEUE            54400019
         LR    CLB,DECB            RESTORE CORRECT CLB ADDRESS          54500019
         L     DECB,ZERO(ZERO,CLB) GET LINE DECB                        54800019
CHKAREA  L     WORK5,DECAREA       GET INPUT BUFFER                     55000019
         CLI   ZERO(WORK5),ZERO    IS FIRST BYTE OF INPUT AREA ZERO     55200019
         BE    HALT                IF YES, GO ISSUE IOHALT              55400019
         MVI   ZERO(WORK5),ZERO    ELSE SET FIRST BYTE TO ZERO          55600019
RENQ1    LR    WORK6,INTLNK                                             55800019
         BAL   INTLNK,ENQUEUE      GO TO RE-ENQUEUE THIS CLB            56200019
         LR    INTLNK,WORK6                                             56400019
         C     CLB,QPTR            WAS THIS CLB QUEUED FIRST (STIMER)   56600019
         BE    ENDUP               IF YES, PREPARE TO END               56800019
         B     TESTIME             AND RESTART STIMER SEARCH CYCLE      57000019
         EJECT                                                          57200019
HALT     LR    WORK5,INTLNK                                             58400019
         BAL   INTLNK,IOHALT       GO TO ISSUE IOHALT                   58600019
         LR    INTLNK,WORK5                                             58800019
         B     TESTIME             AND CONTINUE SEARCH FOR STIMER       59000019
DEQFIRST MVC   QPTR(FOUR),CLBQUEUE UPDATE QUEUE POINTER                 59200019
CLEAR    NI    CLBSTATS,CLBTQUEF   RESET CLB-ENQUEUD FLAG               59400019
         SR    PARM,PARM                                                59600019
         ST    PARM,CLBQUEUE       INITIALIZE CLB QUEUE POINTER         59800019
         ST    PARM,CLBSTOP        INITIALIZE CLB END TIME              60000019
         BR    LINK                RETURN TO CALLER                     60200019
DEQMID   L     PARM,QPTR           GET POINTER TO FIRST CLB ON QUEUE    60400019
         LTR   PARM,PARM           CLB ALREADY DEQUEUED?                60600019
         BNZ   COMP4               IF NOT CONTINUE SEARCH               60800019
         BR    LINK                ELSE RETURN WITHOUT DEQUEUEING       61000019
COMP4    CR    PARM,CLB            IS IT FIRST?                         61200019
         BE    DEQFIRST            IF YES, GO TO DEQUEUE IT FROM TOP    61400019
         C     CLB,D124(PARM)      CURRENT CLB CHAINED HERE?            61600019
         BE    REMOVE              IF YES, GO REMOVE IT                 61800019
         L     PARM,D124(PARM)     ELSE GET ADDRESS OF NEXT ON QUEUE    62000019
         B     DEQMID+FOUR         AND CONTINUE SEARCH                  62200019
REMOVE   MVC   D124(FOUR,PARM),CLBQUEUE DEQUEUE FROM MIDDLE OF CHAIN    62400019
         B     CLEAR                                                    62600019
         TITLE 'PROGRAMMED TIMEOUT POST ROUTINE'                        62800019
DISPATCH MVI   ECB,ZERO                 CLEAR THE ECB                   63000019
         LA    PARM,ECB                 PASS ECB ADDRESS TO DISPATCHER  63200019
         L     LINK,IHKYYDSP            GET DISPATCHER ADDRESS          63400019
         BALR  RTRN,LINK                GO TO DISPATCHER                63600019
LAYPOST  L     CLB,QPTR                 TIMER HAS EXPIRED FOR FIRST CLB 63800019
         L     DECB,CLBLDECB            GET LINE DECB ADDRESS           64000019
         L     AREA,DECAREA             GET INPUT AREA ADDRESS          64200019
         BAL   INTLNK,DEQUEUE           LINK TO DEQUEUE ROUTINE         64400019
         CLI   ZERO(AREA),CIRCLEN       NEGATIVE RESPONSE RECEIVED ?    65000019
         BNE   DISPATCH                 IF NOT, GO BACK TO DISPATCHER   65200019
QIT      BAL   INTLNK,ENQUEUE           QUEUE IT UP AGAIN               65400019
         B     DISPATCH                                                 65600019
         TITLE 'PROGRAMMED TIMEOUT STIMER EXIT'                         67000019
LAYTIMER STM   14,12,12(13)                                             67200019
         USING LAYTIMER,15                                              67400019
         L     BASE,LAYBASE             GET MODULE BASE ADDRESS         67600019
         DROP  15                                                       67800019
         L     CLB,QPTR                 GET ADDR OF FIRST CLB ON QUEUE  68000019
         L     DECB,CLBLDECB            GET LINE DECB ADDRESS           68200019
         TM    DECSDECB,POSTED          IS THE ECB ALREADY POSTED ?     68400019
         BO    BACKTOOS                 IF SO, GO RIGHT BACK            68600019
         TM    CLBREQST,CLBSTOPN        IS 'STOP' OR 'MODIFY' GOING ON  68800019
         BO    BACKTOOS                 IF SO, GO RIGHT BACK            69000019
         L     AREA,DECAREA             GET INPUT AREA ADDRESS          69200019
WASREAD  CLI   ZERO(AREA),ZERO          FIRST BYTE EMPTY ?              69400019
         BNE   POSTLAY                  IF NOT, LET POST HANDLE IT      69600019
         BAL   INTLNK,IOHALT            LINK FOR IOHALT                 69800019
         B     BACKTOOS                                                 70000019
POSTLAY  POST  ECB                      OTHERWISE, POST                 70200019
BACKTOOS LM    14,12,12(13)                                             70400019
         BR    14                       RETURN TO OS                    70600019
IOHALT   XR    RTRN,RTRN                CLEAR THE REGISTERS             71600019
         XR    LINK,LINK                                                71800019
         IC    RTRN,DECRLN              GET RELATIVE LINE NUMBER        72000019
         USING IHADCB,PARM                                              72200019
         L     PARM,DECDCBAD            GET DCB ADDRESS                 72400019
         IC    LINK,DCBEIOBX            GET IOB SIZE                    72600019
         MR    RTRN,RTRN                GET OFFSET TO IOB               72800019
         A     LINK,DCBIOBAD            ADD START OF IOB'S              73000019
         OI    ONE(LINK),IOBRESET       TELL IOS IT'S TRUE              73200019
         IC    RTRN,IOBUCBX(LINK)       OFFSET TO UCB ADDRESS           73400019
         SLL   RTRN,2                   MULTIPLY BY 4                   73600019
         L     PARM,DCBDEBAD            GET DEB ADDRESS                 73800019
         DROP  PARM                                                     74000019
         L     PARM,DEBUCBAD(PARM,RTRN) ADDRESS OF UCB                  74200019
         SVC   HALTIO                   STOP THE CHANNEL COMMAND        74400019
         OI    DECERRST,ERROR      SET SHOULD-NOT-OCCUR ERROR FLAGS     74500019
         BR    INTLNK                                                   74600019
         TITLE 'D E F I N E D  V A L U E S  A N D  D S E C T S'         74800019
STCB     DC    A(0)                                                     75000019
         DC    A(0)                                                     75200019
         DC    A(SAVEAREA)                                              75400019
ECB      DC    A(0)                                                     75600019
SAVEAREA DC    3F'0'                                                    75800019
         DC    A(LAYPOST)                                               76000019
         DC    2F'0'                                                    76200019
         DC    A(ECB)                                                   76400019
         DC    9F'0'                                                    76600019
AVTAD    DC    A(0)                                                     76800019
LAYBASE  DC    A(IHKLAY)                                                77000019
QPTR     DC    F'0'                                                     77200019
TIME     DC    F'0'                                                     77400019
INTERVAL DC    F'9000'                                                  77600019
NULL     DC    F'0'                                                     77800019
TOLER    DC    H'500'                                                   78000019
SWITCH   DC    X'0'                                                     78200019
         EJECT                                                          78400019
         IHKCDSCT   CLB=YES,AVT=YES                                     78600019
         DCBD  DSORG=CX                                                 78800019
         IECTDECB                                                       79000019
         END                                                            79200019
