OPN      TITLE 'IHKOPN - OPEN MODULE FOR OS DATA SETS'                  00100019
IHKOPN   CSECT                                                          00130020
*C109000,282000                                                  A34596 00160020
* C 355000                                                       A45647 00180026
* C172000,C175000                                               A60628  00185017
* A196000                                                       A60635  00190017
* C168000,D169000,D170000                                       A60644  00195017
*********************************************************************** 00200019
*STATUS                                                               * 00300019
*   CHANGE LEVEL 0                                                    * 00400019
*FUNCTION                                                             * 00500019
*   THIS MODULE IS ATTACHED BY IHKEOS TO OPEN OR SCRATCH AN OS DATA   * 00600019
*   SET. IF THE REQUEST IS TO OPEN A DATA SET, A LOCATE MACRO IS      * 00700019
*   ISSUED TO LOCATE THE DATA SET IN SYSCATLG AND AN OBTAIN MACRO IS  * 00800019
*   ISSUED TO GET THE DSCB.  THE JFCB IS THEN READ AND THE DATA SET   * 00900019
*   NAME INSERTED.  A DCB IS SET UP AND AN OPEN TYPE=J IS ISSUED.     * 01000019
*   IF THE OPEN REQUEST IS FOR A MEMBER OF A PDS, A FIND MACRO IS     * 01100019
*   ISSUED TO OBTAIN THE MEMBER.  THE ECB BY WHICH IHKOPN RECEIVED    * 01200019
*   CONTROL IS THEN POSTED WITH THE RETURN CODE AND A WAIT ISSUED ON  * 01300019
*   AN ECB TO BE POSTED BY IHKEOS.  WHEN THE WAIT IS COMPLETE, IHKOPN * 01400019
*   CLOSES THE DATA SET AND RETURNS TO THE CALLER                     * 01500019
*   IF THE REQUEST IS TO SCRATCH A DATA SET, THE CATALOG IS CHECKED.  * 01600019
*   IF THE DATA SET IS CATALOGED, A CHECK IS MADE TO FIND IF A        * 01700019
*   COMPLETE DATA SET IS TO BE SCRATCHED.  IF IT IS, AND IT RESIDES   * 01800019
*   ON 20 VOLUMES OR LESS, A CHECK IS MADE TO FIND IF ALL VOLUMES ARE * 01900019
*   MOUNTED.  IF ALL VOLUMES ARE MOUNTED, A SCRATCH MACRO IS ISSUED   * 02000019
*   TO DELETE THE DATA SET.  IF A MEMBER OF A PDS IS TO BE DELETED,   * 02100019
*   THE DATA SET IS OPENED, AND A STOW DELETE MACRO IS ISSUED TO      * 02200019
*   DELETE THE DATA SET.  CONTROL IS THEN RETURNED AS DESCRIBED IN    * 02300019
*   THE PREVIOUS PARAGRAPH.                                           * 02400019
*ENTRY POINT                                                          * 02500019
*        IHKOPN TO OPEN OR DELETE AN OS DATA SET                      * 02600019
*INPUT                                                                * 02700019
*   REGISTER 1 MUST POINT TO A FIVE WORD PARAMETER LIST CONTAINING    * 02800019
*   THE FOLLOWING ADDRESSES                                           * 02900019
*   TUB                                                               * 03000019
*   AVT                                                               * 03100019
*   1,376 BYTE WORK AREA                                              * 03200019
*   END OF DATA ROUTINE IN IHKEOS                                     * 03300019
*   I/O ERROR SUBROUTINE IN IHKEOS                                    * 03400019
*OUTPUT                                                               * 03500019
*   N/A                                                               * 03600019
*EXTERNAL REFFERENCES                                                 * 03700019
*        NONE                                                         * 03800019
*EXITS, NORMAL                                                        * 03900019
*   RETURN TO CALLER                                                  * 04000019
*EXITS, ERROR                                                         * 04100019
*   N/A                                                               * 04200019
*TABLES/WORK AREAS                                                    * 04300019
*   TUB                                                               * 04400019
*   TUBIRLSA - SAVE AREA FOR CALLER'S REGISTER 13                     * 04500019
*   TUBPRMLS - WORK AREA                                              * 04600019
*   TUBUFFAD - CONTAINS USER BUFFER ADDRESS                           * 04700019
*   DCB                                                               * 04800019
*   DSCB                                                              * 04900019
*   JFCB                                                              * 05000019
*   USER BUFFER                                                       * 05100019
*ATTRIBUTES                                                           * 05200019
*   REENTRANT AND NONRESIDENT                                         * 05300019
*********************************************************************** 05400019
         EJECT                                                          05500019
*********************************************************************** 05700019
*           EQUATES                                                     05800019
*********************************************************************** 05900019
NUMZONE  EQU   X'0F'                    PACKED DECIMAL SIGN             06000019
UILEN    EQU   14                       USER DATA LENGTH                06100019
MAXVOL   EQU   20                       MAX VOLUMES FOR DELETE          06200019
ENDLST   EQU   X'80'                    END OF PARAMETER LIST           06300019
F120     EQU   120                      EQUATE OF 120                   06400019
INSBFL   EQU   888                      INSERT BUFFER LENGTH            06500019
NUMSIGN  EQU   X'F0'                    NUMERIC ZONE                    06600019
BLK      EQU   C' '                     BALNK FOR CLEARING FIELDS       06700019
X04      EQU   X'04'                    HES 04                          06800019
X0F      EQU   X'0F'                    HEX 0F                          06900019
X00      EQU   X'00'                    HEX 00                          07000019
ALLBITS  EQU   X'FF'                    FOR TESTING SCAN ERROR BYTE     07100019
OPEN     EQU   X'10'                    OPEN GOOD                       07200019
EXJFCB   EQU   X'87'                    DCB EXLST INDICATOR             07300019
BUFCTRL  EQU   X'80'                    BUFFER CONTROL USED             07400019
BUFCTRLF EQU   X'7F'                    OFF                             07500019
RECLNGTH EQU   88                       IHKAFI RECORD LENGTH            07600019
         SPACE 3                                                        07700019
*********************************************************************** 07800019
*           REGISTER EQUATES                                            07900019
*********************************************************************** 08000019
         SPACE 1                                                        08100019
REG0     EQU   0                                                        08200019
REG1     EQU   1                                                        08300019
RTUB     EQU   2                                                        08400019
RDSCT    EQU   3                                                        08500019
REG4     EQU   4                                                        08600019
REG5     EQU   5                                                        08700019
REG6     EQU   6                                                        08800019
REG7     EQU   7                                                        08900019
REG8     EQU   8                                                        09000019
RDCB     EQU   9                                                        09100019
REG10    EQU   10                                                       09200019
RBASE    EQU   11                                                       09300019
RAVT     EQU   12                                                       09400019
REG13    EQU   13                                                       09500019
REG14    EQU   14                                                       09600019
REG15    EQU   15                                                       09700019
         EJECT                                                          09800019
*********************************************************************** 09900019
*           INITILIZATION                                               10000019
*********************************************************************** 10100019
         SPACE 1                                                        10200019
         USING IHKOPN,RBASE                                             10300019
         USING OSDSECT,RDSCT                                            10400019
         USING TUBDSECT,RTUB                                            10500019
         USING AVTDSECT,RAVT                                            10600019
         USING IHADCB,RDCB                                              10700019
*                                                                       10800019
         SAVE  (14,12),,OPN73051                                A60644  10900017
         LR    RBASE,REG15              SET UP BASE REGISTER            11000019
         L     RTUB,0(REG1)             SET UP TUB BASE                 11100019
         L     RAVT,4(REG1)             SET UP AVT BASE                 11200019
         L     RDSCT,8(REG1)            SET UP DSECT BASE               11300019
         ST    REG13,TUBIRLSA           SAVE REG 13                     11400019
         LA    RDCB,ADDRDCB             SET UP DCB BASE                 11500019
         EJECT                                                          11600019
*********************************************************************** 11700019
*   PROCESS OS DATASETS FOR EDIT AND DEELETE                            11800019
*********************************************************************** 11900019
         SPACE 1                                                        12000019
PROCOS   NI    PPTFLG,PPTNOERR          TURN OFF ERROR FLAG             12100019
         LA    REG1,VOLLIST             SET UP FOR LOCATE MACRO         12200019
         LA    REG15,LOCOD                                              12300019
         BAL   REG14,SETUPCAM                                           12400019
         LOCATE CAMLIST                 FIND DATA SET IN SYSCATLG       12500019
         LTR   REG15,REG15              TEST FOR 0 RETURN CODE          12600019
         BZ    CKNUMVOL                 IF YES, CONTINUE                12700019
         C     REG15,F24                TEST FOR 24 RETURN CODE         12800019
         BE    OSIOERR                  IF IT IS, RETURN W/CODE         12900019
         BL    OSNFND                   IF LOWER, RETURN W/CODE         13000019
CKNUMVOL LA    REG1,LOCVOL              GET ADDRESS OF CURRENT VOLSER   13100019
         ST    REG1,CURRVOL             SAVE IT                         13200019
         LA    REG4,1                   SET NUMBER OF VOLUMES TO 1      13300019
         LH    REG1,NUMVOL                                              13400019
         TM    PPTFLG,PPTDEL            TEST FOR DELETE                 13500019
         BZ    CKNUM                    IF NOT, CONTINUE                13600019
         TM    PPTFLG,PPTMEMB           TEST FOR DELETE MEMBER          13700019
         BO    CKNUM                    IF YES, CONTINUE                13800019
         LA    REG4,MAXVOL              LOAD MAX VOLUMES FOR DELETE     13900019
CKNUM    CH    REG4,NUMVOL              TEST FOR OVER MAX VOLUMES       14000019
         BL    MULTVOL                  IF YES, RETURN W/CODE           14100019
NXTVOL   STH   REG1,CURRNUM             SET UP FOR OBTAIN               14200019
         LA    REG1,DSCBWORK                                            14300019
         LA    REG15,OBTCOD                                             14400019
         BAL   REG14,SETUPCAM                                           14500019
         L     REG1,CURRVOL                                             14600019
         ST    REG1,CAMPARM3                                            14700019
         OBTAIN CAMLIST                 READ DSCB                       14800019
         B     *+4(REG15)               TEST RETURN CODE                14900019
         B     NXTOBTN                  SUCCESSFUL                      15000019
         B     NOTMOUNT                   VOLUME NOT MOUNTED            15100019
         B     OSNFND                     DSCB NOT FOUND                15200019
         B     OSIOERR                    DISK ERROR                    15300019
         B     OSNFND                   NOT USED                        15400019
         B     OSNFND                   NOT USED                        15500019
         SPACE 3                                                        15600019
*********************************************************************** 15700019
*   SUCCESSFUL OBTAIN COMES HERE,                                       15800019
*        ALSO DELETE MEMBER TO LOOK FOR MEMBER IN NEXT DSCB             15900019
*********************************************************************** 16000019
         SPACE 1                                                        16100019
NXTOBTN  TM    PPTFLG,PPTDEL            TEST FOR DELETE                 16200019
         BZ    OBGOOD                   IF NOT, OPEN DATA SET           16300019
         CLC   DS1EXPDT,NODATE          TEST FOR EXPIRATION DATE        16400019
         BE    SCNP                     IF NONE, SCRATCH DATA SET       16500019
         TIME  ,                        GET CURRENT DATE                16600019
         ST    REG1,TUBPARM1            SAVE DATE                       16700019
         MVO   TUBPARM2(8),TUBPARM1+1(1) MOVE YEAR TO CVB AREA  A60644  16800017
         OI    TUBPARM3+3,NUMZONE       SET UP NUMERIC ZONE             17100019
         CVB   REG15,TUBPARM2          CONVERT YEAR TO BINARY   A60628  17200017
         ST    REG15,TUBPARM4           SAVE YEAR                       17300019
         MVC   TUBPARM3+2(2),TUBPARM1+2  CONVERT DAY TO BINARY          17400019
         CVB   REG15,TUBPARM2                                   A60628  17500017
         ST    REG15,TUBPARM5           SAVE DAY                        17600019
         MVC   TUBPARM5+1(1),TUBPARM4+3  CONSTRUCT DATE                 17700019
         CLC   DS1EXPDT,TUBPARM5+1      TEST FOR EXPIRATION DATE REACH  17800019
         BH    EXPDATE                  IF NOT, ENQUEUE ERROR MESSAGE   17900019
SCNP     TM    PPTFLG,PPTMEMB           TEST FOR DELETE MEMBER          18000019
         BO    OBGOOD                   IF YES, OPEN DATA SET           18100019
         LH    REG1,CURRNUM             GET NEXT VOLUME IN VOLIST       18200019
         L     REG15,CURRVOL                                            18300019
         LA    REG15,12(REG15)                                          18400019
         ST    REG15,CURRVOL            IF DELETE DATA SET OR MEMBER    18500019
         BCT   REG1,NXTVOL              DSCB NOT FOUND, GO BACK FOR     18600019
*                                       NEXT OBTAIN                     18700019
         SPACE 3                                                        18800019
*********************************************************************** 18900019
*   ALL VOL MOUNTED- SCRATCH DATA SET                                   19000019
*********************************************************************** 19100019
         SPACE 1                                                        19200019
         LA    REG1,VOLLIST             SET UP FOR SCRATCH              19300019
         LA    REG15,SCRCOD                                             19400019
         BAL   REG14,SETUPCAM                                           19500019
         MVI   CAMFLG3,NOPRCOD                                          19600019
         SR    0,0                                              A60635  19650017
         SCRATCH CAMLIST                SCRATCH DATA SET                19700019
         B     RTN(REG15)               TEST RETURN CODE                19800019
RTN      B     CKNODEL                  SUCCESSFUL                      19900019
         B     NOTMOUNT                 VOLUME NOT MOUNTED              20000019
         SPACE 3                                                        20100019
*********************************************************************** 20200019
*  SCRATCH FINISHED- CHECK VOL LIST FOR UNUSUAL CONDITION(S)            20300019
*********************************************************************** 20400019
         SPACE 1                                                        20500019
CKNODEL  LH    REG6,NUMVOL              GET NUMBER OF VOLUMES           20600019
         NI    PPTFLG,PPTNOERR          TURN OFF ERROR FLAG             20700019
         LA    REG5,SCRERR              GET ERROR BYTE                  20800019
CKNXTVOL TM    SCRERR,ALLBITS           TEST RESULTS OF SCRATCH         20900019
         BZ    NXTVOLL                  IF YES, CHECK NEXT VOLUME       21000019
         OI    PPTFLG,PPTERR            SET ERROR FLAG                  21100019
         TM    SCRERR,SNOMNT            TEST FOR VOLUME NOT MOUNTED     21200019
         BO    NOTMOUNT                 IF NOT, RETURN W/CODE           21300019
         TM    SCRERR,SNODEVIC          TEST FOR NO DEVICE FOR MOUNTING 21400019
         BO    NOTMOUNT                 IF NONE, RETURNW/CODE           21500019
         TM    SCRERR,SIOERR            TEST FOR I/O ERROR              21600019
         BO    OSIOERR                  IF YES, RETURN W/CODE           21700019
         TM    SCRERR,SNOEXPIR          TEST FOR EXPIRATION DATE NOT    21800019
*                                       REACHED                         21900019
         BO    EXPDATE                  IF IT HASNT, RETURN W/CODE      22000019
         TM    SCRERR,SNODSCB           TEST FOR NO DSCB                22100019
         BO    OSNFND                   IF NONE,RETRUN W/CODE           22200019
NXTVOLL  LA    REG5,L'VOLID(REG5)       GET NEXT ENTRY                  22300019
         BCT   REG6,CKNXTVOL            GET NEXT VOLID                  22400019
*                                                                       22500019
         TM    PPTFLG,PPTERR            TEST FOR ERROR                  22600019
         BZ    UNCATL                   IF NOT, UNCATALOG DATA SET      22700019
         B     RETCD0                   RETURN                          22800019
         SPACE 3                                                        22900019
*********************************************************************** 23000019
*  ALL SCRATCHED- REMOVE FROM CATALOG                                   23100019
*********************************************************************** 23200019
         SPACE 1                                                        23300019
UNCATL   SR    REG1,REG1                SET UP FOR CATALOG MACRO        23400019
         LA    REG15,UNCCOD                                             23500019
         BAL   REG14,SETUPCAM                                           23600019
         CATALOG CAMLIST                UNCATALOG DATA SET              23700019
         LTR   REG15,REG15              TEST FOR 0 RETURN CODE          23800019
         BZ    RETCD0                   IF YES, RETURN                  23900019
         CH    REG15,H8                 TEST FOR 8 RETURN CODE          24000019
         BNH   OSNFND                   IF 4 OR 8, ENQ NOT FND MSG      24100019
         C     REG15,F24                TEST FOR 24 RETURN CODE         24200019
         BH    OSIOERR                  IF 28, ENQUEUE MESSAGE          24300019
         B     RETCD0                   IF OTHER, RETURN                24400019
         SPACE 3                                                        24500019
*********************************************************************** 24600019
*           PREPARE TO OPEN DATA SET                                    24700019
*********************************************************************** 24800019
         SPACE 1                                                        24900019
OBGOOD   TM    DS1DSORG,DS1PS           TEST FOR PS ORGNIZATION         25000019
         BZ    TSTPDS                   IF NOT, TEST FOR PO             25100019
         TM    PPTFLG,PPTDEL            TEST FOR DELETE                 25200019
         BO    ORGERR                   IF YES, RETURN W/CODE           25300019
         B     ORGOK                    CONTINUE                        25400019
TSTPDS   TM    DS1DSORG,DS1PO           TEST FOR PARTIONED ORGANIZATION 25500019
         BZ    ORGERR                   IF NOT ENQUEUE ERR MSG          25600019
         TM    PPTFLG,PPTMEMB           TEST FPR MEMBER SPECIFIED       25700019
         BZ    POERR                    IF NOT, RETURN W/CODE           25800019
ORGOK    LH    REG5,DS1BLKL                                             25900019
         LTR   REG5,REG5                TEST FOR BLOKSIZE PRESENT       26000019
         BE    ORGERR                   IF NOT, REUTRN W/CODE           26100019
         LH    REG5,DS1LRECL                                            26200019
         LTR   REG5,REG5                TEST FOR LRECL PRESENT          26300019
         BNZ   GETDCBCR                 IF YES, CONTINUE                26400019
         MVC   DS1LRECL,DS1BLKL         ASSUME UNBLOCKED RECORDD IF NOT 26500019
GETDCBCR L     REG10,IHKYYKBX           SET UP ADDRESSABILITY FOR       26600019
         USING RAFKNBX,REG10              KONBOX                        26700019
         TM    DS1DSORG,DS1PS           TEST FOR PS ORGNIZATION         26800019
         BZ    NOTPS                    IF NOT BRING IN PO DCB          26900019
         MVC   IHADCB(DCBDLEN),PSDCBCS  BRING IN PS DCB                 27000019
         B     DCBPR1                   CONTINUE                        27100019
NOTPS    MVC   IHADCB(DCBDLEN),PODCBCS  BRING IN PO DCB                 27200019
DCBPR1   MVC   DCBDDNAM(2),DDNAME       PUT DD NAME IN DCB              27300019
         L     REG15,CURRVOL                                            27400019
         MVC   DCBDDNAM+2(6),0(REG15)                                   27500019
         MVC   DCBBLKSI,DS1BLKL         PUT BLOCK SIZE IN DCB           27600019
         MVC   DCBLRECL,DS1LRECL        PUT LOGICAL RECORD LENGTH IN    27700019
*                                         DCB                           27800019
         L     REG15,TUBUFFAD           GET BUFFER ADDRESS              27900019
         L     REG7,72(REG15)           GET EOD ROUTINE ADDRESS         28000019
         ST    REG7,DCBEODAD                                            28100019
         L     REG7,76(REG15)           GET SYNAD ROUTINE ADDR   A34596 28200020
         ST    REG7,DCBSYNAD                                            28300019
         LA    REG7,JFCB                                                28400019
         ST    REG7,TUBPARM5                                            28500019
         MVI   TUBPARM5,EXJFCB                                          28600019
         LA    REG7,TUBPARM5                                            28700019
         ST    REG7,DCBEXLST                                            28800019
         RDJFCB ((RDCB))                READ JFCB                       28900019
ZEROJFCB XC    JFCB+52(34),JFCB+52      ZERO JFCB FIELDS FOR DSCB MERGE 29000019
         XC    JFCB+88(29),JFCB+88                                      29100019
         XC    JFCB+148(26),JFCB+148                                    29200019
         MVI   JFCB+175,X00                                             29300019
         MVC   JFCBDSN,OSDSNAM          PUT DSNAME IN JFCB              29400019
         MVC   JFCBDSN+44(8),BLANKS     BLANK OUT MEMBER NAME IN JFCB   29500019
         SPACE 3                                                        29600019
*********************************************************************** 29700019
*           OPEN DATA SET                                               29800019
*********************************************************************** 29900019
         SPACE 1                                                        30000019
         TM    PPTFLG,PPTDEL                                            30100019
         BO    OPENDEL            GO OPEN DATA SET FOR DELETE           30200019
         OPEN  ((RDCB)),TYPE=J          OPEN DATA SET                   30300019
OPNRTN   TM    DCBOFLGS,OPEN            TEST FOR OPEN SUCCESSFUL        30400019
         BZ    OPNERR                   IF NOT ENQ ERR MSG              30500019
         OI    EDTSW,EDTOPN                                             30600019
         TM    DS1DSORG,DS1PO           TEST FOR PARTIONED ORGNIZATION  30700019
         BZ    NOFIND                                                   30800019
         FIND  (RDCB),OSMEMBER,D        FIND MEMBER                     30900019
         B     *+4(REG15)               TEST RETURN CODE                31000019
         B     NOFIND                   CONTINUE IF GOOD                31100019
         B     MEMBNFND                 MEMBER NOT FOUND                31200019
         B     OSIOERR                  ENQ ERR MSG IF DISK ERROR       31300019
         SPACE 3                                                        31400019
*********************************************************************** 31500019
*   OPEN DATA SET FOR DELETE MEMBER                                     31600019
*********************************************************************** 31700019
         SPACE 1                                                        31800019
OPENDEL  OPEN  ((RDCB),(OUTPUT)),TYPE=J OPEN DATA SET FOR DELETE        31900019
         B     OPNRTN                   TEST OPEN                       32000019
         SPACE 3                                                        32100019
*********************************************************************** 32200019
*   SUCCESSFUL FIND FOR DELETE MEMER - FOR EDIT- CALL EOS               32300019
*********************************************************************** 32400019
         SPACE 1                                                        32500019
NOFIND   TM    PPTFLG,PPTDEL            TEST FOR DELETE                 32600019
         BZ    RETGOOD                  IF NOT, RETURN                  32700019
         STOW  (RDCB),OSMEMBER,D        DELETE MEMBER                   32800019
         B     RTNB(REG15)              TEST RETURN                     32900019
RTNB     B     RETCD0                   SUCCESSFUL                      33000019
         B     RETCD0                   NOT USED                        33100019
         B     MEMBNFND                 NOT FOUND                       33200019
         B     RETCD0                   NOT USED                        33300019
         B     OSIOERR                  I/O ERROR                       33400019
         SPACE 3                                                        33500019
*********************************************************************** 33600019
*           SUBROUTINE TO SET UP CAMLSTS                                33700019
*********************************************************************** 33800019
         SPACE 1                                                        33900019
SETUPCAM ST    REG1,CAMPARM4            SET UP CAMLST                   34000019
         SR    REG1,REG1                                                34100019
         ST    REG1,CAMPARM3                                            34200019
         ST    REG1,CAMLIST                                             34300019
         STC   REG15,CAMFLG1                                            34400019
         LA    REG15,OSDSNAM                                            34500019
         ST    REG15,CAMNAM                                             34600019
         BR    REG14                    EXIT                            34700019
         SPACE 3                                                        34800019
*********************************************************************** 34900019
*           GETMAIN SUBROUTINE                                          35000019
*********************************************************************** 35100019
         SPACE 1                                                        35200019
SUBRGETM LA    REG4,TUBPARM4            GET ADDRESS AREA                35300019
         ST    REG14,TUBPARM3           SAVE ERROR EXIT ADDRESS         35400019
         L     REG1,IHKYYGMS           GET LIST ADDRESS          A45647 35500026
         GETMAIN EC,LV=(REG5),A=(REG4),MF=(E,(1)) GET AREA              35600019
         LTR   REG15,REG15              TEST RETURN CODE                35700019
         BZ    GETMRTN                  IF GOOD, EXIT                   35800019
         L     REG14,TUBPARM3           IF BAD, EXIT TO                 35900019
         BR    REG14                    ERROR ROUTINE                   36000019
GETMRTN  BR    REG6                     EXIT                            36100019
         EJECT                                                          36200019
*********************************************************************** 36300019
*                                                                       36400019
*          SET UP RETURN CODES FOR IHKEOS                               36500019
*                                                                       36600019
*********************************************************************** 36700019
OSIOERR  LA    REG15,IOERCD             GET DISK ERROR RETURN CODE      36800019
         B     RETURN                   RETURN                          36900019
*                                                                       37000019
*          DATA SET ON MULTIPLE VOLUMES (EDIT)                          37100019
*                                                                       37200019
MULTVOL  LA    REG15,MULTCD             GET MULT VOLUME RETURN CODE     37300019
         B     RETURN                   RETURN                          37400019
*                                                                       37500019
*          VOLUME NOT MOUNTED                                           37600019
*                                                                       37700019
NOTMOUNT LA    REG15,MOUNTCD            GET NOT MOUNTED CODE            37800019
         B     RETURN                   RETURN                          37900019
*                                                                       38000019
*          EXPIRATION DATE NOT REACHED                                  38100019
*                                                                       38200019
EXPDATE  LA    REG15,EXPCD              GET EXPIRATION DATE CODE        38300019
         B     RETURN                   RETURN                          38400019
*                                                                       38500019
*          RETURN TO IHKCMD                                             38600019
*                                                                       38700019
RETCD0   LA    REG15,RETCD              GET RETURN CODE                 38800019
         B     RETURN                   RETURN                          38900019
*                                                                       39000019
*          DATA SET ORGNIZATION INVALID                                 39100019
*                                                                       39200019
ORGERR   LA    REG15,ORGCD              GET ORGNIZATION INVALID CODE    39300019
         B     RETURN                   RETURN                          39400019
*                                                                       39500019
*          NO MEMBER NAME FOR PARTIONED DATA SET                        39600019
*                                                                       39700019
POERR    LA    REG15,POCD               GET NO MEMBER NAME CODE         39800019
         B     RETURN                   RETURN                          39900019
*                                                                       40000019
*        OPEN UNCESSFUL                                                 40100019
*                                                                       40200019
OPNERR   LA    REG15,OPNCD              GET OPEN FAILED CODE            40300019
         B     RETURN                   RETURN                          40400019
*                                                                       40500019
*          DATA SET NOT FOUND                                           40600019
*                                                                       40700019
OSNFND   LA    REG15,NOTFNDCD           GET DATA SET NOT FOUND CODE     40800019
         B     RETURN                   RETURN                          40900019
*                                                                       41000019
*          MEMBER NOT FOUND                                             41100019
*                                                                       41200019
MEMBNFND LA    REG15,MEMBCD             GET MEMBER NOT FOUND CODE       41300019
         B     RETURN                   RETURN                          41400019
*                                                                       41500019
*          GOOD RETURN                                                  41600019
*                                                                       41700019
RETGOOD  LA    REG15,GOODCD             GET GOOD RETURN CODE            41800019
         EJECT                                                          41900019
*********************************************************************** 42000019
*           RETURN ROUTINE                                              42100019
*********************************************************************** 42200019
         SPACE 1                                                        42300019
RETURN   LR    REG0,REG15               GET RETURN CODE                 42400019
         L     REG5,TUBUFFAD                                            42500019
         LA    REG5,100(REG5)           GET ECB ADDRESS                 42600019
         LR    REG1,REG5                SET UP FOR POST                 42700019
         MVI   4(REG5),CLRPOST          CLEAR POST BIT                  42800019
         SVC   2                        POST IHKEOS ECB                 42900019
         LA    REG5,4(REG5)             GET ECB ADDRESS                 43000019
         WAIT  ECB=(REG5)               WAIT ON IHKEOS                  43100019
         TM    EDTSW,EDTOPN             TEST FOR DATA SET OPEN          43200019
         BZ    RETURN3                  IF NOT, SKIP CLOSE              43300019
         CLOSE ((RDCB))                 CLOSE DATA SET                  43400019
RETURN3  L     REG13,TUBIRLSA           GET CALLER'S SAVE AREA ADDRESS  43500019
         RETURN (14,12),T,RC=(15)       RETURN                          43600019
         EJECT                                                          43700019
*********************************************************************** 43800019
*                                                                       43900019
*           CONSTANTS                                                   44000019
*                                                                       44100019
*********************************************************************** 44200019
F4     DC    F'4'                       FULLWORD CONSTANT OF 4          44300019
F24      DC    F'24'                    FULLWORD CONSTANT OF 24         44400019
F80      DC    F'80'                    FULLWORD CONSTANT OF 80         44500019
H8       DC    H'8'                     HALFWORD CONSTANT OF 8          44600019
NODATE   DC    XL3'00'                  NO DATE PROTECTION              44700019
BLANKS   DC    CL8' '                   BLANKS FOR CLEARING FIELDS      44800019
DDNAME   DC    C'CR'                    1ST 2 CHARACTERS OF THE DDNAME  44900019
         SPACE 3                                                        45000019
*********************************************************************** 45100019
*          RETURN CODES                                                 45200019
*********************************************************************** 45300019
GOODCD   EQU   0                        GOOD RETURN                     45400019
IOERCD   EQU   8                        I/O ERROR                       45500019
NOTFNDCD EQU   12                       DATA SET NOT FOUND              45600019
MULTCD   EQU   16                       DATA SETR ON MULTIPLE VOLUMES   45700019
MOUNTCD  EQU   20                       VOLUME NOT MOUNTED              45800019
RETCD    EQU   24                       RETURN TO CMD                   45900019
EXPCD    EQU   28                       EXPIRATION DATE NOT REACHED     46000019
ORGCD    EQU   32                       DATA SET ORGNIZATION INVALID    46100019
OPNCD    EQU   36                       OPEN FAILED                     46200019
MEMBCD   EQU   40                       MEMGER NOT FOUND                46300019
POCD     EQU   44                       NO MEMBER FOR PARTIONED DS      46400019
CLRPOST  EQU   X'00'                    CLEAR POST BIT INECB            46500019
         SPACE 3                                                        46600019
*                                                                       46700019
*   CODSS SET BY SCRATCH                                                46800019
*                                                                       46900019
SNODSCB  EQU   X'01'         VTOC DOES NOT CONTAIN DSCB                 47000019
SNOEXPIR EQU   X'03'         EXPIR DATE NOT REACHED                     47100019
SIOERR   EQU   X'04'         I/O ERROR                                  47200019
SNODEVIC EQU   X'05'         NO DEVICE FOR MOUNTING                     47300019
SNOMNT   EQU   X'06'         UNABLE TO MOUNT                            47400019
*                                                                       47500019
*   CAMLIST CODES                                                       47600019
*                                                                       47700019
*        CAMLST NAME,OSDSNAM,,VOLLIST   CAMLST FOR LOCATE MACRO         47800019
*        CAMLST SEARCH,OSDSNAM,CURRVOL,DSCBWORK  LST FOR OBTAIN MACRO   47900019
*CAM3    CAMLST  SCRATCH,OSDSNAM,,VOLLIST,,OVRD                         48000019
*CAM4    CAMLST SCRATCH,OSDSNAM,,VOLLIST                                48100019
*REMOVE  CAMLST UNCAT,EOSDSNAM                                          48200019
LOCOD    EQU   68            LOCATE                                     48300019
OBTCOD   EQU   193           OBTAIN                                     48400019
SCRCOD   EQU   65            SCRATCH                                    48500019
UNCCOD   EQU   12            UNCATALOG                                  48600019
OVRDCOD  EQU   80            PURGE                                      48700019
NOPRCOD  EQU   64            NO PURGE                                   48800019
*                                                                       48900019
*                                                                       49000019
*********************************************************************** 49100019
*                                                                       49200019
*           DSECT FOR VARIABLES PARMATER LISTS ETC.                     49300019
*                                                                       49400019
*********************************************************************** 49500019
*                                                                       49600019
OSDSECT  DSECT                                                          49700019
SAVEA    DS    18F                                                      49800019
ADDRTUB  EQU   X'1C'                                                    49900019
OSDSNAM  DS    CL44                                                     50000019
         DS    CL4                                                      50100019
KEYSTO   DS    CL3                                                      50200019
         ORG   KEYSTO                                                   50300019
OSMEMBER DS    CL8                                                      50400019
CURRNUM  DS    H                                                        50500019
SAVLRECL DS    H                                                        50600019
CURRVOL  DS    F                                                        50700019
ENDRDBUF DS    F                                                        50800019
BUFADR   DS    F                                                        50900019
ENDINBUF DS    F                                                        51000019
RECLEN   DS    F                                                        51100019
REMLEN   DS    F                                                        51200019
LNOCALC  DS    D                                                        51300019
SAVBLKL  DS    CL2                                                      51400019
SAVRECFM DS    X                                                        51500019
*********************************************************************** 51600019
*        INTERNAL SWITCHES - STORED IN PPT                              51700019
*********************************************************************** 51800019
*           EQUATES FOR PPT SWITCHES                                    51900019
PPTEDT   EQU   X'80'                    EDIT FLAG                       52000019
PPTPRG   EQU   X'80'                                                    52100019
PPTNOPRG EQU   X'7F'                                                    52200019
PPTDEL   EQU   X'40'                                                    52300019
PPTOS    EQU   X'10'                    OS SWITCH                       52400019
PPTMEMB  EQU   X'08'                    PDS SWITCH                      52500019
PPTNMNT  EQU   X'04'                                                    52600019
PPTKEY   EQU   X'02'                    KEY STORED SWITCH               52700019
PPTERR   EQU   X'01'                                                    52800019
PPTNOERR EQU   X'FE'                                                    52900019
         SPACE 1                                                        53000019
PPTFLG   DS    X                                                        53100019
SWDEF    DS    0CL4                                                     53200019
SWDEFEDT DS    X                                                        53300019
PL1OFF   EQU   X'FB'                                                    53400019
FORTOFF  EQU   X'FC'                                                    53500019
SWDEFATT DS    X                                                        53600019
SWDEFBSM DS    X                                                        53700019
SWDEFESM DS    X                                                        53800019
ATTOFF   EQU   X'00'                                                    53900019
         SPACE 1                                                        54000019
*********************************************************************** 54100019
*           PROCESSING SWITCHES                                         54200019
*********************************************************************** 54300019
EDTSW    DS    X                                                        54400019
EDTUID   EQU   X'80'                                                    54500019
EDTOPN   EQU   X'40'                                                    54600019
EDTOPNF  EQU   X'BF'                                                    54700019
EOSLPOR  EQU   X'20'                                                    54800019
EOSLPORF EQU   X'DF'                                                    54900019
EOSMSG   EQU   X'10'                                                    55000019
EOSMSGF  EQU   X'EF'                                                    55100019
EDT2PARM EQU   X'08'                    TWO PARAMETERS FOR MSG WTR      55200019
EDT2PARF EQU   X'F7'                    TURN OFF 2 PARM SW              55300019
EOSREAD  EQU   X'04'                                                    55400019
EOSREADF EQU   X'FB'                                                    55500019
EDTREL   EQU   X'02'                                                    55600019
EOSBUFR  EQU   X'01'                                                    55700019
EDTOFF   EQU   X'00'                      ALL SWITCHES OFF              55800019
         SPACE 1                                                        55900019
*                                                                       56000019
CAMLIST  DS    0F            ALIGN ON FULL WORD BOUNDARY                56100019
CAMFLG1  DS    AL1           THREE BYTES OF FLAGS INDICATING            56200019
CAMFLG2  DS    AL1           THE FUNCTION TO BE PERFORMED               56300019
CAMFLG3  DS    AL1                                                      56400019
CAMOPT3  DS    AL1           NO OPTION THREE                            56500019
CAMNAM   DS    A             PARAMETER TWO                              56600019
CAMPARM3 DS    A             PARAMETER THREE                            56700019
CAMPARM4 DS    A             PARAMETER FOUR                             56800019
*                                                                       56900019
         DS    0D                                                       57000019
NUMVOL   DS    H                   NUMBER OF VOLUME POINTERS            57100019
VOLID    DS    CL12                1- 20 VOL ID                         57200019
         ORG   VOLID                                                    57300019
DEVCODE  DS    4C                  DEVICE CODE                          57400019
LOCVOL   DS    6C            VOLUME SERIAL NUMBER                       57500019
SCRERR   DS    C                                                        57600019
         DS    0D                                                       57700019
ADDRDCB  DS    CL96                                                     57800019
INSERTBF DS    0D                                                       57900019
         ORG   NUMVOL                                                   58000019
VOLLIST  DS    265C                                                     58100019
ZEROFLD  EQU   X'0A'               ZERO FIELD- 10 BYTES                 58200019
         SPACE 3                                                        58300019
*********************************************************************** 58400019
*           DSECT FOR DSCB (DATA PORTION)                               58500019
*********************************************************************** 58600019
DSCBWORK DS    0D                                                       58700019
DS1FMTIO DS    C                        FORMAT IDENTIFIER               58800019
DS1DSSN DS     CL6                      DATA SET SERIAL NO              58900019
DS1VOLSQ DS    CL2                      VOLUME SEQUENCE NO              59000019
DS1CREDT DS    CL3                      CREATION DATE                   59100019
DS1EXPDT DS    CL3                      EXPIRATION DATE                 59200019
DS1NOEPV DS    C                        NUMBER OF EXTENTS               59300019
DS1NOBDB DS    C                        NO BYTES USED IN LAST DIR BLK   59400019
         DS    C                        RESERVED                        59500019
DS1SUSCO DS    CL13                     SYSTEM CODE                     59600019
         DS    CL7                      RESERVED                        59700019
DS1DSORG DS    CL2                      DATA SET ORGNIZATION            59800019
DS1PS    EQU   X'40'                      SEQUENTIAL                    59900019
DS1PO    EQU   X'02'                      PARTIONED                     60000019
DS1RECFM DS    X                        RECORD FORMAT                   60100019
DS1F     EQU   X'80'                      FIXED                         60200019
DS1V     EQU   X'40'                      VARIABLE                      60300019
DS1U      EQU  X'C0'                       UNDEFINED                    60400019
DS1B     EQU   X'10'                      BLOCKED                       60500019
DS1OPTCD DS    C                        OPTION CODE                     60600019
DS1BLKL  DS    CL2                      BLOCK LENGTH                    60700019
DS1LRECL DS    CL2                      LOGICAL RECORD LENGTH           60800019
DS1KEYL  DS    C                        KEY LENGTH                      60900019
DS1RKP   DS    CL2                      RELATIVE KEY POSITION           61000019
DS1DSIND DS    C                        DATA SET INDICATORS             61100019
DS1PASS  EQU   X'10'                    PASSWORD PROTECTED              61200019
DS1SCALO DS    CL4                      SECONDARY ALLOCATION            61300019
DS1LSTAR DS    CL3                      LAST BLOCK POINTER              61400019
DS1TRBAL DS    CL2                        CONT                          61500019
          DS    CL2                      RESERVED                       61600019
DS1EXT1  DS    CL10                     FIRST EXTENT                    61700019
DS1EXT2  DS    CL10                     SECOND EXTENT                   61800019
DS1EXT3  DS    CL10                     THIRD EXTENT                    61900019
DS1PTRDS DS    CL5                      POINTER TO FORMAT 2 DSCB        62000019
         ORG   INSERTBF                                                 62100019
         DS    CL888                                                    62200019
         SPACE 3                                                        62300019
*********************************************************************** 62400019
*            DSECT FOR JFCB                                             62500019
*********************************************************************** 62600019
JFCB     DS    0XL176                                                   62700019
JFCBDSN  DS    CL44                                                     62800019
         DS    XL43                                                     62900019
JFCBIND2 DS    X                                                        63000019
         DS    XL30                                                     63100019
JFCBVOLS DS    CL30                                                     63200019
         DS    CL28           REST OF DSCB WORKAREA                     63300019
GMLEN    EQU   *-OSDSECT                                                63400019
*                                                                       63500019
*********************************************************************** 63600019
*                                                                       63700019
*                                                                       63800019
*   DSECTS FOR OS PROCESSING                                            63900019
*                                                                       64000019
*           DSECTS FOR CONTROL BLOCKS                                   64100019
*                                                                       64200019
*********************************************************************** 64300019
         DCBD  DSORG=(PS,PO),DEVD=(DA)                                  64400019
DCBDLEN  EQU   *-IHADCB                                                 64500019
         SPACE 3                                                        64600019
IRLPARMS DSECT                                                          64700019
IRLSW    DS    X                          PROCESSING SWITCHES           64800019
IRLINS   EQU   X'40'                        INSERT ONLY                 64900019
IRLREP   EQU   X'20'                        REPLACE ONLY                65000019
IRLOFF   EQU   X'80'                        ALL SWITCHES OFF            65100019
         DS    CL5                                                      65200019
IRLSTAD  DS    CL8                        BEGNING LINE NO               65300019
IRLINC   DS    F                          DATA SET INCREMENT            65400019
         IHKCDSCT TUB=YES,DIR=YES,AVT=YES,DEF=YES                       65500019
         RAFKNBX TYPE=DSECT                                             65600019
         TUBEQU                         EQUATES FOR TUB                 65700019
         END                                                            65800019
