MUF      TITLE 'IHKMUF - MERGE COMMAND PROCESSOR'                       00100019
IHKMUF   CSECT                                                          00130020
* 066000,119000                                                  A34592 00160020
*A217500-219500                                                  A34600 00170020
*C119000,220000,542000                                           A34600 00180020
*D218000-219000                                                  A34600 00190020
*A628500                                                         A36814 00192020
*C119000,500000                                                  A36814 00194020
*D552500                                                         A36814 00196020
*A223300-223600,586500,675500                                    A47408 00197000
*C119000                                                         A47408 00198000
*********************************************************************** 00200019
*                                                                     * 00300019
*STATUS                                                               * 00400019
*   CHANGE LEVEL 0                                                    * 00500019
*FUNCTION                                                             * 00600019
*   THIS MODULE MERGES LINES FROM AN USER'S LIBRARY INTO THE ACTIVE   * 00700019
*   FILE.  IF A UTILITY FILE EXISTS, THE LINES UP TO AND INCLUDING    * 00800019
*   LINE AFTER WHICH THE LINES ARE TO BE MERGED ARE MOVED TO THE NEW  * 00900019
*   ACTIVE FILE.  THE DATA SET IS OPENED AND THE MEMBER FOUND.  IF    * 01000019
*   THE DATA SET OR MEMBER IS NOT FOUND, THE REST OF THE UTILITY FILE,* 01100019
*   IF IT EXISTS, IS MOVET INTO THE ACTIVE FILE, AN ERROR MESSAGE     * 01200019
*   QUEDED FOR THE USER, AND CONTROL RETURNED TO THE CALLING ROUTINE. * 01300019
*   IF A RANGE OF LINE NUMBERS IS SPECIFIED, THE DATA SET IS READ     * 01400019
*   UNTILL A LINE NUMBER EQUAL TO OR GREATER THAN THE BEGNING LINE    * 01500019
*   NUMBER IS FOUND.  ALL LINES IN THE RANGE SPECIFIED ARE INSERTED   * 01600019
*   AT THE END OF THE ACTIVE FILE AND RESEQUENCED USING THE LAST LINE * 01700019
*   NUMBER AND INCREMENT OF THE ACTIVE FILE.  IF NO RANGE IS          * 01800019
*   SPECIFIED, THE ENTIRE DATA SET IS COPIED.                         * 01900019
*   IF A UTILITY FILE EXISTS, THE REMAINING LINES ARE INSERTED AT THE * 02000019
*   END OF THE ACTIVE FILE AND RESEQUENCED.  CONTROL IS THEN RETURNED * 02100019
*   TO THE CALLING ROUTINE                                            * 02200019
*ENTRY POINTS                                                         * 02300019
*        IHKMUF - TO MERGE LINES FROM A USERS LIBRARY                 * 02400019
*INPUT                                                                * 02500019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING THE * 02600019
*   ADDRESSES OF THE TUB AND AVT                                      * 02700019
*OUTPUT                                                               * 02800019
*   N/A                                                               * 02900019
*EXTERNAL REFERENCES                                                  * 03000019
*        IHKBPM - TO READ LINES FROM USER'S LIBRARY                   * 03100019
*        IHKAFI - TO MANIPULATE ACTIVE AND UTILITY FILES              * 03200019
*        IHKMSG - TO QUEUE MESSAGES FOR THE USER                      * 03300019
*        IHKUTM - TO ENQUEUE FOR IHKBPM                               * 03400019
*EXITS, NORMAL                                                        * 03500019
*   RETURN TO CALLING ROUTINE WITH 0 IN REGISTER 15                   * 03600019
*EXITS, ERROR                                                         * 03700019
*   RETURN TO CALLING ROUTINE WITH ONE OF THE FOLLOWING RETURN CODES  * 03800019
*   IN REGISTER 15                                                    * 03900019
*   8  - GETMAIN FAILURE                                              * 04000019
*   12 - ACTIVE AREA I/O ERROR                                        * 04100019
*   16 - MESSAGE LOST                                                 * 04200019
*   20 - ACTIVE AREA OUT OF SPACE                                     * 04300019
*TABLES/WORK AREAS                                                    * 04400019
*   18 WORD SAVE AREA                                                 * 04500019
*   28 BYTE WORK AREA                                                 * 04600019
*   TUB                                                               * 04700019
*   TUBLNUMN - INDICATES LINE NUMBERS CONTAINED IN LINE               * 04800019
*   TUBPPTAD - CONTAINS THE ADDRESS OF THE PPT                        * 04900019
*   TUBUFFAD - CONTAINS THE ADDRESS OF THE USER BUFFER                * 05000019
*   TUBNXKEY - ACTIVE AREA POINTER                                    * 05100019
*   TUBCNTFS - NUMBER OF LINES                                        * 05200019
*   TUBGBLKY - UTILITY FILE POINTER                                   * 05300019
*   TUBDIRAD - CONTAINS ADDRESS OF DIRECTORY ENTRY                    * 05400019
*   TUBGBLNM - UTILITY FILE NUMBER                                    * 05500019
*   TUBPRMLS - PARAMETER AND WORK AREA                                * 05600019
*   TUBRAFBF - CONTAINS ADDRESS OF IHKAFI AND IHKBPM BUFFER           * 05700019
*   TUBUSRNM - OWNER OF LIBRARY USER ID                               * 05800019
*   PPT - CONTAINS PROCESSING SWITCHES                                * 05900019
*   USER BUFFER - WORK AREA                                           * 06000019
*   DIRECTORY ENTRY                                                   * 06100019
*ATTRIBUTES                                                           * 06200019
*   REENTRANT AND NONRESIDENT                                         * 06300019
*********************************************************************** 06400019
         EJECT                                                          06500019
*********************************************************************** 06700019
*          EQUATES                                                      06800019
*********************************************************************** 06900019
FNDFILE  EQU   X'FF'                    INDICATE END OF FILE (RPOINT)   07000019
BUFLEN   EQU   888                      BUFFER LENGTH                   07100019
X08      EQU   X'08'                                                    07200019
ENDLST   EQU   X'80'                    END OF PARM LIST                07300019
UILEN    EQU   X'0E'                    DIR USER INFO LENGTH (CRJE)     07400019
UILENRBE EQU   X'09'                    DIR USER INFO LENGTH (CRBE)     07500019
ENDFILE  EQU   X'FF'                    POINT TO ENE OF FILE            07600019
NUMZONE  EQU   X'F0'                    NUMERIC ZONE                    07700019
FSTLINE  EQU   X'00'                    POINT TO BEGNING OF LILE        07800019
UFNUM    EQU   X'07'                    UTILITY FILE NUMBER             07900019
X40      EQU     X'40'                                                  08000019
         SPACE 3                                                        08100019
*********************************************************************** 08200019
*        REGISTER EQUATES                                               08300019
*********************************************************************** 08400019
REG0     EQU   0                                                        08500019
REG1     EQU   1                                                        08600019
TUBR     EQU   2                                                        08700019
AVTR     EQU   3                                                        08800019
PPTR     EQU   4                                                        08900019
PARMR    EQU   5                                                        09000019
REG6     EQU   6                                                        09100019
PTR      EQU   6                                                        09200019
REG7     EQU   7                                                        09300019
REG8     EQU   8                                                        09400019
REG9     EQU   9                                                        09500019
KBXR     EQU   10                                                       09600019
BASE     EQU   11                                                       09700019
REG12    EQU   12                                                       09800019
REG13    EQU   13                                                       09900019
REG14    EQU   14                                                       10000019
REG15    EQU   15                                                       10100019
         SPACE 3                                                        10200019
*********************************************************************** 10300019
*          EQUATES FOR PPT SWITCHES                                     10400019
*********************************************************************** 10500019
PPTRANGE EQU   X'20'                    RANGE MERGE SW                  10600019
PPTUTIL  EQU   X'10'                    UTILITY FILE SW                 10700019
PPTFND   EQU   X'08'                    FIND GOOD SW                    10800019
PPTFNDF  EQU   X'F7'                    FIND SW OFF                     10900019
PPTADD   EQU   X'04'                    ADD PHASE SW                    11000019
PPTNFST  EQU   X'02'                    NOT 1ST TIME SW                 11100019
PPTINS   EQU   X'01'                    INSERT SW                       11200019
PPTRNGF  EQU   X'80'                    1ST LINE OF RANGE FOUND         11300019
PPTFNDB  EQU   X'40'                    BAD RFIND SW                    11400019
PPTFNDBF EQU   X'BF'                    OFF                             11500019
PPTOFF   EQU   X'3F'                    ALL UNUSED OFF                  11600019
PPTRANGF EQU   X'DF'                    NO RANGE MERGE           A34592 11650020
OUTSPCD  EQU   20                       OUT OF SPACE AA RETURN CODE     11700019
         EJECT                                                          11800019
         SAVE  (14,12),,MUF72060        SAVE REGISTERS           A47408 11900000
         LR    BASE,REG15               LOAD BASE REGISTER              12000019
         USING IHKMUF,BASE              ESTABLISH CSECT ADDRESSABILITY  12100019
         L     TUBR,0(REG1)             ESTABLISH TUB ADDRESSABILITY    12200019
         USING TUBDSECT,TUBR                                            12300019
         L     AVTR,4(REG1)             ESTABLISH AVT ADDRESSABILITY    12400019
         USING AVTDSECT,AVTR                                            12500019
         L     PPTR,TUBPPTAD            ESTABLISH PPT ADDRESSABILITY    12600019
         USING PPTDSECT,PPTR                                            12700019
         L     KBXR,IHKYYKBX            SET UP ADDRESSABILITY FOR       12800019
         USING RAFKNBX,KBXR               KONBOX                        12900019
         L     REG6,PPTFLG+8            GET WORK AND SAVE AREA ADDR     13000019
         ST    REG13,4(REG6)            CHAIN SAVE AREAS                13100019
         ST    REG6,8(REG13)                                            13200019
         LR    REG13,REG6               SET UP SAVE AND WORK AREA       13300019
         USING WSDSECT,REG13              ADDRESSABILITY                13400019
         L     REG15,TUBUFFAD           SET UP ADDRESSABILITY FOR       13500019
         LA    PARMR,WSDSECT+72         MOVE PARAMETERS TO WORK AREA    13600019
         MVC   0(27,PARMR),0(REG15)                                     13700019
         USING PARMDSCT,PARMR             PARAMETERS FROM IHKMGE        13800019
         NI    MUFSW,MUFOFF             TURN OFF PROCESSING SWITCHES    13900019
         NI    PPTFLG,PPTOFF            TURN OFF UNUSED SWITCHES        14000019
         TM    PPTFLG,PPTUTIL           TEST FOR UTILITY FILE           14100019
         BZ    ENQBPM                   IF NOT, ENQUEUE FOR IHKBPM      14200019
         LA    REG1,28(REG13)           BUILD PARAMETER LIST FOR IHKAFI 14300019
         RPOINT B,NR,KEY=FIRST,FTYPE=GBL  POINT TO BEGNING              14400019
         C   REG15,F4                   TEST RETURN CODE                14500019
         BH    RETURN                   IF ERROR, RETURN                14600019
         LA    REG1,28(REG13)           BUILD PARAMETER LIST FOR IHKAFI 14700019
         RGET  XK,S,B,FTYPE=GBL         GET 1ST LINE NO                 14800019
         C     REG15,F4                 TEST RETURN CODE                14900019
         BH    RETURN                   IF ERROR, RETURN                15000019
         BE    NOINS                    IF EOD, ENQ ERROR MESSAGE       15100019
         CLC   TUBGBLKY,AFTERLNE        TEST FOR BEGNING MERGE          15200019
         BH    ENQBPM                   IF YES ENQUEUE FOR IHKBPM       15300019
         OI    MUFSW,MUF1PAS            SET 1ST PASS SWITCH             15400019
         B     UTILGET1                 GET BLOCK FROM UTILITY FILE     15500019
*                                                                       15600019
*    ENQUEUE FOR IHKBPM                                                 15700019
*                                                                       15800019
ENQBPM   NI    TUBAFISW,TUBFCTLF        TURN OFF BUFFER CONTROL SW      15900019
         MVC   PPTPARS+16(4),TUBRAFBF   SAVE BUFFER ADDRESS             16000019
         ST    TUBR,TUBPARM1            SET UP PARM LIST FOR IHKUTM     16100019
         LA    REG1,X80                                                 16200019
         ST    REG1,TUBPARM2                                            16300019
         LA    REG1,TUBPARM1            GET ADDRESS OF PARM LIST        16400019
         MVC   TUBGBLKY,TUBUSRNM        PUT USERID INTO GBL KEY         16500019
         L     REG15,IHKYYUTM           GET ADDRESS OF IHKUTM           16600019
         BALR  REG14,REG15              ENQUEUE FOR BPAM                16700019
         OI    TUBAFISW,TUBFCTLN        TURN OF BUFFER CONTROL SW       16800019
         MVC   TUBRAFBF,PPTPARS+16      RESTORE BUFFER ADDRESS          16900019
         MVI   TUBGBLNM,UFNUM           RESTORE UTILITY FILE NUMBER     17000019
         B     *+4(REG15)               TEST RETURN CODE                17100019
         B     UTMGOOD                  IF GOOD, CONTINUE               17200019
         B     UIDNF                    IF USERID NOT FOUND,ENQ MSG     17300019
         B     RETURN                    IF GETMAIN FAILED, RETURN      17400019
         B     RETURN                   IF ACTIVE FILE I/O ERR, RETURN  17500019
         B     NODDNM                   IF NO DD NAME, ENQ ERR MSG      17600019
         B     UTMGOOD                  NOT USED                        17700019
         B     LIBINOP                  IF LIBRARY INOPERATIVE, ENQ MSG 17800019
*                                                                       17900019
*          FIND DATA SET                                                18000019
*                                                                       18100019
UTMGOOD  OI    PPTFLG,PPTFNDB           SET BAD FIND SW                 18200019
         OI    PPTFLG,PPTFND            SET FIND SW                     18300019
         LA    REG1,28(REG13)           SET UP PARM LIST FOR IHKAFI     18400019
         RFIND I                        FIND DATA SET                   18500019
         B     *+4(REG15)               TEST RETURN CODE                18600019
         B     FNDGOOD                  IF GOOD, CONTINUE               18700019
         B     NFOUND                   IF NOT FOUND, ENQ ERR MSG       18800019
         B     RETURN                   IF GETMAIN FAILED, RETURN       18900019
         B     LIBIOER                  IF I/O ERR, BRANCH              19000019
*                                                                       19100019
*          PROCESS DATA SET DIRECTORY                                   19200019
*                                                                       19300019
FNDGOOD  NI    PPTFLG,PPTFNDBF          TURN OFF BAD FIND SW            19400019
         LA    REG14,BPBLDLST+4         SET UP ADDRESSABILITY           19500019
         USING DIRDSECT,REG14             DIRECTORY ENTRY               19600019
         CLI   DIRUILEN,UILEN           TEST FOR CRJE D.S.              19700019
         BE    DIROK                    IF YES CONTINUE                 19800019
         CLI   DIRUILEN,UILENRBE        TEST FOR CRBE D.S.              19900019
         BNE   EDTREQ                   IF NOT, BRANCH                  20000019
         B     NOKEY                    SKIP KEY TEST                   20100019
DIROK    CLC   DIRKEY,BLANKS            TEST FOR DATA SET KEY PROTECTED 20200019
         BE    NOKEY                    IF NOT, SKIP KEY COMPARE        20300019
         CLC   TUBUSRID,TUBUSRNM        TEST FOR OWN DATA SET           20400019
         BE    NOKEY                    IF YES, SKIP KEY TEST           20500019
         CLC   DIRKEY,KEY               TEST FOR EQUAL KEYS             20600019
         BNE   KEYERR                   IF NOT, ENQ ERR MSG             20700019
NOKEY    LH    REG15,DIRSAV             INCREMENT DIR COUNTER           20800019
         AH    REG15,H1                                                 20900019
         STH   REG15,DIRSAV                                             21000019
         MVC   SFBUFF1,TUBRAFBF         SET UP BUFFER ADDRESS FOR BPM   21100019
         DROP  REG14                                                    21200019
*                                                                       21300019
*          MERGE DATA SET                                               21400019
*                                                                       21500019
DSREAD   LA    REG1,28(REG13)           SET UP PARM LIST FOR IHKBPM     21600019
         RREAD                          READ BLOCK                      21700019
         B     *+4(REG15)               TEST RETURN CODE         A34600 21750020
         B     RDGOOD                   GOOD, CONTINUE           A34600 21800020
         B     EODDS                    EOD, PROCESS             A34600 21850020
         B     RETURN                   GETMAIN FAILURE, RETURN  A34600 21900020
         B     LIBIOER                  I/O ERROR ON LIB, PROC   A34600 21950020
RDGOOD   LH    REG7,TUBCNTFS            GET NO OF LINES READ     A34600 22020020
         L     PTR,SFBUFF1              POINT TO 1ST LINE OF BLOCK      22100019
         LA    PTR,8(PTR)               INCREMENT PAST CONTROL WORDS    22200019
CALCLNO  MVC   PPTPARS+8(8),0(PTR)      SAVE LINE NUMBER                22300019
         TM    MUFSW,BADEND             BAD END PROCESSING?      A47408 22330000
         BO    NOLNO                    YES, PROCESS UTILITY FILEA47408 22360000
         TM    MUFSW,MUF1PAS            TEST FOR 1ST PASS               22400019
         BZ    TSTRNG                   IF NOT, CONTINUE                22500019
         CLC   0(8,PTR),AFTERLNE        TEST FOR END                    22600019
         BNH   NOLNO                    IF NOT, TEST NEXT LINE          22700019
         BAL   REG12,CALCINS            CALC NO OF LINES, INSERT        22800019
         NI    MUFSW,MUF1PASF           TURN OFF 1ST PASS SWITCH        22900019
         B     ENQBPM                   ENQUEUE FOR IHKBPM              23000019
TSTRNG   TM    PPTFLG,PPTRANGE          TEST FOR RANGE MERGE            23100019
         BO    RANGE                    IF YES, BRANCH                  23200019
RNGMGE   TM    PPTFLG,PPTADD            TEST FOR ADD PHASE              23300019
         BO    NOLNOTST                 IF YES, BRANCH                  23400019
         TM    PPTFLG,PPTRANGE          TEST FOR RANGE MERGE            23500019
         BZ    NOLNOTST                 IF NOT, BRANCH                  23600019
         CLC   0(8,PTR),ENDLNE          TEST FOR END OF RANGE           23700019
         BH    ENDRANGE                 IF YES, BRANCH                  23800019
NOLNOTST TM    PPTFLG,PPTNFST           TEST FOR 1ST TIME               23900019
         BO    NOTFST                   IF NOT, BRANCH                  24000019
         L     REG15,TUBDIRAD           SET UP ADDRESSABILITY FOR       24100019
*                                         DIRECTORY ENTRY               24200019
         USING DIRDSECT,REG15                                           24300019
         L     REG9,DIRINC              GET INCREMENT                   24400019
         DROP  REG15                                                    24500019
         OI    PPTFLG,PPTNFST           SET NOT 1ST TIME SW             24600019
         MVI   TUBNXKEY+7,ENDFILE       SET UP TO POINT TO THE END OF   24700019
*                                         THE AVTIVE FILE               24800019
         BAL   REG8,PTAFTER             POINT                           24900019
         CLI   TUBNXKEY+7,ENDFILE       TEST FOR NULL ACTIVE FILERDS    25000019
         BNE   NOTFST                   IF YES, BRANCH                  25100019
         LR    REG15,REG9               GET STARTING LINE NO            25200019
         B     NULLF                    PROCESS NULL FILE               25300019
NOTFST   PACK  TUBPARM2(8),TUBNXKEY     CALC NEXT LINE NO               25400019
         CVB   REG15,TUBPARM2                                           25500019
         AR    REG15,REG9                                               25600019
         C     REG15,MAXLNO             TEST FOR MAX LINE NO EXCEEDED   25700019
         BH    MAXLNOER                 IF YES, ENQUEUE MESSAGE         25800019
NULLF    CVD   REG15,TUBPARM2                                           25900019
         UNPK  TUBNXKEY,TUBPARM2(8)                                     26000019
         OI    TUBNXKEY+7,NUMZONE       PUT NUMERIC ZONE INTO LAST BYTE 26100019
         MVC   0(8,PTR),TUBNXKEY        PUT NO INTO LINE                26200019
         TM    TUBFLG2,TUBLNUMN         TEST FOR LINE NOS IN LINE       26300019
         BZ    NOLNO                    IF NOT, BRANCH                  26400019
         MVC   80(8,PTR),TUBNXKEY       PUT LINE NO INTO LAST 8 BYTES   26500019
NOLNO    LA    PTR,88(PTR)              INCREMENT TO NEXT LINE          26600019
         BCT   REG7,CALCLNO             PROCESS NEXT LINE IF NOT LAST   26700019
         BAL   REG8,INSAF               INSERT LINES INTO ACTIVE FILE   26800019
         TM    PPTFLG,PPTADD            TEST FOR ADD PHASE              26900019
         BO    UTILGET                  IF YES, GET LINES FROM UTIL     27000019
         TM    MUFSW,MUF1PAS            TEST FOR 1ST PASS               27100019
         BO    UTILGET                  IF YES, GET BLOCK FROM UTIL     27200019
         B     DSREAD                   GET NEXT BLOCK                  27300019
         SPACE 3                                                        27400019
*********************************************************************** 27500019
*          GET LINES FROM UTILITY FILE (ADD PHASE)                      27600019
*********************************************************************** 27700019
UTILGET  MVC   TUBGBLKY,PPTPARS+8       SET UP TP POINT AFTEL LAST      27800019
*                                         LINE OF LAST BLOCK            27900019
         BAL   REG8,PTAFTUF             POINT                           28000019
UTILGET1 LA    REG1,28(REG13)           SET UP PARM LIST FOR IHKAFI     28100019
         MVC   TUBCNTFS,H10             SET UP IHKAFI COUNT FIELD       28200019
         RGET  R,M,A,FTYPE=GBL          GET BLOCK FROM UTULITY FILE     28300019
         C     REG15,F4                 TEST RETURN CODE                28400019
         BH    RETURN                   IF GETMAIN FAILED  OR I/O ERR,  28500019
*                                         RETURN                        28600019
         BE    RETCD0                   IF END OF DATA, BRANCH          28700019
         SR    REG7,REG7                CLEAR BRANCH REGISTER           28800019
         IC    REG7,TUBCNTFS            GET NO OF LINES READ            28900019
         STH   REG7,TUBCNTFS            SET UP IHKAFI COUNT FIELD FOR   29000019
*                                         INSERT                        29100019
         L     PTR,TUBRAFBF             POINT OT 1ST LINE OF BLOCK      29200019
         LA    PTR,8(PTR)                                               29300019
         LA    REG1,28(REG13)           SET UP PARM LIST FOR IHKBPM     29400019
         ENDUP FTYPE=GBL                                                29500019
         C     REG15,F4                 TEST RETURN CODE                29600019
         BH    RETURN                   IF BAD, RETURN                  29700019
         MVI   TUBNXKEY+7,ENDFILE       SET UP TO POINT TO THE END OF   29800019
         BAL   REG8,PTAFTER               THE ACTIVE FILE               29900019
         B     CALCLNO                  CONTINUE                        30000019
         SPACE 3                                                        30100019
*********************************************************************** 30200019
*          FIND 1ST LINE FOR RANGE MERGE                                30300019
*********************************************************************** 30400019
RANGE    TM    PPTFLG,PPTRNGF           TEST FOR 1ST LINE FOUND         30500019
         BO    RNGMGE                   IF YES, BRANCH                  30600019
         L     REG15,F88                FIND LAST LINE OF BLOCK         30700019
         MH    REG15,TUBCNTFS                                           30800019
         S     REG15,F88                                                30900019
         AR    REG15,PTR                POINT TO LAST LINE OF BLOCK     31000019
         CLC   0(8,REG15),STARTLNE      TEST FOR LINE IN RANGE          31100019
         BL    DSREAD                   IF NOT, READ NEXT BLOCK         31200019
*                                                                       31300019
*    IF LAST LINE IS WITHIN RANGE, FIND 1ST LINE IN RANGE               31400019
*                                                                       31500019
         L     PTR,SFBUFF1              POINT TO 1ST LINE OF BLOCK      31600019
         LA    PTR,8(PTR)                                               31700019
RANGE1   CLC   0(8,PTR),STARTLNE        TEST FOR LINE IN RANGE          31800019
         BNL   RANGE2                   IF YES, SET UP NO OF LINES      31900019
         LA    PTR,88(PTR)              INCREMENT TO NEXT LINE          32000019
         B     RANGE1                   TEST NEXT LINE                  32100019
*                                                                       32200019
*    SET UP TO PROCESS LINES IN RANGE                                   32300019
*                                                                       32400019
RANGE2   L     REG14,SFBUFF1            CALC NO OF LINES LEFT IN BLOCK  32500019
         LR    REG15,PTR                                                32600019
         SR    REG15,REG14                                              32700019
         L     REG14,F0                                                 32800019
         D     REG14,F88                                                32900019
         LH    REG14,TUBCNTFS                                           33000019
         SR    REG14,REG15                                              33100019
         STH   REG14,TUBCNTFS           PUT NO OF LINES INTO COUNT      33200019
         LR    REG7,REG14               SET UP BRANCH REGISTER          33300019
         S     PTR,F8                                                   33400019
         ST    PTR,TUBRAFBF             PUT STARTING ADDR INTO TUB      33500019
         LA    PTR,8(PTR)               POINT TO 1ST LINE TO BE MERGED  33600019
         OI    PPTFLG,PPTRNGF           SET 1ST LINE FOUND SWITCH       33700019
         B     RNGMGE                   MERGE LINES                     33800019
         SPACE 3                                                        33900019
*********************************************************************** 34000019
*          PROCESS LAST BLOCK IN RANGE                                  34100019
*********************************************************************** 34200019
ENDRANGE BAL   REG12,CALCINS            CALC NO OF LINES INSERT         34300019
*                                                                       34400019
*    TEST FOR UTILITY FILE                                              34500019
*                                                                       34600019
EODDS    TM    PPTFLG,PPTINS            TEST FOR INSERTE MADE           34700019
         BZ    NOINS                    IF NOT, ENQ ERR MSG             34800019
         MVC   TUBRAFBF,SFBUFF1         INITILIZE BUFFER ADDRESS        34900019
EODDS1   TM    PPTFLG,PPTUTIL           TEST FOR UTILITY FILE           35000019
         BZ    RETCD0                   IF NOT, BRANCH                  35100019
         LA    REG1,28(REG13)           BUILD PARM LIST FOR IHKAFI      35200019
         ENDUP                                                          35300019
         C     REG15,F4                 TEST RETURN CODE                35400019
         BH    RETURN                   IF ERROR, RETURN                35500019
         TM    PPTFLG,PPTFND+PPTFNDB    TEST FOR RFIND ISSUED           35600019
         BZ    EODDS2                   IF NOT, DON'T ISSUE RCLOSE      35700019
         BAL   REG14,CLOSE              CLOSE DATA SET                  35800019
         NI    PPTFLG,PPTFNDF           TIRN OFF FIND SW                35900019
         C     REG15,F4                 TEST RETURN CODE                36000019
         BH    RETURN                   IF ERROR, RETURN                36100019
EODDS2   MVC   TUBGBLKY,AFTERLNE        SET UP FOR ADD PHASE            36200019
         LA    REG1,28(REG13)           BUILD PARM LIST FOR IHKAFI      36300019
*                                       POINT TO THE BEGNING OF         36400019
         RPOINT A,NR,KEY=HIEQ,FTYPE=GBL THE UTILITY FILE                36500019
         C     REG15,F4                 TEST RETURN CODE                36600019
         BH    RETURN                   IF ERROR, RETURN                36700019
         OI    PPTFLG,PPTADD            SET ADD PHASE SW                36800019
         B     UTILGET1                 GET LINES FROM LTILITY FILE     36900019
         EJECT                                                          37000019
*********************************************************************** 37100019
*                                                                       37200019
*          RETURN ROUTINE                                               37300019
*                                                                       37400019
*********************************************************************** 37500019
RETCD0   LA    REG15,0                  SET 0 RETURN CODE               37600019
RETURN   LR    REG12,REG15              SAVE RETURN CODE                37700019
         TM    PPTFLG,PPTUTIL           TEST FOR UTILITY FILE           37800019
         BZ    RETURN1                  IF NOT ONE, SKIP RELEASE        37900019
         LA    REG1,28(REG13)           SET UP PARM LIST FOR IHKAFI     38000019
         RELEASE A,FTYPE=GBL            RELEASE UTILITY FILE            38100019
         ST    REG15,TUBPARM1           SAVE RETURN CODE                38200019
         L     REG15,TUBUFFAD           DEQUEUE FROM UTILITY FILE QUEUE 38300019
         L     REG15,100(REG15)                                         38400019
         ST    REG15,OSDSQCTL                                           38500019
         LA    REG15,0(REG15)                                           38600019
         LA    REG1,OSDSQCTL+4                                          38700019
         CR    REG15,REG1               TEST FOR LAST ELEMENT           38800019
         BE    NOELEM                   IF YES, SKIP POST               38900019
         OI    4(REG15),X40             POST NEXT ELEMENT               39000019
NOELEM   L     REG15,TUBPARM1           RESTORE RETURN CODE             39100019
RETURN1  TM    PPTFLG,PPTFND            TEST FOR USER'S LIB OPENED      39200019
         BZ    RETURN2                  IF NOT, SKIP RCLOSE             39300019
         BAL   REG14,CLOSE              CLOSE DATA SET                  39400019
         C     REG15,F4                 TEST RETURN CODE                39500019
         BL    RETURN2                  IF GOOD CONTINUE                39600019
         LR    REG12,REG15              IF BAD, SAVE RETURN CODE        39700019
RETURN2  LA    REG1,28(REG13)           SET UP PARM LIST FOR IHKAFI     39800019
         ENDUP                                                          39900019
         C     REG15,F4                 TEST RETURN CODE                40000019
         BL    RETURN3                  IF GOOD, CONTINUE               40100019
         LR    REG12,REG15              IF BAD, SAVE RETURN CODE        40200019
RETURN3  L     REG7,TUBRAFBF            SET UP TO FREE BUFFER           40300019
         LA    REG7,0(REG7)             ELEM HIGH ORDER BITS            40400019
         FREEMAIN R,LV=BUFLEN,A=(REG7)  FREE BUFFER                     40500019
         LR    REG7,REG13               SET UP TO FREE SAVE AND WORK    40600019
         L     REG13,4(REG13)             AREAS                         40700019
         FREEMAIN R,LV=GMLEN,A=(REG7)   FREE WORK AND SAVE AREAS        40800019
         NI    TUBAFISW,TUBFCTLF        TURN OFF BUFFER CONTROL SW      40900019
         LR    REG15,REG12              RESTORE RETURN CODE             41000019
         RETURN (14,12),T,RC=(15)       RETURN                          41100019
         EJECT                                                          41200019
*********************************************************************** 41300019
*                                                                       41400019
*          PROCESSING SUBROUTINES                                       41500019
*                                                                       41600019
*********************************************************************** 41700019
         SPACE 3                                                        41800019
CALCINS  L     REG14,TUBRAFBF           CALC NO OF LINES TO BE INSERTED 41900019
         LR    REG15,PTR                                                42000019
         SR    REG15,REG14                                              42100019
         L     REG14,F0                                                 42200019
         D     REG14,F88                                                42300019
         C     REG15,F0                 TEST FOR NO LINES               42400019
         BNH   CALCINS1                 IF NONE, SKIP INSERT            42500019
         STH   REG15,TUBCNTFS           PUT NO OF LINES INTO TUB        42600019
         BAL   REG8,INSAF               INSERT LINES INTO ACTIVE FILE   42700019
CALCINS1 TM    PPTFLG,PPTFND            TEST FOR ENQ FOR IHKBPM         42800019
         BZ    0(REG12)                 IF NOT EXIT                     42900019
         MVC   TUBRAFBF,SFBUFF1         RESET BUFFER ADDRESS            43000019
         BR    REG12                    EXIT                            43100019
*********************************************************************** 43200019
*          POINT AFTER LINE IN ACTIVE FILE                              43300019
*********************************************************************** 43400019
PTAFTER  LA    REG1,28(REG13)           SET UP PARM LIST FOR IHKAFI     43500019
         RPOINT A,NR                    POINT AFTER LINE                43600019
PTAFTER1 C     REG15,F4                 TEST RETURN CODE                43700019
         BH    RETURN                   IF BAD, RETURN                  43800019
         BR    REG8                     EXIT                            43900019
         SPACE 3                                                        44000019
*********************************************************************** 44100019
*          POINT AFTER LINE IN UTILITY FILE                             44200019
*********************************************************************** 44300019
PTAFTUF  LA    REG1,28(REG13)           SET UP PARM LIST FOR IHKAFI     44400019
         RPOINT A,NR,FTYPE=GBL          POINT AFTER LINE                44500019
         B     PTAFTER1                 TEST RETURN CODE                44600019
         SPACE 3                                                        44700019
*********************************************************************** 44800019
*          INSERT LINES INTO ACTIVE FILE                                44900019
*********************************************************************** 45000019
INSAF    LA    REG1,28(REG13)           SET UP PARM LIST FOR IHKAFI     45100019
         INSERT M,A                     INSERT LINES INTO ACTIVE FILE   45200019
         TM    PPTFLG,PPTFND            TEST FOR ENQUEUED FOR IHKBPM    45300019
         BZ    INSAF2                   IF NOT , BRANCH                 45400019
         MVC   TUBRAFBF,SFBUFF1         RESTORE BUFFER ADDRESS          45500019
INSAF2   C     REG15,F4                 TEST RETURN CODE                45600019
         BH    RETURN                   IF GETMAIN FAILED, OR I/O ERR   45700019
*                                         RETURN                        45800019
         BE    OUTSPAA                  IF A.A. OUT OF SPACE ENQ MSG    45900019
         TM    PPTFLG,PPTADD            TEST IF FROM ADD PHASE          46000019
         BO    INSAF1                    IF YES, TEST FOR UTILITY FILE  46100019
         TM    MUFSW,MUF1PAS            TEST FOR 1ST PASS               46200019
         BO    INSAF1                   IF YES, SKIP SET INSERT SW      46300019
         OI    PPTFLG,PPTINS            SET INSERT SW                   46400019
         BR    REG8                      EXIT                           46500019
INSAF1   LA    REG1,28(REG13)           SET UP PARM LIST FOR IHKAFI     46600019
         ENDUP                                                          46700019
         C     REG15,F4                 TEST RETURN CODE                46800019
         BH    RETURN                   IF BAD, RETURN                  46900019
         BR    REG8                     EXIT                            47000019
         SPACE 3                                                        47100019
*********************************************************************** 47200019
*          CLOSE DATA SET                                               47300019
*********************************************************************** 47400019
CLOSE    ST    REG14,TUBIRLSA           SAVE EXIT REGISTER              47500019
         LA    REG14,BPBLDLST+15        GET DIR LENGTH                  47600019
         CLI   0(REG14),UILEN           TEST FOR CRJE DIRECTORY         47700019
         BNE   CLOSE1                   IF NOT, BRANCH                  47800019
         TM    PPTFLG,PPTFNDB           TEST FOR BAD RFIND              47900019
         BO    CLOSE1                   IF YES, CLOSE NOSTOW            48000019
         LA    REG1,28(REG13)           BUILD PARM LIST FOR IHKBPM      48100019
         RCLOSE STOW                    CLOSE CRJE DATA SET             48200019
         B     CLOSE2                                                   48300019
CLOSE1   LA    REG1,28(REG13)           BUILD PARM LIST FOR IHKBPM      48400019
         RCLOSE NOSTOW                  CLOSE OTHER DATA SET            48500019
CLOSE2   L     REG14,TUBIRLSA           RESTORE EXIT REGISTER           48600019
         BR    REG14                    EXIT                            48700019
         EJECT                                                          48800019
*********************************************************************** 48900019
*                                                                       49000019
*          ERROR PROCESSING ROUTINES                                    49100019
*                                                                       49200019
*********************************************************************** 49300019
         SPACE 3                                                        49400019
*********************************************************************** 49500019
*          NO DD NAME FOR LIBRARY                                       49600019
*********************************************************************** 49700019
NODDNM   LA    REG7,NODDNMCD            BUILD PARM LIST FOR MSG WTR     49800019
         MVI   PPTPARS+16,X08           SET UP MESSAGE INSERT           49840019
         MVC   PPTPARS+17(8),TUBUSRNM                                   49880019
         LA    REG12,PPTPARS+16         GET ADDRESS OF INSERT           49920019
         BAL   REG8,ENQMSG2             ENQUEUE MSG                     49960019
         B     EODDS1                   TEST FOR UTILITY FILE    A36814 50030020
         SPACE 3                                                        50100019
*********************************************************************** 50200019
*          LIBRARY I/O ERROR                                            50300019
*********************************************************************** 50400019
LIBIOER  ST    TUBR,TUBPARM1            SET UP PARM LIST FOR IHKUTM TO  50500019
         LA    REG14,INOP                 MARK LIB INOPERATIVE          50600019
         LA    REG1,TUBPARM1                                            50700019
         MVC   TUBGBLKY,TUBUSRID        PUT USER ID INTO KEY AREA       50800019
         MVC   TUBIRLSA,TUBRAFBF        SAVE BUFFER ADDRESS             50900019
         L     REG15,IHKYYUTM           GET ADDR OF IHKUTM              51000019
         BALR  REG14,REG15              CALL IHKUTM                     51100019
         MVC   TUBRAFBF,TUBIRLSA        RESTORE BUFFER ADDRESS          51200019
         OI    TUBAFISW,TUBFCTLN        TURN ON BUFFER CONTROL SW       51300019
         MVI   TUBGBLNM,UFNUM           RESTORE UTILITY FILE NUMBER     51400019
         B     *+4(REG15)               TEST RETURN CODE                51500019
         B     INOPR                    IF GOOD, CONTINUE               51600019
         B     RETCD0                   NOT USED                        51700019
         B     RETURN                   IF GETMAIN FAILED, RETURN       51800019
         B     RETURN                   IF A.A. I/O ERR, RETURN         51900019
         B     INOPR                    NOT USED                        52000019
         B     INOPR                    NOT USED                        52100019
         B     INOPR                    IF LIBRARY INACT, CONTINUE      52200019
INOPR    LA    REG7,INOPRCDU            BUILD PARM LIST FOR IHKMSG      52300019
         BAL   REG8,ENQMSG1             ENQ MSG FOR USER                52400019
         ST    TUBR,TUBPARM1            BUILD PARM LIST FOR IHKMSG TO   52500019
         LA    REG15,F0                   SEND LIB INOPERATIVE MSG      52600019
         ST    REG15,TUBPARM2             TO CENTRAL OPERATOR           52700019
         LA    REG15,INOPRCDC                                           52800019
         ST    REG15,TUBPARM3                                           52900019
         MVI   PPTPARS+16,X08                                           53000019
         MVC   PPTPARS+17(8),TUBUSRID                                   53100019
         LA    REG15,PPTPARS+16                                         53200019
         ST    REG15,TUBPARM4                                           53300019
         OI    TUBPARM4,ENDLST          FLAG END OF PARM LIST           53400019
         MVC   TUBIRLSA,TUBRAFBF        SAVE BUFFER ADDRESS             53500019
         LA    REG1,TUBPARM1            GET ADDRESS OF PARM LIST        53600019
         L     REG15,IHKYYMSG           GET ADDRESS OF MSG WRITER       53700019
         BALR  REG14,REG15              SEND MESSAGE                    53800019
         MVC   TUBRAFBF,TUBIRLSA        RESTORE BUFFER ADDRESS          53900019
         OI    TUBAFISW,TUBFCTLN        TURN ON BUFFER CONTROL SW       54000019
         MVI   TUBGBLNM,UFNUM           RESTORE UTILITY FILE NUMBER     54100019
         B     EODDS1                   TEST FOR UTILITY FILE    A34600 54200020
         SPACE 2                                                        54300019
*********************************************************************** 54400019
*          DATA SET NOT FOUND                                           54500019
*********************************************************************** 54600019
NFOUND   LA    REG7,NFOUNDCD            BUILD PARM LIST FOR DS NOT      54700019
         MVI   PPTPARS+16,X08             FOUND                         54800019
         MVC   PPTPARS+17(8),TUBPMFNM                                   54900019
         LA    REG12,PPTPARS+16                                         55000019
         BAL   REG8,ENQMSG2             FINISH PARM LIST AND ENQUEUE    55100019
*                                         MESSAGE                       55200019
         B     EODDS1                   GET LINES FROM UTILITY FILE     55300019
         SPACE 3                                                        55400019
*********************************************************************** 55500019
*          DS KEY INVALID                                               55600019
*********************************************************************** 55700019
KEYERR   LA    REG7,KEYCD               BUILD PARM LIST FOR KEY INVAL   55800019
*                                         MESSAGE                       55900019
         BAL   REG8,ENQMSG1             FINISH PARM LIST AND ENQ MSG    56000019
         B     EODDS1                   TEST FOR UTILITY FILE           56100019
         SPACE 3                                                        56200019
*********************************************************************** 56300019
*          EDIT OF DATA SET REQUIRED                                    56400019
*********************************************************************** 56500019
EDTREQ   TM    PPTFLG,PPTRANGE          TEST FOR RANGE MERGE            56600019
         BZ    DIROK                    IF NOT, CONTINUE PROCESSING     56700019
         LA    REG7,EDTREQCD            BUILD PARM LIST FOR EDIT REQ    56800019
         BAL   REG8,ENQMSG1             FINISH PARM LIST AND ENQ MSG    56900019
         B     EODDS1                   TEST FOR UTILITY FILE           57000019
         SPACE 3                                                        57100019
*********************************************************************** 57200019
*          OUT OF SPACE, ACTIVE AREA                                    57300019
*********************************************************************** 57400019
OUTSPAA  LA    REG7,OUTSPACD            BUILD PARM LIST FOR OUT OF      57500019
*                                         SPACE ACTIVE AREA MSG         57600019
         BAL   REG8,ENQMSG1             FINISH PARM LIST AND ENQ MSG    57700019
         LA    REG15,OUTSPCD            SET OUT OF SPACE RETURN CODE    57800019
         B     RETURN                   RETURN                          57900019
          SPACE 3                                                       58000019
*********************************************************************** 58100019
*          NO LINES IN RANGE                                            58200019
*********************************************************************** 58300019
NOINS    LA    REG7,NOINSCD             BUILD PARM LIST FOR NO LINES    58400019
*                                          IN RANGE MSG                 58500019
NOINS1   BAL   REG8,ENQMSG1             FINISH PARM LIST AND ENQ MSG    58600019
         OI    MUFSW,BADEND             SET BAD END SWITCH       A47408 58650000
         B     EODDS1                    TEST FOR UTILITY FILE          58700019
         SPACE 3                                                        58800019
*********************************************************************** 58900019
*          USERID NOT FOUND                                             59000019
*********************************************************************** 59100019
UIDNF    LA    REG7,UIDNFCD             GET ADDRESS OF MSG NUMBER       59200019
         B     NOINS1                   ENQUEUE MESSAGE                 59300019
         SPACE 3                                                        59400019
*********************************************************************** 59500019
*          LIBRARY INOPERATIVE                                          59600019
*********************************************************************** 59700019
LIBINOP  LA    REG7,INOPRCDU            GET ADDRESS OF MSG NUMBER       59800019
         B     NOINS1                                                   59900019
         SPACE 3                                                        60000019
*********************************************************************** 60100019
*          MAXIMUM LINE NUMBER EXCEEDED                                 60200019
*********************************************************************** 60300019
MAXLNOER LA    REG7,MAXLNOCD            GET MESSAGE NUMBER              60400019
         BAL   REG8,ENQMSG1             ENQUEUE MESSAGE                 60500019
         B     RETCD0                   RETURN                          60600019
         EJECT                               N                          60700019
*********************************************************************** 60800019
*                                                                       60900019
*          ENQUEUE MESSAGE FOR USER                                     61000019
*                                                                       61100019
*********************************************************************** 61200019
ENQMSG1  ST    REG7,TUBPARM4            FINISH PARM LIST FOR MSG WRITER 61300019
         OI    TUBPARM4,ENDLST          FLAG END OF LIST                61400019
         B     ENQMSG                   ENQ MSG                         61500019
ENQMSG2  ST    REG7,TUBPARM4            FINISH PARM LIST FOR MSG WRITER 61600019
         ST    REG12,TUBPARM5                                           61700019
         OI    TUBPARM5,ENDLST          FLAG END OF PARM LIST           61800019
ENQMSG   ST    TUBR,TUBPARM2                                            61900019
         LA    REG15,TUBUSRID                                           62000019
         ST    REG15,TUBPARM3                                           62100019
         LA    REG1,TUBPARM2            GET ADDRESS OF PARM LIST        62200019
         MVC   TUBIRLSA,TUBRAFBF        SAVE BUFFER ADDRESS             62300019
         L     REG15,IHKYMSG1           GET ADDRESS OF MSG WRITER       62400019
         BALR  REG14,REG15              ENQUEUE MESSAGE                 62500019
         MVC   TUBRAFBF,TUBIRLSA        RESTORE BUFFER ADDRESS          62600019
         OI    TUBAFISW,TUBFCTLN        TURN ON BUFFER CONTROL SW       62700019
         MVI   TUBGBLNM,UFNUM           RESTORE UTILITY FILE NUMBER     62800019
         NI    PPTFLG,PPTRANGF          RESET RANGE MERGE SW     A36814 62850020
         LTR   REG15,REG15              TEST RETURN CODE                62900019
         BNZ   RETURN                   IF BAD, RETURN                  63000019
         BR    REG8                     EXIT                            63100019
         EJECT                                                          63200019
*********************************************************************** 63300019
*                                                                       63400019
*          CONSTANTS                                                    63500019
*                                                                       63600019
*********************************************************************** 63700019
F0       DC    F'0'                     FULL WORK CONST OF 0            63800019
F4       DC    F'4'                     FULL WORK CONST OF 4            63900019
F8       DC    F'8'                     FULL WORK CONST OF 8            64000019
F80      DC    F'80'                    FULL SORD CONST OF 80           64100019
F88      DC    F'88'                    FULL WORK CONST OF 88           64200019
MAXLNO   DC    F'99999999'              MAXIMUM LINE NUMBER             64300019
H1       DC    H'1'                     HALFWORD CONST OF 1             64400019
H10      DC    H'10'                    HALFWORD CONST OF 10            64500019
INOP     DC    X'04'                    INOPERATIVE CODE FOR IHKUTM     64600019
X80      DC    X'80'                    ENQUEUE CODE FOR IHKUTM         64700019
BLANKS   DC    CL8' '                   BLANKS                          64800019
         SPACE 3                                                        64900019
*********************************************************************** 65000019
*          MESSAGE CODES                                                65100019
*********************************************************************** 65200019
         DS    0F                                                       65300019
NODDNMCD DC    X'00F3F7F5'              NO DD NAME                      65400019
INOPRCDU DC    X'00F3F7F0'              LIB INOPER (USER)               65500019
INOPRCDC DC    X'00F2F4F1'              LIB INOPER (CENTRAL)            65600019
NFOUNDCD DC    X'00F3F3F8'              DS NOT FOUND                    65700019
KEYCD    DC    X'00F3F6F9'              KEY UNVALID                     65800019
EDTREQCD DC    X'00F3F9F3'              EDIT OF D.S. REQUIRED           65900019
OUTSPACD DC    X'00F3F5F7'              A.A. OUT OF SPACE               66000019
NOINSCD  DC    X'00F3F4F0'              NO LINES IN RANGE               66100019
UIDNFCD  DC    X'00F3F3F3'              USERID INVALID                  66200019
MAXLNOCD DC    X'00F3F4F8'              MAX LINE NO EXCEEDED            66300019
         EJECT                                                          66400019
*********************************************************************** 66500019
*                                                                       66600019
*          WORK AND SAVE AREAS                                          66700019
*                                                                       66800019
*********************************************************************** 66900019
WSDSECT  DSECT                                                          67000019
SAVA     DS    18F                      SAVE AREA                       67100019
MUFPARMS DS    CL27                     PARAMETER AREA                  67200019
MUFSW    DS    X                        PROCESSING SWITCHES             67300019
MUF1PAS  EQU   X'80'                    1ST PASS                        67400019
MUF1PASF EQU   X'7F'                    OFF                             67500019
BADEND   EQU   X'40'                    BAD END SWITCH           A47408 67550000
MUFOFF   EQU   X'00'                    ALL SWITCHES OFF                67600019
GMLEN    EQU   X'64'                    LENGTH OF GETMAIN AREA          67700019
         EJECT                                                          67800019
*********************************************************************** 67900019
*                                                                       68000019
*          PARAMETERS FROM IHKMGE                                       68100019
*                                                                       68200019
*********************************************************************** 68300019
PARMDSCT DSECT                                                          68400019
STARTLNE DS    CL8                      STARTING LINE NO                68500019
ENDLNE   DS    CL8                      END LINE NO                     68600019
AFTERLNE DS    CL8                      AFTER LINE NO                   68700019
KEY      DS    CL3                      DATA SET KEY                    68800019
         EJECT                                                          68900019
*********************************************************************** 69000019
*                                                                       69100019
*          DSECTS FOR CRJE CONTROL BLOCKS                               69200019
*                                                                       69300019
*********************************************************************** 69400019
         IHKCDSCT TUB=YES,PPT=YES,AVT=YES,DIR=YES                       69500019
         TUBEQU                                                         69600019
         RAFKNBX TYPE=DSECT                                             69700019
         END                                                            69800019
