MSG      TITLE 'IHKMSG - MESSAGE WRITER'                                00080019
IHKMSG   CSECT                                                          00160019
*A316800                                                         A36801 00180020
*C220800,949600                                                  A36801 00200020
*D316800                                                         A36801 00220020
*STATUS -- CHANGE LEVEL 0                                             * 00240019
*                                                                     * 00320019
*FUNCTION -- MESSAGE BUILDING, HANDLING, AND ROUTING                  * 00400019
*   1. BUILD A MESSAGE BY COMBINING 'CANNED' TEXT WITH INSERTS        * 00480019
*      SUPPLIED BY THE USER                                           * 00560019
*   2. BUILD A MESSAGE AND SEND IT TO A TERMINAL USER                 * 00640019
*   3. BUILD A MESSAGE, SEND THE MESSAGE TO A TERMINAL USER, AND      * 00720019
*      RETURN A REPLY FROM THE TERMINAL USER.                         * 00800019
*   4. BUILD A MESSAGE AND QUEUE IT TO AN OPERATOR                    * 00880019
*   5. BUILD A MESSAGE AND QUEUE IT FOR LATER DELIVERY TO A TERMINAL  * 00960019
*      USER.                                                          * 01040019
*   6. QUEUE FOR LATER DELIVERY A SUPPLIED MESSAGE                    * 01120019
*   7. SEND A SUPPLIED MESSAGE TO AN OPERATOR                         * 01200019
*   8. DEQUEUE A CORE MESSAGE FOR A TERMINAL USER AND PLACE THE       * 01280019
*      MESSAGE IN USRMSGS GLOBAL FILE.                                * 01360019
*   9. SEND ALL BROADCAST MESSAGES TO AN OPERATOR                     * 01440019
*   10.SEND ALL AVAILABLE MESSAGES TO A TERMINAL USER                 * 01520019
*                                                                     * 01600019
*   ALL MESSAGES ARE BUILD AS FOLLOWS - (1). THE 'CANNED' PORTION OF  * 01680019
*   THE MESSAGE TEXT IS ACCESSED FROM THE SYSMSGS GLOBAL FILE IN THE  * 01760019
*   ACTIVE AREA USING AFIO AND READ INTO THE FIRST EIGHTY.EIGHT       * 01840019
*   BYTES OF THE USER BUFFER FOR THE CRJE SUBTASK WHICH REQUESTED     * 01920019
*   THAT THE MESSAGE BE BUILT.  THE FIRST 16 BYTES CONTAIN AFIO       * 02000019
*   CONTROL INFORMATION.  THE KEY FOR EACH MESSAGE IS IHK3XX OR       * 02080019
*   IHK4XX FOR A TERMINAL MESSAGE OR IHK2XXI FOR AN OPERATOR          * 02160019
*   MESSAGE.  (2). A CHECK IS MADE TO SEE IF TEXT INSERTION IS        * 02240019
*   ALLOWABLE.  IF BYTES 72 AND 73 OF THE CANNED TEXT CONTAIN         * 02320019
*   X'0000', NO TEXT CAN BE INSERTED.  IF TEXT CAN BE INSERTED, THE   * 02400019
*   BYTES CONTAIN THE TWO OFFSETS AT WHICH THE SUPPLIED TEXT IS TO    * 02480019
*   BE ADDED.  (3). IF TEXT INSERTION IS PREMISSABLE AND TEXT HAS     * 02560019
*   BEEN PROVIDED, THE SUPPLIED TEXT IS MOVED INTO THE CANNED         * 02640019
*   MESSAGE.                                                          * 02720019
*                                                                     * 02800019
*   IF THE MESSAGE IS TO BE QUEUED FOR LATER DELIVERY TO A TERMINAL,  * 02880019
*   ONE OF THE FOLLOW ACTIONS IS TAKEN. - (1). IF THE CRJE SUBTASK    * 02960019
*   WHICH REQUESTED THE QUEUING IS THE SUBTASK FOR THE USER WHO IS    * 03040019
*   TO RECEIVE THE MESSAGE AND NO MESSAGE IS CURRENTLY QUEUED IN      * 03120019
*   CORE FOR THAT USER, A CONDITIONAL GETMAIN FOR 72 BYTES OBTAINS    * 03200019
*   AN AREA, THE ENTIRE TEXT IS MOVED INTO THE AREA, AND THE ADDRESS  * 03280019
*   OF THE AREA IS PLACED IN THE TUBFQEB FIELD OF THE TERMINAL USER   * 03360019
*   BLOCK FOR THE RECIPIENT USER.  (2). IF THE CRJE SUBTASK WHICH     * 03440019
*   REQUESTED THE QUEUING IS NOT THE SUBTASK FOR THE USER FOR WHOM    * 03520019
*   THE MESSAGE IS BEING QUEUED OR A MESSAGE IS CURRENTLY QUEUED IN   * 03600019
*   CORE FOR THE RECIPIENT USER, THE MESSAGE IS WRITTEN TO THE        * 03680019
*   USRMSGS FILE IN THE ACTIVE AREA.  THE KEY USED FOR THE MESSAGE    * 03760019
*   IS THE 7 BYTE USERID OF THE RECIPIENT PLUS A ONE-BYTE SEQUENCE    * 03840019
*   NUMBER TO DENOTE THE RELATIVE POSITION OF THE MESSAGE IN THE      * 03920019
*   LIST OF MESSAGES FOR THAT USER.  IF THE RECIPIENT USER IS ACTIVE  * 04000019
*   THE TUBMSG BIT IN THE TUBFLG1 FIELD OF HIS TERMINAL USER BLOCK    * 04080019
*   IS TURNED ON.  OTHERWISE, THE UVRDMSG BIT IN THE UVRCNTL1 FIELD   * 04160019
*   OF HIS USER VERIFICATION RECORD IN THE USERS GLOBAL FILE IS       * 04240019
*   TURNED ON.                                                        * 04320019
*                                                                     * 04400019
*   IF ALL AVAILABLE MESSAGES ARE TO BE SENT, THE FOLLOWING ACTIONS   * 04480019
*   ARE PREFORMED - (1). 'LOST MESSAGE' MESSAGE IS SENT IF THE LOST   * 04560019
*   MESSAGE BIT (TUBLMSGN) IS ON IN THE TUB.  (2). ANY MESSAGE        * 04640019
*   QUEUED IN CORE IS SENT.  (3). MESSAGES ON USRMSGS FOR THE USER    * 04720019
*   ARE SENT.  (4). BROADCAST MESSAGES ARE SENT IF THE TUBBRD BIT IS  * 04800019
*   ON IN THE TERMINAL USER BLOCK.                                    * 04880019
*                                                                     * 04960019
*   IF A BREAK OCCURS ALL PENDING MESSAGES FOR THE USER ARE DELETED   * 05040019
*   AND THE BROADCAST MESSAGE BIT IS TURNED OFF.                      * 05120019
*                                                                     * 05200019
*   ALL READS/WRITES TO/FROM A TERMINAL USE CRJE MACROS WHICH EXPAND  * 05280019
*   TO A BRANCH TO IHKLAD TO USE BTAM.                                * 05360019
*                                                                     * 05440019
*   AIFO MACROS ARE USED FOR ALL I/O TO/FROM THE ACTIVE AREA.         * 05520019
*                                                                     * 05600019
*ENTRY POINTS --                                                      * 05680019
*        IHKMSG - MAIN ENTRY POINT.  THE FUNCTIONS OF THIS ENTRY ARE  * 05760019
*        TO BUILD AND SEND A MESSAGE TO AN OPERATOR, BUILD AND SEND A * 05840019
*        MESSAGE TO A TERMINAL USER WITH OR WITHOUT A RESPONSE AND    * 05920019
*        WITH OR WITHOUT A MESSAGE IDENTIFIER, OR TO SEND ALL         * 06000019
*        AVAILABLE MESSAGES TO A TERMINAL USER.                       * 06080019
*                                                                     * 06160019
*        THE VARIABLE LENGTH ARGUMENT LIST POINTED TO BY REGISTER ONE * 06240019
*        CONTAINS   IN WORD ONE, THE ADDRESS OF THE TUB FOR THE       * 06320019
*        REQUESTING CRJE SUBTASK, IN WORK TWO.THE ADDRESS OF THE TUB  * 06400019
*        FOR THE TERMINAL USER OR THE ADDRESS OF A ONE BYTE OPERATOR  * 06480019
*        CONSOLE ID FOLLOWED BY THREE BYTES OF BINARY ZEROES FOR AN   * 06560019
*        OPERATOR.   IN WORD THREE THE ADDRESS OF A 4-BYTE MESSAGE    * 06640019
*        AREA ON A WORD BOUNDARY, AND IN WORDS FOUR AND FIVE THE      * 06720019
*        OPTIONAL ADDRESSES OF INSERTION TEXT PRECEDED BY A ONE BYTE  * 06800019
*        LENGTH FIELD.  THE 4-BYTE MESSAGE AREA CONSISTS OF A FLAG    * 06880019
*        BYTE FOLLOWED BY THE EBCDIC EQUIBALENT OF THE THREE DIGIT    * 06960019
*        NUMBER OF THE MESSAGE TO BE BUILT.                           * 07040019
*                                                                     * 07120019
*        IHKMSG01 - SECONDARY ENTRY POINT.  THE FUNCTIONS OF THIS     * 07200019
*        ENTRY ARE TO BUILD AND EQUEUE A MESSAGE FOR LATER DELIVERY   * 07280019
*        TO A TERMINAL USER.                                          * 07360019
*                                                                     * 07440019
*        THE VARIABLE LENGTH ARGUMENT LIST POINTED TO BY REGISTER ONE * 07520019
*        CONTAINS IN WORD ONE, THE ADDRESS OF THE TUB FOR THE         * 07600019
*        REQUESTING CRJE SUBTASK, IN WORD 2 THE ADDRESS OF THE USERID * 07680019
*        OF THE TERMINAL USER TO RECEIVE THE MESSAGE, IN WORD THREE   * 07760019
*        THE ADDRESS OF A FULLWORD WHOSE LOW ORDER THREE BYTES CONTAIN* 07840019
*        THE EBCDIC NUMBER OF THE CANNED MESSAGE, AND IN WORDS FOUR   * 07920019
*        AND FIVE THE OPTIONAL ADDRESSES OF INSERTION TEXT PRECEDED BY* 08000019
*        A ONE-BYTE LENGTH FIELD.                                     * 08080019
*                                                                     * 08160019
*        IHKMSG02 - SECONDARY ENTRY POINT.  THE FUNCTIONS OF THIS     * 08240019
*        ENTRY ARE TO ENQUEUE A SUPPLIED MESSAGE FOR A TERMINAL USER  * 08320019
*        OR TO SEND A SUPPLIED MESSAGE TO AN OPERATOR.                * 08400019
*                                                                     * 08480019
*        THE THREE WORD ARGUMENT LIST POINTED TO BY REGISTER ONE      * 08560019
*        CONTAINS IN WORD ONE THE ADDRESS OF THE TUB FOR THE          * 08640019
*        REQUESTING CRJE SUBTASK, IN WORD TWO THE ADDRESS OF THE TUB  * 08720019
*        FOR AN ACTIVE USER OR A CONSOLE ID FOLLOWED BY THREE BYTES OF* 08800019
*        BINARY ZEROES IF THE MESSAGE IS FOR AN OPERATOR, AND IN WORD * 08880019
*        THREE THE ADDRESS OF A SEVENTY-TWO BYTE MESSAGE (INCLUDING   * 08960019
*        THE MESSAGE ID) FOR A TERMINAL USER OR THE FULL INTERNAL     * 09040019
*        FORMAT OF AN OPERATOR MESSAGE WITH ALL REQUIRED MCS FLAGS    * 09120019
*        AND CODES.                                                   * 09200019
*                                                                     * 09280019
*        IHKMSG03 - SECONDARY ENTRY POINT.  THE ONLY FUNCTION IS TO   * 09360019
*        LIST BROADCAST MESSAGES FOR AN OPERATOR.                     * 09440019
*                                                                     * 09520019
*        THE TWO WORD PARAMETER LIST POINTED TO BY REGISTER ONE       * 09600019
*        CONTAINS IN WORD ONE THE ADDRESS OF THE TUB FOR THE          * 09680019
*        REQUESTING CRJE SUBTASK AND IN WORD TWO THE ADDRESS OF A ONE * 09760019
*        BYTE AREA CONTAINING A CONSOLE ID.                           * 09840019
*                                                                     * 09920019
*INPUT -- INPUT FOR EACH ENTRY POINT IS DESCRIBED IN THE SECTION ON   * 10000019
*   THE ENTRY POINT                                                   * 10080019
*                                                                     * 10160019
*OUTPUT -- IF THE REQUEST IS FOR BUILD ONLY, ALL SWITCHES IN THE TUB  * 10240019
*   ARE SET EXACTLY AS REQUIRED BEFORE A CWRITE MACRO.  THE MESSAGE   * 10320019
*   IS PLACED IN THE USER BUFFER.  IF THE REQUEST IS TO SEND A        * 10400019
*   MESSAGE AND READ A REPLY, ALL SWITCHES ARE LEFT EXACTLY AS SET    * 10480019
*   BY IHKLAD AND THE RESPONSE IN THE USER BUFFER IS NOT ALTERED.     * 10560019
*                                                                     * 10640019
*EXTERNAL REFERENCES --                                               * 10720019
*        IHKLAD - CRJE LINE ADMINISTRATOR FOR TERMINAL I/O            * 10800019
*        IHKAFI - FOR MANIPULATION OF GLOBAL FILES                    * 10880019
*        SVC 35 - FOR WRITE-TO-OPERATOR MACRO (WTO)                   * 10960019
*                                                                     * 11040019
*EXITS,NORMAL --                                                      * 11120019
*        REGISTER 15 = 0                                              * 11200019
*                                                                     * 11280019
*EXITS,ERROR --                                                       * 11360019
*        REGISTER 15 = 4  FOR A COMMUNICATIONS LINE ERROR             * 11440019
*        REGISTER 15 = 8  FOR A GETMAIN FAILURE                       * 11520019
*        REGISTER 15 = 12 FOR AN ACTIVE AREA I/O ERROR                * 11600019
*        REGISTER 15 = 16 FOR A LOST MESSAGE                          * 11680019
*        REGISTER 15 = 20 FOR ACTIVE AREA OUT OF SPACE                * 11760019
*        REGISTER 15 = 24 FOR AN INVALID USERID                       * 11840019
*                                                                     * 11920019
*TABLES/WORK AREAS --                                                 * 12000019
*   THE FORMAT OF THE CANNED MESSAGE TEXT IS :                        * 12080019
*   0-7 = MESSAGE ID                                                  * 12160019
*   8-71= MESSAGE TEXT                                                * 12240019
*   72  = OFFSET WITHIN TEXT AT WHICH TO INSERT VARIABLE TEXT         * 12320019
*   73  = OFFSET WITHIN TEXT AT WHICH TO INSERT VARIABLE TEXT         * 12400019
*   74-5= MCS DESCRIPTOR CODES                                        * 12480019
*   76-7= MCS ROUTING CODES                                           * 12560019
*                                                                     * 12640019
*   TUB - TERMINAL USER BLOCK                                         * 12720019
*   TUBREAKN = X'40' -  A REAL OR SIMULATED BREAK HAS OCCURRED        * 12800019
*   TUBUFFAD = ADDRESS OF USER BUFFER                                 * 12880019
*   TUBDATAL = 2 BYTE LENGTH OF DATA TO/FROM TERMINAL                 * 12960019
*   TUBUSRID = ID OF USER TO WHOM CRJE SUBTASK BELONGS                * 13040019
*   TUBNEXT  = ADDRESS OF NEXT TUB IN CHAIN                           * 13120019
*   TUBMID   = X'40' -  THE USER HAS REQUESTED ID'S ON HIS MESSAGES   * 13200019
*   TUBMSG   = X'02' -  THE USER HAS A MESSAGE IN USRMSGS             * 13280019
*   TUBBRD   = X'01' -  THE USER HAS REQUESTED BROADCAST MESSAGES     * 13360019
*   TUBLMSGN = X'40' -  A MESSAGE FOR THE USER HAS BEEN LOST          * 13440019
*   TUBNOCRN = X'40' -  NO CARRIAGE RETURN AT TERMINAL AFTER MESSAGE  * 13520019
*   TUBFQEB  = 0 OR ADDRESS OF CORE MESSAGE (4 BYTES)                 * 13600019
*   TUBRAFBF = ADDRESS OF BUFFER AFIO (4 BYTES)                       * 13680019
*   TUBGBLNM = NUMBER OF THE GLOBAL FILE (X'01'-SYSMSGS,X'02'-USERS,  * 13760019
*         ,    X'03'-USRMSGS,X'04'-BRDCST)                            * 13840019
*   TUBGBLKY = 8 BYTE KEY OF GLOBAL FILE RECORD                       * 13920019
*   TUBPARM1 = 4 BYTE AREA FOR IHKAFI PARAMETER LIST                  * 14000019
*   TUBAFISW = X'80' TO REQUEST AFIO BUFFER CONTROL                   * 14080019
*                                                                     * 14160019
*   AVT - CRJE ADDRESS VECTOR TABLE                                   * 14240019
*   IHKYYCCT = ADDRESS OF CRJE CONTROL TABLE                          * 14320019
*   IHKYYTUB = ADDRESS OF FIRST TUB IN CHAIN                          * 14400019
*                                                                     * 14480019
*   UVR - USER VERIFICATION RECORD                                    * 14560019
*   UVRDMSG = X'40' - AN INACTIVE USER HAS A MESSAGE IN USRMSGS       * 14640019
*   UVRLMSGN = X'04' - AN INACTIVE USER LOST A MESSAGE                * 14720019
*                                                                     * 14800019
*   THE FORMAT OF A CRJE BROADCAST MESSAGE IS:                        * 14880019
*   0-2 = BRD                                                         * 14960019
*   3-6 = MESSAGE NUMBER                                              * 15040019
*   7   = BLANK                                                       * 15120019
*   8-47= TEXT SUPPLIED BY OPERATOR                                   * 15200019
*   47- = UNUSUED                                                     * 15280019
*                                                                     * 15360019
*   THE SAVE AREA + 72 BYTES CONTAINS THE 24 BYTES OF INFORMATION     * 15440019
*   BEGINNING WITH THE ADDRESS IN REGISTER 1 ON ENTRY.  SINCE THE     * 15520019
*   MAXIMUM LENGTH PARAMETER LIST IS 20 BYTES, THIS GUARANTEES THAT   * 15600019
*   THE PARAMETER LIST AS ENTERED IS PRESERVED INTACT ACROSS BRANCHES * 15680019
*   TO IHKLAD AND IHKAFI.  THE ADDRESS OF THIS AREA IS KEPT IN        * 15760019
*   REGISTER 8.                                                       * 15840019
*                                                                     * 15920019
*ATTRIBUTES -- RESIDENT, REENTRANT, NON-REFRESHABLE                   * 16000019
*                                                                     * 16080019
*NOTES --                                                             * 16160019
*   ALL CANNED TEXT FOR MESSAGES IS KEPT IN THE SYSMSGS GLOBAL FILE   * 16240019
*   AFTER STARTUP OF CRJE.  PRIOR TO STARTUP, THE SYSMSGS MEMBER OF   * 16320019
*   CRJE. SYSLIB CONTAINS THE TEXT.  AT SYSTEM GENERATION, MODULE     * 16400019
*   IHKSMG CONTAINS THE MESSAGE TEXT.                                 * 16480019
*                                                                     * 16560019
*   THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL             * 16640019
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 16720019
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN            * 16800019
*   ARRANGED SO THAT THE REDEFINITION OF 'CHARACTER' CONSTANTS, BY  *   16880019
*   REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW           * 16960019
*   DEFINITIONS                                                       * 17040019
         EJECT                                                          17120019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 17200019
*                                                                     * 17280019
*                   REGISTER   EQUATES                                * 17360019
*                                                                     * 17440019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 17520019
         SPACE                                                          17600019
R0       EQU   0                   WORK REGISTER                        17680019
R1       EQU   1                   WORK REGISTER                        17760019
R2       EQU   2                   INTERNAL BRANCH REGISTER             17840019
R3       EQU   3                   WORK REGISTER                        17920019
R4       EQU   4                   WORK REGISTER                        18000019
R5       EQU   5                   ADDRESS OF BUILT MESSAGE             18080019
R6       EQU   6                   ADDRESS OF REQUESTING TUB            18160019
R7       EQU   7                   ADDRESS OF CCT                       18240019
R8       EQU   8                   ADDRESS OF INPUT PARAMETER LIST      18320019
R9       EQU   9                   ADDRESS OF USER BUFFER               18400019
R10      EQU   10                  BASE REGISTER FOR AVT DSECT          18480019
R11      EQU   11                  ADDRESS OF RECIPIENT TUB OR ZERO     18560019
R12      EQU   12                  BASE REGISTER FOR CSECT              18640019
R13      EQU   13                  ADDRESS OF SAVE AREA                 18720019
R14      EQU   14                  ENTRY REGISTER                       18800019
R15      EQU   15                  RETURN REGISTER                      18880019
         SPACE                                                          18960019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 19040019
*                                                                     * 19120019
*                       OTHER EQUATES                                 * 19200019
*                                                                     * 19280019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 19360019
         SPACE                                                          19440019
X2       EQU   X'02'               USERS GLOBAL FILE NUMBER             19520019
X4       EQU   X'04'               NO. OF BROADCAST GLOBAL FILE         19600019
X00      EQU   X'00'               MASK OF NO BITS                      19680019
X01      EQU   X'01'               SYSMSG GLOBAL FILE NUMBER            19760019
X02      EQU   X'02'               SWITCH TO SEND ALL MESSAGES FOR USER 19840019
X03      EQU   X'03'               NO. OF USRMSGS GLOBAL FILE           19920019
X04      EQU   X'04'               MASK FOR DEQUEUE CORE MSG REQUEST    20000019
X08      EQU   X'08'               MASK FOR SHOW SESS GENERAL RESPONSE  20080019
X10      EQU   X'10'               MASK FOR BUILD ONLY REQUEST          20160019
X20      EQU   X'20'               MASK TO DENOTE REQUESTING CONSOLE ID 20240019
X80      EQU   X'80'               MASK TO TEST FOR END OF PARMLIST     20320019
XF2      EQU   C'2'                MASK TO RECOGNIZE OPERATOR MSG       20400019
XFE      EQU   X'FE'               MASK FOR LAST MESSAGE POSSIBLE       20480019
XFF      EQU   X'FF'               HEX FF                               20560019
XBLANK   EQU   C' '                CHARACTER BLANK                      20640019
CI       EQU   C'I'                USED TO ADD I TO 200 MESSAGE KEY     20720019
         SPACE 1                                                        20800019
ONE      EQU   1                   INCREMENT 1                          20880019
FOUR     EQU   4                   INCREMENT 4                          20960019
LINEERR  EQU   4                   RETUTN CODE 4 - LINE ERROR           21040019
GETFAIL  EQU   8                   RETURN CODE 8 - GETMAIN FAILED       21120019
ACTERR   EQU   12                  RTN CODE 12 - ACTIVE AREA I/O ERROR  21200019
MSGLOST  EQU   16                  RETURN CODE 16 - MESSAGE LOST        21280019
NOUSER   EQU   24                  RETURN CODE 24 - INVALID USERID      21360019
F72      EQU   72                  MAXIMUM LENGTH OF MESSAGES           21440019
         EJECT                                                          21520019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 21600019
*                                                                     * 21680019
*                   SET  UP  ADDRESSABILITY - IHKMSG                  * 21760019
*                                                                     * 21840019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 21920019
         SPACE                                                          22000019
         SAVE  (14,12),,MSG70335   SAVE CALLER'S REGISTERS       A36801 22080020
         LR    R12,R15             LOAD BASE REGISTER                   22160019
         USING IHKMSG,R12          DECLARE R12 AS BASE REGISTER         22240019
         LR    R3,R1               SAVE ADDRESS OF PARMLIST             22320019
         LA    R2,MSG20A           SET UP INTERNAL RETURN ADDRESS       22400019
         SPACE                                                          22480019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 22560019
*                                                                     * 22640019
*         ISSUE  GETMAIN FOR SAVE AREA AND CHAIN SAVE AREAS           * 22720019
*                                                                     * 22800019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 22880019
         SPACE                                                          22960019
MSGSAVEA GETMAIN EC,LV=96,A=GETAD,SP=0 CORE FOR SAVE AREA AND PARMLIST  23040019
         LTR   R15,R15             ZERO INDICATES SUCCESSFUL GETMAIN    23120019
         BZ    MSGG                ERROR, BRANCH TO GET OUT             23200019
         LA    R15,GETFAIL         SET GETMAIN FAILED RETURN CODE       23280019
         B     MSGRTN1             BRANCH TO GET OUT                    23360019
MSGG     DS    0H                                                       23440019
         L     R10,GETAD           PUT ADDRESS OF GETMAIN AREA IN R10   23520019
         ST    R10,8(R13)          STORE NEW SAVE AREA ADDRESS IN WORD3 23600019
         ST    R13,4(R10)          OLD SAVE ADDRESS IN NEW SAVE AREA    23680019
         LR    R13,R10             PLACE SAVE AREA ADDRESS IN R13       23760019
         USING GETAREA,R13                                              23840019
         MVC   PARM1(20),0(R3)     SAVE PARAMETER LIST UPON ENTRY       23920019
         L     R6,PARM1            PLACE ADDRESS OF REQUESTING TUB - R6 24000019
         USING TUBDSECT,R6                                              24080019
         OI    TUBAFISW,TUBFCTLN   SELECT AFIO BUFFER CONTROL OPTION    24160019
         L     R9,TUBUFFAD         ADDRESS OF USER BUFFER               24240019
         USING BUFFER,R9                                                24320019
         L     R10,MSGAVT          SET UP REGISTER 10 AS BASE FOR AVT   24400019
         USING AVTDSECT,R10        DSECT                                24480019
         L     R7,IHKYYCCT         ADDRESS OF CRJE CONTROL TABLE        24560019
         USING CCTDSECT,R7                                              24640019
         BR    R2                  RETURN TO INTERNAL CALLER            24720019
MSG20A   L     R15,PARM2           GET ADDRESS OF RECIPIENT TUB OR USER 24800019
         L     R11,0(R15)          PICK UP USERID OR BINARY ZEROES      24880019
         LA    R0,0(R11)           PICK UP THREE LOW ORDER BYTES        24960019
         LTR   R0,R0               IF R0=0, MSG IS FOR OPERATOR         25040019
         BZ    MSG40               MESSAGE IS FOR OPERATOR              25120019
         LR    R11,R15             RESTORE R11 TO ADDR. OF TUB/USERID   25200019
         SPACE                                                          25280019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 25360019
*                                                                     * 25440019
*              SEND  QUEUED  MSG  IF  REQUESTED  AND  AVAILABLE       * 25520019
*                                                                     * 25600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 25680019
         SPACE                                                          25760019
MSG20    L     R15,PARM3           PICK UP ADDRESS OF MSG REQUEST WORD  25840019
         TM    0(R15),X02          QUEUED MSG TO BE SENT IF AVAIL. ?    25920019
         BZ    MSG40               NO, BRANCH OUT                       26000019
         TM    TUBFLG2,TUBLMSGN    IS LOST MSG BIT SET ?                26080019
         BZ    MSG22C              NO, DO NOT SEND MSG                  26160019
         LA    R1,M358             REQUEST 'MESSAGE LOST' MESSAGE       26240019
         BAL   R2,MSG70            BUILD MSG NO. 237 IN USER BUFFER     26320019
         NI    TUBFLG2,TUBLMSGF    TURN OFF LOST MESSAGE INDICATOR      26400019
         SR    R4,R4               SET SWITCH FOR CWRITE, NOT CWRITE R  26480019
         BAL   R2,MSGSEND          SEND MSG FROM USER BUFFER            26560019
         LTR   R15,R15                                                  26640019
         BNZ   MSGRTN              I/O ERROR - RETURN CONTROL           26720019
MSG22C   L     R15,TUBFQEB         LOAD ADDRESS OF QUEUED MSG           26800019
         LTR   R15,R15             IF ZERO, NO QUEUED MSG IN CORE       26880019
         BZ    MSG25               BRANCH TO TEST FOR DELAYED MSGS      26960019
         MVC   BUFNO(72),0(R15)    MOVE QUEUED MSG INTO USER BUFFER + 8 27040019
         ST    R15,GETAD           STORE ADDRESS OF CORE MESSAGE AREA   27120019
         FREEMAIN R,LV=72,A=GETAD,SP=0 FREE CORE USED TO HOLD MESSAGE   27200019
         XR    R0,R0               CLEAR REGISTER 0                     27280019
         ST    R0,TUBFQEB          DEQUEUE MESSAGE BY ZEROING TUBFQEB   27360019
         XR    R4,R4               CLEAR R4 TO INDICATE WRITE ONLY      27440019
         BAL   R2,MSGSEND          BRANCH TO SEND MESSAGE               27520019
         LTR   R15,R15                                                  27600019
         BZ    MSG25               SUCCESSFUL WRITE                     27680019
         B     MSGRTN              I/O ERROR - GET OUT                  27760019
         SPACE                                                          27840019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 27920019
*                                                                     * 28000019
*               SEND  MESSAGE  FROM  USER  BUFFER                     * 28080019
*                                                                     * 28160019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 28240019
         SPACE                                                          28320019
MSGSEND  DS    0H                                                       28400019
         CLC   BUFNO(4),CRJE       IS THIS A USER/OPERATOR MSG ?        28480019
         BE    MSGSEND2            YES, NO MSG ID ON MESSAGE            28560019
         CLC   BUFNO(4),BRD        IS THIS A BROADCAST MSG ?            28640019
         BE    MSGSEND2            YES, INCLUDE FIRST 8 BYTES           28720019
         TM    TUBFLG1,TUBMID      MESSAGE ID REQUESTED ?               28800019
         BNZ   MSGSEND2            YES, DD NOT REMOVE ID                28880019
         MVC   TUBDATAL(2),H64     SET DATA LENGTH TO 64                28960019
         MVC   BUFFMAIN(64),BUFTEXT MOVE MESSAGE TO DELETE ID           29040019
         B     MSGSEND4            BRANCH TO SEND MESSAGE TO TERMINAL   29120019
MSGSEND2 MVC   TUBDATAL(2),H72     SET DATA LENGTH TO 72                29200019
         MVC   BUFFMAIN(72),BUFNO  MOVE MSG TO DELETE AFIO CONTROL INFO 29280019
MSGSEND4 SR    R15,R15             ZERO R15                             29360019
         L     R14,PARM3           ADDRESS OF MSG AREA                  29440019
         TM    0(R14),X10          WAS BUILD ONLY REQUESTED ?           29520019
         BNZ   MSGRTN              YES, DO NOT SEND MSG                 29600019
         LR    R15,R6              CWRITE REQUIRES TUB ADDRESS IN R15   29680019
         LTR   R4,R4               IS A RESPONSE REQUIRED ?             29760019
         BZ    MSGSEND6            NO, ISSUE CWRITE                     29840019
         OI    TUBFLG3,TUBNOCRN    YES, TURN ON NO CARRIAGE RETURN FLAG 29920019
         LR    R3,R9               POINT TO BEGINNING OF MESSAGE        30000019
         LH    R14,TUBDATAL        SET COUNTER TO 72                    30080019
         AR    R3,R14              POINT ONE PAST END OF MSG            30160019
MSGCOMP  DS    0H                                                       30240019
         BCTR  R3,0                DECREMENT POINTER TO NEXT CHARACTER  30320019
         CLI   0(R3),XFF           CHECK FOR X'FF' CHARACTER            30400019
         BNE   MSGFOUND            IF FOUND, RESET TUBDATAL             30480019
         BCT   R14,MSGCOMP         HAVE ALL CHARACTERS BEEN FOUND ?     30560019
         B     MSGR                IF YES, SEND NO MESSAGE              30640019
MSGFOUND DS    0H                                                       30720019
         STH   R14,TUBDATAL        UPDATE LENGTH                        30800019
         CWRITE R                                                       30880019
         LTR   R15,R15             TEST RETURN CODE                     30960019
         BNZ   MSGSEND9            LINE ERROR                           31040019
MSGR     DS    0H                                                       31120019
         XR    R15,R15             SUCCESSFUL RETURN                    31200019
         B     MSGRTN              BRANCH TO RETURN TO CALLER           31280019
MSGSEND6 CWRITE                                                         31360019
         LTR   R15,R15             TEST RETURN CODE FROM CWRITE         31440019
         BCR   8,R2                IF =0, TAKE PRE-SET INTERNAL BRANCH  31520019
         TM    TUBFLG4,TUBSTOP     MODIFY OR STOP IN PROCESS ?          31600019
         BO    STOPPED             IF SO, CHECK SOME MORE        A36801 31620020
         L     R15,TUBCLBAD        GET CLB ADDRESS               A36801 31640020
         USING CLBDSECT,R15        TELL THE ASSEMBLER ABOUT CLB  A36801 31660020
         TM    CLBREQST,CLBSTOPN   IF NOT, CHECK THE LINE        A36801 31680020
         DROP  R15                                               A36801 31700020
         BZ    MSGSEND9            IF NOT, ASSUME LINE HIT       A36801 31720020
STOPPED  EQU   *                                                 A36801 31740020
         XR    R15,R15             CLEAR RETURN FROM CWRITE             31760019
         TM    TUBSTATS,TUBTIMEN+TUBOFFLN TIME OUT OR OFF LINE ?        31840019
         BCR   8,R2                SUCCESSFUL RETURN                    31920019
MSGSEND9 LA    R15,LINEERR         SET LINE ERROR RETURN CODE           32000019
         TM    TUBSTATS,TUBREAKN   DID A BREAK OCCUR                    32080019
         BO    MSGDEL              YES, DELETE ALL PENDING MESSAGES     32160019
         BR    R2                  TAKE PRE-SET INTERNAL BRANCH         32240019
MSG25    TM    TUBFLG1,TUBMSG      DELAYED MSGS FOR USER ?              32320019
         BZ    MSG50               NO, CHECK FOR BROADCAST REQUEST      32400019
         SPACE                                                          32480019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 32560019
*                                                                     * 32640019
*                  SEND DELAYED MESSAGES TO USER                      * 32720019
*                                                                     * 32800019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 32880019
         SPACE                                                          32960019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      33040019
         MVI   TUBGBLNM,X03        SET GLOBAL FILE NO. FOR DELAYED MSGS 33120019
         MVC   TUBGBLKY(7),TUBUSRID USERID IS KEY FOR HIS MSGS          33200019
         MVI   TUBGBLKY+7,X01      SET KEY TO FIRST MESSAGE FOR USER    33280019
MSG25A   RPOINT B,NR,KEY=HIEQ,FTYPE=XGBL LOCATE FIRST MSG FOR USER      33360019
         B     MSG25C(R15)         BRANCH ON RETURN CODE                33440019
MSG25C   B     MSG26               EXACT KEY FOUND                      33520019
         B     MSG26               EXACT KEY NOT FOUND                  33600019
         B     MSG26               N/A RETURN CODE                      33680019
         B     MSGIOERR            DISK ERROR                           33760019
MSG26    DS    0H                                                       33840019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      33920019
         ST    R9,TUBRAFBF         USER BUFFER IS AFIO BUFFER           34000019
         RGET  R,S,A,FTYPE=XGBL    ACCESS 1 MESSAGE FOR USER            34080019
         B     MSG26X(R15)         BRANCH ON RETURN CODE                34160019
MSG26X   B     MSG26Y              SUCCESSFUL RETRIEVAL                 34240019
         B     MSG60               END OF DATA                          34320019
         B     MSG26Y              N/A RETURN CODE                      34400019
         B     MSGIOERR            DISK ERROR                           34480019
MSG26Y   DS    0H                                                       34560019
         CLC   TUBUSRID(7),BUFKEY  IS MESSAGE FOR CURRENT USER          34640019
         BE    MSG26Z              YES, GO TO SEND MESSAGE              34720019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      34800019
         ST    R9,TUBRAFBF         USER BUFFER = AFIO BUFFER            34880019
         RGET  R,S,A,FTYPE=XGBL    ACCESS NEXT MESSAGE                  34960019
         B     MSG26Y1(R15)        BRANCH ON RETURN CODE                35040019
MSG26Y1  B     MSG26Y5             SUCCESSFUL RETRIEVAL                 35120019
         B     MSG60               END OF DATA                          35200019
         B     MSG26Y              N/A RETURN CODE                      35280019
         B     MSGIOERR            DISK ERROR                           35360019
MSG26Y5  DS    0H                                                       35440019
         CLC   TUBUSRID(7),BUFKEY  IS MESSAGE FOR CURRENT USER          35520019
         BNE   MSG60               NO, NO MORE MESSAGES FOR USER        35600019
MSG26Z   DS    0H                                                       35680019
         MVC   TUBGBLKY(8),BUFKEY  SAVE KEY OF LAST MESSAGE READ        35760019
         BAL   R2,MSGENDUP         END PROCESSING OF GLOBAL FILE        35840019
         XR    R4,R4               SET SWITCH FOR CWRITE, NOT CWRITE R  35920019
         BAL   R2,MSGSEND          SEND MESSAGE TO TERMINAL             36000019
         LTR   R15,R15             TEST RETURN CODE FROM CWRITE         36080019
         BNZ   MSGRTN              ERROR, GET OUT                       36160019
MSG26A   DS    0H                                                       36240019
         LH    R1,CCTMSGNO         INCREMENT NUMBER OF MESSAGES WHICH   36320019
         LA    R1,ONE(R1)          * CAN BE ADDED TO DELAYED MSGS AND   36400019
         STH   R1,CCTMSGNO         * UPDATE COUNTER IN CCT              36480019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      36560019
         RPOINT B,NR,FTYPE=XGBL    POINT TO MSG JUST SENT               36640019
         B     MSG26AC(R15)        BRANCH ON RETURN CODE                36720019
MSG26AC  B     MSG26AG             EXACT KEY FOUND                      36800019
         B     MSG60               KEY NOT FOUND                        36880019
         B     MSG26AG             N/A RETURN CODE                      36960019
         B     MSGIOERR            I/O ERROR                            37040019
MSG26AG  DS    0H                                                       37120019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      37200019
        RDELETE XK,B,FTYPE=XGBL    DELETE MSG JUST SENT                 37280019
         B     MSG26AJ(R15)        BRANCH ON RETURN CODE                37360019
MSG26AJ  B     MSG26               RECORD DELETED SUCCESSFULLY          37440019
         B     MSG60               END OF DATA                          37520019
         B     MSG26               N/A RETURN CODE                      37600019
         B     MSGIOERR            I/O ERROR                            37680019
MSG60    DS    0H                                                       37760019
         BAL   R2,MSGENDUP         END PROCESSING OF GLOBAL FILE        37840019
MSG62    NI    TUBFLG1,TUBMSGF     TURN OFF DELAYED MESSAGE SWITCH      37920019
MSG50    TM    TUBFLG1,TUBBRD      HAVE BROADCAST MSGS BEEN REQUESTED ? 38000019
         BNZ   MSGBRD1             YES, BRANCH TO SEND THEM             38080019
MSG40    LA    R2,MSG55                                                 38160019
         L     R1,PARM3            PICK UP ADDRESS OF MSG REQUEST AREA  38240019
         SR    R15,R15             CLEAR R15 - GOOD RETURN CODE         38320019
         TM    0(R1),X04           QUEUED MSG TO BE ADDED TO DELAYED    38400019
         BZ    MSG45               * MESSAGES ?                         38480019
         L     R1,TUBFQEB          ADDRESS OF QUEUED MSG                38560019
         LTR   R1,R1               ANY QUEUED MSG ?                     38640019
         BZ    MSGRTN              NO                                   38720019
         MVC   BUFNO(72),0(R1)     MOVE QUEUED MSG INTO USER BUFFER     38800019
         ST    R15,TUBFQEB         SET INDICATION OF NO QUEUED MSG      38880019
         ST    R1,GETAD            STORE ADDRESS OF CORE MESSAGE        38960019
         FREEMAIN R,LV=72,A=GETAD,SP=0 FREE CORE USED BY QUEUED MSG     39040019
         LA    R11,TUBUSRID        R11 = USERID OF RECIPIENT            39120019
         B     MSGD01              GO TO PUT MESSAGE IN USRMSGS FILE    39200019
MSG45    CLC   1(3,R1),F0F0F0      IS A MSG TO BE BUILT ?               39280019
         BE    MSGRTN              BRANCH TO GET OUT                    39360019
         B     MSG70               GO TO BUILD MSG                      39440019
MSG55    LA    R2,MSGRTN           SET INTERNAL RETURN ADDRESS          39520019
         B     MSG100            GO TO SEND MESSAGE IF REQUESTED        39600019
         SPACE                                                          39680019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 39760019
*                                                                     * 39840019
*                BUILD A MESSAGE IN THE USER BUFFER                   * 39920019
*                                                                     * 40000019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 40080019
         SPACE                                                          40160019
MSG70    L     R15,0(R1)           ADDRESS OF MSG NUMBER                40240019
         LA    R15,0(R15)          CLEAR HIGH ORDER BYTE                40320019
         LTR   R15,R15             IF R15=0 USER MESSAGE REQUESTED      40400019
         BNZ   MSG70A              NO GO GET CANNED TEXT VIA AFIO       40480019
         MVC   BUFNO(12),CRJE      MOVE CANNED TEXT INTO USER BUFFER    40560019
         MVC   BUFTEXT+4(61),BUFTEXT+3 BLANK OUT MSG AREA               40640019
         MVC   BUFOFF1(2),USEROFF  SET UP TEXT OFFSETS FOR USER MESSAGE 40720019
         LA    R0,ONE                                                   40800019
         LR    R15,R11             PICK UP WORD CONTAINING ROUTING CODE 40880019
         SRL   R15,24              ROUTING CODE IS RIGHT ADJUSTED       40960019
         SLL   R0,16               CONVERT ROUTING CODE TO INTERNAL     41040019
         SRL   R0,0(R15)           REPRESENTATION                       41120019
         STH   R0,BUFRC            STORE ROUTING CODE IN MESSAGE TEXT   41200019
         MVC   BUFDC(2),MCSRCRC    SET UP DESCRIPTOR CODE               41280019
         B     MSGPARM             BRANCH TO ADD USERID AND TEXT        41360019
MSG70A   MVI   TUBGBLNM,X01        SET GLOBAL FILE NUMBER FOR SYSMSGS   41440019
         MVC   TUBGBLKY(8),IHK     MOVE IHK  00 INTO KEY FIELD IN TUB   41520019
         MVC   TUBGBLKY+3(3),1(R1) MOVE MSG NUMBER INTO KEY             41600019
         CLI   TUBGBLKY+3,XF2      IS THIS AN OPERATOR MSG ?            41680019
         BNE   MSG71               NO, DO NOT ADD I TO KEY              41760019
         MVI   TUBGBLKY+6,CI       ADD ACTION CODE OF I TO KEY          41840019
MSG71    DS    0H                                                       41920019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      42000019
         ST    R9,TUBRAFBF         USER BUFFER IS AFIO BUFFER           42080019
         RPOINT A,R,FTYPE=GBL      ACCESS CANNED TEXT                   42160019
         B     MSG71A(R15)         BRANCH ON RETURN CODE                42240019
MSG71A   B     MSGPARM             EXACT KEY FOUND                      42320019
         B     MSGR                NO CANNED TEXT FOR MSG NO- IGNORE    42400019
         B     MSGPARM             N/A RETURN CODE                      42480019
         B     MSGIOERR            I/O ERROR                            42560019
         SPACE                                                          43280019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 43360019
*                                                                     * 43440019
*        ADD  SUPPLIED  TEXT  TO  CANNED  MESSAGE                     * 43520019
*                                                                     * 43600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 43680019
         SPACE                                                          43760019
MSGPARM  XR    R15,R15             ZERO REGISTER 15                     43840019
         IC    R15,BUFOFF1         PICK UP OFFSET FOR FIRST PARM.       43920019
         LTR   R15,R15             IF R15=0, NO TEXT CAN BE INSERTED    44000019
         BCR   8,R2                NO TEXT TO BE ADDED                  44080019
         TM    PARM3,X80           ANY TEXT INSERTS INPUT ?             44160019
         BCR   1,R2                NO                                   44240019
         L     R14,PARM4           PICK UP ADDRESS OF INPUT TEXT LENGTH 44320019
         XR    R3,R3               ZERO REGISTER 3                      44400019
         IC    R3,0(R14)           PICK UP LENGTH OF TEXT TO INSERT     44480019
         LTR   R3,R3               CHECK FOR ZERO LENGTH TEXT           44560019
         BCR   8,R2                YES, NO TEXT TO BE ADDED             44640019
         BCTR  R3,0                DECREMENT LENGTH FOR EX INSTRUCTION  44720019
         AR    R15,R9              COMPUTE ADDRESS AT WHICH TO ADD TEXT 44800019
         EX    R3,MOVE             MOVE TEXT INTO CANNED MESSAGE        44880019
         TM    PARM4,X80           IS A SECOND INPUT TEXT PROVIDED ?    44960019
         BCR   1,R2                NO, MSG IS BUILT                     45040019
         XR    R15,R15             ZERO REG. 15                         45120019
         IC    R15,BUFOFF2         PICK UP OFFSET FOR SECOND TEXT       45200019
         LTR   R15,R15             CAN TEXT BE INSERTED ?               45280019
         BCR   8,R2                NO, IGNORE INPUT TEXT                45360019
         L     R14,PARM5           PICK UP ADDRESS OF TEXT LENGTH       45440019
         XR    R3,R3               ZERO R3                              45520019
         IC    R3,0(R14)           PICK UP TEXT LENGTH                  45600019
         LTR   R3,R3               IS TEXT LENGTH ZERO ?                45680019
         BCR   8,R2                YES, NO TEXT TO BE ADDED             45760019
         BCTR  R3,0                DECREMENT LENGTH FOR EX INSTRUCTION  45840019
         AR    R15,R9              COMPUTE ADDRESS AT WHICH TO ADD TEXT 45920019
         EX    R3,MOVE             MOVE SECOND INPUT TEXT INTO MSG      46000019
         BR    R2                  TAKE PRESET INTERNAL BRANCH          46080019
MSG100   LA    R0,0(R11)           PICK UP LOW ORDER THREE BYTES        46160019
         LTR   R0,R0               IF R0=0, MSG IS FOR OPERATOR         46240019
         BNZ   MSG110              NO, GO TO SEND TO TERMINAL           46320019
         SPACE                                                          46400019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 46480019
*                                                                     * 46560019
*    REMOVE TRAILING BLANKS AND SEND MSG TO OPERATOR                  * 46640019
*                                                                     * 46720019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 46800019
         SPACE                                                          46880019
MSGOPER  DS    0H                                                       46960019
         LA    R15,BUFOFF1         POINT TO 72ND CHAR. IN MSG           47040019
         LA    R14,F72             SET COUNTER TO 72 CHARACTERS         47120019
MSGOPER1 BCTR  R15,0               DECREMENT POINTER TO NEXT CHARACTER  47200019
         CLI   0(R15),XBLANK       CHECK FOR NON-BLANK CHARACTER        47280019
         BNE   MSGOPER4            NON-BLANK FOUND                      47360019
         BCT   R14,MSGOPER1        HAVE ALL CHARACTERS BEEN FOUND ?     47440019
         XR    R15,R15                                                  47520019
         BR    R2                  YES, ZERO LENGTH MSG - GET OUT       47600019
MSGOPER4 DS    0H                                                       47680019
         MVC   1(4,R15),BUFDC      MOVE DESCRIPTOR AND ROUTING CODES    47760019
         MVC   BUFMCS(2),MCSFLAGS  SET MCSFLAGS FIELD FOR ROUTING CODES 47840019
         L     R1,PARM3            ADDRESS OF MSG NO. FIELD IN PARMLIST 47920019
         TM    0(R1),X08           IS THIS A SHOW SESS GENERAL RESPONSE 48000019
         BZ    MSGOPER6            NO, GO TEST FOR CONSOLE ID INPUT     48080019
         MVC   BUFMCS(2),MCSFLAG1  INDICATE PRESENCE OF MSGTYP FIELD    48160019
         MVC   5(2,R15),MSGTYP     SET UP MSG TYPE FIELD FOR SHOW SESS  48240019
         B     MSGOPER8            GO TO ISSUE WTO                      48320019
MSGOPER6 L     R15,PARM3           PICK UP ADDRESS OF MSG NUMBER FIELD  48400019
         TM    0(R15),X20          IS A CONSOLE ID SUPPLIED FOR MCS     48480019
         BZ    MSGOPER8            NO, USE CANNED ROUTING CODES         48560019
         LR    R0,R11              R11 CONTAINS LEFT ADJUSTED CONSOLE   48640019
         SRL   R0,24               ID - RIGHT JUSTIFY ID IN R0          48720019
         MVC   BUFMCS(2),MCSFLAG2  INDICATE CONSOLE ID IN REGISTER 0    48800019
MSGOPER8 DS    0H                                                       48880019
         LA    R14,FOUR(R14)       INCREMENT LENGTH TO INCLUDE LENGTH   48960019
         STH   R14,BUFL            STORE LENGTH IN USER BUFFER + 4      49040019
         LA    R3,4(R9)            WTO MESSAGE IS AT USER BUFFER + 4    49120019
WTO      WTO   ,MF=(E,(3))         USER BUFFER AND ISSUE WTO            49200019
         XR    R15,R15             SET GOOD RETURN CODE                 49280019
         BR    R2                  TAKE PRE-SET INTERNAL BRANCH         49360019
MSG110   L     R5,PARM3            GET ADDRESS OF MSG AREA PARM         49440019
         SR    R4,R4               CLEAR R4 TO INDICATE NO RESPONSE     49520019
         TM    0(R5),X01           IS A RESPONSE REQUIRED               49600019
         BZ    MSGSEND             NO RESPONSE WANTED                   49680019
         LR    R4,R6               SET R4 TO NON-ZERO FOR RESPONSE      49760019
         B     MSGSEND             GO TO SEND MESSAGE                   49840019
         SPACE                                                          49920019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 50000019
*                                                                     * 50080019
*         BREAK  OCCURRED - DELETE  ALL  PENDING  MESSAGES            * 50160019
*                                                                     * 50240019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 50320019
         SPACE                                                          50400019
MSGDEL   L     R15,TUBFQEB         CHECK FOR A QUEUED MSG               50480019
         LA    R15,0(R15)          CLEAR HIGH ORDER BYTE OF ADDRESS     50560019
         LTR   R15,R15             ZERO MEANS NO QUEUED MSG             50640019
         BZ    MSGDEL4             NO QUEUED MSG, GO CHECK FOR DELAYED  50720019
         ST    R15,GETAD           STORE ADDRESS OF AREA TO BE FREED    50800019
         FREEMAIN R,LV=72,A=GETAD,SP=0  FREE CORE USED BY QUEUED MSG    50880019
         SR    R15,R15             ZERO REGISTER 15                     50960019
         ST    R15,TUBFQEB         ZERO QUEUED MSG ADDRESS              51040019
MSGDEL4  TM    TUBFLG1,TUBMSG      CHECK FOR DELAYED MSGS               51120019
         BZ    MSGDEL8A            NONE                                 51200019
         MVI   TUBGBLNM,X03        SET GLOBAL FILE NO. FOR DELAYED MSGS 51280019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      51360019
         MVC   TUBGBLKY(7),TUBUSRID MOVE USERID INTO KEY FIELD          51440019
         MVI   TUBGBLKY+7,XFE      SET HIGHEST POSSIBLE KEY             51520019
         RPOINT A,NR,KEY=HIEQ,FTYPE=XGBL LOCATE HIGHEST KEYED MSG       51600019
         B     MSGDEL4A(R15)       BRANCH ON RETURN CODE                51680019
MSGDEL4A B     MSGDEL5             EXACT KEY FOUND                      51760019
         B     MSGDEL5             EXACT KEY NOT FOUND                  51840019
         B     MSGDEL5             N/A RETURN CODE                      51920019
         B     MSGIOERR            I/O ERROR                            52000019
MSGDEL5  DS    0H                                                       52080019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      52160019
         RGET  XK,S,B,REC=PREVIOUS,FTYPE=XGBL                           52240019
         B     MSGDEL5A(R15)       BRANCH ON RETURN CODE                52320019
MSGDEL5A B     MSGDEL5C            SUCCESSFUL RETRIEVAL OF KEY          52400019
         B     MSGDEL8             END OF DATA                          52480019
         B     MSGDEL5C            N/A RETURN CODE                      52560019
         B     MSGIOERR            I/O ERROR                            52640019
MSGDEL5C CLC   TUBUSRID(7),TUBGBLKY IS THE MSG FOR THE RECIPIENT USERID 52720019
         BNE   MSGDEL8             NO, RELEASE CONTROL OF FILE          52800019
MSGDEL6  DS    0H                                                       52880019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      52960019
         RDELETE NXK,A,FTYPE=XGBL  DELETE MSG                           53040019
         B     MSGDEL6A(R15)       BRANCH ON RETURN CODE                53120019
MSGDEL6A B     MSGDEL6B            SUCCESSFUL DELETION OF RECORD        53200019
         B     MSGDEL8             END OF DATA                          53280019
         B     MSGDEL6B            N/A RETURN CODE                      53360019
         B     MSGIOERR            I/O ERROR                            53440019
MSGDEL6B LH    R1,CCTMSGNO         PICK UP NO. OF MSGS THAT ARE ADDABLE 53520019
         LA    R1,ONE(R1)          INCREMENT NO. OF MSGS ADDABLE        53600019
         STH   R1,CCTMSGNO         STORE UPDATED COUNTER                53680019
         B     MSGDEL5             BRANCH TO READ NEXT MESSAGE          53760019
MSGDEL8  LR    R5,R2               SAVE INTERNAL RETURN ADDRESS         53840019
         BAL   R2,MSGENDUP         TERMINATE PROCESSING ON THIS FILE    53920019
MSGDEL8A LA    R15,LINEERR         SET TP LINE ERROR RETURN CODE        54000019
         NI    TUBFLG1,TUBMSGF     TURN OFF DELAYED MESSAGE FLAG        54080019
         NI    TUBFLG1,TUBBRDF     TURN OFF BROADCAST MESSAGE REQUEST   54160019
         B     MSGRTN              RETURN TO EXTERNAL CALLER            54240019
         SPACE                                                          54320019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 54400019
*                                                                     * 54480019
*                RETURN  TO  USER                                     * 54560019
*                                                                     * 54640019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 54720019
         SPACE                                                          54800019
MSGRTN   ST    R13,GETAD           STORE CURRENT SAVE AREA ADDRESS -R13 54880019
         L     R13,4(R13)          RESTORE OLD SAVE AREA ADDRESS        54960019
         LR    R3,R15              SAVE RETURN CODE OVER FREEMAIN       55040019
         FREEMAIN R,LV=96,A=GETAD,SP=0 FREE SAVE AREA AND PARAMETERS    55120019
         LR    R15,R3              RESTORE RETURN CODE                  55200019
         NI    TUBAFISW,TUBFCTLF   RESET AFIO BUFFER CONTROL SWITCH     55280019
MSGRTN1  DS    0H                                                       55360019
         RETURN (14,12),T,RC=(15)                                       55440019
         EJECT                                                          55520019
*********************************************************************** 55600019
*                                                                     * 55680019
*        IHKMSG01 - SECONDARY  ENTRY  POINT                           * 55760019
*                                                                     * 55840019
*********************************************************************** 55920019
         SPACE                                                          56000019
         ENTRY IHKMSG01                                                 56080019
IHKMSG01 SAVE  (14,12),,IHKMSG01   SAVE REGISTERS                       56160019
         LR    R3,R1               SAVE ADDRESS OF PARM LIST            56240019
         USING IHKMSG01,R15        USE REGISTER 15 AS TEMPORARY BASE    56320019
         L     R12,AIHKMSG         SET UP ACTUAL BASE REGISTER          56400019
         DROP  R15                                                      56480019
         USING IHKMSG,R12                                               56560019
         BAL   R2,MSGSAVEA         BRANCH FOR SAVE AREA GETMAIN         56640019
         L     R1,PARM3            PICK UP ADDRESS OF MSG NUMBER        56720019
         L     R15,PARM2           PICK UP ADDRESS OF RECEIPIENT ID     56800019
         L     R11,0(R15)          RECEIPIENT ID -- USERID OR ZERO      56880019
         LA    R0,0(R11)           PICK UP LOW ORDER THREE BYTES        56960019
         LTR   R0,R0               IF R0=0,MSG IS FOR OPERATOR          57040019
         BZ    MSG300A             BRANCH IF MESSAGE IS FOR OPERATOR    57120019
         LR    R11,R15             RESTORE R11 TO ADDRESS OF USERID     57200019
MSG300A  DS    0H                                                       57280019
         BAL   R2,MSG70            BRANCH TO BUILD MESSAGE IN USER BUFF 57360019
         CLC   TUBUSRID(8),0(R11)  IS REQUESTING TUB ALSO RECIPIENT ?   57440019
         BNE   MSGD01              NO, PUT MSG ON DELAYED MSGS DATA SET 57520019
MSG310A  DS    0H                                                       57600019
         TM    TUBSTATS,TUBTIMEN   TIME OUT ON LINE ?                   57680019
         BO    MSGD01              IF YES, PUT NO MSG IN CORE           57760019
         TM    TUBFLG2,TUBABEND    ABNORMAL TERMINATION ?               57840019
         BZ    MSG320A             IF NOT, CHECK FOR CORE MSG           57920019
         TM    TUBFLG4,TUBSTOP     MODIFY OR STOP COMMAND ?             58000019
         BZ    MSGD01              IF NOT, PUT NO MSG IN CORE           58080019
MSG320A  DS    0H                                                       58160019
         L     R1,TUBFQEB          IF YES,CHECK FOR EXISTING QUEUED MSG 58240019
         LTR   R1,R1               NO, BRANCH TO QUEUE MSG IN CORE      58320019
         BNZ   MSGD01              DELAYED MSG                          58400019
         SPACE                                                          58480019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 58560019
*                                                                     * 58640019
*               ENQUEUE  A  MESSAGE  IN  CORE                         * 58720019
*                                                                     * 58800019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 58880019
         SPACE                                                          58960019
         GETMAIN EC,LV=72,A=GETAD,SP=0  GET CORE TO HOLD MSG            59040019
         LTR   R15,R15             WAS GETMAIN SUCCESSFUL ?             59120019
         BNZ   MSGD01              NO, PUT MSG ON DELAYED MSGS DATA SET 59200019
         L     R1,GETAD            PUT ADDRESS OF GETMAIN IN R1         59280019
         ST    R1,TUBFQEB          STORE ADDRESS OF QUEUED MSG IN TUB   59360019
         MVC   0(72,R1),BUFNO      MOVE MSG FROM USER BUFFER            59440019
         XR    R15,R15             SET SUCCESSFUL RETURN                59520019
         B     MSGRTN              RETURN TO CALLER                     59600019
         SPACE                                                          59680019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 59760019
*                                                                     * 59840019
*        WRITE  A  MESSAGE  TO  USER  MESSAGE  DATA  SET              * 59920019
*                                                                     * 60000019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 60080019
         SPACE                                                          60160019
MSGD01   DS    0H                                                       60240019
         LH    R15,CCTMSGNO        CAN A MESSAGE BE ADDED TO THE        60320019
         LTR   R15,R15             * DELAYED MESSAGES (USRMSGS) ?       60400019
         BNZ   MSGD01A             YES, GO ADD MESSAGE                  60480019
MSGD09   DS    0H                                                       60560019
         LR    R4,R6               SET R4 NONZERO TO INDICATE LOST MSG  60640019
         CLC   TUBUSRID(7),0(R11)  IS REQUESTING SUBTASK MSG RECEIPIENT 60720019
         BNE   MSGUREC1            NO, SET BIT IN USER RECORD           60800019
MSGD01B  OI    TUBFLG2,TUBLMSGN    YES, SET LOST MSG BIT IN TUB         60880019
MSGDF005 LA    R15,MSGLOST         SET MSG LOST RETURN CODE             60960019
         B     MSGRTN              RETURN TO EXTERNAL CALLER            61040019
MSGD01A  DS    0H                                                       61120019
         CLC   TUBUSRID(7),0(R11)  IS REQUESTING SUBTASK MSG RECIPIENT  61200019
         BE    MSGD01D             IF YES, USERID VALID                 61280019
         MVI   TUBGBLNM,X2         SET GLOBAL FILE NO. FOR USERS        61360019
         MVC   TUBGBLKY(7),0(R11)  KEY = USERID RECIPIENT               61440019
         MVI   TUBGBLKY+7,XBLANK                                        61520019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      61600019
         RPOINT B,NR,FTYPE=XGBL    CHECK FOR VALID USER                 61680019
         B     MSGD05(R15)         BRANCH ON RETURN CODE                61760019
MSGD05   B     MSGD01C             USER RECORD FOUND                    61840019
         B     MSGUREC4            NO RECORD FOUND FOR USERID           61920019
         B     MSGD01C             N/A RETURN CODE                      62000019
         B     MSGIOERR            I/O ERROR                            62080019
MSGD01C  DS    0H                                                       62160019
         BAL   R2,MSGENDUP         END PROCESSING OF GLOBAL FILE        62240019
MSGD01D  DS    0H                                                       62320019
         LH    R15,CCTMSGNO        NO. OF DELAYED MESSAGES ADDABLE      62400019
         LTR   R15,R15             CAN MESSAGE BE ADDED ?               62480019
         BZ    MSGD09              IF NOT, SET LOST MESSAGE BIT         62560019
         BCTR  R15,0               DECREMENT NO. OF MESSAGES ADDABLE    62640019
         STH   R15,CCTMSGNO        STORE UPDATED COUNTER                62720019
         MVC   BUFKEY(7),0(R11)    MOVE USERID INTO CHAR 73-79 OF MSG   62800019
         ST    R9,TUBRAFBF         USE USER BUFFER FOR AFIO             62880019
         ST    R9,BUFFMAIN+4       SET UP AFIO CONTROL WORDS IN BUFFER  62960019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      63040019
         MVI   TUBGBLNM,X03        SET GLOBAL FILE NO. FOR DELAYED MSGS 63120019
         MVC   BUFFMAIN(4),F88     SET LENGTH TO 88 BYTES               63200019
         MVC   TUBGBLKY,0(R11)     SET KEY=USERID                       63280019
         MVI   TUBGBLKY+7,XFE      SET KEY TO HIGHEST MSG NO POSSIBLE   63360019
         RPOINT A,NR,KEY=HIEQ,FTYPE=XGBL LOCATE LAST MESSAGE FOR USER   63440019
         B     MSGD05A(R15)        BRANCH ON RETURN CODE                63520019
MSGD05A  B     MSGD50              SUCCESSFUL POSITIONING OF FILE       63600019
         B     MSGD06              KEY NOT FOUND                        63680019
         B     MSGD50              N/A RETURN CODE                      63760019
         B     MSGIOERR            I/O ERROR                            63840019
MSGD06   DS    0H                                                       63920019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      64000019
         RGET XK,S,A,REC=PREVIOUS,FTYPE=XGBL                            64080019
         B     MSGD06A(R15)        BRANCH ON RETURN CODE                64160019
MSGD06A  B     MSGD07              SUCCESSFUL RETRIEVAL OF KEY          64240019
         B     MSGD07S             END OF DATA                          64320019
         B     MSGD07              N/A RETURN CODE                      64400019
         B     MSGIOERR            I/O ERROR                            64480019
MSGD07   CLC   TUBGBLKY(7),0(R11)   IS THERE A MSG FOR CURRENT USER ?   64560019
         BE    MSGD07D             YES, INCREMENT KEY FOR MSG           64640019
MSGD07K  L     R15,PARM2           ADDRESS OF RECIPIENT USERID          64720019
         MVI   BUFKEY+7,X01        SET LAST BYTE OF KEY TO X'01'        64800019
         B     MSGD07N             BRANCH TO INSERT MSG IN USRMSGS      64880019
MSGD07S  DS    0H                                                       64960019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      65040019
         RPOINT B,NR,KEY=FIRST,FTYPE=XGBL    REPOSITION NULL FILE       65120019
         B     MSGD07SA(R15)       BRANCH ON RETURN CODE                65200019
MSGD07SA B     MSGD07K             SUCCESSFUL POSITIONING OF FILE       65280019
         B     MSGD07K             EXACT KEY NOT FOUND                  65360019
         B     MSGD07K             N/A RETURN CODE                      65440019
         B     MSGIOERR            I/O ERROR                            65520019
MSGD07D  XR    R15,R15                                                  65600019
*        KEY = USERID + RELATIVE POSITION IN LIST OF MSG                65680019
         IC    R15,TUBGBLKY+7                                           65760019
         LA    R15,ONE(R15)                                             65840019
         STC   R15,BUFKEY+7                                             65920019
         MVC   TUBGBLKY(8),BUFKEY  SAVE KEY OF LAST MESSAGE             66000019
MSGD07N  DS    0H                                                       66080019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      66160019
         ST    R9,TUBRAFBF         USE USER BUFFER FOR AFIO BUFFER      66240019
         INSERT S,A,FTYPE=XGBL     INSERT MSG IN USRMSGS DATA SET IN AA 66320019
         B     MSGD07NA(R15)       BRANCH ON RETURN CODE                66400019
MSGD07NA B     MSGD07L             SUCCESSFUL INSERTION OF RECORD       66480019
         B     MSGAAF              OUT OF SPACE IN ACTIVE AREA          66560019
         B     MSGD07L             N/A RETURN CODE                      66640019
MSGIOERR BAL   R2,MSGENDUP         END PROCESSING OF GLOBAL FILE        66720019
         LA    R15,ACTERR          SET I/O ERROR IN ACTIVE AREA RETURN  66800019
         B     MSGRTN              RETURN TO EXTERNAL CALLER            66880019
MSGAAF   DS    0H                                                       66960019
         LH    R15,CCTMSGNO        NO. OF DELAYED MESSAGES ADDABLE      67040019
         LA    R15,1(R15)          INCREMENT NO. OF MESSAGES ADDABLE    67120019
         STH   R15,CCTMSGNO        STORE UPDATED COUNTER                67200019
         BAL   R2,MSGENDUP         SET I/O ERROR IN ACTIVE AREA RETURN  67280019
         LA    R1,M240             'OUT OF SPACE' MSG-GETMAIN FAILED    67360019
         BAL   R2,MSG70            GO TO BUILD MSG                      67440019
         BAL   R2,MSGOPER          BRANCH TO SEND MESSAGE TO OPERATOR   67520019
         CLC   TUBUSRID(8),0(R11)  REQUESTING SUBTASK = RECEIPENT ?     67600019
         BE    MSGD01B             YES, SET BIT IN TUB                  67680019
         LA    R4,ONE              SET UP R4 AS INDEX                   67760019
         B     MSGUREC1            GO READ USER RECORD                  67840019
MSGD07L  DS    0H                                                       67920019
         BAL   R2,MSGENDUP         END PROCESSING OF GLOBAL FILE        68000019
         XR    R15,R15             SET GOOD RETURN CODE                 68080019
         LH    R15,CCTMSGNO        NO. OF DELAYED MESSAGES ADDABLE      68160019
         LTR   R15,R15             HAS MESSAGE LIMIT BEEN REACHED ?     68240019
         BNZ   MSGLIM2             NO, DO NOT SEND MESSAGE              68320019
         LA    R1,M236             'MESSAGE LIMIT REACHED' MSG NO.      68400019
         BAL   R2,MSG70            GO TO BUILD MESSAGE                  68480019
         BAL   R2,MSGOPER          BRANCH TO SEND MESSAGE TO OPERATOR   68560019
MSGLIM2  XR    R15,R15             SET SUCCESSFUL RETURN CODE           68640019
         LA    R2,MSGRTN           SET INTERNAL RETURN CODE             68720019
         XR    R4,R4               ZERO R4                              68800019
         CLC   TUBUSRID(7),0(R11)  REQUESTING SUBTASK = MSG RECEIPIENT? 68880019
         BNE   MSGUREC1            NO, GO FIND USER RECORD              68960019
         OI    TUBFLG1,TUBMSG      TURN ON DELAYED MSG INDICATOR        69040019
         B     MSGRTN              RETURN TO EXTERNAL CALLER            69120019
MSGD50   DS    0H                                                       69200019
         BAL   R2,MSGENDUP         END PROCESSING OF GLOBAL FILE        69280019
MSGD51   LA    R15,MSGLOST         SET MESSAGE LOST RETURN CODE         69360019
         B     MSGRTN              GO TO RETURN TO EXTERNAL CALLER      69440019
         SPACE                                                          69520019
* *                                                                     69600019
*    READ USER RECORD                                                   69680019
* *                                                                     69760019
         SPACE                                                          69840019
MSGUREC1 DS    0H                                                       69920019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      70000019
         ST    R9,TUBRAFBF         ADDRESS OF USER BUFFER               70080019
         MVI   TUBGBLNM,X2         SET GLOBAL FILE NO. FOR USERS        70160019
         MVC   TUBGBLKY(8),0(R11)  KEY = USERID OF RECIPIENT            70240019
         MVI   TUBGBLKY+7,XBLANK                                        70320019
         RPOINT B,R,FTYPE=XGBL     READ USER'S RECORD INTO CORE         70400019
         B     MSGURECA(R15)       BRANCH ON RETURN CODE                70480019
MSGURECA B     MSGUREC3            SUCCESSFUL RETRIEVAL OF USER RECORD  70560019
         B     MSGUREC4            NO RECORD FOUND FOR USERID           70640019
         B     MSGUREC3            N/A RETURN CODE                      70720019
         B     MSGIOERR            I/O ERROR                            70800019
         DROP  R9                                                       70880019
         USING UVRDSECT,R9         USE R9 TEMPORARILY AS UVR BASE       70960019
MSGUREC3 TM    UVRCNTL1,UVRACTVN   IS USER ACTIVE ?                     71040019
         BO    MSGD29              YES, GO FIND HIS TUB                 71120019
         LTR   R4,R4               NO, TEST FOR LOST MESSAGE SWITCH TO  71200019
         BZ    MSGUREC5            BE SET -- NO SET DELAYED MSG SWITCH  71280019
         OI    UVRCNTL1,UVRLMSGN   TURN ON LOST MESSAGE SWITCH          71360019
         B     MSGURVIN            GO REPLACE UVR                       71440019
MSGUREC5 OI    UVRCNTL1,UVRDMSG    TURN ON DELAYED MSG SWITCH           71520019
MSGURVIN DS    0H                                                       71600019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      71680019
         L     R15,F88             LENGTH OF UVR = 88 BYTES             71760019
         ST    R15,UVRFMAIN        SET UP AFIO CONTROL WORDS            71840019
         ST    R9,UVRFMAIN+4                                            71920019
         DROP  R9                                                       72000019
         USING BUFFER,R9                                                72080019
         REPLACE NXK,A,FTYPE=XGBL  REPLACE UVR FOR USER                 72160019
         B     MSGD16A(R15)        BRANCH ON RETURN CODE                72240019
MSGD16A  B     MSGD16              SUCCESSFUL RETURN                    72320019
         B     MSGD16              SUCCESS                              72400019
         B     MSGD16              N/A RETURN CODE                      72480019
         B     MSGIOERR            I/O ERROR                            72560019
MSGD16   DS    0H                                                       72640019
         BAL   R2,MSGENDUP         END PROCESSING OF GLOBAL FILE        72720019
         XR    R15,R15             ZERO R15                             72800019
         LTR   R4,R4               MESSAGE LOST ?                       72880019
         BZ    MSGRTN              NO, RETURN                           72960019
         LA    R15,MSGLOST         SET LOST MESSAGE RETURN CODE         73040019
         B     MSGRTN              RETURN TO EXTERNAL CALLER            73120019
         DROP  R6                                                       73200019
         USING TUBDSECT,R3                                              73280019
         SPACE                                                          73360019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 73440019
*                                                                     * 73520019
*                  LOCATE TUB WITH GIVEN USERID                       * 73600019
*                                                                     * 73680019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 73760019
         SPACE                                                          73840019
MSGD29   DS    0H                                                       73920019
         BAL   R2,MSGENDUP         END PROCESSING OF GLOBAL FILE        74000019
         L     R3,IHKYYTUB         GET ADDRESS OF FIRST TUB IN CHAIN    74080019
         XR    R15,R15                                                  74160019
MSGD32   CLC   TUBUSRID(7),0(R11)  COMPARE USERID IN TUB TO INPUT ID    74240019
         BE    MSGD40              MATCH - BRANCH OUT                   74320019
         L     R3,TUBNEXT          PICK UP ADDRESS OF NEXT TUB          74400019
         LTR   R3,R3               IF TUBNEXT=0 THIS IS LAST TUB        74480019
         BNZ   MSGD32              NO, CHECK NEXT TUB                   74560019
         XR    R15,R15                  TUB NOT FOUND- RETURN           74640019
         B     MSGRTN              RETURN TO EXTERNAL CALLER            74720019
MSGD40   LTR   R4,R4               LOST MESSAGE                         74800019
         BNZ   MSGD42              YES, SET BIT                         74880019
         OI    TUBFLG1,TUBMSG      TURN ON DELAYED MSG BIT              74960019
         B     MSGRTN              RETURN TO EXTERNAL CALLER            75040019
MSGD42   OI    TUBFLG2,TUBLMSGN    TURN ON LOST MESSAGE BIT             75120019
         LA    R15,MSGLOST         SET MESSAGE LOST RETURN CODE         75200019
         B     MSGRTN              RETURN TO EXTERNAL CALLER            75280019
         DROP  R3                                                       75360019
         USING TUBDSECT,R6                                              75440019
MSGUREC4 DS    0H                                                       75520019
         BAL   R2,MSGENDUP         END PROCESSING OF GLOBAL FILE        75600019
         LA    R15,NOUSER          INVALID USERID                       75680019
         B     MSGRTN              RETURN TO EXTERNAL CALLER            75760019
         EJECT                                                          75840019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 75920019
*                                                                     * 76000019
*        IHKMSG02 - SECONDARY  ENTRY  POINT                           * 76080019
*                                                                     * 76160019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 76240019
         SPACE                                                          76320019
         ENTRY IHKMSG02                                                 76400019
IHKMSG02 SAVE  (14,12),,IHKMSG02   SAVE REGISTERS                       76480019
         USING IHKMSG02,R15        USE REGISTER 15 AS TEMPORARY BASE    76560019
         L     R12,AIHKMSG         SET UP ACTUAL BASE REGISTER          76640019
         DROP  15                                                       76720019
         USING IHKMSG,R12                                               76800019
         L     R15,4(R1)           GET ADDRESS OF MSG RECIPIENT         76880019
         L     R11,0(R15)          PICK UP MSG RECIPIENT ID             76960019
         LA    R0,0(R11)           PICK UP LOW ORDER THREE BYTES        77040019
         LTR   R0,R0               IF R0=0, MSG IS FOR OPERATOR         77120019
         BZ    MSG250              GO SEND MSG TO OPERATOR              77200019
         LR    R3,R1               SAVE ADDRESS OF PARAMETER LIST       77280019
         BAL   R2,MSGSAVEA         GO GETMAIN FOR SAVE AREA AND CHAIN   77360019
         L     R1,PARM3            ADDRESS OF MSG PROVIDED              77440019
         L     R11,PARM2                                                77520019
         MVC   BUFNO(72),0(R1)     MOVE SUPPLIED MSG TO USER BUFFER + 8 77600019
         B     MSG310A             GO SEND MSG TO TERMINAL              77680019
MSG250   LR    R0,R11              PUT CONSOLE ID IN R0 AND             77760019
         SRL   R0,24               * RIGHT JUSTIFY ID FOR WTO           77840019
         L     R1,8(R1)            ADDRESS OF SUPPLIED MSG              77920019
         LA    R1,0(R1)            CLEAR HIGH ORDER BYTE                78000019
         WTO   ,MF=(E,(R1))        ISSUE WRITE TO OPERATOR              78080019
         XR    R15,R15             SET SUCCESSFUL RETURN CODE           78160019
         B     MSGRTN1             RETURN TO REQUESTOR                  78240019
         EJECT                                                          78320019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 78400019
*                                                                     * 78480019
*        IHKMSG03 - SECONDARY  ENTRY  POINT                           * 78560019
*                                                                     * 78640019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 78720019
         SPACE                                                          78800019
         ENTRY IHKMSG03                                                 78880019
IHKMSG03 SAVE  (14,12),,IHKMSG03   SAVE REGISTERS                       78960019
         LR    R3,R1               SAVE ADDRESS OF PARAMETER LIST       79040019
         USING IHKMSG03,R15        USE REGISTER 15 AS TEMPORARY BASE    79120019
         L     R12,AIHKMSG         SET UP ACTUAL BASE REGISTER          79200019
         DROP  15                                                       79280019
         USING IHKMSG,R12                                               79360019
         BAL   R2,MSGSAVEA         GETMAIN AND CHAIN SAVE AREAS         79440019
         XR    R11,R11             ZERO R11 TO INDICATE FOR OPERATOR    79520019
         L     R1,PARM2                                                 79600019
         IC    R11,0(R1)           PICK UP CONSOLE ID AND SET R11 TO    79680019
         SLL   R11,24              SAME FORMAT AS OTHER ENTRY POINTS    79760019
MSGBRD   LA    R0,0(R11)           PICK UP LOW ORDER THREE BYTES        79840019
         LTR   R0,R0               IF R0=0, MSG IS FOR OPERATOR         79920019
         BNZ   MSGBRD1             NO, NO LEADING MSG REQUIRED          80000019
         LA    R1,M217             MSG 217 = CRJE BROADCAST MSGS START  80080019
         BAL   R2,MSG70            GET MSG BUILT IN USER BUFFER         80160019
MSGBRD1  MVI   TUBGBLNM,X4         SET GLOBAL FILE NO. FOR BROADCAST    80240019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      80320019
         RPOINT B,NR,KEY=FIRST,FTYPE=XGBL LOCATE FIRST BROADCAST MSG    80400019
         B     MSGBRD1A(R15)       BRANCH ON RETURN CODE                80480019
MSGBRD1A B     MSGBRD03            SUCCESSFUL POSITIONING OF FILE       80560019
         B     MSGBRD03            EXACT KEY NOT FOUND                  80640019
         B     MSGBRD03            N/A RETURN CODE                      80720019
         B     MSGIOERR            I/O ERROR                            80800019
MSGBRD03 DS    0H                                                       80880019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      80960019
         RGET  XK,S,B,FTYPE=XGBL   ACCESS BROADCAST MSG                 81040019
         B     MSGBRD3A(R15)       BRANCH ON RETURN CODE                81120019
MSGBRD3A B     MSGBRD04            SUCCESSFUL RETRIEVAL OF KEY          81200019
         B     MSGBRDNO            END OF DATA                          81280019
         B     MSGBRD04            N/A RETURN CODE                      81360019
         B     MSGIOERR            I/O ERROR                            81440019
MSGBRDNO DS    0H                                                       81520019
         BAL   R2,MSGENDUP         END PROCESSING OF GLOBAL FILE        81600019
         LA    R1,M312             'NO BROADCAST MSGS' MESSAGES         81680019
         LA    R0,0(R11)           PICK UP LOW ORDER 3 BYTES            81760019
         LTR   R0,R0               IF R0=0, MSG IS FOR OPERATOR         81840019
         BNZ   MSGBRDN1            NO, FOR USER                         81920019
         LA    R1,M232             M232 = NO BROADCAST MSGS FOR OPER.   82000019
MSGBRDN1 DS    0H                                                       82080019
         BAL   R2,MSG70            BUILD MSG IN USER BUFFER             82160019
MSGBRDN3 LA    R0,0(R11)           PICK UP LOW ORDER 3 BYTES            82240019
         LTR   R0,R0               IF R0=0, MSG IS FOR OPERATOR         82320019
         BNZ   MSGBRDN5            NO, BY USER                          82400019
         LA    R2,MSGRTN                                                82480019
         B     MSGBRDS             SET UP TO SEND MESSAGE TO OPERATOR   82560019
MSGBRDN5 DS    0H                                                       82640019
         NI    TUBFLG1,TUBBRDF     TURN OFF BROADCAST REQUEST FLAG      82720019
         XR    R4,R4               SET SWITCH FOR CWRITE, NOT CWRITE R  82800019
         BAL   R2,MSGSEND          SEND 'NO BRDCST MSGS' TO OPERATOR    82880019
         LTR   R15,R15             SUCCESSFUL RETURN ON CWRITE ?        82960019
         BZ    MSG40               YES, CHECK TO SEE IF MSG TO BE BUILT 83040019
         B     MSGRTN              NO, GET OUT                          83120019
MSGBRD04 LA    R0,0(R11)           PICK UP LOW ORDER 3 BYTES            83200019
         LTR   R0,R0               IF R0=0, MSG IS FOR OPERATOR         83280019
         BNZ   MSGBRD08            NO                                   83360019
         LA    R2,MSGBRD08         SET RETURN ADDRESS                   83440019
         B     MSGBRDS             SET UP TO SEND MESSAGE TO OPERATOR   83520019
MSGBRD07 DS    0H                                                       83600019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      83680019
         RPOINT A,NR,KEY=HIEQ,FTYPE=XGBL LOCATE NEXT BROADCAST MSG      83760019
         B     MSGBRD7A(R15)       BRANCH ON RETURN CODE                83840019
MSGBRD7A B     MSGBRD08            SUCCESSFUL POSITIONING               83920019
         B     MSGBRD08            EXACT KEY NOT FOUND                  84000019
         B     MSGBRD08            N/A RETURN CODE                      84080019
         B     MSGIOERR            I/O ERROR                            84160019
MSGBRD08 DS    0H                                                       84240019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      84320019
         ST    R9,TUBRAFBF         USER BUFFER IS AFIO BUFFER           84400019
         RGET  R,S,A,FTYPE=XGBL    ACCESS BROADCAST MSG                 84480019
         B     MSGBRD8A(R15)       BRANCH ON RETURN CODE                84560019
MSGBRD8A B     MSGBRD26            SUCCESSFUL RETRIEVAL OF RECORDS      84640019
         B     MSGBRD40            END OF DATA                          84720019
         B     MSGBRD26            N/A RETURN CODE                      84800019
         B     MSGIOERR            I/O ERROR                            84880019
MSGBRD26 DS    0H                                                       84960019
         BAL   R2,MSGENDUP         END PROCESSING OF GLOBAL FILE        85040019
         MVC   TUBGBLKY(8),BUFNO                                        85120019
         LA    R0,0(R11)           IGNORE CONSOLE ID IF GIVEN           85200019
         LTR   R0,R0               R0=0 IF MESSAGE IS FOR OPERATOR      85280019
         BNZ   MSGBD27A            MESSAGE  IS FOR TERMINAL USER        85360019
         LA    R2,MSGBRD07         PRE-SET INTERNAL BRANCH ADDRESS      85440019
         B     MSGBRDS             SET UP TO SEND MESSAGE TO OPERATOR   85520019
MSGBD27A XR    R4,R4               SET SWITCH FOR CWRITE, NOT CWRITE R  85600019
         BAL   R2,MSGSEND          SEND MSG TO USER                     85680019
MSGBRD28 LTR   R15,R15             TEST RETURN CODE FROM CWRITE         85760019
         BZ    MSGBRD07            SUCCESSFUL, GET NEXT BRDCST MSG      85840019
         LA    R15,LINEERR         SET LINE ERROR RETURN CODE           85920019
         TM    TUBSTATS,TUBREAKN   DID A BREAK OCCUR ?                  86000019
         BO    MSGDEL              YES, DELETE ALL PENDING MESSAGES     86080019
         B     MSGRTN              RETURN TO EXTERNAL CALLER            86160019
MSGBRD30 XR    R15,R15                                                  86240019
         B     MSGRTN              RETURN TO EXTERNAL CALLER            86320019
MSGBRD40 LA    R2,MSGBRD41         SET INTERNAL RETURN ADDRESS          86400019
         LA    R0,0(R11)           PICK UP LOW ORDER 3 BYTES            86480019
         LTR   R0,R0               IF R0=0, MSG IS FOR OPERATOR         86560019
         BZ    MSGENDUP            YES, END PROCESSING OF GLOBAL FILE   86640019
         NI    TUBFLG1,TUBBRDF     TURN OFF BROADCAST REQUEST FLAG      86720019
         B     MSGENDUP            END PROCESSING OF GLOBAL FILE        86800019
MSGBRD41 LA    R0,0(R11)           PICK UP LOW ORDER 3 BYTES            86880019
         LTR   R0,R0               IF R0=0, MSG IS FOR OPERATOR         86960019
         BNZ   MSG40               NO, NO ENDING MSG REQUIRED           87040019
         LA    R1,M218             YES, 218= BROADCAST MSGS END         87120019
         BAL   R2,MSG70            BRANCH TO BUILD MSG 218              87200019
         LA    R2,MSGRTN           SET RETURN ADDRESS                   87280019
MSGBRDS  DS    0H                                                       87360019
         LA    R15,HEX20           PARM3 POINTS TO BYTE INDICATING      87440019
         ST    R15,PARM3           CONSOLE ID PRESENT                   87520019
         MVC   BUFDC(2),MSGDC      SET DESCRIPTOR CODE                  87600019
         B     MSGOPER             SEND MSG TO OPERATOR                 87680019
         SPACE                                                          87760019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 87840019
*                                                                     * 87920019
*                                                                     * 88000019
*        TERMINATE  PROCESSING OF GLOBAL FILE                         * 88080019
*                                                                     * 88160019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 88240019
         SPACE                                                          88320019
MSGENDUP DS    0H                                                       88400019
         LA    R1,PARM1            R1 POINTS TO ONE WORD PARM LIST      88480019
         ENDUP FTYPE=GBL           END PROCESSING AND RELEASE CONTROL   88560019
         BR    R2                  RETURN TO INTERNAL CALLER            88640019
         EJECT                                                          88720019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 88800019
*                                                                     * 88880019
*                       WORK  AREAS                                   * 88960019
*                                                                     * 89040019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 89120019
         SPACE                                                          89200019
GETAD    DC    F'0'                ADDRESS OF GETMAIN/FREEMAIN AREAS    89280019
MOVE     MVC   8(0,R15),1(R14)     MOVE INSERTS INTO CANNED TEXT        89360019
         SPACE                                                          89440019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 89520019
*                                                                     * 89600019
*                            CONSTANTS                                * 89680019
*                                                                     * 89760019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 89840019
         SPACE                                                          89920019
         DS    0F                                                       90000019
MSGAVT   DC    V(IHKAVT)           ADDRESS OF ADDRESS VECTOR TABLE      90080019
AIHKMSG  DC    A(IHKMSG)           ADDRESS OF MAIN ENTRY POINT          90160019
F88      DC    F'88'               LENGTH OF AFIO BUFFER                90240019
         SPACE 1                                                        90320019
M217     DC    X'00F2F1F7'         'CRJE BROADCAST MESSAGES START'      90400019
M218     DC    X'00F2F1F8'         'CRJE BROADCAST MESSAGES END'        90480019
M219     DC    X'00F2F1F9'         'OUT OF MAIN STORAGE'                90560019
M232     DC    X'00F2F3F2'         'NO CRJE BROADCAST MESSAGES'         90640019
M236     DC    X'00F2F3F6'         'CRJE MESSAGE MAXIMUM REACHED'       90720019
M240     DC    X'00F2F4F0'         'ACTIVE AREA OUT OF SPACE'           90800019
M312     DC    X'00F3F1F2'         'NO BROADCAST MSGS' - TERMINAL       90880019
M358     DC    X'00F3F5F8'         'MESSAGE LOST'                       90960019
         SPACE 1                                                        91040019
H64      DC    H'64'               CONSTANT USED FOR MSG LENGTH W/O ID  91120019
H72      DC    H'72'               CONSTANT USED FOR MSG LENGTH W/ID    91200019
         SPACE 1                                                        91280019
MSGTYP   DC    X'0800'             SHOW SESS COMMAND RESPONSE           91360019
MCSFLAGS DC    X'8000'             NORMAL MCSFLAGS FIELD                91440019
MCSFLAG1 DC    X'1000'             MCSFLAGS WHEN MSGTYP FIELD INCLUDED  91520019
MCSFLAG2 DC    X'4000'             CONSOLE ID IN REGISTER 0             91600019
MCSRCRC  DC    X'0000'                                                  91680019
         SPACE 1                                                        91760019
USEROFF  DC    X'0C14'             INSERT OFFSETS FOR USER MESSAGE      91840019
         DS    0F                                                       91920019
HEX20    DC    X'20'               CODE INDICATING CONSOLE ID           92000019
MSGDC    DC    X'0800'             DESCRIPTOR CODE 5                    92080019
F0F0F0   DC    C'000'              NO MSG TO BE BUILT INDICATION        92160019
         SPACE 1                                                        92240019
BRD      DC    C'BRD '             MASK TO RECOGNIZE BRDCST MSG         92320019
CRJE     DC    C'CRJE MSG FR '     CANNED TEXT FOR USER/OPERATOR MSG    92400019
IHK      DC    C'IHK     '         MASK FOR BUILDING KEY FOR CANNED MSG 92480019
         EJECT                                                          92880019
*        DSECT FOR GETMAIN AREA                                         92960019
         SPACE                                                          93040019
GETAREA  DSECT                                                          93120019
SAVEAREA DS    18F                 SAVE AREA                            93200019
PARM1    DS    F                   POINTER TO TUB                       93280019
PARM2    DS    F                   USERID OR WORD OF 0'S                93360019
PARM3    DS    F                   MESSAGE NUMBER                       93440019
PARM4    DS    F                   1ST INSERT                           93520019
PARM5    DS    F                   2ND INSERT                           93600019
         SPACE 2                                                        93680019
*        DSECT FOR USER BUFFER                                          93760019
         SPACE                                                          93840019
BUFFER   DSECT                                                          93920019
BUFFMAIN DS    8C                  CONTROL INFORMATION                  94000019
BUFL     EQU   BUFFMAIN+4          LENGTH FOR WTO                       94080019
BUFMCS   EQU   BUFFMAIN+6          MCS FLAGS                            94160019
BUFNO    DS    8C                  MSG NUMBER                           94240019
BUFTEXT  DS    64C                 TEXT                                 94320019
BUFOFF1  DS    C                   1ST OFFSET                           94400019
BUFOFF2  DS    C                   2ND OFFSET                           94480019
BUFDC    DS    2C                  DESCRIPTOR CODE                      94560019
BUFRC    DS    2C                  ROUTING CODE                         94640019
BUFMTF   DS    2C                  MESSAGE TYPE FLAGS                   94720019
BUFKEY   EQU   BUFOFF1             RECORD KEY                           94800019
         SPACE 2                                                        94880019
         IHKCDSCT TUB=YES,CLB=YES,AVT=YES,CCT=YES,UVR=YES        A36801 94960020
         END                                                            95040019
