LEW      TITLE 'LINE EDIT WRITE MODULE OR THE BOMBASTIC BLANK BUSTER'   00200019
IHKLEW   CSECT                                                          00400019
         SPACE 2                                                        00600019
*********************************************************************** 00800019
*---------------------------------------------------------------------* 01000019
*-*******************************************************************-* 01200019
*-*                                                                 *-* 01400019
*-*  N A M E --                                                     *-* 01600019
*-*                                                                 *-* 01800019
*-*      IHKLEW -- LINE EDIT WRITE COMPONENT OR THE BOMBASTIC BLANK *-* 02000019
*-*     BUSTER.                                                     *-* 02200019
*-*                                                                 *-* 02400019
*-*                                                                 *-* 02600019
*-*  F U N C T I O N / O P E R A T I O N --                         *-* 02800019
*-*                                                                 *-* 03000019
*-*      THIS FABRICATION PURVEYS THE FUNCTION OF USING USER SPECI- *-* 03200019
*-*     FIED TAB SETTINGS TO SHUN TRANSMISSION OF BOMBASTIC BLANKS. *-* 03400019
*-*     TO DISCHARGE THIS MONUMENTAL EXPLOIT, HORIZONTAL TAB AND    *-* 03600019
*-*     IDLE CHARACTERS ARE JUDICIOUSLY IMPLANTED IN THE OUTPUT     *-* 03800019
*-*     DATA WHENEVER IT IS RESOLVED THE EFFECTED DATA STRING       *-* 04000019
*-*     LENGTH CAN BE EPITOMIZED.  FURTHERMORE, THIS BREVITY MAY    *-* 04200019
*-*     ALSO REQUIRE THE EXPLOITATION OF THE BACK SPACE CHARACTER   *-* 04400019
*-*     (BS) -- NOT TO BE PERVERTED WITH THE WORKING MASSES.        *-* 04600019
*-*                                                                 *-* 04800019
*-*      THERE ARE TWO EVENTS IN WHICH THE INPUT DATA STRING WILL   *-* 05000019
*-*     BE MODIFIED.  THE FIRST, AND PERHAPS EASIER GRASPED OF THE  *-* 05200019
*-*     TWO EPISODES, IS THE CHANCE OF A BLANK STRING PRECEDING A   *-* 05400019
*-*     USER SPECIFIED TAB SETTING.  THERE IS NO ALTERATION OF THE  *-* 05600019
*-*     DATA STRING UNLESS THE BLANK STRING SATISFIES THE SIMPLEST  *-* 05800019
*-*     OF RELATIVE ALGORITHRIMS:                                   *-* 06000019
*-*                                                                 *-* 06200019
*-*         N IS GREATER THAN 3                   (1)               *-* 06400019
*-*            WHERE:                                               *-* 06600019
*-*               N IS THE NUMBER OF BLANKS IN THE BLANK STRING     *-* 06800019
*-*                    PRECEDING THE TAB.                           *-* 07000019
*-*                                                                 *-* 07200019
*-*      IF THE ALGORITHRIM IS SATISFIED, THE TAB AND IDLE CHAR-    *-* 07400019
*-*     ARACTERS ARE IMPLANTED IN THE DATA STRING IN LIEU OF THE    *-* 07600019
*-*     POSITIONS OCCUPIED BY THE BLANK STRING.  THE NUMBER OF IDLE *-* 07800019
*-*     CHARACTERS IMPLANTED, IRRESPECTIVE OF THE EPISODE ENJOYED,  *-* 08000019
*-*     IS COMPUTED USING THE ALGORITHRIM:                          *-* 08200019
*-*                                                                 *-* 08400019
*-*         IDLES = (24+P) --MODULO 10            (2)               *-* 08600019
*-*            WHERE:                                               *-* 08800019
*-*             P IS THE NUMBER OF POSITIONS TO THE TAB USING THE   *-* 09000019
*-*                    FIRST BLANK POSITION AS THE ORIGIN.          *-* 09200019
*-*                                                                 *-* 09400019
*-*      THE HAIR OF THE COMPONENT IS TO BE FOUND IN THE SECOND     *-* 09600019
*-*     EPISODE.  THIS CONDITION PREVAILS WHEN A TAB IS PRECEDED    *-* 09800019
*-*     BY A CHARACTER STRING WHICH IS IN TURN PRECEDED BY A BLANK  *-* 10000019
*-*     STRING.  BEFORE ACTION IS TAKEN, HOWEVER, THESE TWO STRINGS *-* 10200019
*-*     IN COMBINATION MUST SATISFY THE ALGORITHRIM:                *-* 10400019
         EJECT                                                          10600019
*-*         2C+3 IS LESS THAN OR EQUAL TO B       (3)               *-* 10800019
*-*            WHERE:                                               *-* 11000019
*-*               C IS THE LENGTH OF THE CHARACTER STRING PRECEDING *-* 11200019
*-*                  THE TAB POSITION.                              *-* 11400019
*-*               B IS THE LENGTH OF THE BLANK STRING PRECEDING THE *-* 11600019
*-*                    CHARACTER STRING.                            *-* 11800019
*-*                                                                 *-* 12000019
*-*      IF THE ALGORITHRIM IS SATISFIED, THE TAB AND IDLE CHAR-    *-* 12200019
*-*     ACTERS ARE IMPLANTED IN THE DATA STRING AS THEY WERE IN     *-* 12400019
*-*     THE FIRST EPEISODE.  IN ADDITION, BACK SPACE CHARACTERS (BS)*-* 12600019
*-*     ARE EXPLOITED TO PROPERLY POSITION THE CARRIAGE BEFORE      *-* 12800019
*-*     RATTLING ITS BALL.  AGAIN, BS IS NOT TO BE PREVERTED WITH   *-* 13000019
*-*     THE WORKING MASSES.  THE BS'S ARE PLACED FOLLOWING THE      *-* 13200019
*-*     IMPLANTED IDLES AND THE NUMBER IS EQUIVALENT TO THE CHAR-   *-* 13400019
*-*     ACTER STRING LENGTH.  THE BLANK STRING PRECEDING THE CHAR-  *-* 13600019
*-*     ACTER STRING IS CANNED.  THE CHARACTER STRING IS REPOSI-    *-* 13800019
*-*     TIONED NEXT TO THE EXPLOITED BS'S IN THE DATA STRING.       *-* 14000019
*-*                                                                 *-* 14200019
*-*      EPISODES ARE MET UNTIL ALL TABS ARE EXAMINED OR THE END OF *-* 14400019
*-*     THE INPUT STRING IS RECOGNIZED.  IF AND WHEN EITHER OCCURS, *-* 14600019
*-*     RETURN IS MADE TO IHKLAD FOR PROPER DISPOSITION OF THE      *-* 14800019
*-*     CONSTRUCTION DATA STRING.                                   *-* 15000019
*-*                                                                 *-* 15200019
*-*                                                                 *-* 15400019
*-*  E N T R Y   P O I N T --                                       *-* 15600019
*-*                                                                 *-* 15800019
*-*      THE ENTRY POINT FOR THIS COMPONENT IS NAMED IHKLEW.  THE   *-* 16000019
*-*     FUNCTION PROVIDED BY THIS COMPONENT IS USED ONLY AT THE     *-* 16200019
*-*     DISCRETION OF THE LINE ADMINSITRATOR (IHKLAD).              *-* 16400019
*-*                                                                 *-* 16600019
*-*                                                                 *-* 16800019
*-*  I N P U T --                                                   *-* 17000019
*-*                                                                 *-* 17200019
*-*      STANDARD LINKAGE PREVAILS.  REGISTER ONE CONTAINS THE      *-* 17400019
*-*     ADDRESS OF A ONE WORD PARAMETER LIST WHICH CONTAINS THE     *-* 17600019
*-*     TUB ADDRESS.  THE TUB CONTAINS POINTERS TO THE USER BUFFER, *-* 17800019
*-*     AND THE TAB TABLE.  THE USER BUFFER CONTAINS THE DATA       *-* 18000019
*-*     STRING TO BE EDITED.  IHKLAD DOES NOT CALL UPON THIS        *-* 18200019
*-*     FUNCTION IF:                                                *-* 18400019
*-*        1,  NO TABSET COMMAND IS IN FORCE AT THE TERMINAL.       *-* 18600019
*-*        2.  DATA TO BE EDITED CONTAINS NO NON-BLANK CHARACTERS.  *-* 18800019
*-*                                                                 *-* 19000019
*-*                                                                 *-* 19200019
*-*  O U T P U T --                                                 *-* 19400019
*-*                                                                 *-* 19600019
*-*      THE DATA STRING IN THE USER BUFFER IS EDITED WITH TAB,     *-* 19800019
*-*     IDLE AND BACK SPACE CHARACTERS IF REQUIRED.  THE LENGTH     *-* 20000019
*-*     OF THE MODIFIED STRING IS RETURNED IN THE TUB FIELD NAMED   *-* 20200019
*-*     TUBDATAL.                                                   *-* 20400019
*-*                                                                 *-* 20600019
*-*                                                                 *-* 20800019
*-*  E X T E R N A L   R O U T I N E S                              *-* 21000019
*-*                                                                 *-* 21200019
*-*      NONE                                                       *-* 21400019
         EJECT                                                          21600019
*-*                                                                 *-* 21800019
*-*  T A B L E S / W O R K   A R E A S --                           *-* 22000019
*-*                                                                 *-* 22200019
*-*      DUMMY THREE WORD SAVE AREA.                                *-* 22400019
*-*                                                                 *-* 22600019
*-*      TUB FIELDS REFERENCED AND MODIFIED -                       *-* 22800019
*-*         TUBUFFAD - USER BUFFER ADDRESS        (REF)             *-* 23000019
*-*         TUBTABAD - TUB TABLE ADDRESS          (REF)             *-* 23200019
*-*         TUBDATAL - USER BUFFER DATA LENGTH    (MOD)             *-* 23400019
*-*                                                                 *-* 23600019
*-*      TAB TABLE -                                                *-* 23800019
*-*         COUNT OF TAB SETTINGS SPECIFIED                         *-* 24000019
*-*         LOGICAL CARRIAGE POSITION OF EACH TAB                   *-* 24200019
*-*                                                                 *-* 24400019
*-*      USER BUFFER -                                              *-* 24600019
*-*         ON ENTRY CONTAINS DATA TO BE EDITED                     *-* 24800019
*-*         ON EXIT CONTAINS EDITED DATA STRING                     *-* 25000019
*-*                                                                 *-* 25200019
*-*                                                                 *-* 25400019
*-*  E X I T S --                                                   *-* 25600019
*-*                                                                 *-* 25800019
*-*      N/A                                                        *-* 26000019
*-*                                                                 *-* 26200019
*-*                                                                 *-* 26400019
*-*  A T T R I B U T E S --                                         *-* 26600019
*-*                                                                 *-* 26800019
*-*      RESIDENT AND REENTRANT                                     *-* 27000019
*-*                                                                 *-* 27200019
*-*                                                                 *-* 27400019
*-*  N O T E S --                                                   *-* 27600019
*-*                                                                 *-* 27800019
*-*      PICK UP LAUNDRY ON WAY HOME                                *-* 28000019
*-*                                                                 *-* 28200019
*-*                                                                 *-* 28400019
*-*******************************************************************-* 28600019
*---------------------------------------------------------------------* 28800019
*********************************************************************** 29000019
         EJECT                                                          29200019
*      S Y M B O L I C   R E G I S T E R   U S A G E                    29400019
#TB      EQU   0         NUMBER OF TAB SETTINGS                         29600019
TUB      EQU   1         POINTER TO CRJE TUB FOR LINE                   29800019
BUF      EQU   2         USER BUFFER ADDRESS                            30000019
SMA      EQU   3         FIRST CHAR ADDR TO BE MOVED TO PRO/POR BUFFER  30200019
NTB      EQU   4         NEXT TAB SETTING                               30400019
NBS      EQU   5         NEXT BYTE TO BE SCANNED                        30600019
NBP      EQU   6         NEXT BUFFER POSITION FOR ADJUSTED DATA         30800019
#CH      EQU   7         # CHARACTERS IN STRING                         31000019
EVE      EQU   8         EVEN WORK REGISTER                             31200019
ODD      EQU   9         ODD WORK REGISTER                              31400019
BAL      EQU  10         INTERNAL LINKAGE REGISTER                      31600019
TAB      EQU  11         POINTER TO TAB SETTINGS                        31800019
END      EQU  12          END OF DATA IN BUFFER                         32000019
SAV      EQU  13         STUPID SAVE FOR SIMILAR STANDARD               32200019
#BK      EQU  14         # OF BLANKS IN STRING                          32400019
BAS      EQU  15         MODULE BASE                                    32600019
         SPACE 2                                                        32800019
*     S Y M B O L I C   E Q U A T E S   FOR   I H K L E W               33000019
         SPACE 2                                                        33200019
ZIP      EQU   0                                                        33400019
UNO      EQU   1                                                        33600019
TWO      EQU   2                                                        33800019
TRE      EQU   3                                                        34000019
FOR      EQU   4                                                        34200019
TWLV     EQU  12                                                        34400019
BLNK     EQU   C' '                                                     34600019
BS       EQU   X'16'     BACK SPACE CHARACTER                           34800019
FF       EQU   X'FF'                                                    34900019
         EJECT                                                          35000019
*             E N T R Y   L I N K A G E                                 35200019
         SPACE                                                          35400019
    USING      *,BAS          TELL ASSEMBLER CHOICE OF BASE REG         35600019
         SAVE  (14,12),T,IHKLEW10/08/69                                 35800019
         L     TUB,0(TUB)     GET TUB ADDRESS                           36000019
    USING      TUBDSECT,TUB   TELL ASSEMBLER ABOUT TUB DSECT            36200019
         SPACE 2                                                        36400019
*           G E T   P A R A M E T E R S   FROM   T U B                  36600019
         SPACE                                                          36800019
         L     BUF,TUBUFFAD   GET ADDRESS OF USER BUFFER                37000019
         LA    BUF,ZIP(BUF)   CLEAR HIGH ORDER BYTE                     37200019
         L     TAB,TUBOUTAB   GET ADDRESS OF TAB SETTINGS               37400019
         LH    END,TUBDATAL   GET LENGTH OF DATA IN BUFFER              37600019
         LTR   END,END        IS THERE ANY DATA TO WRITE?               37660019
         BZ    BEATIT         IF NOT, DON'T BOTHER WITH TABS            37720019
         AR    END,BUF        COMPUTE END OF DATA ADDRESS               37800019
         MVI   ZIP(END),FF    FLAG END OF TEXT                          37900019
         LR    NBP,BUF        SET UP PROCESSED PORTION POSITION OF      38000019
*                             - BUFFER (PRO/POR) TO BUFFER START        38200019
         LR    NTB,BUF        SET UP NEXT TAB AS BUFFER START           38400019
         LH    #TB,ZIP(TAB)   GET # OF TABS SETTINGS SPACIFIED          38600019
         LA    TAB,UNO(TAB)   GET OVER THE HALF-WORD                    38800019
         SPACE 2                                                        39000019
*           U P D A T E   T A B   S E T T I N G                         39200019
         SPACE                                                          39400019
TABSET   DS    0H        **** TAG FOR BRANCHING                         39600019
         LR    NBS,NTB        GET SCAN START BEFORE UPDATING TAB        39800019
         LR    SMA,NBS        SET UP FOR MOVE TO PRO/POR IF REQUIRED    40000019
         BCTR  #TB,0          DECREMENT # OF TABS PROCESSED             40200019
         LTR   #TB,#TB        ALL TABS PROCESSED?                       40400019
         BM    SOAP           YES, CLEAN UP BUFFER BEFORE RETURN        40600019
         SPACE                                                          40800019
         LA    TAB,UNO(TAB)   POINT TO NEXT TAB SETTING                 41000019
         SR    NTB,NTB        CLEAR FOR INSERT                          41200019
         IC    NTB,ZIP(TAB)   GET LOGICAL OFFSET OF NEXT TAB            41400019
         AR    NTB,BUF        SET UP PHYSICAL RELATIONSHIP BETWEEN THE  41600019
*                             - TABSETS AND BUFFER SO LEW CAN DO HIS    41800019
*                             - THING                                   42000019
         SPACE 2                                                        42200019
*           S C A N   F O R  N O N - B L A N K   OR   T A B             42400019
         SPACE                                                          42600019
SCANC    DS    0H        **** TAG FOR BRANCHING                         42800019
         SR    #BK,#BK        ZIP OUT RESIDUE TO GET NEW STRING LENGTH  43000019
         LR    SMA,NBS        SET UP FOR MOVE TO PRO/POR IF REQUIRED    43200019
         LA    BAL,TABSET     SET UP RETURN LINKAGE TO CHANGE TABS AND  43400019
*                             - SCAN FOR NON-BLANK                      43600019
         SPACE                                                          43800019
LOOPC    DS    0H        **** TAG FOR BRANCHING                         44000019
         CR    NBS,NTB        DID SCAN REACH NEXT TAB SETTING           44200019
         BNL   @TABFCS        YES, HANDLE TAB FOUND ON CHARACTER SCAN   44400019
         SPACE                                                          44600019
         CLI   ZIP(NBS),BLNK  IS THIS CHARACTER NON-BLANK               44800019
         BNE   HAVNB          YES, SCAN SATISFIED - HANDLE CHAR FOUND   45000019
         SPACE                                                          45200019
         LA    NBS,UNO(NBS)   POINT TO NEXT BYTE TO BE CHECKED          45400019
         LA    #BK,UNO(#BK)   INCREMENT BLANK STRING LENGTH             45600019
         B     LOOPC          CONTINUE SCAN FOR NON-BLANK               45800019
         SPACE 2                                                        46000019
*   H A N D L E   T A B   F O U N D   BEFORE   N O N - B L A N K        46200019
         SPACE                                                          46400019
@TABFCS  DS    0H        **** DEFINE TAG FOR BRANCHING                  46600019
         C     #BK,THRE       ROOM TO INSERT TAB AND IDLE CHARS         46800019
         BNH   UPBUF          NO, FORGET THIS IDLE JAZZ AND ADJUST DATA 47000019
*                             - IN PROCESSED PORTION OF BUFFER--PRO/POR 47200019
         SPACE                                                          47400019
         LR    ODD,#BK        GET # OF BLANK CHAR FOR IDLE COMPUTATION  47600019
         SPACE    2                                                     47800019
*     I D L E   C O M P U T A T I O N   AND   I N S E R T I O N         48000019
         SPACE                                                          48200019
IDLE     DS    0H        **** TAG FOR BRANCHING                         48400019
         LA    ODD,FOR(ODD)   MODIFY COUNT TO YIELD # OF IDLES EXECUTED 48600019
         SR    EVE,EVE        CLEAR EVEN REG FOR DIVIDE                 48800019
         D     EVE,TEN        GET ADDITIONAL IDLES REQUIRED             49000019
         MVC   0(TWO,NBP),HID MOVE TAB AND IDLE CHAR TO PRO/POR BUFFER  49200019
         EX    ODD,IDMOV      CASCADE IDLE FOR REQUIRED NUMBER          49400019
         SPACE                                                          49600019
         LA    NBP,TRE(ODD,NBP) UPDATE PRO/POR POSITION IN BUFFER       49800019
         BR    BAL            DO WHAT SOMES NATURALLY                   50000019
         SPACE 2                                                        50200019
*   H A N D L E   N O N - B L A N K   F O U N D   BEFORE   T A B S E T  50400019
         SPACE                                                          50600019
HAVNB    DS    0H        **** TAG FOR BRANCHING                         50800019
         LR    EVE,NTB        GET NEXT ADDR TO COMPUTE STRING LNG       51000019
         SR    EVE,NBS        COMPUTE STRING LENGTH TO NEXT TABSET      51200019
         LR    #CH,EVE        SAVE # OF CHAR POSITIONS TO NEXT TAB      51400019
         SPACE                                                          51600019
*  CHECK ALOGRITHIM TO SEE IF TAB/BACKSPACE COMBO CAN BE UTILIZED       51800019
         SPACE                                                          52000019
*        ALGORITHIM IS   2C+3 <OR= B        WHERE:                      52200019
*    C IS THE STRING LENGTH OF CHARACTER POSITIONS BEFORE THE NEXT TAB  52400019
*    B IS THE NUMBER OF BLANKS PRECEDING THE CHAR POSITION STRING       52600019
         SPACE                                                          52800019
         SLL   EVE,UNO        DOUBLE   CHAR POSITION STRING LENGTH      53000019
         LA    EVE,TRE(EVE)   ADD THREE TO THAT                         53200019
         CR    EVE,#BK        ALGORITHRIM SATISFIED                     53400019
         BNH   KEEPON         NORMAL CONTINUE IF NOT                    53460019
         CLI   ZIP(NBS),FF    END OF TEXT?                              53520019
         BNE   SCANB          NORMAL CONTINUE IF NOT                    53580019
         LTR   #BK,#BK        ZERO LENGTH?                              53640019
         BZ    DUN            EXIT IF YES                               53700019
         BCTR  #BK,0          ELSE DECREMENT FOR EXECUTE                53760019
         EX    #BK,MOVDAT     MOVE IN LAST DATA                         53820019
         LA    NBP,UNO(#BK,NBP) POINT TO END OF TEXT                    53880019
         B     DUN            AND EXIT                                  53940019
         SPACE                                                          54000019
KEEPON   LA    ODD,ZIP(#BK,#CH) GET # CHARS FOR IDLE COMPUTATION        54060019
         BAL   BAL,IDLE       INSERT TAB AND IDLE CHARS INTO BUFFER     54200019
         SPACE                                                          54400019
         LR    EVE,#CH        SAVE NUMBER OF CHARS                      54600019
         MVI   ZIP(NBP),BS    INSERT BACKSPACE AFTER IDLE               54800019
         SH    EVE,#TWO       ONLY ONE CHAR POSITION                    55000019
         BM    NOMOR          YES FORGET THE CASCADE EFFECT             55200019
         SPACE                                                          55400019
         EX    EVE,MOBS       CASCADE REQUIRED BS'S IN PRO/POR OF BUFR  55600019
         SPACE                                                          55800019
NOMOR    DS    0H        **** TAG FOR BRANCHING                         56000019
         AR    NBP,#CH        UPDATE PRO/POR POSITION IN BUFFER         56200019
         AR    SMA,#BK        UPDATE MOVE START ADDRESS                 56400019
         BCTR  #CH,0          DECREMENT STRING LENGTH FOR EXECUTED MOVE 56600019
         EX    #CH,MOVDAT     ADJUST CHAR STRING IN PRO/POR OF BUFFER   56800019
         SPACE                                                          57000019
         LA    NBP,UNO(NBP,#CH) UPDATE PRO/POR POSITION IN BUFFER       57200019
         LA    EVE,UNO(NBS,#CH) COMPUTE NEW SCAN POSITION               57400019
         CR    EVE,END        IS IT PAST END OF DATA                    57600019
         BL    TABSET         NO, SCAN FOR NON-BLANK WITH NEW TABSET    57800019
         SPACE                                                          58000019
         SR    EVE,END        COMPUTE HOW FAR PAST END OF DATA          58200019
         SR    NBP,EVE        REDUCE PRO/POR BUFFER POSITION ACCORDING  58400019
         B     DUN            MOVE IT ON OUT AND EXIT                   58600019
         SPACE 2                                                        58800019
*    C O M P U T E   N O N - B L A N K   S T R I N G   L E N G T H      59000019
         SPACE                                                          59200019
SCANB    DS    0H        **** TAG FOR BRANCHING                         59400019
         SR    #CH,#CH        SET CHARACTER STRING LENGTH TO ZERO       59600019
         SPACE                                                          59800019
LOOPB    DS    0H        **** TAG FOR BRANCHING                         60000019
         CR    NBS,END        DID SCAN REACH END OF DATA IN BUFFER      60200019
         BNL   SUDS           YES, HANDLE BUFFER DATA END AND CLEANUP   60400019
         SPACE                                                          60600019
         CR    NBS,NTB        DID SCAN REACH NEXT TAB SET               60800019
         BNL   HAVB           YES,HANDLE TAB FOUND ON BLANK SCAN --     61000019
*                             - ASSUME BLANK WAS FOUND                  61200019
         SPACE                                                          61400019
         CLI   ZIP(NBS),BLNK  IS THIS BUFFER POSITION BLANK             61600019
         BE    HAVB           YES, SCAN SATISFIED - HANDLE BLANK FOUND  61800019
         SPACE                                                          62000019
         LA    NBS,UNO(NBS)   POINT TO NEXT POSITION TO BE CHECKED      62200019
         LA    #CH,UNO(#CH)   INCREMENT NON-BLANK STRING LENGTH         62400019
         B     LOOPB          CONTINUE SCAN FOR BLANK                   62600019
         SPACE 2                                                        62800019
*  R E P O S I T I O N   D A T A   S T R I N G   IN   B U F F E R       63000019
          SPACE                                                         63200019
HAVB     DS    0H        **** TAG FOR BRANCHING                         63400019
         AR    #BK,#CH        GET LENGTH OF DATA STRING TO POSITION     63600019
*                               - IN PRO/POR OF BUFFER                  63800019
         SPACE                                                          64000019
UPBUF    DS    0H        **** TAG FOR BRANCHING                         64200019
         BCTR  #BK,0          DECREMENT STRING LENGTH FOR EXECUTED MOVE 64400019
         EX    #BK,MOVDAT     PLACE STRING IN PRO/POR OF BUFFER         64600019
         SPACE                                                          64800019
         LA    NBP,UNO(#BK,NBP) UPDATE PRO/POR POSITION IN BUFFER       65000019
         CR    NBS,NTB        IS A NEW TAB SET REQUIRED                 65200019
         BL    SCANC          NO, SCAN FOR NON-BLANK USING CURRENT TAB  65400019
         SPACE                                                          65600019
         BR    BAL            CONTINUE SCAN FOR NON-BLANK WITH NEW TAB  65800019
         SPACE 3                                                        66000019
*      H A N D L E   A L L   T A B S   P R O C E S S E D                66200019
         SPACE                                                          66400019
SOAP     DS    0H        **** TAG FOR BRANCHING                         66600019
         CR    END,NTB        DO TAB AND DATA END POSITIONS COINSIDE    66800019
         BNH   DUN            YES, PRO/POR BUFFER FINE FINISH UP        67000019
         SPACE                                                          67200019
         SR    END,NTB        COMPUTE RESIDUE STRING LENGTH             67400019
         BCTR  END,0          DECREMENT STRING LENGTH FOR EXECUTED MOVE 67600019
         EX    END,MOVDAT     MOVE RESIDUE TO PRO/POR POSITIONS IN BUF  67800019
         SPACE                                                          68000019
         LA    NBP,UNO(NBP,END)  UPDATE PRO/POR POSITION OF UBFFER      68200019
         B     DUN            FINISH UP AND RETURN                      68400019
         SPACE    2                                                     68600019
*      H A N D L E   B U F F E R   D A T A   E N D                      68800019
         SPACE                                                          69000019
SUDS     DS    0H        **** TAG FOR BRANCHING                         69200019
         AR    #BK,#CH        GET RESIDUE DATA STRING LENGTH            69400019
         BCTR  #BK,0          DECREMENT FOR EXECUTE                     69600019
         EX    #BK,MOVDAT     MOVE RESIDUE TO PRO/POR POSITIONS IN BUF  69800019
         SPACE                                                          70000019
         LA    NBP,UNO(#BK,NBP) UPDATE PRO/POR POSITION OF BUFFER       70200019
         SPACE 2                                                        70400019
*     E X I T   FOR   F A B R I C A T I O N                             70600019
         SPACE                                                          70800019
DUN      DS    0H        **** TAG FOR BRANCHING                         71000019
         SR    NBP,BUF        COMPUTE PRO/POR BUFFER LENGTH             71200019
         STH   NBP,TUBDATAL             PASS LENGTH BACK TO L.A.        71400019
BEATIT   EQU   *                                                        71500019
         LM    14,12,TWLV(SAV) RESTORE LAD'S REGS                       71600019
         BR    14             RETURN                                    71800019
         EJECT                                                          72000019
*        E X E C U T E D  I N S T R U C T I O N S                       72200019
         SPACE                                                          72400019
IDMOV    MVC   TWO(ZIP,NBP),UNO(NBP)    CASCADE IDLES                   72600019
MOBS     MVC   UNO(ZIP,NBP),ZIP(NBP)    CASCADE BS                      72800019
MOVDAT   MVC   ZIP(ZIP,NBP),ZIP(SMA)    MOVE INPUT STRING TO PRO/POR    73000019
         SPACE 3                                                        73200019
*             C O N S T A N T S   AND   A R E A S                       73400019
         SPACE                                                          73600019
TEN      DC    F'10'          IDLE COMPUTATION DIVISOR                  73800019
THRE     DC    F'3'           THREE AT LEAST                            74000019
HID      DC    XL2'0517'      HORIZONTAL TAB AND IDLE CHAR COMBO        74200019
#TWO     DC    H'2'                                                     74400019
         IHKCDSCT  TUB=YES                                              74600019
   END                                                                  74800019
