LDC      TITLE 'IHKLDC - LOADER-CONTROLLER'                             00200019
IHKLDC   CSECT                                                          00400019
*A004000,040000,656000,680000                                    A36810 00401020
*C006000,292000,856000                                           A36810 00402020
*********************************************************************** 00403020
*STATUS                                                               * 00404020
*                                                                     * 00405020
*   CHANGE LEVEL 1                                                    * 00406020
*                                                                     * 00407020
*FUNCTION/OPERATION                                                   * 00408020
*   THE PURPOSE OF THE LOADER/CONTROLLER IS TO LOAD AND DELETE NON-   * 00409020
*   RESIDENT MODULES AND TO SERIALIZE REQUESTS FOR SERIALLY REUSABLE  * 00410020
*   MODULES.                                                          * 00411020
*   WHEN IHKLDC IS ENTERED, THE ECB FOR THE INITIALIZATION MODULE     * 00412020
*   (IHKCIP) IS POSTED AND A STAE MACRO IS ISSUED TO INTERCEPT ABENDS * 00413020
*   WITHIN THE TASK. IHKLDC THEN WAITS ON AN ECB LIST, WHICH CONTAINS * 00414020
*   AN ECB FOR EACH CRJE SUB-TASK.                                    * 00415020
*   REQUESTS FOR DELETES OR LOADS ARE FILLED BY SCANNING THE ECBS     * 00416020
*   THREE TIMES IN THE FOLLOWING MANNER:                              * 00417020
*   1. DELETE REQUESTS ARE SATISFIED IMMEDIATELY BY DECREASING THE    * 00418020
*   BLOCK REQUEST COUNT BY ONE. THEN THE RETURN ECB FOR THIS REQUEST  * 00419020
*   IS POSTED.                                                        * 00420020
*   2. THE SECOND SCAN IS FOR LOAD REQUESTS ASKING FOR MODULES THAT   * 00421020
*   ARE ALREADY IN THE TRANSIENT AREA. IF THE REQUESTED MODULE IS     * 00422020
*   REENTERABLE, THE ENTRY POINT ADDRESS IS INSERTED IN THE RETURN ECB* 00423020
*   AND THIS ECB IS POSTED. IF THE MODULE IS SERIALLY REUSABLE AND IS * 00424020
*   ALREADY OCCUPIED BY ANOTHER USER, THE EVENT COUNT OF THE WAIT     * 00425020
*   MACRO IS INCREMENTED AND THE REQUEST ITSELF IS FLAGGED AS WAITING * 00426020
*   FOR A MODULE. THEN THE SCAN IS RESUMED WITH THE NEXT ECB.         * 00427020
*   3. THE THIRD SCAN IS FOR LOAD REQUESTS FOR MODULES THAT ARE NOT   * 00428020
*   ALREADY IN THE TRANSIENT AREA. BEFORE THE MODULE CAN BE LOADED, A * 00429020
*   MODULE IN THE TRANSIENT AREA MUST BE FOUND FOR WHICH THERE ARE NO * 00430020
*   REQUESTS FOR ANY OF ITS ENTRY POINTS. THIS MODULE IS DELETED      * 00431020
*   LEAVING AN EMPTY 2K BLOCK IN THE TRANSIENT AREA. IF NO MODULE IS  * 00432020
*   WITH A REQUEST COUNT OF ZERO, THE NEW LOAD REQUEST CANNOT BE      * 00433020
*   SATISFIED. THE EVENT COUNT OF THE WAIT MACRO IS INCREASED AND THE * 00434020
*   REQUEST IS MARKED AS WAITING FOR A MODULE. ALL REQUESTS STILL     * 00435020
*   PENDING AT THIS TIME ARE TREATED IN THIS WAY. THEN IHKLOC WAITS   * 00436020
*   FOR NEW REQUESTS. THE NEXT TIME IHKLDC GAINS CONTROL, ALL THREE   * 00437020
*   SCANS ARE DONE STARTING WITH THE FIRST REQUEST THAT COULD NOT BE  * 00438020
*   SATISFIED.                                                        * 00439020
*   WHEN A MODULE IS FOUND WITH A ZERO REQUEST COUNT IN THE BLOCK     * 00440020
*   TABLE AND THE LOAD REQUEST IS NOT FOR A 'TROUBLE MODULE', THE     * 00441020
*   MODULE IN THE BLOCK TABLE IS DELETED AND THE MODULE THAT WAS      * 00442020
*   REQUESTED IS LOADED. (A 'TROUBLE MODULE' IS A MODULE THAT REQUESTS* 00443020
*   THE LOADING OF ANOTHER MODULE BEFORE IT IS DELETED ITSELF OR A    * 00444020
*   MODULE THAT QUEUES ITSELF FOR LIBRARY I/O OR USES THE IHKUTM      * 00445020
*   MODULE TO BE QUEUED FOR LIBRARY I/O. IF THE LOAD REQUEST IS FOR   * 00446020
*   A 'TROUBLE MODULE', THE TROUBLE MODULE COUNT IS CHECKED (FIRST    * 00447020
*   BYTE IN THE MODULE TABLE). INITIALLY THE TROUBLE MODULE COUNT     * 00448020
*   CONTAINS THE NUMBER OF 2K BLOCKS ASSIGNED TO THE TRANSIENT AREA   * 00449020
*   MINUS ONE (THIS COUNT PREVENTS ANY INTERLOCKS IN THE SYSTEM WHICH * 00450020
*   COULD BE CAUSED BY HAVING THE TRANSIENT AREA FILLED WITH TROUBLE  * 00451020
*   MODULES). EACH TIME A 'TROUBLE MODULE'IS LOADED THE COUNT IS      * 00452020
*   DECREMENTED. WHEN A 'TROUBLE MODULE' IS DELETED THE COUNT IS      * 00453020
*   INCREMENTED. IF THE COUNT IS ZERO, THE LOAD REQUEST FOR A 'TROUBLE* 00454020
*   MODULE IS MARKED AS WAITING.                                      * 00455020
*   AT CLOSEDOWN, THE CLOSEDOWN ROUTINE PASSES TO THE LOADER/         * 00456020
*   CONTROLLER BINARY ZEROS IN BYTES 4 AND 5 OF THE PARAMETER AREA.   * 00457020
*   THE LOADER/CONTROLLER THEN DELETES ALL MODULES IN THE TRANSIENT   * 00458020
*   AREA AND RETURNS TO THE OPERATING SYSTEM.                         * 00459020
*   THE LOADER/CONTROLLER TASK STAE EXIT ROUTINE (IHKLDC01)      A36810 00460020
*   GAINS CONTROL IF THE TASK ABENDS.  IHKLOC01 POSTS THE MAIN   A36810 00461020
*   TASK TO PREVENT FURTHER ACCESSES TO THE TASK.  EACH CRJE SUB A36810 00462020
*   TASK THAT IS WAITING ON THE LOADER/CONTROLLER TASK IS POSTED A36810 00463020
*   THE CLOSEDOWN AND ABNORMAL CLOSEDOWN FLAGS ARE SET IN THE CCTA36810 00464020
*   AND THE MAIN TASK IS POSTED TO INITIATE CLOSEDOWN OF CRJE.   A36810 00465020
*   CONTROL IS THEN RETURNED TO THE OPERATING SYSTEM TO PROCESS  A36810 00466020
*   THE ABEND.                                                   A36810 00467020
*ENTRY POINTS-                                                        * 00468020
*        IHKLDC IS THE MAIN ENTRY POINT.                              * 00469020
*        IHKLDC01 IS ENTERED FROM ABEND TO INFORM THE MAIN TASK  A36810 00470020
*              OF THE ABEND CONDITION.                           A36810 00471020
*INPUT-                                                               * 00472020
*   WHEN IHKLDC IS ATTACHED BY THE INITIALIZATION MODULE (IHKCIP),    * 00473020
*   REGISTER ONE POINTS TO A TWO WORD PARAMETER LIST CONTAINING THE   * 00474020
*   ADDRESS OF THE ECB FOR THE INITIALIZATION MODULE AND THE ADDRESS  * 00475020
*   OF THE AVT.                                                       * 00476020
*   THE ECBS USED TO POST REQUESTS TO IHKLDC MUST HAVE AS A POST CODE * 00477020
*   THE ADDRESS OF A SEVEN BYTE PARAMETER AREA. BYTES 0-3 OF THE AREA * 00478020
*   IS USED AS A RETURN ECB TO POST THE RESULTS OF THE REQUEST, BYTE  * 00479020
*   4 IS THE CODE OF THE ROUTINE TO BE DELETED OR ZERO IF NO DELETE   * 00480020
*   IS REQUESTED. BYTE 5 IS CODE OF THE ROUTINE TO BE LOADED OR ZERO  * 00481020
*   IF NO LOAD IS REQUESTED. BYTE 6 MUST BE ZERO AND IS USED FOR      * 00482020
*   MARKING REQUESTS AS WAITING.                                      * 00483020
*OUTPUT-                                                              * 00484020
*   REQUESTED MODULE IS DELETED OR LOADED.                            * 00485020
*EXTERNAL ROUTINES-                                                   * 00486020
*   N/A                                                               * 00487020
*EXITS-NORMAL                                                         * 00488020
*   RETURN TO OPERATING SYSTEM.                                       * 00489020
*EXITS-ERROR-                                                         * 00490020
*   N/A                                                               * 00491020
*TABLES/WORK AREAS-                                                   * 00492020
*   AVT                                                               * 00493020
*   CCT                                                               * 00494020
*   MODULE TABLE (IHKMOD) - CONTAINS ONE ENTRY FOR EACH NON-RESIDENT  * 00495020
*                           MODULE.                                   * 00496020
*        EACH ENTRY IN THE TABLE CONSISTS OF THE FOLLOWING 12 BYTES:  * 00497020
*        BYTE 0                                                       * 00498020
*              BIT 0 - SET IF LAST ENTRY IN TABLE,                    * 00499020
*                      MODULES ARE MARKED REENTRANT BY THE O. S.      * 00500020
*                      LINKAGE EDITOR SO THAT SUBPOOL 252 WILL BE     * 00501020
*                      USED FOR THE TRANSIENT AREA IN MVT. NOT ALL    * 00502020
*                      TRANSIENT MODULES ARE USED BY CRJE AS          * 00503020
*                      REENTRANT),                                    * 00504020
*              BIT 1 - SET IF MODULE IS NOT REENTRANT ( ALL TRANSIENT)* 00505020
*              BIT 2 - SET IF MODULE IS A 'TROUBLE MODULE',           * 00506020
*              BIT 3 - NOT USED,                                      * 00507020
*              BIT 4 - SET IF MODULE IS IN THE TRANSIENT AREA,        * 00508020
*              BIT 5 - SET IF MODULE IS LOADED (LOAD MACRO ISSUED FOR * 00509020
*                      IT),                                           * 00510020
*              BIT 6 - SET IF MODULE IS LOCKED,                       * 00511020
*              BIT 7 - NOT USED.                                      * 00512020
*        BYTE 1    - OFFSET IN BLOCK TABLE OF 2K BLOCK ALLOCATED.     * 00513020
*        BYTE 2    - NUMBER OF MODULES IN THIS LOAD MODULE.           * 00514020
*        BYTE 3    - NUMBER OF ENTRY IN MODULE TABLE FOR NEXT MODULE  * 00515020
*                    IN THIS LOAD MODULE.                             * 00516020
*        BYTES 4-8 - FIVE SIGNIFICANT CHARACTERS OF MODULE NAME.      * 00517020
*        BYTES 9-11- ENTRY POINT ADDRESS OF MODULE.                   * 00518020
*        THE FIRST ENTRY IN THE MODULE TABLE IS A DUMMY. IT CONTAINS  * 00519020
*        THE TROUBLE MODULE COUNT IN THE FIRST WORD.                  * 00520020
*   BLOCK TABLE (IHKMAP) - ONE ENTRY FOR EACH 2K BLOCK IN TRANSIENT   * 00521020
*                          AREA.                                      * 00522020
*        BYTE 0 - BLOCK REQUEST COUNT (INCREMENTED FOR LOAD REQUESTS, * 00523020
*                 DECREMENTED FOR DELETE REQUESTS)                    * 00524020
*        BYTE 1 - NUMBER OF ENTRY IN IHKMOD OF MODULE OCCUPYING THIS  * 00525020
*                 2K BLOCK (ZERO IF BLOCK IS EMPTY).                  * 00526020
*   TRANSLATE TABLE (IHKTRT)                                          * 00527020
*        ASSOCIATES THE COMMAND AND SUBCOMMAND CODES AS THEY ARE      * 00528020
*        LISTED IN THE MAJOR COMMAND LIST (IHKMCL) AND THE SUBCOMMAND * 00529020
*        LIST (IHKSCL) TO THE NUMBER OF THE ENTRY IN IHKMOD.          * 00530020
*ATTRIBUTES-                                                          * 00531020
*   NONRESIDENT BUT MADE RESIDENT VIA ATTACH AT START UP OF CRJE.     * 00532020
*   NEITHER REENTRANT NOR SERIALLY REUSABLE.                          * 00533020
*NOTES-                                                               * 00534020
*   THE OPERATION OF THIS MODULE DEPENDS ON AN INTERNAL REPRESENTATION* 00535020
*   OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO THE ONE USED * 00536020
*   AT ASSEMBLY TIME. THE CODING HAS BEEN ARRANGED SO THAT THE        * 00537020
*   REDEFINITION OF CHARACTER CONSTANTS BY REASSEMBLY, WILL RESULT    * 00538020
*   IN A CORRECT MODULE FOR THE NEW DEFINITIONS.                      * 00539020
*********************************************************************** 00540020
         SAVE  (14,12),,LDC71085                                 A36810 00640020
         BALR  R10,0                                                    00800019
         USING *,R10                                                    01000019
         ST    R13,SAVER13         SAVE R13.                            01200019
         L     R11,0(0,R1)         R11 HAS ADDR OF AVT.                 01400019
         USING AVTDSECT,R11                                             01600019
         L     R5,IHKYYMOD         HAS ADDR OF MODULE-TABLE.            01800019
         ST    R5,MODTABLE         STORE THIS ADDR.                     02000019
         L     R4,0(0,R5)          HAS TROUBLE-MODULE-COUNT.            02200019
         L     R5,IHKYYMAP         HAS ADDR OF BLOCK-TABLE.             02400019
         ST    R5,BLKTABLE         STORE THIS ADDR.                     02600019
         L     R5,IHKYYTRT         HAS ADDR OF TRANSLATE-TABLE.         02800019
         ST    R5,TRTTABLE         STORE THIS ADDR.                     03000019
         L     R9,IHKYYECL         R9 POINTS TO ECBLIST.                03200019
         DROP  R11                                                      03400019
         L     R2,INTECB(0,R1)     R2 HAS ADDR OF INITIALISATION-ECB.   03600019
         LR    R7,R9               INIT FIRST-TO-BE-SERVICED ECBLIST-   03800019
*                                    ENTRY.                             04000019
         ST    R11,SAVAVT          SAVE ADDRESS OF AVT           A36810 04060020
         STAE  IHKLDC01,PURGE=HALT                               A36810 04120020
         LA    R2,0(R2)            SET HIGH ORDER BYTE TO ZERO          04160021
         POST  (R2)                POST INITIALIZATION-ECB.             04200019
*                                  EXPANSION OF WAIT-MACRO FOLLOWS.     04400019
         LA    R13,1(0,0)          HAS STARTING EVENTCOUNT.             04600019
WAIT     LR    R0,R13              LOAD PARAMETER REG 0 FOR WAIT.       04800019
         LR    R1,R9               LOAD PARAMETER REG 1 FOR WAIT.       05000019
         LCR   R1,R1               INDICATE ECBLIST USED.               05200019
         SVC   1                   LINK TO WAIT-ROUTINE.                05400019
*                                                                       05600019
         NI    SCANMDUS,FIRSTUSF   CLEAR FLAG.                          05800019
SETSCDEL EQU   *                                                        06000019
         MVI   SCANMDUS,SCANDELT   SCAN FOR DELETE-REQUESTS.            06200019
         LR    R8,R7               FIRST TO BE SERVICED ECBLIST ENTRY.  06400019
ECBPOSTD L     R2,0(0,R8)          HAS ADDR OF ECB IN CLB.              06600019
         TM    0(R2),POSTED        IS ECB POSTED?                       06800019
         BZ    ISITLAST              NO, BRANCH.                        07000019
*                                    YES, GO ON.                        07200019
         L     R3,0(0,R2)          HAS ADDR OF PARAMETERS PASSED.       07400019
         TM    SCANMDUS,SCANMASK   WHAT SCAN-MODUS?                     07600019
         BZ    SCFORDE1              SCAN FOR DELETE.                   07800019
*                                                                       08000019
         CLI   RQDEL(R3),ZERO      REQUEST FOR DELETE?                  08200019
         BNZ   SETSCDEL              YES,BRANCH.                        08400019
*                                    NO, GO ON.                         08600019
         SR    R5,R5                                                    08800019
         IC    R5,RQLOD(0,R3)      HAS COMMAND-CODE.                    09000019
         STC   R5,CODE                                                  09200019
         NI    CODE,CLHIBIT        CLEAR HIGHORDER BIT.                 09400019
         L     R5,TRTTABLE         HAS ADDR OF TRANSLATE-TABLE.         09600019
         TR    CODE,0(R5)          ASSOCIATE MODULE-NUMBER TO COMMAND-  09800019
*                                    CODE.                              10000019
         SR    R5,R5                                                    10200019
         IC    R5,CODE             HAS MODULE-NUMBER.                   10400019
         BAL   R14,MODTBOFS        GO AND GET MODULE-TABLE-ENTRY.       10600019
*                                                                       10800019
         TM    SCANMDUS,SCANMASK   WHAT SCAN-MODUS?                     11000019
         BM    SCFORLI1              SCAN FOR LOAD FOR MODULE IN CORE.  11200019
         B     SCFORLN1              SCAN FOR LOAD FOR MODULE OUT CORE. 11400019
*                                                                       11600019
ISITLAST TM    0(R8),LAST          IS IT LAST ENTRY IN LIST?            11800019
         BZ    GETNENT               NO, BRANCH.                        12000019
*                                    YES, GO ON.                        12200019
         LR    R8,R9               GET FIRST ENTRY IN ECBLIST.          12400019
CIRCCOMP CR    R8,R7               IS LIST SCANNED COMPLETELY?          12600019
         BNE   ECBPOSTD              NO, BRANCH.                        12800019
*                                    YES, GO ON.                        13000019
         TM    SCANMDUS,SCANMASK   WHAT SCAN-MODUS?                     13200019
         BZ    SCFORDE2              SCAN FOR DELETE.                   13400019
         BM    SCFORLI2              SCAN FOR LOAD FOR MODULE IN CORE.  13600019
         B     WAIT                  SCAN FOR LOAD FOR MODULE OUT CORE. 13800019
*                                                                       14000019
GETNENT  LA    R8,ENTLNG(0,R8)     GET NEXT ENTRY IN ECBLIST.           14200019
         B     CIRCCOMP                                                 14400019
*                                                                       14600019
SCFORDE2 MVI   SCANMDUS,SCANLICR   SCAN FOR LOAD FOR MODULES IN CORE.   14800019
         B     ECBPOSTD                                                 15000019
*                                                                       15200019
SCFORLI2 MVI   SCANMDUS,SCANLNCR   SCAN FOR LOAD FOR MODULES OUT CORE.  15400019
         B     ECBPOSTD                                                 15600019
*                                                                       15800019
*********************************************************************** 16000019
*                                                                     * 16200019
*              PROCESS DELETE-REQUEST                                 * 16400019
*                                                                     * 16600019
*********************************************************************** 16800019
SCFORDE1 EQU   *                                                        17000019
         LH    R5,RQDEL(0,R3)                                           17200019
         LTR   R5,R5               CLOSE-DOWN-REQUEST?                  17400019
         BZ    CLOSEDWN              YES, BRANCH.                       17600019
*                                    NO, GO ON.                         17800019
         SRL   R5,SHIFT8(0)        HAS COMMAND-CODE.                    18000019
         LTR   R5,R5               IS MODULE NUMBER ZERO?               18200019
         BZ    ISITLAST              YES, BRANCH.                       18400019
*                                    NO, GO ON.                         18600019
         STC   R5,CODE                                                  18800019
         NI    CODE,CLHIBIT        CLEAR HIGHORDER BIT.                 19000019
         L     R5,TRTTABLE         HAS ADDR OF TRANSLATE-TABLE.         19200019
         TR    CODE,0(R5)          ASSOCIATE MODULE-NUMBER TO COMMAND-  19400019
*                                    CODE                               19600019
         SR    R5,R5                                                    19800019
         IC    R5,CODE             HAS MODULE-NUMBER.                   20000019
         BAL   R14,MODTBOFS        GET OFFSET IN MODULE-TABLE.          20200019
*                                                                       20400019
         USING MODULTAB,R11                                             20600019
         USING BLOCKTAB,R12                                             20800019
         NI    MODFLAGS,MODLKEDF   CLEAR MODULE-LOCKED-FLAG.            21000019
         LA    R6,1                GO AND SUBTRACT                      21200019
         LNR   R6,R6                 ONE FROM REQUEST-                  21400019
         BAL   R14,ADDTOREQ          COUNT IN BLOCKTABLE-ENTRY.         21600019
*                                                                       21800019
         TM    MODFLAGS,MODTRMOD   IS IT TROUBLE-MODULE?                22000019
         BZ    NTRMD1                NO, BRANCH.                        22200019
*                                    YES, GO ON.                        22400019
         CLI   BLKREQCT,ZERO       IS REQUEST-COUNT ZERO?               22600019
         BNE   NTRMD1                NO, BRANCH.                        22800019
*                                    YES, GO ON.                        23000019
         LA    R4,ONE(0,R4)        ADD ONE TO TROUBLE-MD-COUNT.         23200019
NTRMD1   EQU   *                                                        23400019
         MVI   RQDEL(R3),ZERO      CLEAR DELETE-REQUEST.                23600019
         CLI   RQLOD(R3),ZERO      LOAD REQUEST?                        23800019
         BNE   ISITLAST              YES, BRANCH.                       24000019
*                                    NO, GO ON.                         24200019
         XC    0(4,R2),0(R2)       CLEAR ECB IN CLB.                    24400019
         LA    R3,0(R3)            SET HIGH ORDER BYTE TO ZERO          24500021
         POST  (R3)                POST RETURN-ECB.                     24600019
         B     ISITLAST                                                 24800019
*                                                                       25000019
*********************************************************************** 25200019
*                                                                     * 25400019
*              PROCESS CLOSE-DOWN-REQUEST                             * 25600019
*                                                                     * 25800019
*********************************************************************** 26000019
CLOSEDWN EQU   *                                                        26200019
         L     R11,MODTABLE                                             26400019
BLDNAME  EQU   *                                                        26600019
         LA    R11,MDENTLNG(0,R11) HAS FIRST MODULETABLE-ENTRY.         26800019
         TM    MODFLAGS,MODLDEDN   MODULE LOADED?                       27000019
         BZ    LASTINL               NO, BRANCH.                        27200019
*                                    YES, GO ON.                        27400019
         MVC   EPLOCNM,MODNAME     BUILD MODULE-NAME.                   27600019
         DELETE EPLOC=EPLOC        DELETE MODULE.                       27800019
LASTINL  EQU   *                                                        28000019
         TM    MODFLAGS,MODLAST    LAST ENTRY IN TABLE?                 28200019
         BZ    BLDNAME             NO, BRANCH.                          28400019
*                                    YES, GO ON.                        28600019
*                                                                       28800019
         L     R13,SAVER13                                              29000019
         RETURN (14,12),,RC=0                                    A36810 29200020
*                                                                       29400019
*********************************************************************** 29600019
*                                                                     * 29800019
*              GET MODULETABLE-ENTRY                                  * 30000019
*                                                                     * 30200019
*********************************************************************** 30400019
MODTBOFS EQU   *                                                        30600019
         LR    R0,R5                                                    30800019
         SLL   R0,SHIFT3(0)                                             31000019
         SLL   R5,SHIFT2(0)                                             31200019
         AR    R5,R0               HAS OFFSET IN MODULE-TABLE.          31400019
         L     R11,MODTABLE        HAS ADDR OF MODULE TABLE.            31600019
         AR    R11,R5              HAS MODULE TABLE ENTRY.              31800019
         SR    R5,R5                                                    32000019
         BR    R14                                                      32200019
*                                                                       32400019
*********************************************************************** 32600019
*                                                                     * 32800019
*              ADD R6 TO REQUEST-COUNT IN BLOCKTABLE-ENTRY            * 33000019
*                                                                     * 33200019
*********************************************************************** 33400019
ADDTOREQ EQU   *                                                        33600019
         SR    R5,R5                                                    33800019
         IC    R5,MODBLKNM         HAS OFFSET IN BLOCK-TABLE.           34000019
         L     R12,BLKTABLE        HAS ADDR OF BLOCK-TABLE.             34200019
         AR    R12,R5              HAS BLOCK-TABLE-ENTRY.               34400019
         IC    R5,BLKREQCT         HAS REQUEST-COUNT.                   34600019
         AR    R5,R6               INCREASE OR DECREASE REQUEST-COUNT.  34800019
         STC   R5,BLKREQCT         RESTORE REQUEST-COUNT.               35000019
         BR    R14                 GO BACK.                             35200019
*                                                                       35400019
*********************************************************************** 35600019
*                                                                     * 35800019
*              PROCESS LOAD-REQUEST FOR MODULES IN CORE               * 36000019
*                                                                     * 36200019
*********************************************************************** 36400019
SCFORLI1 EQU   *                                                        36600019
         TM    MODFLAGS,MODINCRN   MODULE IN CORE?                      36800019
         BZ    ISITLAST              NO, BRANCH.                        37000019
*                                    YES, GO ON.                        37200019
         TM    MODFLAGS,MODLDEDN   MODULE LOADED?                       37400019
         BO    LOADED                YES, BRANCH.                       37600019
*                                    NO, GO ON.                         37800019
         MVC   EPLOCNM,MODNAME     BUILD MODULE-NAME.                   38000019
         LOAD  EPLOC=EPLOC         LOAD MODULE.                         38200019
         IC    R5,MODNAME+4        SAVE LAST CHAR OF NAME.              38400019
         ST    R0,MODNAME+4        STORE ENTRY-POINT-ADDR.              38600019
         STC   R5,MODNAME+4        RESTORE LAST CHAR OF NAME.           38800019
         OI    MODFLAGS,MODLDEDN   MODULE LOADED, SET FLAG.             39000019
LOADED   TM    MODFLAGS,MODLKEDN   MODULE LOCKED?                       39200019
         BZ    NOTLKED               NO, BRANCH.                        39400019
*                                    YES, GO ON.                        39600019
TSTEVCT  EQU   *                                                        39800019
         TM    RQFLGS(R3),ECTINTDN EVENTCOUNT INCREMENTED?              40000019
         BO    ISITLAST              YES, BRANCH.                       40200019
*                                    NO, GO ON.                         40400019
         LA    R13,1(0,R13)        ADD ONE TO EVENTCOUNT.               40600019
         OI    RQFLGS(R3),ECTINTDN SET FLAG 'EVENTCOUNT INCREMENTED'.   40800019
         B     ISITLAST                                                 41000019
*                                                                       41200019
NOTLKED  TM    RQFLGS(R3),ECTINTDN EVENTCOUNT INCREMENTED?              41400019
         BZ    INCREQCT              NO, BRANCH.                        41600019
*                                    YES, GO ON.                        41800019
         BCTR  R13,0               DECREMENT EVENTCOUNT BY ONE.         42000019
         NI    RQFLGS(R3),ECTINTDF CLEAR EVENTCOUNT-INCREMENTED-FLAG.   42200019
INCREQCT LA    R6,1                GO AND ADD ONE TO REQUEST-           42400019
         BAL   R14,ADDTOREQ          COUNT IN BLOCKTABLE-ENTRY.         42600019
         TM    MODFLAGS,MODTRMOD   IS IT TROUBLE-MODULE?                42800019
         BZ    NTRMD2                NO, BRANCH.                        43000019
*                                    YES, GO ON.                        43200019
         CLI   BLKREQCT,X1         IS REQUEST-COUNT ONE?                43400019
         BNE   NTRMD2                NO, BRANCH.                        43600019
*                                    YES, GO ON.                        43800019
         BCTR  R4,0                SUBTRACT ONE FROM TROUBLE-MD-COUNT.  44000019
NTRMD2   EQU   *                                                        44200019
*                                                                       44400019
         TM    MODFLAGS,MODNRENT   MODULE NON-REENTRANT?                44600019
         BZ    DONTLOCK              NO, BRANCH.                        44800019
*                                    YES, GO ON.                        45000019
         OI    MODFLAGS,MODLKEDN   LOCK MODULE.                         45200019
DONTLOCK EQU   *                                                        45400019
         MVI   0(R2),ZERO          CLEAR FIRST BYTE IN CLB-ECB.         45600019
         L     R2,MODNAME+4        GET ENTRY-POINT OF MODULE.           45800019
         LA    R2,0(0,R2)          CLEAR FIRST BYTE.                    46000019
         LA    R3,0(R3)            SET HIGH ORDER BYTE TO ZERO          46100021
*        POST  (R3)                POST RETURN-ECB AND PASS ENTRY-      46200019
*                                    POINT OF MODULE.                   46400019
         LR    1,R3 LOAD PARAMETER REG 1                                46600019
         LR    0,R2 LOAD PARAMETER REG 2                                46800019
         SVC   2 ISSUE POST SVC                                         47000019
         B     ISITLAST                                                 47200019
*                                                                       47400019
*********************************************************************** 47600019
*                                                                     * 47800019
*              PROCESS LOAD-REQUEST FOR MODULES NOT IN CORE           * 48000019
*                                                                     * 48200019
*********************************************************************** 48400019
SCFORLN1 EQU   *                                                        48600019
         TM    MODFLAGS,MODINCRN   MODULE IN CORE?                      48800019
         BZ    NOINCORE              NO, BRANCH.                        49000019
*                                    YES, GO ON.                        49200019
         TM    MODFLAGS,MODLKEDN   IS MODULE LOCKED?                    49400019
         BO    ISITLAST              YES, BRANCH.                       49600019
*                                    NO, GO ON.                         49800019
RESTART  LR    R8,R7               RESTART WITH FIRST-TO-BE-SERVICED.   50000019
         B     SCFORDE2                                                 50200019
*                                                                       50400019
NOINCORE L     R12,BLKTABLE                                             50600019
CKIFEND  CLC   BLKREQCT(2),ENDBLK  END OF BLOCK-TABLE REACHED?          50800019
         BNE   CHECKIT               NO, BRANCH.                        51000019
*                                    YES, GO ON.                        51200019
         TM    RQFLGS(R3),ECTINTDN EVENTCOUNT INCREMENTED?              51400019
         BO    KEEPFRST              YES, BRANCH.                       51600019
*                                    NO, GO ON.                         51800019
         LA    R13,1(0,R13)        ADD ONE TO EVENTCOUNT.               52000019
         OI    RQFLGS(R3),ECTINTDN SET FLAG 'EVENTCOUNT INCREMENTED'.   52200019
KEEPFRST EQU   *                                                        52400019
         TM    SCANMDUS,FIRSTUSN   FIRST UNSUCCESSFUL REQUEST?          52600019
         BO    ISITLAST              NO, BRANCH.                        52800019
*                                    YES, GO ON.                        53000019
         OI    SCANMDUS,FIRSTUSN   FIRST UNSUCCESSFUL REQUEST, SET FLAG 53200019
         LR    R7,R8               THIS IS THE ECB THAT WILL GET THE    53400019
*                                    FIRST SERVICE.                     53600019
         B     ISITLAST            RESUME SCAN FOR MODULES NOT IN CORE. 53800019
*                                                                       54000019
CHECKIT  CLI   BLKREQCT,ZERO       IS REQUEST-COUNT ZERO?               54200019
         BE    FREEBLK               YES, BRANCH.                       54400019
*                                    NO, GO ON.                         54600019
         LA    R12,TWO(0,R12)      GET NEXT ELEMENT IN BLOCK-TABLE.     54800019
         B     CKIFEND                                                  55000019
*                                                                       55200019
FREEBLK  TM    MODFLAGS,MODTRMOD   IS IT TROUBLE-MODULE?                55400019
         BO    TROUBMDL              YES, BRANCH.                       55600019
*                                    NO, GO ON.                         55800019
FREEBLK1 ST    R11,SAVR11          KEEP THIS MODULE-TABLE-ENTRY.        56000019
         SR    R6,R6                                                    56200019
         LR    R5,R6                                                    56400019
         IC    R5,BLKMODNM         HAS NUMBER OF ENTRY IN MOD-TABLE.    56600019
         LTR   R5,R5               IS NUMBER ZERO?                      56800019
         BZ    BLKFREE               YES, BRANCH.                       57000019
*                                    NO, GO ON.                         57200019
         BAL   R14,MODTBOFS        GO AND GET MODULE-TABLE-ENTRY.       57400019
         IC    R6,MODNMMOD         HAS NUMBER OF MODULES IN THIS LOAD.  57600019
MODULLD  TM    MODFLAGS,MODLDEDN   MODULE LOADED?                       57800019
         BZ    NXTMDINL            MODULE NOT LOADED, BRANCH.           58000019
*                                  MODULE LOADED, GO ON.                58200019
         MVC   EPLOCNM,MODNAME     BUILD NAME.                          58400019
         DELETE EPLOC=EPLOC        DELETE MODULE.                       58600019
NXTMDINL EQU   *                                                        58800019
         NI    MODFLAGS,MODCLEAR   CLEAR FLAGS.                         59000019
         IC    R5,MODNXMOD                                              59200019
         BAL   R14,MODTBOFS        GO GET NEXT MODULE IN LOAD.          59400019
         BCT   R6,MODULLD          GO AND DELETE NEXT MODULE IN LOAD,   59600019
*                                    IF THERE IS ONE.                   59800019
BLKFREE  EQU   *                                                        60000019
         L     R1,BLKTABLE         HAS ADDR OF BLOCKTABLE.              60200019
         LR    R15,R12             HAS ADDR OF BLOCKTABLE-ENTRY.        60400019
         SR    R15,R1              HAS OFFSET IN BLOCKTABLE.            60600019
*                                  THE BLOCK IS FREED UP NOW.           60800019
         L     R11,SAVR11          REQUEST IS FOR THIS MODULETABLE-ENT. 61000019
         IC    R6,MODNMMOD         HAS NUMBER OF MODULES IN THIS LOAD.  61200019
STINCRFL OI    MODFLAGS,MODINCRN   SET MODULE-IN-CORE-FLAG.             61400019
         STC   R15,MODBLKNM        OFFSET TO BLOCKTABLE.                61600019
         IC    R5,MODNXMOD                                              61800019
         BAL   R14,MODTBOFS        GO GET NEXT MODULE IN LOAD.          62000019
         BCT   R6,STINCRFL                                              62200019
*                                                                       62400019
         ST    R4,SAVER4           SAVE R4.                             62600019
         L     R4,MODTABLE         HAS ADDR OF MODTABLE.                62800019
         LR    R5,R11              HAS ADDR OF MODULE-TABLE-ENTRY.      63000019
         SR    R5,R4               HAS OFFSET IN MODULE-TABLE.          63200019
         SR    R4,R4                                                    63400019
         LA    R15,TWELVE                                               63600019
         DR    R4,R15              R5 HAS NOW NUMBER OF ENTRY IN        63800019
*                                    THE MODULE TABLE.                  64000019
         STC   R5,BLKMODNM         STORE NUMBER INTO BLK-TABLE-ENTRY.   64200019
         L     R4,SAVER4           RESTORE R4.                          64400019
         B     RESTART                                                  64600019
*                                                                       64800019
TROUBMDL LTR   R4,R4               CAN OTHER TROUBLE-MODULE BE LOADED?  65000019
         BZ    TSTEVCT               NO, BRANCH.                        65200019
*                                    YES, GO ON.                        65400019
         B     FREEBLK1                                                 65600019
*                                                                A36810 65604020
*****************************************************************A36810 65608020
*                                                                A36810 65612020
*              STAE EXIT FOR LOADER/CONTROLLER ABEND PROCESSING  A36810 65616020
*                                                                A36810 65620020
*****************************************************************A36810 65624020
IHKLDC01 SAVE  (14,12)                                           A36810 65628020
         LR    R10,R15                  SET UP ADDRESSABILITY    A36810 65632020
         USING IHKLDC01,R10                                      A36810 65636020
         L     R11,SAVAVT               GET AVT BASE             A36810 65640020
         USING AVTDSECT,R11                                      A36810 65644020
         MVI   IHKYYLCE,POSTED          POST MAIN TASK OF ABEND  A36810 65648020
         L     R12,IHKYYCCT             ADDRESS OF CCT           A36810 65652020
         USING CCTDSECT,R12                                      A36810 65656020
         TM    CCTOPT1,CCTCLS           CLOSEDOWN ALREADY STARTEDA36810 65660020
         BO    NOPOST                   YES DONT POST CRJE       A36810 65664020
         OI    CCTOPT1,CCTATERM         SET ABNORMAL CLOSE       A36810 65668020
         LA    R2,BADEND                POST CODE TO INSERT      A36810 65672020
         SLL   R2,24                    SHIFT TO HIGH ORDER BYTE A36810 65676020
         L     R1,IHKYYSC3              ADDR. OF CENTRAL STCB    A36810 65680020
         L     R1,4(R1)                 ADDRESS OF ECBLIST ENTRY A36810 65684020
         L     R1,0(R1)                 ADDRESS OF ECB           A36810 65688020
         O     R2,0(R1)                 OR STOP BIT INTO ECB     A36810 65692020
         LR    R0,R2                    MOVE CODE FOR POST       A36810 65696020
         LA    R1,0(R1)                 SET HIGH ORDER BYTE TO ZERO     65698021
         POST  (1),(0)                  POST MAIN TASK TO CLOSE  A36810 65700020
         SPACE 2                                                 A36810 65704020
NOPOST   L     R9,IHKYYECL              LOCATE ECB LISTS FORMAIN A36810 65708020
         L     R8,IHKYYECD              TASK AND IHKLDC          A36810 65712020
         LA    R0,ONE                   CODE TO POST MAIN TASK   A36810 65716020
CKECB    L     R7,0(R9)                 ADDR. STCB ECBFOR LDC    A36810 65720020
         CLC   1(3,R7),1(R8)            BOTH POINT TO SAME ECB   A36810 65724020
         BNE   BUMP                     NO NOT WAITING ON LDC    A36810 65728020
         L     R1,0(R7)                 GET ECB ADDRESS          A36810 65732020
         LA    R1,0(R1)                 SET HIGH ORDER BYTE TO ZERO     65734021
         POST  (1),(0)                                           A36810 65736020
         SPACE 2                                                 A36810 65740020
         STH   R0,2(R7)                 INSURE CODE GETS INTO ECBA36810 65744020
BUMP     TM    0(R9),LAST               END OF LIST?             A36810 65748020
         BO    LDC01END                 YES EXIT                 A36810 65752020
         LA    R8,4(R8)                 BUMP TO NEXT ECB IN MAIN A36810 65756020
         LA    R9,4(R9)                 BUMP TO NEXT ECB IN LDC  A36810 65760020
         B     CKECB                    CHECK NEXT ENTRY         A36810 65764020
LDC01END SR    R15,R15                  SET CODE TO ABEND        A36810 65768020
         RETURN (14,12),,RC=(15)                                 A36810 65772020
*                                                                       65800019
*********************************************************************** 66000019
*                                                                     * 66200019
*              CONSTANTS, STORAGE AND EQUATES                         * 66400019
*                                                                     * 66600019
*********************************************************************** 66800019
BLKTABLE DS    F                   HAS ADDR OF BLOCKTABLE.              67000019
MODTABLE DS    F                   HAS ADDR OF MODULETABLE.             67200019
TRTTABLE DS    F                   HAS ADDR OF TRANSLATE-TABLE.         67400019
SAVER4   DS    F                                                        67600019
SAVR11   DS    F                                                        67800019
SAVER13  DS    F                   SAVEAREA FOR R13.                    68000019
SAVAVT   DC    F'0'                                              A36810 68060020
BADEND   EQU   X'10'                                             A36810 68120020
SCANMDUS DS    CL1                 REFLECTS REQUEST-TYPE ECBLIST IS     68200019
*                                    SCANNED FOR.                       68400019
SCANDELT EQU   X'00'                   SCAN FOR DELETE-REQUESTS.        68600019
SCANLICR EQU   X'01'                   SCAN FOR LOAD-REQUESTS FOR       68800019
*                                        MODULES IN CORE.               69000019
SCANLNCR EQU   X'03'                   SCAN FOR LOAD-REQUESTS FOR       69200019
*                                        MODULES NOT IN CORE.           69400019
SCANMASK EQU   X'03'                   MASK TO TEST ABOVE CONDITIONS.   69600019
FIRSTUSN EQU   X'80'                                                    69800019
FIRSTUSF EQU   X'7F'                                                    70000019
*                                                                       70200019
EPLOC    DC    C'IHK'              TO BUILD                             70400019
EPLOCNM  DS    CL5                   MODULE NAME.                       70600019
ENDBLK   DC    X'FFFF'                                                  70800019
CODE     DS    CL1                                                      71000019
TWELVE   EQU   12                                                       71200019
MDENTLNG EQU   12                                                       71400019
MODCLEAR EQU   X'F0'                                                    71600019
CLHIBIT  EQU   X'7F'               CLEAR HIGHORDER BIT.                 71800019
ONE      EQU   1                                                        72000019
TWO      EQU   2                                                        72200019
INTECB   EQU   4                                                        72400019
MDTABL   EQU   16                                                       72600019
POSTED   EQU   X'40'                                                    72800019
LAST     EQU   X'80'                                                    73000019
X1       EQU   X'01'                                                    73200019
ENTLNG   EQU   4                                                        73400019
RQDEL    EQU   4                                                        73600019
RQLOD    EQU   5                                                        73800019
RQFLGS   EQU   6                                                        74000019
ECTINTDN EQU   X'01'               EVENTCOUNT INCREMENTED - ON.         74200019
ECTINTDF EQU   X'FE'                                      - OFF.        74400019
ZERO     EQU   X'00'                                                    74600019
SHIFT3   EQU   3                                                        74800019
SHIFT2   EQU   2                                                        75000019
SHIFT8   EQU   8                                                        75200019
SHIFT10  EQU   10                                                       75400019
*                                                                       75600019
R0       EQU   0                                                        75800019
R1       EQU   1                   HAS MODULE-TABLE-ENTRY.              76000019
R2       EQU   2                   ECB IN CLB.                          76200019
R3       EQU   3                   RETURN-ECB.                          76400019
R4       EQU   4                   TROUBLE-MODULE-COUNT.                76600019
R5       EQU   5                                                        76800019
R6       EQU   6                                                        77000019
R7       EQU   7                   ECBLIST-ENTRY GETTING FIRST SERVICE. 77200019
R8       EQU   8                   CURRENT ECBLIST-ENTRY.               77400019
R9       EQU   9                   POINTS TO ECBLIST.                   77600019
R10      EQU   10                  BASE REGISTER.                       77800019
R11      EQU   11                                                       78000019
R12      EQU   12                  HAS BLOCK-TABLE-ENTRY.               78200019
R13      EQU   13                                                       78400019
R14      EQU   14                                                       78600019
R15      EQU   15                                                       78800019
*                                                                       79000019
*                                                                       79200019
*********************************************************************** 79400019
*                                                                     * 79600019
*              DSECT FOR MODULE-TABLE                                 * 79800019
*                                                                     * 80000019
*********************************************************************** 80200019
MODULTAB DSECT                                                          80400019
MODFLAGS DS    CL1                 FLAGS.                               80600019
MODLAST  EQU   X'80'               LAST ENTRY IN TABLE.                 80800019
MODNRENT EQU   X'40'               MODULE NON-REENTRANT.                81000019
MODTRMOD EQU   X'20'               TROUBLE-MODULE.                      81200019
MODINCRN EQU   X'08'               MODULE IN CORE - ON.                 81400019
MODINCRF EQU   X'F7'                              - OFF.                81600019
MODLDEDN EQU   X'04'               MODULE LOADED - ON.                  81800019
MODLDEDF EQU   X'FB'                             - OFF.                 82000019
MODLKEDN EQU   X'02'               MODULE LOCKED - ON.                  82200019
MODLKEDF EQU   X'FD'                             - OFF.                 82400019
MODBLKNM DS    CL1                 OFFSET OF BLOCK ALLOCATED.           82600019
MODNMMOD DS    CL1                 NUMBER OF MODULES IN THIS LOAD.      82800019
MODNXMOD DS    CL1                 NUMBER OF NEXT MODULE IN CHAIN.      83000019
MODNAME  DS    CL5                 5 SIGNIFICANT CHAR OF MODULE-NAME.   83200019
MODENTAD DS    CL3                 ENTRY-POINT-ADDR OF MODULE.          83400019
*********************************************************************** 83600019
*                                                                     * 83800019
*              DSECT FOR BLOCK-TABLE                                  * 84000019
*                                                                     * 84200019
*********************************************************************** 84400019
BLOCKTAB DSECT                                                          84600019
BLKREQCT DS    CL1                 BLOCK-REQUEST-COUNT.                 84800019
BLKMODNM DS    CL1                 NUMBER OF ONE OF THE MODULES IN BLK. 85000019
         EJECT                                                          85200019
         IHKCDSCT AVT=YES,CCT=YES                                A36810 85500020
         END   IHKLDC                                                   85800019
