OUT      TITLE 'IHKOUT - OUTPUT AND CONTINUE COMMAND PROCESSORS'        00200019
IHKOUT   CSECT                                                          00400019
*A 348000,522000                                                 S21085 00460021
*C 012000,130000                                                 S21085 00520021
*C086000,130000                                                  A52752 00540026
*A640000                                                         A52752 00560026
*********************************************************************** 00600019
*                                                                     * 00800019
*STATUS-                                                              * 01000019
*   CHANGE LEVEL 1                                               S21085 01200021
*                                                                     * 01400019
*FUNCTION/OPERATION-                                                  * 01600019
*       A. OUTPUT FIRST INSPECTS THE TYPE OF COMMAND (OUTPUT OF CON   * 01800019
*   TINUE) AND VERIFIES IT AS VALID. IF THE COMMAND IS CONTINUES THE  * 02000019
*   APPROPRIATE BITS ARE SET FOR LATER INSPECTION. THE FOLLOWING      * 02200019
*   ERROR CONDITIONS ARE CHECKED AND IF FOUND, A MESSAGE IS SENT TO   * 02400019
*   THE USER - OUTPUT 1. JOBNAME NOT FOUND, 2. USER REQUESTING JOB NOT* 02600019
*   JOB'S SUBMITTER, AND 3. JOB NOT COMPLETE; FOR CONTINUE  1.INVALID * 02800019
*   PARAMETERS, AND 2. USER NOT IN DISCONTINUED STATE.                * 03000019
*       B. ONCE THE COMMAND IS VERIFIED, A 504 BYTE WORK AREA FOR     * 03200019
*   IHKPUT IS GOTTEN AND THE RJCT ENTRY IS READ INTO CORE.            * 03400019
*                                                                     * 03600019
*ENTRY POINTS-                                                        * 03800019
*        IHKOUT IS THE ONLY ENTRY POINT. AT ENTRY REGISTER ONE WILL   * 04000019
*   CONTAIN THE ADDRESS OF A TWO WORD PARAMETER LIST. THE FIRST WORD  * 04200019
*   IS THE ADDRESS OF THE TUB, THE SECOND IS THE ADDRESS OF IHKAVT.   * 04400019
*                                                                     * 04600019
*INPUT-                                                               * 04800019
*   AS DESCRIBED IN ENTRY POINTS.                                     * 05000019
*                                                                     * 05200019
*OUTPUT-                                                              * 05400019
*   WORK AREA IS GOTTEN FOR IHKPUT AND THE RJCT IS READ.              * 05600019
*                                                                     * 05800019
*EXTERNAL ROUTINES-                                                   * 06000019
*        IHKAFI - READ RJCT ENTRY                                     * 06200019
*        IHKMSG - (ENTRY POINT IHKMSG01) SEND ERROR MESSAGES.         * 06400019
*                                                                     * 06600019
*EXITS-NORMAL-                                                        * 06800019
*   RETURN TO IHKCMD WITH CODE IN REGISTER 15 TO LOAD IHKPUT.         * 07000019
*                                                                     * 07200019
*EXITS-ERROR-                                                         * 07400019
*   RETURN TO IHKCMD WITH RETURN CODE IN REGISTER 15 OF 8 FOR GETMAIN * 07600019
*   FAILURE OR 12 FOR ACTIVE AREA I/O ERROR.                          * 07800019
*                                                                     * 08000019
*TABLES/WORK AREAS-                                                   * 08200019
*        1. A 72 BYTE GETMAIN FOR SAVE AREA.                          * 08400019
*        2. A 504 BYTE WORK AREA TO CONTAIN PARAMETE LISTSS FOR SUB-  * 08600019
*           ROUTINES, SAVE AREA, DCB, DECB, SMB/DSBS, RJCT, AND       * 08800019
*           TEMPORARY CONSTANTS.                                      * 09000019
*        3. THE TUB AND RJCT.                                         * 09200019
*                                                                     * 09400019
*ATTRIBUTES-                                                          * 09600019
*   REENTRANT AND NON/RESIDENT                                        * 09800019
*                                                                     * 10000019
*********************************************************************** 10200019
ZIP      EQU   0                                                        10400019
PAR      EQU   1                                                        10600019
LNG      EQU   5                                                        10800019
REG      EQU   6                                                        11000019
PPT      EQU   7                                                        11200019
WOK      EQU   8                                                        11400019
RJC      EQU   9                                                        11600019
TUB      EQU   10                                                       11800019
AVT      EQU   11                                                       12000019
BAS      EQU   12                                                       12200019
SAV      EQU   13                                                       12400019
BAC      EQU   14                                                       12600019
GO       EQU   15                                                       12800019
         SAVE  (14,12),,OUT72121                                 A52752 13000026
         LR    BAS,GO              SET UP BASE REGISTER                 13200019
         USING IHKOUT,BAS                                               13400019
         LM    TUB,AVT,ZIP(PAR)    GET TUB AND AVT ADDRESSES            13600019
         USING TUBDSECT,TUB                                             13800019
         USING AVTDSECT,AVT                                             14000019
         USING OUTWORK,SAV                                              14200019
         LA    WOK,TUBPARM5        ADDRESS OF GETMAINED AREA            14400019
         LA    REG,WORKLNG         LENGTH FOR GETMAIN                   14600019
         L     PAR,IHKYYGML        ADDRESS OF GETMAIN PARM LIST         14800019
         SPACE 2                                                        15000019
         GETMAIN EC,LV=(6),A=(8),MF=(E,(1)) GET SAVE AND WORK AREAS     15200019
         SPACE 2                                                        15400019
         LTR   GO,GO               GETMAIN O. K.                        15600019
         LA    GO,ATE              ASSUME FAILURE                       15800019
         BNZ   ERRTURN             NO EXIT TO SYSTEM ADMINISTRATOR      16000019
         L     WOK,TUBPARM5        ADDRESS OF SAVE AND WORK AREA        16200019
         ST    WOK,ATE(SAV)        CHAIN SAVE AREAS                     16400019
         ST    SAV,FOR(WOK)                                             16600019
         LR    SAV,WOK                                                  16800019
         LA     RJC,JTABAD         ADDRESS OF BUFFER FOR RJCT           17000019
         USING RJCTSECT,RJC                                             17200019
         ST    TUB,MSGPARM         SAVE ADDRESS OF TUB                  17400019
         L     PPT,TUBPPTAD        ADDRESS OF PPT                       17600019
         USING PPTDSECT,PPT                                             17800019
         MVC   CODECMD,PPTCMD      SAVE COMMAND CODE                    18000019
         MVI   OUTSWT,ZIP          CLEAR STATUS SW-TCH                  18200019
         CLI   PPTPARS,ALL         ANY OPERANDS IN PPT                  18400019
         BNE   CKCMD               YES INSPECT OPERANDS                 18600019
         L     PPT,PPTCHAD         ADDRESS OF NEXT PPT                  18800019
         LTR   PPT,PPT             DOES NEXT EXIST                      19000019
         BNZ   CKCMD               YES INSPECT OPERANDS                 19200019
         SPACE                                                          19400019
         CLI   CODECMD,CMDOUT      OUTPUT COMMAND                       19600019
         BE    BADPARM             YES - THEN REQ'D OPERAND MISSING     19800019
         SPACE                                                          20000019
         TM    TUBFLG2,DISC        IS USER IN DISCONTINUE STATE         20200019
         BZ    NODIS               YES SEND MESSAGE                     20400019
         L     BAC,IHKYYDEF        ADDRESS OF DEFAULT TABLE             20600019
         USING DEFDSECT,BAC                                             20800019
         MVC   OUTSWT(1),DEFCON    ASSUME DEFAULT CONTINUE OPERAND      21000019
         DROP  BAC                                                      21200019
         B     READRJCT            READ RJCT FOR JOB                    21400019
         SPACE 3                                                        21600019
CKCMD    LA    LNG,PPTPARS                                              21800019
         CLI   CODECMD,CMDOUT      OUTPUT OR CONTINUE COMMAND           22000019
         BE    CLEARNAM            OUTPUT COMMAND                       22200019
         TM    TUBFLG2,DISC        IS USER DISCONTINUED                 22400019
         BZ    NODIS               NO SEND ERROR MESSAGE                22600019
         TM    PPTPARS,PAREN       PARENS AROUND NAME                   22800019
         BNZ   BADOPRND            YES SEND ERROR MESSAGE               23000019
         CLI   0(LNG),FOR          IS OPERAND LENGTH FOUR               23200019
         BNE   CKH1                NO SKIP NEXT CHECK                   23400019
         CLC   PPTPARS+1(4),HERE   CONTINUE HERE                        23600019
         BE    READJTAB            YES                                  23800019
CKH1     CLI   PPTPARS+1,H                                              24000019
         BE     RDRJTAB                                                 24200019
         OI     OUTSWT,CONB        CONTINUE BEGIN SWITCH                24400019
         CLI   0(LNG),FIVE         IS OPERAND LENGTH FIVE               24600019
         BNE   CKB1                NO SKIP NEXT CHECK                   24800019
         CLC   PPTPARS+1(5),BEGIN  CONTINUE BEGIN SPECIFIED             25000019
         BE    READJTAB            READ JOB TABLE                       25200019
CKB1     CLI   PPTPARS+1,B                                              25400019
         BE     RDRJTAB                                                 25600019
         OI     OUTSWT,CONNX       SET FLAG TO CONTINUE NEXT            25800019
         CLI   0(LNG),FOR          IS OPERAND LENGTH FOUR               26000019
         BNE   CKN1                NO SKIP NEXT CHECK                   26200019
         CLC   PPTPARS+1(4),NEXT   IS THIS CONTINUE NEXT                26400019
         BE    READJTAB            YES PROCESS                          26600019
CKN1     CLI   PPTPARS+1,N                                              26800019
         BNE   BADOPRND            BAD OPERAND ON CONTINUE              27000019
RDRJTAB  CLI   0(LNG),ONE          IS OPERAND LENGTH ONE                27200019
         BNE   BADOPRND            NO MUST BE INVALID OPERAND           27400019
         SPACE                                                          27600019
READJTAB EQU   *                                                        27800019
         SR    WOK,WOK             CLEAR FOR LENGTH                     28000019
         IC    WOK,0(LNG)          GET LENGTH                           28200019
         LA    LNG,1(WOK,LNG)      BUMP TO NEXT OPERAND                 28400019
         CLI   0(LNG),ALL          NO PARMS FOLLOW                      28600019
         BNZ   EXOPRND             NOT TRUE EXCESSIVE PARMS             28800019
         SPACE                                                          29000019
         L     PPT,PPTCHAD         ADDRESS OF NEXT PPT                  29200019
         LTR   PPT,PPT             PPT FOLLOW                           29400019
         LA    LNG,PPTPARS         ADDRESS OF BAD PARM                  29600019
         BNZ   EXOPRND             YES EXCESSIVE OPERANDS               29800019
         SPACE                                                          30000019
*                                                                       30200019
*        SEARCH FOR RJCT FOR JOB ON OUTPUT COMMAND  -JOBNAME            30400019
*                                                                       30600019
READRJCT EQU   *                                                        30800019
         LA    REG,JTABAD-8        RJCT MINUS EIGHT FOR BUFFER          31000019
         ST    REG,TUBRAFBF        PROVIDE BUFFER ADDRESS FOR IHKAFI    31200019
         OI    TUBAFISW,TUBFCTLN   INDICATE USING BUFFER CONTROL        31400019
         MVI   TUBGBLNM,RJCTNM     SET GLOBAL FILE TO 5 (RJCT )         31600019
         MVC   TUBGBLKY(8),TUBRJCT KEY IS JOBNAME                       31800019
         LA    PAR,MSGPARM         ADDRESS OF TUB POINTER               32000019
         SPACE                                                          32200019
         RPOINT B,R,FTYPE=GBL      GET RJCT ENTRY                       32400019
         SPACE                                                          32600019
         NI    TUBAFISW,ALL-TUBFCTLN TURN OFF BUFFER CONTROL            32800019
         B     *+4(GO)             BRANCH ON RETURN CODE                33000019
         B     CKUSR               JOB FOUND - INSPECT USERID           33200019
         B     NOTFOUND            JOB NAME NOT FOUND                   33400019
         B     ERREXIT             EXIT ON ERROR                        33600019
         B     ERREXIT             EXIT ON ERROR                        33800019
CKUSR    CLC   RJCTUSER(8),TUBUSRID  CHECK FOR VALID USER               34000019
         BNE   BADUSER             BRANCH IF NOT SUBMITTER              34200019
         TM    RJCTFLGS,COMPLETE   IS JOB COMPLETE                      34400019
         BZ    NOTDONE             NO, TELL USER                        34600019
         OC    OUTSWT(1),RJCTFLGS  SAVE STATUS FLAGS                    34800019
         MVC   OUTDCB(108),OUTDCBM MOVE MODEL DCB AND DECB       S21085 34900021
         LA    GO,CMDPUT           CODE OF TRANSMITTING MODULE          35000019
         LNR   GO,GO               INDICATE DELETE/LOAD FUNCTION        35200019
         L     SAV,SAVE+4          GET CALLERS SAVE AREA                35400019
ERRTURN  RETURN (14,12),T,RC=(15)                                       35600019
         SPACE 5                                                        35800019
CLEARNAM XR    WOK,WOK             CLEAR REGISTER                       36000019
         TM    PPTPARS,PAREN       PARENS AROUND NAME                   36200019
         BNZ   BADOPRND            YES SEND ERROR MESSAGE               36400019
         IC    WOK,PPTPARS         NUMBER OF BYTES IN JOBNAME           36600019
         CLI   PPTPARS,ATE         JOB NAME EXCEED 8 BYTES              36800019
         BH    BADOPRND            YES, SEND ERROR MSG AND GET OUT      37000019
         MVI   TUBRJCT,BLANK       CLEAR JOBNAME FIELD TO BLANKS        37200019
         MVC   TUBRJCT+1(7),TUBRJCT                                     37400019
         NI     TUBFLG2,NSMSG      PRE SET SMSG TO OFF                  37600019
         BCTR  WOK,0               CHANGE LENGTH FOR MOVE               37800019
         EX    WOK,MOVENAM         MOVE JOB NAME FROM PPT TO WORK AREA  38000019
         LA    WOK,PPTPARS+2(WOK)  GET ADDRESS OF SECOND PARAMETER      38200019
CKOPRND  CLI   0(WOK),ALL          DOES ANOTHER OPERAND EXIST           38400019
        BNE   CKSMSG              YES CHECK FOR SMSG                    38600019
         L     PPT,PPTCHAD         ADDRESS OF NEXT PPT                  38800019
        LTR    PPT,PPT            ANOTHER PPT EXIST                     39000019
         BE    READRJCT            ONLY JOBNAME SPECIFIED               39200019
        LA    WOK,PPTPARS         BUMP TO NEXT PPT                      39400019
CKSMSG   LR    LNG,WOK             SAVE PPT POSITION FOR ERROR MSG      39600019
         CLI  0(WOK),FOR           IF LENGTH NOT FOUR OPERAND INVALID   39800019
        BNZ   BADOPRND            SEND ERROR MESSAGE AND EXIT           40000019
         CLC   1(4,WOK),SMSG       SHOULD BE SMSG                       40200019
         BNE   BADOPRND            NO, USER BLEW IT. GO TELL HIM        40400019
         OI     TUBFLG2,YSMSG      TURN ON SMSG REQUESTED SWITCH        40600019
        B     READJTAB            READ IN RJCT FOR JOB                  40800019
         SPACE 5                                                        41000019
BADPARM  EQU   *                   BAD PARAMETERS                       41200019
         MVC   MSGOFF+2(2),MN17                                         41400019
         LA    LNG,JOBNAME         PARMS ON OUTPUT MESSAGE              41600019
         B     SENDMSG             SEND MESSAGE                         41800019
         SPACE 5                                                        42000019
NOTFOUND EQU   *                   JOB NOT FOUND MESSAGE                42200019
         MVC   MSGOFF+2(2),MN44    JOB NOT FOUND MESSAGE                42400019
         B     SENDMSG1            SEND MESSAGE AND RETURN              42600019
         SPACE 5                                                        42800019
BADUSER  EQU   *                   INVALID RECIPIENT MESSAGE            43000019
         MVC   MSGOFF+2(2),MN23                                         43200019
         B     SENDMSG1            SEND MESSAGE AND RETURN              43400019
         SPACE 5                                                        43600019
NOTDONE  EQU   *                   JOB NOT COMPLETE MESSAGE             43800019
         MVC   MSGOFF+2(2),MN24                                         44000019
         B     SENDMSG1            SEND MESSAGE AND RETURN              44200019
         SPACE 5                                                        44400019
BADOPRND MVC   MSGOFF+2(2),MN02    SET MESSAGE TO INVALID OPERAND       44600019
         B     SENDMSG             SEND ERROR MESSAGE AND EXIT          44800019
         SPACE 3                                                        45000019
NODIS    MVC   MSGOFF+2(2),MN74    SET FOR NOT DISCONTINUED MESSAGE     45200019
         SPACE 3                                                        45400019
SENDMSG1 LA    LNG,ZERO            NO VARIABLE PARMS ON MESSAGE         45600019
         SPACE 2                                                        45800019
SENDMSG  ST    LNG,MSGVP           ADDRESS OF VARIABLE PARMS IN LIST    46000019
         NI    0(LNG),ALL-PAREN    TURN OFF PARENTHESES FLAGS           46200019
         LA    REG,TUBUSRID        ADDRESS OF USER ID                   46400019
         ST    REG,MSGTUB          PUT IN PARM LIST                     46600019
         LA    REG,MSGOFF          ADDRESS OF MESSAGE NUMBER            46800019
         ST    REG,MSGNUM          PUT IN PARM LIST                     47000019
         MVC   MSGOFF(2),MSGCODE   INDICATE REMOTE MESSAGE              47200019
         MVI   MSGVP,MSGLAST       FLAG END OF PARM LIST                47400019
         LA    PAR,MSGPARM         ADDRESS OF PARM LIST                 47600019
         L     GO,IHKYMSG1         ADDRESS OF MESSAGE WRITER            47800019
         SPACE                                                          48000019
         BALR  BAC,GO              ENQUEUE MESSAGE FOR USER             48200019
         SPACE 3                                                        48400019
ERREXIT  EQU   *                                                        48600019
         LR    REG,GO              SAVE RETURN CODE                     48800019
         LR    PAR,SAV             AREA TO FREE                         49000019
         L     SAV,SAVE+4          GET CALLERS SAVE AREA                49200019
         LA    ZIP,WORKLNG         LENGTH TO FREE                       49400019
         SPACE                                                          49600019
         FREEMAIN R,LV=(0),A=(1)                                        49800019
         SPACE                                                          50000019
         LR    GO,REG              RESTORE RETURN CODE                  50200019
         TM    TUBFLG2,DISC        OUTPUT DISCONTINUED                  50400019
         BNZ   ERRTURN             YES EXIT                             50600019
         MVI   TUBRJCT,BLANK       CLEAR JOB NAME                       50800019
         B     ERRTURN             EXIT TO SYSTEM ADMINISTRATOR         51000019
         SPACE 3                                                        51200019
EXOPRND  MVC   MSGOFF+2(2),MN34    EXCESSIVE OPERAND MESSAGE            51400019
         B     SENDMSG             SEND ERROR MESSAGE AND EXIT          51600019
         SPACE 3                                                        51800019
MOVENAM  MVC   TUBRJCT(0),PPTPARS+1                                     52000019
         SPACE 3                                                        52200019
OUTDCBM  DCB   DSORG=PS,MACRF=RP,EODAD=OUTDCBM,SYNAD=OUTDCBM,    S21085X52250021
               DDNAME=SYSOUTDD                                   S21085 52300021
         READ  OUTDECBM,SF,OUTDCBM,,'S',,,MF=L                   S21085 52350021
ZERO     DC    F'0'                                                     52400019
MSGCODE  DC    X'00'                                                    52600019
         DC    C'3'                                                     52800019
MSGLAST  EQU   X'80'                                                    53000019
RJCTNM   EQU   5                                                        53200019
PAREN   EQU   X'C0'                                                     53400019
SMSG     DC    C'SMSG'             SMSG SHOULD BE LAST PARM AND IN PPT  53600019
COMPLETE EQU   X'40'               JOB COMPLETION BIT                   53800019
HERE     DC    C'HERE'                                                  54000019
H        EQU   C'H'                                                     54200019
BEGIN    DC    C'BEGIN'                                                 54400019
B        EQU   C'B'                                                     54600019
NEXT     DC    C'NEXT'                                                  54800019
N        EQU   C'N'                                                     55000019
JOBNAME  DC    X'07'                                                    55200019
         DC    C'JOBNAME'                                               55400019
MN02     DC    C'02'                                                    55600019
MN17     DC    C'17'                                                    55800019
MN23     DC    C'23'                                                    56000019
MN24     DC    C'24'                                                    56200019
MN34     DC    C'34'                                                    56400019
MN44     DC    C'44'                                                    56600019
MN74     DC    C'74'                                                    56800019
ONE      EQU   1                                                        57000019
FOR      EQU   4                                                        57200019
FIVE     EQU   5                                                        57400019
ATE      EQU   8                                                        57600019
ALL      EQU   X'FF'                                                    57800019
         IHKCDSCT DEF=YES                                               58200019
         IHKCDSCT PPT=YES                                               58400019
         IHKCDSCT TUB=YES                                               58600019
         IHKCDSCT AVT=YES                                               58800019
         IHKCDSCT RJCT=YES                                              59000019
         CMDEQU                                                         59200019
****                                                               **** 59400019
*                                                                     * 59600019
*        D S E C T  O F  W O R K A R E A  U S E D  B Y  O U T P U T   * 59800019
*                                                                     * 60000019
****                                                               **** 60200019
         SPACE 3                                                        60400019
OUTWORK  DSECT                                                          60600019
SAVE     DS    18F                                                      60800019
CODECMD  EQU   SAVE                                                     61000019
BLANK    EQU   C' '                                                     61200019
CONB     EQU   X'02'                                                    61400019
CONNX    EQU   X'06'                                                    61600019
DISC     EQU   X'08'               DISCONTINUE ON                       61800019
DISCOFF  EQU   X'F7'               DISCONTINUE OFF                      62000019
TCBAD    DC    A(0)                                                     62200019
YSMSG    EQU   X'01'                                                    62400019
NSMSG    EQU   X'F6'                                                    62600019
JTABAD   DS    19F                                                      62800019
RECORD   DS    CL176                                                    63000019
QMPA     EQU   JTABAD+28                                                63200019
OUTDCB   DS    22F                                                      63400019
OUTDECB  DS    5F                                                       63600019
XLIST    DS    CL4                                                      63800019
CHTIOT   DS    CL4                                                      64000019
ALIGN    DC    X'000000'                                         A52752 64060026
DDNAME   DS    CL9                 DDNAME FOR MSG                A52752 64120026
SYSBUFL  DS    F                                                        64200019
SYSBUF   DS    CL4                                                      64400019
ENDBUF   DS    CL4                                                      64600019
MSGPARM  DC    F'0'                                                     64800019
RMVDSB   DC    F'0'                                                     65000019
RMVQMPA  DC    F'0'                                                     65200019
*                  PARAMETER LIST FOR IHKRJC                            65400019
RJCCODE  EQU   RMVDSB                                                   65600019
RJCBUF   EQU   RMVQMPA                                                  65800019
RJCNAM   DC    F'0'                                                     66000019
RJCAVT   DC    F'0'                                                     66200019
         SPACE                                                          66400019
*                    PARM LIST FOR MESSAGE WRITER                       66600019
MSGTUB   EQU   RMVDSB                                                   66800019
MSGNUM   EQU   RMVQMPA                                                  67000019
MSGVP    EQU   RJCNAM                                                   67200019
MSGOFF   EQU   RJCAVT                                                   67400019
*              P A R M  L I S T  F O R  I H K R E R                     67600019
RERTUB   EQU   MSGPARM                                                  67800019
RERVOLAD EQU   RMVDSB                                                   68000019
RERDCB   EQU   RMVQMPA                                                  68200019
RERVOL   EQU   RJCNAM                                                   68400019
NTIOTL   DS    CL2                                                      68600019
CODE     DS    X                                                        68800019
OUTSWT   DS    X                                                        69000019
*        BIT SETTINGS FOR OUTSWT                                        69200019
*              BIT 0-3       RJCTFLGS                                   69400019
*              BIT 4         NOT USED                                   69600019
*              BITS 5-6      CONTINUE STATE                             69800019
*                  00 - HERE                                            70000019
*                  01 - BEGIN                                           70200019
*                  11 - NEXT                                            70400019
*              BIT 7         NOT USED                                   70600019
LDCPARM  DS    0F                                                       70800019
LDCECB   DS    F                                                        71000019
LDCCODE  DS    H                                                        71200019
LDCZERO  DS    X                                                        71400019
SRVCODE  DC    X'0'                                                     71600019
SRVPARM  DC    A(0)                                                     71800019
SRVCODPT DC    A(0)                                                     72000019
SRVQMPA  DC    A(0)                                                     72200019
SRVECB   DC    F'0'                                                     72400019
WORKLNG  EQU   *-OUTWORK           LENGTH OF WORK AREA                  72600019
    END                                                                 72800019
