MAA      TITLE 'IHKMAA - MERGE COMMAND PROCESSOR'                       00100019
*********************************************************************** 00200019
*STATUS                                                               * 00300019
*   CHANGE LEVEL 0                                                    * 00400019
*FUNCTION                                                             * 00500019
*   THIS MODULE HANDLES THE MERGING OF ACTIVE AREA LINES.  IF A       * 00600019
*   UTILITY FILE EXISTS, THE LINES UP TO AND INCLUDING THE LINE AFTER * 00700019
*   WHICH THE MERGE IS TO BE MADE, ARE MOVED TO THE NEW ACTIVE FILE.  * 00800019
*   IF A RANGE OF LINES HAS BEEN SPECIFIED, THE LINES WITHIN THE RANGE* 00900019
*   ARE COPPIED TO THE END OF THE ACTIVE FILE AND RESEQUENCED.  IF NO * 01000019
*   RANGE WAS SPECIFIED, THE ENTIRE ACTIVE OR UTILITY FILE IS COPPIED * 01100019
*   TO THE END OF THE ACTIVE FILE.                                    * 01200019
*   IF A MERGE AFTER A LINE NUMBER WAS SPECIFIED, THE REST OF THE     * 01300019
*   LINES IN THE UTILITY FILE ARE COPPIED TO THE END OF THE ACTIVE    * 01400019
*   FILE AND RESEQUENCED.  CONTROL IS THEN RETURNED TO THE CALLING    * 01500019
*   ROUTINE                                                           * 01600019
*ENTRY POINT                                                          * 01700019
*        IHKMAA TO MERGE LINES FROM THE ACTIVE FILE                   * 01800019
*INPUT                                                                * 01900019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING THE * 02000019
*   ADDRESSES OF THE TUB AND AVT.                                     * 02100019
*OUTPUT                                                               * 02200019
*   N/A                                                               * 02300019
*EXTERNAL REFFERENCES                                                 * 02400019
*        IHKAFI - TO MANIPULATE THE ACTIVE AND UTILITY FILES          * 02500019
*        IHKMSG - TO QUEUE MESSAGES FOR THE USER                      * 02600019
*EXITS, NORMAL                                                        * 02700019
*   RETURN TO CALLING ROUTINE WITH 0 IN REGISTER 15                   * 02800019
*EXITS, ERROR                                                         * 02900019
*   RETURN TO CALLING ROUTINE WITH ONE OF THE FOLLOWING RETURN CODES  * 03000019
*   IN REGISTER 15                                                    * 03100019
*   8  - GETMAIN FAILURE                                              * 03200019
*   12 - ACTIVE AREA I/O ERROR                                        * 03300019
*   16 - MESSAGE LOST                                                 * 03400019
*   20 - ACTIVE AREA OUT OF SPACE                                     * 03500019
*TABLES/WORK AREAS                                                    * 03600019
*   18 WORD SAVE AREA                                                 * 03700019
*   88 BYTE WORK AREA                                                 * 03800019
*   TUB                                                               * 03900019
*   TUBLNUMN - INDICATES LINE NUMBERS CONTAINED IN LINE               * 04000019
*   TUBPPTAD - CONTAINS ADDRESS OF PPT                                * 04100019
*   TUBUFFAD - CONTAINS ADDRESS OF USER                               * 04200019
*   TUBNXKEY - ACTIVE FILE POINTER                                    * 04300019
*   TUBCNTFS - NUMBER OF LINES IN BUFFER                              * 04400019
*   TUBGBLKY - UTILITY FILE POINTER                                   * 04500019
*   TUBPRMLS - PARAMETER AND WORK AREA                                * 04600019
*   TUBRAFBF - CONTAINS ADDRESS OF IHKAFI BUFFER                      * 04700019
*   PPT - CONTAINS PROCESSING SWITCHES                                * 04800019
*   USER BUFFER - WORK AREA                                           * 04900019
*   888 BYTE IHKAFI BUFFER                                            * 05000019
*ATTRIBUTES                                                           * 05100019
*   REENTRANT AND NONRESIDENT                                         * 05200019
*********************************************************************** 05300019
         EJECT                                                          05400019
IHKMAA   CSECT                                                          05500019
*********************************************************************** 05600019
*          REGISTER EQUATES                                             05700019
*********************************************************************** 05800019
REG0     EQU   0                                                        05900019
REG1     EQU   1                                                        06000019
AVTR     EQU   2                                                        06100019
TUBR     EQU   3                                                        06200019
PARMR    EQU   4                                                        06300019
PPTR     EQU   5                                                        06400019
REG6     EQU   6                                                        06500019
REG7     EQU   7                                                        06600019
REG8     EQU   8                                                        06700019
REG9     EQU   9                                                        06800019
REG10    EQU   10                                                       06900019
BASE     EQU   11                                                       07000019
REG12    EQU   12                                                       07100019
REG13    EQU   13                                                       07200019
REG14    EQU   14                                                       07300019
REG15    EQU   15                                                       07400019
         SPACE 3                                                        07500019
*********************************************************************** 07600019
*          EQUATES                                                      07700019
*********************************************************************** 07800019
BGNAA    EQU   X'00'                    BEGNING OF ACTIVE FILE          07900019
ENDAA    EQU   X'FF'                    END OF ACTIVE FILE              08000019
NUMZONE  EQU   X'F0'                    NUMERIC ZONE PATTERN            08100019
ENDLST   EQU   X'80'                    END OF PARAMETER LIST           08200019
BUFLEN   EQU   888                      BUFFER LENGTH                   08300019
BUFCTLF  EQU   X'7F'                    TURN OFF BUFFER CTL SW          08400019
BLK      EQU   X'40'                                                    08500019
GOODRET  EQU   0                        GOOD RETURN CODE                08600019
OUTSPRC  EQU   20                       AA OUT OF SPACE RETURN CODE     08700019
AAIOERRC EQU   12                       AA I/O ERROR RETURN CODE        08800019
UFNUM    EQU   X'07'                    UTILITY FILE NUMBER             08850019
         SPACE 3                                                        08900019
         SAVE  (14,12),,IHKMAA-5/21/70                                  09000019
         LR    BASE,REG15               SET UP BASE REGISTER            09100019
         USING IHKMAA,BASE                                              09200019
         L     AVTR,4(REG1)             GET AVT ADDRESS                 09300019
         USING AVTDSECT,AVTR            SET UP ADDRESSABILITY FOR AVT   09400019
         L     TUBR,0(REG1)             GET ADDR OF TUB                 09500019
         USING TUBDSECT,TUBR            ESTABLISH ADDRESSABILITY FOR    09600019
*                                         TUB                           09700019
         L     PPTR,TUBPPTAD            GET ADDRESS OF PPT              09800019
         USING PPTDSECT,PPTR            SET UP ADDRESSABILITY FOR PPT   09900019
         L     REG10,PPTFLG+8           GET AREA ADDRESS                10000019
         ST    REG13,4(REG10)           CHAIN SAVE AREAS                10100019
         ST    REG10,8(REG13)                                           10200019
         LR    REG13,REG10              GET SAVE AND WORK AREA ADDR     10300019
         USING VDSECT,REG13             ESTABLISH ADDRESSABILITY FOR    10400019
*                                         SAVE AND WORK AREAS           10500019
         L     PARMR,TUBUFFAD           GET ADDRESS OF PARAMETERS       10600019
         USING PARMDCT,PARMR            SET UP ADDRESSABILITY FOR       10700019
*                                         PARAMETERS                    10800019
         NI    PPTFLG,PPTOFF            TURN OFF UNUSED PPT SWITCHES    10900019
         TM    PPTFLG,PPTUTIL           TEST FOR UTILITY FILE           11000019
         BZ    TSTAA                    IF NOT, START 2ND PASS          11100019
         BAL   REG6,PTBGNUF             POINT TO BEGNING OF UTILTY FILE 11200019
         LA    REG1,32(REG13)           BUILD PARAMETER LIST FOR IHKAFI 11300019
         RGET  XK,S,A,FTYPE=GBL         GET 1ST LINE NUMBER             11400019
         C     REG15,F4                 TEST RETURN CODE                11500019
         BH    RETURN3                  IF ERROR, RETURN                11600019
         BAL   REG6,ENDUPUF             ENDUP UTILITY FILE              11700019
         CLC   TUBGBLKY,AFTLINE         TEST FOR BEGNING MERGE          11800019
         BH    TSTAA                    IF NOT, CONTINUE                11900019
         OI    PPTFLG,PPT1PAS           SET 1ST PASS SWITCH             12000019
         B     SWGETS2                  GET LINES FROM UTILTITY FILE    12100019
TSTAA    BAL   REG6,PTENDAA             POINT TO END OF ACTIVE AREA     12200019
         TM    PPTFLG,PPTRANGE          TEST FOR RANGE MERGE            12300019
         BO    TSTAA1                   IF YES, SKIP NULL FILE TEST     12400019
         CLI   TUBNXKEY+7,ENDAA         TEST FOR NULL FILE              12500019
         BE    SWGETS1                  IF YES, TEST FOR UTIL FILE      12600019
TSTAA1   MVC   PPTPARS(8),TUBNXKEY      SAVE LAST LINE NUMBER           12700019
         BAL   REG6,ENDUPAA             ENDUP FILE                      12800019
TSTRNG   TM    PPTFLG,PPTRANGE          TEST FOR RANGE MERGE            12900019
         BO    PTRANGE                  IF YES, POINT TO 1ST LINE OF    13000019
*                                         RANGE                         13100019
         TM    PPTFLG,PPTUTIL           TEST FOR UTILITY FILE           13200019
         BO    SWGETS2                  IF YES, GET LINES FROM UTILITY  13300019
         LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      13400019
         MVI   TUBNXKEY+7,BGNAA         INDICATE BEGINING FOR A.A.      13500019
*                                       POINT TO THE BEGNING OF THE     13600019
         RPOINT B,NR              ACTIVE FILE                           13700019
*    TEST RETURN                                                        13800019
TSTRET   C     REG15,F4                 TEST RETURN CODE                13900019
         BH    RETURN3                  IF ERROR, RETURN                14000019
GETAA    LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      14100019
         SR    REG8,REG8                                                14200019
         MVC   TUBCNTFS,H10             SET UP COUNT FOR IHKAFI         14300019
         RGET  R,M,A                    GET A BLOCK FROM ACTIVE AREA    14400019
*    TEST RETURN                                                        14500019
         IC    REG8,TUBCNTFS       GET NUMBER OF LINES                  14600019
         LR    REG9,REG8                SAVE NO OF LINES                14700019
         C     REG15,F4                 TEST RETURN CODE                14800019
         BH    RETURN3                  IF ERROR, RETURN                14900019
         BE    SWGETS1                  IF EOD, TEST FOR UTILITY FILE   15000019
         BAL   REG6,ENDUPAA             ISSUE ENDUP                     15100019
INSLNO   BAL   REG14,CALCLNO            CALC AND INSERT LINE NOS        15200019
         BAL   REG6,INSAA               INSERT LINES INTO THE ACTIVE    15300019
*                                         AREA                          15400019
         TM    PPTFLG,PPTUGET           TEST FOR LINES FROM UTILITY     15500019
*                                         FILE                          15600019
         BO    GETUTIL                  IF YES, GET FROM UTILITY FILE   15700019
         MVC   TUBNXKEY,PPTPARS+8       GET LAST LINE NO OF LAST BLOCK  15800019
         LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      15900019
*                                       POINT AFTER LAST LINE OF        16000019
         RPOINT A,NR                    LAST BLOCK                      16100019
*    TEST RETURN                                                        16200019
         C     REG15,F4                 TEST RETURN CODE                16300019
         BH    RETURN3                  IF ERROR, RET1RN                16400019
         B     GETAA                    GET BLOCK FROM ACTIVE AREA      16500019
         SPACE 3                                                        16600019
*********************************************************************** 16700019
*          SET UP FOR MERGE OF RANGE OF LINES                           16800019
*********************************************************************** 16900019
PTRANGE  TM    PPTFLG,PPTUTIL           TEST FOR 1ST LINE OF RANGE IN   17000019
*                                         ACTIVE AREA                   17100019
         BZ    PTBFAA                   IF YES, POINT BEFORE LINE NO    17200019
***************                                                         17300019
*    IF NOT IN ACTIVE AREA, POINT BEFORE LINE NO IN UTILITY FILE        17400019
         OI    PPTFLG,PPTUGET           SET UTILITY FILE GET SW         17500019
         LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      17600019
         MVC   TUBGBLKY,FSTLINE         PUT LINE NO INTO TUB KEY AREA   17700019
         RPOINT B,NR,FTYPE=GBL          POINT BEFORE LINE               17800019
*    TEST RETURN                                                        17900019
         C     REG15,F4                 TEST RETURN CODE                18000019
         BL    GETBLKUF                 IF GOOD, GET BLOCK FROM FILE    18100019
         BH    RETURN3                  IF ERROR, RETURN                18200019
         LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      18300019
         RPOINT A,NR,KEY=HIEQ,FTYPE=GBL   POINT AFTER PREVIOUS LINE     18400019
         C     REG15,F4                 TEST RETURN CODE                18500019
         BH    RETURN3                  IF ERROR, RETURN                18600019
GETBLKUF BAL   REG6,RGETUF              GET BLOCK FROM UTILITY FILE     18700019
         B     INSLNO                   INSERT LINES INTO ACTIVE AREA   18800019
         SPACE 1                                                        18900019
***************                                                         19000019
*    SET UP TO GET BLOCK FROM UTILITY FILE                              19100019
*                                       POINT AFTER LAST LINE OF        19200019
GETUTIL  BAL   REG6,PTAFTUF             LAST BLOCK                      19300019
         B     GETBLKUF                 GET BLOCK                       19400019
         SPACE 1                                                        19500019
***************                                                         19600019
*    POINT BEFORE LINE IN ACTIVE AREA                                   19700019
*                                                                       19800019
PTBFAA   LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      19900019
         MVC   TUBNXKEY,FSTLINE         PUT LINE NO INTO TUB KEY AREA   20000019
         RPOINT B,NR                    POINT BEFORE LINE NO            20100019
*    TEST RETURN                                                        20200019
         C     REG15,F4                 TEST RETURN CODE                20300019
         BL    GETAA                    IF GOOD, GET BLOCK FROM ACT FLE 20400019
         BH    RETURN3                  IF ERROR, RETURN                20500019
***************                                                         20600019
*    IF NONE OF THE ABOVE, LINE WAS NOT FOUND                           20700019
         LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      20800019
         RPOINT A,NR,KEY=HIEQ           POINT AFTER PREVIOUS LINE       20900019
         B     TSTRET                   TEST RETURN AND CONTINUE        21000019
         SPACE 1                                                        21100019
         SPACE 3                                                        21200019
*********************************************************************** 21300019
*          ROUTINE TO SWITCH FROM ACTIVE AREA GET TO UTILITY FILE GET   21400019
*********************************************************************** 21500019
SWGETS   BAL   REG14,CALCINS            CALC NO OF LINES AND INSERT     21600019
*                                         INTO ACTIVE AREA              21700019
SWGETS1  TM    PPTFLG,PPTUTIL           TEST FOR UTILITY FILE           21800019
         BZ    RETCD0                   IF NO, SET UP TO RETURN         21900019
SWGETS2  BAL   REG6,PTBGNUF             POINT TO THE BEGINING ON THE    22000019
*                                         UTILITY FILE                  22100019
         OI    PPTFLG,PPTUGET           SET SW TO INDICATE GET FROM     22200019
*                                         UTILITY FILE                  22300019
         B     GETBLKUF                 GET BLOCK FROM UTILITY FILE     22400019
         EJECT                                                          22500019
*********************************************************************** 22600019
*                                                                       22700019
*          SUBROUTINE TO MANIPULATE ACTIVE AREA AND UTILITY FILE        22800019
*                                                                       22900019
*********************************************************************** 23000019
         SPACE 3                                                        23100019
*********************************************************************** 23200019
*          POINT TO THE END OF THE ACTIVE AREA                          23300019
*********************************************************************** 23400019
PTENDAA  LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      23500019
         MVI   TUBNXKEY+7,ENDAA         INDICATE END OF ACTIVE FILE     23600019
         RPOINT A,NR                    POINT AFTER LAST LINE           23700019
*    TEST RETURN                                                        23800019
         C     REG15,F4                 TEST RETURN CODE                23900019
         BH    RETURN3                  IFERROR, RETURN                 24000019
         BR    REG6                     RETURN                          24100019
         SPACE 3                                                        24200019
*********************************************************************** 24300019
*          INSERT LINES INTO ACTIVE AREA                                24400019
*********************************************************************** 24500019
INSAA    LR    REG7,REG6                SAVE RETURN REGISTER            24600019
         BAL   REG6,PTENDAA             POINT TO THE END OF THE         24700019
*                                         ACTIVE AREA                   24800019
         LR    REG6,REG7                RESTORE RETURN REGISTER         24900019
         LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      25000019
         STH   REG9,TUBCNTFS            SET UP COUNT FOR INSERT         25100019
         INSERT M,A                     INSERT BLOCK INTO ACTIVE AREA   25200019
*    TEST RETURN                                                        25300019
         C     REG15,F4                 TEST RETURN                     25400019
         BE    OUTSPA                   IF A.A. OUT OF SPACE, ENQ MSG   25500019
         BH    RETURN3                  IF OTHER ERROR, RETURN          25600019
         TM    PPTFLG,PPTADD            TEST FOR ADD PHASE              25700019
         BO    ENDUPAA                  IF YES, SKIP SETTING INSERT SW  25800019
         TM    PPTFLG,PPT1PAS           TEST FOR 1ST PASS               25900019
         BO    ENDUPAA                  IF YES, SKIP SETTING INSERT SW  26000019
         OI    PPTFLG,PPTINS            SET INSRET SW                   26100019
*    ENTRY FOR ENDUP ONLY                                               26200019
ENDUPAA  LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      26300019
         ENDUP                                                          26400019
*    TEST RETURN                                                        26500019
         C     REG15,F4                 TEST RETURN CODE                26600019
         BH    RETURN3                  IF ERROR, RETURN                26700019
         BR    REG6                     RETURN                          26800019
         SPACE 3                                                        26900019
*********************************************************************** 27000019
*          POINT TO THE BEGINING OF THE UTILITY FILE                    27100019
*********************************************************************** 27200019
PTBGNUF  LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      27300019
         MVI   TUBGBLKY+7,BGNAA         INDICATE BEGINING               27400019
*                                       POINT TO THE BEGNING OF THE     27500019
         RPOINT B,NR,FTYPE=GBL          UTILITY FILE                    27600019
*    TEST RETURN                                                        27700019
         C     REG15,F4                 TEST RETURN CODE                27800019
         BH    RETURN3                  IF ERROR, RETURN                27900019
         BR    REG6                     RETURN                          28000019
         SPACE 3                                                        28100019
*********************************************************************** 28200019
*          POINT TO THE END OF THE UTILITY FILE                         28300019
*********************************************************************** 28400019
PTAFTUF  MVC   TUBGBLKY,PPTPARS+8       GET LAST LINE NO OF LAST BLOCK  28500019
PTAFTUF1 LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      28600019
         RPOINT A,NR,FTYPE=GBL,KEY=HIEQ  POINT AFTER LINE               28700019
*    TEST RETURN                                                        28800019
         C     REG15,F4                 TEST RETURN CODE                28900019
         BH    RETURN3                  IF ERROR, RETURN                29000019
         BR    REG6                     RETURN                          29100019
         SPACE 3                                                        29200019
*********************************************************************** 29300019
*          GET BLOCK FROM UTILITY FILE                                  29400019
*********************************************************************** 29500019
RGETUF   LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      29600019
         MVC   TUBCNTFS,H10             PUT NO OF LINES INTO TUB        29700019
         RGET  R,M,A,FTYPE=GBL          GET BLOCK FROM UTILITY FILE     29800019
*    TEST RETURN                                                        29900019
         C     REG15,F4                 TEST RETURN                     30000019
         BE    EODUF                    IF EOD, BRANDH                  30100019
         BH    RETURN3                  IF ERROR, RETURN                30200019
         SR    REG8,REG8                                                30300019
         IC    REG8,TUBCNTFS            GET NUMBER OF LINES             30400019
         LR    REG9,REG8                SET UP FOR INSERT               30500019
***************                                                         30600019
*    ENTRY TO ENDUP UTILITY FILE                                        30700019
ENDUPUF  LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      30800019
         ENDUP FTYPE=GBL                ENDUP UTILITY FILE              30900019
*    TEST RETURN                                                        31000019
         C     REG15,F4                 TEST RETURN CODE                31100019
         BH    RETURN3                  IF ERROR, RETURN                31200019
         BR    REG6                     RETURN                          31300019
         SPACE 1                                                        31400019
***************                                                         31500019
*    TEST END OF DATA ON UTILITY FILE                                   31600019
EODUF    BAL   REG6,ENDUPUF             ENDUP UTILITY FILE              31700019
         TM    PPTFLG,PPTADD            TEST IF FROM ADD PHASE          31800019
         BO    RETCD0                   IF YES RETURN                   31900019
EODUF2   OI    PPTFLG,PPTADD            SET ADD PHASE SWITCH            32000019
***************                                                         32100019
*    ADD LINES FROM UTILITY FILE TO END OF ACTIVE AREA                  32200019
         MVC   PPTPARS(8),AFTLINE       SET UP FOR POINT                32300019
         MVC   TUBGBLKY,AFTLINE         SET UP FOR POINT                32400019
         BAL   REG6,PTAFTUF1            POINT TO THE BEGINING OF THE    32500019
*                                         UTILITY FILE                  32600019
EODUF1   BAL   REG6,RGETUF              GET BLOCK FROM UTILITY FILE     32700019
         BAL   REG14,CALCLNO            SEQUENCE LINES                  32800019
         BAL   REG6,INSAA               INSERT LINES INTO ACTIVE AREA   32900019
         BAL   REG6,PTAFTUF             POINT AFTER LAST LINE OF        33000019
*                                         LAST BLOCK                    33100019
         B     EODUF1                   GET NEXT BLOCK                  33200019
         SPACE 3                                                        33300019
*********************************************************************** 33400019
*    SEQUENCE LINE NUMBERS                                              33500019
*********************************************************************** 33600019
CALCLNO  L     REG7,TUBRAFBF            GET ADDRESS OF BLOCK            33700019
         LA    REG7,8(REG7)             INCREMENT PAST CONTROL WORDS    33800019
         L     REG10,TUBDIRAD           GET ADDR OF DIRECTORY ENTRY     33900019
         USING DIRDSECT,REG10                                           34000019
         TM    PPTFLG,PPTNFST           TEST FOR 1ST TIME THROUGH       34100019
         BO    CALCLNO1                 IF NOT, SKIP INILITIZATION      34200019
         TM    PPTFLG,PPT1PAS           TEST FOR 1ST PASS               34300019
         BO    CALCLNO5                 IF YES, SKIP INITILIZATION      34400019
         CLI   TUBNXKEY+7,ENDAA         TEST FOR NULL FILE              34500019
         BNE   CALCLNO7                 IF NOT, CONTINUE PROCESSING     34600019
         L     REG15,ZEROS              GET DATA SET INCREMENT          34700019
         B     CALCLNO8                 CONTINUE PROCESSING             34800019
CALCLNO7 PACK  CALCLINE,PPTPARS(8)      PACK LAST LINE NO               34900019
         CVB   REG15,CALCLINE           CONVERT TO BINARY               35000019
CALCLNO8 ST    REG15,SAVELINE           SAVE BINARY LINE NO             35100019
CALCLNO1 OI    PPTFLG,PPTNFST           SET NOT 1ST TIME SW             35200019
CALCLNO5 MVC   PPTPARS+8(8),0(REG7)     SAVE LINE NUMBER                35300019
         TM    PPTFLG,PPT1PAS           TEST FOR 1ST PASS               35400019
         BZ    CALCLNO9                 IF NOT, CONTUNUE                35500019
         CLC   0(8,REG7),AFTLINE        TEST FOR END OF 1ST PASS        35600019
         BNH   CALCLN10                 IF NOT CONTINUE                 35700019
         BAL   REG14,CALCINS            CALC NO OF LINES INSERT         35800019
         NI    PPTFLG,PPT1PASF          TURN OFF 1ST PASS SWITCH        35900019
         B     TSTAA                    TEST FOR RANGE MERGE            36000019
CALCLNO9 TM    PPTFLG,PPTADD            TEST FOR ADD PHASE              36100019
         BO    CALCLNO2                 IF YES, SKIP TESTS              36200019
         TM    PPTFLG,PPTRANGE          TEST FOR RANGE MERGE            36300019
         BZ    CALCLNO3                 IF NOT, SKIP RANGE TEST         36400019
         CLC   0(8,REG7),LSTLINE        TEST FOR LINE NO GT OR EQ LAST  36500019
*                                         LINE OF RANGE                 36600019
         BH    CALCLNO6                 IF YES, TEST FOR LINES IN       36700019
*                                         UTILITY FILE                  36800019
CALCLNO3 TM    PPTFLG,PPTUGET           TEST FOR GET FROM UTILITY FILE  36900019
         BO    CALCLNO2                 IF YES, SKIP END OF A.F. TEST   37000019
         CLC   0(8,REG7),PPTPARS        TEST FOR LINE NO GT LAST        37100019
*                                         LINE OF ACTIVE AREA           37200019
         BH    SWGETS                   IF YES, TEST FOR LINES IN       37300019
*                                         UTILITY FILE                  37400019
CALCLNO2 L     REG15,SAVELINE           SET UP TO CALC LINE NO          37500019
         A     REG15,DIRINC             CALC LINE NO                    37600019
         C     REG15,MAXLNO             TEST FOR MAX LINE NO EXCEEDED   37700019
         BH    MAXLNOER                 IF YES, ENQUEUE MSG             37800019
         CVD   REG15,CALCLINE                                           37900019
         UNPK  0(8,REG7),CALCLINE       PUT LINE NO INTO KEY AREA       38000019
         OI    7(REG7),NUMZONE                                          38100019
         TM    TUBFLG2,TUBLNUMN         TEST FOR LINE NOS IN LINE       38200019
         BZ    CALCLNO4                 IF NOT, SKIP MOVING LINE NO     38300019
         MVC   80(8,REG7),0(REG7)       PUT LINE NO IN LAST 8 BYTES     38400019
CALCLNO4 ST    REG15,SAVELINE           SAVE LINE NO                    38500019
CALCLN10 LA    REG7,88(REG7)            INCREMENT TO NEXT LINE          38600019
         BCT   REG8,CALCLNO5            IF NOT LAST LINE, REPEAT        38700019
         BR    REG14                    RETURN                          38800019
***************                                                         38900019
*    IF END OF RANGE, TEST FOR UTILITY FILE                             39000019
CALCLNO6 BAL   REG14,CALCINS            INSERT GOOD LINES               39100019
         TM    PPTFLG,PPTUTIL           TEST FOR UTILITY FILE           39200019
         BZ    RETCD0                   IF NOT,RETURN                   39300019
         B     EODUF2                   IF YES, ADD LINES FROM UTILITY  39400019
*                                         FILE TO END OF ACTIVE FILE    39500019
         SPACE 3                                                        39600019
*********************************************************************** 39700019
*          CALCULATE NUMBER OF LINES TO BE INSERTED                     39800019
*********************************************************************** 39900019
CALCINS  L     REG15,TUBRAFBF           GET BEGINING ADDR OF BLOCK      40000019
         LR    REG9,REG7                CALC NO OF LINES TO BE INSERTED 40100019
         SR    REG9,REG15                                               40200019
         LH    REG8,H0                                                  40300019
         D     REG8,F88                                                 40400019
         LR    REG12,REG14              SAVE RETURN REGISTER            40500019
         CH    REG9,H0                  TEST FOR NO LINES               40600019
         BNH   CALCINS2                 IF YES, SKIP INSERT             40700019
         BAL   REG6,INSAA               INSERT LINES                    40800019
CALCINS2 LR    REG14,REG12              RESTORE RETURN REGISTER         40900019
         BR    REG14                    RETURN                          41000019
         EJECT                                                          41100019
*********************************************************************** 41200019
*                                                                       41300019
*          ERROR ROUTINES                                               41400019
*                                                                       41500019
*********************************************************************** 41600019
         SPACE 3                                                        41700019
*********************************************************************** 41800019
*          DISK ERROR ACTIVE AREA                                       41900019
*********************************************************************** 42000019
DSKERA   LA    REG15,AAIOERRC           SET DISK ERR RETURN CODE        42100019
         B     RETURN3                  RETURN                          42200019
         SPACE 3                                                        42300019
*********************************************************************** 42400019
*          OUT OF SPACE, ACTIVE AREA                                    42500019
*********************************************************************** 42600019
OUTSPA   LA    REG15,OUTSPCDU           BUILD PARAMETER LIST FOR OUT    42700019
         ST    REG15,TUBPARM4             OF SPACE ACTIVE AREA FOR      42800019
         OI    TUBPARM4,ENDLST            USER                          42900019
         LA    REG15,OUTSPRC            SET OUT OF SPACE RETURN CODE    43000019
         L     REG14,4(0,REG13)                                         43100019
         ST    REG15,16(REG14)          SAVE RETURN CODE                43200019
         B     ENQMSG                   ENQUEUE MESSAGE                 43300019
         SPACE 3                                                        43400019
*********************************************************************** 43500019
*          ENQUEUE MESSAGE FOR USER                                     43600019
*********************************************************************** 43700019
ENQMSG   LA    REG15,TUBUSRID           FINISH PARAMETER LIST           43800019
         ST    REG15,TUBPARM3                                           43900019
         ST    TUBR,TUBPARM2                                            44000019
         LA    REG1,TUBPARM2            GET ADDRESS OF LIST             44100019
         L     REG9,TUBRAFBF            SAVE AFI BUFFER ADDRESS         44200019
         L     REG15,IHKYMSG1           GETADDR OF MSG WRITER           44300019
         BALR  REG14,REG15              ENQUEU MESSAGE                  44400019
         ST    REG9,TUBRAFBF            RESTORE BUFFER ADDRESS          44500019
         LTR   REG15,REG15              TEST RETURN CODE                44600019
         BC    8,RETURN                 IF GOOD, RETURN                 44700019
         B     RETURN3                  RETURN                          44800019
         SPACE 3                                                        44900019
*********************************************************************** 45000019
*           NO LINES IN RANGE                                           45100019
*********************************************************************** 45200019
NOLINE   LA    REG15,NOLINECD           BUILD PARM LIST FOR NO LINES    45300019
         ST    REG15,TUBPARM4             IN RANGE MESSAGE              45400019
         LA    REG15,TUBUSRID                                           45500019
         ST    REG15,TUBPARM3                                           45600019
         OI    TUBPARM4,ENDLST          FLAG END OF PARM LIST           45700019
         LA    REG15,GOODRET            SET GOOD RETURN CODE            45800019
         L     REG14,4(REG13)                                           45900019
         ST    REG15,16(REG14)          SAVE RETURN CODE                46000019
         B     ENQMSG                   ENQUEUE MESSAGE FOR USER        46100019
         SPACE 3                                                        46200019
*********************************************************************** 46300019
*          MAXIMUM LINE NUMBER EXCEEDED                                 46400019
*********************************************************************** 46500019
         SPACE 1                                                        46600019
MAXLNOER LA    REG15,MAXLNOCD           BUILD PARAMETER LIST FOR MAX    46700019
         ST    REG15,TUBPARM4             LINE NUMBER EXCEEDED          46800019
         OI    TUBPARM4,ENDLST          FLAG END OF LIST                46900019
         LA    REG15,GOODRET            SET GOOD RETURN CODE            47000019
         L     REG14,4(REG13)                                           47100019
         ST    REG15,16(REG14)          SAVE RETURN CODE                47200019
         B     ENQMSG                   ENQUEUE MESSAGE                 47300019
         EJECT                                                          47400019
*********************************************************************** 47500019
*                                                                       47600019
*          RETURN                                                       47700019
*                                                                       47800019
*********************************************************************** 47900019
RETCD0   TM    PPTFLG,PPTINS            TEST FOR LINES INSERTED         48000019
         BZ    NOLINE                   IF NOT, ENQ MSG                 48100019
         LA    REG15,GOODRET            SET 0 RETURN CODE               48200019
RETURN3   L    REG14,4(REG13)                                           48300019
         ST    REG15,16(REG14)          SAVE RETURN CODE                48400019
RETURN   L     REG1,TUBRAFBF            SET UP TO FREE BUFFER           48500019
         FREEMAIN R,LV=BUFLEN,A=(1)     FREE BUFFER                     48600019
         NI    TUBAFISW,BUFCTLF         TURN OFF BUF CTL SW             48700019
         TM    PPTFLG,PPTUTIL           TEST FOR UTILITY FILE           48800019
         BZ    RETURN1                  IF NOT, SKIP RELEASE            48900019
         MVI   TUBGBLNM,UFNUM           RESTORE UTILITY FILE NUMBER     48950019
         LA    REG1,32(REG13)           BUILD PARM LIST FOR IHKAFI      49000019
         RELEASE A,FTYPE=GBL            RELEASE UTILITY FILE            49100019
         ST    REG15,TUBPARM1           SAVE RETURN CODE                49200019
         L     REG15,TUBUFFAD                                           49300019
         L     REG15,100(REG15)                                         49400019
         L     REG14,IHKYYKBX                                           49500019
         USING RAFKNBX,REG14                                            49600019
         ST    REG15,OSDSQCTL                                           49700019
         LA    REG15,0(REG15)                                           49800019
         LA    REG1,OSDSQCTL+4                                          49900019
         CR    REG15,REG1                                               50000019
         BE    NOELEM                                                   50100019
         OI    4(REG15),BLK                                             50200019
         DROP  REG14                                                    50300019
NOELEM   L     REG15,TUBPARM1           RESTORE RETURN CODE             50400019
*    TEST RETURN                                                        50500019
          C    REG15,F4                 TEST RETURN CODE                50600019
          BNH  RETURN1                  IF GOOD, RETURN                 50700019
          L    REG14,4(REG13)           IF ERROR, SAVE RETURN CODE      50800019
          ST   REG15,16(REG14)                                          50900019
RETURN1  LR    REG1,REG13               GET ADDR FRO FREEMAIN           51000019
         L     REG13,4(REG13)           GET CALLER'S SAVE AREA ADDR     51100019
         LA    REG0,GMLEN               GET LENGTH FOR FREEMAIN         51200019
         FREEMAIN R,LV=(0),A=(1)        FREE SAVE AREA                  51300019
         RETURN (14,12),T               RETURN                          51400019
         EJECT                                                          51500019
*********************************************************************** 51600019
*          CONSTANTS                                                    51700019
*********************************************************************** 51800019
ACTA     DC    X'0B'                                                    51900019
         DC    C'ACTIVE AREA'                                           52000019
UF       DC    X'0C'                                                    52100019
         DC    C'UTILITY FILE'                                          52200019
ZEROS    DC    F'0'                                                     52300019
F4       DC    F'4'                     FULL WORD CONST OF 4            52400019
F88      DC    F'88'                                                    52500019
MAXLNO   DC    F'99999999'              MAXIMUM LINE NUMBER             52600019
H10      DC    H'10'                                                    52700019
H0       DC    H'0'                                                     52800019
         SPACE 3                                                        52900019
*********************************************************************** 53000019
*          MESSAGE CODES                                                53100019
*********************************************************************** 53200019
         DS    0F                                                       53300019
OUTSPCDU DC    XL4'00F3F5F7'            OUT OF SPACE (USER)             53400019
NOLINECD DC    XL4'00F3F4F0'            NO LINES IN RANGE               53500019
MAXLNOCD DC    XL4'00F3F4F8'            MAX LINE NUMBER EXCEEDED        53600019
         SPACE 3                                                        53700019
*********************************************************************** 53800019
*           EQUATES FOR PPT SWITCHES                                    53900019
*********************************************************************** 54000019
PPT1PAS  EQU   X'80'                    1ST PASS SWITCH                 54100019
PPT1PASF EQU   X'7F'                    OFF                             54200019
PPTRANGE EQU   X'20'                    RANGE MERGE SW                  54300019
PPTUTIL  EQU   X'10'                    UTILITY FILE SW                 54400019
PPTUTILF EQU   X'EF'                      OFF                           54500019
PPTADD   EQU   X'08'                    ADD PHASE SW                    54600019
PPTUGET  EQU   X'04'                    GET FROM UTILITY FILE SW        54700019
PPTNFST  EQU   X'02'                    NOT 1ST TIME SW                 54800019
PPTINS   EQU   X'01'                    INSERT MADE                     54900019
PPTOFF   EQU   X'30'                    TURN OFF UNUSED SWITCHES        55000019
         EJECT                                                          55100019
*********************************************************************** 55200019
*          SAVE AND WORK AREAS                                          55300019
*********************************************************************** 55400019
VDSECT   DSECT                                                          55500019
SAVA     DS    18F                      SAVE AREA                       55600019
GMLEN    EQU   X'63'                                                    55700019
         EJECT                                                          55800019
*********************************************************************** 55900019
*                                                                       56000019
*           DSECT FOR PARAMETERS FROM IHKMGE                            56100019
*                                                                       56200019
*********************************************************************** 56300019
PARMDCT  DSECT                                                          56400019
FSTLINE  DS    CL8                      1ST LINE OF RANGE TO BE MERGED  56500019
LSTLINE  DS    CL8                      LAST LINE OF RANGE TO BE MERGED 56600019
AFTLINE  DS    CL8                      LINE AFTER TO BE MERGED         56700019
CALCLINE DS    D                        AREA FOR CALCULATING LINE NO    56800019
SAVELINE DS    F                        AREA TO SAVE LINE NO            56900019
         EJECT                                                          57000019
*********************************************************************** 57100019
*                                                                       57200019
*           DSECTS FOR PPT, TUB, AND AVT                                57300019
*                                                                       57400019
*********************************************************************** 57500019
         IHKCDSCT TUB=YES,PPT=YES,AVT=YES,DIR=YES                       57600019
         TUBEQU                                                         57700019
         RAFKNBX TYPE=DSECT                                             57800019
         END                                                            57900019
