RNQ      TITLE 'IHKRNQ - LIBRARIAN ENQUEUE MODULE'                      00800019
*********************************************************************** 01600019
*********************************************************************** 02400019
*                                                                     * 03200019
*                           I H K R N Q                               * 04000019
*                                                                     * 04800019
*  STATUS -                                                           * 05600019
*      CHANGE LEVEL                                                   * 06400019
*                                                                     * 07200019
*  FUNCTION/OPERATION -                                               * 08000019
*      THIS MODULE CONTROLS THE QUEUEING REQUIRED FOR SEVERAL CRJE    * 08800019
*      SYSTEM RESOURCES. REQUESTS FOR ACCESS TO USER LIBRARIES,       * 09600019
*      SYSTEM GLOBAL FILES, AFIO EXTENDED WORK AREA AND CERTAIN       * 10400019
*      SERIALLY REUSABLE FUNCTIONS SUCH AS SYNTAX CHECKER INTERFACE,  * 11200019
*      CRJE SUBMIT FUNCTION, ARE HANDLED BY RNQ.                      * 12000019
*                                                                     * 12800019
*      IHKRNQ CHECKS TO DETERMINE IF THE SPECIFIED QUEUE IS EMPTY.    * 13600019
*      IF SO, THE QUE ELEMENT IS PLACED AS THE FIRST IN THE QUEUE     * 14400019
*      AND RETURN IS MADE TO THE CALLER. IF THE SPECIFIED QUEUE IS    * 15200019
*      NOT EMPTY, THE QUE ELEMENT IS CHAINED INTO THE QUEUE AND THE   * 16000019
*      LINE IS PUT INTO A WAIT IN THE CRJE DISPATCHER. THE DIS-       * 16800019
*      PATCHER RETURNS CONTROL TO RNQ WHEN THE QUE ELEMENT ECB        * 17600019
*      IS POSTED AND RNQ RETURNS CONTROL TO THE CALLER.               * 18400019
*                                                                     * 19200019
*  ENTRY POINTS -                                                     * 20000019
*      IHKRNQ IS THE ONLY ENTRY POINT INTO THIS MODULE.               * 20800019
*                                                                     * 21600019
*  INPUT -                                                            * 22400019
*      UPON ENTRY TO IHKRNQ, REGISTER 1 CONTAINS A POINTER TO A       * 23200019
*      PARAMETER LIST AS SHOWN.                                       * 24000019
*                                                                     * 24800019
*                1. POINTER TO QUE ELEMENT                            * 25600019
*                2. POINTER TO QUE CONTROL ELEMENT                    * 26400019
*                                                                     * 27200019
*  OUTPUT -                                                           * 28000019
*      NONE                                                           * 28800019
*                                                                     * 29600019
*  EXTERNAL ROUTINES -                                                * 30400019
*      IHKDSP - CRJE DISPATCHER                                       * 31200019
*                                                                     * 32000019
*  EXITS -                                                            * 32800019
*      NORMAL AND ABNORMAL RETURN TO CALLER.                          * 33600019
*                                                                     * 34400019
*  RETURN CODES -                                                     * 35200019
*0 - NORMAL                                                           * 36000019
*      4 - GETMAIN FAILURE                                            * 36800019
*                                                                     * 37600019
*  TABLES/WORKAREAS -                                                 * 38400019
*      TUB                                                            * 39200019
*      IHKNBX                                                         * 40000019
*                                                                     * 40800019
*  ATTRIBUTES -                                                       * 41600019
*      RESIDENT AND REENTRANT                                         * 42400019
*                                                                     * 43200019
*********************************************************************** 44000019
*********************************************************************** 44800019
*        UPON ENTRY TO THIS MODULE REGISTER 13 MUST POINT TO A          45600019
*        72 BYTE SAVEAREA AND REGISTER 1 MUST POINT TO A PARAMETER      46400019
*        LIST THAT CONTAINS IN THE FIRST WORD A POINTER TO THE Q        47200019
*        ELEMENT AND IN THE SECOND WORD A POINTER TO THE Q CONTROL      48000019
*        ELEMENT.                                                       48800019
IHKRNQ   CSECT                                                          49600019
         USING *,BASERG                                                 50400019
         SAVE  (14,12)                                                  51200019
         LR    BASERG,BRNRG        LOAD BASE REGISTER                   52000019
         L     WRKRG1,0(PARMRG)        LOAD PTR TO QELEMENT             52800019
         MVI   4(WRKRG1),ZERO                                           53600019
         L     WRKRG2,4(PARMRG)        LOAD PTR TO QCTL ELEMENT         54400019
         LA    WRKRG3,4(WRKRG2)    POINT TO SECOND WORD OF CTL ELEMENT  55200019
         ST    WRKRG3,0(WRKRG1)    POINT Q ELEMENT TO IT                56000019
         CLC   1(3,WRKRG1),1(WRKRG2)   IS QUE EMPTY                     56800019
         BNE   NOTFIRST            NO - BRANCH                          57600019
         ST    WRKRG1,0(WRKRG2)    ENQUEUE THIS ELEMENT AS              58400019
         ST    WRKRG1,4(WRKRG2)        FIRST ON THE QUE                 59200019
         B     FIRST                                                    60000019
NOTFIRST GETMAIN  EC,LV=72,A=COREADD                                    60800019
         LTR   BRNRG,BRNRG         WAS GETMAIN SUCCESSFUL               61600019
         BNZ   NOCORE              NO  -  BRANCH                        62400019
         L     WRKRG4,COREADD      SAVE PTR IN REG 2                    63200019
         L     WRKRG3,4(WRKRG2)    PLACE THIS ELEMENT INTO THE          64000019
         ST    WRKRG1,0(WRKRG3)        QUE AND UPDATE                   64800019
         ST    WRKRG1,4(WRKRG2)            THE CHAIN                    65600019
         ST    SAVERG,4(WRKRG4)    SAVE PREVIOUS SAVEAREA PTR           66400019
         ST    WRKRG4,8(SAVERG)    SAVE THIS SAVEAREA PTR               67200019
         LR    SAVERG,WRKRG4       POINT REG 13 TO SAVEAREA             68000019
         LA    PARMRG,4(WRKRG1)    LOAD ECB PTR                         68800019
         L     BRNRG,DISP                                               69600019
         BALR  RETRG,BRNRG         WAIT IN DISPATCHER UNTIL POSTED      70400019
*                                          ON TOP OF QUE                71200019
         L     SAVERG,4(SAVERG)    LOAD SAVEAREA PTR                    72000019
         ST    WRKRG4,COREADD                                           72800019
         FREEMAIN  E,LV=72,A=COREADD                                    73600019
FIRST    SR    BRNRG,BRNRG             SET RC=0                         74400019
EXIT     RETURN  (14,12),RC=(15)                                        75200019
NOCORE   LH    BRNRG,FOUR          SET RC=4  GETMAIN FAILED             76000019
         B     EXIT                                                     76800019
         DS    0F                                                       77600019
COREADD  DC    F'0'                                                     78400019
DISP     DC    V(IHKDSP)                                                79200019
FOUR     DC    H'4'                                                     80000019
PARMRG   EQU   1                                                        80800019
WRKRG4   EQU   2                                                        81600019
WRKRG1   EQU   3                                                        82400019
WRKRG2   EQU   4                                                        83200019
WRKRG3   EQU   5                                                        84000019
BASERG   EQU   10                                                       84800019
SAVERG   EQU   13                                                       85600019
RETRG    EQU   14                                                       86400019
BRNRG    EQU   15                                                       87200019
ZERO     EQU   X'00'                                                    88000019
         END                                                            88800019
