LST      TITLE 'IHKLST - LIST COMMAND PROCESSOR'                        00001019
IHKLST   CSECT ,                                                 S21085 00001221
*A000012,654600-656400                                           S21085 00001421
*D001780-006000,655000-656000                                    S21085 00001621
*C045000                                                         S21085 00001821
*A551000                                                         A42682 00002300
*C045000                                                         A42682 00002800
* A 367000,369000,654500                                       OS66699  00003028
*********************************************************************** 00003300
*                                                                     * 00004019
*STATUS                                                               * 00006019
*   CHANGE LEVEL 0                                                    * 00008019
*FUNCTION                                                             * 00010019
*   AT THE ENTRY POINT, THE OPERANDS ARE CHECKED. THE NUMERIC         * 00012019
*   VERIFICATION MODULE (IHKNUM) CHECKS THE LINENUM OPERANDS,         * 00014019
*   IF SPECIFIED, FOR ALL NUMERICS.  A GETMAIN MACRO IS ISSUED FOR    * 00016019
*   TWO DOUBLE WORDS TO CONTAIN THE LINE NUMBERS.  IF THERE ARE ANY   * 00018019
*   ERRORS IN THE OPERANDS, AN ERROR MESSAGE IS SENT TO THE USER AND  * 00020019
*   CONTROL IS RETURNED TO THE CALLING ROUTINE.  IF NO LINE NUMBERS   * 00022019
*   ARE SPECIFIED, THE ENTIRE DATA SET IS LISTED. IF A RANGE OF LINE  * 00024019
*   NUMBERS IS SPECIFIED, THE LISTING STARTS WITH THE FIRST SPECIFIED * 00026019
*   LINE OR, IF THAT LINE DOES NOT EXIST, WITH THE NEXT HIGHER NUMBER * 00028019
*   LINE.  THE LISTING CONTINUES TO GIVE SUCCESSIVE LINES UNTIL EOD   * 00030019
*   IS DETECTED OR UNTIL THE NEXT LINE NUMBER IN THE DATA SET IS      * 00032019
*   GREATER THAN THE SPECIFIED LAST NUMBER.  IF ONLY ONE LINE NUMBER  * 00034019
*   IS SPECIFIED, THAT LINE ALONE IS LISTED.  IF THE LINE CANNOT BE   * 00036019
*   FOUND, A MESSAGE INFORMS THE USER THAT THE LINE DOES NOT EXIST.   * 00038019
*   IF THE NUM OPERAND IS SPECIFIED, EACH LINE LISTED IS PRECEDED     * 00040019
*   BY ITS LINE NUMBER.  IF THE NONUM OPERAND WAS GIVEN, ONLY THE     * 00042019
*   LINE IS LISTED. HOWEVER, IF THE DATA SET HAS THE SEQ ATTRIBUTE,   * 00044019
*   THE LAST 8 POSITIONS OF THE LINE ARE NOT PRINTED FOR BOTH NUM AND * 00046019
*   NONUM CONDITIONS.  THE TUBLONGN SWITCH OF THE TUBFLG3 FIELD IS    * 00048019
*   CHECKED TO DETERMINE THE PRESENCE OF RECORDS WITH A LENGTH OF UP  * 00050019
*   TO 120 CHARACTERS. IF SO, THE EXTRA FORTY CHARACTERS ARE LISTED   * 00052019
*   FOLLOWING THE STANDARD 80 CHARACTER LINE.  THE RPOINT AND RGET    * 00054019
*   MACROS OF AFIO ARE USED TO READ THE ACTIVE FILE ONE LINE AT A     * 00056019
*   TIME.  AN 80 CHARACTER LINE IS PUT IN THE USER BUFFER.  IF A 120  * 00058019
*   CHARACTER LINE IS INDICATED, A SECOND LINE IS PUT IN AN ALLOCATED * 00060019
*   AFIO BUFFER AND THE FIRST 40 CHARACTERS ARE MOVED INTO THE USER   * 00062019
*   BUFFER FOLLOWING THE FIRST FULL LINE.  THE AFIO BUFFER IS THEN    * 00064019
*   FREED.  BOTH 80 AND 120 CHARACTER 6INES ARE WRITTEN FROM THE USER * 00066019
*   BUFFER TO THE USER AT A TERMINAL BY USE OF THE CWRITE MACRO. THE  * 00068019
*   ENTRY POINT IS ALSO USED BY THE LISTLIB/LISTDS PROCESSOR TO LIST  * 00070019
*   THE REQUESTED INFORMATION PERTAINING TO A DATA SET OR SETS FROM A * 00072019
*   USER LIBRARY. THE IHKLDS MODULE BUILDS THE LINES IN THE ACTIVE    * 00074019
*   AREA AND BRANCHES TO TH2S MODULE TO WRITE THE LINES.  UPON        * 00076019
*   COMPLETION OF THIS IHKLDS LISTING, THE ACTIVE AREA CREATED BY THE * 00078019
*   IHKLDS ROUTINE IS RELEASED.                                       * 00080019
         EJECT                                                          00082019
*ENTRY POINTS                                                         * 00084019
*        IHKLST TO LIST THE CONTENSE OF THE ACTIVE AREA               * 00086019
*INPUT                                                                * 00088019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING     * 00090019
*   THE ADDRESS OF THE TUB IN THE FIRST WORD AND                      * 00092019
*   THE ADDRESS OF THE AVT IN THE SECOND                              * 00094019
*OUTPUT                                                               * 00096019
*   A LISTING OF THE ACTIVE AREA LINE BY LINE WITH OR WITHOUT NUMBERS * 00098019
*EXTERNAL REFERENCES                                                  * 00100019
*        IHKNUM - TO CHECK LINENUM OPERANDS FOR ALL NUMERICS.         * 00102019
*        IHKAFI - TO READ ACTIVE FILE ( OR CERTAIN LINES) .           * 00104019
*        IHKLAD - TO WRITE ACTIVE FILE (OR CERTAIN LINES) AT TERMINAL * 00106019
*        IHKMSG - (ENTRY POINT IHKMSG01) TO QUEUE ERROR MESSAGES      * 00108019
*EXITS, NORMAL                                                        * 00110019
*   RETURN TO THE CALLING ROUTINE WITH ZERO IN REGISTER 15            * 00112019
*EXITS, ERROR                                                         * 00114019
*   RETURN TO CALLING ROUTINE WITH ONE OF THE FOLLOWING RETURN CODES  * 00116019
*   IN REGISTER 15                                                    * 00118019
*   4  - LINE ERROR                                                   * 00120019
*   8  - GETMAIN FAILED                                               * 00122019
*   12 - ACTIVE AREA I/O ERROR                                        * 00124019
*   16 - ERROR MESSAGE LOST                                           * 00126019
*   20 - ACTIVE AREA OUT OF SPACE                                     * 00128019
*TABLES/WORK AREAS                                                    * 00130019
*   18-WORD SAVE AREA                                                 * 00132019
*   96-BYTE BUFFER USED WHEN LISTING LINE OF A LENGTH GREATER THAN 80 * 00134019
*   I DOUBLE WORDS TO STORE LINE NUMBERS                              * 00136019
*   USER BUFFER TO PASS LINE TO IHKLAD                                * 00138019
*   PPT - FLAG BYTE                                                   * 00140019
*   TUB                                                               * 00142019
*   TUBLNO - INDICATES WHETHER LINE NUMBERS ARE REQUESTED             * 00144019
*   TUBPRMLS - USED FOR PARAMETER LISTS FOR THE IHKNUM AND IHKMSG MOD * 00146019
*   TUBDATAL - USED TO SPECIFY DATA LENGTH FOR CWRITE OPERATION       * 00148019
*   TUB AFISW - SET AND TURNED OFF FOR AFIO BUFFER CONTROL            * 00150019
*   TUBLNUMN - CHECKED FOR SEQUENTIAL NUMBER IN LINE                  * 00152019
*   TUBLONGN - CHECKED FOR 80 AND 120 CHARACTER LINE                  * 00154019
*   TUBPPTAD - CHECKED FOR PPT ADDRESS                                * 00156019
*   TUBRAFBF - SET AND CHECKED FOR AFIO BUFFER ADDRESS                * 00158019
*   TUBUFFAD - CHECKED FOR USER BUFFER ADDRESS                        * 00160019
*   TUBUSERID - USERID PASSED TO MESSAGE WRITER                       * 00162019
*   DEF                                                               * 00164019
*   DEFLST - INDICATES DEFAULT FOR LINE NUMBERS                       * 00166019
*ATTRIBUTES                                                           * 00168019
*   RESIDENT AND REENTRANT                                            * 00170019
*                                                                     * 00172019
*********************************************************************** 00174019
         EJECT                                                          00176019
         SPACE 2                                                        00700019
R0       EQU   0                   GENERAL WORK REGISTER                00800019
R1       EQU   1                   PARMPT,MSGCODE                       00900019
R2       EQU   2                   TUBPT                                01000019
R3       EQU   3                   PPTPT, DEFPT                         01100019
R4       EQU   4                   PPTAD                                01200019
R5       EQU   5                   INCR                                 01300019
R6       EQU   6                   OPNDCTR                              01400019
R7       EQU   7                   USRBUFAD                             01500019
R8       EQU   8                   RAFBUFAD                             01600019
R9       EQU   9                   PPTESTRG                             01700019
R10      EQU   10                  AVTPT                                01800019
R11      EQU   11                  INTERNAL BRANCHING                   01900019
R12      EQU   12                  BASE REG                             02000019
R13      EQU   13                  SAVE AREA                            02100019
R14      EQU   14                  RETURN ADDRESS                       02200019
R15      EQU   15                  RETURN CODE                          02300019
         SPACE 2                                                        02400019
MSGCODE  EQU   1                   REGISTER FOR MESSAGE CODE            02500019
PARMPT   EQU   1                   REGISTER FOR PARAMETER POINTER       02600019
TUBPT    EQU   2                   POINTER TO TUB                       02700019
DEFPT    EQU   3                   REGISTER FOR DEFAULT TABLE ADDRESS   02800019
PPTPT    EQU   3                   POINTER TO PPT                       02900019
PPTAD    EQU   4                   REG. TO RETAIN PTR TO  PPTFLG BYTE   03000019
INCR     EQU   5                   INCREMENT USED TO UPDATE PPT POINTER 03100019
OPNDCTR  EQU   6                   REG USED TO COUNT PARAMETERS         03200019
USRBUFAD EQU   7                   USER BUFFER POINTER                  03300019
RAFBUFAD EQU   8                   RADIO BUFFER POINTER                 03400019
PPTESTRG EQU   9                   POINTER TO PPT ADDR UNDER TEST       03500019
AVTPT    EQU   10                  POINTER TO ADDRESS VECTOR TABLE      03600019
INNERBR  EQU   11                  REGISTER FOR INNER BRANCH AND LINK   03700019
 EJECT                                                                  03800019
***********************************                                     03900019
*                                                                       04000019
* SAVE REGISTERS                                                        04100019
*                                                                       04200019
***********************************                                     04300019
 SPACE                                                                  04400019
         SAVE  (14,12),,LST73274                               OS66699  04500028
         LR    R12,R15             LOAD BASE REGISTER WITH START ADDRSS 04600019
         USING IHKLST,R12                                               04700019
 SPACE                                                                  04800019
***********************************                                     04900019
*                                                                       05000019
* DYNAMIC STORAGE FOR SAVE AND WORK AREAS                               05100019
*                                                                       05200019
***********************************                                     05300019
 SPACE                                                                  05400019
         L     TUBPT,0(,R1)        LOAD THE PTR TO THE TUB              05500019
         USING TUBDSECT,TUBPT      ADDRESSABILITY FOR TUB FIELDS        05600019
         L     AVTPT,4(,R1)        ADDRESS OF ADDRESS VECTOR TABLE      05700019
         USING AVTDSECT,AVTPT      ADDRESSABILITY TO AVT                05800019
         L     1,IHKYYGML                                               05900019
         LA    R3,NEED             PROVIDE SPACE REQUIRMENTS            06000019
         LA    R4,TUBPARM1         PROVIDE FOR POINTER TO SAVE AREA     06100019
         GETMAIN   EC,LV=(R3),A=(R4),MF=(E,(1))                         06200019
         LTR   R15,R15             TEST FOR SUCCESSFUL COMPLETION       06300019
         BNZ   RTRNBAD2            RETURN WITH GETMAIN FAILURE          06400019
 SPACE 2                                                                06500019
***********************************                                     06600019
*                                                                       06700019
* ESTABLISH LINKAGE OF SAVE AREAS                                       06800019
*                                                                       06900019
***********************************                                     07000019
         SPACE 1                                                        07100019
         L     R15,TUBPARM1        LOAD SAVE AREA POINTER               07200019
         ST    R13,4(R15)          STORE LA SAVE ADRS IN LST SAVE AREA  07300019
         ST    R15,8(R13)          STORE LST SAVE ADRS IN LA SAVE AREA  07400019
         LR    R13,R15             PLACE SAVE AREA ADRS IN R13          07500019
         USING LISTSAVE,R13        ADDRESSABILITY FOR LIST SAVE AREA    07600019
         EJECT                                                          07700019
***********************************                                     07800019
*                                                                       07900019
* SET DEFAULT PARAMETERS                                                08000019
*                                                                       08100019
***********************************                                     08200019
 SPACE                                                                  08300019
         L     DEFPT,IHKYYDEF      OBTAIN ADDRESS OF DEFAULT TABLE      08400019
         USING DEFDSECT,DEFPT      ADDRESSABILITY FOR DEFAULT TABLE     08500019
         OC    TUBFLG1,DEFLST      SET THE DEFAULT VALUE FOR LINE NUMS  08600019
         DROP  DEFPT                                                    08700019
         MVC   STRTLNNO,DFLTSTRT   SET STARTING LINE NO. TO 0'S         08800019
         MVC   LASTLNNO,DFLTLAST   SET ENDING LINE NO. TO 9'S           08900019
 SPACE 2                                                                09000019
***********************************                                     09100019
*                                                                       09200019
* INITIALIZE SWITCH USED TO RECORD SUCCESSFUL LISTING OF LINES          09300019
*                                                                       09400019
***********************************                                     09500019
 SPACE                                                                  09600019
         L     PPTAD,TUBPPTAD      LOAD ADDRESS OF PPT                  09700019
         USING PPTDSECT,PPTAD      ADDRESSABILITY FOR PPT               09800019
         XC    PPTFLG,PPTFLG       INNITIALIZE THE FLAGS OF THE PPTFLG  09900019
         XR    OPNDCTR,OPNDCTR     CLEAR PARAMETER COUNTER              10000019
         CLI   PPTPARS,LDSCODE     TEST FOR LDS LISTING                 10100019
         BE    PTLDS               IF LDS LISTING, INITIALIZE           10200019
         EJECT                                                          10300019
***********************************                                     10400019
*                                                                       10500019
* TEST FIRST OPERAND                                                    10600019
*                                                                       10700019
***********************************                                     10800019
 SPACE                                                                  10900019
         LA    PPTPT,PPTPARS       OBTAIN THE POINTER TO PPT PARAMS     11000019
         BAL   INNERBR,FRSTTEST    TEST FOR THE FIRST PARAMETER         11100019
 SPACE                                                                  11200019
***********************************                                     11300019
*                                                                       11400019
* TEST FOR ALL NUMERICS IN THE FIRST PARAMETER FIELD                    11500019
*                                                                       11600019
***********************************                                     11700019
 SPACE                                                                  11800019
         BAL   INNERBR,ALLNUMCK    CALL IHKNUM ROUTINE                  11900019
 SPACE 2                                                                12000019
***********************************                                     12100019
*                                                                       12200019
* SET STARTING LINE NUMBER                                              12300019
*                                                                       12400019
***********************************                                     12500019
 SPACE                                                                  12600019
         MVC   STRTLNNO,TUBNXKEY   ESTABLISH STARTING LINE NUMBER       12700019
         MVC   LASTLNNO,DFLTSTRT   SET LAST LINE NUMBER TO 0            12800019
         EJECT                                                          12900019
***********************************                                     13000019
*                                                                       13100019
* ADVANCE PPT POINTER TO THE NEXT OPERAND AND TEST FOR LAST OPERAND     13200019
*                                                                       13300019
***********************************                                     13400019
 SPACE                                                                  13500019
         BAL   INNERBR,NEXTTEST    TEST SECOND OPERAND                  13600019
 SPACE 2                                                                13700019
***********************************                                     13800019
*                                                                       13900019
* TEST FOR ALL NUMERICS IN THE SECOND PARAMETER FIELD                   14000019
*                                                                       14100019
***********************************                                     14200019
 SPACE                                                                  14300019
         BAL   INNERBR,ALLNUMCK    CALL IHKNUM ROUTINE                  14400019
 SPACE 2                                                                14500019
***********************************                                     14600019
*                                                                       14700019
* SET ENDING LINE NUMBER                                                14800019
*                                                                       14900019
***********************************                                     15000019
 SPACE                                                                  15100019
         MVC   LASTLNNO,TUBNXKEY   ESTABLISH ENDING LINE NUMBER         15200019
         CLC   STRTLNNO,LASTLNNO   TEST FOR INVALID LINE NO COMBINATION 15300019
         BNL   ERRRANGE            SEND MESSAGE OF INVALID RANGE        15400019
         EJECT                                                          15500019
***********************************                                     15600019
*                                                                       15700019
* ADVANCE PPT POINTER TO THE NEXT OPERAND AND TEST FOR LAST OPERAND     15800019
*                                                                       15900019
***********************************                                     16000019
 SPACE                                                                  16100019
LASTTEST EQU   *                                                        16200019
         BAL   INNERBR,NEXTTEST    TEST NEXT OPERAND                    16300019
 SPACE 2                                                                16400019
***********************************                                     16500019
*                                                                       16600019
* IF OPERAND COUNT EXCEEDS 3, INDICATE EXCESSIVE OPERAND ERROR          16700019
*                                                                       16800019
***********************************                                     16900019
 SPACE                                                                  17000019
NUMTEST  EQU   *                                                        17100019
         LA    R0,EXCSOPND         PROVIDE FOR TESTING OPERAND COUNT    17200019
         CLR   OPNDCTR,R0          TEST FOR EXCESSIVE OPERANDS          17300019
         BH    ERREXCSS            IF COUNT EXCEED 3, OPERAND EXCESSIVE 17400019
 SPACE 2                                                                17500019
***********************************                                     17600019
*                                                                       17700019
* TEST FOR NUM/NONUM OPERANDS                                           17800019
*                                                                       17900019
***********************************                                     18000019
 SPACE                                                                  18100019
         CLC   NUMTST,0(PPTPT)     TEST OPERAND FOR 'NUM'               18200019
         BE    STLNOPND            IF 'NUM', GO TO SET LNOPND FLAG      18300019
         CLC   NONUMTST,0(PPTPT)   TEST OPERAND FOR 'NONUM'             18400019
         BNE   ERRNOPND            IF NOT 'NONUM', INDICATE ERROR       18500019
 SPACE 2                                                                18600019
***********************************                                     18700019
*                                                                       18800019
* SET FLAG FOR NO LINE NUMBERS DESIRED                                  18900019
*                                                                       19000019
***********************************                                     19100019
 SPACE                                                                  19200019
         NI    TUBFLG1,MX7F        SET TUBLNO BIT TO 0: NO LINE NUMBERS 19300019
STLNOPND EQU   *                                                        19400019
         LA    OPNDCTR,3(OPNDCTR)  INCREASE OPERAND COUNT TO SHOW LAST  19500019
         B     LASTTEST                                                 19600019
 SPACE 2                                                                19700019
***********************************                                     19800019
*                                                                       19900019
* IF A PREVIOUS ERROR IS INDICATED, RETURN WITH A CODE OF 0             20000019
*                                                                       20100019
***********************************                                     20200019
 SPACE                                                                  20300019
CHKERRSW EQU   *                                                        20400019
         TM    PPTFLG,ERRORSW      TEST FOR PREVIOUS ERROR DETECTED     20500019
         BO    RTRNGOOD            RETURN                               20600019
 EJECT                                                                  20700019
***********************************                                     20800019
*                                                                       20900019
* POINT TO STARTING LINE REQUESTED BY USER                              21000019
*                                                                       21100019
***********************************                                     21200019
 SPACE                                                                  21300019
PTLDS    EQU   *                                                        21400019
         MVC   TUBNXKEY,STRTLNNO   INITIALIZE LINE KEY FIELD OF TUB     21500019
         LA    R1,PTTUBPT(0,R13)   LOAD POINTER TO TUB POINTER          21600019
         RPOINT B,NR               POINT TO STARTING LINE IN FILE       21700019
         B     *+4(R15)            EVALUATE RETURN CODE                 21800019
         B     NUMSEQCK            NO ERRORS, PROCEED TO NUM SEQ CHK    21900019
         B     PTHIEQ              RECORD NOT FOUND, ATTEMPT PT HI/EQ   22000019
         B     RETURN              GETMAIN FAILURE                      22100019
         B     RETURN              I/O ERROR                            22200019
PTHIEQ   EQU   *                                                        22300019
         CLC   LASTLNNO,DFLTSTRT   IF LAST LINE NUMBER= 0,              22400019
         BE    ERRLNTFD            SEND MESSAGE OF NON-EXISTANT LINE    22500019
         LA    R1,PTTUBPT(0,R13)   LOAD POINTER TO TUB POINTER          22600019
         RPOINT A,NR,KEY=HIEQ      POINT TO NEXT HIGHEST RECORD         22700019
         B     *+4(R15)            EVALUATE RETURN CODE                 22800019
         B     NUMSEQCK            NO ERRORS, PROCEED TO NUM SEQ CHK    22900019
         B     NUMSEQCK            NOT FOUND, PROCEED                   23000019
         B     RETURN              GETMAIN FAILURE                      23100019
         B     RETURN              I/O ERROR                            23200019
 EJECT                                                                  23300019
***********************************                                     23400019
*                                                                       23500019
* CHECK NUM AND SEQ ATTRIBUTES TO SET DATA LENGTH CODE                  23600019
*                                                                       23700019
***********************************                                     23800019
 SPACE 2                                                                23900019
NUMSEQCK EQU   *                                                        24000019
         CLI   PPTPARS,LDSCODE     TEST FOR LDS LISTING                 24100019
         BE    GETLINE1            IF LDS, PROCEED TO GET LINE          24200019
         LA    R5,SHRTLINE         SET LINE LENGTH TO GIVE FIRST 72     24300019
         TM    TUBFLG2,TUBLNUMN    TEST FOR SEQUENCE NUMBERING IN LINE  24400019
         BO    NUMCHECK            IF SEQUENCING INDICATED, CHECK NUM   24500019
         LA    R5,NSEQLINE(R5)     SET LINE LENGTH FOR NO SEQUENCE NUMS 24600019
NUMCHECK EQU   *                                                        24700019
         TM    TUBFLG1,TUBLNO      TEST FOR LINE NUMBERS DESIRED        24800019
         BZ    GETLONG             NO LINE NUMBERS, PROCEED TO GET LINE 24900019
         LA    R5,HDRLNG(R5)       SET LINE LENGTH FOR HEADER LENGTH    25000019
GETLONG  EQU   *                                                        25100019
         TM    TUBFLG3,TUBLONGN    TEST FOR LONG LINE                   25200019
         BZ    GETLINE1            NORMAL LINE, PROCEED TO GET LINE     25300019
         TM    TUBFLG2,TUBLNUMN    TEST FOR SEQ NUMBERS          S21085 25330021
         BZ    GETLONG1            IF NOT, SET LENGTH            S21085 25360021
         LA    R5,LONGLINE(R5)     SET LINE LENGTH FOR LONG LINE        25400019
         B     GETLINE1            GET LINE                      S21085 25420021
GETLONG1 EQU   *                                                 S21085 25440021
         LA    R5,LNGLNUM(R5)      SET LENGTH                    S21085 25460021
 EJECT                                                                  25500019
***********************************                                     25600019
*                                                                       25700019
* GET KEY AND LINE INTO RAFIO BUFFER                                    25800019
*                                                                       25900019
***********************************                                     26000019
 SPACE                                                                  26100019
GETLINE1 EQU   *                                                        26200019
         L     USRBUFAD,TUBUFFAD   LOAD REGISTER WITH USER BUFFER ADDR  26300019
         LR    RAFBUFAD,USRBUFAD                                        26400019
         ST    RAFBUFAD,TUBRAFBF   PROVIDE BUFFER ADDRESS FOR AFIOO     26500019
         OI    TUBAFISW,TUBFCTLN                                        26600019
         LA    R1,PTTUBPT(0,R13)   LOAD POINTER TO TUB POINTER          26700019
         RGET  R,S,A               GET LINE WITH KEY                    26800019
         NI    TUBAFISW,TUBFCTLF                                        26900019
         B     *+4(R15)            EVALUATE RETURN CODE                 27000019
         B     CHECKKEY            NO ERRORS, PROCEED TO CHK FOR LAST   27100019
         B     INSRTCHK            END OF DATA, CHECK FOR PREVIOUR WRIT 27200019
         B     RETURN              GETMAIN FAILURE                      27300019
         B     RETURN              I/O ERROR                            27400019
 SPACE 2                                                                27500019
***********************************                                     27600019
*                                                                       27700019
* COMPARE KEY TO LAST LINE NUMBER                                       27800019
*                                                                       27900019
***********************************                                     28000019
 SPACE                                                                  28100019
CHECKKEY EQU   *                                                        28200019
         CLI   PPTPARS,LDSCODE     TEST FOR LDS LISTING                 28300019
         BE    WRTLDSLN                                                 28400019
         CLC   LASTLNNO,DFLTSTRT   IF LAST LINE NUMBER EQUALS ZERO,     28500019
         BE    CHECKNUM            BYPASS LIMIT CHECK                   28600019
         CLC   8(8,RAFBUFAD),LASTLNNO                                   28700019
         BH    INSRTCHK            IF KEY TOO GREAT, CHECK FOR INSERTS  28800019
 EJECT                                                                  28900019
***********************************                                     29000019
*                                                                       29100019
* CHECK FOR LINE NUMBERS DESIRED                                        29200019
*                                                                       29300019
***********************************                                     29400019
 SPACE                                                                  29500019
CHECKNUM EQU   *                                                        29600019
         TM    TUBFLG1,TUBLNO                                           29700019
         BZ    CHECKSEQ            IF NONUM, CHECK FOR SEQUENCE NUMBERS 29800019
 SPACE 2                                                                29900019
***********************************                                     30000019
*                                                                       30100019
* POSITION HEADER IN BUFFER                                             30200019
*                                                                       30300019
***********************************                                     30400019
 SPACE                                                                  30500019
         MVC   0(KEYLNG,USRBUFAD),KEYOFFST(RAFBUFAD)                    30600019
         MVC   KEYLNG(BLANKLNG,USRBUFAD),BLANKSPC                       30700019
         LR    R4,USRBUFAD         LOAD POINTER TO START OF NUMBER      30800019
         BAL   INNERBR,BLANKZRO    BLANK LEADING ZEROS IN HEADER        30900019
         LA    USRBUFAD,HDRLNG(USRBUFAD)     POSITION PTR AFTER HEADER  31000019
 SPACE 2                                                                31100019
***********************************                                     31200019
*                                                                       31300019
* CHECK SEQUENCE NUMBER FLAG                                            31400019
*                                                                       31500019
***********************************                                     31600019
 SPACE                                                                  31700019
CHECKSEQ EQU   *                                                        31800019
         TM    TUBFLG2,TUBLNUMN    TEST FOR SEQUENCE NUMBERING IN LINE  31900019
         BO    MOVESHRT            IF SEQUENCING INDICATED, MOVE SHORT  32000019
 EJECT                                                                  32100019
***********************************                                     32200019
*                                                                       32300019
* MOVE FULL LENGTH LINE INTO USER BUFFER                                32400019
*                                                                       32500019
***********************************                                     32600019
 SPACE                                                                  32700019
         MVC   0(FULLLINE,USRBUFAD),LNOFFSET(RAFBUFAD)                  32800019
         LA    USRBUFAD,FULLLINE(USRBUFAD)  SET USER BUFFER PTR TO END  32900019
         B     TESTLONG                                                 33000019
 SPACE 2                                                                33100019
***********************************                                     33200019
*                                                                       33300019
* MOVE SHORT LENGTH LINE INTO USER BUFFER                               33400019
*                                                                       33500019
***********************************                                     33600019
 SPACE                                                                  33700019
MOVESHRT EQU   *                                                        33800019
         MVC   0(SHRTLINE,USRBUFAD),LNOFFSET(RAFBUFAD)                  33900019
         LA    USRBUFAD,SHRTLINE(USRBUFAD)  SET USER BUFFER PTR TO END  34000019
 EJECT                                                                  34100019
***********************************                                     34200019
*                                                                       34300019
* FREEMAIN RAFIO BUFFER                                                 34400019
*                                                                       34500019
***********************************                                     34600019
 SPACE                                                                  34700019
TESTLONG EQU   *                                                        34800019
         TM    TUBFLG3,TUBLONGN    TEST FOR LONG LINE INDICATION        34900019
         BNO   WRITLINE            IF NORMAL LINE, PROCEED TO WRITE     35000019
         LA    R1,PTTUBPT(0,R13)   LOAD POINTER TO TUB POINTER          35100019
         RGET  R,S,A               OBTAIN THE NEXT RECORD FOR LONG LINE 35200019
         B     *+4(R15)            EVALUATE RETURN CODE                 35300019
         B     BUFFADDR            NO ERROR, PROCEED TO LOAD BUFFER PTR 35400019
         B     MOVEBLNK            RECORD NOT FOUND, LOAD WITH BLANKS   35500019
         B     RETURN              GETMAIN FAILURE                      35600019
         B     RETURN              I/O ERROR                            35700019
BUFFADDR EQU   *                                                        35800019
         L     RAFBUFAD,TUBRAFBF   OBTAIN ADDRESS OF RAFIO BUFFER       35900019
MOVELONG EQU   *                                                        36000019
         TM    TUBFLG2,TUBLNUMN    TEST FOR SEQ NUMBERS          S21085 36030021
         BZ    MVCLGN1             IF NOT, MOVE CHARS            S21085 36060021
         MVC   0(LONGLINE,USRBUFAD),LNOFFSET(RAFBUFAD)                  36100019
         B     MVCLGN2             FREE BUFFER                   S21085 36120021
MVCLGN1  EQU   *                                                 S21085 36140021
         MVC   0(LNGLNUM,USRBUFAD),LNOFFSET(RAFBUFAD)            S21085 36160021
MVCLGN2  EQU   *                                                 S21085 36180021
         LM    R0,R1,0(RAFBUFAD)   PROVIDE BFR ADDRESS AND SIZE         36200019
         FREEMAIN  R,LV=(0),A=(1)  FREE BUFFER                          36300019
         B     WRITLINE            PROCEED TO WRITE LINE                36400019
MOVEBLNK EQU   *                                                        36500019
         MVC   LASTLNNO,DFLTSTRT   SET LAST LINE NUMBER TO ZERO         36600019
         MVI   0(USRBUFAD),MX40    INVERT BLANK CHARACTER               36700019
         TM    TUBFLG2,TUBLNUMN  TEST FOR SEQ NUMBERS                   36730003
         BZ    MVCBLK2   IF NOT, MOVE CHARACTERS               OS66699  36760028
         MVC   1(BLNKLINE,USRBUFAD),0(USRBUFAD)  FILL WITH BLANKS       36800019
         B     WRITLINE                                                 36900019
MVCBLK2  MVC  1(BLNKLIN2,USRBUFAD),0(USRBUFAD) FILL WITH BLANKS         36930003
         B     WRITLINE                                        OS66699  36960028
WRTLDSLN EQU   *                                                        37000019
         LA    R5,LDSLNLNG         SET LINE LENGTH FOR LDS LINE         37100019
         MVC   0(SHRTLINE,USRBUFAD),KEYOFFST(RAFBUFAD)                  37200019
 EJECT                                                                  37300019
***********************************                                     37400019
*                                                                       37500019
* WRITE LINE TO USER                                                    37600019
*                                                                       37700019
***********************************                                     37800019
 SPACE                                                                  37900019
WRITLINE EQU   *                                                        38000019
         STH   R5,TUBDATAL         SET DATA LENGTH IN TUB               38100019
         LR    R15,TUBPT           PROVIDE POINTER TO TUB               38200019
         CWRITE                                                         38300019
         LTR   R15,R15             TEST FOR ERROR                       38400019
         BNZ   RTRNBAD1            RETURN CODE FOR LINE ERROR           38500019
         CLC   LASTLNNO,DFLTSTRT   IF LAST LINE NUMBER EQUALS ZERO,     38600019
         BE    RTRNGOOD            RETURN                               38700019
 SPACE                                                                  38800019
***********************************                                     38900019
*                                                                       39000019
* SET SWITCH TO INDICATE SUCCESSFUL LISTING OF A LINE                   39100019
*                                                                       39200019
***********************************                                     39300019
 SPACE                                                                  39400019
         OI    0(PPTAD),NSRTCOMP   INDICATE LINE INSERTION COMPLETED    39500019
         B     GETLINE1            RETURN TO GET NEXT LINE              39600019
 EJECT                                                                  39700019
***********************************                                     39800019
*                                                                       39900019
* ADVANCE PPT POINTER TO THE NEXT OPERAND AND TEST FOR LAST OPERAND     40000019
*                                                                       40100019
***********************************                                     40200019
 SPACE                                                                  40300019
NEXTTEST EQU   *                                                        40400019
         XR    INCR,INCR           CLEAR REG OF INCREMENT               40500019
         NI    0(PPTPT),INCRONLY   ISOLATE INCRENENT OF OPND COUNT      40600019
INCRONLY EQU   X'3F'               MASK USED TO ISOLATE OPERAND COUNT   40700019
         IC    INCR,0(,PPTPT)      OBTAIN LENGTH OF PARAMETER FIELD     40800019
         LA    PPTPT,1(INCR,PPTPT) INCREMENT PPT POINTER                40900019
FRSTTEST EQU   *                                                        41000019
         LA    OPNDCTR,1(,OPNDCTR) INCREMENT PARAMETER COUNTER BY 1     41100019
RETEST   EQU   *                                                        41200019
         TM    0(PPTPT),MXFF       TEST FOR LAST OPERAND                41300019
         BNO   0(INNERBR)          IF NO OPERAND, RETURN                41400019
         L     PPTESTRG,PPTCHAD    OBTAIN ADDR FLD OF NEXT PPT IN CHAIN 41500019
         LA    PPTESTRG,0(PPTESTRG)                                     41600019
         LTR   PPTESTRG,PPTESTRG   TEST FOR PRESENTS OF ADDRESS         41700019
         BZ    CHKERRSW            IF NO ADDRESS, CHECK ERROR SWITCH    41800019
         OC    0(1,PPTESTRG),0(PPTAD)   MOVE FLAGS TO NEXT PPT          41900019
         LR    PPTAD,PPTESTRG      CHANGE POINTER TO NEXT PPT           42000019
         LA    PPTPT,PPTPARS       OBTAIN ADDRESS OF PARAMETER FLD      42100019
         B     RETEST                                                   42200019
 EJECT                                                                  42300019
***********************************                                     42400019
*                                                                       42500019
* TEST FOR ALL NUMERIC ZONES IN FIELD                                   42600019
*                                                                       42700019
***********************************                                     42800019
 SPACE                                                                  42900019
ALLNUMCK EQU   *                                                        43000019
         ST    PPTPT,TUBPARM1      STORE POINTER TO FIELD BYTE COUNT    43100019
         LA    PARMPT,1(PPTPT)                                          43200019
         ST    PARMPT,TUBPARM2     STORE POINTER TO OPERAND FIELD       43300019
CALLNUM  EQU   *                                                        43400019
         LA    PARMPT,TUBNXKEY                                          43500019
         ST    PARMPT,TUBPARM3     STORE POINTER TO RETURN FIELD        43600019
         OI    TUBPARM3,MX80       SET LAST PARAMETER FLAG              43700019
         LA    PARMPT,TUBPRMLS     SET POINTER TO PARAMETER LIST        43800019
         L     R15,IHKYYNUM                                             43900019
         BALR  R14,R15             BRANCH TO IHKNUM                     44000019
         LTR   R15,R15             TEST FOR ALL NUMBERS IN PARAM. FIELD 44100019
         BNZ   NUMTEST             IF NOT ALL NO'S, CHECK FOR NUM/NONUM 44200019
         BR    INNERBR             RETURN                               44300019
 EJECT                                                                  44400019
***********************************                                     44500019
*                                                                       44600019
* PREPARE MESSAGE FOR INVALIDE RANGE OF LINE NUMBERS                    44700019
*                                                                       44800019
***********************************                                     44900019
 SPACE                                                                  45000019
ERRRANGE EQU   *                                                        45100019
         LA    MSGCODE,MSGRANGE    LOAD CODE FOR INVALID RANGE          45200019
         B     MSGEXIT             CALL MESSAGE WRITER AND EXIT         45300019
 SPACE                                                                  45400019
***********************************                                     45500019
*                                                                       45600019
* PREPARE ERROR MESSAGE FOR NON-EXISTANT LINE NUMBER                    45700019
*                                                                       45800019
***********************************                                     45900019
 SPACE                                                                  46000019
ERRLNTFD EQU   *                                                        46100019
         LA    R4,STRTLNNO         PROVIDE ADDRESS TO STARTING NUMBER   46200019
         BAL   INNERBR,BLANKZRO    BLANK THE LEADING ZEROS IN NUMBER    46300019
         LA    MSGCODE,STRTLNNO-1  OBTAIN ADDRESS FOR LENGTH CODE       46400019
         MVI   0(MSGCODE),MX08     SET LENGTH CODE OF LINE NUMBER       46500019
         ST    MSGCODE,TUBPARM4    PROVIDE MESSAGE CODE                 46600019
         OI    TUBPARM4,MX80       SET LAST PARAMETER FLAG              46700019
         LA    MSGCODE,MSGLNTFD    MESSAGE CODE FOR LINE NOT FOUND      46800019
         B     MSGEXIT             CALL MESSAGE WRITER AND EXIT         46900019
 SPACE                                                                  47000019
***********************************                                     47100019
*                                                                       47200019
* CHECK FOR PREVIOUS INSERTS OF LINES TO THE USER TO DETERMINE          47300019
* IF ANY LINES WERE FOUND IN THE RANGE SPECIFIED                        47400019
*                                                                       47500019
***********************************                                     47600019
 SPACE                                                                  47700019
INSRTCHK EQU   *                                                        47800019
         TM    0(PPTAD),NSRTCOMP   TEST FOR PREVIOUS INSERTION OF LINE  47900019
         BO    RTRNGOOD            IF INSERT WAS MADE, END NORMALLY     48000019
 SPACE                                                                  48100019
***********************************                                     48200019
*                                                                       48300019
* ENQUEUE MESSAGE FOR LINE NOT FOUND WITHIN RANGE REQUESTED             48400019
*                                                                       48500019
***********************************                                     48600019
 SPACE                                                                  48700019
ERRNOLIN EQU   *                                                        48800019
         LA    MSGCODE,MSGNOLIN    LOAD  CODE FOR NO LINE               48900019
MSGEXIT  EQU   *                                                        49000019
         BAL   INNERBR,CALLMSG1                                         49100019
         B     RTRNGOOD            RETURN                               49200019
 EJECT                                                                  49300019
***********************************                                     49400019
*                                                                       49500019
* PREPARE AND SEND A MESSAGE INDICATING AN INVALID OPERAND              49600019
*                                                                       49700019
***********************************                                     49800019
 SPACE                                                                  49900019
ERRNOPND EQU   *                                                        50000019
         BAL   INNERBR,MSGNSRT     INSERT INTO MESSAGE                  50100019
         LA    MSGCODE,MSGNOPND    MESSAGE CODE FOR INVALID OPERAND     50200019
         BAL   INNERBR,CALLMSG1                                         50300019
         STC   R0,0(PPTPT)         RESTORE   LENGTH BYTE TO PPT         50400019
         OI    0(PPTAD),ERRORSW    INDICATE ERROR                       50500019
         B     LASTTEST            CONTINUE TO TEST OPERANDS            50600019
 SPACE                                                                  50700019
***********************************                                     50800019
*                                                                       50900019
* PREPARE AND SEND MESSAGE TO USER INDICATING EXCESSIVE OPERANDS        51000019
*                                                                       51100019
***********************************                                     51200019
 SPACE                                                                  51300019
ERREXCSS EQU   *                                                        51400019
         BAL   INNERBR,MSGNSRT     INSERT INTO MESSAGE                  51500019
         LA    MSGCODE,MSGEXCSS    MESSAGE CODE FOR EXCESSIVE OPERANDS  51600019
         BAL   INNERBR,CALLMSG1    SEND MESSAGE TO USER                 51700019
         STC   R0,0(PPTPT)         RESTORE OPERAND LENGTH               51800019
         B     RTRNGOOD                                                 51900019
 SPACE 2                                                                52000019
***********************************                                     52100019
*                                                                       52200019
* INSERT TEXT INTO MESSAGE                                              52300019
*                                                                       52400019
***********************************                                     52500019
 SPACE                                                                  52600019
MSGNSRT  EQU   *                                                        52700019
         NI    0(PPTPT),INCRONLY   ISOLATE THE OPERAND LENGTH           52800019
         IC    R0,0(PPTPT)         SAVE LENGTH BYTE FROM PPT            52900019
         CLI   0(PPTPT),MAXINSRT   TEST FOR LENGTH TOO GREAT            53000019
         BNH   ACCPTABL            IF LENGTH NOT TOO GREAT, ACCEPABLE   53100019
         MVI   0(PPTPT),MAXINSRT   REPLACE LENGTH WITH MAXIMUM          53200019
ACCPTABL EQU   *                                                        53300019
         ST    PPTPT,TUBPARM4      PROVIDE POINTER TO BAD PARM.         53400019
         OI    TUBPARM4,MX80       SET LAST PARM FLAG                   53500019
         BR    INNERBR             RETURN                               53600019
 EJECT                                                                  53700019
***********************************                                     53800019
*                                                                       53900019
* BLANK OUT LEADING ZEROS                                               54000019
*                                                                       54100019
***********************************                                     54200019
 SPACE                                                                  54300019
BLANKZRO EQU   *                                                        54400019
         LA    R6,BLANKCNT         CREATE COUNT FOR LOOP CONTROL        54500019
BLANKNUM EQU   *                                                        54600019
         CLI   0(R4),MXF0          COMPARE DIGET, UPDATE USRBUF PTR     54700019
         BNE   0(INNERBR)          RETURN                               54800019
         MVI   0(R4),MX40          INSERT BLANK CHARACTER               54900019
         LA    R4,1(R4)            INCREMENT DIGET POINTER              55000019
         BCT   R6,BLANKNUM         LOOP CONTROL FOR FIRST SIX DIGETS    55100019
         L     R4,TUBPPTAD         RESTORE R4 AS BASE FOR PPT    A42682 55150000
         BR    INNERBR             RETURN                               55200019
 EJECT                                                                  55300019
***********************************                                     55400019
*                                                                       55500019
* CALL FOR MESSAGE WRITER TO USER                                       55600019
*                                                                       55700019
***********************************                                     55800019
 SPACE                                                                  55900019
CALLMSG1 EQU   *                                                        56000019
         ST    MSGCODE,TUBPARM3    PROVIDE POINTER TO MSG CODE          56100019
         MVC   TUBPARM3(1),0(MSGCODE)  LAST PARAMETER FLAG IF APPROP.   56200019
         LA    MSGCODE,TUBUSRID                                         56300019
         ST    MSGCODE,TUBPARM2    PROVIDE POINTER TO USER ID           56400019
         ST    TUBPT,TUBPARM1      PROVIDE POINTER TO TUB               56500019
         LA    PARMPT,TUBPRMLS     PROVIDE POINTER TO PARAMETER LIST    56600019
         L     R15,IHKYMSG1        BRANCH TO IHKMSG01                   56700019
         BALR  R14,R15             BRANCH TO IHKMSG01                   56800019
         LTR   R15,R15             TEST FOR ZERO RETURN CODE            56900019
         BNZ   RETURN              IF NON-ZERO RETURN CODE, RETURN      57000019
         BR    INNERBR             NO ERROR, RETURN TO CALLING POINT    57100019
 EJECT                                                                  57200019
***********************************                                     57300019
*                                                                       57400019
* SET RETURN CODES AND RETURN                                           57500019
*                                                                       57600019
***********************************                                     57700019
 SPACE                                                                  57800019
RTRNBAD2 EQU   *                                                        57900019
         LA    R15,GTMNFAIL        RETURN CODE FOR FAILURE OF GETMAIN   58000019
         B     RETURN                                                   58100019
 SPACE                                                                  58200019
RTRNBAD1 EQU   *                                                        58300019
         LA    R15,LINEERR         RETURN CODE FOR LINE ERROR           58400019
         B     RETURN                                                   58500019
 SPACE                                                                  58600019
RTRNGOOD EQU   *                                                        58700019
         LA    R15,NOERROR         RETURN CODE FOR NO ERROR             58800019
 SPACE 2                                                                58900019
RETURN   EQU   *                                                        59000019
         L     R11,CALLNGSA(R13)   LOAD ADDRESS OF CALLING SAVE AREA    59100019
         ST    R15,RTRNCODE(0,R11) SAVE RETURN CODE IN CALLNG SAVE AREA 59200019
         CLI   PPTPARS,LDSCODE     TEST FOR LDS/LIB LISTING             59300019
 SPACE 2                                                                59400019
         BNE   ENDUP               IF NOT, PROCEED TO ENDUP             59500019
         LA    R1,PTTUBPT(0,R13)   LOAD POINTER TO TUB POINTER          59600019
         RELEASE A                 RELEASE ACTIVE AREA                  59700019
         B     *+4(R15)            EVALUATE RETURN CODE                 59800019
         B     ENDUP               NO ERRORS, ENDUP                     59900019
         B     ENDUP                                                    60000019
         BC    0,*+4               GETMAIN FAILURE                      60100019
         L     R1,RTRNCODE(0,R11)  OBTAIN CURRANT RETURN CODE           60200019
         CLI   R1,AAIOFAIL         TEST FOR CURRANT I/O ERROR CODE      60300019
         BE    ENDUP               IF I/O ERROR INDICATED, RETAIN CODE  60400019
         ST    R15,RTRNCODE(0,R11) IF NOT I/O ERROR, SET NEW CODE       60500019
 EJECT                                                                  60600019
***********************************                                     60700019
*                                                                       60800019
* TERMINATE AND RETURN                                                  60900019
*                                                                       61000019
***********************************                                     61100019
 SPACE                                                                  61200019
ENDUP    EQU     *                                                      61300019
         LA    R1,PTTUBPT(0,R13)   LOAD POINTER TO TUB POINTER          61400019
         ENDUP                                                          61500019
         B     *+4(R15)            EVALUATE RETURN CODE                 61600019
         B     FREENEED            NO ERROR, PROCEED TO FREE SAVE AREA  61700019
         B     FREENEED            PROCEED TO FREE SAVE AREA            61800019
         BC    0,*+4               GETMAIN FAILURE                      61900019
         L     R1,RTRNCODE(0,R11)  OBTAIN CURRANT RETURN CODE           62000019
         CLI   R1,AAIOFAIL         TEST FOR CURRANT I/O ERROR CODE      62100019
         BE    FREENEED            IF I/O ERROR INDICATED, RETAIN CODE  62200019
         ST    R15,RTRNCODE(0,R11) IF NOT I/O ERROR, SET NEW CODE       62300019
FREENEED EQU   *                                                        62400019
         FREEMAIN  R,LV=NEED,A=(R13)   FREE SAVE AREA                   62500019
         LR    R13,R11             RESTORE ADDRESS OF CALLING SAVE AREA 62600019
         RETURN (14,12),T          RETURN TO LINE ADMINISTRATOR         62700019
 EJECT                                                                  62800019
***********************************                                     62900019
*                                                                       63000019
*        EQUATES                                                        63100019
*                                                                       63200019
***********************************                                     63300019
 SPACE 2                                                                63400019
NEED     EQU   88                  NEEDED SPACE FOR SAVE & WORK AREAS   63500019
PTTUBPT  EQU   28                  DISPLACEMENT OF PT TO TUB PT IN S A  63600019
MAXINSRT EQU   10                  MAXIMUM LENGTH OF MESSAGE INSERT     63700019
BLANKCNT EQU   6                   COUNT OF DIGETS TO BE BLANKED        63800019
EXCSOPND EQU   3                   EXCESSIVE OPERAND COUNTER TEST       63900019
BLANKLNG EQU   2                   NUMBER OF BLANK SPACES IN HEADER     64000019
MX40     EQU   X'40'               VALUE OF BLANK CHARACTER             64100019
 SPACE                                                                  64200019
NOERROR  EQU   0                   RETURN CODE FOR NO ERROR             64300019
LINEERR  EQU   4                   RETURN CODE FOR LINE ERROR           64400019
GTMNFAIL EQU   8                   RETURN CODE FOR FAILURE OF GETMAIN   64500019
AAIOFAIL EQU   12                  RETURN CODE FOR ACTIVE AREA I/O ERR  64600019
 SPACE                                                                  64700019
KEYLNG   EQU   8                   LENGTH OF KEY NUMBER IN HEADER       64800019
HDRLNG   EQU   10                  HEADER LENGTH                        64900019
 SPACE                                                                  65000019
KEYOFFST EQU   8                   OFFSET  OF KEY IN RAFIO BUFFER       65100019
LNOFFSET EQU   16                  OFFSET OF LINE IN RAFIO BUFFER       65200019
 SPACE                                                                  65300019
NSEQLINE EQU   8                   LENGTH OF LINE FOR NO SEQUENCE NUMS  65400019
BLNKLINE EQU   47                  LENGTH OF LINE FOR BLANKING   S21085 65450021
BLNKLIN2 EQU 39                                                OS66699  65470028
*                                  OUT  LONG LINE AREA           S21085 65500021
LONGLINE EQU   48                  LENGTH OF LINE FOR LONG LINE  S21085 65550021
*                                  LIST                          S21085 65600021
LNGLNUM  EQU   40                  LENGTH OF LONG LST W/SEQ NO   S21085 65650021
SHRTLINE EQU   72                  LENGTH OF LINE FOR NONUM OPERAND     65700019
FULLLINE EQU   80                  LENGTH OF LINE FOR NUM OPERAND       65800019
LDSLNLNG EQU   70                                                       65900019
 SPACE                                                                  66000019
MXF0     EQU   X'F0'               MASK USED TO CHECK FOR ZERO DIGET    66100019
INTFLAGS EQU   X'FF'               MASK TO INITIALIZE FLAG BYTE         66200019
MXFF     EQU   X'FF'               MASK TO TEST FOR END OF OPND STRING  66300019
MX7F     EQU   X'7F'               MASK TO TEST FOR TUBLNO              66400019
MX80     EQU   X'80'               MASK TO SET LAST PARM FLAG TO ON     66500019
NSRTCOMP EQU   X'02'               MASK FOR COMPLETED LINE INSERT       66600019
ERRORSW  EQU   X'04'               MASK FOR ERROR SWITCH                66700019
MX08     EQU   X'08'               MASK FOR DISCONTINUE FLAG            66800019
LDSCODE  EQU   X'BD'               MASK FOR TESTING LDS/LIB TYPE LIST   66900019
 SPACE                                                                  67000019
LGNALLOC EQU   0                   DISPLACEMENT OF LENGTH ALLOCATION    67100019
CALLNGSA EQU   4                   DISPLACEMENT OF CALLING SAVE AREA PT 67200019
CALLEDSA EQU   8                   DISPLACEMENT OF CALLED  SAVE AREA PT 67300019
RETURNPT EQU   12                  DISPLACEMENT OF RETURN POINTER       67400019
ENTRYPT  EQU   16                  DISPLACEMENT OF ENTRY  POINTER       67500019
RTRNCODE EQU   16                  DISPLACEMENT OF RETURN CODE IN SV AR 67600019
SAVEREGS EQU   20                  DISPLACEMENT OF REGISTERS SAVED      67700019
 EJECT                                                                  67800019
***********************************                                     67900019
*                                                                       68000019
*        MESSAGE NUMBER CONSTANTS                                       68100019
*                                                                       68200019
***********************************                                     68300019
 SPACE 2                                                                68400019
         CNOP  0,4                                                      68500019
MSGNOPND EQU   *                   MESSAGE CODE FOR OPERAND INVALID     68600019
         DC    X'00F3F0F2'                                              68700019
MSGEXCSS EQU   *                   MESSAGE CODE FOR EXCESSIVE OPERANDS  68800019
         DC    X'00F3F3F4'                                              68900019
MSGLNTFD EQU   *                   MESSAGE CODE FOR LINE NOT FOUND      69000019
         DC    X'00F3F4F9'                                              69100019
MSGNOLIN EQU   *                   MESSAGE CODE FOR NO LINES IN RANGE   69200019
         DC    X'80F3F4F0'                                              69300019
MSGRANGE EQU   *                   MESSAGE CODE FOR INVALID RANGE OF NO 69400019
         DC    X'80F3F6F7'                                              69500019
 EJECT                                                                  69600019
***********************************                                     69700019
*                                                                       69800019
*        CONSTANTS                                                      69900019
*                                                                       70000019
***********************************                                     70100019
 SPACE 2                                                                70200019
         DS    0F                  ALIGNMENT                            70300019
DFLTSTRT DC    8X'00'              DEFAULT STARTING LINE NUMBER         70400019
DFLTLAST DC    8X'FF'              DEFAULT ENDING LINE NUMBER           70500019
BLANKSPC DC    X'4040'             BLANK SPACES FOR THE HEADER          70600019
NUMTST   DC    X'03D5E4D4'         MASK FOR TESTING NUM OPERAND         70700019
NONUMTST DC    X'05D5D6D5E4D4'     MASK FOR TESTING NONUM OPERAND       70800019
 EJECT                                                                  70900019
***********************************                                     71000019
*                                                                       71100019
*        DSECTS                                                         71200019
*                                                                       71300019
***********************************                                     71400019
 SPACE 2                                                                71500019
LISTSAVE DSECT                                                          71600019
         DS    0D                  ALIGNMENT                            71700019
SAVEAREA DS    18F                 LIST SAVE AREA FOR REGS AND LINKAGE  71800019
LASTLNNO DS    CL8                 ENDING LINE NUMBER                   71900019
STRTLNNO DS    CL8                 STARTING LINE NUMBER                 72000019
 EJECT                                                                  72100019
         IHKCDSCT   TUB=YES                                             72200019
         IHKCDSCT   AVT=YES                                             72300019
         IHKCDSCT   DIR=YES                                             72400019
         IHKCDSCT  PPT=YES                                              72500019
         IHKCDSCT  DEF=YES                                              72600019
         CMDEQU                                                         72700019
*                                                                       72800019
         ENTRY IHKLST                                                   72900019
         END                                                            73000019
