NUM      TITLE 'NUMERIC VERIFICATION MODULE'                            01000019
*********************************************************************** 01020019
*STATUS: CHANGE LEVEL 0                                               * 01040019
*                                                                     * 01060019
*FUNCTION:                                                            * 01080019
*   THIS ROUTINE VEFIFIES A FIELD OF CHARACTERS AS NUMERICS AND       * 01100019
*   OPTIONALLY MOVES THE FIELD INTO AN AREA, RIGHT JUSTIFIED. IF      * 01120019
*   THE FIELD CONTAINS MORE THAN EIGHT CHARACTERS OR IF ANY OF THE    * 01140019
*   CHARACTERS ARE NOT NUMERIC, THEN A RETURN CODE OF FOUR IS         * 01160019
*   RETURNED TO THE CALLER. IF A THIRD PARAMETER IS GIVEN, THEN THE   * 01180019
*   FIELD OF NUMERICS IS MOVED TO THE AREA ADDRESSED BY THE PARAMETER.* 01200019
*                                                                     * 01220019
*ENTRY POINTS:                                                        * 01240019
*   IHKNUM IS THE ONLY ENTRY POINT. CALLING SEQUENCE IS AS FOLLOWS:   * 01260019
*   LA   1,PARAMETER LIST                                             * 01280019
*   L    15,IHKYYNUM                                                  * 01300019
*   BALR 14,15                                                        * 01320019
*                                                                     * 01340019
*INPUT:                                                               * 01360019
*   INPUT IS THE FOLLOWING PARAMETER LIST ADDRESSED BY REGISTER 1:    * 01380019
*   (1) ADDRESS OF ONE-BYTE LENGTH FIELD                              * 01400019
*   (2) ADDRESS OF ONE-TO-EIGHT BYTE DATA FIELD                       * 01420019
*   (3) ADDRESS OF AREA TO WHICH DATA IS TO BE MOVED                  * 01440019
*   (THE THIRD PARAMETER IS OPTIONAL. THE LAST PARAMETER IS DETECTED  * 01460019
*   WHEN THE HIGH-ORDER BIT OF THE PARAMETER IS SET).                 * 01480019
*                                                                     * 01500019
*OUTPUT: N/A                                                          * 01520019
*                                                                     * 01540019
*EXTERNAL REFERENCES: N/A                                             * 01560019
*                                                                     * 01580019
*EXITS,NORMAL:                                                        * 01600019
*    RETURN BY REGISTER 14 TO THE CALLING ROUTINE WITH A ZERO IN      * 01620019
*   REGISTER 15.                                                      * 01640019
*                                                                     * 01660019
*EXITS,ERROR:                                                         * 01680019
*   RETURN BY REGISTER 14 TO CALLING ROUTINE WITH A FOUR IN           * 01700019
*   REGISTER 15 IF DATA FIELD MORE THAN EIGHT CHARACTERS LONG OR      * 01720019
*   IF ANY CHARACTER IS NOT A NUMERIC.                                * 01740019
*                                                                     * 01760019
*TABLES / WORK AREAS: N/A                                             * 01780019
*                                                                     * 01800019
*ATTRIBUTES:                                                          * 01820019
*   REENTRANT AND RESIDENT                                            * 01840019
*                                                                     * 01860019
*********************************************************************** 01880019
         EJECT                                                          01900019
IHKNUM   CSECT                                                          02000019
         SPACE 1                                                        03000019
PARMREG  EQU   1                        POINTER TO PARM LIST            04000019
LENGTH   EQU   3                        LENGTH OF DATA                  05000019
MAIN     EQU   4                        POINTER TO LENGTH               06000019
DATA     EQU   5                        POINTER TO DATA                 07000019
AREA     EQU   6                        POINTER TO AREA FOR MOVE        08000019
POINT    EQU   7                        INCREMENT POINTER FOR DATA      09000019
COMP     EQU   10                       COMPARE REGISTER                10000019
BASEREG  EQU   11                       BASE REGISTER                   11000019
REG13    EQU   13                       POINTER TO CALLER'S SAVE AREA   12000019
REG14    EQU   14                                                       13000019
RETREG   EQU   15                                                       14000019
         SPACE 1                                                        15000019
ZERO     EQU   0                                                        16000019
ONE      EQU   1                                                        17000019
FOUR     EQU   4                                                        18000019
SEVEN    EQU   7                                                        19000019
EIGHT    EQU   8                                                        20000019
TWELVE   EQU   12                                                       21000019
TWENTY   EQU   20                                                       22000019
         SPACE 1                                                        23000019
F0       EQU   X'F0'                                                    24000019
F9       EQU   X'F9'                                                    25000019
X80      EQU   X'80'                                                    26000019
         SPACE 2                                                        27000019
         SAVE  (14,12),,*                                               28000019
         LR    BASEREG,RETREG           SET BASE REGISTER               29000019
         USING IHKNUM,BASEREG                                           30000019
         LM    MAIN,DATA,ZERO(PARMREG)  SET POINTERS TO DATA LENGTH     31000019
*                                            AND TO DATA                32000019
         SPACE 1                                                        33000019
         SR    LENGTH,LENGTH                                            34000019
         IC    LENGTH,ZERO(MAIN)        PICK UP LENGTH BYTE             35000019
         LTR   LENGTH,LENGTH            IS LENGTH > 0 ?                 36000019
         BNP   RET4                     IF NOT, SET RETURN TO 4         37000019
         LA    COMP,EIGHT                                               38000019
         CLR   LENGTH,COMP              IS LENGTH > 8 ?                 39000019
         BH    RET4                     IF YES, SET RETURN CODE TO 4    40000019
         SPACE 1                                                        41000019
         LR    COMP,LENGTH              SAVE LENGTH                     42000019
         LR    POINT,DATA               POINT TO 1ST BYTE OF DATA       43000019
         EJECT                                                          44000019
*        TEST CHARACTER FOR EBCDIC NUMERIC                              45000019
         SPACE 1                                                        46000019
TEST     DS    0H                                                       47000019
         TM    ZERO(POINT),F0           IS CHARACTER > OR = F0 ?        48000019
         BNO   RET4                     IF NOT, SET RETURN CODE TO 4    49000019
         SPACE 1                                                        50000019
         CLI   ZERO(POINT),F9           IS CHARACTER < OR = F9 ?        51000019
         BH    RET4                     IF NOT, SET RETURN CODE TO 4    52000019
         SPACE 1                                                        53000019
         LA    POINT,ONE(POINT)         POINT TO NEXT CHARACTER         54000019
         BCT   COMP,TEST                IF ANOTHER CHARACTER, TEST IT   55000019
         TM    FOUR(PARMREG),X80        IS THERE A THIRD OPERAND ?      56000019
         BO    RET0                     IF NOT, RETURN                  57000019
         SPACE 1                                                        58000019
         L     AREA,EIGHT(PARMREG)      POINT TO FIELD TO CONTAIN DATA  59000019
         SPACE 1                                                        60000019
*        PUT F0 INTO 8-BYTE FIELD                                       61000019
         MVI   ZERO(AREA),F0                                            62000019
         MVC   ONE(SEVEN,AREA),ZERO(AREA)                               63000019
         LA    AREA,EIGHT(AREA)         POINT TO END OF FIELD           64000019
         SR    AREA,LENGTH              POINT TO END OF FIELD MINUS     65000019
*                                            LENGTH OF DATA             66000019
         BCTR  LENGTH,ZERO              DECREMENT LENGTH FOR EX         67000019
         EX    LENGTH,MOVE                                              68000019
         SPACE 1                                                        69000019
RET0     DS    0H                                                       70000019
         SR    RETREG,RETREG            RETURN CODE 0                   71000019
         B     RETURN                   RETURN TO CALLER                72000019
         SPACE 1                                                        73000019
*        MOVE DATA INTO RIGHTMOST BYTES OF FIELD                        74000019
MOVE     MVC   ZERO(ZERO,AREA),ZERO(DATA)                               75000019
         SPACE 2                                                        76000019
RET4     DS    0H                                                       77000019
         LA    RETREG,FOUR              RETURN CODE 4                   78000019
         SPACE 1                                                        79000019
RETURN   DS    0H                                                       80000019
         L     REG14,TWELVE(REG13)                                      81000019
         LM    ZERO,TWELVE,TWENTY(REG13)                                82000019
         BR    REG14                                                    83000019
         END                                                            84000019
