MGE      TITLE 'IHKMGE - MERGE COMMAND PROCESSOR'                       00100019
*********************************************************************** 00200019
*                                                                     * 00300019
*STATUS                                                               * 00400019
*   CHANGE LEVEL 0                                                    * 00500019
*                                                                     * 00600019
*FUNCTION                                                             * 00700019
*   THE FIRST OPERAND IS CHECKED FOR AN *, IF IT IS, THE SWITCH THAT  * 00800019
*   INDICATES AN ACTIVE FILE MERGE IS SET.  OTHERWISE, THE DSNAME IS  * 00900019
*   STORED IF NO ERROR IS DETECTED.  THE FOLLOWING OPERANDS ARE       * 01000019
*   CHECKED FOR ALL NUMERICS AND STORED.  ANY OPERAND ERROR CAUSES    * 01100019
*   AN ERROR MESSAGE TO BE ENQUED FOR THE USER AND CONTROL TO BE      * 01200019
*   RETURNED TO THE SYSTEM ADMINISTRATOR.                             * 01300019
*   IF THERE ARE NONE OR 2 NUMERIC OPERANDS, AND AN ACTIVE FILE MERGE * 01400019
*   HAS BEEN SPECIFIED, THE LOAD CODE FOR IHKMAA IS PLACED IN REGISTER* 01500019
*   15 AND CONTROL IS RETURNED TO THE SYSTEM ADMINISTRATOR.  IF A     * 01600019
*   MERGE FROM A USER'S LIBRARY IS SPECIFIED THE LOAD CODE FOR IHKMUF * 01700019
*   IS PLACED IN REGISTER 15 AND CONTROL IS RETURNED TO THE SYSTEM    * 01800019
*   ADMINISTRATOR.                                                    * 01900019
*   WHEN THERE ARE ONE OR THREE NUMERIC OPERANDS, THE ENTIRE ACTIVE   * 02000019
*   FILE IS MOVED TO AN UTILITY FILE (GLOBAL FILE 7), THE ACTIVE FILE * 02100019
*   RELEASED, AND A NEW ACTIVE FILE CREATED.  CONTROL IS THEN PASSED  * 02200019
*   TO IHKMAA OR IHKMOF AS DESCRIBED UNDER NONE OR TWO NUMERIC        * 02300019
*   OPERANDS.                                                         * 02400019
*                                                                     * 02500019
*ENTRY POINTS                                                         * 02600019
*        IHKMGE TO MERGE LINES FROM AN USER'S LIBRARY OR THE ACTIVE   * 02700019
*        FILE                                                         * 02800019
*                                                                     * 02900019
*INPUT                                                                * 03000019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING THE * 03100019
*   ADDRESS OF THE TUB AND AVT.                                       * 03200019
*OUTPUT                                                               * 03300019
*   N/A                                                               * 03400019
*                                                                     * 03500019
*EXTERNAL REFERENCES                                                  * 03600019
*        IHKAFI - TO MANIPULATE THE ACTIVE AND UTILITY FILES          * 03700019
*        IHKMSG - TO QUEUE MESSAGES FOR THE USER                      * 03800019
*        IHKNUM - TO CHECK NUMERIC OPERANDS                           * 03900019
*EXITS, NORMAL                                                        * 04000019
*   RETURN TO CALLING ROUTINE WITH LOAD CODE FOR IHKMAA OR IHKMUF IN  * 04100019
*   REGISTER 15                                                       * 04200019
*EXITS, ERROR                                                         * 04300019
*   RETURN TO CALLING ROUTINE WITH ONE OF THE FOLLOWING RETURN CODES  * 04400019
*   IN REGISTER 15                                                    * 04500019
*   0  - SYNTAX ERROR IN COMMAND                                      * 04600019
*   8  - GETMAIN FAILURE                                              * 04700019
*   12 - ACTIVE AREA I/O ERROR                                        * 04800019
*   16 - MESSAGE LOST                                                 * 04900019
*   20 - ACTIVE AREA OUT OF SPACE                                     * 05000019
*TABLES/WORK AREAS                                                    * 05100019
*   18 WORD SAVE AREA                                                 * 05200019
*   28 BYTE WORK AREA                                                 * 05300019
*   PPT - CONTAINS OPERANDS OF THE MERGE COMMAND                      * 05400019
*   USER BUFFER - WORK AREA AND CONTAINS PARAMETERS FOR IHKMAA AND    * 05500019
*   IHKMUF                                                            * 05600019
*   888 BYTE AFIO AND BPAM BUFFER                                     * 05700019
*   TUB                                                               * 05800019
*   TUBAFISW - BUFFER CONTROL FOR IHKAFI AND IHKBPM                   * 05900019
*   TUBCNTFS - NUMBER OF LINES IN BUFFER                              * 06000019
*   TUBGBLKY - UTILITY FILE POINTER                                   * 06100019
*   TUBPRMLS - PARAMETER AREA                                         * 06200019
*   TUBRAFBF - POINTS TO BUFFER                                       * 06300019
*   TUBUSRID - USERID OF USER                                         * 06400019
*   TUBUSRNM - USERID OF OWNER OF LIBRARY                             * 06500019
*ATTRIBUTES                                                           * 06600019
*   REENTRANT AND NONRESIDENT                                         * 06700019
*********************************************************************** 06800019
         EJECT                                                          06900019
IHKMGE   CSECT                                                          07000019
*********************************************************************** 07100019
*           REGISTER EQUATES                                            07200019
*********************************************************************** 07300019
REG0     EQU   0                                                        07400019
REG1     EQU   1                                                        07500019
REG2     EQU   2                                                        07600019
REG3     EQU   3                                                        07700019
REG4     EQU   4                                                        07800019
REG5     EQU   5                                                        07900019
REG6     EQU   6                                                        08000019
REG7     EQU   7                                                        08100019
REG8     EQU   8                                                        08200019
REG9     EQU   9                                                        08300019
REG10    EQU   10                                                       08400019
REG11    EQU   11                                                       08500019
REG12    EQU   12                                                       08600019
REG13    EQU   13                                                       08700019
REG14    EQU   14                                                       08800019
REG15    EQU   15                                                       08900019
         SPACE 3                                                        09000019
*********************************************************************** 09100019
*           EQUATES                                                     09200019
*********************************************************************** 09300019
SUBOPER  EQU   X'40'                    SUBOPERAND                      09400019
LSTSUB   EQU   X'C0'                    LAST SUBOPERAND                 09500019
LASTOPER EQU   X'FF'                    LAST OPERAND IN PPT             09600019
SUBOPERF EQU   X'3F'                    TURN OFF SUBOPERAND BITS        09700019
LSTPARM  EQU   X'80'                    LAST PARAMETER IN LIST          09800019
LSTPARMF EQU   X'7F'                    TURN OFF LAST PARM BIT          09900019
PPTACTA  EQU   X'40'                    PPT SWITCH FOR ACTIVE AREA MGE  10000019
PPTRANGE EQU   X'20'                    RANGE MERGE SWITCH              10100019
PPTUTIL  EQU   X'10'                    UTILITY FILE SW                 10200019
BLK      EQU   C' '                     BLANK                           10300019
ENDACT   EQU   X'FF'                    POINT TO END OF ACTIVE AREA     10400019
BGNFILE  EQU   X'00'                    POINT TO BEGNING                10500019
BUFCTL   EQU   X'80'                    BUFFER CONTROL                  10600019
BUFCTLF  EQU   X'7F'                      OFF                           10700019
BUFLEN   EQU   888                      BUFFER LENGTH                   10800019
POST     EQU   X'40'                    POST CODE FOR ECB               10900019
C0       EQU   C'0'                     CHARACTER 0                     11000019
C9       EQU   C'9'                     CHARACTER 9                     11100019
C$       EQU   C'$'                     CHARACTER $                     11200019
C#       EQU   C'#'                     CHARACTER #                     11300019
C@       EQU   C'@'                     CHARACTER @                     11400019
CA       EQU   C'A'                     CHARACTER A                     11500019
CZ       EQU   C'Z'                     CHARACTER Z                     11600019
X00      EQU     X'00'                  HEX 00                          11700019
CODE8    EQU   8                        RETURN CODE OF 8                11800019
CODE0    EQU   0                        GOOD RETURN CODE                11900019
ALEN     EQU   1                        * OPERAND LENGTH                12000019
UIDLEN   EQU   7                        LENGTH OF USERID                12100019
DSLEN    EQU   8                        DATA SET NAME LENGTH            12200019
CODE12   EQU   12                       RETURN CODE OF 12               12300019
UFCODE   EQU   X'07'                    UTILITY FILE NUMBER             12350019
         EJECT                                                          12400019
         SAVE  (14,12),,IHKMGE-05/25/70  SAVE REGISTERS                 12500019
         LR    REG11,REG15              LOAD BASE REGISTER              12600019
         USING IHKMGE,REG11                                             12700019
         L     REG2,0(REG1)             SET UP ADDRESSABILITY FOR TUB   12800019
         USING TUBDSECT,REG2                                            12900019
         L     REG4,4(REG1)             SET UP ADDRESSABILITY FOR AVT   13000019
         USING AVTDSECT,REG4                                            13100019
         LA    REG6,TUBPARM1            SET UP FOR GETMAIN              13200019
         L     REG1,IHKYYGML                                            13300019
         GETMAIN EC,LV=GMLEN,A=(REG6),MF=(E,(1))  GET WORK AND SAVE    X13400019
                                          AREAS                         13500019
         LTR   REG15,REG15              TEST RETURN CODE                13600019
         BC    7,RETCD8                 IF BAD RETURN                   13700019
         L     REG6,TUBPARM1                                            13800019
         ST    REG13,4(REG6)            SAVE CALLERS SAVE AREA ADDR     13900019
         ST    REG6,8(REG13)            SAVE SAVE AREA ADDR IN CALLERS  14000019
*                                         SAVE AREA                     14100019
         LR    REG13,REG6               SET UP ADDRESSABILITY FOR SAVE  14200019
         USING VDSECT,REG13               AREA AND VARIABLES            14300019
         NI    MGESW,MGEOFF             TURN OFF PROCESSING SWITCHES    14400019
         L     REG3,TUBPPTAD            SET UP ADDRESSABILITY FOR PPT   14500019
         USING PPTDSECT,REG3                                            14600019
         MVC   CTR,F0                   SET UP OPERAND COUNTER          14700019
         LA    REG5,PPTPARS             POINT TO LENGTH OF 1ST OPER     14800019
         TM    0(REG5),LASTOPER         TEST FOR NO OPERANDS            14900019
         BO    TSTCONT3                 IF NONE ENQUEUE ERROR MSG       15000019
FSTOPER  TM    0(REG5),SUBOPER          TEST FOR SUBOPERAND             15100019
         BO    DSNERR2                  IF YES, ENQUEUE ERROR MSG       15200019
         SR    REG6,REG6                                                15300019
         IC    REG6,0(REG5)             PUT OPERAND LEN INTO REG        15400019
         LA    REG5,1(REG5)             POINT TO 1ST OPERAND            15500019
         LH    REG15,CTR                ADD 1 TO NO OF OPERANDS         15600019
         AH    REG15,H1                                                 15700019
         STH   REG15,CTR                                                15800019
         CLC   0(1,REG5),ASTERISK       TEST FOR ACTIVE AREA MERGE      15900019
         BE    ACTAMGE                  IF YES BRANCH                   16000019
         SPACE 3                                                        16100019
*********************************************************************** 16200019
*          TEST DSNAME                                                  16300019
*********************************************************************** 16400019
         SPACE 1                                                        16500019
         LA    REG7,DSLEN                                               16600019
         CR    REG6,REG7                TEST FOR DSNAME OPERAND TOO     16700019
*                                         LONG                          16800019
         BH    DSNERR                   IF YES SEND ERROR MESSAGE       16900019
         LR    REG15,REG6               SET UP TO TEST DSNAME           17000019
         LR    REG14,REG5                                               17100019
         B     TSTDSN                   TEST DSNAME                     17200019
TSTDSN3  CLI   0(REG14),C0              TEST FOR NUMREIC                17300019
         BL    TSTDSN                   IF LOWER, TEST ALPHA OR $@#     17400019
         CLI   0(REG14),C9                                              17500019
         BH    DSNERR                   IF HIGHER THAN 9, ENQ ERR MEG   17600019
         B     TSTDSN2                  IF IN RANGE, TEST NEXT CHAR     17700019
TSTDSN   CLI   0(REG14),C$              TEXT FOR $                      17800019
         BE    TSTDSN2                  IF YES, TEST NEXT CHAR          17900019
         CLI   0(REG14),C#              TEST FOR #                      18000019
         BE    TSTDSN2                  IF YES, TEST NEXT CHAR          18100019
         CLI   0(REG14),C@              TEST FOR @                      18200019
         BE    TSTDSN2                  IF YES, TEST MEXT CHAR          18300019
         CLI   0(REG14),CA              TEST FOR ALPHABETIC             18400019
         BL    DSNERR                   IF NOT, ENQ MSG                 18500019
         CLI   0(REG14),CZ                                              18600019
         BH    DSNERR                   IF NOT ALPHA, ENQ MSG           18700019
TSTDSN2  LA    REG14,1(REG14)           INCREMENT TO NEXT CHARACTER     18800019
         BCT   REG15,TSTDSN3            TEST NEXT CHAR, IF NOT LAST     18900019
         MVC   TUBPMFNM,BLANKS          BLANK OUT DSNAME AREA IN TUB    19000019
         LR    REG15,REG6               SET UP TO MOVE DSNAME TO TUB    19100019
         BCTR  REG15,0                                                  19200019
         EX    REG15,MVCDSN             MOVE DSNAME TO TUB              19300019
INCRSUB  BAL   REG12,INCRE              INCREMENT TO NEXT OPERAND       19400019
TSTSUB   TM    0(REG5),SUBOPER          TEST FOR SUBOPERAND             19500019
         BZ    TSTLAST                  IF NOT, PROC NUMERIC OPERANDS   19600019
         TM    0(REG5),LASTOPER         TEST FOR LAST OPERAND           19700019
         BO    TSTCONT1                 IF YES TEST FOR ANOTHER PPT     19800019
         TM    MGESW,MGEUID             TEST FOR USERID FOUND           19900019
         BO    TSTKEY                   IF YES TEST VALIDITY OF KEY     20000019
         TM    0(REG5),LSTSUB           TEST FOR LAST SUBOPER           20100019
         BNO   NLSTSUB                  IF NOT, CONTINUE                20200019
         OI    MGESW,MGENKEY            SET NO KEY SWITCH               20300019
NLSTSUB  NI    0(REG5),SUBOPERF         TURN OFF SUBOPERAND BIT         20400019
         IC    REG6,0(REG5)                                             20500019
         LA    REG5,1(REG5)             POINT TO OPERAND                20600019
         LA    REG15,UIDLEN                                             20700019
         CR    REG6,REG15               TEST USERID LENGTH              20800019
         BH    UIDERR                   IF TOO LONG ENQ ERROR MSG       20900019
         MVC   TUBUSRNM,BLANKS          CLEAR OUT AFIO USERID AREA      21000019
         LR    REG15,REG6               SET UP TO MOVE OWNERS USERID    21100019
         BCTR  REG15,0                    TO AFIO AREA OF TUB           21200019
         EX    REG15,MVCUID             MOVE USERID TO TUB              21300019
         OI    MGESW,MGEUID             SET USERID SW                   21400019
         TM    MGESW,MGENKEY            TEST FOR KEY                    21500019
         BO    INCOPER                  IF NOT, TEST NEXT OPERAND       21600019
         B     INCRSUB                  TEST NEXT OPERAND               21700019
TSTKEY   NI    0(REG5),SUBOPERF         TURN OFF SUBOPERAND BITS        21800019
         IC    REG6,0(REG5)             GET OPERAND LENGTH              21900019
         LA    REG5,1(REG5)             POINT TO OPERAND                22000019
         CH    REG6,H3                  TEST KEY LENGTH                 22100019
         BH    KEYERR                   IF TOO LONG ENQ ERR MSG         22200019
         LR    REG15,REG6                                               22300019
         L     REG14,TUBUFFAD                                           22400019
         LA    REG14,24(REG14)          GET ADDRESS OF KEY STORAGE AREA 22500019
         MVC   0(3,REG14),BLANKS        BLANK OUT KEY STORAGE AREA      22600019
         BCTR  REG15,0                                                  22700019
         EX    REG15,MVCKEY             SAVE KEY                        22800019
         B     INCOPER                  TEST NEXT OPERAND               22900019
         SPACE 3                                                        23000019
*********************************************************************** 23100019
*           PROCESS * PARAMETER                                         23200019
*********************************************************************** 23300019
ACTAMGE  LA    REG15,ALEN               TEST OPERAND LENGTH             23400019
         CR    REG6,REG15                                               23500019
         BH    OPRERR                   IF TOO LONG ENQ ERR MSG         23600019
         OI    PPTFLG,PPTACTA           SET ACTIVE AREA MERGE SW        23700019
         B     INCOPER                  TEST NEXT OPERAND               23800019
         SPACE 3                                                        23900019
*********************************************************************** 24000019
*           TEST FOR CONTINUATION PPT                                   24100019
*********************************************************************** 24200019
TSTCONT  CLC   PPTCHAD+1(3),F0          TEST FOR CHAINING ADDRESS IN   X24300019
                                          PPT                           24400019
         BE    PROCESS                  IF NOT PROCESS COMMAND          24500019
         LR    REG15,REG3               SET UP TO PRSERVE PPR SWITCHES  24600019
         L     REG3,PPTCHAD             GET ADDRESS OF NEXT PPT         24700019
         OC    PPTFLG,0(REG15)          MOVE PPT SWITCHES TO NEXT PPT   24800019
         LA    REG5,PPTPARS             POINT TO 1ST OPERAND            24900019
         SR    REG6,REG6                                                25000019
         IC    REG6,0(REG5)             PUT PARM LENGTH INTO REG        25100019
         BR    REG12                    EXIT                            25200019
TSTCONT1 BAL   REG12,TSTCONT            TEST FOR CONTINUATION PPT       25300019
         B     TSTSUB                   TEST FOR SUBOPERAND             25400019
TSTCONT2 BAL   REG12,TSTCONT            TEST FOR CONTINUATION PPT       25500019
         B     TSTLAST                  TEST FOR LAST OPERAND           25600019
TSTCONT3 BAL   REG12,TSTCONT            TEST FOR ANOTHER PPT            25700019
         B     FSTOPER                  IF YES, CONTINUE PROCESSING     25800019
TSTCONT4 BAL   REG12,TSTCONT            TEST FOR CONTUNATION PPT        25900019
         NI    MGESW,MGESUBF            TURN OFF NOT LAST SWITCH        26000019
         BR    REG9                     EXIT                            26100019
         EJECT                                                          26200019
*********************************************************************** 26300019
*                                                                       26400019
*           PROCESS OTHER OPERANDS                                      26500019
*                                                                       26600019
*********************************************************************** 26700019
INCOPER  BAL   REG12,INCRE              INCREMENT TO NEXT OPERAND       26800019
TSTLAST  TM    0(REG5),LASTOPER         TEST FOR LAST OPERAND           26900019
         BO    TSTCONT2                 IF YES PROCESS CMD              27000019
         TM    0(REG5),SUBOPER          TEST FOR SUBOPERAND             27100019
         BO    OPRERR1                  IF YES, ENQ ERR MSG             27200019
TSTNUM   ST    REG5,TUBPARM1            STORE 1ST PARAMETER             27300019
         LA    REG5,1(REG5)             POINT TO OPERAND                27400019
         ST    REG5,TUBPARM2            STORE 2ND PARAMETER             27500019
         CLC   CTR,H1                   TEST FOR 1ST TIME THROUGH       27600019
         BNE   NFST                                                     27700019
         L     REG10,TUBUFFAD           LOAD STORAGE AREA ADDRESS       27800019
         B     BLDNUMP                                                  27900019
NFST     LA    REG10,8(REG10)           INCREMENT TO NEXT STORAGE AREA  28000019
BLDNUMP  ST    REG10,TUBPARM3           STORE 3RD PARAMETER             28100019
         OI    TUBPARM3,LSTPARM         FLAG END OF PARAMETER LIST      28200019
         LH    REG8,H1                                                  28300019
         AH    REG8,CTR                 GET NO OF OPERANDS              28400019
         CH    REG8,H4                  TEST FOR MAX NUMERIC OPERANDS   28500019
         BH    EXCESSOP                 IF OVER ENQ ERROR MSG           28600019
         STH   REG8,CTR                 SAVE COUNTER                    28700019
         LA    REG1,TUBPARM1            GET ADDRESS OF PARM LIST        28800019
         L     REG15,IHKYYNUM           GET ADDRESS OF IHKNUM           28900019
         OI    TUBPARM3,LSTPARM         FLAG END OF PARAMETER LIST      29000019
         BALR  REG14,REG15              CALL IHKNUM TO VERIFY OPER NUM X29100019
                                          AND STORE OPERAND             29200019
         LTR   REG15,REG15              TEST RETURN CODE                29300019
         BC    7,LNOERR                 IF BAD ENQ ERR MSG              29400019
         B     INCOPER                  TEST NEXT OPERAND               29500019
         SPACE 3                                                        29600019
*********************************************************************** 29700019
*           SET UP TO PROCESS COMMAND                                   29800019
*********************************************************************** 29900019
PROCESS  TM    MGESW,MGEERR             TEST FOR OPERAND ERROR          30000019
         BO    RETCD0                   IF YES RETURN                   30100019
         TM    MGESW,MGEUID             TEST FOR USERID STORED          30200019
         BO    PROCESS1                 IF YES, TEST NUMERIC OPERANDS   30300019
         MVC   TUBUSRNM,TUBUSRID        PUT USERID INTO TUB FOR IHKBPM  30400019
PROCESS1 CLC   CTR,F0                   TEST FOR NO OPERANDS            30500019
         BE    NOOPER                   IF NONE, ENQUEUE MSG            30600019
         CLC   CTR,H1                   TEST FOR NO NUMERIC OPERANDS    30700019
         BE    TWOOPR1                  IF NONE PROCESS COMMAND         30800019
         CLC   CTR,H2                   TEST FOR 1 NUMERIC OPERAND      30900019
         BE    ONEOPR                   IF 1 PROCESS COMMAND            31000019
         CLC   CTR,H3                   TEST FOR 2 NUMERIC OPERANDS     31100019
         BE    TWOOPR                   IF 2 PROCESS COMMAND            31200019
         SPACE 1                                                        31300019
*********************************************************************** 31400019
*           IF THREE NUMERIC OPERANDS PASS CONTROL TO IHKMMF            31500019
*********************************************************************** 31600019
THROPR   BAL   REG14,TSTRANGE           TEST LINE NO RANGE              31700019
         OI    PPTFLG,PPTRANGE          SET RANGE MERGE SWITCH          31800019
         B     MOVELINE                 PUT LINES AFTER MERGE AFTER     31900019
         SPACE 1                                                        32000019
*********************************************************************** 32100019
*           PROCESS 2 NUMERIC OPERANDS                                  32200019
*********************************************************************** 32300019
TWOOPR   BAL   REG14,TSTRANGE           TEST LINE NO RANGE              32400019
         OI    PPTFLG,PPTRANGE          SET RANGE MERGE SWITCH          32500019
TWOOPR1  BAL   REG5,GETAFIBF            GET BUFFER FOR IHKAFI           32600019
         B     TSTACT                   FIND WHICH MERGE IS TO BE DONE  32700019
         SPACE 1                                                        32800019
*                                                                       32900019
*                                                                       33000019
*********************************************************************** 33100019
*           PROCESS 1 NUMERIC OPERAND                                   33200019
*********************************************************************** 33300019
ONEOPR   L     REG8,TUBUFFAD            FIND PARAMETER AREA             33400019
         MVC   16(8,REG8),0(REG8)       MOVE MERGE AFTER TO PROPER      33500019
*                                         POSITION                      33600019
         B     MOVELINE                 PUT LINES AFTER MERGE AFTER     33700019
*                                         LINE INTO UTILITY FILE        33800019
         SPACE 3                                                        33900019
*********************************************************************** 34000019
*           TEST LINE NO RANGE FOR TWO AND THREE NUMERIC OPERANDS       34100019
*********************************************************************** 34200019
TSTRANGE L     REG15,TUBUFFAD           GET ADDRESS OF LINE NO STO AREA 34300019
         CLC   0(8,REG15),8(REG15)      TEST FOR STARTING LINE NO LT    34400019
*                                         THAN ENDING LINE NO           34500019
         BH    RANGERR                  IF NOT ENQUEUE ERR MSG          34600019
         BR    REG14                    RETURN                          34700019
         EJECT                                                          34800019
*********************************************************************** 34900019
*           RETURN ROUTINE                                              35000019
*********************************************************************** 35100019
RETURN   LR    REG1,REG13               SET UP FOR FREEMAIN             35200019
         L     REG13,4(REG13)           GET ADDRESS OF CALLERS SAVE     35300019
*                                         AREA                          35400019
         ST    REG15,16(REG13)          SAVE RETURN CODE                35500019
         FREEMAIN R,LV=GMLEN,A=(1)      FREE UP SAVE AND WORK AREAS     35600019
RETURN1  RETURN (14,12),T               RETURN TO CALLER                35700019
RETCD0   LA    REG15,CODE0              SET RETURN CODE OF 0            35800019
         B     RETURN                   RETURN                          35900019
RETCD8   LA    REG15,CODE8              SET RETURN CODE OF 8            36000019
         B     RETURN                   RETURN                          36100019
RETCD12  LA    REG15,CODE12             SET RETURN CODE OF 12           36200019
         B     RETURN                                                   36300019
         EJECT                                                          36400019
*********************************************************************** 36500019
*           SUBROUTINE TO INDEX THROUGH OPERANDS                        36600019
*********************************************************************** 36700019
INCRE    AR    REG5,REG6                INCREMENT TO NEXT OPERAND       36800019
         SR    REG6,REG6                                                36900019
         IC    REG6,0(REG5)             SET UP LENGTH REGISTER          37000019
         BR    REG12                    RETURN                          37100019
         SPACE 3                                                        37200019
*********************************************************************** 37300019
*                                                                       37400019
*           SUBROUTINE TO SET UP SUBOPERAND                             37500019
*                                                                       37600019
*********************************************************************** 37700019
SUBPROC  TM    0(REG5),LSTSUB           TEST FOR LAST SUBOPERAND        37800019
         BO    SUBPROC2                 IF YES, ENQUEUE MESSAGE         37900019
         OI    MGESW,MGESUB             SET NOT LAST SWITCH             38000019
SUBPROC2 NI    0(REG5),SUBOPERF         TURN OFF SUBOPERAND BIRS        38100019
         SR    REG6,REG6                CLEAR LENGTH REGISTER           38200019
         IC    REG6,0(REG5)             SET UP LENGTH REGISTER          38300019
         LA    REG14,OPRERRCD           GET MESSAGE CODE                38400019
         BAL   REG8,ENQMSG2             ENQUEUE MESSAGE                 38500019
         TM    MGESW,MGESUB             TEST FOR LAST SUBOPERAND        38600019
         BZ    SUBPROC3                 IF YES, EXIT                    38700019
SUBPROC5 LA    REG5,1(REG5)             POINT TO OPERAND                38800019
         BAL   REG12,INCRE              INCREMENT TO NEXT OPERAND       38900019
         TM    0(REG5),LASTOPER         TEST FOR LAST OPERAND           39000019
         BO    TSTCONT4                 IF YES, TEST FOR CONTINUATION   39100019
         TM    0(REG5),LSTSUB           TEST FOR LAST SUBOPERAND        39200019
         BO    SUBPROC4                 IF YES, PROCESS                 39300019
         NI    0(REG5),SUBOPERF         TUEN OFF SUBOPERAND BITS        39400019
         SR    REG6,REG6                CLEAR OUT LENGTH REGISTER       39500019
         IC    REG6,0(REG5)             GET OPERAND LENGTH              39600019
         B     SUBPROC5                 PROCESS                         39700019
SUBPROC3 LA    REG5,1(REG5)             POINT TO OPERAND                39800019
         NI    MGESW,MGESUBF            TURN OFF NOT LAST SWITCH        39900019
         BAL   REG12,INCRE              INCREMENT TO NEXT OPERAND       40000019
         BR    REG9                     EXIT                            40100019
SUBPROC4 NI    0(REG5),SUBOPERF         CLEAR SUBOPERAND BITS           40200019
         SR    REG6,REG6                CLEAR LENGTH REGISTER           40300019
         IC    REG6,0(REG5)             GET OPERAND LENGTH              40400019
         B     SUBPROC3                 EXIT                            40500019
         SPACE 3                                                        40600019
*********************************************************************** 40700019
*           GET BUFFER FOR IHKAFI AND IHKBPM                            40800019
*********************************************************************** 40900019
GETAFIBF LA    REG7,TUBRAFBF            SET UP FOR GETMAIN              41000019
         L     REG1,IHKYYGML                                            41100019
         GETMAIN EC,LV=BUFLEN,A=(REG7),MF=(E,(1)) GET AFIO BUFFER       41200019
         LTR   REG15,REG15                                              41300019
         BC    7,GETBFER                IF OUT OF SPACE,RETURN          41400019
         OI    TUBAFISW,BUFCTL          INDICATE BUFFER ALLOCATED       41500019
         BR    REG5                     EXIT                            41600019
GETBFER  TM    PPTFLG,PPTUTIL           TEST FOR UTILITY FILE           41650019
         BZ    RETCD8                   IF NOT, RETURN                  41700019
         BAL   REG8,RLSEUTIL            OTHERWISE, RELEASE UTILITY FILE 41750019
         B     RETCD8                   RETURN WITH GETMAIN FAILURE     41800019
*                                         RETURN CODE                   41900019
         EJECT                                                          42000019
*********************************************************************** 42100019
*                                                                       42200019
*           MOVE LINES FROM ACTIVE FILE TO UTILITY FILE AND CREATE      42300019
*           NEW ACTIVE FILE                                             42400019
*                                                                       42500019
*********************************************************************** 42600019
MOVELINE MVI   TUBNXKEY+7,ENDACT        SET UP TO POINT                 42700019
         BAL   REG14,PTAFTER            POINT TO END OF ACTIVE FILE     42800019
         CLI   TUBNXKEY+7,ENDACT        TEST FOR NULL ACTIVE FILE       42900019
         BE    TWOOPR1                  IF YES, PROC AS NO OPERANDS     43000019
         L     REG15,TUBUFFAD                                           43100019
         CLC   TUBNXKEY,16(REG15)       TEST FOR END OF FILE MERGE      43200019
         BNH   TWOOPR1                  IF YES, DON'T CREATE UTILITY    43300019
         L     REG15,IHKYYKBX           SET UP ADDRESSABILITY FOR       43400019
         USING RAFKNBX,REG15              KONBOX                        43500019
         LA    REG1,OSDSQCTL            BUILD PARAMETER LIST FOR IHKRNQ 43600019
         ST    REG1,TUBPARM2                                            43700019
         DROP  REG15                                                    43800019
         L     REG1,TUBUFFAD                                            43900019
         LA    REG1,100(REG1)                                           44000019
         ST    REG1,TUBPARM1                                            44100019
         MVI   4(REG1),X00              CLEAR POST CODE IN ECB          44200019
         LA    REG1,TUBPARM1            GET ADDRESS OF PARM LIST        44300019
         L     REG15,IHKYYRNQ           GET ADDRESS OF IHKRNQ           44400019
         BALR  REG14,REG15              ENQUEUE FOR UTILITY FILE        44500019
         LTR   REG15,REG15              TEST RETURN CODE                44600019
         BNZ   RETCD8                   IF GETMAIN FAILED, RETURN       44700019
         BAL   REG15,TUBPARMB           BUILD PARM LIST FOR IHKAFI      44800019
         CREATE IS,ACTNUM=7,FTYPE=GBL   CREATE UTITITY FILE             44900019
*   TEST RETURN                                                         45000019
         CH    REG15,H4                 TEST RETURN CODE                45100019
         BE    OUTSPA1                  IF A.A. OUT OF SPACE, BRANCH    45200019
         BH    AFIRET1                  IF OTHER ERR, RETUNR            45300019
         OI    PPTFLG,PPTUTIL           SET UTILITY FILE SW             45400019
         BAL   REG5,GETAFIBF            GET BUFFER FOR IHKAFI           45500019
         L     REG5,TUBUFFAD                                            45600019
         LA    REG5,16(REG5)            POSITION TO MERGE AFTER LINE NO 45700019
         MVI   TUBNXKEY+7,BGNFILE       INDICATE BEGNING                45800019
         BAL   REG15,TUBPARMB           BUILD PARAMETER LIST FOR IHKAFI 45900019
         RPOINT B,NR                    POINT TO BEGNING OF ACTIVE FILE 46000019
         CH    REG15,H4                 TEST RETURN CODE                46100019
         BH    AFIRET                   IF ERROR, RETURN                46200019
         B     GETBLK1                  GET BLOCK FROM ACTIVE FILE      46300019
GETBLK   BAL   REG14,PTAFTER            POINT AFTER SPECIFIED LINE      46400019
GETBLK1  BAL   REG15,TUBPARMB           BUILD PARM LIST FOR AFI         46500019
         MVC   TUBCNTFS,H10             SET UP COUNT FOR IHKAFI         46600019
         RGET  R,M,A                    GET LINES FROM ACTIVE AREA      46700019
*   TEST RETURN CODE                                                    46800019
         CH    REG15,H4                 TEST RETURN CODE                46900019
         BE    EODAA                    IF EOD, PROCESS                 47000019
         BH    AFIRET                   IF OTHER ERR, RETURN            47100019
         SR    REG9,REG9                                                47200019
         IC    REG9,TUBCNTFS            GET NUMBER OF LINES             47300019
***************                                                         47400019
*   FIND AND SAVE LAST LINE NO                                          47500019
         LA    REG15,88                 GET LINE LENGTH                 47600019
         LR    REG6,REG15               SAVE LENGTH                     47700019
         MR    REG14,REG9               GET MAX LENGTH                  47800019
         SR    REG15,REG6               GET RELATIVE POSITION OF LAST   47900019
*                                         LINE NUMBER                   48000019
         L     REG6,TUBRAFBF            GET BUFFER ADDRESS              48100019
         LA    REG6,8(REG6)             POSITION PAST CONTROL WORDS     48200019
         AR    REG15,REG6               POSITION TO LAST LINE NUMBER    48300019
         MVC   PPTPARS(8),0(REG15)      SAVE LINE NO                    48400019
***************                                                         48500019
*   INSERT LINES INTO GLOBAL FILE                                       48600019
         BAL   REG15,TUBPARMB           BUILD PARM LIST FOR IHKAFI      48700019
         ENDUP                                                          48800019
*   TEST RETURN                                                         48900019
         LTR   REG15,REG15              TEST RETURN CODE                49000019
         BNZ   AFIRET                   IF ERR, RETURN                  49100019
         BAL   REG15,TUBPARMB           BUILD PARM LIST FOR IHKAFI      49200019
         MVI   TUBGBLKY+7,ENDACT        SET UP TO POINT TO END OF       49300019
*                                         GLOBAL FILE                   49400019
         RPOINT A,NR,FTYPE=GBL          POINT TO END OF GLOBAL FILE     49500019
*   TEST RETURN                                                         49600019
         CH    REG15,H4                 TEST RETURN CODE                49700019
         BH    AFIRET                   IF ERR, RETURN                  49800019
         BAL   REG15,TUBPARMB           BUILD PARM LIST FOR IHKAFI      49900019
         STH   REG9,TUBCNTFS                                            50000019
         INSERT M,FTYPE=GBL             INSERT LINES INTO GLOBAL FILE   50100019
*   TEST RETURN                                                         50200019
         CH    REG15,H4                 TEST RETURN CODE                50300019
         BE    OUTSPA                   IF A.A. OUT OF SPACE, BRANCH    50400019
         BH    AFIRET                   IF OTHER ERR, RETURN            50500019
         BAL   REG15,TUBPARMB           BUILD PARM LIST FOR IHKAFI      50600019
         ENDUP FTYPE=GBL                INSURE ALL UPDATES DONE         50700019
*   TEST RETURN                                                         50800019
         LTR   REG15,REG15              TEST RETURN CODE                50900019
         BNZ   AFIRET                   IF ERR, RETURN                  51000019
         MVC   TUBNXKEY,PPTPARS         PUT LINE NO OF LAST LINE IN     51100019
*                                         LAST INSERT INTO IHKAF AREA   51200019
         B     GETBLK                   MOVE NEXT BLOCK                 51300019
         SPACE 3                                                        51400019
*********************************************************************** 51500019
*          ROUTINE TO DELETE LINES SAVED                                51600019
*********************************************************************** 51700019
EODAA    BAL   REG15,TUBPARMB           BUILD PARAMETER LIST FOR IHKAFI 51800019
         RELEASE A                      RELEASE ACTIVE FILE             51900019
         LTR   REG15,REG15              TEST RETURN CODE                52000019
         BNZ   AFIRET                   IF ERROR, RETURN                52100019
         BAL   REG15,TUBPARMB           BUILD PARAMERTR LIST FOR IHKAFI 52200019
         CREATE IS                      CREATE ACTIVE FILE              52300019
         CH    REG15,H4                 TEST RETURN CODE                52400019
         BE    OUTSPA                   IF A.A. OUT OF SPACE, ENQ MSG   52500019
         BH    AFIRET                   IF OTHER ERROR, RETURN          52600019
TSTACT   LR    REG15,REG3               SAVE CURRENT PPT ADDR           52700019
         L     REG3,TUBPPTAD            GET ORIGONAL PPT                52800019
         OC    PPTFLG,0(REG15)          SET ALL SWITCHES IN PPT         52900019
         ST    REG13,PPTFLG+8                                           53000019
         TM    PPTFLG,PPTACTA           TEST FOR ACTIVE AREA MERGE      53100019
         BZ    UFMGE                    IF NOT, CALL IHKMUF TO MERGE    53200019
*                                         LINES FROM USER'S LIBRARY     53300019
         SPACE 1                                                        53400019
*********************************************************************** 53500019
*          CALL IHKMAA TO MERGE LINES FROM ACTIVE AREA                  53600019
*********************************************************************** 53700019
         LA    REG15,CMDMAA             GET ADDRESS OF IHKMAA           53800019
TSTACT1  LCR   REG15,REG15              PUT MAA CODE INT REG            53900019
         L     REG13,4(REG13)           GET CALLER'S SAVE AREA ADDR     54000019
         ST    REG15,16(REG13)          SAVE RETURN CODE                54100019
         B     RETURN1                  RETURN                          54200019
         SPACE 1                                                        54300019
*********************************************************************** 54400019
*          CALL IHKMUFF TO MERGE LINES FROM USER'S LIBRARY              54500019
*********************************************************************** 54600019
UFMGE    LA    REG15,CMDMUF             GET ADDRESS OF IHKMUF           54700019
         B     TSTACT1                                                  54800019
         EJECT                                                          54900019
*********************************************************************** 55000019
*                                                                       55100019
*           SUBROUTINE TO POINT AFTER THE LAST LINE INSERTED INTO       55200019
*           THE ACTIVE FILE                                             55300019
*                                                                       55400019
*********************************************************************** 55500019
PTAFTER  ST    REG14,PPTDSECT+16        SAVE RETURN REG                 55600019
         BAL   REG15,TUBPARMB           BUILD PARM LIST FOR IHKAFI      55700019
         RPOINT A,NR                    POINT AFTER LINE NO             55800019
*   TEST RETURN                                                         55900019
         CH    REG15,H4                 TEST RETURN                     56000019
         BL    GOBACK                   IF GOOD, EXIT                   56100019
         BH    AFIRET                   IF ERR, RETURN                  56200019
***************                                                         56300019
*   IF NONE OF THE ABOVE, LINE NO WAS NOT FOUND.  POINT AFTER           56400019
* PREVIOUS LINE                                                         56500019
         BAL   REG15,TUBPARMB           BUILD PARM LIST FOR IHKAFI      56600019
         RPOINT A,NR,KEY=HIEQ           POINT AFTER PREVIOUS LINE       56700019
*   TEST RETURN                                                         56800019
         CH    REG15,H4                 TEST RETURN CODE                56900019
         BH    AFIRET                   IF ERR, RETURN                  57000019
GOBACK   L     REG14,PPTDSECT+16        RESTORE RETURN REGISTER         57100019
         BR    REG14                    RETURN                          57200019
         EJECT                                                          57300019
*********************************************************************** 57400019
*                                                                       57500019
*          SUBROUTINE TO BUILD PARM LIST FOR IHKAFI                     57600019
*                                                                       57700019
*********************************************************************** 57800019
TUBPARMB LA    REG1,TUBDSECT            BUILD PARM LIST FOR IHKAFI      57900019
         ST    REG1,TUBPARM5                                            58000019
         LA    REG1,TUBPARM5            PUT LIST ADDR INTO PARM REG     58100019
         BR    REG15                    RETURN                          58200019
         SPACE 3                                                        58300019
**********************************************************************< 58400019
*          SET UP FOR RETURN FROM IHKAFI ERROR                          58500019
*********************************************************************** 58600019
AFIRET   ST    REG15,TUBIRLSA           SAVE RETURN CODE                58700019
         BAL   REG8,RLSEUTIL            RELEASE UTILITY FILE            58800019
AFIRET2  L     REG15,TUBIRLSA           RESTORE RETURN CODE             58900019
         B     RETURN                   RETURN                          59000019
AFIRET1  ST    REG15,TUBIRLSA           SAVE RETURN CODE                59100019
         BAL   REG8,ENDUPACT            ENDUP ACTIVE AREA               59200019
         B     AFIRET2                  RETURN                          59300019
         EJECT                                                          59400019
*********************************************************************** 59500019
*                                                                       59600019
*           ERROR PROCESSING ROUTINES                                   59700019
*                                                                       59800019
*********************************************************************** 59900019
         SPACE 3                                                        60000019
*********************************************************************** 60100019
*           DATA SET NAME IN ERROR                                      60200019
*********************************************************************** 60300019
DSNERR   LA    REG15,DSNAME             SET UP 3RD PARM                 60400019
DSNERR1  LA    REG14,OPRERRCD           SET UP 2ND PARM                 60500019
         BAL   REG8,ENQMSG2             ENQUEUE MSG FOR USER            60600019
         B     INCRSUB                  TEST NEXT OPERAND               60700019
DSNERR2  LA    REG15,DSNAME             SET UP FOR ERRRR MESSAGE        60800019
         BAL   REG9,SUBPROC             PROCESS ERROR                   60900019
         B     TSTSUB                   TEST NEXT OPERAND               61000019
         SPACE 3                                                        61100019
*********************************************************************** 61200019
*           USERID INVALID                                              61300019
*********************************************************************** 61400019
UIDERR   LA    REG15,USERID             SET UP 3RD PARM                 61500019
         B     DSNERR1                  FINISH PARM SET UP              61600019
         SPACE 3                                                        61700019
*********************************************************************** 61800019
*           LINE NUMBER OPERAND INVALID                                 61900019
*********************************************************************** 62000019
LNOERR   LA    REG14,LNOERRCD           SET UP 2ND PARM                 62100019
         LR    REG15,REG5               GET OPERAND ADDRESS             62200019
         BCTR  REG15,0                                                  62300019
LNOERR1  BAL   REG8,ENQMSG2             ENQUEUE MSG FOR USER            62400019
         B     INCOPER                  TEST NEXT OPERAND               62500019
         SPACE 3                                                        62600019
*********************************************************************** 62700019
*           KEY LENGTH ERROR                                            62800019
*********************************************************************** 62900019
KEYERR   LA    REG15,KEY                SET UP 3RD PARM                 63000019
         LA    REG14,OPRERRCD           GET MESSAGE CODE                63100019
         BAL   REG8,ENQMSG2             ENQUEUE ERROR MESSAGE           63200019
         B     INCOPER                  TEST NEXT OPERAND               63300019
         SPACE 3                                                        63400019
*********************************************************************** 63500019
*           ** OPERAND INVALID                                          63600019
*********************************************************************** 63700019
OPRERR   LR    REG15,REG5               SET UP 3RD PARM                 63800019
         BCTR  REG15,0                                                  63900019
         B     DSNERR1                  FINISH PARM SETUP               64000019
OPRERR1  LR    REG15,REG5               SET UP FOR ERROR MESSAGE        64100019
         BAL   REG9,SUBPROC             PROCESS ERROR                   64200019
         B     TSTLAST                  TEST NEXT OPERAND               64300019
         SPACE 3                                                        64400019
*********************************************************************** 64500019
*           EXCESSIVE OPERANDS                                          64600019
*********************************************************************** 64700019
EXCESSOP LA    REG14,EXOPCD             SET UP 2ND PARM                 64800019
         LR    REG15,REG5               GET OPERAND ADDRESS             64900019
         BCTR  REG15,0                                                  65000019
         BAL   REG8,ENQMSG2             ENQUEUE MSG                     65100019
         B     RETCD0                   RETURN                          65200019
         SPACE 3                                                        65300019
*********************************************************************** 65400019
*           NO OPERANDS                                                 65500019
*********************************************************************** 65600019
NOOPER   LA    REG14,REQOPRCD           SET UP 2ND PARM                 65700019
         LA    REG15,DSNAME             SETUP 3RD PARM                  65800019
         BAL   REG8,ENQMSG2             ENQUEUE MSG                     65900019
         B     RETCD0                   RETURN                          66000019
         SPACE 3                                                        66100019
*********************************************************************** 66200019
*           LINE NO RANGE INVALID                                       66300019
*********************************************************************** 66400019
RANGERR  LA    REG14,RANGECD            SET UP 2NE PARM                 66500019
         BAL   REG8,ENQMSG1             ENQUEUE MESSAGE                 66600019
         B     RETCD0                   RETURN                          66700019
         SPACE 3                                                        66800019
*********************************************************************** 66900019
*                                                                       67000019
*           ROUTINE TO ENQUEUE MESSAGE FOR USER                         67100019
*                                                                       67200019
*********************************************************************** 67300019
ENQMSG2  ST    REG15,TUBPARM5           PUT 3RD PARM INTO LIST          67400019
         OI    TUBPARM5,LSTPARM         FLAG END OF LIST                67500019
         ST    REG14,TUBPARM4           PUT 2ND PARM INTO LIST          67600019
         B     ENQMSG                   FINISH LIST AND ENQ MSG         67700019
ENQMSG1  ST    REG14,TUBPARM4           PUT 2ND PARM INTO LIST          67800019
         OI    TUBPARM4,LSTPARM         FLAG END OF LIST                67900019
ENQMSG   LA    REG15,TUBUSRID           GET 1ST PARM ADDR               68000019
         ST    REG15,TUBPARM3           PUT INTO LIST                   68100019
         ST    REG2,TUBPARM2            PUT TUB ADDRESS INTO LIST       68200019
         LA    REG1,TUBPARM2            GET ADDRESS OF PARAMETER LIST   68300019
         L     REG12,TUBRAFBF           SAVE AFI BUFFER ADDR            68400019
         L     REG15,IHKYMSG1           GET ADDRESS OF MSG WRITER       68500019
         BALR  REG14,REG15              ENQUEUE MSG FOR USER            68600019
         ST    REG12,TUBRAFBF           RESTORE BUFFER ADDRESS          68700019
         LTR   REG15,REG15              TEST RETURN CODE                68800019
         BC    7,RETURN                 IF BAD, RETURN                  68900019
         OI    MGESW,MGEERR             SET ERROR SW                    69000019
         NI    TUBPARM4,LSTPARMF        TURN OFF END OF LIST FLAG       69100019
         NI    TUBPARM5,LSTPARMF        TURN OFF END OF LIST FLAG       69200019
         BR    REG8                     EXIT                            69300019
         SPACE 1                                                        69400019
         SPACE 3                                                        69500019
*********************************************************************** 69600019
*          ERROR RECOVERY PROCEDURE FOR DISK ERROR IN ACTIVE AREA       69700019
*********************************************************************** 69800019
DSKERA   BAL   REG9,DEQGBL              DEQUEUE FROM GLOBAL QUEUE       69900019
         LA    REG15,12                 SET ACTIVE AREA I/O ERROR       70000019
*                                         RETURN CODE                   70100019
         B     RETURN                   RETURN                          70200019
         SPACE 3                                                        70300019
*********************************************************************** 70400019
*          ERROR RECOVERY ROUTINE FOR OUT OF SPACE ACTIVE AREA          70500019
*********************************************************************** 70600019
OUTSPA   BAL   REG8,RLSEUTIL            RELEASE UTILITY FILE AND ENDUP  70700019
OUTSPA3  LA    REG14,OUTSPACD           PUT OUT OF SPACE CODE IN PARM   70800019
*                                         LIST                          70900019
         BAL   REG8,ENQMSG1             QUEUE MESSAGE                   71000019
         LA    REG15,20                 SET UPT OF SPACE RETURN CODE    71100019
         B     RETURN                   RETURN                          71200019
OUTSPA1  BAL   REG8,ENDUPACT            ENDUP ACTIVE AREA               71300019
         B     OUTSPA3                  BUILD PARM LIST FOR MSG         71400019
         SPACE 3                                                        71500019
*********************************************************************** 71600019
*          SUBROUTINE TO RELEASE UTILITY FILE AND ENDUP ACTIVE AREA     71700019
*********************************************************************** 71800019
RLSEUTIL ST    REG8,TUBPARM4            SAVE EXIT REGISTER              71900019
         MVI   TUBGBLNM,UFCODE          PUT UTILITY FILE NO INTO TUB    71950019
         BAL   REG15,TUBPARMB           BUILD PARM LIST FOR IHKAFI      72000019
         RELEASE A,FTYPE=GBL            RELEASE UTILITY FILE            72100019
         LTR   REG15,REG15              TEST RETURN CODE                72200019
         BNZ   RETURN                   IF ERR, RETURN                  72300019
         TM    TUBAFISW,BUFCTL          TEST FOR BUFFER                 72400019
         BZ    ENDUPACT                 IF NOT, SKIP FREEMAIN           72500019
         L     REG1,TUBRAFBF            SET UP FOR FREEMAIN             72600019
         LA    REG1,0(0,REG1)           CLEAR HIGH ORDER BYTE           72700019
         FREEMAIN R,LV=BUFLEN,A=(1)     FREE BUFFER                     72800019
         NI    TUBAFISW,BUFCTLF         TURN OFF BUFFER CTL SW          72900019
ENDUPACT BAL   REG9,DEQGBL              DEQUEUE FROM GLOBAL QUEUE       73000019
         BAL   REG15,TUBPARMB           BUILD PARM LIST FOR IHKAFI      73100019
         ENDUP                                                          73200019
         LTR   REG15,REG15              TEST RETURN CODE                73300019
         BNZ   RETURN                   IF ERR, RETURN                  73400019
         BR    REG8                     RETURN                          73500019
         SPACE 3                                                        73600019
*********************************************************************** 73700019
*          DEQUEUE FROM GLOBAL FILE                                     73800019
*********************************************************************** 73900019
         SPACE 1                                                        74000019
DEQGBL   L     REG15,TUBUFFAD           DEQUEUE FROM GLOBAL FILE        74100019
         L     REG15,100(REG15)                                         74200019
         L     REG14,IHKYYKBX                                           74300019
         USING RAFKNBX,REG14                                            74400019
         ST    REG15,OSDSQCTL           UPDATE QUEUE CONTROL BLOCK      74500019
         LA    REG15,0(REG15)                                           74600019
         LA    REG1,OSDSQCTL+4                                          74700019
         CR    REG15,REG1               TEST FOR EMPTY QUEUE            74800019
         BE    0(REG9)                  IF YES, EXIT                    74900019
         OI    4(REG15),POST            IF NOT, POST NEXT ELEMENT       75000019
NOELEM   BR    REG9                     EXIT                            75100019
         EJECT                                                          75200019
*********************************************************************** 75300019
*                                                                       75400019
*           CONSTANTS                                                   75500019
*                                                                       75600019
*********************************************************************** 75700019
H10      DC    H'10'                    HALFWORD CONSTANT OF 10         75800019
H1       DC    H'1'                     HALFWORD CONSTANT OF 1          75900019
H2       DC    H'2'                     HALFWORD CONSTANT OF 2          76000019
H3       DC    H'3'                     HALFWORD CONSTANT OF 3          76100019
H4       DC    H'4'                     HALFWORD CONSTANT OF 4          76200019
F0       DC    F'0'                     FULLWORD CONSTANT OF 0          76300019
ASTERISK DC    C'*'                     COMPARE CONSTANT FOR ACTIVE FI  76400019
BLANKS   DC    CL8' '                   8 BYTES OF BLANKS FOR CLEARING  76500019
DSNAME   DC    X'06'                    CONSTANT FOR DSNAME INVALID MSG 76600019
         DC    C'DSNAME'                                                76700019
USERID   DC    X'06'                    CONST FOR USRID INVALID MSG     76800019
         DC    C'USERID'                                                76900019
KEY      DC    X'03'                    CONSTANT FOR KEY INVALID MSG    77000019
         DC    C'KEY'                                                   77100019
         SPACE 3                                                        77200019
*********************************************************************** 77300019
*           MESSAGE CODES                                               77400019
*********************************************************************** 77500019
         DS    0F                                                       77600019
OPRERRCD DC    X'00F3F0F2'              OPERAND INVALID                 77700019
LNOERRCD DC    X'00F3F0F7'              LINE NUMBER INVALID             77800019
EXOPCD   DC    X'00F3F3F4'              EXCESSIVE OPERANDS              77900019
REQOPRCD DC    X'00F3F1F7'              REQUIRED OPERAND MESSING        78000019
RANGECD  DC    X'00F3F6F7'              LINE NUMBER RANGE INVALID       78100019
OUTSPACD DC    X'00F3F5F7'              OUT OF SPACE ACTIVE AREA        78200019
         SPACE 3                                                        78300019
*********************************************************************** 78400019
*           EXECUTED INSTRUCTIONS                                       78500019
*********************************************************************** 78600019
MVCDSN   MVC   TUBPMFNM(0),0(REG5)      MOVE DSNAME TO TUB              78700019
MVCUID   MVC   TUBUSRNM(0),0(REG5)      MOVE USERID TO TUB              78800019
MVCKEY   MVC   0(0,REG14),0(REG5)       SAVE KEY                        78900019
         SPACE 3                                                        79000019
         EJECT                                                          79100019
*********************************************************************** 79200019
*                                                                       79300019
*           DSECT FOR SAVE AREA AND WORK AREAS                          79400019
*                                                                       79500019
*********************************************************************** 79600019
VDSECT   DSECT                                                          79700019
SAVEA    DS    18F                      SAVE AREA                       79800019
CTR      DS    H                        OPERAND COUNTER                 79900019
         SPACE 3                                                        80000019
*********************************************************************** 80100019
*           PARAMETER AREAS                                             80200019
*********************************************************************** 80300019
PARM1    DS    0F                                                       80400019
         DS    CL10                                                     80500019
PARM2    DS    0F                                                       80600019
         DS    CL10                                                     80700019
         SPACE 3                                                        80800019
*********************************************************************** 80900019
*           PROCESSING SWITCHES                                         81000019
*********************************************************************** 81100019
MGESW    DS    X                        SWITCH AREA                     81200019
MGEUID   EQU   X'80'                    USERID FOUND                    81300019
MGEERR   EQU   X'40'                    OPERAND ERROR FOUND             81400019
MGESUB   EQU   X'20'                    NOT LAST SUBOPERAND             81500019
MGESUBF  EQU   X'DF'                    OFF                             81600019
MGENKEY   EQU  X'10'                    NO KEY                          81700019
MGEOFF   EQU   X'00'                    ALL SWITCHES OFF                81800019
GMLEN    EQU   *-VDSECT                 LENGTH OF DSECT                 81900019
         EJECT                                                          82000019
*********************************************************************** 82100019
*                                                                       82200019
*           DSECTS FOR CRJE CONTROL BLOCKS                              82300019
*                                                                       82400019
*********************************************************************** 82500019
         IHKCDSCT TUB=YES,PPT=YES,AVT=YES                               82600019
         TUBEQU                                                         82700019
         RAFKNBX TYPE=DSECT                                             82800019
         CMDEQU                                                         82900019
         END                                                            83000019
