LDS      TITLE 'IHKLDS - LISTDS COMMAND PROCESSOR'                      00090019
IHKLDS   CSECT                                                   A34597 00090220
*A147600                                                         A34597 00090420
*C051300,240300                                                  A34597 00090620
*D001810-006300,141300,243900-246600                             A34597 00090820
* C 095400, A 803700, C 051300                                  OS61492 00090928
*********************************************************************** 00091019
*                                                                     * 00092019
*STATUS                                                               * 00093019
*   CHANGE LEVEL 0                                                    * 00094019
*FUNCTION                                                             * 00095019
*   THE OPERANDS OF THE LISTDS OR LISTLIB COMMAND ARE CHECKED.  IF AN * 00096019
*   ERROR IS FOUND, AN ERROR MESSAGE IS SENT TO THE USER AND CONTROL  * 00097019
*   IS RETURNED TO THE CALLING ROUTINE WITH A 0 IN REGISTER 15.  THE  * 00098019
*   COMMAND CODE IN THE PPT IS CHECKED TO DETERMINE WHICH COMMAND WAS * 00099019
*   ENTERED.  IF A DATA SET NAME IS SPECIFIED ON THE LISTLIB COMMAND, * 00100019
*   IT IS NOTED AS AN ERROR.  A DSNAME MUST BE SPECIFIED ON THE       * 00101019
*   LISTDS COMMAND AND IT IS PUT IN THE TUBPMFNM FIELD.  IF STSTUS    * 00102019
*   AND/OR HISTORY IS SPECIFIED, CORRESPONDING FLAGS ARE SET IN THE   * 00103019
*   PPTFLG BYTE.  THE IHKUTM MODULE IS USED TO QUEUE FOR LIBRARY I/O. * 00104019
*   THE I FORM (LISTDS) OR THE F FORM (LISTLIB) OF THE RFIND MACRO IS * 00105019
*   THEN ISSUED TO FIND DATA SETS IN THE USER LIBRARY.  IF THE        * 00106019
*   REQUESTED DATA SET (LISTDS) OR THE USER LIBRARY (LISTLIB) IS NOT  * 00107019
*   FOUND, AN APPROPRIATE MESSAGE IS SENT TO THE USER.  IF THE        * 00108019
*   COMM&ND IS A LISTDS, THE DIRECTORY FOR THE DATA SET IS IN THE     * 00109019
*   KONBOX AT BPBLDLST + 4.  IF THE COMMAND IS A LISTLIB, A BLOCK OF  * 00110019
*   DIRECTORY ENTRIES IS READ INTO THE AREA POINTED TO BY THE SFBUFF1 * 00111019
*   FIELD.  IF THE RREAD MACRO INDICATES NO DATA SETS IN THE USER     * 00112019
*   LIBRARY, A MESSAGE IS SENT TO THE USER TO INDICATE THAT THE       * 00113019
*   LIBRARY IS EMPTY.  THE IHKLDS MODULE TERMINATES AFTER SENDING     * 00114019
*   THESE MESSAGES TO THE USER.  CREATE AND RPOINT MACROS ARE ISSUED  * 00115019
*   TO ACQUIRE AN ACTIVE AREA IN WHICH TO BUILD THE INFORMATION TO BE * 00116019
*   SENT BACK TO THE TERMINAL.  A HEADER MESSAGE IS OBTAINED FROM THE * 00117019
*   MESSAGE WRITER AND INSERTED INTO THE ACTIVE AREA. THE             * 00118019
*   INFORMATION REQUESTED WILL BE LISTED UNDER THE APPROPRIATE LABELS * 00119019
*   OF THE HEADER.  THE REQUESTED INFORMATION CONTAINED IN A          * 00120019
*   DIRECTORY IS INTERPRETED.  THE NECESSARY INFORMATION IS ASSEMBLED * 00121019
*   IN THE USER BUFFER IN AN ALIGNMENT THAT CORRESPONDS TO THE LABELS * 00122019
*   OF THE HEADER.  THE FLAGS INDICATING WHAT OPERANDS WERE SPECIFIED * 00123019
*   IN THE COMMAND ARE CHECKED.  ANY UNNECESSARY INFORMATION IS       * 00124019
*   BLANKED OUT AND THE LINE IS COMPRESSED.  THE LINE OF INFORMATION  * 00125019
*   IS THEN INSERTED INTO THE ACTIVE AREA.  WHEN ALL THE INFORMATION  * 00126019
*   REQUESTED IS GATHERED IN THE ACTIVE AREA FILE, THE PROCESSOR      * 00127019
*   DEQUEUES ITSELF FROM THE LIBRARY I/O QUEUE AND CONTROL IS PASSED  * 00128019
*   TO THE LIST PROCESSOR (IHKLST).  THE LIST PROCESSOR REQUESTS THAT * 00129019
*   THE ACTIVE FILE BE LISTED AT THE TERMINAL.  AFTER ALL THE LINES   * 00130019
*   ARE LISTED, THE ACTIVE FILE IS RELEASED BY THE LIST PROCESSOR.    * 00131019
         EJECT                                                          00132019
*ENTRY POINTS                                                         * 00133019
*        IHKLDS IS USED BY BOTH THE LISTDS AND THE LISTLIB COMMANDS   * 00134019
*INPUT                                                                * 00135019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING     * 00136019
*   THE ADDRESS OF THE TUB IN THE FIRST WORD AND                      * 00137019
*   THE ADDRESS OF THE AVT IN THE SECOND                              * 00138019
*OUTPUT                                                               * 00139019
*   ACTIVE FILE PASSED TO LIST PROCESSOR (IHKLST)                     * 00140019
*EXTERNAL REFERENCES                                                  * 00141019
*        IHKBPN - TO MANIPULATE A USER LIBRARY                        * 00142019
*        IHKAFI - TO CREATE AND MANIPULATE AN ACTIVE AREA             * 00143019
*        IHKMSG - TO SEND ERROR MESSAGES TO THE USER AND              * 00144019
*                 TO OBTAIN THE HEADER MESSAGE                        * 00145019
*        IHKUTM - TO QUEUE FOR LIBRARY I/O                            * 00146019
*        IHKLST - TO LIST THE ACTIVE FILE AT THE TERMINAL             * 00147019
*EXITS, NORMAL                                                        * 00148019
*   RETURN TO THE CALLING ROUTINE WITH ZERO IN REGISTER 15            * 00149019
*EXITS, ERROR                                                         * 00150019
*   RETURN TO CALLING ROUTINE WITH ONE OF THE FOLLOWING RETURN CODES  * 00151019
*   IN REGISTER 15                                                    * 00152019
*   4  - LINE ERROR                                                   * 00153019
*   8  - GETMAIN FAILED                                               * 00154019
*   12 - ACTIVE AREA I/O ERROR                                        * 00155019
*   16 - ERROR MESSAGE LOST                                           * 00156019
*   20 - ACTIVE AREA OUT OF SPACE                                     * 00157019
*TABLES/WORK AREAS                                                    * 00158019
*   18-WORD SAVE AREA                                                 * 00159019
*   TUB                                                               * 00160019
*   TUBUSERID - USED TO OBTAIN SPECIFIED DATA SET NAME DIRECTORY      * 00161019
*   TUBPRMLS - CONTAINS PARAMETER LIST FOR EXTERNAL ROUTINES          * 00162019
*   TUBAFISW - USED TO INDICATE TO AFIO BUFFER CONTROL IN USE         * 00163019
*   TUBGBLKY - USED TO PASS USERID TO THE IHKUTM ROUTINE              * 00164019
*   TUBNID - CHECKED FOR MESSAGE ID'S                                 * 00165019
*   TUBPMFNM - SET TO BPAM FILE NAME                                  * 00166019
*   TUBPPTAD - CHECKED FOR ADDRESS OF PPT                             * 00167019
*   TUBRAFBF - USED FOR BUFFERING CONTROL WHEN INSERTING LINES        * 00168019
*   TUBUFFAD - PROVIDES ADDRESS OF USER BUFFER                        * 00169019
*   TUBUSRNM - SET TO USER NAME FOR RFINDI FOR LISTDS                 * 00170019
*   USER BUFFER - CONTAINS LINE FOR INSERTION INTO ACTIVE AREA        * 00171019
*   ACTIVE AREA - RETAINS DATA TO BE LISTED                           * 00172019
*   PPT                                                               * 00173019
*   PPTFLG - INDICATES OPERANDS SPECIFIED IN COMMAND                  * 00174019
*   PPTPARS - PASS CODE TO IHKLST TO INDICATE IHKLDS REQUEST          * 00175019
*ATTRIBUTES                                                           * 00176019
*   NONRESIDENT AND REENTRANT                                         * 00177019
*                                                                     * 00178019
*********************************************************************** 00179019
         EJECT                                                          00180019
R0       EQU   0                   GENLREG                              00720019
R1       EQU   1                   PARAMPT,PARMREG                      00810019
R2       EQU   2                   INNERBR                              00900019
R3       EQU   3                   MSGCODE                              00990019
R4       EQU   4                   KBXPT                                01080019
R5       EQU   5                   USRBUFAD                             01170019
R6       EQU   6                   OPNDINCR,PPTESTRG,DIRDISP            01260019
R7       EQU   7                   OPNDCTR                              01350019
R8       EQU   8                   OPNDPT,RETCODE,KBXDIRAD,SFBUFFAD     01440019
R9       EQU   9                   PPTPT          USING                 01530019
R10      EQU   10                  AVTPT          USING                 01620019
R11      EQU   11                  TUBPT          USING                 01710019
R12      EQU   12                  BASEREG        USING                 01800019
R13      EQU   13                  SAVEPT                               01890019
R14      EQU   14                  RETADDR                              01980019
R15      EQU   15                  RETREG, OUTERBR                      02070019
         SPACE 2                                                        02160019
GENLREG  EQU   0                   REG FOR GENERAL USE                  02250019
PARAMPT  EQU   1                   REG FOR PARAMETER LIST ADDRESS       02340019
PARMREG  EQU   1                   REG FOR PARAMETER HANDLING           02430019
INNERBR  EQU   2                   REG FOR INTERNAL BRANCH/LINK ADDRESS 02520019
MSGCODE  EQU   3                   REG FOR MESSAGE CODE TO MSGWTR       02610019
KBXPT    EQU   4                   REG FOR KONBOX ADDRESSABILITY        02700019
USRBUFAD EQU   5                   REG FOR POINTER TO USER BUFFER       02790019
OPNDINCR EQU   6                   REG FOR INCREMENTING OPNDPT          02880019
PPTESTRG EQU   6                   REG FOR TESTING OF PPTCHAINING       02970019
DIRDISP  EQU   6                   REG FOR DIRECTORY DISPLACEMENT OF DS 03060019
OPNDCTR  EQU   7                   REG FOR COUNTING OPERANDS            03150019
LDSBUFAD EQU   7                   REG FOR ADDR OF LINE IN USER BUFFER  03240019
KBXDIRAD EQU   8                   REG FOR DIRECTORY ADDRESSABILITY     03330019
OPNDPT   EQU   8                   REG FOR POINTING TO PPT OPERANDS     03420019
RETCODE  EQU   8                   REG FOR RETURN CODE                  03510019
SFBUFFAD EQU   8                   REG FOR SFBUF1 ADDRESS               03600019
PPTPT    EQU   9                   REG FOR POINTING TO PPT              03690019
AVTPT    EQU   10                  REG FOR POINTING TO AVT              03780019
TUBPT    EQU   11                  REG FOR POINTINS TO TUB              03870019
BASEREG  EQU   12                  REG FOR BASE ADDRESS OF IHKLDS       03960019
SAVEPT   EQU   13                  REG FOR POINTING TO SAVE AREA        04050019
RETADDR  EQU   14                  REG FOR RETURN ADDRESSES             04140019
ENTRYREG EQU   15                  REG FOR IHKLDS ADDRESS AT ENTRY      04230019
RETREG   EQU   15                  REG FOR RETURN CODES                 04320019
OUTERBR  EQU   15                  REG FOR BRANCHING OUT OF ROUTINE     04410019
         EJECT                                                          04500019
***********************************                                     04590019
*                                                                       04680019
* SAVE REGISTERS AND ESTABLISH ADDRESSABILITY                           04770019
*                                                                       04860019
***********************************                                     04950019
 SPACE                                                                  05040019
         SAVE  (14,12),,LDS73190       SAVE REGISTERS           OS61492 05130028
         LR    BASEREG,ENTRYREG    LOAD BASE REG                        05220019
         USING IHKLDS,BASEREG                                           05310019
 SPACE 2                                                                05400019
***********************************                                     05490019
*                                                                       05580019
* DYNAMIC STORAGE FOR SAVE AND WORK AREAS                               05670019
*                                                                       05760019
***********************************                                     05850019
 SPACE                                                                  05940019
         L     TUBPT,WD1DISPL(PARAMPT)                                  06030019
         USING TUBDSECT,TUBPT      ADDRESSABILITY TO THE TUB            06120019
         L     PPTPT,TUBPPTAD      OBTAIN ADDRESS OF PPT                06210019
         USING PPTDSECT,PPTPT      ADDRESSABILITY FOR PPT               06300019
         L     AVTPT,WD2DISPL(PARAMPT)                                  06390019
         USING AVTDSECT,AVTPT      ADDRESSABILITY FOR THE AVT           06480019
         L     R1,IHKYYGML                                              06570019
         LA    R2,NEED             PROVIDE STORAGE NEEDS                06660019
         LA    R3,TUBPARM1         PROVIDE FOR POINTER TO GETMAIN AREA  06750019
         GETMAIN EC,LV=(R2),A=(R3),MF=(E,(1))                           06840019
         LTR   R15,R15             TEST FOR SUCCESSFUL COMPLETION       06930019
         LA    R15,GTMNFAIL        PROVIDE RETURN CODE FOR GETMAIN FAIL 07020019
         BNZ   RETURN1             IF IN ERROR, INDICATE GETMAIN FAIL   07110019
 SPACE 2                                                                07200019
***********************************                                     07290019
*                                                                       07380019
* ESTABLISH LINKAGE OF SAVE AREAS                                       07470019
*                                                                       07560019
***********************************                                     07650019
 SPACE                                                                  07740019
         L     R15,TUBPARM1        LOAD SAVE AREA ADDRESS               07830019
         ST    R13,CALLNGSA(R15)   STORE CALLING SAVE AREA ADDRESS      07920019
         ST    R15,CALLEDSA(R13)   STORE CALLED SAVE AREA ADDRESS       08010019
         LR    R13,R15             PLACE SAVE AREA ADDRESS IN SAVE REG  08100019
         EJECT                                                          08190019
***********************************                                     08280019
*                                                                       08370019
* TEST OPERANDS OF PPT                                                  08460019
*                                                                       08550019
***********************************                                     08640019
 SPACE                                                                  08730019
         LA    OPNDPT,PPTPARS      OBTAIN POINTER TO PARAMETER FLD      08820019
         SR    OPNDCTR,OPNDCTR     CLEAR OPERAND COUNTER TO ZERO        08910019
         CLI   PPTCMD,CMDLDS       TEST FOR LDS COMMAND                 09000019
         BC    NOTEQUAL,LIBOPND1   IF LSTLIB COMMAND, TEST LSTLIB OPNDS 09090019
         BAL   INNERBR,RETEST      TEST FOR FIRST LDS OPERAND           09180019
         B     ERRNODSN            IF NO OPERAND, NO DSNAME ERROR       09270019
         CLI   0(OPNDPT),DSNMLNG   TEST FOR DSNSME LENGTH               09360019
         BH    ERROPND             IF GREATER THAN EIGHT, ERROR         09450019
         CLI   1(OPNDPT),ALPHAZ    COMPARE 1ST CHAR TO Z        OS61492 09540028
         BH    ERROPND             IF HIGHER...ERROR            OS61492 09580028
         CLI   1(OPNDPT),ALPHAA    COMPARE 1ST CHAR TO A        OS61492 09620028
         BNL   FIRSTOK             IF >= A...1ST CHAR BETWEEN A&Z       09660030
         CLI   1(OPNDPT),ALPHA@    COMPARE 1ST CHAR TO @        OS61492 09700028
         BE    FIRSTOK             IF EQUAL...1ST CHAR IS OK    OS61492 09740028
         CLI   1(OPNDPT),ALPHA#    COMPARE 1ST CHAR TO #        OS61492 09780028
         BE    FIRSTOK             IF EQUAL...1ST CHAR IS OK    OS61492 09820028
         CLI   1(OPNDPT),ALPHA$    COMPARE 1ST CHAR TO $        OS61492 09860028
         BNE   ERROPND             IF NOT EQUAL...ERROR         OS61492 09900028
FIRSTOK  MVC   TUBPMFNM,DBLWDBLK   BLANK OUT BPAM FILE NAME     OS61492 09940028
         IC    OPNDINCR,0(OPNDPT)  OBTAIN LENGTH OF FILE NAME           09990019
         BCTR  OPNDINCR,0          REDUCE LENGTH COUNT BY ONE           10080019
         EX    OPNDINCR,LOADDSNM   MOVE DSNAME INTO TUB BPAM FILE NAME  10170019
         B     CHKNXTOP            CHECK NEXT OPERAND                   10260019
LIBOPND1 DS    0H                                                       10350019
         BAL   INNERBR,FRSTTEST    TEST FOR FIRST LISTLIB OPERAND       10440019
         B     CHKERRSW            BR IF NO MORE OPERANDS FOUND         10530019
         B     CHKEXCSS            BR IF OPND FOUND, CHECK FOR EXCESS   10620019
         EJECT                                                          10710019
CHKNXTOP DS    0H                                                       10800019
         BAL   INNERBR,NEXTTEST         CHECK FOR NEXT OPERAND PRESENT  10890019
         B     CHKERRSW                 IF NOT PRESENT, CHECK FOR ERROR 10980019
CHKEXCSS DS    0H                                                       11070019
         LA    GENLREG,EXCSOPND         CREAT EXCESS OPERAND COUNT      11160019
         CLR   GENLREG,OPNDCTR          TEST FOR EXCESS OPERAND COUNT   11250019
         BC    LOW,ERREXCSS             IF EXCESS OPENAND, ERROR & END  11340019
         CLC   MDLSTAT1,0(OPNDPT)       TEST FOR 'S', STATUS, OPERAND   11430019
         BC    EQUAL,SETSFLAG           IF 'S', SET STATUS FLAG         11520019
         CLC   MDLSTAT2,0(OPNDPT)       TEST FOR 'STATUS' OPERAND       11610019
         BC    EQUAL,SETSFLAG           IF 'STATUS', SET STATUS FLAG    11700019
         CLC   MDLHIST1,0(OPNDPT)       TEST FOR 'H', HISTORY, OPERAND  11790019
         BC    EQUAL,SETHFLAG           IF 'H', SET HISTORY FLAG        11880019
         CLC   MDLHIST2,0(OPNDPT)       TEST FOR 'HISTORY' OPERAND      11970019
         BC    EQUAL,SETHFLAG           IF 'HISTORY', SET HISTORY FLAG  12060019
         B     ERROPND                  INDICATE ERROR IN OPERAND       12150019
SETHFLAG DS    0H                                                       12240019
         TM    PPTFLG,HSTRYFLG          TEST FOR PREVIOUS H OPERAND     12330019
         BC    ON,ERRMULTI              IF PREVIOUS OPND, MULTI ERROR   12420019
         OI    PPTFLG,HSTRYFLG          SET HISTORY FLAG                12510019
         B     CHKNXTOP                 CHECK FOR NEXT OPERAND          12600019
SETSFLAG DS    0H                                                       12690019
         TM    PPTFLG,STATSFLG          TEST FOR PREVIOUS S OPERAND     12780019
         BC    ON,ERRMULTI              IF PREVIOUS OPND, MULTI ERROR   12870019
         OI    PPTFLG,STATSFLG          SET STATUS FLAG                 12960019
         B     CHKNXTOP                 CHECK FOR NEXT OPERAND          13050019
CHKERRSW DS    0H                                                       13140019
         XR    R15,R15                  SET RTRN CODE IN CASE OF ERROR  13230019
         TM    PPTFLG,ERRORSW           TEST FOR ERROR IN PARAMETERS    13320019
         BO    RETURN1                  IF PRIOR ERROR, TERMINATE       13410019
         EJECT                                                          13500019
***********************************                                     13590019
*                                                                       13680019
* ENQUEUE FOR BPAM                                                      13770019
*                                                                       13860019
***********************************                                     13950019
 SPACE                                                                  14040019
         LA    PARAMPT,UTMCODE     PROVIDE PT TO UTM CODE               14220019
         ST    PARAMPT,TUBPARM2                                         14310019
         BAL   INNERBR,CALLUTM     ENQUEUE FOR BPAM OPERATIONS          14400019
         B     FINDLDS             USERID VERIFIED, ENQUEUED FOR BPAM   14490019
CALLUTM  DS    0H                                                       14580019
         ST    TUBPT,TUBPARM1      PROVIDE PT TO TUB                    14670019
         LA    PARAMPT,TUBPRMLS    PROVIDE PT TO PARAMETER LIST         14760019
         MVC   TUBGBLKY,TUBUSRID   PUT USERID INTO KEY AREA      A34597 14800020
         L     OUTERBR,IHKYYUTM    OBTAIN ADDRESS OF USER FILE MANAGER  14850019
         BALR  RETADDR,OUTERBR     ENQUEUE FOR BPAM                     14940019
         B     *+4(RETREG)         EVALUATE RETURN CODE                 15030019
         B     0(INNERBR)          NO ERRORS, PROCEED                   15120019
         B     ERRDD               USERID NOT FOUND                     15210019
         B     RETURN1             GETMAIN FAILED                       15300019
         B     RETURN1             DISK ERROR IN ACTIVE AREA            15390019
         B     ERRDD               DDNAME BLANK                         15480019
         B     FINDLDS             USERID ACTIVE                        15570019
         B     ERRLIBNO            LIBRARY INOPERATIVE                  15660019
 EJECT                                                                  15750019
***********************************                                     15840019
*                                                                       15930019
* LOCATE THE DESIRED DIRECTORY INFORMATION                              16020019
*                                                                       16110019
***********************************                                     16200019
 SPACE                                                                  16290019
FINDLDS  DS    0H                                                       16380019
         OI    PPTFLG,CLOSFLAG          INDICATE NEED FOR RCLOSE        16470019
         MVC   TUBUSRNM,TUBUSRID        INITIALIZE USER NAME            16560019
         LA    PARAMPT,PTTUBPT(SAVEPT)  PROVIDE POINTER TO TUB POINTER  16650019
         CLI   PPTCMD,CMDLDS            TEST FOR LDS OPERAND            16740019
         BC    NOTEQUAL,FINDLIB         IF LSTLIB DO F FORM RFIND       16830019
         RFIND I                        INITIATE LIBRARY I/O FOR LSTLDS 16920019
         B     FINDCHK                  EVALUATE FIND RETURN CODE       17010019
FINDLIB  DS    0H                                                       17100019
         RFIND F                        INITIATE LIBRARY I/O FOR LSTLIB 17190019
FINDCHK  DS    0H                                                       17280019
         B     *+4(RETREG)              EVALUATE THE RETURN CODE        17370019
         B     CREATE                   NO ERROR, CREATE ACTIVE AREA    17460019
         B     ERRNODS                  UNIQUE DSNAME, NOT FOUND        17550019
         B     RETURN1                  GETMAIN ERROR                   17640019
         B     LIBIOERR                 I/O ERROR                       17730019
         B     CREATE                   CREATE ACTIVE AREA              17820019
 EJECT                                                                  17910019
***********************************                                     18000019
*                                                                       18090019
* CREATE THE ACTIVE AREA NEEDED FOR LISTING                             18180019
*                                                                       18270019
***********************************                                     18360019
 SPACE                                                                  18450019
CREATE   DS    0H                                                       18540019
         LA    PARAMPT,PTTUBPT(SAVEPT)  PROVIDE POINTER TO TUB POINTER  18630019
         CREATE IS                      CREATE ACTIVE AREA              18720019
         B     *+4(RETREG)              EVALUATE RETURN CODE            18810019
         B     POINT                    NO ERRORS, PROCEED TO POINT     18900019
         B     ERRSPACE                 OUT OF SPACE ERROR              18990019
         B     RETURN1                  GETMAIN ERROR                   19080019
         B     RETURN1                  I/O ERROR                       19170019
         EJECT                                                          19260019
***********************************                                     19350019
*                                                                       19440019
* POINT TO THE BEGINNING OF THE ACTIVE AREA                             19530019
*                                                                       19620019
***********************************                                     19710019
 SPACE                                                                  19800019
POINT    DS    0H                                                       19890019
         OI    PPTFLG,CREATFLG          INDICATE NEED FOR RELEASE       19980019
         LA    PARAMPT,PTTUBPT(SAVEPT)  PROVIDE POINTER TO TUB POINTER  20070019
         RPOINT B,NR,KEY=FIRST          POINT TO BEGINNING OF ACTIVE AR 20160019
         B     *+4(RETREG)              EVALUATE RETURN CODES           20250019
         B     HEADER                   NO ERRORS, INSERT HEADER        20340019
         B     ERRSPACE                 OUT OF SPACE ERROR              20430019
         B     RETURN                   GETMAIN ERROR                   20520019
         B     RETURN                   I/O ERROR                       20610019
         EJECT                                                          20700019
***********************************                                     20790019
*                                                                       20880019
* LOAD THE HEADER INFORMATION INTO THE ACTIVE AREA                      20970019
*                                                                       21060019
***********************************                                     21150019
 SPACE                                                                  21240019
HEADER   DS    0H                                                       21330019
         OI    PPTFLG,NDUPFLAG          INDICATE NEED FOR ENDUP         21420019
         LA    MSGCODE,MSGHEADR         OBTAIN ADDRESS OF MSG CODE      21510019
         BAL   INNERBR,CALLMSG          CALL MSGWTR TO GET HEADER       21600019
         L     USRBUFAD,TUBUFFAD        OBTAIN ADDRESS OF USER BUFFER   21690019
         MVC   72(36,USRBUFAD),36(USRBUFAD)  MOVE RT LAST HALF OF MSG   21780019
         MVC   36(36,USRBUFAD),0(USRBUFAD)   MOVE RT FIRST HALF MSG     21870019
         MVC   8(72,USRBUFAD),36(USRBUFAD)   MOVE LEFT WHOLE MSG OFST+8 21960019
         LA    LDSBUFAD,8(USRBUFAD)     PROVIDE POINTER TO MSG          22050019
         BAL   INNERBR,INSERT           INSERT LINE INTO ACTIVE AREA    22140019
         L     KBXPT,IHKYYKBX           OBTAIN POINTER TO KONBOX        22230019
         USING RAFKNBX,KBXPT            ADDRESSABILITY FOR KONBOX       22320019
         CLI   PPTCMD,CMDLDS            TEST FOR LSTLDS OR LSTLIB CMD   22410019
         BC    NOTEQUAL,READ            IF LSTLIB READ BLOCK OF DIR'S   22500019
         LA    KBXDIRAD,BPBLDLST+4      OBTAIN ADDRESS OF DIRECTORY     22590019
         USING DIRDSECT,KBXDIRAD        ADDRESSABILITY FOR DIRECTORY    22680019
         B     LDSLINE                  BUILD LINE                      22770019
         EJECT                                                          22860019
***********************************                                     22950019
*                                                                       23040019
* READ A BLOCK FROM THE LIBRARY DIRECTORY FOR LISTLIB                   23130019
*                                                                       23220019
***********************************                                     23310019
 SPACE                                                                  23400019
READ     DS    0H                                                       23490019
         LA    DIRDISP,LNGLNG           UP DISPLACEMENT FOR BFR LNG CNT 23580019
         LA    PARAMPT,PTTUBPT(SAVEPT)  PROVIDE POINTER TO TUB POINTER  23670019
         RREAD                          READ BLOCK OF DIRECTORY         23760019
         B     *+4(RETREG)              EVALUATE RETURN CODE            23850019
         B     LIBLINE                  PROCEED TO PROCESS LIB LINE     23940019
         B     LIBIOERR            MARK LIB INOPERATIVE          A34597 24030020
         B     RETURN                   GETMAIN ERROR                   24120019
         B     LIBIOERR                 I/O ERROR                       24210019
         SPACE 1                                                        24300019
         EJECT                                                          24750019
***********************************                                     24840019
*                                                                       24930019
* PREPARE THE LISTLIB LINE                                              25020019
*                                                                       25110019
***********************************                                     25200019
 SPACE                                                                  25290019
LIBLINE  DS    0H                                                       25380019
         L     SFBUFFAD,SFBUFF1         OBTAIN ADDRESS OF BUFFER        25470019
         LA    SFBUFFAD,8(SFBUFFAD)     ADVANCE ADDR PAST BUFFER INFO   25560019
         LA    INNERBR,READ             IF END OF BFR, FREEMAIN & READ  25650019
         CH    DIRDISP,0(SFBUFFAD)      TEST FOR END OF BUFFER          25740019
         BC    NOTLOW,FREEMAIN                                          25830019
         LA    R3,0(DIRDISP,SFBUFFAD)   ESTABLISH ADDRESS FOR LAST TEST 25920019
         CLC   0(8,R3),BPAMEOD          TEST DIR NAME FOR LAST ENTRY    26010019
         BE    CHKNSRT2                 IF LAST ENTRY, CHECK FOR INSERT 26100019
         LR    SFBUFFAD,R3                   POINT TO NEXT DIRECTORY    26190019
         USING DIRDSECT,SFBUFFAD        ADDRESSABILITY FOR DIRECTORY    26280019
         B     LDSLINE                  IF NOT LAST, PROCEED TO PROCESS 26370019
CHKNSRT2 DS    0H                                                       26460019
         LA    INNERBR,RTRNLIST         IF FREEMAIN, EXIT TO LIST       26550019
         TM    PPTFLG,INSRTFLG          TEST FOR PREVIOUS INSERTS       26640019
         BC    ON,FREEMAIN              IF INSERTS, FREEMAIN AND LIST   26730019
         BAL   INNERBR,FREEMAIN                                         26820019
         B     ERRLIBEM                 IF NO INSERTS, RETURN NO LIST   26910019
         EJECT                                                          27000019
***********************************                                     27090019
*                                                                       27180019
* PREPARE THE LISTDS LINE                                               27270019
*                                                                       27360019
***********************************                                     27450019
 SPACE                                                                  27540019
LDSLINE  DS    0H                                                       27630019
         LA    LDSBUFAD,8(USRBUFAD)     RESET ADDRESSABILITY FOR LDS    27720019
         USING LDSDSECT,LDSBUFAD                                        27810019
         MVI   0(LDSBUFAD),BLANK        INSERT A BLANK                  27900019
         MVC   1(LDSBUFSZ-1,LDSBUFAD),0(LDSBUFAD) BLANK OUT USER BUFFER 27990019
         MVC   LDSDSNAM,DIRFNAME        POSITION DATA SET FILE NAME     28080019
         CLC   DIRFNAME,ACTIVE          TEST FOR 'ACTIVE' DSNAME        28170019
         BC    EQUAL,ACTIVELN           IF 'ACTIVE', PAD LINE WITH *'S  28260019
         EJECT                                                          28350019
***********************************                                     28440019
*                                                                       28530019
* ANALYSIS OF THE TYPE ATTRIBUTE OF THE DATA SET                        28620019
*                                                                       28710019
***********************************                                     28800019
 SPACE                                                                  28890019
TSTPL148 DS    0H                                                       28980019
         TM    DIRATTRL,DIRPL148        TEST FOR PL/1-48 ATTRIBUTE      29070019
         BC    NOT,TSTFORTH             IF NOT GO TO NEXT TEST          29160019
         MVC   LDSATYPE,LBLPL148        POSITION PL/1-48 ATTRIBUTE MSG  29250019
         B     TSTLNO                   GO TO LINE NUMBER TEST          29340019
TSTFORTH DS    0H                                                       29430019
         TM    DIRATTRL,DIRFORTH        TEST FOR FORTRAN-H ATTRIBUTE    29520019
         BC    NOT,TSTFORTG             IF NOT GO TO NEXT TEST          29610019
         MVC   LDSATYPE,LBLFORTH        POSITION FORTRAN-H ATTRIBUTE    29700019
         B     TSTLNO                   GO TO LINE NUMBER TEST          29790019
TSTFORTG DS    0H                                                       29880019
         TM    DIRATTRL,DIRFORTG        TEST FOR FORTRAN-G ATTRIBUTE    29970019
         BC    NOT,TSTADATA             IF NOT GO TO NEXT TEST          30060019
         MVC   LDSATYPE,LBLFORTG        POSITION FORTRAN-G ATTRIBUTE    30150019
         B     TSTLNO                   GO TO LINE NUMBER TEST          30240019
TSTADATA DS    0H                                                       30330019
         TM    DIRATTRL,DIRADATA        TEST FOR DATA ATTRIBUTE         30420019
         BC    NOT,TSTATEXT             IF NOT GO TO NEXT TEST          30510019
         MVC   LDSATYPE,LBLADATA        POSITION DATA ATTRIBUTE MSG     30600019
         B     TSTLNO                   GO TO LINE NUMBER TEST          30690019
TSTATEXT DS    0H                                                       30780019
         TM    DIRATTRL,DIRATEXT        TEST FOR TEXT ATTRIBUTE         30870019
         BC    NOT,TSTADLST             IF NOT GO TO NEXT TEST          30960019
         MVC   LDSATYPE,LBLATEXT        POSITION TEXT ATTRIBUTE         31050019
         B     TSTLNO                   GO TO LINE NUMBER TEST          31140019
TSTADLST DS    0H                                                       31230019
         TM    DIRATTRL,DIRADLST        TEST FOR DSLIST ATTRIBUTE       31320019
         BC    NOT,TSTACLST             IF NOT GO TO NEXT TEST          31410019
         MVC   LDSATYPE,LBLADLST        POSITION DSLIST ATTRIBUTE MSG   31500019
         B     TSTLNO                   GO TO LINE NUMBER TEST          31590019
TSTACLST DS    0H                                                       31680019
         TM    DIRATTRL,DIRACLST        TEST FOR CLIST ATTRIBUTE        31770019
         BC    NOT,TSTPL1               IF NOT GO TO NEXT TEST          31860019
         MVC   LDSATYPE,LBLACLST        POSITION CLIST ATTRIBUTE MSG    31950019
         B     TSTLNO                   GO TO LINE NUMBER TEST          32040019
TSTPL1   DS    0H                                                       32130019
         TM    DIRATTRL,DIRPL1          TEST FOR PL/1 ATTRIBUTE         32220019
         BC    NOT,TSTFORTE             IF NOT GO TO NEXT TEST          32310019
         MVC   LDSATYPE,LBLPL1          POSITION CLIST ATTRIBUTE MSG    32400019
         B     TSTLNO                   GO TO LINE NUMBER TEST          32490019
TSTFORTE DS    0H                                                       32580019
         TM    DIRATTRL,DIRFORTE        TEST FOR FORTRAN-E ATTRIBUTE    32670019
         BC    NOT,TSTLNO               IF NOT GO TO NEXT TEST          32760019
         MVC   LDSATYPE,LBLFORTE        POSITION FORTRAN-E ATTRIBUTE    32850019
         B     TSTLNO                   GO TO LINE NUMBER TEST          32940019
         EJECT                                                          33030019
***********************************                                     33120019
*                                                                       33210019
* TEST FOR LINE NUMBER ATTRIBUTES                                       33300019
*                                                                       33390019
***********************************                                     33480019
 SPACE                                                                  33570019
TSTLNO   DS    0H                                                       33660019
         TM    DIRATTRO,DIROLNO         TEST FOR LINE NUMBER ATTRIBUTE  33750019
         BC    OFF,NOLNO                IF NOT INDICATE NO LINE NUMBERS 33840019
         MVC   LDSLNO,LBLYES            POSITION YES FOR LINE NUMBERS   33930019
         B     STATUS                   GO TO STATUS CHECK              34020019
NOLNO    DS    0H                                                       34110019
         MVC   LDSLNO,LBLNO             POSITION NO FOR LINE NUMBERS    34200019
         B     STATUS                   GO TO STATUS CHECK              34290019
         EJECT                                                          34380019
***********************************                                     34470019
*                                                                       34560019
* TEST FOR STATUS AND/OR HISTORY INFORMATION REQUESTED                  34650019
*                                                                       34740019
***********************************                                     34830019
 SPACE                                                                  34920019
STATUS   DS    0H                                                       35010019
         TM    PPTFLG,STATSFLG          TEST FOR STATUS OPERAND         35100019
         BC    OFF,HISTORY              IF NOT GO TO HISTORY CHECK      35190019
         LH    GENLREG,DIRNOBLK         OBTAIN BLOCK COUNT OF DATA SET  35280019
         CVD   GENLREG,PPTWD0(PPTPT)    CHANGE BINARY COUNT TO DIGETS   35370019
         UNPK  LDSBLKS,PPTWD1(WDLNG,PPTPT)   CHANGE DIGETS TO ZONE NUMS 35460019
         OI    LDSBLKS+5,NUMZONE        CHANGE SIGN TO NUMERIC ZONE     35550019
         CLC   DIRKEY,DBLWDBLK          TEST FOR PRESENTS OF KEY        35640019
         BC    EQUAL,NOKEY              IF BLANK INDICATE NO KEY        35730019
         MVC   LDSKEY,LBLYES            POSITION YES KEY MSG            35820019
         B     HISTORY                  GO TO HISTORY CHECK             35910019
NOKEY    MVC   LDSKEY,LBLNO             POSITION NO KEY MSG             36000019
         B     HISTORY                  GO TO HISTORY CHECK             36090019
HISTORY  DS    0H                                                       36180019
         TM    PPTFLG,HSTRYFLG          CHECK FOR HISTORY OPERAND       36270019
         BC    OFF,INSERTLN             IF NOT GO TO INSERT LINE        36360019
         UNPK  LDSCRE,DIRCRE            POSITION CREATION DATE          36450019
         OI    LDSCRE+5,NUMZONE         CHANGE SIGN TO NUMERIC ZONE     36540019
         MVC   LDSCRE(2),LDSCRE+1       SEPERATE YEAR AND DAY           36630019
         MVC   LDSCRE+2(1),PERIOD       INSERT PERIOD IN DATE           36720019
         UNPK  LDSMODAT,DIRMODAT        POSITION DATE LAST MODIFIED     36810019
         OI    LDSMODAT+5,NUMZONE       CHANGE SIGN TO NUMERIC ZONE     36900019
         MVC   LDSMODAT(2),LDSMODAT+1   SEPARATE YEAR AND DATE          36990019
         MVC   LDSMODAT+2(1),PERIOD     INSERT PERIOD IN DATE           37080019
         LH    GENLREG,DIRREAD          OBTAIN BINARY COUNT OF TIMES RD 37170019
         CVD   GENLREG,PPTWD0(PPTPT)    CHANGE BINARY COUNT TO DECIMAL  37260019
         UNPK  LDSREAD,PPTWD1(WDLNG,PPTPT)   CHANGE TO ZONE DECIMAL     37350019
         OI    LDSREAD+5,NUMZONE        CHANGE SIGN TO ZONE IN LAST DGT 37440019
         B     INSERTLN                 INSERT LINE INTO ACTIVE AREA    37530019
 EJECT                                                                  37620019
***********************************                                     37710019
*                                                                       37800019
* DSNAME = ACTIVE, ATTRIBUTES SET TO *                                  37890019
*                                                                       37980019
***********************************                                     38070019
 SPACE                                                                  38160019
ACTIVELN DS    0H                                                       38250019
         MVI   LDSATYPE,ASTRIX          INSERT * IN LINE                38340019
         MVC   LDSATYPE+1(LDSLNEND-LDSATYPE),LDSATYPE      LINE OF *'S  38430019
 SPACE 2                                                                38520019
***********************************                                     38610019
*                                                                       38700019
* INSERT LINE INTO ACTIVE AREA FOR LISTING                              38790019
*                                                                       38880019
***********************************                                     38970019
 SPACE                                                                  39060019
INSERTLN DS    0H                                                       39150019
         BAL   INNERBR,PTINSERT         INSERT LINE INTO ACTIVE AREA    39240019
         CLI   PPTCMD,CMDLDS            TEST FOR LDS COMMAND            39330019
         BC    EQUAL,RTRNLIST           IF LDS, RETURN TO LIST LINE     39420019
         OI    PPTFLG,INSRTFLG          IF LIB, SET INSERT-MADE FLAG    39510019
         NI    DIRUILEN,CNTONLY         ZERO BITS TO LEAVE ONLY THE CNT 39600019
         SR    R3,R3                    ZERO REGISTER                   39690019
         IC    R3,DIRUILEN              OBTAIN USER INFO LENGTH COUNT   39780019
         AR    R3,R3                    DOUBLE HALFWORD TO BYTE COUNT   39870019
         LA    DIRDISP,DIRCRE-DIRFNAME(R3,DIRDISP)     UPDATE DISPLACMT 39960019
         DROP  SFBUFFAD                                                 40050019
         B     LIBLINE                  RETURN FOR NEXT DIR             40140019
         EJECT                                                          40230019
***********************************                                     40320019
*                                                                       40410019
* SUBROUTINE TO FREE THE READ BUFFER AREA                               40500019
*                                                                       40590019
***********************************                                     40680019
 SPACE                                                                  40770019
FREEMAIN DS    0H                                                       40860019
         L     R1,SFBUFF1                                               40950019
         LM    0,1,0(1)                                                 41040019
         FREEMAIN R,LV=(0),A=(1)   FREE THE READ AREA                   41130019
         BR    INNERBR                                                  41220019
         SPACE 3                                                        41310019
***********************************                                     41400019
*                                                                       41490019
* SUBROUTINE TO MOVE DSNAME INTO TUB BPAM FILE NAME FIELD               41580019
*                                                                       41670019
***********************************                                     41760019
 SPACE                                                                  41850019
LOADDSNM DS    0H                                                       41940019
         MVC   TUBPMFNM(0),PPTPARS+1    MOVE DSNAME INTO TUB BPAM FLD   42030019
         EJECT                                                          42120019
***********************************                                     42210019
*                                                                       42300019
* POINT TO NEXT LINE SPACE IN ACTIVE AREA                               42390019
*                                                                       42480019
***********************************                                     42570019
 SPACE                                                                  42660019
PTINSERT DS    0H                                                       42750019
         TM    TUBFLG1,TUBMID           TEST FOR MESSAGE ID REQUESTED   42840019
         BC    ON,PTLAST                                                42930019
         MVC   8(LDSBUFSZ,USRBUFAD),LDSDSNAM-1                          43020019
PTLAST   DS    0H                                                       43110019
         LA    PARAMPT,PTTUBPT(SAVEPT)                                  43200019
         RPOINT A,NR,KEY=LAST                                           43290019
         B     *+4(RETREG)                                              43380019
         B     INSERT                                                   43470019
         B     ERRSPACE                                                 43560019
         B     RETURN                   GETMAIN ERROR                   43650019
         B     RETURN                   I/O ERROR                       43740019
INSERT   DS    0H                                                       43830019
         TM    TUBFLG1,TUBMID           TEST FOR MESSAGE ID REQUESTED   43920019
         BC    ON,INSERT2                                               44010019
         LR    LDSBUFAD,USRBUFAD                                        44100019
INSERT2  DS    0H                                                       44190019
         TM    PPTFLG,HSTRYFLG          TEST FOR HISTORY REQUESTED      44280019
         BC    ON,CHKSTATS              IF HISTORY, CHECK STATUS        44370019
         MVI   LDSCRE,BLANK             INSERT A BLANK CHARACTER        44460019
         MVC   LDSCRE+1(HSTRYLNG),LDSCRE     NO HISTORY, BLANK AREA     44550019
CHKSTATS DS    0H                                                       44640019
         TM    PPTFLG,STATSFLG          TEST FOR STATUS REQUESTED       44730019
         BC    ON,INSERT1               IF STATUS, PROCEED TO INSERT    44820019
         MVI   LDSBLKS,BLANK            INSERT A BLANK CHARACTER        44910019
         MVC   LDSBLKS+1(STATSLNG),LDSBLKS   NO STATUS, BLANK AREA      45000019
         TM    PPTFLG,HSTRYFLG          TEST FOR HISTORY REQUESTED      45090019
         BC    OFF,INSERT1              NO HISTORY, PROCEED TO INSERT   45180019
         MVC   LDSBLKS(HSTRYLNG),LDSCRE MOVE HISTORY INTO STATUS AREA   45270019
         MVI   LDSMODAT+3,BLANK                                         45360019
         MVC   LDSMODAT+4(LASTOFH),LDSMODAT+3     BLANK LAST OF HISTORY 45450019
 EJECT                                                                  45540019
***********************************                                     45630019
*                                                                       45720019
* INSERT LINE INTO ACTIVE AREA                                          45810019
*                                                                       45900019
***********************************                                     45990019
 SPACE                                                                  46080019
INSERT1  DS    0H                                                       46170019
         MVI   71(LDSBUFAD),BLANK                                       46260019
         MVC   72(8,LDSBUFAD),71(LDSBUFAD)                              46350019
         ST    USRBUFAD,TUBRAFBF        PROVIDE POINTER TO USER BUFFER  46440019
         LA    PARAMPT,LINLNG                                           46530019
         ST    PARAMPT,0(USRBUFAD)      PROVIDE LINE LENGTH COUNT       46620019
         ST    USRBUFAD,4(USRBUFAD)     PROVIDE POINTER TO USER BUFFER  46710019
         OI    TUBAFISW,TUBFCTLN        SET SAVE-THE-BUFFER FLAG ON     46800019
         LA    PARAMPT,PTTUBPT(SAVEPT)  PROVIDE POINTER TO TUB PTR      46890019
         INSERT S,A                     INSERT LINE INTO ACTIVE AREA    46980019
         NI    TUBAFISW,TUBFCTLF        SET SAVE-THE-BUFFER FLAG OFF    47070019
         B     *+4(RETREG)              EVALUATE RETURN CODE            47160019
         B     0(INNERBR)               NO ERROR, RETURN TO CALLING RTN 47250019
         B     ERRSPACE                 OUT OF SPACE ERRIO              47340019
         B     RETURN                   GETMAIN ERROR                   47430019
         B     RETURN                   I/O ERROR                       47520019
         EJECT                                                          47610019
***********************************                                     47700019
*                                                                       47790019
* ADVANCE PPT OPERAND POINTER TO                                        47880019
* NEXT OPERAND AND TEST FOR LAST                                        47970019
*                                                                       48060019
***********************************                                     48150019
 SPACE                                                                  48240019
NEXTTEST DS    0H                                                       48330019
         XR    OPNDINCR,OPNDINCR   CLEAR INCREMENT REGISTER             48420019
         NI    0(OPNDPT),INCRONLY  ISOLATE INCREMENT OF OPND COUNT      48510019
         IC    OPNDINCR,0(OPNDPT)  OBTAIN LENGTH OF PARAMETER FIELD     48600019
         LA    OPNDPT,INCR(OPNDINCR,OPNDPT)  ADVANCE POINTER TO NEXT    48690019
FRSTTEST DS    0H                                                       48780019
         LA    OPNDCTR,INCR(OPNDCTR)         ADVANCE COUNTER OF OPNDS   48870019
RETEST   DS    0H                                                       48960019
         TM    0(OPNDPT),LASTOPND  TEST FOR LAST OPERAND IN PPT CHAIN   49050019
         BC    NOTONES,4(INNERBR)  IF OPERAND PRESENT, RETURN           49140019
         L     PPTESTRG,PPTCHAD    OBTAIN ADDR FLD OF NEXT PPT IN CHAIN 49230019
         LA    PPTESTRG,0(PPTESTRG)                                     49320019
         LTR   PPTESTRG,PPTESTRG   TEST FOR PRESENTS OF ADDRESS         49410019
         BCR   ZEROS,INNERBR       IF OPND NOT PRESENT, RETURN TO TEST  49500019
         OC    0(1,PPTESTRG),0(PPTPT)   MOVE FLAGS TO THE NEXT PPT      49590019
         LR    PPTPT,PPTESTRG      CHANGE POINTER TO NEXT PPT           49680019
         LA    OPNDPT,PPTPARS      REINITIALIZE OPERAND POINTER         49770019
         B     RETEST              TEST AGAIN FOR OPERAND IN NEW PPT    49860019
*                                                                       49950019
         EJECT                                                          50040019
***********************************                                     50130019
*                                                                       50220019
* INVALID OPERAND ERROR                                                 50310019
*                                                                       50400019
***********************************                                     50490019
 SPACE                                                                  50580019
ERROPND  DS    0H                                                       50670019
         BAL   INNERBR,MSGNSRT          PREPARE INSERT FOR MESSAGE      50760019
         LA    MSGCODE,MSGOPND          POINT TO OPERAND ERROR MSG CODE 50850019
         BAL   INNERBR,CALLMSG1         WRITE OPERAND ERROR MESSAGE     50940019
         STC   GENLREG,0(OPNDPT)        RESTORE OPERAND LENGTH          51030019
         B     MSGEXIT2                                                 51120019
         SPACE 2                                                        51210019
***********************************                                     51300019
*                                                                       51390019
* MULTI OR CONTRA OPERAND ERROR                                         51480019
*                                                                       51570019
***********************************                                     51660019
 SPACE                                                                  51750019
ERRMULTI DS    0H                                                       51840019
         BAL   INNERBR,MSGNSRT1         INSERT OFFENDING OPND INTO MSG  51930019
         LA    MSGCODE,MSGMULTI         PROVIDE CODE FOR MULTI OPND ERR 52020019
         BAL   INNERBR,CALLMSG1         SEND MSG TO USER                52110019
MSGEXIT2 OI    PPTFLG,ERRORSW           SET OPERAND ERROR SWITCH        52200019
         B     CHKNXTOP                 CHECK NEXT OPERAND              52290019
         SPACE 2                                                        52380019
***********************************                                     52470019
*                                                                       52560019
* EXCESSIVE OPERAND ERROR                                               52650019
*                                                                       52740019
***********************************                                     52830019
 SPACE                                                                  52920019
ERREXCSS DS    0H                                                       53010019
         BAL   INNERBR,MSGNSRT          PREPARE INSERT FOR MESSAGE      53100019
         LA    MSGCODE,MSGEXCS          POINT TO EXCESS OPERAND MSG CD  53190019
         B     MSGEXIT                  SEND MESSAGE AND EXIT, CD 0     53280019
 EJECT                                                                  53370019
***********************************                                     53460019
*                                                                       53550019
* INVALID DSNAME ERROR                                                  53640019
*                                                                       53730019
***********************************                                     53820019
 SPACE                                                                  53910019
ERRNODSN DS    0H                                                       54000019
         LA    OPNDPT,DSNAME                                            54090019
         BAL   INNERBR,MSGNSRT1    INSERT DSNAME INTO MESSAGE           54180019
         LA    MSGCODE,MSGNODSN    PROVIDE MESSAGE CODE FOR NO DSNAME   54270019
         B     MSGEXIT             SEND MESSAGE AND EXIT WITH CODE OF 0 54360019
         SPACE 2                                                        54450019
***********************************                                     54540019
*                                                                       54630019
* NO DSNAME ERROR                                                       54720019
*                                                                       54810019
***********************************                                     54900019
 SPACE                                                                  54990019
ERRNODS  DS    0H                                                       55080019
         CLI   PPTCMD,CMDLDS       TEST FOR LISTDS COMMAND              55170019
         BC    NOTEQUAL,ERRDD      IF NOT LISTDS, INDICATE NO LIBRARY   55260019
         LA    MSGCODE,MSGNODS     PROVIDE MSG CODE FOR DATA SET NOT FD 55350019
         B     MSGEXIT             SEND MESSAGE AND EXIT WITH CODE OF 0 55440019
         SPACE 2                                                        55530019
***********************************                                     55620019
*                                                                       56610019
* NO DDNAME OR NO LIBRARY ERROR                                         56700019
*                                                                       56790019
***********************************                                     56880019
 SPACE                                                                  56970019
ERRDD    DS    0H                                                       57060019
         LA    MSGCODE,MSGDD       POINT TO CODE FOR NO DDNAME GIVEN    57150019
         B     MSGEXIT                                                  57240019
 EJECT                                                                  57330019
***********************************                                     57420019
*                                                                       57510019
* LIBRARY EMPTY ERROR                                                   57600019
*                                                                       57690019
***********************************                                     57780019
 SPACE                                                                  57870019
ERRLIBEM DS    0H                                                       57960019
         LA    MSGCODE,MSGLIBEM    PROVIDE MSG CODE FOR LIBRARY EMPTY   58050019
         B     MSGEXIT             SEND MESSAGE AND EXIT WITH CODE OF 0 58140019
         SPACE 2                                                        58230019
***********************************                                     58320019
*                                                                       58410019
* OUT OF SPACE ERROR                                                    58500019
*                                                                       58590019
***********************************                                     58680019
 SPACE                                                                  58770019
ERRSPACE DS    0H                                                       58860019
         LA    MSGCODE,MSGSPACE    PROVIDE MESSAGE CODE FOR OUT OF SPC  58950019
         BAL   INNERBR,CALLMSG1    SEND MESSAGE TO USER                 59040019
         LA    R15,SPACEERR        SET RETURN CODE                      59130019
         B     RETURN                                                   59220019
 EJECT                                                                  59310019
***********************************                                     59400019
*                                                                       59490019
* LIBRARY I/O ERROR                                                     59580019
*                                                                       59670019
***********************************                                     59760019
 SPACE                                                                  59850019
LIBIOERR DS    0H                                                       59940019
         LA    PARMREG,UTMCODE1    PROVIDE UTM CODE FOR LIB INOPERATIVE 60030019
         ST    PARMREG,TUBPARM2                                         60120019
         BAL   INNERBR,CALLUTM     FLAG LIBRARY AS INOPERATIVE          60210019
         XR    PARMREG,PARMREG                                          60300019
         ST    PARMREG,TUBPARM2    INDICATE MSG FOR CENTRAL OPERATOR    60390019
         LA    MSGCODE,MSGLIBER                                         60480019
         ST    MSGCODE,TUBPARM3    PROVIDE CODE FOR LIB IN ERROR        60570019
         L     USRBUFAD,TUBUFFAD                                        60660019
         USING TEXTNSRT,USRBUFAD   USE USER BUFFER FOR MSG INSERTS      60750019
         MVI   TEXT1LNG,LNG8       SET LENGTH FOR DDNAME INSERT         60840019
         MVC   TEXT1TXT,PPTWD2     PROVIDE DDNAME AS INSERT             60930019
         MVI   TEXT2LNG,LNG8       SET LENGTH FOR USERID INSERT         61020019
         MVC   TEXT2TXT,TUBUSRID   PROVIDE USERID AS INSERT             61110019
         LA    PARMREG,TEXT1                                            61200019
         ST    PARMREG,TUBPARM4    PROVIDE ADDRESS OF DDNAME            61290019
         LA    PARMREG,TEXT2                                            61380019
         ST    PARMREG,TUBPARM5    PROVIDE ADDRESS OF USERID            61470019
         DROP  USRBUFAD                                                 61560019
         BAL   INNERBR,CALLMSG0    SEND LIBRARY ERROR MSG TO CENTRAL    61650019
         SPACE 2                                                        61740019
ERRLIBNO DS    0H                                                       61830019
         LA    MSGCODE,MSGLIBNO    PROVIDE MSG CODE FOR LIBRARY INOP    61920019
         SPACE 2                                                        62010019
MSGEXIT  DS    0H                                                       62100019
         BAL   INNERBR,CALLMSG1    SEND MESSAGE TO USER                 62190019
RETURN0  DS    0H                                                       62280019
         XR    R15,R15             SET RETURN CODE                      62370019
         B     RETURN                                                   62460019
 EJECT                                                                  62550019
***********************************                                     62640019
*                                                                       62730019
* CALL TO MESSAGE WRITER ROUTINE                                        62820019
*                                                                       62910019
***********************************                                     63000019
 SPACE                                                                  63090019
CALLMSG  DS    0H                                                       63180019
         ST    MSGCODE,TUBPARM3         PROVIDE POINTER TO MESSAGE CODE 63270019
         MVI   TUBPARM3,MX80            SET LAST OPND FLAG              63360019
         ST    TUBPT,TUBPARM2           PROVIDE POINTER TO TUB          63450019
CALLMSG0 DS    0H                                                       63540019
         L     OUTERBR,IHKYYMSG         OBTAIN ADDRESS OF MESSAGE WRTR  63630019
         B     MSGWTR                   GO TO MESSAGE WRITER            63720019
         SPACE 1                                                        63810019
CALLMSG1 DS    0H                                                       63900019
         ST    MSGCODE,TUBPARM3         PROVIDE POINTER TO MESSAGE CODE 63990019
         MVC   TUBPARM3(1),0(MSGCODE)   SET LAST OPND FLAG IF APROPRIAT 64080019
         LA    MSGCODE,TUBUSRID         OBTAIN ADDRESS OF USER ID       64170019
         ST    MSGCODE,TUBPARM2         PROVIDE POINTER TO USERID       64260019
         L     OUTERBR,IHKYMSG1         OBTAIN ADDRESS OF MESSAGE WTR1  64350019
         SPACE 1                                                        64440019
MSGWTR   DS    0H                                                       64530019
         ST    TUBPT,TUBPARM1           PROVIDE POINTER TO TUB          64620019
         LA    PARAMPT,TUBPRMLS         PROVIDE POINTER TO PARAMETERS   64710019
         BALR  RETADDR,OUTERBR          GO TO MESSAGE WRITER            64800019
         LTR   RETREG,RETREG            TEST FOR ZERO RETURN CODE       64890019
         BZ    0(INNERBR)               ZERO RETURN, RETURN TO CALL PT  64980019
         B     RETURN                   EXIT PROCESSOR                  65070019
         SPACE 2                                                        65160019
***********************************                                     65250019
*                                                                       65340019
* INSERT INTO MESSAGE ROUTINE                                           65430019
*                                                                       65520019
***********************************                                     65610019
 SPACE                                                                  65700019
MSGNSRT  DS    0H                                                       65790019
         NI    0(OPNDPT),INCRONLY       ISOLATE OPERAND LENGTH          65880019
         IC    GENLREG,0(OPNDPT)        OBTAIN OPERAND LENGTH           65970019
         CLI   0(OPNDPT),MAXINSRT       TEST FOR MAXIMUM LENGTH         66060019
         BNH   MSGNSRT1                 IF NO EXCESSIVE, PROCEED        66150019
         MVI   0(OPNDPT),MAXINSRT       IF EXCESSIVE, REPLACE WITH MAX  66240019
MSGNSRT1 DS    0H                                                       66330019
         ST    OPNDPT,TUBPARM4          PROVIDE POINTER TO OPERAND      66420019
         OI    TUBPARM4,MX80            SET LAST OPERAND FLAG           66510019
         BR    INNERBR                  RETURN TO CALLING ROUTINE       66600019
         EJECT                                                          66690019
***********************************                                     66780019
*                                                                       66870019
* RETURN CODES                                                          66960019
*                                                                       67050019
***********************************                                     67140019
 SPACE                                                                  67230019
RTRNLIST DS    0H                                                       67320019
         L     RETCODE,TUBPPTAD    OBTAIN ADDRESS OF FIRST PPT          67410019
         DROP  PPTPT                                                    67500019
         USING PPTDSECT,RETCODE                                         67590019
         MVI   PPTPARS,LDSCODE     SET LINK CODE FOR LIST               67680019
         DROP  RETCODE                                                  67770019
         USING PPTDSECT,PPTPT                                           67860019
         LA    RETCODE,CMDLST      LOAD CODE FOR LIST PROCESSOR         67950019
         LNR   RETCODE,RETCODE                                          68040019
         B     RETURN2                                                  68130019
 SPACE                                                                  68220019
RETURN   DS    0H                                                       68310019
         TM    PPTFLG,CREATFLG     TEST FOR NEED OF RELEASE             68400019
         BZ    RETURN1             NO ACTIVE AREA, NO RELEASE           68490019
         LR    RETCODE,R15         SAVE RETURN CODE                     68580019
         LA    PARAMPT,PTTUBPT(SAVEPT)  PROVIDE POINTER TO TUB POINTER  68670019
         RELEASE A                                                      68760019
         B     *+4(R15)            EVALUATE RETURN CODE                 68850019
         B     RETURN2             NO ERRORS                            68940019
         B     RETURN2             NOT USED                             69030019
         BAL   R14,CHKFOR12        GETMAIN FAILURE                      69120019
RETURN1  DS    0H                                                       69210019
         LR    RETCODE,R15         I/O ERROR                            69300019
RETURN2  DS    0H                                                       69390019
         TM    PPTFLG,NDUPFLAG     TST FOR NEED OF ENDUP                69480019
         BC    OFF,CLOSE           IF ENDUP NOT NEEDED, TEST CLOSE      69570019
         LA    PARAMPT,PTTUBPT(SAVEPT)  PROVIDE POINTER TO TUB POINTER  69660019
         ENDUP                                                          69750019
         B     *+4(R15)            EVALUATE RETURN CODE                 69840019
         B     CLOSE               NO ERRORS                            69930019
         B     CLOSE                                                    70020019
         BAL   R14,CHKFOR12        GETMAIN FAILURE                      70110019
         LR    RETCODE,R15         I/O ERROR                            70200019
 EJECT                                                                  70290019
***********************************                                     70380019
*                                                                       70470019
* EXIT PROCEDURE                                                        70560019
*                                                                       70650019
***********************************                                     70740019
 SPACE                                                                  70830019
CLOSE    DS    0H                                                       70920019
         TM    PPTFLG,CLOSFLAG                                          71010019
         BC    OFF,FREENEED        IF NO RCLOSE NEEDED, PROCEED TO EXIT 71100019
         LA    PARAMPT,PTTUBPT(SAVEPT)  PROVIDE POINTER TO TUB POINTER  71190019
         RCLOSE     NOSTOW                                              71280019
         B     *+4(R15)            EVALUATE RETURN CODE                 71370019
         B     FREENEED            NO ERRORS                            71460019
         B     FREENEED                                                 71550019
         BAL   R14,CHKFOR12        GETMAIN FAILURE                      71640019
         LR    RETCODE,R15         I/O ERROR                            71730019
         NOPR  R14                                                      71820019
         SPACE  4                                                       71910019
FREENEED DS    0H                                                       72000019
         L     R11,CALLNGSA(SAVEPT)     LOAD ADDRESS OF CALLING SAVE AR 72090019
         FREEMAIN   R,LV=NEED,A=(SAVEPT)                                72180019
         LR    SAVEPT,R11               RESTORE CALLING SAVE AREA TO 13 72270019
         ST    RETCODE,RTRNCODE(SAVEPT) POSITION RETURN CODE            72360019
         RETURN (14,12),T          RETURN TO LINE ADMINISTRATOR         72450019
         SPACE 2                                                        72540019
         SPACE 2                                                        72630019
CHKFOR12 DS    0H                                                       72720019
         CH    RETCODE,AAIOFAIL    TEST FOR PREVIOUS I/O ERROR          72810019
         BCR   NOTEQUAL,R14        IF NOT, SET NEW RETURN CODE          72900019
         LA    R14,2(R14)          SET ADDRESS TO RETAIN I/O ERR CODE   72990019
         BR    R14                 BYPASS SETING NEW RTRN CODE          73080019
         EJECT                                                          73170019
***********************************                                     73260019
*                                                                       73350019
*        EQUATES                                                        73440019
*                                                                       73530019
***********************************                                     73620019
 SPACE 2                                                                73710019
NOERROR  EQU   0                   RETURN CODE FOR NO ERRORS            73800019
LINEERR  EQU   4                   RETURN CODE FOR LINE ERROR           73890019
GTMNFAIL EQU   8                   RETURN CODE FOR GETMAIN FAILURE      73980019
SPACEERR EQU   20                  RETURN CODE FOR OUT OF SPACE         74070019
 SPACE                                                                  74160019
HIGH     EQU   2                   CONDITION CODE FOR COMPARE INST      74250019
LOW      EQU   4                   CONDITION CODE FOR COMPARE INST      74340019
EQUAL    EQU   8                   CONDITION CODE FOR COMPARE INST      74430019
NOTEQUAL EQU   7                   CONDITION CODE FOR COMPARE INST      74520019
NOTHIGH  EQU   13                  CONDITION CODE FOR COMPARE INST      74610019
NOTLOW   EQU   11                  CONDITION CODE FOR COMPARE INST      74700019
         SPACE 1                                                        74790019
ONES     EQU   1                   CONDITION CODE FOR TEST UNDER MASK   74880019
MIXED    EQU   4                   CONDITION CODE FOR TEST UNDER MASK   74970019
ZEROS    EQU   8                   CONDITION CODE FOR TEST UNDER MASK   75060019
NOTONES  EQU   14                  CONDITION CODE FOR TEST UNDER MASK   75150019
NOT      EQU   14                  CONDITION CODE FOR TEST UNDER MASK   75240019
         SPACE 1                                                        75330019
ON       EQU   1                   CONDITION CODE FOR TESTING SW/FLAGS  75420019
OFF      EQU   8                   CONDITION CODE FOR TESTING SW/FLAGS  75510019
         SPACE 2                                                        75600019
CREATFLG EQU   X'01'               FLAG FOR RELEASE NEEDED              75690019
ERRORSW  EQU   X'02'               FLAG FOR OPERAND ERROR               75780019
NDUPFLAG EQU   X'04'               FLAG FOR ENDUP NEEDED                75870019
CLOSFLAG EQU   X'08'               FLAG FOR RCLOSE NEEDED               75960019
STATSFLG EQU   X'40'               FLAG FOR HISTORY OPERAND             76050019
HSTRYFLG EQU   X'20'               FLAG FOR STATUS OPERAND              76140019
INSRTFLG EQU   X'10'               FLAG FOR INSERT PREFORMED            76230019
         EJECT                                                          76320019
PPTWD0   EQU   8                   DISPLACEMENT OF STG WD 0 IN PPT      76410019
PPTWD1   EQU   12                  DISPLACEMENT OF STG WD 1 IN PPT      76500019
PPTWD2   EQU   16                  DISPLACEMENT OF STG WD 2 IN PPT      76590019
PPTWD3   EQU   20                  DISPLACEMENT OF STG WD 3 IN PPT      76680019
PPTWD4   EQU   24                  DISPLACEMENT OF STG WD 4 IN PPT      76770019
PPTWD5   EQU   28                  DISPLACEMENT OF STG WD 5 IN PPT      76860019
         SPACE 1                                                        76950019
WD1DISPL EQU   0                   DISPLACEMENT OF WORD 1 IN PARAM LIST 77040019
WD2DISPL EQU   4                   DISPLACEMENT OF WORD 2 IN PARAM LIST 77130019
WD3DISPL EQU   8                   DISPLACEMENT OF WORD 3 IN PARAM LIST 77220019
WD4DISPL EQU   12                  DISPLACEMENT OF WORD 4 IN PARAM LIST 77310019
         SPACE 1                                                        77400019
LGNALLOC EQU   0                   DISPLACEMENT FOR LENGTH ALLOCATION   77490019
CALLNGSA EQU   4                   DISPLACEMENT FOR CALLING SAVE AREA   77580019
CALLEDSA EQU   8                   DISPLACEMENT FOR CALLED SAVE AREA    77670019
RETURNPT EQU   12                  DISPLACEMENT FOR RETURN POINTER      77760019
ENTRYPT  EQU   16                  DISPLACEMENT FOR ENTRY POINTER       77850019
RTRNCODE EQU   16                  DISPLACEMENT FOR RETURN CODE IN SAVE 77940019
SAVEREGS EQU   20                  DISPLACEMENT FOR REGISTERS SAVED     78030019
         EJECT                                                          78120019
INCR     EQU   1                   INCREMENTAL VALUE                    78210019
EXCSOPND EQU   2                   EXCESSIVE OPERAND COUNT              78300019
MAXINSRT EQU   10                  MAXIMUM CHARACTER COUNT FOR INS)RT   78390019
PTTUBPT  EQU   64                  DISPLACEMENT OF POINTER TO TUB PT    78480019
NEED     EQU   72                  NEEDED SPACE FOR SAVE AREA           78570019
 SPACE                                                                  78660019
LDSBUFSZ EQU   80                  SIZE OF LDS BUFFER                   78750019
USRBUFSZ EQU   132                 SIZE OF USER BUFFER                  78840019
SFBUFFSZ EQU   880                 SIZE OF DIR BUFFER                   78930019
 SPACE                                                                  79020019
WDLNG    EQU   4                   LENGTH OF WORD IN BYTES              79110019
LNG8     EQU   8                   LENGTH OF DDNAME AND USERID          79200019
DSNMLNG  EQU   8                   LENGTH OF DSNAME                     79290019
BYTELNG  EQU   8                   LENGTH OF BYTE IN BITS               79380019
DBLWDLNG EQU   8                   LENGTH OF DOUBLE WORD IN BYTES       79470019
LINLNG   EQU   88                  LENGTH OF INSERT LINE                79560019
LNGLNG   EQU   2                   LENGTH OF DIR. LENGTH FIELD IN BYTES 79650019
STATSLNG EQU   12                  LENGTH OF STATUS AREA                79740019
HSTRYLNG EQU   25                  LENGTH OF HISTORY AREA               79830019
LASTOFH  EQU   13                  LENGTH OF LAST OF HISTORY TO BLANK   79920019
         SPACE 1                                                        80010019
CNTONLY  EQU   B'00011111'                                              80100019
         SPACE 1                                                        80190019
ALPHAA   EQU   X'C1'               MASK FOR 'A' CHARACTER TEST          80280019
ALPHAZ   EQU   X'E9'               MASK FOR 'Z' CHARACTER TEST          80370019
ALPHA@   EQU   C'@'                                             OS61492 80390028
ALPHA#   EQU   C'#'                                             OS61492 80410028
ALPHA$   EQU   C'$'                                             OS61492 80430028
 SPACE                                                                  80460019
INCRONLY EQU   X'3F'               MASK USED TO ISOLATE OPERAND COUNT   80550019
NUMZONE  EQU   X'F0'               MASK USED TO TEST NUMERIC ZONE       80640019
BLANK    EQU   X'40'                                                    80730019
ASTRIX   EQU   X'5C'               * CHARACTER                          80820019
MX80     EQU   X'80'                                                    80910019
LDSCODE  EQU   X'BD'               CODE FOR LINKAGE TO LIST             81000019
LASTOPND EQU   X'FF'               MASK FOR TESTING FOR LAST OPERAND    81090019
 EJECT                                                                  81180019
***********************************                                     81270019
*                                                                       81360019
*        CONSTANTS                                                      81450019
*                                                                       81540019
***********************************                                     81630019
 SPACE                                                                  81720019
LBLNO    DC    C'NO '        LABEL NO                                   81810019
LBLYES   DC    C'YES'        LABEL YES                                  81900019
LBLPL1   DC    C'PL/1   '    LABEL PL/1           ATTRIBUTE             81990019
LBLPL148 DC    C'PL/1-48'    LABEL PL/1-48        ATTRIBUTE             82080019
LBLFORTE DC    C'FORT-E '    LABEL FORTRAN-E      ATTRIBUTE             82170019
LBLFORTH DC    C'FORT-H '    LABEL FORTRAN-H      ATTRIBUTES            82260019
LBLFORTG DC    C'FORT-G '    LABEL FORTRAN-G      ATTRIBUTES            82350019
LBLADLST DC    C'DSLIST '    LABEL DS LIST        ATTRIBUTES            82440019
LBLACLST DC    C'CLIST  '    LABEL C  LIST        ATTRIBUTES            82530019
LBLADATA DC    C'DATA   '    LABEL DATA           ATTRIBUTES            82620019
LBLATEXT DC    C'TEXT   '    LABEL TEXT           ATTRIBUTE             82710019
         SPACE 2                                                        82800019
MDLSTAT1 DC    X'01E2'                  MODEL 'S' STATUS OPERAND        82890019
MDLSTAT2 DC    X'06E2E3C1E3E4E2'        MODEL 'STATUS' OPERAND          82980019
MDLHIST1 DC    X'01C8'                  MODEL 'H' HISTORY OPERAND       83070019
MDLHIST2 DC    X'07C8C9E2E3D6D9E8'      MODEL 'HISTORY' OPERAND         83160019
         SPACE 2                                                        83250019
DSNAME   DC    X'06',C'DSNAME'     MESSAGE INSERT FOR REQUIRED OPERAND  83340019
PERIOD   DC    X'4B'               PERIOD                               83430019
UTMCODE  DC    X'80'                                                    83520019
UTMCODE1 DC    X'04'               UTM CODE TO FLAG LIBRARY INOPERATIVE 83610019
DBLWDBLK DC    8X'40'              DOUBLE WORK OF BLANKS                83700019
         SPACE 1                                                        83790019
AAIOFAIL DC    H'12'               MASK FOR TESTING FOR I/O ERRORS      83880019
         SPACE 1                                                        83970019
ACTIVE   DC    C'ACTIVE  '         MASK FOR DETECTING 'ACTIVE' DSNAME   84060019
         EJECT                                                          84150019
***********************************                                     84240019
*                                                                       84330019
*        MESSAGE NUMBER CONSTANTS                                       84420019
*                                                                       84510019
***********************************                                     84600019
 SPACE                                                                  84690019
         CNOP  0,4                                                      84780019
MSGLIBER DC    X'00F2F4F1'         MSG CODE FOR LIBRARY I/O ERROR       84870019
MSGOPND  DC    X'00F3F0F2'         MSG CODE FOR INVALID OPERAND         84960019
MSGNODSN DC    X'00F3F1F7'         MSG CODE FOR REQ'D OPERAND MISSING   85050019
MSGHEADR DC    X'10F3F2F0'         MSG CODE FOR HEADER                  85140019
MSGMULTI DC    X'00F3F2F1'         MSG CODE FOR MULTI OPND ERR MSG      85230019
MSGEXCS  DC    X'00F3F3F4'         MSG CODE FOR EXCESSIVE OPERANDS      85320019
MSGNODS  DC    X'80F3F3F8'         MSG CODE FOR DATA SET NOT FOUND      85410019
MSGSPACE DC    X'80F3F5F7'         MSG CODE FOR ACTIVE AREA OUT OF SPC  85590019
MSGLIBNO DC    X'80F3F7F0'         MSG CODE FOR LIBRARY INOPERATIVE     85680019
MSGDD    DC    X'80F3F7F5'         MSG CODE FOR NO DDNAME OR LIBRARY    85770019
MSGLIBEM DC    X'80F4F0F5'         MSG CODE FOR LIBRARY EMPTY           85860019
         EJECT                                                          85950019
***********************************                                     86040019
*                                                                       86130019
*        DSECTS                                                         86220019
*                                                                       86310019
***********************************                                     86400019
 SPACE                                                                  86490019
LDSDSECT DSECT                                                          86580019
 SPACE                                                                  86670019
         DC    9X'40'        BLANKS                                     86760019
LDSDSNAM DS    CL8           DATA SET FILE NAME                         86850019
         DC    2X'40'        BLANKS                                     86940019
LDSATYPE DS    CL7           TYPE ATTRIBUTE                             87030019
         DC    X'40'         BLANK                                      87120019
LDSLNO   DS    CL3           LINE NUMBER INDICATION                     87210019
         DC    2X'40'        BLANKS                                     87300019
LDSBLKS  DS    CL6           BLOCK COUNT                                87390019
         DC    2X'40'        BLANKS                                     87480019
LDSKEY   DS    CL3           KEY WORK INDICATION                        87570019
         DC    2X'40'        BLANKS                                     87660019
LDSCRE   DS    CL6           CREATION DATE                              87750019
         DC    3X'40'        BLANKS                                     87840019
LDSMODAT DS    CL6           DATE LAST MODIFIED                         87930019
         DC    4X'40'        BLANKS                                     88020019
LDSREAD  DS    CL6           TIMES READ                                 88110019
LDSLNEND DS    0X                                                       88200019
         DC    10X'40'       BLANK                                      88290019
 EJECT                                                                  88380019
TEXTNSRT DSECT                                                          88470019
         SPACE 1                                                        88560019
         DS    CL88                FIELD USER BY MSG WTR                88650019
TEXT1    DS    0C                                                       88740019
TEXT1LNG DS    C                   LENGTH BYTE FOR FIRST TEXT           88830019
TEXT1TXT DS    CL8                 TEXT FIELD OF FIRST TEXT             88920019
TEXT2    DS    0C                                                       89010019
TEXT2LNG DS    C                   LENGTH BYTE FOR SECOND TEXT          89100019
TEXT2TXT DS    CL8                 TEXT FIELD OF SECOND TEXT            89190019
 EJECT                                                                  89280019
         IHKCDSCT   TUB=YES                                             89370019
         IHKCDSCT   PPT=YES                                             89460019
         IHKCDSCT   AVT=YES                                             89550019
         IHKCDSCT   DIR=YES                                             89640019
         RAFKNBX    TYPE=DSECT                                          89730019
         CMDEQU                                                         89820019
         TUBEQU                                                         89910019
         ENTRY IHKLDS                                                   90000019
         END                                                            90090019
